src/HOL/Tools/inductive.ML
author wenzelm
Fri Jul 24 22:59:08 2009 +0200 (2009-07-24)
changeset 32181 7e460c2d4223
parent 32172 c4e55f30d527
child 32602 f2b741473860
permissions -rw-r--r--
more antiquotations instead of adhoc ML stuff;
     1 (*  Title:      HOL/Tools/inductive.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 (Co)Inductive Definition module for HOL.
     6 
     7 Features:
     8   * least or greatest fixedpoints
     9   * mutually recursive definitions
    10   * definitions involving arbitrary monotone operators
    11   * automatically proves introduction and elimination rules
    12 
    13   Introduction rules have the form
    14   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    15   where M is some monotone operator (usually the identity)
    16   Q x is any side condition on the free variables
    17   ti, t are any terms
    18   Pj, Pk are two of the predicates being defined in mutual recursion
    19 *)
    20 
    21 signature BASIC_INDUCTIVE =
    22 sig
    23   type inductive_result
    24   val morph_result: morphism -> inductive_result -> inductive_result
    25   type inductive_info
    26   val the_inductive: Proof.context -> string -> inductive_info
    27   val print_inductives: Proof.context -> unit
    28   val mono_add: attribute
    29   val mono_del: attribute
    30   val get_monos: Proof.context -> thm list
    31   val mk_cases: Proof.context -> term -> thm
    32   val inductive_forall_name: string
    33   val inductive_forall_def: thm
    34   val rulify: thm -> thm
    35   val inductive_cases: (Attrib.binding * string list) list -> local_theory ->
    36     thm list list * local_theory
    37   val inductive_cases_i: (Attrib.binding * term list) list -> local_theory ->
    38     thm list list * local_theory
    39   type inductive_flags
    40   val add_inductive_i:
    41     inductive_flags -> ((binding * typ) * mixfix) list ->
    42     (string * typ) list -> (Attrib.binding * term) list -> thm list -> local_theory ->
    43     inductive_result * local_theory
    44   val add_inductive: bool -> bool ->
    45     (binding * string option * mixfix) list ->
    46     (binding * string option * mixfix) list ->
    47     (Attrib.binding * string) list ->
    48     (Facts.ref * Attrib.src list) list ->
    49     bool -> local_theory -> inductive_result * local_theory
    50   val add_inductive_global: string -> inductive_flags ->
    51     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    52     thm list -> theory -> inductive_result * theory
    53   val arities_of: thm -> (string * int) list
    54   val params_of: thm -> term list
    55   val partition_rules: thm -> thm list -> (string * thm list) list
    56   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    57   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    58   val infer_intro_vars: thm -> int -> thm list -> term list list
    59   val setup: theory -> theory
    60 end;
    61 
    62 signature INDUCTIVE =
    63 sig
    64   include BASIC_INDUCTIVE
    65   type add_ind_def
    66   val declare_rules: string -> binding -> bool -> bool -> string list ->
    67     thm list -> binding list -> Attrib.src list list -> (thm * string list) list ->
    68     thm -> local_theory -> thm list * thm list * thm * local_theory
    69   val add_ind_def: add_ind_def
    70   val gen_add_inductive_i: add_ind_def -> inductive_flags ->
    71     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    72     thm list -> local_theory -> inductive_result * local_theory
    73   val gen_add_inductive: add_ind_def -> bool -> bool ->
    74     (binding * string option * mixfix) list ->
    75     (binding * string option * mixfix) list ->
    76     (Attrib.binding * string) list -> (Facts.ref * Attrib.src list) list ->
    77     bool -> local_theory -> inductive_result * local_theory
    78   val gen_ind_decl: add_ind_def -> bool ->
    79     OuterParse.token list -> (bool -> local_theory -> local_theory) * OuterParse.token list
    80 end;
    81 
    82 structure Inductive: INDUCTIVE =
    83 struct
    84 
    85 
    86 (** theory context references **)
    87 
    88 val inductive_forall_name = "HOL.induct_forall";
    89 val inductive_forall_def = thm "induct_forall_def";
    90 val inductive_conj_name = "HOL.induct_conj";
    91 val inductive_conj_def = thm "induct_conj_def";
    92 val inductive_conj = thms "induct_conj";
    93 val inductive_atomize = thms "induct_atomize";
    94 val inductive_rulify = thms "induct_rulify";
    95 val inductive_rulify_fallback = thms "induct_rulify_fallback";
    96 
    97 val notTrueE = TrueI RSN (2, notE);
    98 val notFalseI = Seq.hd (atac 1 notI);
    99 
   100 val simp_thms' = map mk_meta_eq
   101   @{lemma "(~True) = False" "(~False) = True"
   102       "(True --> P) = P" "(False --> P) = True"
   103       "(P & True) = P" "(True & P) = P"
   104     by (fact simp_thms)+};
   105 
   106 
   107 
   108 (** context data **)
   109 
   110 type inductive_result =
   111   {preds: term list, elims: thm list, raw_induct: thm,
   112    induct: thm, intrs: thm list};
   113 
   114 fun morph_result phi {preds, elims, raw_induct: thm, induct, intrs} =
   115   let
   116     val term = Morphism.term phi;
   117     val thm = Morphism.thm phi;
   118     val fact = Morphism.fact phi;
   119   in
   120    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   121     induct = thm induct, intrs = fact intrs}
   122   end;
   123 
   124 type inductive_info =
   125   {names: string list, coind: bool} * inductive_result;
   126 
   127 structure InductiveData = GenericDataFun
   128 (
   129   type T = inductive_info Symtab.table * thm list;
   130   val empty = (Symtab.empty, []);
   131   val extend = I;
   132   fun merge _ ((tab1, monos1), (tab2, monos2)) =
   133     (Symtab.merge (K true) (tab1, tab2), Thm.merge_thms (monos1, monos2));
   134 );
   135 
   136 val get_inductives = InductiveData.get o Context.Proof;
   137 
   138 fun print_inductives ctxt =
   139   let
   140     val (tab, monos) = get_inductives ctxt;
   141     val space = Consts.space_of (ProofContext.consts_of ctxt);
   142   in
   143     [Pretty.strs ("(co)inductives:" :: map #1 (NameSpace.extern_table (space, tab))),
   144      Pretty.big_list "monotonicity rules:" (map (Display.pretty_thm ctxt) monos)]
   145     |> Pretty.chunks |> Pretty.writeln
   146   end;
   147 
   148 
   149 (* get and put data *)
   150 
   151 fun the_inductive ctxt name =
   152   (case Symtab.lookup (#1 (get_inductives ctxt)) name of
   153     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   154   | SOME info => info);
   155 
   156 fun put_inductives names info = InductiveData.map
   157   (apfst (fold (fn name => Symtab.update (name, info)) names));
   158 
   159 
   160 
   161 (** monotonicity rules **)
   162 
   163 val get_monos = #2 o get_inductives;
   164 val map_monos = InductiveData.map o apsnd;
   165 
   166 fun mk_mono thm =
   167   let
   168     val concl = concl_of thm;
   169     fun eq2mono thm' = [thm' RS (thm' RS eq_to_mono)] @
   170       (case concl of
   171           (_ $ (_ $ (Const ("Not", _) $ _) $ _)) => []
   172         | _ => [thm' RS (thm' RS eq_to_mono2)]);
   173     fun dest_less_concl thm = dest_less_concl (thm RS le_funD)
   174       handle THM _ => thm RS le_boolD
   175   in
   176     case concl of
   177       Const ("==", _) $ _ $ _ => eq2mono (thm RS meta_eq_to_obj_eq)
   178     | _ $ (Const ("op =", _) $ _ $ _) => eq2mono thm
   179     | _ $ (Const ("HOL.ord_class.less_eq", _) $ _ $ _) =>
   180       [dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   181          (resolve_tac [le_funI, le_boolI'])) thm))]
   182     | _ => [thm]
   183   end handle THM _ =>
   184     error ("Bad monotonicity theorem:\n" ^ Display.string_of_thm_without_context thm);
   185 
   186 val mono_add = Thm.declaration_attribute (map_monos o fold Thm.add_thm o mk_mono);
   187 val mono_del = Thm.declaration_attribute (map_monos o fold Thm.del_thm o mk_mono);
   188 
   189 
   190 
   191 (** misc utilities **)
   192 
   193 fun message quiet_mode s = if quiet_mode then () else writeln s;
   194 fun clean_message quiet_mode s = if ! quick_and_dirty then () else message quiet_mode s;
   195 
   196 fun coind_prefix true = "co"
   197   | coind_prefix false = "";
   198 
   199 fun log (b:int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   200 
   201 fun make_bool_args f g [] i = []
   202   | make_bool_args f g (x :: xs) i =
   203       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   204 
   205 fun make_bool_args' xs =
   206   make_bool_args (K HOLogic.false_const) (K HOLogic.true_const) xs;
   207 
   208 fun find_arg T x [] = sys_error "find_arg"
   209   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   210       apsnd (cons p) (find_arg T x ps)
   211   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   212       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   213       else apsnd (cons p) (find_arg T x ps);
   214 
   215 fun make_args Ts xs =
   216   map (fn (T, (NONE, ())) => Const (@{const_name undefined}, T) | (_, (SOME t, ())) => t)
   217     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   218 
   219 fun make_args' Ts xs Us =
   220   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   221 
   222 fun dest_predicate cs params t =
   223   let
   224     val k = length params;
   225     val (c, ts) = strip_comb t;
   226     val (xs, ys) = chop k ts;
   227     val i = find_index (fn c' => c' = c) cs;
   228   in
   229     if xs = params andalso i >= 0 then
   230       SOME (c, i, ys, chop (length ys)
   231         (List.drop (binder_types (fastype_of c), k)))
   232     else NONE
   233   end;
   234 
   235 fun mk_names a 0 = []
   236   | mk_names a 1 = [a]
   237   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   238 
   239 
   240 
   241 (** process rules **)
   242 
   243 local
   244 
   245 fun err_in_rule ctxt name t msg =
   246   error (cat_lines ["Ill-formed introduction rule " ^ quote name,
   247     Syntax.string_of_term ctxt t, msg]);
   248 
   249 fun err_in_prem ctxt name t p msg =
   250   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   251     "in introduction rule " ^ quote name, Syntax.string_of_term ctxt t, msg]);
   252 
   253 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   254 
   255 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   256 
   257 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   258 
   259 fun atomize_term thy = MetaSimplifier.rewrite_term thy inductive_atomize [];
   260 
   261 in
   262 
   263 fun check_rule ctxt cs params ((binding, att), rule) =
   264   let
   265     val err_name = Binding.str_of binding;
   266     val params' = Term.variant_frees rule (Logic.strip_params rule);
   267     val frees = rev (map Free params');
   268     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   269     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   270     val rule' = Logic.list_implies (prems, concl);
   271     val aprems = map (atomize_term (ProofContext.theory_of ctxt)) prems;
   272     val arule = list_all_free (params', Logic.list_implies (aprems, concl));
   273 
   274     fun check_ind err t = case dest_predicate cs params t of
   275         NONE => err (bad_app ^
   276           commas (map (Syntax.string_of_term ctxt) params))
   277       | SOME (_, _, ys, _) =>
   278           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   279           then err bad_ind_occ else ();
   280 
   281     fun check_prem' prem t =
   282       if head_of t mem cs then
   283         check_ind (err_in_prem ctxt err_name rule prem) t
   284       else (case t of
   285           Abs (_, _, t) => check_prem' prem t
   286         | t $ u => (check_prem' prem t; check_prem' prem u)
   287         | _ => ());
   288 
   289     fun check_prem (prem, aprem) =
   290       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   291       else err_in_prem ctxt err_name rule prem "Non-atomic premise";
   292   in
   293     (case concl of
   294        Const ("Trueprop", _) $ t =>
   295          if head_of t mem cs then
   296            (check_ind (err_in_rule ctxt err_name rule') t;
   297             List.app check_prem (prems ~~ aprems))
   298          else err_in_rule ctxt err_name rule' bad_concl
   299      | _ => err_in_rule ctxt err_name rule' bad_concl);
   300     ((binding, att), arule)
   301   end;
   302 
   303 val rulify =
   304   hol_simplify inductive_conj
   305   #> hol_simplify inductive_rulify
   306   #> hol_simplify inductive_rulify_fallback
   307   #> Simplifier.norm_hhf;
   308 
   309 end;
   310 
   311 
   312 
   313 (** proofs for (co)inductive predicates **)
   314 
   315 (* prove monotonicity *)
   316 
   317 fun prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt =
   318  (message (quiet_mode orelse skip_mono andalso !quick_and_dirty orelse fork_mono)
   319     "  Proving monotonicity ...";
   320   (if skip_mono then SkipProof.prove else if fork_mono then Goal.prove_future else Goal.prove) ctxt
   321     [] []
   322     (HOLogic.mk_Trueprop
   323       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   324     (fn _ => EVERY [rtac @{thm monoI} 1,
   325       REPEAT (resolve_tac [le_funI, le_boolI'] 1),
   326       REPEAT (FIRST
   327         [atac 1,
   328          resolve_tac (List.concat (map mk_mono monos) @ get_monos ctxt) 1,
   329          etac le_funE 1, dtac le_boolD 1])]));
   330 
   331 
   332 (* prove introduction rules *)
   333 
   334 fun prove_intrs quiet_mode coind mono fp_def k params intr_ts rec_preds_defs ctxt =
   335   let
   336     val _ = clean_message quiet_mode "  Proving the introduction rules ...";
   337 
   338     val unfold = funpow k (fn th => th RS fun_cong)
   339       (mono RS (fp_def RS
   340         (if coind then def_gfp_unfold else def_lfp_unfold)));
   341 
   342     fun select_disj 1 1 = []
   343       | select_disj _ 1 = [rtac disjI1]
   344       | select_disj n i = (rtac disjI2)::(select_disj (n - 1) (i - 1));
   345 
   346     val rules = [refl, TrueI, notFalseI, exI, conjI];
   347 
   348     val intrs = map_index (fn (i, intr) => rulify
   349       (SkipProof.prove ctxt (map (fst o dest_Free) params) [] intr (fn _ => EVERY
   350        [rewrite_goals_tac rec_preds_defs,
   351         rtac (unfold RS iffD2) 1,
   352         EVERY1 (select_disj (length intr_ts) (i + 1)),
   353         (*Not ares_tac, since refl must be tried before any equality assumptions;
   354           backtracking may occur if the premises have extra variables!*)
   355         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)]))) intr_ts
   356 
   357   in (intrs, unfold) end;
   358 
   359 
   360 (* prove elimination rules *)
   361 
   362 fun prove_elims quiet_mode cs params intr_ts intr_names unfold rec_preds_defs ctxt =
   363   let
   364     val _ = clean_message quiet_mode "  Proving the elimination rules ...";
   365 
   366     val ([pname], ctxt') = ctxt |>
   367       Variable.add_fixes (map (fst o dest_Free) params) |> snd |>
   368       Variable.variant_fixes ["P"];
   369     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   370 
   371     fun dest_intr r =
   372       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   373        Logic.strip_assums_hyp r, Logic.strip_params r);
   374 
   375     val intrs = map dest_intr intr_ts ~~ intr_names;
   376 
   377     val rules1 = [disjE, exE, FalseE];
   378     val rules2 = [conjE, FalseE, notTrueE];
   379 
   380     fun prove_elim c =
   381       let
   382         val Ts = List.drop (binder_types (fastype_of c), length params);
   383         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   384         val frees = map Free (anames ~~ Ts);
   385 
   386         fun mk_elim_prem ((_, _, us, _), ts, params') =
   387           list_all (params',
   388             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   389               (frees ~~ us) @ ts, P));
   390         val c_intrs = (List.filter (equal c o #1 o #1 o #1) intrs);
   391         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   392            map mk_elim_prem (map #1 c_intrs)
   393       in
   394         (SkipProof.prove ctxt'' [] prems P
   395           (fn {prems, ...} => EVERY
   396             [cut_facts_tac [hd prems] 1,
   397              rewrite_goals_tac rec_preds_defs,
   398              dtac (unfold RS iffD1) 1,
   399              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   400              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   401              EVERY (map (fn prem =>
   402                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   403           |> rulify
   404           |> singleton (ProofContext.export ctxt'' ctxt),
   405          map #2 c_intrs)
   406       end
   407 
   408    in map prove_elim cs end;
   409 
   410 
   411 (* derivation of simplified elimination rules *)
   412 
   413 local
   414 
   415 (*delete needless equality assumptions*)
   416 val refl_thin = Goal.prove_global @{theory HOL} [] [] @{prop "!!P. a = a ==> P ==> P"}
   417   (fn _ => assume_tac 1);
   418 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   419 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   420 
   421 fun simp_case_tac ss i =
   422   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   423 
   424 in
   425 
   426 fun mk_cases ctxt prop =
   427   let
   428     val thy = ProofContext.theory_of ctxt;
   429     val ss = simpset_of ctxt;
   430 
   431     fun err msg =
   432       error (Pretty.string_of (Pretty.block
   433         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   434 
   435     val elims = Induct.find_casesP ctxt prop;
   436 
   437     val cprop = Thm.cterm_of thy prop;
   438     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   439     fun mk_elim rl =
   440       Thm.implies_intr cprop (Tactic.rule_by_tactic tac (Thm.assume cprop RS rl))
   441       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   442   in
   443     (case get_first (try mk_elim) elims of
   444       SOME r => r
   445     | NONE => err "Proposition not an inductive predicate:")
   446   end;
   447 
   448 end;
   449 
   450 
   451 (* inductive_cases *)
   452 
   453 fun gen_inductive_cases prep_att prep_prop args lthy =
   454   let
   455     val thy = ProofContext.theory_of lthy;
   456     val facts = args |> map (fn ((a, atts), props) =>
   457       ((a, map (prep_att thy) atts),
   458         map (Thm.no_attributes o single o mk_cases lthy o prep_prop lthy) props));
   459   in lthy |> LocalTheory.notes Thm.generatedK facts |>> map snd end;
   460 
   461 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   462 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   463 
   464 
   465 val ind_cases_setup =
   466   Method.setup @{binding ind_cases}
   467     (Scan.lift (Scan.repeat1 Args.name_source --
   468       Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.name) []) >>
   469       (fn (raw_props, fixes) => fn ctxt =>
   470         let
   471           val (_, ctxt') = Variable.add_fixes fixes ctxt;
   472           val props = Syntax.read_props ctxt' raw_props;
   473           val ctxt'' = fold Variable.declare_term props ctxt';
   474           val rules = ProofContext.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   475         in Method.erule 0 rules end))
   476     "dynamic case analysis on predicates";
   477 
   478 
   479 (* prove induction rule *)
   480 
   481 fun prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono
   482     fp_def rec_preds_defs ctxt =
   483   let
   484     val _ = clean_message quiet_mode "  Proving the induction rule ...";
   485     val thy = ProofContext.theory_of ctxt;
   486 
   487     (* predicates for induction rule *)
   488 
   489     val (pnames, ctxt') = ctxt |>
   490       Variable.add_fixes (map (fst o dest_Free) params) |> snd |>
   491       Variable.variant_fixes (mk_names "P" (length cs));
   492     val preds = map Free (pnames ~~
   493       map (fn c => List.drop (binder_types (fastype_of c), length params) --->
   494         HOLogic.boolT) cs);
   495 
   496     (* transform an introduction rule into a premise for induction rule *)
   497 
   498     fun mk_ind_prem r =
   499       let
   500         fun subst s = (case dest_predicate cs params s of
   501             SOME (_, i, ys, (_, Ts)) =>
   502               let
   503                 val k = length Ts;
   504                 val bs = map Bound (k - 1 downto 0);
   505                 val P = list_comb (List.nth (preds, i),
   506                   map (incr_boundvars k) ys @ bs);
   507                 val Q = list_abs (mk_names "x" k ~~ Ts,
   508                   HOLogic.mk_binop inductive_conj_name
   509                     (list_comb (incr_boundvars k s, bs), P))
   510               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   511           | NONE => (case s of
   512               (t $ u) => (fst (subst t) $ fst (subst u), NONE)
   513             | (Abs (a, T, t)) => (Abs (a, T, fst (subst t)), NONE)
   514             | _ => (s, NONE)));
   515 
   516         fun mk_prem (s, prems) = (case subst s of
   517               (_, SOME (t, u)) => t :: u :: prems
   518             | (t, _) => t :: prems);
   519 
   520         val SOME (_, i, ys, _) = dest_predicate cs params
   521           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))
   522 
   523       in list_all_free (Logic.strip_params r,
   524         Logic.list_implies (map HOLogic.mk_Trueprop (List.foldr mk_prem
   525           [] (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r))),
   526             HOLogic.mk_Trueprop (list_comb (List.nth (preds, i), ys))))
   527       end;
   528 
   529     val ind_prems = map mk_ind_prem intr_ts;
   530 
   531 
   532     (* make conclusions for induction rules *)
   533 
   534     val Tss = map (binder_types o fastype_of) preds;
   535     val (xnames, ctxt'') =
   536       Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   537     val mutual_ind_concl = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   538         (map (fn (((xnames, Ts), c), P) =>
   539            let val frees = map Free (xnames ~~ Ts)
   540            in HOLogic.mk_imp
   541              (list_comb (c, params @ frees), list_comb (P, frees))
   542            end) (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   543 
   544 
   545     (* make predicate for instantiation of abstract induction rule *)
   546 
   547     val ind_pred = fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   548       (map_index (fn (i, P) => List.foldr HOLogic.mk_imp
   549          (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))
   550          (make_bool_args HOLogic.mk_not I bs i)) preds));
   551 
   552     val ind_concl = HOLogic.mk_Trueprop
   553       (HOLogic.mk_binrel "HOL.ord_class.less_eq" (rec_const, ind_pred));
   554 
   555     val raw_fp_induct = (mono RS (fp_def RS def_lfp_induct));
   556 
   557     val induct = SkipProof.prove ctxt'' [] ind_prems ind_concl
   558       (fn {prems, ...} => EVERY
   559         [rewrite_goals_tac [inductive_conj_def],
   560          DETERM (rtac raw_fp_induct 1),
   561          REPEAT (resolve_tac [le_funI, le_boolI] 1),
   562          rewrite_goals_tac (inf_fun_eq :: inf_bool_eq :: simp_thms'),
   563          (*This disjE separates out the introduction rules*)
   564          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   565          (*Now break down the individual cases.  No disjE here in case
   566            some premise involves disjunction.*)
   567          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   568          REPEAT (FIRSTGOAL
   569            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   570          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   571              (inductive_conj_def :: rec_preds_defs @ simp_thms') prem,
   572            conjI, refl] 1)) prems)]);
   573 
   574     val lemma = SkipProof.prove ctxt'' [] []
   575       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   576         [rewrite_goals_tac rec_preds_defs,
   577          REPEAT (EVERY
   578            [REPEAT (resolve_tac [conjI, impI] 1),
   579             REPEAT (eresolve_tac [le_funE, le_boolE] 1),
   580             atac 1,
   581             rewrite_goals_tac simp_thms',
   582             atac 1])])
   583 
   584   in singleton (ProofContext.export ctxt'' ctxt) (induct RS lemma) end;
   585 
   586 
   587 
   588 (** specification of (co)inductive predicates **)
   589 
   590 fun mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts monos params cnames_syn ctxt =
   591   let
   592     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   593 
   594     val argTs = fold (fn c => fn Ts => Ts @
   595       (List.drop (binder_types (fastype_of c), length params) \\ Ts)) cs [];
   596     val k = log 2 1 (length cs);
   597     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   598     val p :: xs = map Free (Variable.variant_frees ctxt intr_ts
   599       (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   600     val bs = map Free (Variable.variant_frees ctxt (p :: xs @ intr_ts)
   601       (map (rpair HOLogic.boolT) (mk_names "b" k)));
   602 
   603     fun subst t = (case dest_predicate cs params t of
   604         SOME (_, i, ts, (Ts, Us)) =>
   605           let
   606             val l = length Us;
   607             val zs = map Bound (l - 1 downto 0)
   608           in
   609             list_abs (map (pair "z") Us, list_comb (p,
   610               make_bool_args' bs i @ make_args argTs
   611                 ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   612           end
   613       | NONE => (case t of
   614           t1 $ t2 => subst t1 $ subst t2
   615         | Abs (x, T, u) => Abs (x, T, subst u)
   616         | _ => t));
   617 
   618     (* transform an introduction rule into a conjunction  *)
   619     (*   [| p_i t; ... |] ==> p_j u                       *)
   620     (* is transformed into                                *)
   621     (*   b_j & x_j = u & p b_j t & ...                    *)
   622 
   623     fun transform_rule r =
   624       let
   625         val SOME (_, i, ts, (Ts, _)) = dest_predicate cs params
   626           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   627         val ps = make_bool_args HOLogic.mk_not I bs i @
   628           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   629           map (subst o HOLogic.dest_Trueprop)
   630             (Logic.strip_assums_hyp r)
   631       in List.foldr (fn ((x, T), P) => HOLogic.exists_const T $ (Abs (x, T, P)))
   632         (if null ps then HOLogic.true_const else foldr1 HOLogic.mk_conj ps)
   633         (Logic.strip_params r)
   634       end
   635 
   636     (* make a disjunction of all introduction rules *)
   637 
   638     val fp_fun = fold_rev lambda (p :: bs @ xs)
   639       (if null intr_ts then HOLogic.false_const
   640        else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   641 
   642     (* add definiton of recursive predicates to theory *)
   643 
   644     val rec_name =
   645       if Binding.is_empty alt_name then
   646         Binding.name (space_implode "_" (map (Binding.name_of o fst) cnames_syn))
   647       else alt_name;
   648 
   649     val ((rec_const, (_, fp_def)), ctxt') = ctxt |>
   650       LocalTheory.define Thm.internalK
   651         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   652          (Attrib.empty_binding, fold_rev lambda params
   653            (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)));
   654     val fp_def' = Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   655       (cterm_of (ProofContext.theory_of ctxt') (list_comb (rec_const, params)));
   656     val specs = if length cs < 2 then [] else
   657       map_index (fn (i, (name_mx, c)) =>
   658         let
   659           val Ts = List.drop (binder_types (fastype_of c), length params);
   660           val xs = map Free (Variable.variant_frees ctxt intr_ts
   661             (mk_names "x" (length Ts) ~~ Ts))
   662         in
   663           (name_mx, (Attrib.empty_binding, fold_rev lambda (params @ xs)
   664             (list_comb (rec_const, params @ make_bool_args' bs i @
   665               make_args argTs (xs ~~ Ts)))))
   666         end) (cnames_syn ~~ cs);
   667     val (consts_defs, ctxt'') = fold_map (LocalTheory.define Thm.internalK) specs ctxt';
   668     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   669 
   670     val mono = prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt'';
   671     val ((_, [mono']), ctxt''') =
   672       LocalTheory.note Thm.internalK (Attrib.empty_binding, [mono]) ctxt'';
   673 
   674   in (ctxt''', rec_name, mono', fp_def', map (#2 o #2) consts_defs,
   675     list_comb (rec_const, params), preds, argTs, bs, xs)
   676   end;
   677 
   678 fun declare_rules kind rec_binding coind no_ind cnames intrs intr_bindings intr_atts
   679       elims raw_induct ctxt =
   680   let
   681     val rec_name = Binding.name_of rec_binding;
   682     val rec_qualified = Binding.qualify false rec_name;
   683     val intr_names = map Binding.name_of intr_bindings;
   684     val ind_case_names = RuleCases.case_names intr_names;
   685     val induct =
   686       if coind then
   687         (raw_induct, [RuleCases.case_names [rec_name],
   688           RuleCases.case_conclusion (rec_name, intr_names),
   689           RuleCases.consumes 1, Induct.coinduct_pred (hd cnames)])
   690       else if no_ind orelse length cnames > 1 then
   691         (raw_induct, [ind_case_names, RuleCases.consumes 0])
   692       else (raw_induct RSN (2, rev_mp), [ind_case_names, RuleCases.consumes 1]);
   693 
   694     val (intrs', ctxt1) =
   695       ctxt |>
   696       LocalTheory.notes kind
   697         (map rec_qualified intr_bindings ~~ intr_atts ~~ map (fn th => [([th],
   698            [Attrib.internal (K (ContextRules.intro_query NONE)),
   699             Attrib.internal (K Nitpick_Ind_Intros.add)])]) intrs) |>>
   700       map (hd o snd);
   701     val (((_, elims'), (_, [induct'])), ctxt2) =
   702       ctxt1 |>
   703       LocalTheory.note kind ((rec_qualified (Binding.name "intros"), []), intrs') ||>>
   704       fold_map (fn (name, (elim, cases)) =>
   705         LocalTheory.note kind ((Binding.qualified_name (Long_Name.qualify (Long_Name.base_name name) "cases"),
   706           [Attrib.internal (K (RuleCases.case_names cases)),
   707            Attrib.internal (K (RuleCases.consumes 1)),
   708            Attrib.internal (K (Induct.cases_pred name)),
   709            Attrib.internal (K (ContextRules.elim_query NONE))]), [elim]) #>
   710         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   711       LocalTheory.note kind
   712         ((rec_qualified (Binding.name (coind_prefix coind ^ "induct")),
   713           map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   714 
   715     val ctxt3 = if no_ind orelse coind then ctxt2 else
   716       let val inducts = cnames ~~ Project_Rule.projects ctxt2 (1 upto length cnames) induct'
   717       in
   718         ctxt2 |>
   719         LocalTheory.notes kind [((rec_qualified (Binding.name "inducts"), []),
   720           inducts |> map (fn (name, th) => ([th],
   721             [Attrib.internal (K ind_case_names),
   722              Attrib.internal (K (RuleCases.consumes 1)),
   723              Attrib.internal (K (Induct.induct_pred name))])))] |> snd
   724       end
   725   in (intrs', elims', induct', ctxt3) end;
   726 
   727 type inductive_flags =
   728   {quiet_mode: bool, verbose: bool, kind: string, alt_name: binding,
   729    coind: bool, no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool}
   730 
   731 type add_ind_def =
   732   inductive_flags ->
   733   term list -> (Attrib.binding * term) list -> thm list ->
   734   term list -> (binding * mixfix) list ->
   735   local_theory -> inductive_result * local_theory
   736 
   737 fun add_ind_def {quiet_mode, verbose, kind, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono}
   738     cs intros monos params cnames_syn ctxt =
   739   let
   740     val _ = null cnames_syn andalso error "No inductive predicates given";
   741     val names = map (Binding.name_of o fst) cnames_syn;
   742     val _ = message (quiet_mode andalso not verbose)
   743       ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^ commas_quote names);
   744 
   745     val cnames = map (LocalTheory.full_name ctxt o #1) cnames_syn;  (* FIXME *)
   746     val ((intr_names, intr_atts), intr_ts) =
   747       apfst split_list (split_list (map (check_rule ctxt cs params) intros));
   748 
   749     val (ctxt1, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   750       argTs, bs, xs) = mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts
   751         monos params cnames_syn ctxt;
   752 
   753     val (intrs, unfold) = prove_intrs quiet_mode coind mono fp_def (length bs + length xs)
   754       params intr_ts rec_preds_defs ctxt1;
   755     val elims = if no_elim then [] else
   756       prove_elims quiet_mode cs params intr_ts (map Binding.name_of intr_names)
   757         unfold rec_preds_defs ctxt1;
   758     val raw_induct = zero_var_indexes
   759       (if no_ind then Drule.asm_rl else
   760        if coind then
   761          singleton (ProofContext.export
   762            (snd (Variable.add_fixes (map (fst o dest_Free) params) ctxt1)) ctxt1)
   763            (rotate_prems ~1 (ObjectLogic.rulify
   764              (fold_rule rec_preds_defs
   765                (rewrite_rule [le_fun_def, le_bool_def, sup_fun_eq, sup_bool_eq]
   766                 (mono RS (fp_def RS def_coinduct))))))
   767        else
   768          prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono fp_def
   769            rec_preds_defs ctxt1);
   770 
   771     val (intrs', elims', induct, ctxt2) = declare_rules kind rec_name coind no_ind
   772       cnames intrs intr_names intr_atts elims raw_induct ctxt1;
   773 
   774     val result =
   775       {preds = preds,
   776        intrs = intrs',
   777        elims = elims',
   778        raw_induct = rulify raw_induct,
   779        induct = induct};
   780 
   781     val ctxt3 = ctxt2
   782       |> LocalTheory.declaration (fn phi =>
   783         let val result' = morph_result phi result;
   784         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   785   in (result, ctxt3) end;
   786 
   787 
   788 (* external interfaces *)
   789 
   790 fun gen_add_inductive_i mk_def
   791     (flags as {quiet_mode, verbose, kind, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono})
   792     cnames_syn pnames spec monos lthy =
   793   let
   794     val thy = ProofContext.theory_of lthy;
   795     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   796 
   797 
   798     (* abbrevs *)
   799 
   800     val (_, ctxt1) = Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn) lthy;
   801 
   802     fun get_abbrev ((name, atts), t) =
   803       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   804         let
   805           val _ = Binding.is_empty name andalso null atts orelse
   806             error "Abbreviations may not have names or attributes";
   807           val ((x, T), rhs) = LocalDefs.abs_def (snd (LocalDefs.cert_def ctxt1 t));
   808           val var =
   809             (case find_first (fn ((c, _), _) => Binding.name_of c = x) cnames_syn of
   810               NONE => error ("Undeclared head of abbreviation " ^ quote x)
   811             | SOME ((b, T'), mx) =>
   812                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
   813                 else (b, mx));
   814         in SOME (var, rhs) end
   815       else NONE;
   816 
   817     val abbrevs = map_filter get_abbrev spec;
   818     val bs = map (Binding.name_of o fst o fst) abbrevs;
   819 
   820 
   821     (* predicates *)
   822 
   823     val pre_intros = filter_out (is_some o get_abbrev) spec;
   824     val cnames_syn' = filter_out (member (op =) bs o Binding.name_of o fst o fst) cnames_syn;
   825     val cs = map (Free o apfst Binding.name_of o fst) cnames_syn';
   826     val ps = map Free pnames;
   827 
   828     val (_, ctxt2) = lthy |> Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn');
   829     val _ = map (fn abbr => LocalDefs.fixed_abbrev abbr ctxt2) abbrevs;
   830     val ctxt3 = ctxt2 |> fold (snd oo LocalDefs.fixed_abbrev) abbrevs;
   831     val expand = Assumption.export_term ctxt3 lthy #> ProofContext.cert_term lthy;
   832 
   833     fun close_rule r = list_all_free (rev (fold_aterms
   834       (fn t as Free (v as (s, _)) =>
   835           if Variable.is_fixed ctxt1 s orelse
   836             member (op =) ps t then I else insert (op =) v
   837         | _ => I) r []), r);
   838 
   839     val intros = map (apsnd (Syntax.check_term lthy #> close_rule #> expand)) pre_intros;
   840     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
   841   in
   842     lthy
   843     |> mk_def flags cs intros monos ps preds
   844     ||> fold (snd oo LocalTheory.abbrev Syntax.mode_default) abbrevs
   845   end;
   846 
   847 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos int lthy =
   848   let
   849     val ((vars, intrs), _) = lthy
   850       |> ProofContext.set_mode ProofContext.mode_abbrev
   851       |> Specification.read_spec (cnames_syn @ pnames_syn) intro_srcs;
   852     val (cs, ps) = chop (length cnames_syn) vars;
   853     val monos = Attrib.eval_thms lthy raw_monos;
   854     val flags = {quiet_mode = false, verbose = verbose, kind = Thm.generatedK,
   855       alt_name = Binding.empty, coind = coind, no_elim = false, no_ind = false,
   856       skip_mono = false, fork_mono = not int};
   857   in
   858     lthy
   859     |> LocalTheory.set_group (serial_string ())
   860     |> gen_add_inductive_i mk_def flags cs (map (apfst Binding.name_of o fst) ps) intrs monos
   861   end;
   862 
   863 val add_inductive_i = gen_add_inductive_i add_ind_def;
   864 val add_inductive = gen_add_inductive add_ind_def;
   865 
   866 fun add_inductive_global group flags cnames_syn pnames pre_intros monos thy =
   867   let
   868     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
   869     val ctxt' = thy
   870       |> TheoryTarget.init NONE
   871       |> LocalTheory.set_group group
   872       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
   873       |> LocalTheory.exit;
   874     val info = #2 (the_inductive ctxt' name);
   875   in (info, ProofContext.theory_of ctxt') end;
   876 
   877 
   878 (* read off arities of inductive predicates from raw induction rule *)
   879 fun arities_of induct =
   880   map (fn (_ $ t $ u) =>
   881       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
   882     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
   883 
   884 (* read off parameters of inductive predicate from raw induction rule *)
   885 fun params_of induct =
   886   let
   887     val (_ $ t $ u :: _) =
   888       HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
   889     val (_, ts) = strip_comb t;
   890     val (_, us) = strip_comb u
   891   in
   892     List.take (ts, length ts - length us)
   893   end;
   894 
   895 val pname_of_intr =
   896   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
   897 
   898 (* partition introduction rules according to predicate name *)
   899 fun gen_partition_rules f induct intros =
   900   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
   901     (map (rpair [] o fst) (arities_of induct));
   902 
   903 val partition_rules = gen_partition_rules I;
   904 fun partition_rules' induct = gen_partition_rules fst induct;
   905 
   906 fun unpartition_rules intros xs =
   907   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
   908     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
   909 
   910 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
   911 fun infer_intro_vars elim arity intros =
   912   let
   913     val thy = theory_of_thm elim;
   914     val _ :: cases = prems_of elim;
   915     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
   916     fun mtch (t, u) =
   917       let
   918         val params = Logic.strip_params t;
   919         val vars = map (Var o apfst (rpair 0))
   920           (Name.variant_list used (map fst params) ~~ map snd params);
   921         val ts = map (curry subst_bounds (rev vars))
   922           (List.drop (Logic.strip_assums_hyp t, arity));
   923         val us = Logic.strip_imp_prems u;
   924         val tab = fold (Pattern.first_order_match thy) (ts ~~ us)
   925           (Vartab.empty, Vartab.empty);
   926       in
   927         map (Envir.subst_term tab) vars
   928       end
   929   in
   930     map (mtch o apsnd prop_of) (cases ~~ intros)
   931   end;
   932 
   933 
   934 
   935 (** package setup **)
   936 
   937 (* setup theory *)
   938 
   939 val setup =
   940   ind_cases_setup #>
   941   Attrib.setup @{binding mono} (Attrib.add_del mono_add mono_del)
   942     "declaration of monotonicity rule";
   943 
   944 
   945 (* outer syntax *)
   946 
   947 local structure P = OuterParse and K = OuterKeyword in
   948 
   949 val _ = OuterKeyword.keyword "monos";
   950 
   951 fun gen_ind_decl mk_def coind =
   952   P.fixes -- P.for_fixes --
   953   Scan.optional SpecParse.where_alt_specs [] --
   954   Scan.optional (P.$$$ "monos" |-- P.!!! SpecParse.xthms1) []
   955   >> (fn (((preds, params), specs), monos) =>
   956       (snd oo gen_add_inductive mk_def true coind preds params specs monos));
   957 
   958 val ind_decl = gen_ind_decl add_ind_def;
   959 
   960 val _ = OuterSyntax.local_theory' "inductive" "define inductive predicates" K.thy_decl (ind_decl false);
   961 val _ = OuterSyntax.local_theory' "coinductive" "define coinductive predicates" K.thy_decl (ind_decl true);
   962 
   963 val _ =
   964   OuterSyntax.local_theory "inductive_cases"
   965     "create simplified instances of elimination rules (improper)" K.thy_script
   966     (P.and_list1 SpecParse.specs >> (snd oo inductive_cases));
   967 
   968 end;
   969 
   970 end;