src/HOL/Analysis/Complex_Transcendental.thy
author paulson <lp15@cam.ac.uk>
Thu May 04 15:14:49 2017 +0100 (2017-05-04)
changeset 65719 7c57d79d61b7
parent 65587 16a8991ab398
child 66252 b73f94b366b7
permissions -rw-r--r--
A few more new lemmas
     1 section \<open>Complex Transcendental Functions\<close>
     2 
     3 text\<open>By John Harrison et al.  Ported from HOL Light by L C Paulson (2015)\<close>
     4 
     5 theory Complex_Transcendental
     6 imports
     7   Complex_Analysis_Basics
     8   Summation_Tests
     9    "~~/src/HOL/Library/Periodic_Fun"
    10 begin
    11 
    12 (* TODO: Figure out what to do with Möbius transformations *)
    13 definition "moebius a b c d = (\<lambda>z. (a*z+b) / (c*z+d :: 'a :: field))"
    14 
    15 lemma moebius_inverse:
    16   assumes "a * d \<noteq> b * c" "c * z + d \<noteq> 0"
    17   shows   "moebius d (-b) (-c) a (moebius a b c d z) = z"
    18 proof -
    19   from assms have "(-c) * moebius a b c d z + a \<noteq> 0" unfolding moebius_def
    20     by (simp add: field_simps)
    21   with assms show ?thesis
    22     unfolding moebius_def by (simp add: moebius_def divide_simps) (simp add: algebra_simps)?
    23 qed
    24 
    25 lemma moebius_inverse':
    26   assumes "a * d \<noteq> b * c" "c * z - a \<noteq> 0"
    27   shows   "moebius a b c d (moebius d (-b) (-c) a z) = z"
    28   using assms moebius_inverse[of d a "-b" "-c" z]
    29   by (auto simp: algebra_simps)
    30 
    31 lemma cmod_add_real_less:
    32   assumes "Im z \<noteq> 0" "r\<noteq>0"
    33     shows "cmod (z + r) < cmod z + \<bar>r\<bar>"
    34 proof (cases z)
    35   case (Complex x y)
    36   have "r * x / \<bar>r\<bar> < sqrt (x*x + y*y)"
    37     apply (rule real_less_rsqrt)
    38     using assms
    39     apply (simp add: Complex power2_eq_square)
    40     using not_real_square_gt_zero by blast
    41   then show ?thesis using assms Complex
    42     apply (auto simp: cmod_def)
    43     apply (rule power2_less_imp_less, auto)
    44     apply (simp add: power2_eq_square field_simps)
    45     done
    46 qed
    47 
    48 lemma cmod_diff_real_less: "Im z \<noteq> 0 \<Longrightarrow> x\<noteq>0 \<Longrightarrow> cmod (z - x) < cmod z + \<bar>x\<bar>"
    49   using cmod_add_real_less [of z "-x"]
    50   by simp
    51 
    52 lemma cmod_square_less_1_plus:
    53   assumes "Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1"
    54     shows "(cmod z)\<^sup>2 < 1 + cmod (1 - z\<^sup>2)"
    55   using assms
    56   apply (cases "Im z = 0 \<or> Re z = 0")
    57   using abs_square_less_1
    58     apply (force simp add: Re_power2 Im_power2 cmod_def)
    59   using cmod_diff_real_less [of "1 - z\<^sup>2" "1"]
    60   apply (simp add: norm_power Im_power2)
    61   done
    62 
    63 subsection\<open>The Exponential Function is Differentiable and Continuous\<close>
    64 
    65 lemma field_differentiable_within_exp: "exp field_differentiable (at z within s)"
    66   using DERIV_exp field_differentiable_at_within field_differentiable_def by blast
    67 
    68 lemma continuous_within_exp:
    69   fixes z::"'a::{real_normed_field,banach}"
    70   shows "continuous (at z within s) exp"
    71 by (simp add: continuous_at_imp_continuous_within)
    72 
    73 lemma holomorphic_on_exp [holomorphic_intros]: "exp holomorphic_on s"
    74   by (simp add: field_differentiable_within_exp holomorphic_on_def)
    75 
    76 subsection\<open>Euler and de Moivre formulas.\<close>
    77 
    78 text\<open>The sine series times @{term i}\<close>
    79 lemma sin_i_eq: "(\<lambda>n. (\<i> * sin_coeff n) * z^n) sums (\<i> * sin z)"
    80 proof -
    81   have "(\<lambda>n. \<i> * sin_coeff n *\<^sub>R z^n) sums (\<i> * sin z)"
    82     using sin_converges sums_mult by blast
    83   then show ?thesis
    84     by (simp add: scaleR_conv_of_real field_simps)
    85 qed
    86 
    87 theorem exp_Euler: "exp(\<i> * z) = cos(z) + \<i> * sin(z)"
    88 proof -
    89   have "(\<lambda>n. (cos_coeff n + \<i> * sin_coeff n) * z^n)
    90         = (\<lambda>n. (\<i> * z) ^ n /\<^sub>R (fact n))"
    91   proof
    92     fix n
    93     show "(cos_coeff n + \<i> * sin_coeff n) * z^n = (\<i> * z) ^ n /\<^sub>R (fact n)"
    94       by (auto simp: cos_coeff_def sin_coeff_def scaleR_conv_of_real field_simps elim!: evenE oddE)
    95   qed
    96   also have "... sums (exp (\<i> * z))"
    97     by (rule exp_converges)
    98   finally have "(\<lambda>n. (cos_coeff n + \<i> * sin_coeff n) * z^n) sums (exp (\<i> * z))" .
    99   moreover have "(\<lambda>n. (cos_coeff n + \<i> * sin_coeff n) * z^n) sums (cos z + \<i> * sin z)"
   100     using sums_add [OF cos_converges [of z] sin_i_eq [of z]]
   101     by (simp add: field_simps scaleR_conv_of_real)
   102   ultimately show ?thesis
   103     using sums_unique2 by blast
   104 qed
   105 
   106 corollary exp_minus_Euler: "exp(-(\<i> * z)) = cos(z) - \<i> * sin(z)"
   107   using exp_Euler [of "-z"]
   108   by simp
   109 
   110 lemma sin_exp_eq: "sin z = (exp(\<i> * z) - exp(-(\<i> * z))) / (2*\<i>)"
   111   by (simp add: exp_Euler exp_minus_Euler)
   112 
   113 lemma sin_exp_eq': "sin z = \<i> * (exp(-(\<i> * z)) - exp(\<i> * z)) / 2"
   114   by (simp add: exp_Euler exp_minus_Euler)
   115 
   116 lemma cos_exp_eq:  "cos z = (exp(\<i> * z) + exp(-(\<i> * z))) / 2"
   117   by (simp add: exp_Euler exp_minus_Euler)
   118 
   119 subsection\<open>Relationships between real and complex trig functions\<close>
   120 
   121 lemma real_sin_eq [simp]:
   122   fixes x::real
   123   shows "Re(sin(of_real x)) = sin x"
   124   by (simp add: sin_of_real)
   125 
   126 lemma real_cos_eq [simp]:
   127   fixes x::real
   128   shows "Re(cos(of_real x)) = cos x"
   129   by (simp add: cos_of_real)
   130 
   131 lemma DeMoivre: "(cos z + \<i> * sin z) ^ n = cos(n * z) + \<i> * sin(n * z)"
   132   apply (simp add: exp_Euler [symmetric])
   133   by (metis exp_of_nat_mult mult.left_commute)
   134 
   135 lemma exp_cnj:
   136   fixes z::complex
   137   shows "cnj (exp z) = exp (cnj z)"
   138 proof -
   139   have "(\<lambda>n. cnj (z ^ n /\<^sub>R (fact n))) = (\<lambda>n. (cnj z)^n /\<^sub>R (fact n))"
   140     by auto
   141   also have "... sums (exp (cnj z))"
   142     by (rule exp_converges)
   143   finally have "(\<lambda>n. cnj (z ^ n /\<^sub>R (fact n))) sums (exp (cnj z))" .
   144   moreover have "(\<lambda>n. cnj (z ^ n /\<^sub>R (fact n))) sums (cnj (exp z))"
   145     by (metis exp_converges sums_cnj)
   146   ultimately show ?thesis
   147     using sums_unique2
   148     by blast
   149 qed
   150 
   151 lemma cnj_sin: "cnj(sin z) = sin(cnj z)"
   152   by (simp add: sin_exp_eq exp_cnj field_simps)
   153 
   154 lemma cnj_cos: "cnj(cos z) = cos(cnj z)"
   155   by (simp add: cos_exp_eq exp_cnj field_simps)
   156 
   157 lemma field_differentiable_at_sin: "sin field_differentiable at z"
   158   using DERIV_sin field_differentiable_def by blast
   159 
   160 lemma field_differentiable_within_sin: "sin field_differentiable (at z within s)"
   161   by (simp add: field_differentiable_at_sin field_differentiable_at_within)
   162 
   163 lemma field_differentiable_at_cos: "cos field_differentiable at z"
   164   using DERIV_cos field_differentiable_def by blast
   165 
   166 lemma field_differentiable_within_cos: "cos field_differentiable (at z within s)"
   167   by (simp add: field_differentiable_at_cos field_differentiable_at_within)
   168 
   169 lemma holomorphic_on_sin: "sin holomorphic_on s"
   170   by (simp add: field_differentiable_within_sin holomorphic_on_def)
   171 
   172 lemma holomorphic_on_cos: "cos holomorphic_on s"
   173   by (simp add: field_differentiable_within_cos holomorphic_on_def)
   174 
   175 subsection\<open>Get a nice real/imaginary separation in Euler's formula.\<close>
   176 
   177 lemma Euler: "exp(z) = of_real(exp(Re z)) *
   178               (of_real(cos(Im z)) + \<i> * of_real(sin(Im z)))"
   179 by (cases z) (simp add: exp_add exp_Euler cos_of_real exp_of_real sin_of_real Complex_eq)
   180 
   181 lemma Re_sin: "Re(sin z) = sin(Re z) * (exp(Im z) + exp(-(Im z))) / 2"
   182   by (simp add: sin_exp_eq field_simps Re_divide Im_exp)
   183 
   184 lemma Im_sin: "Im(sin z) = cos(Re z) * (exp(Im z) - exp(-(Im z))) / 2"
   185   by (simp add: sin_exp_eq field_simps Im_divide Re_exp)
   186 
   187 lemma Re_cos: "Re(cos z) = cos(Re z) * (exp(Im z) + exp(-(Im z))) / 2"
   188   by (simp add: cos_exp_eq field_simps Re_divide Re_exp)
   189 
   190 lemma Im_cos: "Im(cos z) = sin(Re z) * (exp(-(Im z)) - exp(Im z)) / 2"
   191   by (simp add: cos_exp_eq field_simps Im_divide Im_exp)
   192 
   193 lemma Re_sin_pos: "0 < Re z \<Longrightarrow> Re z < pi \<Longrightarrow> Re (sin z) > 0"
   194   by (auto simp: Re_sin Im_sin add_pos_pos sin_gt_zero)
   195 
   196 lemma Im_sin_nonneg: "Re z = 0 \<Longrightarrow> 0 \<le> Im z \<Longrightarrow> 0 \<le> Im (sin z)"
   197   by (simp add: Re_sin Im_sin algebra_simps)
   198 
   199 lemma Im_sin_nonneg2: "Re z = pi \<Longrightarrow> Im z \<le> 0 \<Longrightarrow> 0 \<le> Im (sin z)"
   200   by (simp add: Re_sin Im_sin algebra_simps)
   201 
   202 subsection\<open>More on the Polar Representation of Complex Numbers\<close>
   203 
   204 lemma exp_Complex: "exp(Complex r t) = of_real(exp r) * Complex (cos t) (sin t)"
   205   by (simp add: Complex_eq exp_add exp_Euler exp_of_real sin_of_real cos_of_real)
   206 
   207 lemma exp_eq_1: "exp z = 1 \<longleftrightarrow> Re(z) = 0 \<and> (\<exists>n::int. Im(z) = of_int (2 * n) * pi)"
   208                  (is "?lhs = ?rhs")
   209 proof 
   210   assume "exp z = 1"
   211   then have "Re z = 0"
   212     by (metis exp_eq_one_iff norm_exp_eq_Re norm_one)
   213   with \<open>?lhs\<close> show ?rhs
   214     by (metis Re_exp complex_Re_of_int cos_one_2pi_int exp_zero mult.commute mult_numeral_1 numeral_One of_int_mult of_int_numeral)
   215 next
   216   assume ?rhs then show ?lhs
   217     using Im_exp Re_exp complex_Re_Im_cancel_iff by force
   218 qed
   219 
   220 lemma exp_eq: "exp w = exp z \<longleftrightarrow> (\<exists>n::int. w = z + (of_int (2 * n) * pi) * \<i>)"
   221                 (is "?lhs = ?rhs")
   222 proof -
   223   have "exp w = exp z \<longleftrightarrow> exp (w-z) = 1"
   224     by (simp add: exp_diff)
   225   also have "... \<longleftrightarrow> (Re w = Re z \<and> (\<exists>n::int. Im w - Im z = of_int (2 * n) * pi))"
   226     by (simp add: exp_eq_1)
   227   also have "... \<longleftrightarrow> ?rhs"
   228     by (auto simp: algebra_simps intro!: complex_eqI)
   229   finally show ?thesis .
   230 qed
   231 
   232 lemma exp_complex_eqI: "\<bar>Im w - Im z\<bar> < 2*pi \<Longrightarrow> exp w = exp z \<Longrightarrow> w = z"
   233   by (auto simp: exp_eq abs_mult)
   234 
   235 lemma exp_integer_2pi:
   236   assumes "n \<in> \<int>"
   237   shows "exp((2 * n * pi) * \<i>) = 1"
   238 proof -
   239   have "exp((2 * n * pi) * \<i>) = exp 0"
   240     using assms
   241     by (simp only: Ints_def exp_eq) auto
   242   also have "... = 1"
   243     by simp
   244   finally show ?thesis .
   245 qed
   246 
   247 lemma exp_plus_2pin [simp]: "exp (z + \<i> * (of_int n * (of_real pi * 2))) = exp z"
   248   by (simp add: exp_eq)
   249 
   250 lemma inj_on_exp_pi:
   251   fixes z::complex shows "inj_on exp (ball z pi)"
   252 proof (clarsimp simp: inj_on_def exp_eq)
   253   fix y n
   254   assume "dist z (y + 2 * of_int n * of_real pi * \<i>) < pi"
   255          "dist z y < pi"
   256   then have "dist y (y + 2 * of_int n * of_real pi * \<i>) < pi+pi"
   257     using dist_commute_lessI dist_triangle_less_add by blast
   258   then have "norm (2 * of_int n * of_real pi * \<i>) < 2*pi"
   259     by (simp add: dist_norm)
   260   then show "n = 0"
   261     by (auto simp: norm_mult)
   262 qed
   263 
   264 lemma sin_cos_eq_iff: "sin y = sin x \<and> cos y = cos x \<longleftrightarrow> (\<exists>n::int. y = x + 2 * n * pi)"
   265 proof -
   266   { assume "sin y = sin x" "cos y = cos x"
   267     then have "cos (y-x) = 1"
   268       using cos_add [of y "-x"] by simp
   269     then have "\<exists>n::int. y-x = n * 2 * pi"
   270       using cos_one_2pi_int by blast }
   271   then show ?thesis
   272   apply (auto simp: sin_add cos_add)
   273   apply (metis add.commute diff_add_cancel mult.commute)
   274   done
   275 qed
   276 
   277 lemma exp_i_ne_1:
   278   assumes "0 < x" "x < 2*pi"
   279   shows "exp(\<i> * of_real x) \<noteq> 1"
   280 proof
   281   assume "exp (\<i> * of_real x) = 1"
   282   then have "exp (\<i> * of_real x) = exp 0"
   283     by simp
   284   then obtain n where "\<i> * of_real x = (of_int (2 * n) * pi) * \<i>"
   285     by (simp only: Ints_def exp_eq) auto
   286   then have  "of_real x = (of_int (2 * n) * pi)"
   287     by (metis complex_i_not_zero mult.commute mult_cancel_left of_real_eq_iff real_scaleR_def scaleR_conv_of_real)
   288   then have  "x = (of_int (2 * n) * pi)"
   289     by simp
   290   then show False using assms
   291     by (cases n) (auto simp: zero_less_mult_iff mult_less_0_iff)
   292 qed
   293 
   294 lemma sin_eq_0:
   295   fixes z::complex
   296   shows "sin z = 0 \<longleftrightarrow> (\<exists>n::int. z = of_real(n * pi))"
   297   by (simp add: sin_exp_eq exp_eq of_real_numeral)
   298 
   299 lemma cos_eq_0:
   300   fixes z::complex
   301   shows "cos z = 0 \<longleftrightarrow> (\<exists>n::int. z = of_real(n * pi) + of_real pi/2)"
   302   using sin_eq_0 [of "z - of_real pi/2"]
   303   by (simp add: sin_diff algebra_simps)
   304 
   305 lemma cos_eq_1:
   306   fixes z::complex
   307   shows "cos z = 1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi))"
   308 proof -
   309   have "cos z = cos (2*(z/2))"
   310     by simp
   311   also have "... = 1 - 2 * sin (z/2) ^ 2"
   312     by (simp only: cos_double_sin)
   313   finally have [simp]: "cos z = 1 \<longleftrightarrow> sin (z/2) = 0"
   314     by simp
   315   show ?thesis
   316     by (auto simp: sin_eq_0 of_real_numeral)
   317 qed
   318 
   319 lemma csin_eq_1:
   320   fixes z::complex
   321   shows "sin z = 1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi) + of_real pi/2)"
   322   using cos_eq_1 [of "z - of_real pi/2"]
   323   by (simp add: cos_diff algebra_simps)
   324 
   325 lemma csin_eq_minus1:
   326   fixes z::complex
   327   shows "sin z = -1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi) + 3/2*pi)"
   328         (is "_ = ?rhs")
   329 proof -
   330   have "sin z = -1 \<longleftrightarrow> sin (-z) = 1"
   331     by (simp add: equation_minus_iff)
   332   also have "...  \<longleftrightarrow> (\<exists>n::int. -z = of_real(2 * n * pi) + of_real pi/2)"
   333     by (simp only: csin_eq_1)
   334   also have "...  \<longleftrightarrow> (\<exists>n::int. z = - of_real(2 * n * pi) - of_real pi/2)"
   335     apply (rule iff_exI)
   336     by (metis (no_types)  is_num_normalize(8) minus_minus of_real_def real_vector.scale_minus_left uminus_add_conv_diff)
   337   also have "... = ?rhs"
   338     apply (auto simp: of_real_numeral)
   339     apply (rule_tac [2] x="-(x+1)" in exI)
   340     apply (rule_tac x="-(x+1)" in exI)
   341     apply (simp_all add: algebra_simps)
   342     done
   343   finally show ?thesis .
   344 qed
   345 
   346 lemma ccos_eq_minus1:
   347   fixes z::complex
   348   shows "cos z = -1 \<longleftrightarrow> (\<exists>n::int. z = of_real(2 * n * pi) + pi)"
   349   using csin_eq_1 [of "z - of_real pi/2"]
   350   apply (simp add: sin_diff)
   351   apply (simp add: algebra_simps of_real_numeral equation_minus_iff)
   352   done
   353 
   354 lemma sin_eq_1: "sin x = 1 \<longleftrightarrow> (\<exists>n::int. x = (2 * n + 1 / 2) * pi)"
   355                 (is "_ = ?rhs")
   356 proof -
   357   have "sin x = 1 \<longleftrightarrow> sin (complex_of_real x) = 1"
   358     by (metis of_real_1 one_complex.simps(1) real_sin_eq sin_of_real)
   359   also have "...  \<longleftrightarrow> (\<exists>n::int. complex_of_real x = of_real(2 * n * pi) + of_real pi/2)"
   360     by (simp only: csin_eq_1)
   361   also have "...  \<longleftrightarrow> (\<exists>n::int. x = of_real(2 * n * pi) + of_real pi/2)"
   362     apply (rule iff_exI)
   363     apply (auto simp: algebra_simps of_real_numeral)
   364     apply (rule injD [OF inj_of_real [where 'a = complex]])
   365     apply (auto simp: of_real_numeral)
   366     done
   367   also have "... = ?rhs"
   368     by (auto simp: algebra_simps)
   369   finally show ?thesis .
   370 qed
   371 
   372 lemma sin_eq_minus1: "sin x = -1 \<longleftrightarrow> (\<exists>n::int. x = (2*n + 3/2) * pi)"  (is "_ = ?rhs")
   373 proof -
   374   have "sin x = -1 \<longleftrightarrow> sin (complex_of_real x) = -1"
   375     by (metis Re_complex_of_real of_real_def scaleR_minus1_left sin_of_real)
   376   also have "...  \<longleftrightarrow> (\<exists>n::int. complex_of_real x = of_real(2 * n * pi) + 3/2*pi)"
   377     by (simp only: csin_eq_minus1)
   378   also have "...  \<longleftrightarrow> (\<exists>n::int. x = of_real(2 * n * pi) + 3/2*pi)"
   379     apply (rule iff_exI)
   380     apply (auto simp: algebra_simps)
   381     apply (rule injD [OF inj_of_real [where 'a = complex]], auto)
   382     done
   383   also have "... = ?rhs"
   384     by (auto simp: algebra_simps)
   385   finally show ?thesis .
   386 qed
   387 
   388 lemma cos_eq_minus1: "cos x = -1 \<longleftrightarrow> (\<exists>n::int. x = (2*n + 1) * pi)"
   389                       (is "_ = ?rhs")
   390 proof -
   391   have "cos x = -1 \<longleftrightarrow> cos (complex_of_real x) = -1"
   392     by (metis Re_complex_of_real of_real_def scaleR_minus1_left cos_of_real)
   393   also have "...  \<longleftrightarrow> (\<exists>n::int. complex_of_real x = of_real(2 * n * pi) + pi)"
   394     by (simp only: ccos_eq_minus1)
   395   also have "...  \<longleftrightarrow> (\<exists>n::int. x = of_real(2 * n * pi) + pi)"
   396     apply (rule iff_exI)
   397     apply (auto simp: algebra_simps)
   398     apply (rule injD [OF inj_of_real [where 'a = complex]], auto)
   399     done
   400   also have "... = ?rhs"
   401     by (auto simp: algebra_simps)
   402   finally show ?thesis .
   403 qed
   404 
   405 lemma dist_exp_i_1: "norm(exp(\<i> * of_real t) - 1) = 2 * \<bar>sin(t / 2)\<bar>"
   406   apply (simp add: exp_Euler cmod_def power2_diff sin_of_real cos_of_real algebra_simps)
   407   using cos_double_sin [of "t/2"]
   408   apply (simp add: real_sqrt_mult)
   409   done
   410 
   411 
   412 lemma complex_sin_eq:
   413   fixes w :: complex
   414   shows "sin w = sin z \<longleftrightarrow> (\<exists>n \<in> \<int>. w = z + of_real(2*n*pi) \<or> w = -z + of_real((2*n + 1)*pi))"
   415         (is "?lhs = ?rhs")
   416 proof
   417   assume ?lhs
   418   then have "sin w - sin z = 0"
   419     by (auto simp: algebra_simps)
   420   then have "sin ((w - z) / 2)*cos ((w + z) / 2) = 0"
   421     by (auto simp: sin_diff_sin)
   422   then consider "sin ((w - z) / 2) = 0" | "cos ((w + z) / 2) = 0"
   423     using mult_eq_0_iff by blast
   424   then show ?rhs
   425   proof cases
   426     case 1
   427     then show ?thesis
   428       apply (auto simp: sin_eq_0 algebra_simps)
   429       by (metis Ints_of_int of_real_of_int_eq)
   430   next
   431     case 2
   432     then show ?thesis
   433       apply (auto simp: cos_eq_0 algebra_simps)
   434       by (metis Ints_of_int of_real_of_int_eq)
   435   qed
   436 next
   437   assume ?rhs
   438   then obtain n::int where w: "w = z + of_real (2* of_int n*pi) \<or>
   439                                w = -z + of_real ((2* of_int n + 1)*pi)"
   440     using Ints_cases by blast
   441   then show ?lhs
   442     using Periodic_Fun.sin.plus_of_int [of z n]
   443     apply (auto simp: algebra_simps)
   444     by (metis (no_types, hide_lams) add_diff_cancel_left add_diff_cancel_left' add_minus_cancel
   445               mult.commute sin.plus_of_int sin_minus sin_plus_pi)
   446 qed
   447 
   448 lemma complex_cos_eq:
   449   fixes w :: complex
   450   shows "cos w = cos z \<longleftrightarrow>
   451          (\<exists>n \<in> \<int>. w = z + of_real(2*n*pi) \<or> w = -z + of_real(2*n*pi))"
   452         (is "?lhs = ?rhs")
   453 proof
   454   assume ?lhs
   455   then have "cos w - cos z = 0"
   456     by (auto simp: algebra_simps)
   457   then have "sin ((w + z) / 2) * sin ((z - w) / 2) = 0"
   458     by (auto simp: cos_diff_cos)
   459   then consider "sin ((w + z) / 2) = 0" | "sin ((z - w) / 2) = 0"
   460     using mult_eq_0_iff by blast
   461   then show ?rhs
   462   proof cases
   463     case 1
   464     then show ?thesis
   465       apply (auto simp: sin_eq_0 algebra_simps)
   466       by (metis Ints_of_int of_real_of_int_eq)
   467   next
   468     case 2
   469     then show ?thesis
   470       apply (auto simp: sin_eq_0 algebra_simps)
   471       by (metis Ints_of_int add_minus_cancel distrib_right mult_of_int_commute mult_zero_right of_int_0 of_int_add of_real_of_int_eq)
   472   qed
   473 next
   474   assume ?rhs
   475   then obtain n::int where w: "w = z + of_real (2* of_int n*pi) \<or>
   476                                w = -z + of_real(2*n*pi)"
   477     using Ints_cases  by (metis of_int_mult of_int_numeral)
   478   then show ?lhs
   479     using Periodic_Fun.cos.plus_of_int [of z n]
   480     apply (auto simp: algebra_simps)
   481     by (metis cos.plus_of_int cos_minus minus_add_cancel mult.commute)
   482 qed
   483 
   484 lemma sin_eq:
   485    "sin x = sin y \<longleftrightarrow> (\<exists>n \<in> \<int>. x = y + 2*n*pi \<or> x = -y + (2*n + 1)*pi)"
   486   using complex_sin_eq [of x y]
   487   by (simp only: sin_of_real Re_complex_of_real of_real_add [symmetric] of_real_minus [symmetric] of_real_mult [symmetric] of_real_eq_iff)
   488 
   489 lemma cos_eq:
   490    "cos x = cos y \<longleftrightarrow> (\<exists>n \<in> \<int>. x = y + 2*n*pi \<or> x = -y + 2*n*pi)"
   491   using complex_cos_eq [of x y]
   492   by (simp only: cos_of_real Re_complex_of_real of_real_add [symmetric] of_real_minus [symmetric] of_real_mult [symmetric] of_real_eq_iff)
   493 
   494 lemma sinh_complex:
   495   fixes z :: complex
   496   shows "(exp z - inverse (exp z)) / 2 = -\<i> * sin(\<i> * z)"
   497   by (simp add: sin_exp_eq divide_simps exp_minus)
   498 
   499 lemma sin_i_times:
   500   fixes z :: complex
   501   shows "sin(\<i> * z) = \<i> * ((exp z - inverse (exp z)) / 2)"
   502   using sinh_complex by auto
   503 
   504 lemma sinh_real:
   505   fixes x :: real
   506   shows "of_real((exp x - inverse (exp x)) / 2) = -\<i> * sin(\<i> * of_real x)"
   507   by (simp add: exp_of_real sin_i_times)
   508 
   509 lemma cosh_complex:
   510   fixes z :: complex
   511   shows "(exp z + inverse (exp z)) / 2 = cos(\<i> * z)"
   512   by (simp add: cos_exp_eq divide_simps exp_minus exp_of_real)
   513 
   514 lemma cosh_real:
   515   fixes x :: real
   516   shows "of_real((exp x + inverse (exp x)) / 2) = cos(\<i> * of_real x)"
   517   by (simp add: cos_exp_eq divide_simps exp_minus exp_of_real)
   518 
   519 lemmas cos_i_times = cosh_complex [symmetric]
   520 
   521 lemma norm_cos_squared:
   522     "norm(cos z) ^ 2 = cos(Re z) ^ 2 + (exp(Im z) - inverse(exp(Im z))) ^ 2 / 4"
   523   apply (cases z)
   524   apply (simp add: cos_add cmod_power2 cos_of_real sin_of_real Complex_eq)
   525   apply (simp add: cos_exp_eq sin_exp_eq exp_minus exp_of_real Re_divide Im_divide power_divide)
   526   apply (simp only: left_diff_distrib [symmetric] power_mult_distrib)
   527   apply (simp add: sin_squared_eq)
   528   apply (simp add: power2_eq_square algebra_simps divide_simps)
   529   done
   530 
   531 lemma norm_sin_squared:
   532     "norm(sin z) ^ 2 = (exp(2 * Im z) + inverse(exp(2 * Im z)) - 2 * cos(2 * Re z)) / 4"
   533   apply (cases z)
   534   apply (simp add: sin_add cmod_power2 cos_of_real sin_of_real cos_double_cos exp_double Complex_eq)
   535   apply (simp add: cos_exp_eq sin_exp_eq exp_minus exp_of_real Re_divide Im_divide power_divide)
   536   apply (simp only: left_diff_distrib [symmetric] power_mult_distrib)
   537   apply (simp add: cos_squared_eq)
   538   apply (simp add: power2_eq_square algebra_simps divide_simps)
   539   done
   540 
   541 lemma exp_uminus_Im: "exp (- Im z) \<le> exp (cmod z)"
   542   using abs_Im_le_cmod linear order_trans by fastforce
   543 
   544 lemma norm_cos_le:
   545   fixes z::complex
   546   shows "norm(cos z) \<le> exp(norm z)"
   547 proof -
   548   have "Im z \<le> cmod z"
   549     using abs_Im_le_cmod abs_le_D1 by auto
   550   with exp_uminus_Im show ?thesis
   551     apply (simp add: cos_exp_eq norm_divide)
   552     apply (rule order_trans [OF norm_triangle_ineq], simp)
   553     apply (metis add_mono exp_le_cancel_iff mult_2_right)
   554     done
   555 qed
   556 
   557 lemma norm_cos_plus1_le:
   558   fixes z::complex
   559   shows "norm(1 + cos z) \<le> 2 * exp(norm z)"
   560 proof -
   561   have mono: "\<And>u w z::real. (1 \<le> w | 1 \<le> z) \<Longrightarrow> (w \<le> u & z \<le> u) \<Longrightarrow> 2 + w + z \<le> 4 * u"
   562       by arith
   563   have *: "Im z \<le> cmod z"
   564     using abs_Im_le_cmod abs_le_D1 by auto
   565   have triangle3: "\<And>x y z. norm(x + y + z) \<le> norm(x) + norm(y) + norm(z)"
   566     by (simp add: norm_add_rule_thm)
   567   have "norm(1 + cos z) = cmod (1 + (exp (\<i> * z) + exp (- (\<i> * z))) / 2)"
   568     by (simp add: cos_exp_eq)
   569   also have "... = cmod ((2 + exp (\<i> * z) + exp (- (\<i> * z))) / 2)"
   570     by (simp add: field_simps)
   571   also have "... = cmod (2 + exp (\<i> * z) + exp (- (\<i> * z))) / 2"
   572     by (simp add: norm_divide)
   573   finally show ?thesis
   574     apply (rule ssubst, simp)
   575     apply (rule order_trans [OF triangle3], simp)
   576     using exp_uminus_Im *
   577     apply (auto intro: mono)
   578     done
   579 qed
   580 
   581 subsection\<open>Taylor series for complex exponential, sine and cosine.\<close>
   582 
   583 declare power_Suc [simp del]
   584 
   585 lemma Taylor_exp:
   586   "norm(exp z - (\<Sum>k\<le>n. z ^ k / (fact k))) \<le> exp\<bar>Re z\<bar> * (norm z) ^ (Suc n) / (fact n)"
   587 proof (rule complex_taylor [of _ n "\<lambda>k. exp" "exp\<bar>Re z\<bar>" 0 z, simplified])
   588   show "convex (closed_segment 0 z)"
   589     by (rule convex_closed_segment [of 0 z])
   590 next
   591   fix k x
   592   assume "x \<in> closed_segment 0 z" "k \<le> n"
   593   show "(exp has_field_derivative exp x) (at x within closed_segment 0 z)"
   594     using DERIV_exp DERIV_subset by blast
   595 next
   596   fix x
   597   assume "x \<in> closed_segment 0 z"
   598   then show "Re x \<le> \<bar>Re z\<bar>"
   599     apply (auto simp: closed_segment_def scaleR_conv_of_real)
   600     by (meson abs_ge_self abs_ge_zero linear mult_left_le_one_le mult_nonneg_nonpos order_trans)
   601 next
   602   show "0 \<in> closed_segment 0 z"
   603     by (auto simp: closed_segment_def)
   604 next
   605   show "z \<in> closed_segment 0 z"
   606     apply (simp add: closed_segment_def scaleR_conv_of_real)
   607     using of_real_1 zero_le_one by blast
   608 qed
   609 
   610 lemma
   611   assumes "0 \<le> u" "u \<le> 1"
   612   shows cmod_sin_le_exp: "cmod (sin (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>"
   613     and cmod_cos_le_exp: "cmod (cos (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>"
   614 proof -
   615   have mono: "\<And>u w z::real. w \<le> u \<Longrightarrow> z \<le> u \<Longrightarrow> w + z \<le> u*2"
   616     by arith
   617   show "cmod (sin (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>" using assms
   618     apply (auto simp: scaleR_conv_of_real norm_mult norm_power sin_exp_eq norm_divide)
   619     apply (rule order_trans [OF norm_triangle_ineq4])
   620     apply (rule mono)
   621     apply (auto simp: abs_if mult_left_le_one_le)
   622     apply (meson mult_nonneg_nonneg neg_le_0_iff_le not_le order_trans)
   623     apply (meson less_eq_real_def mult_nonneg_nonpos neg_0_le_iff_le order_trans)
   624     done
   625   show "cmod (cos (u *\<^sub>R z)) \<le> exp \<bar>Im z\<bar>" using assms
   626     apply (auto simp: scaleR_conv_of_real norm_mult norm_power cos_exp_eq norm_divide)
   627     apply (rule order_trans [OF norm_triangle_ineq])
   628     apply (rule mono)
   629     apply (auto simp: abs_if mult_left_le_one_le)
   630     apply (meson mult_nonneg_nonneg neg_le_0_iff_le not_le order_trans)
   631     apply (meson less_eq_real_def mult_nonneg_nonpos neg_0_le_iff_le order_trans)
   632     done
   633 qed
   634 
   635 lemma Taylor_sin:
   636   "norm(sin z - (\<Sum>k\<le>n. complex_of_real (sin_coeff k) * z ^ k))
   637    \<le> exp\<bar>Im z\<bar> * (norm z) ^ (Suc n) / (fact n)"
   638 proof -
   639   have mono: "\<And>u w z::real. w \<le> u \<Longrightarrow> z \<le> u \<Longrightarrow> w + z \<le> u*2"
   640       by arith
   641   have *: "cmod (sin z -
   642                  (\<Sum>i\<le>n. (-1) ^ (i div 2) * (if even i then sin 0 else cos 0) * z ^ i / (fact i)))
   643            \<le> exp \<bar>Im z\<bar> * cmod z ^ Suc n / (fact n)"
   644   proof (rule complex_taylor [of "closed_segment 0 z" n
   645                                  "\<lambda>k x. (-1)^(k div 2) * (if even k then sin x else cos x)"
   646                                  "exp\<bar>Im z\<bar>" 0 z,  simplified])
   647     fix k x
   648     show "((\<lambda>x. (- 1) ^ (k div 2) * (if even k then sin x else cos x)) has_field_derivative
   649             (- 1) ^ (Suc k div 2) * (if odd k then sin x else cos x))
   650             (at x within closed_segment 0 z)"
   651       apply (auto simp: power_Suc)
   652       apply (intro derivative_eq_intros | simp)+
   653       done
   654   next
   655     fix x
   656     assume "x \<in> closed_segment 0 z"
   657     then show "cmod ((- 1) ^ (Suc n div 2) * (if odd n then sin x else cos x)) \<le> exp \<bar>Im z\<bar>"
   658       by (auto simp: closed_segment_def norm_mult norm_power cmod_sin_le_exp cmod_cos_le_exp)
   659   qed
   660   have **: "\<And>k. complex_of_real (sin_coeff k) * z ^ k
   661             = (-1)^(k div 2) * (if even k then sin 0 else cos 0) * z^k / of_nat (fact k)"
   662     by (auto simp: sin_coeff_def elim!: oddE)
   663   show ?thesis
   664     apply (rule order_trans [OF _ *])
   665     apply (simp add: **)
   666     done
   667 qed
   668 
   669 lemma Taylor_cos:
   670   "norm(cos z - (\<Sum>k\<le>n. complex_of_real (cos_coeff k) * z ^ k))
   671    \<le> exp\<bar>Im z\<bar> * (norm z) ^ Suc n / (fact n)"
   672 proof -
   673   have mono: "\<And>u w z::real. w \<le> u \<Longrightarrow> z \<le> u \<Longrightarrow> w + z \<le> u*2"
   674       by arith
   675   have *: "cmod (cos z -
   676                  (\<Sum>i\<le>n. (-1) ^ (Suc i div 2) * (if even i then cos 0 else sin 0) * z ^ i / (fact i)))
   677            \<le> exp \<bar>Im z\<bar> * cmod z ^ Suc n / (fact n)"
   678   proof (rule complex_taylor [of "closed_segment 0 z" n "\<lambda>k x. (-1)^(Suc k div 2) * (if even k then cos x else sin x)" "exp\<bar>Im z\<bar>" 0 z,
   679 simplified])
   680     fix k x
   681     assume "x \<in> closed_segment 0 z" "k \<le> n"
   682     show "((\<lambda>x. (- 1) ^ (Suc k div 2) * (if even k then cos x else sin x)) has_field_derivative
   683             (- 1) ^ Suc (k div 2) * (if odd k then cos x else sin x))
   684              (at x within closed_segment 0 z)"
   685       apply (auto simp: power_Suc)
   686       apply (intro derivative_eq_intros | simp)+
   687       done
   688   next
   689     fix x
   690     assume "x \<in> closed_segment 0 z"
   691     then show "cmod ((- 1) ^ Suc (n div 2) * (if odd n then cos x else sin x)) \<le> exp \<bar>Im z\<bar>"
   692       by (auto simp: closed_segment_def norm_mult norm_power cmod_sin_le_exp cmod_cos_le_exp)
   693   qed
   694   have **: "\<And>k. complex_of_real (cos_coeff k) * z ^ k
   695             = (-1)^(Suc k div 2) * (if even k then cos 0 else sin 0) * z^k / of_nat (fact k)"
   696     by (auto simp: cos_coeff_def elim!: evenE)
   697   show ?thesis
   698     apply (rule order_trans [OF _ *])
   699     apply (simp add: **)
   700     done
   701 qed
   702 
   703 declare power_Suc [simp]
   704 
   705 text\<open>32-bit Approximation to e\<close>
   706 lemma e_approx_32: "\<bar>exp(1) - 5837465777 / 2147483648\<bar> \<le> (inverse(2 ^ 32)::real)"
   707   using Taylor_exp [of 1 14] exp_le
   708   apply (simp add: sum_distrib_right in_Reals_norm Re_exp atMost_nat_numeral fact_numeral)
   709   apply (simp only: pos_le_divide_eq [symmetric], linarith)
   710   done
   711 
   712 lemma e_less_272: "exp 1 < (272/100::real)"
   713   using e_approx_32
   714   by (simp add: abs_if split: if_split_asm)
   715 
   716 lemma ln_272_gt_1: "ln (272/100) > (1::real)"
   717   by (metis e_less_272 exp_less_cancel_iff exp_ln_iff less_trans ln_exp)
   718 
   719 text\<open>Apparently redundant. But many arguments involve integers.\<close>
   720 lemma ln3_gt_1: "ln 3 > (1::real)"
   721   by (simp add: less_trans [OF ln_272_gt_1])
   722 
   723 subsection\<open>The argument of a complex number\<close>
   724 
   725 definition Arg :: "complex \<Rightarrow> real" where
   726  "Arg z \<equiv> if z = 0 then 0
   727            else THE t. 0 \<le> t \<and> t < 2*pi \<and>
   728                     z = of_real(norm z) * exp(\<i> * of_real t)"
   729 
   730 lemma Arg_0 [simp]: "Arg(0) = 0"
   731   by (simp add: Arg_def)
   732 
   733 lemma Arg_unique_lemma:
   734   assumes z:  "z = of_real(norm z) * exp(\<i> * of_real t)"
   735       and z': "z = of_real(norm z) * exp(\<i> * of_real t')"
   736       and t:  "0 \<le> t"  "t < 2*pi"
   737       and t': "0 \<le> t'" "t' < 2*pi"
   738       and nz: "z \<noteq> 0"
   739   shows "t' = t"
   740 proof -
   741   have [dest]: "\<And>x y z::real. x\<ge>0 \<Longrightarrow> x+y < z \<Longrightarrow> y<z"
   742     by arith
   743   have "of_real (cmod z) * exp (\<i> * of_real t') = of_real (cmod z) * exp (\<i> * of_real t)"
   744     by (metis z z')
   745   then have "exp (\<i> * of_real t') = exp (\<i> * of_real t)"
   746     by (metis nz mult_left_cancel mult_zero_left z)
   747   then have "sin t' = sin t \<and> cos t' = cos t"
   748     apply (simp add: exp_Euler sin_of_real cos_of_real)
   749     by (metis Complex_eq complex.sel)
   750   then obtain n::int where n: "t' = t + 2 * n * pi"
   751     by (auto simp: sin_cos_eq_iff)
   752   then have "n=0"
   753     apply (rule_tac z=n in int_cases)
   754     using t t'
   755     apply (auto simp: mult_less_0_iff algebra_simps)
   756     done
   757   then show "t' = t"
   758       by (simp add: n)
   759 qed
   760 
   761 lemma Arg: "0 \<le> Arg z & Arg z < 2*pi & z = of_real(norm z) * exp(\<i> * of_real(Arg z))"
   762 proof (cases "z=0")
   763   case True then show ?thesis
   764     by (simp add: Arg_def)
   765 next
   766   case False
   767   obtain t where t: "0 \<le> t" "t < 2*pi"
   768              and ReIm: "Re z / cmod z = cos t" "Im z / cmod z = sin t"
   769     using sincos_total_2pi [OF complex_unit_circle [OF False]]
   770     by blast
   771   have z: "z = of_real(norm z) * exp(\<i> * of_real t)"
   772     apply (rule complex_eqI)
   773     using t False ReIm
   774     apply (auto simp: exp_Euler sin_of_real cos_of_real divide_simps)
   775     done
   776   show ?thesis
   777     apply (simp add: Arg_def False)
   778     apply (rule theI [where a=t])
   779     using t z False
   780     apply (auto intro: Arg_unique_lemma)
   781     done
   782 qed
   783 
   784 corollary
   785   shows Arg_ge_0: "0 \<le> Arg z"
   786     and Arg_lt_2pi: "Arg z < 2*pi"
   787     and Arg_eq: "z = of_real(norm z) * exp(\<i> * of_real(Arg z))"
   788   using Arg by auto
   789 
   790 lemma complex_norm_eq_1_exp: "norm z = 1 \<longleftrightarrow> exp(\<i> * of_real (Arg z)) = z"
   791   by (metis Arg_eq cis_conv_exp mult.left_neutral norm_cis of_real_1)
   792 
   793 lemma Arg_unique: "\<lbrakk>of_real r * exp(\<i> * of_real a) = z; 0 < r; 0 \<le> a; a < 2*pi\<rbrakk> \<Longrightarrow> Arg z = a"
   794   apply (rule Arg_unique_lemma [OF _ Arg_eq])
   795   using Arg [of z]
   796   apply (auto simp: norm_mult)
   797   done
   798 
   799 lemma Arg_minus: "z \<noteq> 0 \<Longrightarrow> Arg (-z) = (if Arg z < pi then Arg z + pi else Arg z - pi)"
   800   apply (rule Arg_unique [of "norm z"])
   801   apply (rule complex_eqI)
   802   using Arg_ge_0 [of z] Arg_eq [of z] Arg_lt_2pi [of z] Arg_eq [of z]
   803   apply auto
   804   apply (auto simp: Re_exp Im_exp cos_diff sin_diff cis_conv_exp [symmetric])
   805   apply (metis Re_rcis Im_rcis rcis_def)+
   806   done
   807 
   808 lemma Arg_times_of_real [simp]: "0 < r \<Longrightarrow> Arg (of_real r * z) = Arg z"
   809   apply (cases "z=0", simp)
   810   apply (rule Arg_unique [of "r * norm z"])
   811   using Arg
   812   apply auto
   813   done
   814 
   815 lemma Arg_times_of_real2 [simp]: "0 < r \<Longrightarrow> Arg (z * of_real r) = Arg z"
   816   by (metis Arg_times_of_real mult.commute)
   817 
   818 lemma Arg_divide_of_real [simp]: "0 < r \<Longrightarrow> Arg (z / of_real r) = Arg z"
   819   by (metis Arg_times_of_real2 less_numeral_extra(3) nonzero_eq_divide_eq of_real_eq_0_iff)
   820 
   821 lemma Arg_le_pi: "Arg z \<le> pi \<longleftrightarrow> 0 \<le> Im z"
   822 proof (cases "z=0")
   823   case True then show ?thesis
   824     by simp
   825 next
   826   case False
   827   have "0 \<le> Im z \<longleftrightarrow> 0 \<le> Im (of_real (cmod z) * exp (\<i> * complex_of_real (Arg z)))"
   828     by (metis Arg_eq)
   829   also have "... = (0 \<le> Im (exp (\<i> * complex_of_real (Arg z))))"
   830     using False
   831     by (simp add: zero_le_mult_iff)
   832   also have "... \<longleftrightarrow> Arg z \<le> pi"
   833     by (simp add: Im_exp) (metis Arg_ge_0 Arg_lt_2pi sin_lt_zero sin_ge_zero not_le)
   834   finally show ?thesis
   835     by blast
   836 qed
   837 
   838 lemma Arg_lt_pi: "0 < Arg z \<and> Arg z < pi \<longleftrightarrow> 0 < Im z"
   839 proof (cases "z=0")
   840   case True then show ?thesis
   841     by simp
   842 next
   843   case False
   844   have "0 < Im z \<longleftrightarrow> 0 < Im (of_real (cmod z) * exp (\<i> * complex_of_real (Arg z)))"
   845     by (metis Arg_eq)
   846   also have "... = (0 < Im (exp (\<i> * complex_of_real (Arg z))))"
   847     using False
   848     by (simp add: zero_less_mult_iff)
   849   also have "... \<longleftrightarrow> 0 < Arg z \<and> Arg z < pi"
   850     using Arg_ge_0  Arg_lt_2pi sin_le_zero sin_gt_zero
   851     apply (auto simp: Im_exp)
   852     using le_less apply fastforce
   853     using not_le by blast
   854   finally show ?thesis
   855     by blast
   856 qed
   857 
   858 lemma Arg_eq_0: "Arg z = 0 \<longleftrightarrow> z \<in> \<real> \<and> 0 \<le> Re z"
   859 proof (cases "z=0")
   860   case True then show ?thesis
   861     by simp
   862 next
   863   case False
   864   have "z \<in> \<real> \<and> 0 \<le> Re z \<longleftrightarrow> z \<in> \<real> \<and> 0 \<le> Re (of_real (cmod z) * exp (\<i> * complex_of_real (Arg z)))"
   865     by (metis Arg_eq)
   866   also have "... \<longleftrightarrow> z \<in> \<real> \<and> 0 \<le> Re (exp (\<i> * complex_of_real (Arg z)))"
   867     using False
   868     by (simp add: zero_le_mult_iff)
   869   also have "... \<longleftrightarrow> Arg z = 0"
   870     apply (auto simp: Re_exp)
   871     apply (metis Arg_lt_pi Arg_ge_0 Arg_le_pi cos_pi complex_is_Real_iff leD less_linear less_minus_one_simps(2) minus_minus neg_less_eq_nonneg order_refl)
   872     using Arg_eq [of z]
   873     apply (auto simp: Reals_def)
   874     done
   875   finally show ?thesis
   876     by blast
   877 qed
   878 
   879 corollary Arg_gt_0:
   880   assumes "z \<in> \<real> \<Longrightarrow> Re z < 0"
   881     shows "Arg z > 0"
   882   using Arg_eq_0 Arg_ge_0 assms dual_order.strict_iff_order by fastforce
   883 
   884 lemma Arg_of_real: "Arg(of_real x) = 0 \<longleftrightarrow> 0 \<le> x"
   885   by (simp add: Arg_eq_0)
   886 
   887 lemma Arg_eq_pi: "Arg z = pi \<longleftrightarrow> z \<in> \<real> \<and> Re z < 0"
   888   apply  (cases "z=0", simp)
   889   using Arg_eq_0 [of "-z"]
   890   apply (auto simp: complex_is_Real_iff Arg_minus)
   891   apply (simp add: complex_Re_Im_cancel_iff)
   892   apply (metis Arg_minus pi_gt_zero add.left_neutral minus_minus minus_zero)
   893   done
   894 
   895 lemma Arg_eq_0_pi: "Arg z = 0 \<or> Arg z = pi \<longleftrightarrow> z \<in> \<real>"
   896   using Arg_eq_0 Arg_eq_pi not_le by auto
   897 
   898 lemma Arg_inverse: "Arg(inverse z) = (if z \<in> \<real> \<and> 0 \<le> Re z then Arg z else 2*pi - Arg z)"
   899   apply (cases "z=0", simp)
   900   apply (rule Arg_unique [of "inverse (norm z)"])
   901   using Arg_ge_0 [of z] Arg_lt_2pi [of z] Arg_eq [of z] Arg_eq_0 [of z] exp_two_pi_i
   902   apply (auto simp: of_real_numeral algebra_simps exp_diff divide_simps)
   903   done
   904 
   905 lemma Arg_eq_iff:
   906   assumes "w \<noteq> 0" "z \<noteq> 0"
   907      shows "Arg w = Arg z \<longleftrightarrow> (\<exists>x. 0 < x & w = of_real x * z)"
   908   using assms Arg_eq [of z] Arg_eq [of w]
   909   apply auto
   910   apply (rule_tac x="norm w / norm z" in exI)
   911   apply (simp add: divide_simps)
   912   by (metis mult.commute mult.left_commute)
   913 
   914 lemma Arg_inverse_eq_0: "Arg(inverse z) = 0 \<longleftrightarrow> Arg z = 0"
   915   using complex_is_Real_iff
   916   apply (simp add: Arg_eq_0)
   917   apply (auto simp: divide_simps not_sum_power2_lt_zero)
   918   done
   919 
   920 lemma Arg_divide:
   921   assumes "w \<noteq> 0" "z \<noteq> 0" "Arg w \<le> Arg z"
   922     shows "Arg(z / w) = Arg z - Arg w"
   923   apply (rule Arg_unique [of "norm(z / w)"])
   924   using assms Arg_eq [of z] Arg_eq [of w] Arg_ge_0 [of w] Arg_lt_2pi [of z]
   925   apply (auto simp: exp_diff norm_divide algebra_simps divide_simps)
   926   done
   927 
   928 lemma Arg_le_div_sum:
   929   assumes "w \<noteq> 0" "z \<noteq> 0" "Arg w \<le> Arg z"
   930     shows "Arg z = Arg w + Arg(z / w)"
   931   by (simp add: Arg_divide assms)
   932 
   933 lemma Arg_le_div_sum_eq:
   934   assumes "w \<noteq> 0" "z \<noteq> 0"
   935     shows "Arg w \<le> Arg z \<longleftrightarrow> Arg z = Arg w + Arg(z / w)"
   936   using assms
   937   by (auto simp: Arg_ge_0 intro: Arg_le_div_sum)
   938 
   939 lemma Arg_diff:
   940   assumes "w \<noteq> 0" "z \<noteq> 0"
   941     shows "Arg w - Arg z = (if Arg z \<le> Arg w then Arg(w / z) else Arg(w/z) - 2*pi)"
   942   using assms
   943   apply (auto simp: Arg_ge_0 Arg_divide not_le)
   944   using Arg_divide [of w z] Arg_inverse [of "w/z"]
   945   apply auto
   946   by (metis Arg_eq_0 less_irrefl minus_diff_eq right_minus_eq)
   947 
   948 lemma Arg_add:
   949   assumes "w \<noteq> 0" "z \<noteq> 0"
   950     shows "Arg w + Arg z = (if Arg w + Arg z < 2*pi then Arg(w * z) else Arg(w * z) + 2*pi)"
   951   using assms
   952   using Arg_diff [of "w*z" z] Arg_le_div_sum_eq [of z "w*z"]
   953   apply (auto simp: Arg_ge_0 Arg_divide not_le)
   954   apply (metis Arg_lt_2pi add.commute)
   955   apply (metis (no_types) Arg add.commute diff_0 diff_add_cancel diff_less_eq diff_minus_eq_add not_less)
   956   done
   957 
   958 lemma Arg_times:
   959   assumes "w \<noteq> 0" "z \<noteq> 0"
   960     shows "Arg (w * z) = (if Arg w + Arg z < 2*pi then Arg w + Arg z
   961                             else (Arg w + Arg z) - 2*pi)"
   962   using Arg_add [OF assms]
   963   by auto
   964 
   965 lemma Arg_cnj: "Arg(cnj z) = (if z \<in> \<real> \<and> 0 \<le> Re z then Arg z else 2*pi - Arg z)"
   966   apply (cases "z=0", simp)
   967   apply (rule trans [of _ "Arg(inverse z)"])
   968   apply (simp add: Arg_eq_iff divide_simps complex_norm_square [symmetric] mult.commute)
   969   apply (metis norm_eq_zero of_real_power zero_less_power2)
   970   apply (auto simp: of_real_numeral Arg_inverse)
   971   done
   972 
   973 lemma Arg_real: "z \<in> \<real> \<Longrightarrow> Arg z = (if 0 \<le> Re z then 0 else pi)"
   974   using Arg_eq_0 Arg_eq_0_pi
   975   by auto
   976 
   977 lemma Arg_exp: "0 \<le> Im z \<Longrightarrow> Im z < 2*pi \<Longrightarrow> Arg(exp z) = Im z"
   978   by (rule Arg_unique [of  "exp(Re z)"]) (auto simp: exp_eq_polar)
   979 
   980 lemma complex_split_polar:
   981   obtains r a::real where "z = complex_of_real r * (cos a + \<i> * sin a)" "0 \<le> r" "0 \<le> a" "a < 2*pi"
   982   using Arg cis.ctr cis_conv_exp unfolding Complex_eq by fastforce
   983 
   984 lemma Re_Im_le_cmod: "Im w * sin \<phi> + Re w * cos \<phi> \<le> cmod w"
   985 proof (cases w rule: complex_split_polar)
   986   case (1 r a) with sin_cos_le1 [of a \<phi>] show ?thesis
   987     apply (simp add: norm_mult cmod_unit_one)
   988     by (metis (no_types, hide_lams) abs_le_D1 distrib_left mult.commute mult.left_commute mult_left_le)
   989 qed
   990 
   991 subsection\<open>Analytic properties of tangent function\<close>
   992 
   993 lemma cnj_tan: "cnj(tan z) = tan(cnj z)"
   994   by (simp add: cnj_cos cnj_sin tan_def)
   995 
   996 lemma field_differentiable_at_tan: "~(cos z = 0) \<Longrightarrow> tan field_differentiable at z"
   997   unfolding field_differentiable_def
   998   using DERIV_tan by blast
   999 
  1000 lemma field_differentiable_within_tan: "~(cos z = 0)
  1001          \<Longrightarrow> tan field_differentiable (at z within s)"
  1002   using field_differentiable_at_tan field_differentiable_at_within by blast
  1003 
  1004 lemma continuous_within_tan: "~(cos z = 0) \<Longrightarrow> continuous (at z within s) tan"
  1005   using continuous_at_imp_continuous_within isCont_tan by blast
  1006 
  1007 lemma continuous_on_tan [continuous_intros]: "(\<And>z. z \<in> s \<Longrightarrow> ~(cos z = 0)) \<Longrightarrow> continuous_on s tan"
  1008   by (simp add: continuous_at_imp_continuous_on)
  1009 
  1010 lemma holomorphic_on_tan: "(\<And>z. z \<in> s \<Longrightarrow> ~(cos z = 0)) \<Longrightarrow> tan holomorphic_on s"
  1011   by (simp add: field_differentiable_within_tan holomorphic_on_def)
  1012 
  1013 
  1014 subsection\<open>Complex logarithms (the conventional principal value)\<close>
  1015 
  1016 instantiation complex :: ln
  1017 begin
  1018 
  1019 definition ln_complex :: "complex \<Rightarrow> complex"
  1020   where "ln_complex \<equiv> \<lambda>z. THE w. exp w = z & -pi < Im(w) & Im(w) \<le> pi"
  1021 
  1022 text\<open>NOTE: within this scope, the constant Ln is not yet available!\<close>
  1023 lemma
  1024   assumes "z \<noteq> 0"
  1025     shows exp_Ln [simp]:  "exp(ln z) = z"
  1026       and mpi_less_Im_Ln: "-pi < Im(ln z)"
  1027       and Im_Ln_le_pi:    "Im(ln z) \<le> pi"
  1028 proof -
  1029   obtain \<psi> where z: "z / (cmod z) = Complex (cos \<psi>) (sin \<psi>)"
  1030     using complex_unimodular_polar [of "z / (norm z)"] assms
  1031     by (auto simp: norm_divide divide_simps)
  1032   obtain \<phi> where \<phi>: "- pi < \<phi>" "\<phi> \<le> pi" "sin \<phi> = sin \<psi>" "cos \<phi> = cos \<psi>"
  1033     using sincos_principal_value [of "\<psi>"] assms
  1034     by (auto simp: norm_divide divide_simps)
  1035   have "exp(ln z) = z & -pi < Im(ln z) & Im(ln z) \<le> pi" unfolding ln_complex_def
  1036     apply (rule theI [where a = "Complex (ln(norm z)) \<phi>"])
  1037     using z assms \<phi>
  1038     apply (auto simp: field_simps exp_complex_eqI exp_eq_polar cis.code)
  1039     done
  1040   then show "exp(ln z) = z" "-pi < Im(ln z)" "Im(ln z) \<le> pi"
  1041     by auto
  1042 qed
  1043 
  1044 lemma Ln_exp [simp]:
  1045   assumes "-pi < Im(z)" "Im(z) \<le> pi"
  1046     shows "ln(exp z) = z"
  1047   apply (rule exp_complex_eqI)
  1048   using assms mpi_less_Im_Ln  [of "exp z"] Im_Ln_le_pi [of "exp z"]
  1049   apply auto
  1050   done
  1051 
  1052 subsection\<open>Relation to Real Logarithm\<close>
  1053 
  1054 lemma Ln_of_real:
  1055   assumes "0 < z"
  1056     shows "ln(of_real z::complex) = of_real(ln z)"
  1057 proof -
  1058   have "ln(of_real (exp (ln z))::complex) = ln (exp (of_real (ln z)))"
  1059     by (simp add: exp_of_real)
  1060   also have "... = of_real(ln z)"
  1061     using assms
  1062     by (subst Ln_exp) auto
  1063   finally show ?thesis
  1064     using assms by simp
  1065 qed
  1066 
  1067 corollary Ln_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> Re z > 0 \<Longrightarrow> ln z \<in> \<real>"
  1068   by (auto simp: Ln_of_real elim: Reals_cases)
  1069 
  1070 corollary Im_Ln_of_real [simp]: "r > 0 \<Longrightarrow> Im (ln (of_real r)) = 0"
  1071   by (simp add: Ln_of_real)
  1072 
  1073 lemma cmod_Ln_Reals [simp]: "z \<in> \<real> \<Longrightarrow> 0 < Re z \<Longrightarrow> cmod (ln z) = norm (ln (Re z))"
  1074   using Ln_of_real by force
  1075 
  1076 lemma Ln_Reals_eq: "\<lbrakk>x \<in> \<real>; Re x > 0\<rbrakk> \<Longrightarrow> ln x = of_real (ln (Re x))"
  1077   using Ln_of_real by force
  1078 
  1079 lemma Ln_1 [simp]: "ln 1 = (0::complex)"
  1080 proof -
  1081   have "ln (exp 0) = (0::complex)"
  1082     by (metis (mono_tags, hide_lams) Ln_of_real exp_zero ln_one of_real_0 of_real_1 zero_less_one)
  1083   then show ?thesis
  1084     by simp                              
  1085 qed
  1086 
  1087   
  1088 lemma Ln_eq_zero_iff [simp]: "x \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> ln x = 0 \<longleftrightarrow> x = 1" for x::complex
  1089   by auto (metis exp_Ln exp_zero nonpos_Reals_zero_I)
  1090 
  1091 instance
  1092   by intro_classes (rule ln_complex_def Ln_1)
  1093 
  1094 end
  1095 
  1096 abbreviation Ln :: "complex \<Rightarrow> complex"
  1097   where "Ln \<equiv> ln"
  1098 
  1099 lemma Ln_eq_iff: "w \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> (Ln w = Ln z \<longleftrightarrow> w = z)"
  1100   by (metis exp_Ln)
  1101 
  1102 lemma Ln_unique: "exp(z) = w \<Longrightarrow> -pi < Im(z) \<Longrightarrow> Im(z) \<le> pi \<Longrightarrow> Ln w = z"
  1103   using Ln_exp by blast
  1104 
  1105 lemma Re_Ln [simp]: "z \<noteq> 0 \<Longrightarrow> Re(Ln z) = ln(norm z)"
  1106   by (metis exp_Ln ln_exp norm_exp_eq_Re)
  1107 
  1108 corollary ln_cmod_le:
  1109   assumes z: "z \<noteq> 0"
  1110     shows "ln (cmod z) \<le> cmod (Ln z)"
  1111   using norm_exp [of "Ln z", simplified exp_Ln [OF z]]
  1112   by (metis Re_Ln complex_Re_le_cmod z)
  1113 
  1114 proposition exists_complex_root:
  1115   fixes z :: complex
  1116   assumes "n \<noteq> 0"  obtains w where "z = w ^ n"
  1117   apply (cases "z=0")
  1118   using assms apply (simp add: power_0_left)
  1119   apply (rule_tac w = "exp(Ln z / n)" in that)
  1120   apply (auto simp: assms exp_of_nat_mult [symmetric])
  1121   done
  1122 
  1123 corollary exists_complex_root_nonzero:
  1124   fixes z::complex
  1125   assumes "z \<noteq> 0" "n \<noteq> 0"
  1126   obtains w where "w \<noteq> 0" "z = w ^ n"
  1127   by (metis exists_complex_root [of n z] assms power_0_left)
  1128 
  1129 subsection\<open>The Unwinding Number and the Ln-product Formula\<close>
  1130 
  1131 text\<open>Note that in this special case the unwinding number is -1, 0 or 1.\<close>
  1132 
  1133 definition unwinding :: "complex \<Rightarrow> complex" where
  1134    "unwinding(z) = (z - Ln(exp z)) / (of_real(2*pi) * \<i>)"
  1135 
  1136 lemma unwinding_2pi: "(2*pi) * \<i> * unwinding(z) = z - Ln(exp z)"
  1137   by (simp add: unwinding_def)
  1138 
  1139 lemma Ln_times_unwinding:
  1140     "w \<noteq> 0 \<Longrightarrow> z \<noteq> 0 \<Longrightarrow> Ln(w * z) = Ln(w) + Ln(z) - (2*pi) * \<i> * unwinding(Ln w + Ln z)"
  1141   using unwinding_2pi by (simp add: exp_add)
  1142 
  1143 
  1144 subsection\<open>Derivative of Ln away from the branch cut\<close>
  1145 
  1146 lemma
  1147   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  1148     shows has_field_derivative_Ln: "(Ln has_field_derivative inverse(z)) (at z)"
  1149       and Im_Ln_less_pi:           "Im (Ln z) < pi"
  1150 proof -
  1151   have znz: "z \<noteq> 0"
  1152     using assms by auto
  1153   then have "Im (Ln z) \<noteq> pi"
  1154     by (metis (no_types) Im_exp Ln_in_Reals assms complex_nonpos_Reals_iff complex_is_Real_iff exp_Ln mult_zero_right not_less pi_neq_zero sin_pi znz)
  1155   then show *: "Im (Ln z) < pi" using assms Im_Ln_le_pi
  1156     by (simp add: le_neq_trans znz)
  1157   have "(exp has_field_derivative z) (at (Ln z))"
  1158     by (metis znz DERIV_exp exp_Ln)
  1159   then show "(Ln has_field_derivative inverse(z)) (at z)"
  1160     apply (rule has_complex_derivative_inverse_strong_x
  1161               [where s = "{w. -pi < Im(w) \<and> Im(w) < pi}"])
  1162     using znz *
  1163     apply (auto simp: Transcendental.continuous_on_exp [OF continuous_on_id] open_Collect_conj open_halfspace_Im_gt open_halfspace_Im_lt mpi_less_Im_Ln)
  1164     done
  1165 qed
  1166 
  1167 declare has_field_derivative_Ln [derivative_intros]
  1168 declare has_field_derivative_Ln [THEN DERIV_chain2, derivative_intros]
  1169 
  1170 lemma field_differentiable_at_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> Ln field_differentiable at z"
  1171   using field_differentiable_def has_field_derivative_Ln by blast
  1172 
  1173 lemma field_differentiable_within_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0
  1174          \<Longrightarrow> Ln field_differentiable (at z within s)"
  1175   using field_differentiable_at_Ln field_differentiable_within_subset by blast
  1176 
  1177 lemma continuous_at_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z) Ln"
  1178   by (simp add: field_differentiable_imp_continuous_at field_differentiable_within_Ln)
  1179 
  1180 lemma isCont_Ln' [simp]:
  1181    "\<lbrakk>isCont f z; f z \<notin> \<real>\<^sub>\<le>\<^sub>0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. Ln (f x)) z"
  1182   by (blast intro: isCont_o2 [OF _ continuous_at_Ln])
  1183 
  1184 lemma continuous_within_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z within s) Ln"
  1185   using continuous_at_Ln continuous_at_imp_continuous_within by blast
  1186 
  1187 lemma continuous_on_Ln [continuous_intros]: "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> continuous_on s Ln"
  1188   by (simp add: continuous_at_imp_continuous_on continuous_within_Ln)
  1189 
  1190 lemma holomorphic_on_Ln: "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> Ln holomorphic_on s"
  1191   by (simp add: field_differentiable_within_Ln holomorphic_on_def)
  1192 
  1193 lemma divide_ln_mono:
  1194   fixes x y::real
  1195   assumes "3 \<le> x" "x \<le> y"
  1196   shows "x / ln x \<le> y / ln y"
  1197 proof (rule exE [OF complex_mvt_line [of x y "\<lambda>z. z / Ln z" "\<lambda>z. 1/(Ln z) - 1/(Ln z)^2"]];
  1198     clarsimp simp add: closed_segment_Reals closed_segment_eq_real_ivl assms)
  1199   show "\<And>u. \<lbrakk>x \<le> u; u \<le> y\<rbrakk> \<Longrightarrow> ((\<lambda>z. z / Ln z) has_field_derivative 1 / Ln u - 1 / (Ln u)\<^sup>2) (at u)"
  1200     using \<open>3 \<le> x\<close> apply -
  1201     apply (rule derivative_eq_intros | simp)+
  1202     apply (force simp: field_simps power_eq_if)
  1203     done
  1204   show "x / ln x \<le> y / ln y"
  1205     if "Re (y / Ln y) - Re (x / Ln x) = (Re (1 / Ln u) - Re (1 / (Ln u)\<^sup>2)) * (y - x)"
  1206     and x: "x \<le> u" "u \<le> y" for u
  1207   proof -
  1208     have eq: "y / ln y = (1 / ln u - 1 / (ln u)\<^sup>2) * (y - x) + x / ln x"
  1209       using that \<open>3 \<le> x\<close> by (auto simp: Ln_Reals_eq in_Reals_norm group_add_class.diff_eq_eq)
  1210     show ?thesis
  1211       using exp_le \<open>3 \<le> x\<close> x by (simp add: eq) (simp add: power_eq_if divide_simps ln_ge_iff)
  1212   qed
  1213 qed
  1214     
  1215 
  1216 subsection\<open>Quadrant-type results for Ln\<close>
  1217 
  1218 lemma cos_lt_zero_pi: "pi/2 < x \<Longrightarrow> x < 3*pi/2 \<Longrightarrow> cos x < 0"
  1219   using cos_minus_pi cos_gt_zero_pi [of "x-pi"]
  1220   by simp
  1221 
  1222 lemma Re_Ln_pos_lt:
  1223   assumes "z \<noteq> 0"
  1224     shows "\<bar>Im(Ln z)\<bar> < pi/2 \<longleftrightarrow> 0 < Re(z)"
  1225 proof -
  1226   { fix w
  1227     assume "w = Ln z"
  1228     then have w: "Im w \<le> pi" "- pi < Im w"
  1229       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1230       by auto
  1231     then have "\<bar>Im w\<bar> < pi/2 \<longleftrightarrow> 0 < Re(exp w)"
  1232       apply (auto simp: Re_exp zero_less_mult_iff cos_gt_zero_pi)
  1233       using cos_lt_zero_pi [of "-(Im w)"] cos_lt_zero_pi [of "(Im w)"]
  1234       apply (simp add: abs_if split: if_split_asm)
  1235       apply (metis (no_types) cos_minus cos_pi_half eq_divide_eq_numeral1(1) eq_numeral_simps(4)
  1236                less_numeral_extra(3) linorder_neqE_linordered_idom minus_mult_minus minus_mult_right
  1237                mult_numeral_1_right)
  1238       done
  1239   }
  1240   then show ?thesis using assms
  1241     by auto
  1242 qed
  1243 
  1244 lemma Re_Ln_pos_le:
  1245   assumes "z \<noteq> 0"
  1246     shows "\<bar>Im(Ln z)\<bar> \<le> pi/2 \<longleftrightarrow> 0 \<le> Re(z)"
  1247 proof -
  1248   { fix w
  1249     assume "w = Ln z"
  1250     then have w: "Im w \<le> pi" "- pi < Im w"
  1251       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1252       by auto
  1253     then have "\<bar>Im w\<bar> \<le> pi/2 \<longleftrightarrow> 0 \<le> Re(exp w)"
  1254       apply (auto simp: Re_exp zero_le_mult_iff cos_ge_zero)
  1255       using cos_lt_zero_pi [of "- (Im w)"] cos_lt_zero_pi [of "(Im w)"] not_le
  1256       apply (auto simp: abs_if split: if_split_asm)
  1257       done
  1258   }
  1259   then show ?thesis using assms
  1260     by auto
  1261 qed
  1262 
  1263 lemma Im_Ln_pos_lt:
  1264   assumes "z \<noteq> 0"
  1265     shows "0 < Im(Ln z) \<and> Im(Ln z) < pi \<longleftrightarrow> 0 < Im(z)"
  1266 proof -
  1267   { fix w
  1268     assume "w = Ln z"
  1269     then have w: "Im w \<le> pi" "- pi < Im w"
  1270       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1271       by auto
  1272     then have "0 < Im w \<and> Im w < pi \<longleftrightarrow> 0 < Im(exp w)"
  1273       using sin_gt_zero [of "- (Im w)"] sin_gt_zero [of "(Im w)"]
  1274       apply (auto simp: Im_exp zero_less_mult_iff)
  1275       using less_linear apply fastforce
  1276       using less_linear apply fastforce
  1277       done
  1278   }
  1279   then show ?thesis using assms
  1280     by auto
  1281 qed
  1282 
  1283 lemma Im_Ln_pos_le:
  1284   assumes "z \<noteq> 0"
  1285     shows "0 \<le> Im(Ln z) \<and> Im(Ln z) \<le> pi \<longleftrightarrow> 0 \<le> Im(z)"
  1286 proof -
  1287   { fix w
  1288     assume "w = Ln z"
  1289     then have w: "Im w \<le> pi" "- pi < Im w"
  1290       using Im_Ln_le_pi [of z]  mpi_less_Im_Ln [of z]  assms
  1291       by auto
  1292     then have "0 \<le> Im w \<and> Im w \<le> pi \<longleftrightarrow> 0 \<le> Im(exp w)"
  1293       using sin_ge_zero [of "- (Im w)"] sin_ge_zero [of "(Im w)"]
  1294       apply (auto simp: Im_exp zero_le_mult_iff sin_ge_zero)
  1295       apply (metis not_le not_less_iff_gr_or_eq pi_not_less_zero sin_eq_0_pi)
  1296       done }
  1297   then show ?thesis using assms
  1298     by auto
  1299 qed
  1300 
  1301 lemma Re_Ln_pos_lt_imp: "0 < Re(z) \<Longrightarrow> \<bar>Im(Ln z)\<bar> < pi/2"
  1302   by (metis Re_Ln_pos_lt less_irrefl zero_complex.simps(1))
  1303 
  1304 lemma Im_Ln_pos_lt_imp: "0 < Im(z) \<Longrightarrow> 0 < Im(Ln z) \<and> Im(Ln z) < pi"
  1305   by (metis Im_Ln_pos_lt not_le order_refl zero_complex.simps(2))
  1306 
  1307 text\<open>A reference to the set of positive real numbers\<close>
  1308 lemma Im_Ln_eq_0: "z \<noteq> 0 \<Longrightarrow> (Im(Ln z) = 0 \<longleftrightarrow> 0 < Re(z) \<and> Im(z) = 0)"
  1309 by (metis Im_complex_of_real Im_exp Ln_in_Reals Re_Ln_pos_lt Re_Ln_pos_lt_imp
  1310           Re_complex_of_real complex_is_Real_iff exp_Ln exp_of_real pi_gt_zero)
  1311 
  1312 lemma Im_Ln_eq_pi: "z \<noteq> 0 \<Longrightarrow> (Im(Ln z) = pi \<longleftrightarrow> Re(z) < 0 \<and> Im(z) = 0)"
  1313 by (metis Im_Ln_eq_0 Im_Ln_pos_le Im_Ln_pos_lt add.left_neutral complex_eq less_eq_real_def
  1314     mult_zero_right not_less_iff_gr_or_eq pi_ge_zero pi_neq_zero rcis_zero_arg rcis_zero_mod)
  1315 
  1316 
  1317 subsection\<open>More Properties of Ln\<close>
  1318 
  1319 lemma cnj_Ln: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> cnj(Ln z) = Ln(cnj z)"
  1320   apply (cases "z=0", auto)
  1321   apply (rule exp_complex_eqI)
  1322   apply (auto simp: abs_if split: if_split_asm)
  1323   using Im_Ln_less_pi Im_Ln_le_pi apply force
  1324   apply (metis complex_cnj_zero_iff diff_minus_eq_add diff_strict_mono minus_less_iff
  1325           mpi_less_Im_Ln mult.commute mult_2_right)
  1326   by (metis exp_Ln exp_cnj)
  1327 
  1328 lemma Ln_inverse: "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> Ln(inverse z) = -(Ln z)"
  1329   apply (cases "z=0", auto)
  1330   apply (rule exp_complex_eqI)
  1331   using mpi_less_Im_Ln [of z] mpi_less_Im_Ln [of "inverse z"]
  1332   apply (auto simp: abs_if exp_minus split: if_split_asm)
  1333   apply (metis Im_Ln_less_pi Im_Ln_le_pi add.commute add_mono_thms_linordered_field(3) inverse_nonzero_iff_nonzero mult_2)
  1334   done
  1335 
  1336 lemma Ln_minus1 [simp]: "Ln(-1) = \<i> * pi"
  1337   apply (rule exp_complex_eqI)
  1338   using Im_Ln_le_pi [of "-1"] mpi_less_Im_Ln [of "-1"] cis_conv_exp cis_pi
  1339   apply (auto simp: abs_if)
  1340   done
  1341 
  1342 lemma Ln_ii [simp]: "Ln \<i> = \<i> * of_real pi/2"
  1343   using Ln_exp [of "\<i> * (of_real pi/2)"]
  1344   unfolding exp_Euler
  1345   by simp
  1346 
  1347 lemma Ln_minus_ii [simp]: "Ln(-\<i>) = - (\<i> * pi/2)"
  1348 proof -
  1349   have  "Ln(-\<i>) = Ln(inverse \<i>)"    by simp
  1350   also have "... = - (Ln \<i>)"         using Ln_inverse by blast
  1351   also have "... = - (\<i> * pi/2)"     by simp
  1352   finally show ?thesis .
  1353 qed
  1354 
  1355 lemma Ln_times:
  1356   assumes "w \<noteq> 0" "z \<noteq> 0"
  1357     shows "Ln(w * z) =
  1358                 (if Im(Ln w + Ln z) \<le> -pi then
  1359                   (Ln(w) + Ln(z)) + \<i> * of_real(2*pi)
  1360                 else if Im(Ln w + Ln z) > pi then
  1361                   (Ln(w) + Ln(z)) - \<i> * of_real(2*pi)
  1362                 else Ln(w) + Ln(z))"
  1363   using pi_ge_zero Im_Ln_le_pi [of w] Im_Ln_le_pi [of z]
  1364   using assms mpi_less_Im_Ln [of w] mpi_less_Im_Ln [of z]
  1365   by (auto simp: exp_add exp_diff sin_double cos_double exp_Euler intro!: Ln_unique)
  1366 
  1367 corollary Ln_times_simple:
  1368     "\<lbrakk>w \<noteq> 0; z \<noteq> 0; -pi < Im(Ln w) + Im(Ln z); Im(Ln w) + Im(Ln z) \<le> pi\<rbrakk>
  1369          \<Longrightarrow> Ln(w * z) = Ln(w) + Ln(z)"
  1370   by (simp add: Ln_times)
  1371 
  1372 corollary Ln_times_of_real:
  1373     "\<lbrakk>r > 0; z \<noteq> 0\<rbrakk> \<Longrightarrow> Ln(of_real r * z) = ln r + Ln(z)"
  1374   using mpi_less_Im_Ln Im_Ln_le_pi
  1375   by (force simp: Ln_times)
  1376 
  1377 corollary Ln_divide_of_real:
  1378     "\<lbrakk>r > 0; z \<noteq> 0\<rbrakk> \<Longrightarrow> Ln(z / of_real r) = Ln(z) - ln r"
  1379 using Ln_times_of_real [of "inverse r" z]
  1380 by (simp add: ln_inverse Ln_of_real mult.commute divide_inverse of_real_inverse [symmetric]
  1381          del: of_real_inverse)
  1382 
  1383 lemma Ln_minus:
  1384   assumes "z \<noteq> 0"
  1385     shows "Ln(-z) = (if Im(z) \<le> 0 \<and> ~(Re(z) < 0 \<and> Im(z) = 0)
  1386                      then Ln(z) + \<i> * pi
  1387                      else Ln(z) - \<i> * pi)" (is "_ = ?rhs")
  1388   using Im_Ln_le_pi [of z] mpi_less_Im_Ln [of z] assms
  1389         Im_Ln_eq_pi [of z] Im_Ln_pos_lt [of z]
  1390     by (fastforce simp: exp_add exp_diff exp_Euler intro!: Ln_unique)
  1391 
  1392 lemma Ln_inverse_if:
  1393   assumes "z \<noteq> 0"
  1394     shows "Ln (inverse z) = (if z \<in> \<real>\<^sub>\<le>\<^sub>0 then -(Ln z) + \<i> * 2 * complex_of_real pi else -(Ln z))"
  1395 proof (cases "z \<in> \<real>\<^sub>\<le>\<^sub>0")
  1396   case False then show ?thesis
  1397     by (simp add: Ln_inverse)
  1398 next
  1399   case True
  1400   then have z: "Im z = 0" "Re z < 0"
  1401     using assms
  1402     apply (auto simp: complex_nonpos_Reals_iff)
  1403     by (metis complex_is_Real_iff le_imp_less_or_eq of_real_0 of_real_Re)
  1404   have "Ln(inverse z) = Ln(- (inverse (-z)))"
  1405     by simp
  1406   also have "... = Ln (inverse (-z)) + \<i> * complex_of_real pi"
  1407     using assms z
  1408     apply (simp add: Ln_minus)
  1409     apply (simp add: field_simps)
  1410     done
  1411   also have "... = - Ln (- z) + \<i> * complex_of_real pi"
  1412     apply (subst Ln_inverse)
  1413     using z by (auto simp add: complex_nonneg_Reals_iff)
  1414   also have "... = - (Ln z) + \<i> * 2 * complex_of_real pi"
  1415     apply (subst Ln_minus [OF assms])
  1416     using assms z
  1417     apply simp
  1418     done
  1419   finally show ?thesis by (simp add: True)
  1420 qed
  1421 
  1422 lemma Ln_times_ii:
  1423   assumes "z \<noteq> 0"
  1424     shows  "Ln(\<i> * z) = (if 0 \<le> Re(z) | Im(z) < 0
  1425                           then Ln(z) + \<i> * of_real pi/2
  1426                           else Ln(z) - \<i> * of_real(3 * pi/2))"
  1427   using Im_Ln_le_pi [of z] mpi_less_Im_Ln [of z] assms
  1428         Im_Ln_eq_pi [of z] Im_Ln_pos_lt [of z] Re_Ln_pos_le [of z]
  1429   by (simp add: Ln_times) auto
  1430 
  1431 lemma Ln_of_nat [simp]: "0 < n \<Longrightarrow> Ln (of_nat n) = of_real (ln (of_nat n))"
  1432   by (subst of_real_of_nat_eq[symmetric], subst Ln_of_real[symmetric]) simp_all
  1433 
  1434 lemma Ln_of_nat_over_of_nat:
  1435   assumes "m > 0" "n > 0"
  1436   shows   "Ln (of_nat m / of_nat n) = of_real (ln (of_nat m) - ln (of_nat n))"
  1437 proof -
  1438   have "of_nat m / of_nat n = (of_real (of_nat m / of_nat n) :: complex)" by simp
  1439   also from assms have "Ln ... = of_real (ln (of_nat m / of_nat n))"
  1440     by (simp add: Ln_of_real[symmetric])
  1441   also from assms have "... = of_real (ln (of_nat m) - ln (of_nat n))"
  1442     by (simp add: ln_div)
  1443   finally show ?thesis .
  1444 qed
  1445 
  1446 
  1447 subsection\<open>Relation between Ln and Arg, and hence continuity of Arg\<close>
  1448 
  1449 lemma Arg_Ln:
  1450   assumes "0 < Arg z" shows "Arg z = Im(Ln(-z)) + pi"
  1451 proof (cases "z = 0")
  1452   case True
  1453   with assms show ?thesis
  1454     by simp
  1455 next
  1456   case False
  1457   then have "z / of_real(norm z) = exp(\<i> * of_real(Arg z))"
  1458     using Arg [of z]
  1459     by (metis abs_norm_cancel nonzero_mult_div_cancel_left norm_of_real zero_less_norm_iff)
  1460   then have "- z / of_real(norm z) = exp (\<i> * (of_real (Arg z) - pi))"
  1461     using cis_conv_exp cis_pi
  1462     by (auto simp: exp_diff algebra_simps)
  1463   then have "ln (- z / of_real(norm z)) = ln (exp (\<i> * (of_real (Arg z) - pi)))"
  1464     by simp
  1465   also have "... = \<i> * (of_real(Arg z) - pi)"
  1466     using Arg [of z] assms pi_not_less_zero
  1467     by auto
  1468   finally have "Arg z =  Im (Ln (- z / of_real (cmod z))) + pi"
  1469     by simp
  1470   also have "... = Im (Ln (-z) - ln (cmod z)) + pi"
  1471     by (metis diff_0_right minus_diff_eq zero_less_norm_iff Ln_divide_of_real False)
  1472   also have "... = Im (Ln (-z)) + pi"
  1473     by simp
  1474   finally show ?thesis .
  1475 qed
  1476 
  1477 lemma continuous_at_Arg:
  1478   assumes "z \<notin> \<real>\<^sub>\<ge>\<^sub>0"
  1479     shows "continuous (at z) Arg"
  1480 proof -
  1481   have *: "isCont (\<lambda>z. Im (Ln (- z)) + pi) z"
  1482     by (rule Complex.isCont_Im isCont_Ln' continuous_intros | simp add: assms complex_is_Real_iff)+
  1483   have [simp]: "\<And>x. \<lbrakk>Im x \<noteq> 0\<rbrakk> \<Longrightarrow> Im (Ln (- x)) + pi = Arg x"
  1484       using Arg_Ln Arg_gt_0 complex_is_Real_iff by auto
  1485   consider "Re z < 0" | "Im z \<noteq> 0" using assms
  1486     using complex_nonneg_Reals_iff not_le by blast
  1487   then have [simp]: "(\<lambda>z. Im (Ln (- z)) + pi) \<midarrow>z\<rightarrow> Arg z"
  1488       using "*"  by (simp add: isCont_def) (metis Arg_Ln Arg_gt_0 complex_is_Real_iff)
  1489   show ?thesis
  1490       apply (simp add: continuous_at)
  1491       apply (rule Lim_transform_within_open [where s= "-\<real>\<^sub>\<ge>\<^sub>0" and f = "\<lambda>z. Im(Ln(-z)) + pi"])
  1492       apply (auto simp add: not_le Arg_Ln [OF Arg_gt_0] complex_nonneg_Reals_iff closed_def [symmetric])
  1493       using assms apply (force simp add: complex_nonneg_Reals_iff)
  1494       done
  1495 qed
  1496 
  1497 lemma Ln_series:
  1498   fixes z :: complex
  1499   assumes "norm z < 1"
  1500   shows   "(\<lambda>n. (-1)^Suc n / of_nat n * z^n) sums ln (1 + z)" (is "(\<lambda>n. ?f n * z^n) sums _")
  1501 proof -
  1502   let ?F = "\<lambda>z. \<Sum>n. ?f n * z^n" and ?F' = "\<lambda>z. \<Sum>n. diffs ?f n * z^n"
  1503   have r: "conv_radius ?f = 1"
  1504     by (intro conv_radius_ratio_limit_nonzero[of _ 1])
  1505        (simp_all add: norm_divide LIMSEQ_Suc_n_over_n del: of_nat_Suc)
  1506 
  1507   have "\<exists>c. \<forall>z\<in>ball 0 1. ln (1 + z) - ?F z = c"
  1508   proof (rule has_field_derivative_zero_constant)
  1509     fix z :: complex assume z': "z \<in> ball 0 1"
  1510     hence z: "norm z < 1" by (simp add: dist_0_norm)
  1511     define t :: complex where "t = of_real (1 + norm z) / 2"
  1512     from z have t: "norm z < norm t" "norm t < 1" unfolding t_def
  1513       by (simp_all add: field_simps norm_divide del: of_real_add)
  1514 
  1515     have "Re (-z) \<le> norm (-z)" by (rule complex_Re_le_cmod)
  1516     also from z have "... < 1" by simp
  1517     finally have "((\<lambda>z. ln (1 + z)) has_field_derivative inverse (1+z)) (at z)"
  1518       by (auto intro!: derivative_eq_intros simp: complex_nonpos_Reals_iff)
  1519     moreover have "(?F has_field_derivative ?F' z) (at z)" using t r
  1520       by (intro termdiffs_strong[of _ t] summable_in_conv_radius) simp_all
  1521     ultimately have "((\<lambda>z. ln (1 + z) - ?F z) has_field_derivative (inverse (1 + z) - ?F' z))
  1522                        (at z within ball 0 1)"
  1523       by (intro derivative_intros) (simp_all add: at_within_open[OF z'])
  1524     also have "(\<lambda>n. of_nat n * ?f n * z ^ (n - Suc 0)) sums ?F' z" using t r
  1525       by (intro diffs_equiv termdiff_converges[OF t(1)] summable_in_conv_radius) simp_all
  1526     from sums_split_initial_segment[OF this, of 1]
  1527       have "(\<lambda>i. (-z) ^ i) sums ?F' z" by (simp add: power_minus[of z] del: of_nat_Suc)
  1528     hence "?F' z = inverse (1 + z)" using z by (simp add: sums_iff suminf_geometric divide_inverse)
  1529     also have "inverse (1 + z) - inverse (1 + z) = 0" by simp
  1530     finally show "((\<lambda>z. ln (1 + z) - ?F z) has_field_derivative 0) (at z within ball 0 1)" .
  1531   qed simp_all
  1532   then obtain c where c: "\<And>z. z \<in> ball 0 1 \<Longrightarrow> ln (1 + z) - ?F z = c" by blast
  1533   from c[of 0] have "c = 0" by (simp only: powser_zero) simp
  1534   with c[of z] assms have "ln (1 + z) = ?F z" by (simp add: dist_0_norm)
  1535   moreover have "summable (\<lambda>n. ?f n * z^n)" using assms r
  1536     by (intro summable_in_conv_radius) simp_all
  1537   ultimately show ?thesis by (simp add: sums_iff)
  1538 qed
  1539 
  1540 lemma Ln_series': "cmod z < 1 \<Longrightarrow> (\<lambda>n. - ((-z)^n) / of_nat n) sums ln (1 + z)"
  1541   by (drule Ln_series) (simp add: power_minus')
  1542 
  1543 lemma ln_series':
  1544   assumes "abs (x::real) < 1"
  1545   shows   "(\<lambda>n. - ((-x)^n) / of_nat n) sums ln (1 + x)"
  1546 proof -
  1547   from assms have "(\<lambda>n. - ((-of_real x)^n) / of_nat n) sums ln (1 + complex_of_real x)"
  1548     by (intro Ln_series') simp_all
  1549   also have "(\<lambda>n. - ((-of_real x)^n) / of_nat n) = (\<lambda>n. complex_of_real (- ((-x)^n) / of_nat n))"
  1550     by (rule ext) simp
  1551   also from assms have "ln (1 + complex_of_real x) = of_real (ln (1 + x))"
  1552     by (subst Ln_of_real [symmetric]) simp_all
  1553   finally show ?thesis by (subst (asm) sums_of_real_iff)
  1554 qed
  1555 
  1556 lemma Ln_approx_linear:
  1557   fixes z :: complex
  1558   assumes "norm z < 1"
  1559   shows   "norm (ln (1 + z) - z) \<le> norm z^2 / (1 - norm z)"
  1560 proof -
  1561   let ?f = "\<lambda>n. (-1)^Suc n / of_nat n"
  1562   from assms have "(\<lambda>n. ?f n * z^n) sums ln (1 + z)" using Ln_series by simp
  1563   moreover have "(\<lambda>n. (if n = 1 then 1 else 0) * z^n) sums z" using powser_sums_if[of 1] by simp
  1564   ultimately have "(\<lambda>n. (?f n - (if n = 1 then 1 else 0)) * z^n) sums (ln (1 + z) - z)"
  1565     by (subst left_diff_distrib, intro sums_diff) simp_all
  1566   from sums_split_initial_segment[OF this, of "Suc 1"]
  1567     have "(\<lambda>i. (-(z^2)) * inverse (2 + of_nat i) * (- z)^i) sums (Ln (1 + z) - z)"
  1568     by (simp add: power2_eq_square mult_ac power_minus[of z] divide_inverse)
  1569   hence "(Ln (1 + z) - z) = (\<Sum>i. (-(z^2)) * inverse (of_nat (i+2)) * (-z)^i)"
  1570     by (simp add: sums_iff)
  1571   also have A: "summable (\<lambda>n. norm z^2 * (inverse (real_of_nat (Suc (Suc n))) * cmod z ^ n))"
  1572     by (rule summable_mult, rule summable_comparison_test_ev[OF _ summable_geometric[of "norm z"]])
  1573        (auto simp: assms field_simps intro!: always_eventually)
  1574   hence "norm (\<Sum>i. (-(z^2)) * inverse (of_nat (i+2)) * (-z)^i) \<le>
  1575              (\<Sum>i. norm (-(z^2) * inverse (of_nat (i+2)) * (-z)^i))"
  1576     by (intro summable_norm)
  1577        (auto simp: norm_power norm_inverse norm_mult mult_ac simp del: of_nat_add of_nat_Suc)
  1578   also have "norm ((-z)^2 * (-z)^i) * inverse (of_nat (i+2)) \<le> norm ((-z)^2 * (-z)^i) * 1" for i
  1579     by (intro mult_left_mono) (simp_all add: divide_simps)
  1580   hence "(\<Sum>i. norm (-(z^2) * inverse (of_nat (i+2)) * (-z)^i)) \<le>
  1581            (\<Sum>i. norm (-(z^2) * (-z)^i))" using A assms
  1582     apply (simp_all only: norm_power norm_inverse norm_divide norm_mult)
  1583     apply (intro suminf_le summable_mult summable_geometric)
  1584     apply (auto simp: norm_power field_simps simp del: of_nat_add of_nat_Suc)
  1585     done
  1586   also have "... = norm z^2 * (\<Sum>i. norm z^i)" using assms
  1587     by (subst suminf_mult [symmetric]) (auto intro!: summable_geometric simp: norm_mult norm_power)
  1588   also have "(\<Sum>i. norm z^i) = inverse (1 - norm z)" using assms
  1589     by (subst suminf_geometric) (simp_all add: divide_inverse)
  1590   also have "norm z^2 * ... = norm z^2 / (1 - norm z)" by (simp add: divide_inverse)
  1591   finally show ?thesis .
  1592 qed
  1593 
  1594 
  1595 text\<open>Relation between Arg and arctangent in upper halfplane\<close>
  1596 lemma Arg_arctan_upperhalf:
  1597   assumes "0 < Im z"
  1598     shows "Arg z = pi/2 - arctan(Re z / Im z)"
  1599 proof (cases "z = 0")
  1600   case True with assms show ?thesis
  1601     by simp
  1602 next
  1603   case False
  1604   show ?thesis
  1605     apply (rule Arg_unique [of "norm z"])
  1606     using False assms arctan [of "Re z / Im z"] pi_ge_two pi_half_less_two
  1607     apply (auto simp: exp_Euler cos_diff sin_diff)
  1608     using norm_complex_def [of z, symmetric]
  1609     apply (simp add: sin_of_real cos_of_real sin_arctan cos_arctan field_simps real_sqrt_divide)
  1610     apply (metis complex_eq mult.assoc ring_class.ring_distribs(2))
  1611     done
  1612 qed
  1613 
  1614 lemma Arg_eq_Im_Ln:
  1615   assumes "0 \<le> Im z" "0 < Re z"
  1616     shows "Arg z = Im (Ln z)"
  1617 proof (cases "z = 0 \<or> Im z = 0")
  1618   case True then show ?thesis
  1619     using assms Arg_eq_0 complex_is_Real_iff
  1620     apply auto
  1621     by (metis Arg_eq_0_pi Arg_eq_pi Im_Ln_eq_0 Im_Ln_eq_pi less_numeral_extra(3) zero_complex.simps(1))
  1622 next
  1623   case False
  1624   then have "Arg z > 0"
  1625     using Arg_gt_0 complex_is_Real_iff by blast
  1626   then show ?thesis
  1627     using assms False
  1628     by (subst Arg_Ln) (auto simp: Ln_minus)
  1629 qed
  1630 
  1631 lemma continuous_within_upperhalf_Arg:
  1632   assumes "z \<noteq> 0"
  1633     shows "continuous (at z within {z. 0 \<le> Im z}) Arg"
  1634 proof (cases "z \<in> \<real>\<^sub>\<ge>\<^sub>0")
  1635   case False then show ?thesis
  1636     using continuous_at_Arg continuous_at_imp_continuous_within by auto
  1637 next
  1638   case True
  1639   then have z: "z \<in> \<real>" "0 < Re z"
  1640     using assms  by (auto simp: complex_nonneg_Reals_iff complex_is_Real_iff complex_neq_0)
  1641   then have [simp]: "Arg z = 0" "Im (Ln z) = 0"
  1642     by (auto simp: Arg_eq_0 Im_Ln_eq_0 assms complex_is_Real_iff)
  1643   show ?thesis
  1644   proof (clarsimp simp add: continuous_within Lim_within dist_norm)
  1645     fix e::real
  1646     assume "0 < e"
  1647     moreover have "continuous (at z) (\<lambda>x. Im (Ln x))"
  1648       using z by (simp add: continuous_at_Ln complex_nonpos_Reals_iff)
  1649     ultimately
  1650     obtain d where d: "d>0" "\<And>x. x \<noteq> z \<Longrightarrow> cmod (x - z) < d \<Longrightarrow> \<bar>Im (Ln x)\<bar> < e"
  1651       by (auto simp: continuous_within Lim_within dist_norm)
  1652     { fix x
  1653       assume "cmod (x - z) < Re z / 2"
  1654       then have "\<bar>Re x - Re z\<bar> < Re z / 2"
  1655         by (metis le_less_trans abs_Re_le_cmod minus_complex.simps(1))
  1656       then have "0 < Re x"
  1657         using z by linarith
  1658     }
  1659     then show "\<exists>d>0. \<forall>x. 0 \<le> Im x \<longrightarrow> x \<noteq> z \<and> cmod (x - z) < d \<longrightarrow> \<bar>Arg x\<bar> < e"
  1660       apply (rule_tac x="min d (Re z / 2)" in exI)
  1661       using z d
  1662       apply (auto simp: Arg_eq_Im_Ln)
  1663       done
  1664   qed
  1665 qed
  1666 
  1667 lemma continuous_on_upperhalf_Arg: "continuous_on ({z. 0 \<le> Im z} - {0}) Arg"
  1668   apply (auto simp: continuous_on_eq_continuous_within)
  1669   by (metis Diff_subset continuous_within_subset continuous_within_upperhalf_Arg)
  1670 
  1671 lemma open_Arg_less_Int:
  1672   assumes "0 \<le> s" "t \<le> 2*pi"
  1673     shows "open ({y. s < Arg y} \<inter> {y. Arg y < t})"
  1674 proof -
  1675   have 1: "continuous_on (UNIV - \<real>\<^sub>\<ge>\<^sub>0) Arg"
  1676     using continuous_at_Arg continuous_at_imp_continuous_within
  1677     by (auto simp: continuous_on_eq_continuous_within)
  1678   have 2: "open (UNIV - \<real>\<^sub>\<ge>\<^sub>0 :: complex set)"  by (simp add: open_Diff)
  1679   have "open ({z. s < z} \<inter> {z. z < t})"
  1680     using open_lessThan [of t] open_greaterThan [of s]
  1681     by (metis greaterThan_def lessThan_def open_Int)
  1682   moreover have "{y. s < Arg y} \<inter> {y. Arg y < t} \<subseteq> - \<real>\<^sub>\<ge>\<^sub>0"
  1683     using assms by (auto simp: Arg_real complex_nonneg_Reals_iff complex_is_Real_iff)
  1684   ultimately show ?thesis
  1685     using continuous_imp_open_vimage [OF 1 2, of  "{z. Re z > s} \<inter> {z. Re z < t}"]
  1686     by auto
  1687 qed
  1688 
  1689 lemma open_Arg_gt: "open {z. t < Arg z}"
  1690 proof (cases "t < 0")
  1691   case True then have "{z. t < Arg z} = UNIV"
  1692     using Arg_ge_0 less_le_trans by auto
  1693   then show ?thesis
  1694     by simp
  1695 next
  1696   case False then show ?thesis
  1697     using open_Arg_less_Int [of t "2*pi"] Arg_lt_2pi
  1698     by auto
  1699 qed
  1700 
  1701 lemma closed_Arg_le: "closed {z. Arg z \<le> t}"
  1702   using open_Arg_gt [of t]
  1703   by (simp add: closed_def Set.Collect_neg_eq [symmetric] not_le)
  1704 
  1705 subsection\<open>Complex Powers\<close>
  1706 
  1707 lemma powr_to_1 [simp]: "z powr 1 = (z::complex)"
  1708   by (simp add: powr_def)
  1709 
  1710 lemma powr_nat:
  1711   fixes n::nat and z::complex shows "z powr n = (if z = 0 then 0 else z^n)"
  1712   by (simp add: exp_of_nat_mult powr_def)
  1713 
  1714 lemma norm_powr_real: "w \<in> \<real> \<Longrightarrow> 0 < Re w \<Longrightarrow> norm(w powr z) = exp(Re z * ln(Re w))"
  1715   apply (simp add: powr_def)
  1716   using Im_Ln_eq_0 complex_is_Real_iff norm_complex_def
  1717   by auto
  1718 
  1719 lemma powr_complexpow [simp]:
  1720   fixes x::complex shows "x \<noteq> 0 \<Longrightarrow> x powr (of_nat n) = x^n"
  1721   by (induct n) (auto simp: ac_simps powr_add)
  1722 
  1723 lemma powr_complexnumeral [simp]:
  1724   fixes x::complex shows "x \<noteq> 0 \<Longrightarrow> x powr (numeral n) = x ^ (numeral n)"
  1725   by (metis of_nat_numeral powr_complexpow)
  1726 
  1727 lemma cnj_powr:
  1728   assumes "Im a = 0 \<Longrightarrow> Re a \<ge> 0"
  1729   shows   "cnj (a powr b) = cnj a powr cnj b"
  1730 proof (cases "a = 0")
  1731   case False
  1732   with assms have "a \<notin> \<real>\<^sub>\<le>\<^sub>0" by (auto simp: complex_eq_iff complex_nonpos_Reals_iff)
  1733   with False show ?thesis by (simp add: powr_def exp_cnj cnj_Ln)
  1734 qed simp
  1735 
  1736 lemma powr_real_real:
  1737     "\<lbrakk>w \<in> \<real>; z \<in> \<real>; 0 < Re w\<rbrakk> \<Longrightarrow> w powr z = exp(Re z * ln(Re w))"
  1738   apply (simp add: powr_def)
  1739   by (metis complex_eq complex_is_Real_iff diff_0 diff_0_right diff_minus_eq_add exp_ln exp_not_eq_zero
  1740        exp_of_real Ln_of_real mult_zero_right of_real_0 of_real_mult)
  1741 
  1742 lemma powr_of_real:
  1743   fixes x::real and y::real
  1744   shows "0 \<le> x \<Longrightarrow> of_real x powr (of_real y::complex) = of_real (x powr y)"
  1745   by (simp_all add: powr_def exp_eq_polar)
  1746 
  1747 lemma powr_Reals_eq: "\<lbrakk>x \<in> \<real>; y \<in> \<real>; Re x > 0\<rbrakk> \<Longrightarrow> x powr y = of_real (Re x powr Re y)"
  1748   by (metis linear not_le of_real_Re powr_of_real)
  1749 
  1750 lemma norm_powr_real_mono:
  1751     "\<lbrakk>w \<in> \<real>; 1 < Re w\<rbrakk>
  1752      \<Longrightarrow> cmod(w powr z1) \<le> cmod(w powr z2) \<longleftrightarrow> Re z1 \<le> Re z2"
  1753   by (auto simp: powr_def algebra_simps Reals_def Ln_of_real)
  1754 
  1755 lemma powr_times_real:
  1756     "\<lbrakk>x \<in> \<real>; y \<in> \<real>; 0 \<le> Re x; 0 \<le> Re y\<rbrakk>
  1757            \<Longrightarrow> (x * y) powr z = x powr z * y powr z"
  1758   by (auto simp: Reals_def powr_def Ln_times exp_add algebra_simps less_eq_real_def Ln_of_real)
  1759 
  1760 lemma Re_powr_le: "r \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> Re (r powr z) \<le> Re r powr Re z"
  1761   by (auto simp: powr_def nonneg_Reals_def order_trans [OF complex_Re_le_cmod])
  1762 
  1763 lemma
  1764   fixes w::complex
  1765   shows Reals_powr [simp]: "\<lbrakk>w \<in> \<real>\<^sub>\<ge>\<^sub>0; z \<in> \<real>\<rbrakk> \<Longrightarrow> w powr z \<in> \<real>"
  1766   and nonneg_Reals_powr [simp]: "\<lbrakk>w \<in> \<real>\<^sub>\<ge>\<^sub>0; z \<in> \<real>\<rbrakk> \<Longrightarrow> w powr z \<in> \<real>\<^sub>\<ge>\<^sub>0"
  1767   by (auto simp: nonneg_Reals_def Reals_def powr_of_real)
  1768 
  1769 lemma powr_neg_real_complex:
  1770   shows   "(- of_real x) powr a = (-1) powr (of_real (sgn x) * a) * of_real x powr (a :: complex)"
  1771 proof (cases "x = 0")
  1772   assume x: "x \<noteq> 0"
  1773   hence "(-x) powr a = exp (a * ln (-of_real x))" by (simp add: powr_def)
  1774   also from x have "ln (-of_real x) = Ln (of_real x) + of_real (sgn x) * pi * \<i>"
  1775     by (simp add: Ln_minus Ln_of_real)
  1776   also from x have "exp (a * ...) = cis pi powr (of_real (sgn x) * a) * of_real x powr a"
  1777     by (simp add: powr_def exp_add algebra_simps Ln_of_real cis_conv_exp)
  1778   also note cis_pi
  1779   finally show ?thesis by simp
  1780 qed simp_all
  1781 
  1782 lemma has_field_derivative_powr:
  1783   fixes z :: complex
  1784   shows "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> ((\<lambda>z. z powr s) has_field_derivative (s * z powr (s - 1))) (at z)"
  1785   apply (cases "z=0", auto)
  1786   apply (simp add: powr_def)
  1787   apply (rule DERIV_transform_at [where d = "norm z" and f = "\<lambda>z. exp (s * Ln z)"])
  1788   apply (auto simp: dist_complex_def)
  1789   apply (intro derivative_eq_intros | simp)+
  1790   apply (simp add: field_simps exp_diff)
  1791   done
  1792 
  1793 declare has_field_derivative_powr[THEN DERIV_chain2, derivative_intros]
  1794 
  1795 
  1796 lemma has_field_derivative_powr_right [derivative_intros]:
  1797     "w \<noteq> 0 \<Longrightarrow> ((\<lambda>z. w powr z) has_field_derivative Ln w * w powr z) (at z)"
  1798   apply (simp add: powr_def)
  1799   apply (intro derivative_eq_intros | simp)+
  1800   done
  1801 
  1802 lemma field_differentiable_powr_right [derivative_intros]:
  1803   fixes w::complex
  1804   shows "w \<noteq> 0 \<Longrightarrow> (\<lambda>z. w powr z) field_differentiable (at z)"
  1805 using field_differentiable_def has_field_derivative_powr_right by blast
  1806 
  1807 lemma holomorphic_on_powr_right [holomorphic_intros]:
  1808     "f holomorphic_on s \<Longrightarrow> w \<noteq> 0 \<Longrightarrow> (\<lambda>z. w powr (f z)) holomorphic_on s"
  1809   unfolding holomorphic_on_def field_differentiable_def
  1810   by (metis (full_types) DERIV_chain' has_field_derivative_powr_right)
  1811 
  1812 lemma norm_powr_real_powr:
  1813   "w \<in> \<real> \<Longrightarrow> 0 \<le> Re w \<Longrightarrow> cmod (w powr z) = Re w powr Re z"
  1814   by (cases "w = 0") (auto simp add: norm_powr_real powr_def Im_Ln_eq_0
  1815                                      complex_is_Real_iff in_Reals_norm complex_eq_iff)
  1816 
  1817 lemma tendsto_ln_complex [tendsto_intros]:
  1818   assumes "(f \<longlongrightarrow> a) F" "a \<notin> \<real>\<^sub>\<le>\<^sub>0"
  1819   shows   "((\<lambda>z. ln (f z :: complex)) \<longlongrightarrow> ln a) F"
  1820   using tendsto_compose[OF continuous_at_Ln[of a, unfolded isCont_def] assms(1)] assms(2) by simp
  1821 
  1822 lemma tendsto_powr_complex:
  1823   fixes f g :: "_ \<Rightarrow> complex"
  1824   assumes a: "a \<notin> \<real>\<^sub>\<le>\<^sub>0"
  1825   assumes f: "(f \<longlongrightarrow> a) F" and g: "(g \<longlongrightarrow> b) F"
  1826   shows   "((\<lambda>z. f z powr g z) \<longlongrightarrow> a powr b) F"
  1827 proof -
  1828   from a have [simp]: "a \<noteq> 0" by auto
  1829   from f g a have "((\<lambda>z. exp (g z * ln (f z))) \<longlongrightarrow> a powr b) F" (is ?P)
  1830     by (auto intro!: tendsto_intros simp: powr_def)
  1831   also {
  1832     have "eventually (\<lambda>z. z \<noteq> 0) (nhds a)"
  1833       by (intro t1_space_nhds) simp_all
  1834     with f have "eventually (\<lambda>z. f z \<noteq> 0) F" using filterlim_iff by blast
  1835   }
  1836   hence "?P \<longleftrightarrow> ((\<lambda>z. f z powr g z) \<longlongrightarrow> a powr b) F"
  1837     by (intro tendsto_cong refl) (simp_all add: powr_def mult_ac)
  1838   finally show ?thesis .
  1839 qed
  1840 
  1841 lemma tendsto_powr_complex_0:
  1842   fixes f g :: "'a \<Rightarrow> complex"
  1843   assumes f: "(f \<longlongrightarrow> 0) F" and g: "(g \<longlongrightarrow> b) F" and b: "Re b > 0"
  1844   shows   "((\<lambda>z. f z powr g z) \<longlongrightarrow> 0) F"
  1845 proof (rule tendsto_norm_zero_cancel)
  1846   define h where
  1847     "h = (\<lambda>z. if f z = 0 then 0 else exp (Re (g z) * ln (cmod (f z)) + abs (Im (g z)) * pi))"
  1848   {
  1849     fix z :: 'a assume z: "f z \<noteq> 0"
  1850     define c where "c = abs (Im (g z)) * pi"
  1851     from mpi_less_Im_Ln[OF z] Im_Ln_le_pi[OF z]
  1852       have "abs (Im (Ln (f z))) \<le> pi" by simp
  1853     from mult_left_mono[OF this, of "abs (Im (g z))"]
  1854       have "abs (Im (g z) * Im (ln (f z))) \<le> c" by (simp add: abs_mult c_def)
  1855     hence "-Im (g z) * Im (ln (f z)) \<le> c" by simp
  1856     hence "norm (f z powr g z) \<le> h z" by (simp add: powr_def field_simps h_def c_def)
  1857   }
  1858   hence le: "norm (f z powr g z) \<le> h z" for z by (cases "f x = 0") (simp_all add: h_def)
  1859 
  1860   have g': "(g \<longlongrightarrow> b) (inf F (principal {z. f z \<noteq> 0}))"
  1861     by (rule tendsto_mono[OF _ g]) simp_all
  1862   have "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) (inf F (principal {z. f z \<noteq> 0}))"
  1863     by (subst tendsto_norm_zero_iff, rule tendsto_mono[OF _ f]) simp_all
  1864   moreover {
  1865     have "filterlim (\<lambda>x. norm (f x)) (principal {0<..}) (principal {z. f z \<noteq> 0})"
  1866       by (auto simp: filterlim_def)
  1867     hence "filterlim (\<lambda>x. norm (f x)) (principal {0<..})
  1868              (inf F (principal {z. f z \<noteq> 0}))"
  1869       by (rule filterlim_mono) simp_all
  1870   }
  1871   ultimately have norm: "filterlim (\<lambda>x. norm (f x)) (at_right 0) (inf F (principal {z. f z \<noteq> 0}))"
  1872     by (simp add: filterlim_inf at_within_def)
  1873 
  1874   have A: "LIM x inf F (principal {z. f z \<noteq> 0}). Re (g x) * -ln (cmod (f x)) :> at_top"
  1875     by (rule filterlim_tendsto_pos_mult_at_top tendsto_intros g' b
  1876           filterlim_compose[OF filterlim_uminus_at_top_at_bot] filterlim_compose[OF ln_at_0] norm)+
  1877   have B: "LIM x inf F (principal {z. f z \<noteq> 0}).
  1878           -\<bar>Im (g x)\<bar> * pi + -(Re (g x) * ln (cmod (f x))) :> at_top"
  1879     by (rule filterlim_tendsto_add_at_top tendsto_intros g')+ (insert A, simp_all)
  1880   have C: "(h \<longlongrightarrow> 0) F" unfolding h_def
  1881     by (intro filterlim_If tendsto_const filterlim_compose[OF exp_at_bot])
  1882        (insert B, auto simp: filterlim_uminus_at_bot algebra_simps)
  1883   show "((\<lambda>x. norm (f x powr g x)) \<longlongrightarrow> 0) F"
  1884     by (rule Lim_null_comparison[OF always_eventually C]) (insert le, auto)
  1885 qed
  1886 
  1887 lemma tendsto_powr_complex' [tendsto_intros]:
  1888   fixes f g :: "_ \<Rightarrow> complex"
  1889   assumes fz: "a \<notin> \<real>\<^sub>\<le>\<^sub>0 \<or> (a = 0 \<and> Re b > 0)"
  1890   assumes fg: "(f \<longlongrightarrow> a) F" "(g \<longlongrightarrow> b) F"
  1891   shows   "((\<lambda>z. f z powr g z) \<longlongrightarrow> a powr b) F"
  1892 proof (cases "a = 0")
  1893   case True
  1894   with assms show ?thesis by (auto intro!: tendsto_powr_complex_0)
  1895 next
  1896   case False
  1897   with assms show ?thesis by (auto intro!: tendsto_powr_complex elim!: nonpos_Reals_cases)
  1898 qed
  1899 
  1900 lemma continuous_powr_complex:
  1901   assumes "f (netlimit F) \<notin> \<real>\<^sub>\<le>\<^sub>0" "continuous F f" "continuous F g"
  1902   shows   "continuous F (\<lambda>z. f z powr g z :: complex)"
  1903   using assms unfolding continuous_def by (intro tendsto_powr_complex) simp_all
  1904 
  1905 lemma isCont_powr_complex [continuous_intros]:
  1906   assumes "f z \<notin> \<real>\<^sub>\<le>\<^sub>0" "isCont f z" "isCont g z"
  1907   shows   "isCont (\<lambda>z. f z powr g z :: complex) z"
  1908   using assms unfolding isCont_def by (intro tendsto_powr_complex) simp_all
  1909 
  1910 lemma continuous_on_powr_complex [continuous_intros]:
  1911   assumes "A \<subseteq> {z. Re (f z) \<ge> 0 \<or> Im (f z) \<noteq> 0}"
  1912   assumes "\<And>z. z \<in> A \<Longrightarrow> f z = 0 \<Longrightarrow> Re (g z) > 0"
  1913   assumes "continuous_on A f" "continuous_on A g"
  1914   shows   "continuous_on A (\<lambda>z. f z powr g z)"
  1915   unfolding continuous_on_def
  1916 proof
  1917   fix z assume z: "z \<in> A"
  1918   show "((\<lambda>z. f z powr g z) \<longlongrightarrow> f z powr g z) (at z within A)"
  1919   proof (cases "f z = 0")
  1920     case False
  1921     from assms(1,2) z have "Re (f z) \<ge> 0 \<or> Im (f z) \<noteq> 0" "f z = 0 \<longrightarrow> Re (g z) > 0" by auto
  1922     with assms(3,4) z show ?thesis
  1923       by (intro tendsto_powr_complex')
  1924          (auto elim!: nonpos_Reals_cases simp: complex_eq_iff continuous_on_def)
  1925   next
  1926     case True
  1927     with assms z show ?thesis
  1928       by (auto intro!: tendsto_powr_complex_0 simp: continuous_on_def)
  1929   qed
  1930 qed
  1931 
  1932 
  1933 subsection\<open>Some Limits involving Logarithms\<close>
  1934 
  1935 lemma lim_Ln_over_power:
  1936   fixes s::complex
  1937   assumes "0 < Re s"
  1938     shows "((\<lambda>n. Ln n / (n powr s)) \<longlongrightarrow> 0) sequentially"
  1939 proof (simp add: lim_sequentially dist_norm, clarify)
  1940   fix e::real
  1941   assume e: "0 < e"
  1942   have "\<exists>xo>0. \<forall>x\<ge>xo. 0 < e * 2 + (e * Re s * 2 - 2) * x + e * (Re s)\<^sup>2 * x\<^sup>2"
  1943   proof (rule_tac x="2/(e * (Re s)\<^sup>2)" in exI, safe)
  1944     show "0 < 2 / (e * (Re s)\<^sup>2)"
  1945       using e assms by (simp add: field_simps)
  1946   next
  1947     fix x::real
  1948     assume x: "2 / (e * (Re s)\<^sup>2) \<le> x"
  1949     then have "x>0"
  1950     using e assms
  1951       by (metis less_le_trans mult_eq_0_iff mult_pos_pos pos_less_divide_eq power2_eq_square
  1952                 zero_less_numeral)
  1953     then show "0 < e * 2 + (e * Re s * 2 - 2) * x + e * (Re s)\<^sup>2 * x\<^sup>2"
  1954       using e assms x
  1955       apply (auto simp: field_simps)
  1956       apply (rule_tac y = "e * (x\<^sup>2 * (Re s)\<^sup>2)" in le_less_trans)
  1957       apply (auto simp: power2_eq_square field_simps add_pos_pos)
  1958       done
  1959   qed
  1960   then have "\<exists>xo>0. \<forall>x\<ge>xo. x / e < 1 + (Re s * x) + (1/2) * (Re s * x)^2"
  1961     using e  by (simp add: field_simps)
  1962   then have "\<exists>xo>0. \<forall>x\<ge>xo. x / e < exp (Re s * x)"
  1963     using assms
  1964     by (force intro: less_le_trans [OF _ exp_lower_taylor_quadratic])
  1965   then have "\<exists>xo>0. \<forall>x\<ge>xo. x < e * exp (Re s * x)"
  1966     using e   by (auto simp: field_simps)
  1967   with e show "\<exists>no. \<forall>n\<ge>no. norm (Ln (of_nat n) / of_nat n powr s) < e"
  1968     apply (auto simp: norm_divide norm_powr_real divide_simps)
  1969     apply (rule_tac x="nat \<lceil>exp xo\<rceil>" in exI)
  1970     apply clarify
  1971     apply (drule_tac x="ln n" in spec)
  1972     apply (auto simp: exp_less_mono nat_ceiling_le_eq not_le)
  1973     apply (metis exp_less_mono exp_ln not_le of_nat_0_less_iff)
  1974     done
  1975 qed
  1976 
  1977 lemma lim_Ln_over_n: "((\<lambda>n. Ln(of_nat n) / of_nat n) \<longlongrightarrow> 0) sequentially"
  1978   using lim_Ln_over_power [of 1] by simp
  1979 
  1980 lemma lim_ln_over_power:
  1981   fixes s :: real
  1982   assumes "0 < s"
  1983     shows "((\<lambda>n. ln n / (n powr s)) \<longlongrightarrow> 0) sequentially"
  1984   using lim_Ln_over_power [of "of_real s", THEN filterlim_sequentially_Suc [THEN iffD2]] assms
  1985   apply (subst filterlim_sequentially_Suc [symmetric])
  1986   apply (simp add: lim_sequentially dist_norm
  1987           Ln_Reals_eq norm_powr_real_powr norm_divide)
  1988   done
  1989 
  1990 lemma lim_ln_over_n: "((\<lambda>n. ln(real_of_nat n) / of_nat n) \<longlongrightarrow> 0) sequentially"
  1991   using lim_ln_over_power [of 1, THEN filterlim_sequentially_Suc [THEN iffD2]]
  1992   apply (subst filterlim_sequentially_Suc [symmetric])
  1993   apply (simp add: lim_sequentially dist_norm)
  1994   done
  1995 
  1996 lemma lim_1_over_complex_power:
  1997   assumes "0 < Re s"
  1998     shows "((\<lambda>n. 1 / (of_nat n powr s)) \<longlongrightarrow> 0) sequentially"
  1999 proof -
  2000   have "\<forall>n>0. 3 \<le> n \<longrightarrow> 1 \<le> ln (real_of_nat n)"
  2001     using ln_272_gt_1
  2002     by (force intro: order_trans [of _ "ln (272/100)"])
  2003   moreover have "(\<lambda>n. cmod (Ln (of_nat n) / of_nat n powr s)) \<longlonglongrightarrow> 0"
  2004     using lim_Ln_over_power [OF assms]
  2005     by (metis tendsto_norm_zero_iff)
  2006   ultimately show ?thesis
  2007     apply (auto intro!: Lim_null_comparison [where g = "\<lambda>n. norm (Ln(of_nat n) / of_nat n powr s)"])
  2008     apply (auto simp: norm_divide divide_simps eventually_sequentially)
  2009     done
  2010 qed
  2011 
  2012 lemma lim_1_over_real_power:
  2013   fixes s :: real
  2014   assumes "0 < s"
  2015     shows "((\<lambda>n. 1 / (of_nat n powr s)) \<longlongrightarrow> 0) sequentially"
  2016   using lim_1_over_complex_power [of "of_real s", THEN filterlim_sequentially_Suc [THEN iffD2]] assms
  2017   apply (subst filterlim_sequentially_Suc [symmetric])
  2018   apply (simp add: lim_sequentially dist_norm)
  2019   apply (simp add: Ln_Reals_eq norm_powr_real_powr norm_divide)
  2020   done
  2021 
  2022 lemma lim_1_over_Ln: "((\<lambda>n. 1 / Ln(of_nat n)) \<longlongrightarrow> 0) sequentially"
  2023 proof (clarsimp simp add: lim_sequentially dist_norm norm_divide divide_simps)
  2024   fix r::real
  2025   assume "0 < r"
  2026   have ir: "inverse (exp (inverse r)) > 0"
  2027     by simp
  2028   obtain n where n: "1 < of_nat n * inverse (exp (inverse r))"
  2029     using ex_less_of_nat_mult [of _ 1, OF ir]
  2030     by auto
  2031   then have "exp (inverse r) < of_nat n"
  2032     by (simp add: divide_simps)
  2033   then have "ln (exp (inverse r)) < ln (of_nat n)"
  2034     by (metis exp_gt_zero less_trans ln_exp ln_less_cancel_iff)
  2035   with \<open>0 < r\<close> have "1 < r * ln (real_of_nat n)"
  2036     by (simp add: field_simps)
  2037   moreover have "n > 0" using n
  2038     using neq0_conv by fastforce
  2039   ultimately show "\<exists>no. \<forall>n. Ln (of_nat n) \<noteq> 0 \<longrightarrow> no \<le> n \<longrightarrow> 1 < r * cmod (Ln (of_nat n))"
  2040     using n \<open>0 < r\<close>
  2041     apply (rule_tac x=n in exI)
  2042     apply (auto simp: divide_simps)
  2043     apply (erule less_le_trans, auto)
  2044     done
  2045 qed
  2046 
  2047 lemma lim_1_over_ln: "((\<lambda>n. 1 / ln(real_of_nat n)) \<longlongrightarrow> 0) sequentially"
  2048   using lim_1_over_Ln [THEN filterlim_sequentially_Suc [THEN iffD2]]
  2049   apply (subst filterlim_sequentially_Suc [symmetric])
  2050   apply (simp add: lim_sequentially dist_norm)
  2051   apply (simp add: Ln_Reals_eq norm_powr_real_powr norm_divide)
  2052   done
  2053 
  2054 lemma lim_ln1_over_ln: "(\<lambda>n. ln(Suc n) / ln n) \<longlonglongrightarrow> 1"
  2055 proof (rule Lim_transform_eventually)
  2056   have "(\<lambda>n. ln(1 + 1/n) / ln n) \<longlonglongrightarrow> 0"
  2057   proof (rule Lim_transform_bound)
  2058     show "(inverse o real) \<longlonglongrightarrow> 0"
  2059       by (metis comp_def seq_harmonic tendsto_explicit)
  2060     show "\<forall>\<^sub>F n in sequentially. norm (ln (1 + 1 / n) / ln n) \<le> norm ((inverse \<circ> real) n)"
  2061     proof
  2062       fix n::nat
  2063       assume n: "3 \<le> n"
  2064       then have "ln 3 \<le> ln n" and ln0: "0 \<le> ln n"
  2065         by auto
  2066       with ln3_gt_1 have "1/ ln n \<le> 1"
  2067         by (simp add: divide_simps)
  2068       moreover have "ln (1 + 1 / real n) \<le> 1/n"
  2069         by (simp add: ln_add_one_self_le_self)
  2070       ultimately have "ln (1 + 1 / real n) * (1 / ln n) \<le> (1/n) * 1"
  2071         by (intro mult_mono) (use n in auto)
  2072       then show "norm (ln (1 + 1 / n) / ln n) \<le> norm ((inverse \<circ> real) n)"
  2073         by (simp add: field_simps ln0)
  2074       qed
  2075   qed
  2076   then show "(\<lambda>n. 1 + ln(1 + 1/n) / ln n) \<longlonglongrightarrow> 1"
  2077     by (metis (full_types) add.right_neutral tendsto_add_const_iff)
  2078   show "\<forall>\<^sub>F k in sequentially. 1 + ln (1 + 1 / k) / ln k = ln(Suc k) / ln k"
  2079     by (simp add: divide_simps ln_div eventually_sequentiallyI [of 2])
  2080 qed
  2081 
  2082 lemma lim_ln_over_ln1: "(\<lambda>n. ln n / ln(Suc n)) \<longlonglongrightarrow> 1"
  2083 proof -
  2084   have "(\<lambda>n. inverse (ln(Suc n) / ln n)) \<longlonglongrightarrow> inverse 1"
  2085     by (rule tendsto_inverse [OF lim_ln1_over_ln]) auto
  2086   then show ?thesis
  2087     by simp
  2088 qed
  2089 
  2090 
  2091 subsection\<open>Relation between Square Root and exp/ln, hence its derivative\<close>
  2092 
  2093 lemma csqrt_exp_Ln:
  2094   assumes "z \<noteq> 0"
  2095     shows "csqrt z = exp(Ln(z) / 2)"
  2096 proof -
  2097   have "(exp (Ln z / 2))\<^sup>2 = (exp (Ln z))"
  2098     by (metis exp_double nonzero_mult_div_cancel_left times_divide_eq_right zero_neq_numeral)
  2099   also have "... = z"
  2100     using assms exp_Ln by blast
  2101   finally have "csqrt z = csqrt ((exp (Ln z / 2))\<^sup>2)"
  2102     by simp
  2103   also have "... = exp (Ln z / 2)"
  2104     apply (subst csqrt_square)
  2105     using cos_gt_zero_pi [of "(Im (Ln z) / 2)"] Im_Ln_le_pi mpi_less_Im_Ln assms
  2106     apply (auto simp: Re_exp Im_exp zero_less_mult_iff zero_le_mult_iff, fastforce+)
  2107     done
  2108   finally show ?thesis using assms csqrt_square
  2109     by simp
  2110 qed
  2111 
  2112 lemma csqrt_inverse:
  2113   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2114     shows "csqrt (inverse z) = inverse (csqrt z)"
  2115 proof (cases "z=0", simp)
  2116   assume "z \<noteq> 0"
  2117   then show ?thesis
  2118     using assms csqrt_exp_Ln Ln_inverse exp_minus
  2119     by (simp add: csqrt_exp_Ln Ln_inverse exp_minus)
  2120 qed
  2121 
  2122 lemma cnj_csqrt:
  2123   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2124     shows "cnj(csqrt z) = csqrt(cnj z)"
  2125 proof (cases "z=0", simp)
  2126   assume "z \<noteq> 0"
  2127   then show ?thesis
  2128      by (simp add: assms cnj_Ln csqrt_exp_Ln exp_cnj)
  2129 qed
  2130 
  2131 lemma has_field_derivative_csqrt:
  2132   assumes "z \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2133     shows "(csqrt has_field_derivative inverse(2 * csqrt z)) (at z)"
  2134 proof -
  2135   have z: "z \<noteq> 0"
  2136     using assms by auto
  2137   then have *: "inverse z = inverse (2*z) * 2"
  2138     by (simp add: divide_simps)
  2139   have [simp]: "exp (Ln z / 2) * inverse z = inverse (csqrt z)"
  2140     by (simp add: z field_simps csqrt_exp_Ln [symmetric]) (metis power2_csqrt power2_eq_square)
  2141   have "Im z = 0 \<Longrightarrow> 0 < Re z"
  2142     using assms complex_nonpos_Reals_iff not_less by blast
  2143   with z have "((\<lambda>z. exp (Ln z / 2)) has_field_derivative inverse (2 * csqrt z)) (at z)"
  2144     by (force intro: derivative_eq_intros * simp add: assms)
  2145   then show ?thesis
  2146     apply (rule DERIV_transform_at[where d = "norm z"])
  2147     apply (intro z derivative_eq_intros | simp add: assms)+
  2148     using z
  2149     apply (metis csqrt_exp_Ln dist_0_norm less_irrefl)
  2150     done
  2151 qed
  2152 
  2153 lemma field_differentiable_at_csqrt:
  2154     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> csqrt field_differentiable at z"
  2155   using field_differentiable_def has_field_derivative_csqrt by blast
  2156 
  2157 lemma field_differentiable_within_csqrt:
  2158     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> csqrt field_differentiable (at z within s)"
  2159   using field_differentiable_at_csqrt field_differentiable_within_subset by blast
  2160 
  2161 lemma continuous_at_csqrt:
  2162     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z) csqrt"
  2163   by (simp add: field_differentiable_within_csqrt field_differentiable_imp_continuous_at)
  2164 
  2165 corollary isCont_csqrt' [simp]:
  2166    "\<lbrakk>isCont f z; f z \<notin> \<real>\<^sub>\<le>\<^sub>0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. csqrt (f x)) z"
  2167   by (blast intro: isCont_o2 [OF _ continuous_at_csqrt])
  2168 
  2169 lemma continuous_within_csqrt:
  2170     "z \<notin> \<real>\<^sub>\<le>\<^sub>0 \<Longrightarrow> continuous (at z within s) csqrt"
  2171   by (simp add: field_differentiable_imp_continuous_at field_differentiable_within_csqrt)
  2172 
  2173 lemma continuous_on_csqrt [continuous_intros]:
  2174     "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> continuous_on s csqrt"
  2175   by (simp add: continuous_at_imp_continuous_on continuous_within_csqrt)
  2176 
  2177 lemma holomorphic_on_csqrt:
  2178     "(\<And>z. z \<in> s \<Longrightarrow> z \<notin> \<real>\<^sub>\<le>\<^sub>0) \<Longrightarrow> csqrt holomorphic_on s"
  2179   by (simp add: field_differentiable_within_csqrt holomorphic_on_def)
  2180 
  2181 lemma continuous_within_closed_nontrivial:
  2182     "closed s \<Longrightarrow> a \<notin> s ==> continuous (at a within s) f"
  2183   using open_Compl
  2184   by (force simp add: continuous_def eventually_at_topological filterlim_iff open_Collect_neg)
  2185 
  2186 lemma continuous_within_csqrt_posreal:
  2187     "continuous (at z within (\<real> \<inter> {w. 0 \<le> Re(w)})) csqrt"
  2188 proof (cases "z \<in> \<real>\<^sub>\<le>\<^sub>0")
  2189   case True
  2190   then have "Im z = 0" "Re z < 0 \<or> z = 0"
  2191     using cnj.code complex_cnj_zero_iff  by (auto simp: Complex_eq complex_nonpos_Reals_iff) fastforce
  2192   then show ?thesis
  2193     apply (auto simp: continuous_within_closed_nontrivial [OF closed_Real_halfspace_Re_ge])
  2194     apply (auto simp: continuous_within_eps_delta norm_conv_dist [symmetric])
  2195     apply (rule_tac x="e^2" in exI)
  2196     apply (auto simp: Reals_def)
  2197     by (metis linear not_less real_sqrt_less_iff real_sqrt_pow2_iff real_sqrt_power)
  2198 next
  2199   case False
  2200     then show ?thesis   by (blast intro: continuous_within_csqrt)
  2201 qed
  2202 
  2203 subsection\<open>Complex arctangent\<close>
  2204 
  2205 text\<open>The branch cut gives standard bounds in the real case.\<close>
  2206 
  2207 definition Arctan :: "complex \<Rightarrow> complex" where
  2208     "Arctan \<equiv> \<lambda>z. (\<i>/2) * Ln((1 - \<i>*z) / (1 + \<i>*z))"
  2209 
  2210 lemma Arctan_def_moebius: "Arctan z = \<i>/2 * Ln (moebius (-\<i>) 1 \<i> 1 z)"
  2211   by (simp add: Arctan_def moebius_def add_ac)
  2212 
  2213 lemma Ln_conv_Arctan:
  2214   assumes "z \<noteq> -1"
  2215   shows   "Ln z = -2*\<i> * Arctan (moebius 1 (- 1) (- \<i>) (- \<i>) z)"
  2216 proof -
  2217   have "Arctan (moebius 1 (- 1) (- \<i>) (- \<i>) z) =
  2218              \<i>/2 * Ln (moebius (- \<i>) 1 \<i> 1 (moebius 1 (- 1) (- \<i>) (- \<i>) z))"
  2219     by (simp add: Arctan_def_moebius)
  2220   also from assms have "\<i> * z \<noteq> \<i> * (-1)" by (subst mult_left_cancel) simp
  2221   hence "\<i> * z - -\<i> \<noteq> 0" by (simp add: eq_neg_iff_add_eq_0)
  2222   from moebius_inverse'[OF _ this, of 1 1]
  2223     have "moebius (- \<i>) 1 \<i> 1 (moebius 1 (- 1) (- \<i>) (- \<i>) z) = z" by simp
  2224   finally show ?thesis by (simp add: field_simps)
  2225 qed
  2226 
  2227 lemma Arctan_0 [simp]: "Arctan 0 = 0"
  2228   by (simp add: Arctan_def)
  2229 
  2230 lemma Im_complex_div_lemma: "Im((1 - \<i>*z) / (1 + \<i>*z)) = 0 \<longleftrightarrow> Re z = 0"
  2231   by (auto simp: Im_complex_div_eq_0 algebra_simps)
  2232 
  2233 lemma Re_complex_div_lemma: "0 < Re((1 - \<i>*z) / (1 + \<i>*z)) \<longleftrightarrow> norm z < 1"
  2234   by (simp add: Re_complex_div_gt_0 algebra_simps cmod_def power2_eq_square)
  2235 
  2236 lemma tan_Arctan:
  2237   assumes "z\<^sup>2 \<noteq> -1"
  2238     shows [simp]:"tan(Arctan z) = z"
  2239 proof -
  2240   have "1 + \<i>*z \<noteq> 0"
  2241     by (metis assms complex_i_mult_minus i_squared minus_unique power2_eq_square power2_minus)
  2242   moreover
  2243   have "1 - \<i>*z \<noteq> 0"
  2244     by (metis assms complex_i_mult_minus i_squared power2_eq_square power2_minus right_minus_eq)
  2245   ultimately
  2246   show ?thesis
  2247     by (simp add: Arctan_def tan_def sin_exp_eq cos_exp_eq exp_minus csqrt_exp_Ln [symmetric]
  2248                   divide_simps power2_eq_square [symmetric])
  2249 qed
  2250 
  2251 lemma Arctan_tan [simp]:
  2252   assumes "\<bar>Re z\<bar> < pi/2"
  2253     shows "Arctan(tan z) = z"
  2254 proof -
  2255   have ge_pi2: "\<And>n::int. \<bar>of_int (2*n + 1) * pi/2\<bar> \<ge> pi/2"
  2256     by (case_tac n rule: int_cases) (auto simp: abs_mult)
  2257   have "exp (\<i>*z)*exp (\<i>*z) = -1 \<longleftrightarrow> exp (2*\<i>*z) = -1"
  2258     by (metis distrib_right exp_add mult_2)
  2259   also have "... \<longleftrightarrow> exp (2*\<i>*z) = exp (\<i>*pi)"
  2260     using cis_conv_exp cis_pi by auto
  2261   also have "... \<longleftrightarrow> exp (2*\<i>*z - \<i>*pi) = 1"
  2262     by (metis (no_types) diff_add_cancel diff_minus_eq_add exp_add exp_minus_inverse mult.commute)
  2263   also have "... \<longleftrightarrow> Re(\<i>*2*z - \<i>*pi) = 0 \<and> (\<exists>n::int. Im(\<i>*2*z - \<i>*pi) = of_int (2 * n) * pi)"
  2264     by (simp add: exp_eq_1)
  2265   also have "... \<longleftrightarrow> Im z = 0 \<and> (\<exists>n::int. 2 * Re z = of_int (2*n + 1) * pi)"
  2266     by (simp add: algebra_simps)
  2267   also have "... \<longleftrightarrow> False"
  2268     using assms ge_pi2
  2269     apply (auto simp: algebra_simps)
  2270     by (metis abs_mult_pos not_less of_nat_less_0_iff of_nat_numeral)
  2271   finally have *: "exp (\<i>*z)*exp (\<i>*z) + 1 \<noteq> 0"
  2272     by (auto simp: add.commute minus_unique)
  2273   show ?thesis
  2274     using assms *
  2275     apply (simp add: Arctan_def tan_def sin_exp_eq cos_exp_eq exp_minus divide_simps
  2276                      i_times_eq_iff power2_eq_square [symmetric])
  2277     apply (rule Ln_unique)
  2278     apply (auto simp: divide_simps exp_minus)
  2279     apply (simp add: algebra_simps exp_double [symmetric])
  2280     done
  2281 qed
  2282 
  2283 lemma
  2284   assumes "Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1"
  2285   shows Re_Arctan_bounds: "\<bar>Re(Arctan z)\<bar> < pi/2"
  2286     and has_field_derivative_Arctan: "(Arctan has_field_derivative inverse(1 + z\<^sup>2)) (at z)"
  2287 proof -
  2288   have nz0: "1 + \<i>*z \<noteq> 0"
  2289     using assms
  2290     by (metis abs_one complex_i_mult_minus diff_0_right diff_minus_eq_add imaginary_unit.simps
  2291               less_irrefl minus_diff_eq mult.right_neutral right_minus_eq)
  2292   have "z \<noteq> -\<i>" using assms
  2293     by auto
  2294   then have zz: "1 + z * z \<noteq> 0"
  2295     by (metis abs_one assms i_squared imaginary_unit.simps less_irrefl minus_unique square_eq_iff)
  2296   have nz1: "1 - \<i>*z \<noteq> 0"
  2297     using assms by (force simp add: i_times_eq_iff)
  2298   have nz2: "inverse (1 + \<i>*z) \<noteq> 0"
  2299     using assms
  2300     by (metis Im_complex_div_lemma Re_complex_div_lemma cmod_eq_Im divide_complex_def
  2301               less_irrefl mult_zero_right zero_complex.simps(1) zero_complex.simps(2))
  2302   have nzi: "((1 - \<i>*z) * inverse (1 + \<i>*z)) \<noteq> 0"
  2303     using nz1 nz2 by auto
  2304   have "Im ((1 - \<i>*z) / (1 + \<i>*z)) = 0 \<Longrightarrow> 0 < Re ((1 - \<i>*z) / (1 + \<i>*z))"
  2305     apply (simp add: divide_complex_def)
  2306     apply (simp add: divide_simps split: if_split_asm)
  2307     using assms
  2308     apply (auto simp: algebra_simps abs_square_less_1 [unfolded power2_eq_square])
  2309     done
  2310   then have *: "((1 - \<i>*z) / (1 + \<i>*z)) \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2311     by (auto simp add: complex_nonpos_Reals_iff)
  2312   show "\<bar>Re(Arctan z)\<bar> < pi/2"
  2313     unfolding Arctan_def divide_complex_def
  2314     using mpi_less_Im_Ln [OF nzi]
  2315     apply (auto simp: abs_if intro!: Im_Ln_less_pi * [unfolded divide_complex_def])
  2316     done
  2317   show "(Arctan has_field_derivative inverse(1 + z\<^sup>2)) (at z)"
  2318     unfolding Arctan_def scaleR_conv_of_real
  2319     apply (rule DERIV_cong)
  2320     apply (intro derivative_eq_intros | simp add: nz0 *)+
  2321     using nz0 nz1 zz
  2322     apply (simp add: divide_simps power2_eq_square)
  2323     apply (auto simp: algebra_simps)
  2324     done
  2325 qed
  2326 
  2327 lemma field_differentiable_at_Arctan: "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> Arctan field_differentiable at z"
  2328   using has_field_derivative_Arctan
  2329   by (auto simp: field_differentiable_def)
  2330 
  2331 lemma field_differentiable_within_Arctan:
  2332     "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> Arctan field_differentiable (at z within s)"
  2333   using field_differentiable_at_Arctan field_differentiable_at_within by blast
  2334 
  2335 declare has_field_derivative_Arctan [derivative_intros]
  2336 declare has_field_derivative_Arctan [THEN DERIV_chain2, derivative_intros]
  2337 
  2338 lemma continuous_at_Arctan:
  2339     "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> continuous (at z) Arctan"
  2340   by (simp add: field_differentiable_imp_continuous_at field_differentiable_within_Arctan)
  2341 
  2342 lemma continuous_within_Arctan:
  2343     "(Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> continuous (at z within s) Arctan"
  2344   using continuous_at_Arctan continuous_at_imp_continuous_within by blast
  2345 
  2346 lemma continuous_on_Arctan [continuous_intros]:
  2347     "(\<And>z. z \<in> s \<Longrightarrow> Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> continuous_on s Arctan"
  2348   by (auto simp: continuous_at_imp_continuous_on continuous_within_Arctan)
  2349 
  2350 lemma holomorphic_on_Arctan:
  2351     "(\<And>z. z \<in> s \<Longrightarrow> Re z = 0 \<Longrightarrow> \<bar>Im z\<bar> < 1) \<Longrightarrow> Arctan holomorphic_on s"
  2352   by (simp add: field_differentiable_within_Arctan holomorphic_on_def)
  2353 
  2354 lemma Arctan_series:
  2355   assumes z: "norm (z :: complex) < 1"
  2356   defines "g \<equiv> \<lambda>n. if odd n then -\<i>*\<i>^n / n else 0"
  2357   defines "h \<equiv> \<lambda>z n. (-1)^n / of_nat (2*n+1) * (z::complex)^(2*n+1)"
  2358   shows   "(\<lambda>n. g n * z^n) sums Arctan z"
  2359   and     "h z sums Arctan z"
  2360 proof -
  2361   define G where [abs_def]: "G z = (\<Sum>n. g n * z^n)" for z
  2362   have summable: "summable (\<lambda>n. g n * u^n)" if "norm u < 1" for u
  2363   proof (cases "u = 0")
  2364     assume u: "u \<noteq> 0"
  2365     have "(\<lambda>n. ereal (norm (h u n) / norm (h u (Suc n)))) = (\<lambda>n. ereal (inverse (norm u)^2) *
  2366               ereal ((2 + inverse (real (Suc n))) / (2 - inverse (real (Suc n)))))"
  2367     proof
  2368       fix n
  2369       have "ereal (norm (h u n) / norm (h u (Suc n))) =
  2370              ereal (inverse (norm u)^2) * ereal ((of_nat (2*Suc n+1) / of_nat (Suc n)) /
  2371                  (of_nat (2*Suc n-1) / of_nat (Suc n)))"
  2372       by (simp add: h_def norm_mult norm_power norm_divide divide_simps
  2373                     power2_eq_square eval_nat_numeral del: of_nat_add of_nat_Suc)
  2374       also have "of_nat (2*Suc n+1) / of_nat (Suc n) = (2::real) + inverse (real (Suc n))"
  2375         by (auto simp: divide_simps simp del: of_nat_Suc) simp_all?
  2376       also have "of_nat (2*Suc n-1) / of_nat (Suc n) = (2::real) - inverse (real (Suc n))"
  2377         by (auto simp: divide_simps simp del: of_nat_Suc) simp_all?
  2378       finally show "ereal (norm (h u n) / norm (h u (Suc n))) = ereal (inverse (norm u)^2) *
  2379               ereal ((2 + inverse (real (Suc n))) / (2 - inverse (real (Suc n))))" .
  2380     qed
  2381     also have "\<dots> \<longlonglongrightarrow> ereal (inverse (norm u)^2) * ereal ((2 + 0) / (2 - 0))"
  2382       by (intro tendsto_intros LIMSEQ_inverse_real_of_nat) simp_all
  2383     finally have "liminf (\<lambda>n. ereal (cmod (h u n) / cmod (h u (Suc n)))) = inverse (norm u)^2"
  2384       by (intro lim_imp_Liminf) simp_all
  2385     moreover from power_strict_mono[OF that, of 2] u have "inverse (norm u)^2 > 1"
  2386       by (simp add: divide_simps)
  2387     ultimately have A: "liminf (\<lambda>n. ereal (cmod (h u n) / cmod (h u (Suc n)))) > 1" by simp
  2388     from u have "summable (h u)"
  2389       by (intro summable_norm_cancel[OF ratio_test_convergence[OF _ A]])
  2390          (auto simp: h_def norm_divide norm_mult norm_power simp del: of_nat_Suc
  2391                intro!: mult_pos_pos divide_pos_pos always_eventually)
  2392     thus "summable (\<lambda>n. g n * u^n)"
  2393       by (subst summable_mono_reindex[of "\<lambda>n. 2*n+1", symmetric])
  2394          (auto simp: power_mult subseq_def g_def h_def elim!: oddE)
  2395   qed (simp add: h_def)
  2396 
  2397   have "\<exists>c. \<forall>u\<in>ball 0 1. Arctan u - G u = c"
  2398   proof (rule has_field_derivative_zero_constant)
  2399     fix u :: complex assume "u \<in> ball 0 1"
  2400     hence u: "norm u < 1" by (simp add: dist_0_norm)
  2401     define K where "K = (norm u + 1) / 2"
  2402     from u and abs_Im_le_cmod[of u] have Im_u: "\<bar>Im u\<bar> < 1" by linarith
  2403     from u have K: "0 \<le> K" "norm u < K" "K < 1" by (simp_all add: K_def)
  2404     hence "(G has_field_derivative (\<Sum>n. diffs g n * u ^ n)) (at u)" unfolding G_def
  2405       by (intro termdiffs_strong[of _ "of_real K"] summable) simp_all
  2406     also have "(\<lambda>n. diffs g n * u^n) = (\<lambda>n. if even n then (\<i>*u)^n else 0)"
  2407       by (intro ext) (simp_all del: of_nat_Suc add: g_def diffs_def power_mult_distrib)
  2408     also have "suminf \<dots> = (\<Sum>n. (-(u^2))^n)"
  2409       by (subst suminf_mono_reindex[of "\<lambda>n. 2*n", symmetric])
  2410          (auto elim!: evenE simp: subseq_def power_mult power_mult_distrib)
  2411     also from u have "norm u^2 < 1^2" by (intro power_strict_mono) simp_all
  2412     hence "(\<Sum>n. (-(u^2))^n) = inverse (1 + u^2)"
  2413       by (subst suminf_geometric) (simp_all add: norm_power inverse_eq_divide)
  2414     finally have "(G has_field_derivative inverse (1 + u\<^sup>2)) (at u)" .
  2415     from DERIV_diff[OF has_field_derivative_Arctan this] Im_u u
  2416       show "((\<lambda>u. Arctan u - G u) has_field_derivative 0) (at u within ball 0 1)"
  2417       by (simp_all add: dist_0_norm at_within_open[OF _ open_ball])
  2418   qed simp_all
  2419   then obtain c where c: "\<And>u. norm u < 1 \<Longrightarrow> Arctan u - G u = c" by (auto simp: dist_0_norm)
  2420   from this[of 0] have "c = 0" by (simp add: G_def g_def powser_zero)
  2421   with c z have "Arctan z = G z" by simp
  2422   with summable[OF z] show "(\<lambda>n. g n * z^n) sums Arctan z" unfolding G_def by (simp add: sums_iff)
  2423   thus "h z sums Arctan z" by (subst (asm) sums_mono_reindex[of "\<lambda>n. 2*n+1", symmetric])
  2424                               (auto elim!: oddE simp: subseq_def power_mult g_def h_def)
  2425 qed
  2426 
  2427 text \<open>A quickly-converging series for the logarithm, based on the arctangent.\<close>
  2428 lemma ln_series_quadratic:
  2429   assumes x: "x > (0::real)"
  2430   shows "(\<lambda>n. (2*((x - 1) / (x + 1)) ^ (2*n+1) / of_nat (2*n+1))) sums ln x"
  2431 proof -
  2432   define y :: complex where "y = of_real ((x-1)/(x+1))"
  2433   from x have x': "complex_of_real x \<noteq> of_real (-1)"  by (subst of_real_eq_iff) auto
  2434   from x have "\<bar>x - 1\<bar> < \<bar>x + 1\<bar>" by linarith
  2435   hence "norm (complex_of_real (x - 1) / complex_of_real (x + 1)) < 1"
  2436     by (simp add: norm_divide del: of_real_add of_real_diff)
  2437   hence "norm (\<i> * y) < 1" unfolding y_def by (subst norm_mult) simp
  2438   hence "(\<lambda>n. (-2*\<i>) * ((-1)^n / of_nat (2*n+1) * (\<i>*y)^(2*n+1))) sums ((-2*\<i>) * Arctan (\<i>*y))"
  2439     by (intro Arctan_series sums_mult) simp_all
  2440   also have "(\<lambda>n. (-2*\<i>) * ((-1)^n / of_nat (2*n+1) * (\<i>*y)^(2*n+1))) =
  2441                  (\<lambda>n. (-2*\<i>) * ((-1)^n * (\<i>*y*(-y\<^sup>2)^n)/of_nat (2*n+1)))"
  2442     by (intro ext) (simp_all add: power_mult power_mult_distrib)
  2443   also have "\<dots> = (\<lambda>n. 2*y* ((-1) * (-y\<^sup>2))^n/of_nat (2*n+1))"
  2444     by (intro ext, subst power_mult_distrib) (simp add: algebra_simps power_mult)
  2445   also have "\<dots> = (\<lambda>n. 2*y^(2*n+1) / of_nat (2*n+1))"
  2446     by (subst power_add, subst power_mult) (simp add: mult_ac)
  2447   also have "\<dots> = (\<lambda>n. of_real (2*((x-1)/(x+1))^(2*n+1) / of_nat (2*n+1)))"
  2448     by (intro ext) (simp add: y_def)
  2449   also have "\<i> * y = (of_real x - 1) / (-\<i> * (of_real x + 1))"
  2450     by (subst divide_divide_eq_left [symmetric]) (simp add: y_def)
  2451   also have "\<dots> = moebius 1 (-1) (-\<i>) (-\<i>) (of_real x)" by (simp add: moebius_def algebra_simps)
  2452   also from x' have "-2*\<i>*Arctan \<dots> = Ln (of_real x)" by (intro Ln_conv_Arctan [symmetric]) simp_all
  2453   also from x have "\<dots> = ln x" by (rule Ln_of_real)
  2454   finally show ?thesis by (subst (asm) sums_of_real_iff)
  2455 qed
  2456 
  2457 subsection \<open>Real arctangent\<close>
  2458 
  2459 lemma norm_exp_i_times [simp]: "norm (exp(\<i> * of_real y)) = 1"
  2460   by simp
  2461 
  2462 lemma norm_exp_imaginary: "norm(exp z) = 1 \<Longrightarrow> Re z = 0"
  2463   by simp
  2464 
  2465 lemma Im_Arctan_of_real [simp]: "Im (Arctan (of_real x)) = 0"
  2466   unfolding Arctan_def divide_complex_def
  2467   apply (simp add: complex_eq_iff)
  2468   apply (rule norm_exp_imaginary)
  2469   apply (subst exp_Ln, auto)
  2470   apply (simp_all add: cmod_def complex_eq_iff)
  2471   apply (auto simp: divide_simps)
  2472   apply (metis power_one sum_power2_eq_zero_iff zero_neq_one, algebra)
  2473   done
  2474 
  2475 lemma arctan_eq_Re_Arctan: "arctan x = Re (Arctan (of_real x))"
  2476 proof (rule arctan_unique)
  2477   show "- (pi / 2) < Re (Arctan (complex_of_real x))"
  2478     apply (simp add: Arctan_def)
  2479     apply (rule Im_Ln_less_pi)
  2480     apply (auto simp: Im_complex_div_lemma complex_nonpos_Reals_iff)
  2481     done
  2482 next
  2483   have *: " (1 - \<i>*x) / (1 + \<i>*x) \<noteq> 0"
  2484     by (simp add: divide_simps) ( simp add: complex_eq_iff)
  2485   show "Re (Arctan (complex_of_real x)) < pi / 2"
  2486     using mpi_less_Im_Ln [OF *]
  2487     by (simp add: Arctan_def)
  2488 next
  2489   have "tan (Re (Arctan (of_real x))) = Re (tan (Arctan (of_real x)))"
  2490     apply (auto simp: tan_def Complex.Re_divide Re_sin Re_cos Im_sin Im_cos)
  2491     apply (simp add: field_simps)
  2492     by (simp add: power2_eq_square)
  2493   also have "... = x"
  2494     apply (subst tan_Arctan, auto)
  2495     by (metis diff_0_right minus_diff_eq mult_zero_left not_le of_real_1 of_real_eq_iff of_real_minus of_real_power power2_eq_square real_minus_mult_self_le zero_less_one)
  2496   finally show "tan (Re (Arctan (complex_of_real x))) = x" .
  2497 qed
  2498 
  2499 lemma Arctan_of_real: "Arctan (of_real x) = of_real (arctan x)"
  2500   unfolding arctan_eq_Re_Arctan divide_complex_def
  2501   by (simp add: complex_eq_iff)
  2502 
  2503 lemma Arctan_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> Arctan z \<in> \<real>"
  2504   by (metis Reals_cases Reals_of_real Arctan_of_real)
  2505 
  2506 declare arctan_one [simp]
  2507 
  2508 lemma arctan_less_pi4_pos: "x < 1 \<Longrightarrow> arctan x < pi/4"
  2509   by (metis arctan_less_iff arctan_one)
  2510 
  2511 lemma arctan_less_pi4_neg: "-1 < x \<Longrightarrow> -(pi/4) < arctan x"
  2512   by (metis arctan_less_iff arctan_minus arctan_one)
  2513 
  2514 lemma arctan_less_pi4: "\<bar>x\<bar> < 1 \<Longrightarrow> \<bar>arctan x\<bar> < pi/4"
  2515   by (metis abs_less_iff arctan_less_pi4_pos arctan_minus)
  2516 
  2517 lemma arctan_le_pi4: "\<bar>x\<bar> \<le> 1 \<Longrightarrow> \<bar>arctan x\<bar> \<le> pi/4"
  2518   by (metis abs_le_iff arctan_le_iff arctan_minus arctan_one)
  2519 
  2520 lemma abs_arctan: "\<bar>arctan x\<bar> = arctan \<bar>x\<bar>"
  2521   by (simp add: abs_if arctan_minus)
  2522 
  2523 lemma arctan_add_raw:
  2524   assumes "\<bar>arctan x + arctan y\<bar> < pi/2"
  2525     shows "arctan x + arctan y = arctan((x + y) / (1 - x * y))"
  2526 proof (rule arctan_unique [symmetric])
  2527   show 12: "- (pi / 2) < arctan x + arctan y" "arctan x + arctan y < pi / 2"
  2528     using assms by linarith+
  2529   show "tan (arctan x + arctan y) = (x + y) / (1 - x * y)"
  2530     using cos_gt_zero_pi [OF 12]
  2531     by (simp add: arctan tan_add)
  2532 qed
  2533 
  2534 lemma arctan_inverse:
  2535   assumes "0 < x"
  2536     shows "arctan(inverse x) = pi/2 - arctan x"
  2537 proof -
  2538   have "arctan(inverse x) = arctan(inverse(tan(arctan x)))"
  2539     by (simp add: arctan)
  2540   also have "... = arctan (tan (pi / 2 - arctan x))"
  2541     by (simp add: tan_cot)
  2542   also have "... = pi/2 - arctan x"
  2543   proof -
  2544     have "0 < pi - arctan x"
  2545     using arctan_ubound [of x] pi_gt_zero by linarith
  2546     with assms show ?thesis
  2547       by (simp add: Transcendental.arctan_tan)
  2548   qed
  2549   finally show ?thesis .
  2550 qed
  2551 
  2552 lemma arctan_add_small:
  2553   assumes "\<bar>x * y\<bar> < 1"
  2554     shows "(arctan x + arctan y = arctan((x + y) / (1 - x * y)))"
  2555 proof (cases "x = 0 \<or> y = 0")
  2556   case True then show ?thesis
  2557     by auto
  2558 next
  2559   case False
  2560   then have *: "\<bar>arctan x\<bar> < pi / 2 - \<bar>arctan y\<bar>" using assms
  2561     apply (auto simp add: abs_arctan arctan_inverse [symmetric] arctan_less_iff)
  2562     apply (simp add: divide_simps abs_mult)
  2563     done
  2564   show ?thesis
  2565     apply (rule arctan_add_raw)
  2566     using * by linarith
  2567 qed
  2568 
  2569 lemma abs_arctan_le:
  2570   fixes x::real shows "\<bar>arctan x\<bar> \<le> \<bar>x\<bar>"
  2571 proof -
  2572   { fix w::complex and z::complex
  2573     assume *: "w \<in> \<real>" "z \<in> \<real>"
  2574     have "cmod (Arctan w - Arctan z) \<le> 1 * cmod (w-z)"
  2575       apply (rule field_differentiable_bound [OF convex_Reals, of Arctan _ 1])
  2576       apply (rule has_field_derivative_at_within [OF has_field_derivative_Arctan])
  2577       apply (force simp add: Reals_def)
  2578       apply (simp add: norm_divide divide_simps in_Reals_norm complex_is_Real_iff power2_eq_square)
  2579       using * by auto
  2580   }
  2581   then have "cmod (Arctan (of_real x) - Arctan 0) \<le> 1 * cmod (of_real x -0)"
  2582     using Reals_0 Reals_of_real by blast
  2583   then show ?thesis
  2584     by (simp add: Arctan_of_real)
  2585 qed
  2586 
  2587 lemma arctan_le_self: "0 \<le> x \<Longrightarrow> arctan x \<le> x"
  2588   by (metis abs_arctan_le abs_of_nonneg zero_le_arctan_iff)
  2589 
  2590 lemma abs_tan_ge: "\<bar>x\<bar> < pi/2 \<Longrightarrow> \<bar>x\<bar> \<le> \<bar>tan x\<bar>"
  2591   by (metis abs_arctan_le abs_less_iff arctan_tan minus_less_iff)
  2592 
  2593 lemma arctan_bounds:
  2594   assumes "0 \<le> x" "x < 1"
  2595   shows arctan_lower_bound:
  2596     "(\<Sum>k<2 * n. (- 1) ^ k * (1 / real (k * 2 + 1) * x ^ (k * 2 + 1))) \<le> arctan x"
  2597     (is "(\<Sum>k<_. (- 1)^ k * ?a k) \<le> _")
  2598     and arctan_upper_bound:
  2599     "arctan x \<le> (\<Sum>k<2 * n + 1. (- 1) ^ k * (1 / real (k * 2 + 1) * x ^ (k * 2 + 1)))"
  2600 proof -
  2601   have tendsto_zero: "?a \<longlonglongrightarrow> 0"
  2602     using assms
  2603     apply -
  2604     apply (rule tendsto_eq_rhs[where x="0 * 0"])
  2605     subgoal by (intro tendsto_mult real_tendsto_divide_at_top)
  2606         (auto simp: filterlim_real_sequentially filterlim_sequentially_iff_filterlim_real
  2607           intro!: real_tendsto_divide_at_top tendsto_power_zero filterlim_real_sequentially
  2608            tendsto_eq_intros filterlim_at_top_mult_tendsto_pos filterlim_tendsto_add_at_top)
  2609     subgoal by simp
  2610     done
  2611   have nonneg: "0 \<le> ?a n" for n
  2612     by (force intro!: divide_nonneg_nonneg mult_nonneg_nonneg zero_le_power assms)
  2613   have le: "?a (Suc n) \<le> ?a n" for n
  2614     by (rule mult_mono[OF _ power_decreasing]) (auto simp: divide_simps assms less_imp_le)
  2615   from summable_Leibniz'(4)[of ?a, OF tendsto_zero nonneg le, of n]
  2616     summable_Leibniz'(2)[of ?a, OF tendsto_zero nonneg le, of n]
  2617     assms
  2618   show "(\<Sum>k<2*n. (- 1)^ k * ?a k) \<le> arctan x" "arctan x \<le> (\<Sum>k<2 * n + 1. (- 1)^ k * ?a k)"
  2619     by (auto simp: arctan_series)
  2620 qed
  2621 
  2622 subsection \<open>Bounds on pi using real arctangent\<close>
  2623 
  2624 lemma pi_machin: "pi = 16 * arctan (1 / 5) - 4 * arctan (1 / 239)"
  2625   using machin
  2626   by simp
  2627 
  2628 lemma pi_approx: "3.141592653588 \<le> pi" "pi \<le> 3.1415926535899"
  2629   unfolding pi_machin
  2630   using arctan_bounds[of "1/5"   4]
  2631         arctan_bounds[of "1/239" 4]
  2632   by (simp_all add: eval_nat_numeral)
  2633     
  2634 corollary pi_gt3: "pi > 3"
  2635   using pi_approx by simp
  2636 
  2637 
  2638 subsection\<open>Inverse Sine\<close>
  2639 
  2640 definition Arcsin :: "complex \<Rightarrow> complex" where
  2641    "Arcsin \<equiv> \<lambda>z. -\<i> * Ln(\<i> * z + csqrt(1 - z\<^sup>2))"
  2642 
  2643 lemma Arcsin_body_lemma: "\<i> * z + csqrt(1 - z\<^sup>2) \<noteq> 0"
  2644   using power2_csqrt [of "1 - z\<^sup>2"]
  2645   apply auto
  2646   by (metis complex_i_mult_minus diff_add_cancel diff_minus_eq_add diff_self mult.assoc mult.left_commute numeral_One power2_csqrt power2_eq_square zero_neq_numeral)
  2647 
  2648 lemma Arcsin_range_lemma: "\<bar>Re z\<bar> < 1 \<Longrightarrow> 0 < Re(\<i> * z + csqrt(1 - z\<^sup>2))"
  2649   using Complex.cmod_power2 [of z, symmetric]
  2650   by (simp add: real_less_rsqrt algebra_simps Re_power2 cmod_square_less_1_plus)
  2651 
  2652 lemma Re_Arcsin: "Re(Arcsin z) = Im (Ln (\<i> * z + csqrt(1 - z\<^sup>2)))"
  2653   by (simp add: Arcsin_def)
  2654 
  2655 lemma Im_Arcsin: "Im(Arcsin z) = - ln (cmod (\<i> * z + csqrt (1 - z\<^sup>2)))"
  2656   by (simp add: Arcsin_def Arcsin_body_lemma)
  2657 
  2658 lemma one_minus_z2_notin_nonpos_Reals:
  2659   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2660   shows "1 - z\<^sup>2 \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2661     using assms
  2662     apply (auto simp: complex_nonpos_Reals_iff Re_power2 Im_power2)
  2663     using power2_less_0 [of "Im z"] apply force
  2664     using abs_square_less_1 not_le by blast
  2665 
  2666 lemma isCont_Arcsin_lemma:
  2667   assumes le0: "Re (\<i> * z + csqrt (1 - z\<^sup>2)) \<le> 0" and "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2668     shows False
  2669 proof (cases "Im z = 0")
  2670   case True
  2671   then show ?thesis
  2672     using assms by (fastforce simp: cmod_def abs_square_less_1 [symmetric])
  2673 next
  2674   case False
  2675   have neq: "(cmod z)\<^sup>2 \<noteq> 1 + cmod (1 - z\<^sup>2)"
  2676   proof (clarsimp simp add: cmod_def)
  2677     assume "(Re z)\<^sup>2 + (Im z)\<^sup>2 = 1 + sqrt ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2678     then have "((Re z)\<^sup>2 + (Im z)\<^sup>2 - 1)\<^sup>2 = ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2679       by simp
  2680     then show False using False
  2681       by (simp add: power2_eq_square algebra_simps)
  2682   qed
  2683   moreover have 2: "(Im z)\<^sup>2 = (1 + ((Im z)\<^sup>2 + cmod (1 - z\<^sup>2)) - (Re z)\<^sup>2) / 2"
  2684     using le0
  2685     apply simp
  2686     apply (drule sqrt_le_D)
  2687     using cmod_power2 [of z] norm_triangle_ineq2 [of "z^2" 1]
  2688     apply (simp add: norm_power Re_power2 norm_minus_commute [of 1])
  2689     done
  2690   ultimately show False
  2691     by (simp add: Re_power2 Im_power2 cmod_power2)
  2692 qed
  2693 
  2694 lemma isCont_Arcsin:
  2695   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2696     shows "isCont Arcsin z"
  2697 proof -
  2698   have *: "\<i> * z + csqrt (1 - z\<^sup>2) \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2699     by (metis isCont_Arcsin_lemma assms complex_nonpos_Reals_iff)
  2700   show ?thesis
  2701     using assms
  2702     apply (simp add: Arcsin_def)
  2703     apply (rule isCont_Ln' isCont_csqrt' continuous_intros)+
  2704     apply (simp add: one_minus_z2_notin_nonpos_Reals assms)
  2705     apply (rule *)
  2706     done
  2707 qed
  2708 
  2709 lemma isCont_Arcsin' [simp]:
  2710   shows "isCont f z \<Longrightarrow> (Im (f z) = 0 \<Longrightarrow> \<bar>Re (f z)\<bar> < 1) \<Longrightarrow> isCont (\<lambda>x. Arcsin (f x)) z"
  2711   by (blast intro: isCont_o2 [OF _ isCont_Arcsin])
  2712 
  2713 lemma sin_Arcsin [simp]: "sin(Arcsin z) = z"
  2714 proof -
  2715   have "\<i>*z*2 + csqrt (1 - z\<^sup>2)*2 = 0 \<longleftrightarrow> (\<i>*z)*2 + csqrt (1 - z\<^sup>2)*2 = 0"
  2716     by (simp add: algebra_simps)  \<comment>\<open>Cancelling a factor of 2\<close>
  2717   moreover have "... \<longleftrightarrow> (\<i>*z) + csqrt (1 - z\<^sup>2) = 0"
  2718     by (metis Arcsin_body_lemma distrib_right no_zero_divisors zero_neq_numeral)
  2719   ultimately show ?thesis
  2720     apply (simp add: sin_exp_eq Arcsin_def Arcsin_body_lemma exp_minus divide_simps)
  2721     apply (simp add: algebra_simps)
  2722     apply (simp add: power2_eq_square [symmetric] algebra_simps)
  2723     done
  2724 qed
  2725 
  2726 lemma Re_eq_pihalf_lemma:
  2727     "\<bar>Re z\<bar> = pi/2 \<Longrightarrow> Im z = 0 \<Longrightarrow>
  2728       Re ((exp (\<i>*z) + inverse (exp (\<i>*z))) / 2) = 0 \<and> 0 \<le> Im ((exp (\<i>*z) + inverse (exp (\<i>*z))) / 2)"
  2729   apply (simp add: cos_i_times [symmetric] Re_cos Im_cos abs_if del: eq_divide_eq_numeral1)
  2730   by (metis cos_minus cos_pi_half)
  2731 
  2732 lemma Re_less_pihalf_lemma:
  2733   assumes "\<bar>Re z\<bar> < pi / 2"
  2734     shows "0 < Re ((exp (\<i>*z) + inverse (exp (\<i>*z))) / 2)"
  2735 proof -
  2736   have "0 < cos (Re z)" using assms
  2737     using cos_gt_zero_pi by auto
  2738   then show ?thesis
  2739     by (simp add: cos_i_times [symmetric] Re_cos Im_cos add_pos_pos)
  2740 qed
  2741 
  2742 lemma Arcsin_sin:
  2743     assumes "\<bar>Re z\<bar> < pi/2 \<or> (\<bar>Re z\<bar> = pi/2 \<and> Im z = 0)"
  2744       shows "Arcsin(sin z) = z"
  2745 proof -
  2746   have "Arcsin(sin z) = - (\<i> * Ln (csqrt (1 - (\<i> * (exp (\<i>*z) - inverse (exp (\<i>*z))))\<^sup>2 / 4) - (inverse (exp (\<i>*z)) - exp (\<i>*z)) / 2))"
  2747     by (simp add: sin_exp_eq Arcsin_def exp_minus power_divide)
  2748   also have "... = - (\<i> * Ln (csqrt (((exp (\<i>*z) + inverse (exp (\<i>*z)))/2)\<^sup>2) - (inverse (exp (\<i>*z)) - exp (\<i>*z)) / 2))"
  2749     by (simp add: field_simps power2_eq_square)
  2750   also have "... = - (\<i> * Ln (((exp (\<i>*z) + inverse (exp (\<i>*z)))/2) - (inverse (exp (\<i>*z)) - exp (\<i>*z)) / 2))"
  2751     apply (subst csqrt_square)
  2752     using assms Re_eq_pihalf_lemma Re_less_pihalf_lemma
  2753     apply auto
  2754     done
  2755   also have "... =  - (\<i> * Ln (exp (\<i>*z)))"
  2756     by (simp add: field_simps power2_eq_square)
  2757   also have "... = z"
  2758     apply (subst Complex_Transcendental.Ln_exp)
  2759     using assms
  2760     apply (auto simp: abs_if simp del: eq_divide_eq_numeral1 split: if_split_asm)
  2761     done
  2762   finally show ?thesis .
  2763 qed
  2764 
  2765 lemma Arcsin_unique:
  2766     "\<lbrakk>sin z = w; \<bar>Re z\<bar> < pi/2 \<or> (\<bar>Re z\<bar> = pi/2 \<and> Im z = 0)\<rbrakk> \<Longrightarrow> Arcsin w = z"
  2767   by (metis Arcsin_sin)
  2768 
  2769 lemma Arcsin_0 [simp]: "Arcsin 0 = 0"
  2770   by (metis Arcsin_sin norm_zero pi_half_gt_zero real_norm_def sin_zero zero_complex.simps(1))
  2771 
  2772 lemma Arcsin_1 [simp]: "Arcsin 1 = pi/2"
  2773   by (metis Arcsin_sin Im_complex_of_real Re_complex_of_real numeral_One of_real_numeral pi_half_ge_zero real_sqrt_abs real_sqrt_pow2 real_sqrt_power sin_of_real sin_pi_half)
  2774 
  2775 lemma Arcsin_minus_1 [simp]: "Arcsin(-1) = - (pi/2)"
  2776   by (metis Arcsin_1 Arcsin_sin Im_complex_of_real Re_complex_of_real abs_of_nonneg of_real_minus pi_half_ge_zero power2_minus real_sqrt_abs sin_Arcsin sin_minus)
  2777 
  2778 lemma has_field_derivative_Arcsin:
  2779   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2780     shows "(Arcsin has_field_derivative inverse(cos(Arcsin z))) (at z)"
  2781 proof -
  2782   have "(sin (Arcsin z))\<^sup>2 \<noteq> 1"
  2783     using assms
  2784     apply atomize
  2785     apply (auto simp: complex_eq_iff Re_power2 Im_power2 abs_square_eq_1)
  2786     apply (metis abs_minus_cancel abs_one abs_power2 numeral_One numeral_neq_neg_one)
  2787     by (metis abs_minus_cancel abs_one abs_power2 one_neq_neg_one)
  2788   then have "cos (Arcsin z) \<noteq> 0"
  2789     by (metis diff_0_right power_zero_numeral sin_squared_eq)
  2790   then show ?thesis
  2791     apply (rule has_complex_derivative_inverse_basic [OF DERIV_sin _ _ open_ball [of z 1]])
  2792     apply (auto intro: isCont_Arcsin assms)
  2793     done
  2794 qed
  2795 
  2796 declare has_field_derivative_Arcsin [derivative_intros]
  2797 declare has_field_derivative_Arcsin [THEN DERIV_chain2, derivative_intros]
  2798 
  2799 lemma field_differentiable_at_Arcsin:
  2800     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arcsin field_differentiable at z"
  2801   using field_differentiable_def has_field_derivative_Arcsin by blast
  2802 
  2803 lemma field_differentiable_within_Arcsin:
  2804     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arcsin field_differentiable (at z within s)"
  2805   using field_differentiable_at_Arcsin field_differentiable_within_subset by blast
  2806 
  2807 lemma continuous_within_Arcsin:
  2808     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous (at z within s) Arcsin"
  2809   using continuous_at_imp_continuous_within isCont_Arcsin by blast
  2810 
  2811 lemma continuous_on_Arcsin [continuous_intros]:
  2812     "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous_on s Arcsin"
  2813   by (simp add: continuous_at_imp_continuous_on)
  2814 
  2815 lemma holomorphic_on_Arcsin: "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arcsin holomorphic_on s"
  2816   by (simp add: field_differentiable_within_Arcsin holomorphic_on_def)
  2817 
  2818 
  2819 subsection\<open>Inverse Cosine\<close>
  2820 
  2821 definition Arccos :: "complex \<Rightarrow> complex" where
  2822    "Arccos \<equiv> \<lambda>z. -\<i> * Ln(z + \<i> * csqrt(1 - z\<^sup>2))"
  2823 
  2824 lemma Arccos_range_lemma: "\<bar>Re z\<bar> < 1 \<Longrightarrow> 0 < Im(z + \<i> * csqrt(1 - z\<^sup>2))"
  2825   using Arcsin_range_lemma [of "-z"]
  2826   by simp
  2827 
  2828 lemma Arccos_body_lemma: "z + \<i> * csqrt(1 - z\<^sup>2) \<noteq> 0"
  2829   using Arcsin_body_lemma [of z]
  2830   by (metis complex_i_mult_minus diff_add_cancel minus_diff_eq minus_unique mult.assoc mult.left_commute
  2831            power2_csqrt power2_eq_square zero_neq_one)
  2832 
  2833 lemma Re_Arccos: "Re(Arccos z) = Im (Ln (z + \<i> * csqrt(1 - z\<^sup>2)))"
  2834   by (simp add: Arccos_def)
  2835 
  2836 lemma Im_Arccos: "Im(Arccos z) = - ln (cmod (z + \<i> * csqrt (1 - z\<^sup>2)))"
  2837   by (simp add: Arccos_def Arccos_body_lemma)
  2838 
  2839 text\<open>A very tricky argument to find!\<close>
  2840 lemma isCont_Arccos_lemma:
  2841   assumes eq0: "Im (z + \<i> * csqrt (1 - z\<^sup>2)) = 0" and "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2842     shows False
  2843 proof (cases "Im z = 0")
  2844   case True
  2845   then show ?thesis
  2846     using assms by (fastforce simp add: cmod_def abs_square_less_1 [symmetric])
  2847 next
  2848   case False
  2849   have Imz: "Im z = - sqrt ((1 + ((Im z)\<^sup>2 + cmod (1 - z\<^sup>2)) - (Re z)\<^sup>2) / 2)"
  2850     using eq0 abs_Re_le_cmod [of "1-z\<^sup>2"]
  2851     by (simp add: Re_power2 algebra_simps)
  2852   have "(cmod z)\<^sup>2 - 1 \<noteq> cmod (1 - z\<^sup>2)"
  2853   proof (clarsimp simp add: cmod_def)
  2854     assume "(Re z)\<^sup>2 + (Im z)\<^sup>2 - 1 = sqrt ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2855     then have "((Re z)\<^sup>2 + (Im z)\<^sup>2 - 1)\<^sup>2 = ((1 - Re (z\<^sup>2))\<^sup>2 + (Im (z\<^sup>2))\<^sup>2)"
  2856       by simp
  2857     then show False using False
  2858       by (simp add: power2_eq_square algebra_simps)
  2859   qed
  2860   moreover have "(Im z)\<^sup>2 = ((1 + ((Im z)\<^sup>2 + cmod (1 - z\<^sup>2)) - (Re z)\<^sup>2) / 2)"
  2861     apply (subst Imz)
  2862     using abs_Re_le_cmod [of "1-z\<^sup>2"]
  2863     apply (simp add: Re_power2)
  2864     done
  2865   ultimately show False
  2866     by (simp add: cmod_power2)
  2867 qed
  2868 
  2869 lemma isCont_Arccos:
  2870   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2871     shows "isCont Arccos z"
  2872 proof -
  2873   have "z + \<i> * csqrt (1 - z\<^sup>2) \<notin> \<real>\<^sub>\<le>\<^sub>0"
  2874     by (metis complex_nonpos_Reals_iff isCont_Arccos_lemma assms)
  2875   with assms show ?thesis
  2876     apply (simp add: Arccos_def)
  2877     apply (rule isCont_Ln' isCont_csqrt' continuous_intros)+
  2878     apply (simp_all add: one_minus_z2_notin_nonpos_Reals assms)
  2879     done
  2880 qed
  2881 
  2882 lemma isCont_Arccos' [simp]:
  2883   shows "isCont f z \<Longrightarrow> (Im (f z) = 0 \<Longrightarrow> \<bar>Re (f z)\<bar> < 1) \<Longrightarrow> isCont (\<lambda>x. Arccos (f x)) z"
  2884   by (blast intro: isCont_o2 [OF _ isCont_Arccos])
  2885 
  2886 lemma cos_Arccos [simp]: "cos(Arccos z) = z"
  2887 proof -
  2888   have "z*2 + \<i> * (2 * csqrt (1 - z\<^sup>2)) = 0 \<longleftrightarrow> z*2 + \<i> * csqrt (1 - z\<^sup>2)*2 = 0"
  2889     by (simp add: algebra_simps)  \<comment>\<open>Cancelling a factor of 2\<close>
  2890   moreover have "... \<longleftrightarrow> z + \<i> * csqrt (1 - z\<^sup>2) = 0"
  2891     by (metis distrib_right mult_eq_0_iff zero_neq_numeral)
  2892   ultimately show ?thesis
  2893     apply (simp add: cos_exp_eq Arccos_def Arccos_body_lemma exp_minus field_simps)
  2894     apply (simp add: power2_eq_square [symmetric])
  2895     done
  2896 qed
  2897 
  2898 lemma Arccos_cos:
  2899     assumes "0 < Re z & Re z < pi \<or>
  2900              Re z = 0 & 0 \<le> Im z \<or>
  2901              Re z = pi & Im z \<le> 0"
  2902       shows "Arccos(cos z) = z"
  2903 proof -
  2904   have *: "((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z))) = sin z"
  2905     by (simp add: sin_exp_eq exp_minus field_simps power2_eq_square)
  2906   have "1 - (exp (\<i> * z) + inverse (exp (\<i> * z)))\<^sup>2 / 4 = ((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z)))\<^sup>2"
  2907     by (simp add: field_simps power2_eq_square)
  2908   then have "Arccos(cos z) = - (\<i> * Ln ((exp (\<i> * z) + inverse (exp (\<i> * z))) / 2 +
  2909                            \<i> * csqrt (((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z)))\<^sup>2)))"
  2910     by (simp add: cos_exp_eq Arccos_def exp_minus power_divide)
  2911   also have "... = - (\<i> * Ln ((exp (\<i> * z) + inverse (exp (\<i> * z))) / 2 +
  2912                               \<i> * ((\<i> - (exp (\<i> * z))\<^sup>2 * \<i>) / (2 * exp (\<i> * z)))))"
  2913     apply (subst csqrt_square)
  2914     using assms Re_sin_pos [of z] Im_sin_nonneg [of z] Im_sin_nonneg2 [of z]
  2915     apply (auto simp: * Re_sin Im_sin)
  2916     done
  2917   also have "... =  - (\<i> * Ln (exp (\<i>*z)))"
  2918     by (simp add: field_simps power2_eq_square)
  2919   also have "... = z"
  2920     using assms
  2921     apply (subst Complex_Transcendental.Ln_exp, auto)
  2922     done
  2923   finally show ?thesis .
  2924 qed
  2925 
  2926 lemma Arccos_unique:
  2927     "\<lbrakk>cos z = w;
  2928       0 < Re z \<and> Re z < pi \<or>
  2929       Re z = 0 \<and> 0 \<le> Im z \<or>
  2930       Re z = pi \<and> Im z \<le> 0\<rbrakk> \<Longrightarrow> Arccos w = z"
  2931   using Arccos_cos by blast
  2932 
  2933 lemma Arccos_0 [simp]: "Arccos 0 = pi/2"
  2934   by (rule Arccos_unique) (auto simp: of_real_numeral)
  2935 
  2936 lemma Arccos_1 [simp]: "Arccos 1 = 0"
  2937   by (rule Arccos_unique) auto
  2938 
  2939 lemma Arccos_minus1: "Arccos(-1) = pi"
  2940   by (rule Arccos_unique) auto
  2941 
  2942 lemma has_field_derivative_Arccos:
  2943   assumes "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1)"
  2944     shows "(Arccos has_field_derivative - inverse(sin(Arccos z))) (at z)"
  2945 proof -
  2946   have "(cos (Arccos z))\<^sup>2 \<noteq> 1"
  2947     using assms
  2948     apply atomize
  2949     apply (auto simp: complex_eq_iff Re_power2 Im_power2 abs_square_eq_1)
  2950     apply (metis abs_minus_cancel abs_one abs_power2 numeral_One numeral_neq_neg_one)
  2951     apply (metis left_minus less_irrefl power_one sum_power2_gt_zero_iff zero_neq_neg_one)
  2952     done
  2953   then have "- sin (Arccos z) \<noteq> 0"
  2954     by (metis cos_squared_eq diff_0_right mult_zero_left neg_0_equal_iff_equal power2_eq_square)
  2955   then have "(Arccos has_field_derivative inverse(- sin(Arccos z))) (at z)"
  2956     apply (rule has_complex_derivative_inverse_basic [OF DERIV_cos _ _ open_ball [of z 1]])
  2957     apply (auto intro: isCont_Arccos assms)
  2958     done
  2959   then show ?thesis
  2960     by simp
  2961 qed
  2962 
  2963 declare has_field_derivative_Arcsin [derivative_intros]
  2964 declare has_field_derivative_Arcsin [THEN DERIV_chain2, derivative_intros]
  2965 
  2966 lemma field_differentiable_at_Arccos:
  2967     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arccos field_differentiable at z"
  2968   using field_differentiable_def has_field_derivative_Arccos by blast
  2969 
  2970 lemma field_differentiable_within_Arccos:
  2971     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arccos field_differentiable (at z within s)"
  2972   using field_differentiable_at_Arccos field_differentiable_within_subset by blast
  2973 
  2974 lemma continuous_within_Arccos:
  2975     "(Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous (at z within s) Arccos"
  2976   using continuous_at_imp_continuous_within isCont_Arccos by blast
  2977 
  2978 lemma continuous_on_Arccos [continuous_intros]:
  2979     "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> continuous_on s Arccos"
  2980   by (simp add: continuous_at_imp_continuous_on)
  2981 
  2982 lemma holomorphic_on_Arccos: "(\<And>z. z \<in> s \<Longrightarrow> Im z = 0 \<Longrightarrow> \<bar>Re z\<bar> < 1) \<Longrightarrow> Arccos holomorphic_on s"
  2983   by (simp add: field_differentiable_within_Arccos holomorphic_on_def)
  2984 
  2985 
  2986 subsection\<open>Upper and Lower Bounds for Inverse Sine and Cosine\<close>
  2987 
  2988 lemma Arcsin_bounds: "\<bar>Re z\<bar> < 1 \<Longrightarrow> \<bar>Re(Arcsin z)\<bar> < pi/2"
  2989   unfolding Re_Arcsin
  2990   by (blast intro: Re_Ln_pos_lt_imp Arcsin_range_lemma)
  2991 
  2992 lemma Arccos_bounds: "\<bar>Re z\<bar> < 1 \<Longrightarrow> 0 < Re(Arccos z) \<and> Re(Arccos z) < pi"
  2993   unfolding Re_Arccos
  2994   by (blast intro!: Im_Ln_pos_lt_imp Arccos_range_lemma)
  2995 
  2996 lemma Re_Arccos_bounds: "-pi < Re(Arccos z) \<and> Re(Arccos z) \<le> pi"
  2997   unfolding Re_Arccos
  2998   by (blast intro!: mpi_less_Im_Ln Im_Ln_le_pi Arccos_body_lemma)
  2999 
  3000 lemma Re_Arccos_bound: "\<bar>Re(Arccos z)\<bar> \<le> pi"
  3001   by (meson Re_Arccos_bounds abs_le_iff less_eq_real_def minus_less_iff)
  3002 
  3003 lemma Im_Arccos_bound: "\<bar>Im (Arccos w)\<bar> \<le> cmod w"
  3004 proof -
  3005   have "(Im (Arccos w))\<^sup>2 \<le> (cmod (cos (Arccos w)))\<^sup>2 - (cos (Re (Arccos w)))\<^sup>2"
  3006     using norm_cos_squared [of "Arccos w"] real_le_abs_sinh [of "Im (Arccos w)"]
  3007     apply (simp only: abs_le_square_iff)
  3008     apply (simp add: divide_simps)
  3009     done
  3010   also have "... \<le> (cmod w)\<^sup>2"
  3011     by (auto simp: cmod_power2)
  3012   finally show ?thesis
  3013     using abs_le_square_iff by force
  3014 qed
  3015 
  3016 lemma Re_Arcsin_bounds: "-pi < Re(Arcsin z) & Re(Arcsin z) \<le> pi"
  3017   unfolding Re_Arcsin
  3018   by (blast intro!: mpi_less_Im_Ln Im_Ln_le_pi Arcsin_body_lemma)
  3019 
  3020 lemma Re_Arcsin_bound: "\<bar>Re(Arcsin z)\<bar> \<le> pi"
  3021   by (meson Re_Arcsin_bounds abs_le_iff less_eq_real_def minus_less_iff)
  3022 
  3023 lemma norm_Arccos_bounded:
  3024   fixes w :: complex
  3025   shows "norm (Arccos w) \<le> pi + norm w"
  3026 proof -
  3027   have Re: "(Re (Arccos w))\<^sup>2 \<le> pi\<^sup>2" "(Im (Arccos w))\<^sup>2 \<le> (cmod w)\<^sup>2"
  3028     using Re_Arccos_bound [of w] Im_Arccos_bound [of w] abs_le_square_iff by force+
  3029   have "Arccos w \<bullet> Arccos w \<le> pi\<^sup>2 + (cmod w)\<^sup>2"
  3030     using Re by (simp add: dot_square_norm cmod_power2 [of "Arccos w"])
  3031   then have "cmod (Arccos w) \<le> pi + cmod (cos (Arccos w))"
  3032     apply (simp add: norm_le_square)
  3033     by (metis dot_square_norm norm_ge_zero norm_le_square pi_ge_zero triangle_lemma)
  3034   then show "cmod (Arccos w) \<le> pi + cmod w"
  3035     by auto
  3036 qed
  3037 
  3038 
  3039 subsection\<open>Interrelations between Arcsin and Arccos\<close>
  3040 
  3041 lemma cos_Arcsin_nonzero:
  3042   assumes "z\<^sup>2 \<noteq> 1" shows "cos(Arcsin z) \<noteq> 0"
  3043 proof -
  3044   have eq: "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = z\<^sup>2 * (z\<^sup>2 - 1)"
  3045     by (simp add: power_mult_distrib algebra_simps)
  3046   have "\<i> * z * (csqrt (1 - z\<^sup>2)) \<noteq> z\<^sup>2 - 1"
  3047   proof
  3048     assume "\<i> * z * (csqrt (1 - z\<^sup>2)) = z\<^sup>2 - 1"
  3049     then have "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = (z\<^sup>2 - 1)\<^sup>2"
  3050       by simp
  3051     then have "z\<^sup>2 * (z\<^sup>2 - 1) = (z\<^sup>2 - 1)*(z\<^sup>2 - 1)"
  3052       using eq power2_eq_square by auto
  3053     then show False
  3054       using assms by simp
  3055   qed
  3056   then have "1 + \<i> * z * (csqrt (1 - z * z)) \<noteq> z\<^sup>2"
  3057     by (metis add_minus_cancel power2_eq_square uminus_add_conv_diff)
  3058   then have "2*(1 + \<i> * z * (csqrt (1 - z * z))) \<noteq> 2*z\<^sup>2"  (*FIXME cancel_numeral_factor*)
  3059     by (metis mult_cancel_left zero_neq_numeral)
  3060   then have "(\<i> * z + csqrt (1 - z\<^sup>2))\<^sup>2 \<noteq> -1"
  3061     using assms
  3062     apply (auto simp: power2_sum)
  3063     apply (simp add: power2_eq_square algebra_simps)
  3064     done
  3065   then show ?thesis
  3066     apply (simp add: cos_exp_eq Arcsin_def exp_minus)
  3067     apply (simp add: divide_simps Arcsin_body_lemma)
  3068     apply (metis add.commute minus_unique power2_eq_square)
  3069     done
  3070 qed
  3071 
  3072 lemma sin_Arccos_nonzero:
  3073   assumes "z\<^sup>2 \<noteq> 1" shows "sin(Arccos z) \<noteq> 0"
  3074 proof -
  3075   have eq: "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = -(z\<^sup>2) * (1 - z\<^sup>2)"
  3076     by (simp add: power_mult_distrib algebra_simps)
  3077   have "\<i> * z * (csqrt (1 - z\<^sup>2)) \<noteq> 1 - z\<^sup>2"
  3078   proof
  3079     assume "\<i> * z * (csqrt (1 - z\<^sup>2)) = 1 - z\<^sup>2"
  3080     then have "(\<i> * z * (csqrt (1 - z\<^sup>2)))\<^sup>2 = (1 - z\<^sup>2)\<^sup>2"
  3081       by simp
  3082     then have "-(z\<^sup>2) * (1 - z\<^sup>2) = (1 - z\<^sup>2)*(1 - z\<^sup>2)"
  3083       using eq power2_eq_square by auto
  3084     then have "-(z\<^sup>2) = (1 - z\<^sup>2)"
  3085       using assms
  3086       by (metis add.commute add.right_neutral diff_add_cancel mult_right_cancel)
  3087     then show False
  3088       using assms by simp
  3089   qed
  3090   then have "z\<^sup>2 + \<i> * z * (csqrt (1 - z\<^sup>2)) \<noteq> 1"
  3091     by (simp add: algebra_simps)
  3092   then have "2*(z\<^sup>2 + \<i> * z * (csqrt (1 - z\<^sup>2))) \<noteq> 2*1"
  3093     by (metis mult_cancel_left2 zero_neq_numeral)  (*FIXME cancel_numeral_factor*)
  3094   then have "(z + \<i> * csqrt (1 - z\<^sup>2))\<^sup>2 \<noteq> 1"
  3095     using assms
  3096     apply (auto simp: Power.comm_semiring_1_class.power2_sum power_mult_distrib)
  3097     apply (simp add: power2_eq_square algebra_simps)
  3098     done
  3099   then show ?thesis
  3100     apply (simp add: sin_exp_eq Arccos_def exp_minus)
  3101     apply (simp add: divide_simps Arccos_body_lemma)
  3102     apply (simp add: power2_eq_square)
  3103     done
  3104 qed
  3105 
  3106 lemma cos_sin_csqrt:
  3107   assumes "0 < cos(Re z)  \<or>  cos(Re z) = 0 \<and> Im z * sin(Re z) \<le> 0"
  3108     shows "cos z = csqrt(1 - (sin z)\<^sup>2)"
  3109   apply (rule csqrt_unique [THEN sym])
  3110   apply (simp add: cos_squared_eq)
  3111   using assms
  3112   apply (auto simp: Re_cos Im_cos add_pos_pos mult_le_0_iff zero_le_mult_iff)
  3113   done
  3114 
  3115 lemma sin_cos_csqrt:
  3116   assumes "0 < sin(Re z)  \<or>  sin(Re z) = 0 \<and> 0 \<le> Im z * cos(Re z)"
  3117     shows "sin z = csqrt(1 - (cos z)\<^sup>2)"
  3118   apply (rule csqrt_unique [THEN sym])
  3119   apply (simp add: sin_squared_eq)
  3120   using assms
  3121   apply (auto simp: Re_sin Im_sin add_pos_pos mult_le_0_iff zero_le_mult_iff)
  3122   done
  3123 
  3124 lemma Arcsin_Arccos_csqrt_pos:
  3125     "(0 < Re z | Re z = 0 & 0 \<le> Im z) \<Longrightarrow> Arcsin z = Arccos(csqrt(1 - z\<^sup>2))"
  3126   by (simp add: Arcsin_def Arccos_def Complex.csqrt_square add.commute)
  3127 
  3128 lemma Arccos_Arcsin_csqrt_pos:
  3129     "(0 < Re z | Re z = 0 & 0 \<le> Im z) \<Longrightarrow> Arccos z = Arcsin(csqrt(1 - z\<^sup>2))"
  3130   by (simp add: Arcsin_def Arccos_def Complex.csqrt_square add.commute)
  3131 
  3132 lemma sin_Arccos:
  3133     "0 < Re z | Re z = 0 & 0 \<le> Im z \<Longrightarrow> sin(Arccos z) = csqrt(1 - z\<^sup>2)"
  3134   by (simp add: Arccos_Arcsin_csqrt_pos)
  3135 
  3136 lemma cos_Arcsin:
  3137     "0 < Re z | Re z = 0 & 0 \<le> Im z \<Longrightarrow> cos(Arcsin z) = csqrt(1 - z\<^sup>2)"
  3138   by (simp add: Arcsin_Arccos_csqrt_pos)
  3139 
  3140 
  3141 subsection\<open>Relationship with Arcsin on the Real Numbers\<close>
  3142 
  3143 lemma Im_Arcsin_of_real:
  3144   assumes "\<bar>x\<bar> \<le> 1"
  3145     shows "Im (Arcsin (of_real x)) = 0"
  3146 proof -
  3147   have "csqrt (1 - (of_real x)\<^sup>2) = (if x^2 \<le> 1 then sqrt (1 - x^2) else \<i> * sqrt (x^2 - 1))"
  3148     by (simp add: of_real_sqrt del: csqrt_of_real_nonneg)
  3149   then have "cmod (\<i> * of_real x + csqrt (1 - (of_real x)\<^sup>2))^2 = 1"
  3150     using assms abs_square_le_1
  3151     by (force simp add: Complex.cmod_power2)
  3152   then have "cmod (\<i> * of_real x + csqrt (1 - (of_real x)\<^sup>2)) = 1"
  3153     by (simp add: norm_complex_def)
  3154   then show ?thesis
  3155     by (simp add: Im_Arcsin exp_minus)
  3156 qed
  3157 
  3158 corollary Arcsin_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> \<bar>Re z\<bar> \<le> 1 \<Longrightarrow> Arcsin z \<in> \<real>"
  3159   by (metis Im_Arcsin_of_real Re_complex_of_real Reals_cases complex_is_Real_iff)
  3160 
  3161 lemma arcsin_eq_Re_Arcsin:
  3162   assumes "\<bar>x\<bar> \<le> 1"
  3163     shows "arcsin x = Re (Arcsin (of_real x))"
  3164 unfolding arcsin_def
  3165 proof (rule the_equality, safe)
  3166   show "- (pi / 2) \<le> Re (Arcsin (complex_of_real x))"
  3167     using Re_Ln_pos_le [OF Arcsin_body_lemma, of "of_real x"]
  3168     by (auto simp: Complex.in_Reals_norm Re_Arcsin)
  3169 next
  3170   show "Re (Arcsin (complex_of_real x)) \<le> pi / 2"
  3171     using Re_Ln_pos_le [OF Arcsin_body_lemma, of "of_real x"]
  3172     by (auto simp: Complex.in_Reals_norm Re_Arcsin)
  3173 next
  3174   show "sin (Re (Arcsin (complex_of_real x))) = x"
  3175     using Re_sin [of "Arcsin (of_real x)"] Arcsin_body_lemma [of "of_real x"]
  3176     by (simp add: Im_Arcsin_of_real assms)
  3177 next
  3178   fix x'
  3179   assume "- (pi / 2) \<le> x'" "x' \<le> pi / 2" "x = sin x'"
  3180   then show "x' = Re (Arcsin (complex_of_real (sin x')))"
  3181     apply (simp add: sin_of_real [symmetric])
  3182     apply (subst Arcsin_sin)
  3183     apply (auto simp: )
  3184     done
  3185 qed
  3186 
  3187 lemma of_real_arcsin: "\<bar>x\<bar> \<le> 1 \<Longrightarrow> of_real(arcsin x) = Arcsin(of_real x)"
  3188   by (metis Im_Arcsin_of_real add.right_neutral arcsin_eq_Re_Arcsin complex_eq mult_zero_right of_real_0)
  3189 
  3190 
  3191 subsection\<open>Relationship with Arccos on the Real Numbers\<close>
  3192 
  3193 lemma Im_Arccos_of_real:
  3194   assumes "\<bar>x\<bar> \<le> 1"
  3195     shows "Im (Arccos (of_real x)) = 0"
  3196 proof -
  3197   have "csqrt (1 - (of_real x)\<^sup>2) = (if x^2 \<le> 1 then sqrt (1 - x^2) else \<i> * sqrt (x^2 - 1))"
  3198     by (simp add: of_real_sqrt del: csqrt_of_real_nonneg)
  3199   then have "cmod (of_real x + \<i> * csqrt (1 - (of_real x)\<^sup>2))^2 = 1"
  3200     using assms abs_square_le_1
  3201     by (force simp add: Complex.cmod_power2)
  3202   then have "cmod (of_real x + \<i> * csqrt (1 - (of_real x)\<^sup>2)) = 1"
  3203     by (simp add: norm_complex_def)
  3204   then show ?thesis
  3205     by (simp add: Im_Arccos exp_minus)
  3206 qed
  3207 
  3208 corollary Arccos_in_Reals [simp]: "z \<in> \<real> \<Longrightarrow> \<bar>Re z\<bar> \<le> 1 \<Longrightarrow> Arccos z \<in> \<real>"
  3209   by (metis Im_Arccos_of_real Re_complex_of_real Reals_cases complex_is_Real_iff)
  3210 
  3211 lemma arccos_eq_Re_Arccos:
  3212   assumes "\<bar>x\<bar> \<le> 1"
  3213     shows "arccos x = Re (Arccos (of_real x))"
  3214 unfolding arccos_def
  3215 proof (rule the_equality, safe)
  3216   show "0 \<le> Re (Arccos (complex_of_real x))"
  3217     using Im_Ln_pos_le [OF Arccos_body_lemma, of "of_real x"]
  3218     by (auto simp: Complex.in_Reals_norm Re_Arccos)
  3219 next
  3220   show "Re (Arccos (complex_of_real x)) \<le> pi"
  3221     using Im_Ln_pos_le [OF Arccos_body_lemma, of "of_real x"]
  3222     by (auto simp: Complex.in_Reals_norm Re_Arccos)
  3223 next
  3224   show "cos (Re (Arccos (complex_of_real x))) = x"
  3225     using Re_cos [of "Arccos (of_real x)"] Arccos_body_lemma [of "of_real x"]
  3226     by (simp add: Im_Arccos_of_real assms)
  3227 next
  3228   fix x'
  3229   assume "0 \<le> x'" "x' \<le> pi" "x = cos x'"
  3230   then show "x' = Re (Arccos (complex_of_real (cos x')))"
  3231     apply (simp add: cos_of_real [symmetric])
  3232     apply (subst Arccos_cos)
  3233     apply (auto simp: )
  3234     done
  3235 qed
  3236 
  3237 lemma of_real_arccos: "\<bar>x\<bar> \<le> 1 \<Longrightarrow> of_real(arccos x) = Arccos(of_real x)"
  3238   by (metis Im_Arccos_of_real add.right_neutral arccos_eq_Re_Arccos complex_eq mult_zero_right of_real_0)
  3239 
  3240 subsection\<open>Some interrelationships among the real inverse trig functions.\<close>
  3241 
  3242 lemma arccos_arctan:
  3243   assumes "-1 < x" "x < 1"
  3244     shows "arccos x = pi/2 - arctan(x / sqrt(1 - x\<^sup>2))"
  3245 proof -
  3246   have "arctan(x / sqrt(1 - x\<^sup>2)) - (pi/2 - arccos x) = 0"
  3247   proof (rule sin_eq_0_pi)
  3248     show "- pi < arctan (x / sqrt (1 - x\<^sup>2)) - (pi / 2 - arccos x)"
  3249       using arctan_lbound [of "x / sqrt(1 - x\<^sup>2)"]  arccos_bounded [of x] assms
  3250       by (simp add: algebra_simps)
  3251   next
  3252     show "arctan (x / sqrt (1 - x\<^sup>2)) - (pi / 2 - arccos x) < pi"
  3253       using arctan_ubound [of "x / sqrt(1 - x\<^sup>2)"]  arccos_bounded [of x] assms
  3254       by (simp add: algebra_simps)
  3255   next
  3256     show "sin (arctan (x / sqrt (1 - x\<^sup>2)) - (pi / 2 - arccos x)) = 0"
  3257       using assms
  3258       by (simp add: algebra_simps sin_diff cos_add sin_arccos sin_arctan cos_arctan
  3259                     power2_eq_square square_eq_1_iff)
  3260   qed
  3261   then show ?thesis
  3262     by simp
  3263 qed
  3264 
  3265 lemma arcsin_plus_arccos:
  3266   assumes "-1 \<le> x" "x \<le> 1"
  3267     shows "arcsin x + arccos x = pi/2"
  3268 proof -
  3269   have "arcsin x = pi/2 - arccos x"
  3270     apply (rule sin_inj_pi)
  3271     using assms arcsin [OF assms] arccos [OF assms]
  3272     apply (auto simp: algebra_simps sin_diff)
  3273     done
  3274   then show ?thesis
  3275     by (simp add: algebra_simps)
  3276 qed
  3277 
  3278 lemma arcsin_arccos_eq: "-1 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arcsin x = pi/2 - arccos x"
  3279   using arcsin_plus_arccos by force
  3280 
  3281 lemma arccos_arcsin_eq: "-1 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arccos x = pi/2 - arcsin x"
  3282   using arcsin_plus_arccos by force
  3283 
  3284 lemma arcsin_arctan: "-1 < x \<Longrightarrow> x < 1 \<Longrightarrow> arcsin x = arctan(x / sqrt(1 - x\<^sup>2))"
  3285   by (simp add: arccos_arctan arcsin_arccos_eq)
  3286 
  3287 lemma csqrt_1_diff_eq: "csqrt (1 - (of_real x)\<^sup>2) = (if x^2 \<le> 1 then sqrt (1 - x^2) else \<i> * sqrt (x^2 - 1))"
  3288   by ( simp add: of_real_sqrt del: csqrt_of_real_nonneg)
  3289 
  3290 lemma arcsin_arccos_sqrt_pos: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arcsin x = arccos(sqrt(1 - x\<^sup>2))"
  3291   apply (simp add: abs_square_le_1 arcsin_eq_Re_Arcsin arccos_eq_Re_Arccos)
  3292   apply (subst Arcsin_Arccos_csqrt_pos)
  3293   apply (auto simp: power_le_one csqrt_1_diff_eq)
  3294   done
  3295 
  3296 lemma arcsin_arccos_sqrt_neg: "-1 \<le> x \<Longrightarrow> x \<le> 0 \<Longrightarrow> arcsin x = -arccos(sqrt(1 - x\<^sup>2))"
  3297   using arcsin_arccos_sqrt_pos [of "-x"]
  3298   by (simp add: arcsin_minus)
  3299 
  3300 lemma arccos_arcsin_sqrt_pos: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> arccos x = arcsin(sqrt(1 - x\<^sup>2))"
  3301   apply (simp add: abs_square_le_1 arcsin_eq_Re_Arcsin arccos_eq_Re_Arccos)
  3302   apply (subst Arccos_Arcsin_csqrt_pos)
  3303   apply (auto simp: power_le_one csqrt_1_diff_eq)
  3304   done
  3305 
  3306 lemma arccos_arcsin_sqrt_neg: "-1 \<le> x \<Longrightarrow> x \<le> 0 \<Longrightarrow> arccos x = pi - arcsin(sqrt(1 - x\<^sup>2))"
  3307   using arccos_arcsin_sqrt_pos [of "-x"]
  3308   by (simp add: arccos_minus)
  3309 
  3310 subsection\<open>continuity results for arcsin and arccos.\<close>
  3311 
  3312 lemma continuous_on_Arcsin_real [continuous_intros]:
  3313     "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} Arcsin"
  3314 proof -
  3315   have "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (arcsin (Re x))) =
  3316         continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (Re (Arcsin (of_real (Re x)))))"
  3317     by (rule continuous_on_cong [OF refl]) (simp add: arcsin_eq_Re_Arcsin)
  3318   also have "... = ?thesis"
  3319     by (rule continuous_on_cong [OF refl]) simp
  3320   finally show ?thesis
  3321     using continuous_on_arcsin [OF continuous_on_Re [OF continuous_on_id], of "{w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}"]
  3322           continuous_on_of_real
  3323     by fastforce
  3324 qed
  3325 
  3326 lemma continuous_within_Arcsin_real:
  3327     "continuous (at z within {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}) Arcsin"
  3328 proof (cases "z \<in> {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}")
  3329   case True then show ?thesis
  3330     using continuous_on_Arcsin_real continuous_on_eq_continuous_within
  3331     by blast
  3332 next
  3333   case False
  3334   with closed_real_abs_le [of 1] show ?thesis
  3335     by (rule continuous_within_closed_nontrivial)
  3336 qed
  3337 
  3338 lemma continuous_on_Arccos_real:
  3339     "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} Arccos"
  3340 proof -
  3341   have "continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (arccos (Re x))) =
  3342         continuous_on {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1} (\<lambda>x. complex_of_real (Re (Arccos (of_real (Re x)))))"
  3343     by (rule continuous_on_cong [OF refl]) (simp add: arccos_eq_Re_Arccos)
  3344   also have "... = ?thesis"
  3345     by (rule continuous_on_cong [OF refl]) simp
  3346   finally show ?thesis
  3347     using continuous_on_arccos [OF continuous_on_Re [OF continuous_on_id], of "{w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}"]
  3348           continuous_on_of_real
  3349     by fastforce
  3350 qed
  3351 
  3352 lemma continuous_within_Arccos_real:
  3353     "continuous (at z within {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}) Arccos"
  3354 proof (cases "z \<in> {w \<in> \<real>. \<bar>Re w\<bar> \<le> 1}")
  3355   case True then show ?thesis
  3356     using continuous_on_Arccos_real continuous_on_eq_continuous_within
  3357     by blast
  3358 next
  3359   case False
  3360   with closed_real_abs_le [of 1] show ?thesis
  3361     by (rule continuous_within_closed_nontrivial)
  3362 qed
  3363 
  3364 
  3365 subsection\<open>Roots of unity\<close>
  3366 
  3367 lemma complex_root_unity:
  3368   fixes j::nat
  3369   assumes "n \<noteq> 0"
  3370     shows "exp(2 * of_real pi * \<i> * of_nat j / of_nat n)^n = 1"
  3371 proof -
  3372   have *: "of_nat j * (complex_of_real pi * 2) = complex_of_real (2 * real j * pi)"
  3373     by (simp add: of_real_numeral)
  3374   then show ?thesis
  3375     apply (simp add: exp_of_nat_mult [symmetric] mult_ac exp_Euler)
  3376     apply (simp only: * cos_of_real sin_of_real)
  3377     apply (simp add: )
  3378     done
  3379 qed
  3380 
  3381 lemma complex_root_unity_eq:
  3382   fixes j::nat and k::nat
  3383   assumes "1 \<le> n"
  3384     shows "(exp(2 * of_real pi * \<i> * of_nat j / of_nat n) = exp(2 * of_real pi * \<i> * of_nat k / of_nat n)
  3385            \<longleftrightarrow> j mod n = k mod n)"
  3386 proof -
  3387     have "(\<exists>z::int. \<i> * (of_nat j * (of_real pi * 2)) =
  3388                \<i> * (of_nat k * (of_real pi * 2)) + \<i> * (of_int z * (of_nat n * (of_real pi * 2)))) \<longleftrightarrow>
  3389           (\<exists>z::int. of_nat j * (\<i> * (of_real pi * 2)) =
  3390               (of_nat k + of_nat n * of_int z) * (\<i> * (of_real pi * 2)))"
  3391       by (simp add: algebra_simps)
  3392     also have "... \<longleftrightarrow> (\<exists>z::int. of_nat j = of_nat k + of_nat n * (of_int z :: complex))"
  3393       by simp
  3394     also have "... \<longleftrightarrow> (\<exists>z::int. of_nat j = of_nat k + of_nat n * z)"
  3395       apply (rule HOL.iff_exI)
  3396       apply (auto simp: )
  3397       using of_int_eq_iff apply fastforce
  3398       by (metis of_int_add of_int_mult of_int_of_nat_eq)
  3399     also have "... \<longleftrightarrow> int j mod int n = int k mod int n"
  3400       by (auto simp: mod_eq_dvd_iff dvd_def algebra_simps)
  3401     also have "... \<longleftrightarrow> j mod n = k mod n"
  3402       by (metis of_nat_eq_iff zmod_int)
  3403     finally have "(\<exists>z. \<i> * (of_nat j * (of_real pi * 2)) =
  3404              \<i> * (of_nat k * (of_real pi * 2)) + \<i> * (of_int z * (of_nat n * (of_real pi * 2)))) \<longleftrightarrow> j mod n = k mod n" .
  3405    note * = this
  3406   show ?thesis
  3407     using assms
  3408     by (simp add: exp_eq divide_simps mult_ac of_real_numeral *)
  3409 qed
  3410 
  3411 corollary bij_betw_roots_unity:
  3412     "bij_betw (\<lambda>j. exp(2 * of_real pi * \<i> * of_nat j / of_nat n))
  3413               {..<n}  {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j. j < n}"
  3414   by (auto simp: bij_betw_def inj_on_def complex_root_unity_eq)
  3415 
  3416 lemma complex_root_unity_eq_1:
  3417   fixes j::nat and k::nat
  3418   assumes "1 \<le> n"
  3419     shows "exp(2 * of_real pi * \<i> * of_nat j / of_nat n) = 1 \<longleftrightarrow> n dvd j"
  3420 proof -
  3421   have "1 = exp(2 * of_real pi * \<i> * (of_nat n / of_nat n))"
  3422     using assms by simp
  3423   then have "exp(2 * of_real pi * \<i> * (of_nat j / of_nat n)) = 1 \<longleftrightarrow> j mod n = n mod n"
  3424      using complex_root_unity_eq [of n j n] assms
  3425      by simp
  3426   then show ?thesis
  3427     by auto
  3428 qed
  3429 
  3430 lemma finite_complex_roots_unity_explicit:
  3431      "finite {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j::nat. j < n}"
  3432 by simp
  3433 
  3434 lemma card_complex_roots_unity_explicit:
  3435      "card {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j::nat. j < n} = n"
  3436   by (simp add:  Finite_Set.bij_betw_same_card [OF bij_betw_roots_unity, symmetric])
  3437 
  3438 lemma complex_roots_unity:
  3439   assumes "1 \<le> n"
  3440     shows "{z::complex. z^n = 1} = {exp(2 * of_real pi * \<i> * of_nat j / of_nat n) | j::nat. j < n}"
  3441   apply (rule Finite_Set.card_seteq [symmetric])
  3442   using assms
  3443   apply (auto simp: card_complex_roots_unity_explicit finite_roots_unity complex_root_unity card_roots_unity)
  3444   done
  3445 
  3446 lemma card_complex_roots_unity: "1 \<le> n \<Longrightarrow> card {z::complex. z^n = 1} = n"
  3447   by (simp add: card_complex_roots_unity_explicit complex_roots_unity)
  3448 
  3449 lemma complex_not_root_unity:
  3450     "1 \<le> n \<Longrightarrow> \<exists>u::complex. norm u = 1 \<and> u^n \<noteq> 1"
  3451   apply (rule_tac x="exp (of_real pi * \<i> * of_real (1 / n))" in exI)
  3452   apply (auto simp: Re_complex_div_eq_0 exp_of_nat_mult [symmetric] mult_ac exp_Euler)
  3453   done
  3454 
  3455 subsection\<open> Formulation of loop homotopy in terms of maps out of type complex\<close>
  3456 
  3457 lemma homotopic_circlemaps_imp_homotopic_loops:
  3458   assumes "homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3459    shows "homotopic_loops S (f \<circ> exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>))
  3460                             (g \<circ> exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>))"
  3461 proof -
  3462   have "homotopic_with (\<lambda>f. True) {z. cmod z = 1} S f g"
  3463     using assms by (auto simp: sphere_def)
  3464   moreover have "continuous_on {0..1} (exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>))"
  3465      by (intro continuous_intros)
  3466   moreover have "(exp \<circ> (\<lambda>t. 2 * of_real pi * of_real t * \<i>)) ` {0..1} \<subseteq> {z. cmod z = 1}"
  3467     by (auto simp: norm_mult)
  3468   ultimately
  3469   show ?thesis
  3470     apply (simp add: homotopic_loops_def comp_assoc)
  3471     apply (rule homotopic_with_compose_continuous_right)
  3472       apply (auto simp: pathstart_def pathfinish_def)
  3473     done
  3474 qed
  3475 
  3476 lemma homotopic_loops_imp_homotopic_circlemaps:
  3477   assumes "homotopic_loops S p q"
  3478     shows "homotopic_with (\<lambda>h. True) (sphere 0 1) S
  3479                           (p \<circ> (\<lambda>z. (Arg z / (2 * pi))))
  3480                           (q \<circ> (\<lambda>z. (Arg z / (2 * pi))))"
  3481 proof -
  3482   obtain h where conth: "continuous_on ({0..1::real} \<times> {0..1}) h"
  3483              and him: "h ` ({0..1} \<times> {0..1}) \<subseteq> S"
  3484              and h0: "(\<forall>x. h (0, x) = p x)"
  3485              and h1: "(\<forall>x. h (1, x) = q x)"
  3486              and h01: "(\<forall>t\<in>{0..1}. h (t, 1) = h (t, 0)) "
  3487     using assms
  3488     by (auto simp: homotopic_loops_def sphere_def homotopic_with_def pathstart_def pathfinish_def)
  3489   define j where "j \<equiv> \<lambda>z. if 0 \<le> Im (snd z)
  3490                           then h (fst z, Arg (snd z) / (2 * pi))
  3491                           else h (fst z, 1 - Arg (cnj (snd z)) / (2 * pi))"
  3492   have Arg_eq: "1 - Arg (cnj y) / (2 * pi) = Arg y / (2 * pi) \<or> Arg y = 0 \<and> Arg (cnj y) = 0" if "cmod y = 1" for y
  3493     using that Arg_eq_0_pi Arg_eq_pi by (force simp: Arg_cnj divide_simps)
  3494   show ?thesis
  3495   proof (simp add: homotopic_with; intro conjI ballI exI)
  3496     show "continuous_on ({0..1} \<times> sphere 0 1) (\<lambda>w. h (fst w, Arg (snd w) / (2 * pi)))"
  3497     proof (rule continuous_on_eq)
  3498       show j: "j x = h (fst x, Arg (snd x) / (2 * pi))" if "x \<in> {0..1} \<times> sphere 0 1" for x
  3499         using Arg_eq that h01 by (force simp: j_def)
  3500       have eq:  "S = S \<inter> (UNIV \<times> {z. 0 \<le> Im z}) \<union> S \<inter> (UNIV \<times> {z. Im z \<le> 0})" for S :: "(real*complex)set"
  3501         by auto
  3502       have c1: "continuous_on ({0..1} \<times> sphere 0 1 \<inter> UNIV \<times> {z. 0 \<le> Im z}) (\<lambda>x. h (fst x, Arg (snd x) / (2 * pi)))"
  3503         apply (intro continuous_intros continuous_on_compose2 [OF conth]  continuous_on_compose2 [OF continuous_on_upperhalf_Arg])
  3504             apply (auto simp: Arg)
  3505         apply (meson Arg_lt_2pi linear not_le)
  3506         done
  3507       have c2: "continuous_on ({0..1} \<times> sphere 0 1 \<inter> UNIV \<times> {z. Im z \<le> 0}) (\<lambda>x. h (fst x, 1 - Arg (cnj (snd x)) / (2 * pi)))"
  3508         apply (intro continuous_intros continuous_on_compose2 [OF conth]  continuous_on_compose2 [OF continuous_on_upperhalf_Arg])
  3509             apply (auto simp: Arg)
  3510         apply (meson Arg_lt_2pi linear not_le)
  3511         done
  3512       show "continuous_on ({0..1} \<times> sphere 0 1) j"
  3513         apply (simp add: j_def)
  3514         apply (subst eq)
  3515         apply (rule continuous_on_cases_local)
  3516             apply (simp_all add: eq [symmetric] closedin_closed_Int closed_Times closed_halfspace_Im_le closed_halfspace_Im_ge c1 c2)
  3517         using Arg_eq h01
  3518         by force
  3519     qed
  3520     have "(\<lambda>w. h (fst w, Arg (snd w) / (2 * pi))) ` ({0..1} \<times> sphere 0 1) \<subseteq> h ` ({0..1} \<times> {0..1})"
  3521       by (auto simp: Arg_ge_0 Arg_lt_2pi less_imp_le)
  3522     also have "... \<subseteq> S"
  3523       using him by blast
  3524     finally show "(\<lambda>w. h (fst w, Arg (snd w) / (2 * pi))) ` ({0..1} \<times> sphere 0 1) \<subseteq> S" .
  3525   qed (auto simp: h0 h1)
  3526 qed
  3527 
  3528 lemma simply_connected_homotopic_loops:
  3529   "simply_connected S \<longleftrightarrow>
  3530        (\<forall>p q. homotopic_loops S p p \<and> homotopic_loops S q q \<longrightarrow> homotopic_loops S p q)"
  3531 unfolding simply_connected_def using homotopic_loops_refl by metis
  3532 
  3533 
  3534 lemma simply_connected_eq_homotopic_circlemaps1:
  3535   fixes f :: "complex \<Rightarrow> 'a::topological_space" and g :: "complex \<Rightarrow> 'a"
  3536   assumes S: "simply_connected S"
  3537       and contf: "continuous_on (sphere 0 1) f" and fim: "f ` (sphere 0 1) \<subseteq> S"
  3538       and contg: "continuous_on (sphere 0 1) g" and gim: "g ` (sphere 0 1) \<subseteq> S"
  3539     shows "homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3540 proof -
  3541   have "homotopic_loops S (f \<circ> exp \<circ> (\<lambda>t. of_real(2 * pi * t) * \<i>)) (g \<circ> exp \<circ> (\<lambda>t. of_real(2 * pi *  t) * \<i>))"
  3542     apply (rule S [unfolded simply_connected_homotopic_loops, rule_format])
  3543     apply (simp add: homotopic_circlemaps_imp_homotopic_loops homotopic_with_refl contf fim contg gim)
  3544     done
  3545   then show ?thesis
  3546     apply (rule homotopic_with_eq [OF homotopic_loops_imp_homotopic_circlemaps])
  3547       apply (auto simp: o_def complex_norm_eq_1_exp mult.commute)
  3548     done
  3549 qed
  3550 
  3551 lemma simply_connected_eq_homotopic_circlemaps2a:
  3552   fixes h :: "complex \<Rightarrow> 'a::topological_space"
  3553   assumes conth: "continuous_on (sphere 0 1) h" and him: "h ` (sphere 0 1) \<subseteq> S"
  3554       and hom: "\<And>f g::complex \<Rightarrow> 'a.
  3555                 \<lbrakk>continuous_on (sphere 0 1) f; f ` (sphere 0 1) \<subseteq> S;
  3556                 continuous_on (sphere 0 1) g; g ` (sphere 0 1) \<subseteq> S\<rbrakk>
  3557                 \<Longrightarrow> homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3558             shows "\<exists>a. homotopic_with (\<lambda>h. True) (sphere 0 1) S h (\<lambda>x. a)"
  3559     apply (rule_tac x="h 1" in exI)
  3560     apply (rule hom)
  3561     using assms
  3562     by (auto simp: continuous_on_const)
  3563 
  3564 lemma simply_connected_eq_homotopic_circlemaps2b:
  3565   fixes S :: "'a::real_normed_vector set"
  3566   assumes "\<And>f g::complex \<Rightarrow> 'a.
  3567                 \<lbrakk>continuous_on (sphere 0 1) f; f ` (sphere 0 1) \<subseteq> S;
  3568                 continuous_on (sphere 0 1) g; g ` (sphere 0 1) \<subseteq> S\<rbrakk>
  3569                 \<Longrightarrow> homotopic_with (\<lambda>h. True) (sphere 0 1) S f g"
  3570   shows "path_connected S"
  3571 proof (clarsimp simp add: path_connected_eq_homotopic_points)
  3572   fix a b
  3573   assume "a \<in> S" "b \<in> S"
  3574   then show "homotopic_loops S (linepath a a) (linepath b b)"
  3575     using homotopic_circlemaps_imp_homotopic_loops [OF assms [of "\<lambda>x. a" "\<lambda>x. b"]]
  3576     by (auto simp: o_def continuous_on_const linepath_def)
  3577 qed
  3578 
  3579 lemma simply_connected_eq_homotopic_circlemaps3:
  3580   fixes h :: "complex \<Rightarrow> 'a::real_normed_vector"
  3581   assumes "path_connected S"
  3582       and hom: "\<And>f::complex \<Rightarrow> 'a.
  3583                   \<lbrakk>continuous_on (sphere 0 1) f; f `(sphere 0 1) \<subseteq> S\<rbrakk>
  3584                   \<Longrightarrow> \<exists>a. homotopic_with (\<lambda>h. True) (sphere 0 1) S f (\<lambda>x. a)"
  3585     shows "simply_connected S"
  3586 proof (clarsimp simp add: simply_connected_eq_contractible_loop_some assms)
  3587   fix p
  3588   assume p: "path p" "path_image p \<subseteq> S" "pathfinish p = pathstart p"
  3589   then have "homotopic_loops S p p"
  3590     by (simp add: homotopic_loops_refl)
  3591   then obtain a where homp: "homotopic_with (\<lambda>h. True) (sphere 0 1) S (p \<circ> (\<lambda>z. Arg z / (2 * pi))) (\<lambda>x. a)"
  3592     by (metis homotopic_with_imp_subset2 homotopic_loops_imp_homotopic_circlemaps homotopic_with_imp_continuous hom)
  3593   show "\<exists>a. a \<in> S \<and> homotopic_loops S p (linepath a a)"
  3594   proof (intro exI conjI)
  3595     show "a \<in> S"
  3596       using homotopic_with_imp_subset2 [OF homp]
  3597       by (metis dist_0_norm image_subset_iff mem_sphere norm_one)
  3598     have teq: "\<And>t. \<lbrakk>0 \<le> t; t \<le> 1\<rbrakk>
  3599                \<Longrightarrow> t = Arg (exp (2 * of_real pi * of_real t * \<i>)) / (2 * pi) \<or> t=1 \<and> Arg (exp (2 * of_real pi * of_real t * \<i>)) = 0"
  3600       apply (rule disjCI)
  3601       using Arg_of_real [of 1] apply (auto simp: Arg_exp)
  3602       done
  3603     have "homotopic_loops S p (p \<circ> (\<lambda>z. Arg z / (2 * pi)) \<circ> exp \<circ> (\<lambda>t. 2 * complex_of_real pi * complex_of_real t * \<i>))"
  3604       apply (rule homotopic_loops_eq [OF p])
  3605       using p teq apply (fastforce simp: pathfinish_def pathstart_def)
  3606       done
  3607     then
  3608     show "homotopic_loops S p (linepath a a)"
  3609       by (simp add: linepath_refl  homotopic_loops_trans [OF _ homotopic_circlemaps_imp_homotopic_loops [OF homp, simplified K_record_comp]])
  3610   qed
  3611 qed
  3612 
  3613 
  3614 proposition simply_connected_eq_homotopic_circlemaps:
  3615   fixes S :: "'a::real_normed_vector set"
  3616   shows "simply_connected S \<longleftrightarrow>
  3617          (\<forall>f g::complex \<Rightarrow> 'a.
  3618               continuous_on (sphere 0 1) f \<and> f ` (sphere 0 1) \<subseteq> S \<and>
  3619               continuous_on (sphere 0 1) g \<and> g ` (sphere 0 1) \<subseteq> S
  3620               \<longrightarrow> homotopic_with (\<lambda>h. True) (sphere 0 1) S f g)"
  3621   apply (rule iffI)
  3622    apply (blast elim: dest: simply_connected_eq_homotopic_circlemaps1)
  3623   by (simp add: simply_connected_eq_homotopic_circlemaps2a simply_connected_eq_homotopic_circlemaps2b simply_connected_eq_homotopic_circlemaps3)
  3624 
  3625 proposition simply_connected_eq_contractible_circlemap:
  3626   fixes S :: "'a::real_normed_vector set"
  3627   shows "simply_connected S \<longleftrightarrow>
  3628          path_connected S \<and>
  3629          (\<forall>f::complex \<Rightarrow> 'a.
  3630               continuous_on (sphere 0 1) f \<and> f `(sphere 0 1) \<subseteq> S
  3631               \<longrightarrow> (\<exists>a. homotopic_with (\<lambda>h. True) (sphere 0 1) S f (\<lambda>x. a)))"
  3632   apply (rule iffI)
  3633    apply (simp add: simply_connected_eq_homotopic_circlemaps1 simply_connected_eq_homotopic_circlemaps2a simply_connected_eq_homotopic_circlemaps2b)
  3634   using simply_connected_eq_homotopic_circlemaps3 by blast
  3635 
  3636 corollary homotopy_eqv_simple_connectedness:
  3637   fixes S :: "'a::real_normed_vector set" and T :: "'b::real_normed_vector set"
  3638   shows "S homotopy_eqv T \<Longrightarrow> simply_connected S \<longleftrightarrow> simply_connected T"
  3639   by (simp add: simply_connected_eq_homotopic_circlemaps homotopy_eqv_homotopic_triviality)
  3640 
  3641 
  3642 subsection\<open>Homeomorphism of simple closed curves to circles\<close>
  3643 
  3644 proposition homeomorphic_simple_path_image_circle:
  3645   fixes a :: complex and \<gamma> :: "real \<Rightarrow> 'a::t2_space"
  3646   assumes "simple_path \<gamma>" and loop: "pathfinish \<gamma> = pathstart \<gamma>" and "0 < r"
  3647   shows "(path_image \<gamma>) homeomorphic sphere a r"
  3648 proof -
  3649   have "homotopic_loops (path_image \<gamma>) \<gamma> \<gamma>"
  3650     by (simp add: assms homotopic_loops_refl simple_path_imp_path)
  3651   then have hom: "homotopic_with (\<lambda>h. True) (sphere 0 1) (path_image \<gamma>)
  3652                (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi)))"
  3653     by (rule homotopic_loops_imp_homotopic_circlemaps)
  3654   have "\<exists>g. homeomorphism (sphere 0 1) (path_image \<gamma>) (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) g"
  3655   proof (rule homeomorphism_compact)
  3656     show "continuous_on (sphere 0 1) (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi)))"
  3657       using hom homotopic_with_imp_continuous by blast
  3658     show "inj_on (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) (sphere 0 1)"
  3659     proof
  3660       fix x y
  3661       assume xy: "x \<in> sphere 0 1" "y \<in> sphere 0 1"
  3662          and eq: "(\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) x = (\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) y"
  3663       then have "(Arg x / (2*pi)) = (Arg y / (2*pi))"
  3664       proof -
  3665         have "(Arg x / (2*pi)) \<in> {0..1}" "(Arg y / (2*pi)) \<in> {0..1}"
  3666           using Arg_ge_0 Arg_lt_2pi dual_order.strict_iff_order by fastforce+
  3667         with eq show ?thesis
  3668           using \<open>simple_path \<gamma>\<close> Arg_lt_2pi unfolding simple_path_def o_def
  3669           by (metis eq_divide_eq_1 not_less_iff_gr_or_eq)
  3670       qed
  3671       with xy show "x = y"
  3672         by (metis Arg Arg_0 dist_0_norm divide_cancel_right dual_order.strict_iff_order mem_sphere)
  3673     qed
  3674     have "\<And>z. cmod z = 1 \<Longrightarrow> \<exists>x\<in>{0..1}. \<gamma> (Arg z / (2*pi)) = \<gamma> x"
  3675        by (metis Arg_ge_0 Arg_lt_2pi atLeastAtMost_iff divide_less_eq_1 less_eq_real_def zero_less_mult_iff pi_gt_zero zero_le_divide_iff zero_less_numeral)
  3676      moreover have "\<exists>z\<in>sphere 0 1. \<gamma> x = \<gamma> (Arg z / (2*pi))" if "0 \<le> x" "x \<le> 1" for x
  3677      proof (cases "x=1")
  3678        case True
  3679        then show ?thesis
  3680          apply (rule_tac x=1 in bexI)
  3681          apply (metis loop Arg_of_real divide_eq_0_iff of_real_1 pathfinish_def pathstart_def \<open>0 \<le> x\<close>, auto)
  3682          done
  3683      next
  3684        case False
  3685        then have *: "(Arg (exp (\<i>*(2* of_real pi* of_real x))) / (2*pi)) = x"
  3686          using that by (auto simp: Arg_exp divide_simps)
  3687        show ?thesis
  3688          by (rule_tac x="exp(\<i> * of_real(2*pi*x))" in bexI) (auto simp: *)
  3689     qed
  3690     ultimately show "(\<gamma> \<circ> (\<lambda>z. Arg z / (2*pi))) ` sphere 0 1 = path_image \<gamma>"
  3691       by (auto simp: path_image_def image_iff)
  3692     qed auto
  3693     then have "path_image \<gamma> homeomorphic sphere (0::complex) 1"
  3694       using homeomorphic_def homeomorphic_sym by blast
  3695   also have "... homeomorphic sphere a r"
  3696     by (simp add: assms homeomorphic_spheres)
  3697   finally show ?thesis .
  3698 qed
  3699 
  3700 lemma homeomorphic_simple_path_images:
  3701   fixes \<gamma>1 :: "real \<Rightarrow> 'a::t2_space" and \<gamma>2 :: "real \<Rightarrow> 'b::t2_space"
  3702   assumes "simple_path \<gamma>1" and loop: "pathfinish \<gamma>1 = pathstart \<gamma>1"
  3703   assumes "simple_path \<gamma>2" and loop: "pathfinish \<gamma>2 = pathstart \<gamma>2"
  3704   shows "(path_image \<gamma>1) homeomorphic (path_image \<gamma>2)"
  3705   by (meson assms homeomorphic_simple_path_image_circle homeomorphic_sym homeomorphic_trans loop pi_gt_zero)
  3706 
  3707 end