src/HOL/Library/Quotient_Sum.thy
author kuncar
Fri Mar 08 13:21:52 2013 +0100 (2013-03-08)
changeset 51377 7da251a6c16e
parent 47982 7aa35601ff65
child 51956 a4d81cdebf8b
permissions -rw-r--r--
add [relator_mono] and [relator_distr] rules
     1 (*  Title:      HOL/Library/Quotient_Sum.thy
     2     Author:     Cezary Kaliszyk, Christian Urban and Brian Huffman
     3 *)
     4 
     5 header {* Quotient infrastructure for the sum type *}
     6 
     7 theory Quotient_Sum
     8 imports Main Quotient_Syntax
     9 begin
    10 
    11 subsection {* Relator for sum type *}
    12 
    13 fun
    14   sum_rel :: "('a \<Rightarrow> 'c \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> 'd \<Rightarrow> bool) \<Rightarrow> 'a + 'b \<Rightarrow> 'c + 'd \<Rightarrow> bool"
    15 where
    16   "sum_rel R1 R2 (Inl a1) (Inl b1) = R1 a1 b1"
    17 | "sum_rel R1 R2 (Inl a1) (Inr b2) = False"
    18 | "sum_rel R1 R2 (Inr a2) (Inl b1) = False"
    19 | "sum_rel R1 R2 (Inr a2) (Inr b2) = R2 a2 b2"
    20 
    21 lemma sum_rel_unfold:
    22   "sum_rel R1 R2 x y = (case (x, y) of (Inl x, Inl y) \<Rightarrow> R1 x y
    23     | (Inr x, Inr y) \<Rightarrow> R2 x y
    24     | _ \<Rightarrow> False)"
    25   by (cases x) (cases y, simp_all)+
    26 
    27 lemma sum_rel_map1:
    28   "sum_rel R1 R2 (sum_map f1 f2 x) y \<longleftrightarrow> sum_rel (\<lambda>x. R1 (f1 x)) (\<lambda>x. R2 (f2 x)) x y"
    29   by (simp add: sum_rel_unfold split: sum.split)
    30 
    31 lemma sum_rel_map2:
    32   "sum_rel R1 R2 x (sum_map f1 f2 y) \<longleftrightarrow> sum_rel (\<lambda>x y. R1 x (f1 y)) (\<lambda>x y. R2 x (f2 y)) x y"
    33   by (simp add: sum_rel_unfold split: sum.split)
    34 
    35 lemma sum_map_id [id_simps]:
    36   "sum_map id id = id"
    37   by (simp add: id_def sum_map.identity fun_eq_iff)
    38 
    39 lemma sum_rel_eq [id_simps, relator_eq]:
    40   "sum_rel (op =) (op =) = (op =)"
    41   by (simp add: sum_rel_unfold fun_eq_iff split: sum.split)
    42 
    43 lemma split_sum_all: "(\<forall>x. P x) \<longleftrightarrow> (\<forall>x. P (Inl x)) \<and> (\<forall>x. P (Inr x))"
    44   by (metis sum.exhaust) (* TODO: move to Sum_Type.thy *)
    45 
    46 lemma split_sum_ex: "(\<exists>x. P x) \<longleftrightarrow> (\<exists>x. P (Inl x)) \<or> (\<exists>x. P (Inr x))"
    47   by (metis sum.exhaust) (* TODO: move to Sum_Type.thy *)
    48 
    49 lemma sum_rel_mono[relator_mono]:
    50   assumes "A \<le> C"
    51   assumes "B \<le> D"
    52   shows "(sum_rel A B) \<le> (sum_rel C D)"
    53 using assms by (auto simp: sum_rel_unfold split: sum.splits)
    54 
    55 lemma sum_rel_OO[relator_distr]:
    56   "(sum_rel A B) OO (sum_rel C D) = sum_rel (A OO C) (B OO D)"
    57 by (rule ext)+ (auto simp add: sum_rel_unfold OO_def split_sum_ex split: sum.split)
    58 
    59 lemma sum_reflp[reflexivity_rule]:
    60   "reflp R1 \<Longrightarrow> reflp R2 \<Longrightarrow> reflp (sum_rel R1 R2)"
    61   unfolding reflp_def split_sum_all sum_rel.simps by fast
    62 
    63 lemma sum_left_total[reflexivity_rule]:
    64   "left_total R1 \<Longrightarrow> left_total R2 \<Longrightarrow> left_total (sum_rel R1 R2)"
    65   apply (intro left_totalI)
    66   unfolding split_sum_ex 
    67   by (case_tac x) (auto elim: left_totalE)
    68 
    69 lemma sum_symp:
    70   "symp R1 \<Longrightarrow> symp R2 \<Longrightarrow> symp (sum_rel R1 R2)"
    71   unfolding symp_def split_sum_all sum_rel.simps by fast
    72 
    73 lemma sum_transp:
    74   "transp R1 \<Longrightarrow> transp R2 \<Longrightarrow> transp (sum_rel R1 R2)"
    75   unfolding transp_def split_sum_all sum_rel.simps by fast
    76 
    77 lemma sum_equivp [quot_equiv]:
    78   "equivp R1 \<Longrightarrow> equivp R2 \<Longrightarrow> equivp (sum_rel R1 R2)"
    79   by (blast intro: equivpI sum_reflp sum_symp sum_transp elim: equivpE)
    80 
    81 lemma right_total_sum_rel [transfer_rule]:
    82   "right_total R1 \<Longrightarrow> right_total R2 \<Longrightarrow> right_total (sum_rel R1 R2)"
    83   unfolding right_total_def split_sum_all split_sum_ex by simp
    84 
    85 lemma right_unique_sum_rel [transfer_rule]:
    86   "right_unique R1 \<Longrightarrow> right_unique R2 \<Longrightarrow> right_unique (sum_rel R1 R2)"
    87   unfolding right_unique_def split_sum_all by simp
    88 
    89 lemma bi_total_sum_rel [transfer_rule]:
    90   "bi_total R1 \<Longrightarrow> bi_total R2 \<Longrightarrow> bi_total (sum_rel R1 R2)"
    91   using assms unfolding bi_total_def split_sum_all split_sum_ex by simp
    92 
    93 lemma bi_unique_sum_rel [transfer_rule]:
    94   "bi_unique R1 \<Longrightarrow> bi_unique R2 \<Longrightarrow> bi_unique (sum_rel R1 R2)"
    95   using assms unfolding bi_unique_def split_sum_all by simp
    96 
    97 subsection {* Transfer rules for transfer package *}
    98 
    99 lemma Inl_transfer [transfer_rule]: "(A ===> sum_rel A B) Inl Inl"
   100   unfolding fun_rel_def by simp
   101 
   102 lemma Inr_transfer [transfer_rule]: "(B ===> sum_rel A B) Inr Inr"
   103   unfolding fun_rel_def by simp
   104 
   105 lemma sum_case_transfer [transfer_rule]:
   106   "((A ===> C) ===> (B ===> C) ===> sum_rel A B ===> C) sum_case sum_case"
   107   unfolding fun_rel_def sum_rel_unfold by (simp split: sum.split)
   108 
   109 subsection {* Setup for lifting package *}
   110 
   111 lemma Quotient_sum[quot_map]:
   112   assumes "Quotient R1 Abs1 Rep1 T1"
   113   assumes "Quotient R2 Abs2 Rep2 T2"
   114   shows "Quotient (sum_rel R1 R2) (sum_map Abs1 Abs2)
   115     (sum_map Rep1 Rep2) (sum_rel T1 T2)"
   116   using assms unfolding Quotient_alt_def
   117   by (simp add: split_sum_all)
   118 
   119 fun sum_pred :: "('a \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> bool) \<Rightarrow> 'a + 'b \<Rightarrow> bool"
   120 where
   121   "sum_pred R1 R2 (Inl a) = R1 a"
   122 | "sum_pred R1 R2 (Inr a) = R2 a"
   123 
   124 lemma sum_invariant_commute [invariant_commute]: 
   125   "sum_rel (Lifting.invariant P1) (Lifting.invariant P2) = Lifting.invariant (sum_pred P1 P2)"
   126   apply (simp add: fun_eq_iff Lifting.invariant_def)
   127   apply (intro allI) 
   128   apply (case_tac x rule: sum.exhaust)
   129   apply (case_tac xa rule: sum.exhaust)
   130   apply auto[2]
   131   apply (case_tac xa rule: sum.exhaust)
   132   apply auto
   133 done
   134 
   135 subsection {* Rules for quotient package *}
   136 
   137 lemma sum_quotient [quot_thm]:
   138   assumes q1: "Quotient3 R1 Abs1 Rep1"
   139   assumes q2: "Quotient3 R2 Abs2 Rep2"
   140   shows "Quotient3 (sum_rel R1 R2) (sum_map Abs1 Abs2) (sum_map Rep1 Rep2)"
   141   apply (rule Quotient3I)
   142   apply (simp_all add: sum_map.compositionality comp_def sum_map.identity sum_rel_eq sum_rel_map1 sum_rel_map2
   143     Quotient3_abs_rep [OF q1] Quotient3_rel_rep [OF q1] Quotient3_abs_rep [OF q2] Quotient3_rel_rep [OF q2])
   144   using Quotient3_rel [OF q1] Quotient3_rel [OF q2]
   145   apply (simp add: sum_rel_unfold comp_def split: sum.split)
   146   done
   147 
   148 declare [[mapQ3 sum = (sum_rel, sum_quotient)]]
   149 
   150 lemma sum_Inl_rsp [quot_respect]:
   151   assumes q1: "Quotient3 R1 Abs1 Rep1"
   152   assumes q2: "Quotient3 R2 Abs2 Rep2"
   153   shows "(R1 ===> sum_rel R1 R2) Inl Inl"
   154   by auto
   155 
   156 lemma sum_Inr_rsp [quot_respect]:
   157   assumes q1: "Quotient3 R1 Abs1 Rep1"
   158   assumes q2: "Quotient3 R2 Abs2 Rep2"
   159   shows "(R2 ===> sum_rel R1 R2) Inr Inr"
   160   by auto
   161 
   162 lemma sum_Inl_prs [quot_preserve]:
   163   assumes q1: "Quotient3 R1 Abs1 Rep1"
   164   assumes q2: "Quotient3 R2 Abs2 Rep2"
   165   shows "(Rep1 ---> sum_map Abs1 Abs2) Inl = Inl"
   166   apply(simp add: fun_eq_iff)
   167   apply(simp add: Quotient3_abs_rep[OF q1])
   168   done
   169 
   170 lemma sum_Inr_prs [quot_preserve]:
   171   assumes q1: "Quotient3 R1 Abs1 Rep1"
   172   assumes q2: "Quotient3 R2 Abs2 Rep2"
   173   shows "(Rep2 ---> sum_map Abs1 Abs2) Inr = Inr"
   174   apply(simp add: fun_eq_iff)
   175   apply(simp add: Quotient3_abs_rep[OF q2])
   176   done
   177 
   178 end