src/HOL/Algebra/UnivPoly.thy
author ballarin
Wed Aug 17 17:02:16 2005 +0200 (2005-08-17)
changeset 17094 7a3c2efecffe
parent 16639 5a89d3622ac0
child 19582 a669c98b9c24
permissions -rw-r--r--
Use interpretation in locales.
     1 (*
     2   Title:     HOL/Algebra/UnivPoly.thy
     3   Id:        $Id$
     4   Author:    Clemens Ballarin, started 9 December 1996
     5   Copyright: Clemens Ballarin
     6 *)
     7 
     8 header {* Univariate Polynomials *}
     9 
    10 theory UnivPoly imports Module begin
    11 
    12 text {*
    13   Polynomials are formalised as modules with additional operations for
    14   extracting coefficients from polynomials and for obtaining monomials
    15   from coefficients and exponents (record @{text "up_ring"}).  The
    16   carrier set is a set of bounded functions from Nat to the
    17   coefficient domain.  Bounded means that these functions return zero
    18   above a certain bound (the degree).  There is a chapter on the
    19   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},
    20   which was implemented with axiomatic type classes.  This was later
    21   ported to Locales.
    22 *}
    23 
    24 
    25 subsection {* The Constructor for Univariate Polynomials *}
    26 
    27 text {*
    28   Functions with finite support.
    29 *}
    30 
    31 locale bound =
    32   fixes z :: 'a
    33     and n :: nat
    34     and f :: "nat => 'a"
    35   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    36 
    37 declare bound.intro [intro!]
    38   and bound.bound [dest]
    39 
    40 lemma bound_below:
    41   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    42 proof (rule classical)
    43   assume "~ ?thesis"
    44   then have "m < n" by arith
    45   with bound have "f n = z" ..
    46   with nonzero show ?thesis by contradiction
    47 qed
    48 
    49 record ('a, 'p) up_ring = "('a, 'p) module" +
    50   monom :: "['a, nat] => 'p"
    51   coeff :: "['p, nat] => 'a"
    52 
    53 constdefs (structure R)
    54   up :: "('a, 'm) ring_scheme => (nat => 'a) set"
    55   "up R == {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero> n f)}"
    56   UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"
    57   "UP R == (|
    58     carrier = up R,
    59     mult = (%p:up R. %q:up R. %n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)),
    60     one = (%i. if i=0 then \<one> else \<zero>),
    61     zero = (%i. \<zero>),
    62     add = (%p:up R. %q:up R. %i. p i \<oplus> q i),
    63     smult = (%a:carrier R. %p:up R. %i. a \<otimes> p i),
    64     monom = (%a:carrier R. %n i. if i=n then a else \<zero>),
    65     coeff = (%p:up R. %n. p n) |)"
    66 
    67 text {*
    68   Properties of the set of polynomials @{term up}.
    69 *}
    70 
    71 lemma mem_upI [intro]:
    72   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"
    73   by (simp add: up_def Pi_def)
    74 
    75 lemma mem_upD [dest]:
    76   "f \<in> up R ==> f n \<in> carrier R"
    77   by (simp add: up_def Pi_def)
    78 
    79 lemma (in cring) bound_upD [dest]:
    80   "f \<in> up R ==> EX n. bound \<zero> n f"
    81   by (simp add: up_def)
    82 
    83 lemma (in cring) up_one_closed:
    84    "(%n. if n = 0 then \<one> else \<zero>) \<in> up R"
    85   using up_def by force
    86 
    87 lemma (in cring) up_smult_closed:
    88   "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R"
    89   by force
    90 
    91 lemma (in cring) up_add_closed:
    92   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"
    93 proof
    94   fix n
    95   assume "p \<in> up R" and "q \<in> up R"
    96   then show "p n \<oplus> q n \<in> carrier R"
    97     by auto
    98 next
    99   assume UP: "p \<in> up R" "q \<in> up R"
   100   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"
   101   proof -
   102     from UP obtain n where boundn: "bound \<zero> n p" by fast
   103     from UP obtain m where boundm: "bound \<zero> m q" by fast
   104     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"
   105     proof
   106       fix i
   107       assume "max n m < i"
   108       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp
   109     qed
   110     then show ?thesis ..
   111   qed
   112 qed
   113 
   114 lemma (in cring) up_a_inv_closed:
   115   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"
   116 proof
   117   assume R: "p \<in> up R"
   118   then obtain n where "bound \<zero> n p" by auto
   119   then have "bound \<zero> n (%i. \<ominus> p i)" by auto
   120   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto
   121 qed auto
   122 
   123 lemma (in cring) up_mult_closed:
   124   "[| p \<in> up R; q \<in> up R |] ==>
   125   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   126 proof
   127   fix n
   128   assume "p \<in> up R" "q \<in> up R"
   129   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   130     by (simp add: mem_upD  funcsetI)
   131 next
   132   assume UP: "p \<in> up R" "q \<in> up R"
   133   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   134   proof -
   135     from UP obtain n where boundn: "bound \<zero> n p" by fast
   136     from UP obtain m where boundm: "bound \<zero> m q" by fast
   137     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   138     proof
   139       fix k assume bound: "n + m < k"
   140       {
   141         fix i
   142         have "p i \<otimes> q (k-i) = \<zero>"
   143         proof (cases "n < i")
   144           case True
   145           with boundn have "p i = \<zero>" by auto
   146           moreover from UP have "q (k-i) \<in> carrier R" by auto
   147           ultimately show ?thesis by simp
   148         next
   149           case False
   150           with bound have "m < k-i" by arith
   151           with boundm have "q (k-i) = \<zero>" by auto
   152           moreover from UP have "p i \<in> carrier R" by auto
   153           ultimately show ?thesis by simp
   154         qed
   155       }
   156       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   157         by (simp add: Pi_def)
   158     qed
   159     then show ?thesis by fast
   160   qed
   161 qed
   162 
   163 
   164 subsection {* Effect of operations on coefficients *}
   165 
   166 locale UP = struct R + struct P +
   167   defines P_def: "P == UP R"
   168 
   169 locale UP_cring = UP + cring R
   170 
   171 locale UP_domain = UP_cring + "domain" R
   172 
   173 text {*
   174   Temporarily declare @{thm [locale=UP] P_def} as simp rule.
   175 *}
   176 
   177 declare (in UP) P_def [simp]
   178 
   179 lemma (in UP_cring) coeff_monom [simp]:
   180   "a \<in> carrier R ==>
   181   coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   182 proof -
   183   assume R: "a \<in> carrier R"
   184   then have "(%n. if n = m then a else \<zero>) \<in> up R"
   185     using up_def by force
   186   with R show ?thesis by (simp add: UP_def)
   187 qed
   188 
   189 lemma (in UP_cring) coeff_zero [simp]:
   190   "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>"
   191   by (auto simp add: UP_def)
   192 
   193 lemma (in UP_cring) coeff_one [simp]:
   194   "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"
   195   using up_one_closed by (simp add: UP_def)
   196 
   197 lemma (in UP_cring) coeff_smult [simp]:
   198   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   199   coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"
   200   by (simp add: UP_def up_smult_closed)
   201 
   202 lemma (in UP_cring) coeff_add [simp]:
   203   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   204   coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"
   205   by (simp add: UP_def up_add_closed)
   206 
   207 lemma (in UP_cring) coeff_mult [simp]:
   208   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   209   coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   210   by (simp add: UP_def up_mult_closed)
   211 
   212 lemma (in UP) up_eqI:
   213   assumes prem: "!!n. coeff P p n = coeff P q n"
   214     and R: "p \<in> carrier P" "q \<in> carrier P"
   215   shows "p = q"
   216 proof
   217   fix x
   218   from prem and R show "p x = q x" by (simp add: UP_def)
   219 qed
   220 
   221 subsection {* Polynomials form a commutative ring. *}
   222 
   223 text {* Operations are closed over @{term P}. *}
   224 
   225 lemma (in UP_cring) UP_mult_closed [simp]:
   226   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P"
   227   by (simp add: UP_def up_mult_closed)
   228 
   229 lemma (in UP_cring) UP_one_closed [simp]:
   230   "\<one>\<^bsub>P\<^esub> \<in> carrier P"
   231   by (simp add: UP_def up_one_closed)
   232 
   233 lemma (in UP_cring) UP_zero_closed [intro, simp]:
   234   "\<zero>\<^bsub>P\<^esub> \<in> carrier P"
   235   by (auto simp add: UP_def)
   236 
   237 lemma (in UP_cring) UP_a_closed [intro, simp]:
   238   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P"
   239   by (simp add: UP_def up_add_closed)
   240 
   241 lemma (in UP_cring) monom_closed [simp]:
   242   "a \<in> carrier R ==> monom P a n \<in> carrier P"
   243   by (auto simp add: UP_def up_def Pi_def)
   244 
   245 lemma (in UP_cring) UP_smult_closed [simp]:
   246   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P"
   247   by (simp add: UP_def up_smult_closed)
   248 
   249 lemma (in UP) coeff_closed [simp]:
   250   "p \<in> carrier P ==> coeff P p n \<in> carrier R"
   251   by (auto simp add: UP_def)
   252 
   253 declare (in UP) P_def [simp del]
   254 
   255 text {* Algebraic ring properties *}
   256 
   257 lemma (in UP_cring) UP_a_assoc:
   258   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   259   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)"
   260   by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   261 
   262 lemma (in UP_cring) UP_l_zero [simp]:
   263   assumes R: "p \<in> carrier P"
   264   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p"
   265   by (rule up_eqI, simp_all add: R)
   266 
   267 lemma (in UP_cring) UP_l_neg_ex:
   268   assumes R: "p \<in> carrier P"
   269   shows "EX q : carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   270 proof -
   271   let ?q = "%i. \<ominus> (p i)"
   272   from R have closed: "?q \<in> carrier P"
   273     by (simp add: UP_def P_def up_a_inv_closed)
   274   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   275     by (simp add: UP_def P_def up_a_inv_closed)
   276   show ?thesis
   277   proof
   278     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   279       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   280   qed (rule closed)
   281 qed
   282 
   283 lemma (in UP_cring) UP_a_comm:
   284   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   285   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p"
   286   by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   287 
   288 lemma (in UP_cring) UP_m_assoc:
   289   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   290   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   291 proof (rule up_eqI)
   292   fix n
   293   {
   294     fix k and a b c :: "nat=>'a"
   295     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   296       "c \<in> UNIV -> carrier R"
   297     then have "k <= n ==>
   298       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   299       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   300       (concl is "?eq k")
   301     proof (induct k)
   302       case 0 then show ?case by (simp add: Pi_def m_assoc)
   303     next
   304       case (Suc k)
   305       then have "k <= n" by arith
   306       then have "?eq k" by (rule Suc)
   307       with R show ?case
   308         by (simp cong: finsum_cong
   309              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   310           (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   311     qed
   312   }
   313   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"
   314     by (simp add: Pi_def)
   315 qed (simp_all add: R)
   316 
   317 lemma (in UP_cring) UP_l_one [simp]:
   318   assumes R: "p \<in> carrier P"
   319   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"
   320 proof (rule up_eqI)
   321   fix n
   322   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"
   323   proof (cases n)
   324     case 0 with R show ?thesis by simp
   325   next
   326     case Suc with R show ?thesis
   327       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   328   qed
   329 qed (simp_all add: R)
   330 
   331 lemma (in UP_cring) UP_l_distr:
   332   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   333   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   334   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   335 
   336 lemma (in UP_cring) UP_m_comm:
   337   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   338   shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"
   339 proof (rule up_eqI)
   340   fix n
   341   {
   342     fix k and a b :: "nat=>'a"
   343     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   344     then have "k <= n ==>
   345       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) =
   346       (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   347       (concl is "?eq k")
   348     proof (induct k)
   349       case 0 then show ?case by (simp add: Pi_def)
   350     next
   351       case (Suc k) then show ?case
   352         by (subst (2) finsum_Suc2) (simp add: Pi_def a_comm)+
   353     qed
   354   }
   355   note l = this
   356   from R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"
   357     apply (simp add: Pi_def)
   358     apply (subst l)
   359     apply (auto simp add: Pi_def)
   360     apply (simp add: m_comm)
   361     done
   362 qed (simp_all add: R)
   363 
   364 theorem (in UP_cring) UP_cring:
   365   "cring P"
   366   by (auto intro!: cringI abelian_groupI comm_monoidI UP_a_assoc UP_l_zero
   367     UP_l_neg_ex UP_a_comm UP_m_assoc UP_l_one UP_m_comm UP_l_distr)
   368 
   369 lemma (in UP_cring) UP_ring:
   370   (* preliminary,
   371      we want "UP_ring R P ==> ring P", not "UP_cring R P ==> ring P" *)
   372   "ring P"
   373   by (auto intro: ring.intro cring.axioms UP_cring)
   374 
   375 lemma (in UP_cring) UP_a_inv_closed [intro, simp]:
   376   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"
   377   by (rule abelian_group.a_inv_closed
   378     [OF ring.is_abelian_group [OF UP_ring]])
   379 
   380 lemma (in UP_cring) coeff_a_inv [simp]:
   381   assumes R: "p \<in> carrier P"
   382   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"
   383 proof -
   384   from R coeff_closed UP_a_inv_closed have
   385     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"
   386     by algebra
   387   also from R have "... =  \<ominus> (coeff P p n)"
   388     by (simp del: coeff_add add: coeff_add [THEN sym]
   389       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   390   finally show ?thesis .
   391 qed
   392 
   393 text {*
   394   Interpretation of lemmas from @{term cring}.  Saves lifting 43
   395   lemmas manually.
   396 *}
   397 
   398 interpretation UP_cring < cring P
   399   using UP_cring
   400   by - (erule cring.axioms)+
   401 
   402 
   403 subsection {* Polynomials form an Algebra *}
   404 
   405 lemma (in UP_cring) UP_smult_l_distr:
   406   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   407   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"
   408   by (rule up_eqI) (simp_all add: R.l_distr)
   409 
   410 lemma (in UP_cring) UP_smult_r_distr:
   411   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   412   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"
   413   by (rule up_eqI) (simp_all add: R.r_distr)
   414 
   415 lemma (in UP_cring) UP_smult_assoc1:
   416       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   417       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"
   418   by (rule up_eqI) (simp_all add: R.m_assoc)
   419 
   420 lemma (in UP_cring) UP_smult_one [simp]:
   421       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"
   422   by (rule up_eqI) simp_all
   423 
   424 lemma (in UP_cring) UP_smult_assoc2:
   425   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   426   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"
   427   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   428 
   429 text {*
   430   Interpretation of lemmas from @{term algebra}.
   431 *}
   432 
   433 lemma (in cring) cring:
   434   "cring R"
   435   by (fast intro: cring.intro prems)
   436 
   437 lemma (in UP_cring) UP_algebra:
   438   "algebra R P"
   439   by (auto intro: algebraI R.cring UP_cring UP_smult_l_distr UP_smult_r_distr
   440     UP_smult_assoc1 UP_smult_assoc2)
   441 
   442 interpretation UP_cring < algebra R P
   443   using UP_algebra
   444   by - (erule algebra.axioms)+
   445 
   446 
   447 subsection {* Further lemmas involving monomials *}
   448 
   449 lemma (in UP_cring) monom_zero [simp]:
   450   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>"
   451   by (simp add: UP_def P_def)
   452 
   453 lemma (in UP_cring) monom_mult_is_smult:
   454   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   455   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"
   456 proof (rule up_eqI)
   457   fix n
   458   have "coeff P (p \<otimes>\<^bsub>P\<^esub> monom P a 0) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   459   proof (cases n)
   460     case 0 with R show ?thesis by (simp add: R.m_comm)
   461   next
   462     case Suc with R show ?thesis
   463       by (simp cong: R.finsum_cong add: R.r_null Pi_def)
   464         (simp add: R.m_comm)
   465   qed
   466   with R show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   467     by (simp add: UP_m_comm)
   468 qed (simp_all add: R)
   469 
   470 lemma (in UP_cring) monom_add [simp]:
   471   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   472   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"
   473   by (rule up_eqI) simp_all
   474 
   475 lemma (in UP_cring) monom_one_Suc:
   476   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   477 proof (rule up_eqI)
   478   fix k
   479   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   480   proof (cases "k = Suc n")
   481     case True show ?thesis
   482     proof -
   483       from True have less_add_diff:
   484         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   485       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   486       also from True
   487       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   488         coeff P (monom P \<one> 1) (k - i))"
   489         by (simp cong: R.finsum_cong add: Pi_def)
   490       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   491         coeff P (monom P \<one> 1) (k - i))"
   492         by (simp only: ivl_disj_un_singleton)
   493       also from True
   494       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   495         coeff P (monom P \<one> 1) (k - i))"
   496         by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   497           order_less_imp_not_eq Pi_def)
   498       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   499         by (simp add: ivl_disj_un_one)
   500       finally show ?thesis .
   501     qed
   502   next
   503     case False
   504     note neq = False
   505     let ?s =
   506       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   507     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   508     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   509     proof -
   510       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"
   511         by (simp cong: R.finsum_cong add: Pi_def)
   512       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   513         by (simp cong: R.finsum_cong add: Pi_def) arith
   514       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   515         by (simp cong: R.finsum_cong add: order_less_imp_not_eq Pi_def)
   516       show ?thesis
   517       proof (cases "k < n")
   518         case True then show ?thesis by (simp cong: R.finsum_cong add: Pi_def)
   519       next
   520         case False then have n_le_k: "n <= k" by arith
   521         show ?thesis
   522         proof (cases "n = k")
   523           case True
   524           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   525             by (simp cong: R.finsum_cong add: ivl_disj_int_singleton Pi_def)
   526           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   527             by (simp only: ivl_disj_un_singleton)
   528           finally show ?thesis .
   529         next
   530           case False with n_le_k have n_less_k: "n < k" by arith
   531           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   532             by (simp add: R.finsum_Un_disjoint f1 f2
   533               ivl_disj_int_singleton Pi_def del: Un_insert_right)
   534           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   535             by (simp only: ivl_disj_un_singleton)
   536           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   537             by (simp add: R.finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   538           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   539             by (simp only: ivl_disj_un_one)
   540           finally show ?thesis .
   541         qed
   542       qed
   543     qed
   544     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp
   545     finally show ?thesis .
   546   qed
   547 qed (simp_all)
   548 
   549 lemma (in UP_cring) monom_mult_smult:
   550   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"
   551   by (rule up_eqI) simp_all
   552 
   553 lemma (in UP_cring) monom_one [simp]:
   554   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"
   555   by (rule up_eqI) simp_all
   556 
   557 lemma (in UP_cring) monom_one_mult:
   558   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"
   559 proof (induct n)
   560   case 0 show ?case by simp
   561 next
   562   case Suc then show ?case
   563     by (simp only: add_Suc monom_one_Suc) (simp add: P.m_ac)
   564 qed
   565 
   566 lemma (in UP_cring) monom_mult [simp]:
   567   assumes R: "a \<in> carrier R" "b \<in> carrier R"
   568   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"
   569 proof -
   570   from R have "monom P (a \<otimes> b) (n + m) = monom P (a \<otimes> b \<otimes> \<one>) (n + m)" by simp
   571   also from R have "... = a \<otimes> b \<odot>\<^bsub>P\<^esub> monom P \<one> (n + m)"
   572     by (simp add: monom_mult_smult del: R.r_one)
   573   also have "... = a \<otimes> b \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m)"
   574     by (simp only: monom_one_mult)
   575   also from R have "... = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m))"
   576     by (simp add: UP_smult_assoc1)
   577   also from R have "... = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> (monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n))"
   578     by (simp add: P.m_comm)
   579   also from R have "... = a \<odot>\<^bsub>P\<^esub> ((b \<odot>\<^bsub>P\<^esub> monom P \<one> m) \<otimes>\<^bsub>P\<^esub> monom P \<one> n)"
   580     by (simp add: UP_smult_assoc2)
   581   also from R have "... = a \<odot>\<^bsub>P\<^esub> (monom P \<one> n \<otimes>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> monom P \<one> m))"
   582     by (simp add: P.m_comm)
   583   also from R have "... = (a \<odot>\<^bsub>P\<^esub> monom P \<one> n) \<otimes>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> monom P \<one> m)"
   584     by (simp add: UP_smult_assoc2)
   585   also from R have "... = monom P (a \<otimes> \<one>) n \<otimes>\<^bsub>P\<^esub> monom P (b \<otimes> \<one>) m"
   586     by (simp add: monom_mult_smult del: R.r_one)
   587   also from R have "... = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m" by simp
   588   finally show ?thesis .
   589 qed
   590 
   591 lemma (in UP_cring) monom_a_inv [simp]:
   592   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"
   593   by (rule up_eqI) simp_all
   594 
   595 lemma (in UP_cring) monom_inj:
   596   "inj_on (%a. monom P a n) (carrier R)"
   597 proof (rule inj_onI)
   598   fix x y
   599   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   600   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   601   with R show "x = y" by simp
   602 qed
   603 
   604 
   605 subsection {* The degree function *}
   606 
   607 constdefs (structure R)
   608   deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"
   609   "deg R p == LEAST n. bound \<zero> n (coeff (UP R) p)"
   610 
   611 lemma (in UP_cring) deg_aboveI:
   612   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   613   by (unfold deg_def P_def) (fast intro: Least_le)
   614 
   615 (*
   616 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   617 proof -
   618   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   619   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   620   then show ?thesis ..
   621 qed
   622 
   623 lemma bound_coeff_obtain:
   624   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   625 proof -
   626   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   627   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   628   with prem show P .
   629 qed
   630 *)
   631 
   632 lemma (in UP_cring) deg_aboveD:
   633   "[| deg R p < m; p \<in> carrier P |] ==> coeff P p m = \<zero>"
   634 proof -
   635   assume R: "p \<in> carrier P" and "deg R p < m"
   636   from R obtain n where "bound \<zero> n (coeff P p)"
   637     by (auto simp add: UP_def P_def)
   638   then have "bound \<zero> (deg R p) (coeff P p)"
   639     by (auto simp: deg_def P_def dest: LeastI)
   640   then show ?thesis ..
   641 qed
   642 
   643 lemma (in UP_cring) deg_belowI:
   644   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"
   645     and R: "p \<in> carrier P"
   646   shows "n <= deg R p"
   647 -- {* Logically, this is a slightly stronger version of
   648    @{thm [source] deg_aboveD} *}
   649 proof (cases "n=0")
   650   case True then show ?thesis by simp
   651 next
   652   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)
   653   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)
   654   then show ?thesis by arith
   655 qed
   656 
   657 lemma (in UP_cring) lcoeff_nonzero_deg:
   658   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"
   659   shows "coeff P p (deg R p) ~= \<zero>"
   660 proof -
   661   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"
   662   proof -
   663     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"
   664       by arith
   665 (* TODO: why does simplification below not work with "1" *)
   666     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   667       by (unfold deg_def P_def) arith
   668     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   669     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"
   670       by (unfold bound_def) fast
   671     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)
   672     then show ?thesis by auto
   673   qed
   674   with deg_belowI R have "deg R p = m" by fastsimp
   675   with m_coeff show ?thesis by simp
   676 qed
   677 
   678 lemma (in UP_cring) lcoeff_nonzero_nonzero:
   679   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   680   shows "coeff P p 0 ~= \<zero>"
   681 proof -
   682   have "EX m. coeff P p m ~= \<zero>"
   683   proof (rule classical)
   684     assume "~ ?thesis"
   685     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)
   686     with nonzero show ?thesis by contradiction
   687   qed
   688   then obtain m where coeff: "coeff P p m ~= \<zero>" ..
   689   then have "m <= deg R p" by (rule deg_belowI)
   690   then have "m = 0" by (simp add: deg)
   691   with coeff show ?thesis by simp
   692 qed
   693 
   694 lemma (in UP_cring) lcoeff_nonzero:
   695   assumes neq: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   696   shows "coeff P p (deg R p) ~= \<zero>"
   697 proof (cases "deg R p = 0")
   698   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   699 next
   700   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   701 qed
   702 
   703 lemma (in UP_cring) deg_eqI:
   704   "[| !!m. n < m ==> coeff P p m = \<zero>;
   705       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"
   706 by (fast intro: le_anti_sym deg_aboveI deg_belowI)
   707 
   708 text {* Degree and polynomial operations *}
   709 
   710 lemma (in UP_cring) deg_add [simp]:
   711   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   712   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) <= max (deg R p) (deg R q)"
   713 proof (cases "deg R p <= deg R q")
   714   case True show ?thesis
   715     by (rule deg_aboveI) (simp_all add: True R deg_aboveD)
   716 next
   717   case False show ?thesis
   718     by (rule deg_aboveI) (simp_all add: False R deg_aboveD)
   719 qed
   720 
   721 lemma (in UP_cring) deg_monom_le:
   722   "a \<in> carrier R ==> deg R (monom P a n) <= n"
   723   by (intro deg_aboveI) simp_all
   724 
   725 lemma (in UP_cring) deg_monom [simp]:
   726   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   727   by (fastsimp intro: le_anti_sym deg_aboveI deg_belowI)
   728 
   729 lemma (in UP_cring) deg_const [simp]:
   730   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   731 proof (rule le_anti_sym)
   732   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)
   733 next
   734   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   735 qed
   736 
   737 lemma (in UP_cring) deg_zero [simp]:
   738   "deg R \<zero>\<^bsub>P\<^esub> = 0"
   739 proof (rule le_anti_sym)
   740   show "deg R \<zero>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   741 next
   742   show "0 <= deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   743 qed
   744 
   745 lemma (in UP_cring) deg_one [simp]:
   746   "deg R \<one>\<^bsub>P\<^esub> = 0"
   747 proof (rule le_anti_sym)
   748   show "deg R \<one>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   749 next
   750   show "0 <= deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   751 qed
   752 
   753 lemma (in UP_cring) deg_uminus [simp]:
   754   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"
   755 proof (rule le_anti_sym)
   756   show "deg R (\<ominus>\<^bsub>P\<^esub> p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)
   757 next
   758   show "deg R p <= deg R (\<ominus>\<^bsub>P\<^esub> p)"
   759     by (simp add: deg_belowI lcoeff_nonzero_deg
   760       inj_on_iff [OF R.a_inv_inj, of _ "\<zero>", simplified] R)
   761 qed
   762 
   763 lemma (in UP_domain) deg_smult_ring:
   764   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   765   deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   766   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   767 
   768 lemma (in UP_domain) deg_smult [simp]:
   769   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   770   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"
   771 proof (rule le_anti_sym)
   772   show "deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   773     by (rule deg_smult_ring)
   774 next
   775   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^bsub>P\<^esub> p)"
   776   proof (cases "a = \<zero>")
   777   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   778 qed
   779 
   780 lemma (in UP_cring) deg_mult_cring:
   781   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   782   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q"
   783 proof (rule deg_aboveI)
   784   fix m
   785   assume boundm: "deg R p + deg R q < m"
   786   {
   787     fix k i
   788     assume boundk: "deg R p + deg R q < k"
   789     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   790     proof (cases "deg R p < i")
   791       case True then show ?thesis by (simp add: deg_aboveD R)
   792     next
   793       case False with boundk have "deg R q < k - i" by arith
   794       then show ?thesis by (simp add: deg_aboveD R)
   795     qed
   796   }
   797   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp
   798 qed (simp add: R)
   799 
   800 lemma (in UP_domain) deg_mult [simp]:
   801   "[| p ~= \<zero>\<^bsub>P\<^esub>; q ~= \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>
   802   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"
   803 proof (rule le_anti_sym)
   804   assume "p \<in> carrier P" " q \<in> carrier P"
   805   show "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q" by (rule deg_mult_cring)
   806 next
   807   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   808   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^bsub>P\<^esub>" "q ~= \<zero>\<^bsub>P\<^esub>"
   809   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   810   show "deg R p + deg R q <= deg R (p \<otimes>\<^bsub>P\<^esub> q)"
   811   proof (rule deg_belowI, simp add: R)
   812     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   813       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"
   814       by (simp only: ivl_disj_un_one)
   815     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"
   816       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   817         deg_aboveD less_add_diff R Pi_def)
   818     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"
   819       by (simp only: ivl_disj_un_singleton)
   820     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   821       by (simp cong: R.finsum_cong
   822 	add: ivl_disj_int_singleton deg_aboveD R Pi_def)
   823     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   824       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
   825     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) ~= \<zero>"
   826       by (simp add: integral_iff lcoeff_nonzero R)
   827     qed (simp add: R)
   828   qed
   829 
   830 lemma (in UP_cring) coeff_finsum:
   831   assumes fin: "finite A"
   832   shows "p \<in> A -> carrier P ==>
   833     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"
   834   using fin by induct (auto simp: Pi_def)
   835 
   836 lemma (in UP_cring) up_repr:
   837   assumes R: "p \<in> carrier P"
   838   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
   839 proof (rule up_eqI)
   840   let ?s = "(%i. monom P (coeff P p i) i)"
   841   fix k
   842   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
   843     by simp
   844   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"
   845   proof (cases "k <= deg R p")
   846     case True
   847     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   848           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"
   849       by (simp only: ivl_disj_un_one)
   850     also from True
   851     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"
   852       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint
   853         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
   854     also
   855     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"
   856       by (simp only: ivl_disj_un_singleton)
   857     also have "... = coeff P p k"
   858       by (simp cong: R.finsum_cong
   859 	add: ivl_disj_int_singleton coeff_finsum deg_aboveD R RR Pi_def)
   860     finally show ?thesis .
   861   next
   862     case False
   863     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   864           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"
   865       by (simp only: ivl_disj_un_singleton)
   866     also from False have "... = coeff P p k"
   867       by (simp cong: R.finsum_cong
   868 	add: ivl_disj_int_singleton coeff_finsum deg_aboveD R Pi_def)
   869     finally show ?thesis .
   870   qed
   871 qed (simp_all add: R Pi_def)
   872 
   873 lemma (in UP_cring) up_repr_le:
   874   "[| deg R p <= n; p \<in> carrier P |] ==>
   875   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"
   876 proof -
   877   let ?s = "(%i. monom P (coeff P p i) i)"
   878   assume R: "p \<in> carrier P" and "deg R p <= n"
   879   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"
   880     by (simp only: ivl_disj_un_one)
   881   also have "... = finsum P ?s {..deg R p}"
   882     by (simp cong: P.finsum_cong add: P.finsum_Un_disjoint ivl_disj_int_one
   883       deg_aboveD R Pi_def)
   884   also have "... = p" by (rule up_repr)
   885   finally show ?thesis .
   886 qed
   887 
   888 
   889 subsection {* Polynomials over an integral domain form an integral domain *}
   890 
   891 lemma domainI:
   892   assumes cring: "cring R"
   893     and one_not_zero: "one R ~= zero R"
   894     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;
   895       b \<in> carrier R |] ==> a = zero R | b = zero R"
   896   shows "domain R"
   897   by (auto intro!: domain.intro domain_axioms.intro cring.axioms prems
   898     del: disjCI)
   899 
   900 lemma (in UP_domain) UP_one_not_zero:
   901   "\<one>\<^bsub>P\<^esub> ~= \<zero>\<^bsub>P\<^esub>"
   902 proof
   903   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"
   904   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp
   905   hence "\<one> = \<zero>" by simp
   906   with one_not_zero show "False" by contradiction
   907 qed
   908 
   909 lemma (in UP_domain) UP_integral:
   910   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
   911 proof -
   912   fix p q
   913   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"
   914   show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
   915   proof (rule classical)
   916     assume c: "~ (p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>)"
   917     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp
   918     also from pq have "... = 0" by simp
   919     finally have "deg R p + deg R q = 0" .
   920     then have f1: "deg R p = 0 & deg R q = 0" by simp
   921     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"
   922       by (simp only: up_repr_le)
   923     also from R have "... = monom P (coeff P p 0) 0" by simp
   924     finally have p: "p = monom P (coeff P p 0) 0" .
   925     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"
   926       by (simp only: up_repr_le)
   927     also from R have "... = monom P (coeff P q 0) 0" by simp
   928     finally have q: "q = monom P (coeff P q 0) 0" .
   929     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp
   930     also from pq have "... = \<zero>" by simp
   931     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
   932     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"
   933       by (simp add: R.integral_iff)
   934     with p q show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>" by fastsimp
   935   qed
   936 qed
   937 
   938 theorem (in UP_domain) UP_domain:
   939   "domain P"
   940   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
   941 
   942 text {*
   943   Interpretation of theorems from @{term domain}.
   944 *}
   945 
   946 interpretation UP_domain < "domain" P
   947   using UP_domain
   948   by (rule domain.axioms)
   949 
   950 
   951 subsection {* Evaluation Homomorphism and Universal Property*}
   952 
   953 (* alternative congruence rule (possibly more efficient)
   954 lemma (in abelian_monoid) finsum_cong2:
   955   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
   956   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
   957   sorry*)
   958 
   959 theorem (in cring) diagonal_sum:
   960   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>
   961   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
   962   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
   963 proof -
   964   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"
   965   {
   966     fix j
   967     have "j <= n + m ==>
   968       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
   969       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
   970     proof (induct j)
   971       case 0 from Rf Rg show ?case by (simp add: Pi_def)
   972     next
   973       case (Suc j)
   974       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
   975         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
   976       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
   977         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
   978       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
   979         using Suc by (auto intro!: funcset_mem [OF Rf])
   980       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
   981         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
   982       have R11: "g 0 \<in> carrier R"
   983         using Suc by (auto intro!: funcset_mem [OF Rg])
   984       from Suc show ?case
   985         by (simp cong: finsum_cong add: Suc_diff_le a_ac
   986           Pi_def R6 R8 R9 R10 R11)
   987     qed
   988   }
   989   then show ?thesis by fast
   990 qed
   991 
   992 lemma (in abelian_monoid) boundD_carrier:
   993   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
   994   by auto
   995 
   996 theorem (in cring) cauchy_product:
   997   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
   998     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"
   999   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1000     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"      (* State reverse direction? *)
  1001 proof -
  1002   have f: "!!x. f x \<in> carrier R"
  1003   proof -
  1004     fix x
  1005     show "f x \<in> carrier R"
  1006       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1007   qed
  1008   have g: "!!x. g x \<in> carrier R"
  1009   proof -
  1010     fix x
  1011     show "g x \<in> carrier R"
  1012       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1013   qed
  1014   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1015       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1016     by (simp add: diagonal_sum Pi_def)
  1017   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1018     by (simp only: ivl_disj_un_one)
  1019   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1020     by (simp cong: finsum_cong
  1021       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1022   also from f g
  1023   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1024     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1025   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1026     by (simp cong: finsum_cong
  1027       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1028   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1029     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1030       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1031   finally show ?thesis .
  1032 qed
  1033 
  1034 lemma (in UP_cring) const_ring_hom:
  1035   "(%a. monom P a 0) \<in> ring_hom R P"
  1036   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1037 
  1038 constdefs (structure S)
  1039   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,
  1040            'a => 'b, 'b, nat => 'a] => 'b"
  1041   "eval R S phi s == \<lambda>p \<in> carrier (UP R).
  1042     \<Oplus>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes> s (^) i"
  1043 
  1044 
  1045 lemma (in UP) eval_on_carrier:
  1046   includes struct S
  1047   shows "p \<in> carrier P ==>
  1048   eval R S phi s p = (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1049   by (unfold eval_def, fold P_def) simp
  1050 
  1051 lemma (in UP) eval_extensional:
  1052   "eval R S phi p \<in> extensional (carrier P)"
  1053   by (unfold eval_def, fold P_def) simp
  1054 
  1055 
  1056 text {* The universal property of the polynomial ring *}
  1057 
  1058 locale UP_pre_univ_prop = ring_hom_cring R S h + UP_cring R P
  1059 
  1060 locale UP_univ_prop = UP_pre_univ_prop + var s + var Eval +
  1061   assumes indet_img_carrier [simp, intro]: "s \<in> carrier S"
  1062   defines Eval_def: "Eval == eval R S h s"
  1063 
  1064 theorem (in UP_pre_univ_prop) eval_ring_hom:
  1065   assumes S: "s \<in> carrier S"
  1066   shows "eval R S h s \<in> ring_hom P S"
  1067 proof (rule ring_hom_memI)
  1068   fix p
  1069   assume R: "p \<in> carrier P"
  1070   then show "eval R S h s p \<in> carrier S"
  1071     by (simp only: eval_on_carrier) (simp add: S Pi_def)
  1072 next
  1073   fix p q
  1074   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1075   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1076   proof (simp only: eval_on_carrier UP_mult_closed)
  1077     from R S have
  1078       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1079       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.
  1080         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1081       by (simp cong: S.finsum_cong
  1082         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def
  1083         del: coeff_mult)
  1084     also from R have "... =
  1085       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1086       by (simp only: ivl_disj_un_one deg_mult_cring)
  1087     also from R S have "... =
  1088       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.
  1089          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.
  1090            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>
  1091            (s (^)\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> (i - k)))"
  1092       by (simp cong: S.finsum_cong add: S.nat_pow_mult Pi_def
  1093         S.m_ac S.finsum_rdistr)
  1094     also from R S have "... =
  1095       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1096       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1097       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1098         Pi_def)
  1099     finally show
  1100       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1101       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1102       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1103   qed
  1104 next
  1105   fix p q
  1106   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1107   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1108   proof (simp only: eval_on_carrier P.a_closed)
  1109     from S R have
  1110       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1111       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.
  1112         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1113       by (simp cong: S.finsum_cong
  1114         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def
  1115         del: coeff_add)
  1116     also from R have "... =
  1117         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.
  1118           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1119       by (simp add: ivl_disj_un_one)
  1120     also from R S have "... =
  1121       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1122       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1123       by (simp cong: S.finsum_cong
  1124         add: S.l_distr deg_aboveD ivl_disj_int_one Pi_def)
  1125     also have "... =
  1126         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1127           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1128         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1129           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1130       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)
  1131     also from R S have "... =
  1132       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1133       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1134       by (simp cong: S.finsum_cong
  1135         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1136     finally show
  1137       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1138       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1139       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1140   qed
  1141 next
  1142   show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1143     by (simp only: eval_on_carrier UP_one_closed) simp
  1144 qed
  1145 
  1146 text {* Interpretation of ring homomorphism lemmas. *}
  1147 
  1148 interpretation UP_univ_prop < ring_hom_cring P S Eval
  1149   by (unfold Eval_def)
  1150     (fast intro!: ring_hom_cring.intro UP_cring cring.axioms prems
  1151       intro: ring_hom_cring_axioms.intro eval_ring_hom)
  1152 
  1153 text {* Further properties of the evaluation homomorphism. *}
  1154 
  1155 (* The following lemma could be proved in UP\_cring with the additional
  1156    assumption that h is closed. *)
  1157 
  1158 lemma (in UP_pre_univ_prop) eval_const:
  1159   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1160   by (simp only: eval_on_carrier monom_closed) simp
  1161 
  1162 text {* The following proof is complicated by the fact that in arbitrary
  1163   rings one might have @{term "one R = zero R"}. *}
  1164 
  1165 (* TODO: simplify by cases "one R = zero R" *)
  1166 
  1167 lemma (in UP_pre_univ_prop) eval_monom1:
  1168   assumes S: "s \<in> carrier S"
  1169   shows "eval R S h s (monom P \<one> 1) = s"
  1170 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1171    from S have
  1172     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1173     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1174       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1175     by (simp cong: S.finsum_cong del: coeff_monom
  1176       add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1177   also have "... =
  1178     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1179     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1180   also have "... = s"
  1181   proof (cases "s = \<zero>\<^bsub>S\<^esub>")
  1182     case True then show ?thesis by (simp add: Pi_def)
  1183   next
  1184     case False then show ?thesis by (simp add: S Pi_def)
  1185   qed
  1186   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.
  1187     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) = s" .
  1188 qed
  1189 
  1190 lemma (in UP_cring) monom_pow:
  1191   assumes R: "a \<in> carrier R"
  1192   shows "(monom P a n) (^)\<^bsub>P\<^esub> m = monom P (a (^) m) (n * m)"
  1193 proof (induct m)
  1194   case 0 from R show ?case by simp
  1195 next
  1196   case Suc with R show ?case
  1197     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)
  1198 qed
  1199 
  1200 lemma (in ring_hom_cring) hom_pow [simp]:
  1201   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^bsub>S\<^esub> (n::nat)"
  1202   by (induct n) simp_all
  1203 
  1204 lemma (in UP_univ_prop) Eval_monom:
  1205   "r \<in> carrier R ==> Eval (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1206 proof -
  1207   assume R: "r \<in> carrier R"
  1208   from R have "Eval (monom P r n) = Eval (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) (^)\<^bsub>P\<^esub> n)"
  1209     by (simp del: monom_mult add: monom_mult [THEN sym] monom_pow)
  1210   also
  1211   from R eval_monom1 [where s = s, folded Eval_def]
  1212   have "... = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1213     by (simp add: eval_const [where s = s, folded Eval_def])
  1214   finally show ?thesis .
  1215 qed
  1216 
  1217 lemma (in UP_pre_univ_prop) eval_monom:
  1218   assumes R: "r \<in> carrier R" and S: "s \<in> carrier S"
  1219   shows "eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1220 proof -
  1221   from S interpret UP_univ_prop [R S h P s _]
  1222     by (auto intro!: UP_univ_prop_axioms.intro)
  1223   from R
  1224   show ?thesis by (rule Eval_monom)
  1225 qed
  1226 
  1227 lemma (in UP_univ_prop) Eval_smult:
  1228   "[| r \<in> carrier R; p \<in> carrier P |] ==> Eval (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> Eval p"
  1229 proof -
  1230   assume R: "r \<in> carrier R" and P: "p \<in> carrier P"
  1231   then show ?thesis
  1232     by (simp add: monom_mult_is_smult [THEN sym]
  1233       eval_const [where s = s, folded Eval_def])
  1234 qed
  1235 
  1236 lemma ring_hom_cringI:
  1237   assumes "cring R"
  1238     and "cring S"
  1239     and "h \<in> ring_hom R S"
  1240   shows "ring_hom_cring R S h"
  1241   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1242     cring.axioms prems)
  1243 
  1244 lemma (in UP_pre_univ_prop) UP_hom_unique:
  1245   includes ring_hom_cring P S Phi
  1246   assumes Phi: "Phi (monom P \<one> (Suc 0)) = s"
  1247       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1248   includes ring_hom_cring P S Psi
  1249   assumes Psi: "Psi (monom P \<one> (Suc 0)) = s"
  1250       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1251     and P: "p \<in> carrier P" and S: "s \<in> carrier S"
  1252   shows "Phi p = Psi p"
  1253 proof -
  1254   have "Phi p =
  1255       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1256     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1257   also
  1258   have "... =
  1259       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1260     by (simp add: Phi Psi P Pi_def comp_def)
  1261   also have "... = Psi p"
  1262     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1263   finally show ?thesis .
  1264 qed
  1265 
  1266 lemma (in UP_pre_univ_prop) ring_homD:
  1267   assumes Phi: "Phi \<in> ring_hom P S"
  1268   shows "ring_hom_cring P S Phi"
  1269 proof (rule ring_hom_cring.intro)
  1270   show "ring_hom_cring_axioms P S Phi"
  1271   by (rule ring_hom_cring_axioms.intro) (rule Phi)
  1272 qed (auto intro: P.cring cring.axioms)
  1273 
  1274 theorem (in UP_pre_univ_prop) UP_universal_property:
  1275   assumes S: "s \<in> carrier S"
  1276   shows "EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &
  1277     Phi (monom P \<one> 1) = s &
  1278     (ALL r : carrier R. Phi (monom P r 0) = h r)"
  1279   using S eval_monom1
  1280   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1281   apply (rule extensionalityI)
  1282   apply (auto intro: UP_hom_unique ring_homD)
  1283   done
  1284 
  1285 
  1286 subsection {* Sample application of evaluation homomorphism *}
  1287 
  1288 lemma UP_pre_univ_propI:
  1289   assumes "cring R"
  1290     and "cring S"
  1291     and "h \<in> ring_hom R S"
  1292   shows "UP_pre_univ_prop R S h "
  1293   by (fast intro: UP_pre_univ_prop.intro ring_hom_cring_axioms.intro
  1294     cring.axioms prems)
  1295 
  1296 constdefs
  1297   INTEG :: "int ring"
  1298   "INTEG == (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"
  1299 
  1300 lemma INTEG_cring:
  1301   "cring INTEG"
  1302   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1303     zadd_zminus_inverse2 zadd_zmult_distrib)
  1304 
  1305 lemma INTEG_id_eval:
  1306   "UP_pre_univ_prop INTEG INTEG id"
  1307   by (fast intro: UP_pre_univ_propI INTEG_cring id_ring_hom)
  1308 
  1309 text {*
  1310   Interpretation now enables to import all theorems and lemmas
  1311   valid in the context of homomorphisms between @{term INTEG} and @{term
  1312   "UP INTEG"} globally.
  1313 *}
  1314 
  1315 interpretation INTEG: UP_pre_univ_prop [INTEG INTEG id]
  1316   using INTEG_id_eval
  1317   by - (erule UP_pre_univ_prop.axioms)+
  1318 
  1319 lemma INTEG_closed [intro, simp]:
  1320   "z \<in> carrier INTEG"
  1321   by (unfold INTEG_def) simp
  1322 
  1323 lemma INTEG_mult [simp]:
  1324   "mult INTEG z w = z * w"
  1325   by (unfold INTEG_def) simp
  1326 
  1327 lemma INTEG_pow [simp]:
  1328   "pow INTEG z n = z ^ n"
  1329   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1330 
  1331 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1332   by (simp add: INTEG.eval_monom)
  1333 
  1334 end