src/HOL/Number_Theory/Euclidean_Algorithm.thy
author haftmann
Sat Dec 17 15:22:14 2016 +0100 (2016-12-17)
changeset 64592 7759f1766189
parent 64243 aee949f6642d
child 64784 5cb5e7ecb284
permissions -rw-r--r--
more fine-grained type class hierarchy for div and mod
     1 (* Author: Manuel Eberl *)
     2 
     3 section \<open>Abstract euclidean algorithm\<close>
     4 
     5 theory Euclidean_Algorithm
     6 imports "~~/src/HOL/GCD" Factorial_Ring
     7 begin
     8 
     9 text \<open>
    10   A Euclidean semiring is a semiring upon which the Euclidean algorithm can be
    11   implemented. It must provide:
    12   \begin{itemize}
    13   \item division with remainder
    14   \item a size function such that @{term "size (a mod b) < size b"} 
    15         for any @{term "b \<noteq> 0"}
    16   \end{itemize}
    17   The existence of these functions makes it possible to derive gcd and lcm functions 
    18   for any Euclidean semiring.
    19 \<close> 
    20 class euclidean_semiring = semidom_modulo + normalization_semidom + 
    21   fixes euclidean_size :: "'a \<Rightarrow> nat"
    22   assumes size_0 [simp]: "euclidean_size 0 = 0"
    23   assumes mod_size_less: 
    24     "b \<noteq> 0 \<Longrightarrow> euclidean_size (a mod b) < euclidean_size b"
    25   assumes size_mult_mono:
    26     "b \<noteq> 0 \<Longrightarrow> euclidean_size a \<le> euclidean_size (a * b)"
    27 begin
    28 
    29 lemma euclidean_size_normalize [simp]:
    30   "euclidean_size (normalize a) = euclidean_size a"
    31 proof (cases "a = 0")
    32   case True
    33   then show ?thesis
    34     by simp
    35 next
    36   case [simp]: False
    37   have "euclidean_size (normalize a) \<le> euclidean_size (normalize a * unit_factor a)"
    38     by (rule size_mult_mono) simp
    39   moreover have "euclidean_size a \<le> euclidean_size (a * (1 div unit_factor a))"
    40     by (rule size_mult_mono) simp
    41   ultimately show ?thesis
    42     by simp
    43 qed
    44 
    45 lemma euclidean_division:
    46   fixes a :: 'a and b :: 'a
    47   assumes "b \<noteq> 0"
    48   obtains s and t where "a = s * b + t" 
    49     and "euclidean_size t < euclidean_size b"
    50 proof -
    51   from div_mult_mod_eq [of a b] 
    52      have "a = a div b * b + a mod b" by simp
    53   with that and assms show ?thesis by (auto simp add: mod_size_less)
    54 qed
    55 
    56 lemma dvd_euclidean_size_eq_imp_dvd:
    57   assumes "a \<noteq> 0" and b_dvd_a: "b dvd a" and size_eq: "euclidean_size a = euclidean_size b"
    58   shows "a dvd b"
    59 proof (rule ccontr)
    60   assume "\<not> a dvd b"
    61   hence "b mod a \<noteq> 0" using mod_0_imp_dvd[of b a] by blast
    62   then have "b mod a \<noteq> 0" by (simp add: mod_eq_0_iff_dvd)
    63   from b_dvd_a have b_dvd_mod: "b dvd b mod a" by (simp add: dvd_mod_iff)
    64   from b_dvd_mod obtain c where "b mod a = b * c" unfolding dvd_def by blast
    65     with \<open>b mod a \<noteq> 0\<close> have "c \<noteq> 0" by auto
    66   with \<open>b mod a = b * c\<close> have "euclidean_size (b mod a) \<ge> euclidean_size b"
    67       using size_mult_mono by force
    68   moreover from \<open>\<not> a dvd b\<close> and \<open>a \<noteq> 0\<close>
    69   have "euclidean_size (b mod a) < euclidean_size a"
    70       using mod_size_less by blast
    71   ultimately show False using size_eq by simp
    72 qed
    73 
    74 lemma size_mult_mono': "b \<noteq> 0 \<Longrightarrow> euclidean_size a \<le> euclidean_size (b * a)"
    75   by (subst mult.commute) (rule size_mult_mono)
    76 
    77 lemma euclidean_size_times_unit:
    78   assumes "is_unit a"
    79   shows   "euclidean_size (a * b) = euclidean_size b"
    80 proof (rule antisym)
    81   from assms have [simp]: "a \<noteq> 0" by auto
    82   thus "euclidean_size (a * b) \<ge> euclidean_size b" by (rule size_mult_mono')
    83   from assms have "is_unit (1 div a)" by simp
    84   hence "1 div a \<noteq> 0" by (intro notI) simp_all
    85   hence "euclidean_size (a * b) \<le> euclidean_size ((1 div a) * (a * b))"
    86     by (rule size_mult_mono')
    87   also from assms have "(1 div a) * (a * b) = b"
    88     by (simp add: algebra_simps unit_div_mult_swap)
    89   finally show "euclidean_size (a * b) \<le> euclidean_size b" .
    90 qed
    91 
    92 lemma euclidean_size_unit: "is_unit a \<Longrightarrow> euclidean_size a = euclidean_size 1"
    93   using euclidean_size_times_unit[of a 1] by simp
    94 
    95 lemma unit_iff_euclidean_size: 
    96   "is_unit a \<longleftrightarrow> euclidean_size a = euclidean_size 1 \<and> a \<noteq> 0"
    97 proof safe
    98   assume A: "a \<noteq> 0" and B: "euclidean_size a = euclidean_size 1"
    99   show "is_unit a" by (rule dvd_euclidean_size_eq_imp_dvd[OF A _ B]) simp_all
   100 qed (auto intro: euclidean_size_unit)
   101 
   102 lemma euclidean_size_times_nonunit:
   103   assumes "a \<noteq> 0" "b \<noteq> 0" "\<not>is_unit a"
   104   shows   "euclidean_size b < euclidean_size (a * b)"
   105 proof (rule ccontr)
   106   assume "\<not>euclidean_size b < euclidean_size (a * b)"
   107   with size_mult_mono'[OF assms(1), of b] 
   108     have eq: "euclidean_size (a * b) = euclidean_size b" by simp
   109   have "a * b dvd b"
   110     by (rule dvd_euclidean_size_eq_imp_dvd[OF _ _ eq]) (insert assms, simp_all)
   111   hence "a * b dvd 1 * b" by simp
   112   with \<open>b \<noteq> 0\<close> have "is_unit a" by (subst (asm) dvd_times_right_cancel_iff)
   113   with assms(3) show False by contradiction
   114 qed
   115 
   116 lemma dvd_imp_size_le:
   117   assumes "a dvd b" "b \<noteq> 0" 
   118   shows   "euclidean_size a \<le> euclidean_size b"
   119   using assms by (auto elim!: dvdE simp: size_mult_mono)
   120 
   121 lemma dvd_proper_imp_size_less:
   122   assumes "a dvd b" "\<not>b dvd a" "b \<noteq> 0" 
   123   shows   "euclidean_size a < euclidean_size b"
   124 proof -
   125   from assms(1) obtain c where "b = a * c" by (erule dvdE)
   126   hence z: "b = c * a" by (simp add: mult.commute)
   127   from z assms have "\<not>is_unit c" by (auto simp: mult.commute mult_unit_dvd_iff)
   128   with z assms show ?thesis
   129     by (auto intro!: euclidean_size_times_nonunit simp: )
   130 qed
   131 
   132 function gcd_eucl :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   133 where
   134   "gcd_eucl a b = (if b = 0 then normalize a else gcd_eucl b (a mod b))"
   135   by pat_completeness simp
   136 termination
   137   by (relation "measure (euclidean_size \<circ> snd)") (simp_all add: mod_size_less)
   138 
   139 declare gcd_eucl.simps [simp del]
   140 
   141 lemma gcd_eucl_induct [case_names zero mod]:
   142   assumes H1: "\<And>b. P b 0"
   143   and H2: "\<And>a b. b \<noteq> 0 \<Longrightarrow> P b (a mod b) \<Longrightarrow> P a b"
   144   shows "P a b"
   145 proof (induct a b rule: gcd_eucl.induct)
   146   case ("1" a b)
   147   show ?case
   148   proof (cases "b = 0")
   149     case True then show "P a b" by simp (rule H1)
   150   next
   151     case False
   152     then have "P b (a mod b)"
   153       by (rule "1.hyps")
   154     with \<open>b \<noteq> 0\<close> show "P a b"
   155       by (blast intro: H2)
   156   qed
   157 qed
   158 
   159 definition lcm_eucl :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   160 where
   161   "lcm_eucl a b = normalize (a * b) div gcd_eucl a b"
   162 
   163 definition Lcm_eucl :: "'a set \<Rightarrow> 'a" \<comment> \<open>
   164   Somewhat complicated definition of Lcm that has the advantage of working
   165   for infinite sets as well\<close>
   166 where
   167   "Lcm_eucl A = (if \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) then
   168      let l = SOME l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l =
   169        (LEAST n. \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n)
   170        in normalize l 
   171       else 0)"
   172 
   173 definition Gcd_eucl :: "'a set \<Rightarrow> 'a"
   174 where
   175   "Gcd_eucl A = Lcm_eucl {d. \<forall>a\<in>A. d dvd a}"
   176 
   177 declare Lcm_eucl_def Gcd_eucl_def [code del]
   178 
   179 lemma gcd_eucl_0:
   180   "gcd_eucl a 0 = normalize a"
   181   by (simp add: gcd_eucl.simps [of a 0])
   182 
   183 lemma gcd_eucl_0_left:
   184   "gcd_eucl 0 a = normalize a"
   185   by (simp_all add: gcd_eucl_0 gcd_eucl.simps [of 0 a])
   186 
   187 lemma gcd_eucl_non_0:
   188   "b \<noteq> 0 \<Longrightarrow> gcd_eucl a b = gcd_eucl b (a mod b)"
   189   by (simp add: gcd_eucl.simps [of a b] gcd_eucl.simps [of b 0])
   190 
   191 lemma gcd_eucl_dvd1 [iff]: "gcd_eucl a b dvd a"
   192   and gcd_eucl_dvd2 [iff]: "gcd_eucl a b dvd b"
   193   by (induct a b rule: gcd_eucl_induct)
   194      (simp_all add: gcd_eucl_0 gcd_eucl_non_0 dvd_mod_iff)
   195 
   196 lemma normalize_gcd_eucl [simp]:
   197   "normalize (gcd_eucl a b) = gcd_eucl a b"
   198   by (induct a b rule: gcd_eucl_induct) (simp_all add: gcd_eucl_0 gcd_eucl_non_0)
   199      
   200 lemma gcd_eucl_greatest:
   201   fixes k a b :: 'a
   202   shows "k dvd a \<Longrightarrow> k dvd b \<Longrightarrow> k dvd gcd_eucl a b"
   203 proof (induct a b rule: gcd_eucl_induct)
   204   case (zero a) from zero(1) show ?case by (rule dvd_trans) (simp add: gcd_eucl_0)
   205 next
   206   case (mod a b)
   207   then show ?case
   208     by (simp add: gcd_eucl_non_0 dvd_mod_iff)
   209 qed
   210 
   211 lemma gcd_euclI:
   212   fixes gcd :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   213   assumes "d dvd a" "d dvd b" "normalize d = d"
   214           "\<And>k. k dvd a \<Longrightarrow> k dvd b \<Longrightarrow> k dvd d"
   215   shows   "gcd_eucl a b = d"
   216   by (rule associated_eqI) (simp_all add: gcd_eucl_greatest assms)
   217 
   218 lemma eq_gcd_euclI:
   219   fixes gcd :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   220   assumes "\<And>a b. gcd a b dvd a" "\<And>a b. gcd a b dvd b" "\<And>a b. normalize (gcd a b) = gcd a b"
   221           "\<And>a b k. k dvd a \<Longrightarrow> k dvd b \<Longrightarrow> k dvd gcd a b"
   222   shows   "gcd = gcd_eucl"
   223   by (intro ext, rule associated_eqI) (simp_all add: gcd_eucl_greatest assms)
   224 
   225 lemma gcd_eucl_zero [simp]:
   226   "gcd_eucl a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
   227   by (metis dvd_0_left dvd_refl gcd_eucl_dvd1 gcd_eucl_dvd2 gcd_eucl_greatest)+
   228 
   229   
   230 lemma dvd_Lcm_eucl [simp]: "a \<in> A \<Longrightarrow> a dvd Lcm_eucl A"
   231   and Lcm_eucl_least: "(\<And>a. a \<in> A \<Longrightarrow> a dvd b) \<Longrightarrow> Lcm_eucl A dvd b"
   232   and unit_factor_Lcm_eucl [simp]: 
   233           "unit_factor (Lcm_eucl A) = (if Lcm_eucl A = 0 then 0 else 1)"
   234 proof -
   235   have "(\<forall>a\<in>A. a dvd Lcm_eucl A) \<and> (\<forall>l'. (\<forall>a\<in>A. a dvd l') \<longrightarrow> Lcm_eucl A dvd l') \<and>
   236     unit_factor (Lcm_eucl A) = (if Lcm_eucl A = 0 then 0 else 1)" (is ?thesis)
   237   proof (cases "\<exists>l. l \<noteq>  0 \<and> (\<forall>a\<in>A. a dvd l)")
   238     case False
   239     hence "Lcm_eucl A = 0" by (auto simp: Lcm_eucl_def)
   240     with False show ?thesis by auto
   241   next
   242     case True
   243     then obtain l\<^sub>0 where l\<^sub>0_props: "l\<^sub>0 \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l\<^sub>0)" by blast
   244     define n where "n = (LEAST n. \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n)"
   245     define l where "l = (SOME l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n)"
   246     have "\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
   247       apply (subst n_def)
   248       apply (rule LeastI[of _ "euclidean_size l\<^sub>0"])
   249       apply (rule exI[of _ l\<^sub>0])
   250       apply (simp add: l\<^sub>0_props)
   251       done
   252     from someI_ex[OF this] have "l \<noteq> 0" and "\<forall>a\<in>A. a dvd l" and "euclidean_size l = n" 
   253       unfolding l_def by simp_all
   254     {
   255       fix l' assume "\<forall>a\<in>A. a dvd l'"
   256       with \<open>\<forall>a\<in>A. a dvd l\<close> have "\<forall>a\<in>A. a dvd gcd_eucl l l'" by (auto intro: gcd_eucl_greatest)
   257       moreover from \<open>l \<noteq> 0\<close> have "gcd_eucl l l' \<noteq> 0" by simp
   258       ultimately have "\<exists>b. b \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd b) \<and> 
   259                           euclidean_size b = euclidean_size (gcd_eucl l l')"
   260         by (intro exI[of _ "gcd_eucl l l'"], auto)
   261       hence "euclidean_size (gcd_eucl l l') \<ge> n" by (subst n_def) (rule Least_le)
   262       moreover have "euclidean_size (gcd_eucl l l') \<le> n"
   263       proof -
   264         have "gcd_eucl l l' dvd l" by simp
   265         then obtain a where "l = gcd_eucl l l' * a" unfolding dvd_def by blast
   266         with \<open>l \<noteq> 0\<close> have "a \<noteq> 0" by auto
   267         hence "euclidean_size (gcd_eucl l l') \<le> euclidean_size (gcd_eucl l l' * a)"
   268           by (rule size_mult_mono)
   269         also have "gcd_eucl l l' * a = l" using \<open>l = gcd_eucl l l' * a\<close> ..
   270         also note \<open>euclidean_size l = n\<close>
   271         finally show "euclidean_size (gcd_eucl l l') \<le> n" .
   272       qed
   273       ultimately have *: "euclidean_size l = euclidean_size (gcd_eucl l l')" 
   274         by (intro le_antisym, simp_all add: \<open>euclidean_size l = n\<close>)
   275       from \<open>l \<noteq> 0\<close> have "l dvd gcd_eucl l l'"
   276         by (rule dvd_euclidean_size_eq_imp_dvd) (auto simp add: *)
   277       hence "l dvd l'" by (rule dvd_trans[OF _ gcd_eucl_dvd2])
   278     }
   279 
   280     with \<open>(\<forall>a\<in>A. a dvd l)\<close> and unit_factor_is_unit[OF \<open>l \<noteq> 0\<close>] and \<open>l \<noteq> 0\<close>
   281       have "(\<forall>a\<in>A. a dvd normalize l) \<and> 
   282         (\<forall>l'. (\<forall>a\<in>A. a dvd l') \<longrightarrow> normalize l dvd l') \<and>
   283         unit_factor (normalize l) = 
   284         (if normalize l = 0 then 0 else 1)"
   285       by (auto simp: unit_simps)
   286     also from True have "normalize l = Lcm_eucl A"
   287       by (simp add: Lcm_eucl_def Let_def n_def l_def)
   288     finally show ?thesis .
   289   qed
   290   note A = this
   291 
   292   {fix a assume "a \<in> A" then show "a dvd Lcm_eucl A" using A by blast}
   293   {fix b assume "\<And>a. a \<in> A \<Longrightarrow> a dvd b" then show "Lcm_eucl A dvd b" using A by blast}
   294   from A show "unit_factor (Lcm_eucl A) = (if Lcm_eucl A = 0 then 0 else 1)" by blast
   295 qed
   296 
   297 lemma normalize_Lcm_eucl [simp]:
   298   "normalize (Lcm_eucl A) = Lcm_eucl A"
   299 proof (cases "Lcm_eucl A = 0")
   300   case True then show ?thesis by simp
   301 next
   302   case False
   303   have "unit_factor (Lcm_eucl A) * normalize (Lcm_eucl A) = Lcm_eucl A"
   304     by (fact unit_factor_mult_normalize)
   305   with False show ?thesis by simp
   306 qed
   307 
   308 lemma eq_Lcm_euclI:
   309   fixes lcm :: "'a set \<Rightarrow> 'a"
   310   assumes "\<And>A a. a \<in> A \<Longrightarrow> a dvd lcm A" and "\<And>A c. (\<And>a. a \<in> A \<Longrightarrow> a dvd c) \<Longrightarrow> lcm A dvd c"
   311           "\<And>A. normalize (lcm A) = lcm A" shows "lcm = Lcm_eucl"
   312   by (intro ext, rule associated_eqI) (auto simp: assms intro: Lcm_eucl_least)  
   313 
   314 lemma Gcd_eucl_dvd: "a \<in> A \<Longrightarrow> Gcd_eucl A dvd a"
   315   unfolding Gcd_eucl_def by (auto intro: Lcm_eucl_least)
   316 
   317 lemma Gcd_eucl_greatest: "(\<And>x. x \<in> A \<Longrightarrow> d dvd x) \<Longrightarrow> d dvd Gcd_eucl A"
   318   unfolding Gcd_eucl_def by auto
   319 
   320 lemma normalize_Gcd_eucl [simp]: "normalize (Gcd_eucl A) = Gcd_eucl A"
   321   by (simp add: Gcd_eucl_def)
   322 
   323 lemma Lcm_euclI:
   324   assumes "\<And>x. x \<in> A \<Longrightarrow> x dvd d" "\<And>d'. (\<And>x. x \<in> A \<Longrightarrow> x dvd d') \<Longrightarrow> d dvd d'" "normalize d = d"
   325   shows   "Lcm_eucl A = d"
   326 proof -
   327   have "normalize (Lcm_eucl A) = normalize d"
   328     by (intro associatedI) (auto intro: dvd_Lcm_eucl Lcm_eucl_least assms)
   329   thus ?thesis by (simp add: assms)
   330 qed
   331 
   332 lemma Gcd_euclI:
   333   assumes "\<And>x. x \<in> A \<Longrightarrow> d dvd x" "\<And>d'. (\<And>x. x \<in> A \<Longrightarrow> d' dvd x) \<Longrightarrow> d' dvd d" "normalize d = d"
   334   shows   "Gcd_eucl A = d"
   335 proof -
   336   have "normalize (Gcd_eucl A) = normalize d"
   337     by (intro associatedI) (auto intro: Gcd_eucl_dvd Gcd_eucl_greatest assms)
   338   thus ?thesis by (simp add: assms)
   339 qed
   340   
   341 lemmas lcm_gcd_eucl_facts = 
   342   gcd_eucl_dvd1 gcd_eucl_dvd2 gcd_eucl_greatest normalize_gcd_eucl lcm_eucl_def
   343   Gcd_eucl_def Gcd_eucl_dvd Gcd_eucl_greatest normalize_Gcd_eucl
   344   dvd_Lcm_eucl Lcm_eucl_least normalize_Lcm_eucl
   345 
   346 lemma normalized_factors_product:
   347   "{p. p dvd a * b \<and> normalize p = p} = 
   348      (\<lambda>(x,y). x * y) ` ({p. p dvd a \<and> normalize p = p} \<times> {p. p dvd b \<and> normalize p = p})"
   349 proof safe
   350   fix p assume p: "p dvd a * b" "normalize p = p"
   351   interpret semiring_gcd 1 0 "op *" gcd_eucl lcm_eucl "op div" "op +" "op -" normalize unit_factor
   352     by standard (rule lcm_gcd_eucl_facts; assumption)+
   353   from dvd_productE[OF p(1)] guess x y . note xy = this
   354   define x' y' where "x' = normalize x" and "y' = normalize y"
   355   have "p = x' * y'"
   356     by (subst p(2) [symmetric]) (simp add: xy x'_def y'_def normalize_mult)
   357   moreover from xy have "normalize x' = x'" "normalize y' = y'" "x' dvd a" "y' dvd b" 
   358     by (simp_all add: x'_def y'_def)
   359   ultimately show "p \<in> (\<lambda>(x, y). x * y) ` 
   360                      ({p. p dvd a \<and> normalize p = p} \<times> {p. p dvd b \<and> normalize p = p})"
   361     by blast
   362 qed (auto simp: normalize_mult mult_dvd_mono)
   363 
   364 
   365 subclass factorial_semiring
   366 proof (standard, rule factorial_semiring_altI_aux)
   367   fix x assume "x \<noteq> 0"
   368   thus "finite {p. p dvd x \<and> normalize p = p}"
   369   proof (induction "euclidean_size x" arbitrary: x rule: less_induct)
   370     case (less x)
   371     show ?case
   372     proof (cases "\<exists>y. y dvd x \<and> \<not>x dvd y \<and> \<not>is_unit y")
   373       case False
   374       have "{p. p dvd x \<and> normalize p = p} \<subseteq> {1, normalize x}"
   375       proof
   376         fix p assume p: "p \<in> {p. p dvd x \<and> normalize p = p}"
   377         with False have "is_unit p \<or> x dvd p" by blast
   378         thus "p \<in> {1, normalize x}"
   379         proof (elim disjE)
   380           assume "is_unit p"
   381           hence "normalize p = 1" by (simp add: is_unit_normalize)
   382           with p show ?thesis by simp
   383         next
   384           assume "x dvd p"
   385           with p have "normalize p = normalize x" by (intro associatedI) simp_all
   386           with p show ?thesis by simp
   387         qed
   388       qed
   389       moreover have "finite \<dots>" by simp
   390       ultimately show ?thesis by (rule finite_subset)
   391       
   392     next
   393       case True
   394       then obtain y where y: "y dvd x" "\<not>x dvd y" "\<not>is_unit y" by blast
   395       define z where "z = x div y"
   396       let ?fctrs = "\<lambda>x. {p. p dvd x \<and> normalize p = p}"
   397       from y have x: "x = y * z" by (simp add: z_def)
   398       with less.prems have "y \<noteq> 0" "z \<noteq> 0" by auto
   399       from x y have "\<not>is_unit z" by (auto simp: mult_unit_dvd_iff)
   400       have "?fctrs x = (\<lambda>(p,p'). p * p') ` (?fctrs y \<times> ?fctrs z)"
   401         by (subst x) (rule normalized_factors_product)
   402       also have "\<not>y * z dvd y * 1" "\<not>y * z dvd 1 * z"
   403         by (subst dvd_times_left_cancel_iff dvd_times_right_cancel_iff; fact)+
   404       hence "finite ((\<lambda>(p,p'). p * p') ` (?fctrs y \<times> ?fctrs z))"
   405         by (intro finite_imageI finite_cartesian_product less dvd_proper_imp_size_less)
   406            (auto simp: x)
   407       finally show ?thesis .
   408     qed
   409   qed
   410 next
   411   interpret semiring_gcd 1 0 "op *" gcd_eucl lcm_eucl "op div" "op +" "op -" normalize unit_factor
   412     by standard (rule lcm_gcd_eucl_facts; assumption)+
   413   fix p assume p: "irreducible p"
   414   thus "prime_elem p" by (rule irreducible_imp_prime_elem_gcd)
   415 qed
   416 
   417 lemma gcd_eucl_eq_gcd_factorial: "gcd_eucl = gcd_factorial"
   418   by (intro ext gcd_euclI gcd_lcm_factorial)
   419 
   420 lemma lcm_eucl_eq_lcm_factorial: "lcm_eucl = lcm_factorial"
   421   by (intro ext) (simp add: lcm_eucl_def lcm_factorial_gcd_factorial gcd_eucl_eq_gcd_factorial)
   422 
   423 lemma Gcd_eucl_eq_Gcd_factorial: "Gcd_eucl = Gcd_factorial"
   424   by (intro ext Gcd_euclI gcd_lcm_factorial)
   425 
   426 lemma Lcm_eucl_eq_Lcm_factorial: "Lcm_eucl = Lcm_factorial"
   427   by (intro ext Lcm_euclI gcd_lcm_factorial)
   428 
   429 lemmas eucl_eq_factorial = 
   430   gcd_eucl_eq_gcd_factorial lcm_eucl_eq_lcm_factorial 
   431   Gcd_eucl_eq_Gcd_factorial Lcm_eucl_eq_Lcm_factorial
   432   
   433 end
   434 
   435 class euclidean_ring = euclidean_semiring + idom
   436 begin
   437 
   438 function euclid_ext_aux :: "'a \<Rightarrow> _" where
   439   "euclid_ext_aux r' r s' s t' t = (
   440      if r = 0 then let c = 1 div unit_factor r' in (s' * c, t' * c, normalize r')
   441      else let q = r' div r
   442           in  euclid_ext_aux r (r' mod r) s (s' - q * s) t (t' - q * t))"
   443 by auto
   444 termination by (relation "measure (\<lambda>(_,b,_,_,_,_). euclidean_size b)") (simp_all add: mod_size_less)
   445 
   446 declare euclid_ext_aux.simps [simp del]
   447 
   448 lemma euclid_ext_aux_correct:
   449   assumes "gcd_eucl r' r = gcd_eucl a b"
   450   assumes "s' * a + t' * b = r'"
   451   assumes "s * a + t * b = r"
   452   shows   "case euclid_ext_aux r' r s' s t' t of (x,y,c) \<Rightarrow>
   453              x * a + y * b = c \<and> c = gcd_eucl a b" (is "?P (euclid_ext_aux r' r s' s t' t)")
   454 using assms
   455 proof (induction r' r s' s t' t rule: euclid_ext_aux.induct)
   456   case (1 r' r s' s t' t)
   457   show ?case
   458   proof (cases "r = 0")
   459     case True
   460     hence "euclid_ext_aux r' r s' s t' t = 
   461              (s' div unit_factor r', t' div unit_factor r', normalize r')"
   462       by (subst euclid_ext_aux.simps) (simp add: Let_def)
   463     also have "?P \<dots>"
   464     proof safe
   465       have "s' div unit_factor r' * a + t' div unit_factor r' * b = 
   466                 (s' * a + t' * b) div unit_factor r'"
   467         by (cases "r' = 0") (simp_all add: unit_div_commute)
   468       also have "s' * a + t' * b = r'" by fact
   469       also have "\<dots> div unit_factor r' = normalize r'" by simp
   470       finally show "s' div unit_factor r' * a + t' div unit_factor r' * b = normalize r'" .
   471     next
   472       from "1.prems" True show "normalize r' = gcd_eucl a b" by (simp add: gcd_eucl_0)
   473     qed
   474     finally show ?thesis .
   475   next
   476     case False
   477     hence "euclid_ext_aux r' r s' s t' t = 
   478              euclid_ext_aux r (r' mod r) s (s' - r' div r * s) t (t' - r' div r * t)"
   479       by (subst euclid_ext_aux.simps) (simp add: Let_def)
   480     also from "1.prems" False have "?P \<dots>"
   481     proof (intro "1.IH")
   482       have "(s' - r' div r * s) * a + (t' - r' div r * t) * b =
   483               (s' * a + t' * b) - r' div r * (s * a + t * b)" by (simp add: algebra_simps)
   484       also have "s' * a + t' * b = r'" by fact
   485       also have "s * a + t * b = r" by fact
   486       also have "r' - r' div r * r = r' mod r" using div_mult_mod_eq [of r' r]
   487         by (simp add: algebra_simps)
   488       finally show "(s' - r' div r * s) * a + (t' - r' div r * t) * b = r' mod r" .
   489     qed (auto simp: gcd_eucl_non_0 algebra_simps minus_mod_eq_div_mult [symmetric])
   490     finally show ?thesis .
   491   qed
   492 qed
   493 
   494 definition euclid_ext where
   495   "euclid_ext a b = euclid_ext_aux a b 1 0 0 1"
   496 
   497 lemma euclid_ext_0: 
   498   "euclid_ext a 0 = (1 div unit_factor a, 0, normalize a)"
   499   by (simp add: euclid_ext_def euclid_ext_aux.simps)
   500 
   501 lemma euclid_ext_left_0: 
   502   "euclid_ext 0 a = (0, 1 div unit_factor a, normalize a)"
   503   by (simp add: euclid_ext_def euclid_ext_aux.simps)
   504 
   505 lemma euclid_ext_correct':
   506   "case euclid_ext a b of (x,y,c) \<Rightarrow> x * a + y * b = c \<and> c = gcd_eucl a b"
   507   unfolding euclid_ext_def by (rule euclid_ext_aux_correct) simp_all
   508 
   509 lemma euclid_ext_gcd_eucl:
   510   "(case euclid_ext a b of (x,y,c) \<Rightarrow> c) = gcd_eucl a b"
   511   using euclid_ext_correct'[of a b] by (simp add: case_prod_unfold)
   512 
   513 definition euclid_ext' where
   514   "euclid_ext' a b = (case euclid_ext a b of (x, y, _) \<Rightarrow> (x, y))"
   515 
   516 lemma euclid_ext'_correct':
   517   "case euclid_ext' a b of (x,y) \<Rightarrow> x * a + y * b = gcd_eucl a b"
   518   using euclid_ext_correct'[of a b] by (simp add: case_prod_unfold euclid_ext'_def)
   519 
   520 lemma euclid_ext'_0: "euclid_ext' a 0 = (1 div unit_factor a, 0)" 
   521   by (simp add: euclid_ext'_def euclid_ext_0)
   522 
   523 lemma euclid_ext'_left_0: "euclid_ext' 0 a = (0, 1 div unit_factor a)" 
   524   by (simp add: euclid_ext'_def euclid_ext_left_0)
   525 
   526 end
   527 
   528 class euclidean_semiring_gcd = euclidean_semiring + gcd + Gcd +
   529   assumes gcd_gcd_eucl: "gcd = gcd_eucl" and lcm_lcm_eucl: "lcm = lcm_eucl"
   530   assumes Gcd_Gcd_eucl: "Gcd = Gcd_eucl" and Lcm_Lcm_eucl: "Lcm = Lcm_eucl"
   531 begin
   532 
   533 subclass semiring_gcd
   534   by standard (simp_all add: gcd_gcd_eucl gcd_eucl_greatest lcm_lcm_eucl lcm_eucl_def)
   535 
   536 subclass semiring_Gcd
   537   by standard (auto simp: Gcd_Gcd_eucl Lcm_Lcm_eucl Gcd_eucl_def intro: Lcm_eucl_least)
   538 
   539 subclass factorial_semiring_gcd
   540 proof
   541   fix a b
   542   show "gcd a b = gcd_factorial a b"
   543     by (rule sym, rule gcdI) (rule gcd_lcm_factorial; assumption)+
   544   thus "lcm a b = lcm_factorial a b"
   545     by (simp add: lcm_factorial_gcd_factorial lcm_gcd)
   546 next
   547   fix A 
   548   show "Gcd A = Gcd_factorial A"
   549     by (rule sym, rule GcdI) (rule gcd_lcm_factorial; assumption)+
   550   show "Lcm A = Lcm_factorial A"
   551     by (rule sym, rule LcmI) (rule gcd_lcm_factorial; assumption)+
   552 qed
   553 
   554 lemma gcd_non_0:
   555   "b \<noteq> 0 \<Longrightarrow> gcd a b = gcd b (a mod b)"
   556   unfolding gcd_gcd_eucl by (fact gcd_eucl_non_0)
   557 
   558 lemmas gcd_0 = gcd_0_right
   559 lemmas dvd_gcd_iff = gcd_greatest_iff
   560 lemmas gcd_greatest_iff = dvd_gcd_iff
   561 
   562 lemma gcd_mod1 [simp]:
   563   "gcd (a mod b) b = gcd a b"
   564   by (rule gcdI, metis dvd_mod_iff gcd_dvd1 gcd_dvd2, simp_all add: gcd_greatest dvd_mod_iff)
   565 
   566 lemma gcd_mod2 [simp]:
   567   "gcd a (b mod a) = gcd a b"
   568   by (rule gcdI, simp, metis dvd_mod_iff gcd_dvd1 gcd_dvd2, simp_all add: gcd_greatest dvd_mod_iff)
   569          
   570 lemma euclidean_size_gcd_le1 [simp]:
   571   assumes "a \<noteq> 0"
   572   shows "euclidean_size (gcd a b) \<le> euclidean_size a"
   573 proof -
   574    have "gcd a b dvd a" by (rule gcd_dvd1)
   575    then obtain c where A: "a = gcd a b * c" unfolding dvd_def by blast
   576    with \<open>a \<noteq> 0\<close> show ?thesis by (subst (2) A, intro size_mult_mono) auto
   577 qed
   578 
   579 lemma euclidean_size_gcd_le2 [simp]:
   580   "b \<noteq> 0 \<Longrightarrow> euclidean_size (gcd a b) \<le> euclidean_size b"
   581   by (subst gcd.commute, rule euclidean_size_gcd_le1)
   582 
   583 lemma euclidean_size_gcd_less1:
   584   assumes "a \<noteq> 0" and "\<not>a dvd b"
   585   shows "euclidean_size (gcd a b) < euclidean_size a"
   586 proof (rule ccontr)
   587   assume "\<not>euclidean_size (gcd a b) < euclidean_size a"
   588   with \<open>a \<noteq> 0\<close> have A: "euclidean_size (gcd a b) = euclidean_size a"
   589     by (intro le_antisym, simp_all)
   590   have "a dvd gcd a b"
   591     by (rule dvd_euclidean_size_eq_imp_dvd) (simp_all add: assms A)
   592   hence "a dvd b" using dvd_gcdD2 by blast
   593   with \<open>\<not>a dvd b\<close> show False by contradiction
   594 qed
   595 
   596 lemma euclidean_size_gcd_less2:
   597   assumes "b \<noteq> 0" and "\<not>b dvd a"
   598   shows "euclidean_size (gcd a b) < euclidean_size b"
   599   using assms by (subst gcd.commute, rule euclidean_size_gcd_less1)
   600 
   601 lemma euclidean_size_lcm_le1: 
   602   assumes "a \<noteq> 0" and "b \<noteq> 0"
   603   shows "euclidean_size a \<le> euclidean_size (lcm a b)"
   604 proof -
   605   have "a dvd lcm a b" by (rule dvd_lcm1)
   606   then obtain c where A: "lcm a b = a * c" ..
   607   with \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> have "c \<noteq> 0" by (auto simp: lcm_eq_0_iff)
   608   then show ?thesis by (subst A, intro size_mult_mono)
   609 qed
   610 
   611 lemma euclidean_size_lcm_le2:
   612   "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> euclidean_size b \<le> euclidean_size (lcm a b)"
   613   using euclidean_size_lcm_le1 [of b a] by (simp add: ac_simps)
   614 
   615 lemma euclidean_size_lcm_less1:
   616   assumes "b \<noteq> 0" and "\<not>b dvd a"
   617   shows "euclidean_size a < euclidean_size (lcm a b)"
   618 proof (rule ccontr)
   619   from assms have "a \<noteq> 0" by auto
   620   assume "\<not>euclidean_size a < euclidean_size (lcm a b)"
   621   with \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> have "euclidean_size (lcm a b) = euclidean_size a"
   622     by (intro le_antisym, simp, intro euclidean_size_lcm_le1)
   623   with assms have "lcm a b dvd a" 
   624     by (rule_tac dvd_euclidean_size_eq_imp_dvd) (auto simp: lcm_eq_0_iff)
   625   hence "b dvd a" by (rule lcm_dvdD2)
   626   with \<open>\<not>b dvd a\<close> show False by contradiction
   627 qed
   628 
   629 lemma euclidean_size_lcm_less2:
   630   assumes "a \<noteq> 0" and "\<not>a dvd b"
   631   shows "euclidean_size b < euclidean_size (lcm a b)"
   632   using assms euclidean_size_lcm_less1 [of a b] by (simp add: ac_simps)
   633 
   634 lemma Lcm_eucl_set [code]:
   635   "Lcm_eucl (set xs) = foldl lcm_eucl 1 xs"
   636   by (simp add: Lcm_Lcm_eucl [symmetric] lcm_lcm_eucl Lcm_set)
   637 
   638 lemma Gcd_eucl_set [code]:
   639   "Gcd_eucl (set xs) = foldl gcd_eucl 0 xs"
   640   by (simp add: Gcd_Gcd_eucl [symmetric] gcd_gcd_eucl Gcd_set)
   641 
   642 end
   643 
   644 
   645 text \<open>
   646   A Euclidean ring is a Euclidean semiring with additive inverses. It provides a 
   647   few more lemmas; in particular, Bezout's lemma holds for any Euclidean ring.
   648 \<close>
   649 
   650 class euclidean_ring_gcd = euclidean_semiring_gcd + idom
   651 begin
   652 
   653 subclass euclidean_ring ..
   654 subclass ring_gcd ..
   655 subclass factorial_ring_gcd ..
   656 
   657 lemma euclid_ext_gcd [simp]:
   658   "(case euclid_ext a b of (_, _ , t) \<Rightarrow> t) = gcd a b"
   659   using euclid_ext_correct'[of a b] by (simp add: case_prod_unfold Let_def gcd_gcd_eucl)
   660 
   661 lemma euclid_ext_gcd' [simp]:
   662   "euclid_ext a b = (r, s, t) \<Longrightarrow> t = gcd a b"
   663   by (insert euclid_ext_gcd[of a b], drule (1) subst, simp)
   664 
   665 lemma euclid_ext_correct:
   666   "case euclid_ext a b of (x,y,c) \<Rightarrow> x * a + y * b = c \<and> c = gcd a b"
   667   using euclid_ext_correct'[of a b]
   668   by (simp add: gcd_gcd_eucl case_prod_unfold)
   669   
   670 lemma euclid_ext'_correct:
   671   "fst (euclid_ext' a b) * a + snd (euclid_ext' a b) * b = gcd a b"
   672   using euclid_ext_correct'[of a b]
   673   by (simp add: gcd_gcd_eucl case_prod_unfold euclid_ext'_def)
   674 
   675 lemma bezout: "\<exists>s t. s * a + t * b = gcd a b"
   676   using euclid_ext'_correct by blast
   677 
   678 end
   679 
   680 
   681 subsection \<open>Typical instances\<close>
   682 
   683 instantiation nat :: euclidean_semiring
   684 begin
   685 
   686 definition [simp]:
   687   "euclidean_size_nat = (id :: nat \<Rightarrow> nat)"
   688 
   689 instance by standard simp_all
   690 
   691 end
   692 
   693 
   694 instantiation int :: euclidean_ring
   695 begin
   696 
   697 definition [simp]:
   698   "euclidean_size_int = (nat \<circ> abs :: int \<Rightarrow> nat)"
   699 
   700 instance by standard (auto simp add: abs_mult nat_mult_distrib split: abs_split)
   701 
   702 end
   703 
   704 instance nat :: euclidean_semiring_gcd
   705 proof
   706   show [simp]: "gcd = (gcd_eucl :: nat \<Rightarrow> _)" "Lcm = (Lcm_eucl :: nat set \<Rightarrow> _)"
   707     by (simp_all add: eq_gcd_euclI eq_Lcm_euclI)
   708   show "lcm = (lcm_eucl :: nat \<Rightarrow> _)" "Gcd = (Gcd_eucl :: nat set \<Rightarrow> _)"
   709     by (intro ext, simp add: lcm_eucl_def lcm_nat_def Gcd_nat_def Gcd_eucl_def)+
   710 qed
   711 
   712 instance int :: euclidean_ring_gcd
   713 proof
   714   show [simp]: "gcd = (gcd_eucl :: int \<Rightarrow> _)" "Lcm = (Lcm_eucl :: int set \<Rightarrow> _)"
   715     by (simp_all add: eq_gcd_euclI eq_Lcm_euclI)
   716   show "lcm = (lcm_eucl :: int \<Rightarrow> _)" "Gcd = (Gcd_eucl :: int set \<Rightarrow> _)"
   717     by (intro ext, simp add: lcm_eucl_def lcm_altdef_int 
   718           semiring_Gcd_class.Gcd_Lcm Gcd_eucl_def abs_mult)+
   719 qed
   720 
   721 end