src/Pure/Thy/thy_output.ML
author wenzelm
Sat Oct 17 19:47:34 2015 +0200 (2015-10-17)
changeset 61461 77c9643a6353
parent 61459 5f2ddeb15c06
child 61462 e16649b70107
permissions -rw-r--r--
more explicit output of list items;
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Theory document output with antiquotations.
     5 *)
     6 
     7 signature THY_OUTPUT =
     8 sig
     9   val display: bool Config.T
    10   val quotes: bool Config.T
    11   val margin: int Config.T
    12   val indent: int Config.T
    13   val source: bool Config.T
    14   val break: bool Config.T
    15   val modes: string Config.T
    16   val add_wrapper: ((unit -> string) -> unit -> string) -> Proof.context -> Proof.context
    17   val add_option: binding -> (string -> Proof.context -> Proof.context) -> theory -> theory
    18   val check_command: Proof.context -> xstring * Position.T -> string
    19   val check_option: Proof.context -> xstring * Position.T -> string
    20   val print_antiquotations: bool -> Proof.context -> unit
    21   val antiquotation: binding -> 'a context_parser ->
    22     ({source: Token.src, state: Toplevel.state, context: Proof.context} -> 'a -> string) ->
    23       theory -> theory
    24   val boolean: string -> bool
    25   val integer: string -> int
    26   val eval_antiquote: Toplevel.state -> Antiquote.text_antiquote -> string
    27   val output_text: Toplevel.state -> {markdown: bool} -> Input.source -> string
    28   val present_thy: theory -> (Toplevel.transition * Toplevel.state) list -> Token.T list -> Buffer.T
    29   val pretty_text: Proof.context -> string -> Pretty.T
    30   val pretty_term: Proof.context -> term -> Pretty.T
    31   val pretty_thm: Proof.context -> thm -> Pretty.T
    32   val str_of_source: Token.src -> string
    33   val maybe_pretty_source: (Proof.context -> 'a -> Pretty.T) -> Proof.context ->
    34     Token.src -> 'a list -> Pretty.T list
    35   val string_of_margin: Proof.context -> Pretty.T -> string
    36   val output: Proof.context -> Pretty.T list -> string
    37   val verbatim_text: Proof.context -> string -> string
    38   val old_header_command: Input.source -> Toplevel.transition -> Toplevel.transition
    39   val document_command: {markdown: bool} -> (xstring * Position.T) option * Input.source ->
    40     Toplevel.transition -> Toplevel.transition
    41 end;
    42 
    43 structure Thy_Output: THY_OUTPUT =
    44 struct
    45 
    46 (** options **)
    47 
    48 val display = Attrib.setup_option_bool ("thy_output_display", @{here});
    49 val break = Attrib.setup_option_bool ("thy_output_break", @{here});
    50 val quotes = Attrib.setup_option_bool ("thy_output_quotes", @{here});
    51 val margin = Attrib.setup_option_int ("thy_output_margin", @{here});
    52 val indent = Attrib.setup_option_int ("thy_output_indent", @{here});
    53 val source = Attrib.setup_option_bool ("thy_output_source", @{here});
    54 val modes = Attrib.setup_option_string ("thy_output_modes", @{here});
    55 
    56 
    57 structure Wrappers = Proof_Data
    58 (
    59   type T = ((unit -> string) -> unit -> string) list;
    60   fun init _ = [];
    61 );
    62 
    63 fun add_wrapper wrapper = Wrappers.map (cons wrapper);
    64 
    65 val wrap = Wrappers.get #> fold (fn wrapper => fn f => wrapper f);
    66 
    67 
    68 
    69 (** maintain global antiquotations **)
    70 
    71 structure Antiquotations = Theory_Data
    72 (
    73   type T =
    74     (Token.src -> Toplevel.state -> Proof.context -> string) Name_Space.table *
    75       (string -> Proof.context -> Proof.context) Name_Space.table;
    76   val empty : T =
    77     (Name_Space.empty_table Markup.document_antiquotationN,
    78       Name_Space.empty_table Markup.document_antiquotation_optionN);
    79   val extend = I;
    80   fun merge ((commands1, options1), (commands2, options2)) : T =
    81     (Name_Space.merge_tables (commands1, commands2),
    82       Name_Space.merge_tables (options1, options2));
    83 );
    84 
    85 val get_antiquotations = Antiquotations.get o Proof_Context.theory_of;
    86 
    87 fun add_command name cmd thy = thy
    88   |> Antiquotations.map (apfst (Name_Space.define (Context.Theory thy) true (name, cmd) #> snd));
    89 
    90 fun add_option name opt thy = thy
    91   |> Antiquotations.map (apsnd (Name_Space.define (Context.Theory thy) true (name, opt) #> snd));
    92 
    93 fun check_command ctxt = #1 o Name_Space.check (Context.Proof ctxt) (#1 (get_antiquotations ctxt));
    94 
    95 fun check_option ctxt = #1 o Name_Space.check (Context.Proof ctxt) (#2 (get_antiquotations ctxt));
    96 
    97 fun command src state ctxt =
    98   let val (src', f) = Token.check_src ctxt (#1 (get_antiquotations ctxt)) src
    99   in f src' state ctxt end;
   100 
   101 fun option ((xname, pos), s) ctxt =
   102   let
   103     val (_, opt) =
   104       Name_Space.check (Context.Proof ctxt) (#2 (get_antiquotations ctxt)) (xname, pos);
   105   in opt s ctxt end;
   106 
   107 fun print_antiquotations verbose ctxt =
   108   let
   109     val (commands, options) = get_antiquotations ctxt;
   110     val command_names = map #1 (Name_Space.markup_table verbose ctxt commands);
   111     val option_names = map #1 (Name_Space.markup_table verbose ctxt options);
   112   in
   113     [Pretty.big_list "document antiquotations:" (map Pretty.mark_str command_names),
   114      Pretty.big_list "document antiquotation options:" (map Pretty.mark_str option_names)]
   115   end |> Pretty.writeln_chunks;
   116 
   117 fun antiquotation name scan body =
   118   add_command name
   119     (fn src => fn state => fn ctxt =>
   120       let val (x, ctxt') = Token.syntax scan src ctxt
   121       in body {source = src, state = state, context = ctxt'} x end);
   122 
   123 
   124 
   125 (** syntax of antiquotations **)
   126 
   127 (* option values *)
   128 
   129 fun boolean "" = true
   130   | boolean "true" = true
   131   | boolean "false" = false
   132   | boolean s = error ("Bad boolean value: " ^ quote s);
   133 
   134 fun integer s =
   135   let
   136     fun int ss =
   137       (case Library.read_int ss of (i, []) => i
   138       | _ => error ("Bad integer value: " ^ quote s));
   139   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   140 
   141 
   142 (* outer syntax *)
   143 
   144 local
   145 
   146 val property =
   147   Parse.position Parse.xname -- Scan.optional (Parse.$$$ "=" |-- Parse.!!! Parse.xname) "";
   148 
   149 val properties =
   150   Scan.optional (Parse.$$$ "[" |-- Parse.!!! (Parse.enum "," property --| Parse.$$$ "]")) [];
   151 
   152 in
   153 
   154 val antiq =
   155   Parse.!!!
   156     (Parse.position Parse.liberal_name -- properties -- Parse.args --| Scan.ahead Parse.eof)
   157   >> (fn ((name, props), args) => (props, Token.src name args));
   158 
   159 end;
   160 
   161 
   162 (* eval antiquote *)
   163 
   164 fun eval_antiquote _ (Antiquote.Text ss) = Symbol_Pos.content ss
   165   | eval_antiquote state (Antiquote.Antiq (ss, {range = (pos, _), ...})) =
   166       let
   167         val keywords =
   168           (case try Toplevel.presentation_context_of state of
   169             SOME ctxt => Thy_Header.get_keywords' ctxt
   170           | NONE =>
   171               error ("Unknown context -- cannot expand document antiquotations" ^
   172                 Position.here pos));
   173 
   174         val (opts, src) = Token.read_antiq keywords antiq (ss, pos);
   175         fun cmd ctxt = wrap ctxt (fn () => command src state ctxt) ();
   176 
   177         val preview_ctxt = fold option opts (Toplevel.presentation_context_of state);
   178         val print_ctxt = Context_Position.set_visible false preview_ctxt;
   179         val _ = cmd preview_ctxt;
   180         val print_modes = space_explode "," (Config.get print_ctxt modes) @ Latex.modes;
   181       in Print_Mode.with_modes print_modes (fn () => cmd print_ctxt) () end;
   182 
   183 
   184 (* output text *)
   185 
   186 fun output_text state {markdown} source =
   187   let
   188     val pos = Input.pos_of source;
   189     val _ = Position.report pos (Markup.language_document (Input.is_delimited source));
   190     val syms = Input.source_explode source;
   191 
   192     val output_antiquote = eval_antiquote state #> Symbol.explode #> Latex.output_ctrl_symbols;
   193     val output_antiquotes = map output_antiquote #> implode;
   194 
   195     fun output_line line =
   196       (if Markdown.line_is_item line then "\\item " else "") ^
   197         output_antiquotes (Markdown.line_content line);
   198 
   199     fun output_blocks blocks = space_implode "\n\n" (map output_block blocks)
   200     and output_block (Markdown.Paragraph lines) = cat_lines (map output_line lines)
   201       | output_block (Markdown.List {kind, body, ...}) =
   202           let val env = Markdown.print_kind kind in
   203             "%\n\\begin{" ^ env ^ "}%\n" ^
   204             output_blocks body ^
   205             "%\n\\end{" ^ env ^ "}%\n"
   206           end;
   207   in
   208     if Toplevel.is_skipped_proof state then ""
   209     else if markdown andalso exists (Markdown.is_control o Symbol_Pos.symbol) syms
   210     then
   211       let
   212         val ants = Antiquote.read' pos syms;
   213         val blocks = Markdown.read_antiquotes ants;
   214         val _ = Position.reports (Markdown.reports blocks);
   215       in output_blocks blocks end
   216     else
   217       let
   218         val ants = Antiquote.read' pos (Symbol_Pos.trim_blanks syms);
   219         val _ = Position.reports (Markdown.text_reports ants);
   220       in output_antiquotes ants end
   221   end;
   222 
   223 
   224 
   225 (** present theory source **)
   226 
   227 (*NB: arranging white space around command spans is a black art*)
   228 
   229 (* presentation tokens *)
   230 
   231 datatype token =
   232     No_Token
   233   | Basic_Token of Token.T
   234   | Markup_Token of string * Input.source
   235   | Markup_Env_Token of string * Input.source
   236   | Raw_Token of Input.source;
   237 
   238 
   239 fun basic_token pred (Basic_Token tok) = pred tok
   240   | basic_token _ _ = false;
   241 
   242 val improper_token = basic_token Token.is_improper;
   243 val comment_token = basic_token Token.is_comment;
   244 val blank_token = basic_token Token.is_blank;
   245 val newline_token = basic_token Token.is_newline;
   246 
   247 
   248 (* output token *)
   249 
   250 fun output_token state tok =
   251   (case tok of
   252     No_Token => ""
   253   | Basic_Token tok => Latex.output_token tok
   254   | Markup_Token (cmd, source) =>
   255       "%\n\\isamarkup" ^ cmd ^ "{" ^ output_text state {markdown = false} source ^ "%\n}\n"
   256   | Markup_Env_Token (cmd, source) =>
   257       "%\n\\begin{isamarkup" ^ cmd ^ "}%\n" ^
   258       output_text state {markdown = true} source ^
   259       "%\n\\end{isamarkup" ^ cmd ^ "}%\n"
   260   | Raw_Token source =>
   261       "%\n" ^ output_text state {markdown = true} source ^ "\n");
   262 
   263 
   264 (* command spans *)
   265 
   266 type command = string * Position.T * string list;   (*name, position, tags*)
   267 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   268 
   269 datatype span = Span of command * (source * source * source * source) * bool;
   270 
   271 fun make_span cmd src =
   272   let
   273     fun take_newline (tok :: toks) =
   274           if newline_token (fst tok) then ([tok], toks, true)
   275           else ([], tok :: toks, false)
   276       | take_newline [] = ([], [], false);
   277     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   278       src
   279       |> take_prefix (improper_token o fst)
   280       ||>> take_suffix (improper_token o fst)
   281       ||>> take_prefix (comment_token o fst)
   282       ||> take_newline;
   283   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   284 
   285 
   286 (* present spans *)
   287 
   288 local
   289 
   290 fun err_bad_nesting pos =
   291   error ("Bad nesting of commands in presentation" ^ pos);
   292 
   293 fun edge which f (x: string option, y) =
   294   if x = y then I
   295   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   296 
   297 val begin_tag = edge #2 Latex.begin_tag;
   298 val end_tag = edge #1 Latex.end_tag;
   299 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   300 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   301 
   302 in
   303 
   304 fun present_span keywords span state state' (tag_stack, active_tag, newline, buffer, present_cont) =
   305   let
   306     val present = fold (fn (tok, (flag, 0)) =>
   307         Buffer.add (output_token state' tok)
   308         #> Buffer.add flag
   309       | _ => I);
   310 
   311     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   312 
   313     val (tag, tags) = tag_stack;
   314     val tag' = try hd (fold (update (op =)) cmd_tags (the_list tag));
   315 
   316     val nesting = Toplevel.level state' - Toplevel.level state;
   317 
   318     val active_tag' =
   319       if is_some tag' then tag'
   320       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   321       else
   322         (case Keyword.command_tags keywords cmd_name of
   323           default_tag :: _ => SOME default_tag
   324         | [] =>
   325             if Keyword.is_vacuous keywords cmd_name andalso Toplevel.is_proof state
   326             then active_tag
   327             else NONE);
   328 
   329     val edge = (active_tag, active_tag');
   330 
   331     val newline' =
   332       if is_none active_tag' then span_newline else newline;
   333 
   334     val tag_stack' =
   335       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   336       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   337       else
   338         (case drop (~ nesting - 1) tags of
   339           tg :: tgs => (tg, tgs)
   340         | [] => err_bad_nesting (Position.here cmd_pos));
   341 
   342     val buffer' =
   343       buffer
   344       |> end_tag edge
   345       |> close_delim (fst present_cont) edge
   346       |> snd present_cont
   347       |> open_delim (present (#1 srcs)) edge
   348       |> begin_tag edge
   349       |> present (#2 srcs);
   350     val present_cont' =
   351       if newline then (present (#3 srcs), present (#4 srcs))
   352       else (I, present (#3 srcs) #> present (#4 srcs));
   353   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   354 
   355 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   356   if not (null tags) then err_bad_nesting " at end of theory"
   357   else
   358     buffer
   359     |> end_tag (active_tag, NONE)
   360     |> close_delim (fst present_cont) (active_tag, NONE)
   361     |> snd present_cont;
   362 
   363 end;
   364 
   365 
   366 (* present_thy *)
   367 
   368 local
   369 
   370 val markup_true = "\\isamarkuptrue%\n";
   371 val markup_false = "\\isamarkupfalse%\n";
   372 
   373 val space_proper =
   374   Scan.one Token.is_blank -- Scan.many Token.is_comment -- Scan.one Token.is_proper;
   375 
   376 val is_improper = not o (Token.is_proper orf Token.is_begin_ignore orf Token.is_end_ignore);
   377 val improper = Scan.many is_improper;
   378 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   379 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one Token.is_blank));
   380 
   381 val opt_newline = Scan.option (Scan.one Token.is_newline);
   382 
   383 val ignore =
   384   Scan.depend (fn d => opt_newline |-- Scan.one Token.is_begin_ignore
   385     >> pair (d + 1)) ||
   386   Scan.depend (fn d => Scan.one Token.is_end_ignore --|
   387     (if d = 0 then Scan.fail_with (K (fn () => "Bad nesting of meta-comments")) else opt_newline)
   388     >> pair (d - 1));
   389 
   390 val tag = (improper -- Parse.$$$ "%" -- improper) |-- Parse.!!! (Parse.tag_name --| blank_end);
   391 
   392 val locale =
   393   Scan.option ((Parse.$$$ "(" -- improper -- Parse.$$$ "in") |--
   394     Parse.!!! (improper |-- Parse.xname --| (improper -- Parse.$$$ ")")));
   395 
   396 in
   397 
   398 fun present_thy thy command_results toks =
   399   let
   400     val keywords = Thy_Header.get_keywords thy;
   401 
   402 
   403     (* tokens *)
   404 
   405     val ignored = Scan.state --| ignore
   406       >> (fn d => (NONE, (No_Token, ("", d))));
   407 
   408     fun markup pred mk flag = Scan.peek (fn d =>
   409       improper |--
   410         Parse.position (Scan.one (fn tok =>
   411           Token.is_command tok andalso pred keywords (Token.content_of tok))) --
   412       Scan.repeat tag --
   413       Parse.!!!! ((improper -- locale -- improper) |-- Parse.document_source --| improper_end)
   414       >> (fn (((tok, pos'), tags), source) =>
   415         let val name = Token.content_of tok
   416         in (SOME (name, pos', tags), (mk (name, source), (flag, d))) end));
   417 
   418     val command = Scan.peek (fn d =>
   419       Scan.optional (Scan.one Token.is_command_modifier -- improper >> op ::) [] --
   420       Scan.one Token.is_command -- Scan.repeat tag
   421       >> (fn ((cmd_mod, cmd), tags) =>
   422         map (fn tok => (NONE, (Basic_Token tok, ("", d)))) cmd_mod @
   423           [(SOME (Token.content_of cmd, Token.pos_of cmd, tags),
   424             (Basic_Token cmd, (markup_false, d)))]));
   425 
   426     val cmt = Scan.peek (fn d =>
   427       Parse.$$$ "--" |-- Parse.!!!! (improper |-- Parse.document_source) >>
   428         (fn source => (NONE, (Markup_Token ("cmt", source), ("", d)))));
   429 
   430     val other = Scan.peek (fn d =>
   431        Parse.not_eof >> (fn tok => (NONE, (Basic_Token tok, ("", d)))));
   432 
   433     val tokens =
   434       (ignored ||
   435         markup Keyword.is_document_heading Markup_Token markup_true ||
   436         markup Keyword.is_document_body Markup_Env_Token markup_true ||
   437         markup Keyword.is_document_raw (Raw_Token o #2) "") >> single ||
   438       command ||
   439       (cmt || other) >> single;
   440 
   441 
   442     (* spans *)
   443 
   444     val is_eof = fn (_, (Basic_Token x, _)) => Token.is_eof x | _ => false;
   445     val stopper = Scan.stopper (K (NONE, (Basic_Token Token.eof, ("", 0)))) is_eof;
   446 
   447     val cmd = Scan.one (is_some o fst);
   448     val non_cmd = Scan.one (is_none o fst andf not o is_eof) >> #2;
   449 
   450     val comments = Scan.many (comment_token o fst o snd);
   451     val blank = Scan.one (blank_token o fst o snd);
   452     val newline = Scan.one (newline_token o fst o snd);
   453     val before_cmd =
   454       Scan.option (newline -- comments) --
   455       Scan.option (newline -- comments) --
   456       Scan.option (blank -- comments) -- cmd;
   457 
   458     val span =
   459       Scan.repeat non_cmd -- cmd --
   460         Scan.repeat (Scan.unless before_cmd non_cmd) --
   461         Scan.option (newline >> (single o snd))
   462       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   463           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   464 
   465     val spans = toks
   466       |> take_suffix Token.is_space |> #1
   467       |> Source.of_list
   468       |> Source.source' 0 Token.stopper (Scan.error (Scan.bulk tokens >> flat))
   469       |> Source.source stopper (Scan.error (Scan.bulk span))
   470       |> Source.exhaust;
   471 
   472 
   473     (* present commands *)
   474 
   475     fun present_command tr span st st' =
   476       Toplevel.setmp_thread_position tr (present_span keywords span st st');
   477 
   478     fun present _ [] = I
   479       | present st (((tr, st'), span) :: rest) = present_command tr span st st' #> present st' rest;
   480   in
   481     if length command_results = length spans then
   482       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   483       |> present Toplevel.toplevel (command_results ~~ spans)
   484       |> present_trailer
   485     else error "Messed-up outer syntax for presentation"
   486   end;
   487 
   488 end;
   489 
   490 
   491 
   492 (** setup default output **)
   493 
   494 (* options *)
   495 
   496 val _ = Theory.setup
   497  (add_option @{binding show_types} (Config.put show_types o boolean) #>
   498   add_option @{binding show_sorts} (Config.put show_sorts o boolean) #>
   499   add_option @{binding show_structs} (Config.put show_structs o boolean) #>
   500   add_option @{binding show_question_marks} (Config.put show_question_marks o boolean) #>
   501   add_option @{binding show_abbrevs} (Config.put show_abbrevs o boolean) #>
   502   add_option @{binding names_long} (Config.put Name_Space.names_long o boolean) #>
   503   add_option @{binding names_short} (Config.put Name_Space.names_short o boolean) #>
   504   add_option @{binding names_unique} (Config.put Name_Space.names_unique o boolean) #>
   505   add_option @{binding eta_contract} (Config.put Syntax_Trans.eta_contract o boolean) #>
   506   add_option @{binding display} (Config.put display o boolean) #>
   507   add_option @{binding break} (Config.put break o boolean) #>
   508   add_option @{binding quotes} (Config.put quotes o boolean) #>
   509   add_option @{binding mode} (add_wrapper o Print_Mode.with_modes o single) #>
   510   add_option @{binding margin} (Config.put margin o integer) #>
   511   add_option @{binding indent} (Config.put indent o integer) #>
   512   add_option @{binding source} (Config.put source o boolean) #>
   513   add_option @{binding goals_limit} (Config.put Goal_Display.goals_limit o integer));
   514 
   515 
   516 (* basic pretty printing *)
   517 
   518 fun perhaps_trim ctxt =
   519   not (Config.get ctxt display) ? Symbol.trim_blanks;
   520 
   521 fun pretty_text ctxt =
   522   Pretty.chunks o map Pretty.str o map (perhaps_trim ctxt) o split_lines;
   523 
   524 fun pretty_text_report ctxt source =
   525  (Context_Position.report ctxt (Input.pos_of source)
   526     (Markup.language_text (Input.is_delimited source));
   527   pretty_text ctxt (Input.source_content source));
   528 
   529 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   530 
   531 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   532 
   533 fun pretty_term_style ctxt (style, t) =
   534   pretty_term ctxt (style t);
   535 
   536 fun pretty_thm_style ctxt (style, th) =
   537   pretty_term ctxt (style (Thm.full_prop_of th));
   538 
   539 fun pretty_term_typ ctxt (style, t) =
   540   let val t' = style t
   541   in pretty_term ctxt (Type.constraint (Term.fastype_of t') t') end;
   542 
   543 fun pretty_term_typeof ctxt (style, t) =
   544   Syntax.pretty_typ ctxt (Term.fastype_of (style t));
   545 
   546 fun pretty_const ctxt c =
   547   let
   548     val t = Const (c, Consts.type_scheme (Proof_Context.consts_of ctxt) c)
   549       handle TYPE (msg, _, _) => error msg;
   550     val ([t'], _) = Variable.import_terms true [t] ctxt;
   551   in pretty_term ctxt t' end;
   552 
   553 fun pretty_abbrev ctxt s =
   554   let
   555     val t = Syntax.read_term (Proof_Context.set_mode Proof_Context.mode_abbrev ctxt) s;
   556     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   557     val (head, args) = Term.strip_comb t;
   558     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   559     val (U, u) = Consts.the_abbreviation (Proof_Context.consts_of ctxt) c
   560       handle TYPE _ => err ();
   561     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   562     val eq = Logic.mk_equals (t, t');
   563     val ctxt' = Variable.auto_fixes eq ctxt;
   564   in Proof_Context.pretty_term_abbrev ctxt' eq end;
   565 
   566 fun pretty_class ctxt =
   567   Pretty.str o Proof_Context.extern_class ctxt o Proof_Context.read_class ctxt;
   568 
   569 fun pretty_type ctxt s =
   570   let val Type (name, _) = Proof_Context.read_type_name {proper = true, strict = false} ctxt s
   571   in Pretty.str (Proof_Context.extern_type ctxt name) end;
   572 
   573 fun pretty_prf full ctxt = Proof_Syntax.pretty_proof_of ctxt full;
   574 
   575 fun pretty_theory ctxt (name, pos) = (Theory.check ctxt (name, pos); Pretty.str name);
   576 
   577 
   578 (* default output *)
   579 
   580 val str_of_source = space_implode " " o Token.unparse_src;
   581 
   582 fun maybe_pretty_source pretty ctxt src xs =
   583   map (pretty ctxt) xs  (*always pretty in order to exhibit errors!*)
   584   |> (if Config.get ctxt source then K [pretty_text ctxt (str_of_source src)] else I);
   585 
   586 fun string_of_margin ctxt = Pretty.string_of_margin (Config.get ctxt margin);
   587 
   588 fun output ctxt prts =
   589   prts
   590   |> Config.get ctxt quotes ? map Pretty.quote
   591   |> (if Config.get ctxt display then
   592         map (Pretty.indent (Config.get ctxt indent) #> string_of_margin ctxt #> Output.output)
   593         #> space_implode "\\isasep\\isanewline%\n"
   594         #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   595       else
   596         map ((if Config.get ctxt break then string_of_margin ctxt else Pretty.str_of) #>
   597           Output.output)
   598         #> space_implode "\\isasep\\isanewline%\n"
   599         #> enclose "\\isa{" "}");
   600 
   601 
   602 
   603 (** concrete antiquotations **)
   604 
   605 (* basic entities *)
   606 
   607 local
   608 
   609 fun basic_entities name scan pretty =
   610   antiquotation name scan (fn {source, context, ...} =>
   611     output context o maybe_pretty_source pretty context source);
   612 
   613 fun basic_entities_style name scan pretty =
   614   antiquotation name scan (fn {source, context, ...} => fn (style, xs) =>
   615     output context
   616       (maybe_pretty_source (fn ctxt => fn x => pretty ctxt (style, x)) context source xs));
   617 
   618 fun basic_entity name scan = basic_entities name (scan >> single);
   619 
   620 in
   621 
   622 val _ = Theory.setup
   623  (basic_entities_style @{binding thm} (Term_Style.parse -- Attrib.thms) pretty_thm_style #>
   624   basic_entity @{binding prop} (Term_Style.parse -- Args.prop) pretty_term_style #>
   625   basic_entity @{binding term} (Term_Style.parse -- Args.term) pretty_term_style #>
   626   basic_entity @{binding term_type} (Term_Style.parse -- Args.term) pretty_term_typ #>
   627   basic_entity @{binding typeof} (Term_Style.parse -- Args.term) pretty_term_typeof #>
   628   basic_entity @{binding const} (Args.const {proper = true, strict = false}) pretty_const #>
   629   basic_entity @{binding abbrev} (Scan.lift Args.name_inner_syntax) pretty_abbrev #>
   630   basic_entity @{binding typ} Args.typ_abbrev Syntax.pretty_typ #>
   631   basic_entity @{binding class} (Scan.lift Args.name_inner_syntax) pretty_class #>
   632   basic_entity @{binding type} (Scan.lift Args.name) pretty_type #>
   633   basic_entity @{binding text} (Scan.lift Args.text_input) pretty_text_report #>
   634   basic_entities @{binding prf} Attrib.thms (pretty_prf false) #>
   635   basic_entities @{binding full_prf} Attrib.thms (pretty_prf true) #>
   636   basic_entity @{binding theory} (Scan.lift (Parse.position Args.name)) pretty_theory);
   637 
   638 end;
   639 
   640 
   641 (* goal state *)
   642 
   643 local
   644 
   645 fun goal_state name main = antiquotation name (Scan.succeed ())
   646   (fn {state, context = ctxt, ...} => fn () =>
   647     output ctxt
   648       [Goal_Display.pretty_goal
   649         (Config.put Goal_Display.show_main_goal main ctxt)
   650         (#goal (Proof.goal (Toplevel.proof_of state)))]);
   651 
   652 in
   653 
   654 val _ = Theory.setup
   655  (goal_state @{binding goals} true #>
   656   goal_state @{binding subgoals} false);
   657 
   658 end;
   659 
   660 
   661 (* embedded lemma *)
   662 
   663 val _ = Theory.setup
   664   (antiquotation @{binding lemma}
   665     (Scan.lift (Scan.ahead Parse.not_eof) -- Args.prop --
   666       Scan.lift (Parse.position (Parse.reserved "by") -- Method.parse -- Scan.option Method.parse))
   667     (fn {source, context = ctxt, ...} => fn ((prop_token, prop), (((_, by_pos), m1), m2)) =>
   668       let
   669         val prop_src = Token.src (Token.name_of_src source) [prop_token];
   670 
   671         val reports = (by_pos, Markup.keyword1) :: maps Method.reports_of (m1 :: the_list m2);
   672         val _ = Context_Position.reports ctxt reports;
   673 
   674         (* FIXME check proof!? *)
   675         val _ = ctxt
   676           |> Proof.theorem NONE (K I) [[(prop, [])]]
   677           |> Proof.global_terminal_proof (m1, m2);
   678       in output ctxt (maybe_pretty_source pretty_term ctxt prop_src [prop]) end));
   679 
   680 
   681 (* verbatim text *)
   682 
   683 fun verbatim_text ctxt =
   684   if Config.get ctxt display then
   685     Latex.output_ascii #>
   686     enclose "\\begin{isabellett}%\n" "%\n\\end{isabellett}"
   687   else
   688     split_lines #>
   689     map (Latex.output_ascii #> enclose "\\isatt{" "}") #>
   690     space_implode "\\isasep\\isanewline%\n";
   691 
   692 val _ =
   693   Theory.setup
   694     (antiquotation @{binding verbatim} (Scan.lift Args.text) (verbatim_text o #context));
   695 
   696 
   697 (* ML text *)
   698 
   699 local
   700 
   701 fun ml_text name ml = antiquotation name (Scan.lift Args.text_input)
   702   (fn {context = ctxt, ...} => fn source =>
   703    (ML_Context.eval_in (SOME ctxt) ML_Compiler.flags (Input.pos_of source) (ml source);
   704     verbatim_text ctxt (Input.source_content source)));
   705 
   706 fun ml_enclose bg en source =
   707   ML_Lex.read bg @ ML_Lex.read_source false source @ ML_Lex.read en;
   708 
   709 in
   710 
   711 val _ = Theory.setup
   712  (ml_text @{binding ML} (ml_enclose "fn _ => (" ");") #>
   713   ml_text @{binding ML_op} (ml_enclose "fn _ => (op " ");") #>
   714   ml_text @{binding ML_type} (ml_enclose "val _ = NONE : (" ") option;") #>
   715   ml_text @{binding ML_structure}
   716     (ml_enclose "functor XXX() = struct structure XX = " " end;") #>
   717 
   718   ml_text @{binding ML_functor}   (* FIXME formal treatment of functor name (!?) *)
   719     (fn source =>
   720       ML_Lex.read ("ML_Env.check_functor " ^
   721         ML_Syntax.print_string (Input.source_content source))) #>
   722 
   723   ml_text @{binding ML_text} (K []));
   724 
   725 end;
   726 
   727 
   728 (* URLs *)
   729 
   730 val _ = Theory.setup
   731   (antiquotation @{binding url} (Scan.lift (Parse.position Parse.name))
   732     (fn {context = ctxt, ...} => fn (name, pos) =>
   733       (Context_Position.reports ctxt [(pos, Markup.language_path), (pos, Markup.url name)];
   734        enclose "\\url{" "}" name)));
   735 
   736 
   737 
   738 (** document commands **)
   739 
   740 fun old_header_command txt =
   741   Toplevel.keep (fn state =>
   742     if Toplevel.is_toplevel state then
   743      (legacy_feature "Obsolete 'header' command -- use 'chapter', 'section' etc. instead";
   744       ignore (output_text state {markdown = false} txt))
   745     else raise Toplevel.UNDEF);
   746 
   747 fun document_command markdown (loc, txt) =
   748   Toplevel.keep (fn state =>
   749     (case loc of
   750       NONE => ignore (output_text state markdown txt)
   751     | SOME (_, pos) =>
   752         error ("Illegal target specification -- not a theory context" ^ Position.here pos))) o
   753   Toplevel.present_local_theory loc (fn state => ignore (output_text state markdown txt));
   754 
   755 end;