src/Pure/Isar/class_target.ML
author haftmann
Tue Apr 28 13:34:48 2009 +0200 (2009-04-28)
changeset 31012 751f5aa3e315
parent 30764 3e3e7aa0cc7a
child 31210 d6681ddc046c
permissions -rw-r--r--
prevent potential failure
     1 (*  Title:      Pure/Isar/class_target.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Type classes derived from primitive axclasses and locales - mechanisms.
     5 *)
     6 
     7 signature CLASS_TARGET =
     8 sig
     9   (*classes*)
    10   val register: class -> class list -> ((string * typ) * (string * typ)) list
    11     -> sort -> morphism -> thm option -> thm option -> thm
    12     -> theory -> theory
    13   val register_subclass: class * class -> morphism option -> Element.witness option
    14     -> morphism -> theory -> theory
    15 
    16   val is_class: theory -> class -> bool
    17   val base_sort: theory -> class -> sort
    18   val rules: theory -> class -> thm option * thm
    19   val these_params: theory -> sort -> (string * (class * (string * typ))) list
    20   val these_defs: theory -> sort -> thm list
    21   val these_operations: theory -> sort -> (string * (class * (typ * term))) list
    22   val print_classes: theory -> unit
    23 
    24   val begin: class list -> sort -> Proof.context -> Proof.context
    25   val init: class -> theory -> Proof.context
    26   val declare: class -> Properties.T
    27     -> (binding * mixfix) * term -> theory -> theory
    28   val abbrev: class -> Syntax.mode -> Properties.T
    29     -> (binding * mixfix) * term -> theory -> theory
    30   val class_prefix: string -> string
    31   val refresh_syntax: class -> Proof.context -> Proof.context
    32   val redeclare_operations: theory -> sort -> Proof.context -> Proof.context
    33 
    34   (*instances*)
    35   val init_instantiation: string list * (string * sort) list * sort
    36     -> theory -> local_theory
    37   val instantiation_instance: (local_theory -> local_theory)
    38     -> local_theory -> Proof.state
    39   val prove_instantiation_instance: (Proof.context -> tactic)
    40     -> local_theory -> local_theory
    41   val prove_instantiation_exit: (Proof.context -> tactic)
    42     -> local_theory -> theory
    43   val prove_instantiation_exit_result: (morphism -> 'a -> 'b)
    44     -> (Proof.context -> 'b -> tactic) -> 'a -> local_theory -> 'b * theory
    45   val conclude_instantiation: local_theory -> local_theory
    46   val instantiation_param: local_theory -> binding -> string option
    47   val confirm_declaration: binding -> local_theory -> local_theory
    48   val pretty_instantiation: local_theory -> Pretty.T
    49   val type_name: string -> string
    50 
    51   val intro_classes_tac: thm list -> tactic
    52   val default_intro_tac: Proof.context -> thm list -> tactic
    53 
    54   (*old axclass layer*)
    55   val axclass_cmd: binding * xstring list
    56     -> (Attrib.binding * string list) list
    57     -> theory -> class * theory
    58   val classrel_cmd: xstring * xstring -> theory -> Proof.state
    59   val instance_arity: (theory -> theory) -> arity -> theory -> Proof.state
    60   val instance_arity_cmd: xstring * xstring list * xstring -> theory -> Proof.state
    61 end;
    62 
    63 structure Class_Target : CLASS_TARGET =
    64 struct
    65 
    66 (** primitive axclass and instance commands **)
    67 
    68 fun axclass_cmd (class, raw_superclasses) raw_specs thy =
    69   let
    70     val ctxt = ProofContext.init thy;
    71     val superclasses = map (Sign.read_class thy) raw_superclasses;
    72     val name_atts = map ((apsnd o map) (Attrib.attribute thy) o fst)
    73       raw_specs;
    74     val axiomss = ProofContext.read_propp (ctxt, map (map (rpair []) o snd)
    75           raw_specs)
    76       |> snd
    77       |> (map o map) fst;
    78   in
    79     AxClass.define_class (class, superclasses) []
    80       (name_atts ~~ axiomss) thy
    81   end;
    82 
    83 local
    84 
    85 fun gen_instance mk_prop add_thm after_qed insts thy =
    86   let
    87     fun after_qed' results =
    88       ProofContext.theory ((fold o fold) add_thm results #> after_qed);
    89   in
    90     thy
    91     |> ProofContext.init
    92     |> Proof.theorem_i NONE after_qed' ((map (fn t => [(t, [])])
    93         o mk_prop thy) insts)
    94   end;
    95 
    96 in
    97 
    98 val instance_arity =
    99   gen_instance (Logic.mk_arities oo Sign.cert_arity) AxClass.add_arity;
   100 val instance_arity_cmd =
   101   gen_instance (Logic.mk_arities oo Sign.read_arity) AxClass.add_arity I;
   102 val classrel =
   103   gen_instance (single oo (Logic.mk_classrel oo AxClass.cert_classrel)) AxClass.add_classrel I;
   104 val classrel_cmd =
   105   gen_instance (single oo (Logic.mk_classrel oo AxClass.read_classrel)) AxClass.add_classrel I;
   106 
   107 end; (*local*)
   108 
   109 
   110 (** class data **)
   111 
   112 datatype class_data = ClassData of {
   113 
   114   (* static part *)
   115   consts: (string * string) list
   116     (*locale parameter ~> constant name*),
   117   base_sort: sort,
   118   base_morph: morphism
   119     (*static part of canonical morphism*),
   120   assm_intro: thm option,
   121   of_class: thm,
   122   axiom: thm option,
   123   
   124   (* dynamic part *)
   125   defs: thm list,
   126   operations: (string * (class * (typ * term))) list
   127 
   128 };
   129 
   130 fun rep_class_data (ClassData data) = data;
   131 fun mk_class_data ((consts, base_sort, base_morph, assm_intro, of_class, axiom),
   132     (defs, operations)) =
   133   ClassData { consts = consts, base_sort = base_sort,
   134     base_morph = base_morph, assm_intro = assm_intro, of_class = of_class, axiom = axiom,
   135     defs = defs, operations = operations };
   136 fun map_class_data f (ClassData { consts, base_sort, base_morph, assm_intro,
   137     of_class, axiom, defs, operations }) =
   138   mk_class_data (f ((consts, base_sort, base_morph, assm_intro, of_class, axiom),
   139     (defs, operations)));
   140 fun merge_class_data _ (ClassData { consts = consts,
   141     base_sort = base_sort, base_morph = base_morph, assm_intro = assm_intro,
   142     of_class = of_class, axiom = axiom, defs = defs1, operations = operations1 },
   143   ClassData { consts = _, base_sort = _, base_morph = _, assm_intro = _,
   144     of_class = _, axiom = _, defs = defs2, operations = operations2 }) =
   145   mk_class_data ((consts, base_sort, base_morph, assm_intro, of_class, axiom),
   146     (Thm.merge_thms (defs1, defs2),
   147       AList.merge (op =) (K true) (operations1, operations2)));
   148 
   149 structure ClassData = TheoryDataFun
   150 (
   151   type T = class_data Graph.T
   152   val empty = Graph.empty;
   153   val copy = I;
   154   val extend = I;
   155   fun merge _ = Graph.join merge_class_data;
   156 );
   157 
   158 
   159 (* queries *)
   160 
   161 val lookup_class_data = Option.map rep_class_data oo try o Graph.get_node o ClassData.get;
   162 
   163 fun the_class_data thy class = case lookup_class_data thy class
   164  of NONE => error ("Undeclared class " ^ quote class)
   165   | SOME data => data;
   166 
   167 val is_class = is_some oo lookup_class_data;
   168 
   169 val ancestry = Graph.all_succs o ClassData.get;
   170 val heritage = Graph.all_preds o ClassData.get;
   171 
   172 fun these_params thy =
   173   let
   174     fun params class =
   175       let
   176         val const_typs = (#params o AxClass.get_info thy) class;
   177         val const_names = (#consts o the_class_data thy) class;
   178       in
   179         (map o apsnd)
   180           (fn c => (class, (c, (the o AList.lookup (op =) const_typs) c))) const_names
   181       end;
   182   in maps params o ancestry thy end;
   183 
   184 val base_sort = #base_sort oo the_class_data;
   185 
   186 fun rules thy class =
   187   let val { axiom, of_class, ... } = the_class_data thy class
   188   in (axiom, of_class) end;
   189 
   190 fun all_assm_intros thy =
   191   Graph.fold (fn (_, (data, _)) => fold (insert Thm.eq_thm)
   192     ((the_list o #assm_intro o rep_class_data) data)) (ClassData.get thy) [];
   193 
   194 fun these_defs thy = maps (#defs o the_class_data thy) o ancestry thy;
   195 fun these_operations thy = maps (#operations o the_class_data thy) o ancestry thy;
   196 
   197 val base_morphism = #base_morph oo the_class_data;
   198 fun morphism thy class = base_morphism thy class
   199   $> Element.eq_morphism thy (these_defs thy [class]);
   200 
   201 fun print_classes thy =
   202   let
   203     val ctxt = ProofContext.init thy;
   204     val algebra = Sign.classes_of thy;
   205     val arities =
   206       Symtab.empty
   207       |> Symtab.fold (fn (tyco, arities) => fold (fn (class, _) =>
   208            Symtab.map_default (class, []) (insert (op =) tyco)) arities)
   209              ((#arities o Sorts.rep_algebra) algebra);
   210     val the_arities = these o Symtab.lookup arities;
   211     fun mk_arity class tyco =
   212       let
   213         val Ss = Sorts.mg_domain algebra tyco [class];
   214       in Syntax.pretty_arity ctxt (tyco, Ss, [class]) end;
   215     fun mk_param (c, ty) = Pretty.str (Sign.extern_const thy c ^ " :: "
   216       ^ setmp show_sorts false (Syntax.string_of_typ ctxt o Type.strip_sorts) ty);
   217     fun mk_entry class = (Pretty.block o Pretty.fbreaks o map_filter I) [
   218       (SOME o Pretty.str) ("class " ^ Sign.extern_class thy class ^ ":"),
   219       (SOME o Pretty.block) [Pretty.str "supersort: ",
   220         (Syntax.pretty_sort ctxt o Sign.minimize_sort thy o Sign.super_classes thy) class],
   221       ((fn [] => NONE | ps => (SOME o Pretty.block o Pretty.fbreaks)
   222           (Pretty.str "parameters:" :: ps)) o map mk_param
   223         o these o Option.map #params o try (AxClass.get_info thy)) class,
   224       (SOME o Pretty.block o Pretty.breaks) [
   225         Pretty.str "instances:",
   226         Pretty.list "" "" (map (mk_arity class) (the_arities class))
   227       ]
   228     ]
   229   in
   230     (Pretty.writeln o Pretty.chunks o separate (Pretty.str "")
   231       o map mk_entry o Sorts.all_classes) algebra
   232   end;
   233 
   234 
   235 (* updaters *)
   236 
   237 fun register class sups params base_sort morph
   238     axiom assm_intro of_class thy =
   239   let
   240     val operations = map (fn (v_ty as (_, ty), (c, _)) =>
   241       (c, (class, (ty, Free v_ty)))) params;
   242     val add_class = Graph.new_node (class,
   243         mk_class_data (((map o pairself) fst params, base_sort,
   244           morph, assm_intro, of_class, axiom), ([], operations)))
   245       #> fold (curry Graph.add_edge class) sups;
   246   in ClassData.map add_class thy end;
   247 
   248 fun activate_defs class thms thy =
   249   let
   250     val eq_morph = Element.eq_morphism thy thms;
   251     fun amend cls thy = Locale.amend_registration eq_morph
   252       (cls, morphism thy cls) thy;
   253   in fold amend (heritage thy [class]) thy end;
   254 
   255 fun register_operation class (c, (t, some_def)) thy =
   256   let
   257     val base_sort = base_sort thy class;
   258     val prep_typ = map_type_tfree
   259       (fn (v, sort) => if Name.aT = v
   260         then TFree (v, base_sort) else TVar ((v, 0), sort));
   261     val t' = map_types prep_typ t;
   262     val ty' = Term.fastype_of t';
   263   in
   264     thy
   265     |> (ClassData.map o Graph.map_node class o map_class_data o apsnd)
   266       (fn (defs, operations) =>
   267         (fold cons (the_list some_def) defs,
   268           (c, (class, (ty', t'))) :: operations))
   269     |> is_some some_def ? activate_defs class (the_list some_def)
   270   end;
   271 
   272 fun register_subclass (sub, sup) some_dep_morph some_wit export thy =
   273   let
   274     val intros = (snd o rules thy) sup :: map_filter I
   275       [Option.map (Drule.standard' o Element.conclude_witness) some_wit,
   276         (fst o rules thy) sub];
   277     val tac = EVERY (map (TRYALL o Tactic.rtac) intros);
   278     val classrel = Goal.prove_global thy [] [] (Logic.mk_classrel (sub, sup))
   279       (K tac);
   280     val diff_sort = Sign.complete_sort thy [sup]
   281       |> subtract (op =) (Sign.complete_sort thy [sub])
   282       |> filter (is_class thy);
   283   in
   284     thy
   285     |> AxClass.add_classrel classrel
   286     |> ClassData.map (Graph.add_edge (sub, sup))
   287     |> activate_defs sub (these_defs thy diff_sort)
   288     |> fold (fn dep_morph => Locale.add_dependency sub (sup,
   289         dep_morph $> Element.satisfy_morphism (the_list some_wit) $> export))
   290           (the_list some_dep_morph)
   291     |> (fn thy => fold_rev (Context.theory_map o Locale.activate_facts)
   292         (Locale.get_registrations thy) thy)
   293   end;
   294 
   295 
   296 (** classes and class target **)
   297 
   298 (* class context syntax *)
   299 
   300 fun these_unchecks thy =
   301   map (fn (c, (_, (ty, t))) => (t, Const (c, ty))) o these_operations thy;
   302 
   303 fun redeclare_const thy c =
   304   let val b = Long_Name.base_name c
   305   in Sign.intern_const thy b = c ? Variable.declare_const (b, c) end;
   306 
   307 fun synchronize_class_syntax sort base_sort ctxt =
   308   let
   309     val thy = ProofContext.theory_of ctxt;
   310     val algebra = Sign.classes_of thy;
   311     val operations = these_operations thy sort;
   312     fun subst_class_typ sort = map_type_tfree (K (TVar ((Name.aT, 0), sort)));
   313     val primary_constraints =
   314       (map o apsnd) (subst_class_typ base_sort o fst o snd) operations;
   315     val secondary_constraints =
   316       (map o apsnd) (fn (class, (ty, _)) => subst_class_typ [class] ty) operations;
   317     fun improve (c, ty) = (case AList.lookup (op =) primary_constraints c
   318      of SOME ty' => (case try (Type.raw_match (ty', ty)) Vartab.empty
   319          of SOME tyenv => (case Vartab.lookup tyenv (Name.aT, 0)
   320              of SOME (_, ty' as TVar (tvar as (vi, sort))) =>
   321                   if TypeInfer.is_param vi
   322                     andalso Sorts.sort_le algebra (base_sort, sort)
   323                       then SOME (ty', TFree (Name.aT, base_sort))
   324                       else NONE
   325               | _ => NONE)
   326           | NONE => NONE)
   327       | NONE => NONE)
   328     fun subst (c, ty) = Option.map snd (AList.lookup (op =) operations c);
   329     val unchecks = these_unchecks thy sort;
   330   in
   331     ctxt
   332     |> fold (redeclare_const thy o fst) primary_constraints
   333     |> Overloading.map_improvable_syntax (K (((primary_constraints, secondary_constraints),
   334         (((improve, subst), true), unchecks)), false))
   335     |> Overloading.set_primary_constraints
   336   end;
   337 
   338 fun refresh_syntax class ctxt =
   339   let
   340     val thy = ProofContext.theory_of ctxt;
   341     val base_sort = base_sort thy class;
   342   in synchronize_class_syntax [class] base_sort ctxt end;
   343 
   344 fun redeclare_operations thy sort =
   345   fold (redeclare_const thy o fst) (these_operations thy sort);
   346 
   347 fun begin sort base_sort ctxt =
   348   ctxt
   349   |> Variable.declare_term
   350       (Logic.mk_type (TFree (Name.aT, base_sort)))
   351   |> synchronize_class_syntax sort base_sort
   352   |> Overloading.add_improvable_syntax;
   353 
   354 fun init class thy =
   355   thy
   356   |> Locale.init class
   357   |> begin [class] (base_sort thy class);
   358 
   359 
   360 (* class target *)
   361 
   362 val class_prefix = Logic.const_of_class o Long_Name.base_name;
   363 
   364 fun declare class pos ((c, mx), dict) thy =
   365   let
   366     val morph = morphism thy class;
   367     val b = Morphism.binding morph c;
   368     val b_def = Morphism.binding morph (Binding.suffix_name "_dict" b);
   369     val c' = Sign.full_name thy b;
   370     val dict' = Morphism.term morph dict;
   371     val ty' = Term.fastype_of dict';
   372     val def_eq = Logic.mk_equals (Const (c', ty'), dict')
   373       |> map_types Type.strip_sorts;
   374   in
   375     thy
   376     |> Sign.declare_const pos ((b, Type.strip_sorts ty'), mx)
   377     |> snd
   378     |> Thm.add_def false false (b_def, def_eq)
   379     |>> Thm.varifyT
   380     |-> (fn def_thm => PureThy.store_thm (b_def, def_thm)
   381       #> snd
   382       #> register_operation class (c', (dict', SOME (Thm.symmetric def_thm))))
   383     |> Sign.add_const_constraint (c', SOME ty')
   384   end;
   385 
   386 fun abbrev class prmode pos ((c, mx), rhs) thy =
   387   let
   388     val morph = morphism thy class;
   389     val unchecks = these_unchecks thy [class];
   390     val b = Morphism.binding morph c;
   391     val c' = Sign.full_name thy b;
   392     val rhs' = Pattern.rewrite_term thy unchecks [] rhs;
   393     val ty' = Term.fastype_of rhs';
   394     val rhs'' = map_types ((*Type.strip_sorts o *)Logic.varifyT) rhs';
   395   in
   396     thy
   397     |> Sign.add_abbrev (#1 prmode) pos (b, rhs'')
   398     |> snd
   399     |> Sign.add_const_constraint (c', SOME ty')
   400     |> Sign.notation true prmode [(Const (c', ty'), mx)]
   401     |> not (#1 prmode = PrintMode.input) ? register_operation class (c', (rhs', NONE))
   402   end;
   403 
   404 
   405 (** instantiation target **)
   406 
   407 (* bookkeeping *)
   408 
   409 datatype instantiation = Instantiation of {
   410   arities: string list * (string * sort) list * sort,
   411   params: ((string * string) * (string * typ)) list
   412     (*(instantiation parameter, type constructor), (local instantiation parameter, typ)*)
   413 }
   414 
   415 structure Instantiation = ProofDataFun
   416 (
   417   type T = instantiation
   418   fun init _ = Instantiation { arities = ([], [], []), params = [] };
   419 );
   420 
   421 fun mk_instantiation (arities, params) =
   422   Instantiation { arities = arities, params = params };
   423 fun get_instantiation lthy = case Instantiation.get (LocalTheory.target_of lthy)
   424  of Instantiation data => data;
   425 fun map_instantiation f = (LocalTheory.target o Instantiation.map)
   426   (fn Instantiation { arities, params } => mk_instantiation (f (arities, params)));
   427 
   428 fun the_instantiation lthy = case get_instantiation lthy
   429  of { arities = ([], [], []), ... } => error "No instantiation target"
   430   | data => data;
   431 
   432 val instantiation_params = #params o get_instantiation;
   433 
   434 fun instantiation_param lthy b = instantiation_params lthy
   435   |> find_first (fn (_, (v, _)) => Binding.name_of b = v)
   436   |> Option.map (fst o fst);
   437 
   438 
   439 (* syntax *)
   440 
   441 fun synchronize_inst_syntax ctxt =
   442   let
   443     val Instantiation { arities = (_, _, sort), params = params } = Instantiation.get ctxt;
   444     val thy = ProofContext.theory_of ctxt;
   445     fun subst (c, ty) = case AxClass.inst_tyco_of thy (c, ty)
   446          of SOME tyco => (case AList.lookup (op =) params (c, tyco)
   447              of SOME (v_ty as (_, ty)) => SOME (ty, Free v_ty)
   448               | NONE => NONE)
   449           | NONE => NONE;
   450     val unchecks =
   451       map (fn ((c, _), v_ty as (_, ty)) => (Free v_ty, Const (c, ty))) params;
   452   in
   453     ctxt
   454     |> Overloading.map_improvable_syntax
   455          (fn (((primary_constraints, _), (((improve, _), _), _)), _) =>
   456             (((primary_constraints, []), (((improve, subst), false), unchecks)), false))
   457   end;
   458 
   459 
   460 (* target *)
   461 
   462 val sanatize_name = (*FIXME*)
   463   let
   464     fun is_valid s = Symbol.is_ascii_letter s orelse Symbol.is_ascii_digit s
   465       orelse s = "'" orelse s = "_";
   466     val is_junk = not o is_valid andf Symbol.is_regular;
   467     val junk = Scan.many is_junk;
   468     val scan_valids = Symbol.scanner "Malformed input"
   469       ((junk |--
   470         (Scan.optional (Scan.one Symbol.is_ascii_letter) "x" ^^ (Scan.many is_valid >> implode)
   471         --| junk))
   472       ::: Scan.repeat ((Scan.many1 is_valid >> implode) --| junk));
   473   in
   474     explode #> scan_valids #> implode
   475   end;
   476 
   477 fun type_name "*" = "prod"
   478   | type_name "+" = "sum"
   479   | type_name s = sanatize_name (Long_Name.base_name s);
   480 
   481 fun resort_terms pp algebra consts constraints ts =
   482   let
   483     fun matchings (Const (c_ty as (c, _))) = (case constraints c
   484          of NONE => I
   485           | SOME sorts => fold2 (curry (Sorts.meet_sort algebra))
   486               (Consts.typargs consts c_ty) sorts)
   487       | matchings _ = I
   488     val tvartab = (fold o fold_aterms) matchings ts Vartab.empty
   489       handle Sorts.CLASS_ERROR e => error (Sorts.class_error pp e);
   490     val inst = map_type_tvar
   491       (fn (vi, sort) => TVar (vi, the_default sort (Vartab.lookup tvartab vi)));
   492   in if Vartab.is_empty tvartab then NONE else SOME ((map o map_types) inst ts) end;
   493 
   494 fun init_instantiation (tycos, vs, sort) thy =
   495   let
   496     val _ = if null tycos then error "At least one arity must be given" else ();
   497     val params = these_params thy (filter (can (AxClass.get_info thy)) sort);
   498     fun get_param tyco (param, (_, (c, ty))) =
   499       if can (AxClass.param_of_inst thy) (c, tyco)
   500       then NONE else SOME ((c, tyco),
   501         (param ^ "_" ^ type_name tyco, map_atyps (K (Type (tyco, map TFree vs))) ty));
   502     val inst_params = map_product get_param tycos params |> map_filter I;
   503     val primary_constraints = map (apsnd
   504       (map_atyps (K (TVar ((Name.aT, 0), [])))) o snd o snd) params;
   505     val pp = Syntax.pp_global thy;
   506     val algebra = Sign.classes_of thy
   507       |> fold (fn tyco => Sorts.add_arities pp
   508             (tyco, map (fn class => (class, map snd vs)) sort)) tycos;
   509     val consts = Sign.consts_of thy;
   510     val improve_constraints = AList.lookup (op =)
   511       (map (fn (_, (class, (c, _))) => (c, [[class]])) params);
   512     fun resort_check ts ctxt = case resort_terms pp algebra consts improve_constraints ts
   513      of NONE => NONE
   514       | SOME ts' => SOME (ts', ctxt);
   515     fun improve (c, ty) = case AxClass.inst_tyco_of thy (c, ty)
   516      of SOME tyco => (case AList.lookup (op =) inst_params (c, tyco)
   517          of SOME (_, ty') => if Type.typ_instance (Sign.tsig_of thy) (ty', ty)
   518               then SOME (ty, ty') else NONE
   519           | NONE => NONE)
   520       | NONE => NONE;
   521   in
   522     thy
   523     |> ProofContext.init
   524     |> Instantiation.put (mk_instantiation ((tycos, vs, sort), inst_params))
   525     |> fold (Variable.declare_typ o TFree) vs
   526     |> fold (Variable.declare_names o Free o snd) inst_params
   527     |> (Overloading.map_improvable_syntax o apfst)
   528          (K ((primary_constraints, []), (((improve, K NONE), false), [])))
   529     |> Overloading.add_improvable_syntax
   530     |> Context.proof_map (Syntax.add_term_check 0 "resorting" resort_check)
   531     |> synchronize_inst_syntax
   532   end;
   533 
   534 fun confirm_declaration b = (map_instantiation o apsnd)
   535   (filter_out (fn (_, (c', _)) => c' = Binding.name_of b))
   536   #> LocalTheory.target synchronize_inst_syntax
   537 
   538 fun gen_instantiation_instance do_proof after_qed lthy =
   539   let
   540     val (tycos, vs, sort) = (#arities o the_instantiation) lthy;
   541     val arities_proof = maps (fn tyco => Logic.mk_arities (tyco, map snd vs, sort)) tycos;
   542     fun after_qed' results =
   543       LocalTheory.theory (fold (AxClass.add_arity o Thm.varifyT) results)
   544       #> after_qed;
   545   in
   546     lthy
   547     |> do_proof after_qed' arities_proof
   548   end;
   549 
   550 val instantiation_instance = gen_instantiation_instance (fn after_qed => fn ts =>
   551   Proof.theorem_i NONE (after_qed o map the_single) (map (fn t => [(t, [])]) ts));
   552 
   553 fun prove_instantiation_instance tac = gen_instantiation_instance (fn after_qed =>
   554   fn ts => fn lthy => after_qed (map (fn t => Goal.prove lthy [] [] t
   555     (fn {context, ...} => tac context)) ts) lthy) I;
   556 
   557 fun prove_instantiation_exit tac = prove_instantiation_instance tac
   558   #> LocalTheory.exit_global;
   559 
   560 fun prove_instantiation_exit_result f tac x lthy =
   561   let
   562     val morph = ProofContext.export_morphism lthy
   563       (ProofContext.init (ProofContext.theory_of lthy));
   564     val y = f morph x;
   565   in
   566     lthy
   567     |> prove_instantiation_exit (fn ctxt => tac ctxt y)
   568     |> pair y
   569   end;
   570 
   571 fun conclude_instantiation lthy =
   572   let
   573     val { arities, params } = the_instantiation lthy;
   574     val (tycos, vs, sort) = arities;
   575     val thy = ProofContext.theory_of lthy;
   576     val _ = map (fn tyco => if Sign.of_sort thy
   577         (Type (tyco, map TFree vs), sort)
   578       then () else error ("Missing instance proof for type " ^ quote (Sign.extern_type thy tyco)))
   579         tycos;
   580   in lthy end;
   581 
   582 fun pretty_instantiation lthy =
   583   let
   584     val { arities, params } = the_instantiation lthy;
   585     val (tycos, vs, sort) = arities;
   586     val thy = ProofContext.theory_of lthy;
   587     fun pr_arity tyco = Syntax.pretty_arity lthy (tyco, map snd vs, sort);
   588     fun pr_param ((c, _), (v, ty)) =
   589       (Pretty.block o Pretty.breaks) [Pretty.str v, Pretty.str "==",
   590         (Pretty.str o Sign.extern_const thy) c, Pretty.str "::", Syntax.pretty_typ_global thy ty];
   591   in
   592     (Pretty.block o Pretty.fbreaks)
   593       (Pretty.str "instantiation" :: map pr_arity tycos @ map pr_param params)
   594   end;
   595 
   596 
   597 (** tactics and methods **)
   598 
   599 fun intro_classes_tac facts st =
   600   let
   601     val thy = Thm.theory_of_thm st;
   602     val classes = Sign.all_classes thy;
   603     val class_trivs = map (Thm.class_triv thy) classes;
   604     val class_intros = map_filter (try (#intro o AxClass.get_info thy)) classes;
   605     val assm_intros = all_assm_intros thy;
   606   in
   607     Method.intros_tac (class_trivs @ class_intros @ assm_intros) facts st
   608   end;
   609 
   610 fun default_intro_tac ctxt [] =
   611       intro_classes_tac [] ORELSE Locale.intro_locales_tac true ctxt []
   612   | default_intro_tac _ _ = no_tac;
   613 
   614 fun default_tac rules ctxt facts =
   615   HEADGOAL (Method.some_rule_tac rules ctxt facts) ORELSE
   616     default_intro_tac ctxt facts;
   617 
   618 val _ = Context.>> (Context.map_theory
   619  (Method.setup (Binding.name "intro_classes") (Scan.succeed (K (METHOD intro_classes_tac)))
   620     "back-chain introduction rules of classes" #>
   621   Method.setup (Binding.name "default") (Attrib.thms >> (METHOD oo default_tac))
   622     "apply some intro/elim rule"));
   623 
   624 end;
   625