src/Pure/drule.ML
author wenzelm
Thu Feb 03 13:55:03 1994 +0100 (1994-02-03)
changeset 252 7532f95d7f44
parent 229 4002c4cd450c
child 385 921f87897a76
permissions -rw-r--r--
removed eq_sg, pprint_sg, print_sg (now in sign.ML);
removed cterm_fun, read_ctyp (now in thm.ML);
print_theory: now shows all contents;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems and theories
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL COMP;
    10 
    11 signature DRULE =
    12   sig
    13   structure Thm : THM
    14   local open Thm  in
    15   val asm_rl: thm
    16   val assume_ax: theory -> string -> thm
    17   val COMP: thm * thm -> thm
    18   val compose: thm * int * thm -> thm list
    19   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    20   val cut_rl: thm
    21   val equal_abs_elim: cterm  -> thm -> thm
    22   val equal_abs_elim_list: cterm list -> thm -> thm
    23   val eq_thm: thm * thm -> bool
    24   val eq_thm_sg: thm * thm -> bool
    25   val flexpair_abs_elim_list: cterm list -> thm -> thm
    26   val forall_intr_list: cterm list -> thm -> thm
    27   val forall_intr_frees: thm -> thm
    28   val forall_elim_list: cterm list -> thm -> thm
    29   val forall_elim_var: int -> thm -> thm
    30   val forall_elim_vars: int -> thm -> thm
    31   val implies_elim_list: thm -> thm list -> thm
    32   val implies_intr_list: cterm list -> thm -> thm
    33   val MRL: thm list list * thm list -> thm list
    34   val MRS: thm list * thm -> thm
    35   val pprint_cterm: cterm -> pprint_args -> unit
    36   val pprint_ctyp: ctyp -> pprint_args -> unit
    37   val pprint_theory: theory -> pprint_args -> unit
    38   val pprint_thm: thm -> pprint_args -> unit
    39   val pretty_thm: thm -> Sign.Syntax.Pretty.T
    40   val print_cterm: cterm -> unit
    41   val print_ctyp: ctyp -> unit
    42   val print_goals: int -> thm -> unit
    43   val print_goals_ref: (int -> thm -> unit) ref
    44   val print_theory: theory -> unit
    45   val print_thm: thm -> unit
    46   val prth: thm -> thm
    47   val prthq: thm Sequence.seq -> thm Sequence.seq
    48   val prths: thm list -> thm list
    49   val read_instantiate: (string*string)list -> thm -> thm
    50   val read_instantiate_sg: Sign.sg -> (string*string)list -> thm -> thm
    51   val read_insts:
    52           Sign.sg -> (indexname -> typ option) * (indexname -> sort option)
    53                   -> (indexname -> typ option) * (indexname -> sort option)
    54                   -> (string*string)list
    55                   -> (indexname*ctyp)list * (cterm*cterm)list
    56   val reflexive_thm: thm
    57   val revcut_rl: thm
    58   val rewrite_goal_rule: bool*bool -> (meta_simpset -> thm -> thm option)
    59         -> meta_simpset -> int -> thm -> thm
    60   val rewrite_goals_rule: thm list -> thm -> thm
    61   val rewrite_rule: thm list -> thm -> thm
    62   val RS: thm * thm -> thm
    63   val RSN: thm * (int * thm) -> thm
    64   val RL: thm list * thm list -> thm list
    65   val RLN: thm list * (int * thm list) -> thm list
    66   val show_hyps: bool ref
    67   val size_of_thm: thm -> int
    68   val standard: thm -> thm
    69   val string_of_cterm: cterm -> string
    70   val string_of_ctyp: ctyp -> string
    71   val string_of_thm: thm -> string
    72   val symmetric_thm: thm
    73   val transitive_thm: thm
    74   val triv_forall_equality: thm
    75   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    76   val zero_var_indexes: thm -> thm
    77   end
    78   end;
    79 
    80 functor DruleFun (structure Logic: LOGIC and Thm: THM): DRULE =
    81 struct
    82 structure Thm = Thm;
    83 structure Sign = Thm.Sign;
    84 structure Type = Sign.Type;
    85 structure Pretty = Sign.Syntax.Pretty
    86 local open Thm
    87 in
    88 
    89 (**** More derived rules and operations on theorems ****)
    90 
    91 (** reading of instantiations **)
    92 
    93 fun indexname cs = case Syntax.scan_varname cs of (v,[]) => v
    94         | _ => error("Lexical error in variable name " ^ quote (implode cs));
    95 
    96 fun absent ixn =
    97   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
    98 
    99 fun inst_failure ixn =
   100   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   101 
   102 fun read_insts sign (rtypes,rsorts) (types,sorts) insts =
   103 let val {tsig,...} = Sign.rep_sg sign
   104     fun split([],tvs,vs) = (tvs,vs)
   105       | split((sv,st)::l,tvs,vs) = (case explode sv of
   106                   "'"::cs => split(l,(indexname cs,st)::tvs,vs)
   107                 | cs => split(l,tvs,(indexname cs,st)::vs));
   108     val (tvs,vs) = split(insts,[],[]);
   109     fun readT((a,i),st) =
   110         let val ixn = ("'" ^ a,i);
   111             val S = case rsorts ixn of Some S => S | None => absent ixn;
   112             val T = Sign.read_typ (sign,sorts) st;
   113         in if Type.typ_instance(tsig,T,TVar(ixn,S)) then (ixn,T)
   114            else inst_failure ixn
   115         end
   116     val tye = map readT tvs;
   117     fun add_cterm ((cts,tye), (ixn,st)) =
   118         let val T = case rtypes ixn of
   119                       Some T => typ_subst_TVars tye T
   120                     | None => absent ixn;
   121             val (ct,tye2) = read_def_cterm (sign,types,sorts) (st,T);
   122             val cv = cterm_of sign (Var(ixn,typ_subst_TVars tye2 T))
   123         in ((cv,ct)::cts,tye2 @ tye) end
   124     val (cterms,tye') = foldl add_cterm (([],tye), vs);
   125 in (map (fn (ixn,T) => (ixn,ctyp_of sign T)) tye', cterms) end;
   126 
   127 
   128 
   129 (*** Printing of theories, theorems, etc. ***)
   130 
   131 (*If false, hypotheses are printed as dots*)
   132 val show_hyps = ref true;
   133 
   134 fun pretty_thm th =
   135 let val {sign, hyps, prop,...} = rep_thm th
   136     val hsymbs = if null hyps then []
   137                  else if !show_hyps then
   138                       [Pretty.brk 2,
   139                        Pretty.lst("[","]") (map (Sign.pretty_term sign) hyps)]
   140                  else Pretty.str" [" :: map (fn _ => Pretty.str".") hyps @
   141                       [Pretty.str"]"];
   142 in Pretty.blk(0, Sign.pretty_term sign prop :: hsymbs) end;
   143 
   144 val string_of_thm = Pretty.string_of o pretty_thm;
   145 
   146 val pprint_thm = Pretty.pprint o Pretty.quote o pretty_thm;
   147 
   148 
   149 (** Top-level commands for printing theorems **)
   150 val print_thm = writeln o string_of_thm;
   151 
   152 fun prth th = (print_thm th; th);
   153 
   154 (*Print and return a sequence of theorems, separated by blank lines. *)
   155 fun prthq thseq =
   156   (Sequence.prints (fn _ => print_thm) 100000 thseq; thseq);
   157 
   158 (*Print and return a list of theorems, separated by blank lines. *)
   159 fun prths ths = (print_list_ln print_thm ths; ths);
   160 
   161 
   162 (* other printing commands *)
   163 
   164 fun pprint_ctyp cT =
   165   let val {sign, T} = rep_ctyp cT in Sign.pprint_typ sign T end;
   166 
   167 fun string_of_ctyp cT =
   168   let val {sign, T} = rep_ctyp cT in Sign.string_of_typ sign T end;
   169 
   170 val print_ctyp = writeln o string_of_ctyp;
   171 
   172 fun pprint_cterm ct =
   173   let val {sign, t, ...} = rep_cterm ct in Sign.pprint_term sign t end;
   174 
   175 fun string_of_cterm ct =
   176   let val {sign, t, ...} = rep_cterm ct in Sign.string_of_term sign t end;
   177 
   178 val print_cterm = writeln o string_of_cterm;
   179 
   180 
   181 (* print theory *)
   182 
   183 val pprint_theory = Sign.pprint_sg o sign_of;
   184 
   185 fun print_theory thy =
   186   let
   187     fun prt_thm (name, thm) = Pretty.block
   188       [Pretty.str (name ^ ":"), Pretty.brk 1, Pretty.quote (pretty_thm thm)];
   189 
   190     val sg = sign_of thy;
   191     val axioms =        (* FIXME should rather fix axioms_of *)
   192       sort (fn ((x, _), (y, _)) => x <= y)
   193         (gen_distinct eq_fst (axioms_of thy));
   194   in
   195     Sign.print_sg sg;
   196     Pretty.writeln (Pretty.big_list "axioms:" (map prt_thm axioms))
   197   end;
   198 
   199 
   200 
   201 (** Print thm A1,...,An/B in "goal style" -- premises as numbered subgoals **)
   202 
   203 fun prettyprints es = writeln(Pretty.string_of(Pretty.blk(0,es)));
   204 
   205 fun print_goals maxgoals th : unit =
   206 let val {sign, hyps, prop,...} = rep_thm th;
   207     fun printgoals (_, []) = ()
   208       | printgoals (n, A::As) =
   209         let val prettyn = Pretty.str(" " ^ string_of_int n ^ ". ");
   210             val prettyA = Sign.pretty_term sign A
   211         in prettyprints[prettyn,prettyA];
   212            printgoals (n+1,As)
   213         end;
   214     fun prettypair(t,u) =
   215         Pretty.blk(0, [Sign.pretty_term sign t, Pretty.str" =?=", Pretty.brk 1,
   216                        Sign.pretty_term sign u]);
   217     fun printff [] = ()
   218       | printff tpairs =
   219          writeln("\nFlex-flex pairs:\n" ^
   220                  Pretty.string_of(Pretty.lst("","") (map prettypair tpairs)))
   221     val (tpairs,As,B) = Logic.strip_horn(prop);
   222     val ngoals = length As
   223 in
   224    writeln (Sign.string_of_term sign B);
   225    if ngoals=0 then writeln"No subgoals!"
   226    else if ngoals>maxgoals
   227         then (printgoals (1, take(maxgoals,As));
   228               writeln("A total of " ^ string_of_int ngoals ^ " subgoals..."))
   229         else printgoals (1, As);
   230    printff tpairs
   231 end;
   232 
   233 (*"hook" for user interfaces: allows print_goals to be replaced*)
   234 val print_goals_ref = ref print_goals;
   235 
   236 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   237      Used for establishing default types (of variables) and sorts (of
   238      type variables) when reading another term.
   239      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   240 ***)
   241 
   242 fun types_sorts thm =
   243     let val {prop,hyps,...} = rep_thm thm;
   244         val big = list_comb(prop,hyps); (* bogus term! *)
   245         val vars = map dest_Var (term_vars big);
   246         val frees = map dest_Free (term_frees big);
   247         val tvars = term_tvars big;
   248         val tfrees = term_tfrees big;
   249         fun typ(a,i) = if i<0 then assoc(frees,a) else assoc(vars,(a,i));
   250         fun sort(a,i) = if i<0 then assoc(tfrees,a) else assoc(tvars,(a,i));
   251     in (typ,sort) end;
   252 
   253 (** Standardization of rules **)
   254 
   255 (*Generalization over a list of variables, IGNORING bad ones*)
   256 fun forall_intr_list [] th = th
   257   | forall_intr_list (y::ys) th =
   258         let val gth = forall_intr_list ys th
   259         in  forall_intr y gth   handle THM _ =>  gth  end;
   260 
   261 (*Generalization over all suitable Free variables*)
   262 fun forall_intr_frees th =
   263     let val {prop,sign,...} = rep_thm th
   264     in  forall_intr_list
   265          (map (cterm_of sign) (sort atless (term_frees prop)))
   266          th
   267     end;
   268 
   269 (*Replace outermost quantified variable by Var of given index.
   270     Could clash with Vars already present.*)
   271 fun forall_elim_var i th =
   272     let val {prop,sign,...} = rep_thm th
   273     in case prop of
   274           Const("all",_) $ Abs(a,T,_) =>
   275               forall_elim (cterm_of sign (Var((a,i), T)))  th
   276         | _ => raise THM("forall_elim_var", i, [th])
   277     end;
   278 
   279 (*Repeat forall_elim_var until all outer quantifiers are removed*)
   280 fun forall_elim_vars i th =
   281     forall_elim_vars i (forall_elim_var i th)
   282         handle THM _ => th;
   283 
   284 (*Specialization over a list of cterms*)
   285 fun forall_elim_list cts th = foldr (uncurry forall_elim) (rev cts, th);
   286 
   287 (* maps [A1,...,An], B   to   [| A1;...;An |] ==> B  *)
   288 fun implies_intr_list cAs th = foldr (uncurry implies_intr) (cAs,th);
   289 
   290 (* maps [| A1;...;An |] ==> B and [A1,...,An]   to   B *)
   291 fun implies_elim_list impth ths = foldl (uncurry implies_elim) (impth,ths);
   292 
   293 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   294 fun zero_var_indexes th =
   295     let val {prop,sign,...} = rep_thm th;
   296         val vars = term_vars prop
   297         val bs = foldl add_new_id ([], map (fn Var((a,_),_)=>a) vars)
   298         val inrs = add_term_tvars(prop,[]);
   299         val nms' = rev(foldl add_new_id ([], map (#1 o #1) inrs));
   300         val tye = map (fn ((v,rs),a) => (v, TVar((a,0),rs))) (inrs ~~ nms')
   301         val ctye = map (fn (v,T) => (v,ctyp_of sign T)) tye;
   302         fun varpairs([],[]) = []
   303           | varpairs((var as Var(v,T)) :: vars, b::bs) =
   304                 let val T' = typ_subst_TVars tye T
   305                 in (cterm_of sign (Var(v,T')),
   306                     cterm_of sign (Var((b,0),T'))) :: varpairs(vars,bs)
   307                 end
   308           | varpairs _ = raise TERM("varpairs", []);
   309     in instantiate (ctye, varpairs(vars,rev bs)) th end;
   310 
   311 
   312 (*Standard form of object-rule: no hypotheses, Frees, or outer quantifiers;
   313     all generality expressed by Vars having index 0.*)
   314 fun standard th =
   315     let val {maxidx,...} = rep_thm th
   316     in  varifyT (zero_var_indexes (forall_elim_vars(maxidx+1)
   317                          (forall_intr_frees(implies_intr_hyps th))))
   318     end;
   319 
   320 (*Assume a new formula, read following the same conventions as axioms.
   321   Generalizes over Free variables,
   322   creates the assumption, and then strips quantifiers.
   323   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   324              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   325 fun assume_ax thy sP =
   326     let val sign = sign_of thy
   327         val prop = Logic.close_form (term_of (read_cterm sign
   328                          (sP, propT)))
   329     in forall_elim_vars 0 (assume (cterm_of sign prop))  end;
   330 
   331 (*Resolution: exactly one resolvent must be produced.*)
   332 fun tha RSN (i,thb) =
   333   case Sequence.chop (2, biresolution false [(false,tha)] i thb) of
   334       ([th],_) => th
   335     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   336     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   337 
   338 (*resolution: P==>Q, Q==>R gives P==>R. *)
   339 fun tha RS thb = tha RSN (1,thb);
   340 
   341 (*For joining lists of rules*)
   342 fun thas RLN (i,thbs) =
   343   let val resolve = biresolution false (map (pair false) thas) i
   344       fun resb thb = Sequence.list_of_s (resolve thb) handle THM _ => []
   345   in  flat (map resb thbs)  end;
   346 
   347 fun thas RL thbs = thas RLN (1,thbs);
   348 
   349 (*Resolve a list of rules against bottom_rl from right to left;
   350   makes proof trees*)
   351 fun rls MRS bottom_rl =
   352   let fun rs_aux i [] = bottom_rl
   353         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   354   in  rs_aux 1 rls  end;
   355 
   356 (*As above, but for rule lists*)
   357 fun rlss MRL bottom_rls =
   358   let fun rs_aux i [] = bottom_rls
   359         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   360   in  rs_aux 1 rlss  end;
   361 
   362 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   363   with no lifting or renaming!  Q may contain ==> or meta-quants
   364   ALWAYS deletes premise i *)
   365 fun compose(tha,i,thb) =
   366     Sequence.list_of_s (bicompose false (false,tha,0) i thb);
   367 
   368 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   369 fun tha COMP thb =
   370     case compose(tha,1,thb) of
   371         [th] => th
   372       | _ =>   raise THM("COMP", 1, [tha,thb]);
   373 
   374 (*Instantiate theorem th, reading instantiations under signature sg*)
   375 fun read_instantiate_sg sg sinsts th =
   376     let val ts = types_sorts th;
   377     in  instantiate (read_insts sg ts ts sinsts) th  end;
   378 
   379 (*Instantiate theorem th, reading instantiations under theory of th*)
   380 fun read_instantiate sinsts th =
   381     read_instantiate_sg (#sign (rep_thm th)) sinsts th;
   382 
   383 
   384 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   385   Instantiates distinct Vars by terms, inferring type instantiations. *)
   386 local
   387   fun add_types ((ct,cu), (sign,tye)) =
   388     let val {sign=signt, t=t, T= T, ...} = rep_cterm ct
   389         and {sign=signu, t=u, T= U, ...} = rep_cterm cu
   390         val sign' = Sign.merge(sign, Sign.merge(signt, signu))
   391         val tye' = Type.unify (#tsig(Sign.rep_sg sign')) ((T,U), tye)
   392           handle Type.TUNIFY => raise TYPE("add_types", [T,U], [t,u])
   393     in  (sign', tye')  end;
   394 in
   395 fun cterm_instantiate ctpairs0 th =
   396   let val (sign,tye) = foldr add_types (ctpairs0, (#sign(rep_thm th),[]))
   397       val tsig = #tsig(Sign.rep_sg sign);
   398       fun instT(ct,cu) = let val inst = subst_TVars tye
   399                          in (cterm_fun inst ct, cterm_fun inst cu) end
   400       fun ctyp2 (ix,T) = (ix, ctyp_of sign T)
   401   in  instantiate (map ctyp2 tye, map instT ctpairs0) th  end
   402   handle TERM _ =>
   403            raise THM("cterm_instantiate: incompatible signatures",0,[th])
   404        | TYPE _ => raise THM("cterm_instantiate: types", 0, [th])
   405 end;
   406 
   407 
   408 (** theorem equality test is exported and used by BEST_FIRST **)
   409 
   410 (*equality of theorems uses equality of signatures and
   411   the a-convertible test for terms*)
   412 fun eq_thm (th1,th2) =
   413     let val {sign=sg1, hyps=hyps1, prop=prop1, ...} = rep_thm th1
   414         and {sign=sg2, hyps=hyps2, prop=prop2, ...} = rep_thm th2
   415     in  Sign.eq_sg (sg1,sg2) andalso
   416         aconvs(hyps1,hyps2) andalso
   417         prop1 aconv prop2
   418     end;
   419 
   420 (*Do the two theorems have the same signature?*)
   421 fun eq_thm_sg (th1,th2) = Sign.eq_sg(#sign(rep_thm th1), #sign(rep_thm th2));
   422 
   423 (*Useful "distance" function for BEST_FIRST*)
   424 val size_of_thm = size_of_term o #prop o rep_thm;
   425 
   426 
   427 (*** Meta-Rewriting Rules ***)
   428 
   429 
   430 val reflexive_thm =
   431   let val cx = cterm_of Sign.pure (Var(("x",0),TVar(("'a",0),["logic"])))
   432   in Thm.reflexive cx end;
   433 
   434 val symmetric_thm =
   435   let val xy = read_cterm Sign.pure ("x::'a::logic == y",propT)
   436   in standard(Thm.implies_intr_hyps(Thm.symmetric(Thm.assume xy))) end;
   437 
   438 val transitive_thm =
   439   let val xy = read_cterm Sign.pure ("x::'a::logic == y",propT)
   440       val yz = read_cterm Sign.pure ("y::'a::logic == z",propT)
   441       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   442   in standard(Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   443 
   444 (** Below, a "conversion" has type cterm -> thm **)
   445 
   446 val refl_cimplies = reflexive (cterm_of Sign.pure implies);
   447 
   448 (*In [A1,...,An]==>B, rewrite the selected A's only -- for rewrite_goals_tac*)
   449 (*Do not rewrite flex-flex pairs*)
   450 fun goals_conv pred cv =
   451   let fun gconv i ct =
   452         let val (A,B) = Thm.dest_cimplies ct
   453             val (thA,j) = case term_of A of
   454                   Const("=?=",_)$_$_ => (reflexive A, i)
   455                 | _ => (if pred i then cv A else reflexive A, i+1)
   456         in  combination (combination refl_cimplies thA) (gconv j B) end
   457         handle TERM _ => reflexive ct
   458   in gconv 1 end;
   459 
   460 (*Use a conversion to transform a theorem*)
   461 fun fconv_rule cv th = equal_elim (cv (cprop_of th)) th;
   462 
   463 (*rewriting conversion*)
   464 fun rew_conv mode prover mss = rewrite_cterm mode mss prover;
   465 
   466 (*Rewrite a theorem*)
   467 fun rewrite_rule thms =
   468   fconv_rule (rew_conv (true,false) (K(K None)) (Thm.mss_of thms));
   469 
   470 (*Rewrite the subgoals of a proof state (represented by a theorem) *)
   471 fun rewrite_goals_rule thms =
   472   fconv_rule (goals_conv (K true) (rew_conv (true,false) (K(K None))
   473              (Thm.mss_of thms)));
   474 
   475 (*Rewrite the subgoal of a proof state (represented by a theorem) *)
   476 fun rewrite_goal_rule mode prover mss i thm =
   477   if 0 < i  andalso  i <= nprems_of thm
   478   then fconv_rule (goals_conv (fn j => j=i) (rew_conv mode prover mss)) thm
   479   else raise THM("rewrite_goal_rule",i,[thm]);
   480 
   481 
   482 (** Derived rules mainly for METAHYPS **)
   483 
   484 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   485 fun equal_abs_elim ca eqth =
   486   let val {sign=signa, t=a, ...} = rep_cterm ca
   487       and combth = combination eqth (reflexive ca)
   488       val {sign,prop,...} = rep_thm eqth
   489       val (abst,absu) = Logic.dest_equals prop
   490       val cterm = cterm_of (Sign.merge (sign,signa))
   491   in  transitive (symmetric (beta_conversion (cterm (abst$a))))
   492            (transitive combth (beta_conversion (cterm (absu$a))))
   493   end
   494   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   495 
   496 (*Calling equal_abs_elim with multiple terms*)
   497 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) (rev cts, th);
   498 
   499 local
   500   open Logic
   501   val alpha = TVar(("'a",0), [])     (*  type ?'a::{}  *)
   502   fun err th = raise THM("flexpair_inst: ", 0, [th])
   503   fun flexpair_inst def th =
   504     let val {prop = Const _ $ t $ u,  sign,...} = rep_thm th
   505         val cterm = cterm_of sign
   506         fun cvar a = cterm(Var((a,0),alpha))
   507         val def' = cterm_instantiate [(cvar"t", cterm t), (cvar"u", cterm u)]
   508                    def
   509     in  equal_elim def' th
   510     end
   511     handle THM _ => err th | bind => err th
   512 in
   513 val flexpair_intr = flexpair_inst (symmetric flexpair_def)
   514 and flexpair_elim = flexpair_inst flexpair_def
   515 end;
   516 
   517 (*Version for flexflex pairs -- this supports lifting.*)
   518 fun flexpair_abs_elim_list cts =
   519     flexpair_intr o equal_abs_elim_list cts o flexpair_elim;
   520 
   521 
   522 (*** Some useful meta-theorems ***)
   523 
   524 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   525 val asm_rl = trivial(read_cterm Sign.pure ("PROP ?psi",propT));
   526 
   527 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   528 val cut_rl = trivial(read_cterm Sign.pure
   529         ("PROP ?psi ==> PROP ?theta", propT));
   530 
   531 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   532      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   533 val revcut_rl =
   534   let val V = read_cterm Sign.pure ("PROP V", propT)
   535       and VW = read_cterm Sign.pure ("PROP V ==> PROP W", propT);
   536   in  standard (implies_intr V
   537                 (implies_intr VW
   538                  (implies_elim (assume VW) (assume V))))
   539   end;
   540 
   541 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   542 val triv_forall_equality =
   543   let val V  = read_cterm Sign.pure ("PROP V", propT)
   544       and QV = read_cterm Sign.pure ("!!x::'a. PROP V", propT)
   545       and x  = read_cterm Sign.pure ("x", TFree("'a",["logic"]));
   546   in  standard (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   547                            (implies_intr V  (forall_intr x (assume V))))
   548   end;
   549 
   550 end
   551 end;
   552