src/HOL/Probability/Probability_Mass_Function.thy
author eberlm <eberlm@in.tum.de>
Tue Apr 04 08:57:21 2017 +0200 (2017-04-04)
changeset 65395 7504569a73c7
parent 64634 5bd30359e46e
child 66089 def95e0bc529
permissions -rw-r--r--
moved material from AFP to distribution
     1 (*  Title:      HOL/Probability/Probability_Mass_Function.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Andreas Lochbihler, ETH Zurich
     4 *)
     5 
     6 section \<open> Probability mass function \<close>
     7 
     8 theory Probability_Mass_Function
     9 imports
    10   Giry_Monad
    11   "~~/src/HOL/Library/Multiset"
    12 begin
    13 
    14 lemma AE_emeasure_singleton:
    15   assumes x: "emeasure M {x} \<noteq> 0" and ae: "AE x in M. P x" shows "P x"
    16 proof -
    17   from x have x_M: "{x} \<in> sets M"
    18     by (auto intro: emeasure_notin_sets)
    19   from ae obtain N where N: "{x\<in>space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
    20     by (auto elim: AE_E)
    21   { assume "\<not> P x"
    22     with x_M[THEN sets.sets_into_space] N have "emeasure M {x} \<le> emeasure M N"
    23       by (intro emeasure_mono) auto
    24     with x N have False
    25       by (auto simp:) }
    26   then show "P x" by auto
    27 qed
    28 
    29 lemma AE_measure_singleton: "measure M {x} \<noteq> 0 \<Longrightarrow> AE x in M. P x \<Longrightarrow> P x"
    30   by (metis AE_emeasure_singleton measure_def emeasure_empty measure_empty)
    31 
    32 lemma (in finite_measure) AE_support_countable:
    33   assumes [simp]: "sets M = UNIV"
    34   shows "(AE x in M. measure M {x} \<noteq> 0) \<longleftrightarrow> (\<exists>S. countable S \<and> (AE x in M. x \<in> S))"
    35 proof
    36   assume "\<exists>S. countable S \<and> (AE x in M. x \<in> S)"
    37   then obtain S where S[intro]: "countable S" and ae: "AE x in M. x \<in> S"
    38     by auto
    39   then have "emeasure M (\<Union>x\<in>{x\<in>S. emeasure M {x} \<noteq> 0}. {x}) =
    40     (\<integral>\<^sup>+ x. emeasure M {x} * indicator {x\<in>S. emeasure M {x} \<noteq> 0} x \<partial>count_space UNIV)"
    41     by (subst emeasure_UN_countable)
    42        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    43   also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} * indicator S x \<partial>count_space UNIV)"
    44     by (auto intro!: nn_integral_cong split: split_indicator)
    45   also have "\<dots> = emeasure M (\<Union>x\<in>S. {x})"
    46     by (subst emeasure_UN_countable)
    47        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    48   also have "\<dots> = emeasure M (space M)"
    49     using ae by (intro emeasure_eq_AE) auto
    50   finally have "emeasure M {x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0} = emeasure M (space M)"
    51     by (simp add: emeasure_single_in_space cong: rev_conj_cong)
    52   with finite_measure_compl[of "{x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0}"]
    53   have "AE x in M. x \<in> S \<and> emeasure M {x} \<noteq> 0"
    54     by (intro AE_I[OF order_refl]) (auto simp: emeasure_eq_measure measure_nonneg set_diff_eq cong: conj_cong)
    55   then show "AE x in M. measure M {x} \<noteq> 0"
    56     by (auto simp: emeasure_eq_measure)
    57 qed (auto intro!: exI[of _ "{x. measure M {x} \<noteq> 0}"] countable_support)
    58 
    59 subsection \<open> PMF as measure \<close>
    60 
    61 typedef 'a pmf = "{M :: 'a measure. prob_space M \<and> sets M = UNIV \<and> (AE x in M. measure M {x} \<noteq> 0)}"
    62   morphisms measure_pmf Abs_pmf
    63   by (intro exI[of _ "uniform_measure (count_space UNIV) {undefined}"])
    64      (auto intro!: prob_space_uniform_measure AE_uniform_measureI)
    65 
    66 declare [[coercion measure_pmf]]
    67 
    68 lemma prob_space_measure_pmf: "prob_space (measure_pmf p)"
    69   using pmf.measure_pmf[of p] by auto
    70 
    71 interpretation measure_pmf: prob_space "measure_pmf M" for M
    72   by (rule prob_space_measure_pmf)
    73 
    74 interpretation measure_pmf: subprob_space "measure_pmf M" for M
    75   by (rule prob_space_imp_subprob_space) unfold_locales
    76 
    77 lemma subprob_space_measure_pmf: "subprob_space (measure_pmf x)"
    78   by unfold_locales
    79 
    80 locale pmf_as_measure
    81 begin
    82 
    83 setup_lifting type_definition_pmf
    84 
    85 end
    86 
    87 context
    88 begin
    89 
    90 interpretation pmf_as_measure .
    91 
    92 lemma sets_measure_pmf[simp]: "sets (measure_pmf p) = UNIV"
    93   by transfer blast
    94 
    95 lemma sets_measure_pmf_count_space[measurable_cong]:
    96   "sets (measure_pmf M) = sets (count_space UNIV)"
    97   by simp
    98 
    99 lemma space_measure_pmf[simp]: "space (measure_pmf p) = UNIV"
   100   using sets_eq_imp_space_eq[of "measure_pmf p" "count_space UNIV"] by simp
   101 
   102 lemma measure_pmf_UNIV [simp]: "measure (measure_pmf p) UNIV = 1"
   103 using measure_pmf.prob_space[of p] by simp
   104 
   105 lemma measure_pmf_in_subprob_algebra[measurable (raw)]: "measure_pmf x \<in> space (subprob_algebra (count_space UNIV))"
   106   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   107 
   108 lemma measurable_pmf_measure1[simp]: "measurable (M :: 'a pmf) N = UNIV \<rightarrow> space N"
   109   by (auto simp: measurable_def)
   110 
   111 lemma measurable_pmf_measure2[simp]: "measurable N (M :: 'a pmf) = measurable N (count_space UNIV)"
   112   by (intro measurable_cong_sets) simp_all
   113 
   114 lemma measurable_pair_restrict_pmf2:
   115   assumes "countable A"
   116   assumes [measurable]: "\<And>y. y \<in> A \<Longrightarrow> (\<lambda>x. f (x, y)) \<in> measurable M L"
   117   shows "f \<in> measurable (M \<Otimes>\<^sub>M restrict_space (measure_pmf N) A) L" (is "f \<in> measurable ?M _")
   118 proof -
   119   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   120     by (simp add: restrict_count_space)
   121 
   122   show ?thesis
   123     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (fst b, a)" and g=snd and I=A,
   124                                             unfolded prod.collapse] assms)
   125         measurable
   126 qed
   127 
   128 lemma measurable_pair_restrict_pmf1:
   129   assumes "countable A"
   130   assumes [measurable]: "\<And>x. x \<in> A \<Longrightarrow> (\<lambda>y. f (x, y)) \<in> measurable N L"
   131   shows "f \<in> measurable (restrict_space (measure_pmf M) A \<Otimes>\<^sub>M N) L"
   132 proof -
   133   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   134     by (simp add: restrict_count_space)
   135 
   136   show ?thesis
   137     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (a, snd b)" and g=fst and I=A,
   138                                             unfolded prod.collapse] assms)
   139         measurable
   140 qed
   141 
   142 lift_definition pmf :: "'a pmf \<Rightarrow> 'a \<Rightarrow> real" is "\<lambda>M x. measure M {x}" .
   143 
   144 lift_definition set_pmf :: "'a pmf \<Rightarrow> 'a set" is "\<lambda>M. {x. measure M {x} \<noteq> 0}" .
   145 declare [[coercion set_pmf]]
   146 
   147 lemma AE_measure_pmf: "AE x in (M::'a pmf). x \<in> M"
   148   by transfer simp
   149 
   150 lemma emeasure_pmf_single_eq_zero_iff:
   151   fixes M :: "'a pmf"
   152   shows "emeasure M {y} = 0 \<longleftrightarrow> y \<notin> M"
   153   unfolding set_pmf.rep_eq by (simp add: measure_pmf.emeasure_eq_measure)
   154 
   155 lemma AE_measure_pmf_iff: "(AE x in measure_pmf M. P x) \<longleftrightarrow> (\<forall>y\<in>M. P y)"
   156   using AE_measure_singleton[of M] AE_measure_pmf[of M]
   157   by (auto simp: set_pmf.rep_eq)
   158 
   159 lemma AE_pmfI: "(\<And>y. y \<in> set_pmf M \<Longrightarrow> P y) \<Longrightarrow> almost_everywhere (measure_pmf M) P"
   160 by(simp add: AE_measure_pmf_iff)
   161 
   162 lemma countable_set_pmf [simp]: "countable (set_pmf p)"
   163   by transfer (metis prob_space.finite_measure finite_measure.countable_support)
   164 
   165 lemma pmf_positive: "x \<in> set_pmf p \<Longrightarrow> 0 < pmf p x"
   166   by transfer (simp add: less_le)
   167 
   168 lemma pmf_nonneg[simp]: "0 \<le> pmf p x"
   169   by transfer simp
   170 
   171 lemma pmf_not_neg [simp]: "\<not>pmf p x < 0"
   172   by (simp add: not_less pmf_nonneg)
   173 
   174 lemma pmf_pos [simp]: "pmf p x \<noteq> 0 \<Longrightarrow> pmf p x > 0"
   175   using pmf_nonneg[of p x] by linarith
   176 
   177 lemma pmf_le_1: "pmf p x \<le> 1"
   178   by (simp add: pmf.rep_eq)
   179 
   180 lemma set_pmf_not_empty: "set_pmf M \<noteq> {}"
   181   using AE_measure_pmf[of M] by (intro notI) simp
   182 
   183 lemma set_pmf_iff: "x \<in> set_pmf M \<longleftrightarrow> pmf M x \<noteq> 0"
   184   by transfer simp
   185 
   186 lemma pmf_positive_iff: "0 < pmf p x \<longleftrightarrow> x \<in> set_pmf p"
   187   unfolding less_le by (simp add: set_pmf_iff)
   188 
   189 lemma set_pmf_eq: "set_pmf M = {x. pmf M x \<noteq> 0}"
   190   by (auto simp: set_pmf_iff)
   191 
   192 lemma set_pmf_eq': "set_pmf p = {x. pmf p x > 0}"
   193 proof safe
   194   fix x assume "x \<in> set_pmf p"
   195   hence "pmf p x \<noteq> 0" by (auto simp: set_pmf_eq)
   196   with pmf_nonneg[of p x] show "pmf p x > 0" by simp
   197 qed (auto simp: set_pmf_eq)
   198 
   199 lemma emeasure_pmf_single:
   200   fixes M :: "'a pmf"
   201   shows "emeasure M {x} = pmf M x"
   202   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   203 
   204 lemma measure_pmf_single: "measure (measure_pmf M) {x} = pmf M x"
   205   using emeasure_pmf_single[of M x] by(simp add: measure_pmf.emeasure_eq_measure pmf_nonneg measure_nonneg)
   206 
   207 lemma emeasure_measure_pmf_finite: "finite S \<Longrightarrow> emeasure (measure_pmf M) S = (\<Sum>s\<in>S. pmf M s)"
   208   by (subst emeasure_eq_sum_singleton) (auto simp: emeasure_pmf_single pmf_nonneg)
   209 
   210 lemma measure_measure_pmf_finite: "finite S \<Longrightarrow> measure (measure_pmf M) S = sum (pmf M) S"
   211   using emeasure_measure_pmf_finite[of S M]
   212   by (simp add: measure_pmf.emeasure_eq_measure measure_nonneg sum_nonneg pmf_nonneg)
   213 
   214 lemma sum_pmf_eq_1:
   215   assumes "finite A" "set_pmf p \<subseteq> A"
   216   shows   "(\<Sum>x\<in>A. pmf p x) = 1"
   217 proof -
   218   have "(\<Sum>x\<in>A. pmf p x) = measure_pmf.prob p A"
   219     by (simp add: measure_measure_pmf_finite assms)
   220   also from assms have "\<dots> = 1"
   221     by (subst measure_pmf.prob_eq_1) (auto simp: AE_measure_pmf_iff)
   222   finally show ?thesis .
   223 qed
   224 
   225 lemma nn_integral_measure_pmf_support:
   226   fixes f :: "'a \<Rightarrow> ennreal"
   227   assumes f: "finite A" and nn: "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x" "\<And>x. x \<in> set_pmf M \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = 0"
   228   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>A. f x * pmf M x)"
   229 proof -
   230   have "(\<integral>\<^sup>+x. f x \<partial>M) = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   231     using nn by (intro nn_integral_cong_AE) (auto simp: AE_measure_pmf_iff split: split_indicator)
   232   also have "\<dots> = (\<Sum>x\<in>A. f x * emeasure M {x})"
   233     using assms by (intro nn_integral_indicator_finite) auto
   234   finally show ?thesis
   235     by (simp add: emeasure_measure_pmf_finite)
   236 qed
   237 
   238 lemma nn_integral_measure_pmf_finite:
   239   fixes f :: "'a \<Rightarrow> ennreal"
   240   assumes f: "finite (set_pmf M)" and nn: "\<And>x. x \<in> set_pmf M \<Longrightarrow> 0 \<le> f x"
   241   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>set_pmf M. f x * pmf M x)"
   242   using assms by (intro nn_integral_measure_pmf_support) auto
   243 
   244 lemma integrable_measure_pmf_finite:
   245   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   246   shows "finite (set_pmf M) \<Longrightarrow> integrable M f"
   247   by (auto intro!: integrableI_bounded simp: nn_integral_measure_pmf_finite ennreal_mult_less_top)
   248 
   249 lemma integral_measure_pmf_real:
   250   assumes [simp]: "finite A" and "\<And>a. a \<in> set_pmf M \<Longrightarrow> f a \<noteq> 0 \<Longrightarrow> a \<in> A"
   251   shows "(\<integral>x. f x \<partial>measure_pmf M) = (\<Sum>a\<in>A. f a * pmf M a)"
   252 proof -
   253   have "(\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x * indicator A x \<partial>measure_pmf M)"
   254     using assms(2) by (intro integral_cong_AE) (auto split: split_indicator simp: AE_measure_pmf_iff)
   255   also have "\<dots> = (\<Sum>a\<in>A. f a * pmf M a)"
   256     by (subst integral_indicator_finite_real)
   257        (auto simp: measure_def emeasure_measure_pmf_finite pmf_nonneg)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma integrable_pmf: "integrable (count_space X) (pmf M)"
   262 proof -
   263   have " (\<integral>\<^sup>+ x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+ x. pmf M x \<partial>count_space (M \<inter> X))"
   264     by (auto simp add: nn_integral_count_space_indicator set_pmf_iff intro!: nn_integral_cong split: split_indicator)
   265   then have "integrable (count_space X) (pmf M) = integrable (count_space (M \<inter> X)) (pmf M)"
   266     by (simp add: integrable_iff_bounded pmf_nonneg)
   267   then show ?thesis
   268     by (simp add: pmf.rep_eq measure_pmf.integrable_measure disjoint_family_on_def)
   269 qed
   270 
   271 lemma integral_pmf: "(\<integral>x. pmf M x \<partial>count_space X) = measure M X"
   272 proof -
   273   have "(\<integral>x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+x. pmf M x \<partial>count_space X)"
   274     by (simp add: pmf_nonneg integrable_pmf nn_integral_eq_integral)
   275   also have "\<dots> = (\<integral>\<^sup>+x. emeasure M {x} \<partial>count_space (X \<inter> M))"
   276     by (auto intro!: nn_integral_cong_AE split: split_indicator
   277              simp: pmf.rep_eq measure_pmf.emeasure_eq_measure nn_integral_count_space_indicator
   278                    AE_count_space set_pmf_iff)
   279   also have "\<dots> = emeasure M (X \<inter> M)"
   280     by (rule emeasure_countable_singleton[symmetric]) (auto intro: countable_set_pmf)
   281   also have "\<dots> = emeasure M X"
   282     by (auto intro!: emeasure_eq_AE simp: AE_measure_pmf_iff)
   283   finally show ?thesis
   284     by (simp add: measure_pmf.emeasure_eq_measure measure_nonneg integral_nonneg pmf_nonneg)
   285 qed
   286 
   287 lemma integral_pmf_restrict:
   288   "(f::'a \<Rightarrow> 'b::{banach, second_countable_topology}) \<in> borel_measurable (count_space UNIV) \<Longrightarrow>
   289     (\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x \<partial>restrict_space M M)"
   290   by (auto intro!: integral_cong_AE simp add: integral_restrict_space AE_measure_pmf_iff)
   291 
   292 lemma emeasure_pmf: "emeasure (M::'a pmf) M = 1"
   293 proof -
   294   have "emeasure (M::'a pmf) M = emeasure (M::'a pmf) (space M)"
   295     by (intro emeasure_eq_AE) (simp_all add: AE_measure_pmf)
   296   then show ?thesis
   297     using measure_pmf.emeasure_space_1 by simp
   298 qed
   299 
   300 lemma emeasure_pmf_UNIV [simp]: "emeasure (measure_pmf M) UNIV = 1"
   301 using measure_pmf.emeasure_space_1[of M] by simp
   302 
   303 lemma in_null_sets_measure_pmfI:
   304   "A \<inter> set_pmf p = {} \<Longrightarrow> A \<in> null_sets (measure_pmf p)"
   305 using emeasure_eq_0_AE[where ?P="\<lambda>x. x \<in> A" and M="measure_pmf p"]
   306 by(auto simp add: null_sets_def AE_measure_pmf_iff)
   307 
   308 lemma measure_subprob: "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   309   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   310 
   311 subsection \<open> Monad Interpretation \<close>
   312 
   313 lemma measurable_measure_pmf[measurable]:
   314   "(\<lambda>x. measure_pmf (M x)) \<in> measurable (count_space UNIV) (subprob_algebra (count_space UNIV))"
   315   by (auto simp: space_subprob_algebra intro!: prob_space_imp_subprob_space) unfold_locales
   316 
   317 lemma bind_measure_pmf_cong:
   318   assumes "\<And>x. A x \<in> space (subprob_algebra N)" "\<And>x. B x \<in> space (subprob_algebra N)"
   319   assumes "\<And>i. i \<in> set_pmf x \<Longrightarrow> A i = B i"
   320   shows "bind (measure_pmf x) A = bind (measure_pmf x) B"
   321 proof (rule measure_eqI)
   322   show "sets (measure_pmf x \<bind> A) = sets (measure_pmf x \<bind> B)"
   323     using assms by (subst (1 2) sets_bind) (auto simp: space_subprob_algebra)
   324 next
   325   fix X assume "X \<in> sets (measure_pmf x \<bind> A)"
   326   then have X: "X \<in> sets N"
   327     using assms by (subst (asm) sets_bind) (auto simp: space_subprob_algebra)
   328   show "emeasure (measure_pmf x \<bind> A) X = emeasure (measure_pmf x \<bind> B) X"
   329     using assms
   330     by (subst (1 2) emeasure_bind[where N=N, OF _ _ X])
   331        (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   332 qed
   333 
   334 lift_definition bind_pmf :: "'a pmf \<Rightarrow> ('a \<Rightarrow> 'b pmf ) \<Rightarrow> 'b pmf" is bind
   335 proof (clarify, intro conjI)
   336   fix f :: "'a measure" and g :: "'a \<Rightarrow> 'b measure"
   337   assume "prob_space f"
   338   then interpret f: prob_space f .
   339   assume "sets f = UNIV" and ae_f: "AE x in f. measure f {x} \<noteq> 0"
   340   then have s_f[simp]: "sets f = sets (count_space UNIV)"
   341     by simp
   342   assume g: "\<And>x. prob_space (g x) \<and> sets (g x) = UNIV \<and> (AE y in g x. measure (g x) {y} \<noteq> 0)"
   343   then have g: "\<And>x. prob_space (g x)" and s_g[simp]: "\<And>x. sets (g x) = sets (count_space UNIV)"
   344     and ae_g: "\<And>x. AE y in g x. measure (g x) {y} \<noteq> 0"
   345     by auto
   346 
   347   have [measurable]: "g \<in> measurable f (subprob_algebra (count_space UNIV))"
   348     by (auto simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space g)
   349 
   350   show "prob_space (f \<bind> g)"
   351     using g by (intro f.prob_space_bind[where S="count_space UNIV"]) auto
   352   then interpret fg: prob_space "f \<bind> g" .
   353   show [simp]: "sets (f \<bind> g) = UNIV"
   354     using sets_eq_imp_space_eq[OF s_f]
   355     by (subst sets_bind[where N="count_space UNIV"]) auto
   356   show "AE x in f \<bind> g. measure (f \<bind> g) {x} \<noteq> 0"
   357     apply (simp add: fg.prob_eq_0 AE_bind[where B="count_space UNIV"])
   358     using ae_f
   359     apply eventually_elim
   360     using ae_g
   361     apply eventually_elim
   362     apply (auto dest: AE_measure_singleton)
   363     done
   364 qed
   365 
   366 adhoc_overloading Monad_Syntax.bind bind_pmf
   367 
   368 lemma ennreal_pmf_bind: "pmf (bind_pmf N f) i = (\<integral>\<^sup>+x. pmf (f x) i \<partial>measure_pmf N)"
   369   unfolding pmf.rep_eq bind_pmf.rep_eq
   370   by (auto simp: measure_pmf.measure_bind[where N="count_space UNIV"] measure_subprob measure_nonneg
   371            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   372 
   373 lemma pmf_bind: "pmf (bind_pmf N f) i = (\<integral>x. pmf (f x) i \<partial>measure_pmf N)"
   374   using ennreal_pmf_bind[of N f i]
   375   by (subst (asm) nn_integral_eq_integral)
   376      (auto simp: pmf_nonneg pmf_le_1 pmf_nonneg integral_nonneg
   377            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   378 
   379 lemma bind_pmf_const[simp]: "bind_pmf M (\<lambda>x. c) = c"
   380   by transfer (simp add: bind_const' prob_space_imp_subprob_space)
   381 
   382 lemma set_bind_pmf[simp]: "set_pmf (bind_pmf M N) = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   383 proof -
   384   have "set_pmf (bind_pmf M N) = {x. ennreal (pmf (bind_pmf M N) x) \<noteq> 0}"
   385     by (simp add: set_pmf_eq pmf_nonneg)
   386   also have "\<dots> = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   387     unfolding ennreal_pmf_bind
   388     by (subst nn_integral_0_iff_AE) (auto simp: AE_measure_pmf_iff pmf_nonneg set_pmf_eq)
   389   finally show ?thesis .
   390 qed
   391 
   392 lemma bind_pmf_cong [fundef_cong]:
   393   assumes "p = q"
   394   shows "(\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   395   unfolding \<open>p = q\<close>[symmetric] measure_pmf_inject[symmetric] bind_pmf.rep_eq
   396   by (auto simp: AE_measure_pmf_iff Pi_iff space_subprob_algebra subprob_space_measure_pmf
   397                  sets_bind[where N="count_space UNIV"] emeasure_bind[where N="count_space UNIV"]
   398            intro!: nn_integral_cong_AE measure_eqI)
   399 
   400 lemma bind_pmf_cong_simp:
   401   "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q =simp=> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   402   by (simp add: simp_implies_def cong: bind_pmf_cong)
   403 
   404 lemma measure_pmf_bind: "measure_pmf (bind_pmf M f) = (measure_pmf M \<bind> (\<lambda>x. measure_pmf (f x)))"
   405   by transfer simp
   406 
   407 lemma nn_integral_bind_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>bind_pmf M N) = (\<integral>\<^sup>+x. \<integral>\<^sup>+y. f y \<partial>N x \<partial>M)"
   408   using measurable_measure_pmf[of N]
   409   unfolding measure_pmf_bind
   410   apply (intro nn_integral_bind[where B="count_space UNIV"])
   411   apply auto
   412   done
   413 
   414 lemma emeasure_bind_pmf[simp]: "emeasure (bind_pmf M N) X = (\<integral>\<^sup>+x. emeasure (N x) X \<partial>M)"
   415   using measurable_measure_pmf[of N]
   416   unfolding measure_pmf_bind
   417   by (subst emeasure_bind[where N="count_space UNIV"]) auto
   418 
   419 lift_definition return_pmf :: "'a \<Rightarrow> 'a pmf" is "return (count_space UNIV)"
   420   by (auto intro!: prob_space_return simp: AE_return measure_return)
   421 
   422 lemma bind_return_pmf: "bind_pmf (return_pmf x) f = f x"
   423   by transfer
   424      (auto intro!: prob_space_imp_subprob_space bind_return[where N="count_space UNIV"]
   425            simp: space_subprob_algebra)
   426 
   427 lemma set_return_pmf[simp]: "set_pmf (return_pmf x) = {x}"
   428   by transfer (auto simp add: measure_return split: split_indicator)
   429 
   430 lemma bind_return_pmf': "bind_pmf N return_pmf = N"
   431 proof (transfer, clarify)
   432   fix N :: "'a measure" assume "sets N = UNIV" then show "N \<bind> return (count_space UNIV) = N"
   433     by (subst return_sets_cong[where N=N]) (simp_all add: bind_return')
   434 qed
   435 
   436 lemma bind_assoc_pmf: "bind_pmf (bind_pmf A B) C = bind_pmf A (\<lambda>x. bind_pmf (B x) C)"
   437   by transfer
   438      (auto intro!: bind_assoc[where N="count_space UNIV" and R="count_space UNIV"]
   439            simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space)
   440 
   441 definition "map_pmf f M = bind_pmf M (\<lambda>x. return_pmf (f x))"
   442 
   443 lemma map_bind_pmf: "map_pmf f (bind_pmf M g) = bind_pmf M (\<lambda>x. map_pmf f (g x))"
   444   by (simp add: map_pmf_def bind_assoc_pmf)
   445 
   446 lemma bind_map_pmf: "bind_pmf (map_pmf f M) g = bind_pmf M (\<lambda>x. g (f x))"
   447   by (simp add: map_pmf_def bind_assoc_pmf bind_return_pmf)
   448 
   449 lemma map_pmf_transfer[transfer_rule]:
   450   "rel_fun op = (rel_fun cr_pmf cr_pmf) (\<lambda>f M. distr M (count_space UNIV) f) map_pmf"
   451 proof -
   452   have "rel_fun op = (rel_fun pmf_as_measure.cr_pmf pmf_as_measure.cr_pmf)
   453      (\<lambda>f M. M \<bind> (return (count_space UNIV) o f)) map_pmf"
   454     unfolding map_pmf_def[abs_def] comp_def by transfer_prover
   455   then show ?thesis
   456     by (force simp: rel_fun_def cr_pmf_def bind_return_distr)
   457 qed
   458 
   459 lemma map_pmf_rep_eq:
   460   "measure_pmf (map_pmf f M) = distr (measure_pmf M) (count_space UNIV) f"
   461   unfolding map_pmf_def bind_pmf.rep_eq comp_def return_pmf.rep_eq
   462   using bind_return_distr[of M f "count_space UNIV"] by (simp add: comp_def)
   463 
   464 lemma map_pmf_id[simp]: "map_pmf id = id"
   465   by (rule, transfer) (auto simp: emeasure_distr measurable_def intro!: measure_eqI)
   466 
   467 lemma map_pmf_ident[simp]: "map_pmf (\<lambda>x. x) = (\<lambda>x. x)"
   468   using map_pmf_id unfolding id_def .
   469 
   470 lemma map_pmf_compose: "map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g"
   471   by (rule, transfer) (simp add: distr_distr[symmetric, where N="count_space UNIV"] measurable_def)
   472 
   473 lemma map_pmf_comp: "map_pmf f (map_pmf g M) = map_pmf (\<lambda>x. f (g x)) M"
   474   using map_pmf_compose[of f g] by (simp add: comp_def)
   475 
   476 lemma map_pmf_cong: "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g q"
   477   unfolding map_pmf_def by (rule bind_pmf_cong) auto
   478 
   479 lemma pmf_set_map: "set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
   480   by (auto simp add: comp_def fun_eq_iff map_pmf_def)
   481 
   482 lemma set_map_pmf[simp]: "set_pmf (map_pmf f M) = f`set_pmf M"
   483   using pmf_set_map[of f] by (auto simp: comp_def fun_eq_iff)
   484 
   485 lemma emeasure_map_pmf[simp]: "emeasure (map_pmf f M) X = emeasure M (f -` X)"
   486   unfolding map_pmf_rep_eq by (subst emeasure_distr) auto
   487 
   488 lemma measure_map_pmf[simp]: "measure (map_pmf f M) X = measure M (f -` X)"
   489 using emeasure_map_pmf[of f M X] by(simp add: measure_pmf.emeasure_eq_measure measure_nonneg)
   490 
   491 lemma nn_integral_map_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>map_pmf g M) = (\<integral>\<^sup>+x. f (g x) \<partial>M)"
   492   unfolding map_pmf_rep_eq by (intro nn_integral_distr) auto
   493 
   494 lemma ennreal_pmf_map: "pmf (map_pmf f p) x = (\<integral>\<^sup>+ y. indicator (f -` {x}) y \<partial>measure_pmf p)"
   495 proof (transfer fixing: f x)
   496   fix p :: "'b measure"
   497   presume "prob_space p"
   498   then interpret prob_space p .
   499   presume "sets p = UNIV"
   500   then show "ennreal (measure (distr p (count_space UNIV) f) {x}) = integral\<^sup>N p (indicator (f -` {x}))"
   501     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   502 qed simp_all
   503 
   504 lemma pmf_map: "pmf (map_pmf f p) x = measure p (f -` {x})"
   505 proof (transfer fixing: f x)
   506   fix p :: "'b measure"
   507   presume "prob_space p"
   508   then interpret prob_space p .
   509   presume "sets p = UNIV"
   510   then show "measure (distr p (count_space UNIV) f) {x} = measure p (f -` {x})"
   511     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   512 qed simp_all
   513 
   514 lemma nn_integral_pmf: "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = emeasure (measure_pmf p) A"
   515 proof -
   516   have "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = (\<integral>\<^sup>+ x. pmf p x \<partial>count_space (A \<inter> set_pmf p))"
   517     by(auto simp add: nn_integral_count_space_indicator indicator_def set_pmf_iff intro: nn_integral_cong)
   518   also have "\<dots> = emeasure (measure_pmf p) (\<Union>x\<in>A \<inter> set_pmf p. {x})"
   519     by(subst emeasure_UN_countable)(auto simp add: emeasure_pmf_single disjoint_family_on_def)
   520   also have "\<dots> = emeasure (measure_pmf p) ((\<Union>x\<in>A \<inter> set_pmf p. {x}) \<union> {x. x \<in> A \<and> x \<notin> set_pmf p})"
   521     by(rule emeasure_Un_null_set[symmetric])(auto intro: in_null_sets_measure_pmfI)
   522   also have "\<dots> = emeasure (measure_pmf p) A"
   523     by(auto intro: arg_cong2[where f=emeasure])
   524   finally show ?thesis .
   525 qed
   526 
   527 lemma integral_map_pmf[simp]:
   528   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   529   shows "integral\<^sup>L (map_pmf g p) f = integral\<^sup>L p (\<lambda>x. f (g x))"
   530   by (simp add: integral_distr map_pmf_rep_eq)
   531 
   532 lemma map_return_pmf [simp]: "map_pmf f (return_pmf x) = return_pmf (f x)"
   533   by transfer (simp add: distr_return)
   534 
   535 lemma map_pmf_const[simp]: "map_pmf (\<lambda>_. c) M = return_pmf c"
   536   by transfer (auto simp: prob_space.distr_const)
   537 
   538 lemma pmf_return [simp]: "pmf (return_pmf x) y = indicator {y} x"
   539   by transfer (simp add: measure_return)
   540 
   541 lemma nn_integral_return_pmf[simp]: "0 \<le> f x \<Longrightarrow> (\<integral>\<^sup>+x. f x \<partial>return_pmf x) = f x"
   542   unfolding return_pmf.rep_eq by (intro nn_integral_return) auto
   543 
   544 lemma emeasure_return_pmf[simp]: "emeasure (return_pmf x) X = indicator X x"
   545   unfolding return_pmf.rep_eq by (intro emeasure_return) auto
   546 
   547 lemma measure_return_pmf [simp]: "measure_pmf.prob (return_pmf x) A = indicator A x"
   548 proof -
   549   have "ennreal (measure_pmf.prob (return_pmf x) A) =
   550           emeasure (measure_pmf (return_pmf x)) A"
   551     by (simp add: measure_pmf.emeasure_eq_measure)
   552   also have "\<dots> = ennreal (indicator A x)" by (simp add: ennreal_indicator)
   553   finally show ?thesis by simp
   554 qed
   555 
   556 lemma return_pmf_inj[simp]: "return_pmf x = return_pmf y \<longleftrightarrow> x = y"
   557   by (metis insertI1 set_return_pmf singletonD)
   558 
   559 lemma map_pmf_eq_return_pmf_iff:
   560   "map_pmf f p = return_pmf x \<longleftrightarrow> (\<forall>y \<in> set_pmf p. f y = x)"
   561 proof
   562   assume "map_pmf f p = return_pmf x"
   563   then have "set_pmf (map_pmf f p) = set_pmf (return_pmf x)" by simp
   564   then show "\<forall>y \<in> set_pmf p. f y = x" by auto
   565 next
   566   assume "\<forall>y \<in> set_pmf p. f y = x"
   567   then show "map_pmf f p = return_pmf x"
   568     unfolding map_pmf_const[symmetric, of _ p] by (intro map_pmf_cong) auto
   569 qed
   570 
   571 definition "pair_pmf A B = bind_pmf A (\<lambda>x. bind_pmf B (\<lambda>y. return_pmf (x, y)))"
   572 
   573 lemma pmf_pair: "pmf (pair_pmf M N) (a, b) = pmf M a * pmf N b"
   574   unfolding pair_pmf_def pmf_bind pmf_return
   575   apply (subst integral_measure_pmf_real[where A="{b}"])
   576   apply (auto simp: indicator_eq_0_iff)
   577   apply (subst integral_measure_pmf_real[where A="{a}"])
   578   apply (auto simp: indicator_eq_0_iff sum_nonneg_eq_0_iff pmf_nonneg)
   579   done
   580 
   581 lemma set_pair_pmf[simp]: "set_pmf (pair_pmf A B) = set_pmf A \<times> set_pmf B"
   582   unfolding pair_pmf_def set_bind_pmf set_return_pmf by auto
   583 
   584 lemma measure_pmf_in_subprob_space[measurable (raw)]:
   585   "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   586   by (simp add: space_subprob_algebra) intro_locales
   587 
   588 lemma nn_integral_pair_pmf': "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   589 proof -
   590   have "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+x. f x * indicator (A \<times> B) x \<partial>pair_pmf A B)"
   591     by (auto simp: AE_measure_pmf_iff intro!: nn_integral_cong_AE)
   592   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) * indicator (A \<times> B) (a, b) \<partial>B \<partial>A)"
   593     by (simp add: pair_pmf_def)
   594   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   595     by (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   596   finally show ?thesis .
   597 qed
   598 
   599 lemma bind_pair_pmf:
   600   assumes M[measurable]: "M \<in> measurable (count_space UNIV \<Otimes>\<^sub>M count_space UNIV) (subprob_algebra N)"
   601   shows "measure_pmf (pair_pmf A B) \<bind> M = (measure_pmf A \<bind> (\<lambda>x. measure_pmf B \<bind> (\<lambda>y. M (x, y))))"
   602     (is "?L = ?R")
   603 proof (rule measure_eqI)
   604   have M'[measurable]: "M \<in> measurable (pair_pmf A B) (subprob_algebra N)"
   605     using M[THEN measurable_space] by (simp_all add: space_pair_measure)
   606 
   607   note measurable_bind[where N="count_space UNIV", measurable]
   608   note measure_pmf_in_subprob_space[simp]
   609 
   610   have sets_eq_N: "sets ?L = N"
   611     by (subst sets_bind[OF sets_kernel[OF M']]) auto
   612   show "sets ?L = sets ?R"
   613     using measurable_space[OF M]
   614     by (simp add: sets_eq_N space_pair_measure space_subprob_algebra)
   615   fix X assume "X \<in> sets ?L"
   616   then have X[measurable]: "X \<in> sets N"
   617     unfolding sets_eq_N .
   618   then show "emeasure ?L X = emeasure ?R X"
   619     apply (simp add: emeasure_bind[OF _ M' X])
   620     apply (simp add: nn_integral_bind[where B="count_space UNIV"] pair_pmf_def measure_pmf_bind[of A]
   621                      nn_integral_measure_pmf_finite)
   622     apply (subst emeasure_bind[OF _ _ X])
   623     apply measurable
   624     apply (subst emeasure_bind[OF _ _ X])
   625     apply measurable
   626     done
   627 qed
   628 
   629 lemma map_fst_pair_pmf: "map_pmf fst (pair_pmf A B) = A"
   630   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   631 
   632 lemma map_snd_pair_pmf: "map_pmf snd (pair_pmf A B) = B"
   633   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   634 
   635 lemma nn_integral_pmf':
   636   "inj_on f A \<Longrightarrow> (\<integral>\<^sup>+x. pmf p (f x) \<partial>count_space A) = emeasure p (f ` A)"
   637   by (subst nn_integral_bij_count_space[where g=f and B="f`A"])
   638      (auto simp: bij_betw_def nn_integral_pmf)
   639 
   640 lemma pmf_le_0_iff[simp]: "pmf M p \<le> 0 \<longleftrightarrow> pmf M p = 0"
   641   using pmf_nonneg[of M p] by arith
   642 
   643 lemma min_pmf_0[simp]: "min (pmf M p) 0 = 0" "min 0 (pmf M p) = 0"
   644   using pmf_nonneg[of M p] by arith+
   645 
   646 lemma pmf_eq_0_set_pmf: "pmf M p = 0 \<longleftrightarrow> p \<notin> set_pmf M"
   647   unfolding set_pmf_iff by simp
   648 
   649 lemma pmf_map_inj: "inj_on f (set_pmf M) \<Longrightarrow> x \<in> set_pmf M \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   650   by (auto simp: pmf.rep_eq map_pmf_rep_eq measure_distr AE_measure_pmf_iff inj_onD
   651            intro!: measure_pmf.finite_measure_eq_AE)
   652 
   653 lemma pmf_map_inj': "inj f \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   654 apply(cases "x \<in> set_pmf M")
   655  apply(simp add: pmf_map_inj[OF subset_inj_on])
   656 apply(simp add: pmf_eq_0_set_pmf[symmetric])
   657 apply(auto simp add: pmf_eq_0_set_pmf dest: injD)
   658 done
   659 
   660 lemma pmf_map_outside: "x \<notin> f ` set_pmf M \<Longrightarrow> pmf (map_pmf f M) x = 0"
   661   unfolding pmf_eq_0_set_pmf by simp
   662 
   663 lemma measurable_set_pmf[measurable]: "Measurable.pred (count_space UNIV) (\<lambda>x. x \<in> set_pmf M)"
   664   by simp
   665 
   666 
   667 subsection \<open> PMFs as function \<close>
   668 
   669 context
   670   fixes f :: "'a \<Rightarrow> real"
   671   assumes nonneg: "\<And>x. 0 \<le> f x"
   672   assumes prob: "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   673 begin
   674 
   675 lift_definition embed_pmf :: "'a pmf" is "density (count_space UNIV) (ennreal \<circ> f)"
   676 proof (intro conjI)
   677   have *[simp]: "\<And>x y. ennreal (f y) * indicator {x} y = ennreal (f x) * indicator {x} y"
   678     by (simp split: split_indicator)
   679   show "AE x in density (count_space UNIV) (ennreal \<circ> f).
   680     measure (density (count_space UNIV) (ennreal \<circ> f)) {x} \<noteq> 0"
   681     by (simp add: AE_density nonneg measure_def emeasure_density max_def)
   682   show "prob_space (density (count_space UNIV) (ennreal \<circ> f))"
   683     by standard (simp add: emeasure_density prob)
   684 qed simp
   685 
   686 lemma pmf_embed_pmf: "pmf embed_pmf x = f x"
   687 proof transfer
   688   have *[simp]: "\<And>x y. ennreal (f y) * indicator {x} y = ennreal (f x) * indicator {x} y"
   689     by (simp split: split_indicator)
   690   fix x show "measure (density (count_space UNIV) (ennreal \<circ> f)) {x} = f x"
   691     by transfer (simp add: measure_def emeasure_density nonneg max_def)
   692 qed
   693 
   694 lemma set_embed_pmf: "set_pmf embed_pmf = {x. f x \<noteq> 0}"
   695 by(auto simp add: set_pmf_eq pmf_embed_pmf)
   696 
   697 end
   698 
   699 lemma embed_pmf_transfer:
   700   "rel_fun (eq_onp (\<lambda>f. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ennreal (f x) \<partial>count_space UNIV) = 1)) pmf_as_measure.cr_pmf (\<lambda>f. density (count_space UNIV) (ennreal \<circ> f)) embed_pmf"
   701   by (auto simp: rel_fun_def eq_onp_def embed_pmf.transfer)
   702 
   703 lemma measure_pmf_eq_density: "measure_pmf p = density (count_space UNIV) (pmf p)"
   704 proof (transfer, elim conjE)
   705   fix M :: "'a measure" assume [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   706   assume "prob_space M" then interpret prob_space M .
   707   show "M = density (count_space UNIV) (\<lambda>x. ennreal (measure M {x}))"
   708   proof (rule measure_eqI)
   709     fix A :: "'a set"
   710     have "(\<integral>\<^sup>+ x. ennreal (measure M {x}) * indicator A x \<partial>count_space UNIV) =
   711       (\<integral>\<^sup>+ x. emeasure M {x} * indicator (A \<inter> {x. measure M {x} \<noteq> 0}) x \<partial>count_space UNIV)"
   712       by (auto intro!: nn_integral_cong simp: emeasure_eq_measure split: split_indicator)
   713     also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} \<partial>count_space (A \<inter> {x. measure M {x} \<noteq> 0}))"
   714       by (subst nn_integral_restrict_space[symmetric]) (auto simp: restrict_count_space)
   715     also have "\<dots> = emeasure M (\<Union>x\<in>(A \<inter> {x. measure M {x} \<noteq> 0}). {x})"
   716       by (intro emeasure_UN_countable[symmetric] countable_Int2 countable_support)
   717          (auto simp: disjoint_family_on_def)
   718     also have "\<dots> = emeasure M A"
   719       using ae by (intro emeasure_eq_AE) auto
   720     finally show " emeasure M A = emeasure (density (count_space UNIV) (\<lambda>x. ennreal (measure M {x}))) A"
   721       using emeasure_space_1 by (simp add: emeasure_density)
   722   qed simp
   723 qed
   724 
   725 lemma td_pmf_embed_pmf:
   726   "type_definition pmf embed_pmf {f::'a \<Rightarrow> real. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ennreal (f x) \<partial>count_space UNIV) = 1}"
   727   unfolding type_definition_def
   728 proof safe
   729   fix p :: "'a pmf"
   730   have "(\<integral>\<^sup>+ x. 1 \<partial>measure_pmf p) = 1"
   731     using measure_pmf.emeasure_space_1[of p] by simp
   732   then show *: "(\<integral>\<^sup>+ x. ennreal (pmf p x) \<partial>count_space UNIV) = 1"
   733     by (simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg del: nn_integral_const)
   734 
   735   show "embed_pmf (pmf p) = p"
   736     by (intro measure_pmf_inject[THEN iffD1])
   737        (simp add: * embed_pmf.rep_eq pmf_nonneg measure_pmf_eq_density[of p] comp_def)
   738 next
   739   fix f :: "'a \<Rightarrow> real" assume "\<forall>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   740   then show "pmf (embed_pmf f) = f"
   741     by (auto intro!: pmf_embed_pmf)
   742 qed (rule pmf_nonneg)
   743 
   744 end
   745 
   746 lemma nn_integral_measure_pmf: "(\<integral>\<^sup>+ x. f x \<partial>measure_pmf p) = \<integral>\<^sup>+ x. ennreal (pmf p x) * f x \<partial>count_space UNIV"
   747 by(simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg)
   748 
   749 lemma integral_measure_pmf:
   750   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   751   assumes A: "finite A"
   752   shows "(\<And>a. a \<in> set_pmf M \<Longrightarrow> f a \<noteq> 0 \<Longrightarrow> a \<in> A) \<Longrightarrow> (LINT x|M. f x) = (\<Sum>a\<in>A. pmf M a *\<^sub>R f a)"
   753   unfolding measure_pmf_eq_density
   754   apply (simp add: integral_density)
   755   apply (subst lebesgue_integral_count_space_finite_support)
   756   apply (auto intro!: finite_subset[OF _ \<open>finite A\<close>] sum.mono_neutral_left simp: pmf_eq_0_set_pmf)
   757   done
   758     
   759 lemma expectation_return_pmf [simp]:
   760   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   761   shows "measure_pmf.expectation (return_pmf x) f = f x"
   762   by (subst integral_measure_pmf[of "{x}"]) simp_all
   763 
   764 lemma pmf_expectation_bind:
   765   fixes p :: "'a pmf" and f :: "'a \<Rightarrow> 'b pmf"
   766     and  h :: "'b \<Rightarrow> 'c::{banach, second_countable_topology}"
   767   assumes "finite A" "\<And>x. x \<in> A \<Longrightarrow> finite (set_pmf (f x))" "set_pmf p \<subseteq> A"
   768   shows "measure_pmf.expectation (p \<bind> f) h =
   769            (\<Sum>a\<in>A. pmf p a *\<^sub>R measure_pmf.expectation (f a) h)"
   770 proof -
   771   have "measure_pmf.expectation (p \<bind> f) h = (\<Sum>a\<in>(\<Union>x\<in>A. set_pmf (f x)). pmf (p \<bind> f) a *\<^sub>R h a)"
   772     using assms by (intro integral_measure_pmf) auto
   773   also have "\<dots> = (\<Sum>x\<in>(\<Union>x\<in>A. set_pmf (f x)). (\<Sum>a\<in>A. (pmf p a * pmf (f a) x) *\<^sub>R h x))"
   774   proof (intro sum.cong refl, goal_cases)
   775     case (1 x)
   776     thus ?case
   777       by (subst pmf_bind, subst integral_measure_pmf[of A]) 
   778          (insert assms, auto simp: scaleR_sum_left)
   779   qed
   780   also have "\<dots> = (\<Sum>j\<in>A. pmf p j *\<^sub>R (\<Sum>i\<in>(\<Union>x\<in>A. set_pmf (f x)). pmf (f j) i *\<^sub>R h i))"
   781     by (subst sum.commute) (simp add: scaleR_sum_right)
   782   also have "\<dots> = (\<Sum>j\<in>A. pmf p j *\<^sub>R measure_pmf.expectation (f j) h)"
   783   proof (intro sum.cong refl, goal_cases)
   784     case (1 x)
   785     thus ?case
   786       by (subst integral_measure_pmf[of "(\<Union>x\<in>A. set_pmf (f x))"]) 
   787          (insert assms, auto simp: scaleR_sum_left)
   788   qed
   789   finally show ?thesis .
   790 qed
   791 
   792 lemma continuous_on_LINT_pmf: -- \<open>This is dominated convergence!?\<close>
   793   fixes f :: "'i \<Rightarrow> 'a::topological_space \<Rightarrow> 'b::{banach, second_countable_topology}"
   794   assumes f: "\<And>i. i \<in> set_pmf M \<Longrightarrow> continuous_on A (f i)"
   795     and bnd: "\<And>a i. a \<in> A \<Longrightarrow> i \<in> set_pmf M \<Longrightarrow> norm (f i a) \<le> B"
   796   shows "continuous_on A (\<lambda>a. LINT i|M. f i a)"
   797 proof cases
   798   assume "finite M" with f show ?thesis
   799     using integral_measure_pmf[OF \<open>finite M\<close>]
   800     by (subst integral_measure_pmf[OF \<open>finite M\<close>])
   801        (auto intro!: continuous_on_sum continuous_on_scaleR continuous_on_const)
   802 next
   803   assume "infinite M"
   804   let ?f = "\<lambda>i x. pmf (map_pmf (to_nat_on M) M) i *\<^sub>R f (from_nat_into M i) x"
   805 
   806   show ?thesis
   807   proof (rule uniform_limit_theorem)
   808     show "\<forall>\<^sub>F n in sequentially. continuous_on A (\<lambda>a. \<Sum>i<n. ?f i a)"
   809       by (intro always_eventually allI continuous_on_sum continuous_on_scaleR continuous_on_const f
   810                 from_nat_into set_pmf_not_empty)
   811     show "uniform_limit A (\<lambda>n a. \<Sum>i<n. ?f i a) (\<lambda>a. LINT i|M. f i a) sequentially"
   812     proof (subst uniform_limit_cong[where g="\<lambda>n a. \<Sum>i<n. ?f i a"])
   813       fix a assume "a \<in> A"
   814       have 1: "(LINT i|M. f i a) = (LINT i|map_pmf (to_nat_on M) M. f (from_nat_into M i) a)"
   815         by (auto intro!: integral_cong_AE AE_pmfI)
   816       have 2: "\<dots> = (LINT i|count_space UNIV. pmf (map_pmf (to_nat_on M) M) i *\<^sub>R f (from_nat_into M i) a)"
   817         by (simp add: measure_pmf_eq_density integral_density)
   818       have "(\<lambda>n. ?f n a) sums (LINT i|M. f i a)"
   819         unfolding 1 2
   820       proof (intro sums_integral_count_space_nat)
   821         have A: "integrable M (\<lambda>i. f i a)"
   822           using \<open>a\<in>A\<close> by (auto intro!: measure_pmf.integrable_const_bound AE_pmfI bnd)
   823         have "integrable (map_pmf (to_nat_on M) M) (\<lambda>i. f (from_nat_into M i) a)"
   824           by (auto simp add: map_pmf_rep_eq integrable_distr_eq intro!: AE_pmfI integrable_cong_AE_imp[OF A])
   825         then show "integrable (count_space UNIV) (\<lambda>n. ?f n a)"
   826           by (simp add: measure_pmf_eq_density integrable_density)
   827       qed
   828       then show "(LINT i|M. f i a) = (\<Sum> n. ?f n a)"
   829         by (simp add: sums_unique)
   830     next
   831       show "uniform_limit A (\<lambda>n a. \<Sum>i<n. ?f i a) (\<lambda>a. (\<Sum> n. ?f n a)) sequentially"
   832       proof (rule weierstrass_m_test)
   833         fix n a assume "a\<in>A"
   834         then show "norm (?f n a) \<le> pmf (map_pmf (to_nat_on M) M) n * B"
   835           using bnd by (auto intro!: mult_mono simp: from_nat_into set_pmf_not_empty)
   836       next
   837         have "integrable (map_pmf (to_nat_on M) M) (\<lambda>n. B)"
   838           by auto
   839         then show "summable (\<lambda>n. pmf (map_pmf (to_nat_on (set_pmf M)) M) n * B)"
   840           by (simp add: measure_pmf_eq_density integrable_density integrable_count_space_nat_iff summable_rabs_cancel)
   841       qed
   842     qed simp
   843   qed simp
   844 qed
   845 
   846 lemma continuous_on_LBINT:
   847   fixes f :: "real \<Rightarrow> real"
   848   assumes f: "\<And>b. a \<le> b \<Longrightarrow> set_integrable lborel {a..b} f"
   849   shows "continuous_on UNIV (\<lambda>b. LBINT x:{a..b}. f x)"
   850 proof (subst set_borel_integral_eq_integral)
   851   { fix b :: real assume "a \<le> b"
   852     from f[OF this] have "continuous_on {a..b} (\<lambda>b. integral {a..b} f)"
   853       by (intro indefinite_integral_continuous set_borel_integral_eq_integral) }
   854   note * = this
   855 
   856   have "continuous_on (\<Union>b\<in>{a..}. {a <..< b}) (\<lambda>b. integral {a..b} f)"
   857   proof (intro continuous_on_open_UN)
   858     show "b \<in> {a..} \<Longrightarrow> continuous_on {a<..<b} (\<lambda>b. integral {a..b} f)" for b
   859       using *[of b] by (rule continuous_on_subset) auto
   860   qed simp
   861   also have "(\<Union>b\<in>{a..}. {a <..< b}) = {a <..}"
   862     by (auto simp: lt_ex gt_ex less_imp_le) (simp add: Bex_def less_imp_le gt_ex cong: rev_conj_cong)
   863   finally have "continuous_on {a+1 ..} (\<lambda>b. integral {a..b} f)"
   864     by (rule continuous_on_subset) auto
   865   moreover have "continuous_on {a..a+1} (\<lambda>b. integral {a..b} f)"
   866     by (rule *) simp
   867   moreover
   868   have "x \<le> a \<Longrightarrow> {a..x} = (if a = x then {a} else {})" for x
   869     by auto
   870   then have "continuous_on {..a} (\<lambda>b. integral {a..b} f)"
   871     by (subst continuous_on_cong[OF refl, where g="\<lambda>x. 0"]) (auto intro!: continuous_on_const)
   872   ultimately have "continuous_on ({..a} \<union> {a..a+1} \<union> {a+1 ..}) (\<lambda>b. integral {a..b} f)"
   873     by (intro continuous_on_closed_Un) auto
   874   also have "{..a} \<union> {a..a+1} \<union> {a+1 ..} = UNIV"
   875     by auto
   876   finally show "continuous_on UNIV (\<lambda>b. integral {a..b} f)"
   877     by auto
   878 next
   879   show "set_integrable lborel {a..b} f" for b
   880     using f by (cases "a \<le> b") auto
   881 qed
   882 
   883 locale pmf_as_function
   884 begin
   885 
   886 setup_lifting td_pmf_embed_pmf
   887 
   888 lemma set_pmf_transfer[transfer_rule]:
   889   assumes "bi_total A"
   890   shows "rel_fun (pcr_pmf A) (rel_set A) (\<lambda>f. {x. f x \<noteq> 0}) set_pmf"
   891   using \<open>bi_total A\<close>
   892   by (auto simp: pcr_pmf_def cr_pmf_def rel_fun_def rel_set_def bi_total_def Bex_def set_pmf_iff)
   893      metis+
   894 
   895 end
   896 
   897 context
   898 begin
   899 
   900 interpretation pmf_as_function .
   901 
   902 lemma pmf_eqI: "(\<And>i. pmf M i = pmf N i) \<Longrightarrow> M = N"
   903   by transfer auto
   904 
   905 lemma pmf_eq_iff: "M = N \<longleftrightarrow> (\<forall>i. pmf M i = pmf N i)"
   906   by (auto intro: pmf_eqI)
   907 
   908 lemma pmf_neq_exists_less:
   909   assumes "M \<noteq> N"
   910   shows   "\<exists>x. pmf M x < pmf N x"
   911 proof (rule ccontr)
   912   assume "\<not>(\<exists>x. pmf M x < pmf N x)"
   913   hence ge: "pmf M x \<ge> pmf N x" for x by (auto simp: not_less)
   914   from assms obtain x where "pmf M x \<noteq> pmf N x" by (auto simp: pmf_eq_iff)
   915   with ge[of x] have gt: "pmf M x > pmf N x" by simp
   916   have "1 = measure (measure_pmf M) UNIV" by simp
   917   also have "\<dots> = measure (measure_pmf N) {x} + measure (measure_pmf N) (UNIV - {x})"
   918     by (subst measure_pmf.finite_measure_Union [symmetric]) simp_all
   919   also from gt have "measure (measure_pmf N) {x} < measure (measure_pmf M) {x}"
   920     by (simp add: measure_pmf_single)
   921   also have "measure (measure_pmf N) (UNIV - {x}) \<le> measure (measure_pmf M) (UNIV - {x})"
   922     by (subst (1 2) integral_pmf [symmetric])
   923        (intro integral_mono integrable_pmf, simp_all add: ge)
   924   also have "measure (measure_pmf M) {x} + \<dots> = 1"
   925     by (subst measure_pmf.finite_measure_Union [symmetric]) simp_all
   926   finally show False by simp_all
   927 qed
   928 
   929 lemma bind_commute_pmf: "bind_pmf A (\<lambda>x. bind_pmf B (C x)) = bind_pmf B (\<lambda>y. bind_pmf A (\<lambda>x. C x y))"
   930   unfolding pmf_eq_iff pmf_bind
   931 proof
   932   fix i
   933   interpret B: prob_space "restrict_space B B"
   934     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   935        (auto simp: AE_measure_pmf_iff)
   936   interpret A: prob_space "restrict_space A A"
   937     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   938        (auto simp: AE_measure_pmf_iff)
   939 
   940   interpret AB: pair_prob_space "restrict_space A A" "restrict_space B B"
   941     by unfold_locales
   942 
   943   have "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>A)"
   944     by (rule Bochner_Integration.integral_cong) (auto intro!: integral_pmf_restrict)
   945   also have "\<dots> = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>restrict_space A A)"
   946     by (intro integral_pmf_restrict B.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   947               countable_set_pmf borel_measurable_count_space)
   948   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>restrict_space B B)"
   949     by (rule AB.Fubini_integral[symmetric])
   950        (auto intro!: AB.integrable_const_bound[where B=1] measurable_pair_restrict_pmf2
   951              simp: pmf_nonneg pmf_le_1 measurable_restrict_space1)
   952   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>B)"
   953     by (intro integral_pmf_restrict[symmetric] A.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   954               countable_set_pmf borel_measurable_count_space)
   955   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)"
   956     by (rule Bochner_Integration.integral_cong) (auto intro!: integral_pmf_restrict[symmetric])
   957   finally show "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)" .
   958 qed
   959 
   960 lemma pair_map_pmf1: "pair_pmf (map_pmf f A) B = map_pmf (apfst f) (pair_pmf A B)"
   961 proof (safe intro!: pmf_eqI)
   962   fix a :: "'a" and b :: "'b"
   963   have [simp]: "\<And>c d. indicator (apfst f -` {(a, b)}) (c, d) = indicator (f -` {a}) c * (indicator {b} d::ennreal)"
   964     by (auto split: split_indicator)
   965 
   966   have "ennreal (pmf (pair_pmf (map_pmf f A) B) (a, b)) =
   967          ennreal (pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b))"
   968     unfolding pmf_pair ennreal_pmf_map
   969     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_multc pmf_nonneg
   970                   emeasure_map_pmf[symmetric] ennreal_mult del: emeasure_map_pmf)
   971   then show "pmf (pair_pmf (map_pmf f A) B) (a, b) = pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b)"
   972     by (simp add: pmf_nonneg)
   973 qed
   974 
   975 lemma pair_map_pmf2: "pair_pmf A (map_pmf f B) = map_pmf (apsnd f) (pair_pmf A B)"
   976 proof (safe intro!: pmf_eqI)
   977   fix a :: "'a" and b :: "'b"
   978   have [simp]: "\<And>c d. indicator (apsnd f -` {(a, b)}) (c, d) = indicator {a} c * (indicator (f -` {b}) d::ennreal)"
   979     by (auto split: split_indicator)
   980 
   981   have "ennreal (pmf (pair_pmf A (map_pmf f B)) (a, b)) =
   982          ennreal (pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b))"
   983     unfolding pmf_pair ennreal_pmf_map
   984     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_cmult nn_integral_multc pmf_nonneg
   985                   emeasure_map_pmf[symmetric] ennreal_mult del: emeasure_map_pmf)
   986   then show "pmf (pair_pmf A (map_pmf f B)) (a, b) = pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b)"
   987     by (simp add: pmf_nonneg)
   988 qed
   989 
   990 lemma map_pair: "map_pmf (\<lambda>(a, b). (f a, g b)) (pair_pmf A B) = pair_pmf (map_pmf f A) (map_pmf g B)"
   991   by (simp add: pair_map_pmf2 pair_map_pmf1 map_pmf_comp split_beta')
   992 
   993 end
   994 
   995 lemma pair_return_pmf1: "pair_pmf (return_pmf x) y = map_pmf (Pair x) y"
   996 by(simp add: pair_pmf_def bind_return_pmf map_pmf_def)
   997 
   998 lemma pair_return_pmf2: "pair_pmf x (return_pmf y) = map_pmf (\<lambda>x. (x, y)) x"
   999 by(simp add: pair_pmf_def bind_return_pmf map_pmf_def)
  1000 
  1001 lemma pair_pair_pmf: "pair_pmf (pair_pmf u v) w = map_pmf (\<lambda>(x, (y, z)). ((x, y), z)) (pair_pmf u (pair_pmf v w))"
  1002 by(simp add: pair_pmf_def bind_return_pmf map_pmf_def bind_assoc_pmf)
  1003 
  1004 lemma pair_commute_pmf: "pair_pmf x y = map_pmf (\<lambda>(x, y). (y, x)) (pair_pmf y x)"
  1005 unfolding pair_pmf_def by(subst bind_commute_pmf)(simp add: map_pmf_def bind_assoc_pmf bind_return_pmf)
  1006 
  1007 lemma set_pmf_subset_singleton: "set_pmf p \<subseteq> {x} \<longleftrightarrow> p = return_pmf x"
  1008 proof(intro iffI pmf_eqI)
  1009   fix i
  1010   assume x: "set_pmf p \<subseteq> {x}"
  1011   hence *: "set_pmf p = {x}" using set_pmf_not_empty[of p] by auto
  1012   have "ennreal (pmf p x) = \<integral>\<^sup>+ i. indicator {x} i \<partial>p" by(simp add: emeasure_pmf_single)
  1013   also have "\<dots> = \<integral>\<^sup>+ i. 1 \<partial>p" by(rule nn_integral_cong_AE)(simp add: AE_measure_pmf_iff * )
  1014   also have "\<dots> = 1" by simp
  1015   finally show "pmf p i = pmf (return_pmf x) i" using x
  1016     by(auto split: split_indicator simp add: pmf_eq_0_set_pmf)
  1017 qed auto
  1018 
  1019 lemma bind_eq_return_pmf:
  1020   "bind_pmf p f = return_pmf x \<longleftrightarrow> (\<forall>y\<in>set_pmf p. f y = return_pmf x)"
  1021   (is "?lhs \<longleftrightarrow> ?rhs")
  1022 proof(intro iffI strip)
  1023   fix y
  1024   assume y: "y \<in> set_pmf p"
  1025   assume "?lhs"
  1026   hence "set_pmf (bind_pmf p f) = {x}" by simp
  1027   hence "(\<Union>y\<in>set_pmf p. set_pmf (f y)) = {x}" by simp
  1028   hence "set_pmf (f y) \<subseteq> {x}" using y by auto
  1029   thus "f y = return_pmf x" by(simp add: set_pmf_subset_singleton)
  1030 next
  1031   assume *: ?rhs
  1032   show ?lhs
  1033   proof(rule pmf_eqI)
  1034     fix i
  1035     have "ennreal (pmf (bind_pmf p f) i) = \<integral>\<^sup>+ y. ennreal (pmf (f y) i) \<partial>p"
  1036       by (simp add: ennreal_pmf_bind)
  1037     also have "\<dots> = \<integral>\<^sup>+ y. ennreal (pmf (return_pmf x) i) \<partial>p"
  1038       by(rule nn_integral_cong_AE)(simp add: AE_measure_pmf_iff * )
  1039     also have "\<dots> = ennreal (pmf (return_pmf x) i)"
  1040       by simp
  1041     finally show "pmf (bind_pmf p f) i = pmf (return_pmf x) i"
  1042       by (simp add: pmf_nonneg)
  1043   qed
  1044 qed
  1045 
  1046 lemma pmf_False_conv_True: "pmf p False = 1 - pmf p True"
  1047 proof -
  1048   have "pmf p False + pmf p True = measure p {False} + measure p {True}"
  1049     by(simp add: measure_pmf_single)
  1050   also have "\<dots> = measure p ({False} \<union> {True})"
  1051     by(subst measure_pmf.finite_measure_Union) simp_all
  1052   also have "{False} \<union> {True} = space p" by auto
  1053   finally show ?thesis by simp
  1054 qed
  1055 
  1056 lemma pmf_True_conv_False: "pmf p True = 1 - pmf p False"
  1057 by(simp add: pmf_False_conv_True)
  1058 
  1059 subsection \<open> Conditional Probabilities \<close>
  1060 
  1061 lemma measure_pmf_zero_iff: "measure (measure_pmf p) s = 0 \<longleftrightarrow> set_pmf p \<inter> s = {}"
  1062   by (subst measure_pmf.prob_eq_0) (auto simp: AE_measure_pmf_iff)
  1063 
  1064 context
  1065   fixes p :: "'a pmf" and s :: "'a set"
  1066   assumes not_empty: "set_pmf p \<inter> s \<noteq> {}"
  1067 begin
  1068 
  1069 interpretation pmf_as_measure .
  1070 
  1071 lemma emeasure_measure_pmf_not_zero: "emeasure (measure_pmf p) s \<noteq> 0"
  1072 proof
  1073   assume "emeasure (measure_pmf p) s = 0"
  1074   then have "AE x in measure_pmf p. x \<notin> s"
  1075     by (rule AE_I[rotated]) auto
  1076   with not_empty show False
  1077     by (auto simp: AE_measure_pmf_iff)
  1078 qed
  1079 
  1080 lemma measure_measure_pmf_not_zero: "measure (measure_pmf p) s \<noteq> 0"
  1081   using emeasure_measure_pmf_not_zero by (simp add: measure_pmf.emeasure_eq_measure measure_nonneg)
  1082 
  1083 lift_definition cond_pmf :: "'a pmf" is
  1084   "uniform_measure (measure_pmf p) s"
  1085 proof (intro conjI)
  1086   show "prob_space (uniform_measure (measure_pmf p) s)"
  1087     by (intro prob_space_uniform_measure) (auto simp: emeasure_measure_pmf_not_zero)
  1088   show "AE x in uniform_measure (measure_pmf p) s. measure (uniform_measure (measure_pmf p) s) {x} \<noteq> 0"
  1089     by (simp add: emeasure_measure_pmf_not_zero measure_measure_pmf_not_zero AE_uniform_measure
  1090                   AE_measure_pmf_iff set_pmf.rep_eq less_top[symmetric])
  1091 qed simp
  1092 
  1093 lemma pmf_cond: "pmf cond_pmf x = (if x \<in> s then pmf p x / measure p s else 0)"
  1094   by transfer (simp add: emeasure_measure_pmf_not_zero pmf.rep_eq)
  1095 
  1096 lemma set_cond_pmf[simp]: "set_pmf cond_pmf = set_pmf p \<inter> s"
  1097   by (auto simp add: set_pmf_iff pmf_cond measure_measure_pmf_not_zero split: if_split_asm)
  1098 
  1099 end
  1100 
  1101 lemma measure_pmf_posI: "x \<in> set_pmf p \<Longrightarrow> x \<in> A \<Longrightarrow> measure_pmf.prob p A > 0"
  1102   using measure_measure_pmf_not_zero[of p A] by (subst zero_less_measure_iff) blast
  1103 
  1104 lemma cond_map_pmf:
  1105   assumes "set_pmf p \<inter> f -` s \<noteq> {}"
  1106   shows "cond_pmf (map_pmf f p) s = map_pmf f (cond_pmf p (f -` s))"
  1107 proof -
  1108   have *: "set_pmf (map_pmf f p) \<inter> s \<noteq> {}"
  1109     using assms by auto
  1110   { fix x
  1111     have "ennreal (pmf (map_pmf f (cond_pmf p (f -` s))) x) =
  1112       emeasure p (f -` s \<inter> f -` {x}) / emeasure p (f -` s)"
  1113       unfolding ennreal_pmf_map cond_pmf.rep_eq[OF assms] by (simp add: nn_integral_uniform_measure)
  1114     also have "f -` s \<inter> f -` {x} = (if x \<in> s then f -` {x} else {})"
  1115       by auto
  1116     also have "emeasure p (if x \<in> s then f -` {x} else {}) / emeasure p (f -` s) =
  1117       ennreal (pmf (cond_pmf (map_pmf f p) s) x)"
  1118       using measure_measure_pmf_not_zero[OF *]
  1119       by (simp add: pmf_cond[OF *] ennreal_pmf_map measure_pmf.emeasure_eq_measure
  1120                     divide_ennreal pmf_nonneg measure_nonneg zero_less_measure_iff pmf_map)
  1121     finally have "ennreal (pmf (cond_pmf (map_pmf f p) s) x) = ennreal (pmf (map_pmf f (cond_pmf p (f -` s))) x)"
  1122       by simp }
  1123   then show ?thesis
  1124     by (intro pmf_eqI) (simp add: pmf_nonneg)
  1125 qed
  1126 
  1127 lemma bind_cond_pmf_cancel:
  1128   assumes [simp]: "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
  1129   assumes [simp]: "\<And>y. y \<in> set_pmf q \<Longrightarrow> set_pmf p \<inter> {x. R x y} \<noteq> {}"
  1130   assumes [simp]: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow> measure q {y. R x y} = measure p {x. R x y}"
  1131   shows "bind_pmf p (\<lambda>x. cond_pmf q {y. R x y}) = q"
  1132 proof (rule pmf_eqI)
  1133   fix i
  1134   have "ennreal (pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i) =
  1135     (\<integral>\<^sup>+x. ennreal (pmf q i / measure p {x. R x i}) * ennreal (indicator {x. R x i} x) \<partial>p)"
  1136     by (auto simp add: ennreal_pmf_bind AE_measure_pmf_iff pmf_cond pmf_eq_0_set_pmf pmf_nonneg measure_nonneg
  1137              intro!: nn_integral_cong_AE)
  1138   also have "\<dots> = (pmf q i * measure p {x. R x i}) / measure p {x. R x i}"
  1139     by (simp add: pmf_nonneg measure_nonneg zero_ennreal_def[symmetric] ennreal_indicator
  1140                   nn_integral_cmult measure_pmf.emeasure_eq_measure ennreal_mult[symmetric])
  1141   also have "\<dots> = pmf q i"
  1142     by (cases "pmf q i = 0")
  1143        (simp_all add: pmf_eq_0_set_pmf measure_measure_pmf_not_zero pmf_nonneg)
  1144   finally show "pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i = pmf q i"
  1145     by (simp add: pmf_nonneg)
  1146 qed
  1147 
  1148 subsection \<open> Relator \<close>
  1149 
  1150 inductive rel_pmf :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf \<Rightarrow> bool"
  1151 for R p q
  1152 where
  1153   "\<lbrakk> \<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y;
  1154      map_pmf fst pq = p; map_pmf snd pq = q \<rbrakk>
  1155   \<Longrightarrow> rel_pmf R p q"
  1156 
  1157 lemma rel_pmfI:
  1158   assumes R: "rel_set R (set_pmf p) (set_pmf q)"
  1159   assumes eq: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow>
  1160     measure p {x. R x y} = measure q {y. R x y}"
  1161   shows "rel_pmf R p q"
  1162 proof
  1163   let ?pq = "bind_pmf p (\<lambda>x. bind_pmf (cond_pmf q {y. R x y}) (\<lambda>y. return_pmf (x, y)))"
  1164   have "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
  1165     using R by (auto simp: rel_set_def)
  1166   then show "\<And>x y. (x, y) \<in> set_pmf ?pq \<Longrightarrow> R x y"
  1167     by auto
  1168   show "map_pmf fst ?pq = p"
  1169     by (simp add: map_bind_pmf bind_return_pmf')
  1170 
  1171   show "map_pmf snd ?pq = q"
  1172     using R eq
  1173     apply (simp add: bind_cond_pmf_cancel map_bind_pmf bind_return_pmf')
  1174     apply (rule bind_cond_pmf_cancel)
  1175     apply (auto simp: rel_set_def)
  1176     done
  1177 qed
  1178 
  1179 lemma rel_pmf_imp_rel_set: "rel_pmf R p q \<Longrightarrow> rel_set R (set_pmf p) (set_pmf q)"
  1180   by (force simp add: rel_pmf.simps rel_set_def)
  1181 
  1182 lemma rel_pmfD_measure:
  1183   assumes rel_R: "rel_pmf R p q" and R: "\<And>a b. R a b \<Longrightarrow> R a y \<longleftrightarrow> R x b"
  1184   assumes "x \<in> set_pmf p" "y \<in> set_pmf q"
  1185   shows "measure p {x. R x y} = measure q {y. R x y}"
  1186 proof -
  1187   from rel_R obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1188     and eq: "p = map_pmf fst pq" "q = map_pmf snd pq"
  1189     by (auto elim: rel_pmf.cases)
  1190   have "measure p {x. R x y} = measure pq {x. R (fst x) y}"
  1191     by (simp add: eq map_pmf_rep_eq measure_distr)
  1192   also have "\<dots> = measure pq {y. R x (snd y)}"
  1193     by (intro measure_pmf.finite_measure_eq_AE)
  1194        (auto simp: AE_measure_pmf_iff R dest!: pq)
  1195   also have "\<dots> = measure q {y. R x y}"
  1196     by (simp add: eq map_pmf_rep_eq measure_distr)
  1197   finally show "measure p {x. R x y} = measure q {y. R x y}" .
  1198 qed
  1199 
  1200 lemma rel_pmf_measureD:
  1201   assumes "rel_pmf R p q"
  1202   shows "measure (measure_pmf p) A \<le> measure (measure_pmf q) {y. \<exists>x\<in>A. R x y}" (is "?lhs \<le> ?rhs")
  1203 using assms
  1204 proof cases
  1205   fix pq
  1206   assume R: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1207     and p[symmetric]: "map_pmf fst pq = p"
  1208     and q[symmetric]: "map_pmf snd pq = q"
  1209   have "?lhs = measure (measure_pmf pq) (fst -` A)" by(simp add: p)
  1210   also have "\<dots> \<le> measure (measure_pmf pq) {y. \<exists>x\<in>A. R x (snd y)}"
  1211     by(rule measure_pmf.finite_measure_mono_AE)(auto 4 3 simp add: AE_measure_pmf_iff dest: R)
  1212   also have "\<dots> = ?rhs" by(simp add: q)
  1213   finally show ?thesis .
  1214 qed
  1215 
  1216 lemma rel_pmf_iff_measure:
  1217   assumes "symp R" "transp R"
  1218   shows "rel_pmf R p q \<longleftrightarrow>
  1219     rel_set R (set_pmf p) (set_pmf q) \<and>
  1220     (\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y})"
  1221   by (safe intro!: rel_pmf_imp_rel_set rel_pmfI)
  1222      (auto intro!: rel_pmfD_measure dest: sympD[OF \<open>symp R\<close>] transpD[OF \<open>transp R\<close>])
  1223 
  1224 lemma quotient_rel_set_disjoint:
  1225   "equivp R \<Longrightarrow> C \<in> UNIV // {(x, y). R x y} \<Longrightarrow> rel_set R A B \<Longrightarrow> A \<inter> C = {} \<longleftrightarrow> B \<inter> C = {}"
  1226   using in_quotient_imp_closed[of UNIV "{(x, y). R x y}" C]
  1227   by (auto 0 0 simp: equivp_equiv rel_set_def set_eq_iff elim: equivpE)
  1228      (blast dest: equivp_symp)+
  1229 
  1230 lemma quotientD: "equiv X R \<Longrightarrow> A \<in> X // R \<Longrightarrow> x \<in> A \<Longrightarrow> A = R `` {x}"
  1231   by (metis Image_singleton_iff equiv_class_eq_iff quotientE)
  1232 
  1233 lemma rel_pmf_iff_equivp:
  1234   assumes "equivp R"
  1235   shows "rel_pmf R p q \<longleftrightarrow> (\<forall>C\<in>UNIV // {(x, y). R x y}. measure p C = measure q C)"
  1236     (is "_ \<longleftrightarrow>   (\<forall>C\<in>_//?R. _)")
  1237 proof (subst rel_pmf_iff_measure, safe)
  1238   show "symp R" "transp R"
  1239     using assms by (auto simp: equivp_reflp_symp_transp)
  1240 next
  1241   fix C assume C: "C \<in> UNIV // ?R" and R: "rel_set R (set_pmf p) (set_pmf q)"
  1242   assume eq: "\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y}"
  1243 
  1244   show "measure p C = measure q C"
  1245   proof (cases "p \<inter> C = {}")
  1246     case True
  1247     then have "q \<inter> C = {}"
  1248       using quotient_rel_set_disjoint[OF assms C R] by simp
  1249     with True show ?thesis
  1250       unfolding measure_pmf_zero_iff[symmetric] by simp
  1251   next
  1252     case False
  1253     then have "q \<inter> C \<noteq> {}"
  1254       using quotient_rel_set_disjoint[OF assms C R] by simp
  1255     with False obtain x y where in_set: "x \<in> set_pmf p" "y \<in> set_pmf q" and in_C: "x \<in> C" "y \<in> C"
  1256       by auto
  1257     then have "R x y"
  1258       using in_quotient_imp_in_rel[of UNIV ?R C x y] C assms
  1259       by (simp add: equivp_equiv)
  1260     with in_set eq have "measure p {x. R x y} = measure q {y. R x y}"
  1261       by auto
  1262     moreover have "{y. R x y} = C"
  1263       using assms \<open>x \<in> C\<close> C quotientD[of UNIV ?R C x] by (simp add: equivp_equiv)
  1264     moreover have "{x. R x y} = C"
  1265       using assms \<open>y \<in> C\<close> C quotientD[of UNIV "?R" C y] sympD[of R]
  1266       by (auto simp add: equivp_equiv elim: equivpE)
  1267     ultimately show ?thesis
  1268       by auto
  1269   qed
  1270 next
  1271   assume eq: "\<forall>C\<in>UNIV // ?R. measure p C = measure q C"
  1272   show "rel_set R (set_pmf p) (set_pmf q)"
  1273     unfolding rel_set_def
  1274   proof safe
  1275     fix x assume x: "x \<in> set_pmf p"
  1276     have "{y. R x y} \<in> UNIV // ?R"
  1277       by (auto simp: quotient_def)
  1278     with eq have *: "measure q {y. R x y} = measure p {y. R x y}"
  1279       by auto
  1280     have "measure q {y. R x y} \<noteq> 0"
  1281       using x assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
  1282     then show "\<exists>y\<in>set_pmf q. R x y"
  1283       unfolding measure_pmf_zero_iff by auto
  1284   next
  1285     fix y assume y: "y \<in> set_pmf q"
  1286     have "{x. R x y} \<in> UNIV // ?R"
  1287       using assms by (auto simp: quotient_def dest: equivp_symp)
  1288     with eq have *: "measure p {x. R x y} = measure q {x. R x y}"
  1289       by auto
  1290     have "measure p {x. R x y} \<noteq> 0"
  1291       using y assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
  1292     then show "\<exists>x\<in>set_pmf p. R x y"
  1293       unfolding measure_pmf_zero_iff by auto
  1294   qed
  1295 
  1296   fix x y assume "x \<in> set_pmf p" "y \<in> set_pmf q" "R x y"
  1297   have "{y. R x y} \<in> UNIV // ?R" "{x. R x y} = {y. R x y}"
  1298     using assms \<open>R x y\<close> by (auto simp: quotient_def dest: equivp_symp equivp_transp)
  1299   with eq show "measure p {x. R x y} = measure q {y. R x y}"
  1300     by auto
  1301 qed
  1302 
  1303 bnf pmf: "'a pmf" map: map_pmf sets: set_pmf bd : "natLeq" rel: rel_pmf
  1304 proof -
  1305   show "map_pmf id = id" by (rule map_pmf_id)
  1306   show "\<And>f g. map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g" by (rule map_pmf_compose)
  1307   show "\<And>f g::'a \<Rightarrow> 'b. \<And>p. (\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g p"
  1308     by (intro map_pmf_cong refl)
  1309 
  1310   show "\<And>f::'a \<Rightarrow> 'b. set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
  1311     by (rule pmf_set_map)
  1312 
  1313   show "(card_of (set_pmf p), natLeq) \<in> ordLeq" for p :: "'s pmf"
  1314   proof -
  1315     have "(card_of (set_pmf p), card_of (UNIV :: nat set)) \<in> ordLeq"
  1316       by (rule card_of_ordLeqI[where f="to_nat_on (set_pmf p)"])
  1317          (auto intro: countable_set_pmf)
  1318     also have "(card_of (UNIV :: nat set), natLeq) \<in> ordLeq"
  1319       by (metis Field_natLeq card_of_least natLeq_Well_order)
  1320     finally show ?thesis .
  1321   qed
  1322 
  1323   show "\<And>R. rel_pmf R = (\<lambda>x y. \<exists>z. set_pmf z \<subseteq> {(x, y). R x y} \<and>
  1324     map_pmf fst z = x \<and> map_pmf snd z = y)"
  1325      by (auto simp add: fun_eq_iff rel_pmf.simps)
  1326 
  1327   show "rel_pmf R OO rel_pmf S \<le> rel_pmf (R OO S)"
  1328     for R :: "'a \<Rightarrow> 'b \<Rightarrow> bool" and S :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
  1329   proof -
  1330     { fix p q r
  1331       assume pq: "rel_pmf R p q"
  1332         and qr:"rel_pmf S q r"
  1333       from pq obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1334         and p: "p = map_pmf fst pq" and q: "q = map_pmf snd pq" by cases auto
  1335       from qr obtain qr where qr: "\<And>y z. (y, z) \<in> set_pmf qr \<Longrightarrow> S y z"
  1336         and q': "q = map_pmf fst qr" and r: "r = map_pmf snd qr" by cases auto
  1337 
  1338       define pr where "pr =
  1339         bind_pmf pq (\<lambda>xy. bind_pmf (cond_pmf qr {yz. fst yz = snd xy})
  1340           (\<lambda>yz. return_pmf (fst xy, snd yz)))"
  1341       have pr_welldefined: "\<And>y. y \<in> q \<Longrightarrow> qr \<inter> {yz. fst yz = y} \<noteq> {}"
  1342         by (force simp: q')
  1343 
  1344       have "rel_pmf (R OO S) p r"
  1345       proof (rule rel_pmf.intros)
  1346         fix x z assume "(x, z) \<in> pr"
  1347         then have "\<exists>y. (x, y) \<in> pq \<and> (y, z) \<in> qr"
  1348           by (auto simp: q pr_welldefined pr_def split_beta)
  1349         with pq qr show "(R OO S) x z"
  1350           by blast
  1351       next
  1352         have "map_pmf snd pr = map_pmf snd (bind_pmf q (\<lambda>y. cond_pmf qr {yz. fst yz = y}))"
  1353           by (simp add: pr_def q split_beta bind_map_pmf map_pmf_def[symmetric] map_bind_pmf map_pmf_comp)
  1354         then show "map_pmf snd pr = r"
  1355           unfolding r q' bind_map_pmf by (subst (asm) bind_cond_pmf_cancel) (auto simp: eq_commute)
  1356       qed (simp add: pr_def map_bind_pmf split_beta map_pmf_def[symmetric] p map_pmf_comp)
  1357     }
  1358     then show ?thesis
  1359       by(auto simp add: le_fun_def)
  1360   qed
  1361 qed (fact natLeq_card_order natLeq_cinfinite)+
  1362 
  1363 lemma map_pmf_idI: "(\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = x) \<Longrightarrow> map_pmf f p = p"
  1364 by(simp cong: pmf.map_cong)
  1365 
  1366 lemma rel_pmf_conj[simp]:
  1367   "rel_pmf (\<lambda>x y. P \<and> Q x y) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1368   "rel_pmf (\<lambda>x y. Q x y \<and> P) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1369   using set_pmf_not_empty by (fastforce simp: pmf.in_rel subset_eq)+
  1370 
  1371 lemma rel_pmf_top[simp]: "rel_pmf top = top"
  1372   by (auto simp: pmf.in_rel[abs_def] fun_eq_iff map_fst_pair_pmf map_snd_pair_pmf
  1373            intro: exI[of _ "pair_pmf x y" for x y])
  1374 
  1375 lemma rel_pmf_return_pmf1: "rel_pmf R (return_pmf x) M \<longleftrightarrow> (\<forall>a\<in>M. R x a)"
  1376 proof safe
  1377   fix a assume "a \<in> M" "rel_pmf R (return_pmf x) M"
  1378   then obtain pq where *: "\<And>a b. (a, b) \<in> set_pmf pq \<Longrightarrow> R a b"
  1379     and eq: "return_pmf x = map_pmf fst pq" "M = map_pmf snd pq"
  1380     by (force elim: rel_pmf.cases)
  1381   moreover have "set_pmf (return_pmf x) = {x}"
  1382     by simp
  1383   with \<open>a \<in> M\<close> have "(x, a) \<in> pq"
  1384     by (force simp: eq)
  1385   with * show "R x a"
  1386     by auto
  1387 qed (auto intro!: rel_pmf.intros[where pq="pair_pmf (return_pmf x) M"]
  1388           simp: map_fst_pair_pmf map_snd_pair_pmf)
  1389 
  1390 lemma rel_pmf_return_pmf2: "rel_pmf R M (return_pmf x) \<longleftrightarrow> (\<forall>a\<in>M. R a x)"
  1391   by (subst pmf.rel_flip[symmetric]) (simp add: rel_pmf_return_pmf1)
  1392 
  1393 lemma rel_return_pmf[simp]: "rel_pmf R (return_pmf x1) (return_pmf x2) = R x1 x2"
  1394   unfolding rel_pmf_return_pmf2 set_return_pmf by simp
  1395 
  1396 lemma rel_pmf_False[simp]: "rel_pmf (\<lambda>x y. False) x y = False"
  1397   unfolding pmf.in_rel fun_eq_iff using set_pmf_not_empty by fastforce
  1398 
  1399 lemma rel_pmf_rel_prod:
  1400   "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B') \<longleftrightarrow> rel_pmf R A B \<and> rel_pmf S A' B'"
  1401 proof safe
  1402   assume "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1403   then obtain pq where pq: "\<And>a b c d. ((a, c), (b, d)) \<in> set_pmf pq \<Longrightarrow> R a b \<and> S c d"
  1404     and eq: "map_pmf fst pq = pair_pmf A A'" "map_pmf snd pq = pair_pmf B B'"
  1405     by (force elim: rel_pmf.cases)
  1406   show "rel_pmf R A B"
  1407   proof (rule rel_pmf.intros)
  1408     let ?f = "\<lambda>(a, b). (fst a, fst b)"
  1409     have [simp]: "(\<lambda>x. fst (?f x)) = fst o fst" "(\<lambda>x. snd (?f x)) = fst o snd"
  1410       by auto
  1411 
  1412     show "map_pmf fst (map_pmf ?f pq) = A"
  1413       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1414     show "map_pmf snd (map_pmf ?f pq) = B"
  1415       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1416 
  1417     fix a b assume "(a, b) \<in> set_pmf (map_pmf ?f pq)"
  1418     then obtain c d where "((a, c), (b, d)) \<in> set_pmf pq"
  1419       by auto
  1420     from pq[OF this] show "R a b" ..
  1421   qed
  1422   show "rel_pmf S A' B'"
  1423   proof (rule rel_pmf.intros)
  1424     let ?f = "\<lambda>(a, b). (snd a, snd b)"
  1425     have [simp]: "(\<lambda>x. fst (?f x)) = snd o fst" "(\<lambda>x. snd (?f x)) = snd o snd"
  1426       by auto
  1427 
  1428     show "map_pmf fst (map_pmf ?f pq) = A'"
  1429       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1430     show "map_pmf snd (map_pmf ?f pq) = B'"
  1431       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1432 
  1433     fix c d assume "(c, d) \<in> set_pmf (map_pmf ?f pq)"
  1434     then obtain a b where "((a, c), (b, d)) \<in> set_pmf pq"
  1435       by auto
  1436     from pq[OF this] show "S c d" ..
  1437   qed
  1438 next
  1439   assume "rel_pmf R A B" "rel_pmf S A' B'"
  1440   then obtain Rpq Spq
  1441     where Rpq: "\<And>a b. (a, b) \<in> set_pmf Rpq \<Longrightarrow> R a b"
  1442         "map_pmf fst Rpq = A" "map_pmf snd Rpq = B"
  1443       and Spq: "\<And>a b. (a, b) \<in> set_pmf Spq \<Longrightarrow> S a b"
  1444         "map_pmf fst Spq = A'" "map_pmf snd Spq = B'"
  1445     by (force elim: rel_pmf.cases)
  1446 
  1447   let ?f = "(\<lambda>((a, c), (b, d)). ((a, b), (c, d)))"
  1448   let ?pq = "map_pmf ?f (pair_pmf Rpq Spq)"
  1449   have [simp]: "(\<lambda>x. fst (?f x)) = (\<lambda>(a, b). (fst a, fst b))" "(\<lambda>x. snd (?f x)) = (\<lambda>(a, b). (snd a, snd b))"
  1450     by auto
  1451 
  1452   show "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1453     by (rule rel_pmf.intros[where pq="?pq"])
  1454        (auto simp: map_snd_pair_pmf map_fst_pair_pmf map_pmf_comp Rpq Spq
  1455                    map_pair)
  1456 qed
  1457 
  1458 lemma rel_pmf_reflI:
  1459   assumes "\<And>x. x \<in> set_pmf p \<Longrightarrow> P x x"
  1460   shows "rel_pmf P p p"
  1461   by (rule rel_pmf.intros[where pq="map_pmf (\<lambda>x. (x, x)) p"])
  1462      (auto simp add: pmf.map_comp o_def assms)
  1463 
  1464 lemma rel_pmf_bij_betw:
  1465   assumes f: "bij_betw f (set_pmf p) (set_pmf q)"
  1466   and eq: "\<And>x. x \<in> set_pmf p \<Longrightarrow> pmf p x = pmf q (f x)"
  1467   shows "rel_pmf (\<lambda>x y. f x = y) p q"
  1468 proof(rule rel_pmf.intros)
  1469   let ?pq = "map_pmf (\<lambda>x. (x, f x)) p"
  1470   show "map_pmf fst ?pq = p" by(simp add: pmf.map_comp o_def)
  1471 
  1472   have "map_pmf f p = q"
  1473   proof(rule pmf_eqI)
  1474     fix i
  1475     show "pmf (map_pmf f p) i = pmf q i"
  1476     proof(cases "i \<in> set_pmf q")
  1477       case True
  1478       with f obtain j where "i = f j" "j \<in> set_pmf p"
  1479         by(auto simp add: bij_betw_def image_iff)
  1480       thus ?thesis using f by(simp add: bij_betw_def pmf_map_inj eq)
  1481     next
  1482       case False thus ?thesis
  1483         by(subst pmf_map_outside)(auto simp add: set_pmf_iff eq[symmetric])
  1484     qed
  1485   qed
  1486   then show "map_pmf snd ?pq = q" by(simp add: pmf.map_comp o_def)
  1487 qed auto
  1488 
  1489 context
  1490 begin
  1491 
  1492 interpretation pmf_as_measure .
  1493 
  1494 definition "join_pmf M = bind_pmf M (\<lambda>x. x)"
  1495 
  1496 lemma bind_eq_join_pmf: "bind_pmf M f = join_pmf (map_pmf f M)"
  1497   unfolding join_pmf_def bind_map_pmf ..
  1498 
  1499 lemma join_eq_bind_pmf: "join_pmf M = bind_pmf M id"
  1500   by (simp add: join_pmf_def id_def)
  1501 
  1502 lemma pmf_join: "pmf (join_pmf N) i = (\<integral>M. pmf M i \<partial>measure_pmf N)"
  1503   unfolding join_pmf_def pmf_bind ..
  1504 
  1505 lemma ennreal_pmf_join: "ennreal (pmf (join_pmf N) i) = (\<integral>\<^sup>+M. pmf M i \<partial>measure_pmf N)"
  1506   unfolding join_pmf_def ennreal_pmf_bind ..
  1507 
  1508 lemma set_pmf_join_pmf[simp]: "set_pmf (join_pmf f) = (\<Union>p\<in>set_pmf f. set_pmf p)"
  1509   by (simp add: join_pmf_def)
  1510 
  1511 lemma join_return_pmf: "join_pmf (return_pmf M) = M"
  1512   by (simp add: integral_return pmf_eq_iff pmf_join return_pmf.rep_eq)
  1513 
  1514 lemma map_join_pmf: "map_pmf f (join_pmf AA) = join_pmf (map_pmf (map_pmf f) AA)"
  1515   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf)
  1516 
  1517 lemma join_map_return_pmf: "join_pmf (map_pmf return_pmf A) = A"
  1518   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
  1519 
  1520 end
  1521 
  1522 lemma rel_pmf_joinI:
  1523   assumes "rel_pmf (rel_pmf P) p q"
  1524   shows "rel_pmf P (join_pmf p) (join_pmf q)"
  1525 proof -
  1526   from assms obtain pq where p: "p = map_pmf fst pq"
  1527     and q: "q = map_pmf snd pq"
  1528     and P: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> rel_pmf P x y"
  1529     by cases auto
  1530   from P obtain PQ
  1531     where PQ: "\<And>x y a b. \<lbrakk> (x, y) \<in> set_pmf pq; (a, b) \<in> set_pmf (PQ x y) \<rbrakk> \<Longrightarrow> P a b"
  1532     and x: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf fst (PQ x y) = x"
  1533     and y: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf snd (PQ x y) = y"
  1534     by(metis rel_pmf.simps)
  1535 
  1536   let ?r = "bind_pmf pq (\<lambda>(x, y). PQ x y)"
  1537   have "\<And>a b. (a, b) \<in> set_pmf ?r \<Longrightarrow> P a b" by (auto intro: PQ)
  1538   moreover have "map_pmf fst ?r = join_pmf p" "map_pmf snd ?r = join_pmf q"
  1539     by (simp_all add: p q x y join_pmf_def map_bind_pmf bind_map_pmf split_def cong: bind_pmf_cong)
  1540   ultimately show ?thesis ..
  1541 qed
  1542 
  1543 lemma rel_pmf_bindI:
  1544   assumes pq: "rel_pmf R p q"
  1545   and fg: "\<And>x y. R x y \<Longrightarrow> rel_pmf P (f x) (g y)"
  1546   shows "rel_pmf P (bind_pmf p f) (bind_pmf q g)"
  1547   unfolding bind_eq_join_pmf
  1548   by (rule rel_pmf_joinI)
  1549      (auto simp add: pmf.rel_map intro: pmf.rel_mono[THEN le_funD, THEN le_funD, THEN le_boolD, THEN mp, OF _ pq] fg)
  1550 
  1551 text \<open>
  1552   Proof that @{const rel_pmf} preserves orders.
  1553   Antisymmetry proof follows Thm. 1 in N. Saheb-Djahromi, Cpo's of measures for nondeterminism,
  1554   Theoretical Computer Science 12(1):19--37, 1980,
  1555   \<^url>\<open>http://dx.doi.org/10.1016/0304-3975(80)90003-1\<close>
  1556 \<close>
  1557 
  1558 lemma
  1559   assumes *: "rel_pmf R p q"
  1560   and refl: "reflp R" and trans: "transp R"
  1561   shows measure_Ici: "measure p {y. R x y} \<le> measure q {y. R x y}" (is ?thesis1)
  1562   and measure_Ioi: "measure p {y. R x y \<and> \<not> R y x} \<le> measure q {y. R x y \<and> \<not> R y x}" (is ?thesis2)
  1563 proof -
  1564   from * obtain pq
  1565     where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1566     and p: "p = map_pmf fst pq"
  1567     and q: "q = map_pmf snd pq"
  1568     by cases auto
  1569   show ?thesis1 ?thesis2 unfolding p q map_pmf_rep_eq using refl trans
  1570     by(auto 4 3 simp add: measure_distr reflpD AE_measure_pmf_iff intro!: measure_pmf.finite_measure_mono_AE dest!: pq elim: transpE)
  1571 qed
  1572 
  1573 lemma rel_pmf_inf:
  1574   fixes p q :: "'a pmf"
  1575   assumes 1: "rel_pmf R p q"
  1576   assumes 2: "rel_pmf R q p"
  1577   and refl: "reflp R" and trans: "transp R"
  1578   shows "rel_pmf (inf R R\<inverse>\<inverse>) p q"
  1579 proof (subst rel_pmf_iff_equivp, safe)
  1580   show "equivp (inf R R\<inverse>\<inverse>)"
  1581     using trans refl by (auto simp: equivp_reflp_symp_transp intro: sympI transpI reflpI dest: transpD reflpD)
  1582 
  1583   fix C assume "C \<in> UNIV // {(x, y). inf R R\<inverse>\<inverse> x y}"
  1584   then obtain x where C: "C = {y. R x y \<and> R y x}"
  1585     by (auto elim: quotientE)
  1586 
  1587   let ?R = "\<lambda>x y. R x y \<and> R y x"
  1588   let ?\<mu>R = "\<lambda>y. measure q {x. ?R x y}"
  1589   have "measure p {y. ?R x y} = measure p ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1590     by(auto intro!: arg_cong[where f="measure p"])
  1591   also have "\<dots> = measure p {y. R x y} - measure p {y. R x y \<and> \<not> R y x}"
  1592     by (rule measure_pmf.finite_measure_Diff) auto
  1593   also have "measure p {y. R x y \<and> \<not> R y x} = measure q {y. R x y \<and> \<not> R y x}"
  1594     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ioi)
  1595   also have "measure p {y. R x y} = measure q {y. R x y}"
  1596     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ici)
  1597   also have "measure q {y. R x y} - measure q {y. R x y \<and> \<not> R y x} =
  1598     measure q ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1599     by(rule measure_pmf.finite_measure_Diff[symmetric]) auto
  1600   also have "\<dots> = ?\<mu>R x"
  1601     by(auto intro!: arg_cong[where f="measure q"])
  1602   finally show "measure p C = measure q C"
  1603     by (simp add: C conj_commute)
  1604 qed
  1605 
  1606 lemma rel_pmf_antisym:
  1607   fixes p q :: "'a pmf"
  1608   assumes 1: "rel_pmf R p q"
  1609   assumes 2: "rel_pmf R q p"
  1610   and refl: "reflp R" and trans: "transp R" and antisym: "antisymp R"
  1611   shows "p = q"
  1612 proof -
  1613   from 1 2 refl trans have "rel_pmf (inf R R\<inverse>\<inverse>) p q" by(rule rel_pmf_inf)
  1614   also have "inf R R\<inverse>\<inverse> = op ="
  1615     using refl antisym by (auto intro!: ext simp add: reflpD dest: antisympD)
  1616   finally show ?thesis unfolding pmf.rel_eq .
  1617 qed
  1618 
  1619 lemma reflp_rel_pmf: "reflp R \<Longrightarrow> reflp (rel_pmf R)"
  1620   by (fact pmf.rel_reflp)
  1621 
  1622 lemma antisymp_rel_pmf:
  1623   "\<lbrakk> reflp R; transp R; antisymp R \<rbrakk>
  1624   \<Longrightarrow> antisymp (rel_pmf R)"
  1625 by(rule antisympI)(blast intro: rel_pmf_antisym)
  1626 
  1627 lemma transp_rel_pmf:
  1628   assumes "transp R"
  1629   shows "transp (rel_pmf R)"
  1630   using assms by (fact pmf.rel_transp)
  1631 
  1632     
  1633 subsection \<open> Distributions \<close>
  1634 
  1635 context
  1636 begin
  1637 
  1638 interpretation pmf_as_function .
  1639 
  1640 subsubsection \<open> Bernoulli Distribution \<close>
  1641 
  1642 lift_definition bernoulli_pmf :: "real \<Rightarrow> bool pmf" is
  1643   "\<lambda>p b. ((\<lambda>p. if b then p else 1 - p) \<circ> min 1 \<circ> max 0) p"
  1644   by (auto simp: nn_integral_count_space_finite[where A="{False, True}"] UNIV_bool
  1645            split: split_max split_min)
  1646 
  1647 lemma pmf_bernoulli_True[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) True = p"
  1648   by transfer simp
  1649 
  1650 lemma pmf_bernoulli_False[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) False = 1 - p"
  1651   by transfer simp
  1652 
  1653 lemma set_pmf_bernoulli[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (bernoulli_pmf p) = UNIV"
  1654   by (auto simp add: set_pmf_iff UNIV_bool)
  1655 
  1656 lemma nn_integral_bernoulli_pmf[simp]:
  1657   assumes [simp]: "0 \<le> p" "p \<le> 1" "\<And>x. 0 \<le> f x"
  1658   shows "(\<integral>\<^sup>+x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1659   by (subst nn_integral_measure_pmf_support[of UNIV])
  1660      (auto simp: UNIV_bool field_simps)
  1661 
  1662 lemma integral_bernoulli_pmf[simp]:
  1663   assumes [simp]: "0 \<le> p" "p \<le> 1"
  1664   shows "(\<integral>x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1665   by (subst integral_measure_pmf[of UNIV]) (auto simp: UNIV_bool)
  1666 
  1667 lemma pmf_bernoulli_half [simp]: "pmf (bernoulli_pmf (1 / 2)) x = 1 / 2"
  1668 by(cases x) simp_all
  1669 
  1670 lemma measure_pmf_bernoulli_half: "measure_pmf (bernoulli_pmf (1 / 2)) = uniform_count_measure UNIV"
  1671   by (rule measure_eqI)
  1672      (simp_all add: nn_integral_pmf[symmetric] emeasure_uniform_count_measure ennreal_divide_numeral[symmetric]
  1673                     nn_integral_count_space_finite sets_uniform_count_measure divide_ennreal_def mult_ac
  1674                     ennreal_of_nat_eq_real_of_nat)
  1675 
  1676 subsubsection \<open> Geometric Distribution \<close>
  1677 
  1678 context
  1679   fixes p :: real assumes p[arith]: "0 < p" "p \<le> 1"
  1680 begin
  1681 
  1682 lift_definition geometric_pmf :: "nat pmf" is "\<lambda>n. (1 - p)^n * p"
  1683 proof
  1684   have "(\<Sum>i. ennreal (p * (1 - p) ^ i)) = ennreal (p * (1 / (1 - (1 - p))))"
  1685     by (intro suminf_ennreal_eq sums_mult geometric_sums) auto
  1686   then show "(\<integral>\<^sup>+ x. ennreal ((1 - p)^x * p) \<partial>count_space UNIV) = 1"
  1687     by (simp add: nn_integral_count_space_nat field_simps)
  1688 qed simp
  1689 
  1690 lemma pmf_geometric[simp]: "pmf geometric_pmf n = (1 - p)^n * p"
  1691   by transfer rule
  1692 
  1693 end
  1694 
  1695 lemma set_pmf_geometric: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (geometric_pmf p) = UNIV"
  1696   by (auto simp: set_pmf_iff)
  1697 
  1698 subsubsection \<open> Uniform Multiset Distribution \<close>
  1699 
  1700 context
  1701   fixes M :: "'a multiset" assumes M_not_empty: "M \<noteq> {#}"
  1702 begin
  1703 
  1704 lift_definition pmf_of_multiset :: "'a pmf" is "\<lambda>x. count M x / size M"
  1705 proof
  1706   show "(\<integral>\<^sup>+ x. ennreal (real (count M x) / real (size M)) \<partial>count_space UNIV) = 1"
  1707     using M_not_empty
  1708     by (simp add: zero_less_divide_iff nn_integral_count_space nonempty_has_size
  1709                   sum_divide_distrib[symmetric])
  1710        (auto simp: size_multiset_overloaded_eq intro!: sum.cong)
  1711 qed simp
  1712 
  1713 lemma pmf_of_multiset[simp]: "pmf pmf_of_multiset x = count M x / size M"
  1714   by transfer rule
  1715 
  1716 lemma set_pmf_of_multiset[simp]: "set_pmf pmf_of_multiset = set_mset M"
  1717   by (auto simp: set_pmf_iff)
  1718 
  1719 end
  1720 
  1721 subsubsection \<open> Uniform Distribution \<close>
  1722 
  1723 context
  1724   fixes S :: "'a set" assumes S_not_empty: "S \<noteq> {}" and S_finite: "finite S"
  1725 begin
  1726 
  1727 lift_definition pmf_of_set :: "'a pmf" is "\<lambda>x. indicator S x / card S"
  1728 proof
  1729   show "(\<integral>\<^sup>+ x. ennreal (indicator S x / real (card S)) \<partial>count_space UNIV) = 1"
  1730     using S_not_empty S_finite
  1731     by (subst nn_integral_count_space'[of S])
  1732        (auto simp: ennreal_of_nat_eq_real_of_nat ennreal_mult[symmetric])
  1733 qed simp
  1734 
  1735 lemma pmf_of_set[simp]: "pmf pmf_of_set x = indicator S x / card S"
  1736   by transfer rule
  1737 
  1738 lemma set_pmf_of_set[simp]: "set_pmf pmf_of_set = S"
  1739   using S_finite S_not_empty by (auto simp: set_pmf_iff)
  1740 
  1741 lemma emeasure_pmf_of_set_space[simp]: "emeasure pmf_of_set S = 1"
  1742   by (rule measure_pmf.emeasure_eq_1_AE) (auto simp: AE_measure_pmf_iff)
  1743 
  1744 lemma nn_integral_pmf_of_set: "nn_integral (measure_pmf pmf_of_set) f = sum f S / card S"
  1745   by (subst nn_integral_measure_pmf_finite)
  1746      (simp_all add: sum_distrib_right[symmetric] card_gt_0_iff S_not_empty S_finite divide_ennreal_def
  1747                 divide_ennreal[symmetric] ennreal_of_nat_eq_real_of_nat[symmetric] ennreal_times_divide)
  1748 
  1749 lemma integral_pmf_of_set: "integral\<^sup>L (measure_pmf pmf_of_set) f = sum f S / card S"
  1750   by (subst integral_measure_pmf[of S]) (auto simp: S_finite sum_divide_distrib)
  1751 
  1752 lemma emeasure_pmf_of_set: "emeasure (measure_pmf pmf_of_set) A = card (S \<inter> A) / card S"
  1753   by (subst nn_integral_indicator[symmetric], simp)
  1754      (simp add: S_finite S_not_empty card_gt_0_iff indicator_def sum.If_cases divide_ennreal
  1755                 ennreal_of_nat_eq_real_of_nat nn_integral_pmf_of_set)
  1756 
  1757 lemma measure_pmf_of_set: "measure (measure_pmf pmf_of_set) A = card (S \<inter> A) / card S"
  1758   using emeasure_pmf_of_set[of A]
  1759   by (simp add: measure_nonneg measure_pmf.emeasure_eq_measure)
  1760 
  1761 end
  1762   
  1763 lemma pmf_expectation_bind_pmf_of_set:
  1764   fixes A :: "'a set" and f :: "'a \<Rightarrow> 'b pmf"
  1765     and  h :: "'b \<Rightarrow> 'c::{banach, second_countable_topology}"
  1766   assumes "A \<noteq> {}" "finite A" "\<And>x. x \<in> A \<Longrightarrow> finite (set_pmf (f x))"
  1767   shows "measure_pmf.expectation (pmf_of_set A \<bind> f) h =
  1768            (\<Sum>a\<in>A. measure_pmf.expectation (f a) h /\<^sub>R real (card A))"
  1769   using assms by (subst pmf_expectation_bind[of A]) (auto simp: divide_simps)
  1770 
  1771 lemma map_pmf_of_set:
  1772   assumes "finite A" "A \<noteq> {}"
  1773   shows   "map_pmf f (pmf_of_set A) = pmf_of_multiset (image_mset f (mset_set A))"
  1774     (is "?lhs = ?rhs")
  1775 proof (intro pmf_eqI)
  1776   fix x
  1777   from assms have "ennreal (pmf ?lhs x) = ennreal (pmf ?rhs x)"
  1778     by (subst ennreal_pmf_map)
  1779        (simp_all add: emeasure_pmf_of_set mset_set_empty_iff count_image_mset Int_commute)
  1780   thus "pmf ?lhs x = pmf ?rhs x" by simp
  1781 qed
  1782 
  1783 lemma pmf_bind_pmf_of_set:
  1784   assumes "A \<noteq> {}" "finite A"
  1785   shows   "pmf (bind_pmf (pmf_of_set A) f) x =
  1786              (\<Sum>xa\<in>A. pmf (f xa) x) / real_of_nat (card A)" (is "?lhs = ?rhs")
  1787 proof -
  1788   from assms have "card A > 0" by auto
  1789   with assms have "ennreal ?lhs = ennreal ?rhs"
  1790     by (subst ennreal_pmf_bind)
  1791        (simp_all add: nn_integral_pmf_of_set max_def pmf_nonneg divide_ennreal [symmetric]
  1792         sum_nonneg ennreal_of_nat_eq_real_of_nat)
  1793   thus ?thesis by (subst (asm) ennreal_inj) (auto intro!: sum_nonneg divide_nonneg_nonneg)
  1794 qed
  1795 
  1796 lemma pmf_of_set_singleton: "pmf_of_set {x} = return_pmf x"
  1797 by(rule pmf_eqI)(simp add: indicator_def)
  1798 
  1799 lemma map_pmf_of_set_inj:
  1800   assumes f: "inj_on f A"
  1801   and [simp]: "A \<noteq> {}" "finite A"
  1802   shows "map_pmf f (pmf_of_set A) = pmf_of_set (f ` A)" (is "?lhs = ?rhs")
  1803 proof(rule pmf_eqI)
  1804   fix i
  1805   show "pmf ?lhs i = pmf ?rhs i"
  1806   proof(cases "i \<in> f ` A")
  1807     case True
  1808     then obtain i' where "i = f i'" "i' \<in> A" by auto
  1809     thus ?thesis using f by(simp add: card_image pmf_map_inj)
  1810   next
  1811     case False
  1812     hence "pmf ?lhs i = 0" by(simp add: pmf_eq_0_set_pmf set_map_pmf)
  1813     moreover have "pmf ?rhs i = 0" using False by simp
  1814     ultimately show ?thesis by simp
  1815   qed
  1816 qed
  1817 
  1818 lemma map_pmf_of_set_bij_betw:
  1819   assumes "bij_betw f A B" "A \<noteq> {}" "finite A"
  1820   shows   "map_pmf f (pmf_of_set A) = pmf_of_set B"
  1821 proof -
  1822   have "map_pmf f (pmf_of_set A) = pmf_of_set (f ` A)"
  1823     by (intro map_pmf_of_set_inj assms bij_betw_imp_inj_on[OF assms(1)])
  1824   also from assms have "f ` A = B" by (simp add: bij_betw_def)
  1825   finally show ?thesis .
  1826 qed
  1827 
  1828 text \<open>
  1829   Choosing an element uniformly at random from the union of a disjoint family
  1830   of finite non-empty sets with the same size is the same as first choosing a set
  1831   from the family uniformly at random and then choosing an element from the chosen set
  1832   uniformly at random.
  1833 \<close>
  1834 lemma pmf_of_set_UN:
  1835   assumes "finite (UNION A f)" "A \<noteq> {}" "\<And>x. x \<in> A \<Longrightarrow> f x \<noteq> {}"
  1836           "\<And>x. x \<in> A \<Longrightarrow> card (f x) = n" "disjoint_family_on f A"
  1837   shows   "pmf_of_set (UNION A f) = do {x \<leftarrow> pmf_of_set A; pmf_of_set (f x)}"
  1838             (is "?lhs = ?rhs")
  1839 proof (intro pmf_eqI)
  1840   fix x
  1841   from assms have [simp]: "finite A"
  1842     using infinite_disjoint_family_imp_infinite_UNION[of A f] by blast
  1843   from assms have "ereal (pmf (pmf_of_set (UNION A f)) x) =
  1844     ereal (indicator (\<Union>x\<in>A. f x) x / real (card (\<Union>x\<in>A. f x)))"
  1845     by (subst pmf_of_set) auto
  1846   also from assms have "card (\<Union>x\<in>A. f x) = card A * n"
  1847     by (subst card_UN_disjoint) (auto simp: disjoint_family_on_def)
  1848   also from assms
  1849     have "indicator (\<Union>x\<in>A. f x) x / real \<dots> =
  1850               indicator (\<Union>x\<in>A. f x) x / (n * real (card A))"
  1851       by (simp add: sum_divide_distrib [symmetric] mult_ac)
  1852   also from assms have "indicator (\<Union>x\<in>A. f x) x = (\<Sum>y\<in>A. indicator (f y) x)"
  1853     by (intro indicator_UN_disjoint) simp_all
  1854   also from assms have "ereal ((\<Sum>y\<in>A. indicator (f y) x) / (real n * real (card A))) =
  1855                           ereal (pmf ?rhs x)"
  1856     by (subst pmf_bind_pmf_of_set) (simp_all add: sum_divide_distrib)
  1857   finally show "pmf ?lhs x = pmf ?rhs x" by simp
  1858 qed
  1859 
  1860 lemma bernoulli_pmf_half_conv_pmf_of_set: "bernoulli_pmf (1 / 2) = pmf_of_set UNIV"
  1861   by (rule pmf_eqI) simp_all
  1862 
  1863 subsubsection \<open> Poisson Distribution \<close>
  1864 
  1865 context
  1866   fixes rate :: real assumes rate_pos: "0 < rate"
  1867 begin
  1868 
  1869 lift_definition poisson_pmf :: "nat pmf" is "\<lambda>k. rate ^ k / fact k * exp (-rate)"
  1870 proof  (* by Manuel Eberl *)
  1871   have summable: "summable (\<lambda>x::nat. rate ^ x / fact x)" using summable_exp
  1872     by (simp add: field_simps divide_inverse [symmetric])
  1873   have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x * exp (-rate) \<partial>count_space UNIV) =
  1874           exp (-rate) * (\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV)"
  1875     by (simp add: field_simps nn_integral_cmult[symmetric] ennreal_mult'[symmetric])
  1876   also from rate_pos have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV) = (\<Sum>x. rate ^ x / fact x)"
  1877     by (simp_all add: nn_integral_count_space_nat suminf_ennreal summable ennreal_suminf_neq_top)
  1878   also have "... = exp rate" unfolding exp_def
  1879     by (simp add: field_simps divide_inverse [symmetric])
  1880   also have "ennreal (exp (-rate)) * ennreal (exp rate) = 1"
  1881     by (simp add: mult_exp_exp ennreal_mult[symmetric])
  1882   finally show "(\<integral>\<^sup>+ x. ennreal (rate ^ x / (fact x) * exp (- rate)) \<partial>count_space UNIV) = 1" .
  1883 qed (simp add: rate_pos[THEN less_imp_le])
  1884 
  1885 lemma pmf_poisson[simp]: "pmf poisson_pmf k = rate ^ k / fact k * exp (-rate)"
  1886   by transfer rule
  1887 
  1888 lemma set_pmf_poisson[simp]: "set_pmf poisson_pmf = UNIV"
  1889   using rate_pos by (auto simp: set_pmf_iff)
  1890 
  1891 end
  1892 
  1893 subsubsection \<open> Binomial Distribution \<close>
  1894 
  1895 context
  1896   fixes n :: nat and p :: real assumes p_nonneg: "0 \<le> p" and p_le_1: "p \<le> 1"
  1897 begin
  1898 
  1899 lift_definition binomial_pmf :: "nat pmf" is "\<lambda>k. (n choose k) * p^k * (1 - p)^(n - k)"
  1900 proof
  1901   have "(\<integral>\<^sup>+k. ennreal (real (n choose k) * p ^ k * (1 - p) ^ (n - k)) \<partial>count_space UNIV) =
  1902     ennreal (\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k))"
  1903     using p_le_1 p_nonneg by (subst nn_integral_count_space') auto
  1904   also have "(\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k)) = (p + (1 - p)) ^ n"
  1905     by (subst binomial_ring) (simp add: atLeast0AtMost)
  1906   finally show "(\<integral>\<^sup>+ x. ennreal (real (n choose x) * p ^ x * (1 - p) ^ (n - x)) \<partial>count_space UNIV) = 1"
  1907     by simp
  1908 qed (insert p_nonneg p_le_1, simp)
  1909 
  1910 lemma pmf_binomial[simp]: "pmf binomial_pmf k = (n choose k) * p^k * (1 - p)^(n - k)"
  1911   by transfer rule
  1912 
  1913 lemma set_pmf_binomial_eq: "set_pmf binomial_pmf = (if p = 0 then {0} else if p = 1 then {n} else {.. n})"
  1914   using p_nonneg p_le_1 unfolding set_eq_iff set_pmf_iff pmf_binomial by (auto simp: set_pmf_iff)
  1915 
  1916 end
  1917 
  1918 end
  1919 
  1920 lemma set_pmf_binomial_0[simp]: "set_pmf (binomial_pmf n 0) = {0}"
  1921   by (simp add: set_pmf_binomial_eq)
  1922 
  1923 lemma set_pmf_binomial_1[simp]: "set_pmf (binomial_pmf n 1) = {n}"
  1924   by (simp add: set_pmf_binomial_eq)
  1925 
  1926 lemma set_pmf_binomial[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (binomial_pmf n p) = {..n}"
  1927   by (simp add: set_pmf_binomial_eq)
  1928 
  1929 context includes lifting_syntax
  1930 begin
  1931 
  1932 lemma bind_pmf_parametric [transfer_rule]:
  1933   "(rel_pmf A ===> (A ===> rel_pmf B) ===> rel_pmf B) bind_pmf bind_pmf"
  1934 by(blast intro: rel_pmf_bindI dest: rel_funD)
  1935 
  1936 lemma return_pmf_parametric [transfer_rule]: "(A ===> rel_pmf A) return_pmf return_pmf"
  1937 by(rule rel_funI) simp
  1938 
  1939 end
  1940 
  1941 
  1942 primrec replicate_pmf :: "nat \<Rightarrow> 'a pmf \<Rightarrow> 'a list pmf" where
  1943   "replicate_pmf 0 _ = return_pmf []"
  1944 | "replicate_pmf (Suc n) p = do {x \<leftarrow> p; xs \<leftarrow> replicate_pmf n p; return_pmf (x#xs)}"
  1945 
  1946 lemma replicate_pmf_1: "replicate_pmf 1 p = map_pmf (\<lambda>x. [x]) p"
  1947   by (simp add: map_pmf_def bind_return_pmf)
  1948 
  1949 lemma set_replicate_pmf:
  1950   "set_pmf (replicate_pmf n p) = {xs\<in>lists (set_pmf p). length xs = n}"
  1951   by (induction n) (auto simp: length_Suc_conv)
  1952 
  1953 lemma replicate_pmf_distrib:
  1954   "replicate_pmf (m + n) p =
  1955      do {xs \<leftarrow> replicate_pmf m p; ys \<leftarrow> replicate_pmf n p; return_pmf (xs @ ys)}"
  1956   by (induction m) (simp_all add: bind_return_pmf bind_return_pmf' bind_assoc_pmf)
  1957 
  1958 lemma power_diff':
  1959   assumes "b \<le> a"
  1960   shows   "x ^ (a - b) = (if x = 0 \<and> a = b then 1 else x ^ a / (x::'a::field) ^ b)"
  1961 proof (cases "x = 0")
  1962   case True
  1963   with assms show ?thesis by (cases "a - b") simp_all
  1964 qed (insert assms, simp_all add: power_diff)
  1965 
  1966 
  1967 lemma binomial_pmf_Suc:
  1968   assumes "p \<in> {0..1}"
  1969   shows   "binomial_pmf (Suc n) p =
  1970              do {b \<leftarrow> bernoulli_pmf p;
  1971                  k \<leftarrow> binomial_pmf n p;
  1972                  return_pmf ((if b then 1 else 0) + k)}" (is "_ = ?rhs")
  1973 proof (intro pmf_eqI)
  1974   fix k
  1975   have A: "indicator {Suc a} (Suc b) = indicator {a} b" for a b
  1976     by (simp add: indicator_def)
  1977   show "pmf (binomial_pmf (Suc n) p) k = pmf ?rhs k"
  1978     by (cases k; cases "k > n")
  1979        (insert assms, auto simp: pmf_bind measure_pmf_single A divide_simps algebra_simps
  1980           not_less less_eq_Suc_le [symmetric] power_diff')
  1981 qed
  1982 
  1983 lemma binomial_pmf_0: "p \<in> {0..1} \<Longrightarrow> binomial_pmf 0 p = return_pmf 0"
  1984   by (rule pmf_eqI) (simp_all add: indicator_def)
  1985 
  1986 lemma binomial_pmf_altdef:
  1987   assumes "p \<in> {0..1}"
  1988   shows   "binomial_pmf n p = map_pmf (length \<circ> filter id) (replicate_pmf n (bernoulli_pmf p))"
  1989   by (induction n)
  1990      (insert assms, auto simp: binomial_pmf_Suc map_pmf_def bind_return_pmf bind_assoc_pmf
  1991         bind_return_pmf' binomial_pmf_0 intro!: bind_pmf_cong)
  1992 
  1993 
  1994 subsection \<open>PMFs from assiciation lists\<close>
  1995 
  1996 definition pmf_of_list ::" ('a \<times> real) list \<Rightarrow> 'a pmf" where
  1997   "pmf_of_list xs = embed_pmf (\<lambda>x. sum_list (map snd (filter (\<lambda>z. fst z = x) xs)))"
  1998 
  1999 definition pmf_of_list_wf where
  2000   "pmf_of_list_wf xs \<longleftrightarrow> (\<forall>x\<in>set (map snd xs) . x \<ge> 0) \<and> sum_list (map snd xs) = 1"
  2001 
  2002 lemma pmf_of_list_wfI:
  2003   "(\<And>x. x \<in> set (map snd xs) \<Longrightarrow> x \<ge> 0) \<Longrightarrow> sum_list (map snd xs) = 1 \<Longrightarrow> pmf_of_list_wf xs"
  2004   unfolding pmf_of_list_wf_def by simp
  2005 
  2006 context
  2007 begin
  2008 
  2009 private lemma pmf_of_list_aux:
  2010   assumes "\<And>x. x \<in> set (map snd xs) \<Longrightarrow> x \<ge> 0"
  2011   assumes "sum_list (map snd xs) = 1"
  2012   shows "(\<integral>\<^sup>+ x. ennreal (sum_list (map snd [z\<leftarrow>xs . fst z = x])) \<partial>count_space UNIV) = 1"
  2013 proof -
  2014   have "(\<integral>\<^sup>+ x. ennreal (sum_list (map snd (filter (\<lambda>z. fst z = x) xs))) \<partial>count_space UNIV) =
  2015             (\<integral>\<^sup>+ x. ennreal (sum_list (map (\<lambda>(x',p). indicator {x'} x * p) xs)) \<partial>count_space UNIV)"
  2016     by (intro nn_integral_cong ennreal_cong, subst sum_list_map_filter') (auto intro: sum_list_cong)
  2017   also have "\<dots> = (\<Sum>(x',p)\<leftarrow>xs. (\<integral>\<^sup>+ x. ennreal (indicator {x'} x * p) \<partial>count_space UNIV))"
  2018     using assms(1)
  2019   proof (induction xs)
  2020     case (Cons x xs)
  2021     from Cons.prems have "snd x \<ge> 0" by simp
  2022     moreover have "b \<ge> 0" if "(a,b) \<in> set xs" for a b
  2023       using Cons.prems[of b] that by force
  2024     ultimately have "(\<integral>\<^sup>+ y. ennreal (\<Sum>(x', p)\<leftarrow>x # xs. indicator {x'} y * p) \<partial>count_space UNIV) =
  2025             (\<integral>\<^sup>+ y. ennreal (indicator {fst x} y * snd x) +
  2026             ennreal (\<Sum>(x', p)\<leftarrow>xs. indicator {x'} y * p) \<partial>count_space UNIV)"
  2027       by (intro nn_integral_cong, subst ennreal_plus [symmetric])
  2028          (auto simp: case_prod_unfold indicator_def intro!: sum_list_nonneg)
  2029     also have "\<dots> = (\<integral>\<^sup>+ y. ennreal (indicator {fst x} y * snd x) \<partial>count_space UNIV) +
  2030                       (\<integral>\<^sup>+ y. ennreal (\<Sum>(x', p)\<leftarrow>xs. indicator {x'} y * p) \<partial>count_space UNIV)"
  2031       by (intro nn_integral_add)
  2032          (force intro!: sum_list_nonneg AE_I2 intro: Cons simp: indicator_def)+
  2033     also have "(\<integral>\<^sup>+ y. ennreal (\<Sum>(x', p)\<leftarrow>xs. indicator {x'} y * p) \<partial>count_space UNIV) =
  2034                (\<Sum>(x', p)\<leftarrow>xs. (\<integral>\<^sup>+ y. ennreal (indicator {x'} y * p) \<partial>count_space UNIV))"
  2035       using Cons(1) by (intro Cons) simp_all
  2036     finally show ?case by (simp add: case_prod_unfold)
  2037   qed simp
  2038   also have "\<dots> = (\<Sum>(x',p)\<leftarrow>xs. ennreal p * (\<integral>\<^sup>+ x. indicator {x'} x \<partial>count_space UNIV))"
  2039     using assms(1)
  2040     by (intro sum_list_cong, simp only: case_prod_unfold, subst nn_integral_cmult [symmetric])
  2041        (auto intro!: assms(1) simp: max_def times_ereal.simps [symmetric] mult_ac ereal_indicator
  2042              simp del: times_ereal.simps)+
  2043   also from assms have "\<dots> = sum_list (map snd xs)" by (simp add: case_prod_unfold sum_list_ennreal)
  2044   also have "\<dots> = 1" using assms(2) by simp
  2045   finally show ?thesis .
  2046 qed
  2047 
  2048 lemma pmf_pmf_of_list:
  2049   assumes "pmf_of_list_wf xs"
  2050   shows   "pmf (pmf_of_list xs) x = sum_list (map snd (filter (\<lambda>z. fst z = x) xs))"
  2051   using assms pmf_of_list_aux[of xs] unfolding pmf_of_list_def pmf_of_list_wf_def
  2052   by (subst pmf_embed_pmf) (auto intro!: sum_list_nonneg)
  2053 
  2054 end
  2055 
  2056 lemma set_pmf_of_list:
  2057   assumes "pmf_of_list_wf xs"
  2058   shows   "set_pmf (pmf_of_list xs) \<subseteq> set (map fst xs)"
  2059 proof clarify
  2060   fix x assume A: "x \<in> set_pmf (pmf_of_list xs)"
  2061   show "x \<in> set (map fst xs)"
  2062   proof (rule ccontr)
  2063     assume "x \<notin> set (map fst xs)"
  2064     hence "[z\<leftarrow>xs . fst z = x] = []" by (auto simp: filter_empty_conv)
  2065     with A assms show False by (simp add: pmf_pmf_of_list set_pmf_eq)
  2066   qed
  2067 qed
  2068 
  2069 lemma finite_set_pmf_of_list:
  2070   assumes "pmf_of_list_wf xs"
  2071   shows   "finite (set_pmf (pmf_of_list xs))"
  2072   using assms by (rule finite_subset[OF set_pmf_of_list]) simp_all
  2073 
  2074 lemma emeasure_Int_set_pmf:
  2075   "emeasure (measure_pmf p) (A \<inter> set_pmf p) = emeasure (measure_pmf p) A"
  2076   by (rule emeasure_eq_AE) (auto simp: AE_measure_pmf_iff)
  2077 
  2078 lemma measure_Int_set_pmf:
  2079   "measure (measure_pmf p) (A \<inter> set_pmf p) = measure (measure_pmf p) A"
  2080   using emeasure_Int_set_pmf[of p A] by (simp add: Sigma_Algebra.measure_def)
  2081 
  2082 lemma emeasure_pmf_of_list:
  2083   assumes "pmf_of_list_wf xs"
  2084   shows   "emeasure (pmf_of_list xs) A = ennreal (sum_list (map snd (filter (\<lambda>x. fst x \<in> A) xs)))"
  2085 proof -
  2086   have "emeasure (pmf_of_list xs) A = nn_integral (measure_pmf (pmf_of_list xs)) (indicator A)"
  2087     by simp
  2088   also from assms
  2089     have "\<dots> = (\<Sum>x\<in>set_pmf (pmf_of_list xs) \<inter> A. ennreal (sum_list (map snd [z\<leftarrow>xs . fst z = x])))"
  2090     by (subst nn_integral_measure_pmf_finite) (simp_all add: finite_set_pmf_of_list pmf_pmf_of_list Int_def)
  2091   also from assms
  2092     have "\<dots> = ennreal (\<Sum>x\<in>set_pmf (pmf_of_list xs) \<inter> A. sum_list (map snd [z\<leftarrow>xs . fst z = x]))"
  2093     by (subst sum_ennreal) (auto simp: pmf_of_list_wf_def intro!: sum_list_nonneg)
  2094   also have "\<dots> = ennreal (\<Sum>x\<in>set_pmf (pmf_of_list xs) \<inter> A.
  2095       indicator A x * pmf (pmf_of_list xs) x)" (is "_ = ennreal ?S")
  2096     using assms by (intro ennreal_cong sum.cong) (auto simp: pmf_pmf_of_list)
  2097   also have "?S = (\<Sum>x\<in>set_pmf (pmf_of_list xs). indicator A x * pmf (pmf_of_list xs) x)"
  2098     using assms by (intro sum.mono_neutral_left set_pmf_of_list finite_set_pmf_of_list) auto
  2099   also have "\<dots> = (\<Sum>x\<in>set (map fst xs). indicator A x * pmf (pmf_of_list xs) x)"
  2100     using assms by (intro sum.mono_neutral_left set_pmf_of_list) (auto simp: set_pmf_eq)
  2101   also have "\<dots> = (\<Sum>x\<in>set (map fst xs). indicator A x *
  2102                       sum_list (map snd (filter (\<lambda>z. fst z = x) xs)))"
  2103     using assms by (simp add: pmf_pmf_of_list)
  2104   also have "\<dots> = (\<Sum>x\<in>set (map fst xs). sum_list (map snd (filter (\<lambda>z. fst z = x \<and> x \<in> A) xs)))"
  2105     by (intro sum.cong) (auto simp: indicator_def)
  2106   also have "\<dots> = (\<Sum>x\<in>set (map fst xs). (\<Sum>xa = 0..<length xs.
  2107                      if fst (xs ! xa) = x \<and> x \<in> A then snd (xs ! xa) else 0))"
  2108     by (intro sum.cong refl, subst sum_list_map_filter', subst sum_list_sum_nth) simp
  2109   also have "\<dots> = (\<Sum>xa = 0..<length xs. (\<Sum>x\<in>set (map fst xs).
  2110                      if fst (xs ! xa) = x \<and> x \<in> A then snd (xs ! xa) else 0))"
  2111     by (rule sum.commute)
  2112   also have "\<dots> = (\<Sum>xa = 0..<length xs. if fst (xs ! xa) \<in> A then
  2113                      (\<Sum>x\<in>set (map fst xs). if x = fst (xs ! xa) then snd (xs ! xa) else 0) else 0)"
  2114     by (auto intro!: sum.cong sum.neutral)
  2115   also have "\<dots> = (\<Sum>xa = 0..<length xs. if fst (xs ! xa) \<in> A then snd (xs ! xa) else 0)"
  2116     by (intro sum.cong refl) (simp_all add: sum.delta)
  2117   also have "\<dots> = sum_list (map snd (filter (\<lambda>x. fst x \<in> A) xs))"
  2118     by (subst sum_list_map_filter', subst sum_list_sum_nth) simp_all
  2119   finally show ?thesis .
  2120 qed
  2121 
  2122 lemma measure_pmf_of_list:
  2123   assumes "pmf_of_list_wf xs"
  2124   shows   "measure (pmf_of_list xs) A = sum_list (map snd (filter (\<lambda>x. fst x \<in> A) xs))"
  2125   using assms unfolding pmf_of_list_wf_def Sigma_Algebra.measure_def
  2126   by (subst emeasure_pmf_of_list [OF assms], subst enn2real_ennreal) (auto intro!: sum_list_nonneg)
  2127 
  2128 (* TODO Move? *)
  2129 lemma sum_list_nonneg_eq_zero_iff:
  2130   fixes xs :: "'a :: linordered_ab_group_add list"
  2131   shows "(\<And>x. x \<in> set xs \<Longrightarrow> x \<ge> 0) \<Longrightarrow> sum_list xs = 0 \<longleftrightarrow> set xs \<subseteq> {0}"
  2132 proof (induction xs)
  2133   case (Cons x xs)
  2134   from Cons.prems have "sum_list (x#xs) = 0 \<longleftrightarrow> x = 0 \<and> sum_list xs = 0"
  2135     unfolding sum_list_simps by (subst add_nonneg_eq_0_iff) (auto intro: sum_list_nonneg)
  2136   with Cons.IH Cons.prems show ?case by simp
  2137 qed simp_all
  2138 
  2139 lemma sum_list_filter_nonzero:
  2140   "sum_list (filter (\<lambda>x. x \<noteq> 0) xs) = sum_list xs"
  2141   by (induction xs) simp_all
  2142 (* END MOVE *)
  2143 
  2144 lemma set_pmf_of_list_eq:
  2145   assumes "pmf_of_list_wf xs" "\<And>x. x \<in> snd ` set xs \<Longrightarrow> x > 0"
  2146   shows   "set_pmf (pmf_of_list xs) = fst ` set xs"
  2147 proof
  2148   {
  2149     fix x assume A: "x \<in> fst ` set xs" and B: "x \<notin> set_pmf (pmf_of_list xs)"
  2150     then obtain y where y: "(x, y) \<in> set xs" by auto
  2151     from B have "sum_list (map snd [z\<leftarrow>xs. fst z = x]) = 0"
  2152       by (simp add: pmf_pmf_of_list[OF assms(1)] set_pmf_eq)
  2153     moreover from y have "y \<in> snd ` {xa \<in> set xs. fst xa = x}" by force
  2154     ultimately have "y = 0" using assms(1)
  2155       by (subst (asm) sum_list_nonneg_eq_zero_iff) (auto simp: pmf_of_list_wf_def)
  2156     with assms(2) y have False by force
  2157   }
  2158   thus "fst ` set xs \<subseteq> set_pmf (pmf_of_list xs)" by blast
  2159 qed (insert set_pmf_of_list[OF assms(1)], simp_all)
  2160 
  2161 lemma pmf_of_list_remove_zeros:
  2162   assumes "pmf_of_list_wf xs"
  2163   defines "xs' \<equiv> filter (\<lambda>z. snd z \<noteq> 0) xs"
  2164   shows   "pmf_of_list_wf xs'" "pmf_of_list xs' = pmf_of_list xs"
  2165 proof -
  2166   have "map snd [z\<leftarrow>xs . snd z \<noteq> 0] = filter (\<lambda>x. x \<noteq> 0) (map snd xs)"
  2167     by (induction xs) simp_all
  2168   with assms(1) show wf: "pmf_of_list_wf xs'"
  2169     by (auto simp: pmf_of_list_wf_def xs'_def sum_list_filter_nonzero)
  2170   have "sum_list (map snd [z\<leftarrow>xs' . fst z = i]) = sum_list (map snd [z\<leftarrow>xs . fst z = i])" for i
  2171     unfolding xs'_def by (induction xs) simp_all
  2172   with assms(1) wf show "pmf_of_list xs' = pmf_of_list xs"
  2173     by (intro pmf_eqI) (simp_all add: pmf_pmf_of_list)
  2174 qed
  2175 
  2176 end