src/HOL/BNF_FP_Base.thy
author traytel
Tue Feb 25 18:14:26 2014 +0100 (2014-02-25)
changeset 55803 74d3fe9031d8
parent 55702 63c80031d8dd
child 55811 aa1acc25126b
permissions -rw-r--r--
joint work with blanchet: intermediate typedef for the input to fp-operations
     1 (*  Title:      HOL/BNF_FP_Base.thy
     2     Author:     Lorenz Panny, TU Muenchen
     3     Author:     Dmitriy Traytel, TU Muenchen
     4     Author:     Jasmin Blanchette, TU Muenchen
     5     Copyright   2012, 2013
     6 
     7 Shared fixed point operations on bounded natural functors.
     8 *)
     9 
    10 header {* Shared Fixed Point Operations on Bounded Natural Functors *}
    11 
    12 theory BNF_FP_Base
    13 imports BNF_Comp
    14 begin
    15 
    16 lemma mp_conj: "(P \<longrightarrow> Q) \<and> R \<Longrightarrow> P \<Longrightarrow> R \<and> Q"
    17 by auto
    18 
    19 lemma eq_sym_Unity_conv: "(x = (() = ())) = x"
    20 by blast
    21 
    22 lemma case_unit_Unity: "(case u of () \<Rightarrow> f) = f"
    23 by (cases u) (hypsubst, rule unit.case)
    24 
    25 lemma case_prod_Pair_iden: "(case p of (x, y) \<Rightarrow> (x, y)) = p"
    26 by simp
    27 
    28 lemma unit_all_impI: "(P () \<Longrightarrow> Q ()) \<Longrightarrow> \<forall>x. P x \<longrightarrow> Q x"
    29 by simp
    30 
    31 lemma prod_all_impI: "(\<And>x y. P (x, y) \<Longrightarrow> Q (x, y)) \<Longrightarrow> \<forall>x. P x \<longrightarrow> Q x"
    32 by clarify
    33 
    34 lemma prod_all_impI_step: "(\<And>x. \<forall>y. P (x, y) \<longrightarrow> Q (x, y)) \<Longrightarrow> \<forall>x. P x \<longrightarrow> Q x"
    35 by auto
    36 
    37 lemma pointfree_idE: "f \<circ> g = id \<Longrightarrow> f (g x) = x"
    38 unfolding comp_def fun_eq_iff by simp
    39 
    40 lemma o_bij:
    41   assumes gf: "g \<circ> f = id" and fg: "f \<circ> g = id"
    42   shows "bij f"
    43 unfolding bij_def inj_on_def surj_def proof safe
    44   fix a1 a2 assume "f a1 = f a2"
    45   hence "g ( f a1) = g (f a2)" by simp
    46   thus "a1 = a2" using gf unfolding fun_eq_iff by simp
    47 next
    48   fix b
    49   have "b = f (g b)"
    50   using fg unfolding fun_eq_iff by simp
    51   thus "EX a. b = f a" by blast
    52 qed
    53 
    54 lemma ssubst_mem: "\<lbrakk>t = s; s \<in> X\<rbrakk> \<Longrightarrow> t \<in> X" by simp
    55 
    56 lemma case_sum_step:
    57 "case_sum (case_sum f' g') g (Inl p) = case_sum f' g' p"
    58 "case_sum f (case_sum f' g') (Inr p) = case_sum f' g' p"
    59 by auto
    60 
    61 lemma one_pointE: "\<lbrakk>\<And>x. s = x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
    62 by simp
    63 
    64 lemma obj_one_pointE: "\<forall>x. s = x \<longrightarrow> P \<Longrightarrow> P"
    65 by blast
    66 
    67 lemma type_copy_obj_one_point_absE:
    68   assumes "type_definition Rep Abs UNIV"
    69   shows "\<forall>x. s = Abs x \<longrightarrow> P \<Longrightarrow> P"
    70   using type_definition.Rep_inverse[OF assms] by metis
    71 
    72 lemma obj_sumE_f:
    73 "\<lbrakk>\<forall>x. s = f (Inl x) \<longrightarrow> P; \<forall>x. s = f (Inr x) \<longrightarrow> P\<rbrakk> \<Longrightarrow> \<forall>x. s = f x \<longrightarrow> P"
    74 by (rule allI) (metis sumE)
    75 
    76 lemma obj_sumE: "\<lbrakk>\<forall>x. s = Inl x \<longrightarrow> P; \<forall>x. s = Inr x \<longrightarrow> P\<rbrakk> \<Longrightarrow> P"
    77 by (cases s) auto
    78 
    79 lemma case_sum_if:
    80 "case_sum f g (if p then Inl x else Inr y) = (if p then f x else g y)"
    81 by simp
    82 
    83 lemma mem_UN_compreh_eq: "(z : \<Union>{y. \<exists>x\<in>A. y = F x}) = (\<exists>x\<in>A. z : F x)"
    84 by blast
    85 
    86 lemma UN_compreh_eq_eq:
    87 "\<Union>{y. \<exists>x\<in>A. y = {}} = {}"
    88 "\<Union>{y. \<exists>x\<in>A. y = {x}} = A"
    89 by blast+
    90 
    91 lemma Inl_Inr_False: "(Inl x = Inr y) = False"
    92 by simp
    93 
    94 lemma prod_set_simps:
    95 "fsts (x, y) = {x}"
    96 "snds (x, y) = {y}"
    97 unfolding fsts_def snds_def by simp+
    98 
    99 lemma sum_set_simps:
   100 "setl (Inl x) = {x}"
   101 "setl (Inr x) = {}"
   102 "setr (Inl x) = {}"
   103 "setr (Inr x) = {x}"
   104 unfolding sum_set_defs by simp+
   105 
   106 lemma spec2: "\<forall>x y. P x y \<Longrightarrow> P x y"
   107 by blast
   108 
   109 lemma rewriteR_comp_comp: "\<lbrakk>g o h = r\<rbrakk> \<Longrightarrow> f o g o h = f o r"
   110   unfolding comp_def fun_eq_iff by auto
   111 
   112 lemma rewriteR_comp_comp2: "\<lbrakk>g o h = r1 o r2; f o r1 = l\<rbrakk> \<Longrightarrow> f o g o h = l o r2"
   113   unfolding comp_def fun_eq_iff by auto
   114 
   115 lemma rewriteL_comp_comp: "\<lbrakk>f o g = l\<rbrakk> \<Longrightarrow> f o (g o h) = l o h"
   116   unfolding comp_def fun_eq_iff by auto
   117 
   118 lemma rewriteL_comp_comp2: "\<lbrakk>f o g = l1 o l2; l2 o h = r\<rbrakk> \<Longrightarrow> f o (g o h) = l1 o r"
   119   unfolding comp_def fun_eq_iff by auto
   120 
   121 lemma convol_o: "<f, g> o h = <f o h, g o h>"
   122   unfolding convol_def by auto
   123 
   124 lemma map_pair_o_convol: "map_pair h1 h2 o <f, g> = <h1 o f, h2 o g>"
   125   unfolding convol_def by auto
   126 
   127 lemma map_pair_o_convol_id: "(map_pair f id \<circ> <id , g>) x = <id \<circ> f , g> x"
   128   unfolding map_pair_o_convol id_comp comp_id ..
   129 
   130 lemma o_case_sum: "h o case_sum f g = case_sum (h o f) (h o g)"
   131   unfolding comp_def by (auto split: sum.splits)
   132 
   133 lemma case_sum_o_sum_map: "case_sum f g o sum_map h1 h2 = case_sum (f o h1) (g o h2)"
   134   unfolding comp_def by (auto split: sum.splits)
   135 
   136 lemma case_sum_o_sum_map_id: "(case_sum id g o sum_map f id) x = case_sum (f o id) g x"
   137   unfolding case_sum_o_sum_map id_comp comp_id ..
   138 
   139 lemma fun_rel_def_butlast:
   140   "fun_rel R (fun_rel S T) f g = (\<forall>x y. R x y \<longrightarrow> (fun_rel S T) (f x) (g y))"
   141   unfolding fun_rel_def ..
   142 
   143 lemma subst_eq_imp: "(\<forall>a b. a = b \<longrightarrow> P a b) \<equiv> (\<forall>a. P a a)"
   144   by auto
   145 
   146 lemma eq_subset: "op = \<le> (\<lambda>a b. P a b \<or> a = b)"
   147   by auto
   148 
   149 lemma eq_le_Grp_id_iff: "(op = \<le> Grp (Collect R) id) = (All R)"
   150   unfolding Grp_def id_apply by blast
   151 
   152 lemma Grp_id_mono_subst: "(\<And>x y. Grp P id x y \<Longrightarrow> Grp Q id (f x) (f y)) \<equiv>
   153    (\<And>x. x \<in> P \<Longrightarrow> f x \<in> Q)"
   154   unfolding Grp_def by rule auto
   155 
   156 lemma vimage2p_mono: "vimage2p f g R x y \<Longrightarrow> R \<le> S \<Longrightarrow> vimage2p f g S x y"
   157   unfolding vimage2p_def by blast
   158 
   159 lemma vimage2p_refl: "(\<And>x. R x x) \<Longrightarrow> vimage2p f f R x x"
   160   unfolding vimage2p_def by auto
   161 
   162 lemma
   163   assumes "type_definition Rep Abs UNIV"
   164   shows type_copy_Rep_o_Abs: "Rep \<circ> Abs = id" and type_copy_Abs_o_Rep: "Abs o Rep = id"
   165   unfolding fun_eq_iff comp_apply id_apply
   166     type_definition.Abs_inverse[OF assms UNIV_I] type_definition.Rep_inverse[OF assms] by simp_all
   167 
   168 lemma type_copy_map_comp0_undo:
   169   assumes "type_definition Rep Abs UNIV"
   170           "type_definition Rep' Abs' UNIV"
   171           "type_definition Rep'' Abs'' UNIV"
   172   shows "Abs' o M o Rep'' = (Abs' o M1 o Rep) o (Abs o M2 o Rep'') \<Longrightarrow> M1 o M2 = M"
   173   by (rule sym) (auto simp: fun_eq_iff type_definition.Abs_inject[OF assms(2) UNIV_I UNIV_I]
   174     type_definition.Abs_inverse[OF assms(1) UNIV_I]
   175     type_definition.Abs_inverse[OF assms(3) UNIV_I] dest: spec[of _ "Abs'' x" for x])
   176 
   177 lemma vimage2p_comp: "vimage2p (f1 o f2) (g1 o g2) = vimage2p f2 g2 o vimage2p f1 g1"
   178   unfolding fun_eq_iff vimage2p_def o_apply by simp
   179 
   180 ML_file "Tools/BNF/bnf_fp_util.ML"
   181 ML_file "Tools/BNF/bnf_fp_def_sugar_tactics.ML"
   182 ML_file "Tools/BNF/bnf_fp_def_sugar.ML"
   183 ML_file "Tools/BNF/bnf_fp_n2m_tactics.ML"
   184 ML_file "Tools/BNF/bnf_fp_n2m.ML"
   185 ML_file "Tools/BNF/bnf_fp_n2m_sugar.ML"
   186 
   187 end