src/HOL/Limits.thy
author hoelzl
Tue Mar 26 12:20:57 2013 +0100 (2013-03-26)
changeset 51524 7cb5ac44ca9e
parent 51478 270b21f3ae0a
child 51526 155263089e7b
permissions -rw-r--r--
rename RealVector.thy to Real_Vector_Spaces.thy
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports Real_Vector_Spaces
     9 begin
    10 
    11 definition at_infinity :: "'a::real_normed_vector filter" where
    12   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
    13 
    14 lemma eventually_at_infinity:
    15   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    16 unfolding at_infinity_def
    17 proof (rule eventually_Abs_filter, rule is_filter.intro)
    18   fix P Q :: "'a \<Rightarrow> bool"
    19   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
    20   then obtain r s where
    21     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
    22   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
    23   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
    24 qed auto
    25 
    26 lemma at_infinity_eq_at_top_bot:
    27   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    28   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
    29 proof (intro arg_cong[where f=Abs_filter] ext iffI)
    30   fix P :: "real \<Rightarrow> bool" assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    31   then guess r ..
    32   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
    33   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
    34 next
    35   fix P :: "real \<Rightarrow> bool" assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
    36   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
    37   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
    38     by (intro exI[of _ "max p (-q)"])
    39        (auto simp: abs_real_def)
    40 qed
    41 
    42 lemma at_top_le_at_infinity:
    43   "at_top \<le> (at_infinity :: real filter)"
    44   unfolding at_infinity_eq_at_top_bot by simp
    45 
    46 lemma at_bot_le_at_infinity:
    47   "at_bot \<le> (at_infinity :: real filter)"
    48   unfolding at_infinity_eq_at_top_bot by simp
    49 
    50 subsection {* Boundedness *}
    51 
    52 lemma Bfun_def:
    53   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    54   unfolding Bfun_metric_def norm_conv_dist
    55 proof safe
    56   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    57   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    58     by (intro always_eventually) (metis dist_commute dist_triangle)
    59   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    60     by eventually_elim auto
    61   with `0 < K` show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    62     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    63 qed auto
    64 
    65 lemma BfunI:
    66   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    67 unfolding Bfun_def
    68 proof (intro exI conjI allI)
    69   show "0 < max K 1" by simp
    70 next
    71   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    72     using K by (rule eventually_elim1, simp)
    73 qed
    74 
    75 lemma BfunE:
    76   assumes "Bfun f F"
    77   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    78 using assms unfolding Bfun_def by fast
    79 
    80 subsection {* Convergence to Zero *}
    81 
    82 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
    83   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
    84 
    85 lemma ZfunI:
    86   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
    87   unfolding Zfun_def by simp
    88 
    89 lemma ZfunD:
    90   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
    91   unfolding Zfun_def by simp
    92 
    93 lemma Zfun_ssubst:
    94   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
    95   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
    96 
    97 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
    98   unfolding Zfun_def by simp
    99 
   100 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   101   unfolding Zfun_def by simp
   102 
   103 lemma Zfun_imp_Zfun:
   104   assumes f: "Zfun f F"
   105   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   106   shows "Zfun (\<lambda>x. g x) F"
   107 proof (cases)
   108   assume K: "0 < K"
   109   show ?thesis
   110   proof (rule ZfunI)
   111     fix r::real assume "0 < r"
   112     hence "0 < r / K"
   113       using K by (rule divide_pos_pos)
   114     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   115       using ZfunD [OF f] by fast
   116     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   117     proof eventually_elim
   118       case (elim x)
   119       hence "norm (f x) * K < r"
   120         by (simp add: pos_less_divide_eq K)
   121       thus ?case
   122         by (simp add: order_le_less_trans [OF elim(1)])
   123     qed
   124   qed
   125 next
   126   assume "\<not> 0 < K"
   127   hence K: "K \<le> 0" by (simp only: not_less)
   128   show ?thesis
   129   proof (rule ZfunI)
   130     fix r :: real
   131     assume "0 < r"
   132     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   133     proof eventually_elim
   134       case (elim x)
   135       also have "norm (f x) * K \<le> norm (f x) * 0"
   136         using K norm_ge_zero by (rule mult_left_mono)
   137       finally show ?case
   138         using `0 < r` by simp
   139     qed
   140   qed
   141 qed
   142 
   143 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   144   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   145 
   146 lemma Zfun_add:
   147   assumes f: "Zfun f F" and g: "Zfun g F"
   148   shows "Zfun (\<lambda>x. f x + g x) F"
   149 proof (rule ZfunI)
   150   fix r::real assume "0 < r"
   151   hence r: "0 < r / 2" by simp
   152   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   153     using f r by (rule ZfunD)
   154   moreover
   155   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   156     using g r by (rule ZfunD)
   157   ultimately
   158   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   159   proof eventually_elim
   160     case (elim x)
   161     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   162       by (rule norm_triangle_ineq)
   163     also have "\<dots> < r/2 + r/2"
   164       using elim by (rule add_strict_mono)
   165     finally show ?case
   166       by simp
   167   qed
   168 qed
   169 
   170 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   171   unfolding Zfun_def by simp
   172 
   173 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   174   by (simp only: diff_minus Zfun_add Zfun_minus)
   175 
   176 lemma (in bounded_linear) Zfun:
   177   assumes g: "Zfun g F"
   178   shows "Zfun (\<lambda>x. f (g x)) F"
   179 proof -
   180   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   181     using bounded by fast
   182   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   183     by simp
   184   with g show ?thesis
   185     by (rule Zfun_imp_Zfun)
   186 qed
   187 
   188 lemma (in bounded_bilinear) Zfun:
   189   assumes f: "Zfun f F"
   190   assumes g: "Zfun g F"
   191   shows "Zfun (\<lambda>x. f x ** g x) F"
   192 proof (rule ZfunI)
   193   fix r::real assume r: "0 < r"
   194   obtain K where K: "0 < K"
   195     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   196     using pos_bounded by fast
   197   from K have K': "0 < inverse K"
   198     by (rule positive_imp_inverse_positive)
   199   have "eventually (\<lambda>x. norm (f x) < r) F"
   200     using f r by (rule ZfunD)
   201   moreover
   202   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   203     using g K' by (rule ZfunD)
   204   ultimately
   205   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   206   proof eventually_elim
   207     case (elim x)
   208     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   209       by (rule norm_le)
   210     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   211       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   212     also from K have "r * inverse K * K = r"
   213       by simp
   214     finally show ?case .
   215   qed
   216 qed
   217 
   218 lemma (in bounded_bilinear) Zfun_left:
   219   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   220   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   221 
   222 lemma (in bounded_bilinear) Zfun_right:
   223   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   224   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   225 
   226 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   227 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   228 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   229 
   230 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   231   by (simp only: tendsto_iff Zfun_def dist_norm)
   232 
   233 subsubsection {* Distance and norms *}
   234 
   235 lemma tendsto_norm [tendsto_intros]:
   236   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   237   unfolding norm_conv_dist by (intro tendsto_intros)
   238 
   239 lemma continuous_norm [continuous_intros]:
   240   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   241   unfolding continuous_def by (rule tendsto_norm)
   242 
   243 lemma continuous_on_norm [continuous_on_intros]:
   244   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   245   unfolding continuous_on_def by (auto intro: tendsto_norm)
   246 
   247 lemma tendsto_norm_zero:
   248   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   249   by (drule tendsto_norm, simp)
   250 
   251 lemma tendsto_norm_zero_cancel:
   252   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   253   unfolding tendsto_iff dist_norm by simp
   254 
   255 lemma tendsto_norm_zero_iff:
   256   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   257   unfolding tendsto_iff dist_norm by simp
   258 
   259 lemma tendsto_rabs [tendsto_intros]:
   260   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   261   by (fold real_norm_def, rule tendsto_norm)
   262 
   263 lemma continuous_rabs [continuous_intros]:
   264   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   265   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   266 
   267 lemma continuous_on_rabs [continuous_on_intros]:
   268   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   269   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   270 
   271 lemma tendsto_rabs_zero:
   272   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   273   by (fold real_norm_def, rule tendsto_norm_zero)
   274 
   275 lemma tendsto_rabs_zero_cancel:
   276   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   277   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   278 
   279 lemma tendsto_rabs_zero_iff:
   280   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   281   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   282 
   283 subsubsection {* Addition and subtraction *}
   284 
   285 lemma tendsto_add [tendsto_intros]:
   286   fixes a b :: "'a::real_normed_vector"
   287   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   288   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   289 
   290 lemma continuous_add [continuous_intros]:
   291   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   292   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   293   unfolding continuous_def by (rule tendsto_add)
   294 
   295 lemma continuous_on_add [continuous_on_intros]:
   296   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   297   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   298   unfolding continuous_on_def by (auto intro: tendsto_add)
   299 
   300 lemma tendsto_add_zero:
   301   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   302   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   303   by (drule (1) tendsto_add, simp)
   304 
   305 lemma tendsto_minus [tendsto_intros]:
   306   fixes a :: "'a::real_normed_vector"
   307   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   308   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   309 
   310 lemma continuous_minus [continuous_intros]:
   311   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   312   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   313   unfolding continuous_def by (rule tendsto_minus)
   314 
   315 lemma continuous_on_minus [continuous_on_intros]:
   316   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   317   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   318   unfolding continuous_on_def by (auto intro: tendsto_minus)
   319 
   320 lemma tendsto_minus_cancel:
   321   fixes a :: "'a::real_normed_vector"
   322   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   323   by (drule tendsto_minus, simp)
   324 
   325 lemma tendsto_minus_cancel_left:
   326     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   327   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   328   by auto
   329 
   330 lemma tendsto_diff [tendsto_intros]:
   331   fixes a b :: "'a::real_normed_vector"
   332   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   333   by (simp add: diff_minus tendsto_add tendsto_minus)
   334 
   335 lemma continuous_diff [continuous_intros]:
   336   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   337   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   338   unfolding continuous_def by (rule tendsto_diff)
   339 
   340 lemma continuous_on_diff [continuous_on_intros]:
   341   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   342   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   343   unfolding continuous_on_def by (auto intro: tendsto_diff)
   344 
   345 lemma tendsto_setsum [tendsto_intros]:
   346   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   347   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   348   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   349 proof (cases "finite S")
   350   assume "finite S" thus ?thesis using assms
   351     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   352 next
   353   assume "\<not> finite S" thus ?thesis
   354     by (simp add: tendsto_const)
   355 qed
   356 
   357 lemma continuous_setsum [continuous_intros]:
   358   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   359   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   360   unfolding continuous_def by (rule tendsto_setsum)
   361 
   362 lemma continuous_on_setsum [continuous_intros]:
   363   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   364   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   365   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   366 
   367 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   368 
   369 subsubsection {* Linear operators and multiplication *}
   370 
   371 lemma (in bounded_linear) tendsto:
   372   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   373   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   374 
   375 lemma (in bounded_linear) continuous:
   376   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   377   using tendsto[of g _ F] by (auto simp: continuous_def)
   378 
   379 lemma (in bounded_linear) continuous_on:
   380   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   381   using tendsto[of g] by (auto simp: continuous_on_def)
   382 
   383 lemma (in bounded_linear) tendsto_zero:
   384   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   385   by (drule tendsto, simp only: zero)
   386 
   387 lemma (in bounded_bilinear) tendsto:
   388   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   389   by (simp only: tendsto_Zfun_iff prod_diff_prod
   390                  Zfun_add Zfun Zfun_left Zfun_right)
   391 
   392 lemma (in bounded_bilinear) continuous:
   393   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   394   using tendsto[of f _ F g] by (auto simp: continuous_def)
   395 
   396 lemma (in bounded_bilinear) continuous_on:
   397   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   398   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   399 
   400 lemma (in bounded_bilinear) tendsto_zero:
   401   assumes f: "(f ---> 0) F"
   402   assumes g: "(g ---> 0) F"
   403   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   404   using tendsto [OF f g] by (simp add: zero_left)
   405 
   406 lemma (in bounded_bilinear) tendsto_left_zero:
   407   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   408   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   409 
   410 lemma (in bounded_bilinear) tendsto_right_zero:
   411   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   412   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   413 
   414 lemmas tendsto_of_real [tendsto_intros] =
   415   bounded_linear.tendsto [OF bounded_linear_of_real]
   416 
   417 lemmas tendsto_scaleR [tendsto_intros] =
   418   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   419 
   420 lemmas tendsto_mult [tendsto_intros] =
   421   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   422 
   423 lemmas continuous_of_real [continuous_intros] =
   424   bounded_linear.continuous [OF bounded_linear_of_real]
   425 
   426 lemmas continuous_scaleR [continuous_intros] =
   427   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   428 
   429 lemmas continuous_mult [continuous_intros] =
   430   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   431 
   432 lemmas continuous_on_of_real [continuous_on_intros] =
   433   bounded_linear.continuous_on [OF bounded_linear_of_real]
   434 
   435 lemmas continuous_on_scaleR [continuous_on_intros] =
   436   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   437 
   438 lemmas continuous_on_mult [continuous_on_intros] =
   439   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   440 
   441 lemmas tendsto_mult_zero =
   442   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   443 
   444 lemmas tendsto_mult_left_zero =
   445   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   446 
   447 lemmas tendsto_mult_right_zero =
   448   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   449 
   450 lemma tendsto_power [tendsto_intros]:
   451   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   452   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   453   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   454 
   455 lemma continuous_power [continuous_intros]:
   456   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   457   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   458   unfolding continuous_def by (rule tendsto_power)
   459 
   460 lemma continuous_on_power [continuous_on_intros]:
   461   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   462   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   463   unfolding continuous_on_def by (auto intro: tendsto_power)
   464 
   465 lemma tendsto_setprod [tendsto_intros]:
   466   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   467   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   468   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   469 proof (cases "finite S")
   470   assume "finite S" thus ?thesis using assms
   471     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   472 next
   473   assume "\<not> finite S" thus ?thesis
   474     by (simp add: tendsto_const)
   475 qed
   476 
   477 lemma continuous_setprod [continuous_intros]:
   478   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   479   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   480   unfolding continuous_def by (rule tendsto_setprod)
   481 
   482 lemma continuous_on_setprod [continuous_intros]:
   483   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   484   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   485   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   486 
   487 subsubsection {* Inverse and division *}
   488 
   489 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   490   assumes f: "Zfun f F"
   491   assumes g: "Bfun g F"
   492   shows "Zfun (\<lambda>x. f x ** g x) F"
   493 proof -
   494   obtain K where K: "0 \<le> K"
   495     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   496     using nonneg_bounded by fast
   497   obtain B where B: "0 < B"
   498     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   499     using g by (rule BfunE)
   500   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   501   using norm_g proof eventually_elim
   502     case (elim x)
   503     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   504       by (rule norm_le)
   505     also have "\<dots> \<le> norm (f x) * B * K"
   506       by (intro mult_mono' order_refl norm_g norm_ge_zero
   507                 mult_nonneg_nonneg K elim)
   508     also have "\<dots> = norm (f x) * (B * K)"
   509       by (rule mult_assoc)
   510     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   511   qed
   512   with f show ?thesis
   513     by (rule Zfun_imp_Zfun)
   514 qed
   515 
   516 lemma (in bounded_bilinear) flip:
   517   "bounded_bilinear (\<lambda>x y. y ** x)"
   518   apply default
   519   apply (rule add_right)
   520   apply (rule add_left)
   521   apply (rule scaleR_right)
   522   apply (rule scaleR_left)
   523   apply (subst mult_commute)
   524   using bounded by fast
   525 
   526 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   527   assumes f: "Bfun f F"
   528   assumes g: "Zfun g F"
   529   shows "Zfun (\<lambda>x. f x ** g x) F"
   530   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   531 
   532 lemma Bfun_inverse_lemma:
   533   fixes x :: "'a::real_normed_div_algebra"
   534   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   535   apply (subst nonzero_norm_inverse, clarsimp)
   536   apply (erule (1) le_imp_inverse_le)
   537   done
   538 
   539 lemma Bfun_inverse:
   540   fixes a :: "'a::real_normed_div_algebra"
   541   assumes f: "(f ---> a) F"
   542   assumes a: "a \<noteq> 0"
   543   shows "Bfun (\<lambda>x. inverse (f x)) F"
   544 proof -
   545   from a have "0 < norm a" by simp
   546   hence "\<exists>r>0. r < norm a" by (rule dense)
   547   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   548   have "eventually (\<lambda>x. dist (f x) a < r) F"
   549     using tendstoD [OF f r1] by fast
   550   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   551   proof eventually_elim
   552     case (elim x)
   553     hence 1: "norm (f x - a) < r"
   554       by (simp add: dist_norm)
   555     hence 2: "f x \<noteq> 0" using r2 by auto
   556     hence "norm (inverse (f x)) = inverse (norm (f x))"
   557       by (rule nonzero_norm_inverse)
   558     also have "\<dots> \<le> inverse (norm a - r)"
   559     proof (rule le_imp_inverse_le)
   560       show "0 < norm a - r" using r2 by simp
   561     next
   562       have "norm a - norm (f x) \<le> norm (a - f x)"
   563         by (rule norm_triangle_ineq2)
   564       also have "\<dots> = norm (f x - a)"
   565         by (rule norm_minus_commute)
   566       also have "\<dots> < r" using 1 .
   567       finally show "norm a - r \<le> norm (f x)" by simp
   568     qed
   569     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   570   qed
   571   thus ?thesis by (rule BfunI)
   572 qed
   573 
   574 lemma tendsto_inverse [tendsto_intros]:
   575   fixes a :: "'a::real_normed_div_algebra"
   576   assumes f: "(f ---> a) F"
   577   assumes a: "a \<noteq> 0"
   578   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   579 proof -
   580   from a have "0 < norm a" by simp
   581   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   582     by (rule tendstoD)
   583   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   584     unfolding dist_norm by (auto elim!: eventually_elim1)
   585   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   586     - (inverse (f x) * (f x - a) * inverse a)) F"
   587     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   588   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   589     by (intro Zfun_minus Zfun_mult_left
   590       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   591       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   592   ultimately show ?thesis
   593     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   594 qed
   595 
   596 lemma continuous_inverse:
   597   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   598   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   599   shows "continuous F (\<lambda>x. inverse (f x))"
   600   using assms unfolding continuous_def by (rule tendsto_inverse)
   601 
   602 lemma continuous_at_within_inverse[continuous_intros]:
   603   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   604   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   605   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   606   using assms unfolding continuous_within by (rule tendsto_inverse)
   607 
   608 lemma isCont_inverse[continuous_intros, simp]:
   609   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   610   assumes "isCont f a" and "f a \<noteq> 0"
   611   shows "isCont (\<lambda>x. inverse (f x)) a"
   612   using assms unfolding continuous_at by (rule tendsto_inverse)
   613 
   614 lemma continuous_on_inverse[continuous_on_intros]:
   615   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   616   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   617   shows "continuous_on s (\<lambda>x. inverse (f x))"
   618   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   619 
   620 lemma tendsto_divide [tendsto_intros]:
   621   fixes a b :: "'a::real_normed_field"
   622   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   623     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   624   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   625 
   626 lemma continuous_divide:
   627   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   628   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   629   shows "continuous F (\<lambda>x. (f x) / (g x))"
   630   using assms unfolding continuous_def by (rule tendsto_divide)
   631 
   632 lemma continuous_at_within_divide[continuous_intros]:
   633   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   634   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   635   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   636   using assms unfolding continuous_within by (rule tendsto_divide)
   637 
   638 lemma isCont_divide[continuous_intros, simp]:
   639   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   640   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   641   shows "isCont (\<lambda>x. (f x) / g x) a"
   642   using assms unfolding continuous_at by (rule tendsto_divide)
   643 
   644 lemma continuous_on_divide[continuous_on_intros]:
   645   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   646   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   647   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   648   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   649 
   650 lemma tendsto_sgn [tendsto_intros]:
   651   fixes l :: "'a::real_normed_vector"
   652   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   653   unfolding sgn_div_norm by (simp add: tendsto_intros)
   654 
   655 lemma continuous_sgn:
   656   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   657   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   658   shows "continuous F (\<lambda>x. sgn (f x))"
   659   using assms unfolding continuous_def by (rule tendsto_sgn)
   660 
   661 lemma continuous_at_within_sgn[continuous_intros]:
   662   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   663   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   664   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   665   using assms unfolding continuous_within by (rule tendsto_sgn)
   666 
   667 lemma isCont_sgn[continuous_intros]:
   668   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   669   assumes "isCont f a" and "f a \<noteq> 0"
   670   shows "isCont (\<lambda>x. sgn (f x)) a"
   671   using assms unfolding continuous_at by (rule tendsto_sgn)
   672 
   673 lemma continuous_on_sgn[continuous_on_intros]:
   674   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   675   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   676   shows "continuous_on s (\<lambda>x. sgn (f x))"
   677   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   678 
   679 lemma filterlim_at_infinity:
   680   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   681   assumes "0 \<le> c"
   682   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   683   unfolding filterlim_iff eventually_at_infinity
   684 proof safe
   685   fix P :: "'a \<Rightarrow> bool" and b
   686   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   687     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   688   have "max b (c + 1) > c" by auto
   689   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   690     by auto
   691   then show "eventually (\<lambda>x. P (f x)) F"
   692   proof eventually_elim
   693     fix x assume "max b (c + 1) \<le> norm (f x)"
   694     with P show "P (f x)" by auto
   695   qed
   696 qed force
   697 
   698 subsection {* Relate @{const at}, @{const at_left} and @{const at_right} *}
   699 
   700 text {*
   701 
   702 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   703 @{term "at_right x"} and also @{term "at_right 0"}.
   704 
   705 *}
   706 
   707 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   708 
   709 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::real)"
   710   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
   711   by (intro allI ex_cong) (auto simp: dist_real_def field_simps)
   712 
   713 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::real)"
   714   unfolding filter_eq_iff eventually_filtermap eventually_nhds_metric
   715   apply (intro allI ex_cong)
   716   apply (auto simp: dist_real_def field_simps)
   717   apply (erule_tac x="-x" in allE)
   718   apply simp
   719   done
   720 
   721 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::real)"
   722   unfolding at_def filtermap_nhds_shift[symmetric]
   723   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   724 
   725 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   726   unfolding filtermap_at_shift[symmetric]
   727   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   728 
   729 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   730   using filtermap_at_right_shift[of "-a" 0] by simp
   731 
   732 lemma filterlim_at_right_to_0:
   733   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   734   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   735 
   736 lemma eventually_at_right_to_0:
   737   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   738   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   739 
   740 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::real)"
   741   unfolding at_def filtermap_nhds_minus[symmetric]
   742   by (simp add: filter_eq_iff eventually_filtermap eventually_within)
   743 
   744 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   745   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
   746 
   747 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   748   by (simp add: filter_eq_iff eventually_filtermap eventually_within filtermap_at_minus[symmetric])
   749 
   750 lemma filterlim_at_left_to_right:
   751   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   752   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   753 
   754 lemma eventually_at_left_to_right:
   755   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   756   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   757 
   758 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   759   unfolding filter_eq_iff eventually_filtermap eventually_at_top_linorder eventually_at_bot_linorder
   760   by (metis le_minus_iff minus_minus)
   761 
   762 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   763   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   764 
   765 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   766   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   767 
   768 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   769   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   770 
   771 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   772   unfolding filterlim_at_top eventually_at_bot_dense
   773   by (metis leI minus_less_iff order_less_asym)
   774 
   775 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   776   unfolding filterlim_at_bot eventually_at_top_dense
   777   by (metis leI less_minus_iff order_less_asym)
   778 
   779 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   780   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   781   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   782   by auto
   783 
   784 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   785   unfolding filterlim_uminus_at_top by simp
   786 
   787 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   788   unfolding filterlim_at_top_gt[where c=0] eventually_within at_def
   789 proof safe
   790   fix Z :: real assume [arith]: "0 < Z"
   791   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
   792     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
   793   then show "eventually (\<lambda>x. x \<in> - {0} \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
   794     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
   795 qed
   796 
   797 lemma filterlim_inverse_at_top:
   798   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
   799   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
   800      (simp add: filterlim_def eventually_filtermap le_within_iff at_def eventually_elim1)
   801 
   802 lemma filterlim_inverse_at_bot_neg:
   803   "LIM x (at_left (0::real)). inverse x :> at_bot"
   804   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
   805 
   806 lemma filterlim_inverse_at_bot:
   807   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
   808   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
   809   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
   810 
   811 lemma tendsto_inverse_0:
   812   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
   813   shows "(inverse ---> (0::'a)) at_infinity"
   814   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
   815 proof safe
   816   fix r :: real assume "0 < r"
   817   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
   818   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
   819     fix x :: 'a
   820     from `0 < r` have "0 < inverse (r / 2)" by simp
   821     also assume *: "inverse (r / 2) \<le> norm x"
   822     finally show "norm (inverse x) < r"
   823       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
   824   qed
   825 qed
   826 
   827 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
   828 proof (rule antisym)
   829   have "(inverse ---> (0::real)) at_top"
   830     by (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
   831   then show "filtermap inverse at_top \<le> at_right (0::real)"
   832     unfolding at_within_eq
   833     by (intro le_withinI) (simp_all add: eventually_filtermap eventually_gt_at_top filterlim_def)
   834 next
   835   have "filtermap inverse (filtermap inverse (at_right (0::real))) \<le> filtermap inverse at_top"
   836     using filterlim_inverse_at_top_right unfolding filterlim_def by (rule filtermap_mono)
   837   then show "at_right (0::real) \<le> filtermap inverse at_top"
   838     by (simp add: filtermap_ident filtermap_filtermap)
   839 qed
   840 
   841 lemma eventually_at_right_to_top:
   842   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
   843   unfolding at_right_to_top eventually_filtermap ..
   844 
   845 lemma filterlim_at_right_to_top:
   846   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
   847   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
   848 
   849 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
   850   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
   851 
   852 lemma eventually_at_top_to_right:
   853   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
   854   unfolding at_top_to_right eventually_filtermap ..
   855 
   856 lemma filterlim_at_top_to_right:
   857   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
   858   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
   859 
   860 lemma filterlim_inverse_at_infinity:
   861   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
   862   shows "filterlim inverse at_infinity (at (0::'a))"
   863   unfolding filterlim_at_infinity[OF order_refl]
   864 proof safe
   865   fix r :: real assume "0 < r"
   866   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
   867     unfolding eventually_at norm_inverse
   868     by (intro exI[of _ "inverse r"])
   869        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
   870 qed
   871 
   872 lemma filterlim_inverse_at_iff:
   873   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
   874   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
   875   unfolding filterlim_def filtermap_filtermap[symmetric]
   876 proof
   877   assume "filtermap g F \<le> at_infinity"
   878   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
   879     by (rule filtermap_mono)
   880   also have "\<dots> \<le> at 0"
   881     using tendsto_inverse_0
   882     by (auto intro!: le_withinI exI[of _ 1]
   883              simp: eventually_filtermap eventually_at_infinity filterlim_def at_def)
   884   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
   885 next
   886   assume "filtermap inverse (filtermap g F) \<le> at 0"
   887   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
   888     by (rule filtermap_mono)
   889   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
   890     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
   891 qed
   892 
   893 lemma tendsto_inverse_0_at_top:
   894   "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
   895  by (metis at_top_le_at_infinity filterlim_at filterlim_inverse_at_iff filterlim_mono order_refl)
   896 
   897 text {*
   898 
   899 We only show rules for multiplication and addition when the functions are either against a real
   900 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
   901 
   902 *}
   903 
   904 lemma filterlim_tendsto_pos_mult_at_top: 
   905   assumes f: "(f ---> c) F" and c: "0 < c"
   906   assumes g: "LIM x F. g x :> at_top"
   907   shows "LIM x F. (f x * g x :: real) :> at_top"
   908   unfolding filterlim_at_top_gt[where c=0]
   909 proof safe
   910   fix Z :: real assume "0 < Z"
   911   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
   912     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
   913              simp: dist_real_def abs_real_def split: split_if_asm)
   914   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
   915     unfolding filterlim_at_top by auto
   916   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
   917   proof eventually_elim
   918     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
   919     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) \<le> f x * g x"
   920       by (intro mult_mono) (auto simp: zero_le_divide_iff)
   921     with `0 < c` show "Z \<le> f x * g x"
   922        by simp
   923   qed
   924 qed
   925 
   926 lemma filterlim_at_top_mult_at_top: 
   927   assumes f: "LIM x F. f x :> at_top"
   928   assumes g: "LIM x F. g x :> at_top"
   929   shows "LIM x F. (f x * g x :: real) :> at_top"
   930   unfolding filterlim_at_top_gt[where c=0]
   931 proof safe
   932   fix Z :: real assume "0 < Z"
   933   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
   934     unfolding filterlim_at_top by auto
   935   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
   936     unfolding filterlim_at_top by auto
   937   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
   938   proof eventually_elim
   939     fix x assume "1 \<le> f x" "Z \<le> g x"
   940     with `0 < Z` have "1 * Z \<le> f x * g x"
   941       by (intro mult_mono) (auto simp: zero_le_divide_iff)
   942     then show "Z \<le> f x * g x"
   943        by simp
   944   qed
   945 qed
   946 
   947 lemma filterlim_tendsto_pos_mult_at_bot:
   948   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
   949   shows "LIM x F. f x * g x :> at_bot"
   950   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
   951   unfolding filterlim_uminus_at_bot by simp
   952 
   953 lemma filterlim_tendsto_add_at_top: 
   954   assumes f: "(f ---> c) F"
   955   assumes g: "LIM x F. g x :> at_top"
   956   shows "LIM x F. (f x + g x :: real) :> at_top"
   957   unfolding filterlim_at_top_gt[where c=0]
   958 proof safe
   959   fix Z :: real assume "0 < Z"
   960   from f have "eventually (\<lambda>x. c - 1 < f x) F"
   961     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
   962   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
   963     unfolding filterlim_at_top by auto
   964   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
   965     by eventually_elim simp
   966 qed
   967 
   968 lemma LIM_at_top_divide:
   969   fixes f g :: "'a \<Rightarrow> real"
   970   assumes f: "(f ---> a) F" "0 < a"
   971   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
   972   shows "LIM x F. f x / g x :> at_top"
   973   unfolding divide_inverse
   974   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
   975 
   976 lemma filterlim_at_top_add_at_top: 
   977   assumes f: "LIM x F. f x :> at_top"
   978   assumes g: "LIM x F. g x :> at_top"
   979   shows "LIM x F. (f x + g x :: real) :> at_top"
   980   unfolding filterlim_at_top_gt[where c=0]
   981 proof safe
   982   fix Z :: real assume "0 < Z"
   983   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
   984     unfolding filterlim_at_top by auto
   985   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
   986     unfolding filterlim_at_top by auto
   987   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
   988     by eventually_elim simp
   989 qed
   990 
   991 lemma tendsto_divide_0:
   992   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
   993   assumes f: "(f ---> c) F"
   994   assumes g: "LIM x F. g x :> at_infinity"
   995   shows "((\<lambda>x. f x / g x) ---> 0) F"
   996   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
   997 
   998 lemma linear_plus_1_le_power:
   999   fixes x :: real
  1000   assumes x: "0 \<le> x"
  1001   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1002 proof (induct n)
  1003   case (Suc n)
  1004   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1005     by (simp add: field_simps real_of_nat_Suc mult_nonneg_nonneg x)
  1006   also have "\<dots> \<le> (x + 1)^Suc n"
  1007     using Suc x by (simp add: mult_left_mono)
  1008   finally show ?case .
  1009 qed simp
  1010 
  1011 lemma filterlim_realpow_sequentially_gt1:
  1012   fixes x :: "'a :: real_normed_div_algebra"
  1013   assumes x[arith]: "1 < norm x"
  1014   shows "LIM n sequentially. x ^ n :> at_infinity"
  1015 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1016   fix y :: real assume "0 < y"
  1017   have "0 < norm x - 1" by simp
  1018   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1019   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1020   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1021   also have "\<dots> = norm x ^ N" by simp
  1022   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1023     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1024   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1025     unfolding eventually_sequentially
  1026     by (auto simp: norm_power)
  1027 qed simp
  1028 
  1029 
  1030 (* Unfortunately eventually_within was overwritten by Multivariate_Analysis.
  1031    Hence it was references as Limits.within, but now it is Basic_Topology.eventually_within *)
  1032 lemmas eventually_within = eventually_within
  1033 
  1034 end
  1035