src/HOL/Library/Multiset.thy
author haftmann
Wed Mar 27 10:55:05 2013 +0100 (2013-03-27)
changeset 51548 757fa47af981
parent 51161 6ed12ae3b3e1
child 51599 1559e9266280
permissions -rw-r--r--
centralized various multiset operations in theory multiset;
more conversions between multisets and lists respectively
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3 *)
     4 
     5 header {* (Finite) multisets *}
     6 
     7 theory Multiset
     8 imports Main DAList (* FIXME too specific dependency for a generic theory *)
     9 begin
    10 
    11 subsection {* The type of multisets *}
    12 
    13 definition "multiset = {f :: 'a => nat. finite {x. f x > 0}}"
    14 
    15 typedef 'a multiset = "multiset :: ('a => nat) set"
    16   morphisms count Abs_multiset
    17   unfolding multiset_def
    18 proof
    19   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    20 qed
    21 
    22 setup_lifting type_definition_multiset
    23 
    24 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
    25   "a :# M == 0 < count M a"
    26 
    27 notation (xsymbols)
    28   Melem (infix "\<in>#" 50)
    29 
    30 lemma multiset_eq_iff:
    31   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    32   by (simp only: count_inject [symmetric] fun_eq_iff)
    33 
    34 lemma multiset_eqI:
    35   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    36   using multiset_eq_iff by auto
    37 
    38 text {*
    39  \medskip Preservation of the representing set @{term multiset}.
    40 *}
    41 
    42 lemma const0_in_multiset:
    43   "(\<lambda>a. 0) \<in> multiset"
    44   by (simp add: multiset_def)
    45 
    46 lemma only1_in_multiset:
    47   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    48   by (simp add: multiset_def)
    49 
    50 lemma union_preserves_multiset:
    51   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    52   by (simp add: multiset_def)
    53 
    54 lemma diff_preserves_multiset:
    55   assumes "M \<in> multiset"
    56   shows "(\<lambda>a. M a - N a) \<in> multiset"
    57 proof -
    58   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    59     by auto
    60   with assms show ?thesis
    61     by (auto simp add: multiset_def intro: finite_subset)
    62 qed
    63 
    64 lemma filter_preserves_multiset:
    65   assumes "M \<in> multiset"
    66   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    67 proof -
    68   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    69     by auto
    70   with assms show ?thesis
    71     by (auto simp add: multiset_def intro: finite_subset)
    72 qed
    73 
    74 lemmas in_multiset = const0_in_multiset only1_in_multiset
    75   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    76 
    77 
    78 subsection {* Representing multisets *}
    79 
    80 text {* Multiset enumeration *}
    81 
    82 instantiation multiset :: (type) cancel_comm_monoid_add
    83 begin
    84 
    85 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    86 by (rule const0_in_multiset)
    87 
    88 abbreviation Mempty :: "'a multiset" ("{#}") where
    89   "Mempty \<equiv> 0"
    90 
    91 lift_definition plus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    92 by (rule union_preserves_multiset)
    93 
    94 instance
    95 by default (transfer, simp add: fun_eq_iff)+
    96 
    97 end
    98 
    99 lift_definition single :: "'a => 'a multiset" is "\<lambda>a b. if b = a then 1 else 0"
   100 by (rule only1_in_multiset)
   101 
   102 syntax
   103   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
   104 translations
   105   "{#x, xs#}" == "{#x#} + {#xs#}"
   106   "{#x#}" == "CONST single x"
   107 
   108 lemma count_empty [simp]: "count {#} a = 0"
   109   by (simp add: zero_multiset.rep_eq)
   110 
   111 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   112   by (simp add: single.rep_eq)
   113 
   114 
   115 subsection {* Basic operations *}
   116 
   117 subsubsection {* Union *}
   118 
   119 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   120   by (simp add: plus_multiset.rep_eq)
   121 
   122 
   123 subsubsection {* Difference *}
   124 
   125 instantiation multiset :: (type) comm_monoid_diff
   126 begin
   127 
   128 lift_definition minus_multiset :: "'a multiset => 'a multiset => 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
   129 by (rule diff_preserves_multiset)
   130  
   131 instance
   132 by default (transfer, simp add: fun_eq_iff)+
   133 
   134 end
   135 
   136 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   137   by (simp add: minus_multiset.rep_eq)
   138 
   139 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   140 by(simp add: multiset_eq_iff)
   141 
   142 lemma diff_cancel[simp]: "A - A = {#}"
   143 by (rule multiset_eqI) simp
   144 
   145 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
   146 by(simp add: multiset_eq_iff)
   147 
   148 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
   149 by(simp add: multiset_eq_iff)
   150 
   151 lemma insert_DiffM:
   152   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   153   by (clarsimp simp: multiset_eq_iff)
   154 
   155 lemma insert_DiffM2 [simp]:
   156   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   157   by (clarsimp simp: multiset_eq_iff)
   158 
   159 lemma diff_right_commute:
   160   "(M::'a multiset) - N - Q = M - Q - N"
   161   by (auto simp add: multiset_eq_iff)
   162 
   163 lemma diff_add:
   164   "(M::'a multiset) - (N + Q) = M - N - Q"
   165 by (simp add: multiset_eq_iff)
   166 
   167 lemma diff_union_swap:
   168   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
   169   by (auto simp add: multiset_eq_iff)
   170 
   171 lemma diff_union_single_conv:
   172   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   173   by (simp add: multiset_eq_iff)
   174 
   175 
   176 subsubsection {* Equality of multisets *}
   177 
   178 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   179   by (simp add: multiset_eq_iff)
   180 
   181 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   182   by (auto simp add: multiset_eq_iff)
   183 
   184 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   185   by (auto simp add: multiset_eq_iff)
   186 
   187 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   188   by (auto simp add: multiset_eq_iff)
   189 
   190 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
   191   by (auto simp add: multiset_eq_iff)
   192 
   193 lemma diff_single_trivial:
   194   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   195   by (auto simp add: multiset_eq_iff)
   196 
   197 lemma diff_single_eq_union:
   198   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
   199   by auto
   200 
   201 lemma union_single_eq_diff:
   202   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
   203   by (auto dest: sym)
   204 
   205 lemma union_single_eq_member:
   206   "M + {#x#} = N \<Longrightarrow> x \<in># N"
   207   by auto
   208 
   209 lemma union_is_single:
   210   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")
   211 proof
   212   assume ?rhs then show ?lhs by auto
   213 next
   214   assume ?lhs then show ?rhs
   215     by (simp add: multiset_eq_iff split:if_splits) (metis add_is_1)
   216 qed
   217 
   218 lemma single_is_union:
   219   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   220   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   221 
   222 lemma add_eq_conv_diff:
   223   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
   224 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   225 proof
   226   assume ?rhs then show ?lhs
   227   by (auto simp add: add_assoc add_commute [of "{#b#}"])
   228     (drule sym, simp add: add_assoc [symmetric])
   229 next
   230   assume ?lhs
   231   show ?rhs
   232   proof (cases "a = b")
   233     case True with `?lhs` show ?thesis by simp
   234   next
   235     case False
   236     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
   237     with False have "a \<in># N" by auto
   238     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
   239     moreover note False
   240     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
   241   qed
   242 qed
   243 
   244 lemma insert_noteq_member: 
   245   assumes BC: "B + {#b#} = C + {#c#}"
   246    and bnotc: "b \<noteq> c"
   247   shows "c \<in># B"
   248 proof -
   249   have "c \<in># C + {#c#}" by simp
   250   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   251   then have "c \<in># B + {#b#}" using BC by simp
   252   then show "c \<in># B" using nc by simp
   253 qed
   254 
   255 lemma add_eq_conv_ex:
   256   "(M + {#a#} = N + {#b#}) =
   257     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   258   by (auto simp add: add_eq_conv_diff)
   259 
   260 
   261 subsubsection {* Pointwise ordering induced by count *}
   262 
   263 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
   264 begin
   265 
   266 lift_definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" is "\<lambda> A B. (\<forall>a. A a \<le> B a)"
   267 by simp
   268 lemmas mset_le_def = less_eq_multiset_def
   269 
   270 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
   271   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
   272 
   273 instance
   274   by default (auto simp add: mset_le_def mset_less_def multiset_eq_iff intro: order_trans antisym)
   275 
   276 end
   277 
   278 lemma mset_less_eqI:
   279   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
   280   by (simp add: mset_le_def)
   281 
   282 lemma mset_le_exists_conv:
   283   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
   284 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
   285 apply (auto intro: multiset_eq_iff [THEN iffD2])
   286 done
   287 
   288 lemma mset_le_mono_add_right_cancel [simp]:
   289   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
   290   by (fact add_le_cancel_right)
   291 
   292 lemma mset_le_mono_add_left_cancel [simp]:
   293   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
   294   by (fact add_le_cancel_left)
   295 
   296 lemma mset_le_mono_add:
   297   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
   298   by (fact add_mono)
   299 
   300 lemma mset_le_add_left [simp]:
   301   "(A::'a multiset) \<le> A + B"
   302   unfolding mset_le_def by auto
   303 
   304 lemma mset_le_add_right [simp]:
   305   "B \<le> (A::'a multiset) + B"
   306   unfolding mset_le_def by auto
   307 
   308 lemma mset_le_single:
   309   "a :# B \<Longrightarrow> {#a#} \<le> B"
   310   by (simp add: mset_le_def)
   311 
   312 lemma multiset_diff_union_assoc:
   313   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
   314   by (simp add: multiset_eq_iff mset_le_def)
   315 
   316 lemma mset_le_multiset_union_diff_commute:
   317   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
   318 by (simp add: multiset_eq_iff mset_le_def)
   319 
   320 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le> M"
   321 by(simp add: mset_le_def)
   322 
   323 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   324 apply (clarsimp simp: mset_le_def mset_less_def)
   325 apply (erule_tac x=x in allE)
   326 apply auto
   327 done
   328 
   329 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   330 apply (clarsimp simp: mset_le_def mset_less_def)
   331 apply (erule_tac x = x in allE)
   332 apply auto
   333 done
   334   
   335 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
   336 apply (rule conjI)
   337  apply (simp add: mset_lessD)
   338 apply (clarsimp simp: mset_le_def mset_less_def)
   339 apply safe
   340  apply (erule_tac x = a in allE)
   341  apply (auto split: split_if_asm)
   342 done
   343 
   344 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
   345 apply (rule conjI)
   346  apply (simp add: mset_leD)
   347 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
   348 done
   349 
   350 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
   351   by (auto simp add: mset_less_def mset_le_def multiset_eq_iff)
   352 
   353 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
   354   by (auto simp: mset_le_def mset_less_def)
   355 
   356 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
   357   by simp
   358 
   359 lemma mset_less_add_bothsides:
   360   "T + {#x#} < S + {#x#} \<Longrightarrow> T < S"
   361   by (fact add_less_imp_less_right)
   362 
   363 lemma mset_less_empty_nonempty:
   364   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
   365   by (auto simp: mset_le_def mset_less_def)
   366 
   367 lemma mset_less_diff_self:
   368   "c \<in># B \<Longrightarrow> B - {#c#} < B"
   369   by (auto simp: mset_le_def mset_less_def multiset_eq_iff)
   370 
   371 
   372 subsubsection {* Intersection *}
   373 
   374 instantiation multiset :: (type) semilattice_inf
   375 begin
   376 
   377 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   378   multiset_inter_def: "inf_multiset A B = A - (A - B)"
   379 
   380 instance
   381 proof -
   382   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
   383   show "OFCLASS('a multiset, semilattice_inf_class)"
   384     by default (auto simp add: multiset_inter_def mset_le_def aux)
   385 qed
   386 
   387 end
   388 
   389 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
   390   "multiset_inter \<equiv> inf"
   391 
   392 lemma multiset_inter_count [simp]:
   393   "count (A #\<inter> B) x = min (count A x) (count B x)"
   394   by (simp add: multiset_inter_def)
   395 
   396 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   397   by (rule multiset_eqI) auto
   398 
   399 lemma multiset_union_diff_commute:
   400   assumes "B #\<inter> C = {#}"
   401   shows "A + B - C = A - C + B"
   402 proof (rule multiset_eqI)
   403   fix x
   404   from assms have "min (count B x) (count C x) = 0"
   405     by (auto simp add: multiset_eq_iff)
   406   then have "count B x = 0 \<or> count C x = 0"
   407     by auto
   408   then show "count (A + B - C) x = count (A - C + B) x"
   409     by auto
   410 qed
   411 
   412 
   413 subsubsection {* Filter (with comprehension syntax) *}
   414 
   415 text {* Multiset comprehension *}
   416 
   417 lift_definition filter :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
   418 by (rule filter_preserves_multiset)
   419 
   420 hide_const (open) filter
   421 
   422 lemma count_filter [simp]:
   423   "count (Multiset.filter P M) a = (if P a then count M a else 0)"
   424   by (simp add: filter.rep_eq)
   425 
   426 lemma filter_empty [simp]:
   427   "Multiset.filter P {#} = {#}"
   428   by (rule multiset_eqI) simp
   429 
   430 lemma filter_single [simp]:
   431   "Multiset.filter P {#x#} = (if P x then {#x#} else {#})"
   432   by (rule multiset_eqI) simp
   433 
   434 lemma filter_union [simp]:
   435   "Multiset.filter P (M + N) = Multiset.filter P M + Multiset.filter P N"
   436   by (rule multiset_eqI) simp
   437 
   438 lemma filter_diff [simp]:
   439   "Multiset.filter P (M - N) = Multiset.filter P M - Multiset.filter P N"
   440   by (rule multiset_eqI) simp
   441 
   442 lemma filter_inter [simp]:
   443   "Multiset.filter P (M #\<inter> N) = Multiset.filter P M #\<inter> Multiset.filter P N"
   444   by (rule multiset_eqI) simp
   445 
   446 syntax
   447   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ :# _./ _#})")
   448 syntax (xsymbol)
   449   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{# _ \<in># _./ _#})")
   450 translations
   451   "{#x \<in># M. P#}" == "CONST Multiset.filter (\<lambda>x. P) M"
   452 
   453 
   454 subsubsection {* Set of elements *}
   455 
   456 definition set_of :: "'a multiset => 'a set" where
   457   "set_of M = {x. x :# M}"
   458 
   459 lemma set_of_empty [simp]: "set_of {#} = {}"
   460 by (simp add: set_of_def)
   461 
   462 lemma set_of_single [simp]: "set_of {#b#} = {b}"
   463 by (simp add: set_of_def)
   464 
   465 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
   466 by (auto simp add: set_of_def)
   467 
   468 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
   469 by (auto simp add: set_of_def multiset_eq_iff)
   470 
   471 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
   472 by (auto simp add: set_of_def)
   473 
   474 lemma set_of_filter [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
   475 by (auto simp add: set_of_def)
   476 
   477 lemma finite_set_of [iff]: "finite (set_of M)"
   478   using count [of M] by (simp add: multiset_def set_of_def)
   479 
   480 lemma finite_Collect_mem [iff]: "finite {x. x :# M}"
   481   unfolding set_of_def[symmetric] by simp
   482 
   483 subsubsection {* Size *}
   484 
   485 instantiation multiset :: (type) size
   486 begin
   487 
   488 definition size_def:
   489   "size M = setsum (count M) (set_of M)"
   490 
   491 instance ..
   492 
   493 end
   494 
   495 lemma size_empty [simp]: "size {#} = 0"
   496 by (simp add: size_def)
   497 
   498 lemma size_single [simp]: "size {#b#} = 1"
   499 by (simp add: size_def)
   500 
   501 lemma setsum_count_Int:
   502   "finite A ==> setsum (count N) (A \<inter> set_of N) = setsum (count N) A"
   503 apply (induct rule: finite_induct)
   504  apply simp
   505 apply (simp add: Int_insert_left set_of_def)
   506 done
   507 
   508 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   509 apply (unfold size_def)
   510 apply (subgoal_tac "count (M + N) = (\<lambda>a. count M a + count N a)")
   511  prefer 2
   512  apply (rule ext, simp)
   513 apply (simp (no_asm_simp) add: setsum_Un_nat setsum_addf setsum_count_Int)
   514 apply (subst Int_commute)
   515 apply (simp (no_asm_simp) add: setsum_count_Int)
   516 done
   517 
   518 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   519 by (auto simp add: size_def multiset_eq_iff)
   520 
   521 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   522 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   523 
   524 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
   525 apply (unfold size_def)
   526 apply (drule setsum_SucD)
   527 apply auto
   528 done
   529 
   530 lemma size_eq_Suc_imp_eq_union:
   531   assumes "size M = Suc n"
   532   shows "\<exists>a N. M = N + {#a#}"
   533 proof -
   534   from assms obtain a where "a \<in># M"
   535     by (erule size_eq_Suc_imp_elem [THEN exE])
   536   then have "M = M - {#a#} + {#a#}" by simp
   537   then show ?thesis by blast
   538 qed
   539 
   540 
   541 subsection {* Induction and case splits *}
   542 
   543 theorem multiset_induct [case_names empty add, induct type: multiset]:
   544   assumes empty: "P {#}"
   545   assumes add: "\<And>M x. P M \<Longrightarrow> P (M + {#x#})"
   546   shows "P M"
   547 proof (induct n \<equiv> "size M" arbitrary: M)
   548   case 0 thus "P M" by (simp add: empty)
   549 next
   550   case (Suc k)
   551   obtain N x where "M = N + {#x#}"
   552     using `Suc k = size M` [symmetric]
   553     using size_eq_Suc_imp_eq_union by fast
   554   with Suc add show "P M" by simp
   555 qed
   556 
   557 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   558 by (induct M) auto
   559 
   560 lemma multiset_cases [cases type, case_names empty add]:
   561 assumes em:  "M = {#} \<Longrightarrow> P"
   562 assumes add: "\<And>N x. M = N + {#x#} \<Longrightarrow> P"
   563 shows "P"
   564 using assms by (induct M) simp_all
   565 
   566 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   567 by (rule_tac x="M - {#x#}" in exI, simp)
   568 
   569 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   570 by (cases "B = {#}") (auto dest: multi_member_split)
   571 
   572 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
   573 apply (subst multiset_eq_iff)
   574 apply auto
   575 done
   576 
   577 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
   578 proof (induct A arbitrary: B)
   579   case (empty M)
   580   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
   581   then obtain M' x where "M = M' + {#x#}" 
   582     by (blast dest: multi_nonempty_split)
   583   then show ?case by simp
   584 next
   585   case (add S x T)
   586   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
   587   have SxsubT: "S + {#x#} < T" by fact
   588   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
   589   then obtain T' where T: "T = T' + {#x#}" 
   590     by (blast dest: multi_member_split)
   591   then have "S < T'" using SxsubT 
   592     by (blast intro: mset_less_add_bothsides)
   593   then have "size S < size T'" using IH by simp
   594   then show ?case using T by simp
   595 qed
   596 
   597 
   598 subsubsection {* Strong induction and subset induction for multisets *}
   599 
   600 text {* Well-foundedness of proper subset operator: *}
   601 
   602 text {* proper multiset subset *}
   603 
   604 definition
   605   mset_less_rel :: "('a multiset * 'a multiset) set" where
   606   "mset_less_rel = {(A,B). A < B}"
   607 
   608 lemma multiset_add_sub_el_shuffle: 
   609   assumes "c \<in># B" and "b \<noteq> c" 
   610   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
   611 proof -
   612   from `c \<in># B` obtain A where B: "B = A + {#c#}" 
   613     by (blast dest: multi_member_split)
   614   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
   615   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}" 
   616     by (simp add: add_ac)
   617   then show ?thesis using B by simp
   618 qed
   619 
   620 lemma wf_mset_less_rel: "wf mset_less_rel"
   621 apply (unfold mset_less_rel_def)
   622 apply (rule wf_measure [THEN wf_subset, where f1=size])
   623 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
   624 done
   625 
   626 text {* The induction rules: *}
   627 
   628 lemma full_multiset_induct [case_names less]:
   629 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
   630 shows "P B"
   631 apply (rule wf_mset_less_rel [THEN wf_induct])
   632 apply (rule ih, auto simp: mset_less_rel_def)
   633 done
   634 
   635 lemma multi_subset_induct [consumes 2, case_names empty add]:
   636 assumes "F \<le> A"
   637   and empty: "P {#}"
   638   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
   639 shows "P F"
   640 proof -
   641   from `F \<le> A`
   642   show ?thesis
   643   proof (induct F)
   644     show "P {#}" by fact
   645   next
   646     fix x F
   647     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
   648     show "P (F + {#x#})"
   649     proof (rule insert)
   650       from i show "x \<in># A" by (auto dest: mset_le_insertD)
   651       from i have "F \<le> A" by (auto dest: mset_le_insertD)
   652       with P show "P F" .
   653     qed
   654   qed
   655 qed
   656 
   657 
   658 subsection {* The fold combinator *}
   659 
   660 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
   661 where
   662   "fold f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_of M)"
   663 
   664 lemma fold_mset_empty [simp]:
   665   "fold f s {#} = s"
   666   by (simp add: fold_def)
   667 
   668 context comp_fun_commute
   669 begin
   670 
   671 lemma fold_mset_insert:
   672   "fold f s (M + {#x#}) = f x (fold f s M)"
   673 proof -
   674   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
   675     by (fact comp_fun_commute_funpow)
   676   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (M + {#x#}) y"
   677     by (fact comp_fun_commute_funpow)
   678   show ?thesis
   679   proof (cases "x \<in> set_of M")
   680     case False
   681     then have *: "count (M + {#x#}) x = 1" by simp
   682     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s (set_of M) =
   683       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_of M)"
   684       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   685     with False * show ?thesis
   686       by (simp add: fold_def del: count_union)
   687   next
   688     case True
   689     def N \<equiv> "set_of M - {x}"
   690     from N_def True have *: "set_of M = insert x N" "x \<notin> N" "finite N" by auto
   691     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (M + {#x#}) y) s N =
   692       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
   693       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
   694     with * show ?thesis by (simp add: fold_def del: count_union) simp
   695   qed
   696 qed
   697 
   698 corollary fold_mset_single [simp]:
   699   "fold f s {#x#} = f x s"
   700 proof -
   701   have "fold f s ({#} + {#x#}) = f x s" by (simp only: fold_mset_insert) simp
   702   then show ?thesis by simp
   703 qed
   704 
   705 lemma fold_mset_fun_left_comm:
   706   "f x (fold f s M) = fold f (f x s) M"
   707   by (induct M) (simp_all add: fold_mset_insert fun_left_comm)
   708 
   709 lemma fold_mset_union [simp]:
   710   "fold f s (M + N) = fold f (fold f s M) N"
   711 proof (induct M)
   712   case empty then show ?case by simp
   713 next
   714   case (add M x)
   715   have "M + {#x#} + N = (M + N) + {#x#}"
   716     by (simp add: add_ac)
   717   with add show ?case by (simp add: fold_mset_insert fold_mset_fun_left_comm)
   718 qed
   719 
   720 lemma fold_mset_fusion:
   721   assumes "comp_fun_commute g"
   722   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold g w A) = fold f (h w) A" (is "PROP ?P")
   723 proof -
   724   interpret comp_fun_commute g by (fact assms)
   725   show "PROP ?P" by (induct A) auto
   726 qed
   727 
   728 end
   729 
   730 text {*
   731   A note on code generation: When defining some function containing a
   732   subterm @{term "fold F"}, code generation is not automatic. When
   733   interpreting locale @{text left_commutative} with @{text F}, the
   734   would be code thms for @{const fold} become thms like
   735   @{term "fold F z {#} = z"} where @{text F} is not a pattern but
   736   contains defined symbols, i.e.\ is not a code thm. Hence a separate
   737   constant with its own code thms needs to be introduced for @{text
   738   F}. See the image operator below.
   739 *}
   740 
   741 
   742 subsection {* Image *}
   743 
   744 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
   745   "image_mset f = fold (plus o single o f) {#}"
   746 
   747 lemma comp_fun_commute_mset_image:
   748   "comp_fun_commute (plus o single o f)"
   749 proof
   750 qed (simp add: add_ac fun_eq_iff)
   751 
   752 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
   753   by (simp add: image_mset_def)
   754 
   755 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
   756 proof -
   757   interpret comp_fun_commute "plus o single o f"
   758     by (fact comp_fun_commute_mset_image)
   759   show ?thesis by (simp add: image_mset_def)
   760 qed
   761 
   762 lemma image_mset_union [simp]:
   763   "image_mset f (M + N) = image_mset f M + image_mset f N"
   764 proof -
   765   interpret comp_fun_commute "plus o single o f"
   766     by (fact comp_fun_commute_mset_image)
   767   show ?thesis by (induct N) (simp_all add: image_mset_def add_ac)
   768 qed
   769 
   770 corollary image_mset_insert:
   771   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
   772   by simp
   773 
   774 lemma set_of_image_mset [simp]:
   775   "set_of (image_mset f M) = image f (set_of M)"
   776   by (induct M) simp_all
   777 
   778 lemma size_image_mset [simp]:
   779   "size (image_mset f M) = size M"
   780   by (induct M) simp_all
   781 
   782 lemma image_mset_is_empty_iff [simp]:
   783   "image_mset f M = {#} \<longleftrightarrow> M = {#}"
   784   by (cases M) auto
   785 
   786 syntax
   787   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
   788       ("({#_/. _ :# _#})")
   789 translations
   790   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
   791 
   792 syntax
   793   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
   794       ("({#_/ | _ :# _./ _#})")
   795 translations
   796   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
   797 
   798 text {*
   799   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
   800   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
   801   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
   802   @{term "{#x+x|x:#M. x<c#}"}.
   803 *}
   804 
   805 enriched_type image_mset: image_mset
   806 proof -
   807   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
   808   proof
   809     fix A
   810     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
   811       by (induct A) simp_all
   812   qed
   813   show "image_mset id = id"
   814   proof
   815     fix A
   816     show "image_mset id A = id A"
   817       by (induct A) simp_all
   818   qed
   819 qed
   820 
   821 declare image_mset.identity [simp]
   822 
   823 
   824 subsection {* Further conversions *}
   825 
   826 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
   827   "multiset_of [] = {#}" |
   828   "multiset_of (a # x) = multiset_of x + {# a #}"
   829 
   830 lemma in_multiset_in_set:
   831   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
   832   by (induct xs) simp_all
   833 
   834 lemma count_multiset_of:
   835   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   836   by (induct xs) simp_all
   837 
   838 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
   839 by (induct x) auto
   840 
   841 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
   842 by (induct x) auto
   843 
   844 lemma set_of_multiset_of[simp]: "set_of (multiset_of x) = set x"
   845 by (induct x) auto
   846 
   847 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
   848 by (induct xs) auto
   849 
   850 lemma size_multiset_of [simp]: "size (multiset_of xs) = length xs"
   851   by (induct xs) simp_all
   852 
   853 lemma multiset_of_append [simp]:
   854   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
   855   by (induct xs arbitrary: ys) (auto simp: add_ac)
   856 
   857 lemma multiset_of_filter:
   858   "multiset_of (filter P xs) = {#x :# multiset_of xs. P x #}"
   859   by (induct xs) simp_all
   860 
   861 lemma multiset_of_rev [simp]:
   862   "multiset_of (rev xs) = multiset_of xs"
   863   by (induct xs) simp_all
   864 
   865 lemma surj_multiset_of: "surj multiset_of"
   866 apply (unfold surj_def)
   867 apply (rule allI)
   868 apply (rule_tac M = y in multiset_induct)
   869  apply auto
   870 apply (rule_tac x = "x # xa" in exI)
   871 apply auto
   872 done
   873 
   874 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
   875 by (induct x) auto
   876 
   877 lemma distinct_count_atmost_1:
   878   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
   879 apply (induct x, simp, rule iffI, simp_all)
   880 apply (rule conjI)
   881 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
   882 apply (erule_tac x = a in allE, simp, clarify)
   883 apply (erule_tac x = aa in allE, simp)
   884 done
   885 
   886 lemma multiset_of_eq_setD:
   887   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
   888 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
   889 
   890 lemma set_eq_iff_multiset_of_eq_distinct:
   891   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   892     (set x = set y) = (multiset_of x = multiset_of y)"
   893 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
   894 
   895 lemma set_eq_iff_multiset_of_remdups_eq:
   896    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
   897 apply (rule iffI)
   898 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
   899 apply (drule distinct_remdups [THEN distinct_remdups
   900       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
   901 apply simp
   902 done
   903 
   904 lemma multiset_of_compl_union [simp]:
   905   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
   906   by (induct xs) (auto simp: add_ac)
   907 
   908 lemma count_multiset_of_length_filter:
   909   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
   910   by (induct xs) auto
   911 
   912 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
   913 apply (induct ls arbitrary: i)
   914  apply simp
   915 apply (case_tac i)
   916  apply auto
   917 done
   918 
   919 lemma multiset_of_remove1[simp]:
   920   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
   921 by (induct xs) (auto simp add: multiset_eq_iff)
   922 
   923 lemma multiset_of_eq_length:
   924   assumes "multiset_of xs = multiset_of ys"
   925   shows "length xs = length ys"
   926   using assms by (metis size_multiset_of)
   927 
   928 lemma multiset_of_eq_length_filter:
   929   assumes "multiset_of xs = multiset_of ys"
   930   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
   931   using assms by (metis count_multiset_of)
   932 
   933 lemma fold_multiset_equiv:
   934   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
   935     and equiv: "multiset_of xs = multiset_of ys"
   936   shows "List.fold f xs = List.fold f ys"
   937 using f equiv [symmetric]
   938 proof (induct xs arbitrary: ys)
   939   case Nil then show ?case by simp
   940 next
   941   case (Cons x xs)
   942   then have *: "set ys = set (x # xs)" by (blast dest: multiset_of_eq_setD)
   943   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x" 
   944     by (rule Cons.prems(1)) (simp_all add: *)
   945   moreover from * have "x \<in> set ys" by simp
   946   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x" by (fact fold_remove1_split)
   947   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)" by (auto intro: Cons.hyps)
   948   ultimately show ?case by simp
   949 qed
   950 
   951 lemma multiset_of_insort [simp]:
   952   "multiset_of (insort x xs) = multiset_of xs + {#x#}"
   953   by (induct xs) (simp_all add: ac_simps)
   954 
   955 definition multiset_of_set :: "'a set \<Rightarrow> 'a multiset"
   956 where
   957   "multiset_of_set = folding.F (\<lambda>x M. {#x#} + M) {#}"
   958 
   959 interpretation multiset_of_set!: folding "\<lambda>x M. {#x#} + M" "{#}"
   960 where
   961   "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set"
   962 proof -
   963   interpret comp_fun_commute "\<lambda>x M. {#x#} + M" by default (simp add: fun_eq_iff ac_simps)
   964   show "folding (\<lambda>x M. {#x#} + M)" by default (fact comp_fun_commute)
   965   from multiset_of_set_def show "folding.F (\<lambda>x M. {#x#} + M) {#} = multiset_of_set" ..
   966 qed
   967 
   968 context linorder
   969 begin
   970 
   971 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
   972 where
   973   "sorted_list_of_multiset M = fold insort [] M"
   974 
   975 lemma sorted_list_of_multiset_empty [simp]:
   976   "sorted_list_of_multiset {#} = []"
   977   by (simp add: sorted_list_of_multiset_def)
   978 
   979 lemma sorted_list_of_multiset_singleton [simp]:
   980   "sorted_list_of_multiset {#x#} = [x]"
   981 proof -
   982   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
   983   show ?thesis by (simp add: sorted_list_of_multiset_def)
   984 qed
   985 
   986 lemma sorted_list_of_multiset_insert [simp]:
   987   "sorted_list_of_multiset (M + {#x#}) = List.insort x (sorted_list_of_multiset M)"
   988 proof -
   989   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
   990   show ?thesis by (simp add: sorted_list_of_multiset_def)
   991 qed
   992 
   993 end
   994 
   995 lemma multiset_of_sorted_list_of_multiset [simp]:
   996   "multiset_of (sorted_list_of_multiset M) = M"
   997   by (induct M) simp_all
   998 
   999 lemma sorted_list_of_multiset_multiset_of [simp]:
  1000   "sorted_list_of_multiset (multiset_of xs) = sort xs"
  1001   by (induct xs) simp_all
  1002 
  1003 lemma finite_set_of_multiset_of_set:
  1004   assumes "finite A"
  1005   shows "set_of (multiset_of_set A) = A"
  1006   using assms by (induct A) simp_all
  1007 
  1008 lemma infinite_set_of_multiset_of_set:
  1009   assumes "\<not> finite A"
  1010   shows "set_of (multiset_of_set A) = {}"
  1011   using assms by simp
  1012 
  1013 lemma set_sorted_list_of_multiset [simp]:
  1014   "set (sorted_list_of_multiset M) = set_of M"
  1015   by (induct M) (simp_all add: set_insort)
  1016 
  1017 lemma sorted_list_of_multiset_of_set [simp]:
  1018   "sorted_list_of_multiset (multiset_of_set A) = sorted_list_of_set A"
  1019   by (cases "finite A") (induct A rule: finite_induct, simp_all add: ac_simps)
  1020 
  1021 
  1022 subsection {* Big operators *}
  1023 
  1024 no_notation times (infixl "*" 70)
  1025 no_notation Groups.one ("1")
  1026 
  1027 locale comm_monoid_mset = comm_monoid
  1028 begin
  1029 
  1030 definition F :: "'a multiset \<Rightarrow> 'a"
  1031 where
  1032   eq_fold: "F M = Multiset.fold f 1 M"
  1033 
  1034 lemma empty [simp]:
  1035   "F {#} = 1"
  1036   by (simp add: eq_fold)
  1037 
  1038 lemma singleton [simp]:
  1039   "F {#x#} = x"
  1040 proof -
  1041   interpret comp_fun_commute
  1042     by default (simp add: fun_eq_iff left_commute)
  1043   show ?thesis by (simp add: eq_fold)
  1044 qed
  1045 
  1046 lemma union [simp]:
  1047   "F (M + N) = F M * F N"
  1048 proof -
  1049   interpret comp_fun_commute f
  1050     by default (simp add: fun_eq_iff left_commute)
  1051   show ?thesis by (induct N) (simp_all add: left_commute eq_fold)
  1052 qed
  1053 
  1054 end
  1055 
  1056 notation times (infixl "*" 70)
  1057 notation Groups.one ("1")
  1058 
  1059 definition (in comm_monoid_add) msetsum :: "'a multiset \<Rightarrow> 'a"
  1060 where
  1061   "msetsum = comm_monoid_mset.F plus 0"
  1062 
  1063 definition (in comm_monoid_mult) msetprod :: "'a multiset \<Rightarrow> 'a"
  1064 where
  1065   "msetprod = comm_monoid_mset.F times 1"
  1066 
  1067 sublocale comm_monoid_add < msetsum!: comm_monoid_mset plus 0
  1068 where
  1069   "comm_monoid_mset.F plus 0 = msetsum"
  1070 proof -
  1071   show "comm_monoid_mset plus 0" ..
  1072   from msetsum_def show "comm_monoid_mset.F plus 0 = msetsum" ..
  1073 qed
  1074 
  1075 context comm_monoid_add
  1076 begin
  1077 
  1078 lemma setsum_unfold_msetsum:
  1079   "setsum f A = msetsum (image_mset f (multiset_of_set A))"
  1080   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1081 
  1082 abbreviation msetsum_image :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b multiset \<Rightarrow> 'a"
  1083 where
  1084   "msetsum_image f M \<equiv> msetsum (image_mset f M)"
  1085 
  1086 end
  1087 
  1088 syntax
  1089   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1090       ("(3SUM _:#_. _)" [0, 51, 10] 10)
  1091 
  1092 syntax (xsymbols)
  1093   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1094       ("(3\<Sum>_:#_. _)" [0, 51, 10] 10)
  1095 
  1096 syntax (HTML output)
  1097   "_msetsum_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add" 
  1098       ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  1099 
  1100 translations
  1101   "SUM i :# A. b" == "CONST msetsum_image (\<lambda>i. b) A"
  1102 
  1103 sublocale comm_monoid_mult < msetprod!: comm_monoid_mset times 1
  1104 where
  1105   "comm_monoid_mset.F times 1 = msetprod"
  1106 proof -
  1107   show "comm_monoid_mset times 1" ..
  1108   from msetprod_def show "comm_monoid_mset.F times 1 = msetprod" ..
  1109 qed
  1110 
  1111 context comm_monoid_mult
  1112 begin
  1113 
  1114 lemma msetprod_empty:
  1115   "msetprod {#} = 1"
  1116   by (fact msetprod.empty)
  1117 
  1118 lemma msetprod_singleton:
  1119   "msetprod {#x#} = x"
  1120   by (fact msetprod.singleton)
  1121 
  1122 lemma msetprod_Un:
  1123   "msetprod (A + B) = msetprod A * msetprod B" 
  1124   by (fact msetprod.union)
  1125 
  1126 lemma setprod_unfold_msetprod:
  1127   "setprod f A = msetprod (image_mset f (multiset_of_set A))"
  1128   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  1129 
  1130 lemma msetprod_multiplicity:
  1131   "msetprod M = setprod (\<lambda>x. x ^ count M x) (set_of M)"
  1132   by (simp add: Multiset.fold_def setprod.eq_fold msetprod.eq_fold funpow_times_power comp_def)
  1133 
  1134 abbreviation msetprod_image :: "('b \<Rightarrow> 'a) \<Rightarrow> 'b multiset \<Rightarrow> 'a"
  1135 where
  1136   "msetprod_image f M \<equiv> msetprod (image_mset f M)"
  1137 
  1138 end
  1139 
  1140 syntax
  1141   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1142       ("(3PROD _:#_. _)" [0, 51, 10] 10)
  1143 
  1144 syntax (xsymbols)
  1145   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1146       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1147 
  1148 syntax (HTML output)
  1149   "_msetprod_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult" 
  1150       ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  1151 
  1152 translations
  1153   "PROD i :# A. b" == "CONST msetprod_image (\<lambda>i. b) A"
  1154 
  1155 lemma (in comm_semiring_1) dvd_msetprod:
  1156   assumes "x \<in># A"
  1157   shows "x dvd msetprod A"
  1158 proof -
  1159   from assms have "A = (A - {#x#}) + {#x#}" by simp
  1160   then obtain B where "A = B + {#x#}" ..
  1161   then show ?thesis by simp
  1162 qed
  1163 
  1164 
  1165 subsection {* Cardinality *}
  1166 
  1167 definition mcard :: "'a multiset \<Rightarrow> nat"
  1168 where
  1169   "mcard = msetsum \<circ> image_mset (\<lambda>_. 1)"
  1170 
  1171 lemma mcard_empty [simp]:
  1172   "mcard {#} = 0"
  1173   by (simp add: mcard_def)
  1174 
  1175 lemma mcard_singleton [simp]:
  1176   "mcard {#a#} = Suc 0"
  1177   by (simp add: mcard_def)
  1178 
  1179 lemma mcard_plus [simp]:
  1180   "mcard (M + N) = mcard M + mcard N"
  1181   by (simp add: mcard_def)
  1182 
  1183 lemma mcard_empty_iff [simp]:
  1184   "mcard M = 0 \<longleftrightarrow> M = {#}"
  1185   by (induct M) simp_all
  1186 
  1187 lemma mcard_unfold_setsum:
  1188   "mcard M = setsum (count M) (set_of M)"
  1189 proof (induct M)
  1190   case empty then show ?case by simp
  1191 next
  1192   case (add M x) then show ?case
  1193     by (cases "x \<in> set_of M")
  1194       (simp_all del: mem_set_of_iff add: setsum.distrib setsum.delta' insert_absorb, simp)
  1195 qed
  1196 
  1197 
  1198 subsection {* Alternative representations *}
  1199 
  1200 subsubsection {* Lists *}
  1201 
  1202 context linorder
  1203 begin
  1204 
  1205 lemma multiset_of_insort [simp]:
  1206   "multiset_of (insort_key k x xs) = {#x#} + multiset_of xs"
  1207   by (induct xs) (simp_all add: ac_simps)
  1208  
  1209 lemma multiset_of_sort [simp]:
  1210   "multiset_of (sort_key k xs) = multiset_of xs"
  1211   by (induct xs) (simp_all add: ac_simps)
  1212 
  1213 text {*
  1214   This lemma shows which properties suffice to show that a function
  1215   @{text "f"} with @{text "f xs = ys"} behaves like sort.
  1216 *}
  1217 
  1218 lemma properties_for_sort_key:
  1219   assumes "multiset_of ys = multiset_of xs"
  1220   and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  1221   and "sorted (map f ys)"
  1222   shows "sort_key f xs = ys"
  1223 using assms
  1224 proof (induct xs arbitrary: ys)
  1225   case Nil then show ?case by simp
  1226 next
  1227   case (Cons x xs)
  1228   from Cons.prems(2) have
  1229     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  1230     by (simp add: filter_remove1)
  1231   with Cons.prems have "sort_key f xs = remove1 x ys"
  1232     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  1233   moreover from Cons.prems have "x \<in> set ys"
  1234     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
  1235   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  1236 qed
  1237 
  1238 lemma properties_for_sort:
  1239   assumes multiset: "multiset_of ys = multiset_of xs"
  1240   and "sorted ys"
  1241   shows "sort xs = ys"
  1242 proof (rule properties_for_sort_key)
  1243   from multiset show "multiset_of ys = multiset_of xs" .
  1244   from `sorted ys` show "sorted (map (\<lambda>x. x) ys)" by simp
  1245   from multiset have "\<And>k. length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)"
  1246     by (rule multiset_of_eq_length_filter)
  1247   then have "\<And>k. replicate (length (filter (\<lambda>y. k = y) ys)) k = replicate (length (filter (\<lambda>x. k = x) xs)) k"
  1248     by simp
  1249   then show "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs"
  1250     by (simp add: replicate_length_filter)
  1251 qed
  1252 
  1253 lemma sort_key_by_quicksort:
  1254   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  1255     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  1256     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  1257 proof (rule properties_for_sort_key)
  1258   show "multiset_of ?rhs = multiset_of ?lhs"
  1259     by (rule multiset_eqI) (auto simp add: multiset_of_filter)
  1260 next
  1261   show "sorted (map f ?rhs)"
  1262     by (auto simp add: sorted_append intro: sorted_map_same)
  1263 next
  1264   fix l
  1265   assume "l \<in> set ?rhs"
  1266   let ?pivot = "f (xs ! (length xs div 2))"
  1267   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  1268   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  1269     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  1270   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  1271   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  1272   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  1273     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  1274   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  1275   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  1276   proof (cases "f l" ?pivot rule: linorder_cases)
  1277     case less
  1278     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  1279     with less show ?thesis
  1280       by (simp add: filter_sort [symmetric] ** ***)
  1281   next
  1282     case equal then show ?thesis
  1283       by (simp add: * less_le)
  1284   next
  1285     case greater
  1286     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  1287     with greater show ?thesis
  1288       by (simp add: filter_sort [symmetric] ** ***)
  1289   qed
  1290 qed
  1291 
  1292 lemma sort_by_quicksort:
  1293   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  1294     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  1295     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  1296   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  1297 
  1298 text {* A stable parametrized quicksort *}
  1299 
  1300 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  1301   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  1302 
  1303 lemma part_code [code]:
  1304   "part f pivot [] = ([], [], [])"
  1305   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  1306      if x' < pivot then (x # lts, eqs, gts)
  1307      else if x' > pivot then (lts, eqs, x # gts)
  1308      else (lts, x # eqs, gts))"
  1309   by (auto simp add: part_def Let_def split_def)
  1310 
  1311 lemma sort_key_by_quicksort_code [code]:
  1312   "sort_key f xs = (case xs of [] \<Rightarrow> []
  1313     | [x] \<Rightarrow> xs
  1314     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  1315     | _ \<Rightarrow> (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1316        in sort_key f lts @ eqs @ sort_key f gts))"
  1317 proof (cases xs)
  1318   case Nil then show ?thesis by simp
  1319 next
  1320   case (Cons _ ys) note hyps = Cons show ?thesis
  1321   proof (cases ys)
  1322     case Nil with hyps show ?thesis by simp
  1323   next
  1324     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  1325     proof (cases zs)
  1326       case Nil with hyps show ?thesis by auto
  1327     next
  1328       case Cons 
  1329       from sort_key_by_quicksort [of f xs]
  1330       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  1331         in sort_key f lts @ eqs @ sort_key f gts)"
  1332       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  1333       with hyps Cons show ?thesis by (simp only: list.cases)
  1334     qed
  1335   qed
  1336 qed
  1337 
  1338 end
  1339 
  1340 hide_const (open) part
  1341 
  1342 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
  1343   by (induct xs) (auto intro: order_trans)
  1344 
  1345 lemma multiset_of_update:
  1346   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
  1347 proof (induct ls arbitrary: i)
  1348   case Nil then show ?case by simp
  1349 next
  1350   case (Cons x xs)
  1351   show ?case
  1352   proof (cases i)
  1353     case 0 then show ?thesis by simp
  1354   next
  1355     case (Suc i')
  1356     with Cons show ?thesis
  1357       apply simp
  1358       apply (subst add_assoc)
  1359       apply (subst add_commute [of "{#v#}" "{#x#}"])
  1360       apply (subst add_assoc [symmetric])
  1361       apply simp
  1362       apply (rule mset_le_multiset_union_diff_commute)
  1363       apply (simp add: mset_le_single nth_mem_multiset_of)
  1364       done
  1365   qed
  1366 qed
  1367 
  1368 lemma multiset_of_swap:
  1369   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1370     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
  1371   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
  1372 
  1373 
  1374 subsubsection {* Association lists -- including code generation *}
  1375 
  1376 text {* Preliminaries *}
  1377 
  1378 text {* Raw operations on lists *}
  1379 
  1380 definition join_raw :: "('key \<Rightarrow> 'val \<times> 'val \<Rightarrow> 'val) \<Rightarrow> ('key \<times> 'val) list \<Rightarrow> ('key \<times> 'val) list \<Rightarrow> ('key \<times> 'val) list"
  1381 where
  1382   "join_raw f xs ys = foldr (\<lambda>(k, v). map_default k v (%v'. f k (v', v))) ys xs"
  1383 
  1384 lemma join_raw_Nil [simp]:
  1385   "join_raw f xs [] = xs"
  1386 by (simp add: join_raw_def)
  1387 
  1388 lemma join_raw_Cons [simp]:
  1389   "join_raw f xs ((k, v) # ys) = map_default k v (%v'. f k (v', v)) (join_raw f xs ys)"
  1390 by (simp add: join_raw_def)
  1391 
  1392 lemma map_of_join_raw:
  1393   assumes "distinct (map fst ys)"
  1394   shows "map_of (join_raw f xs ys) x = (case map_of xs x of None => map_of ys x | Some v =>
  1395     (case map_of ys x of None => Some v | Some v' => Some (f x (v, v'))))"
  1396 using assms
  1397 apply (induct ys)
  1398 apply (auto simp add: map_of_map_default split: option.split)
  1399 apply (metis map_of_eq_None_iff option.simps(2) weak_map_of_SomeI)
  1400 by (metis Some_eq_map_of_iff map_of_eq_None_iff option.simps(2))
  1401 
  1402 lemma distinct_join_raw:
  1403   assumes "distinct (map fst xs)"
  1404   shows "distinct (map fst (join_raw f xs ys))"
  1405 using assms
  1406 proof (induct ys)
  1407   case (Cons y ys)
  1408   thus ?case by (cases y) (simp add: distinct_map_default)
  1409 qed auto
  1410 
  1411 definition
  1412   "subtract_entries_raw xs ys = foldr (%(k, v). AList.map_entry k (%v'. v' - v)) ys xs"
  1413 
  1414 lemma map_of_subtract_entries_raw:
  1415   assumes "distinct (map fst ys)"
  1416   shows "map_of (subtract_entries_raw xs ys) x = (case map_of xs x of None => None | Some v =>
  1417     (case map_of ys x of None => Some v | Some v' => Some (v - v')))"
  1418 using assms unfolding subtract_entries_raw_def
  1419 apply (induct ys)
  1420 apply auto
  1421 apply (simp split: option.split)
  1422 apply (simp add: map_of_map_entry)
  1423 apply (auto split: option.split)
  1424 apply (metis map_of_eq_None_iff option.simps(3) option.simps(4))
  1425 by (metis map_of_eq_None_iff option.simps(4) option.simps(5))
  1426 
  1427 lemma distinct_subtract_entries_raw:
  1428   assumes "distinct (map fst xs)"
  1429   shows "distinct (map fst (subtract_entries_raw xs ys))"
  1430 using assms
  1431 unfolding subtract_entries_raw_def by (induct ys) (auto simp add: distinct_map_entry)
  1432 
  1433 text {* Operations on alists with distinct keys *}
  1434 
  1435 lift_definition join :: "('a \<Rightarrow> 'b \<times> 'b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) alist \<Rightarrow> ('a, 'b) alist \<Rightarrow> ('a, 'b) alist" 
  1436 is join_raw
  1437 by (simp add: distinct_join_raw)
  1438 
  1439 lift_definition subtract_entries :: "('a, ('b :: minus)) alist \<Rightarrow> ('a, 'b) alist \<Rightarrow> ('a, 'b) alist"
  1440 is subtract_entries_raw 
  1441 by (simp add: distinct_subtract_entries_raw)
  1442 
  1443 text {* Implementing multisets by means of association lists *}
  1444 
  1445 definition count_of :: "('a \<times> nat) list \<Rightarrow> 'a \<Rightarrow> nat" where
  1446   "count_of xs x = (case map_of xs x of None \<Rightarrow> 0 | Some n \<Rightarrow> n)"
  1447 
  1448 lemma count_of_multiset:
  1449   "count_of xs \<in> multiset"
  1450 proof -
  1451   let ?A = "{x::'a. 0 < (case map_of xs x of None \<Rightarrow> 0\<Colon>nat | Some (n\<Colon>nat) \<Rightarrow> n)}"
  1452   have "?A \<subseteq> dom (map_of xs)"
  1453   proof
  1454     fix x
  1455     assume "x \<in> ?A"
  1456     then have "0 < (case map_of xs x of None \<Rightarrow> 0\<Colon>nat | Some (n\<Colon>nat) \<Rightarrow> n)" by simp
  1457     then have "map_of xs x \<noteq> None" by (cases "map_of xs x") auto
  1458     then show "x \<in> dom (map_of xs)" by auto
  1459   qed
  1460   with finite_dom_map_of [of xs] have "finite ?A"
  1461     by (auto intro: finite_subset)
  1462   then show ?thesis
  1463     by (simp add: count_of_def fun_eq_iff multiset_def)
  1464 qed
  1465 
  1466 lemma count_simps [simp]:
  1467   "count_of [] = (\<lambda>_. 0)"
  1468   "count_of ((x, n) # xs) = (\<lambda>y. if x = y then n else count_of xs y)"
  1469   by (simp_all add: count_of_def fun_eq_iff)
  1470 
  1471 lemma count_of_empty:
  1472   "x \<notin> fst ` set xs \<Longrightarrow> count_of xs x = 0"
  1473   by (induct xs) (simp_all add: count_of_def)
  1474 
  1475 lemma count_of_filter:
  1476   "count_of (List.filter (P \<circ> fst) xs) x = (if P x then count_of xs x else 0)"
  1477   by (induct xs) auto
  1478 
  1479 lemma count_of_map_default [simp]:
  1480   "count_of (map_default x b (%x. x + b) xs) y = (if x = y then count_of xs x + b else count_of xs y)"
  1481 unfolding count_of_def by (simp add: map_of_map_default split: option.split)
  1482 
  1483 lemma count_of_join_raw:
  1484   "distinct (map fst ys) ==> count_of xs x + count_of ys x = count_of (join_raw (%x (x, y). x + y) xs ys) x"
  1485 unfolding count_of_def by (simp add: map_of_join_raw split: option.split)
  1486 
  1487 lemma count_of_subtract_entries_raw:
  1488   "distinct (map fst ys) ==> count_of xs x - count_of ys x = count_of (subtract_entries_raw xs ys) x"
  1489 unfolding count_of_def by (simp add: map_of_subtract_entries_raw split: option.split)
  1490 
  1491 text {* Code equations for multiset operations *}
  1492 
  1493 definition Bag :: "('a, nat) alist \<Rightarrow> 'a multiset" where
  1494   "Bag xs = Abs_multiset (count_of (DAList.impl_of xs))"
  1495 
  1496 code_datatype Bag
  1497 
  1498 lemma count_Bag [simp, code]:
  1499   "count (Bag xs) = count_of (DAList.impl_of xs)"
  1500   by (simp add: Bag_def count_of_multiset Abs_multiset_inverse)
  1501 
  1502 lemma Mempty_Bag [code]:
  1503   "{#} = Bag (DAList.empty)"
  1504   by (simp add: multiset_eq_iff alist.Alist_inverse DAList.empty_def)
  1505 
  1506 lemma single_Bag [code]:
  1507   "{#x#} = Bag (DAList.update x 1 DAList.empty)"
  1508   by (simp add: multiset_eq_iff alist.Alist_inverse update.rep_eq empty.rep_eq)
  1509 
  1510 lemma union_Bag [code]:
  1511   "Bag xs + Bag ys = Bag (join (\<lambda>x (n1, n2). n1 + n2) xs ys)"
  1512 by (rule multiset_eqI) (simp add: count_of_join_raw alist.Alist_inverse distinct_join_raw join_def)
  1513 
  1514 lemma minus_Bag [code]:
  1515   "Bag xs - Bag ys = Bag (subtract_entries xs ys)"
  1516 by (rule multiset_eqI)
  1517   (simp add: count_of_subtract_entries_raw alist.Alist_inverse distinct_subtract_entries_raw subtract_entries_def)
  1518 
  1519 lemma filter_Bag [code]:
  1520   "Multiset.filter P (Bag xs) = Bag (DAList.filter (P \<circ> fst) xs)"
  1521 by (rule multiset_eqI) (simp add: count_of_filter DAList.filter.rep_eq)
  1522 
  1523 lemma mset_less_eq_Bag [code]:
  1524   "Bag xs \<le> A \<longleftrightarrow> (\<forall>(x, n) \<in> set (DAList.impl_of xs). count_of (DAList.impl_of xs) x \<le> count A x)"
  1525     (is "?lhs \<longleftrightarrow> ?rhs")
  1526 proof
  1527   assume ?lhs then show ?rhs
  1528     by (auto simp add: mset_le_def)
  1529 next
  1530   assume ?rhs
  1531   show ?lhs
  1532   proof (rule mset_less_eqI)
  1533     fix x
  1534     from `?rhs` have "count_of (DAList.impl_of xs) x \<le> count A x"
  1535       by (cases "x \<in> fst ` set (DAList.impl_of xs)") (auto simp add: count_of_empty)
  1536     then show "count (Bag xs) x \<le> count A x"
  1537       by (simp add: mset_le_def)
  1538   qed
  1539 qed
  1540 
  1541 instantiation multiset :: (equal) equal
  1542 begin
  1543 
  1544 definition
  1545   [code]: "HOL.equal A B \<longleftrightarrow> (A::'a multiset) \<le> B \<and> B \<le> A"
  1546 
  1547 instance
  1548   by default (simp add: equal_multiset_def eq_iff)
  1549 
  1550 end
  1551 
  1552 text {* Quickcheck generators *}
  1553 
  1554 definition (in term_syntax)
  1555   bagify :: "('a\<Colon>typerep, nat) alist \<times> (unit \<Rightarrow> Code_Evaluation.term)
  1556     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  1557   [code_unfold]: "bagify xs = Code_Evaluation.valtermify Bag {\<cdot>} xs"
  1558 
  1559 notation fcomp (infixl "\<circ>>" 60)
  1560 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1561 
  1562 instantiation multiset :: (random) random
  1563 begin
  1564 
  1565 definition
  1566   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (bagify xs))"
  1567 
  1568 instance ..
  1569 
  1570 end
  1571 
  1572 no_notation fcomp (infixl "\<circ>>" 60)
  1573 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1574 
  1575 instantiation multiset :: (exhaustive) exhaustive
  1576 begin
  1577 
  1578 definition exhaustive_multiset :: "('a multiset => (bool * term list) option) => natural => (bool * term list) option"
  1579 where
  1580   "exhaustive_multiset f i = Quickcheck_Exhaustive.exhaustive (%xs. f (Bag xs)) i"
  1581 
  1582 instance ..
  1583 
  1584 end
  1585 
  1586 instantiation multiset :: (full_exhaustive) full_exhaustive
  1587 begin
  1588 
  1589 definition full_exhaustive_multiset :: "('a multiset * (unit => term) => (bool * term list) option) => natural => (bool * term list) option"
  1590 where
  1591   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (%xs. f (bagify xs)) i"
  1592 
  1593 instance ..
  1594 
  1595 end
  1596 
  1597 hide_const (open) bagify
  1598 
  1599 
  1600 subsection {* The multiset order *}
  1601 
  1602 subsubsection {* Well-foundedness *}
  1603 
  1604 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1605   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
  1606       (\<forall>b. b :# K --> (b, a) \<in> r)}"
  1607 
  1608 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
  1609   "mult r = (mult1 r)\<^sup>+"
  1610 
  1611 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  1612 by (simp add: mult1_def)
  1613 
  1614 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
  1615     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
  1616     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
  1617   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
  1618 proof (unfold mult1_def)
  1619   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
  1620   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
  1621   let ?case1 = "?case1 {(N, M). ?R N M}"
  1622 
  1623   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
  1624   then have "\<exists>a' M0' K.
  1625       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
  1626   then show "?case1 \<or> ?case2"
  1627   proof (elim exE conjE)
  1628     fix a' M0' K
  1629     assume N: "N = M0' + K" and r: "?r K a'"
  1630     assume "M0 + {#a#} = M0' + {#a'#}"
  1631     then have "M0 = M0' \<and> a = a' \<or>
  1632         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
  1633       by (simp only: add_eq_conv_ex)
  1634     then show ?thesis
  1635     proof (elim disjE conjE exE)
  1636       assume "M0 = M0'" "a = a'"
  1637       with N r have "?r K a \<and> N = M0 + K" by simp
  1638       then have ?case2 .. then show ?thesis ..
  1639     next
  1640       fix K'
  1641       assume "M0' = K' + {#a#}"
  1642       with N have n: "N = K' + K + {#a#}" by (simp add: add_ac)
  1643 
  1644       assume "M0 = K' + {#a'#}"
  1645       with r have "?R (K' + K) M0" by blast
  1646       with n have ?case1 by simp then show ?thesis ..
  1647     qed
  1648   qed
  1649 qed
  1650 
  1651 lemma all_accessible: "wf r ==> \<forall>M. M \<in> acc (mult1 r)"
  1652 proof
  1653   let ?R = "mult1 r"
  1654   let ?W = "acc ?R"
  1655   {
  1656     fix M M0 a
  1657     assume M0: "M0 \<in> ?W"
  1658       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1659       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
  1660     have "M0 + {#a#} \<in> ?W"
  1661     proof (rule accI [of "M0 + {#a#}"])
  1662       fix N
  1663       assume "(N, M0 + {#a#}) \<in> ?R"
  1664       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
  1665           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
  1666         by (rule less_add)
  1667       then show "N \<in> ?W"
  1668       proof (elim exE disjE conjE)
  1669         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
  1670         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
  1671         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
  1672         then show "N \<in> ?W" by (simp only: N)
  1673       next
  1674         fix K
  1675         assume N: "N = M0 + K"
  1676         assume "\<forall>b. b :# K --> (b, a) \<in> r"
  1677         then have "M0 + K \<in> ?W"
  1678         proof (induct K)
  1679           case empty
  1680           from M0 show "M0 + {#} \<in> ?W" by simp
  1681         next
  1682           case (add K x)
  1683           from add.prems have "(x, a) \<in> r" by simp
  1684           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
  1685           moreover from add have "M0 + K \<in> ?W" by simp
  1686           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
  1687           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add_assoc)
  1688         qed
  1689         then show "N \<in> ?W" by (simp only: N)
  1690       qed
  1691     qed
  1692   } note tedious_reasoning = this
  1693 
  1694   assume wf: "wf r"
  1695   fix M
  1696   show "M \<in> ?W"
  1697   proof (induct M)
  1698     show "{#} \<in> ?W"
  1699     proof (rule accI)
  1700       fix b assume "(b, {#}) \<in> ?R"
  1701       with not_less_empty show "b \<in> ?W" by contradiction
  1702     qed
  1703 
  1704     fix M a assume "M \<in> ?W"
  1705     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1706     proof induct
  1707       fix a
  1708       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
  1709       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
  1710       proof
  1711         fix M assume "M \<in> ?W"
  1712         then show "M + {#a#} \<in> ?W"
  1713           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  1714       qed
  1715     qed
  1716     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
  1717   qed
  1718 qed
  1719 
  1720 theorem wf_mult1: "wf r ==> wf (mult1 r)"
  1721 by (rule acc_wfI) (rule all_accessible)
  1722 
  1723 theorem wf_mult: "wf r ==> wf (mult r)"
  1724 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  1725 
  1726 
  1727 subsubsection {* Closure-free presentation *}
  1728 
  1729 text {* One direction. *}
  1730 
  1731 lemma mult_implies_one_step:
  1732   "trans r ==> (M, N) \<in> mult r ==>
  1733     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
  1734     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
  1735 apply (unfold mult_def mult1_def set_of_def)
  1736 apply (erule converse_trancl_induct, clarify)
  1737  apply (rule_tac x = M0 in exI, simp, clarify)
  1738 apply (case_tac "a :# K")
  1739  apply (rule_tac x = I in exI)
  1740  apply (simp (no_asm))
  1741  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
  1742  apply (simp (no_asm_simp) add: add_assoc [symmetric])
  1743  apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong)
  1744  apply (simp add: diff_union_single_conv)
  1745  apply (simp (no_asm_use) add: trans_def)
  1746  apply blast
  1747 apply (subgoal_tac "a :# I")
  1748  apply (rule_tac x = "I - {#a#}" in exI)
  1749  apply (rule_tac x = "J + {#a#}" in exI)
  1750  apply (rule_tac x = "K + Ka" in exI)
  1751  apply (rule conjI)
  1752   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1753  apply (rule conjI)
  1754   apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong, simp)
  1755   apply (simp add: multiset_eq_iff split: nat_diff_split)
  1756  apply (simp (no_asm_use) add: trans_def)
  1757  apply blast
  1758 apply (subgoal_tac "a :# (M0 + {#a#})")
  1759  apply simp
  1760 apply (simp (no_asm))
  1761 done
  1762 
  1763 lemma one_step_implies_mult_aux:
  1764   "trans r ==>
  1765     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
  1766       --> (I + K, I + J) \<in> mult r"
  1767 apply (induct_tac n, auto)
  1768 apply (frule size_eq_Suc_imp_eq_union, clarify)
  1769 apply (rename_tac "J'", simp)
  1770 apply (erule notE, auto)
  1771 apply (case_tac "J' = {#}")
  1772  apply (simp add: mult_def)
  1773  apply (rule r_into_trancl)
  1774  apply (simp add: mult1_def set_of_def, blast)
  1775 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
  1776 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
  1777 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
  1778 apply (erule ssubst)
  1779 apply (simp add: Ball_def, auto)
  1780 apply (subgoal_tac
  1781   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
  1782     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
  1783  prefer 2
  1784  apply force
  1785 apply (simp (no_asm_use) add: add_assoc [symmetric] mult_def)
  1786 apply (erule trancl_trans)
  1787 apply (rule r_into_trancl)
  1788 apply (simp add: mult1_def set_of_def)
  1789 apply (rule_tac x = a in exI)
  1790 apply (rule_tac x = "I + J'" in exI)
  1791 apply (simp add: add_ac)
  1792 done
  1793 
  1794 lemma one_step_implies_mult:
  1795   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
  1796     ==> (I + K, I + J) \<in> mult r"
  1797 using one_step_implies_mult_aux by blast
  1798 
  1799 
  1800 subsubsection {* Partial-order properties *}
  1801 
  1802 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
  1803   "M' <# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  1804 
  1805 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
  1806   "M' <=# M \<longleftrightarrow> M' <# M \<or> M' = M"
  1807 
  1808 notation (xsymbols) less_multiset (infix "\<subset>#" 50)
  1809 notation (xsymbols) le_multiset (infix "\<subseteq>#" 50)
  1810 
  1811 interpretation multiset_order: order le_multiset less_multiset
  1812 proof -
  1813   have irrefl: "\<And>M :: 'a multiset. \<not> M \<subset># M"
  1814   proof
  1815     fix M :: "'a multiset"
  1816     assume "M \<subset># M"
  1817     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  1818     have "trans {(x'::'a, x). x' < x}"
  1819       by (rule transI) simp
  1820     moreover note MM
  1821     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  1822       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
  1823       by (rule mult_implies_one_step)
  1824     then obtain I J K where "M = I + J" and "M = I + K"
  1825       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
  1826     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
  1827     have "finite (set_of K)" by simp
  1828     moreover note aux2
  1829     ultimately have "set_of K = {}"
  1830       by (induct rule: finite_induct) (auto intro: order_less_trans)
  1831     with aux1 show False by simp
  1832   qed
  1833   have trans: "\<And>K M N :: 'a multiset. K \<subset># M \<Longrightarrow> M \<subset># N \<Longrightarrow> K \<subset># N"
  1834     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  1835   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset"
  1836     by default (auto simp add: le_multiset_def irrefl dest: trans)
  1837 qed
  1838 
  1839 lemma mult_less_irrefl [elim!]: "M \<subset># (M::'a::order multiset) ==> R"
  1840   by simp
  1841 
  1842 
  1843 subsubsection {* Monotonicity of multiset union *}
  1844 
  1845 lemma mult1_union: "(B, D) \<in> mult1 r ==> (C + B, C + D) \<in> mult1 r"
  1846 apply (unfold mult1_def)
  1847 apply auto
  1848 apply (rule_tac x = a in exI)
  1849 apply (rule_tac x = "C + M0" in exI)
  1850 apply (simp add: add_assoc)
  1851 done
  1852 
  1853 lemma union_less_mono2: "B \<subset># D ==> C + B \<subset># C + (D::'a::order multiset)"
  1854 apply (unfold less_multiset_def mult_def)
  1855 apply (erule trancl_induct)
  1856  apply (blast intro: mult1_union)
  1857 apply (blast intro: mult1_union trancl_trans)
  1858 done
  1859 
  1860 lemma union_less_mono1: "B \<subset># D ==> B + C \<subset># D + (C::'a::order multiset)"
  1861 apply (subst add_commute [of B C])
  1862 apply (subst add_commute [of D C])
  1863 apply (erule union_less_mono2)
  1864 done
  1865 
  1866 lemma union_less_mono:
  1867   "A \<subset># C ==> B \<subset># D ==> A + B \<subset># C + (D::'a::order multiset)"
  1868   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
  1869 
  1870 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
  1871 proof
  1872 qed (auto simp add: le_multiset_def intro: union_less_mono2)
  1873 
  1874 
  1875 subsection {* Termination proofs with multiset orders *}
  1876 
  1877 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1878   and multi_member_this: "x \<in># {# x #} + XS"
  1879   and multi_member_last: "x \<in># {# x #}"
  1880   by auto
  1881 
  1882 definition "ms_strict = mult pair_less"
  1883 definition "ms_weak = ms_strict \<union> Id"
  1884 
  1885 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1886 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1887 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1888 
  1889 lemma smsI:
  1890   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1891   unfolding ms_strict_def
  1892 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1893 
  1894 lemma wmsI:
  1895   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1896   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1897 unfolding ms_weak_def ms_strict_def
  1898 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1899 
  1900 inductive pw_leq
  1901 where
  1902   pw_leq_empty: "pw_leq {#} {#}"
  1903 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1904 
  1905 lemma pw_leq_lstep:
  1906   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1907 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1908 
  1909 lemma pw_leq_split:
  1910   assumes "pw_leq X Y"
  1911   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1912   using assms
  1913 proof (induct)
  1914   case pw_leq_empty thus ?case by auto
  1915 next
  1916   case (pw_leq_step x y X Y)
  1917   then obtain A B Z where
  1918     [simp]: "X = A + Z" "Y = B + Z" 
  1919       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})" 
  1920     by auto
  1921   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less" 
  1922     unfolding pair_leq_def by auto
  1923   thus ?case
  1924   proof
  1925     assume [simp]: "x = y"
  1926     have
  1927       "{#x#} + X = A + ({#y#}+Z) 
  1928       \<and> {#y#} + Y = B + ({#y#}+Z)
  1929       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1930       by (auto simp: add_ac)
  1931     thus ?case by (intro exI)
  1932   next
  1933     assume A: "(x, y) \<in> pair_less"
  1934     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1935     have "{#x#} + X = ?A' + Z"
  1936       "{#y#} + Y = ?B' + Z"
  1937       by (auto simp add: add_ac)
  1938     moreover have 
  1939       "(set_of ?A', set_of ?B') \<in> max_strict"
  1940       using 1 A unfolding max_strict_def 
  1941       by (auto elim!: max_ext.cases)
  1942     ultimately show ?thesis by blast
  1943   qed
  1944 qed
  1945 
  1946 lemma 
  1947   assumes pwleq: "pw_leq Z Z'"
  1948   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1949   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1950   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1951 proof -
  1952   from pw_leq_split[OF pwleq] 
  1953   obtain A' B' Z''
  1954     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1955     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1956     by blast
  1957   {
  1958     assume max: "(set_of A, set_of B) \<in> max_strict"
  1959     from mx_or_empty
  1960     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1961     proof
  1962       assume max': "(set_of A', set_of B') \<in> max_strict"
  1963       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
  1964         by (auto simp: max_strict_def intro: max_ext_additive)
  1965       thus ?thesis by (rule smsI) 
  1966     next
  1967       assume [simp]: "A' = {#} \<and> B' = {#}"
  1968       show ?thesis by (rule smsI) (auto intro: max)
  1969     qed
  1970     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:add_ac)
  1971     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1972   }
  1973   from mx_or_empty
  1974   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1975   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:add_ac)
  1976 qed
  1977 
  1978 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  1979 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1980 and nonempty_single: "{# x #} \<noteq> {#}"
  1981 by auto
  1982 
  1983 setup {*
  1984 let
  1985   fun msetT T = Type (@{type_name multiset}, [T]);
  1986 
  1987   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  1988     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1989     | mk_mset T (x :: xs) =
  1990           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1991                 mk_mset T [x] $ mk_mset T xs
  1992 
  1993   fun mset_member_tac m i =
  1994       (if m <= 0 then
  1995            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
  1996        else
  1997            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
  1998 
  1999   val mset_nonempty_tac =
  2000       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
  2001 
  2002   val regroup_munion_conv =
  2003       Function_Lib.regroup_conv @{const_abbrev Mempty} @{const_name plus}
  2004         (map (fn t => t RS eq_reflection) (@{thms add_ac} @ @{thms empty_neutral}))
  2005 
  2006   fun unfold_pwleq_tac i =
  2007     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
  2008       ORELSE (rtac @{thm pw_leq_lstep} i)
  2009       ORELSE (rtac @{thm pw_leq_empty} i)
  2010 
  2011   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
  2012                       @{thm Un_insert_left}, @{thm Un_empty_left}]
  2013 in
  2014   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset 
  2015   {
  2016     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  2017     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  2018     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
  2019     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  2020     reduction_pair= @{thm ms_reduction_pair}
  2021   })
  2022 end
  2023 *}
  2024 
  2025 
  2026 subsection {* Legacy theorem bindings *}
  2027 
  2028 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  2029 
  2030 lemma union_commute: "M + N = N + (M::'a multiset)"
  2031   by (fact add_commute)
  2032 
  2033 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  2034   by (fact add_assoc)
  2035 
  2036 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  2037   by (fact add_left_commute)
  2038 
  2039 lemmas union_ac = union_assoc union_commute union_lcomm
  2040 
  2041 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  2042   by (fact add_right_cancel)
  2043 
  2044 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  2045   by (fact add_left_cancel)
  2046 
  2047 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  2048   by (fact add_imp_eq)
  2049 
  2050 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
  2051   by (fact order_less_trans)
  2052 
  2053 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
  2054   by (fact inf.commute)
  2055 
  2056 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
  2057   by (fact inf.assoc [symmetric])
  2058 
  2059 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
  2060   by (fact inf.left_commute)
  2061 
  2062 lemmas multiset_inter_ac =
  2063   multiset_inter_commute
  2064   multiset_inter_assoc
  2065   multiset_inter_left_commute
  2066 
  2067 lemma mult_less_not_refl:
  2068   "\<not> M \<subset># (M::'a::order multiset)"
  2069   by (fact multiset_order.less_irrefl)
  2070 
  2071 lemma mult_less_trans:
  2072   "K \<subset># M ==> M \<subset># N ==> K \<subset># (N::'a::order multiset)"
  2073   by (fact multiset_order.less_trans)
  2074     
  2075 lemma mult_less_not_sym:
  2076   "M \<subset># N ==> \<not> N \<subset># (M::'a::order multiset)"
  2077   by (fact multiset_order.less_not_sym)
  2078 
  2079 lemma mult_less_asym:
  2080   "M \<subset># N ==> (\<not> P ==> N \<subset># (M::'a::order multiset)) ==> P"
  2081   by (fact multiset_order.less_asym)
  2082 
  2083 ML {*
  2084 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
  2085                       (Const _ $ t') =
  2086     let
  2087       val (maybe_opt, ps) =
  2088         Nitpick_Model.dest_plain_fun t' ||> op ~~
  2089         ||> map (apsnd (snd o HOLogic.dest_number))
  2090       fun elems_for t =
  2091         case AList.lookup (op =) ps t of
  2092           SOME n => replicate n t
  2093         | NONE => [Const (maybe_name, elem_T --> elem_T) $ t]
  2094     in
  2095       case maps elems_for (all_values elem_T) @
  2096            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
  2097             else []) of
  2098         [] => Const (@{const_name zero_class.zero}, T)
  2099       | ts => foldl1 (fn (t1, t2) =>
  2100                          Const (@{const_name plus_class.plus}, T --> T --> T)
  2101                          $ t1 $ t2)
  2102                      (map (curry (op $) (Const (@{const_name single},
  2103                                                 elem_T --> T))) ts)
  2104     end
  2105   | multiset_postproc _ _ _ _ t = t
  2106 *}
  2107 
  2108 declaration {*
  2109 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
  2110     multiset_postproc
  2111 *}
  2112 
  2113 hide_const (open) fold
  2114 
  2115 end
  2116