src/Pure/variable.ML
author wenzelm
Tue Jul 25 21:18:05 2006 +0200 (2006-07-25)
changeset 20198 7b385487f22f
parent 20162 d4bcb27686f9
child 20220 5dc68e9ecd9a
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Context.proof -> bool
    11   val set_body: bool -> Context.proof -> Context.proof
    12   val restore_body: Context.proof -> Context.proof -> Context.proof
    13   val names_of: Context.proof -> Name.context
    14   val fixes_of: Context.proof -> (string * string) list
    15   val binds_of: Context.proof -> (typ * term) Vartab.table
    16   val constraints_of: Context.proof -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Context.proof -> string -> bool
    18   val is_fixed: Context.proof -> string -> bool
    19   val newly_fixed: Context.proof -> Context.proof -> string -> bool
    20   val default_type: Context.proof -> string -> typ option
    21   val def_type: Context.proof -> bool -> indexname -> typ option
    22   val def_sort: Context.proof -> indexname -> sort option
    23   val declare_constraints: term -> Context.proof -> Context.proof
    24   val declare_internal: term -> Context.proof -> Context.proof
    25   val declare_term: term -> Context.proof -> Context.proof
    26   val declare_thm: thm -> Context.proof -> Context.proof
    27   val thm_context: thm -> Context.proof
    28   val variant_frees: Context.proof -> term list -> (string * 'a) list -> (string * 'a) list
    29   val add_fixes: string list -> Context.proof -> string list * Context.proof
    30   val invent_fixes: string list -> Context.proof -> string list * Context.proof
    31   val invent_types: sort list -> Context.proof -> (string * sort) list * Context.proof
    32   val export_inst: Context.proof -> Context.proof -> string list * string list
    33   val exportT_inst: Context.proof -> Context.proof -> string list
    34   val export_terms: Context.proof -> Context.proof -> term list -> term list
    35   val exportT_terms: Context.proof -> Context.proof -> term list -> term list
    36   val exportT: Context.proof -> Context.proof -> thm list -> thm list
    37   val export: Context.proof -> Context.proof -> thm list -> thm list
    38   val importT_inst: term list -> Context.proof -> ((indexname * sort) * typ) list * Context.proof
    39   val import_inst: bool -> term list -> Context.proof ->
    40     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Context.proof
    41   val importT_terms: term list -> Context.proof -> term list * Context.proof
    42   val import_terms: bool -> term list -> Context.proof -> term list * Context.proof
    43   val importT: thm list -> Context.proof -> thm list * Context.proof
    44   val import: bool -> thm list -> Context.proof -> thm list * Context.proof
    45   val tradeT: Context.proof -> (thm list -> thm list) -> thm list -> thm list
    46   val trade: Context.proof -> (thm list -> thm list) -> thm list -> thm list
    47   val focus: cterm -> Context.proof -> ((string * typ) list * cterm) * Context.proof
    48   val warn_extra_tfrees: Context.proof -> Context.proof -> unit
    49   val polymorphic: Context.proof -> term list -> term list
    50   val hidden_polymorphism: term -> typ -> (indexname * sort) list
    51   val add_binds: (indexname * term option) list -> Context.proof -> Context.proof
    52   val expand_binds: Context.proof -> term -> term
    53 end;
    54 
    55 structure Variable: VARIABLE =
    56 struct
    57 
    58 (** local context data **)
    59 
    60 datatype data = Data of
    61  {is_body: bool,                        (*inner body mode*)
    62   names: Name.context,                  (*type/term variable names*)
    63   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    64   binds: (typ * term) Vartab.table,     (*term bindings*)
    65   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    66   constraints:
    67     typ Vartab.table *                  (*type constraints*)
    68     sort Vartab.table};                 (*default sorts*)
    69 
    70 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    71   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    72     type_occs = type_occs, constraints = constraints};
    73 
    74 structure Data = ProofDataFun
    75 (
    76   val name = "Pure/variable";
    77   type T = data;
    78   fun init thy =
    79     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    80   fun print _ _ = ();
    81 );
    82 
    83 val _ = Context.add_setup Data.init;
    84 
    85 fun map_data f =
    86   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    87     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    88 
    89 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    90   (is_body, f names, fixes, binds, type_occs, constraints));
    91 
    92 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    93   (is_body, names, f fixes, binds, type_occs, constraints));
    94 
    95 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    96   (is_body, names, fixes, f binds, type_occs, constraints));
    97 
    98 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    99   (is_body, names, fixes, binds, f type_occs, constraints));
   100 
   101 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   102   (is_body, names, fixes, binds, type_occs, f constraints));
   103 
   104 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   105 
   106 val is_body = #is_body o rep_data;
   107 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   108   (b, names, fixes, binds, type_occs, constraints));
   109 fun restore_body ctxt = set_body (is_body ctxt);
   110 
   111 val names_of = #names o rep_data;
   112 val fixes_of = #fixes o rep_data;
   113 val binds_of = #binds o rep_data;
   114 val type_occs_of = #type_occs o rep_data;
   115 val constraints_of = #constraints o rep_data;
   116 
   117 val is_declared = Name.is_declared o names_of;
   118 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   119 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   120 
   121 
   122 
   123 (** declarations **)
   124 
   125 (* default sorts and types *)
   126 
   127 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   128 
   129 fun def_type ctxt pattern xi =
   130   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   131     (case Vartab.lookup types xi of
   132       NONE =>
   133         if pattern then NONE
   134         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   135     | some => some)
   136   end;
   137 
   138 val def_sort = Vartab.lookup o #2 o constraints_of;
   139 
   140 
   141 (* names *)
   142 
   143 val declare_type_names = map_names o
   144   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   145 
   146 fun declare_names t =
   147   declare_type_names t #>
   148   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   149 
   150 
   151 (* type occurrences *)
   152 
   153 val declare_type_occs = map_type_occs o fold_term_types
   154   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   155     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   156 
   157 
   158 (* constraints *)
   159 
   160 fun redeclare_skolems ctxt = ctxt |> map_constraints (apfst (fn types =>
   161   let
   162     fun decl (x, x') =
   163       (case default_type ctxt x' of
   164         SOME T => Vartab.update ((x, ~1), T)
   165       | NONE => I);
   166   in fold_rev decl (fixes_of ctxt) types end));
   167 
   168 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   169   let
   170     val types' = fold_aterms
   171       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   172         | Var v => Vartab.update v
   173         | _ => I) t types;
   174     val sorts' = fold_types (fold_atyps
   175       (fn TFree (x, S) => Vartab.update ((x, ~1), S)
   176         | TVar v => Vartab.update v
   177         | _ => I)) t sorts;
   178   in (types', sorts') end)
   179   #> declare_type_names t
   180   #> redeclare_skolems;
   181 
   182 
   183 (* common declarations *)
   184 
   185 fun declare_internal t =
   186   declare_names t #>
   187   declare_type_occs t;
   188 
   189 fun declare_term t =
   190   declare_internal t #>
   191   declare_constraints t;
   192 
   193 fun declare_thm th = fold declare_internal (Thm.full_prop_of th :: Thm.hyps_of th);
   194 fun thm_context th = declare_thm th (Context.init_proof (Thm.theory_of_thm th));
   195 
   196 
   197 (* renaming term/type frees *)
   198 
   199 fun variant_frees ctxt ts frees =
   200   let
   201     val names = names_of (fold declare_names ts ctxt);
   202     val xs = fst (Name.variants (map #1 frees) names);
   203   in xs ~~ map snd frees end;
   204 
   205 
   206 
   207 (** fixes **)
   208 
   209 local
   210 
   211 fun no_dups [] = ()
   212   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   213 
   214 fun new_fixes names' xs xs' =
   215   map_names (K names') #>
   216   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   217   fold (declare_constraints o Syntax.free) xs' #>
   218   pair xs';
   219 
   220 in
   221 
   222 fun add_fixes xs ctxt =
   223   let
   224     val _ =
   225       (case filter (can Name.dest_skolem) xs of [] => ()
   226       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   227     val _ = no_dups (duplicates (op =) xs);
   228     val (ys, zs) = split_list (fixes_of ctxt);
   229     val names = names_of ctxt;
   230     val (xs', names') =
   231       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   232       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   233         (xs, fold Name.declare xs names));
   234   in ctxt |> new_fixes names' xs xs' end;
   235 
   236 fun invent_fixes raw_xs ctxt =
   237   let
   238     val names = names_of ctxt;
   239     val xs = map Name.clean raw_xs;
   240     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   241   in ctxt |> new_fixes names' xs xs' end;
   242 
   243 end;
   244 
   245 fun invent_types Ss ctxt =
   246   let
   247     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   248     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   249   in (tfrees, ctxt') end;
   250 
   251 
   252 
   253 (** export -- generalize type/term variables **)
   254 
   255 fun export_inst inner outer =
   256   let
   257     val declared_outer = is_declared outer;
   258     val fixes_inner = fixes_of inner;
   259     val fixes_outer = fixes_of outer;
   260 
   261     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   262     val still_fixed = not o member (op =) gen_fixes;
   263     val gen_fixesT =
   264       Symtab.fold (fn (a, xs) =>
   265         if declared_outer a orelse exists still_fixed xs
   266         then I else cons a) (type_occs_of inner) [];
   267   in (gen_fixesT, gen_fixes) end;
   268 
   269 fun exportT_inst inner outer = #1 (export_inst inner outer);
   270 
   271 fun exportT_terms inner outer ts =
   272   map (Term.generalize (exportT_inst (fold declare_type_occs ts inner) outer, [])
   273     (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1)) ts;
   274 
   275 fun export_terms inner outer ts =
   276   map (Term.generalize (export_inst (fold declare_type_occs ts inner) outer)
   277     (fold Term.maxidx_term ts ~1 + 1)) ts;
   278 
   279 fun gen_export inst inner outer ths =
   280   let
   281     val ths' = map Thm.adjust_maxidx_thm ths;
   282     val inner' = fold (declare_type_occs o Thm.full_prop_of) ths' inner;
   283   in map (Thm.generalize (inst inner' outer) (fold Thm.maxidx_thm ths' ~1 + 1)) ths' end;
   284 
   285 val exportT = gen_export (rpair [] oo exportT_inst);
   286 val export = gen_export export_inst;
   287 
   288 
   289 
   290 (** import -- fix schematic type/term variables **)
   291 
   292 fun importT_inst ts ctxt =
   293   let
   294     val tvars = rev (fold Term.add_tvars ts []);
   295     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   296   in (tvars ~~ map TFree tfrees, ctxt') end;
   297 
   298 fun import_inst is_open ts ctxt =
   299   let
   300     val ren = if is_open then I else Name.internal;
   301     val (instT, ctxt') = importT_inst ts ctxt;
   302     val vars = map (apsnd (Term.instantiateT instT)) (rev (fold Term.add_vars ts []));
   303     val (xs, ctxt'') = invent_fixes (map (ren o #1 o #1) vars) ctxt';
   304     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   305   in ((instT, inst), ctxt'') end;
   306 
   307 fun importT_terms ts ctxt =
   308   let val (instT, ctxt') = importT_inst ts ctxt
   309   in (map (Term.instantiate (instT, [])) ts, ctxt') end;
   310 
   311 fun import_terms is_open ts ctxt =
   312   let val (inst, ctxt') = import_inst is_open ts ctxt
   313   in (map (Term.instantiate inst) ts, ctxt') end;
   314 
   315 fun importT ths ctxt =
   316   let
   317     val thy = Context.theory_of_proof ctxt;
   318     val certT = Thm.ctyp_of thy;
   319     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   320     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   321     val ths' = map (Thm.instantiate (instT', [])) ths;
   322   in (ths', ctxt') end;
   323 
   324 fun import is_open ths ctxt =
   325   let
   326     val thy = Context.theory_of_proof ctxt;
   327     val cert = Thm.cterm_of thy;
   328     val certT = Thm.ctyp_of thy;
   329     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   330     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   331     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   332     val ths' = map (Thm.instantiate (instT', inst')) ths;
   333   in (ths', ctxt') end;
   334 
   335 
   336 (* import/export *)
   337 
   338 fun gen_trade imp exp ctxt f ths =
   339   let val (ths', ctxt') = imp ths ctxt
   340   in exp ctxt' ctxt (f ths') end;
   341 
   342 val tradeT = gen_trade importT exportT;
   343 val trade = gen_trade (import true) export;
   344 
   345 
   346 (* focus on outermost parameters *)
   347 
   348 fun forall_elim_prop t prop =
   349   Thm.beta_conversion false (Thm.capply (#2 (Thm.dest_comb prop)) t)
   350   |> Thm.cprop_of |> Thm.dest_comb |> #2;
   351 
   352 fun focus goal ctxt =
   353   let
   354     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   355     val t = Thm.term_of goal;
   356     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   357     val (xs, Ts) = split_list ps;
   358     val (xs', ctxt') = invent_fixes xs ctxt;
   359     val ps' = xs' ~~ Ts;
   360     val goal' = fold (forall_elim_prop o cert o Free) ps' goal;
   361   in ((ps', goal'), ctxt') end;
   362 
   363 
   364 (** implicit polymorphism **)
   365 
   366 (* warn_extra_tfrees *)
   367 
   368 fun warn_extra_tfrees ctxt1 ctxt2 =
   369   let
   370     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   371     fun occs_free a x =
   372       (case def_type ctxt1 false (x, ~1) of
   373         SOME T => if occs_typ a T then I else cons (a, x)
   374       | NONE => cons (a, x));
   375 
   376     val occs1 = type_occs_of ctxt1;
   377     val occs2 = type_occs_of ctxt2;
   378     val extras = Symtab.fold (fn (a, xs) =>
   379       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   380     val tfrees = map #1 extras |> sort_distinct string_ord;
   381     val frees = map #2 extras |> sort_distinct string_ord;
   382   in
   383     if null extras then ()
   384     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   385       space_implode " or " (map quote frees))
   386   end;
   387 
   388 
   389 (* polymorphic terms *)
   390 
   391 fun polymorphic ctxt ts =
   392   let
   393     val ctxt' = fold declare_term ts ctxt;
   394     val occs = type_occs_of ctxt;
   395     val occs' = type_occs_of ctxt';
   396     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   397     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   398   in map (Term.generalize (types, []) idx) ts end;
   399 
   400 fun hidden_polymorphism t T =
   401   let
   402     val tvarsT = Term.add_tvarsT T [];
   403     val extra_tvars = Term.fold_types (Term.fold_atyps
   404       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   405   in extra_tvars end;
   406 
   407 
   408 
   409 (** term bindings **)
   410 
   411 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   412   | add_bind ((x, i), SOME t) =
   413       let
   414         val T = Term.fastype_of t;
   415         val t' =
   416           if null (hidden_polymorphism t T) then t
   417           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   418       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   419 
   420 val add_binds = fold add_bind;
   421 
   422 fun expand_binds ctxt =
   423   let
   424     val binds = binds_of ctxt;
   425     fun expand (t as Var (xi, T)) =
   426           (case Vartab.lookup binds xi of
   427             SOME u => Envir.expand_atom T u
   428           | NONE => t)
   429       | expand t = t;
   430   in Envir.beta_norm o Term.map_aterms expand end;
   431 
   432 end;