src/Pure/display.ML
author wenzelm
Mon Oct 22 17:59:39 2001 +0200 (2001-10-22)
changeset 11883 7b9522995a78
parent 11501 3b6415035d1a
child 12067 b2f5fbb39f14
permissions -rw-r--r--
print_goals stuff is back (from locale.ML);
     1 (*  Title:      Pure/display.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Printing of theories, theorems, etc.
     7 *)
     8 
     9 signature BASIC_DISPLAY =
    10 sig
    11   val show_hyps: bool ref
    12   val show_tags: bool ref
    13   val string_of_thm: thm -> string
    14   val print_thm: thm -> unit
    15   val print_thms: thm list -> unit
    16   val prth: thm -> thm
    17   val prthq: thm Seq.seq -> thm Seq.seq
    18   val prths: thm list -> thm list
    19   val string_of_ctyp: ctyp -> string
    20   val print_ctyp: ctyp -> unit
    21   val string_of_cterm: cterm -> string
    22   val print_cterm: cterm -> unit
    23   val print_syntax: theory -> unit
    24   val show_consts: bool ref
    25 end;
    26 
    27 signature DISPLAY =
    28 sig
    29   include BASIC_DISPLAY
    30   val pretty_thm_no_quote: thm -> Pretty.T
    31   val pretty_thm: thm -> Pretty.T
    32   val pretty_thms: thm list -> Pretty.T
    33   val pretty_thm_sg: Sign.sg -> thm -> Pretty.T
    34   val pretty_thms_sg: Sign.sg -> thm list -> Pretty.T
    35   val pprint_thm: thm -> pprint_args -> unit
    36   val pretty_ctyp: ctyp -> Pretty.T
    37   val pprint_ctyp: ctyp -> pprint_args -> unit
    38   val pretty_cterm: cterm -> Pretty.T
    39   val pprint_cterm: cterm -> pprint_args -> unit
    40   val pretty_theory: theory -> Pretty.T
    41   val pprint_theory: theory -> pprint_args -> unit
    42   val pretty_full_theory: theory -> Pretty.T list
    43   val pretty_name_space: string * NameSpace.T -> Pretty.T
    44   val pretty_goals_marker: string -> int -> thm -> Pretty.T list
    45   val pretty_goals: int -> thm -> Pretty.T list
    46   val pretty_sub_goals: bool -> int -> thm -> Pretty.T list
    47   val print_goals_marker: string -> int -> thm -> unit
    48   val print_goals: int -> thm -> unit
    49   val current_goals_markers: (string * string * string) ref
    50   val print_current_goals_default: (int -> int -> thm -> unit)
    51   val print_current_goals_fn : (int -> int -> thm -> unit) ref
    52 end;
    53 
    54 structure Display: DISPLAY =
    55 struct
    56 
    57 
    58 (** print thm **)
    59 
    60 val show_hyps = ref true;       (*false: print meta-hypotheses as dots*)
    61 val show_tags = ref false;      (*false: suppress tags*)
    62 
    63 local
    64 
    65 fun pretty_tag (name, args) = Pretty.strs (name :: map quote args);
    66 val pretty_tags = Pretty.list "[" "]" o map pretty_tag;
    67 
    68 fun pretty_thm_aux quote th =
    69   let
    70     val {sign, hyps, prop, der = (ora, _), ...} = rep_thm th;
    71     val xshyps = Thm.extra_shyps th;
    72     val (_, tags) = Thm.get_name_tags th;
    73 
    74     val prt_term = (if quote then Pretty.quote else I) o Sign.pretty_term sign;
    75 
    76     val hlen = length xshyps + length hyps;
    77     val hsymbs =
    78       if hlen = 0 andalso not ora then []
    79       else if ! show_hyps then
    80         [Pretty.brk 2, Pretty.list "[" "]"
    81           (map prt_term hyps @ map (Sign.pretty_sort sign) xshyps @
    82             (if ora then [Pretty.str "!"] else []))]
    83       else [Pretty.brk 2, Pretty.str ("[" ^ implode (replicate hlen ".") ^
    84         (if ora then "!" else "") ^ "]")];
    85     val tsymbs =
    86       if null tags orelse not (! show_tags) then []
    87       else [Pretty.brk 1, pretty_tags tags];
    88   in Pretty.block (prt_term prop :: (hsymbs @ tsymbs)) end;
    89 
    90 in
    91 
    92 val pretty_thm = pretty_thm_aux true;
    93 val pretty_thm_no_quote = pretty_thm_aux false;
    94 
    95 end;
    96 
    97 
    98 val string_of_thm = Pretty.string_of o pretty_thm;
    99 val pprint_thm = Pretty.pprint o pretty_thm;
   100 
   101 fun pretty_thms [th] = pretty_thm th
   102   | pretty_thms ths = Pretty.block (Pretty.fbreaks (map pretty_thm ths));
   103 
   104 val pretty_thm_sg = pretty_thm oo Thm.transfer_sg;
   105 val pretty_thms_sg = pretty_thms oo (map o Thm.transfer_sg);
   106 
   107 
   108 (* top-level commands for printing theorems *)
   109 
   110 val print_thm = Pretty.writeln o pretty_thm;
   111 val print_thms = Pretty.writeln o pretty_thms;
   112 
   113 fun prth th = (print_thm th; th);
   114 
   115 (*Print and return a sequence of theorems, separated by blank lines. *)
   116 fun prthq thseq =
   117   (Seq.print (fn _ => print_thm) 100000 thseq; thseq);
   118 
   119 (*Print and return a list of theorems, separated by blank lines. *)
   120 fun prths ths = (seq (fn th => (print_thm th; writeln "")) ths; ths);
   121 
   122 
   123 (* other printing commands *)
   124 
   125 fun pretty_ctyp cT =
   126   let val {sign, T} = rep_ctyp cT in Sign.pretty_typ sign T end;
   127 
   128 fun pprint_ctyp cT =
   129   let val {sign, T} = rep_ctyp cT in Sign.pprint_typ sign T end;
   130 
   131 fun string_of_ctyp cT =
   132   let val {sign, T} = rep_ctyp cT in Sign.string_of_typ sign T end;
   133 
   134 val print_ctyp = writeln o string_of_ctyp;
   135 
   136 fun pretty_cterm ct =
   137   let val {sign, t, ...} = rep_cterm ct in Sign.pretty_term sign t end;
   138 
   139 fun pprint_cterm ct =
   140   let val {sign, t, ...} = rep_cterm ct in Sign.pprint_term sign t end;
   141 
   142 fun string_of_cterm ct =
   143   let val {sign, t, ...} = rep_cterm ct in Sign.string_of_term sign t end;
   144 
   145 val print_cterm = writeln o string_of_cterm;
   146 
   147 
   148 
   149 (** print theory **)
   150 
   151 val pretty_theory = Sign.pretty_sg o Theory.sign_of;
   152 val pprint_theory = Sign.pprint_sg o Theory.sign_of;
   153 
   154 val print_syntax = Syntax.print_syntax o Theory.syn_of;
   155 
   156 
   157 (* pretty_name_space  *)
   158 
   159 fun pretty_name_space (kind, space) =
   160   let
   161     fun prt_entry (name, accs) = Pretty.block
   162       (Pretty.str (quote name ^ " =") :: Pretty.brk 1 ::
   163         Pretty.commas (map (Pretty.str o quote) accs));
   164   in
   165     Pretty.fbreaks (Pretty.str (kind ^ ":") :: map prt_entry (NameSpace.dest space))
   166     |> Pretty.block
   167   end;
   168 
   169 
   170 (* pretty_full_theory *)
   171 
   172 fun pretty_full_theory thy =
   173   let
   174     val sg = Theory.sign_of thy;
   175 
   176     fun prt_cls c = Sign.pretty_sort sg [c];
   177     fun prt_sort S = Sign.pretty_sort sg S;
   178     fun prt_arity t (c, Ss) = Sign.pretty_arity sg (t, Ss, [c]);
   179     fun prt_typ_no_tvars ty = Pretty.quote (Sign.pretty_typ sg (#1 (Type.freeze_thaw_type ty)));
   180     fun prt_term t = Pretty.quote (Sign.pretty_term sg t);
   181 
   182     fun pretty_classes cs = Pretty.block
   183       (Pretty.breaks (Pretty.str "classes:" :: map prt_cls cs));
   184 
   185     fun pretty_classrel (c, cs) = Pretty.block
   186       (prt_cls c :: Pretty.str " <" :: Pretty.brk 1 ::
   187         Pretty.commas (map prt_cls cs));
   188 
   189     fun pretty_default S = Pretty.block
   190       [Pretty.str "default:", Pretty.brk 1, prt_sort S];
   191 
   192     fun pretty_ty (t, n) = Pretty.block
   193       [Pretty.str t, Pretty.brk 1, Pretty.str (string_of_int n)];
   194 
   195     fun pretty_log_types ts = Pretty.block
   196       (Pretty.breaks (Pretty.str "logical types:" :: map Pretty.str ts));
   197 
   198     fun pretty_witness None = Pretty.str "universal non-emptiness witness: --"
   199       | pretty_witness (Some (T, S)) = Pretty.block
   200           [Pretty.str "universal non-emptiness witness:", Pretty.brk 1, prt_typ_no_tvars T,
   201             Pretty.brk 1, prt_sort S];
   202 
   203     fun pretty_abbr (t, (vs, rhs)) = Pretty.block
   204       [prt_typ_no_tvars (Type (t, map (fn v => TVar ((v, 0), [])) vs)),
   205         Pretty.str " =", Pretty.brk 1, prt_typ_no_tvars rhs];
   206 
   207     fun pretty_arities (t, ars) = map (prt_arity t) ars;
   208 
   209     fun pretty_const (c, ty) = Pretty.block
   210       [Pretty.str c, Pretty.str " ::", Pretty.brk 1, prt_typ_no_tvars ty];
   211 
   212     fun prt_axm (a, t) = Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, prt_term t];
   213 
   214 
   215     val {self = _, tsig, const_tab, syn = _, path, spaces, data} = Sign.rep_sg sg;
   216     val {axioms, oracles, ...} = Theory.rep_theory thy;
   217     val spaces' = Library.sort_wrt fst spaces;
   218     val {classes, classrel, default, tycons = type_tab, log_types, univ_witness, abbrs, arities} =
   219       Type.rep_tsig tsig;
   220     val tycons = Sign.cond_extern_table sg Sign.typeK type_tab;
   221     val consts = Sign.cond_extern_table sg Sign.constK const_tab;
   222     val axms = Sign.cond_extern_table sg Theory.axiomK axioms;
   223     val oras = Sign.cond_extern_table sg Theory.oracleK oracles;
   224   in
   225     [Pretty.strs ("stamps:" :: Sign.stamp_names_of sg),
   226       Pretty.strs ("data:" :: Sign.data_kinds data),
   227       Pretty.strs ["name prefix:", NameSpace.pack (if_none path ["-"])],
   228       Pretty.big_list "name spaces:" (map pretty_name_space spaces'),
   229       pretty_classes classes,
   230       Pretty.big_list "class relation:" (map pretty_classrel (Symtab.dest classrel)),
   231       pretty_default default,
   232       pretty_log_types log_types,
   233       pretty_witness univ_witness,
   234       Pretty.big_list "type constructors:" (map pretty_ty tycons),
   235       Pretty.big_list "type abbreviations:" (map pretty_abbr (Symtab.dest abbrs)),
   236       Pretty.big_list "type arities:" (flat (map pretty_arities (Symtab.dest arities))),
   237       Pretty.big_list "consts:" (map pretty_const consts),
   238       Pretty.big_list "axioms:" (map prt_axm axms),
   239       Pretty.strs ("oracles:" :: (map #1 oras))]
   240   end;
   241 
   242 
   243 
   244 (** print_goals **)
   245 
   246 (* print_goals etc. *)
   247 
   248 (*show consts with types in proof state output?*)
   249 val show_consts = ref false;
   250 
   251 
   252 (*print thm A1,...,An/B in "goal style" -- premises as numbered subgoals*)
   253 
   254 local
   255 
   256   (* utils *)
   257 
   258   fun ins_entry (x, y) [] = [(x, [y])]
   259     | ins_entry (x, y) ((pair as (x', ys')) :: pairs) =
   260         if x = x' then (x', y ins ys') :: pairs
   261         else pair :: ins_entry (x, y) pairs;
   262 
   263   fun add_consts (Const (c, T), env) = ins_entry (T, (c, T)) env
   264     | add_consts (t $ u, env) = add_consts (u, add_consts (t, env))
   265     | add_consts (Abs (_, _, t), env) = add_consts (t, env)
   266     | add_consts (_, env) = env;
   267 
   268   fun add_vars (Free (x, T), env) = ins_entry (T, (x, ~1)) env
   269     | add_vars (Var (xi, T), env) = ins_entry (T, xi) env
   270     | add_vars (Abs (_, _, t), env) = add_vars (t, env)
   271     | add_vars (t $ u, env) = add_vars (u, add_vars (t, env))
   272     | add_vars (_, env) = env;
   273 
   274   fun add_varsT (Type (_, Ts), env) = foldr add_varsT (Ts, env)
   275     | add_varsT (TFree (x, S), env) = ins_entry (S, (x, ~1)) env
   276     | add_varsT (TVar (xi, S), env) = ins_entry (S, xi) env;
   277 
   278   fun sort_idxs vs = map (apsnd (sort (prod_ord string_ord int_ord))) vs;
   279   fun sort_cnsts cs = map (apsnd (sort_wrt fst)) cs;
   280 
   281 
   282   (* prepare atoms *)
   283 
   284   fun consts_of t = sort_cnsts (add_consts (t, []));
   285   fun vars_of t = sort_idxs (add_vars (t, []));
   286   fun varsT_of t = rev (sort_idxs (it_term_types add_varsT (t, [])));
   287 
   288   fun pretty_goals_marker_aux begin_goal print_msg print_goal maxgoals state =
   289     let
   290       val {sign, ...} = rep_thm state;
   291 
   292       val prt_term = Sign.pretty_term sign;
   293       val prt_typ = Sign.pretty_typ sign;
   294       val prt_sort = Sign.pretty_sort sign;
   295 
   296       fun prt_atoms prt prtT (X, xs) = Pretty.block
   297         [Pretty.block (Pretty.commas (map prt xs)), Pretty.str " ::",
   298           Pretty.brk 1, prtT X];
   299 
   300       fun prt_var (x, ~1) = prt_term (Syntax.free x)
   301         | prt_var xi = prt_term (Syntax.var xi);
   302 
   303       fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
   304         | prt_varT xi = prt_typ (TVar (xi, []));
   305 
   306       val prt_consts = prt_atoms (prt_term o Const) prt_typ;
   307       val prt_vars = prt_atoms prt_var prt_typ;
   308       val prt_varsT = prt_atoms prt_varT prt_sort;
   309 
   310 
   311       fun pretty_list _ _ [] = []
   312         | pretty_list name prt lst = [Pretty.big_list name (map prt lst)];
   313 
   314       fun pretty_subgoal (n, A) =
   315         Pretty.blk (0, [Pretty.str (begin_goal ^ " " ^ string_of_int n ^ ". "), prt_term A]);
   316       fun pretty_subgoals As = map pretty_subgoal (1 upto length As ~~ As);
   317 
   318       val pretty_ffpairs = pretty_list "flex-flex pairs:" (prt_term o Logic.mk_flexpair);
   319 
   320       val pretty_consts = pretty_list "constants:" prt_consts o consts_of;
   321       val pretty_vars = pretty_list "variables:" prt_vars o vars_of;
   322       val pretty_varsT = pretty_list "type variables:" prt_varsT o varsT_of;
   323 
   324 
   325       val {prop, ...} = rep_thm state;
   326       val (tpairs, As, B) = Logic.strip_horn prop;
   327       val ngoals = length As;
   328 
   329       fun pretty_gs (types, sorts) =
   330         (if print_goal then [prt_term B] else []) @
   331          (if ngoals = 0 then [Pretty.str "No subgoals!"]
   332           else if ngoals > maxgoals then
   333             pretty_subgoals (take (maxgoals, As)) @
   334             (if print_msg then
   335                 [Pretty.str ("A total of " ^ string_of_int ngoals ^ " subgoals...")]
   336              else [])
   337           else pretty_subgoals As) @
   338         pretty_ffpairs tpairs @
   339         (if ! show_consts then pretty_consts prop else []) @
   340         (if types then pretty_vars prop else []) @
   341         (if sorts then pretty_varsT prop else []);
   342     in
   343       setmp show_no_free_types true
   344         (setmp show_types (! show_types orelse ! show_sorts)
   345           (setmp show_sorts false pretty_gs))
   346      (! show_types orelse ! show_sorts, ! show_sorts)
   347   end;
   348 
   349 in
   350   fun pretty_goals_marker bg = pretty_goals_marker_aux bg true true;
   351   val print_goals_marker = (Pretty.writeln o Pretty.chunks) ooo pretty_goals_marker;
   352   val pretty_sub_goals = pretty_goals_marker_aux "" false;
   353   val pretty_goals = pretty_goals_marker "";
   354   val print_goals = print_goals_marker "";
   355 end;
   356 
   357 
   358 (* print_current_goals *)
   359 
   360 val current_goals_markers = ref ("", "", "");
   361 
   362 fun print_current_goals_default n max th =
   363   let
   364     val ref (begin_state, end_state, begin_goal) = current_goals_markers;
   365     val ngoals = nprems_of th;
   366   in
   367     if begin_state = "" then () else writeln begin_state;
   368     writeln ("Level " ^ string_of_int n ^
   369       (if ngoals > 0 then " (" ^ string_of_int ngoals ^ " subgoal" ^
   370         (if ngoals <> 1 then "s" else "") ^ ")"
   371       else ""));
   372     print_goals_marker begin_goal max th;
   373     if end_state = "" then () else writeln end_state
   374   end;
   375 
   376 val print_current_goals_fn = ref print_current_goals_default;
   377 
   378 end;
   379 
   380 structure BasicDisplay: BASIC_DISPLAY = Display;
   381 open BasicDisplay;