src/HOL/Orderings.thy
author paulson
Wed Aug 15 12:52:56 2007 +0200 (2007-08-15)
changeset 24286 7619080e49f0
parent 23948 261bd4678076
child 24422 c0b5ff9e9e4d
permissions -rw-r--r--
ATP blacklisting is now in theory data, attribute noatp
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports Set Fun
    10 uses
    11   (*"~~/src/Provers/quasi.ML"*)
    12   "~~/src/Provers/order.ML"
    13 begin
    14 
    15 subsection {* Partial orders *}
    16 
    17 class order = ord +
    18   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    19   and order_refl [iff]: "x \<sqsubseteq> x"
    20   and order_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    21   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
    22 
    23 begin
    24 
    25 text {* Reflexivity. *}
    26 
    27 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
    28     -- {* This form is useful with the classical reasoner. *}
    29 by (erule ssubst) (rule order_refl)
    30 
    31 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
    32 by (simp add: less_le)
    33 
    34 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
    35     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    36 by (simp add: less_le) blast
    37 
    38 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
    39 unfolding less_le by blast
    40 
    41 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
    42 unfolding less_le by blast
    43 
    44 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    45 by (erule contrapos_pn, erule subst, rule less_irrefl)
    46 
    47 
    48 text {* Useful for simplification, but too risky to include by default. *}
    49 
    50 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
    51 by auto
    52 
    53 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
    54 by auto
    55 
    56 
    57 text {* Transitivity rules for calculational reasoning *}
    58 
    59 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
    60 by (simp add: less_le)
    61 
    62 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
    63 by (simp add: less_le)
    64 
    65 
    66 text {* Asymmetry. *}
    67 
    68 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
    69 by (simp add: less_le antisym)
    70 
    71 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
    72 by (drule less_not_sym, erule contrapos_np) simp
    73 
    74 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
    75 by (blast intro: antisym)
    76 
    77 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
    78 by (blast intro: antisym)
    79 
    80 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    81 by (erule contrapos_pn, erule subst, rule less_irrefl)
    82 
    83 
    84 text {* Transitivity. *}
    85 
    86 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    87 by (simp add: less_le) (blast intro: order_trans antisym)
    88 
    89 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    90 by (simp add: less_le) (blast intro: order_trans antisym)
    91 
    92 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
    93 by (simp add: less_le) (blast intro: order_trans antisym)
    94 
    95 
    96 text {* Useful for simplification, but too risky to include by default. *}
    97 
    98 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
    99 by (blast elim: less_asym)
   100 
   101 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   102 by (blast elim: less_asym)
   103 
   104 
   105 text {* Transitivity rules for calculational reasoning *}
   106 
   107 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   108 by (rule less_asym)
   109 
   110 
   111 text {* Reverse order *}
   112 
   113 lemma order_reverse:
   114   "order (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   115 by unfold_locales
   116    (simp add: less_le, auto intro: antisym order_trans)
   117 
   118 end
   119 
   120 
   121 subsection {* Linear (total) orders *}
   122 
   123 class linorder = order +
   124   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   125 begin
   126 
   127 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   128 unfolding less_le using less_le linear by blast
   129 
   130 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   131 by (simp add: le_less less_linear)
   132 
   133 lemma le_cases [case_names le ge]:
   134   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   135 using linear by blast
   136 
   137 lemma linorder_cases [case_names less equal greater]:
   138   "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   139 using less_linear by blast
   140 
   141 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   142 apply (simp add: less_le)
   143 using linear apply (blast intro: antisym)
   144 done
   145 
   146 lemma not_less_iff_gr_or_eq:
   147  "\<not>(x \<^loc>< y) \<longleftrightarrow> (x \<^loc>> y | x = y)"
   148 apply(simp add:not_less le_less)
   149 apply blast
   150 done
   151 
   152 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   153 apply (simp add: less_le)
   154 using linear apply (blast intro: antisym)
   155 done
   156 
   157 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   158 by (cut_tac x = x and y = y in less_linear, auto)
   159 
   160 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   161 by (simp add: neq_iff) blast
   162 
   163 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   164 by (blast intro: antisym dest: not_less [THEN iffD1])
   165 
   166 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   167 by (blast intro: antisym dest: not_less [THEN iffD1])
   168 
   169 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   170 by (blast intro: antisym dest: not_less [THEN iffD1])
   171 
   172 text{*Replacing the old Nat.leI*}
   173 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   174 unfolding not_less .
   175 
   176 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   177 unfolding not_less .
   178 
   179 (*FIXME inappropriate name (or delete altogether)*)
   180 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   181 unfolding not_le .
   182 
   183 
   184 text {* Reverse order *}
   185 
   186 lemma linorder_reverse:
   187   "linorder (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   188 by unfold_locales
   189   (simp add: less_le, auto intro: antisym order_trans simp add: linear)
   190 
   191 
   192 text {* min/max *}
   193 
   194 text {* for historic reasons, definitions are done in context ord *}
   195 
   196 definition (in ord)
   197   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   198   [code unfold, code inline del]: "min a b = (if a \<^loc>\<le> b then a else b)"
   199 
   200 definition (in ord)
   201   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   202   [code unfold, code inline del]: "max a b = (if a \<^loc>\<le> b then b else a)"
   203 
   204 lemma min_le_iff_disj:
   205   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   206 unfolding min_def using linear by (auto intro: order_trans)
   207 
   208 lemma le_max_iff_disj:
   209   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   210 unfolding max_def using linear by (auto intro: order_trans)
   211 
   212 lemma min_less_iff_disj:
   213   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   214 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   215 
   216 lemma less_max_iff_disj:
   217   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   218 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   219 
   220 lemma min_less_iff_conj [simp]:
   221   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   222 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   223 
   224 lemma max_less_iff_conj [simp]:
   225   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   226 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   227 
   228 lemma split_min [noatp]:
   229   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   230 by (simp add: min_def)
   231 
   232 lemma split_max [noatp]:
   233   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   234 by (simp add: max_def)
   235 
   236 end
   237 
   238 
   239 subsection {* Name duplicates *}
   240 
   241 lemmas order_less_le = less_le
   242 lemmas order_eq_refl = order_class.eq_refl
   243 lemmas order_less_irrefl = order_class.less_irrefl
   244 lemmas order_le_less = order_class.le_less
   245 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   246 lemmas order_less_imp_le = order_class.less_imp_le
   247 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   248 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   249 lemmas order_neq_le_trans = order_class.neq_le_trans
   250 lemmas order_le_neq_trans = order_class.le_neq_trans
   251 
   252 lemmas order_antisym = antisym
   253 lemmas order_less_not_sym = order_class.less_not_sym
   254 lemmas order_less_asym = order_class.less_asym
   255 lemmas order_eq_iff = order_class.eq_iff
   256 lemmas order_antisym_conv = order_class.antisym_conv
   257 lemmas order_less_trans = order_class.less_trans
   258 lemmas order_le_less_trans = order_class.le_less_trans
   259 lemmas order_less_le_trans = order_class.less_le_trans
   260 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   261 lemmas order_less_imp_triv = order_class.less_imp_triv
   262 lemmas order_less_asym' = order_class.less_asym'
   263 
   264 lemmas linorder_linear = linear
   265 lemmas linorder_less_linear = linorder_class.less_linear
   266 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   267 lemmas linorder_le_cases = linorder_class.le_cases
   268 lemmas linorder_not_less = linorder_class.not_less
   269 lemmas linorder_not_le = linorder_class.not_le
   270 lemmas linorder_neq_iff = linorder_class.neq_iff
   271 lemmas linorder_neqE = linorder_class.neqE
   272 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   273 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   274 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   275 
   276 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj
   277 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj
   278 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj
   279 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj
   280 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj
   281 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj
   282 lemmas split_min = linorder_class.split_min
   283 lemmas split_max = linorder_class.split_max
   284 
   285 
   286 subsection {* Reasoning tools setup *}
   287 
   288 ML {*
   289 local
   290 
   291 fun decomp_gen sort thy (Trueprop $ t) =
   292   let
   293     fun of_sort t =
   294       let
   295         val T = type_of t
   296       in
   297         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   298         T <> HOLogic.natT andalso T <> HOLogic.intT
   299           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   300       end;
   301     fun dec (Const (@{const_name Not}, _) $ t) = (case dec t
   302           of NONE => NONE
   303            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   304       | dec (Const (@{const_name "op ="},  _) $ t1 $ t2) =
   305           if of_sort t1
   306           then SOME (t1, "=", t2)
   307           else NONE
   308       | dec (Const (@{const_name HOL.less_eq},  _) $ t1 $ t2) =
   309           if of_sort t1
   310           then SOME (t1, "<=", t2)
   311           else NONE
   312       | dec (Const (@{const_name HOL.less},  _) $ t1 $ t2) =
   313           if of_sort t1
   314           then SOME (t1, "<", t2)
   315           else NONE
   316       | dec _ = NONE;
   317   in dec t end;
   318 
   319 in
   320 
   321 (* sorry - there is no preorder class
   322 structure Quasi_Tac = Quasi_Tac_Fun (
   323 struct
   324   val le_trans = thm "order_trans";
   325   val le_refl = thm "order_refl";
   326   val eqD1 = thm "order_eq_refl";
   327   val eqD2 = thm "sym" RS thm "order_eq_refl";
   328   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   329   val less_imp_le = thm "order_less_imp_le";
   330   val le_neq_trans = thm "order_le_neq_trans";
   331   val neq_le_trans = thm "order_neq_le_trans";
   332   val less_imp_neq = thm "less_imp_neq";
   333   val decomp_trans = decomp_gen ["Orderings.preorder"];
   334   val decomp_quasi = decomp_gen ["Orderings.preorder"];
   335 end);*)
   336 
   337 structure Order_Tac = Order_Tac_Fun (
   338 struct
   339   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   340   val le_refl = thm "order_refl";
   341   val less_imp_le = thm "order_less_imp_le";
   342   val not_lessI = thm "linorder_not_less" RS thm "iffD2";
   343   val not_leI = thm "linorder_not_le" RS thm "iffD2";
   344   val not_lessD = thm "linorder_not_less" RS thm "iffD1";
   345   val not_leD = thm "linorder_not_le" RS thm "iffD1";
   346   val eqI = thm "order_antisym";
   347   val eqD1 = thm "order_eq_refl";
   348   val eqD2 = thm "sym" RS thm "order_eq_refl";
   349   val less_trans = thm "order_less_trans";
   350   val less_le_trans = thm "order_less_le_trans";
   351   val le_less_trans = thm "order_le_less_trans";
   352   val le_trans = thm "order_trans";
   353   val le_neq_trans = thm "order_le_neq_trans";
   354   val neq_le_trans = thm "order_neq_le_trans";
   355   val less_imp_neq = thm "less_imp_neq";
   356   val eq_neq_eq_imp_neq = thm "eq_neq_eq_imp_neq";
   357   val not_sym = thm "not_sym";
   358   val decomp_part = decomp_gen ["Orderings.order"];
   359   val decomp_lin = decomp_gen ["Orderings.linorder"];
   360 end);
   361 
   362 end;
   363 *}
   364 
   365 setup {*
   366 let
   367 
   368 fun prp t thm = (#prop (rep_thm thm) = t);
   369 
   370 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   371   let val prems = prems_of_ss ss;
   372       val less = Const (@{const_name less}, T);
   373       val t = HOLogic.mk_Trueprop(le $ s $ r);
   374   in case find_first (prp t) prems of
   375        NONE =>
   376          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   377          in case find_first (prp t) prems of
   378               NONE => NONE
   379             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv1}))
   380          end
   381      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_antisym_conv}))
   382   end
   383   handle THM _ => NONE;
   384 
   385 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   386   let val prems = prems_of_ss ss;
   387       val le = Const (@{const_name less_eq}, T);
   388       val t = HOLogic.mk_Trueprop(le $ r $ s);
   389   in case find_first (prp t) prems of
   390        NONE =>
   391          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   392          in case find_first (prp t) prems of
   393               NONE => NONE
   394             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv3}))
   395          end
   396      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_antisym_conv2}))
   397   end
   398   handle THM _ => NONE;
   399 
   400 fun add_simprocs procs thy =
   401   (Simplifier.change_simpset_of thy (fn ss => ss
   402     addsimprocs (map (fn (name, raw_ts, proc) =>
   403       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   404 fun add_solver name tac thy =
   405   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   406     (mk_solver name (K tac))); thy);
   407 
   408 in
   409   add_simprocs [
   410        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   411        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   412      ]
   413   #> add_solver "Trans_linear" Order_Tac.linear_tac
   414   #> add_solver "Trans_partial" Order_Tac.partial_tac
   415   (* Adding the transitivity reasoners also as safe solvers showed a slight
   416      speed up, but the reasoning strength appears to be not higher (at least
   417      no breaking of additional proofs in the entire HOL distribution, as
   418      of 5 March 2004, was observed). *)
   419 end
   420 *}
   421 
   422 
   423 subsection {* Bounded quantifiers *}
   424 
   425 syntax
   426   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   427   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   428   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   429   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   430 
   431   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   432   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   433   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   434   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   435 
   436 syntax (xsymbols)
   437   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   438   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   439   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   440   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   441 
   442   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   443   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   444   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   445   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   446 
   447 syntax (HOL)
   448   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   449   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   450   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   451   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   452 
   453 syntax (HTML output)
   454   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   455   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   456   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   457   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   458 
   459   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   460   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   461   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   462   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   463 
   464 translations
   465   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   466   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   467   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   468   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   469   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   470   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   471   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   472   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   473 
   474 print_translation {*
   475 let
   476   val All_binder = Syntax.binder_name @{const_syntax All};
   477   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   478   val impl = @{const_syntax "op -->"};
   479   val conj = @{const_syntax "op &"};
   480   val less = @{const_syntax less};
   481   val less_eq = @{const_syntax less_eq};
   482 
   483   val trans =
   484    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   485     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   486     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   487     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   488 
   489   fun matches_bound v t = 
   490      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   491               | _ => false
   492   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   493   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   494 
   495   fun tr' q = (q,
   496     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   497       (case AList.lookup (op =) trans (q, c, d) of
   498         NONE => raise Match
   499       | SOME (l, g) =>
   500           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   501           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   502           else raise Match)
   503      | _ => raise Match);
   504 in [tr' All_binder, tr' Ex_binder] end
   505 *}
   506 
   507 
   508 subsection {* Transitivity reasoning *}
   509 
   510 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   511 by (rule subst)
   512 
   513 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   514 by (rule ssubst)
   515 
   516 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   517 by (rule subst)
   518 
   519 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   520 by (rule ssubst)
   521 
   522 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   523   (!!x y. x < y ==> f x < f y) ==> f a < c"
   524 proof -
   525   assume r: "!!x y. x < y ==> f x < f y"
   526   assume "a < b" hence "f a < f b" by (rule r)
   527   also assume "f b < c"
   528   finally (order_less_trans) show ?thesis .
   529 qed
   530 
   531 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   532   (!!x y. x < y ==> f x < f y) ==> a < f c"
   533 proof -
   534   assume r: "!!x y. x < y ==> f x < f y"
   535   assume "a < f b"
   536   also assume "b < c" hence "f b < f c" by (rule r)
   537   finally (order_less_trans) show ?thesis .
   538 qed
   539 
   540 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   541   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   542 proof -
   543   assume r: "!!x y. x <= y ==> f x <= f y"
   544   assume "a <= b" hence "f a <= f b" by (rule r)
   545   also assume "f b < c"
   546   finally (order_le_less_trans) show ?thesis .
   547 qed
   548 
   549 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   550   (!!x y. x < y ==> f x < f y) ==> a < f c"
   551 proof -
   552   assume r: "!!x y. x < y ==> f x < f y"
   553   assume "a <= f b"
   554   also assume "b < c" hence "f b < f c" by (rule r)
   555   finally (order_le_less_trans) show ?thesis .
   556 qed
   557 
   558 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   559   (!!x y. x < y ==> f x < f y) ==> f a < c"
   560 proof -
   561   assume r: "!!x y. x < y ==> f x < f y"
   562   assume "a < b" hence "f a < f b" by (rule r)
   563   also assume "f b <= c"
   564   finally (order_less_le_trans) show ?thesis .
   565 qed
   566 
   567 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   568   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   569 proof -
   570   assume r: "!!x y. x <= y ==> f x <= f y"
   571   assume "a < f b"
   572   also assume "b <= c" hence "f b <= f c" by (rule r)
   573   finally (order_less_le_trans) show ?thesis .
   574 qed
   575 
   576 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   577   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   578 proof -
   579   assume r: "!!x y. x <= y ==> f x <= f y"
   580   assume "a <= f b"
   581   also assume "b <= c" hence "f b <= f c" by (rule r)
   582   finally (order_trans) show ?thesis .
   583 qed
   584 
   585 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   586   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   587 proof -
   588   assume r: "!!x y. x <= y ==> f x <= f y"
   589   assume "a <= b" hence "f a <= f b" by (rule r)
   590   also assume "f b <= c"
   591   finally (order_trans) show ?thesis .
   592 qed
   593 
   594 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   595   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   596 proof -
   597   assume r: "!!x y. x <= y ==> f x <= f y"
   598   assume "a <= b" hence "f a <= f b" by (rule r)
   599   also assume "f b = c"
   600   finally (ord_le_eq_trans) show ?thesis .
   601 qed
   602 
   603 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   604   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   605 proof -
   606   assume r: "!!x y. x <= y ==> f x <= f y"
   607   assume "a = f b"
   608   also assume "b <= c" hence "f b <= f c" by (rule r)
   609   finally (ord_eq_le_trans) show ?thesis .
   610 qed
   611 
   612 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   613   (!!x y. x < y ==> f x < f y) ==> f a < c"
   614 proof -
   615   assume r: "!!x y. x < y ==> f x < f y"
   616   assume "a < b" hence "f a < f b" by (rule r)
   617   also assume "f b = c"
   618   finally (ord_less_eq_trans) show ?thesis .
   619 qed
   620 
   621 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   622   (!!x y. x < y ==> f x < f y) ==> a < f c"
   623 proof -
   624   assume r: "!!x y. x < y ==> f x < f y"
   625   assume "a = f b"
   626   also assume "b < c" hence "f b < f c" by (rule r)
   627   finally (ord_eq_less_trans) show ?thesis .
   628 qed
   629 
   630 text {*
   631   Note that this list of rules is in reverse order of priorities.
   632 *}
   633 
   634 lemmas order_trans_rules [trans] =
   635   order_less_subst2
   636   order_less_subst1
   637   order_le_less_subst2
   638   order_le_less_subst1
   639   order_less_le_subst2
   640   order_less_le_subst1
   641   order_subst2
   642   order_subst1
   643   ord_le_eq_subst
   644   ord_eq_le_subst
   645   ord_less_eq_subst
   646   ord_eq_less_subst
   647   forw_subst
   648   back_subst
   649   rev_mp
   650   mp
   651   order_neq_le_trans
   652   order_le_neq_trans
   653   order_less_trans
   654   order_less_asym'
   655   order_le_less_trans
   656   order_less_le_trans
   657   order_trans
   658   order_antisym
   659   ord_le_eq_trans
   660   ord_eq_le_trans
   661   ord_less_eq_trans
   662   ord_eq_less_trans
   663   trans
   664 
   665 
   666 (* FIXME cleanup *)
   667 
   668 text {* These support proving chains of decreasing inequalities
   669     a >= b >= c ... in Isar proofs. *}
   670 
   671 lemma xt1:
   672   "a = b ==> b > c ==> a > c"
   673   "a > b ==> b = c ==> a > c"
   674   "a = b ==> b >= c ==> a >= c"
   675   "a >= b ==> b = c ==> a >= c"
   676   "(x::'a::order) >= y ==> y >= x ==> x = y"
   677   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   678   "(x::'a::order) > y ==> y >= z ==> x > z"
   679   "(x::'a::order) >= y ==> y > z ==> x > z"
   680   "(a::'a::order) > b ==> b > a ==> P"
   681   "(x::'a::order) > y ==> y > z ==> x > z"
   682   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   683   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   684   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   685   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   686   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   687   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   688 by auto
   689 
   690 lemma xt2:
   691   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   692 by (subgoal_tac "f b >= f c", force, force)
   693 
   694 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   695     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   696 by (subgoal_tac "f a >= f b", force, force)
   697 
   698 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   699   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   700 by (subgoal_tac "f b >= f c", force, force)
   701 
   702 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   703     (!!x y. x > y ==> f x > f y) ==> f a > c"
   704 by (subgoal_tac "f a > f b", force, force)
   705 
   706 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   707     (!!x y. x > y ==> f x > f y) ==> a > f c"
   708 by (subgoal_tac "f b > f c", force, force)
   709 
   710 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   711     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   712 by (subgoal_tac "f a >= f b", force, force)
   713 
   714 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   715     (!!x y. x > y ==> f x > f y) ==> a > f c"
   716 by (subgoal_tac "f b > f c", force, force)
   717 
   718 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   719     (!!x y. x > y ==> f x > f y) ==> f a > c"
   720 by (subgoal_tac "f a > f b", force, force)
   721 
   722 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   723 
   724 (* 
   725   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   726   for the wrong thing in an Isar proof.
   727 
   728   The extra transitivity rules can be used as follows: 
   729 
   730 lemma "(a::'a::order) > z"
   731 proof -
   732   have "a >= b" (is "_ >= ?rhs")
   733     sorry
   734   also have "?rhs >= c" (is "_ >= ?rhs")
   735     sorry
   736   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   737     sorry
   738   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   739     sorry
   740   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   741     sorry
   742   also (xtrans) have "?rhs > z"
   743     sorry
   744   finally (xtrans) show ?thesis .
   745 qed
   746 
   747   Alternatively, one can use "declare xtrans [trans]" and then
   748   leave out the "(xtrans)" above.
   749 *)
   750 
   751 subsection {* Order on bool *}
   752 
   753 instance bool :: order 
   754   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   755   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   756   by intro_classes (auto simp add: le_bool_def less_bool_def)
   757 
   758 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   759 by (simp add: le_bool_def)
   760 
   761 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   762 by (simp add: le_bool_def)
   763 
   764 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   765 by (simp add: le_bool_def)
   766 
   767 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   768 by (simp add: le_bool_def)
   769 
   770 lemma [code func]:
   771   "False \<le> b \<longleftrightarrow> True"
   772   "True \<le> b \<longleftrightarrow> b"
   773   "False < b \<longleftrightarrow> b"
   774   "True < b \<longleftrightarrow> False"
   775   unfolding le_bool_def less_bool_def by simp_all
   776 
   777 
   778 subsection {* Order on sets *}
   779 
   780 instance set :: (type) order
   781   by (intro_classes,
   782       (assumption | rule subset_refl subset_trans subset_antisym psubset_eq)+)
   783 
   784 lemmas basic_trans_rules [trans] =
   785   order_trans_rules set_rev_mp set_mp
   786 
   787 
   788 subsection {* Order on functions *}
   789 
   790 instance "fun" :: (type, ord) ord
   791   le_fun_def: "f \<le> g \<equiv> \<forall>x. f x \<le> g x"
   792   less_fun_def: "f < g \<equiv> f \<le> g \<and> f \<noteq> g" ..
   793 
   794 lemmas [code func del] = le_fun_def less_fun_def
   795 
   796 instance "fun" :: (type, order) order
   797   by default
   798     (auto simp add: le_fun_def less_fun_def expand_fun_eq
   799        intro: order_trans order_antisym)
   800 
   801 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
   802   unfolding le_fun_def by simp
   803 
   804 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
   805   unfolding le_fun_def by simp
   806 
   807 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
   808   unfolding le_fun_def by simp
   809 
   810 text {*
   811   Handy introduction and elimination rules for @{text "\<le>"}
   812   on unary and binary predicates
   813 *}
   814 
   815 lemma predicate1I [Pure.intro!, intro!]:
   816   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
   817   shows "P \<le> Q"
   818   apply (rule le_funI)
   819   apply (rule le_boolI)
   820   apply (rule PQ)
   821   apply assumption
   822   done
   823 
   824 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
   825   apply (erule le_funE)
   826   apply (erule le_boolE)
   827   apply assumption+
   828   done
   829 
   830 lemma predicate2I [Pure.intro!, intro!]:
   831   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
   832   shows "P \<le> Q"
   833   apply (rule le_funI)+
   834   apply (rule le_boolI)
   835   apply (rule PQ)
   836   apply assumption
   837   done
   838 
   839 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
   840   apply (erule le_funE)+
   841   apply (erule le_boolE)
   842   apply assumption+
   843   done
   844 
   845 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
   846   by (rule predicate1D)
   847 
   848 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
   849   by (rule predicate2D)
   850 
   851 
   852 subsection {* Monotonicity, least value operator and min/max *}
   853 
   854 locale mono =
   855   fixes f
   856   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   857 
   858 lemmas monoI [intro?] = mono.intro
   859   and monoD [dest?] = mono.mono
   860 
   861 lemma LeastI2_order:
   862   "[| P (x::'a::order);
   863       !!y. P y ==> x <= y;
   864       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   865    ==> Q (Least P)"
   866 apply (unfold Least_def)
   867 apply (rule theI2)
   868   apply (blast intro: order_antisym)+
   869 done
   870 
   871 lemma Least_mono:
   872   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
   873     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
   874     -- {* Courtesy of Stephan Merz *}
   875   apply clarify
   876   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
   877   apply (rule LeastI2_order)
   878   apply (auto elim: monoD intro!: order_antisym)
   879   done
   880 
   881 lemma Least_equality:
   882   "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   883 apply (simp add: Least_def)
   884 apply (rule the_equality)
   885 apply (auto intro!: order_antisym)
   886 done
   887 
   888 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   889 by (simp add: min_def)
   890 
   891 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   892 by (simp add: max_def)
   893 
   894 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   895 apply (simp add: min_def)
   896 apply (blast intro: order_antisym)
   897 done
   898 
   899 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   900 apply (simp add: max_def)
   901 apply (blast intro: order_antisym)
   902 done
   903 
   904 lemma min_of_mono:
   905   "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   906 by (simp add: min_def)
   907 
   908 lemma max_of_mono:
   909   "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   910 by (simp add: max_def)
   911 
   912 
   913 subsection {* legacy ML bindings *}
   914 
   915 ML {*
   916 val monoI = @{thm monoI};
   917 *}
   918 
   919 end