src/Pure/library.ML
author wenzelm
Thu Oct 11 19:10:21 2007 +0200 (2007-10-11)
changeset 24979 783bf93c8f92
parent 24864 f33ff5fc1f7e
child 25058 d8d8bac48031
permissions -rw-r--r--
removed obsolete flip;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    67   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68 
    69   (*lists*)
    70   exception UnequalLengths
    71   val single: 'a -> 'a list
    72   val the_single: 'a list -> 'a
    73   val singleton: ('a list -> 'b list) -> 'a -> 'b
    74   val apply: ('a -> 'a) list -> 'a -> 'a
    75   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    76   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    77   val flat: 'a list list -> 'a list
    78   val unflat: 'a list list -> 'b list -> 'b list list
    79   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    80   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    81   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    82   val maps: ('a -> 'b list) -> 'a list -> 'b list
    83   val chop: int -> 'a list -> 'a list * 'a list
    84   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    85   val nth: 'a list -> int -> 'a
    86   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    87   val nth_drop: int -> 'a list -> 'a list
    88   val nth_list: 'a list list -> int -> 'a list
    89   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    90   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val split_last: 'a list -> 'a list * 'a
    92   val find_index: ('a -> bool) -> 'a list -> int
    93   val find_index_eq: ''a -> ''a list -> int
    94   val find_first: ('a -> bool) -> 'a list -> 'a option
    95   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    96   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    97   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    98   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    99   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   101   val ~~ : 'a list * 'b list -> ('a * 'b) list
   102   val split_list: ('a * 'b) list -> 'a list * 'b list
   103   val separate: 'a -> 'a list -> 'a list
   104   val replicate: int -> 'a -> 'a list
   105   val multiply: 'a list -> 'a list list -> 'a list list
   106   val product: 'a list -> 'b list -> ('a * 'b) list
   107   val filter: ('a -> bool) -> 'a list -> 'a list
   108   val filter_out: ('a -> bool) -> 'a list -> 'a list
   109   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   110   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   111   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   112   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   113   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val prefixes1: 'a list -> 'a list list
   115   val prefixes: 'a list -> 'a list list
   116   val suffixes1: 'a list -> 'a list list
   117   val suffixes: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val inc: int ref -> int
   121   val dec: int ref -> int
   122   val upto: int * int -> int list
   123   val downto: int * int -> int list
   124   val radixpand: int * int -> int list
   125   val radixstring: int * string * int -> string
   126   val string_of_int: int -> string
   127   val signed_string_of_int: int -> string
   128   val string_of_indexname: string * int -> string
   129   val read_radix_int: int -> string list -> int * string list
   130   val read_int: string list -> int * string list
   131   val oct_char: string -> string
   132 
   133   (*strings*)
   134   val nth_string: string -> int -> string
   135   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   136   val exists_string: (string -> bool) -> string -> bool
   137   val forall_string: (string -> bool) -> string -> bool
   138   val enclose: string -> string -> string -> string
   139   val unenclose: string -> string
   140   val quote: string -> string
   141   val space_implode: string -> string list -> string
   142   val commas: string list -> string
   143   val commas_quote: string list -> string
   144   val cat_lines: string list -> string
   145   val space_explode: string -> string -> string list
   146   val split_lines: string -> string list
   147   val prefix_lines: string -> string -> string
   148   val untabify: string list -> string list
   149   val prefix: string -> string -> string
   150   val suffix: string -> string -> string
   151   val unprefix: string -> string -> string
   152   val unsuffix: string -> string -> string
   153   val replicate_string: int -> string -> string
   154   val translate_string: (string -> string) -> string -> string
   155 
   156   (*lists as sets -- see also Pure/General/ord_list.ML*)
   157   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   158   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   159   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   160   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   161   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   162   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   163   val mem: ''a * ''a list -> bool
   164   val mem_int: int * int list -> bool
   165   val mem_string: string * string list -> bool
   166   val union: ''a list * ''a list -> ''a list
   167   val union_int: int list * int list -> int list
   168   val union_string: string list * string list -> string list
   169   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   170   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   171   val inter: ''a list * ''a list -> ''a list
   172   val inter_int: int list * int list -> int list
   173   val inter_string: string list * string list -> string list
   174   val subset: ''a list * ''a list -> bool
   175   val subset_int: int list * int list -> bool
   176   val subset_string: string list * string list -> bool
   177   val eq_set: ''a list * ''a list -> bool
   178   val eq_set_string: string list * string list -> bool
   179   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   180   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   181   val \ : ''a list * ''a -> ''a list
   182   val \\ : ''a list * ''a list -> ''a list
   183   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   184   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   185   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   186 
   187   (*lists as multisets*)
   188   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   189   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   190 
   191   (*orders*)
   192   val is_equal: order -> bool
   193   val rev_order: order -> order
   194   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   195   val int_ord: int * int -> order
   196   val string_ord: string * string -> order
   197   val fast_string_ord: string * string -> order
   198   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   199   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   200   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   201   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   202   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   203   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   204   val sort_strings: string list -> string list
   205   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   206 
   207   (*random numbers*)
   208   exception RANDOM
   209   val random: unit -> real
   210   val random_range: int -> int -> int
   211   val one_of: 'a list -> 'a
   212   val frequency: (int * 'a) list -> 'a
   213 
   214   (*misc*)
   215   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   216   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   217   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   218   val gensym: string -> string
   219   type stamp
   220   val stamp: unit -> stamp
   221   type serial
   222   val serial: unit -> serial
   223   val serial_string: unit -> string
   224   structure Object: sig type T end
   225 end;
   226 
   227 signature LIBRARY =
   228 sig
   229   include BASIC_LIBRARY
   230   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   231   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   232   val take: int * 'a list -> 'a list
   233   val drop: int * 'a list -> 'a list
   234   val last_elem: 'a list -> 'a
   235 end;
   236 
   237 structure Library: LIBRARY =
   238 struct
   239 
   240 (* functions *)
   241 
   242 fun undefined _ = raise Match;
   243 
   244 fun I x = x;
   245 fun K x = fn _ => x;
   246 fun curry f x y = f (x, y);
   247 fun uncurry f (x, y) = f x y;
   248 
   249 (*application and structured results -- old version*)
   250 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   251 
   252 (*conditional application*)
   253 fun b ? f = fn x => if b then f x else x;
   254 
   255 (*composition with multiple args*)
   256 fun (f oo g) x y = f (g x y);
   257 fun (f ooo g) x y z = f (g x y z);
   258 fun (f oooo g) x y z w = f (g x y z w);
   259 
   260 (*function exponentiation: f(...(f x)...) with n applications of f*)
   261 fun funpow (0: int) _ x = x
   262   | funpow n f x = funpow (n - 1) f (f x);
   263 
   264 
   265 (* errors *)
   266 
   267 exception SYS_ERROR of string;
   268 fun sys_error msg = raise SYS_ERROR msg;
   269 
   270 exception ERROR of string;
   271 fun error msg = raise ERROR msg;
   272 
   273 fun cat_error "" msg = error msg
   274   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   275 
   276 fun assert_all pred list msg =
   277   let
   278     fun ass [] = ()
   279       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   280   in ass list end;
   281 
   282 
   283 (* pairs *)
   284 
   285 fun pair x y = (x, y);
   286 fun rpair x y = (y, x);
   287 
   288 fun fst (x, y) = x;
   289 fun snd (x, y) = y;
   290 
   291 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   292 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   293 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   294 
   295 fun swap (x, y) = (y, x);
   296 
   297 fun apfst f (x, y) = (f x, y);
   298 fun apsnd f (x, y) = (x, f y);
   299 fun pairself f (x, y) = (f x, f y);
   300 
   301 
   302 (* booleans *)
   303 
   304 (*polymorphic equality*)
   305 fun equal x y = x = y;
   306 fun not_equal x y = x <> y;
   307 
   308 (*combining predicates*)
   309 fun p orf q = fn x => p x orelse q x;
   310 fun p andf q = fn x => p x andalso q x;
   311 
   312 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   313 fun exists (pred: 'a -> bool) : 'a list -> bool =
   314   let fun boolf [] = false
   315         | boolf (x :: xs) = pred x orelse boolf xs
   316   in boolf end;
   317 
   318 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   319 fun forall (pred: 'a -> bool) : 'a list -> bool =
   320   let fun boolf [] = true
   321         | boolf (x :: xs) = pred x andalso boolf xs
   322   in boolf end;
   323 
   324 
   325 (* flags *)
   326 
   327 fun set flag = (flag := true; true);
   328 fun reset flag = (flag := false; false);
   329 fun toggle flag = (flag := not (! flag); ! flag);
   330 
   331 fun change r f = r := f (! r);
   332 
   333 (*temporarily set flag during execution*)
   334 fun setmp_noncritical flag value f x =
   335   let
   336     val orig_value = ! flag;
   337     val _ = flag := value;
   338     val result = Exn.capture f x;
   339     val _ = flag := orig_value;
   340   in Exn.release result end;
   341 
   342 fun setmp flag value f x = NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   343 
   344 
   345 
   346 (** lists **)
   347 
   348 exception UnequalLengths;
   349 
   350 fun single x = [x];
   351 
   352 fun the_single [x] = x
   353   | the_single _ = raise Empty;
   354 
   355 fun singleton f x = the_single (f [x]);
   356 
   357 fun apply [] x = x
   358   | apply (f :: fs) x = apply fs (f x);
   359 
   360 
   361 (* fold -- old versions *)
   362 
   363 (*the following versions of fold are designed to fit nicely with infixes*)
   364 
   365 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   366     for operators that associate to the left (TAIL RECURSIVE)*)
   367 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   368   let fun itl (e, [])  = e
   369         | itl (e, a::l) = itl (f(e, a), l)
   370   in  itl end;
   371 
   372 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   373     for operators that associate to the right (not tail recursive)*)
   374 fun foldr f (l, e) =
   375   let fun itr [] = e
   376         | itr (a::l) = f(a, itr l)
   377   in  itr l  end;
   378 
   379 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   380     for n > 0, operators that associate to the right (not tail recursive)*)
   381 fun foldr1 f [] = raise Empty
   382   | foldr1 f l =
   383       let fun itr [x] = x
   384             | itr (x::l) = f(x, itr l)
   385       in  itr l  end;
   386 
   387 fun foldl_map f =
   388   let
   389     fun fold_aux (x, []) = (x, [])
   390       | fold_aux (x, y :: ys) =
   391           let
   392             val (x', y') = f (x, y);
   393             val (x'', ys') = fold_aux (x', ys);
   394           in (x'', y' :: ys') end;
   395   in fold_aux end;
   396 
   397 
   398 (* basic list functions *)
   399 
   400 fun eq_list eq (list1, list2) =
   401   let
   402     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   403       | eq_lst _ = true;
   404   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   405 
   406 fun maps f [] = []
   407   | maps f (x :: xs) = f x @ maps f xs;
   408 
   409 fun chop (0: int) xs = ([], xs)
   410   | chop _ [] = ([], [])
   411   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   412 
   413 (*take the first n elements from a list*)
   414 fun take (n: int, []) = []
   415   | take (n, x :: xs) =
   416       if n > 0 then x :: take (n - 1, xs) else [];
   417 
   418 (*drop the first n elements from a list*)
   419 fun drop (n: int, []) = []
   420   | drop (n, x :: xs) =
   421       if n > 0 then drop (n - 1, xs) else x :: xs;
   422 
   423 fun dropwhile P [] = []
   424   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   425 
   426 (*return nth element of a list, where 0 designates the first element;
   427   raise Subscript if list too short*)
   428 fun nth xs i = List.nth (xs, i);
   429 
   430 fun nth_list xss i = nth xss i handle Subscript => [];
   431 
   432 fun nth_map 0 f (x :: xs) = f x :: xs
   433   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   434   | nth_map (_: int) _ [] = raise Subscript;
   435 
   436 fun nth_drop n xs =
   437   List.take (xs, n) @ List.drop (xs, n + 1);
   438 
   439 fun map_index f =
   440   let
   441     fun mapp (_: int) [] = []
   442       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   443   in mapp 0 end;
   444 
   445 fun fold_index f =
   446   let
   447     fun fold_aux (_: int) [] y = y
   448       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   449   in fold_aux 0 end;
   450 
   451 val last_elem = List.last;
   452 
   453 (*rear decomposition*)
   454 fun split_last [] = raise Empty
   455   | split_last [x] = ([], x)
   456   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   457 
   458 (*find the position of an element in a list*)
   459 fun find_index pred =
   460   let fun find (_: int) [] = ~1
   461         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   462   in find 0 end;
   463 
   464 fun find_index_eq x = find_index (equal x);
   465 
   466 (*find first element satisfying predicate*)
   467 val find_first = List.find;
   468 
   469 (*get first element by lookup function*)
   470 fun get_first _ [] = NONE
   471   | get_first f (x :: xs) =
   472       (case f x of
   473         NONE => get_first f xs
   474       | some => some);
   475 
   476 fun get_index f =
   477   let
   478     fun get (_: int) [] = NONE
   479       | get i (x :: xs) =
   480           case f x
   481            of NONE => get (i + 1) xs
   482             | SOME y => SOME (i, y)
   483   in get 0 end;
   484 
   485 val flat = List.concat;
   486 
   487 fun unflat (xs :: xss) ys =
   488       let val (ps, qs) = chop (length xs) ys
   489       in ps :: unflat xss qs end
   490   | unflat [] [] = []
   491   | unflat _ _ = raise UnequalLengths;
   492 
   493 fun burrow f xss = unflat xss (f (flat xss));
   494 
   495 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   496 
   497 fun fold_burrow f xss s =
   498   apfst (unflat xss) (f (flat xss) s);
   499 
   500 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   501 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   502   | separate _ xs = xs;
   503 
   504 (*make the list [x, x, ..., x] of length n*)
   505 fun replicate (n: int) x =
   506   let fun rep (0, xs) = xs
   507         | rep (n, xs) = rep (n - 1, x :: xs)
   508   in
   509     if n < 0 then raise Subscript
   510     else rep (n, [])
   511   end;
   512 
   513 fun translate_string f = String.translate (f o String.str);
   514 
   515 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   516 fun multiply [] _ = []
   517   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   518 
   519 (*direct product*)
   520 fun product _ [] = []
   521   | product [] _ = []
   522   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   523 
   524 
   525 (* filter *)
   526 
   527 (*copy the list preserving elements that satisfy the predicate*)
   528 val filter = List.filter;
   529 fun filter_out f = filter (not o f);
   530 val map_filter = List.mapPartial;
   531 
   532 
   533 (* lists of pairs *)
   534 
   535 exception UnequalLengths;
   536 
   537 fun map2 _ [] [] = []
   538   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   539   | map2 _ _ _ = raise UnequalLengths;
   540 
   541 fun fold2 f [] [] z = z
   542   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   543   | fold2 f _ _ _ = raise UnequalLengths;
   544 
   545 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   546   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   547   | zip_options _ [] = []
   548   | zip_options [] _ = raise UnequalLengths;
   549 
   550 (*combine two lists forming a list of pairs:
   551   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   552 fun [] ~~ [] = []
   553   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   554   | _ ~~ _ = raise UnequalLengths;
   555 
   556 (*inverse of ~~; the old 'split':
   557   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   558 val split_list = ListPair.unzip;
   559 
   560 
   561 (* prefixes, suffixes *)
   562 
   563 fun is_prefix _ [] _ = true
   564   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   565   | is_prefix eq _ _ = false;
   566 
   567 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   568    where xi is the first element that does not satisfy the predicate*)
   569 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   570   let fun take (rxs, []) = (rev rxs, [])
   571         | take (rxs, x :: xs) =
   572             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   573   in  take([], xs)  end;
   574 
   575 fun chop_prefix eq ([], ys) = ([], ([], ys))
   576   | chop_prefix eq (xs, []) = ([], (xs, []))
   577   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   578       if eq (x, y) then
   579         let val (ps', xys'') = chop_prefix eq (xs', ys')
   580         in (x :: ps', xys'') end
   581       else ([], (xs, ys));
   582 
   583 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   584    where xi is the last element that does not satisfy the predicate*)
   585 fun take_suffix _ [] = ([], [])
   586   | take_suffix pred (x :: xs) =
   587       (case take_suffix pred xs of
   588         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   589       | (prfx, sffx) => (x :: prfx, sffx));
   590 
   591 fun prefixes1 [] = []
   592   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   593 
   594 fun prefixes xs = [] :: prefixes1 xs;
   595 
   596 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   597 fun suffixes xs = [] :: suffixes1 xs;
   598 
   599 
   600 
   601 (** integers **)
   602 
   603 fun inc i = (i := ! i + (1: int); ! i);
   604 fun dec i = (i := ! i - (1: int); ! i);
   605 
   606 
   607 (* lists of integers *)
   608 
   609 (*make the list [from, from + 1, ..., to]*)
   610 fun ((i: int) upto j) =
   611   if i > j then [] else i :: (i + 1 upto j);
   612 
   613 (*make the list [from, from - 1, ..., to]*)
   614 fun ((i: int) downto j) =
   615   if i < j then [] else i :: (i - 1 downto j);
   616 
   617 
   618 (* convert integers to strings *)
   619 
   620 (*expand the number in the given base;
   621   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   622 fun radixpand (base, num) : int list =
   623   let
   624     fun radix (n, tail) =
   625       if n < base then n :: tail
   626       else radix (n div base, (n mod base) :: tail)
   627   in radix (num, []) end;
   628 
   629 (*expands a number into a string of characters starting from "zerochar";
   630   example: radixstring (2, "0", 8) gives "1000"*)
   631 fun radixstring (base, zerochar, num) =
   632   let val offset = ord zerochar;
   633       fun chrof n = chr (offset + n)
   634   in implode (map chrof (radixpand (base, num))) end;
   635 
   636 
   637 val string_of_int = Int.toString;
   638 
   639 fun signed_string_of_int i =
   640   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   641 
   642 fun string_of_indexname (a, 0) = a
   643   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   644 
   645 
   646 (* read integers *)
   647 
   648 fun read_radix_int radix cs =
   649   let
   650     val zero = ord "0";
   651     val limit = zero + radix;
   652     fun scan (num, []) = (num, [])
   653       | scan (num, c :: cs) =
   654         if zero <= ord c andalso ord c < limit then
   655           scan (radix * num + (ord c - zero), cs)
   656         else (num, c :: cs);
   657   in scan (0, cs) end;
   658 
   659 val read_int = read_radix_int 10;
   660 
   661 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   662 
   663 
   664 
   665 (** strings **)
   666 
   667 (* functions tuned for strings, avoiding explode *)
   668 
   669 fun nth_string str i =
   670   (case try String.substring (str, i, 1) of
   671     SOME s => s
   672   | NONE => raise Subscript);
   673 
   674 fun fold_string f str x0 =
   675   let
   676     val n = size str;
   677     fun iter (x, i) =
   678       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   679   in iter (x0, 0) end;
   680 
   681 fun exists_string pred str =
   682   let
   683     val n = size str;
   684     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   685   in ex 0 end;
   686 
   687 fun forall_string pred = not o exists_string (not o pred);
   688 
   689 (*enclose in brackets*)
   690 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   691 fun unenclose str = String.substring (str, 1, size str - 2);
   692 
   693 (*simple quoting (does not escape special chars)*)
   694 val quote = enclose "\"" "\"";
   695 
   696 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   697 fun space_implode a bs = implode (separate a bs);
   698 
   699 val commas = space_implode ", ";
   700 val commas_quote = commas o map quote;
   701 
   702 (*concatenate messages, one per line, into a string*)
   703 val cat_lines = space_implode "\n";
   704 
   705 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   706 fun space_explode _ "" = []
   707   | space_explode sep s = String.fields (fn c => str c = sep) s;
   708 
   709 val split_lines = space_explode "\n";
   710 
   711 fun prefix_lines "" txt = txt
   712   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   713 
   714 fun untabify chs =
   715   let
   716     val tab_width = 8;
   717 
   718     fun untab pos [] ys = rev ys
   719       | untab pos ("\n" :: xs) ys = untab 0 xs ("\n" :: ys)
   720       | untab pos ("\t" :: xs) ys =
   721           let val d = tab_width - (pos mod tab_width)
   722           in untab (pos + d) xs (funpow d (cons " ") ys) end
   723       | untab pos (c :: xs) ys = untab (pos + 1) xs (c :: ys);
   724   in
   725     if not (exists (fn c => c = "\t") chs) then chs
   726     else untab 0 chs []
   727   end;
   728 
   729 fun prefix prfx s = prfx ^ s;
   730 fun suffix sffx s = s ^ sffx;
   731 
   732 fun unprefix prfx s =
   733   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   734   else raise Fail "unprefix";
   735 
   736 fun unsuffix sffx s =
   737   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   738   else raise Fail "unsuffix";
   739 
   740 fun replicate_string (0: int) _ = ""
   741   | replicate_string 1 a = a
   742   | replicate_string k a =
   743       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   744       else replicate_string (k div 2) (a ^ a) ^ a;
   745 
   746 
   747 
   748 (** lists as sets -- see also Pure/General/ord_list.ML **)
   749 
   750 (*canonical member, insert, remove*)
   751 fun member eq list x =
   752   let
   753     fun memb [] = false
   754       | memb (y :: ys) = eq (x, y) orelse memb ys;
   755   in memb list end;
   756 
   757 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   758 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   759 fun update eq x xs = cons x (remove eq x xs);
   760 
   761 fun subtract eq = fold (remove eq);
   762 
   763 fun merge _ ([], ys) = ys
   764   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   765 
   766 (*old-style infixes*)
   767 fun x mem xs = member (op =) xs x;
   768 fun (x: int) mem_int xs = member (op =) xs x;
   769 fun (x: string) mem_string xs = member (op =) xs x;
   770 
   771 
   772 (*union of sets represented as lists: no repetitions*)
   773 fun xs union [] = xs
   774   | [] union ys = ys
   775   | (x :: xs) union ys = xs union (insert (op =) x ys);
   776 
   777 (*union of sets, optimized version for ints*)
   778 fun (xs:int list) union_int [] = xs
   779   | [] union_int ys = ys
   780   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   781 
   782 (*union of sets, optimized version for strings*)
   783 fun (xs:string list) union_string [] = xs
   784   | [] union_string ys = ys
   785   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   786 
   787 (*generalized union*)
   788 fun gen_union eq (xs, []) = xs
   789   | gen_union eq ([], ys) = ys
   790   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   791 
   792 
   793 (*intersection*)
   794 fun [] inter ys = []
   795   | (x :: xs) inter ys =
   796       if x mem ys then x :: (xs inter ys) else xs inter ys;
   797 
   798 (*intersection, optimized version for ints*)
   799 fun ([]:int list) inter_int ys = []
   800   | (x :: xs) inter_int ys =
   801       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   802 
   803 (*intersection, optimized version for strings *)
   804 fun ([]:string list) inter_string ys = []
   805   | (x :: xs) inter_string ys =
   806       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   807 
   808 (*generalized intersection*)
   809 fun gen_inter eq ([], ys) = []
   810   | gen_inter eq (x::xs, ys) =
   811       if member eq ys x then x :: gen_inter eq (xs, ys)
   812       else gen_inter eq (xs, ys);
   813 
   814 
   815 (*subset*)
   816 fun [] subset ys = true
   817   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   818 
   819 (*subset, optimized version for ints*)
   820 fun ([]: int list) subset_int ys = true
   821   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   822 
   823 (*subset, optimized version for strings*)
   824 fun ([]: string list) subset_string ys = true
   825   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   826 
   827 (*set equality*)
   828 fun eq_set (xs, ys) =
   829   xs = ys orelse (xs subset ys andalso ys subset xs);
   830 
   831 (*set equality for strings*)
   832 fun eq_set_string ((xs: string list), ys) =
   833   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   834 
   835 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   836 
   837 fun gen_eq_set eq (xs, ys) =
   838   eq_list eq (xs, ys) orelse
   839     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   840 
   841 
   842 (*removing an element from a list WITHOUT duplicates*)
   843 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   844   | [] \ x = [];
   845 fun ys \\ xs = foldl (op \) (ys,xs);
   846 
   847 
   848 (*makes a list of the distinct members of the input; preserves order, takes
   849   first of equal elements*)
   850 fun distinct eq lst =
   851   let
   852     fun dist (rev_seen, []) = rev rev_seen
   853       | dist (rev_seen, x :: xs) =
   854           if member eq rev_seen x then dist (rev_seen, xs)
   855           else dist (x :: rev_seen, xs);
   856   in dist ([], lst) end;
   857 
   858 (*returns a list containing all repeated elements exactly once; preserves
   859   order, takes first of equal elements*)
   860 fun duplicates eq lst =
   861   let
   862     fun dups (rev_dups, []) = rev rev_dups
   863       | dups (rev_dups, x :: xs) =
   864           if member eq rev_dups x orelse not (member eq xs x) then
   865             dups (rev_dups, xs)
   866           else dups (x :: rev_dups, xs);
   867   in dups ([], lst) end;
   868 
   869 fun has_duplicates eq =
   870   let
   871     fun dups [] = false
   872       | dups (x :: xs) = member eq xs x orelse dups xs;
   873   in dups end;
   874 
   875 
   876 
   877 (** lists as multisets **)
   878 
   879 fun remove1 _ _ [] = raise Empty
   880   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   881 
   882 fun submultiset _ ([], _)  = true
   883   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   884 
   885 
   886 
   887 (** orders **)
   888 
   889 fun is_equal EQUAL = true
   890   | is_equal _ = false;
   891 
   892 fun rev_order LESS = GREATER
   893   | rev_order EQUAL = EQUAL
   894   | rev_order GREATER = LESS;
   895 
   896 (*assume rel is a linear strict order*)
   897 fun make_ord rel (x, y) =
   898   if rel (x, y) then LESS
   899   else if rel (y, x) then GREATER
   900   else EQUAL;
   901 
   902 val int_ord = Int.compare;
   903 val string_ord = String.compare;
   904 
   905 fun fast_string_ord (s1, s2) =
   906   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   907 
   908 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   909   | option_ord _ (NONE, NONE) = EQUAL
   910   | option_ord _ (NONE, SOME _) = LESS
   911   | option_ord _ (SOME _, NONE) = GREATER;
   912 
   913 (*lexicographic product*)
   914 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   915   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   916 
   917 (*dictionary order -- in general NOT well-founded!*)
   918 fun dict_ord elem_ord (x :: xs, y :: ys) =
   919       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   920   | dict_ord _ ([], []) = EQUAL
   921   | dict_ord _ ([], _ :: _) = LESS
   922   | dict_ord _ (_ :: _, []) = GREATER;
   923 
   924 (*lexicographic product of lists*)
   925 fun list_ord elem_ord (xs, ys) =
   926   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   927 
   928 
   929 (* sorting *)
   930 
   931 (*quicksort -- stable, i.e. does not reorder equal elements*)
   932 fun quicksort unique ord =
   933   let
   934     fun qsort [] = []
   935       | qsort (xs as [_]) = xs
   936       | qsort (xs as [x, y]) =
   937           (case ord (x, y) of
   938             LESS => xs
   939           | EQUAL => if unique then [x] else xs
   940           | GREATER => [y, x])
   941       | qsort xs =
   942           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   943           in qsort lts @ eqs @ qsort gts end
   944     and part _ [] = ([], [], [])
   945       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   946     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   947       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   948       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   949       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   950   in qsort end;
   951 
   952 fun sort ord = quicksort false ord;
   953 fun sort_distinct ord = quicksort true ord;
   954 
   955 val sort_strings = sort string_ord;
   956 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   957 
   958 
   959 
   960 (** random numbers **)
   961 
   962 exception RANDOM;
   963 
   964 fun rmod x y = x - y * Real.realFloor (x / y);
   965 
   966 local
   967   val a = 16807.0;
   968   val m = 2147483647.0;
   969   val random_seed = ref 1.0;
   970 in
   971 
   972 fun random () = CRITICAL (fn () =>
   973   let val r = rmod (a * ! random_seed) m
   974   in (random_seed := r; r) end);
   975 
   976 end;
   977 
   978 fun random_range l h =
   979   if h < l orelse l < 0 then raise RANDOM
   980   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   981 
   982 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   983 
   984 fun frequency xs =
   985   let
   986     val sum = foldl op + (0, map fst xs);
   987     fun pick n ((k: int, x) :: xs) =
   988       if n <= k then x else pick (n - k) xs
   989   in pick (random_range 1 sum) xs end;
   990 
   991 
   992 
   993 (** misc **)
   994 
   995 fun divide_and_conquer decomp x =
   996   let val (ys, recomb) = decomp x
   997   in recomb (map (divide_and_conquer decomp) ys) end;
   998 
   999 
  1000 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1001    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1002 fun partition_list p i j =
  1003   let fun part k xs =
  1004             if k>j then
  1005               (case xs of [] => []
  1006                          | _ => raise Fail "partition_list")
  1007             else
  1008             let val (ns, rest) = List.partition (p k) xs;
  1009             in  ns :: part(k+1)rest  end
  1010   in  part (i: int) end;
  1011 
  1012 fun partition_eq (eq:'a * 'a -> bool) =
  1013   let
  1014     fun part [] = []
  1015       | part (x :: ys) =
  1016           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1017           in (x::xs)::(part xs') end
  1018   in part end;
  1019 
  1020 
  1021 
  1022 (* generating identifiers *)
  1023 
  1024 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1025 local
  1026 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1027 fun gensym_char i =
  1028   if i<26 then chr (ord "A" + i)
  1029   else if i<52 then chr (ord "a" + i - 26)
  1030   else chr (ord "0" + i - 52);
  1031 
  1032 val char_vec = Vector.tabulate (62, gensym_char);
  1033 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1034 
  1035 val gensym_seed = ref (0: int);
  1036 
  1037 in
  1038   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1039 end;
  1040 
  1041 
  1042 (* stamps and serial numbers *)
  1043 
  1044 type stamp = unit ref;
  1045 val stamp: unit -> stamp = ref;
  1046 
  1047 type serial = int;
  1048 local val count = ref (0: int)
  1049 in fun serial () = NAMED_CRITICAL "serial" (fn () => inc count) end;
  1050 
  1051 val serial_string = string_of_int o serial;
  1052 
  1053 
  1054 (* generic objects *)
  1055 
  1056 (*note that the builtin exception datatype may be extended by new
  1057   constructors at any time*)
  1058 structure Object = struct type T = exn end;
  1059 
  1060 end;
  1061 
  1062 structure BasicLibrary: BASIC_LIBRARY = Library;
  1063 open BasicLibrary;