src/HOL/Nat.thy
author Thomas Sewell <thomas.sewell@nicta.com.au>
Wed Jun 11 14:24:23 2014 +1000 (2014-06-11)
changeset 57492 74bf65a1910a
parent 57200 aab87ffa60cc
child 57512 cc97b347b301
permissions -rw-r--r--
Hypsubst preserves equality hypotheses

Fixes included for various theories affected by this change.
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 ML_file "Tools/arith_data.ML"
    16 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    17 
    18 
    19 subsection {* Type @{text ind} *}
    20 
    21 typedecl ind
    22 
    23 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    24   -- {* the axiom of infinity in 2 parts *}
    25   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 
    28 subsection {* Type nat *}
    29 
    30 text {* Type definition *}
    31 
    32 inductive Nat :: "ind \<Rightarrow> bool" where
    33   Zero_RepI: "Nat Zero_Rep"
    34 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    35 
    36 typedef nat = "{n. Nat n}"
    37   morphisms Rep_Nat Abs_Nat
    38   using Nat.Zero_RepI by auto
    39 
    40 lemma Nat_Rep_Nat:
    41   "Nat (Rep_Nat n)"
    42   using Rep_Nat by simp
    43 
    44 lemma Nat_Abs_Nat_inverse:
    45   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    46   using Abs_Nat_inverse by simp
    47 
    48 lemma Nat_Abs_Nat_inject:
    49   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    50   using Abs_Nat_inject by simp
    51 
    52 instantiation nat :: zero
    53 begin
    54 
    55 definition Zero_nat_def:
    56   "0 = Abs_Nat Zero_Rep"
    57 
    58 instance ..
    59 
    60 end
    61 
    62 definition Suc :: "nat \<Rightarrow> nat" where
    63   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    67 
    68 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    69   by (rule not_sym, rule Suc_not_Zero not_sym)
    70 
    71 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    72   by (rule iffI, rule Suc_Rep_inject) simp_all
    73 
    74 lemma nat_induct0:
    75   fixes n
    76   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    77   shows "P n"
    78 using assms
    79 apply (unfold Zero_nat_def Suc_def)
    80 apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    81 apply (erule Nat_Rep_Nat [THEN Nat.induct])
    82 apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    83 done
    84 
    85 free_constructors case_nat for
    86     "0 \<Colon> nat"
    87   | Suc pred
    88 where
    89   "pred (0 \<Colon> nat) = (0 \<Colon> nat)"
    90   apply atomize_elim
    91   apply (rename_tac n, induct_tac n rule: nat_induct0, auto)
    92  apply (simp add: Suc_def Nat_Abs_Nat_inject Nat_Rep_Nat Suc_RepI
    93    Suc_Rep_inject' Rep_Nat_inject)
    94 apply (simp only: Suc_not_Zero)
    95 done
    96 
    97 -- {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    98 setup {* Sign.mandatory_path "old" *}
    99 
   100 rep_datatype "0 \<Colon> nat" Suc
   101   apply (erule nat_induct0, assumption)
   102  apply (rule nat.inject)
   103 apply (rule nat.distinct(1))
   104 done
   105 
   106 setup {* Sign.parent_path *}
   107 
   108 -- {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   109 setup {* Sign.mandatory_path "nat" *}
   110 
   111 declare
   112   old.nat.inject[iff del]
   113   old.nat.distinct(1)[simp del, induct_simp del]
   114 
   115 lemmas induct = old.nat.induct
   116 lemmas inducts = old.nat.inducts
   117 lemmas rec = old.nat.rec
   118 lemmas simps = nat.inject nat.distinct nat.case nat.rec
   119 
   120 setup {* Sign.parent_path *}
   121 
   122 abbreviation rec_nat :: "'a \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a" where
   123   "rec_nat \<equiv> old.rec_nat"
   124 
   125 declare nat.sel[code del]
   126 
   127 hide_const (open) Nat.pred -- {* hide everything related to the selector *}
   128 hide_fact
   129   nat.case_eq_if
   130   nat.collapse
   131   nat.expand
   132   nat.sel
   133   nat.sel_exhaust
   134   nat.sel_split
   135   nat.sel_split_asm
   136 
   137 lemma nat_exhaust [case_names 0 Suc, cases type: nat]:
   138   -- {* for backward compatibility -- names of variables differ *}
   139   "(y = 0 \<Longrightarrow> P) \<Longrightarrow> (\<And>nat. y = Suc nat \<Longrightarrow> P) \<Longrightarrow> P"
   140 by (rule old.nat.exhaust)
   141 
   142 lemma nat_induct [case_names 0 Suc, induct type: nat]:
   143   -- {* for backward compatibility -- names of variables differ *}
   144   fixes n
   145   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
   146   shows "P n"
   147 using assms by (rule nat.induct)
   148 
   149 hide_fact
   150   nat_exhaust
   151   nat_induct0
   152 
   153 text {* Injectiveness and distinctness lemmas *}
   154 
   155 lemma inj_Suc[simp]: "inj_on Suc N"
   156   by (simp add: inj_on_def)
   157 
   158 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   159 by (rule notE, rule Suc_not_Zero)
   160 
   161 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   162 by (rule Suc_neq_Zero, erule sym)
   163 
   164 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   165 by (rule inj_Suc [THEN injD])
   166 
   167 lemma n_not_Suc_n: "n \<noteq> Suc n"
   168 by (induct n) simp_all
   169 
   170 lemma Suc_n_not_n: "Suc n \<noteq> n"
   171 by (rule not_sym, rule n_not_Suc_n)
   172 
   173 text {* A special form of induction for reasoning
   174   about @{term "m < n"} and @{term "m - n"} *}
   175 
   176 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   177     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   178   apply (rule_tac x = m in spec)
   179   apply (induct n)
   180   prefer 2
   181   apply (rule allI)
   182   apply (induct_tac x, iprover+)
   183   done
   184 
   185 
   186 subsection {* Arithmetic operators *}
   187 
   188 instantiation nat :: comm_monoid_diff
   189 begin
   190 
   191 primrec plus_nat where
   192   add_0:      "0 + n = (n\<Colon>nat)"
   193 | add_Suc:  "Suc m + n = Suc (m + n)"
   194 
   195 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   196   by (induct m) simp_all
   197 
   198 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   199   by (induct m) simp_all
   200 
   201 declare add_0 [code]
   202 
   203 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   204   by simp
   205 
   206 primrec minus_nat where
   207   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   208 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   209 
   210 declare diff_Suc [simp del]
   211 
   212 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   213   by (induct n) (simp_all add: diff_Suc)
   214 
   215 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   216   by (induct n) (simp_all add: diff_Suc)
   217 
   218 instance proof
   219   fix n m q :: nat
   220   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   221   show "n + m = m + n" by (induct n) simp_all
   222   show "0 + n = n" by simp
   223   show "n - 0 = n" by simp
   224   show "0 - n = 0" by simp
   225   show "(q + n) - (q + m) = n - m" by (induct q) simp_all
   226   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   227 qed
   228 
   229 end
   230 
   231 hide_fact (open) add_0 add_0_right diff_0
   232 
   233 instantiation nat :: comm_semiring_1_cancel
   234 begin
   235 
   236 definition
   237   One_nat_def [simp]: "1 = Suc 0"
   238 
   239 primrec times_nat where
   240   mult_0:     "0 * n = (0\<Colon>nat)"
   241 | mult_Suc: "Suc m * n = n + (m * n)"
   242 
   243 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   244   by (induct m) simp_all
   245 
   246 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   247   by (induct m) (simp_all add: add_left_commute)
   248 
   249 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   250   by (induct m) (simp_all add: add_assoc)
   251 
   252 instance proof
   253   fix n m q :: nat
   254   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   255   show "1 * n = n" unfolding One_nat_def by simp
   256   show "n * m = m * n" by (induct n) simp_all
   257   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   258   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   259   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   260 qed
   261 
   262 end
   263 
   264 subsubsection {* Addition *}
   265 
   266 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   267   by (rule add_assoc)
   268 
   269 lemma nat_add_commute: "m + n = n + (m::nat)"
   270   by (rule add_commute)
   271 
   272 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   273   by (rule add_left_commute)
   274 
   275 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   276   by (rule add_left_cancel)
   277 
   278 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   279   by (rule add_right_cancel)
   280 
   281 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   282 
   283 lemma add_is_0 [iff]:
   284   fixes m n :: nat
   285   shows "(m + n = 0) = (m = 0 & n = 0)"
   286   by (cases m) simp_all
   287 
   288 lemma add_is_1:
   289   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   290   by (cases m) simp_all
   291 
   292 lemma one_is_add:
   293   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   294   by (rule trans, rule eq_commute, rule add_is_1)
   295 
   296 lemma add_eq_self_zero:
   297   fixes m n :: nat
   298   shows "m + n = m \<Longrightarrow> n = 0"
   299   by (induct m) simp_all
   300 
   301 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   302   apply (induct k)
   303    apply simp
   304   apply(drule comp_inj_on[OF _ inj_Suc])
   305   apply (simp add:o_def)
   306   done
   307 
   308 lemma Suc_eq_plus1: "Suc n = n + 1"
   309   unfolding One_nat_def by simp
   310 
   311 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   312   unfolding One_nat_def by simp
   313 
   314 
   315 subsubsection {* Difference *}
   316 
   317 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   318   by (induct m) simp_all
   319 
   320 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   321   by (induct i j rule: diff_induct) simp_all
   322 
   323 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   324   by (simp add: diff_diff_left)
   325 
   326 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   327   by (simp add: diff_diff_left add_commute)
   328 
   329 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   330   by (induct n) simp_all
   331 
   332 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   333   by (simp add: diff_add_inverse add_commute [of m n])
   334 
   335 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   336   by (induct k) simp_all
   337 
   338 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   339   by (simp add: diff_cancel add_commute)
   340 
   341 lemma diff_add_0: "n - (n + m) = (0::nat)"
   342   by (induct n) simp_all
   343 
   344 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   345   unfolding One_nat_def by simp
   346 
   347 text {* Difference distributes over multiplication *}
   348 
   349 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   350 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   351 
   352 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   353 by (simp add: diff_mult_distrib mult_commute [of k])
   354   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   355 
   356 
   357 subsubsection {* Multiplication *}
   358 
   359 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   360   by (rule mult_assoc)
   361 
   362 lemma nat_mult_commute: "m * n = n * (m::nat)"
   363   by (rule mult_commute)
   364 
   365 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   366   by (rule distrib_left)
   367 
   368 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   369   by (induct m) auto
   370 
   371 lemmas nat_distrib =
   372   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   373 
   374 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   375   apply (induct m)
   376    apply simp
   377   apply (induct n)
   378    apply auto
   379   done
   380 
   381 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   382   apply (rule trans)
   383   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   384   done
   385 
   386 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   387   unfolding One_nat_def by (rule mult_eq_1_iff)
   388 
   389 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   390   unfolding One_nat_def by (rule one_eq_mult_iff)
   391 
   392 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   393 proof -
   394   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   395   proof (induct n arbitrary: m)
   396     case 0 then show "m = 0" by simp
   397   next
   398     case (Suc n) then show "m = Suc n"
   399       by (cases m) (simp_all add: eq_commute [of "0"])
   400   qed
   401   then show ?thesis by auto
   402 qed
   403 
   404 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   405   by (simp add: mult_commute)
   406 
   407 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   408   by (subst mult_cancel1) simp
   409 
   410 
   411 subsection {* Orders on @{typ nat} *}
   412 
   413 subsubsection {* Operation definition *}
   414 
   415 instantiation nat :: linorder
   416 begin
   417 
   418 primrec less_eq_nat where
   419   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   420 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   421 
   422 declare less_eq_nat.simps [simp del]
   423 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   424 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by simp
   425 
   426 definition less_nat where
   427   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   428 
   429 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   430   by (simp add: less_eq_nat.simps(2))
   431 
   432 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   433   unfolding less_eq_Suc_le ..
   434 
   435 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   436   by (induct n) (simp_all add: less_eq_nat.simps(2))
   437 
   438 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   439   by (simp add: less_eq_Suc_le)
   440 
   441 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   442   by simp
   443 
   444 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   445   by (simp add: less_eq_Suc_le)
   446 
   447 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   448   by (simp add: less_eq_Suc_le)
   449 
   450 lemma Suc_less_eq2: "Suc n < m \<longleftrightarrow> (\<exists>m'. m = Suc m' \<and> n < m')"
   451   by (cases m) auto
   452 
   453 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   454   by (induct m arbitrary: n)
   455     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   456 
   457 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   458   by (cases n) (auto intro: le_SucI)
   459 
   460 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   461   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   462 
   463 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   464   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   465 
   466 instance
   467 proof
   468   fix n m :: nat
   469   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   470   proof (induct n arbitrary: m)
   471     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   472   next
   473     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   474   qed
   475 next
   476   fix n :: nat show "n \<le> n" by (induct n) simp_all
   477 next
   478   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   479   then show "n = m"
   480     by (induct n arbitrary: m)
   481       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   482 next
   483   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   484   then show "n \<le> q"
   485   proof (induct n arbitrary: m q)
   486     case 0 show ?case by simp
   487   next
   488     case (Suc n) then show ?case
   489       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   490         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   491         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   492   qed
   493 next
   494   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   495     by (induct n arbitrary: m)
   496       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   497 qed
   498 
   499 end
   500 
   501 instantiation nat :: order_bot
   502 begin
   503 
   504 definition bot_nat :: nat where
   505   "bot_nat = 0"
   506 
   507 instance proof
   508 qed (simp add: bot_nat_def)
   509 
   510 end
   511 
   512 instance nat :: no_top
   513   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   514 
   515 
   516 subsubsection {* Introduction properties *}
   517 
   518 lemma lessI [iff]: "n < Suc n"
   519   by (simp add: less_Suc_eq_le)
   520 
   521 lemma zero_less_Suc [iff]: "0 < Suc n"
   522   by (simp add: less_Suc_eq_le)
   523 
   524 
   525 subsubsection {* Elimination properties *}
   526 
   527 lemma less_not_refl: "~ n < (n::nat)"
   528   by (rule order_less_irrefl)
   529 
   530 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   531   by (rule not_sym) (rule less_imp_neq) 
   532 
   533 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   534   by (rule less_imp_neq)
   535 
   536 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   537   by (rule notE, rule less_not_refl)
   538 
   539 lemma less_zeroE: "(n::nat) < 0 ==> R"
   540   by (rule notE) (rule not_less0)
   541 
   542 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   543   unfolding less_Suc_eq_le le_less ..
   544 
   545 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   546   by (simp add: less_Suc_eq)
   547 
   548 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   549   unfolding One_nat_def by (rule less_Suc0)
   550 
   551 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   552   by simp
   553 
   554 text {* "Less than" is antisymmetric, sort of *}
   555 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   556   unfolding not_less less_Suc_eq_le by (rule antisym)
   557 
   558 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   559   by (rule linorder_neq_iff)
   560 
   561 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   562   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   563   shows "P n m"
   564   apply (rule less_linear [THEN disjE])
   565   apply (erule_tac [2] disjE)
   566   apply (erule lessCase)
   567   apply (erule sym [THEN eqCase])
   568   apply (erule major)
   569   done
   570 
   571 
   572 subsubsection {* Inductive (?) properties *}
   573 
   574 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   575   unfolding less_eq_Suc_le [of m] le_less by simp 
   576 
   577 lemma lessE:
   578   assumes major: "i < k"
   579   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   580   shows P
   581 proof -
   582   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   583     unfolding less_eq_Suc_le by (induct k) simp_all
   584   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   585     by (clarsimp simp add: less_le)
   586   with p1 p2 show P by auto
   587 qed
   588 
   589 lemma less_SucE: assumes major: "m < Suc n"
   590   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   591   apply (rule major [THEN lessE])
   592   apply (rule eq, blast)
   593   apply (rule less, blast)
   594   done
   595 
   596 lemma Suc_lessE: assumes major: "Suc i < k"
   597   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   598   apply (rule major [THEN lessE])
   599   apply (erule lessI [THEN minor])
   600   apply (erule Suc_lessD [THEN minor], assumption)
   601   done
   602 
   603 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   604   by simp
   605 
   606 lemma less_trans_Suc:
   607   assumes le: "i < j" shows "j < k ==> Suc i < k"
   608   apply (induct k, simp_all)
   609   apply (insert le)
   610   apply (simp add: less_Suc_eq)
   611   apply (blast dest: Suc_lessD)
   612   done
   613 
   614 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   615 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   616   unfolding not_less less_Suc_eq_le ..
   617 
   618 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   619   unfolding not_le Suc_le_eq ..
   620 
   621 text {* Properties of "less than or equal" *}
   622 
   623 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   624   unfolding less_Suc_eq_le .
   625 
   626 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   627   unfolding not_le less_Suc_eq_le ..
   628 
   629 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   630   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   631 
   632 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   633   by (drule le_Suc_eq [THEN iffD1], iprover+)
   634 
   635 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   636   unfolding Suc_le_eq .
   637 
   638 text {* Stronger version of @{text Suc_leD} *}
   639 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   640   unfolding Suc_le_eq .
   641 
   642 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   643   unfolding less_eq_Suc_le by (rule Suc_leD)
   644 
   645 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   646 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   647 
   648 
   649 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   650 
   651 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   652   unfolding le_less .
   653 
   654 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   655   by (rule le_less)
   656 
   657 text {* Useful with @{text blast}. *}
   658 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   659   by auto
   660 
   661 lemma le_refl: "n \<le> (n::nat)"
   662   by simp
   663 
   664 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   665   by (rule order_trans)
   666 
   667 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   668   by (rule antisym)
   669 
   670 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   671   by (rule less_le)
   672 
   673 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   674   unfolding less_le ..
   675 
   676 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   677   by (rule linear)
   678 
   679 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   680 
   681 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   682   unfolding less_Suc_eq_le by auto
   683 
   684 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   685   unfolding not_less by (rule le_less_Suc_eq)
   686 
   687 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   688 
   689 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   690 by (cases n) simp_all
   691 
   692 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   693 by (cases n) simp_all
   694 
   695 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   696 by (cases n) simp_all
   697 
   698 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   699 by (cases n) simp_all
   700 
   701 text {* This theorem is useful with @{text blast} *}
   702 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   703 by (rule neq0_conv[THEN iffD1], iprover)
   704 
   705 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   706 by (fast intro: not0_implies_Suc)
   707 
   708 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   709 using neq0_conv by blast
   710 
   711 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   712 by (induct m') simp_all
   713 
   714 text {* Useful in certain inductive arguments *}
   715 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   716 by (cases m) simp_all
   717 
   718 
   719 subsubsection {* Monotonicity of Addition *}
   720 
   721 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   722 by (simp add: diff_Suc split: nat.split)
   723 
   724 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   725 unfolding One_nat_def by (rule Suc_pred)
   726 
   727 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   728 by (induct k) simp_all
   729 
   730 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   731 by (induct k) simp_all
   732 
   733 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   734 by(auto dest:gr0_implies_Suc)
   735 
   736 text {* strict, in 1st argument *}
   737 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   738 by (induct k) simp_all
   739 
   740 text {* strict, in both arguments *}
   741 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   742   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   743   apply (induct j, simp_all)
   744   done
   745 
   746 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   747 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   748   apply (induct n)
   749   apply (simp_all add: order_le_less)
   750   apply (blast elim!: less_SucE
   751                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   752   done
   753 
   754 lemma le_Suc_ex: "(k::nat) \<le> l \<Longrightarrow> (\<exists>n. l = k + n)"
   755   by (auto simp: less_Suc_eq_le[symmetric] dest: less_imp_Suc_add)
   756 
   757 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   758 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   759 apply(auto simp: gr0_conv_Suc)
   760 apply (induct_tac m)
   761 apply (simp_all add: add_less_mono)
   762 done
   763 
   764 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   765 instance nat :: linordered_semidom
   766 proof
   767   show "0 < (1::nat)" by simp
   768   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   769   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   770 qed
   771 
   772 instance nat :: no_zero_divisors
   773 proof
   774   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   775 qed
   776 
   777 
   778 subsubsection {* @{term min} and @{term max} *}
   779 
   780 lemma mono_Suc: "mono Suc"
   781 by (rule monoI) simp
   782 
   783 lemma min_0L [simp]: "min 0 n = (0::nat)"
   784 by (rule min_absorb1) simp
   785 
   786 lemma min_0R [simp]: "min n 0 = (0::nat)"
   787 by (rule min_absorb2) simp
   788 
   789 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   790 by (simp add: mono_Suc min_of_mono)
   791 
   792 lemma min_Suc1:
   793    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   794 by (simp split: nat.split)
   795 
   796 lemma min_Suc2:
   797    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   798 by (simp split: nat.split)
   799 
   800 lemma max_0L [simp]: "max 0 n = (n::nat)"
   801 by (rule max_absorb2) simp
   802 
   803 lemma max_0R [simp]: "max n 0 = (n::nat)"
   804 by (rule max_absorb1) simp
   805 
   806 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   807 by (simp add: mono_Suc max_of_mono)
   808 
   809 lemma max_Suc1:
   810    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   811 by (simp split: nat.split)
   812 
   813 lemma max_Suc2:
   814    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   815 by (simp split: nat.split)
   816 
   817 lemma nat_mult_min_left:
   818   fixes m n q :: nat
   819   shows "min m n * q = min (m * q) (n * q)"
   820   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   821 
   822 lemma nat_mult_min_right:
   823   fixes m n q :: nat
   824   shows "m * min n q = min (m * n) (m * q)"
   825   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   826 
   827 lemma nat_add_max_left:
   828   fixes m n q :: nat
   829   shows "max m n + q = max (m + q) (n + q)"
   830   by (simp add: max_def)
   831 
   832 lemma nat_add_max_right:
   833   fixes m n q :: nat
   834   shows "m + max n q = max (m + n) (m + q)"
   835   by (simp add: max_def)
   836 
   837 lemma nat_mult_max_left:
   838   fixes m n q :: nat
   839   shows "max m n * q = max (m * q) (n * q)"
   840   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   841 
   842 lemma nat_mult_max_right:
   843   fixes m n q :: nat
   844   shows "m * max n q = max (m * n) (m * q)"
   845   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   846 
   847 
   848 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   849 
   850 text {* Complete induction, aka course-of-values induction *}
   851 
   852 instance nat :: wellorder proof
   853   fix P and n :: nat
   854   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   855   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   856   proof (induct n)
   857     case (0 n)
   858     have "P 0" by (rule step) auto
   859     thus ?case using 0 by auto
   860   next
   861     case (Suc m n)
   862     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   863     thus ?case
   864     proof
   865       assume "n \<le> m" thus "P n" by (rule Suc(1))
   866     next
   867       assume n: "n = Suc m"
   868       show "P n"
   869         by (rule step) (rule Suc(1), simp add: n le_simps)
   870     qed
   871   qed
   872   then show "P n" by auto
   873 qed
   874 
   875 
   876 lemma Least_eq_0[simp]: "P(0::nat) \<Longrightarrow> Least P = 0"
   877 by (rule Least_equality[OF _ le0])
   878 
   879 lemma Least_Suc:
   880      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   881   apply (cases n, auto)
   882   apply (frule LeastI)
   883   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   884   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   885   apply (erule_tac [2] Least_le)
   886   apply (cases "LEAST x. P x", auto)
   887   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   888   apply (blast intro: order_antisym)
   889   done
   890 
   891 lemma Least_Suc2:
   892    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   893   apply (erule (1) Least_Suc [THEN ssubst])
   894   apply simp
   895   done
   896 
   897 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   898   apply (cases n)
   899    apply blast
   900   apply (rule_tac x="LEAST k. P(k)" in exI)
   901   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   902   done
   903 
   904 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   905   unfolding One_nat_def
   906   apply (cases n)
   907    apply blast
   908   apply (frule (1) ex_least_nat_le)
   909   apply (erule exE)
   910   apply (case_tac k)
   911    apply simp
   912   apply (rename_tac k1)
   913   apply (rule_tac x=k1 in exI)
   914   apply (auto simp add: less_eq_Suc_le)
   915   done
   916 
   917 lemma nat_less_induct:
   918   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   919   using assms less_induct by blast
   920 
   921 lemma measure_induct_rule [case_names less]:
   922   fixes f :: "'a \<Rightarrow> nat"
   923   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   924   shows "P a"
   925 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   926 
   927 text {* old style induction rules: *}
   928 lemma measure_induct:
   929   fixes f :: "'a \<Rightarrow> nat"
   930   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   931   by (rule measure_induct_rule [of f P a]) iprover
   932 
   933 lemma full_nat_induct:
   934   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   935   shows "P n"
   936   by (rule less_induct) (auto intro: step simp:le_simps)
   937 
   938 text{*An induction rule for estabilishing binary relations*}
   939 lemma less_Suc_induct:
   940   assumes less:  "i < j"
   941      and  step:  "!!i. P i (Suc i)"
   942      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   943   shows "P i j"
   944 proof -
   945   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   946   have "P i (Suc (i + k))"
   947   proof (induct k)
   948     case 0
   949     show ?case by (simp add: step)
   950   next
   951     case (Suc k)
   952     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   953     hence "i < Suc (i + k)" by (simp add: add_commute)
   954     from trans[OF this lessI Suc step]
   955     show ?case by simp
   956   qed
   957   thus "P i j" by (simp add: j)
   958 qed
   959 
   960 text {* The method of infinite descent, frequently used in number theory.
   961 Provided by Roelof Oosterhuis.
   962 $P(n)$ is true for all $n\in\mathbb{N}$ if
   963 \begin{itemize}
   964   \item case ``0'': given $n=0$ prove $P(n)$,
   965   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   966         a smaller integer $m$ such that $\neg P(m)$.
   967 \end{itemize} *}
   968 
   969 text{* A compact version without explicit base case: *}
   970 lemma infinite_descent:
   971   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   972 by (induct n rule: less_induct) auto
   973 
   974 lemma infinite_descent0[case_names 0 smaller]: 
   975   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   976 by (rule infinite_descent) (case_tac "n>0", auto)
   977 
   978 text {*
   979 Infinite descent using a mapping to $\mathbb{N}$:
   980 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   981 \begin{itemize}
   982 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   983 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   984 \end{itemize}
   985 NB: the proof also shows how to use the previous lemma. *}
   986 
   987 corollary infinite_descent0_measure [case_names 0 smaller]:
   988   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   989     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   990   shows "P x"
   991 proof -
   992   obtain n where "n = V x" by auto
   993   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   994   proof (induct n rule: infinite_descent0)
   995     case 0 -- "i.e. $V(x) = 0$"
   996     with A0 show "P x" by auto
   997   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   998     case (smaller n)
   999     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
  1000     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
  1001     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
  1002     then show ?case by auto
  1003   qed
  1004   ultimately show "P x" by auto
  1005 qed
  1006 
  1007 text{* Again, without explicit base case: *}
  1008 lemma infinite_descent_measure:
  1009 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
  1010 proof -
  1011   from assms obtain n where "n = V x" by auto
  1012   moreover have "!!x. V x = n \<Longrightarrow> P x"
  1013   proof (induct n rule: infinite_descent, auto)
  1014     fix x assume "\<not> P x"
  1015     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
  1016   qed
  1017   ultimately show "P x" by auto
  1018 qed
  1019 
  1020 text {* A [clumsy] way of lifting @{text "<"}
  1021   monotonicity to @{text "\<le>"} monotonicity *}
  1022 lemma less_mono_imp_le_mono:
  1023   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
  1024 by (simp add: order_le_less) (blast)
  1025 
  1026 
  1027 text {* non-strict, in 1st argument *}
  1028 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
  1029 by (rule add_right_mono)
  1030 
  1031 text {* non-strict, in both arguments *}
  1032 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
  1033 by (rule add_mono)
  1034 
  1035 lemma le_add2: "n \<le> ((m + n)::nat)"
  1036 by (insert add_right_mono [of 0 m n], simp)
  1037 
  1038 lemma le_add1: "n \<le> ((n + m)::nat)"
  1039 by (simp add: add_commute, rule le_add2)
  1040 
  1041 lemma less_add_Suc1: "i < Suc (i + m)"
  1042 by (rule le_less_trans, rule le_add1, rule lessI)
  1043 
  1044 lemma less_add_Suc2: "i < Suc (m + i)"
  1045 by (rule le_less_trans, rule le_add2, rule lessI)
  1046 
  1047 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
  1048 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
  1049 
  1050 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
  1051 by (rule le_trans, assumption, rule le_add1)
  1052 
  1053 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1054 by (rule le_trans, assumption, rule le_add2)
  1055 
  1056 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1057 by (rule less_le_trans, assumption, rule le_add1)
  1058 
  1059 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1060 by (rule less_le_trans, assumption, rule le_add2)
  1061 
  1062 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1063 apply (rule le_less_trans [of _ "i+j"])
  1064 apply (simp_all add: le_add1)
  1065 done
  1066 
  1067 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1068 apply (rule notI)
  1069 apply (drule add_lessD1)
  1070 apply (erule less_irrefl [THEN notE])
  1071 done
  1072 
  1073 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1074 by (simp add: add_commute)
  1075 
  1076 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1077 apply (rule order_trans [of _ "m+k"])
  1078 apply (simp_all add: le_add1)
  1079 done
  1080 
  1081 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1082 apply (simp add: add_commute)
  1083 apply (erule add_leD1)
  1084 done
  1085 
  1086 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1087 by (blast dest: add_leD1 add_leD2)
  1088 
  1089 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1090 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1091 by (force simp del: add_Suc_right
  1092     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1093 
  1094 
  1095 subsubsection {* More results about difference *}
  1096 
  1097 text {* Addition is the inverse of subtraction:
  1098   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1099 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1100 by (induct m n rule: diff_induct) simp_all
  1101 
  1102 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1103 by (simp add: add_diff_inverse linorder_not_less)
  1104 
  1105 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1106 by (simp add: add_commute)
  1107 
  1108 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1109 by (induct m n rule: diff_induct) simp_all
  1110 
  1111 lemma diff_less_Suc: "m - n < Suc m"
  1112 apply (induct m n rule: diff_induct)
  1113 apply (erule_tac [3] less_SucE)
  1114 apply (simp_all add: less_Suc_eq)
  1115 done
  1116 
  1117 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1118 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1119 
  1120 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1121   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1122 
  1123 instance nat :: ordered_cancel_comm_monoid_diff
  1124 proof
  1125   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1126 qed
  1127 
  1128 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1129 by (rule le_less_trans, rule diff_le_self)
  1130 
  1131 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1132 by (cases n) (auto simp add: le_simps)
  1133 
  1134 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1135 by (induct j k rule: diff_induct) simp_all
  1136 
  1137 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1138 by (simp add: add_commute diff_add_assoc)
  1139 
  1140 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1141 by (auto simp add: diff_add_inverse2)
  1142 
  1143 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1144 by (induct m n rule: diff_induct) simp_all
  1145 
  1146 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1147 by (rule iffD2, rule diff_is_0_eq)
  1148 
  1149 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1150 by (induct m n rule: diff_induct) simp_all
  1151 
  1152 lemma less_imp_add_positive:
  1153   assumes "i < j"
  1154   shows "\<exists>k::nat. 0 < k & i + k = j"
  1155 proof
  1156   from assms show "0 < j - i & i + (j - i) = j"
  1157     by (simp add: order_less_imp_le)
  1158 qed
  1159 
  1160 text {* a nice rewrite for bounded subtraction *}
  1161 lemma nat_minus_add_max:
  1162   fixes n m :: nat
  1163   shows "n - m + m = max n m"
  1164     by (simp add: max_def not_le order_less_imp_le)
  1165 
  1166 lemma nat_diff_split:
  1167   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1168     -- {* elimination of @{text -} on @{text nat} *}
  1169 by (cases "a < b")
  1170   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1171     not_less le_less dest!: add_eq_self_zero add_eq_self_zero[OF sym])
  1172 
  1173 lemma nat_diff_split_asm:
  1174   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1175     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1176 by (auto split: nat_diff_split)
  1177 
  1178 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1179   by simp
  1180 
  1181 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1182   unfolding One_nat_def by (cases m) simp_all
  1183 
  1184 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1185   unfolding One_nat_def by (cases m) simp_all
  1186 
  1187 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1188   unfolding One_nat_def by (cases n) simp_all
  1189 
  1190 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1191   unfolding One_nat_def by (cases m) simp_all
  1192 
  1193 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1194   by (fact Let_def)
  1195 
  1196 
  1197 subsubsection {* Monotonicity of Multiplication *}
  1198 
  1199 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1200 by (simp add: mult_right_mono)
  1201 
  1202 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1203 by (simp add: mult_left_mono)
  1204 
  1205 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1206 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1207 by (simp add: mult_mono)
  1208 
  1209 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1210 by (simp add: mult_strict_right_mono)
  1211 
  1212 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1213       there are no negative numbers.*}
  1214 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1215   apply (induct m)
  1216    apply simp
  1217   apply (case_tac n)
  1218    apply simp_all
  1219   done
  1220 
  1221 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1222   apply (induct m)
  1223    apply simp
  1224   apply (case_tac n)
  1225    apply simp_all
  1226   done
  1227 
  1228 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1229   apply (safe intro!: mult_less_mono1)
  1230   apply (cases k, auto)
  1231   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1232   apply (blast intro: mult_le_mono1)
  1233   done
  1234 
  1235 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1236 by (simp add: mult_commute [of k])
  1237 
  1238 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1239 by (simp add: linorder_not_less [symmetric], auto)
  1240 
  1241 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1242 by (simp add: linorder_not_less [symmetric], auto)
  1243 
  1244 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1245 by (subst mult_less_cancel1) simp
  1246 
  1247 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1248 by (subst mult_le_cancel1) simp
  1249 
  1250 lemma le_square: "m \<le> m * (m::nat)"
  1251   by (cases m) (auto intro: le_add1)
  1252 
  1253 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1254   by (cases m) (auto intro: le_add1)
  1255 
  1256 text {* Lemma for @{text gcd} *}
  1257 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1258   apply (drule sym)
  1259   apply (rule disjCI)
  1260   apply (rule nat_less_cases, erule_tac [2] _)
  1261    apply (drule_tac [2] mult_less_mono2)
  1262     apply (auto)
  1263   done
  1264 
  1265 lemma mono_times_nat:
  1266   fixes n :: nat
  1267   assumes "n > 0"
  1268   shows "mono (times n)"
  1269 proof
  1270   fix m q :: nat
  1271   assume "m \<le> q"
  1272   with assms show "n * m \<le> n * q" by simp
  1273 qed
  1274 
  1275 text {* the lattice order on @{typ nat} *}
  1276 
  1277 instantiation nat :: distrib_lattice
  1278 begin
  1279 
  1280 definition
  1281   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1282 
  1283 definition
  1284   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1285 
  1286 instance by intro_classes
  1287   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1288     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1289 
  1290 end
  1291 
  1292 
  1293 subsection {* Natural operation of natural numbers on functions *}
  1294 
  1295 text {*
  1296   We use the same logical constant for the power operations on
  1297   functions and relations, in order to share the same syntax.
  1298 *}
  1299 
  1300 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1301 
  1302 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1303   "f ^^ n \<equiv> compow n f"
  1304 
  1305 notation (latex output)
  1306   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1307 
  1308 notation (HTML output)
  1309   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1310 
  1311 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1312 
  1313 overloading
  1314   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1315 begin
  1316 
  1317 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1318   "funpow 0 f = id"
  1319 | "funpow (Suc n) f = f o funpow n f"
  1320 
  1321 end
  1322 
  1323 lemma funpow_Suc_right:
  1324   "f ^^ Suc n = f ^^ n \<circ> f"
  1325 proof (induct n)
  1326   case 0 then show ?case by simp
  1327 next
  1328   fix n
  1329   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1330   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1331     by (simp add: o_assoc)
  1332 qed
  1333 
  1334 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1335 
  1336 text {* for code generation *}
  1337 
  1338 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1339   funpow_code_def [code_abbrev]: "funpow = compow"
  1340 
  1341 lemma [code]:
  1342   "funpow (Suc n) f = f o funpow n f"
  1343   "funpow 0 f = id"
  1344   by (simp_all add: funpow_code_def)
  1345 
  1346 hide_const (open) funpow
  1347 
  1348 lemma funpow_add:
  1349   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1350   by (induct m) simp_all
  1351 
  1352 lemma funpow_mult:
  1353   fixes f :: "'a \<Rightarrow> 'a"
  1354   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1355   by (induct n) (simp_all add: funpow_add)
  1356 
  1357 lemma funpow_swap1:
  1358   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1359 proof -
  1360   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1361   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1362   also have "\<dots> = (f ^^ n) (f x)" by simp
  1363   finally show ?thesis .
  1364 qed
  1365 
  1366 lemma comp_funpow:
  1367   fixes f :: "'a \<Rightarrow> 'a"
  1368   shows "comp f ^^ n = comp (f ^^ n)"
  1369   by (induct n) simp_all
  1370 
  1371 lemma Suc_funpow[simp]: "Suc ^^ n = (op + n)"
  1372   by (induct n) simp_all
  1373 
  1374 lemma id_funpow[simp]: "id ^^ n = id"
  1375   by (induct n) simp_all
  1376 
  1377 subsection {* Kleene iteration *}
  1378 
  1379 lemma Kleene_iter_lpfp:
  1380 assumes "mono f" and "f p \<le> p" shows "(f^^k) (bot::'a::order_bot) \<le> p"
  1381 proof(induction k)
  1382   case 0 show ?case by simp
  1383 next
  1384   case Suc
  1385   from monoD[OF assms(1) Suc] assms(2)
  1386   show ?case by simp
  1387 qed
  1388 
  1389 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1390 shows "lfp f = (f^^k) bot"
  1391 proof(rule antisym)
  1392   show "lfp f \<le> (f^^k) bot"
  1393   proof(rule lfp_lowerbound)
  1394     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1395   qed
  1396 next
  1397   show "(f^^k) bot \<le> lfp f"
  1398     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1399 qed
  1400 
  1401 
  1402 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1403 
  1404 context semiring_1
  1405 begin
  1406 
  1407 definition of_nat :: "nat \<Rightarrow> 'a" where
  1408   "of_nat n = (plus 1 ^^ n) 0"
  1409 
  1410 lemma of_nat_simps [simp]:
  1411   shows of_nat_0: "of_nat 0 = 0"
  1412     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1413   by (simp_all add: of_nat_def)
  1414 
  1415 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1416   by (simp add: of_nat_def)
  1417 
  1418 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1419   by (induct m) (simp_all add: add_ac)
  1420 
  1421 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1422   by (induct m) (simp_all add: add_ac distrib_right)
  1423 
  1424 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1425   "of_nat_aux inc 0 i = i"
  1426 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1427 
  1428 lemma of_nat_code:
  1429   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1430 proof (induct n)
  1431   case 0 then show ?case by simp
  1432 next
  1433   case (Suc n)
  1434   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1435     by (induct n) simp_all
  1436   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1437     by simp
  1438   with Suc show ?case by (simp add: add_commute)
  1439 qed
  1440 
  1441 end
  1442 
  1443 declare of_nat_code [code]
  1444 
  1445 text{*Class for unital semirings with characteristic zero.
  1446  Includes non-ordered rings like the complex numbers.*}
  1447 
  1448 class semiring_char_0 = semiring_1 +
  1449   assumes inj_of_nat: "inj of_nat"
  1450 begin
  1451 
  1452 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1453   by (auto intro: inj_of_nat injD)
  1454 
  1455 text{*Special cases where either operand is zero*}
  1456 
  1457 lemma of_nat_0_eq_iff [simp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1458   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1459 
  1460 lemma of_nat_eq_0_iff [simp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1461   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1462 
  1463 end
  1464 
  1465 context linordered_semidom
  1466 begin
  1467 
  1468 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1469   by (induct n) simp_all
  1470 
  1471 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1472   by (simp add: not_less)
  1473 
  1474 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1475   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1476 
  1477 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1478   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1479 
  1480 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1481   by simp
  1482 
  1483 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1484   by simp
  1485 
  1486 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1487 
  1488 subclass semiring_char_0 proof
  1489 qed (auto intro!: injI simp add: eq_iff)
  1490 
  1491 text{*Special cases where either operand is zero*}
  1492 
  1493 lemma of_nat_le_0_iff [simp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1494   by (rule of_nat_le_iff [of _ 0, simplified])
  1495 
  1496 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1497   by (rule of_nat_less_iff [of 0, simplified])
  1498 
  1499 end
  1500 
  1501 context ring_1
  1502 begin
  1503 
  1504 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1505 by (simp add: algebra_simps of_nat_add [symmetric])
  1506 
  1507 end
  1508 
  1509 context linordered_idom
  1510 begin
  1511 
  1512 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1513   unfolding abs_if by auto
  1514 
  1515 end
  1516 
  1517 lemma of_nat_id [simp]: "of_nat n = n"
  1518   by (induct n) simp_all
  1519 
  1520 lemma of_nat_eq_id [simp]: "of_nat = id"
  1521   by (auto simp add: fun_eq_iff)
  1522 
  1523 
  1524 subsection {* The Set of Natural Numbers *}
  1525 
  1526 context semiring_1
  1527 begin
  1528 
  1529 definition Nats  :: "'a set" where
  1530   "Nats = range of_nat"
  1531 
  1532 notation (xsymbols)
  1533   Nats  ("\<nat>")
  1534 
  1535 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1536   by (simp add: Nats_def)
  1537 
  1538 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1539 apply (simp add: Nats_def)
  1540 apply (rule range_eqI)
  1541 apply (rule of_nat_0 [symmetric])
  1542 done
  1543 
  1544 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1545 apply (simp add: Nats_def)
  1546 apply (rule range_eqI)
  1547 apply (rule of_nat_1 [symmetric])
  1548 done
  1549 
  1550 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1551 apply (auto simp add: Nats_def)
  1552 apply (rule range_eqI)
  1553 apply (rule of_nat_add [symmetric])
  1554 done
  1555 
  1556 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1557 apply (auto simp add: Nats_def)
  1558 apply (rule range_eqI)
  1559 apply (rule of_nat_mult [symmetric])
  1560 done
  1561 
  1562 lemma Nats_cases [cases set: Nats]:
  1563   assumes "x \<in> \<nat>"
  1564   obtains (of_nat) n where "x = of_nat n"
  1565   unfolding Nats_def
  1566 proof -
  1567   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1568   then obtain n where "x = of_nat n" ..
  1569   then show thesis ..
  1570 qed
  1571 
  1572 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1573   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1574   by (rule Nats_cases) auto
  1575 
  1576 end
  1577 
  1578 
  1579 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1580 
  1581 lemma subst_equals:
  1582   assumes 1: "t = s" and 2: "u = t"
  1583   shows "u = s"
  1584   using 2 1 by (rule trans)
  1585 
  1586 setup Arith_Data.setup
  1587 
  1588 ML_file "Tools/nat_arith.ML"
  1589 
  1590 simproc_setup nateq_cancel_sums
  1591   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1592   {* fn phi => try o Nat_Arith.cancel_eq_conv *}
  1593 
  1594 simproc_setup natless_cancel_sums
  1595   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1596   {* fn phi => try o Nat_Arith.cancel_less_conv *}
  1597 
  1598 simproc_setup natle_cancel_sums
  1599   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1600   {* fn phi => try o Nat_Arith.cancel_le_conv *}
  1601 
  1602 simproc_setup natdiff_cancel_sums
  1603   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1604   {* fn phi => try o Nat_Arith.cancel_diff_conv *}
  1605 
  1606 ML_file "Tools/lin_arith.ML"
  1607 setup {* Lin_Arith.global_setup *}
  1608 declaration {* K Lin_Arith.setup *}
  1609 
  1610 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1611   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1612 (* Because of this simproc, the arithmetic solver is really only
  1613 useful to detect inconsistencies among the premises for subgoals which are
  1614 *not* themselves (in)equalities, because the latter activate
  1615 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1616 solver all the time rather than add the additional check. *)
  1617 
  1618 
  1619 lemmas [arith_split] = nat_diff_split split_min split_max
  1620 
  1621 context order
  1622 begin
  1623 
  1624 lemma lift_Suc_mono_le:
  1625   assumes mono: "\<And>n. f n \<le> f (Suc n)" and "n \<le> n'"
  1626   shows "f n \<le> f n'"
  1627 proof (cases "n < n'")
  1628   case True
  1629   then show ?thesis
  1630     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1631 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1632 
  1633 lemma lift_Suc_antimono_le:
  1634   assumes mono: "\<And>n. f n \<ge> f (Suc n)" and "n \<le> n'"
  1635   shows "f n \<ge> f n'"
  1636 proof (cases "n < n'")
  1637   case True
  1638   then show ?thesis
  1639     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1640 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1641 
  1642 lemma lift_Suc_mono_less:
  1643   assumes mono: "\<And>n. f n < f (Suc n)" and "n < n'"
  1644   shows "f n < f n'"
  1645 using `n < n'`
  1646 by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1647 
  1648 lemma lift_Suc_mono_less_iff:
  1649   "(\<And>n. f n < f (Suc n)) \<Longrightarrow> f n < f m \<longleftrightarrow> n < m"
  1650   by (blast intro: less_asym' lift_Suc_mono_less [of f]
  1651     dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq [THEN iffD1])
  1652 
  1653 end
  1654 
  1655 lemma mono_iff_le_Suc:
  1656   "mono f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1657   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1658 
  1659 lemma antimono_iff_le_Suc:
  1660   "antimono f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1661   unfolding antimono_def by (auto intro: lift_Suc_antimono_le [of f])
  1662 
  1663 lemma mono_nat_linear_lb:
  1664   fixes f :: "nat \<Rightarrow> nat"
  1665   assumes "\<And>m n. m < n \<Longrightarrow> f m < f n"
  1666   shows "f m + k \<le> f (m + k)"
  1667 proof (induct k)
  1668   case 0 then show ?case by simp
  1669 next
  1670   case (Suc k)
  1671   then have "Suc (f m + k) \<le> Suc (f (m + k))" by simp
  1672   also from assms [of "m + k" "Suc (m + k)"] have "Suc (f (m + k)) \<le> f (Suc (m + k))"
  1673     by (simp add: Suc_le_eq)
  1674   finally show ?case by simp
  1675 qed
  1676 
  1677 
  1678 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1679 
  1680 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1681 by arith
  1682 
  1683 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1684 by arith
  1685 
  1686 lemma less_diff_conv2:
  1687   fixes j k i :: nat
  1688   assumes "k \<le> j"
  1689   shows "j - k < i \<longleftrightarrow> j < i + k"
  1690   using assms by arith
  1691 
  1692 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1693 by arith
  1694 
  1695 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1696 by arith
  1697 
  1698 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1699 by arith
  1700 
  1701 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1702 by arith
  1703 
  1704 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1705   second premise n\<le>m*)
  1706 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1707 by arith
  1708 
  1709 text {* Simplification of relational expressions involving subtraction *}
  1710 
  1711 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1712 by (simp split add: nat_diff_split)
  1713 
  1714 hide_fact (open) diff_diff_eq
  1715 
  1716 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1717 by (auto split add: nat_diff_split)
  1718 
  1719 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1720 by (auto split add: nat_diff_split)
  1721 
  1722 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1723 by (auto split add: nat_diff_split)
  1724 
  1725 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1726 
  1727 (* Monotonicity of subtraction in first argument *)
  1728 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1729 by (simp split add: nat_diff_split)
  1730 
  1731 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1732 by (simp split add: nat_diff_split)
  1733 
  1734 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1735 by (simp split add: nat_diff_split)
  1736 
  1737 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1738 by (simp split add: nat_diff_split)
  1739 
  1740 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1741 by auto
  1742 
  1743 lemma inj_on_diff_nat: 
  1744   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1745   shows "inj_on (\<lambda>n. n - k) N"
  1746 proof (rule inj_onI)
  1747   fix x y
  1748   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1749   with k_le_n have "x - k + k = y - k + k" by auto
  1750   with a k_le_n show "x = y" by auto
  1751 qed
  1752 
  1753 text{*Rewriting to pull differences out*}
  1754 
  1755 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1756 by arith
  1757 
  1758 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1759 by arith
  1760 
  1761 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1762 by arith
  1763 
  1764 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1765 by simp
  1766 
  1767 (*The others are
  1768       i - j - k = i - (j + k),
  1769       k \<le> j ==> j - k + i = j + i - k,
  1770       k \<le> j ==> i + (j - k) = i + j - k *)
  1771 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1772 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1773 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1774 
  1775 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1776 Least_Suc}, since there appears to be no need.*}
  1777 
  1778 text{*Lemmas for ex/Factorization*}
  1779 
  1780 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1781 by (cases m) auto
  1782 
  1783 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1784 by (cases m) auto
  1785 
  1786 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1787 by (cases m) auto
  1788 
  1789 text {* Specialized induction principles that work "backwards": *}
  1790 
  1791 lemma inc_induct[consumes 1, case_names base step]:
  1792   assumes less: "i \<le> j"
  1793   assumes base: "P j"
  1794   assumes step: "\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P (Suc n) \<Longrightarrow> P n"
  1795   shows "P i"
  1796   using less step
  1797 proof (induct d\<equiv>"j - i" arbitrary: i)
  1798   case (0 i)
  1799   hence "i = j" by simp
  1800   with base show ?case by simp
  1801 next
  1802   case (Suc d n)
  1803   hence "n \<le> n" "n < j" "P (Suc n)"
  1804     by simp_all
  1805   then show "P n" by fact
  1806 qed
  1807 
  1808 lemma strict_inc_induct[consumes 1, case_names base step]:
  1809   assumes less: "i < j"
  1810   assumes base: "!!i. j = Suc i ==> P i"
  1811   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1812   shows "P i"
  1813   using less
  1814 proof (induct d=="j - i - 1" arbitrary: i)
  1815   case (0 i)
  1816   with `i < j` have "j = Suc i" by simp
  1817   with base show ?case by simp
  1818 next
  1819   case (Suc d i)
  1820   hence "i < j" "P (Suc i)"
  1821     by simp_all
  1822   thus "P i" by (rule step)
  1823 qed
  1824 
  1825 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1826   using inc_induct[of "k - i" k P, simplified] by blast
  1827 
  1828 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1829   using inc_induct[of 0 k P] by blast
  1830 
  1831 text {* Further induction rule similar to @{thm inc_induct} *}
  1832 
  1833 lemma dec_induct[consumes 1, case_names base step]:
  1834   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1835   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1836  
  1837 subsection {* The divides relation on @{typ nat} *}
  1838 
  1839 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1840 unfolding dvd_def by simp
  1841 
  1842 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1843 by (simp add: dvd_def)
  1844 
  1845 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1846 by (simp add: dvd_def)
  1847 
  1848 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1849   unfolding dvd_def
  1850   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1851 
  1852 text {* @{term "op dvd"} is a partial order *}
  1853 
  1854 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1855   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1856 
  1857 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1858 unfolding dvd_def
  1859 by (blast intro: diff_mult_distrib2 [symmetric])
  1860 
  1861 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1862   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1863   apply (blast intro: dvd_add)
  1864   done
  1865 
  1866 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1867 by (drule_tac m = m in dvd_diff_nat, auto)
  1868 
  1869 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1870   apply (rule iffI)
  1871    apply (erule_tac [2] dvd_add)
  1872    apply (rule_tac [2] dvd_refl)
  1873   apply (subgoal_tac "n = (n+k) -k")
  1874    prefer 2 apply simp
  1875   apply (erule ssubst)
  1876   apply (erule dvd_diff_nat)
  1877   apply (rule dvd_refl)
  1878   done
  1879 
  1880 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1881   unfolding dvd_def
  1882   apply (erule exE)
  1883   apply (simp add: mult_ac)
  1884   done
  1885 
  1886 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1887   apply auto
  1888    apply (subgoal_tac "m*n dvd m*1")
  1889    apply (drule dvd_mult_cancel, auto)
  1890   done
  1891 
  1892 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1893   apply (subst mult_commute)
  1894   apply (erule dvd_mult_cancel1)
  1895   done
  1896 
  1897 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1898 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1899 
  1900 lemma nat_dvd_not_less:
  1901   fixes m n :: nat
  1902   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1903 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1904 
  1905 lemma dvd_plusE:
  1906   fixes m n q :: nat
  1907   assumes "m dvd n + q" "m dvd n"
  1908   obtains "m dvd q"
  1909 proof (cases "m = 0")
  1910   case True with assms that show thesis by simp
  1911 next
  1912   case False then have "m > 0" by simp
  1913   from assms obtain r s where "n = m * r" and "n + q = m * s" by (blast elim: dvdE)
  1914   then have *: "m * r + q = m * s" by simp
  1915   show thesis proof (cases "r \<le> s")
  1916     case False then have "s < r" by (simp add: not_le)
  1917     with * have "m * r + q - m * s = m * s - m * s" by simp
  1918     then have "m * r + q - m * s = 0" by simp
  1919     with `m > 0` `s < r` have "m * r - m * s + q = 0" by (unfold less_le_not_le) auto
  1920     then have "m * (r - s) + q = 0" by auto
  1921     then have "m * (r - s) = 0" by simp
  1922     then have "m = 0 \<or> r - s = 0" by simp
  1923     with `s < r` have "m = 0" by (simp add: less_le_not_le)
  1924     with `m > 0` show thesis by auto
  1925   next
  1926     case True with * have "m * r + q - m * r = m * s - m * r" by simp
  1927     with `m > 0` `r \<le> s` have "m * r - m * r + q = m * s - m * r" by simp
  1928     then have "q = m * (s - r)" by (simp add: diff_mult_distrib2)
  1929     with assms that show thesis by (auto intro: dvdI)
  1930   qed
  1931 qed
  1932 
  1933 lemma dvd_plus_eq_right:
  1934   fixes m n q :: nat
  1935   assumes "m dvd n"
  1936   shows "m dvd n + q \<longleftrightarrow> m dvd q"
  1937   using assms by (auto elim: dvd_plusE)
  1938 
  1939 lemma dvd_plus_eq_left:
  1940   fixes m n q :: nat
  1941   assumes "m dvd q"
  1942   shows "m dvd n + q \<longleftrightarrow> m dvd n"
  1943   using assms by (simp add: dvd_plus_eq_right add_commute [of n])
  1944 
  1945 lemma less_eq_dvd_minus:
  1946   fixes m n :: nat
  1947   assumes "m \<le> n"
  1948   shows "m dvd n \<longleftrightarrow> m dvd n - m"
  1949 proof -
  1950   from assms have "n = m + (n - m)" by simp
  1951   then obtain q where "n = m + q" ..
  1952   then show ?thesis by (simp add: dvd_reduce add_commute [of m])
  1953 qed
  1954 
  1955 lemma dvd_minus_self:
  1956   fixes m n :: nat
  1957   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1958   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1959 
  1960 lemma dvd_minus_add:
  1961   fixes m n q r :: nat
  1962   assumes "q \<le> n" "q \<le> r * m"
  1963   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1964 proof -
  1965   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1966     by (auto elim: dvd_plusE)
  1967   also from assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  1968   also from assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  1969   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add_commute)
  1970   finally show ?thesis .
  1971 qed
  1972 
  1973 
  1974 subsection {* aliases *}
  1975 
  1976 lemma nat_mult_1: "(1::nat) * n = n"
  1977   by (rule mult_1_left)
  1978  
  1979 lemma nat_mult_1_right: "n * (1::nat) = n"
  1980   by (rule mult_1_right)
  1981 
  1982 
  1983 subsection {* size of a datatype value *}
  1984 
  1985 class size =
  1986   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1987 
  1988 
  1989 subsection {* code module namespace *}
  1990 
  1991 code_identifier
  1992   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1993 
  1994 hide_const (open) of_nat_aux
  1995 
  1996 end