src/HOL/Parity.thy
author hoelzl
Wed Jan 06 12:18:53 2016 +0100 (2016-01-06)
changeset 62083 7582b39f51ed
parent 61799 4cf66f21b764
child 62597 b3f2b8c906a6
permissions -rw-r--r--
add the proof of the central limit theorem
     1 (*  Title:      HOL/Parity.thy
     2     Author:     Jeremy Avigad
     3     Author:     Jacques D. Fleuriot
     4 *)
     5 
     6 section \<open>Parity in rings and semirings\<close>
     7 
     8 theory Parity
     9 imports Nat_Transfer
    10 begin
    11 
    12 subsection \<open>Ring structures with parity and \<open>even\<close>/\<open>odd\<close> predicates\<close>
    13 
    14 class semiring_parity = comm_semiring_1_cancel + numeral +
    15   assumes odd_one [simp]: "\<not> 2 dvd 1"
    16   assumes odd_even_add: "\<not> 2 dvd a \<Longrightarrow> \<not> 2 dvd b \<Longrightarrow> 2 dvd a + b"
    17   assumes even_multD: "2 dvd a * b \<Longrightarrow> 2 dvd a \<or> 2 dvd b"
    18   assumes odd_ex_decrement: "\<not> 2 dvd a \<Longrightarrow> \<exists>b. a = b + 1"
    19 begin
    20 
    21 subclass semiring_numeral ..
    22 
    23 abbreviation even :: "'a \<Rightarrow> bool"
    24 where
    25   "even a \<equiv> 2 dvd a"
    26 
    27 abbreviation odd :: "'a \<Rightarrow> bool"
    28 where
    29   "odd a \<equiv> \<not> 2 dvd a"
    30 
    31 lemma even_zero [simp]:
    32   "even 0"
    33   by (fact dvd_0_right)
    34 
    35 lemma even_plus_one_iff [simp]:
    36   "even (a + 1) \<longleftrightarrow> odd a"
    37   by (auto simp add: dvd_add_right_iff intro: odd_even_add)
    38 
    39 lemma evenE [elim?]:
    40   assumes "even a"
    41   obtains b where "a = 2 * b"
    42   using assms by (rule dvdE)
    43 
    44 lemma oddE [elim?]:
    45   assumes "odd a"
    46   obtains b where "a = 2 * b + 1"
    47 proof -
    48   from assms obtain b where *: "a = b + 1"
    49     by (blast dest: odd_ex_decrement)
    50   with assms have "even (b + 2)" by simp
    51   then have "even b" by simp
    52   then obtain c where "b = 2 * c" ..
    53   with * have "a = 2 * c + 1" by simp
    54   with that show thesis .
    55 qed
    56  
    57 lemma even_times_iff [simp]:
    58   "even (a * b) \<longleftrightarrow> even a \<or> even b"
    59   by (auto dest: even_multD)
    60 
    61 lemma even_numeral [simp]:
    62   "even (numeral (Num.Bit0 n))"
    63 proof -
    64   have "even (2 * numeral n)"
    65     unfolding even_times_iff by simp
    66   then have "even (numeral n + numeral n)"
    67     unfolding mult_2 .
    68   then show ?thesis
    69     unfolding numeral.simps .
    70 qed
    71 
    72 lemma odd_numeral [simp]:
    73   "odd (numeral (Num.Bit1 n))"
    74 proof
    75   assume "even (numeral (num.Bit1 n))"
    76   then have "even (numeral n + numeral n + 1)"
    77     unfolding numeral.simps .
    78   then have "even (2 * numeral n + 1)"
    79     unfolding mult_2 .
    80   then have "2 dvd numeral n * 2 + 1"
    81     by (simp add: ac_simps)
    82   with dvd_add_times_triv_left_iff [of 2 "numeral n" 1]
    83     have "2 dvd 1"
    84     by simp
    85   then show False by simp
    86 qed
    87 
    88 lemma even_add [simp]:
    89   "even (a + b) \<longleftrightarrow> (even a \<longleftrightarrow> even b)"
    90   by (auto simp add: dvd_add_right_iff dvd_add_left_iff odd_even_add)
    91 
    92 lemma odd_add [simp]:
    93   "odd (a + b) \<longleftrightarrow> (\<not> (odd a \<longleftrightarrow> odd b))"
    94   by simp
    95 
    96 lemma even_power [simp]:
    97   "even (a ^ n) \<longleftrightarrow> even a \<and> n > 0"
    98   by (induct n) auto
    99 
   100 end
   101 
   102 class ring_parity = ring + semiring_parity
   103 begin
   104 
   105 subclass comm_ring_1 ..
   106 
   107 lemma even_minus [simp]:
   108   "even (- a) \<longleftrightarrow> even a"
   109   by (fact dvd_minus_iff)
   110 
   111 lemma even_diff [simp]:
   112   "even (a - b) \<longleftrightarrow> even (a + b)"
   113   using even_add [of a "- b"] by simp
   114 
   115 end
   116 
   117 
   118 subsection \<open>Instances for @{typ nat} and @{typ int}\<close>
   119 
   120 lemma even_Suc_Suc_iff [simp]:
   121   "2 dvd Suc (Suc n) \<longleftrightarrow> 2 dvd n"
   122   using dvd_add_triv_right_iff [of 2 n] by simp
   123 
   124 lemma even_Suc [simp]:
   125   "2 dvd Suc n \<longleftrightarrow> \<not> 2 dvd n"
   126   by (induct n) auto
   127 
   128 lemma even_diff_nat [simp]:
   129   fixes m n :: nat
   130   shows "2 dvd (m - n) \<longleftrightarrow> m < n \<or> 2 dvd (m + n)"
   131 proof (cases "n \<le> m")
   132   case True
   133   then have "m - n + n * 2 = m + n" by (simp add: mult_2_right)
   134   moreover have "2 dvd (m - n) \<longleftrightarrow> 2 dvd (m - n + n * 2)" by simp
   135   ultimately have "2 dvd (m - n) \<longleftrightarrow> 2 dvd (m + n)" by (simp only:)
   136   then show ?thesis by auto
   137 next
   138   case False
   139   then show ?thesis by simp
   140 qed 
   141   
   142 instance nat :: semiring_parity
   143 proof
   144   show "\<not> 2 dvd (1 :: nat)"
   145     by (rule notI, erule dvdE) simp
   146 next
   147   fix m n :: nat
   148   assume "\<not> 2 dvd m"
   149   moreover assume "\<not> 2 dvd n"
   150   ultimately have *: "2 dvd Suc m \<and> 2 dvd Suc n"
   151     by simp
   152   then have "2 dvd (Suc m + Suc n)"
   153     by (blast intro: dvd_add)
   154   also have "Suc m + Suc n = m + n + 2"
   155     by simp
   156   finally show "2 dvd (m + n)"
   157     using dvd_add_triv_right_iff [of 2 "m + n"] by simp
   158 next
   159   fix m n :: nat
   160   assume *: "2 dvd (m * n)"
   161   show "2 dvd m \<or> 2 dvd n"
   162   proof (rule disjCI)
   163     assume "\<not> 2 dvd n"
   164     then have "2 dvd (Suc n)" by simp
   165     then obtain r where "Suc n = 2 * r" ..
   166     moreover from * obtain s where "m * n = 2 * s" ..
   167     then have "2 * s + m = m * Suc n" by simp
   168     ultimately have " 2 * s + m = 2 * (m * r)" by (simp add: algebra_simps)
   169     then have "m = 2 * (m * r - s)" by simp
   170     then show "2 dvd m" ..
   171   qed
   172 next
   173   fix n :: nat
   174   assume "\<not> 2 dvd n"
   175   then show "\<exists>m. n = m + 1"
   176     by (cases n) simp_all
   177 qed
   178 
   179 lemma odd_pos: 
   180   "odd (n :: nat) \<Longrightarrow> 0 < n"
   181   by (auto elim: oddE)
   182 
   183 lemma even_diff_iff [simp]:
   184   fixes k l :: int
   185   shows "2 dvd (k - l) \<longleftrightarrow> 2 dvd (k + l)"
   186   using dvd_add_times_triv_right_iff [of 2 "k - l" l] by (simp add: mult_2_right)
   187 
   188 lemma even_abs_add_iff [simp]:
   189   fixes k l :: int
   190   shows "2 dvd (\<bar>k\<bar> + l) \<longleftrightarrow> 2 dvd (k + l)"
   191   by (cases "k \<ge> 0") (simp_all add: ac_simps)
   192 
   193 lemma even_add_abs_iff [simp]:
   194   fixes k l :: int
   195   shows "2 dvd (k + \<bar>l\<bar>) \<longleftrightarrow> 2 dvd (k + l)"
   196   using even_abs_add_iff [of l k] by (simp add: ac_simps)
   197 
   198 lemma odd_Suc_minus_one [simp]:
   199   "odd n \<Longrightarrow> Suc (n - Suc 0) = n"
   200   by (auto elim: oddE)
   201 
   202 instance int :: ring_parity
   203 proof
   204   show "\<not> 2 dvd (1 :: int)" by (simp add: dvd_int_unfold_dvd_nat)
   205   fix k l :: int
   206   assume "\<not> 2 dvd k"
   207   moreover assume "\<not> 2 dvd l"
   208   ultimately have "2 dvd (nat \<bar>k\<bar> + nat \<bar>l\<bar>)" 
   209     by (auto simp add: dvd_int_unfold_dvd_nat intro: odd_even_add)
   210   then have "2 dvd (\<bar>k\<bar> + \<bar>l\<bar>)"
   211     by (simp add: dvd_int_unfold_dvd_nat nat_add_distrib)
   212   then show "2 dvd (k + l)"
   213     by simp
   214 next
   215   fix k l :: int
   216   assume "2 dvd (k * l)"
   217   then show "2 dvd k \<or> 2 dvd l"
   218     by (simp add: dvd_int_unfold_dvd_nat even_multD nat_abs_mult_distrib)
   219 next
   220   fix k :: int
   221   have "k = (k - 1) + 1" by simp
   222   then show "\<exists>l. k = l + 1" ..
   223 qed
   224 
   225 lemma even_int_iff [simp]:
   226   "even (int n) \<longleftrightarrow> even n"
   227   by (simp add: dvd_int_iff)
   228 
   229 lemma even_nat_iff:
   230   "0 \<le> k \<Longrightarrow> even (nat k) \<longleftrightarrow> even k"
   231   by (simp add: even_int_iff [symmetric])
   232 
   233 
   234 subsection \<open>Parity and powers\<close>
   235 
   236 context ring_1
   237 begin
   238 
   239 lemma power_minus_even [simp]:
   240   "even n \<Longrightarrow> (- a) ^ n = a ^ n"
   241   by (auto elim: evenE)
   242 
   243 lemma power_minus_odd [simp]:
   244   "odd n \<Longrightarrow> (- a) ^ n = - (a ^ n)"
   245   by (auto elim: oddE)
   246 
   247 lemma neg_one_even_power [simp]:
   248   "even n \<Longrightarrow> (- 1) ^ n = 1"
   249   by simp
   250 
   251 lemma neg_one_odd_power [simp]:
   252   "odd n \<Longrightarrow> (- 1) ^ n = - 1"
   253   by simp
   254 
   255 end  
   256 
   257 context linordered_idom
   258 begin
   259 
   260 lemma zero_le_even_power:
   261   "even n \<Longrightarrow> 0 \<le> a ^ n"
   262   by (auto elim: evenE)
   263 
   264 lemma zero_le_odd_power:
   265   "odd n \<Longrightarrow> 0 \<le> a ^ n \<longleftrightarrow> 0 \<le> a"
   266   by (auto simp add: power_even_eq zero_le_mult_iff elim: oddE)
   267 
   268 lemma zero_le_power_eq:
   269   "0 \<le> a ^ n \<longleftrightarrow> even n \<or> odd n \<and> 0 \<le> a"
   270   by (auto simp add: zero_le_even_power zero_le_odd_power)
   271   
   272 lemma zero_less_power_eq:
   273   "0 < a ^ n \<longleftrightarrow> n = 0 \<or> even n \<and> a \<noteq> 0 \<or> odd n \<and> 0 < a"
   274 proof -
   275   have [simp]: "0 = a ^ n \<longleftrightarrow> a = 0 \<and> n > 0"
   276     unfolding power_eq_0_iff [of a n, symmetric] by blast
   277   show ?thesis
   278   unfolding less_le zero_le_power_eq by auto
   279 qed
   280 
   281 lemma power_less_zero_eq [simp]:
   282   "a ^ n < 0 \<longleftrightarrow> odd n \<and> a < 0"
   283   unfolding not_le [symmetric] zero_le_power_eq by auto
   284   
   285 lemma power_le_zero_eq:
   286   "a ^ n \<le> 0 \<longleftrightarrow> n > 0 \<and> (odd n \<and> a \<le> 0 \<or> even n \<and> a = 0)"
   287   unfolding not_less [symmetric] zero_less_power_eq by auto 
   288 
   289 lemma power_even_abs:
   290   "even n \<Longrightarrow> \<bar>a\<bar> ^ n = a ^ n"
   291   using power_abs [of a n] by (simp add: zero_le_even_power)
   292 
   293 lemma power_mono_even:
   294   assumes "even n" and "\<bar>a\<bar> \<le> \<bar>b\<bar>"
   295   shows "a ^ n \<le> b ^ n"
   296 proof -
   297   have "0 \<le> \<bar>a\<bar>" by auto
   298   with \<open>\<bar>a\<bar> \<le> \<bar>b\<bar>\<close>
   299   have "\<bar>a\<bar> ^ n \<le> \<bar>b\<bar> ^ n" by (rule power_mono)
   300   with \<open>even n\<close> show ?thesis by (simp add: power_even_abs)  
   301 qed
   302 
   303 lemma power_mono_odd:
   304   assumes "odd n" and "a \<le> b"
   305   shows "a ^ n \<le> b ^ n"
   306 proof (cases "b < 0")
   307   case True with \<open>a \<le> b\<close> have "- b \<le> - a" and "0 \<le> - b" by auto
   308   hence "(- b) ^ n \<le> (- a) ^ n" by (rule power_mono)
   309   with \<open>odd n\<close> show ?thesis by simp
   310 next
   311   case False then have "0 \<le> b" by auto
   312   show ?thesis
   313   proof (cases "a < 0")
   314     case True then have "n \<noteq> 0" and "a \<le> 0" using \<open>odd n\<close> [THEN odd_pos] by auto
   315     then have "a ^ n \<le> 0" unfolding power_le_zero_eq using \<open>odd n\<close> by auto
   316     moreover
   317     from \<open>0 \<le> b\<close> have "0 \<le> b ^ n" by auto
   318     ultimately show ?thesis by auto
   319   next
   320     case False then have "0 \<le> a" by auto
   321     with \<open>a \<le> b\<close> show ?thesis using power_mono by auto
   322   qed
   323 qed
   324 
   325 lemma (in comm_ring_1) uminus_power_if: "(- x) ^ n = (if even n then x^n else - (x ^ n))"
   326   by auto
   327 
   328 text \<open>Simplify, when the exponent is a numeral\<close>
   329 
   330 lemma zero_le_power_eq_numeral [simp]:
   331   "0 \<le> a ^ numeral w \<longleftrightarrow> even (numeral w :: nat) \<or> odd (numeral w :: nat) \<and> 0 \<le> a"
   332   by (fact zero_le_power_eq)
   333 
   334 lemma zero_less_power_eq_numeral [simp]:
   335   "0 < a ^ numeral w \<longleftrightarrow> numeral w = (0 :: nat)
   336     \<or> even (numeral w :: nat) \<and> a \<noteq> 0 \<or> odd (numeral w :: nat) \<and> 0 < a"
   337   by (fact zero_less_power_eq)
   338 
   339 lemma power_le_zero_eq_numeral [simp]:
   340   "a ^ numeral w \<le> 0 \<longleftrightarrow> (0 :: nat) < numeral w
   341     \<and> (odd (numeral w :: nat) \<and> a \<le> 0 \<or> even (numeral w :: nat) \<and> a = 0)"
   342   by (fact power_le_zero_eq)
   343 
   344 lemma power_less_zero_eq_numeral [simp]:
   345   "a ^ numeral w < 0 \<longleftrightarrow> odd (numeral w :: nat) \<and> a < 0"
   346   by (fact power_less_zero_eq)
   347 
   348 lemma power_even_abs_numeral [simp]:
   349   "even (numeral w :: nat) \<Longrightarrow> \<bar>a\<bar> ^ numeral w = a ^ numeral w"
   350   by (fact power_even_abs)
   351 
   352 end
   353 
   354 
   355 subsubsection \<open>Tools setup\<close>
   356 
   357 declare transfer_morphism_int_nat [transfer add return:
   358   even_int_iff
   359 ]
   360 
   361 end