src/HOL/Library/FuncSet.thy
author paulson
Fri Sep 27 16:44:50 2002 +0200 (2002-09-27)
changeset 13595 7e6cdcd113a2
parent 13593 e39f0751e4bf
child 14565 c6dc17aab88a
permissions -rw-r--r--
Proof tidying
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     ID:         $Id$
     3     Author:     Florian Kammueller and Lawrence C Paulson
     4 *)
     5 
     6 header {*
     7   \title{Pi and Function Sets}
     8   \author{Florian Kammueller and Lawrence C Paulson}
     9 *}
    10 
    11 theory FuncSet = Main:
    12 
    13 constdefs
    14   Pi      :: "['a set, 'a => 'b set] => ('a => 'b) set"
    15     "Pi A B == {f. \<forall>x. x \<in> A --> f(x) \<in> B(x)}"
    16 
    17   extensional :: "'a set => ('a => 'b) set"
    18     "extensional A == {f. \<forall>x. x~:A --> f(x) = arbitrary}"
    19 
    20   restrict :: "['a => 'b, 'a set] => ('a => 'b)"
    21     "restrict f A == (%x. if x \<in> A then f x else arbitrary)"
    22 
    23 syntax
    24   "@Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    25   funcset :: "['a set, 'b set] => ('a => 'b) set"      (infixr "->" 60)
    26   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    27 
    28 syntax (xsymbols)
    29   "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    30   funcset :: "['a set, 'b set] => ('a => 'b) set"  (infixr "\<rightarrow>" 60) 
    31   "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    32 
    33 translations
    34   "PI x:A. B" => "Pi A (%x. B)"
    35   "A -> B"    => "Pi A (_K B)"
    36   "%x:A. f"  == "restrict (%x. f) A"
    37 
    38 constdefs
    39   compose :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)"
    40   "compose A g f == \<lambda>x\<in>A. g (f x)"
    41 
    42 print_translation {* [("Pi", dependent_tr' ("@Pi", "funcset"))] *}
    43 
    44 
    45 subsection{*Basic Properties of @{term Pi}*}
    46 
    47 lemma Pi_I: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    48 by (simp add: Pi_def)
    49 
    50 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    51 by (simp add: Pi_def)
    52 
    53 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    54 by (simp add: Pi_def)
    55 
    56 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    57 by (simp add: Pi_def)
    58 
    59 lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    60 apply (simp add: Pi_def, auto)
    61 txt{*Converse direction requires Axiom of Choice to exhibit a function
    62 picking an element from each non-empty @{term "B x"}*}
    63 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    64 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto) 
    65 done
    66 
    67 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    68 by (simp add: Pi_def)
    69 
    70 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    71 by (simp add: Pi_def)
    72 
    73 text{*Covariance of Pi-sets in their second argument*}
    74 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    75 by (simp add: Pi_def, blast)
    76 
    77 text{*Contravariance of Pi-sets in their first argument*}
    78 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    79 by (simp add: Pi_def, blast)
    80 
    81 
    82 subsection{*Composition With a Restricted Domain: @{term compose}*}
    83 
    84 lemma funcset_compose: 
    85      "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
    86 by (simp add: Pi_def compose_def restrict_def)
    87 
    88 lemma compose_assoc:
    89      "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |] 
    90       ==> compose A h (compose A g f) = compose A (compose B h g) f"
    91 by (simp add: expand_fun_eq Pi_def compose_def restrict_def) 
    92 
    93 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
    94 by (simp add: compose_def restrict_def)
    95 
    96 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
    97 by (auto simp add: image_def compose_eq)
    98 
    99 lemma inj_on_compose:
   100      "[| f ` A = B; inj_on f A; inj_on g B |] ==> inj_on (compose A g f) A"
   101 by (auto simp add: inj_on_def compose_eq)
   102 
   103 
   104 subsection{*Bounded Abstraction: @{term restrict}*}
   105 
   106 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   107 by (simp add: Pi_def restrict_def)
   108 
   109 lemma restrictI: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   110 by (simp add: Pi_def restrict_def)
   111 
   112 lemma restrict_apply [simp]:
   113      "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else arbitrary)"
   114 by (simp add: restrict_def)
   115 
   116 lemma restrict_ext: 
   117     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   118 by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)
   119 
   120 lemma inj_on_restrict_eq: "inj_on (restrict f A) A = inj_on f A"
   121 by (simp add: inj_on_def restrict_def)
   122 
   123 
   124 lemma Id_compose:
   125      "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   126 by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   127 
   128 lemma compose_Id:
   129      "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   130 by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   131 
   132 
   133 subsection{*Extensionality*}
   134 
   135 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = arbitrary"
   136 by (simp add: extensional_def)
   137 
   138 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   139 by (simp add: restrict_def extensional_def)
   140 
   141 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   142 by (simp add: compose_def)
   143 
   144 lemma extensionalityI:
   145      "[| f \<in> extensional A; g \<in> extensional A; 
   146          !!x. x\<in>A ==> f x = g x |] ==> f = g"
   147 by (force simp add: expand_fun_eq extensional_def)
   148 
   149 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   150 apply (unfold Inv_def)
   151 apply (fast intro: restrict_in_funcset someI2)
   152 done
   153 
   154 lemma compose_Inv_id:
   155      "[| inj_on f A;  f ` A = B |]  
   156       ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   157 apply (simp add: compose_def)
   158 apply (rule restrict_ext, auto)
   159 apply (erule subst)
   160 apply (simp add: Inv_f_f)
   161 done
   162 
   163 lemma compose_id_Inv:
   164      "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   165 apply (simp add: compose_def)
   166 apply (rule restrict_ext)
   167 apply (simp add: f_Inv_f)
   168 done
   169 
   170 end