src/Pure/library.ML
author bulwahn
Fri Dec 03 08:40:47 2010 +0100 (2010-12-03)
changeset 40925 7abeb749ae99
parent 40733 a71f786d20da
child 40930 500171e7aa59
permissions -rw-r--r--
fixing comment in library
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   val single: 'a -> 'a list
    62   val the_single: 'a list -> 'a
    63   val singleton: ('a list -> 'b list) -> 'a -> 'b
    64   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    65   val apply: ('a -> 'a) list -> 'a -> 'a
    66   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    67   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    68   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    69   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    70   val flat: 'a list list -> 'a list
    71   val unflat: 'a list list -> 'b list -> 'b list list
    72   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    73   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    74   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    75   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    76   val maps: ('a -> 'b list) -> 'a list -> 'b list
    77   val filter: ('a -> bool) -> 'a list -> 'a list
    78   val filter_out: ('a -> bool) -> 'a list -> 'a list
    79   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    80   val take: int -> 'a list -> 'a list
    81   val drop: int -> 'a list -> 'a list
    82   val chop: int -> 'a list -> 'a list * 'a list
    83   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    84   val nth: 'a list -> int -> 'a
    85   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    86   val nth_drop: int -> 'a list -> 'a list
    87   val nth_list: 'a list list -> int -> 'a list
    88   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    89   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val map_range: (int -> 'a) -> int -> 'a list
    91   val split_last: 'a list -> 'a list * 'a
    92   val find_index: ('a -> bool) -> 'a list -> int
    93   val find_first: ('a -> bool) -> 'a list -> 'a option
    94   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    95   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    96   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    97   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    98   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
    99   val fold_rev2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val forall2: ('a -> 'b -> bool) -> 'a list -> 'b list -> bool
   101   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   102   val ~~ : 'a list * 'b list -> ('a * 'b) list
   103   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   104   val split_list: ('a * 'b) list -> 'a list * 'b list
   105   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   106   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   107   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   108   val separate: 'a -> 'a list -> 'a list
   109   val surround: 'a -> 'a list -> 'a list
   110   val replicate: int -> 'a -> 'a list
   111   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   112   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   114   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val prefixes1: 'a list -> 'a list list
   116   val prefixes: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118   val suffixes: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_radix_int: int -> string list -> int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*reals*)
   133   val string_of_real: real -> string
   134   val signed_string_of_real: real -> string
   135 
   136   (*strings*)
   137   val nth_string: string -> int -> string
   138   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   139   val exists_string: (string -> bool) -> string -> bool
   140   val forall_string: (string -> bool) -> string -> bool
   141   val first_field: string -> string -> (string * string) option
   142   val enclose: string -> string -> string -> string
   143   val unenclose: string -> string
   144   val quote: string -> string
   145   val space_implode: string -> string list -> string
   146   val commas: string list -> string
   147   val commas_quote: string list -> string
   148   val cat_lines: string list -> string
   149   val space_explode: string -> string -> string list
   150   val split_lines: string -> string list
   151   val prefix_lines: string -> string -> string
   152   val prefix: string -> string -> string
   153   val suffix: string -> string -> string
   154   val unprefix: string -> string -> string
   155   val unsuffix: string -> string -> string
   156   val replicate_string: int -> string -> string
   157   val translate_string: (string -> string) -> string -> string
   158   val match_string: string -> string -> bool
   159 
   160   (*lists as sets -- see also Pure/General/ord_list.ML*)
   161   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   162   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   163   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   164   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   165   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   166   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   167   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   168   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   169   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   170   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   171   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   172   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   173   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   174 
   175   (*lists as multisets*)
   176   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   177   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   178   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   179 
   180   (*orders*)
   181   val is_equal: order -> bool
   182   val rev_order: order -> order
   183   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   184   val bool_ord: bool * bool -> order
   185   val int_ord: int * int -> order
   186   val string_ord: string * string -> order
   187   val fast_string_ord: string * string -> order
   188   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   189   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   190   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   191   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   192   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   193   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   194   val sort_strings: string list -> string list
   195   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   196   val tag_list: int -> 'a list -> (int * 'a) list
   197   val untag_list: (int * 'a) list -> 'a list
   198   val order_list: (int * 'a) list -> 'a list
   199 
   200   (*random numbers*)
   201   exception RANDOM
   202   val random: unit -> real
   203   val random_range: int -> int -> int
   204   val one_of: 'a list -> 'a
   205   val frequency: (int * 'a) list -> 'a
   206 
   207   (*misc*)
   208   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   209   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   210     'a -> 'b -> 'c * 'b
   211   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   212   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   213   val gensym: string -> string
   214   type stamp = unit Unsynchronized.ref
   215   val stamp: unit -> stamp
   216   type serial = int
   217   val serial: unit -> serial
   218   val serial_string: unit -> string
   219   structure Object: sig type T = exn end
   220 end;
   221 
   222 signature LIBRARY =
   223 sig
   224   include BASIC_LIBRARY
   225   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   226   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   227   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   228   val last_elem: 'a list -> 'a
   229 end;
   230 
   231 structure Library: LIBRARY =
   232 struct
   233 
   234 (* functions *)
   235 
   236 fun undefined _ = raise Match;
   237 
   238 fun I x = x;
   239 fun K x = fn _ => x;
   240 fun curry f x y = f (x, y);
   241 fun uncurry f (x, y) = f x y;
   242 
   243 (*conditional application*)
   244 fun b ? f = fn x => if b then f x else x;
   245 
   246 (*composition with multiple args*)
   247 fun (f oo g) x y = f (g x y);
   248 fun (f ooo g) x y z = f (g x y z);
   249 fun (f oooo g) x y z w = f (g x y z w);
   250 
   251 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   252 fun funpow (0 : int) _ = I
   253   | funpow n f = f #> funpow (n - 1) f;
   254 
   255 fun funpow_yield (0 : int) _ x = ([], x)
   256   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   257 
   258 
   259 (* errors *)
   260 
   261 exception ERROR of string;
   262 fun error msg = raise ERROR msg;
   263 
   264 fun cat_error "" msg = error msg
   265   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   266 
   267 fun assert_all pred list msg =
   268   let
   269     fun ass [] = ()
   270       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   271   in ass list end;
   272 
   273 
   274 (* pairs *)
   275 
   276 fun pair x y = (x, y);
   277 fun rpair x y = (y, x);
   278 
   279 fun fst (x, y) = x;
   280 fun snd (x, y) = y;
   281 
   282 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   283 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   284 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   285 
   286 fun swap (x, y) = (y, x);
   287 
   288 fun apfst f (x, y) = (f x, y);
   289 fun apsnd f (x, y) = (x, f y);
   290 fun pairself f (x, y) = (f x, f y);
   291 
   292 
   293 (* booleans *)
   294 
   295 (*polymorphic equality*)
   296 fun equal x y = x = y;
   297 fun not_equal x y = x <> y;
   298 
   299 (*combining predicates*)
   300 fun p orf q = fn x => p x orelse q x;
   301 fun p andf q = fn x => p x andalso q x;
   302 
   303 val exists = List.exists;
   304 val forall = List.all;
   305 
   306 
   307 (* flags *)
   308 
   309 fun setmp_CRITICAL flag value f x =
   310   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   311 
   312 fun setmp_thread_data tag orig_data data f x =
   313   uninterruptible (fn restore_attributes => fn () =>
   314     let
   315       val _ = Thread.setLocal (tag, data);
   316       val result = Exn.capture (restore_attributes f) x;
   317       val _ = Thread.setLocal (tag, orig_data);
   318     in Exn.release result end) ();
   319 
   320 
   321 
   322 (** lists **)
   323 
   324 fun single x = [x];
   325 
   326 fun the_single [x] = x
   327   | the_single _ = raise Empty;
   328 
   329 fun singleton f x = the_single (f [x]);
   330 
   331 fun yield_singleton f x = f [x] #>> the_single;
   332 
   333 fun apply [] x = x
   334   | apply (f :: fs) x = apply fs (f x);
   335 
   336 fun perhaps_apply funs arg =
   337   let
   338     fun app [] res = res
   339       | app (f :: fs) (changed, x) =
   340           (case f x of
   341             NONE => app fs (changed, x)
   342           | SOME x' => app fs (true, x'));
   343   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   344 
   345 fun perhaps_loop f arg =
   346   let
   347     fun loop (changed, x) =
   348       (case f x of
   349         NONE => (changed, x)
   350       | SOME x' => loop (true, x'));
   351   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   352 
   353 
   354 (* fold -- old versions *)
   355 
   356 (*the following versions of fold are designed to fit nicely with infixes*)
   357 
   358 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   359     for operators that associate to the left (TAIL RECURSIVE)*)
   360 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   361   let fun itl (e, [])  = e
   362         | itl (e, a::l) = itl (f(e, a), l)
   363   in  itl end;
   364 
   365 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   366     for operators that associate to the right (not tail recursive)*)
   367 fun foldr f (l, e) =
   368   let fun itr [] = e
   369         | itr (a::l) = f(a, itr l)
   370   in  itr l  end;
   371 
   372 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   373     for operators that associate to the left (TAIL RECURSIVE)*)
   374 fun foldl1 f [] = raise Empty
   375   | foldl1 f (x :: xs) = foldl f (x, xs);
   376 
   377 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   378     for n > 0, operators that associate to the right (not tail recursive)*)
   379 fun foldr1 f [] = raise Empty
   380   | foldr1 f l =
   381       let fun itr [x] = x
   382             | itr (x::l) = f(x, itr l)
   383       in  itr l  end;
   384 
   385 fun foldl_map f =
   386   let
   387     fun fold_aux (x, []) = (x, [])
   388       | fold_aux (x, y :: ys) =
   389           let
   390             val (x', y') = f (x, y);
   391             val (x'', ys') = fold_aux (x', ys);
   392           in (x'', y' :: ys') end;
   393   in fold_aux end;
   394 
   395 
   396 (* basic list functions *)
   397 
   398 fun eq_list eq (list1, list2) =
   399   let
   400     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   401       | eq_lst _ = true;
   402   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   403 
   404 fun maps f [] = []
   405   | maps f (x :: xs) = f x @ maps f xs;
   406 
   407 val filter = List.filter;
   408 fun filter_out f = filter (not o f);
   409 val map_filter = List.mapPartial;
   410 
   411 fun take (0: int) xs = []
   412   | take _ [] = []
   413   | take n (x :: xs) = x :: take (n - 1) xs;
   414 
   415 fun drop (0: int) xs = xs
   416   | drop _ [] = []
   417   | drop n (x :: xs) = drop (n - 1) xs;
   418 
   419 fun chop (0: int) xs = ([], xs)
   420   | chop _ [] = ([], [])
   421   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   422 
   423 fun chop_while P [] = ([], [])
   424   | chop_while P (ys as x :: xs) =
   425       if P x then chop_while P xs |>> cons x else ([], ys);
   426 
   427 (*return nth element of a list, where 0 designates the first element;
   428   raise Subscript if list too short*)
   429 fun nth xs i = List.nth (xs, i);
   430 
   431 fun nth_list xss i = nth xss i handle Subscript => [];
   432 
   433 fun nth_map 0 f (x :: xs) = f x :: xs
   434   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   435   | nth_map (_: int) _ [] = raise Subscript;
   436 
   437 fun nth_drop n xs =
   438   List.take (xs, n) @ List.drop (xs, n + 1);
   439 
   440 fun map_index f =
   441   let
   442     fun mapp (_: int) [] = []
   443       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   444   in mapp 0 end;
   445 
   446 fun fold_index f =
   447   let
   448     fun fold_aux (_: int) [] y = y
   449       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   450   in fold_aux 0 end;
   451 
   452 fun map_range f i =
   453   let
   454     fun mapp (k: int) =
   455       if k < i then f k :: mapp (k + 1) else [];
   456   in mapp 0 end;
   457 
   458 val last_elem = List.last;
   459 
   460 (*rear decomposition*)
   461 fun split_last [] = raise Empty
   462   | split_last [x] = ([], x)
   463   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   464 
   465 (*find position of first element satisfying a predicate*)
   466 fun find_index pred =
   467   let fun find (_: int) [] = ~1
   468         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   469   in find 0 end;
   470 
   471 (*find first element satisfying predicate*)
   472 val find_first = List.find;
   473 
   474 (*get first element by lookup function*)
   475 fun get_first _ [] = NONE
   476   | get_first f (x :: xs) =
   477       (case f x of
   478         NONE => get_first f xs
   479       | some => some);
   480 
   481 fun get_index f =
   482   let
   483     fun get (_: int) [] = NONE
   484       | get i (x :: xs) =
   485           case f x
   486            of NONE => get (i + 1) xs
   487             | SOME y => SOME (i, y)
   488   in get 0 end;
   489 
   490 val flat = List.concat;
   491 
   492 fun unflat (xs :: xss) ys =
   493       let val (ps, qs) = chop (length xs) ys
   494       in ps :: unflat xss qs end
   495   | unflat [] [] = []
   496   | unflat _ _ = raise ListPair.UnequalLengths;
   497 
   498 fun burrow f xss = unflat xss (f (flat xss));
   499 
   500 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   501 
   502 fun fold_burrow f xss s =
   503   apfst (unflat xss) (f (flat xss) s);
   504 
   505 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   506 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   507   | separate _ xs = xs;
   508 
   509 fun surround s (x :: xs) = s :: x :: surround s xs
   510   | surround s [] = [s];
   511 
   512 (*make the list [x, x, ..., x] of length n*)
   513 fun replicate (n: int) x =
   514   let fun rep (0, xs) = xs
   515         | rep (n, xs) = rep (n - 1, x :: xs)
   516   in
   517     if n < 0 then raise Subscript
   518     else rep (n, [])
   519   end;
   520 
   521 
   522 (* direct product *)
   523 
   524 fun map_product f _ [] = []
   525   | map_product f [] _ = []
   526   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   527 
   528 fun fold_product f _ [] z = z
   529   | fold_product f [] _ z = z
   530   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   531 
   532 
   533 (* lists of pairs *)
   534 
   535 fun map2 _ [] [] = []
   536   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   537   | map2 _ _ _ = raise ListPair.UnequalLengths;
   538 
   539 fun fold2 f [] [] z = z
   540   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   541   | fold2 f _ _ _ = raise ListPair.UnequalLengths;
   542 
   543 fun fold_rev2 f [] [] z = z
   544   | fold_rev2 f (x :: xs) (y :: ys) z = f x y (fold_rev2 f xs ys z)
   545   | fold_rev2 f _ _ _ = raise ListPair.UnequalLengths;
   546 
   547 fun forall2 P [] [] = true
   548   | forall2 P (x :: xs) (y :: ys) = P x y andalso forall2 P xs ys
   549   | forall2 P _ _ = raise ListPair.UnequalLengths;
   550 
   551 fun map_split f [] = ([], [])
   552   | map_split f (x :: xs) =
   553       let
   554         val (y, w) = f x;
   555         val (ys, ws) = map_split f xs;
   556       in (y :: ys, w :: ws) end;
   557 
   558 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   559   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   560   | zip_options _ [] = []
   561   | zip_options [] _ = raise ListPair.UnequalLengths;
   562 
   563 (*combine two lists forming a list of pairs:
   564   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   565 fun [] ~~ [] = []
   566   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   567   | _ ~~ _ = raise ListPair.UnequalLengths;
   568 
   569 (*inverse of ~~; the old 'split':
   570   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   571 val split_list = ListPair.unzip;
   572 
   573 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   574 
   575 
   576 (* prefixes, suffixes *)
   577 
   578 fun is_prefix _ [] _ = true
   579   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   580   | is_prefix eq _ _ = false;
   581 
   582 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   583    where xi is the first element that does not satisfy the predicate*)
   584 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   585   let fun take (rxs, []) = (rev rxs, [])
   586         | take (rxs, x :: xs) =
   587             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   588   in  take([], xs)  end;
   589 
   590 fun chop_prefix eq ([], ys) = ([], ([], ys))
   591   | chop_prefix eq (xs, []) = ([], (xs, []))
   592   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   593       if eq (x, y) then
   594         let val (ps', xys'') = chop_prefix eq (xs', ys')
   595         in (x :: ps', xys'') end
   596       else ([], (xs, ys));
   597 
   598 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   599    where xi is the last element that does not satisfy the predicate*)
   600 fun take_suffix _ [] = ([], [])
   601   | take_suffix pred (x :: xs) =
   602       (case take_suffix pred xs of
   603         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   604       | (prfx, sffx) => (x :: prfx, sffx));
   605 
   606 fun prefixes1 [] = []
   607   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   608 
   609 fun prefixes xs = [] :: prefixes1 xs;
   610 
   611 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   612 fun suffixes xs = [] :: suffixes1 xs;
   613 
   614 
   615 
   616 (** integers **)
   617 
   618 (* lists of integers *)
   619 
   620 (*make the list [from, from + 1, ..., to]*)
   621 fun ((i: int) upto j) =
   622   if i > j then [] else i :: (i + 1 upto j);
   623 
   624 (*make the list [from, from - 1, ..., to]*)
   625 fun ((i: int) downto j) =
   626   if i < j then [] else i :: (i - 1 downto j);
   627 
   628 
   629 (* convert integers to strings *)
   630 
   631 (*expand the number in the given base;
   632   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   633 fun radixpand (base, num) : int list =
   634   let
   635     fun radix (n, tail) =
   636       if n < base then n :: tail
   637       else radix (n div base, (n mod base) :: tail)
   638   in radix (num, []) end;
   639 
   640 (*expands a number into a string of characters starting from "zerochar";
   641   example: radixstring (2, "0", 8) gives "1000"*)
   642 fun radixstring (base, zerochar, num) =
   643   let val offset = ord zerochar;
   644       fun chrof n = chr (offset + n)
   645   in implode (map chrof (radixpand (base, num))) end;
   646 
   647 
   648 val string_of_int = Int.toString;
   649 
   650 fun signed_string_of_int i =
   651   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   652 
   653 fun string_of_indexname (a, 0) = a
   654   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   655 
   656 
   657 (* read integers *)
   658 
   659 fun read_radix_int radix cs =
   660   let
   661     val zero = ord "0";
   662     val limit = zero + radix;
   663     fun scan (num, []) = (num, [])
   664       | scan (num, c :: cs) =
   665         if zero <= ord c andalso ord c < limit then
   666           scan (radix * num + (ord c - zero), cs)
   667         else (num, c :: cs);
   668   in scan (0, cs) end;
   669 
   670 val read_int = read_radix_int 10;
   671 
   672 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   673 
   674 
   675 
   676 (** reals **)
   677 
   678 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   679 
   680 fun signed_string_of_real x =
   681   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   682 
   683 
   684 
   685 (** strings **)
   686 
   687 (* functions tuned for strings, avoiding explode *)
   688 
   689 fun nth_string str i =
   690   (case try String.substring (str, i, 1) of
   691     SOME s => s
   692   | NONE => raise Subscript);
   693 
   694 fun fold_string f str x0 =
   695   let
   696     val n = size str;
   697     fun iter (x, i) =
   698       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   699   in iter (x0, 0) end;
   700 
   701 fun exists_string pred str =
   702   let
   703     val n = size str;
   704     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   705   in ex 0 end;
   706 
   707 fun forall_string pred = not o exists_string (not o pred);
   708 
   709 fun first_field sep str =
   710   let
   711     val n = size sep;
   712     val len = size str;
   713     fun find i =
   714       if i + n > len then NONE
   715       else if String.substring (str, i, n) = sep then SOME i
   716       else find (i + 1);
   717   in
   718     (case find 0 of
   719       NONE => NONE
   720     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   721   end;
   722 
   723 (*enclose in brackets*)
   724 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   725 fun unenclose str = String.substring (str, 1, size str - 2);
   726 
   727 (*simple quoting (does not escape special chars)*)
   728 val quote = enclose "\"" "\"";
   729 
   730 (*space_implode "..." (space_explode "hello") = "h...e...l...l...o"*)
   731 fun space_implode a bs = implode (separate a bs);
   732 
   733 val commas = space_implode ", ";
   734 val commas_quote = commas o map quote;
   735 
   736 (*concatenate messages, one per line, into a string*)
   737 val cat_lines = space_implode "\n";
   738 
   739 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   740 fun space_explode _ "" = []
   741   | space_explode sep s = String.fields (fn c => str c = sep) s;
   742 
   743 val split_lines = space_explode "\n";
   744 
   745 fun prefix_lines "" txt = txt
   746   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   747 
   748 fun prefix prfx s = prfx ^ s;
   749 fun suffix sffx s = s ^ sffx;
   750 
   751 fun unprefix prfx s =
   752   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   753   else raise Fail "unprefix";
   754 
   755 fun unsuffix sffx s =
   756   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   757   else raise Fail "unsuffix";
   758 
   759 fun replicate_string (0: int) _ = ""
   760   | replicate_string 1 a = a
   761   | replicate_string k a =
   762       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   763       else replicate_string (k div 2) (a ^ a) ^ a;
   764 
   765 fun translate_string f = String.translate (f o String.str);
   766 
   767 (*crude matching of str against simple glob pat*)
   768 fun match_string pat str =
   769   let
   770     fun match [] _ = true
   771       | match (p :: ps) s =
   772           size p <= size s andalso
   773             (case try (unprefix p) s of
   774               SOME s' => match ps s'
   775             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   776   in match (space_explode "*" pat) str end;
   777 
   778 
   779 
   780 (** lists as sets -- see also Pure/General/ord_list.ML **)
   781 
   782 (* canonical operations *)
   783 
   784 fun member eq list x =
   785   let
   786     fun memb [] = false
   787       | memb (y :: ys) = eq (x, y) orelse memb ys;
   788   in memb list end;
   789 
   790 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   791 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   792 fun update eq x xs = cons x (remove eq x xs);
   793 
   794 fun inter eq xs = filter (member eq xs);
   795 
   796 fun union eq = fold (insert eq);
   797 fun subtract eq = fold (remove eq);
   798 
   799 fun merge eq (xs, ys) =
   800   if pointer_eq (xs, ys) then xs
   801   else if null xs then ys
   802   else fold_rev (insert eq) ys xs;
   803 
   804 
   805 (* subset and set equality *)
   806 
   807 fun subset eq (xs, ys) = forall (member eq ys) xs;
   808 
   809 fun eq_set eq (xs, ys) =
   810   eq_list eq (xs, ys) orelse
   811     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   812 
   813 
   814 (*makes a list of the distinct members of the input; preserves order, takes
   815   first of equal elements*)
   816 fun distinct eq lst =
   817   let
   818     fun dist (rev_seen, []) = rev rev_seen
   819       | dist (rev_seen, x :: xs) =
   820           if member eq rev_seen x then dist (rev_seen, xs)
   821           else dist (x :: rev_seen, xs);
   822   in dist ([], lst) end;
   823 
   824 (*returns a list containing all repeated elements exactly once; preserves
   825   order, takes first of equal elements*)
   826 fun duplicates eq lst =
   827   let
   828     fun dups (rev_dups, []) = rev rev_dups
   829       | dups (rev_dups, x :: xs) =
   830           if member eq rev_dups x orelse not (member eq xs x) then
   831             dups (rev_dups, xs)
   832           else dups (x :: rev_dups, xs);
   833   in dups ([], lst) end;
   834 
   835 fun has_duplicates eq =
   836   let
   837     fun dups [] = false
   838       | dups (x :: xs) = member eq xs x orelse dups xs;
   839   in dups end;
   840 
   841 
   842 (* matrices *)
   843 
   844 fun map_transpose f xss =
   845   let
   846     val n =
   847       (case distinct (op =) (map length xss) of
   848         [] => 0
   849       | [n] => n
   850       | _ => raise ListPair.UnequalLengths);
   851   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   852 
   853 
   854 
   855 (** lists as multisets **)
   856 
   857 fun remove1 eq x [] = []
   858   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   859 
   860 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   861 
   862 fun submultiset _ ([], _)  = true
   863   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   864 
   865 
   866 
   867 (** orders **)
   868 
   869 fun is_equal EQUAL = true
   870   | is_equal _ = false;
   871 
   872 fun rev_order LESS = GREATER
   873   | rev_order EQUAL = EQUAL
   874   | rev_order GREATER = LESS;
   875 
   876 (*assume rel is a linear strict order*)
   877 fun make_ord rel (x, y) =
   878   if rel (x, y) then LESS
   879   else if rel (y, x) then GREATER
   880   else EQUAL;
   881 
   882 fun bool_ord (false, true) = LESS
   883   | bool_ord (true, false) = GREATER
   884   | bool_ord _ = EQUAL;
   885 
   886 val int_ord = Int.compare;
   887 val string_ord = String.compare;
   888 
   889 fun fast_string_ord (s1, s2) =
   890   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   891 
   892 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   893   | option_ord _ (NONE, NONE) = EQUAL
   894   | option_ord _ (NONE, SOME _) = LESS
   895   | option_ord _ (SOME _, NONE) = GREATER;
   896 
   897 (*lexicographic product*)
   898 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   899   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   900 
   901 (*dictionary order -- in general NOT well-founded!*)
   902 fun dict_ord elem_ord (x :: xs, y :: ys) =
   903       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   904   | dict_ord _ ([], []) = EQUAL
   905   | dict_ord _ ([], _ :: _) = LESS
   906   | dict_ord _ (_ :: _, []) = GREATER;
   907 
   908 (*lexicographic product of lists*)
   909 fun list_ord elem_ord (xs, ys) =
   910   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   911 
   912 
   913 (* sorting *)
   914 
   915 (*quicksort -- stable, i.e. does not reorder equal elements*)
   916 fun quicksort unique ord =
   917   let
   918     fun qsort [] = []
   919       | qsort (xs as [_]) = xs
   920       | qsort (xs as [x, y]) =
   921           (case ord (x, y) of
   922             LESS => xs
   923           | EQUAL => if unique then [x] else xs
   924           | GREATER => [y, x])
   925       | qsort xs =
   926           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   927           in qsort lts @ eqs @ qsort gts end
   928     and part _ [] = ([], [], [])
   929       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   930     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   931       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   932       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   933       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   934   in qsort end;
   935 
   936 fun sort ord = quicksort false ord;
   937 fun sort_distinct ord = quicksort true ord;
   938 
   939 val sort_strings = sort string_ord;
   940 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   941 
   942 
   943 (* items tagged by integer index *)
   944 
   945 (*insert tags*)
   946 fun tag_list k [] = []
   947   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   948 
   949 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   950 fun untag_list [] = []
   951   | untag_list [(k: int, x)] = [x]
   952   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   953       if k = k' then untag_list rest
   954       else x :: untag_list rest;
   955 
   956 (*return list elements in original order*)
   957 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   958 
   959 
   960 
   961 (** random numbers **)
   962 
   963 exception RANDOM;
   964 
   965 fun rmod x y = x - y * Real.realFloor (x / y);
   966 
   967 local
   968   val a = 16807.0;
   969   val m = 2147483647.0;
   970   val random_seed = Unsynchronized.ref 1.0;
   971 in
   972 
   973 fun random () = CRITICAL (fn () =>
   974   let val r = rmod (a * ! random_seed) m
   975   in (random_seed := r; r) end);
   976 
   977 end;
   978 
   979 fun random_range l h =
   980   if h < l orelse l < 0 then raise RANDOM
   981   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   982 
   983 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   984 
   985 fun frequency xs =
   986   let
   987     val sum = foldl op + (0, map fst xs);
   988     fun pick n ((k: int, x) :: xs) =
   989       if n <= k then x else pick (n - k) xs
   990   in pick (random_range 1 sum) xs end;
   991 
   992 
   993 
   994 (** misc **)
   995 
   996 fun divide_and_conquer decomp x =
   997   let val (ys, recomb) = decomp x
   998   in recomb (map (divide_and_conquer decomp) ys) end;
   999 
  1000 fun divide_and_conquer' decomp x s =
  1001   let val ((ys, recomb), s') = decomp x s
  1002   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1003 
  1004 
  1005 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1006    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1007 fun partition_list p i j =
  1008   let
  1009     fun part (k: int) xs =
  1010       if k > j then
  1011         (case xs of
  1012           [] => []
  1013         | _ => raise Fail "partition_list")
  1014       else
  1015         let val (ns, rest) = List.partition (p k) xs
  1016         in ns :: part (k + 1) rest end;
  1017   in part (i: int) end;
  1018 
  1019 fun partition_eq (eq: 'a * 'a -> bool) =
  1020   let
  1021     fun part [] = []
  1022       | part (x :: ys) =
  1023           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1024           in (x :: xs) :: part xs' end;
  1025   in part end;
  1026 
  1027 
  1028 
  1029 (* generating identifiers *)
  1030 
  1031 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1032 local
  1033 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1034 fun gensym_char i =
  1035   if i<26 then chr (ord "A" + i)
  1036   else if i<52 then chr (ord "a" + i - 26)
  1037   else chr (ord "0" + i - 52);
  1038 
  1039 val char_vec = Vector.tabulate (62, gensym_char);
  1040 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1041 
  1042 val gensym_seed = Unsynchronized.ref (0: int);
  1043 
  1044 in
  1045   fun gensym pre =
  1046     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1047 end;
  1048 
  1049 
  1050 (* stamps and serial numbers *)
  1051 
  1052 type stamp = unit Unsynchronized.ref;
  1053 val stamp: unit -> stamp = Unsynchronized.ref;
  1054 
  1055 type serial = int;
  1056 val serial = Multithreading.serial;
  1057 val serial_string = string_of_int o serial;
  1058 
  1059 
  1060 (* generic objects *)
  1061 
  1062 (*note that the builtin exception datatype may be extended by new
  1063   constructors at any time*)
  1064 structure Object = struct type T = exn end;
  1065 
  1066 end;
  1067 
  1068 structure Basic_Library: BASIC_LIBRARY = Library;
  1069 open Basic_Library;
  1070 
  1071 datatype legacy = UnequalLengths;