src/Pure/axclass.ML
author wenzelm
Mon Oct 13 17:49:08 1997 +0200 (1997-10-13)
changeset 3854 762606a888fe
parent 3809 6633694439c0
child 3938 c20fbe3cb94f
permissions -rw-r--r--
uses Sign.str_of_classrel, Sign.str_of_arity, Sign.str_of_arity;
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 User interfaces for axiomatic type classes.
     6 *)
     7 
     8 signature AX_CLASS =
     9   sig
    10   val add_thms_as_axms: (string * thm) list -> theory -> theory
    11   val add_classrel_thms: thm list -> theory -> theory
    12   val add_arity_thms: thm list -> theory -> theory
    13   val add_axclass: class * class list -> (string * string) list
    14     -> theory -> theory
    15   val add_axclass_i: class * class list -> (string * term) list
    16     -> theory -> theory
    17   val add_inst_subclass_i: class * class -> string list -> thm list
    18     -> tactic option -> theory -> theory
    19   val add_inst_subclass: class * class -> string list -> thm list
    20     -> tactic option -> theory -> theory
    21   val add_inst_arity_i: string * sort list * class list -> string list
    22     -> thm list -> tactic option -> theory -> theory
    23   val add_inst_arity: string * sort list * class list -> string list
    24     -> thm list -> tactic option -> theory -> theory
    25   val axclass_tac: theory -> thm list -> tactic
    26   val prove_subclass: theory -> class * class -> thm list
    27     -> tactic option -> thm
    28   val prove_arity: theory -> string * sort list * class -> thm list
    29     -> tactic option -> thm
    30   val goal_subclass: theory -> class * class -> thm list
    31   val goal_arity: theory -> string * sort list * class -> thm list
    32   end;
    33 
    34 structure AxClass : AX_CLASS =
    35 struct
    36 
    37 (** utilities **)
    38 
    39 (* type vars *)
    40 
    41 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    42   | map_typ_frees f (TFree a) = f a
    43   | map_typ_frees _ a = a;
    44 
    45 val map_term_tfrees = map_term_types o map_typ_frees;
    46 
    47 fun aT S = TFree ("'a", S);
    48 
    49 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    50   | dest_varT (TVar xi_S) = xi_S
    51   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    52 
    53 
    54 (* get axioms and theorems *)
    55 
    56 fun get_ax thy name =
    57   Some (get_axiom thy name) handle THEORY _ => None;
    58 
    59 val get_axioms = mapfilter o get_ax;
    60 
    61 val is_def = Logic.is_equals o #prop o rep_thm;
    62 
    63 fun witnesses thy axms thms =
    64   map (get_axiom thy) axms @ thms @ filter is_def (map snd (axioms_of thy));
    65 
    66 
    67 
    68 (** abstract syntax operations **)
    69 
    70 (* subclass relations as terms *)
    71 
    72 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    73 
    74 fun dest_classrel tm =
    75   let
    76     fun err () = raise TERM ("dest_classrel", [tm]);
    77 
    78     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    79     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    80       handle TYPE _ => err ();
    81   in
    82     (c1, c2)
    83   end;
    84 
    85 
    86 (* arities as terms *)
    87 
    88 fun mk_arity (t, ss, c) =
    89   let
    90     val names = tl (variantlist (replicate (length ss + 1) "'", []));
    91     val tfrees = ListPair.map TFree (names, ss);
    92   in
    93     Logic.mk_inclass (Type (t, tfrees), c)
    94   end;
    95 
    96 fun dest_arity tm =
    97   let
    98     fun err () = raise TERM ("dest_arity", [tm]);
    99 
   100     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
   101     val (t, tvars) =
   102       (case ty of
   103         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   104       | _ => err ());
   105     val ss =
   106       if null (gen_duplicates eq_fst tvars)
   107       then map snd tvars else err ();
   108   in
   109     (t, ss, c)
   110   end;
   111 
   112 
   113 
   114 (** add theorems as axioms **)
   115 
   116 fun prep_thm_axm thy thm =
   117   let
   118     fun err msg = raise THM ("prep_thm_axm: " ^ msg, 0, [thm]);
   119 
   120     val {sign, hyps, prop, ...} = rep_thm thm;
   121   in
   122     if not (Sign.subsig (sign, sign_of thy)) then
   123       err "theorem not of same theory"
   124     else if not (null (extra_shyps thm)) orelse not (null hyps) then
   125       err "theorem may not contain hypotheses"
   126     else prop
   127   end;
   128 
   129 (*general theorems*)
   130 fun add_thms_as_axms thms thy =
   131   Theory.add_axioms_i (map (apsnd (prep_thm_axm thy)) thms) thy;
   132 
   133 (*theorems expressing class relations*)
   134 fun add_classrel_thms thms thy =
   135   let
   136     fun prep_thm thm =
   137       let
   138         val prop = prep_thm_axm thy thm;
   139         val (c1, c2) = dest_classrel prop handle TERM _ =>
   140           raise THM ("add_classrel_thms: theorem is not a class relation", 0, [thm]);
   141       in (c1, c2) end;
   142   in
   143     Theory.add_classrel (map prep_thm thms) thy
   144   end;
   145 
   146 (*theorems expressing arities*)
   147 fun add_arity_thms thms thy =
   148   let
   149     fun prep_thm thm =
   150       let
   151         val prop = prep_thm_axm thy thm;
   152         val (t, ss, c) = dest_arity prop handle TERM _ =>
   153           raise THM ("add_arity_thms: theorem is not an arity", 0, [thm]);
   154       in (t, ss, [c]) end;
   155   in
   156     Theory.add_arities (map prep_thm thms) thy
   157   end;
   158 
   159 
   160 
   161 (** add axiomatic type classes **)
   162 
   163 (* errors *)
   164 
   165 fun err_not_logic c =
   166   error ("Axiomatic class " ^ quote c ^ " not subclass of \"logic\"");
   167 
   168 fun err_bad_axsort ax c =
   169   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   170 
   171 fun err_bad_tfrees ax =
   172   error ("More than one type variable in axiom " ^ quote ax);
   173 
   174 
   175 (* ext_axclass *)
   176 
   177 fun ext_axclass int prep_axm (raw_class, raw_super_classes) raw_axioms old_thy =
   178   let
   179     val axioms = map (prep_axm (sign_of old_thy)) raw_axioms;
   180     val thy =
   181       (if int then Theory.add_classes else Theory.add_classes_i)
   182         [(raw_class, raw_super_classes)] old_thy;
   183     val sign = sign_of thy;
   184     val class = Sign.intern_class sign raw_class;
   185     val super_classes = map (Sign.intern_class sign) raw_super_classes;
   186 
   187 
   188     (* prepare abstract axioms *)
   189 
   190     fun abs_axm ax =
   191       if null (term_tfrees ax) then
   192         Logic.mk_implies (Logic.mk_inclass (aT logicS, class), ax)
   193       else map_term_tfrees (K (aT [class])) ax;
   194 
   195     val abs_axioms = map (apsnd abs_axm) axioms;
   196 
   197 
   198     (* prepare introduction orule *)
   199 
   200     val _ =
   201       if Sign.subsort sign ([class], logicS) then ()
   202       else err_not_logic class;
   203 
   204     fun axm_sort (name, ax) =
   205       (case term_tfrees ax of
   206         [] => []
   207       | [(_, S)] =>
   208           if Sign.subsort sign ([class], S) then S
   209           else err_bad_axsort name class
   210       | _ => err_bad_tfrees name);
   211 
   212     val axS = Sign.norm_sort sign (logicC :: flat (map axm_sort axioms))
   213 
   214     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   215     fun inclass c = Logic.mk_inclass (aT axS, c);
   216 
   217     val intro_axm = Logic.list_implies
   218       (map inclass super_classes @ map (int_axm o snd) axioms, inclass class);
   219   in
   220     Theory.add_axioms_i ((raw_class ^ "I", intro_axm) :: abs_axioms) thy
   221   end;
   222 
   223 
   224 (* external interfaces *)
   225 
   226 val add_axclass = ext_axclass true read_axm;
   227 val add_axclass_i = ext_axclass false cert_axm;
   228 
   229 
   230 
   231 (** prove class relations and type arities **)
   232 
   233 (* class_axms *)
   234 
   235 fun class_axms thy =
   236   let
   237     val classes = Sign.classes (sign_of thy);
   238     val intros = map (fn c => c ^ "I") classes;
   239   in
   240     map (class_triv thy) classes @
   241     get_axioms thy intros
   242   end;
   243 
   244 
   245 (* axclass_tac *)
   246 
   247 (*(1) repeatedly resolve goals of form "OFCLASS(ty, c_class)",
   248       try class_trivs first, then "cI" axioms
   249   (2) rewrite goals using user supplied definitions
   250   (3) repeatedly resolve goals with user supplied non-definitions*)
   251 
   252 fun axclass_tac thy thms =
   253   let
   254     val defs = filter is_def thms;
   255     val non_defs = filter_out is_def thms;
   256   in
   257     TRY (REPEAT_FIRST (resolve_tac (class_axms thy))) THEN
   258     TRY (rewrite_goals_tac defs) THEN
   259     TRY (REPEAT_FIRST (fn i => assume_tac i ORELSE resolve_tac non_defs i))
   260   end;
   261 
   262 
   263 (* provers *)
   264 
   265 fun prove term_of str_of thy sig_prop thms usr_tac =
   266   let
   267     val sign = sign_of thy;
   268     val goal = cterm_of sign (term_of sig_prop);
   269     val tac = axclass_tac thy thms THEN (if_none usr_tac all_tac);
   270   in
   271     prove_goalw_cterm [] goal (K [tac])
   272   end
   273   handle ERROR => error ("The error(s) above occurred while trying to prove "
   274     ^ quote (str_of (sign_of thy, sig_prop)));
   275 
   276 val prove_subclass =
   277   prove mk_classrel (fn (sg, c1_c2) => Sign.str_of_classrel sg c1_c2);
   278 
   279 val prove_arity =
   280   prove mk_arity (fn (sg, (t, Ss, c)) => Sign.str_of_arity sg (t, Ss, [c]));
   281 
   282 
   283 (* make goals (for interactive use) *)
   284 
   285 fun mk_goal term_of thy sig_prop =
   286   goalw_cterm [] (cterm_of (sign_of thy) (term_of sig_prop));
   287 
   288 val goal_subclass = mk_goal mk_classrel;
   289 val goal_arity = mk_goal mk_arity;
   290 
   291 
   292 
   293 (** add proved subclass relations and arities **)
   294 
   295 fun ext_inst_subclass int raw_c1_c2 axms thms usr_tac thy =
   296   let
   297     val intrn = if int then pairself (Sign.intern_class (sign_of thy)) else I;
   298     val c1_c2 = intrn raw_c1_c2;
   299   in
   300     writeln ("Proving class inclusion " ^
   301       quote (Sign.str_of_classrel (sign_of thy) c1_c2) ^ " ...");
   302     add_classrel_thms
   303       [prove_subclass thy c1_c2 (witnesses thy axms thms) usr_tac] thy
   304   end;
   305 
   306 
   307 fun ext_inst_arity int (raw_t, raw_Ss, raw_cs) axms thms usr_tac thy =
   308   let
   309     val sign = sign_of thy;
   310     val (t, Ss, cs) =
   311       if int then
   312         (Sign.intern_tycon sign raw_t,
   313           map (Sign.intern_sort sign) raw_Ss,
   314           map (Sign.intern_class sign) raw_cs)
   315       else (raw_t, raw_Ss, raw_cs);
   316     val wthms = witnesses thy axms thms;
   317     fun prove c =
   318      (writeln ("Proving type arity " ^
   319         quote (Sign.str_of_arity sign (t, Ss, [c])) ^ " ...");
   320         prove_arity thy (t, Ss, c) wthms usr_tac);
   321   in
   322     add_arity_thms (map prove cs) thy
   323   end;
   324 
   325 val add_inst_subclass = ext_inst_subclass true;
   326 val add_inst_subclass_i = ext_inst_subclass false;
   327 val add_inst_arity = ext_inst_arity true;
   328 val add_inst_arity_i = ext_inst_arity false;
   329 
   330 
   331 end;