src/HOL/Number_Theory/Gauss.thy
author haftmann
Thu Oct 30 21:02:01 2014 +0100 (2014-10-30)
changeset 58834 773b378d9313
parent 58645 94bef115c08f
child 58889 5b7a9633cfa8
permissions -rw-r--r--
more simp rules concerning dvd and even/odd
     1 (*  Authors:    Jeremy Avigad, David Gray, and Adam Kramer
     2 
     3 Ported by lcp but unfinished
     4 *)
     5 
     6 header {* Gauss' Lemma *}
     7 
     8 theory Gauss
     9 imports Residues
    10 begin
    11 
    12 lemma cong_prime_prod_zero_nat: 
    13   fixes a::nat
    14   shows "\<lbrakk>[a * b = 0] (mod p); prime p\<rbrakk> \<Longrightarrow> [a = 0] (mod p) | [b = 0] (mod p)"
    15   by (auto simp add: cong_altdef_nat)
    16 
    17 lemma cong_prime_prod_zero_int: 
    18   fixes a::int
    19   shows "\<lbrakk>[a * b = 0] (mod p); prime p\<rbrakk> \<Longrightarrow> [a = 0] (mod p) | [b = 0] (mod p)"
    20   by (auto simp add: cong_altdef_int)
    21 
    22 
    23 locale GAUSS =
    24   fixes p :: "nat"
    25   fixes a :: "int"
    26 
    27   assumes p_prime: "prime p"
    28   assumes p_ge_2: "2 < p"
    29   assumes p_a_relprime: "[a \<noteq> 0](mod p)"
    30   assumes a_nonzero:    "0 < a"
    31 begin
    32 
    33 definition "A = {0::int <.. ((int p - 1) div 2)}"
    34 definition "B = (\<lambda>x. x * a) ` A"
    35 definition "C = (\<lambda>x. x mod p) ` B"
    36 definition "D = C \<inter> {.. (int p - 1) div 2}"
    37 definition "E = C \<inter> {(int p - 1) div 2 <..}"
    38 definition "F = (\<lambda>x. (int p - x)) ` E"
    39 
    40 
    41 subsection {* Basic properties of p *}
    42 
    43 lemma odd_p: "odd p"
    44 by (metis p_prime p_ge_2 prime_odd_nat)
    45 
    46 lemma p_minus_one_l: "(int p - 1) div 2 < p"
    47 proof -
    48   have "(p - 1) div 2 \<le> (p - 1) div 1"
    49     by (metis div_by_1 div_le_dividend)
    50   also have "\<dots> = p - 1" by simp
    51   finally show ?thesis using p_ge_2 by arith
    52 qed
    53 
    54 lemma p_eq2: "int p = (2 * ((int p - 1) div 2)) + 1"
    55   using odd_p p_ge_2 div_mult_self1_is_id [of 2 "p - 1"]   
    56   by simp
    57 
    58 lemma p_odd_int: obtains z::int where "int p = 2*z+1" "0<z"
    59   using odd_p p_ge_2
    60   by (auto simp add: even_iff_mod_2_eq_zero) (metis p_eq2)
    61 
    62 
    63 subsection {* Basic Properties of the Gauss Sets *}
    64 
    65 lemma finite_A: "finite (A)"
    66 by (auto simp add: A_def)
    67 
    68 lemma finite_B: "finite (B)"
    69 by (auto simp add: B_def finite_A)
    70 
    71 lemma finite_C: "finite (C)"
    72 by (auto simp add: C_def finite_B)
    73 
    74 lemma finite_D: "finite (D)"
    75 by (auto simp add: D_def finite_C)
    76 
    77 lemma finite_E: "finite (E)"
    78 by (auto simp add: E_def finite_C)
    79 
    80 lemma finite_F: "finite (F)"
    81 by (auto simp add: F_def finite_E)
    82 
    83 lemma C_eq: "C = D \<union> E"
    84 by (auto simp add: C_def D_def E_def)
    85 
    86 lemma A_card_eq: "card A = nat ((int p - 1) div 2)"
    87   by (auto simp add: A_def)
    88 
    89 lemma inj_on_xa_A: "inj_on (\<lambda>x. x * a) A"
    90   using a_nonzero by (simp add: A_def inj_on_def)
    91 
    92 definition ResSet :: "int => int set => bool"
    93   where "ResSet m X = (\<forall>y1 y2. (y1 \<in> X & y2 \<in> X & [y1 = y2] (mod m) --> y1 = y2))"
    94 
    95 lemma ResSet_image:
    96   "\<lbrakk> 0 < m; ResSet m A; \<forall>x \<in> A. \<forall>y \<in> A. ([f x = f y](mod m) --> x = y) \<rbrakk> \<Longrightarrow>
    97     ResSet m (f ` A)"
    98   by (auto simp add: ResSet_def)
    99 
   100 lemma A_res: "ResSet p A"
   101   using p_ge_2
   102   by (auto simp add: A_def ResSet_def intro!: cong_less_imp_eq_int)
   103 
   104 lemma B_res: "ResSet p B"
   105 proof -
   106   {fix x fix y
   107     assume a: "[x * a = y * a] (mod p)"
   108     assume b: "0 < x"
   109     assume c: "x \<le> (int p - 1) div 2"
   110     assume d: "0 < y"
   111     assume e: "y \<le> (int p - 1) div 2"
   112     from a p_a_relprime p_prime a_nonzero cong_mult_rcancel_int [of _ a x y]
   113     have "[x = y](mod p)"
   114       by (metis comm_monoid_mult_class.mult.left_neutral cong_dvd_modulus_int cong_mult_rcancel_int 
   115                 cong_mult_self_int gcd_int.commute prime_imp_coprime_int)
   116     with cong_less_imp_eq_int [of x y p] p_minus_one_l
   117         order_le_less_trans [of x "(int p - 1) div 2" p]
   118         order_le_less_trans [of y "(int p - 1) div 2" p] 
   119     have "x = y"
   120       by (metis b c cong_less_imp_eq_int d e zero_less_imp_eq_int zero_zle_int)
   121     } note xy = this
   122   show ?thesis
   123     apply (insert p_ge_2 p_a_relprime p_minus_one_l)
   124     apply (auto simp add: B_def)
   125     apply (rule ResSet_image)
   126     apply (auto simp add: A_res)
   127     apply (auto simp add: A_def xy)
   128     done
   129   qed
   130 
   131 lemma SR_B_inj: "inj_on (\<lambda>x. x mod p) B"
   132 proof -
   133 { fix x fix y
   134   assume a: "x * a mod p = y * a mod p"
   135   assume b: "0 < x"
   136   assume c: "x \<le> (int p - 1) div 2"
   137   assume d: "0 < y"
   138   assume e: "y \<le> (int p - 1) div 2"
   139   assume f: "x \<noteq> y"
   140   from a have "[x * a = y * a](mod p)" 
   141     by (metis cong_int_def)
   142   with p_a_relprime p_prime cong_mult_rcancel_int [of a p x y]
   143   have "[x = y](mod p)" 
   144     by (metis cong_mult_self_int dvd_div_mult_self gcd_commute_int prime_imp_coprime_int)
   145   with cong_less_imp_eq_int [of x y p] p_minus_one_l
   146     order_le_less_trans [of x "(int p - 1) div 2" p]
   147     order_le_less_trans [of y "(int p - 1) div 2" p] 
   148   have "x = y"
   149     by (metis b c cong_less_imp_eq_int d e zero_less_imp_eq_int zero_zle_int)
   150   then have False
   151     by (simp add: f)}
   152   then show ?thesis
   153     by (auto simp add: B_def inj_on_def A_def) metis
   154 qed
   155 
   156 lemma inj_on_pminusx_E: "inj_on (\<lambda>x. p - x) E"
   157   apply (auto simp add: E_def C_def B_def A_def)
   158   apply (rule_tac g = "(op - (int p))" in inj_on_inverseI)
   159   apply auto
   160   done
   161 
   162 lemma nonzero_mod_p:
   163   fixes x::int shows "\<lbrakk>0 < x; x < int p\<rbrakk> \<Longrightarrow> [x \<noteq> 0](mod p)"
   164 by (metis Nat_Transfer.transfer_nat_int_function_closures(9) cong_less_imp_eq_int 
   165      inf.semilattice_strict_iff_order int_less_0_conv le_numeral_extra(3) zero_less_imp_eq_int)
   166 
   167 lemma A_ncong_p: "x \<in> A \<Longrightarrow> [x \<noteq> 0](mod p)"
   168   by (rule nonzero_mod_p) (auto simp add: A_def)
   169 
   170 lemma A_greater_zero: "x \<in> A \<Longrightarrow> 0 < x"
   171   by (auto simp add: A_def)
   172 
   173 lemma B_ncong_p: "x \<in> B \<Longrightarrow> [x \<noteq> 0](mod p)"
   174   by (auto simp add: B_def) (metis cong_prime_prod_zero_int A_ncong_p p_a_relprime p_prime)
   175 
   176 lemma B_greater_zero: "x \<in> B \<Longrightarrow> 0 < x"
   177   using a_nonzero by (auto simp add: B_def A_greater_zero)
   178 
   179 lemma C_greater_zero: "y \<in> C \<Longrightarrow> 0 < y"
   180 proof (auto simp add: C_def)
   181   fix x :: int
   182   assume a1: "x \<in> B"
   183   have f2: "\<And>x\<^sub>1. int x\<^sub>1 = 0 \<or> 0 < int x\<^sub>1" by linarith
   184   have "x mod int p \<noteq> 0" using a1 B_ncong_p cong_int_def by simp
   185   thus "0 < x mod int p" using a1 f2 
   186     by (metis (no_types) B_greater_zero Divides.transfer_int_nat_functions(2) zero_less_imp_eq_int)
   187 qed
   188 
   189 lemma F_subset: "F \<subseteq> {x. 0 < x & x \<le> ((int p - 1) div 2)}"
   190   apply (auto simp add: F_def E_def C_def)
   191   apply (metis p_ge_2 Divides.pos_mod_bound less_diff_eq nat_int plus_int_code(2) zless_nat_conj)
   192   apply (auto intro: p_odd_int)
   193   done
   194 
   195 lemma D_subset: "D \<subseteq> {x. 0 < x & x \<le> ((p - 1) div 2)}"
   196   by (auto simp add: D_def C_greater_zero)
   197 
   198 lemma F_eq: "F = {x. \<exists>y \<in> A. ( x = p - ((y*a) mod p) & (int p - 1) div 2 < (y*a) mod p)}"
   199   by (auto simp add: F_def E_def D_def C_def B_def A_def)
   200 
   201 lemma D_eq: "D = {x. \<exists>y \<in> A. ( x = (y*a) mod p & (y*a) mod p \<le> (int p - 1) div 2)}"
   202   by (auto simp add: D_def C_def B_def A_def)
   203 
   204 lemma all_A_relprime: assumes "x \<in> A" shows "gcd x p = 1"
   205   using p_prime A_ncong_p [OF assms]
   206   by (simp add: cong_altdef_int) (metis gcd_int.commute prime_imp_coprime_int)
   207 
   208 lemma A_prod_relprime: "gcd (setprod id A) p = 1"
   209   by (metis id_def all_A_relprime setprod_coprime_int)
   210 
   211 
   212 subsection {* Relationships Between Gauss Sets *}
   213 
   214 lemma StandardRes_inj_on_ResSet: "ResSet m X \<Longrightarrow> (inj_on (\<lambda>b. b mod m) X)"
   215   by (auto simp add: ResSet_def inj_on_def cong_int_def)
   216 
   217 lemma B_card_eq_A: "card B = card A"
   218   using finite_A by (simp add: finite_A B_def inj_on_xa_A card_image)
   219 
   220 lemma B_card_eq: "card B = nat ((int p - 1) div 2)"
   221   by (simp add: B_card_eq_A A_card_eq)
   222 
   223 lemma F_card_eq_E: "card F = card E"
   224   using finite_E 
   225   by (simp add: F_def inj_on_pminusx_E card_image)
   226 
   227 lemma C_card_eq_B: "card C = card B"
   228 proof -
   229   have "inj_on (\<lambda>x. x mod p) B"
   230     by (metis SR_B_inj) 
   231   then show ?thesis
   232     by (metis C_def card_image)
   233 qed
   234 
   235 lemma D_E_disj: "D \<inter> E = {}"
   236   by (auto simp add: D_def E_def)
   237 
   238 lemma C_card_eq_D_plus_E: "card C = card D + card E"
   239   by (auto simp add: C_eq card_Un_disjoint D_E_disj finite_D finite_E)
   240 
   241 lemma C_prod_eq_D_times_E: "setprod id E * setprod id D = setprod id C"
   242   by (metis C_eq D_E_disj finite_D finite_E inf_commute setprod.union_disjoint sup_commute)
   243 
   244 lemma C_B_zcong_prod: "[setprod id C = setprod id B] (mod p)"
   245   apply (auto simp add: C_def)
   246   apply (insert finite_B SR_B_inj)
   247   apply (drule setprod.reindex [of "\<lambda>x. x mod int p" B id])
   248   apply auto
   249   apply (rule cong_setprod_int)
   250   apply (auto simp add: cong_int_def)
   251   done
   252 
   253 lemma F_Un_D_subset: "(F \<union> D) \<subseteq> A"
   254   apply (intro Un_least subset_trans [OF F_subset] subset_trans [OF D_subset])
   255   apply (auto simp add: A_def)
   256   done
   257 
   258 lemma F_D_disj: "(F \<inter> D) = {}"
   259 proof (auto simp add: F_eq D_eq)
   260   fix y::int and z::int
   261   assume "p - (y*a) mod p = (z*a) mod p"
   262   then have "[(y*a) mod p + (z*a) mod p = 0] (mod p)"
   263     by (metis add.commute diff_eq_eq dvd_refl cong_int_def dvd_eq_mod_eq_0 mod_0)
   264   moreover have "[y * a = (y*a) mod p] (mod p)"
   265     by (metis cong_int_def mod_mod_trivial)
   266   ultimately have "[a * (y + z) = 0] (mod p)"
   267     by (metis cong_int_def mod_add_left_eq mod_add_right_eq mult.commute ring_class.ring_distribs(1))
   268   with p_prime a_nonzero p_a_relprime
   269   have a: "[y + z = 0] (mod p)"
   270     by (metis cong_prime_prod_zero_int)
   271   assume b: "y \<in> A" and c: "z \<in> A"
   272   with A_def have "0 < y + z"
   273     by auto
   274   moreover from b c p_eq2 A_def have "y + z < p"
   275     by auto
   276   ultimately show False
   277     by (metis a nonzero_mod_p)
   278 qed
   279 
   280 lemma F_Un_D_card: "card (F \<union> D) = nat ((p - 1) div 2)"
   281 proof -
   282   have "card (F \<union> D) = card E + card D"
   283     by (auto simp add: finite_F finite_D F_D_disj card_Un_disjoint F_card_eq_E)
   284   then have "card (F \<union> D) = card C"
   285     by (simp add: C_card_eq_D_plus_E)
   286   then show "card (F \<union> D) = nat ((p - 1) div 2)"
   287     by (simp add: C_card_eq_B B_card_eq)
   288 qed
   289 
   290 lemma F_Un_D_eq_A: "F \<union> D = A"
   291   using finite_A F_Un_D_subset A_card_eq F_Un_D_card 
   292   by (auto simp add: card_seteq)
   293 
   294 lemma prod_D_F_eq_prod_A: "(setprod id D) * (setprod id F) = setprod id A"
   295   by (metis F_D_disj F_Un_D_eq_A Int_commute Un_commute finite_D finite_F setprod.union_disjoint)
   296 
   297 lemma prod_F_zcong: "[setprod id F = ((-1) ^ (card E)) * (setprod id E)] (mod p)"
   298 proof -
   299   have FE: "setprod id F = setprod (op - p) E"
   300     apply (auto simp add: F_def)
   301     apply (insert finite_E inj_on_pminusx_E)
   302     apply (drule setprod.reindex, auto)
   303     done
   304   then have "\<forall>x \<in> E. [(p-x) mod p = - x](mod p)"
   305     by (metis cong_int_def minus_mod_self1 mod_mod_trivial)
   306   then have "[setprod ((\<lambda>x. x mod p) o (op - p)) E = setprod (uminus) E](mod p)"
   307     using finite_E p_ge_2
   308           cong_setprod_int [of E "(\<lambda>x. x mod p) o (op - p)" uminus p]
   309     by auto
   310   then have two: "[setprod id F = setprod (uminus) E](mod p)"
   311     by (metis FE cong_cong_mod_int cong_refl_int cong_setprod_int minus_mod_self1)
   312   have "setprod uminus E = (-1) ^ (card E) * (setprod id E)"
   313     using finite_E by (induct set: finite) auto
   314   with two show ?thesis
   315     by simp
   316 qed
   317 
   318 
   319 subsection {* Gauss' Lemma *}
   320 
   321 lemma aux: "setprod id A * (- 1) ^ card E * a ^ card A * (- 1) ^ card E = setprod id A * a ^ card A"
   322 by (metis (no_types) minus_minus mult.commute mult.left_commute power_minus power_one)
   323 
   324 theorem pre_gauss_lemma:
   325   "[a ^ nat((int p - 1) div 2) = (-1) ^ (card E)] (mod p)"
   326 proof -
   327   have "[setprod id A = setprod id F * setprod id D](mod p)"
   328     by (auto simp add: prod_D_F_eq_prod_A mult.commute cong del:setprod.cong)
   329   then have "[setprod id A = ((-1)^(card E) * setprod id E) * setprod id D] (mod p)"
   330     apply (rule cong_trans_int)
   331     apply (metis cong_scalar_int prod_F_zcong)
   332     done
   333   then have "[setprod id A = ((-1)^(card E) * setprod id C)] (mod p)"
   334     by (metis C_prod_eq_D_times_E mult.commute mult.left_commute)
   335   then have "[setprod id A = ((-1)^(card E) * setprod id B)] (mod p)"
   336     by (rule cong_trans_int) (metis C_B_zcong_prod cong_scalar2_int)
   337   then have "[setprod id A = ((-1)^(card E) *
   338     (setprod id ((\<lambda>x. x * a) ` A)))] (mod p)"
   339     by (simp add: B_def)
   340   then have "[setprod id A = ((-1)^(card E) * (setprod (\<lambda>x. x * a) A))]
   341     (mod p)"
   342     by (simp add: inj_on_xa_A setprod.reindex)
   343   moreover have "setprod (\<lambda>x. x * a) A =
   344     setprod (\<lambda>x. a) A * setprod id A"
   345     using finite_A by (induct set: finite) auto
   346   ultimately have "[setprod id A = ((-1)^(card E) * (setprod (\<lambda>x. a) A *
   347     setprod id A))] (mod p)"
   348     by simp
   349   then have "[setprod id A = ((-1)^(card E) * a^(card A) *
   350       setprod id A)](mod p)"
   351     apply (rule cong_trans_int)
   352     apply (simp add: cong_scalar2_int cong_scalar_int finite_A setprod_constant mult.assoc)
   353     done
   354   then have a: "[setprod id A * (-1)^(card E) =
   355       ((-1)^(card E) * a^(card A) * setprod id A * (-1)^(card E))](mod p)"
   356     by (rule cong_scalar_int)
   357   then have "[setprod id A * (-1)^(card E) = setprod id A *
   358       (-1)^(card E) * a^(card A) * (-1)^(card E)](mod p)"
   359     apply (rule cong_trans_int)
   360     apply (simp add: a mult.commute mult.left_commute)
   361     done
   362   then have "[setprod id A * (-1)^(card E) = setprod id A * a^(card A)](mod p)"
   363     apply (rule cong_trans_int)
   364     apply (simp add: aux cong del:setprod.cong)
   365     done
   366   with A_prod_relprime have "[(- 1) ^ card E = a ^ card A](mod p)"
   367     by (metis cong_mult_lcancel_int)
   368   then show ?thesis
   369     by (simp add: A_card_eq cong_sym_int)
   370 qed
   371 
   372 (*NOT WORKING. Old_Number_Theory/Euler.thy needs to be translated, but it's
   373 quite a mess and should better be completely redone.
   374 
   375 theorem gauss_lemma: "(Legendre a p) = (-1) ^ (card E)"
   376 proof -
   377   from Euler_Criterion p_prime p_ge_2 have
   378       "[(Legendre a p) = a^(nat (((p) - 1) div 2))] (mod p)"
   379     by auto
   380   moreover note pre_gauss_lemma
   381   ultimately have "[(Legendre a p) = (-1) ^ (card E)] (mod p)"
   382     by (rule cong_trans_int)
   383   moreover from p_a_relprime have "(Legendre a p) = 1 | (Legendre a p) = (-1)"
   384     by (auto simp add: Legendre_def)
   385   moreover have "(-1::int) ^ (card E) = 1 | (-1::int) ^ (card E) = -1"
   386     by (rule neg_one_power)
   387   ultimately show ?thesis
   388     by (auto simp add: p_ge_2 one_not_neg_one_mod_m zcong_sym)
   389 qed
   390 *)
   391 
   392 end
   393 
   394 end