src/Pure/sign.ML
author wenzelm
Fri Sep 25 19:13:47 2015 +0200 (2015-09-25)
changeset 61262 7bd1eb4b056e
parent 59990 a81dc82ecba3
child 66245 da3b0e848182
permissions -rw-r--r--
tuned signature: eliminated pointless type Context.pretty;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val change_begin: theory -> theory
    11   val change_end: theory -> theory
    12   val change_end_local: Proof.context -> Proof.context
    13   val change_check: theory -> theory
    14   val syn_of: theory -> Syntax.syntax
    15   val tsig_of: theory -> Type.tsig
    16   val classes_of: theory -> Sorts.algebra
    17   val all_classes: theory -> class list
    18   val super_classes: theory -> class -> class list
    19   val minimize_sort: theory -> sort -> sort
    20   val complete_sort: theory -> sort -> sort
    21   val set_defsort: sort -> theory -> theory
    22   val defaultS: theory -> sort
    23   val subsort: theory -> sort * sort -> bool
    24   val of_sort: theory -> typ * sort -> bool
    25   val inter_sort: theory -> sort * sort -> sort
    26   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    27   val logical_types: theory -> string list
    28   val typ_instance: theory -> typ * typ -> bool
    29   val typ_equiv: theory -> typ * typ -> bool
    30   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    31   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    32   val consts_of: theory -> Consts.T
    33   val the_const_constraint: theory -> string -> typ
    34   val const_type: theory -> string -> typ option
    35   val the_const_type: theory -> string -> typ
    36   val declared_tyname: theory -> string -> bool
    37   val declared_const: theory -> string -> bool
    38   val naming_of: theory -> Name_Space.naming
    39   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    40   val restore_naming: theory -> theory -> theory
    41   val inherit_naming: theory -> Proof.context -> Context.generic
    42   val full_name: theory -> binding -> string
    43   val full_name_path: theory -> string -> binding -> string
    44   val full_bname: theory -> bstring -> string
    45   val full_bname_path: theory -> string -> bstring -> string
    46   val const_monomorphic: theory -> string -> bool
    47   val const_typargs: theory -> string * typ -> typ list
    48   val const_instance: theory -> string * typ list -> typ
    49   val mk_const: theory -> string * typ list -> term
    50   val class_space: theory -> Name_Space.T
    51   val type_space: theory -> Name_Space.T
    52   val const_space: theory -> Name_Space.T
    53   val intern_class: theory -> xstring -> string
    54   val intern_type: theory -> xstring -> string
    55   val intern_const: theory -> xstring -> string
    56   val class_alias: binding -> class -> theory -> theory
    57   val type_alias: binding -> string -> theory -> theory
    58   val const_alias: binding -> string -> theory -> theory
    59   val arity_number: theory -> string -> int
    60   val arity_sorts: theory -> string -> sort -> sort list
    61   val certify_class: theory -> class -> class
    62   val certify_sort: theory -> sort -> sort
    63   val certify_typ: theory -> typ -> typ
    64   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    65   val certify': bool -> Context.generic -> bool -> Consts.T -> theory -> term -> term * typ * int
    66   val certify_term: theory -> term -> term * typ * int
    67   val cert_term: theory -> term -> term
    68   val cert_prop: theory -> term -> term
    69   val no_frees: Proof.context -> term -> term
    70   val no_vars: Proof.context -> term -> term
    71   val add_type: Proof.context -> binding * int * mixfix -> theory -> theory
    72   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    73   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    74   val add_nonterminals_global: binding list -> theory -> theory
    75   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    76   val add_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    77   val add_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    78   val del_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    79   val del_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    80   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    81   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    82   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    83   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    84   val add_consts: (binding * typ * mixfix) list -> theory -> theory
    85   val add_consts_cmd: (binding * string * mixfix) list -> theory -> theory
    86   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    87   val revert_abbrev: string -> string -> theory -> theory
    88   val add_const_constraint: string * typ option -> theory -> theory
    89   val primitive_class: binding * class list -> theory -> theory
    90   val primitive_classrel: class * class -> theory -> theory
    91   val primitive_arity: arity -> theory -> theory
    92   val parse_ast_translation:
    93     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
    94   val parse_translation:
    95     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    96   val print_translation:
    97     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    98   val typed_print_translation:
    99     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   100   val print_ast_translation:
   101     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   102   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   103   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   104   val get_scope: theory -> Binding.scope option
   105   val new_scope: theory -> Binding.scope * theory
   106   val new_group: theory -> theory
   107   val reset_group: theory -> theory
   108   val add_path: string -> theory -> theory
   109   val root_path: theory -> theory
   110   val parent_path: theory -> theory
   111   val mandatory_path: string -> theory -> theory
   112   val qualified_path: bool -> binding -> theory -> theory
   113   val local_path: theory -> theory
   114   val private_scope: Binding.scope -> theory -> theory
   115   val private: Position.T -> theory -> theory
   116   val qualified_scope: Binding.scope -> theory -> theory
   117   val qualified: Position.T -> theory -> theory
   118   val concealed: theory -> theory
   119   val hide_class: bool -> string -> theory -> theory
   120   val hide_type: bool -> string -> theory -> theory
   121   val hide_const: bool -> string -> theory -> theory
   122 end
   123 
   124 structure Sign: SIGN =
   125 struct
   126 
   127 (** datatype sign **)
   128 
   129 datatype sign = Sign of
   130  {syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   131   tsig: Type.tsig,              (*order-sorted signature of types*)
   132   consts: Consts.T};            (*polymorphic constants*)
   133 
   134 fun make_sign (syn, tsig, consts) = Sign {syn = syn, tsig = tsig, consts = consts};
   135 
   136 structure Data = Theory_Data'
   137 (
   138   type T = sign;
   139   fun extend (Sign {syn, tsig, consts, ...}) = make_sign (syn, tsig, consts);
   140 
   141   val empty = make_sign (Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   142 
   143   fun merge old_thys (sign1, sign2) =
   144     let
   145       val Sign {syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   146       val Sign {syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   147 
   148       val syn = Syntax.merge_syntax (syn1, syn2);
   149       val tsig = Type.merge_tsig (Context.Theory (fst old_thys)) (tsig1, tsig2);
   150       val consts = Consts.merge (consts1, consts2);
   151     in make_sign (syn, tsig, consts) end;
   152 );
   153 
   154 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   155 
   156 fun map_sign f = Data.map (fn Sign {syn, tsig, consts} => make_sign (f (syn, tsig, consts)));
   157 
   158 fun map_syn f = map_sign (fn (syn, tsig, consts) => (f syn, tsig, consts));
   159 fun map_tsig f = map_sign (fn (syn, tsig, consts) => (syn, f tsig, consts));
   160 fun map_consts f = map_sign (fn (syn, tsig, consts) => (syn, tsig, f consts));
   161 
   162 
   163 (* linear change discipline *)
   164 
   165 fun change_base begin = map_sign (fn (syn, tsig, consts) =>
   166   (syn, Type.change_base begin tsig, Consts.change_base begin consts));
   167 
   168 val change_begin = change_base true;
   169 val change_end = change_base false;
   170 
   171 fun change_end_local ctxt =
   172   Context.raw_transfer (change_end (Proof_Context.theory_of ctxt)) ctxt;
   173 
   174 fun change_check thy =
   175   if can change_end thy
   176   then raise Fail "Unfinished linear change of theory content" else thy;
   177 
   178 
   179 (* syntax *)
   180 
   181 val syn_of = #syn o rep_sg;
   182 
   183 
   184 (* type signature *)
   185 
   186 val tsig_of = #tsig o rep_sg;
   187 
   188 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   189 val all_classes = Sorts.all_classes o classes_of;
   190 val super_classes = Sorts.super_classes o classes_of;
   191 val minimize_sort = Sorts.minimize_sort o classes_of;
   192 val complete_sort = Sorts.complete_sort o classes_of;
   193 
   194 val set_defsort = map_tsig o Type.set_defsort;
   195 val defaultS = Type.defaultS o tsig_of;
   196 val subsort = Type.subsort o tsig_of;
   197 val of_sort = Type.of_sort o tsig_of;
   198 val inter_sort = Type.inter_sort o tsig_of;
   199 val witness_sorts = Type.witness_sorts o tsig_of;
   200 val logical_types = Type.logical_types o tsig_of;
   201 
   202 val typ_instance = Type.typ_instance o tsig_of;
   203 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   204 val typ_match = Type.typ_match o tsig_of;
   205 val typ_unify = Type.unify o tsig_of;
   206 
   207 
   208 (* polymorphic constants *)
   209 
   210 val consts_of = #consts o rep_sg;
   211 val the_const_constraint = Consts.the_constraint o consts_of;
   212 val the_const_type = #2 oo (Consts.the_const o consts_of);
   213 val const_type = try o the_const_type;
   214 val const_monomorphic = Consts.is_monomorphic o consts_of;
   215 val const_typargs = Consts.typargs o consts_of;
   216 val const_instance = Consts.instance o consts_of;
   217 
   218 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   219 
   220 fun declared_tyname ctxt c = can (Type.the_decl (tsig_of ctxt)) (c, Position.none);
   221 val declared_const = can o the_const_constraint;
   222 
   223 
   224 (* naming *)
   225 
   226 val naming_of = Name_Space.naming_of o Context.Theory;
   227 val map_naming = Context.theory_map o Name_Space.map_naming;
   228 val restore_naming = map_naming o K o naming_of;
   229 fun inherit_naming thy = Name_Space.map_naming (K (naming_of thy)) o Context.Proof;
   230 
   231 val full_name = Name_Space.full_name o naming_of;
   232 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   233 
   234 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   235 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   236 
   237 
   238 
   239 (** name spaces **)
   240 
   241 val class_space = Type.class_space o tsig_of;
   242 val type_space = Type.type_space o tsig_of;
   243 val const_space = Consts.space_of o consts_of;
   244 
   245 val intern_class = Name_Space.intern o class_space;
   246 val intern_type = Name_Space.intern o type_space;
   247 val intern_const = Name_Space.intern o const_space;
   248 
   249 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   250 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   251 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   252 
   253 
   254 
   255 (** certify entities **)    (*exception TYPE*)
   256 
   257 (* certify wrt. type signature *)
   258 
   259 val arity_number = Type.arity_number o tsig_of;
   260 fun arity_sorts thy = Type.arity_sorts (Context.Theory thy) (tsig_of thy);
   261 
   262 val certify_class = Type.cert_class o tsig_of;
   263 val certify_sort = Type.cert_sort o tsig_of;
   264 val certify_typ = Type.cert_typ o tsig_of;
   265 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   266 
   267 
   268 (* certify term/prop *)
   269 
   270 local
   271 
   272 fun type_check context tm =
   273   let
   274     fun err_appl bs t T u U =
   275       let
   276         val xs = map Free bs;           (*we do not rename here*)
   277         val t' = subst_bounds (xs, t);
   278         val u' = subst_bounds (xs, u);
   279         val msg = Type.appl_error (Syntax.init_pretty context) t' T u' U;
   280       in raise TYPE (msg, [T, U], [t', u']) end;
   281 
   282     fun typ_of (_, Const (_, T)) = T
   283       | typ_of (_, Free  (_, T)) = T
   284       | typ_of (_, Var (_, T)) = T
   285       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   286           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   287       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   288       | typ_of (bs, t $ u) =
   289           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   290             (case T of
   291               Type ("fun", [T1, T2]) =>
   292                 if T1 = U then T2 else err_appl bs t T u U
   293             | _ => err_appl bs t T u U)
   294           end;
   295   in typ_of ([], tm) end;
   296 
   297 fun err msg = raise TYPE (msg, [], []);
   298 
   299 fun check_vars (t $ u) = (check_vars t; check_vars u)
   300   | check_vars (Abs (_, _, t)) = check_vars t
   301   | check_vars (Free (x, _)) =
   302       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   303   | check_vars (Var (xi as (_, i), _)) =
   304       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   305   | check_vars _ = ();
   306 
   307 in
   308 
   309 fun certify' prop context do_expand consts thy tm =
   310   let
   311     val _ = check_vars tm;
   312     val tm' = Term.map_types (certify_typ thy) tm;
   313     val T = type_check context tm';
   314     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   315     val tm'' = Consts.certify context (tsig_of thy) do_expand consts tm';
   316   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   317 
   318 fun certify_term thy = certify' false (Context.Theory thy) true (consts_of thy) thy;
   319 fun cert_term_abbrev thy = #1 o certify' false (Context.Theory thy) false (consts_of thy) thy;
   320 val cert_term = #1 oo certify_term;
   321 fun cert_prop thy = #1 o certify' true (Context.Theory thy) true (consts_of thy) thy;
   322 
   323 end;
   324 
   325 
   326 (* specifications *)
   327 
   328 fun no_variables kind add addT mk mkT ctxt tm =
   329   (case (add tm [], addT tm []) of
   330     ([], []) => tm
   331   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   332       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   333        Pretty.commas
   334         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   335 
   336 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   337 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   338 
   339 
   340 
   341 (** signature extension functions **)  (*exception ERROR/TYPE*)
   342 
   343 (* add type constructors *)
   344 
   345 fun add_type ctxt (b, n, mx) thy = thy |> map_sign (fn (syn, tsig, consts) =>
   346   let
   347     val type_syntax = (Lexicon.mark_type (full_name thy b), Mixfix.make_type n, mx);
   348     val syn' = Syntax.update_type_gram true Syntax.mode_default [type_syntax] syn;
   349     val tsig' = Type.add_type (inherit_naming thy ctxt) (b, n) tsig;
   350   in (syn', tsig', consts) end);
   351 
   352 fun add_types_global types thy =
   353   fold (add_type (Syntax.init_pretty_global thy)) types thy;
   354 
   355 
   356 (* add nonterminals *)
   357 
   358 fun add_nonterminals ctxt ns thy = thy |> map_sign (fn (syn, tsig, consts) =>
   359   (syn, fold (Type.add_nonterminal (inherit_naming thy ctxt)) ns tsig, consts));
   360 
   361 fun add_nonterminals_global ns thy =
   362   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   363 
   364 
   365 (* add type abbreviations *)
   366 
   367 fun add_type_abbrev ctxt abbr thy = thy |> map_sign (fn (syn, tsig, consts) =>
   368   (syn, Type.add_abbrev (inherit_naming thy ctxt) abbr tsig, consts));
   369 
   370 
   371 (* modify syntax *)
   372 
   373 fun gen_syntax change_gram parse_typ mode args thy =
   374   let
   375     val ctxt = Type.set_mode Type.mode_syntax (Proof_Context.init_global thy);
   376     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   377       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   378   in thy |> map_syn (change_gram (logical_types thy) mode (map prep args)) end;
   379 
   380 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   381 
   382 val add_syntax = gen_add_syntax (K I);
   383 val add_syntax_cmd = gen_add_syntax Syntax.read_typ;
   384 val del_syntax = gen_syntax (Syntax.update_const_gram false) (K I);
   385 val del_syntax_cmd = gen_syntax (Syntax.update_const_gram false) Syntax.read_typ;
   386 
   387 fun type_notation add mode args =
   388   let
   389     fun type_syntax (Type (c, args), mx) =
   390           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   391       | type_syntax _ = NONE;
   392   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   393 
   394 fun notation add mode args thy =
   395   let
   396     fun const_syntax (Const (c, _), mx) =
   397           (case try (Consts.type_scheme (consts_of thy)) c of
   398             SOME T => SOME (Lexicon.mark_const c, T, mx)
   399           | NONE => NONE)
   400       | const_syntax _ = NONE;
   401   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   402 
   403 
   404 (* add constants *)
   405 
   406 local
   407 
   408 fun gen_add_consts prep_typ ctxt raw_args thy =
   409   let
   410     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o prep_typ ctxt;
   411     fun prep (b, raw_T, mx) =
   412       let
   413         val c = full_name thy b;
   414         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   415           cat_error msg ("in declaration of constant " ^ Binding.print b);
   416         val T' = Logic.varifyT_global T;
   417       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   418     val args = map prep raw_args;
   419   in
   420     thy
   421     |> map_consts (fold (Consts.declare (inherit_naming thy ctxt) o #1) args)
   422     |> add_syntax Syntax.mode_default (map #2 args)
   423     |> pair (map #3 args)
   424   end;
   425 
   426 in
   427 
   428 fun add_consts args thy =
   429   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   430 
   431 fun add_consts_cmd args thy =
   432   #2 (gen_add_consts Syntax.read_typ (Proof_Context.init_global thy) args thy);
   433 
   434 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   435 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   436 
   437 end;
   438 
   439 
   440 (* abbreviations *)
   441 
   442 fun add_abbrev mode (b, raw_t) thy =  (* FIXME proper ctxt (?) *)
   443   let
   444     val ctxt = Syntax.init_pretty_global thy;
   445     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   446     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   447       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   448     val (res, consts') = consts_of thy
   449       |> Consts.abbreviate (inherit_naming thy ctxt) (tsig_of thy) mode (b, t);
   450   in (res, thy |> map_consts (K consts')) end;
   451 
   452 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   453 
   454 
   455 (* add constraints *)
   456 
   457 fun add_const_constraint (c, opt_T) thy =
   458   let
   459     fun prepT raw_T =
   460       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   461       in cert_term thy (Const (c, T)); T end
   462       handle TYPE (msg, _, _) => error msg;
   463   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   464 
   465 
   466 (* primitive classes and arities *)
   467 
   468 fun primitive_class (bclass, classes) thy =
   469   thy
   470   |> map_sign (fn (syn, tsig, consts) =>
   471       let val tsig' = Type.add_class (Context.Theory thy) (bclass, classes) tsig;
   472       in (syn, tsig', consts) end)
   473   |> add_consts [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   474 
   475 fun primitive_classrel arg thy =
   476   thy |> map_tsig (Type.add_classrel (Context.Theory thy) arg);
   477 
   478 fun primitive_arity arg thy =
   479   thy |> map_tsig (Type.add_arity (Context.Theory thy) arg);
   480 
   481 
   482 (* add translation functions *)
   483 
   484 local
   485 
   486 fun mk trs = map Syntax_Ext.mk_trfun trs;
   487 
   488 in
   489 
   490 fun parse_ast_translation atrs = map_syn (Syntax.update_trfuns (mk atrs, [], [], []));
   491 fun parse_translation trs = map_syn (Syntax.update_trfuns ([], mk trs, [], []));
   492 fun print_translation tr's =
   493   map_syn (Syntax.update_trfuns ([], [], mk (map (apsnd Syntax_Trans.non_typed_tr') tr's), []));
   494 fun typed_print_translation tr's = map_syn (Syntax.update_trfuns ([], [], mk tr's, []));
   495 fun print_ast_translation atr's = map_syn (Syntax.update_trfuns ([], [], [], mk atr's));
   496 
   497 end;
   498 
   499 
   500 (* translation rules *)
   501 
   502 val add_trrules = map_syn o Syntax.update_trrules;
   503 val del_trrules = map_syn o Syntax.remove_trrules;
   504 
   505 
   506 (* naming *)
   507 
   508 val get_scope = Name_Space.get_scope o naming_of;
   509 
   510 fun new_scope thy =
   511   let
   512     val (scope, naming') = Name_Space.new_scope (naming_of thy);
   513     val thy' = map_naming (K naming') thy;
   514   in (scope, thy') end;
   515 
   516 val new_group = map_naming Name_Space.new_group;
   517 val reset_group = map_naming Name_Space.reset_group;
   518 
   519 val add_path = map_naming o Name_Space.add_path;
   520 val root_path = map_naming Name_Space.root_path;
   521 val parent_path = map_naming Name_Space.parent_path;
   522 val mandatory_path = map_naming o Name_Space.mandatory_path;
   523 val qualified_path = map_naming oo Name_Space.qualified_path;
   524 
   525 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   526 
   527 val private_scope = map_naming o Name_Space.private_scope;
   528 val private = map_naming o Name_Space.private;
   529 val qualified_scope = map_naming o Name_Space.qualified_scope;
   530 val qualified = map_naming o Name_Space.qualified;
   531 val concealed = map_naming Name_Space.concealed;
   532 
   533 
   534 (* hide names *)
   535 
   536 val hide_class = map_tsig oo Type.hide_class;
   537 val hide_type = map_tsig oo Type.hide_type;
   538 val hide_const = map_consts oo Consts.hide;
   539 
   540 end;