src/HOL/Hilbert_Choice.thy
author huffman
Thu Feb 18 14:21:44 2010 -0800 (2010-02-18)
changeset 35216 7641e8d831d2
parent 35115 446c5063e4fd
child 35416 d8d7d1b785af
permissions -rw-r--r--
get rid of many duplicate simp rule warnings
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     Author:     Lawrence C Paulson, Tobias Nipkow
     3     Copyright   2001  University of Cambridge
     4 *)
     5 
     6 header {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
     7 
     8 theory Hilbert_Choice
     9 imports Nat Wellfounded Plain
    10 uses ("Tools/meson.ML") ("Tools/choice_specification.ML")
    11 begin
    12 
    13 subsection {* Hilbert's epsilon *}
    14 
    15 axiomatization Eps :: "('a => bool) => 'a" where
    16   someI: "P x ==> P (Eps P)"
    17 
    18 syntax (epsilon)
    19   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
    20 syntax (HOL)
    21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
    22 syntax
    23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
    24 translations
    25   "SOME x. P" == "CONST Eps (%x. P)"
    26 
    27 print_translation {*
    28   [(@{const_syntax Eps}, fn [Abs abs] =>
    29       let val (x, t) = atomic_abs_tr' abs
    30       in Syntax.const @{syntax_const "_Eps"} $ x $ t end)]
    31 *} -- {* to avoid eta-contraction of body *}
    32 
    33 definition inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
    34 "inv_into A f == %x. SOME y. y : A & f y = x"
    35 
    36 abbreviation inv :: "('a => 'b) => ('b => 'a)" where
    37 "inv == inv_into UNIV"
    38 
    39 
    40 subsection {*Hilbert's Epsilon-operator*}
    41 
    42 text{*Easier to apply than @{text someI} if the witness comes from an
    43 existential formula*}
    44 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
    45 apply (erule exE)
    46 apply (erule someI)
    47 done
    48 
    49 text{*Easier to apply than @{text someI} because the conclusion has only one
    50 occurrence of @{term P}.*}
    51 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    52 by (blast intro: someI)
    53 
    54 text{*Easier to apply than @{text someI2} if the witness comes from an
    55 existential formula*}
    56 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    57 by (blast intro: someI2)
    58 
    59 lemma some_equality [intro]:
    60      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
    61 by (blast intro: someI2)
    62 
    63 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
    64 by blast
    65 
    66 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
    67 by (blast intro: someI)
    68 
    69 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
    70 apply (rule some_equality)
    71 apply (rule refl, assumption)
    72 done
    73 
    74 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
    75 apply (rule some_equality)
    76 apply (rule refl)
    77 apply (erule sym)
    78 done
    79 
    80 
    81 subsection{*Axiom of Choice, Proved Using the Description Operator*}
    82 
    83 text{*Used in @{text "Tools/meson.ML"}*}
    84 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
    85 by (fast elim: someI)
    86 
    87 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    88 by (fast elim: someI)
    89 
    90 
    91 subsection {*Function Inverse*}
    92 
    93 lemma inv_def: "inv f = (%y. SOME x. f x = y)"
    94 by(simp add: inv_into_def)
    95 
    96 lemma inv_into_into: "x : f ` A ==> inv_into A f x : A"
    97 apply (simp add: inv_into_def)
    98 apply (fast intro: someI2)
    99 done
   100 
   101 lemma inv_id [simp]: "inv id = id"
   102 by (simp add: inv_into_def id_def)
   103 
   104 lemma inv_into_f_f [simp]:
   105   "[| inj_on f A;  x : A |] ==> inv_into A f (f x) = x"
   106 apply (simp add: inv_into_def inj_on_def)
   107 apply (blast intro: someI2)
   108 done
   109 
   110 lemma inv_f_f: "inj f ==> inv f (f x) = x"
   111 by simp
   112 
   113 lemma f_inv_into_f: "y : f`A  ==> f (inv_into A f y) = y"
   114 apply (simp add: inv_into_def)
   115 apply (fast intro: someI2)
   116 done
   117 
   118 lemma inv_into_f_eq: "[| inj_on f A; x : A; f x = y |] ==> inv_into A f y = x"
   119 apply (erule subst)
   120 apply (fast intro: inv_into_f_f)
   121 done
   122 
   123 lemma inv_f_eq: "[| inj f; f x = y |] ==> inv f y = x"
   124 by (simp add:inv_into_f_eq)
   125 
   126 lemma inj_imp_inv_eq: "[| inj f; ALL x. f(g x) = x |] ==> inv f = g"
   127 by (blast intro: ext inv_into_f_eq)
   128 
   129 text{*But is it useful?*}
   130 lemma inj_transfer:
   131   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
   132   shows "P x"
   133 proof -
   134   have "f x \<in> range f" by auto
   135   hence "P(inv f (f x))" by (rule minor)
   136   thus "P x" by (simp add: inv_into_f_f [OF injf])
   137 qed
   138 
   139 lemma inj_iff: "(inj f) = (inv f o f = id)"
   140 apply (simp add: o_def expand_fun_eq)
   141 apply (blast intro: inj_on_inverseI inv_into_f_f)
   142 done
   143 
   144 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
   145 by (simp add: inj_iff)
   146 
   147 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
   148 by (simp add: o_assoc[symmetric])
   149 
   150 lemma inv_into_image_cancel[simp]:
   151   "inj_on f A ==> S <= A ==> inv_into A f ` f ` S = S"
   152 by(fastsimp simp: image_def)
   153 
   154 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
   155 by (blast intro: surjI inv_into_f_f)
   156 
   157 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
   158 by (simp add: f_inv_into_f surj_range)
   159 
   160 lemma inv_into_injective:
   161   assumes eq: "inv_into A f x = inv_into A f y"
   162       and x: "x: f`A"
   163       and y: "y: f`A"
   164   shows "x=y"
   165 proof -
   166   have "f (inv_into A f x) = f (inv_into A f y)" using eq by simp
   167   thus ?thesis by (simp add: f_inv_into_f x y)
   168 qed
   169 
   170 lemma inj_on_inv_into: "B <= f`A ==> inj_on (inv_into A f) B"
   171 by (blast intro: inj_onI dest: inv_into_injective injD)
   172 
   173 lemma bij_betw_inv_into: "bij_betw f A B ==> bij_betw (inv_into A f) B A"
   174 by (auto simp add: bij_betw_def inj_on_inv_into)
   175 
   176 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
   177 by (simp add: inj_on_inv_into surj_range)
   178 
   179 lemma surj_iff: "(surj f) = (f o inv f = id)"
   180 apply (simp add: o_def expand_fun_eq)
   181 apply (blast intro: surjI surj_f_inv_f)
   182 done
   183 
   184 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
   185 apply (rule ext)
   186 apply (drule_tac x = "inv f x" in spec)
   187 apply (simp add: surj_f_inv_f)
   188 done
   189 
   190 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
   191 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
   192 
   193 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
   194 apply (rule ext)
   195 apply (auto simp add: inv_into_def)
   196 done
   197 
   198 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
   199 apply (rule inv_equality)
   200 apply (auto simp add: bij_def surj_f_inv_f)
   201 done
   202 
   203 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
   204     f(True)=f(False)=True.  Then it's consistent with axiom someI that
   205     inv f could be any function at all, including the identity function.
   206     If inv f=id then inv f is a bijection, but inj f, surj(f) and
   207     inv(inv f)=f all fail.
   208 **)
   209 
   210 lemma inv_into_comp:
   211   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   212   inv_into A (f o g) x = (inv_into A g o inv_into (g ` A) f) x"
   213 apply (rule inv_into_f_eq)
   214   apply (fast intro: comp_inj_on)
   215  apply (simp add: inv_into_into)
   216 apply (simp add: f_inv_into_f inv_into_into)
   217 done
   218 
   219 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
   220 apply (rule inv_equality)
   221 apply (auto simp add: bij_def surj_f_inv_f)
   222 done
   223 
   224 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
   225 by (simp add: image_eq_UN surj_f_inv_f)
   226 
   227 lemma image_inv_f_f: "inj f ==> (inv f) ` (f ` A) = A"
   228 by (simp add: image_eq_UN)
   229 
   230 lemma inv_image_comp: "inj f ==> inv f ` (f`X) = X"
   231 by (auto simp add: image_def)
   232 
   233 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
   234 apply auto
   235 apply (force simp add: bij_is_inj)
   236 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
   237 done
   238 
   239 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A" 
   240 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
   241 apply (blast intro: bij_is_inj [THEN inv_into_f_f, symmetric])
   242 done
   243 
   244 lemma finite_fun_UNIVD1:
   245   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
   246   and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
   247   shows "finite (UNIV :: 'a set)"
   248 proof -
   249   from fin have finb: "finite (UNIV :: 'b set)" by (rule finite_fun_UNIVD2)
   250   with card have "card (UNIV :: 'b set) \<ge> Suc (Suc 0)"
   251     by (cases "card (UNIV :: 'b set)") (auto simp add: card_eq_0_iff)
   252   then obtain n where "card (UNIV :: 'b set) = Suc (Suc n)" "n = card (UNIV :: 'b set) - Suc (Suc 0)" by auto
   253   then obtain b1 b2 where b1b2: "(b1 :: 'b) \<noteq> (b2 :: 'b)" by (auto simp add: card_Suc_eq)
   254   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))" by (rule finite_imageI)
   255   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
   256   proof (rule UNIV_eq_I)
   257     fix x :: 'a
   258     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1" by (simp add: inv_into_def)
   259     thus "x \<in> range (\<lambda>f\<Colon>'a \<Rightarrow> 'b. inv f b1)" by blast
   260   qed
   261   ultimately show "finite (UNIV :: 'a set)" by simp
   262 qed
   263 
   264 
   265 subsection {*Other Consequences of Hilbert's Epsilon*}
   266 
   267 text {*Hilbert's Epsilon and the @{term split} Operator*}
   268 
   269 text{*Looping simprule*}
   270 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
   271   by simp
   272 
   273 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
   274   by (simp add: split_def)
   275 
   276 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
   277   by blast
   278 
   279 
   280 text{*A relation is wellfounded iff it has no infinite descending chain*}
   281 lemma wf_iff_no_infinite_down_chain:
   282   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
   283 apply (simp only: wf_eq_minimal)
   284 apply (rule iffI)
   285  apply (rule notI)
   286  apply (erule exE)
   287  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
   288 apply (erule contrapos_np, simp, clarify)
   289 apply (subgoal_tac "\<forall>n. nat_rec x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
   290  apply (rule_tac x = "nat_rec x (%i y. @z. z:Q & (z,y) :r)" in exI)
   291  apply (rule allI, simp)
   292  apply (rule someI2_ex, blast, blast)
   293 apply (rule allI)
   294 apply (induct_tac "n", simp_all)
   295 apply (rule someI2_ex, blast+)
   296 done
   297 
   298 lemma wf_no_infinite_down_chainE:
   299   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
   300 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
   301 
   302 
   303 text{*A dynamically-scoped fact for TFL *}
   304 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
   305   by (blast intro: someI)
   306 
   307 
   308 subsection {* Least value operator *}
   309 
   310 constdefs
   311   LeastM :: "['a => 'b::ord, 'a => bool] => 'a"
   312   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
   313 
   314 syntax
   315   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
   316 translations
   317   "LEAST x WRT m. P" == "CONST LeastM m (%x. P)"
   318 
   319 lemma LeastMI2:
   320   "P x ==> (!!y. P y ==> m x <= m y)
   321     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
   322     ==> Q (LeastM m P)"
   323   apply (simp add: LeastM_def)
   324   apply (rule someI2_ex, blast, blast)
   325   done
   326 
   327 lemma LeastM_equality:
   328   "P k ==> (!!x. P x ==> m k <= m x)
   329     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
   330   apply (rule LeastMI2, assumption, blast)
   331   apply (blast intro!: order_antisym)
   332   done
   333 
   334 lemma wf_linord_ex_has_least:
   335   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
   336     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
   337   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
   338   apply (drule_tac x = "m`Collect P" in spec, force)
   339   done
   340 
   341 lemma ex_has_least_nat:
   342     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
   343   apply (simp only: pred_nat_trancl_eq_le [symmetric])
   344   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
   345    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
   346   done
   347 
   348 lemma LeastM_nat_lemma:
   349     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
   350   apply (simp add: LeastM_def)
   351   apply (rule someI_ex)
   352   apply (erule ex_has_least_nat)
   353   done
   354 
   355 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1, standard]
   356 
   357 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
   358 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
   359 
   360 
   361 subsection {* Greatest value operator *}
   362 
   363 constdefs
   364   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a"
   365   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
   366 
   367   Greatest :: "('a::ord => bool) => 'a"    (binder "GREATEST " 10)
   368   "Greatest == GreatestM (%x. x)"
   369 
   370 syntax
   371   "_GreatestM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"
   372       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   373 translations
   374   "GREATEST x WRT m. P" == "CONST GreatestM m (%x. P)"
   375 
   376 lemma GreatestMI2:
   377   "P x ==> (!!y. P y ==> m y <= m x)
   378     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
   379     ==> Q (GreatestM m P)"
   380   apply (simp add: GreatestM_def)
   381   apply (rule someI2_ex, blast, blast)
   382   done
   383 
   384 lemma GreatestM_equality:
   385  "P k ==> (!!x. P x ==> m x <= m k)
   386     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
   387   apply (rule_tac m = m in GreatestMI2, assumption, blast)
   388   apply (blast intro!: order_antisym)
   389   done
   390 
   391 lemma Greatest_equality:
   392   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
   393   apply (simp add: Greatest_def)
   394   apply (erule GreatestM_equality, blast)
   395   done
   396 
   397 lemma ex_has_greatest_nat_lemma:
   398   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
   399     ==> \<exists>y. P y & ~ (m y < m k + n)"
   400   apply (induct n, force)
   401   apply (force simp add: le_Suc_eq)
   402   done
   403 
   404 lemma ex_has_greatest_nat:
   405   "P k ==> \<forall>y. P y --> m y < b
   406     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
   407   apply (rule ccontr)
   408   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   409     apply (subgoal_tac [3] "m k <= b", auto)
   410   done
   411 
   412 lemma GreatestM_nat_lemma:
   413   "P k ==> \<forall>y. P y --> m y < b
   414     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
   415   apply (simp add: GreatestM_def)
   416   apply (rule someI_ex)
   417   apply (erule ex_has_greatest_nat, assumption)
   418   done
   419 
   420 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1, standard]
   421 
   422 lemma GreatestM_nat_le:
   423   "P x ==> \<forall>y. P y --> m y < b
   424     ==> (m x::nat) <= m (GreatestM m P)"
   425   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
   426   done
   427 
   428 
   429 text {* \medskip Specialization to @{text GREATEST}. *}
   430 
   431 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
   432   apply (simp add: Greatest_def)
   433   apply (rule GreatestM_natI, auto)
   434   done
   435 
   436 lemma Greatest_le:
   437     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
   438   apply (simp add: Greatest_def)
   439   apply (rule GreatestM_nat_le, auto)
   440   done
   441 
   442 
   443 subsection {* The Meson proof procedure *}
   444 
   445 subsubsection {* Negation Normal Form *}
   446 
   447 text {* de Morgan laws *}
   448 
   449 lemma meson_not_conjD: "~(P&Q) ==> ~P | ~Q"
   450   and meson_not_disjD: "~(P|Q) ==> ~P & ~Q"
   451   and meson_not_notD: "~~P ==> P"
   452   and meson_not_allD: "!!P. ~(\<forall>x. P(x)) ==> \<exists>x. ~P(x)"
   453   and meson_not_exD: "!!P. ~(\<exists>x. P(x)) ==> \<forall>x. ~P(x)"
   454   by fast+
   455 
   456 text {* Removal of @{text "-->"} and @{text "<->"} (positive and
   457 negative occurrences) *}
   458 
   459 lemma meson_imp_to_disjD: "P-->Q ==> ~P | Q"
   460   and meson_not_impD: "~(P-->Q) ==> P & ~Q"
   461   and meson_iff_to_disjD: "P=Q ==> (~P | Q) & (~Q | P)"
   462   and meson_not_iffD: "~(P=Q) ==> (P | Q) & (~P | ~Q)"
   463     -- {* Much more efficient than @{prop "(P & ~Q) | (Q & ~P)"} for computing CNF *}
   464   and meson_not_refl_disj_D: "x ~= x | P ==> P"
   465   by fast+
   466 
   467 
   468 subsubsection {* Pulling out the existential quantifiers *}
   469 
   470 text {* Conjunction *}
   471 
   472 lemma meson_conj_exD1: "!!P Q. (\<exists>x. P(x)) & Q ==> \<exists>x. P(x) & Q"
   473   and meson_conj_exD2: "!!P Q. P & (\<exists>x. Q(x)) ==> \<exists>x. P & Q(x)"
   474   by fast+
   475 
   476 
   477 text {* Disjunction *}
   478 
   479 lemma meson_disj_exD: "!!P Q. (\<exists>x. P(x)) | (\<exists>x. Q(x)) ==> \<exists>x. P(x) | Q(x)"
   480   -- {* DO NOT USE with forall-Skolemization: makes fewer schematic variables!! *}
   481   -- {* With ex-Skolemization, makes fewer Skolem constants *}
   482   and meson_disj_exD1: "!!P Q. (\<exists>x. P(x)) | Q ==> \<exists>x. P(x) | Q"
   483   and meson_disj_exD2: "!!P Q. P | (\<exists>x. Q(x)) ==> \<exists>x. P | Q(x)"
   484   by fast+
   485 
   486 
   487 subsubsection {* Generating clauses for the Meson Proof Procedure *}
   488 
   489 text {* Disjunctions *}
   490 
   491 lemma meson_disj_assoc: "(P|Q)|R ==> P|(Q|R)"
   492   and meson_disj_comm: "P|Q ==> Q|P"
   493   and meson_disj_FalseD1: "False|P ==> P"
   494   and meson_disj_FalseD2: "P|False ==> P"
   495   by fast+
   496 
   497 
   498 subsection{*Lemmas for Meson, the Model Elimination Procedure*}
   499 
   500 text{* Generation of contrapositives *}
   501 
   502 text{*Inserts negated disjunct after removing the negation; P is a literal.
   503   Model elimination requires assuming the negation of every attempted subgoal,
   504   hence the negated disjuncts.*}
   505 lemma make_neg_rule: "~P|Q ==> ((~P==>P) ==> Q)"
   506 by blast
   507 
   508 text{*Version for Plaisted's "Postive refinement" of the Meson procedure*}
   509 lemma make_refined_neg_rule: "~P|Q ==> (P ==> Q)"
   510 by blast
   511 
   512 text{*@{term P} should be a literal*}
   513 lemma make_pos_rule: "P|Q ==> ((P==>~P) ==> Q)"
   514 by blast
   515 
   516 text{*Versions of @{text make_neg_rule} and @{text make_pos_rule} that don't
   517 insert new assumptions, for ordinary resolution.*}
   518 
   519 lemmas make_neg_rule' = make_refined_neg_rule
   520 
   521 lemma make_pos_rule': "[|P|Q; ~P|] ==> Q"
   522 by blast
   523 
   524 text{* Generation of a goal clause -- put away the final literal *}
   525 
   526 lemma make_neg_goal: "~P ==> ((~P==>P) ==> False)"
   527 by blast
   528 
   529 lemma make_pos_goal: "P ==> ((P==>~P) ==> False)"
   530 by blast
   531 
   532 
   533 subsubsection{* Lemmas for Forward Proof*}
   534 
   535 text{*There is a similarity to congruence rules*}
   536 
   537 (*NOTE: could handle conjunctions (faster?) by
   538     nf(th RS conjunct2) RS (nf(th RS conjunct1) RS conjI) *)
   539 lemma conj_forward: "[| P'&Q';  P' ==> P;  Q' ==> Q |] ==> P&Q"
   540 by blast
   541 
   542 lemma disj_forward: "[| P'|Q';  P' ==> P;  Q' ==> Q |] ==> P|Q"
   543 by blast
   544 
   545 (*Version of @{text disj_forward} for removal of duplicate literals*)
   546 lemma disj_forward2:
   547     "[| P'|Q';  P' ==> P;  [| Q'; P==>False |] ==> Q |] ==> P|Q"
   548 apply blast 
   549 done
   550 
   551 lemma all_forward: "[| \<forall>x. P'(x);  !!x. P'(x) ==> P(x) |] ==> \<forall>x. P(x)"
   552 by blast
   553 
   554 lemma ex_forward: "[| \<exists>x. P'(x);  !!x. P'(x) ==> P(x) |] ==> \<exists>x. P(x)"
   555 by blast
   556 
   557 
   558 subsection {* Meson package *}
   559 
   560 use "Tools/meson.ML"
   561 
   562 setup Meson.setup
   563 
   564 
   565 subsection {* Specification package -- Hilbertized version *}
   566 
   567 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
   568   by (simp only: someI_ex)
   569 
   570 use "Tools/choice_specification.ML"
   571 
   572 
   573 end