src/HOL/Number_Theory/Euclidean_Algorithm.thy
 author haftmann Sat Jun 27 20:20:34 2015 +0200 (2015-06-27) changeset 60598 78ca5674c66a parent 60582 d694f217ee41 child 60599 f8bb070dc98b permissions -rw-r--r--
rings follow immediately their corresponding semirings
1 (* Author: Manuel Eberl *)
3 section \<open>Abstract euclidean algorithm\<close>
5 theory Euclidean_Algorithm
6 imports Complex_Main "~~/src/HOL/Library/Polynomial"
7 begin
9 text \<open>
10   A Euclidean semiring is a semiring upon which the Euclidean algorithm can be
11   implemented. It must provide:
12   \begin{itemize}
13   \item division with remainder
14   \item a size function such that @{term "size (a mod b) < size b"}
15         for any @{term "b \<noteq> 0"}
16   \item a normalization factor such that two associated numbers are equal iff
17         they are the same when divd by their normalization factors.
18   \end{itemize}
19   The existence of these functions makes it possible to derive gcd and lcm functions
20   for any Euclidean semiring.
21 \<close>
22 class euclidean_semiring = semiring_div +
23   fixes euclidean_size :: "'a \<Rightarrow> nat"
24   fixes normalization_factor :: "'a \<Rightarrow> 'a"
25   assumes mod_size_less:
26     "b \<noteq> 0 \<Longrightarrow> \<not> b dvd a \<Longrightarrow> euclidean_size (a mod b) < euclidean_size b"
27   assumes size_mult_mono:
28     "b \<noteq> 0 \<Longrightarrow> euclidean_size (a * b) \<ge> euclidean_size a"
29   assumes normalization_factor_is_unit [intro,simp]:
30     "a \<noteq> 0 \<Longrightarrow> is_unit (normalization_factor a)"
31   assumes normalization_factor_mult: "normalization_factor (a * b) =
32     normalization_factor a * normalization_factor b"
33   assumes normalization_factor_unit: "is_unit a \<Longrightarrow> normalization_factor a = a"
34   assumes normalization_factor_0 [simp]: "normalization_factor 0 = 0"
35 begin
37 lemma normalization_factor_dvd [simp]:
38   "a \<noteq> 0 \<Longrightarrow> normalization_factor a dvd b"
39   by (rule unit_imp_dvd, simp)
41 lemma normalization_factor_1 [simp]:
42   "normalization_factor 1 = 1"
43   by (simp add: normalization_factor_unit)
45 lemma normalization_factor_0_iff [simp]:
46   "normalization_factor a = 0 \<longleftrightarrow> a = 0"
47 proof
48   assume "normalization_factor a = 0"
49   hence "\<not> is_unit (normalization_factor a)"
50     by simp
51   then show "a = 0" by auto
52 qed simp
54 lemma normalization_factor_pow:
55   "normalization_factor (a ^ n) = normalization_factor a ^ n"
56   by (induct n) (simp_all add: normalization_factor_mult power_Suc2)
58 lemma normalization_correct [simp]:
59   "normalization_factor (a div normalization_factor a) = (if a = 0 then 0 else 1)"
60 proof (cases "a = 0", simp)
61   assume "a \<noteq> 0"
62   let ?nf = "normalization_factor"
63   from normalization_factor_is_unit[OF \<open>a \<noteq> 0\<close>] have "?nf a \<noteq> 0"
64     by auto
65   have "?nf (a div ?nf a) * ?nf (?nf a) = ?nf (a div ?nf a * ?nf a)"
66     by (simp add: normalization_factor_mult)
67   also have "a div ?nf a * ?nf a = a" using \<open>a \<noteq> 0\<close>
68     by simp
69   also have "?nf (?nf a) = ?nf a" using \<open>a \<noteq> 0\<close>
70     normalization_factor_is_unit normalization_factor_unit by simp
71   finally have "normalization_factor (a div normalization_factor a) = 1"
72     using \<open>?nf a \<noteq> 0\<close> by (metis div_mult_self2_is_id div_self)
73   with \<open>a \<noteq> 0\<close> show ?thesis by simp
74 qed
76 lemma normalization_0_iff [simp]:
77   "a div normalization_factor a = 0 \<longleftrightarrow> a = 0"
78   by (cases "a = 0", simp, subst unit_eq_div1, blast, simp)
80 lemma mult_div_normalization [simp]:
81   "b * (1 div normalization_factor a) = b div normalization_factor a"
82   by (cases "a = 0") simp_all
84 lemma associated_iff_normed_eq:
85   "associated a b \<longleftrightarrow> a div normalization_factor a = b div normalization_factor b"
86 proof (cases "b = 0", simp, cases "a = 0", metis associated_0(1) normalization_0_iff, rule iffI)
87   let ?nf = normalization_factor
88   assume "a \<noteq> 0" "b \<noteq> 0" "a div ?nf a = b div ?nf b"
89   hence "a = b * (?nf a div ?nf b)"
90     apply (subst (asm) unit_eq_div1, blast, subst (asm) unit_div_commute, blast)
91     apply (subst div_mult_swap, simp, simp)
92     done
93   with \<open>a \<noteq> 0\<close> \<open>b \<noteq> 0\<close> have "\<exists>c. is_unit c \<and> a = c * b"
94     by (intro exI[of _ "?nf a div ?nf b"], force simp: mult_ac)
95   then obtain c where "is_unit c" and "a = c * b" by blast
96   then show "associated a b" by (rule is_unit_associatedI)
97 next
98   let ?nf = normalization_factor
99   assume "a \<noteq> 0" "b \<noteq> 0" "associated a b"
100   then obtain c where "is_unit c" and "a = c * b" by (blast elim: associated_is_unitE)
101   then show "a div ?nf a = b div ?nf b"
102     apply (simp only: \<open>a = c * b\<close> normalization_factor_mult normalization_factor_unit)
103     apply (rule div_mult_mult1, force)
104     done
105   qed
107 lemma normed_associated_imp_eq:
108   "associated a b \<Longrightarrow> normalization_factor a \<in> {0, 1} \<Longrightarrow> normalization_factor b \<in> {0, 1} \<Longrightarrow> a = b"
109   by (simp add: associated_iff_normed_eq, elim disjE, simp_all)
111 lemma normed_dvd [iff]:
112   "a div normalization_factor a dvd a"
113 proof (cases "a = 0")
114   case True then show ?thesis by simp
115 next
116   case False
117   then have "a = a div normalization_factor a * normalization_factor a"
118     by (auto intro: unit_div_mult_self)
119   then show ?thesis ..
120 qed
122 lemma dvd_normed [iff]:
123   "a dvd a div normalization_factor a"
124 proof (cases "a = 0")
125   case True then show ?thesis by simp
126 next
127   case False
128   then have "a div normalization_factor a = a * (1 div normalization_factor a)"
129     by (auto intro: unit_mult_div_div)
130   then show ?thesis ..
131 qed
133 lemma associated_normed:
134   "associated (a div normalization_factor a) a"
135   by (rule associatedI) simp_all
137 lemma normalization_factor_dvd' [simp]:
138   "normalization_factor a dvd a"
139   by (cases "a = 0", simp_all)
141 lemmas normalization_factor_dvd_iff [simp] =
142   unit_dvd_iff [OF normalization_factor_is_unit]
144 lemma euclidean_division:
145   fixes a :: 'a and b :: 'a
146   assumes "b \<noteq> 0" and "\<not> b dvd a"
147   obtains s and t where "a = s * b + t"
148     and "euclidean_size t < euclidean_size b"
149 proof -
150   from div_mod_equality [of a b 0]
151      have "a = a div b * b + a mod b" by simp
152   with that and assms show ?thesis by (auto simp add: mod_size_less)
153 qed
155 lemma dvd_euclidean_size_eq_imp_dvd:
156   assumes "a \<noteq> 0" and b_dvd_a: "b dvd a" and size_eq: "euclidean_size a = euclidean_size b"
157   shows "a dvd b"
158 proof (rule ccontr)
159   assume "\<not> a dvd b"
160   then have "b mod a \<noteq> 0" by (simp add: mod_eq_0_iff_dvd)
161   from b_dvd_a have b_dvd_mod: "b dvd b mod a" by (simp add: dvd_mod_iff)
162   from b_dvd_mod obtain c where "b mod a = b * c" unfolding dvd_def by blast
163     with \<open>b mod a \<noteq> 0\<close> have "c \<noteq> 0" by auto
164   with \<open>b mod a = b * c\<close> have "euclidean_size (b mod a) \<ge> euclidean_size b"
165       using size_mult_mono by force
166   moreover from \<open>\<not> a dvd b\<close> and \<open>a \<noteq> 0\<close>
167   have "euclidean_size (b mod a) < euclidean_size a"
168       using mod_size_less by blast
169   ultimately show False using size_eq by simp
170 qed
172 function gcd_eucl :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
173 where
174   "gcd_eucl a b = (if b = 0 then a div normalization_factor a
175     else if b dvd a then b div normalization_factor b
176     else gcd_eucl b (a mod b))"
177   by pat_completeness simp
178 termination
179   by (relation "measure (euclidean_size \<circ> snd)") (simp_all add: mod_size_less)
181 declare gcd_eucl.simps [simp del]
183 lemma gcd_eucl_induct [case_names zero mod]:
184   assumes H1: "\<And>b. P b 0"
185   and H2: "\<And>a b. b \<noteq> 0 \<Longrightarrow> P b (a mod b) \<Longrightarrow> P a b"
186   shows "P a b"
187 proof (induct a b rule: gcd_eucl.induct)
188   case ("1" a b)
189   show ?case
190   proof (cases "b = 0")
191     case True then show "P a b" by simp (rule H1)
192   next
193     case False
194     have "P b (a mod b)"
195     proof (cases "b dvd a")
196       case False with \<open>b \<noteq> 0\<close> show "P b (a mod b)"
197         by (rule "1.hyps")
198     next
199       case True then have "a mod b = 0"
200         by (simp add: mod_eq_0_iff_dvd)
201       then show "P b (a mod b)" by simp (rule H1)
202     qed
203     with \<open>b \<noteq> 0\<close> show "P a b"
204       by (blast intro: H2)
205   qed
206 qed
208 definition lcm_eucl :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
209 where
210   "lcm_eucl a b = a * b div (gcd_eucl a b * normalization_factor (a * b))"
212 definition Lcm_eucl :: "'a set \<Rightarrow> 'a" -- \<open>
213   Somewhat complicated definition of Lcm that has the advantage of working
214   for infinite sets as well\<close>
215 where
216   "Lcm_eucl A = (if \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) then
217      let l = SOME l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l =
218        (LEAST n. \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n)
219        in l div normalization_factor l
220       else 0)"
222 definition Gcd_eucl :: "'a set \<Rightarrow> 'a"
223 where
224   "Gcd_eucl A = Lcm_eucl {d. \<forall>a\<in>A. d dvd a}"
226 lemma gcd_eucl_0:
227   "gcd_eucl a 0 = a div normalization_factor a"
228   by (simp add: gcd_eucl.simps [of a 0])
230 lemma gcd_eucl_0_left:
231   "gcd_eucl 0 a = a div normalization_factor a"
232   by (simp add: gcd_eucl.simps [of 0 a])
234 lemma gcd_eucl_non_0:
235   "b \<noteq> 0 \<Longrightarrow> gcd_eucl a b = gcd_eucl b (a mod b)"
236   by (cases "b dvd a")
237     (simp_all add: gcd_eucl.simps [of a b] gcd_eucl.simps [of b 0])
239 lemma gcd_eucl_code [code]:
240   "gcd_eucl a b = (if b = 0 then a div normalization_factor a else gcd_eucl b (a mod b))"
241   by (auto simp add: gcd_eucl_non_0 gcd_eucl_0 gcd_eucl_0_left)
243 end
245 class euclidean_ring = euclidean_semiring + idom
246 begin
248 function euclid_ext :: "'a \<Rightarrow> 'a \<Rightarrow> 'a \<times> 'a \<times> 'a" where
249   "euclid_ext a b =
250      (if b = 0 then
251         let c = 1 div normalization_factor a in (c, 0, a * c)
252       else if b dvd a then
253         let c = 1 div normalization_factor b in (0, c, b * c)
254       else
255         case euclid_ext b (a mod b) of
256             (s, t, c) \<Rightarrow> (t, s - t * (a div b), c))"
257   by pat_completeness simp
258 termination
259   by (relation "measure (euclidean_size \<circ> snd)") (simp_all add: mod_size_less)
261 declare euclid_ext.simps [simp del]
263 lemma euclid_ext_0:
264   "euclid_ext a 0 = (1 div normalization_factor a, 0, a div normalization_factor a)"
265   by (simp add: euclid_ext.simps [of a 0])
267 lemma euclid_ext_left_0:
268   "euclid_ext 0 a = (0, 1 div normalization_factor a, a div normalization_factor a)"
269   by (simp add: euclid_ext.simps [of 0 a])
271 lemma euclid_ext_non_0:
272   "b \<noteq> 0 \<Longrightarrow> euclid_ext a b = (case euclid_ext b (a mod b) of
273     (s, t, c) \<Rightarrow> (t, s - t * (a div b), c))"
274   by (cases "b dvd a")
275     (simp_all add: euclid_ext.simps [of a b] euclid_ext.simps [of b 0])
277 lemma euclid_ext_code [code]:
278   "euclid_ext a b = (if b = 0 then (1 div normalization_factor a, 0, a div normalization_factor a)
279     else let (s, t, c) = euclid_ext b (a mod b) in  (t, s - t * (a div b), c))"
280   by (simp add: euclid_ext.simps [of a b] euclid_ext.simps [of b 0])
282 lemma euclid_ext_correct:
283   "case euclid_ext a b of (s, t, c) \<Rightarrow> s * a + t * b = c"
284 proof (induct a b rule: gcd_eucl_induct)
285   case (zero a) then show ?case
286     by (simp add: euclid_ext_0 ac_simps)
287 next
288   case (mod a b)
289   obtain s t c where stc: "euclid_ext b (a mod b) = (s,t,c)"
290     by (cases "euclid_ext b (a mod b)") blast
291   with mod have "c = s * b + t * (a mod b)" by simp
292   also have "... = t * ((a div b) * b + a mod b) + (s - t * (a div b)) * b"
293     by (simp add: algebra_simps)
294   also have "(a div b) * b + a mod b = a" using mod_div_equality .
295   finally show ?case
296     by (subst euclid_ext.simps) (simp add: stc mod ac_simps)
297 qed
299 definition euclid_ext' :: "'a \<Rightarrow> 'a \<Rightarrow> 'a \<times> 'a"
300 where
301   "euclid_ext' a b = (case euclid_ext a b of (s, t, _) \<Rightarrow> (s, t))"
303 lemma euclid_ext'_0: "euclid_ext' a 0 = (1 div normalization_factor a, 0)"
304   by (simp add: euclid_ext'_def euclid_ext_0)
306 lemma euclid_ext'_left_0: "euclid_ext' 0 a = (0, 1 div normalization_factor a)"
307   by (simp add: euclid_ext'_def euclid_ext_left_0)
309 lemma euclid_ext'_non_0: "b \<noteq> 0 \<Longrightarrow> euclid_ext' a b = (snd (euclid_ext' b (a mod b)),
310   fst (euclid_ext' b (a mod b)) - snd (euclid_ext' b (a mod b)) * (a div b))"
311   by (simp add: euclid_ext'_def euclid_ext_non_0 split_def)
313 end
315 class euclidean_semiring_gcd = euclidean_semiring + gcd + Gcd +
316   assumes gcd_gcd_eucl: "gcd = gcd_eucl" and lcm_lcm_eucl: "lcm = lcm_eucl"
317   assumes Gcd_Gcd_eucl: "Gcd = Gcd_eucl" and Lcm_Lcm_eucl: "Lcm = Lcm_eucl"
318 begin
320 lemma gcd_0_left:
321   "gcd 0 a = a div normalization_factor a"
322   unfolding gcd_gcd_eucl by (fact gcd_eucl_0_left)
324 lemma gcd_0:
325   "gcd a 0 = a div normalization_factor a"
326   unfolding gcd_gcd_eucl by (fact gcd_eucl_0)
328 lemma gcd_non_0:
329   "b \<noteq> 0 \<Longrightarrow> gcd a b = gcd b (a mod b)"
330   unfolding gcd_gcd_eucl by (fact gcd_eucl_non_0)
332 lemma gcd_dvd1 [iff]: "gcd a b dvd a"
333   and gcd_dvd2 [iff]: "gcd a b dvd b"
334   by (induct a b rule: gcd_eucl_induct)
335     (simp_all add: gcd_0 gcd_non_0 dvd_mod_iff)
337 lemma dvd_gcd_D1: "k dvd gcd m n \<Longrightarrow> k dvd m"
338   by (rule dvd_trans, assumption, rule gcd_dvd1)
340 lemma dvd_gcd_D2: "k dvd gcd m n \<Longrightarrow> k dvd n"
341   by (rule dvd_trans, assumption, rule gcd_dvd2)
343 lemma gcd_greatest:
344   fixes k a b :: 'a
345   shows "k dvd a \<Longrightarrow> k dvd b \<Longrightarrow> k dvd gcd a b"
346 proof (induct a b rule: gcd_eucl_induct)
347   case (zero a) from zero(1) show ?case by (rule dvd_trans) (simp add: gcd_0)
348 next
349   case (mod a b)
350   then show ?case
351     by (simp add: gcd_non_0 dvd_mod_iff)
352 qed
354 lemma dvd_gcd_iff:
355   "k dvd gcd a b \<longleftrightarrow> k dvd a \<and> k dvd b"
356   by (blast intro!: gcd_greatest intro: dvd_trans)
358 lemmas gcd_greatest_iff = dvd_gcd_iff
360 lemma gcd_zero [simp]:
361   "gcd a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
362   by (metis dvd_0_left dvd_refl gcd_dvd1 gcd_dvd2 gcd_greatest)+
364 lemma normalization_factor_gcd [simp]:
365   "normalization_factor (gcd a b) = (if a = 0 \<and> b = 0 then 0 else 1)" (is "?f a b = ?g a b")
366   by (induct a b rule: gcd_eucl_induct)
367     (auto simp add: gcd_0 gcd_non_0)
369 lemma gcdI:
370   "k dvd a \<Longrightarrow> k dvd b \<Longrightarrow> (\<And>l. l dvd a \<Longrightarrow> l dvd b \<Longrightarrow> l dvd k)
371     \<Longrightarrow> normalization_factor k = (if k = 0 then 0 else 1) \<Longrightarrow> k = gcd a b"
372   by (intro normed_associated_imp_eq) (auto simp: associated_def intro: gcd_greatest)
374 sublocale gcd!: abel_semigroup gcd
375 proof
376   fix a b c
377   show "gcd (gcd a b) c = gcd a (gcd b c)"
378   proof (rule gcdI)
379     have "gcd (gcd a b) c dvd gcd a b" "gcd a b dvd a" by simp_all
380     then show "gcd (gcd a b) c dvd a" by (rule dvd_trans)
381     have "gcd (gcd a b) c dvd gcd a b" "gcd a b dvd b" by simp_all
382     hence "gcd (gcd a b) c dvd b" by (rule dvd_trans)
383     moreover have "gcd (gcd a b) c dvd c" by simp
384     ultimately show "gcd (gcd a b) c dvd gcd b c"
385       by (rule gcd_greatest)
386     show "normalization_factor (gcd (gcd a b) c) =  (if gcd (gcd a b) c = 0 then 0 else 1)"
387       by auto
388     fix l assume "l dvd a" and "l dvd gcd b c"
389     with dvd_trans[OF _ gcd_dvd1] and dvd_trans[OF _ gcd_dvd2]
390       have "l dvd b" and "l dvd c" by blast+
391     with \<open>l dvd a\<close> show "l dvd gcd (gcd a b) c"
392       by (intro gcd_greatest)
393   qed
394 next
395   fix a b
396   show "gcd a b = gcd b a"
397     by (rule gcdI) (simp_all add: gcd_greatest)
398 qed
400 lemma gcd_unique: "d dvd a \<and> d dvd b \<and>
401     normalization_factor d = (if d = 0 then 0 else 1) \<and>
402     (\<forall>e. e dvd a \<and> e dvd b \<longrightarrow> e dvd d) \<longleftrightarrow> d = gcd a b"
403   by (rule, auto intro: gcdI simp: gcd_greatest)
405 lemma gcd_dvd_prod: "gcd a b dvd k * b"
406   using mult_dvd_mono [of 1] by auto
408 lemma gcd_1_left [simp]: "gcd 1 a = 1"
409   by (rule sym, rule gcdI, simp_all)
411 lemma gcd_1 [simp]: "gcd a 1 = 1"
412   by (rule sym, rule gcdI, simp_all)
414 lemma gcd_proj2_if_dvd:
415   "b dvd a \<Longrightarrow> gcd a b = b div normalization_factor b"
416   by (cases "b = 0", simp_all add: dvd_eq_mod_eq_0 gcd_non_0 gcd_0)
418 lemma gcd_proj1_if_dvd:
419   "a dvd b \<Longrightarrow> gcd a b = a div normalization_factor a"
420   by (subst gcd.commute, simp add: gcd_proj2_if_dvd)
422 lemma gcd_proj1_iff: "gcd m n = m div normalization_factor m \<longleftrightarrow> m dvd n"
423 proof
424   assume A: "gcd m n = m div normalization_factor m"
425   show "m dvd n"
426   proof (cases "m = 0")
427     assume [simp]: "m \<noteq> 0"
428     from A have B: "m = gcd m n * normalization_factor m"
429       by (simp add: unit_eq_div2)
430     show ?thesis by (subst B, simp add: mult_unit_dvd_iff)
431   qed (insert A, simp)
432 next
433   assume "m dvd n"
434   then show "gcd m n = m div normalization_factor m" by (rule gcd_proj1_if_dvd)
435 qed
437 lemma gcd_proj2_iff: "gcd m n = n div normalization_factor n \<longleftrightarrow> n dvd m"
438   by (subst gcd.commute, simp add: gcd_proj1_iff)
440 lemma gcd_mod1 [simp]:
441   "gcd (a mod b) b = gcd a b"
442   by (rule gcdI, metis dvd_mod_iff gcd_dvd1 gcd_dvd2, simp_all add: gcd_greatest dvd_mod_iff)
444 lemma gcd_mod2 [simp]:
445   "gcd a (b mod a) = gcd a b"
446   by (rule gcdI, simp, metis dvd_mod_iff gcd_dvd1 gcd_dvd2, simp_all add: gcd_greatest dvd_mod_iff)
448 lemma gcd_mult_distrib':
449   "c div normalization_factor c * gcd a b = gcd (c * a) (c * b)"
450 proof (cases "c = 0")
451   case True then show ?thesis by (simp_all add: gcd_0)
452 next
453   case False then have [simp]: "is_unit (normalization_factor c)" by simp
454   show ?thesis
455   proof (induct a b rule: gcd_eucl_induct)
456     case (zero a) show ?case
457     proof (cases "a = 0")
458       case True then show ?thesis by (simp add: gcd_0)
459     next
460       case False then have "is_unit (normalization_factor a)" by simp
461       then show ?thesis
462         by (simp add: gcd_0 unit_div_commute unit_div_mult_swap normalization_factor_mult is_unit_div_mult2_eq)
463     qed
464     case (mod a b)
465     then show ?case by (simp add: mult_mod_right gcd.commute)
466   qed
467 qed
469 lemma gcd_mult_distrib:
470   "k * gcd a b = gcd (k*a) (k*b) * normalization_factor k"
471 proof-
472   let ?nf = "normalization_factor"
473   from gcd_mult_distrib'
474     have "gcd (k*a) (k*b) = k div ?nf k * gcd a b" ..
475   also have "... = k * gcd a b div ?nf k"
476     by (metis dvd_div_mult dvd_eq_mod_eq_0 mod_0 normalization_factor_dvd)
477   finally show ?thesis
478     by simp
479 qed
481 lemma euclidean_size_gcd_le1 [simp]:
482   assumes "a \<noteq> 0"
483   shows "euclidean_size (gcd a b) \<le> euclidean_size a"
484 proof -
485    have "gcd a b dvd a" by (rule gcd_dvd1)
486    then obtain c where A: "a = gcd a b * c" unfolding dvd_def by blast
487    with \<open>a \<noteq> 0\<close> show ?thesis by (subst (2) A, intro size_mult_mono) auto
488 qed
490 lemma euclidean_size_gcd_le2 [simp]:
491   "b \<noteq> 0 \<Longrightarrow> euclidean_size (gcd a b) \<le> euclidean_size b"
492   by (subst gcd.commute, rule euclidean_size_gcd_le1)
494 lemma euclidean_size_gcd_less1:
495   assumes "a \<noteq> 0" and "\<not>a dvd b"
496   shows "euclidean_size (gcd a b) < euclidean_size a"
497 proof (rule ccontr)
498   assume "\<not>euclidean_size (gcd a b) < euclidean_size a"
499   with \<open>a \<noteq> 0\<close> have "euclidean_size (gcd a b) = euclidean_size a"
500     by (intro le_antisym, simp_all)
501   with assms have "a dvd gcd a b" by (auto intro: dvd_euclidean_size_eq_imp_dvd)
502   hence "a dvd b" using dvd_gcd_D2 by blast
503   with \<open>\<not>a dvd b\<close> show False by contradiction
504 qed
506 lemma euclidean_size_gcd_less2:
507   assumes "b \<noteq> 0" and "\<not>b dvd a"
508   shows "euclidean_size (gcd a b) < euclidean_size b"
509   using assms by (subst gcd.commute, rule euclidean_size_gcd_less1)
511 lemma gcd_mult_unit1: "is_unit a \<Longrightarrow> gcd (b * a) c = gcd b c"
512   apply (rule gcdI)
513   apply (rule dvd_trans, rule gcd_dvd1, simp add: unit_simps)
514   apply (rule gcd_dvd2)
515   apply (rule gcd_greatest, simp add: unit_simps, assumption)
516   apply (subst normalization_factor_gcd, simp add: gcd_0)
517   done
519 lemma gcd_mult_unit2: "is_unit a \<Longrightarrow> gcd b (c * a) = gcd b c"
520   by (subst gcd.commute, subst gcd_mult_unit1, assumption, rule gcd.commute)
522 lemma gcd_div_unit1: "is_unit a \<Longrightarrow> gcd (b div a) c = gcd b c"
523   by (erule is_unitE [of _ b]) (simp add: gcd_mult_unit1)
525 lemma gcd_div_unit2: "is_unit a \<Longrightarrow> gcd b (c div a) = gcd b c"
526   by (erule is_unitE [of _ c]) (simp add: gcd_mult_unit2)
528 lemma gcd_idem: "gcd a a = a div normalization_factor a"
529   by (cases "a = 0") (simp add: gcd_0_left, rule sym, rule gcdI, simp_all)
531 lemma gcd_right_idem: "gcd (gcd a b) b = gcd a b"
532   apply (rule gcdI)
533   apply (simp add: ac_simps)
534   apply (rule gcd_dvd2)
535   apply (rule gcd_greatest, erule (1) gcd_greatest, assumption)
536   apply simp
537   done
539 lemma gcd_left_idem: "gcd a (gcd a b) = gcd a b"
540   apply (rule gcdI)
541   apply simp
542   apply (rule dvd_trans, rule gcd_dvd2, rule gcd_dvd2)
543   apply (rule gcd_greatest, assumption, erule gcd_greatest, assumption)
544   apply simp
545   done
547 lemma comp_fun_idem_gcd: "comp_fun_idem gcd"
548 proof
549   fix a b show "gcd a \<circ> gcd b = gcd b \<circ> gcd a"
550     by (simp add: fun_eq_iff ac_simps)
551 next
552   fix a show "gcd a \<circ> gcd a = gcd a"
553     by (simp add: fun_eq_iff gcd_left_idem)
554 qed
556 lemma coprime_dvd_mult:
557   assumes "gcd c b = 1" and "c dvd a * b"
558   shows "c dvd a"
559 proof -
560   let ?nf = "normalization_factor"
561   from assms gcd_mult_distrib [of a c b]
562     have A: "a = gcd (a * c) (a * b) * ?nf a" by simp
563   from \<open>c dvd a * b\<close> show ?thesis by (subst A, simp_all add: gcd_greatest)
564 qed
566 lemma coprime_dvd_mult_iff:
567   "gcd c b = 1 \<Longrightarrow> (c dvd a * b) = (c dvd a)"
568   by (rule, rule coprime_dvd_mult, simp_all)
570 lemma gcd_dvd_antisym:
571   "gcd a b dvd gcd c d \<Longrightarrow> gcd c d dvd gcd a b \<Longrightarrow> gcd a b = gcd c d"
572 proof (rule gcdI)
573   assume A: "gcd a b dvd gcd c d" and B: "gcd c d dvd gcd a b"
574   have "gcd c d dvd c" by simp
575   with A show "gcd a b dvd c" by (rule dvd_trans)
576   have "gcd c d dvd d" by simp
577   with A show "gcd a b dvd d" by (rule dvd_trans)
578   show "normalization_factor (gcd a b) = (if gcd a b = 0 then 0 else 1)"
579     by simp
580   fix l assume "l dvd c" and "l dvd d"
581   hence "l dvd gcd c d" by (rule gcd_greatest)
582   from this and B show "l dvd gcd a b" by (rule dvd_trans)
583 qed
585 lemma gcd_mult_cancel:
586   assumes "gcd k n = 1"
587   shows "gcd (k * m) n = gcd m n"
588 proof (rule gcd_dvd_antisym)
589   have "gcd (gcd (k * m) n) k = gcd (gcd k n) (k * m)" by (simp add: ac_simps)
590   also note \<open>gcd k n = 1\<close>
591   finally have "gcd (gcd (k * m) n) k = 1" by simp
592   hence "gcd (k * m) n dvd m" by (rule coprime_dvd_mult, simp add: ac_simps)
593   moreover have "gcd (k * m) n dvd n" by simp
594   ultimately show "gcd (k * m) n dvd gcd m n" by (rule gcd_greatest)
595   have "gcd m n dvd (k * m)" and "gcd m n dvd n" by simp_all
596   then show "gcd m n dvd gcd (k * m) n" by (rule gcd_greatest)
597 qed
599 lemma coprime_crossproduct:
600   assumes [simp]: "gcd a d = 1" "gcd b c = 1"
601   shows "associated (a * c) (b * d) \<longleftrightarrow> associated a b \<and> associated c d" (is "?lhs \<longleftrightarrow> ?rhs")
602 proof
603   assume ?rhs then show ?lhs unfolding associated_def by (fast intro: mult_dvd_mono)
604 next
605   assume ?lhs
606   from \<open>?lhs\<close> have "a dvd b * d" unfolding associated_def by (metis dvd_mult_left)
607   hence "a dvd b" by (simp add: coprime_dvd_mult_iff)
608   moreover from \<open>?lhs\<close> have "b dvd a * c" unfolding associated_def by (metis dvd_mult_left)
609   hence "b dvd a" by (simp add: coprime_dvd_mult_iff)
610   moreover from \<open>?lhs\<close> have "c dvd d * b"
611     unfolding associated_def by (auto dest: dvd_mult_right simp add: ac_simps)
612   hence "c dvd d" by (simp add: coprime_dvd_mult_iff gcd.commute)
613   moreover from \<open>?lhs\<close> have "d dvd c * a"
614     unfolding associated_def by (auto dest: dvd_mult_right simp add: ac_simps)
615   hence "d dvd c" by (simp add: coprime_dvd_mult_iff gcd.commute)
616   ultimately show ?rhs unfolding associated_def by simp
617 qed
619 lemma gcd_add1 [simp]:
620   "gcd (m + n) n = gcd m n"
621   by (cases "n = 0", simp_all add: gcd_non_0)
623 lemma gcd_add2 [simp]:
624   "gcd m (m + n) = gcd m n"
625   using gcd_add1 [of n m] by (simp add: ac_simps)
628   "gcd m (k * m + n) = gcd m n"
629 proof -
630   have "gcd m ((k * m + n) mod m) = gcd m (k * m + n)"
631     by (fact gcd_mod2)
632   then show ?thesis by simp
633 qed
635 lemma coprimeI: "(\<And>l. \<lbrakk>l dvd a; l dvd b\<rbrakk> \<Longrightarrow> l dvd 1) \<Longrightarrow> gcd a b = 1"
636   by (rule sym, rule gcdI, simp_all)
638 lemma coprime: "gcd a b = 1 \<longleftrightarrow> (\<forall>d. d dvd a \<and> d dvd b \<longleftrightarrow> is_unit d)"
639   by (auto intro: coprimeI gcd_greatest dvd_gcd_D1 dvd_gcd_D2)
641 lemma div_gcd_coprime:
642   assumes nz: "a \<noteq> 0 \<or> b \<noteq> 0"
643   defines [simp]: "d \<equiv> gcd a b"
644   defines [simp]: "a' \<equiv> a div d" and [simp]: "b' \<equiv> b div d"
645   shows "gcd a' b' = 1"
646 proof (rule coprimeI)
647   fix l assume "l dvd a'" "l dvd b'"
648   then obtain s t where "a' = l * s" "b' = l * t" unfolding dvd_def by blast
649   moreover have "a = a' * d" "b = b' * d" by simp_all
650   ultimately have "a = (l * d) * s" "b = (l * d) * t"
651     by (simp_all only: ac_simps)
652   hence "l*d dvd a" and "l*d dvd b" by (simp_all only: dvd_triv_left)
653   hence "l*d dvd d" by (simp add: gcd_greatest)
654   then obtain u where "d = l * d * u" ..
655   then have "d * (l * u) = d" by (simp add: ac_simps)
656   moreover from nz have "d \<noteq> 0" by simp
657   with div_mult_self1_is_id have "d * (l * u) div d = l * u" .
658   ultimately have "1 = l * u"
659     using \<open>d \<noteq> 0\<close> by simp
660   then show "l dvd 1" ..
661 qed
663 lemma coprime_mult:
664   assumes da: "gcd d a = 1" and db: "gcd d b = 1"
665   shows "gcd d (a * b) = 1"
666   apply (subst gcd.commute)
667   using da apply (subst gcd_mult_cancel)
668   apply (subst gcd.commute, assumption)
669   apply (subst gcd.commute, rule db)
670   done
672 lemma coprime_lmult:
673   assumes dab: "gcd d (a * b) = 1"
674   shows "gcd d a = 1"
675 proof (rule coprimeI)
676   fix l assume "l dvd d" and "l dvd a"
677   hence "l dvd a * b" by simp
678   with \<open>l dvd d\<close> and dab show "l dvd 1" by (auto intro: gcd_greatest)
679 qed
681 lemma coprime_rmult:
682   assumes dab: "gcd d (a * b) = 1"
683   shows "gcd d b = 1"
684 proof (rule coprimeI)
685   fix l assume "l dvd d" and "l dvd b"
686   hence "l dvd a * b" by simp
687   with \<open>l dvd d\<close> and dab show "l dvd 1" by (auto intro: gcd_greatest)
688 qed
690 lemma coprime_mul_eq: "gcd d (a * b) = 1 \<longleftrightarrow> gcd d a = 1 \<and> gcd d b = 1"
691   using coprime_rmult[of d a b] coprime_lmult[of d a b] coprime_mult[of d a b] by blast
693 lemma gcd_coprime:
694   assumes c: "gcd a b \<noteq> 0" and a: "a = a' * gcd a b" and b: "b = b' * gcd a b"
695   shows "gcd a' b' = 1"
696 proof -
697   from c have "a \<noteq> 0 \<or> b \<noteq> 0" by simp
698   with div_gcd_coprime have "gcd (a div gcd a b) (b div gcd a b) = 1" .
699   also from assms have "a div gcd a b = a'" by (metis div_mult_self2_is_id)+
700   also from assms have "b div gcd a b = b'" by (metis div_mult_self2_is_id)+
701   finally show ?thesis .
702 qed
704 lemma coprime_power:
705   assumes "0 < n"
706   shows "gcd a (b ^ n) = 1 \<longleftrightarrow> gcd a b = 1"
707 using assms proof (induct n)
708   case (Suc n) then show ?case
709     by (cases n) (simp_all add: coprime_mul_eq)
710 qed simp
712 lemma gcd_coprime_exists:
713   assumes nz: "gcd a b \<noteq> 0"
714   shows "\<exists>a' b'. a = a' * gcd a b \<and> b = b' * gcd a b \<and> gcd a' b' = 1"
715   apply (rule_tac x = "a div gcd a b" in exI)
716   apply (rule_tac x = "b div gcd a b" in exI)
717   apply (insert nz, auto intro: div_gcd_coprime)
718   done
720 lemma coprime_exp:
721   "gcd d a = 1 \<Longrightarrow> gcd d (a^n) = 1"
722   by (induct n, simp_all add: coprime_mult)
724 lemma coprime_exp2 [intro]:
725   "gcd a b = 1 \<Longrightarrow> gcd (a^n) (b^m) = 1"
726   apply (rule coprime_exp)
727   apply (subst gcd.commute)
728   apply (rule coprime_exp)
729   apply (subst gcd.commute)
730   apply assumption
731   done
733 lemma gcd_exp:
734   "gcd (a^n) (b^n) = (gcd a b) ^ n"
735 proof (cases "a = 0 \<and> b = 0")
736   assume "a = 0 \<and> b = 0"
737   then show ?thesis by (cases n, simp_all add: gcd_0_left)
738 next
739   assume A: "\<not>(a = 0 \<and> b = 0)"
740   hence "1 = gcd ((a div gcd a b)^n) ((b div gcd a b)^n)"
741     using div_gcd_coprime by (subst sym, auto simp: div_gcd_coprime)
742   hence "(gcd a b) ^ n = (gcd a b) ^ n * ..." by simp
743   also note gcd_mult_distrib
744   also have "normalization_factor ((gcd a b)^n) = 1"
745     by (simp add: normalization_factor_pow A)
746   also have "(gcd a b)^n * (a div gcd a b)^n = a^n"
747     by (subst ac_simps, subst div_power, simp, rule dvd_div_mult_self, rule dvd_power_same, simp)
748   also have "(gcd a b)^n * (b div gcd a b)^n = b^n"
749     by (subst ac_simps, subst div_power, simp, rule dvd_div_mult_self, rule dvd_power_same, simp)
750   finally show ?thesis by simp
751 qed
753 lemma coprime_common_divisor:
754   "gcd a b = 1 \<Longrightarrow> a dvd a \<Longrightarrow> a dvd b \<Longrightarrow> is_unit a"
755   apply (subgoal_tac "a dvd gcd a b")
756   apply simp
757   apply (erule (1) gcd_greatest)
758   done
760 lemma division_decomp:
761   assumes dc: "a dvd b * c"
762   shows "\<exists>b' c'. a = b' * c' \<and> b' dvd b \<and> c' dvd c"
763 proof (cases "gcd a b = 0")
764   assume "gcd a b = 0"
765   hence "a = 0 \<and> b = 0" by simp
766   hence "a = 0 * c \<and> 0 dvd b \<and> c dvd c" by simp
767   then show ?thesis by blast
768 next
769   let ?d = "gcd a b"
770   assume "?d \<noteq> 0"
771   from gcd_coprime_exists[OF this]
772     obtain a' b' where ab': "a = a' * ?d" "b = b' * ?d" "gcd a' b' = 1"
773     by blast
774   from ab'(1) have "a' dvd a" unfolding dvd_def by blast
775   with dc have "a' dvd b*c" using dvd_trans[of a' a "b*c"] by simp
776   from dc ab'(1,2) have "a'*?d dvd (b'*?d) * c" by simp
777   hence "?d * a' dvd ?d * (b' * c)" by (simp add: mult_ac)
778   with \<open>?d \<noteq> 0\<close> have "a' dvd b' * c" by simp
779   with coprime_dvd_mult[OF ab'(3)]
780     have "a' dvd c" by (subst (asm) ac_simps, blast)
781   with ab'(1) have "a = ?d * a' \<and> ?d dvd b \<and> a' dvd c" by (simp add: mult_ac)
782   then show ?thesis by blast
783 qed
785 lemma pow_divs_pow:
786   assumes ab: "a ^ n dvd b ^ n" and n: "n \<noteq> 0"
787   shows "a dvd b"
788 proof (cases "gcd a b = 0")
789   assume "gcd a b = 0"
790   then show ?thesis by simp
791 next
792   let ?d = "gcd a b"
793   assume "?d \<noteq> 0"
794   from n obtain m where m: "n = Suc m" by (cases n, simp_all)
795   from \<open>?d \<noteq> 0\<close> have zn: "?d ^ n \<noteq> 0" by (rule power_not_zero)
796   from gcd_coprime_exists[OF \<open>?d \<noteq> 0\<close>]
797     obtain a' b' where ab': "a = a' * ?d" "b = b' * ?d" "gcd a' b' = 1"
798     by blast
799   from ab have "(a' * ?d) ^ n dvd (b' * ?d) ^ n"
800     by (simp add: ab'(1,2)[symmetric])
801   hence "?d^n * a'^n dvd ?d^n * b'^n"
802     by (simp only: power_mult_distrib ac_simps)
803   with zn have "a'^n dvd b'^n" by simp
804   hence "a' dvd b'^n" using dvd_trans[of a' "a'^n" "b'^n"] by (simp add: m)
805   hence "a' dvd b'^m * b'" by (simp add: m ac_simps)
806   with coprime_dvd_mult[OF coprime_exp[OF ab'(3), of m]]
807     have "a' dvd b'" by (subst (asm) ac_simps, blast)
808   hence "a'*?d dvd b'*?d" by (rule mult_dvd_mono, simp)
809   with ab'(1,2) show ?thesis by simp
810 qed
812 lemma pow_divs_eq [simp]:
813   "n \<noteq> 0 \<Longrightarrow> a ^ n dvd b ^ n \<longleftrightarrow> a dvd b"
814   by (auto intro: pow_divs_pow dvd_power_same)
816 lemma divs_mult:
817   assumes mr: "m dvd r" and nr: "n dvd r" and mn: "gcd m n = 1"
818   shows "m * n dvd r"
819 proof -
820   from mr nr obtain m' n' where m': "r = m*m'" and n': "r = n*n'"
821     unfolding dvd_def by blast
822   from mr n' have "m dvd n'*n" by (simp add: ac_simps)
823   hence "m dvd n'" using coprime_dvd_mult_iff[OF mn] by simp
824   then obtain k where k: "n' = m*k" unfolding dvd_def by blast
825   with n' have "r = m * n * k" by (simp add: mult_ac)
826   then show ?thesis unfolding dvd_def by blast
827 qed
829 lemma coprime_plus_one [simp]: "gcd (n + 1) n = 1"
830   by (subst add_commute, simp)
832 lemma setprod_coprime [rule_format]:
833   "(\<forall>i\<in>A. gcd (f i) a = 1) \<longrightarrow> gcd (\<Prod>i\<in>A. f i) a = 1"
834   apply (cases "finite A")
835   apply (induct set: finite)
836   apply (auto simp add: gcd_mult_cancel)
837   done
839 lemma coprime_divisors:
840   assumes "d dvd a" "e dvd b" "gcd a b = 1"
841   shows "gcd d e = 1"
842 proof -
843   from assms obtain k l where "a = d * k" "b = e * l"
844     unfolding dvd_def by blast
845   with assms have "gcd (d * k) (e * l) = 1" by simp
846   hence "gcd (d * k) e = 1" by (rule coprime_lmult)
847   also have "gcd (d * k) e = gcd e (d * k)" by (simp add: ac_simps)
848   finally have "gcd e d = 1" by (rule coprime_lmult)
849   then show ?thesis by (simp add: ac_simps)
850 qed
852 lemma invertible_coprime:
853   assumes "a * b mod m = 1"
854   shows "coprime a m"
855 proof -
856   from assms have "coprime m (a * b mod m)"
857     by simp
858   then have "coprime m (a * b)"
859     by simp
860   then have "coprime m a"
861     by (rule coprime_lmult)
862   then show ?thesis
863     by (simp add: ac_simps)
864 qed
866 lemma lcm_gcd:
867   "lcm a b = a * b div (gcd a b * normalization_factor (a*b))"
868   by (simp only: lcm_lcm_eucl gcd_gcd_eucl lcm_eucl_def)
870 lemma lcm_gcd_prod:
871   "lcm a b * gcd a b = a * b div normalization_factor (a*b)"
872 proof (cases "a * b = 0")
873   let ?nf = normalization_factor
874   assume "a * b \<noteq> 0"
875   hence "gcd a b \<noteq> 0" by simp
876   from lcm_gcd have "lcm a b * gcd a b = gcd a b * (a * b div (?nf (a*b) * gcd a b))"
877     by (simp add: mult_ac)
878   also from \<open>a * b \<noteq> 0\<close> have "... = a * b div ?nf (a*b)"
879     by (simp add: div_mult_swap mult.commute)
880   finally show ?thesis .
881 qed (auto simp add: lcm_gcd)
883 lemma lcm_dvd1 [iff]:
884   "a dvd lcm a b"
885 proof (cases "a*b = 0")
886   assume "a * b \<noteq> 0"
887   hence "gcd a b \<noteq> 0" by simp
888   let ?c = "1 div normalization_factor (a * b)"
889   from \<open>a * b \<noteq> 0\<close> have [simp]: "is_unit (normalization_factor (a * b))" by simp
890   from lcm_gcd_prod[of a b] have "lcm a b * gcd a b = a * ?c * b"
891     by (simp add: div_mult_swap unit_div_commute)
892   hence "lcm a b * gcd a b div gcd a b = a * ?c * b div gcd a b" by simp
893   with \<open>gcd a b \<noteq> 0\<close> have "lcm a b = a * ?c * b div gcd a b"
894     by (subst (asm) div_mult_self2_is_id, simp_all)
895   also have "... = a * (?c * b div gcd a b)"
896     by (metis div_mult_swap gcd_dvd2 mult_assoc)
897   finally show ?thesis by (rule dvdI)
898 qed (auto simp add: lcm_gcd)
900 lemma lcm_least:
901   "\<lbrakk>a dvd k; b dvd k\<rbrakk> \<Longrightarrow> lcm a b dvd k"
902 proof (cases "k = 0")
903   let ?nf = normalization_factor
904   assume "k \<noteq> 0"
905   hence "is_unit (?nf k)" by simp
906   hence "?nf k \<noteq> 0" by (metis not_is_unit_0)
907   assume A: "a dvd k" "b dvd k"
908   hence "gcd a b \<noteq> 0" using \<open>k \<noteq> 0\<close> by auto
909   from A obtain r s where ar: "k = a * r" and bs: "k = b * s"
910     unfolding dvd_def by blast
911   with \<open>k \<noteq> 0\<close> have "r * s \<noteq> 0"
912     by auto (drule sym [of 0], simp)
913   hence "is_unit (?nf (r * s))" by simp
914   let ?c = "?nf k div ?nf (r*s)"
915   from \<open>is_unit (?nf k)\<close> and \<open>is_unit (?nf (r * s))\<close> have "is_unit ?c" by (rule unit_div)
916   hence "?c \<noteq> 0" using not_is_unit_0 by fast
917   from ar bs have "k * k * gcd s r = ?nf k * k * gcd (k * s) (k * r)"
918     by (subst mult_assoc, subst gcd_mult_distrib[of k s r], simp only: ac_simps)
919   also have "... = ?nf k * k * gcd ((r*s) * a) ((r*s) * b)"
920     by (subst (3) \<open>k = a * r\<close>, subst (3) \<open>k = b * s\<close>, simp add: algebra_simps)
921   also have "... = ?c * r*s * k * gcd a b" using \<open>r * s \<noteq> 0\<close>
922     by (subst gcd_mult_distrib'[symmetric], simp add: algebra_simps unit_simps)
923   finally have "(a*r) * (b*s) * gcd s r = ?c * k * r * s * gcd a b"
924     by (subst ar[symmetric], subst bs[symmetric], simp add: mult_ac)
925   hence "a * b * gcd s r * (r * s) = ?c * k * gcd a b * (r * s)"
926     by (simp add: algebra_simps)
927   hence "?c * k * gcd a b = a * b * gcd s r" using \<open>r * s \<noteq> 0\<close>
928     by (metis div_mult_self2_is_id)
929   also have "... = lcm a b * gcd a b * gcd s r * ?nf (a*b)"
930     by (subst lcm_gcd_prod[of a b], metis gcd_mult_distrib gcd_mult_distrib')
931   also have "... = lcm a b * gcd s r * ?nf (a*b) * gcd a b"
932     by (simp add: algebra_simps)
933   finally have "k * ?c = lcm a b * gcd s r * ?nf (a*b)" using \<open>gcd a b \<noteq> 0\<close>
934     by (metis mult.commute div_mult_self2_is_id)
935   hence "k = lcm a b * (gcd s r * ?nf (a*b)) div ?c" using \<open>?c \<noteq> 0\<close>
936     by (metis div_mult_self2_is_id mult_assoc)
937   also have "... = lcm a b * (gcd s r * ?nf (a*b) div ?c)" using \<open>is_unit ?c\<close>
938     by (simp add: unit_simps)
939   finally show ?thesis by (rule dvdI)
940 qed simp
942 lemma lcm_zero:
943   "lcm a b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
944 proof -
945   let ?nf = normalization_factor
946   {
947     assume "a \<noteq> 0" "b \<noteq> 0"
948     hence "a * b div ?nf (a * b) \<noteq> 0" by (simp add: no_zero_divisors)
949     moreover from \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> have "gcd a b \<noteq> 0" by simp
950     ultimately have "lcm a b \<noteq> 0" using lcm_gcd_prod[of a b] by (intro notI, simp)
951   } moreover {
952     assume "a = 0 \<or> b = 0"
953     hence "lcm a b = 0" by (elim disjE, simp_all add: lcm_gcd)
954   }
955   ultimately show ?thesis by blast
956 qed
958 lemmas lcm_0_iff = lcm_zero
960 lemma gcd_lcm:
961   assumes "lcm a b \<noteq> 0"
962   shows "gcd a b = a * b div (lcm a b * normalization_factor (a * b))"
963 proof-
964   from assms have "gcd a b \<noteq> 0" by (simp add: lcm_zero)
965   let ?c = "normalization_factor (a * b)"
966   from \<open>lcm a b \<noteq> 0\<close> have "?c \<noteq> 0" by (intro notI, simp add: lcm_zero no_zero_divisors)
967   hence "is_unit ?c" by simp
968   from lcm_gcd_prod [of a b] have "gcd a b = a * b div ?c div lcm a b"
969     by (subst (2) div_mult_self2_is_id[OF \<open>lcm a b \<noteq> 0\<close>, symmetric], simp add: mult_ac)
970   also from \<open>is_unit ?c\<close> have "... = a * b div (lcm a b * ?c)"
971     by (metis \<open>?c \<noteq> 0\<close> div_mult_mult1 dvd_mult_div_cancel mult_commute normalization_factor_dvd')
972   finally show ?thesis .
973 qed
975 lemma normalization_factor_lcm [simp]:
976   "normalization_factor (lcm a b) = (if a = 0 \<or> b = 0 then 0 else 1)"
977 proof (cases "a = 0 \<or> b = 0")
978   case True then show ?thesis
979     by (auto simp add: lcm_gcd)
980 next
981   case False
982   let ?nf = normalization_factor
983   from lcm_gcd_prod[of a b]
984     have "?nf (lcm a b) * ?nf (gcd a b) = ?nf (a*b) div ?nf (a*b)"
985     by (metis div_by_0 div_self normalization_correct normalization_factor_0 normalization_factor_mult)
986   also have "... = (if a*b = 0 then 0 else 1)"
987     by simp
988   finally show ?thesis using False by simp
989 qed
991 lemma lcm_dvd2 [iff]: "b dvd lcm a b"
992   using lcm_dvd1 [of b a] by (simp add: lcm_gcd ac_simps)
994 lemma lcmI:
995   "\<lbrakk>a dvd k; b dvd k; \<And>l. a dvd l \<Longrightarrow> b dvd l \<Longrightarrow> k dvd l;
996     normalization_factor k = (if k = 0 then 0 else 1)\<rbrakk> \<Longrightarrow> k = lcm a b"
997   by (intro normed_associated_imp_eq) (auto simp: associated_def intro: lcm_least)
999 sublocale lcm!: abel_semigroup lcm
1000 proof
1001   fix a b c
1002   show "lcm (lcm a b) c = lcm a (lcm b c)"
1003   proof (rule lcmI)
1004     have "a dvd lcm a b" and "lcm a b dvd lcm (lcm a b) c" by simp_all
1005     then show "a dvd lcm (lcm a b) c" by (rule dvd_trans)
1007     have "b dvd lcm a b" and "lcm a b dvd lcm (lcm a b) c" by simp_all
1008     hence "b dvd lcm (lcm a b) c" by (rule dvd_trans)
1009     moreover have "c dvd lcm (lcm a b) c" by simp
1010     ultimately show "lcm b c dvd lcm (lcm a b) c" by (rule lcm_least)
1012     fix l assume "a dvd l" and "lcm b c dvd l"
1013     have "b dvd lcm b c" by simp
1014     from this and \<open>lcm b c dvd l\<close> have "b dvd l" by (rule dvd_trans)
1015     have "c dvd lcm b c" by simp
1016     from this and \<open>lcm b c dvd l\<close> have "c dvd l" by (rule dvd_trans)
1017     from \<open>a dvd l\<close> and \<open>b dvd l\<close> have "lcm a b dvd l" by (rule lcm_least)
1018     from this and \<open>c dvd l\<close> show "lcm (lcm a b) c dvd l" by (rule lcm_least)
1019   qed (simp add: lcm_zero)
1020 next
1021   fix a b
1022   show "lcm a b = lcm b a"
1023     by (simp add: lcm_gcd ac_simps)
1024 qed
1026 lemma dvd_lcm_D1:
1027   "lcm m n dvd k \<Longrightarrow> m dvd k"
1028   by (rule dvd_trans, rule lcm_dvd1, assumption)
1030 lemma dvd_lcm_D2:
1031   "lcm m n dvd k \<Longrightarrow> n dvd k"
1032   by (rule dvd_trans, rule lcm_dvd2, assumption)
1034 lemma gcd_dvd_lcm [simp]:
1035   "gcd a b dvd lcm a b"
1036   by (metis dvd_trans gcd_dvd2 lcm_dvd2)
1038 lemma lcm_1_iff:
1039   "lcm a b = 1 \<longleftrightarrow> is_unit a \<and> is_unit b"
1040 proof
1041   assume "lcm a b = 1"
1042   then show "is_unit a \<and> is_unit b" by auto
1043 next
1044   assume "is_unit a \<and> is_unit b"
1045   hence "a dvd 1" and "b dvd 1" by simp_all
1046   hence "is_unit (lcm a b)" by (rule lcm_least)
1047   hence "lcm a b = normalization_factor (lcm a b)"
1048     by (subst normalization_factor_unit, simp_all)
1049   also have "\<dots> = 1" using \<open>is_unit a \<and> is_unit b\<close>
1050     by auto
1051   finally show "lcm a b = 1" .
1052 qed
1054 lemma lcm_0_left [simp]:
1055   "lcm 0 a = 0"
1056   by (rule sym, rule lcmI, simp_all)
1058 lemma lcm_0 [simp]:
1059   "lcm a 0 = 0"
1060   by (rule sym, rule lcmI, simp_all)
1062 lemma lcm_unique:
1063   "a dvd d \<and> b dvd d \<and>
1064   normalization_factor d = (if d = 0 then 0 else 1) \<and>
1065   (\<forall>e. a dvd e \<and> b dvd e \<longrightarrow> d dvd e) \<longleftrightarrow> d = lcm a b"
1066   by (rule, auto intro: lcmI simp: lcm_least lcm_zero)
1068 lemma dvd_lcm_I1 [simp]:
1069   "k dvd m \<Longrightarrow> k dvd lcm m n"
1070   by (metis lcm_dvd1 dvd_trans)
1072 lemma dvd_lcm_I2 [simp]:
1073   "k dvd n \<Longrightarrow> k dvd lcm m n"
1074   by (metis lcm_dvd2 dvd_trans)
1076 lemma lcm_1_left [simp]:
1077   "lcm 1 a = a div normalization_factor a"
1078   by (cases "a = 0") (simp, rule sym, rule lcmI, simp_all)
1080 lemma lcm_1_right [simp]:
1081   "lcm a 1 = a div normalization_factor a"
1082   using lcm_1_left [of a] by (simp add: ac_simps)
1084 lemma lcm_coprime:
1085   "gcd a b = 1 \<Longrightarrow> lcm a b = a * b div normalization_factor (a*b)"
1086   by (subst lcm_gcd) simp
1088 lemma lcm_proj1_if_dvd:
1089   "b dvd a \<Longrightarrow> lcm a b = a div normalization_factor a"
1090   by (cases "a = 0") (simp, rule sym, rule lcmI, simp_all)
1092 lemma lcm_proj2_if_dvd:
1093   "a dvd b \<Longrightarrow> lcm a b = b div normalization_factor b"
1094   using lcm_proj1_if_dvd [of a b] by (simp add: ac_simps)
1096 lemma lcm_proj1_iff:
1097   "lcm m n = m div normalization_factor m \<longleftrightarrow> n dvd m"
1098 proof
1099   assume A: "lcm m n = m div normalization_factor m"
1100   show "n dvd m"
1101   proof (cases "m = 0")
1102     assume [simp]: "m \<noteq> 0"
1103     from A have B: "m = lcm m n * normalization_factor m"
1104       by (simp add: unit_eq_div2)
1105     show ?thesis by (subst B, simp)
1106   qed simp
1107 next
1108   assume "n dvd m"
1109   then show "lcm m n = m div normalization_factor m" by (rule lcm_proj1_if_dvd)
1110 qed
1112 lemma lcm_proj2_iff:
1113   "lcm m n = n div normalization_factor n \<longleftrightarrow> m dvd n"
1114   using lcm_proj1_iff [of n m] by (simp add: ac_simps)
1116 lemma euclidean_size_lcm_le1:
1117   assumes "a \<noteq> 0" and "b \<noteq> 0"
1118   shows "euclidean_size a \<le> euclidean_size (lcm a b)"
1119 proof -
1120   have "a dvd lcm a b" by (rule lcm_dvd1)
1121   then obtain c where A: "lcm a b = a * c" unfolding dvd_def by blast
1122   with \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> have "c \<noteq> 0" by (auto simp: lcm_zero)
1123   then show ?thesis by (subst A, intro size_mult_mono)
1124 qed
1126 lemma euclidean_size_lcm_le2:
1127   "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> euclidean_size b \<le> euclidean_size (lcm a b)"
1128   using euclidean_size_lcm_le1 [of b a] by (simp add: ac_simps)
1130 lemma euclidean_size_lcm_less1:
1131   assumes "b \<noteq> 0" and "\<not>b dvd a"
1132   shows "euclidean_size a < euclidean_size (lcm a b)"
1133 proof (rule ccontr)
1134   from assms have "a \<noteq> 0" by auto
1135   assume "\<not>euclidean_size a < euclidean_size (lcm a b)"
1136   with \<open>a \<noteq> 0\<close> and \<open>b \<noteq> 0\<close> have "euclidean_size (lcm a b) = euclidean_size a"
1137     by (intro le_antisym, simp, intro euclidean_size_lcm_le1)
1138   with assms have "lcm a b dvd a"
1139     by (rule_tac dvd_euclidean_size_eq_imp_dvd) (auto simp: lcm_zero)
1140   hence "b dvd a" by (rule dvd_lcm_D2)
1141   with \<open>\<not>b dvd a\<close> show False by contradiction
1142 qed
1144 lemma euclidean_size_lcm_less2:
1145   assumes "a \<noteq> 0" and "\<not>a dvd b"
1146   shows "euclidean_size b < euclidean_size (lcm a b)"
1147   using assms euclidean_size_lcm_less1 [of a b] by (simp add: ac_simps)
1149 lemma lcm_mult_unit1:
1150   "is_unit a \<Longrightarrow> lcm (b * a) c = lcm b c"
1151   apply (rule lcmI)
1152   apply (rule dvd_trans[of _ "b * a"], simp, rule lcm_dvd1)
1153   apply (rule lcm_dvd2)
1154   apply (rule lcm_least, simp add: unit_simps, assumption)
1155   apply (subst normalization_factor_lcm, simp add: lcm_zero)
1156   done
1158 lemma lcm_mult_unit2:
1159   "is_unit a \<Longrightarrow> lcm b (c * a) = lcm b c"
1160   using lcm_mult_unit1 [of a c b] by (simp add: ac_simps)
1162 lemma lcm_div_unit1:
1163   "is_unit a \<Longrightarrow> lcm (b div a) c = lcm b c"
1164   by (erule is_unitE [of _ b]) (simp add: lcm_mult_unit1)
1166 lemma lcm_div_unit2:
1167   "is_unit a \<Longrightarrow> lcm b (c div a) = lcm b c"
1168   by (erule is_unitE [of _ c]) (simp add: lcm_mult_unit2)
1170 lemma lcm_left_idem:
1171   "lcm a (lcm a b) = lcm a b"
1172   apply (rule lcmI)
1173   apply simp
1174   apply (subst lcm.assoc [symmetric], rule lcm_dvd2)
1175   apply (rule lcm_least, assumption)
1176   apply (erule (1) lcm_least)
1177   apply (auto simp: lcm_zero)
1178   done
1180 lemma lcm_right_idem:
1181   "lcm (lcm a b) b = lcm a b"
1182   apply (rule lcmI)
1183   apply (subst lcm.assoc, rule lcm_dvd1)
1184   apply (rule lcm_dvd2)
1185   apply (rule lcm_least, erule (1) lcm_least, assumption)
1186   apply (auto simp: lcm_zero)
1187   done
1189 lemma comp_fun_idem_lcm: "comp_fun_idem lcm"
1190 proof
1191   fix a b show "lcm a \<circ> lcm b = lcm b \<circ> lcm a"
1192     by (simp add: fun_eq_iff ac_simps)
1193 next
1194   fix a show "lcm a \<circ> lcm a = lcm a" unfolding o_def
1195     by (intro ext, simp add: lcm_left_idem)
1196 qed
1198 lemma dvd_Lcm [simp]: "a \<in> A \<Longrightarrow> a dvd Lcm A"
1199   and Lcm_dvd [simp]: "(\<forall>a\<in>A. a dvd l') \<Longrightarrow> Lcm A dvd l'"
1200   and normalization_factor_Lcm [simp]:
1201           "normalization_factor (Lcm A) = (if Lcm A = 0 then 0 else 1)"
1202 proof -
1203   have "(\<forall>a\<in>A. a dvd Lcm A) \<and> (\<forall>l'. (\<forall>a\<in>A. a dvd l') \<longrightarrow> Lcm A dvd l') \<and>
1204     normalization_factor (Lcm A) = (if Lcm A = 0 then 0 else 1)" (is ?thesis)
1205   proof (cases "\<exists>l. l \<noteq>  0 \<and> (\<forall>a\<in>A. a dvd l)")
1206     case False
1207     hence "Lcm A = 0" by (auto simp: Lcm_Lcm_eucl Lcm_eucl_def)
1208     with False show ?thesis by auto
1209   next
1210     case True
1211     then obtain l\<^sub>0 where l\<^sub>0_props: "l\<^sub>0 \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l\<^sub>0)" by blast
1212     def n \<equiv> "LEAST n. \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
1213     def l \<equiv> "SOME l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
1214     have "\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
1215       apply (subst n_def)
1216       apply (rule LeastI[of _ "euclidean_size l\<^sub>0"])
1217       apply (rule exI[of _ l\<^sub>0])
1218       apply (simp add: l\<^sub>0_props)
1219       done
1220     from someI_ex[OF this] have "l \<noteq> 0" and "\<forall>a\<in>A. a dvd l" and "euclidean_size l = n"
1221       unfolding l_def by simp_all
1222     {
1223       fix l' assume "\<forall>a\<in>A. a dvd l'"
1224       with \<open>\<forall>a\<in>A. a dvd l\<close> have "\<forall>a\<in>A. a dvd gcd l l'" by (auto intro: gcd_greatest)
1225       moreover from \<open>l \<noteq> 0\<close> have "gcd l l' \<noteq> 0" by simp
1226       ultimately have "\<exists>b. b \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd b) \<and> euclidean_size b = euclidean_size (gcd l l')"
1227         by (intro exI[of _ "gcd l l'"], auto)
1228       hence "euclidean_size (gcd l l') \<ge> n" by (subst n_def) (rule Least_le)
1229       moreover have "euclidean_size (gcd l l') \<le> n"
1230       proof -
1231         have "gcd l l' dvd l" by simp
1232         then obtain a where "l = gcd l l' * a" unfolding dvd_def by blast
1233         with \<open>l \<noteq> 0\<close> have "a \<noteq> 0" by auto
1234         hence "euclidean_size (gcd l l') \<le> euclidean_size (gcd l l' * a)"
1235           by (rule size_mult_mono)
1236         also have "gcd l l' * a = l" using \<open>l = gcd l l' * a\<close> ..
1237         also note \<open>euclidean_size l = n\<close>
1238         finally show "euclidean_size (gcd l l') \<le> n" .
1239       qed
1240       ultimately have "euclidean_size l = euclidean_size (gcd l l')"
1241         by (intro le_antisym, simp_all add: \<open>euclidean_size l = n\<close>)
1242       with \<open>l \<noteq> 0\<close> have "l dvd gcd l l'" by (blast intro: dvd_euclidean_size_eq_imp_dvd)
1243       hence "l dvd l'" by (blast dest: dvd_gcd_D2)
1244     }
1246     with \<open>(\<forall>a\<in>A. a dvd l)\<close> and normalization_factor_is_unit[OF \<open>l \<noteq> 0\<close>] and \<open>l \<noteq> 0\<close>
1247       have "(\<forall>a\<in>A. a dvd l div normalization_factor l) \<and>
1248         (\<forall>l'. (\<forall>a\<in>A. a dvd l') \<longrightarrow> l div normalization_factor l dvd l') \<and>
1249         normalization_factor (l div normalization_factor l) =
1250         (if l div normalization_factor l = 0 then 0 else 1)"
1251       by (auto simp: unit_simps)
1252     also from True have "l div normalization_factor l = Lcm A"
1253       by (simp add: Lcm_Lcm_eucl Lcm_eucl_def Let_def n_def l_def)
1254     finally show ?thesis .
1255   qed
1256   note A = this
1258   {fix a assume "a \<in> A" then show "a dvd Lcm A" using A by blast}
1259   {fix l' assume "\<forall>a\<in>A. a dvd l'" then show "Lcm A dvd l'" using A by blast}
1260   from A show "normalization_factor (Lcm A) = (if Lcm A = 0 then 0 else 1)" by blast
1261 qed
1263 lemma LcmI:
1264   "(\<And>a. a\<in>A \<Longrightarrow> a dvd l) \<Longrightarrow> (\<And>l'. (\<forall>a\<in>A. a dvd l') \<Longrightarrow> l dvd l') \<Longrightarrow>
1265       normalization_factor l = (if l = 0 then 0 else 1) \<Longrightarrow> l = Lcm A"
1266   by (intro normed_associated_imp_eq)
1267     (auto intro: Lcm_dvd dvd_Lcm simp: associated_def)
1269 lemma Lcm_subset:
1270   "A \<subseteq> B \<Longrightarrow> Lcm A dvd Lcm B"
1271   by (blast intro: Lcm_dvd dvd_Lcm)
1273 lemma Lcm_Un:
1274   "Lcm (A \<union> B) = lcm (Lcm A) (Lcm B)"
1275   apply (rule lcmI)
1276   apply (blast intro: Lcm_subset)
1277   apply (blast intro: Lcm_subset)
1278   apply (intro Lcm_dvd ballI, elim UnE)
1279   apply (rule dvd_trans, erule dvd_Lcm, assumption)
1280   apply (rule dvd_trans, erule dvd_Lcm, assumption)
1281   apply simp
1282   done
1284 lemma Lcm_1_iff:
1285   "Lcm A = 1 \<longleftrightarrow> (\<forall>a\<in>A. is_unit a)"
1286 proof
1287   assume "Lcm A = 1"
1288   then show "\<forall>a\<in>A. is_unit a" by auto
1289 qed (rule LcmI [symmetric], auto)
1291 lemma Lcm_no_units:
1292   "Lcm A = Lcm (A - {a. is_unit a})"
1293 proof -
1294   have "(A - {a. is_unit a}) \<union> {a\<in>A. is_unit a} = A" by blast
1295   hence "Lcm A = lcm (Lcm (A - {a. is_unit a})) (Lcm {a\<in>A. is_unit a})"
1296     by (simp add: Lcm_Un[symmetric])
1297   also have "Lcm {a\<in>A. is_unit a} = 1" by (simp add: Lcm_1_iff)
1298   finally show ?thesis by simp
1299 qed
1301 lemma Lcm_empty [simp]:
1302   "Lcm {} = 1"
1303   by (simp add: Lcm_1_iff)
1305 lemma Lcm_eq_0 [simp]:
1306   "0 \<in> A \<Longrightarrow> Lcm A = 0"
1307   by (drule dvd_Lcm) simp
1309 lemma Lcm0_iff':
1310   "Lcm A = 0 \<longleftrightarrow> \<not>(\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l))"
1311 proof
1312   assume "Lcm A = 0"
1313   show "\<not>(\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l))"
1314   proof
1315     assume ex: "\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l)"
1316     then obtain l\<^sub>0 where l\<^sub>0_props: "l\<^sub>0 \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l\<^sub>0)" by blast
1317     def n \<equiv> "LEAST n. \<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
1318     def l \<equiv> "SOME l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
1319     have "\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l) \<and> euclidean_size l = n"
1320       apply (subst n_def)
1321       apply (rule LeastI[of _ "euclidean_size l\<^sub>0"])
1322       apply (rule exI[of _ l\<^sub>0])
1323       apply (simp add: l\<^sub>0_props)
1324       done
1325     from someI_ex[OF this] have "l \<noteq> 0" unfolding l_def by simp_all
1326     hence "l div normalization_factor l \<noteq> 0" by simp
1327     also from ex have "l div normalization_factor l = Lcm A"
1328        by (simp only: Lcm_Lcm_eucl Lcm_eucl_def n_def l_def if_True Let_def)
1329     finally show False using \<open>Lcm A = 0\<close> by contradiction
1330   qed
1331 qed (simp only: Lcm_Lcm_eucl Lcm_eucl_def if_False)
1333 lemma Lcm0_iff [simp]:
1334   "finite A \<Longrightarrow> Lcm A = 0 \<longleftrightarrow> 0 \<in> A"
1335 proof -
1336   assume "finite A"
1337   have "0 \<in> A \<Longrightarrow> Lcm A = 0"  by (intro dvd_0_left dvd_Lcm)
1338   moreover {
1339     assume "0 \<notin> A"
1340     hence "\<Prod>A \<noteq> 0"
1341       apply (induct rule: finite_induct[OF \<open>finite A\<close>])
1342       apply simp
1343       apply (subst setprod.insert, assumption, assumption)
1344       apply (rule no_zero_divisors)
1345       apply blast+
1346       done
1347     moreover from \<open>finite A\<close> have "\<forall>a\<in>A. a dvd \<Prod>A" by blast
1348     ultimately have "\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l)" by blast
1349     with Lcm0_iff' have "Lcm A \<noteq> 0" by simp
1350   }
1351   ultimately show "Lcm A = 0 \<longleftrightarrow> 0 \<in> A" by blast
1352 qed
1354 lemma Lcm_no_multiple:
1355   "(\<forall>m. m \<noteq> 0 \<longrightarrow> (\<exists>a\<in>A. \<not>a dvd m)) \<Longrightarrow> Lcm A = 0"
1356 proof -
1357   assume "\<forall>m. m \<noteq> 0 \<longrightarrow> (\<exists>a\<in>A. \<not>a dvd m)"
1358   hence "\<not>(\<exists>l. l \<noteq> 0 \<and> (\<forall>a\<in>A. a dvd l))" by blast
1359   then show "Lcm A = 0" by (simp only: Lcm_Lcm_eucl Lcm_eucl_def if_False)
1360 qed
1362 lemma Lcm_insert [simp]:
1363   "Lcm (insert a A) = lcm a (Lcm A)"
1364 proof (rule lcmI)
1365   fix l assume "a dvd l" and "Lcm A dvd l"
1366   hence "\<forall>a\<in>A. a dvd l" by (blast intro: dvd_trans dvd_Lcm)
1367   with \<open>a dvd l\<close> show "Lcm (insert a A) dvd l" by (force intro: Lcm_dvd)
1368 qed (auto intro: Lcm_dvd dvd_Lcm)
1370 lemma Lcm_finite:
1371   assumes "finite A"
1372   shows "Lcm A = Finite_Set.fold lcm 1 A"
1373   by (induct rule: finite.induct[OF \<open>finite A\<close>])
1374     (simp_all add: comp_fun_idem.fold_insert_idem[OF comp_fun_idem_lcm])
1376 lemma Lcm_set [code_unfold]:
1377   "Lcm (set xs) = fold lcm xs 1"
1378   using comp_fun_idem.fold_set_fold[OF comp_fun_idem_lcm] Lcm_finite by (simp add: ac_simps)
1380 lemma Lcm_singleton [simp]:
1381   "Lcm {a} = a div normalization_factor a"
1382   by simp
1384 lemma Lcm_2 [simp]:
1385   "Lcm {a,b} = lcm a b"
1386   by (simp only: Lcm_insert Lcm_empty lcm_1_right)
1387     (cases "b = 0", simp, rule lcm_div_unit2, simp)
1389 lemma Lcm_coprime:
1390   assumes "finite A" and "A \<noteq> {}"
1391   assumes "\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<noteq> b \<Longrightarrow> gcd a b = 1"
1392   shows "Lcm A = \<Prod>A div normalization_factor (\<Prod>A)"
1393 using assms proof (induct rule: finite_ne_induct)
1394   case (insert a A)
1395   have "Lcm (insert a A) = lcm a (Lcm A)" by simp
1396   also from insert have "Lcm A = \<Prod>A div normalization_factor (\<Prod>A)" by blast
1397   also have "lcm a \<dots> = lcm a (\<Prod>A)" by (cases "\<Prod>A = 0") (simp_all add: lcm_div_unit2)
1398   also from insert have "gcd a (\<Prod>A) = 1" by (subst gcd.commute, intro setprod_coprime) auto
1399   with insert have "lcm a (\<Prod>A) = \<Prod>(insert a A) div normalization_factor (\<Prod>(insert a A))"
1400     by (simp add: lcm_coprime)
1401   finally show ?case .
1402 qed simp
1404 lemma Lcm_coprime':
1405   "card A \<noteq> 0 \<Longrightarrow> (\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<noteq> b \<Longrightarrow> gcd a b = 1)
1406     \<Longrightarrow> Lcm A = \<Prod>A div normalization_factor (\<Prod>A)"
1407   by (rule Lcm_coprime) (simp_all add: card_eq_0_iff)
1409 lemma Gcd_Lcm:
1410   "Gcd A = Lcm {d. \<forall>a\<in>A. d dvd a}"
1411   by (simp add: Gcd_Gcd_eucl Lcm_Lcm_eucl Gcd_eucl_def)
1413 lemma Gcd_dvd [simp]: "a \<in> A \<Longrightarrow> Gcd A dvd a"
1414   and dvd_Gcd [simp]: "(\<forall>a\<in>A. g' dvd a) \<Longrightarrow> g' dvd Gcd A"
1415   and normalization_factor_Gcd [simp]:
1416     "normalization_factor (Gcd A) = (if Gcd A = 0 then 0 else 1)"
1417 proof -
1418   fix a assume "a \<in> A"
1419   hence "Lcm {d. \<forall>a\<in>A. d dvd a} dvd a" by (intro Lcm_dvd) blast
1420   then show "Gcd A dvd a" by (simp add: Gcd_Lcm)
1421 next
1422   fix g' assume "\<forall>a\<in>A. g' dvd a"
1423   hence "g' dvd Lcm {d. \<forall>a\<in>A. d dvd a}" by (intro dvd_Lcm) blast
1424   then show "g' dvd Gcd A" by (simp add: Gcd_Lcm)
1425 next
1426   show "normalization_factor (Gcd A) = (if Gcd A = 0 then 0 else 1)"
1427     by (simp add: Gcd_Lcm)
1428 qed
1430 lemma GcdI:
1431   "(\<And>a. a\<in>A \<Longrightarrow> l dvd a) \<Longrightarrow> (\<And>l'. (\<forall>a\<in>A. l' dvd a) \<Longrightarrow> l' dvd l) \<Longrightarrow>
1432     normalization_factor l = (if l = 0 then 0 else 1) \<Longrightarrow> l = Gcd A"
1433   by (intro normed_associated_imp_eq)
1434     (auto intro: Gcd_dvd dvd_Gcd simp: associated_def)
1436 lemma Lcm_Gcd:
1437   "Lcm A = Gcd {m. \<forall>a\<in>A. a dvd m}"
1438   by (rule LcmI[symmetric]) (auto intro: dvd_Gcd Gcd_dvd)
1440 lemma Gcd_0_iff:
1441   "Gcd A = 0 \<longleftrightarrow> A \<subseteq> {0}"
1442   apply (rule iffI)
1443   apply (rule subsetI, drule Gcd_dvd, simp)
1444   apply (auto intro: GcdI[symmetric])
1445   done
1447 lemma Gcd_empty [simp]:
1448   "Gcd {} = 0"
1449   by (simp add: Gcd_0_iff)
1451 lemma Gcd_1:
1452   "1 \<in> A \<Longrightarrow> Gcd A = 1"
1453   by (intro GcdI[symmetric]) (auto intro: Gcd_dvd dvd_Gcd)
1455 lemma Gcd_insert [simp]:
1456   "Gcd (insert a A) = gcd a (Gcd A)"
1457 proof (rule gcdI)
1458   fix l assume "l dvd a" and "l dvd Gcd A"
1459   hence "\<forall>a\<in>A. l dvd a" by (blast intro: dvd_trans Gcd_dvd)
1460   with \<open>l dvd a\<close> show "l dvd Gcd (insert a A)" by (force intro: Gcd_dvd)
1461 qed auto
1463 lemma Gcd_finite:
1464   assumes "finite A"
1465   shows "Gcd A = Finite_Set.fold gcd 0 A"
1466   by (induct rule: finite.induct[OF \<open>finite A\<close>])
1467     (simp_all add: comp_fun_idem.fold_insert_idem[OF comp_fun_idem_gcd])
1469 lemma Gcd_set [code_unfold]:
1470   "Gcd (set xs) = fold gcd xs 0"
1471   using comp_fun_idem.fold_set_fold[OF comp_fun_idem_gcd] Gcd_finite by (simp add: ac_simps)
1473 lemma Gcd_singleton [simp]: "Gcd {a} = a div normalization_factor a"
1474   by (simp add: gcd_0)
1476 lemma Gcd_2 [simp]: "Gcd {a,b} = gcd a b"
1477   by (simp only: Gcd_insert Gcd_empty gcd_0) (cases "b = 0", simp, rule gcd_div_unit2, simp)
1479 subclass semiring_gcd
1480   by unfold_locales (simp_all add: gcd_greatest_iff)
1482 end
1484 text \<open>
1485   A Euclidean ring is a Euclidean semiring with additive inverses. It provides a
1486   few more lemmas; in particular, Bezout's lemma holds for any Euclidean ring.
1487 \<close>
1489 class euclidean_ring_gcd = euclidean_semiring_gcd + idom
1490 begin
1492 subclass euclidean_ring ..
1494 subclass ring_gcd ..
1496 lemma euclid_ext_gcd [simp]:
1497   "(case euclid_ext a b of (_, _ , t) \<Rightarrow> t) = gcd a b"
1498   by (induct a b rule: gcd_eucl_induct)
1499     (simp_all add: euclid_ext_0 gcd_0 euclid_ext_non_0 ac_simps split: prod.split prod.split_asm)
1501 lemma euclid_ext_gcd' [simp]:
1502   "euclid_ext a b = (r, s, t) \<Longrightarrow> t = gcd a b"
1503   by (insert euclid_ext_gcd[of a b], drule (1) subst, simp)
1505 lemma euclid_ext'_correct:
1506   "fst (euclid_ext' a b) * a + snd (euclid_ext' a b) * b = gcd a b"
1507 proof-
1508   obtain s t c where "euclid_ext a b = (s,t,c)"
1509     by (cases "euclid_ext a b", blast)
1510   with euclid_ext_correct[of a b] euclid_ext_gcd[of a b]
1511     show ?thesis unfolding euclid_ext'_def by simp
1512 qed
1514 lemma bezout: "\<exists>s t. s * a + t * b = gcd a b"
1515   using euclid_ext'_correct by blast
1517 lemma gcd_neg1 [simp]:
1518   "gcd (-a) b = gcd a b"
1519   by (rule sym, rule gcdI, simp_all add: gcd_greatest)
1521 lemma gcd_neg2 [simp]:
1522   "gcd a (-b) = gcd a b"
1523   by (rule sym, rule gcdI, simp_all add: gcd_greatest)
1525 lemma gcd_neg_numeral_1 [simp]:
1526   "gcd (- numeral n) a = gcd (numeral n) a"
1527   by (fact gcd_neg1)
1529 lemma gcd_neg_numeral_2 [simp]:
1530   "gcd a (- numeral n) = gcd a (numeral n)"
1531   by (fact gcd_neg2)
1533 lemma gcd_diff1: "gcd (m - n) n = gcd m n"
1534   by (subst diff_conv_add_uminus, subst gcd_neg2[symmetric],  subst gcd_add1, simp)
1536 lemma gcd_diff2: "gcd (n - m) n = gcd m n"
1537   by (subst gcd_neg1[symmetric], simp only: minus_diff_eq gcd_diff1)
1539 lemma coprime_minus_one [simp]: "gcd (n - 1) n = 1"
1540 proof -
1541   have "gcd (n - 1) n = gcd n (n - 1)" by (fact gcd.commute)
1542   also have "\<dots> = gcd ((n - 1) + 1) (n - 1)" by simp
1543   also have "\<dots> = 1" by (rule coprime_plus_one)
1544   finally show ?thesis .
1545 qed
1547 lemma lcm_neg1 [simp]: "lcm (-a) b = lcm a b"
1548   by (rule sym, rule lcmI, simp_all add: lcm_least lcm_zero)
1550 lemma lcm_neg2 [simp]: "lcm a (-b) = lcm a b"
1551   by (rule sym, rule lcmI, simp_all add: lcm_least lcm_zero)
1553 lemma lcm_neg_numeral_1 [simp]: "lcm (- numeral n) a = lcm (numeral n) a"
1554   by (fact lcm_neg1)
1556 lemma lcm_neg_numeral_2 [simp]: "lcm a (- numeral n) = lcm a (numeral n)"
1557   by (fact lcm_neg2)
1559 end
1562 subsection \<open>Typical instances\<close>
1564 instantiation nat :: euclidean_semiring
1565 begin
1567 definition [simp]:
1568   "euclidean_size_nat = (id :: nat \<Rightarrow> nat)"
1570 definition [simp]:
1571   "normalization_factor_nat (n::nat) = (if n = 0 then 0 else 1 :: nat)"
1573 instance proof
1574 qed simp_all
1576 end
1578 instantiation int :: euclidean_ring
1579 begin
1581 definition [simp]:
1582   "euclidean_size_int = (nat \<circ> abs :: int \<Rightarrow> nat)"
1584 definition [simp]:
1585   "normalization_factor_int = (sgn :: int \<Rightarrow> int)"
1587 instance
1588 proof (default, goals)
1589   case 2
1590   then show ?case by (auto simp add: abs_mult nat_mult_distrib)
1591 next
1592   case 3
1593   then show ?case by (simp add: zsgn_def)
1594 next
1595   case 5
1596   then show ?case by (auto simp: zsgn_def)
1597 next
1598   case 6
1599   then show ?case by (auto split: abs_split simp: zsgn_def)
1600 qed (auto simp: sgn_times split: abs_split)
1602 end
1604 instantiation poly :: (field) euclidean_ring
1605 begin
1607 definition euclidean_size_poly :: "'a poly \<Rightarrow> nat"
1608   where "euclidean_size = (degree :: 'a poly \<Rightarrow> nat)"
1610 definition normalization_factor_poly :: "'a poly \<Rightarrow> 'a poly"
1611   where "normalization_factor p = monom (coeff p (degree p)) 0"
1613 instance
1614 proof (default, unfold euclidean_size_poly_def normalization_factor_poly_def)
1615   fix p q :: "'a poly"
1616   assume "q \<noteq> 0" and "\<not> q dvd p"
1617   then show "degree (p mod q) < degree q"
1618     using degree_mod_less [of q p] by (simp add: mod_eq_0_iff_dvd)
1619 next
1620   fix p q :: "'a poly"
1621   assume "q \<noteq> 0"
1622   from \<open>q \<noteq> 0\<close> show "degree p \<le> degree (p * q)"
1623     by (rule degree_mult_right_le)
1624   from \<open>q \<noteq> 0\<close> show "is_unit (monom (coeff q (degree q)) 0)"
1625     by (auto intro: is_unit_monom_0)
1626 next
1627   fix p :: "'a poly"
1628   show "monom (coeff p (degree p)) 0 = p" if "is_unit p"
1629     using that by (fact is_unit_monom_trival)
1630 next
1631   fix p q :: "'a poly"
1632   show "monom (coeff (p * q) (degree (p * q))) 0 =
1633     monom (coeff p (degree p)) 0 * monom (coeff q (degree q)) 0"
1634     by (simp add: monom_0 coeff_degree_mult)
1635 next
1636   show "monom (coeff 0 (degree 0)) 0 = 0"
1637     by simp
1638 qed
1640 end
1642 end