src/Sequents/T.thy
author wenzelm
Sat Dec 14 17:28:05 2013 +0100 (2013-12-14)
changeset 54742 7a86358a3c0b
parent 51309 473303ef6e34
child 60770 240563fbf41d
permissions -rw-r--r--
proper context for basic Simplifier operations: rewrite_rule, rewrite_goals_rule, rewrite_goals_tac etc.;
clarified tool context in some boundary cases;
     1 (*  Title:      Sequents/T.thy
     2     Author:     Martin Coen
     3     Copyright   1991  University of Cambridge
     4 *)
     5 
     6 theory T
     7 imports Modal0
     8 begin
     9 
    10 axiomatization where
    11 (* Definition of the star operation using a set of Horn clauses *)
    12 (* For system T:  gamma * == {P | []P : gamma}                  *)
    13 (*                delta * == {P | <>P : delta}                  *)
    14 
    15   lstar0:         "|L>" and
    16   lstar1:         "$G |L> $H ==> []P, $G |L> P, $H" and
    17   lstar2:         "$G |L> $H ==>   P, $G |L>    $H" and
    18   rstar0:         "|R>" and
    19   rstar1:         "$G |R> $H ==> <>P, $G |R> P, $H" and
    20   rstar2:         "$G |R> $H ==>   P, $G |R>    $H" and
    21 
    22 (* Rules for [] and <> *)
    23 
    24   boxR:
    25    "[| $E |L> $E';  $F |R> $F';  $G |R> $G';
    26                $E'        |- $F', P, $G'|] ==> $E          |- $F, []P, $G" and
    27   boxL:     "$E, P, $F  |-         $G    ==> $E, []P, $F |-          $G" and
    28   diaR:     "$E         |- $F, P,  $G    ==> $E          |- $F, <>P, $G" and
    29   diaL:
    30    "[| $E |L> $E';  $F |L> $F';  $G |R> $G';
    31                $E', P, $F'|-         $G'|] ==> $E, <>P, $F |-          $G"
    32 
    33 ML {*
    34 structure T_Prover = Modal_ProverFun
    35 (
    36   val rewrite_rls = @{thms rewrite_rls}
    37   val safe_rls = @{thms safe_rls}
    38   val unsafe_rls = @{thms unsafe_rls} @ [@{thm boxR}, @{thm diaL}]
    39   val bound_rls = @{thms bound_rls} @ [@{thm boxL}, @{thm diaR}]
    40   val aside_rls = [@{thm lstar0}, @{thm lstar1}, @{thm lstar2}, @{thm rstar0},
    41     @{thm rstar1}, @{thm rstar2}]
    42 )
    43 *}
    44 
    45 method_setup T_solve = {* Scan.succeed (fn ctxt => SIMPLE_METHOD (T_Prover.solve_tac ctxt 2)) *}
    46 
    47 
    48 (* Theorems of system T from Hughes and Cresswell and Hailpern, LNCS 129 *)
    49 
    50 lemma "|- []P --> P" by T_solve
    51 lemma "|- [](P-->Q) --> ([]P-->[]Q)" by T_solve   (* normality*)
    52 lemma "|- (P--<Q) --> []P --> []Q" by T_solve
    53 lemma "|- P --> <>P" by T_solve
    54 
    55 lemma "|-  [](P & Q) <-> []P & []Q" by T_solve
    56 lemma "|-  <>(P | Q) <-> <>P | <>Q" by T_solve
    57 lemma "|-  [](P<->Q) <-> (P>-<Q)" by T_solve
    58 lemma "|-  <>(P-->Q) <-> ([]P--><>Q)" by T_solve
    59 lemma "|-        []P <-> ~<>(~P)" by T_solve
    60 lemma "|-     [](~P) <-> ~<>P" by T_solve
    61 lemma "|-       ~[]P <-> <>(~P)" by T_solve
    62 lemma "|-      [][]P <-> ~<><>(~P)" by T_solve
    63 lemma "|- ~<>(P | Q) <-> ~<>P & ~<>Q" by T_solve
    64 
    65 lemma "|- []P | []Q --> [](P | Q)" by T_solve
    66 lemma "|- <>(P & Q) --> <>P & <>Q" by T_solve
    67 lemma "|- [](P | Q) --> []P | <>Q" by T_solve
    68 lemma "|- <>P & []Q --> <>(P & Q)" by T_solve
    69 lemma "|- [](P | Q) --> <>P | []Q" by T_solve
    70 lemma "|- <>(P-->(Q & R)) --> ([]P --> <>Q) & ([]P--><>R)" by T_solve
    71 lemma "|- (P--<Q) & (Q--<R) --> (P--<R)" by T_solve
    72 lemma "|- []P --> <>Q --> <>(P & Q)" by T_solve
    73 
    74 end