src/HOL/Complete_Lattice.thy
author hoelzl
Thu Dec 02 14:34:58 2010 +0100 (2010-12-02)
changeset 40872 7c556a9240de
parent 40714 4c17bfdf6f84
child 41080 294956ff285b
permissions -rw-r--r--
Move SUP_commute, SUP_less_iff to HOL image;
Cleanup generic complete_lattice lemmas in Positive_Infinite_Real;
Cleanup lemma positive_integral_alt;
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    56   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    57 
    58 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    59   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    60 
    61 lemma Inf_singleton [simp]:
    62   "\<Sqinter>{a} = a"
    63   by (auto intro: antisym Inf_lower Inf_greatest)
    64 
    65 lemma Sup_singleton [simp]:
    66   "\<Squnion>{a} = a"
    67   by (auto intro: antisym Sup_upper Sup_least)
    68 
    69 lemma Inf_binary:
    70   "\<Sqinter>{a, b} = a \<sqinter> b"
    71   by (simp add: Inf_empty Inf_insert)
    72 
    73 lemma Sup_binary:
    74   "\<Squnion>{a, b} = a \<squnion> b"
    75   by (simp add: Sup_empty Sup_insert)
    76 
    77 lemma Inf_UNIV:
    78   "\<Sqinter>UNIV = bot"
    79   by (simp add: Sup_Inf Sup_empty [symmetric])
    80 
    81 lemma Sup_UNIV:
    82   "\<Squnion>UNIV = top"
    83   by (simp add: Inf_Sup Inf_empty [symmetric])
    84 
    85 lemma Sup_le_iff: "Sup A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    86   by (auto intro: Sup_least dest: Sup_upper)
    87 
    88 lemma le_Inf_iff: "b \<sqsubseteq> Inf A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    89   by (auto intro: Inf_greatest dest: Inf_lower)
    90 
    91 lemma Sup_mono:
    92   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<le> b"
    93   shows "Sup A \<le> Sup B"
    94 proof (rule Sup_least)
    95   fix a assume "a \<in> A"
    96   with assms obtain b where "b \<in> B" and "a \<le> b" by blast
    97   from `b \<in> B` have "b \<le> Sup B" by (rule Sup_upper)
    98   with `a \<le> b` show "a \<le> Sup B" by auto
    99 qed
   100 
   101 lemma Inf_mono:
   102   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<le> b"
   103   shows "Inf A \<le> Inf B"
   104 proof (rule Inf_greatest)
   105   fix b assume "b \<in> B"
   106   with assms obtain a where "a \<in> A" and "a \<le> b" by blast
   107   from `a \<in> A` have "Inf A \<le> a" by (rule Inf_lower)
   108   with `a \<le> b` show "Inf A \<le> b" by auto
   109 qed
   110 
   111 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   112   "SUPR A f = \<Squnion> (f ` A)"
   113 
   114 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   115   "INFI A f = \<Sqinter> (f ` A)"
   116 
   117 end
   118 
   119 syntax
   120   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
   121   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   122   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
   123   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   124 
   125 translations
   126   "SUP x y. B"   == "SUP x. SUP y. B"
   127   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   128   "SUP x. B"     == "SUP x:CONST UNIV. B"
   129   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   130   "INF x y. B"   == "INF x. INF y. B"
   131   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   132   "INF x. B"     == "INF x:CONST UNIV. B"
   133   "INF x:A. B"   == "CONST INFI A (%x. B)"
   134 
   135 print_translation {*
   136   [Syntax.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"},
   137     Syntax.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"}]
   138 *} -- {* to avoid eta-contraction of body *}
   139 
   140 context complete_lattice
   141 begin
   142 
   143 lemma le_SUPI: "i : A \<Longrightarrow> M i \<sqsubseteq> (SUP i:A. M i)"
   144   by (auto simp add: SUPR_def intro: Sup_upper)
   145 
   146 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (SUP i:A. M i) \<sqsubseteq> u"
   147   by (auto simp add: SUPR_def intro: Sup_least)
   148 
   149 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<sqsubseteq> M i"
   150   by (auto simp add: INFI_def intro: Inf_lower)
   151 
   152 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (INF i:A. M i)"
   153   by (auto simp add: INFI_def intro: Inf_greatest)
   154 
   155 lemma SUP_le_iff: "(SUP i:A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   156   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   157 
   158 lemma le_INF_iff: "u \<sqsubseteq> (INF i:A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   159   unfolding INFI_def by (auto simp add: le_Inf_iff)
   160 
   161 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
   162   by (auto intro: antisym SUP_leI le_SUPI)
   163 
   164 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
   165   by (auto intro: antisym INF_leI le_INFI)
   166 
   167 lemma SUP_mono:
   168   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<le> g m) \<Longrightarrow> (SUP n:A. f n) \<le> (SUP n:B. g n)"
   169   by (force intro!: Sup_mono simp: SUPR_def)
   170 
   171 lemma INF_mono:
   172   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<le> g m) \<Longrightarrow> (INF n:A. f n) \<le> (INF n:B. g n)"
   173   by (force intro!: Inf_mono simp: INFI_def)
   174 
   175 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<le> SUPR B f"
   176   by (intro SUP_mono) auto
   177 
   178 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<le> INFI A f"
   179   by (intro INF_mono) auto
   180 
   181 lemma SUP_commute: "(SUP i:A. SUP j:B. f i j) = (SUP j:B. SUP i:A. f i j)"
   182   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   183 
   184 lemma INF_commute: "(INF i:A. INF j:B. f i j) = (INF j:B. INF i:A. f i j)"
   185   by (iprover intro: INF_leI le_INFI order_trans antisym)
   186 
   187 end
   188 
   189 lemma less_Sup_iff:
   190   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   191   shows "a < Sup S \<longleftrightarrow> (\<exists>x\<in>S. a < x)"
   192   unfolding not_le[symmetric] Sup_le_iff by auto
   193 
   194 lemma Inf_less_iff:
   195   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   196   shows "Inf S < a \<longleftrightarrow> (\<exists>x\<in>S. x < a)"
   197   unfolding not_le[symmetric] le_Inf_iff by auto
   198 
   199 lemma less_SUP_iff:
   200   fixes a :: "'a::{complete_lattice,linorder}"
   201   shows "a < (SUP i:A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a < f x)"
   202   unfolding SUPR_def less_Sup_iff by auto
   203 
   204 lemma INF_less_iff:
   205   fixes a :: "'a::{complete_lattice,linorder}"
   206   shows "(INF i:A. f i) < a \<longleftrightarrow> (\<exists>x\<in>A. f x < a)"
   207   unfolding INFI_def Inf_less_iff by auto
   208 
   209 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   210 
   211 instantiation bool :: complete_lattice
   212 begin
   213 
   214 definition
   215   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   216 
   217 definition
   218   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   219 
   220 instance proof
   221 qed (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   222 
   223 end
   224 
   225 lemma Inf_empty_bool [simp]:
   226   "\<Sqinter>{}"
   227   unfolding Inf_bool_def by auto
   228 
   229 lemma not_Sup_empty_bool [simp]:
   230   "\<not> \<Squnion>{}"
   231   unfolding Sup_bool_def by auto
   232 
   233 lemma INFI_bool_eq:
   234   "INFI = Ball"
   235 proof (rule ext)+
   236   fix A :: "'a set"
   237   fix P :: "'a \<Rightarrow> bool"
   238   show "(INF x:A. P x) \<longleftrightarrow> (\<forall>x \<in> A. P x)"
   239     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   240 qed
   241 
   242 lemma SUPR_bool_eq:
   243   "SUPR = Bex"
   244 proof (rule ext)+
   245   fix A :: "'a set"
   246   fix P :: "'a \<Rightarrow> bool"
   247   show "(SUP x:A. P x) \<longleftrightarrow> (\<exists>x \<in> A. P x)"
   248     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   249 qed
   250 
   251 instantiation "fun" :: (type, complete_lattice) complete_lattice
   252 begin
   253 
   254 definition
   255   Inf_fun_def: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   256 
   257 definition
   258   Sup_fun_def: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   259 
   260 instance proof
   261 qed (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
   262   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   263 
   264 end
   265 
   266 lemma SUPR_fun_expand:
   267   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c\<Colon>{complete_lattice}"
   268   shows "(SUP y:A. f y) = (\<lambda>x. SUP y:A. f y x)"
   269   by (auto intro!: arg_cong[where f=Sup] ext[where 'a='b]
   270            simp: SUPR_def Sup_fun_def)
   271 
   272 lemma INFI_fun_expand:
   273   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c\<Colon>{complete_lattice}"
   274   shows "(INF y:A. f y) x = (INF y:A. f y x)"
   275   by (auto intro!: arg_cong[where f=Inf] ext[where 'a='b]
   276            simp: INFI_def Inf_fun_def)
   277 
   278 lemma Inf_empty_fun:
   279   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
   280   by (simp add: Inf_fun_def)
   281 
   282 lemma Sup_empty_fun:
   283   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
   284   by (simp add: Sup_fun_def)
   285 
   286 
   287 subsection {* Union *}
   288 
   289 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   290   "Union S \<equiv> \<Squnion>S"
   291 
   292 notation (xsymbols)
   293   Union  ("\<Union>_" [90] 90)
   294 
   295 lemma Union_eq:
   296   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   297 proof (rule set_eqI)
   298   fix x
   299   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   300     by auto
   301   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   302     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   303 qed
   304 
   305 lemma Union_iff [simp, no_atp]:
   306   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   307   by (unfold Union_eq) blast
   308 
   309 lemma UnionI [intro]:
   310   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   311   -- {* The order of the premises presupposes that @{term C} is rigid;
   312     @{term A} may be flexible. *}
   313   by auto
   314 
   315 lemma UnionE [elim!]:
   316   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A\<in>X \<Longrightarrow> X\<in>C \<Longrightarrow> R) \<Longrightarrow> R"
   317   by auto
   318 
   319 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   320   by (iprover intro: subsetI UnionI)
   321 
   322 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   323   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   324 
   325 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   326   by blast
   327 
   328 lemma Union_empty [simp]: "Union({}) = {}"
   329   by blast
   330 
   331 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
   332   by blast
   333 
   334 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
   335   by blast
   336 
   337 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
   338   by blast
   339 
   340 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   341   by blast
   342 
   343 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
   344   by blast
   345 
   346 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
   347   by blast
   348 
   349 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
   350   by blast
   351 
   352 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   353   by blast
   354 
   355 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   356   by blast
   357 
   358 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
   359   by blast
   360 
   361 
   362 subsection {* Unions of families *}
   363 
   364 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   365   "UNION \<equiv> SUPR"
   366 
   367 syntax
   368   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   369   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   370 
   371 syntax (xsymbols)
   372   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   373   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   374 
   375 syntax (latex output)
   376   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   377   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   378 
   379 translations
   380   "UN x y. B"   == "UN x. UN y. B"
   381   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   382   "UN x. B"     == "UN x:CONST UNIV. B"
   383   "UN x:A. B"   == "CONST UNION A (%x. B)"
   384 
   385 text {*
   386   Note the difference between ordinary xsymbol syntax of indexed
   387   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   388   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   389   former does not make the index expression a subscript of the
   390   union/intersection symbol because this leads to problems with nested
   391   subscripts in Proof General.
   392 *}
   393 
   394 print_translation {*
   395   [Syntax.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   396 *} -- {* to avoid eta-contraction of body *}
   397 
   398 lemma UNION_eq_Union_image:
   399   "(\<Union>x\<in>A. B x) = \<Union>(B`A)"
   400   by (fact SUPR_def)
   401 
   402 lemma Union_def:
   403   "\<Union>S = (\<Union>x\<in>S. x)"
   404   by (simp add: UNION_eq_Union_image image_def)
   405 
   406 lemma UNION_def [no_atp]:
   407   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   408   by (auto simp add: UNION_eq_Union_image Union_eq)
   409   
   410 lemma Union_image_eq [simp]:
   411   "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
   412   by (rule sym) (fact UNION_eq_Union_image)
   413   
   414 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   415   by (unfold UNION_def) blast
   416 
   417 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   418   -- {* The order of the premises presupposes that @{term A} is rigid;
   419     @{term b} may be flexible. *}
   420   by auto
   421 
   422 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   423   by (unfold UNION_def) blast
   424 
   425 lemma UN_cong [cong]:
   426     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   427   by (simp add: UNION_def)
   428 
   429 lemma strong_UN_cong:
   430     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   431   by (simp add: UNION_def simp_implies_def)
   432 
   433 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
   434   by blast
   435 
   436 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   437   by (fact le_SUPI)
   438 
   439 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   440   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   441 
   442 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   443   by blast
   444 
   445 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   446   by blast
   447 
   448 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   449   by blast
   450 
   451 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   452   by blast
   453 
   454 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   455   by blast
   456 
   457 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   458   by auto
   459 
   460 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   461   by blast
   462 
   463 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   464   by blast
   465 
   466 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   467   by blast
   468 
   469 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   470   by (fact SUP_le_iff)
   471 
   472 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   473   by blast
   474 
   475 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   476   by auto
   477 
   478 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   479   by blast
   480 
   481 lemma UNION_empty_conv[simp]:
   482   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
   483   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
   484 by blast+
   485 
   486 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   487   by blast
   488 
   489 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   490   by blast
   491 
   492 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   493   by blast
   494 
   495 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   496   by (auto simp add: split_if_mem2)
   497 
   498 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
   499   by (auto intro: bool_contrapos)
   500 
   501 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   502   by blast
   503 
   504 lemma UN_mono:
   505   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   506     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   507   by (blast dest: subsetD)
   508 
   509 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
   510   by blast
   511 
   512 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
   513   by blast
   514 
   515 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
   516   -- {* NOT suitable for rewriting *}
   517   by blast
   518 
   519 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
   520 by blast
   521 
   522 
   523 subsection {* Inter *}
   524 
   525 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   526   "Inter S \<equiv> \<Sqinter>S"
   527   
   528 notation (xsymbols)
   529   Inter  ("\<Inter>_" [90] 90)
   530 
   531 lemma Inter_eq:
   532   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   533 proof (rule set_eqI)
   534   fix x
   535   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   536     by auto
   537   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   538     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   539 qed
   540 
   541 lemma Inter_iff [simp,no_atp]: "(A : Inter C) = (ALL X:C. A:X)"
   542   by (unfold Inter_eq) blast
   543 
   544 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   545   by (simp add: Inter_eq)
   546 
   547 text {*
   548   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   549   contains @{term A} as an element, but @{prop "A:X"} can hold when
   550   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   551 *}
   552 
   553 lemma InterD [elim, Pure.elim]: "A : Inter C ==> X:C ==> A:X"
   554   by auto
   555 
   556 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   557   -- {* ``Classical'' elimination rule -- does not require proving
   558     @{prop "X:C"}. *}
   559   by (unfold Inter_eq) blast
   560 
   561 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   562   by blast
   563 
   564 lemma Inter_subset:
   565   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
   566   by blast
   567 
   568 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   569   by (iprover intro: InterI subsetI dest: subsetD)
   570 
   571 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   572   by blast
   573 
   574 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   575   by blast
   576 
   577 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   578   by blast
   579 
   580 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   581   by blast
   582 
   583 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   584   by blast
   585 
   586 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   587   by blast
   588 
   589 lemma Inter_UNIV_conv [simp,no_atp]:
   590   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
   591   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
   592   by blast+
   593 
   594 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
   595   by blast
   596 
   597 
   598 subsection {* Intersections of families *}
   599 
   600 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   601   "INTER \<equiv> INFI"
   602 
   603 syntax
   604   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   605   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   606 
   607 syntax (xsymbols)
   608   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   609   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   610 
   611 syntax (latex output)
   612   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   613   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   614 
   615 translations
   616   "INT x y. B"  == "INT x. INT y. B"
   617   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   618   "INT x. B"    == "INT x:CONST UNIV. B"
   619   "INT x:A. B"  == "CONST INTER A (%x. B)"
   620 
   621 print_translation {*
   622   [Syntax.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   623 *} -- {* to avoid eta-contraction of body *}
   624 
   625 lemma INTER_eq_Inter_image:
   626   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   627   by (fact INFI_def)
   628   
   629 lemma Inter_def:
   630   "\<Inter>S = (\<Inter>x\<in>S. x)"
   631   by (simp add: INTER_eq_Inter_image image_def)
   632 
   633 lemma INTER_def:
   634   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   635   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   636 
   637 lemma Inter_image_eq [simp]:
   638   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   639   by (rule sym) (fact INTER_eq_Inter_image)
   640 
   641 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   642   by (unfold INTER_def) blast
   643 
   644 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   645   by (unfold INTER_def) blast
   646 
   647 lemma INT_D [elim, Pure.elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   648   by auto
   649 
   650 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   651   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   652   by (unfold INTER_def) blast
   653 
   654 lemma INT_cong [cong]:
   655     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   656   by (simp add: INTER_def)
   657 
   658 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   659   by blast
   660 
   661 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   662   by blast
   663 
   664 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   665   by (fact INF_leI)
   666 
   667 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   668   by (fact le_INFI)
   669 
   670 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   671   by blast
   672 
   673 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   674   by blast
   675 
   676 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
   677   by (fact le_INF_iff)
   678 
   679 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   680   by blast
   681 
   682 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   683   by blast
   684 
   685 lemma INT_insert_distrib:
   686     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   687   by blast
   688 
   689 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   690   by auto
   691 
   692 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   693   -- {* Look: it has an \emph{existential} quantifier *}
   694   by blast
   695 
   696 lemma INTER_UNIV_conv[simp]:
   697  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   698  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   699 by blast+
   700 
   701 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
   702   by (auto intro: bool_induct)
   703 
   704 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   705   by blast
   706 
   707 lemma INT_anti_mono:
   708   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   709     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   710   -- {* The last inclusion is POSITIVE! *}
   711   by (blast dest: subsetD)
   712 
   713 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
   714   by blast
   715 
   716 
   717 subsection {* Distributive laws *}
   718 
   719 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   720   by blast
   721 
   722 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   723   by blast
   724 
   725 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
   726   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   727   -- {* Union of a family of unions *}
   728   by blast
   729 
   730 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   731   -- {* Equivalent version *}
   732   by blast
   733 
   734 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   735   by blast
   736 
   737 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
   738   by blast
   739 
   740 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   741   -- {* Equivalent version *}
   742   by blast
   743 
   744 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   745   -- {* Halmos, Naive Set Theory, page 35. *}
   746   by blast
   747 
   748 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   749   by blast
   750 
   751 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   752   by blast
   753 
   754 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   755   by blast
   756 
   757 
   758 subsection {* Complement *}
   759 
   760 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   761   by blast
   762 
   763 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   764   by blast
   765 
   766 
   767 subsection {* Miniscoping and maxiscoping *}
   768 
   769 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   770            and Intersections. *}
   771 
   772 lemma UN_simps [simp]:
   773   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
   774   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
   775   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
   776   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
   777   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
   778   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
   779   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
   780   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
   781   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
   782   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
   783   by auto
   784 
   785 lemma INT_simps [simp]:
   786   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
   787   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
   788   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
   789   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
   790   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
   791   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
   792   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
   793   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
   794   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
   795   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
   796   by auto
   797 
   798 lemma ball_simps [simp,no_atp]:
   799   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
   800   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
   801   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
   802   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
   803   "!!P. (ALL x:{}. P x) = True"
   804   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
   805   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
   806   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
   807   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
   808   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
   809   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
   810   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
   811   by auto
   812 
   813 lemma bex_simps [simp,no_atp]:
   814   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
   815   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
   816   "!!P. (EX x:{}. P x) = False"
   817   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
   818   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
   819   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
   820   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
   821   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
   822   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
   823   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
   824   by auto
   825 
   826 lemma ball_conj_distrib:
   827   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
   828   by blast
   829 
   830 lemma bex_disj_distrib:
   831   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
   832   by blast
   833 
   834 
   835 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   836 
   837 lemma UN_extend_simps:
   838   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
   839   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
   840   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
   841   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
   842   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
   843   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
   844   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
   845   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
   846   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
   847   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
   848   by auto
   849 
   850 lemma INT_extend_simps:
   851   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
   852   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
   853   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
   854   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
   855   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
   856   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
   857   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
   858   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
   859   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
   860   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
   861   by auto
   862 
   863 
   864 no_notation
   865   less_eq  (infix "\<sqsubseteq>" 50) and
   866   less (infix "\<sqsubset>" 50) and
   867   inf  (infixl "\<sqinter>" 70) and
   868   sup  (infixl "\<squnion>" 65) and
   869   Inf  ("\<Sqinter>_" [900] 900) and
   870   Sup  ("\<Squnion>_" [900] 900) and
   871   top ("\<top>") and
   872   bot ("\<bottom>")
   873 
   874 lemmas mem_simps =
   875   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   876   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   877   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   878 
   879 end