src/HOL/Power.thy
author huffman
Thu Feb 18 14:21:44 2010 -0800 (2010-02-18)
changeset 35216 7641e8d831d2
parent 35028 108662d50512
child 35828 46cfc4b8112e
permissions -rw-r--r--
get rid of many duplicate simp rule warnings
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 header {* Exponentiation *}
     7 
     8 theory Power
     9 imports Nat
    10 begin
    11 
    12 subsection {* Powers for Arbitrary Monoids *}
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    18     power_0: "a ^ 0 = 1"
    19   | power_Suc: "a ^ Suc n = a * a ^ n"
    20 
    21 notation (latex output)
    22   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    23 
    24 notation (HTML output)
    25   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    26 
    27 end
    28 
    29 context monoid_mult
    30 begin
    31 
    32 subclass power ..
    33 
    34 lemma power_one [simp]:
    35   "1 ^ n = 1"
    36   by (induct n) simp_all
    37 
    38 lemma power_one_right [simp]:
    39   "a ^ 1 = a"
    40   by simp
    41 
    42 lemma power_commutes:
    43   "a ^ n * a = a * a ^ n"
    44   by (induct n) (simp_all add: mult_assoc)
    45 
    46 lemma power_Suc2:
    47   "a ^ Suc n = a ^ n * a"
    48   by (simp add: power_commutes)
    49 
    50 lemma power_add:
    51   "a ^ (m + n) = a ^ m * a ^ n"
    52   by (induct m) (simp_all add: algebra_simps)
    53 
    54 lemma power_mult:
    55   "a ^ (m * n) = (a ^ m) ^ n"
    56   by (induct n) (simp_all add: power_add)
    57 
    58 end
    59 
    60 context comm_monoid_mult
    61 begin
    62 
    63 lemma power_mult_distrib:
    64   "(a * b) ^ n = (a ^ n) * (b ^ n)"
    65   by (induct n) (simp_all add: mult_ac)
    66 
    67 end
    68 
    69 context semiring_1
    70 begin
    71 
    72 lemma of_nat_power:
    73   "of_nat (m ^ n) = of_nat m ^ n"
    74   by (induct n) (simp_all add: of_nat_mult)
    75 
    76 end
    77 
    78 context comm_semiring_1
    79 begin
    80 
    81 text {* The divides relation *}
    82 
    83 lemma le_imp_power_dvd:
    84   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
    85 proof
    86   have "a ^ n = a ^ (m + (n - m))"
    87     using `m \<le> n` by simp
    88   also have "\<dots> = a ^ m * a ^ (n - m)"
    89     by (rule power_add)
    90   finally show "a ^ n = a ^ m * a ^ (n - m)" .
    91 qed
    92 
    93 lemma power_le_dvd:
    94   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
    95   by (rule dvd_trans [OF le_imp_power_dvd])
    96 
    97 lemma dvd_power_same:
    98   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
    99   by (induct n) (auto simp add: mult_dvd_mono)
   100 
   101 lemma dvd_power_le:
   102   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   103   by (rule power_le_dvd [OF dvd_power_same])
   104 
   105 lemma dvd_power [simp]:
   106   assumes "n > (0::nat) \<or> x = 1"
   107   shows "x dvd (x ^ n)"
   108 using assms proof
   109   assume "0 < n"
   110   then have "x ^ n = x ^ Suc (n - 1)" by simp
   111   then show "x dvd (x ^ n)" by simp
   112 next
   113   assume "x = 1"
   114   then show "x dvd (x ^ n)" by simp
   115 qed
   116 
   117 end
   118 
   119 context ring_1
   120 begin
   121 
   122 lemma power_minus:
   123   "(- a) ^ n = (- 1) ^ n * a ^ n"
   124 proof (induct n)
   125   case 0 show ?case by simp
   126 next
   127   case (Suc n) then show ?case
   128     by (simp del: power_Suc add: power_Suc2 mult_assoc)
   129 qed
   130 
   131 end
   132 
   133 context linordered_semidom
   134 begin
   135 
   136 lemma zero_less_power [simp]:
   137   "0 < a \<Longrightarrow> 0 < a ^ n"
   138   by (induct n) (simp_all add: mult_pos_pos)
   139 
   140 lemma zero_le_power [simp]:
   141   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   142   by (induct n) (simp_all add: mult_nonneg_nonneg)
   143 
   144 lemma one_le_power[simp]:
   145   "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   146   apply (induct n)
   147   apply simp_all
   148   apply (rule order_trans [OF _ mult_mono [of 1 _ 1]])
   149   apply (simp_all add: order_trans [OF zero_le_one])
   150   done
   151 
   152 lemma power_gt1_lemma:
   153   assumes gt1: "1 < a"
   154   shows "1 < a * a ^ n"
   155 proof -
   156   from gt1 have "0 \<le> a"
   157     by (fact order_trans [OF zero_le_one less_imp_le])
   158   have "1 * 1 < a * 1" using gt1 by simp
   159   also have "\<dots> \<le> a * a ^ n" using gt1
   160     by (simp only: mult_mono `0 \<le> a` one_le_power order_less_imp_le
   161         zero_le_one order_refl)
   162   finally show ?thesis by simp
   163 qed
   164 
   165 lemma power_gt1:
   166   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   167   by (simp add: power_gt1_lemma)
   168 
   169 lemma one_less_power [simp]:
   170   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   171   by (cases n) (simp_all add: power_gt1_lemma)
   172 
   173 lemma power_le_imp_le_exp:
   174   assumes gt1: "1 < a"
   175   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   176 proof (induct m arbitrary: n)
   177   case 0
   178   show ?case by simp
   179 next
   180   case (Suc m)
   181   show ?case
   182   proof (cases n)
   183     case 0
   184     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   185     with gt1 show ?thesis
   186       by (force simp only: power_gt1_lemma
   187           not_less [symmetric])
   188   next
   189     case (Suc n)
   190     with Suc.prems Suc.hyps show ?thesis
   191       by (force dest: mult_left_le_imp_le
   192           simp add: less_trans [OF zero_less_one gt1])
   193   qed
   194 qed
   195 
   196 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   197 lemma power_inject_exp [simp]:
   198   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   199   by (force simp add: order_antisym power_le_imp_le_exp)
   200 
   201 text{*Can relax the first premise to @{term "0<a"} in the case of the
   202 natural numbers.*}
   203 lemma power_less_imp_less_exp:
   204   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   205   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   206     power_le_imp_le_exp)
   207 
   208 lemma power_mono:
   209   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   210   by (induct n)
   211     (auto intro: mult_mono order_trans [of 0 a b])
   212 
   213 lemma power_strict_mono [rule_format]:
   214   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   215   by (induct n)
   216    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   217 
   218 text{*Lemma for @{text power_strict_decreasing}*}
   219 lemma power_Suc_less:
   220   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   221   by (induct n)
   222     (auto simp add: mult_strict_left_mono)
   223 
   224 lemma power_strict_decreasing [rule_format]:
   225   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   226 proof (induct N)
   227   case 0 then show ?case by simp
   228 next
   229   case (Suc N) then show ?case 
   230   apply (auto simp add: power_Suc_less less_Suc_eq)
   231   apply (subgoal_tac "a * a^N < 1 * a^n")
   232   apply simp
   233   apply (rule mult_strict_mono) apply auto
   234   done
   235 qed
   236 
   237 text{*Proof resembles that of @{text power_strict_decreasing}*}
   238 lemma power_decreasing [rule_format]:
   239   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   240 proof (induct N)
   241   case 0 then show ?case by simp
   242 next
   243   case (Suc N) then show ?case 
   244   apply (auto simp add: le_Suc_eq)
   245   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   246   apply (rule mult_mono) apply auto
   247   done
   248 qed
   249 
   250 lemma power_Suc_less_one:
   251   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   252   using power_strict_decreasing [of 0 "Suc n" a] by simp
   253 
   254 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   255 lemma power_increasing [rule_format]:
   256   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   257 proof (induct N)
   258   case 0 then show ?case by simp
   259 next
   260   case (Suc N) then show ?case 
   261   apply (auto simp add: le_Suc_eq)
   262   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   263   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   264   done
   265 qed
   266 
   267 text{*Lemma for @{text power_strict_increasing}*}
   268 lemma power_less_power_Suc:
   269   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   270   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   271 
   272 lemma power_strict_increasing [rule_format]:
   273   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   274 proof (induct N)
   275   case 0 then show ?case by simp
   276 next
   277   case (Suc N) then show ?case 
   278   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   279   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   280   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   281   done
   282 qed
   283 
   284 lemma power_increasing_iff [simp]:
   285   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   286   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   287 
   288 lemma power_strict_increasing_iff [simp]:
   289   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   290 by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   291 
   292 lemma power_le_imp_le_base:
   293   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   294     and ynonneg: "0 \<le> b"
   295   shows "a \<le> b"
   296 proof (rule ccontr)
   297   assume "~ a \<le> b"
   298   then have "b < a" by (simp only: linorder_not_le)
   299   then have "b ^ Suc n < a ^ Suc n"
   300     by (simp only: prems power_strict_mono)
   301   from le and this show False
   302     by (simp add: linorder_not_less [symmetric])
   303 qed
   304 
   305 lemma power_less_imp_less_base:
   306   assumes less: "a ^ n < b ^ n"
   307   assumes nonneg: "0 \<le> b"
   308   shows "a < b"
   309 proof (rule contrapos_pp [OF less])
   310   assume "~ a < b"
   311   hence "b \<le> a" by (simp only: linorder_not_less)
   312   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   313   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   314 qed
   315 
   316 lemma power_inject_base:
   317   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   318 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   319 
   320 lemma power_eq_imp_eq_base:
   321   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   322   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   323 
   324 end
   325 
   326 context linordered_idom
   327 begin
   328 
   329 lemma power_abs:
   330   "abs (a ^ n) = abs a ^ n"
   331   by (induct n) (auto simp add: abs_mult)
   332 
   333 lemma abs_power_minus [simp]:
   334   "abs ((-a) ^ n) = abs (a ^ n)"
   335   by (simp add: power_abs)
   336 
   337 lemma zero_less_power_abs_iff [simp, noatp]:
   338   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   339 proof (induct n)
   340   case 0 show ?case by simp
   341 next
   342   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   343 qed
   344 
   345 lemma zero_le_power_abs [simp]:
   346   "0 \<le> abs a ^ n"
   347   by (rule zero_le_power [OF abs_ge_zero])
   348 
   349 end
   350 
   351 context ring_1_no_zero_divisors
   352 begin
   353 
   354 lemma field_power_not_zero:
   355   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   356   by (induct n) auto
   357 
   358 end
   359 
   360 context division_ring
   361 begin
   362 
   363 text {* FIXME reorient or rename to @{text nonzero_inverse_power} *}
   364 lemma nonzero_power_inverse:
   365   "a \<noteq> 0 \<Longrightarrow> inverse (a ^ n) = (inverse a) ^ n"
   366   by (induct n)
   367     (simp_all add: nonzero_inverse_mult_distrib power_commutes field_power_not_zero)
   368 
   369 end
   370 
   371 context field
   372 begin
   373 
   374 lemma nonzero_power_divide:
   375   "b \<noteq> 0 \<Longrightarrow> (a / b) ^ n = a ^ n / b ^ n"
   376   by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   377 
   378 end
   379 
   380 lemma power_0_Suc [simp]:
   381   "(0::'a::{power, semiring_0}) ^ Suc n = 0"
   382   by simp
   383 
   384 text{*It looks plausible as a simprule, but its effect can be strange.*}
   385 lemma power_0_left:
   386   "0 ^ n = (if n = 0 then 1 else (0::'a::{power, semiring_0}))"
   387   by (induct n) simp_all
   388 
   389 lemma power_eq_0_iff [simp]:
   390   "a ^ n = 0 \<longleftrightarrow>
   391      a = (0::'a::{mult_zero,zero_neq_one,no_zero_divisors,power}) \<and> n \<noteq> 0"
   392   by (induct n)
   393     (auto simp add: no_zero_divisors elim: contrapos_pp)
   394 
   395 lemma power_diff:
   396   fixes a :: "'a::field"
   397   assumes nz: "a \<noteq> 0"
   398   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   399   by (induct m n rule: diff_induct) (simp_all add: nz)
   400 
   401 text{*Perhaps these should be simprules.*}
   402 lemma power_inverse:
   403   fixes a :: "'a::{division_ring,division_by_zero,power}"
   404   shows "inverse (a ^ n) = (inverse a) ^ n"
   405 apply (cases "a = 0")
   406 apply (simp add: power_0_left)
   407 apply (simp add: nonzero_power_inverse)
   408 done (* TODO: reorient or rename to inverse_power *)
   409 
   410 lemma power_one_over:
   411   "1 / (a::'a::{field,division_by_zero, power}) ^ n =  (1 / a) ^ n"
   412   by (simp add: divide_inverse) (rule power_inverse)
   413 
   414 lemma power_divide:
   415   "(a / b) ^ n = (a::'a::{field,division_by_zero}) ^ n / b ^ n"
   416 apply (cases "b = 0")
   417 apply (simp add: power_0_left)
   418 apply (rule nonzero_power_divide)
   419 apply assumption
   420 done
   421 
   422 
   423 subsection {* Exponentiation for the Natural Numbers *}
   424 
   425 lemma nat_one_le_power [simp]:
   426   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   427   by (rule one_le_power [of i n, unfolded One_nat_def])
   428 
   429 lemma nat_zero_less_power_iff [simp]:
   430   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   431   by (induct n) auto
   432 
   433 lemma nat_power_eq_Suc_0_iff [simp]: 
   434   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   435   by (induct m) auto
   436 
   437 lemma power_Suc_0 [simp]:
   438   "Suc 0 ^ n = Suc 0"
   439   by simp
   440 
   441 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   442 Premises cannot be weakened: consider the case where @{term "i=0"},
   443 @{term "m=1"} and @{term "n=0"}.*}
   444 lemma nat_power_less_imp_less:
   445   assumes nonneg: "0 < (i\<Colon>nat)"
   446   assumes less: "i ^ m < i ^ n"
   447   shows "m < n"
   448 proof (cases "i = 1")
   449   case True with less power_one [where 'a = nat] show ?thesis by simp
   450 next
   451   case False with nonneg have "1 < i" by auto
   452   from power_strict_increasing_iff [OF this] less show ?thesis ..
   453 qed
   454 
   455 lemma power_dvd_imp_le:
   456   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   457   apply (rule power_le_imp_le_exp, assumption)
   458   apply (erule dvd_imp_le, simp)
   459   done
   460 
   461 
   462 subsection {* Code generator tweak *}
   463 
   464 lemma power_power_power [code, code_unfold, code_inline del]:
   465   "power = power.power (1::'a::{power}) (op *)"
   466   unfolding power_def power.power_def ..
   467 
   468 declare power.power.simps [code]
   469 
   470 code_modulename SML
   471   Power Arith
   472 
   473 code_modulename OCaml
   474   Power Arith
   475 
   476 code_modulename Haskell
   477   Power Arith
   478 
   479 end