src/Pure/sign.ML
author wenzelm
Fri Dec 29 17:24:43 2006 +0100 (2006-12-29)
changeset 21932 7d592dc078e3
parent 21796 481094a3dd1f
child 22086 cf6019fece63
permissions -rw-r--r--
replaced classes by all_classes (topologically sorted);
added minimal_classes;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_const_constraint: xstring * string option -> theory -> theory
    27   val add_const_constraint_i: string * typ option -> theory -> theory
    28   val primitive_class: string * class list -> theory -> theory
    29   val primitive_classrel: class * class -> theory -> theory
    30   val primitive_arity: arity -> theory -> theory
    31   val add_trfuns:
    32     (string * (ast list -> ast)) list *
    33     (string * (term list -> term)) list *
    34     (string * (term list -> term)) list *
    35     (string * (ast list -> ast)) list -> theory -> theory
    36   val add_trfunsT:
    37     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    38   val add_advanced_trfuns:
    39     (string * (Proof.context -> ast list -> ast)) list *
    40     (string * (Proof.context -> term list -> term)) list *
    41     (string * (Proof.context -> term list -> term)) list *
    42     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    43   val add_advanced_trfunsT:
    44     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    45   val add_tokentrfuns:
    46     (string * string * (string -> string * real)) list -> theory -> theory
    47   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    48     -> theory -> theory
    49   val parse_ast_translation: bool * string -> theory -> theory
    50   val parse_translation: bool * string -> theory -> theory
    51   val print_translation: bool * string -> theory -> theory
    52   val typed_print_translation: bool * string -> theory -> theory
    53   val print_ast_translation: bool * string -> theory -> theory
    54   val token_translation: string -> theory -> theory
    55   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    56   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    57   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    58   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    59   val add_path: string -> theory -> theory
    60   val parent_path: theory -> theory
    61   val root_path: theory -> theory
    62   val absolute_path: theory -> theory
    63   val local_path: theory -> theory
    64   val no_base_names: theory -> theory
    65   val qualified_names: theory -> theory
    66   val sticky_prefix: string -> theory -> theory
    67   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    68     theory -> theory
    69   val restore_naming: theory -> theory -> theory
    70   val hide_classes: bool -> xstring list -> theory -> theory
    71   val hide_classes_i: bool -> string list -> theory -> theory
    72   val hide_types: bool -> xstring list -> theory -> theory
    73   val hide_types_i: bool -> string list -> theory -> theory
    74   val hide_consts: bool -> xstring list -> theory -> theory
    75   val hide_consts_i: bool -> string list -> theory -> theory
    76   val hide_names: bool -> string * xstring list -> theory -> theory
    77   val hide_names_i: bool -> string * string list -> theory -> theory
    78 end
    79 
    80 signature SIGN =
    81 sig
    82   val init_data: theory -> theory
    83   val rep_sg: theory ->
    84    {naming: NameSpace.naming,
    85     syn: Syntax.syntax,
    86     tsig: Type.tsig,
    87     consts: Consts.T}
    88   val naming_of: theory -> NameSpace.naming
    89   val base_name: string -> bstring
    90   val full_name: theory -> bstring -> string
    91   val full_name_path: theory -> string -> bstring -> string
    92   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    93   val syn_of: theory -> Syntax.syntax
    94   val tsig_of: theory -> Type.tsig
    95   val classes_of: theory -> Sorts.algebra
    96   val all_classes: theory -> class list
    97   val super_classes: theory -> class -> class list
    98   val defaultS: theory -> sort
    99   val subsort: theory -> sort * sort -> bool
   100   val of_sort: theory -> typ * sort -> bool
   101   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   102   val universal_witness: theory -> (typ * sort) option
   103   val all_sorts_nonempty: theory -> bool
   104   val typ_instance: theory -> typ * typ -> bool
   105   val typ_equiv: theory -> typ * typ -> bool
   106   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   107   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   108   val is_logtype: theory -> string -> bool
   109   val consts_of: theory -> Consts.T
   110   val const_constraint: theory -> string -> typ option
   111   val the_const_constraint: theory -> string -> typ
   112   val const_type: theory -> string -> typ option
   113   val the_const_type: theory -> string -> typ
   114   val declared_tyname: theory -> string -> bool
   115   val declared_const: theory -> string -> bool
   116   val const_monomorphic: theory -> string -> bool
   117   val const_syntax_name: theory -> string -> string
   118   val const_typargs: theory -> string * typ -> typ list
   119   val const_instance: theory -> string * typ list -> typ
   120   val class_space: theory -> NameSpace.T
   121   val type_space: theory -> NameSpace.T
   122   val const_space: theory -> NameSpace.T
   123   val intern_class: theory -> xstring -> string
   124   val extern_class: theory -> string -> xstring
   125   val intern_type: theory -> xstring -> string
   126   val extern_type: theory -> string -> xstring
   127   val intern_const: theory -> xstring -> string
   128   val extern_const: theory -> string -> xstring
   129   val intern_sort: theory -> sort -> sort
   130   val extern_sort: theory -> sort -> sort
   131   val intern_typ: theory -> typ -> typ
   132   val extern_typ: theory -> typ -> typ
   133   val intern_term: theory -> term -> term
   134   val extern_term: (string -> xstring) -> theory -> term -> term
   135   val intern_tycons: theory -> typ -> typ
   136   val pretty_term': Proof.context -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   137   val pretty_term: theory -> term -> Pretty.T
   138   val pretty_typ: theory -> typ -> Pretty.T
   139   val pretty_sort: theory -> sort -> Pretty.T
   140   val pretty_classrel: theory -> class list -> Pretty.T
   141   val pretty_arity: theory -> arity -> Pretty.T
   142   val string_of_term: theory -> term -> string
   143   val string_of_typ: theory -> typ -> string
   144   val string_of_sort: theory -> sort -> string
   145   val string_of_classrel: theory -> class list -> string
   146   val string_of_arity: theory -> arity -> string
   147   val pp: theory -> Pretty.pp
   148   val arity_number: theory -> string -> int
   149   val arity_sorts: theory -> string -> sort -> sort list
   150   val certify_class: theory -> class -> class
   151   val certify_sort: theory -> sort -> sort
   152   val certify_typ: theory -> typ -> typ
   153   val certify_typ_syntax: theory -> typ -> typ
   154   val certify_typ_abbrev: theory -> typ -> typ
   155   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   156   val certify_term: theory -> term -> term * typ * int
   157   val certify_prop: theory -> term -> term * typ * int
   158   val cert_term: theory -> term -> term
   159   val cert_prop: theory -> term -> term
   160   val no_frees: Pretty.pp -> term -> term
   161   val no_vars: Pretty.pp -> term -> term
   162   val cert_def: Pretty.pp -> term -> (string * typ) * term
   163   val read_class: theory -> xstring -> class
   164   val read_sort': Syntax.syntax -> Proof.context -> string -> sort
   165   val read_sort: theory -> string -> sort
   166   val read_arity: theory -> xstring * string list * string -> arity
   167   val cert_arity: theory -> arity -> arity
   168   val read_typ': Syntax.syntax -> Proof.context -> (indexname -> sort option) -> string -> typ
   169   val read_typ_syntax': Syntax.syntax -> Proof.context ->
   170     (indexname -> sort option) -> string -> typ
   171   val read_typ_abbrev': Syntax.syntax -> Proof.context ->
   172     (indexname -> sort option) -> string -> typ
   173   val read_typ: theory * (indexname -> sort option) -> string -> typ
   174   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   175   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   176   val read_tyname: theory -> string -> typ
   177   val read_const: theory -> string -> term
   178   val infer_types_simult: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   179     (indexname -> sort option) -> Name.context -> bool
   180     -> (term list * typ) list -> term list * (indexname * typ) list
   181   val infer_types: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   182     (indexname -> sort option) -> Name.context -> bool
   183     -> term list * typ -> term * (indexname * typ) list
   184   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   185     Proof.context -> (indexname -> typ option) * (indexname -> sort option) ->
   186     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   187   val read_def_terms:
   188     theory * (indexname -> typ option) * (indexname -> sort option) ->
   189     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   190   val simple_read_term: theory -> typ -> string -> term
   191   val read_term: theory -> string -> term
   192   val read_prop: theory -> string -> term
   193   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   194   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   195   val add_abbrev: string -> bstring * term -> theory -> (term * term) * theory
   196   include SIGN_THEORY
   197 end
   198 
   199 structure Sign: SIGN =
   200 struct
   201 
   202 
   203 (** datatype sign **)
   204 
   205 datatype sign = Sign of
   206  {naming: NameSpace.naming,     (*common naming conventions*)
   207   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   208   tsig: Type.tsig,              (*order-sorted signature of types*)
   209   consts: Consts.T};            (*polymorphic constants*)
   210 
   211 fun make_sign (naming, syn, tsig, consts) =
   212   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   213 
   214 structure SignData = TheoryDataFun
   215 (struct
   216   val name = "Pure/sign";
   217   type T = sign;
   218   val copy = I;
   219   fun extend (Sign {syn, tsig, consts, ...}) =
   220     make_sign (NameSpace.default_naming, syn, tsig, consts);
   221 
   222   val empty =
   223     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   224 
   225   fun merge pp (sign1, sign2) =
   226     let
   227       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   228       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   229 
   230       val naming = NameSpace.default_naming;
   231       val syn = Syntax.merge_syntaxes syn1 syn2;
   232       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   233       val consts = Consts.merge (consts1, consts2);
   234     in make_sign (naming, syn, tsig, consts) end;
   235 
   236   fun print _ _ = ();
   237 end);
   238 
   239 val init_data = SignData.init;
   240 
   241 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   242 
   243 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   244   make_sign (f (naming, syn, tsig, consts)));
   245 
   246 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   247 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   248 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   249 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   250 
   251 
   252 (* naming *)
   253 
   254 val naming_of = #naming o rep_sg;
   255 val base_name = NameSpace.base;
   256 val full_name = NameSpace.full o naming_of;
   257 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   258 val declare_name = NameSpace.declare o naming_of;
   259 
   260 
   261 (* syntax *)
   262 
   263 val syn_of = #syn o rep_sg;
   264 
   265 
   266 (* type signature *)
   267 
   268 val tsig_of = #tsig o rep_sg;
   269 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   270 val all_classes = Sorts.all_classes o classes_of;
   271 val minimal_classes = Sorts.minimal_classes o classes_of;
   272 val super_classes = Sorts.super_classes o classes_of;
   273 val defaultS = Type.defaultS o tsig_of;
   274 val subsort = Type.subsort o tsig_of;
   275 val of_sort = Type.of_sort o tsig_of;
   276 val witness_sorts = Type.witness_sorts o tsig_of;
   277 val universal_witness = Type.universal_witness o tsig_of;
   278 val all_sorts_nonempty = is_some o universal_witness;
   279 val typ_instance = Type.typ_instance o tsig_of;
   280 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   281 val typ_match = Type.typ_match o tsig_of;
   282 val typ_unify = Type.unify o tsig_of;
   283 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   284 
   285 
   286 (* polymorphic constants *)
   287 
   288 val consts_of = #consts o rep_sg;
   289 val the_const_constraint = Consts.the_constraint o consts_of;
   290 val const_constraint = try o the_const_constraint;
   291 val the_const_type = Consts.the_declaration o consts_of;
   292 val const_type = try o the_const_type;
   293 val const_monomorphic = Consts.is_monomorphic o consts_of;
   294 val const_syntax_name = Consts.syntax_name o consts_of;
   295 val const_typargs = Consts.typargs o consts_of;
   296 val const_instance = Consts.instance o consts_of;
   297 
   298 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   299 val declared_const = is_some oo const_constraint;
   300 
   301 
   302 
   303 (** intern / extern names **)
   304 
   305 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   306 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   307 val const_space = Consts.space_of o consts_of;
   308 
   309 val intern_class = NameSpace.intern o class_space;
   310 val extern_class = NameSpace.extern o class_space;
   311 val intern_type = NameSpace.intern o type_space;
   312 val extern_type = NameSpace.extern o type_space;
   313 val intern_const = NameSpace.intern o const_space;
   314 val extern_const = NameSpace.extern o const_space;
   315 
   316 val intern_sort = map o intern_class;
   317 val extern_sort = map o extern_class;
   318 
   319 local
   320 
   321 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   322   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   323   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   324 
   325 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   326   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   327   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   328   | map_term _ _ _ (t as Bound _) = t
   329   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   330   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   331 
   332 val add_classesT = Term.fold_atyps
   333   (fn TFree (_, S) => fold (insert (op =)) S
   334     | TVar (_, S) => fold (insert (op =)) S
   335     | _ => I);
   336 
   337 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   338   | add_tyconsT _ = I;
   339 
   340 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   341 
   342 fun mapping add_names f t =
   343   let
   344     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   345     val tab = map_filter f' (add_names t []);
   346     fun get x = the_default x (AList.lookup (op =) tab x);
   347   in get end;
   348 
   349 fun typ_mapping f g thy T =
   350   T |> map_typ
   351     (mapping add_classesT (f thy) T)
   352     (mapping add_tyconsT (g thy) T);
   353 
   354 fun term_mapping f g h thy t =
   355   t |> map_term
   356     (mapping (Term.fold_types add_classesT) (f thy) t)
   357     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   358     (mapping add_consts (h thy) t);
   359 
   360 in
   361 
   362 val intern_typ = typ_mapping intern_class intern_type;
   363 val extern_typ = typ_mapping extern_class extern_type;
   364 val intern_term = term_mapping intern_class intern_type intern_const;
   365 fun extern_term h = term_mapping extern_class extern_type (K h);
   366 val intern_tycons = typ_mapping (K I) intern_type;
   367 
   368 end;
   369 
   370 
   371 
   372 (** pretty printing of terms, types etc. **)
   373 
   374 fun pretty_term' ctxt syn ext t =
   375   let val curried = Context.exists_name Context.CPureN (ProofContext.theory_of ctxt)
   376   in Syntax.pretty_term ext ctxt syn curried t end;
   377 
   378 fun pretty_term thy t =
   379   pretty_term' (ProofContext.init thy) (syn_of thy) (Consts.extern (consts_of thy))
   380     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   381 
   382 fun pretty_typ thy T =
   383   Syntax.pretty_typ (ProofContext.init thy) (syn_of thy) (extern_typ thy T);
   384 
   385 fun pretty_sort thy S =
   386   Syntax.pretty_sort (ProofContext.init thy) (syn_of thy) (extern_sort thy S);
   387 
   388 fun pretty_classrel thy cs = Pretty.block (flat
   389   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   390 
   391 fun pretty_arity thy (a, Ss, S) =
   392   let
   393     val a' = extern_type thy a;
   394     val dom =
   395       if null Ss then []
   396       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   397   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   398 
   399 val string_of_term = Pretty.string_of oo pretty_term;
   400 val string_of_typ = Pretty.string_of oo pretty_typ;
   401 val string_of_sort = Pretty.string_of oo pretty_sort;
   402 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   403 val string_of_arity = Pretty.string_of oo pretty_arity;
   404 
   405 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   406   pretty_classrel thy, pretty_arity thy);
   407 
   408 
   409 
   410 (** certify entities **)    (*exception TYPE*)
   411 
   412 (* certify wrt. type signature *)
   413 
   414 val arity_number = Type.arity_number o tsig_of;
   415 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   416 
   417 fun certify cert = cert o tsig_of o Context.check_thy;
   418 
   419 val certify_class      = certify Type.cert_class;
   420 val certify_sort       = certify Type.cert_sort;
   421 val certify_typ        = certify Type.cert_typ;
   422 val certify_typ_syntax = certify Type.cert_typ_syntax;
   423 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   424 
   425 
   426 (* certify term/prop *)
   427 
   428 local
   429 
   430 fun type_check pp tm =
   431   let
   432     fun err_appl why bs t T u U =
   433       let
   434         val xs = map Free bs;           (*we do not rename here*)
   435         val t' = subst_bounds (xs, t);
   436         val u' = subst_bounds (xs, u);
   437         val msg = cat_lines
   438           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   439       in raise TYPE (msg, [T, U], [t', u']) end;
   440 
   441     fun typ_of (_, Const (_, T)) = T
   442       | typ_of (_, Free  (_, T)) = T
   443       | typ_of (_, Var (_, T)) = T
   444       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   445           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   446       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   447       | typ_of (bs, t $ u) =
   448           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   449             (case T of
   450               Type ("fun", [T1, T2]) =>
   451                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   452             | _ => err_appl "Operator not of function type" bs t T u U)
   453           end;
   454   in typ_of ([], tm) end;
   455 
   456 fun err msg = raise TYPE (msg, [], []);
   457 
   458 fun check_vars (t $ u) = (check_vars t; check_vars u)
   459   | check_vars (Abs (_, _, t)) = check_vars t
   460   | check_vars (Var (xi as (_, i), _)) =
   461       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   462   | check_vars _ = ();
   463 
   464 in
   465 
   466 fun certify' normalize prop pp consts thy tm =
   467   let
   468     val _ = Context.check_thy thy;
   469     val _ = check_vars tm;
   470     val tm' = Term.map_types (certify_typ thy) tm;
   471     val T = type_check pp tm';
   472     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   473     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   474     val tm'' = if normalize then tm'' else tm';
   475   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   476 
   477 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   478 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   479 
   480 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   481 val cert_term = #1 oo certify_term;
   482 val cert_prop = #1 oo certify_prop;
   483 
   484 end;
   485 
   486 
   487 (* specifications *)
   488 
   489 fun no_variables kind add addT mk mkT pp tm =
   490   (case (add tm [], addT tm []) of
   491     ([], []) => tm
   492   | (frees, tfrees) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   493       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") ::
   494        map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   495 
   496 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   497 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   498 
   499 fun cert_def pp tm =
   500   let val ((lhs, rhs), _) = tm
   501     |> no_vars pp
   502     |> Logic.strip_imp_concl
   503     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   504   in (Term.dest_Const (Term.head_of lhs), rhs) end
   505   handle TERM (msg, _) => error msg;
   506 
   507 
   508 
   509 (** read and certify entities **)    (*exception ERROR*)
   510 
   511 (* classes and sorts *)
   512 
   513 fun read_class thy c = certify_class thy (intern_class thy c)
   514   handle TYPE (msg, _, _) => error msg;
   515 
   516 fun read_sort' syn ctxt str =
   517   let
   518     val thy = ProofContext.theory_of ctxt;
   519     val _ = Context.check_thy thy;
   520     val S = intern_sort thy (Syntax.read_sort ctxt syn str);
   521   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   522 
   523 fun read_sort thy str = read_sort' (syn_of thy) (ProofContext.init thy) str;
   524 
   525 
   526 (* type arities *)
   527 
   528 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   529   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   530   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   531 
   532 val read_arity = prep_arity intern_type read_sort;
   533 val cert_arity = prep_arity (K I) certify_sort;
   534 
   535 
   536 (* types *)
   537 
   538 local
   539 
   540 fun gen_read_typ' cert syn ctxt def_sort str =
   541   let
   542     val thy = ProofContext.theory_of ctxt;
   543     val _ = Context.check_thy thy;
   544     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   545     val T = intern_tycons thy (Syntax.read_typ ctxt syn get_sort (intern_sort thy) str);
   546   in cert thy T handle TYPE (msg, _, _) => error msg end
   547   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   548 
   549 fun gen_read_typ cert (thy, def_sort) str =
   550   gen_read_typ' cert (syn_of thy) (ProofContext.init thy) def_sort str;
   551 
   552 in
   553 
   554 fun no_def_sort thy = (thy: theory, K NONE);
   555 
   556 val read_typ'        = gen_read_typ' certify_typ;
   557 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   558 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   559 val read_typ         = gen_read_typ certify_typ;
   560 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   561 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   562 
   563 end;
   564 
   565 
   566 (* type and constant names *)
   567 
   568 fun read_tyname thy raw_c =
   569   let val c = intern_type thy raw_c
   570   in Type (c, replicate (arity_number thy c) dummyT) end;
   571 
   572 val read_const = Consts.read_const o consts_of;
   573 
   574 
   575 
   576 (** infer_types **)         (*exception ERROR*)
   577 
   578 (*
   579   def_type: partial map from indexnames to types (constrains Frees and Vars)
   580   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   581   used: context of already used type variables
   582   freeze: if true then generated parameters are turned into TFrees, else TVars
   583 
   584   termss: lists of alternative parses (only one combination should be type-correct)
   585   typs: expected types
   586 *)
   587 
   588 fun infer_types_simult pp thy consts def_type def_sort used freeze args =
   589   let
   590     val termss = fold_rev (multiply o fst) args [[]];
   591     val typs =
   592       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   593 
   594     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   595         (try (Consts.the_constraint consts)) def_type def_sort (Consts.intern consts)
   596         (intern_tycons thy) (intern_sort thy) used freeze typs ts)
   597       handle TYPE (msg, _, _) => Exn (ERROR msg);
   598 
   599     val err_results = map infer termss;
   600     val errs = map_filter (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   601     val results = map_filter get_result err_results;
   602 
   603     val ambiguity = length termss;
   604     fun ambig_msg () =
   605       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   606         "Got more than one parse tree.\n\
   607         \Retry with smaller Syntax.ambiguity_level for more information."
   608       else "";
   609   in
   610     if null results then (cat_error (ambig_msg ()) (cat_lines errs))
   611     else if length results = 1 then
   612       (if ambiguity > ! Syntax.ambiguity_level then
   613         warning "Fortunately, only one parse tree is type correct.\n\
   614           \You may still want to disambiguate your grammar or your input."
   615       else (); hd results)
   616     else (cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   617       cat_lines (map (Pretty.string_of_term pp) (maps fst results))))
   618   end;
   619 
   620 fun infer_types pp thy consts def_type def_sort used freeze tsT =
   621   apfst hd (infer_types_simult pp thy consts def_type def_sort used freeze [tsT]);
   622 
   623 
   624 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   625 
   626 fun read_def_terms' pp is_logtype syn consts ctxt (types, sorts) used freeze sTs =
   627   let
   628     val thy = ProofContext.theory_of ctxt;
   629     fun read (s, T) =
   630       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   631       in (Syntax.read ctxt is_logtype syn T' s, T') end;
   632   in infer_types_simult pp thy consts types sorts used freeze (map read sTs) end;
   633 
   634 fun read_def_terms (thy, types, sorts) used freeze sTs =
   635   let
   636     val pp = pp thy;
   637     val consts = consts_of thy;
   638     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   639     val (ts, inst) =
   640       read_def_terms' pp (is_logtype thy) (syn_of thy) consts
   641         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   642   in (map cert_consts ts, inst) end;
   643 
   644 fun simple_read_term thy T s =
   645   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   646   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   647 
   648 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   649 fun read_prop thy = simple_read_term thy propT;
   650 
   651 
   652 
   653 (** signature extension functions **)  (*exception ERROR/TYPE*)
   654 
   655 (* add default sort *)
   656 
   657 fun gen_add_defsort prep_sort s thy =
   658   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   659 
   660 val add_defsort = gen_add_defsort read_sort;
   661 val add_defsort_i = gen_add_defsort certify_sort;
   662 
   663 
   664 (* add type constructors *)
   665 
   666 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   667   let
   668     val syn' = Syntax.extend_type_gram types syn;
   669     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   670     val tsig' = Type.add_types naming decls tsig;
   671   in (naming, syn', tsig', consts) end);
   672 
   673 fun add_typedecls decls thy =
   674   let
   675     fun type_of (a, vs: string list, mx) =
   676       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   677       else error ("Duplicate parameters in type declaration: " ^ quote a);
   678   in add_types (map type_of decls) thy end;
   679 
   680 
   681 (* add nonterminals *)
   682 
   683 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   684   let
   685     val syn' = Syntax.extend_consts ns syn;
   686     val tsig' = Type.add_nonterminals naming ns tsig;
   687   in (naming, syn', tsig', consts) end);
   688 
   689 
   690 (* add type abbreviations *)
   691 
   692 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   693   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   694     let
   695       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   696       val a' = Syntax.type_name a mx;
   697       val abbr = (a', vs, prep_typ thy rhs)
   698         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   699       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   700     in (naming, syn', tsig', consts) end);
   701 
   702 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   703 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   704 
   705 
   706 (* modify syntax *)
   707 
   708 fun gen_syntax change_gram prep_typ mode args thy =
   709   let
   710     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   711       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   712   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   713 
   714 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   715 
   716 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   717 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   718 val add_syntax = add_modesyntax Syntax.default_mode;
   719 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   720 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   721 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   722 
   723 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   724   | const_syntax _ _ = NONE;
   725 
   726 fun add_notation mode args thy =
   727   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   728 
   729 
   730 (* add constants *)
   731 
   732 local
   733 
   734 fun gen_add_consts prep_typ authentic raw_args thy =
   735   let
   736     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   737     fun prep (raw_c, raw_T, raw_mx) =
   738       let
   739         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   740         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   741         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   742           cat_error msg ("in declaration of constant " ^ quote c);
   743       in (((c, T), authentic), (c', T, mx)) end;
   744     val args = map prep raw_args;
   745   in
   746     thy
   747     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   748     |> add_syntax_i (map #2 args)
   749   end;
   750 
   751 in
   752 
   753 val add_consts = gen_add_consts (read_typ o no_def_sort) false;
   754 val add_consts_i = gen_add_consts certify_typ false;
   755 val add_consts_authentic = gen_add_consts certify_typ true;
   756 
   757 end;
   758 
   759 
   760 (* add abbreviations *)
   761 
   762 fun add_abbrev mode (c, raw_t) thy =
   763   let
   764     val pp = pp thy;
   765     val prep_tm = Compress.term thy o no_frees pp o
   766       map_types Logic.legacy_varifyT (* FIXME tmp *) o
   767       Term.no_dummy_patterns o cert_term_abbrev thy;
   768     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   769       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   770     val (res, consts') = consts_of thy
   771       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (c, t);
   772   in (res, thy |> map_consts (K consts')) end;
   773 
   774 
   775 (* add constraints *)
   776 
   777 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   778   let
   779     val c = int_const thy raw_c;
   780     fun prepT raw_T =
   781       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   782       in cert_term thy (Const (c, T)); T end
   783       handle TYPE (msg, _, _) => error msg;
   784   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   785 
   786 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   787 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   788 
   789 
   790 (* primitive classes and arities *)
   791 
   792 fun primitive_class (bclass, classes) thy =
   793   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   794     let
   795       val syn' = Syntax.extend_consts [bclass] syn;
   796       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   797     in (naming, syn', tsig', consts) end)
   798   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   799 
   800 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   801 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   802 
   803 
   804 (* add translation functions *)
   805 
   806 local
   807 
   808 fun mk trs = map Syntax.mk_trfun trs;
   809 
   810 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   811   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   812 
   813 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   814 
   815 in
   816 
   817 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   818 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   819 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   820 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   821 
   822 end;
   823 
   824 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   825 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   826 
   827 
   828 (* compile translation functions *)
   829 
   830 local
   831 
   832 fun advancedT false = ""
   833   | advancedT true = "Proof.context -> ";
   834 
   835 fun advancedN false = ""
   836   | advancedN true = "advanced_";
   837 
   838 in
   839 
   840 fun parse_ast_translation (a, txt) =
   841   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   842       "Syntax.ast list -> Syntax.ast)) list")
   843     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   844 
   845 fun parse_translation (a, txt) =
   846   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   847       "term list -> term)) list")
   848     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   849 
   850 fun print_translation (a, txt) =
   851   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   852       "term list -> term)) list")
   853     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   854 
   855 fun print_ast_translation (a, txt) =
   856   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   857       "Syntax.ast list -> Syntax.ast)) list")
   858     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   859 
   860 fun typed_print_translation (a, txt) =
   861   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   862       "bool -> typ -> term list -> term)) list")
   863     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   864 
   865 val token_translation =
   866   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   867     "Sign.add_tokentrfuns token_translation";
   868 
   869 end;
   870 
   871 
   872 (* translation rules *)
   873 
   874 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   875   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   876   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   877 
   878 val add_trrules = gen_trrules Syntax.extend_trrules;
   879 val del_trrules = gen_trrules Syntax.remove_trrules;
   880 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   881 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   882 
   883 
   884 (* modify naming *)
   885 
   886 val add_path        = map_naming o NameSpace.add_path;
   887 val no_base_names   = map_naming NameSpace.no_base_names;
   888 val qualified_names = map_naming NameSpace.qualified_names;
   889 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   890 val set_policy      = map_naming o NameSpace.set_policy;
   891 val restore_naming  = map_naming o K o naming_of;
   892 
   893 val parent_path   = add_path "..";
   894 val root_path     = add_path "/";
   895 val absolute_path = add_path "//";
   896 
   897 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   898 
   899 
   900 (* hide names *)
   901 
   902 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   903 val hide_classes_i = map_tsig oo Type.hide_classes;
   904 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   905 val hide_types_i = map_tsig oo Type.hide_types;
   906 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   907 val hide_consts_i = map_consts oo (fold o Consts.hide);
   908 
   909 local
   910 
   911 val kinds =
   912  [("class", (intern_class, can o certify_class, hide_classes_i)),
   913   ("type", (intern_type, declared_tyname, hide_types_i)),
   914   ("const", (intern_const, declared_const, hide_consts_i))];
   915 
   916 fun gen_hide int b (kind, xnames) thy =
   917   (case AList.lookup (op =) kinds kind of
   918     SOME (intern, check, hide) =>
   919       let
   920         val names = if int then map (intern thy) xnames else xnames;
   921         val bads = filter_out (check thy) names;
   922       in
   923         if null bads then hide b names thy
   924         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   925       end
   926   | NONE => error ("Bad name space specification: " ^ quote kind));
   927 
   928 in
   929 
   930 val hide_names = gen_hide true;
   931 val hide_names_i = gen_hide false;
   932 
   933 end;
   934 
   935 end;