src/HOL/Probability/Finite_Product_Measure.thy
author wenzelm
Thu Jun 25 23:33:47 2015 +0200 (2015-06-25)
changeset 60580 7e741e22d7fc
parent 59425 c5e79df8cc21
child 61166 5976fe402824
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Probability/Finite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 section {*Finite product measures*}
     6 
     7 theory Finite_Product_Measure
     8 imports Binary_Product_Measure
     9 begin
    10 
    11 lemma PiE_choice: "(\<exists>f\<in>PiE I F. \<forall>i\<in>I. P i (f i)) \<longleftrightarrow> (\<forall>i\<in>I. \<exists>x\<in>F i. P i x)"
    12   by (auto simp: Bex_def PiE_iff Ball_def dest!: choice_iff'[THEN iffD1])
    13      (force intro: exI[of _ "restrict f I" for f])
    14 
    15 lemma split_const: "(\<lambda>(i, j). c) = (\<lambda>_. c)"
    16   by auto
    17 
    18 subsubsection {* More about Function restricted by @{const extensional}  *}
    19 
    20 definition
    21   "merge I J = (\<lambda>(x, y) i. if i \<in> I then x i else if i \<in> J then y i else undefined)"
    22 
    23 lemma merge_apply[simp]:
    24   "I \<inter> J = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    25   "I \<inter> J = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    26   "J \<inter> I = {} \<Longrightarrow> i \<in> I \<Longrightarrow> merge I J (x, y) i = x i"
    27   "J \<inter> I = {} \<Longrightarrow> i \<in> J \<Longrightarrow> merge I J (x, y) i = y i"
    28   "i \<notin> I \<Longrightarrow> i \<notin> J \<Longrightarrow> merge I J (x, y) i = undefined"
    29   unfolding merge_def by auto
    30 
    31 lemma merge_commute:
    32   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) = merge J I (y, x)"
    33   by (force simp: merge_def)
    34 
    35 lemma Pi_cancel_merge_range[simp]:
    36   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    37   "I \<inter> J = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    38   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge I J (A, B)) \<longleftrightarrow> x \<in> Pi I A"
    39   "J \<inter> I = {} \<Longrightarrow> x \<in> Pi I (merge J I (B, A)) \<longleftrightarrow> x \<in> Pi I A"
    40   by (auto simp: Pi_def)
    41 
    42 lemma Pi_cancel_merge[simp]:
    43   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    44   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
    45   "I \<inter> J = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    46   "J \<inter> I = {} \<Longrightarrow> merge I J (x, y) \<in> Pi J B \<longleftrightarrow> y \<in> Pi J B"
    47   by (auto simp: Pi_def)
    48 
    49 lemma extensional_merge[simp]: "merge I J (x, y) \<in> extensional (I \<union> J)"
    50   by (auto simp: extensional_def)
    51 
    52 lemma restrict_merge[simp]:
    53   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    54   "I \<inter> J = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    55   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) I = restrict x I"
    56   "J \<inter> I = {} \<Longrightarrow> restrict (merge I J (x, y)) J = restrict y J"
    57   by (auto simp: restrict_def)
    58 
    59 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
    60   unfolding merge_def by auto
    61 
    62 lemma PiE_cancel_merge[simp]:
    63   "I \<inter> J = {} \<Longrightarrow>
    64     merge I J (x, y) \<in> PiE (I \<union> J) B \<longleftrightarrow> x \<in> Pi I B \<and> y \<in> Pi J B"
    65   by (auto simp: PiE_def restrict_Pi_cancel)
    66 
    67 lemma merge_singleton[simp]: "i \<notin> I \<Longrightarrow> merge I {i} (x,y) = restrict (x(i := y i)) (insert i I)"
    68   unfolding merge_def by (auto simp: fun_eq_iff)
    69 
    70 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
    71   unfolding merge_def extensional_def by auto
    72 
    73 lemma merge_restrict[simp]:
    74   "merge I J (restrict x I, y) = merge I J (x, y)"
    75   "merge I J (x, restrict y J) = merge I J (x, y)"
    76   unfolding merge_def by auto
    77 
    78 lemma merge_x_x_eq_restrict[simp]:
    79   "merge I J (x, x) = restrict x (I \<union> J)"
    80   unfolding merge_def by auto
    81 
    82 lemma injective_vimage_restrict:
    83   assumes J: "J \<subseteq> I"
    84   and sets: "A \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^sub>E i\<in>J. S i)" and ne: "(\<Pi>\<^sub>E i\<in>I. S i) \<noteq> {}"
    85   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    86   shows "A = B"
    87 proof  (intro set_eqI)
    88   fix x
    89   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
    90   have "J \<inter> (I - J) = {}" by auto
    91   show "x \<in> A \<longleftrightarrow> x \<in> B"
    92   proof cases
    93     assume x: "x \<in> (\<Pi>\<^sub>E i\<in>J. S i)"
    94     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^sub>E i\<in>I. S i)"
    95       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    96       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1)
    97     then show "x \<in> A \<longleftrightarrow> x \<in> B"
    98       using y x `J \<subseteq> I` PiE_cancel_merge[of "J" "I - J" x y S]
    99       by (auto simp del: PiE_cancel_merge simp add: Un_absorb1 eq)
   100   qed (insert sets, auto)
   101 qed
   102 
   103 lemma restrict_vimage:
   104   "I \<inter> J = {} \<Longrightarrow>
   105     (\<lambda>x. (restrict x I, restrict x J)) -` (Pi\<^sub>E I E \<times> Pi\<^sub>E J F) = Pi (I \<union> J) (merge I J (E, F))"
   106   by (auto simp: restrict_Pi_cancel PiE_def)
   107 
   108 lemma merge_vimage:
   109   "I \<inter> J = {} \<Longrightarrow> merge I J -` Pi\<^sub>E (I \<union> J) E = Pi I E \<times> Pi J E"
   110   by (auto simp: restrict_Pi_cancel PiE_def)
   111 
   112 subsection {* Finite product spaces *}
   113 
   114 subsubsection {* Products *}
   115 
   116 definition prod_emb where
   117   "prod_emb I M K X = (\<lambda>x. restrict x K) -` X \<inter> (PIE i:I. space (M i))"
   118 
   119 lemma prod_emb_iff: 
   120   "f \<in> prod_emb I M K X \<longleftrightarrow> f \<in> extensional I \<and> (restrict f K \<in> X) \<and> (\<forall>i\<in>I. f i \<in> space (M i))"
   121   unfolding prod_emb_def PiE_def by auto
   122 
   123 lemma
   124   shows prod_emb_empty[simp]: "prod_emb M L K {} = {}"
   125     and prod_emb_Un[simp]: "prod_emb M L K (A \<union> B) = prod_emb M L K A \<union> prod_emb M L K B"
   126     and prod_emb_Int: "prod_emb M L K (A \<inter> B) = prod_emb M L K A \<inter> prod_emb M L K B"
   127     and prod_emb_UN[simp]: "prod_emb M L K (\<Union>i\<in>I. F i) = (\<Union>i\<in>I. prod_emb M L K (F i))"
   128     and prod_emb_INT[simp]: "I \<noteq> {} \<Longrightarrow> prod_emb M L K (\<Inter>i\<in>I. F i) = (\<Inter>i\<in>I. prod_emb M L K (F i))"
   129     and prod_emb_Diff[simp]: "prod_emb M L K (A - B) = prod_emb M L K A - prod_emb M L K B"
   130   by (auto simp: prod_emb_def)
   131 
   132 lemma prod_emb_PiE: "J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow>
   133     prod_emb I M J (\<Pi>\<^sub>E i\<in>J. E i) = (\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i))"
   134   by (force simp: prod_emb_def PiE_iff split_if_mem2)
   135 
   136 lemma prod_emb_PiE_same_index[simp]:
   137     "(\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> space (M i)) \<Longrightarrow> prod_emb I M I (Pi\<^sub>E I E) = Pi\<^sub>E I E"
   138   by (auto simp: prod_emb_def PiE_iff)
   139 
   140 lemma prod_emb_trans[simp]:
   141   "J \<subseteq> K \<Longrightarrow> K \<subseteq> L \<Longrightarrow> prod_emb L M K (prod_emb K M J X) = prod_emb L M J X"
   142   by (auto simp add: Int_absorb1 prod_emb_def PiE_def)
   143 
   144 lemma prod_emb_Pi:
   145   assumes "X \<in> (\<Pi> j\<in>J. sets (M j))" "J \<subseteq> K"
   146   shows "prod_emb K M J (Pi\<^sub>E J X) = (\<Pi>\<^sub>E i\<in>K. if i \<in> J then X i else space (M i))"
   147   using assms sets.space_closed
   148   by (auto simp: prod_emb_def PiE_iff split: split_if_asm) blast+
   149 
   150 lemma prod_emb_id:
   151   "B \<subseteq> (\<Pi>\<^sub>E i\<in>L. space (M i)) \<Longrightarrow> prod_emb L M L B = B"
   152   by (auto simp: prod_emb_def subset_eq extensional_restrict)
   153 
   154 lemma prod_emb_mono:
   155   "F \<subseteq> G \<Longrightarrow> prod_emb A M B F \<subseteq> prod_emb A M B G"
   156   by (auto simp: prod_emb_def)
   157 
   158 definition PiM :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
   159   "PiM I M = extend_measure (\<Pi>\<^sub>E i\<in>I. space (M i))
   160     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
   161     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j))
   162     (\<lambda>(J, X). \<Prod>j\<in>J \<union> {i\<in>I. emeasure (M i) (space (M i)) \<noteq> 1}. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   163 
   164 definition prod_algebra :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i \<Rightarrow> 'a) set set" where
   165   "prod_algebra I M = (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^sub>E j\<in>J. X j)) `
   166     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}"
   167 
   168 abbreviation
   169   "Pi\<^sub>M I M \<equiv> PiM I M"
   170 
   171 syntax
   172   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3PIM _:_./ _)" 10)
   173 
   174 syntax (xsymbols)
   175   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
   176 
   177 syntax (HTML output)
   178   "_PiM" :: "pttrn \<Rightarrow> 'i set \<Rightarrow> 'a measure \<Rightarrow> ('i => 'a) measure"  ("(3\<Pi>\<^sub>M _\<in>_./ _)"  10)
   179 
   180 translations
   181   "PIM x:I. M" == "CONST PiM I (%x. M)"
   182 
   183 lemma extend_measure_cong:
   184   assumes "\<Omega> = \<Omega>'" "I = I'" "G = G'" "\<And>i. i \<in> I' \<Longrightarrow> \<mu> i = \<mu>' i"
   185   shows "extend_measure \<Omega> I G \<mu> = extend_measure \<Omega>' I' G' \<mu>'"
   186   unfolding extend_measure_def by (auto simp add: assms)
   187 
   188 lemma Pi_cong_sets:
   189     "\<lbrakk>I = J; \<And>x. x \<in> I \<Longrightarrow> M x = N x\<rbrakk> \<Longrightarrow> Pi I M = Pi J N"
   190   unfolding Pi_def by auto 
   191 
   192 lemma PiM_cong:
   193   assumes "I = J" "\<And>x. x \<in> I \<Longrightarrow> M x = N x"
   194   shows "PiM I M = PiM J N"
   195   unfolding PiM_def
   196 proof (rule extend_measure_cong, goals)
   197   case 1
   198   show ?case using assms
   199     by (subst assms(1), intro PiE_cong[of J "\<lambda>i. space (M i)" "\<lambda>i. space (N i)"]) simp_all
   200 next
   201   case 2
   202   have "\<And>K. K \<subseteq> J \<Longrightarrow> (\<Pi> j\<in>K. sets (M j)) = (\<Pi> j\<in>K. sets (N j))"
   203     using assms by (intro Pi_cong_sets) auto
   204   thus ?case by (auto simp: assms)
   205 next
   206   case 3
   207   show ?case using assms 
   208     by (intro ext) (auto simp: prod_emb_def dest: PiE_mem)
   209 next
   210   case (4 x)
   211   thus ?case using assms 
   212     by (auto intro!: setprod.cong split: split_if_asm)
   213 qed
   214 
   215 
   216 lemma prod_algebra_sets_into_space:
   217   "prod_algebra I M \<subseteq> Pow (\<Pi>\<^sub>E i\<in>I. space (M i))"
   218   by (auto simp: prod_emb_def prod_algebra_def)
   219 
   220 lemma prod_algebra_eq_finite:
   221   assumes I: "finite I"
   222   shows "prod_algebra I M = {(\<Pi>\<^sub>E i\<in>I. X i) |X. X \<in> (\<Pi> j\<in>I. sets (M j))}" (is "?L = ?R")
   223 proof (intro iffI set_eqI)
   224   fix A assume "A \<in> ?L"
   225   then obtain J E where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   226     and A: "A = prod_emb I M J (PIE j:J. E j)"
   227     by (auto simp: prod_algebra_def)
   228   let ?A = "\<Pi>\<^sub>E i\<in>I. if i \<in> J then E i else space (M i)"
   229   have A: "A = ?A"
   230     unfolding A using J by (intro prod_emb_PiE sets.sets_into_space) auto
   231   show "A \<in> ?R" unfolding A using J sets.top
   232     by (intro CollectI exI[of _ "\<lambda>i. if i \<in> J then E i else space (M i)"]) simp
   233 next
   234   fix A assume "A \<in> ?R"
   235   then obtain X where A: "A = (\<Pi>\<^sub>E i\<in>I. X i)" and X: "X \<in> (\<Pi> j\<in>I. sets (M j))" by auto
   236   then have A: "A = prod_emb I M I (\<Pi>\<^sub>E i\<in>I. X i)"
   237     by (simp add: prod_emb_PiE_same_index[OF sets.sets_into_space] Pi_iff)
   238   from X I show "A \<in> ?L" unfolding A
   239     by (auto simp: prod_algebra_def)
   240 qed
   241 
   242 lemma prod_algebraI:
   243   "finite J \<Longrightarrow> (J \<noteq> {} \<or> I = {}) \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i))
   244     \<Longrightarrow> prod_emb I M J (PIE j:J. E j) \<in> prod_algebra I M"
   245   by (auto simp: prod_algebra_def)
   246 
   247 lemma prod_algebraI_finite:
   248   "finite I \<Longrightarrow> (\<forall>i\<in>I. E i \<in> sets (M i)) \<Longrightarrow> (Pi\<^sub>E I E) \<in> prod_algebra I M"
   249   using prod_algebraI[of I I E M] prod_emb_PiE_same_index[of I E M, OF sets.sets_into_space] by simp
   250 
   251 lemma Int_stable_PiE: "Int_stable {Pi\<^sub>E J E | E. \<forall>i\<in>I. E i \<in> sets (M i)}"
   252 proof (safe intro!: Int_stableI)
   253   fix E F assume "\<forall>i\<in>I. E i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   254   then show "\<exists>G. Pi\<^sub>E J E \<inter> Pi\<^sub>E J F = Pi\<^sub>E J G \<and> (\<forall>i\<in>I. G i \<in> sets (M i))"
   255     by (auto intro!: exI[of _ "\<lambda>i. E i \<inter> F i"] simp: PiE_Int)
   256 qed
   257 
   258 lemma prod_algebraE:
   259   assumes A: "A \<in> prod_algebra I M"
   260   obtains J E where "A = prod_emb I M J (PIE j:J. E j)"
   261     "finite J" "J \<noteq> {} \<or> I = {}" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> E i \<in> sets (M i)" 
   262   using A by (auto simp: prod_algebra_def)
   263 
   264 lemma prod_algebraE_all:
   265   assumes A: "A \<in> prod_algebra I M"
   266   obtains E where "A = Pi\<^sub>E I E" "E \<in> (\<Pi> i\<in>I. sets (M i))"
   267 proof -
   268   from A obtain E J where A: "A = prod_emb I M J (Pi\<^sub>E J E)"
   269     and J: "J \<subseteq> I" and E: "E \<in> (\<Pi> i\<in>J. sets (M i))"
   270     by (auto simp: prod_algebra_def)
   271   from E have "\<And>i. i \<in> J \<Longrightarrow> E i \<subseteq> space (M i)"
   272     using sets.sets_into_space by auto
   273   then have "A = (\<Pi>\<^sub>E i\<in>I. if i\<in>J then E i else space (M i))"
   274     using A J by (auto simp: prod_emb_PiE)
   275   moreover have "(\<lambda>i. if i\<in>J then E i else space (M i)) \<in> (\<Pi> i\<in>I. sets (M i))"
   276     using sets.top E by auto
   277   ultimately show ?thesis using that by auto
   278 qed
   279 
   280 lemma Int_stable_prod_algebra: "Int_stable (prod_algebra I M)"
   281 proof (unfold Int_stable_def, safe)
   282   fix A assume "A \<in> prod_algebra I M"
   283   from prod_algebraE[OF this] guess J E . note A = this
   284   fix B assume "B \<in> prod_algebra I M"
   285   from prod_algebraE[OF this] guess K F . note B = this
   286   have "A \<inter> B = prod_emb I M (J \<union> K) (\<Pi>\<^sub>E i\<in>J \<union> K. (if i \<in> J then E i else space (M i)) \<inter> 
   287       (if i \<in> K then F i else space (M i)))"
   288     unfolding A B using A(2,3,4) A(5)[THEN sets.sets_into_space] B(2,3,4)
   289       B(5)[THEN sets.sets_into_space]
   290     apply (subst (1 2 3) prod_emb_PiE)
   291     apply (simp_all add: subset_eq PiE_Int)
   292     apply blast
   293     apply (intro PiE_cong)
   294     apply auto
   295     done
   296   also have "\<dots> \<in> prod_algebra I M"
   297     using A B by (auto intro!: prod_algebraI)
   298   finally show "A \<inter> B \<in> prod_algebra I M" .
   299 qed
   300 
   301 lemma prod_algebra_mono:
   302   assumes space: "\<And>i. i \<in> I \<Longrightarrow> space (E i) = space (F i)"
   303   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (E i) \<subseteq> sets (F i)"
   304   shows "prod_algebra I E \<subseteq> prod_algebra I F"
   305 proof
   306   fix A assume "A \<in> prod_algebra I E"
   307   then obtain J G where J: "J \<noteq> {} \<or> I = {}" "finite J" "J \<subseteq> I"
   308     and A: "A = prod_emb I E J (\<Pi>\<^sub>E i\<in>J. G i)"
   309     and G: "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (E i)"
   310     by (auto simp: prod_algebra_def)
   311   moreover
   312   from space have "(\<Pi>\<^sub>E i\<in>I. space (E i)) = (\<Pi>\<^sub>E i\<in>I. space (F i))"
   313     by (rule PiE_cong)
   314   with A have "A = prod_emb I F J (\<Pi>\<^sub>E i\<in>J. G i)"
   315     by (simp add: prod_emb_def)
   316   moreover
   317   from sets G J have "\<And>i. i \<in> J \<Longrightarrow> G i \<in> sets (F i)"
   318     by auto
   319   ultimately show "A \<in> prod_algebra I F"
   320     apply (simp add: prod_algebra_def image_iff)
   321     apply (intro exI[of _ J] exI[of _ G] conjI)
   322     apply auto
   323     done
   324 qed
   325 
   326 lemma prod_algebra_cong:
   327   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
   328   shows "prod_algebra I M = prod_algebra J N"
   329 proof -
   330   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
   331     using sets_eq_imp_space_eq[OF sets] by auto
   332   with sets show ?thesis unfolding `I = J`
   333     by (intro antisym prod_algebra_mono) auto
   334 qed
   335 
   336 lemma space_in_prod_algebra:
   337   "(\<Pi>\<^sub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
   338 proof cases
   339   assume "I = {}" then show ?thesis
   340     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
   341 next
   342   assume "I \<noteq> {}"
   343   then obtain i where "i \<in> I" by auto
   344   then have "(\<Pi>\<^sub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. space (M i))"
   345     by (auto simp: prod_emb_def)
   346   also have "\<dots> \<in> prod_algebra I M"
   347     using `i \<in> I` by (intro prod_algebraI) auto
   348   finally show ?thesis .
   349 qed
   350 
   351 lemma space_PiM: "space (\<Pi>\<^sub>M i\<in>I. M i) = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   352   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro space_extend_measure) simp
   353 
   354 lemma sets_PiM: "sets (\<Pi>\<^sub>M i\<in>I. M i) = sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) (prod_algebra I M)"
   355   using prod_algebra_sets_into_space unfolding PiM_def prod_algebra_def by (intro sets_extend_measure) simp
   356 
   357 lemma sets_PiM_single: "sets (PiM I M) =
   358     sigma_sets (\<Pi>\<^sub>E i\<in>I. space (M i)) {{f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} | i A. i \<in> I \<and> A \<in> sets (M i)}"
   359     (is "_ = sigma_sets ?\<Omega> ?R")
   360   unfolding sets_PiM
   361 proof (rule sigma_sets_eqI)
   362   interpret R: sigma_algebra ?\<Omega> "sigma_sets ?\<Omega> ?R" by (rule sigma_algebra_sigma_sets) auto
   363   fix A assume "A \<in> prod_algebra I M"
   364   from prod_algebraE[OF this] guess J X . note X = this
   365   show "A \<in> sigma_sets ?\<Omega> ?R"
   366   proof cases
   367     assume "I = {}"
   368     with X have "A = {\<lambda>x. undefined}" by (auto simp: prod_emb_def)
   369     with `I = {}` show ?thesis by (auto intro!: sigma_sets_top)
   370   next
   371     assume "I \<noteq> {}"
   372     with X have "A = (\<Inter>j\<in>J. {f\<in>(\<Pi>\<^sub>E i\<in>I. space (M i)). f j \<in> X j})"
   373       by (auto simp: prod_emb_def)
   374     also have "\<dots> \<in> sigma_sets ?\<Omega> ?R"
   375       using X `I \<noteq> {}` by (intro R.finite_INT sigma_sets.Basic) auto
   376     finally show "A \<in> sigma_sets ?\<Omega> ?R" .
   377   qed
   378 next
   379   fix A assume "A \<in> ?R"
   380   then obtain i B where A: "A = {f\<in>\<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" "i \<in> I" "B \<in> sets (M i)" 
   381     by auto
   382   then have "A = prod_emb I M {i} (\<Pi>\<^sub>E i\<in>{i}. B)"
   383      by (auto simp: prod_emb_def)
   384   also have "\<dots> \<in> sigma_sets ?\<Omega> (prod_algebra I M)"
   385     using A by (intro sigma_sets.Basic prod_algebraI) auto
   386   finally show "A \<in> sigma_sets ?\<Omega> (prod_algebra I M)" .
   387 qed
   388 
   389 lemma sets_PiM_eq_proj:
   390   "I \<noteq> {} \<Longrightarrow> sets (PiM I M) = sets (\<Squnion>\<^sub>\<sigma> i\<in>I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. space (M i)) (\<lambda>x. x i) (M i))"
   391   apply (simp add: sets_PiM_single sets_Sup_sigma)
   392   apply (subst SUP_cong[OF refl])
   393   apply (rule sets_vimage_algebra2)
   394   apply auto []
   395   apply (auto intro!: arg_cong2[where f=sigma_sets])
   396   done
   397 
   398 lemma
   399   shows space_PiM_empty: "space (Pi\<^sub>M {} M) = {\<lambda>k. undefined}"
   400     and sets_PiM_empty: "sets (Pi\<^sub>M {} M) = { {}, {\<lambda>k. undefined} }"
   401   by (simp_all add: space_PiM sets_PiM_single image_constant sigma_sets_empty_eq)
   402 
   403 lemma sets_PiM_sigma:
   404   assumes \<Omega>_cover: "\<And>i. i \<in> I \<Longrightarrow> \<exists>S\<subseteq>E i. countable S \<and> \<Omega> i = \<Union>S"
   405   assumes E: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (\<Omega> i)"
   406   assumes J: "\<And>j. j \<in> J \<Longrightarrow> finite j" "\<Union>J = I"
   407   defines "P \<equiv> {{f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i} | A j. j \<in> J \<and> A \<in> Pi j E}"
   408   shows "sets (\<Pi>\<^sub>M i\<in>I. sigma (\<Omega> i) (E i)) = sets (sigma (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P)"
   409 proof cases
   410   assume "I = {}" 
   411   with `\<Union>J = I` have "P = {{\<lambda>_. undefined}} \<or> P = {}"
   412     by (auto simp: P_def)
   413   with `I = {}` show ?thesis
   414     by (auto simp add: sets_PiM_empty sigma_sets_empty_eq)
   415 next
   416   let ?F = "\<lambda>i. {(\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega> |A. A \<in> E i}"
   417   assume "I \<noteq> {}"
   418   then have "sets (Pi\<^sub>M I (\<lambda>i. sigma (\<Omega> i) (E i))) = 
   419       sets (\<Squnion>\<^sub>\<sigma> i\<in>I. vimage_algebra (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<lambda>x. x i) (sigma (\<Omega> i) (E i)))"
   420     by (subst sets_PiM_eq_proj) (auto simp: space_measure_of_conv)
   421   also have "\<dots> = sets (\<Squnion>\<^sub>\<sigma> i\<in>I. sigma (Pi\<^sub>E I \<Omega>) (?F i))"
   422     using E by (intro SUP_sigma_cong arg_cong[where f=sets] vimage_algebra_sigma) auto
   423   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i))"
   424     using `I \<noteq> {}` by (intro arg_cong[where f=sets] SUP_sigma_sigma) auto
   425   also have "\<dots> = sets (sigma (Pi\<^sub>E I \<Omega>) P)"
   426   proof (intro arg_cong[where f=sets] sigma_eqI sigma_sets_eqI)
   427     show "(\<Union>i\<in>I. ?F i) \<subseteq> Pow (Pi\<^sub>E I \<Omega>)" "P \<subseteq> Pow (Pi\<^sub>E I \<Omega>)"
   428       by (auto simp: P_def)
   429   next
   430     interpret P: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
   431       by (auto intro!: sigma_algebra_sigma_sets simp: P_def)
   432 
   433     fix Z assume "Z \<in> (\<Union>i\<in>I. ?F i)"
   434     then obtain i A where i: "i \<in> I" "A \<in> E i" and Z_def: "Z = (\<lambda>x. x i) -` A \<inter> Pi\<^sub>E I \<Omega>"
   435       by auto
   436     from `i \<in> I` J obtain j where j: "i \<in> j" "j \<in> J" "j \<subseteq> I" "finite j"
   437       by auto
   438     obtain S where S: "\<And>i. i \<in> j \<Longrightarrow> S i \<subseteq> E i" "\<And>i. i \<in> j \<Longrightarrow> countable (S i)"
   439       "\<And>i. i \<in> j \<Longrightarrow> \<Omega> i = \<Union>(S i)"
   440       by (metis subset_eq \<Omega>_cover `j \<subseteq> I`)
   441     def A' \<equiv> "\<lambda>n. n(i := A)"
   442     then have A'_i: "\<And>n. A' n i = A"
   443       by simp
   444     { fix n assume "n \<in> Pi\<^sub>E (j - {i}) S"
   445       then have "A' n \<in> Pi j E"
   446         unfolding PiE_def Pi_def using S(1) by (auto simp: A'_def `A \<in> E i` )
   447       with `j \<in> J` have "{f \<in> Pi\<^sub>E I \<Omega>. \<forall>i\<in>j. f i \<in> A' n i} \<in> P"
   448         by (auto simp: P_def) }
   449     note A'_in_P = this
   450 
   451     { fix x assume "x i \<in> A" "x \<in> Pi\<^sub>E I \<Omega>"
   452       with S(3) `j \<subseteq> I` have "\<forall>i\<in>j. \<exists>s\<in>S i. x i \<in> s"
   453         by (auto simp: PiE_def Pi_def)
   454       then obtain s where s: "\<And>i. i \<in> j \<Longrightarrow> s i \<in> S i" "\<And>i. i \<in> j \<Longrightarrow> x i \<in> s i"
   455         by metis
   456       with `x i \<in> A` have "\<exists>n\<in>PiE (j-{i}) S. \<forall>i\<in>j. x i \<in> A' n i"
   457         by (intro bexI[of _ "restrict (s(i := A)) (j-{i})"]) (auto simp: A'_def split: if_splits) }
   458     then have "Z = (\<Union>n\<in>PiE (j-{i}) S. {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A' n i})"
   459       unfolding Z_def
   460       by (auto simp add: set_eq_iff ball_conj_distrib `i\<in>j` A'_i dest: bspec[OF _ `i\<in>j`]
   461                cong: conj_cong)
   462     also have "\<dots> \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P"
   463       using `finite j` S(2)
   464       by (intro P.countable_UN' countable_PiE) (simp_all add: image_subset_iff A'_in_P)
   465     finally show "Z \<in> sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) P" .
   466   next
   467     interpret F: sigma_algebra "\<Pi>\<^sub>E i\<in>I. \<Omega> i" "sigma_sets (\<Pi>\<^sub>E i\<in>I. \<Omega> i) (\<Union>i\<in>I. ?F i)"
   468       by (auto intro!: sigma_algebra_sigma_sets)
   469 
   470     fix b assume "b \<in> P"
   471     then obtain A j where b: "b = {f\<in>(\<Pi>\<^sub>E i\<in>I. \<Omega> i). \<forall>i\<in>j. f i \<in> A i}" "j \<in> J" "A \<in> Pi j E"
   472       by (auto simp: P_def)
   473     show "b \<in> sigma_sets (Pi\<^sub>E I \<Omega>) (\<Union>i\<in>I. ?F i)"
   474     proof cases
   475       assume "j = {}"
   476       with b have "b = (\<Pi>\<^sub>E i\<in>I. \<Omega> i)"
   477         by auto
   478       then show ?thesis
   479         by blast
   480     next
   481       assume "j \<noteq> {}"
   482       with J b(2,3) have eq: "b = (\<Inter>i\<in>j. ((\<lambda>x. x i) -` A i \<inter> Pi\<^sub>E I \<Omega>))"
   483         unfolding b(1)
   484         by (auto simp: PiE_def Pi_def)
   485       show ?thesis
   486         unfolding eq using `A \<in> Pi j E` `j \<in> J` J(2)
   487         by (intro F.finite_INT J `j \<in> J` `j \<noteq> {}` sigma_sets.Basic) blast
   488     qed
   489   qed
   490   finally show "?thesis" .
   491 qed
   492 
   493 lemma sets_PiM_in_sets:
   494   assumes space: "space N = (\<Pi>\<^sub>E i\<in>I. space (M i))"
   495   assumes sets: "\<And>i A. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {x\<in>space N. x i \<in> A} \<in> sets N"
   496   shows "sets (\<Pi>\<^sub>M i \<in> I. M i) \<subseteq> sets N"
   497   unfolding sets_PiM_single space[symmetric]
   498   by (intro sets.sigma_sets_subset subsetI) (auto intro: sets)
   499 
   500 lemma sets_PiM_cong[measurable_cong]:
   501   assumes "I = J" "\<And>i. i \<in> J \<Longrightarrow> sets (M i) = sets (N i)" shows "sets (PiM I M) = sets (PiM J N)"
   502   using assms sets_eq_imp_space_eq[OF assms(2)] by (simp add: sets_PiM_single cong: PiE_cong conj_cong)
   503 
   504 lemma sets_PiM_I:
   505   assumes "finite J" "J \<subseteq> I" "\<forall>i\<in>J. E i \<in> sets (M i)"
   506   shows "prod_emb I M J (PIE j:J. E j) \<in> sets (PIM i:I. M i)"
   507 proof cases
   508   assume "J = {}"
   509   then have "prod_emb I M J (PIE j:J. E j) = (PIE j:I. space (M j))"
   510     by (auto simp: prod_emb_def)
   511   then show ?thesis
   512     by (auto simp add: sets_PiM intro!: sigma_sets_top)
   513 next
   514   assume "J \<noteq> {}" with assms show ?thesis
   515     by (force simp add: sets_PiM prod_algebra_def)
   516 qed
   517 
   518 lemma measurable_PiM:
   519   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   520   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   521     f -` prod_emb I M J (Pi\<^sub>E J X) \<inter> space N \<in> sets N" 
   522   shows "f \<in> measurable N (PiM I M)"
   523   using sets_PiM prod_algebra_sets_into_space space
   524 proof (rule measurable_sigma_sets)
   525   fix A assume "A \<in> prod_algebra I M"
   526   from prod_algebraE[OF this] guess J X .
   527   with sets[of J X] show "f -` A \<inter> space N \<in> sets N" by auto
   528 qed
   529 
   530 lemma measurable_PiM_Collect:
   531   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   532   assumes sets: "\<And>X J. J \<noteq> {} \<or> I = {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> (\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)) \<Longrightarrow>
   533     {\<omega>\<in>space N. \<forall>i\<in>J. f \<omega> i \<in> X i} \<in> sets N" 
   534   shows "f \<in> measurable N (PiM I M)"
   535   using sets_PiM prod_algebra_sets_into_space space
   536 proof (rule measurable_sigma_sets)
   537   fix A assume "A \<in> prod_algebra I M"
   538   from prod_algebraE[OF this] guess J X . note X = this
   539   then have "f -` A \<inter> space N = {\<omega> \<in> space N. \<forall>i\<in>J. f \<omega> i \<in> X i}"
   540     using space by (auto simp: prod_emb_def del: PiE_I)
   541   also have "\<dots> \<in> sets N" using X(3,2,4,5) by (rule sets)
   542   finally show "f -` A \<inter> space N \<in> sets N" .
   543 qed
   544 
   545 lemma measurable_PiM_single:
   546   assumes space: "f \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   547   assumes sets: "\<And>A i. i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> {\<omega> \<in> space N. f \<omega> i \<in> A} \<in> sets N" 
   548   shows "f \<in> measurable N (PiM I M)"
   549   using sets_PiM_single
   550 proof (rule measurable_sigma_sets)
   551   fix A assume "A \<in> {{f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> A} |i A. i \<in> I \<and> A \<in> sets (M i)}"
   552   then obtain B i where "A = {f \<in> \<Pi>\<^sub>E i\<in>I. space (M i). f i \<in> B}" and B: "i \<in> I" "B \<in> sets (M i)"
   553     by auto
   554   with space have "f -` A \<inter> space N = {\<omega> \<in> space N. f \<omega> i \<in> B}" by auto
   555   also have "\<dots> \<in> sets N" using B by (rule sets)
   556   finally show "f -` A \<inter> space N \<in> sets N" .
   557 qed (auto simp: space)
   558 
   559 lemma measurable_PiM_single':
   560   assumes f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> measurable N (M i)"
   561     and "(\<lambda>\<omega> i. f i \<omega>) \<in> space N \<rightarrow> (\<Pi>\<^sub>E i\<in>I. space (M i))"
   562   shows "(\<lambda>\<omega> i. f i \<omega>) \<in> measurable N (Pi\<^sub>M I M)"
   563 proof (rule measurable_PiM_single)
   564   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   565   then have "{\<omega> \<in> space N. f i \<omega> \<in> A} = f i -` A \<inter> space N"
   566     by auto
   567   then show "{\<omega> \<in> space N. f i \<omega> \<in> A} \<in> sets N"
   568     using A f by (auto intro!: measurable_sets)
   569 qed fact
   570 
   571 lemma sets_PiM_I_finite[measurable]:
   572   assumes "finite I" and sets: "(\<And>i. i \<in> I \<Longrightarrow> E i \<in> sets (M i))"
   573   shows "(PIE j:I. E j) \<in> sets (PIM i:I. M i)"
   574   using sets_PiM_I[of I I E M] sets.sets_into_space[OF sets] `finite I` sets by auto
   575 
   576 lemma measurable_component_singleton[measurable (raw)]:
   577   assumes "i \<in> I" shows "(\<lambda>x. x i) \<in> measurable (Pi\<^sub>M I M) (M i)"
   578 proof (unfold measurable_def, intro CollectI conjI ballI)
   579   fix A assume "A \<in> sets (M i)"
   580   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) = prod_emb I M {i} (\<Pi>\<^sub>E j\<in>{i}. A)"
   581     using sets.sets_into_space `i \<in> I`
   582     by (fastforce dest: Pi_mem simp: prod_emb_def space_PiM split: split_if_asm)
   583   then show "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M I M) \<in> sets (Pi\<^sub>M I M)"
   584     using `A \<in> sets (M i)` `i \<in> I` by (auto intro!: sets_PiM_I)
   585 qed (insert `i \<in> I`, auto simp: space_PiM)
   586 
   587 lemma measurable_component_singleton'[measurable_dest]:
   588   assumes f: "f \<in> measurable N (Pi\<^sub>M I M)"
   589   assumes g: "g \<in> measurable L N"
   590   assumes i: "i \<in> I"
   591   shows "(\<lambda>x. (f (g x)) i) \<in> measurable L (M i)"
   592   using measurable_compose[OF measurable_compose[OF g f] measurable_component_singleton, OF i] .
   593 
   594 lemma measurable_PiM_component_rev:
   595   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<lambda>x. f (x i)) \<in> measurable (PiM I M) N"
   596   by simp
   597 
   598 lemma measurable_case_nat[measurable (raw)]:
   599   assumes [measurable (raw)]: "i = 0 \<Longrightarrow> f \<in> measurable M N"
   600     "\<And>j. i = Suc j \<Longrightarrow> (\<lambda>x. g x j) \<in> measurable M N"
   601   shows "(\<lambda>x. case_nat (f x) (g x) i) \<in> measurable M N"
   602   by (cases i) simp_all
   603  
   604 lemma measurable_case_nat'[measurable (raw)]:
   605   assumes fg[measurable]: "f \<in> measurable N M" "g \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   606   shows "(\<lambda>x. case_nat (f x) (g x)) \<in> measurable N (\<Pi>\<^sub>M i\<in>UNIV. M)"
   607   using fg[THEN measurable_space]
   608   by (auto intro!: measurable_PiM_single' simp add: space_PiM PiE_iff split: nat.split)
   609 
   610 lemma measurable_add_dim[measurable]:
   611   "(\<lambda>(f, y). f(i := y)) \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M)"
   612     (is "?f \<in> measurable ?P ?I")
   613 proof (rule measurable_PiM_single)
   614   fix j A assume j: "j \<in> insert i I" and A: "A \<in> sets (M j)"
   615   have "{\<omega> \<in> space ?P. (\<lambda>(f, x). fun_upd f i x) \<omega> j \<in> A} =
   616     (if j = i then space (Pi\<^sub>M I M) \<times> A else ((\<lambda>x. x j) \<circ> fst) -` A \<inter> space ?P)"
   617     using sets.sets_into_space[OF A] by (auto simp add: space_pair_measure space_PiM)
   618   also have "\<dots> \<in> sets ?P"
   619     using A j
   620     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   621   finally show "{\<omega> \<in> space ?P. case_prod (\<lambda>f. fun_upd f i) \<omega> j \<in> A} \<in> sets ?P" .
   622 qed (auto simp: space_pair_measure space_PiM PiE_def)
   623 
   624 lemma measurable_component_update:
   625   "x \<in> space (Pi\<^sub>M I M) \<Longrightarrow> i \<notin> I \<Longrightarrow> (\<lambda>v. x(i := v)) \<in> measurable (M i) (Pi\<^sub>M (insert i I) M)"
   626   by simp
   627 
   628 lemma measurable_merge[measurable]:
   629   "merge I J \<in> measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M)"
   630     (is "?f \<in> measurable ?P ?U")
   631 proof (rule measurable_PiM_single)
   632   fix i A assume A: "A \<in> sets (M i)" "i \<in> I \<union> J"
   633   then have "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} =
   634     (if i \<in> I then ((\<lambda>x. x i) \<circ> fst) -` A \<inter> space ?P else ((\<lambda>x. x i) \<circ> snd) -` A \<inter> space ?P)"
   635     by (auto simp: merge_def)
   636   also have "\<dots> \<in> sets ?P"
   637     using A
   638     by (auto intro!: measurable_sets[OF measurable_comp, OF _ measurable_component_singleton])
   639   finally show "{\<omega> \<in> space ?P. merge I J \<omega> i \<in> A} \<in> sets ?P" .
   640 qed (auto simp: space_pair_measure space_PiM PiE_iff merge_def extensional_def)
   641 
   642 lemma measurable_restrict[measurable (raw)]:
   643   assumes X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> measurable N (M i)"
   644   shows "(\<lambda>x. \<lambda>i\<in>I. X i x) \<in> measurable N (Pi\<^sub>M I M)"
   645 proof (rule measurable_PiM_single)
   646   fix A i assume A: "i \<in> I" "A \<in> sets (M i)"
   647   then have "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} = X i -` A \<inter> space N"
   648     by auto
   649   then show "{\<omega> \<in> space N. (\<lambda>i\<in>I. X i \<omega>) i \<in> A} \<in> sets N"
   650     using A X by (auto intro!: measurable_sets)
   651 qed (insert X, auto simp add: PiE_def dest: measurable_space)
   652 
   653 lemma measurable_abs_UNIV: 
   654   "(\<And>n. (\<lambda>\<omega>. f n \<omega>) \<in> measurable M (N n)) \<Longrightarrow> (\<lambda>\<omega> n. f n \<omega>) \<in> measurable M (PiM UNIV N)"
   655   by (intro measurable_PiM_single) (auto dest: measurable_space)
   656 
   657 lemma measurable_restrict_subset: "J \<subseteq> L \<Longrightarrow> (\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
   658   by (intro measurable_restrict measurable_component_singleton) auto
   659 
   660 lemma measurable_restrict_subset':
   661   assumes "J \<subseteq> L" "\<And>x. x \<in> J \<Longrightarrow> sets (M x) = sets (N x)"
   662   shows "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
   663 proof-
   664   from assms(1) have "(\<lambda>f. restrict f J) \<in> measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M)"
   665     by (rule measurable_restrict_subset)
   666   also from assms(2) have "measurable (Pi\<^sub>M L M) (Pi\<^sub>M J M) = measurable (Pi\<^sub>M L M) (Pi\<^sub>M J N)"
   667     by (intro sets_PiM_cong measurable_cong_sets) simp_all
   668   finally show ?thesis .
   669 qed
   670 
   671 lemma measurable_prod_emb[intro, simp]:
   672   "J \<subseteq> L \<Longrightarrow> X \<in> sets (Pi\<^sub>M J M) \<Longrightarrow> prod_emb L M J X \<in> sets (Pi\<^sub>M L M)"
   673   unfolding prod_emb_def space_PiM[symmetric]
   674   by (auto intro!: measurable_sets measurable_restrict measurable_component_singleton)
   675 
   676 lemma sets_in_Pi_aux:
   677   "finite I \<Longrightarrow> (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   678   {x\<in>space (PiM I M). x \<in> Pi I F} \<in> sets (PiM I M)"
   679   by (simp add: subset_eq Pi_iff)
   680 
   681 lemma sets_in_Pi[measurable (raw)]:
   682   "finite I \<Longrightarrow> f \<in> measurable N (PiM I M) \<Longrightarrow>
   683   (\<And>j. j \<in> I \<Longrightarrow> {x\<in>space (M j). x \<in> F j} \<in> sets (M j)) \<Longrightarrow>
   684   Measurable.pred N (\<lambda>x. f x \<in> Pi I F)"
   685   unfolding pred_def
   686   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_Pi_aux]) auto
   687 
   688 lemma sets_in_extensional_aux:
   689   "{x\<in>space (PiM I M). x \<in> extensional I} \<in> sets (PiM I M)"
   690 proof -
   691   have "{x\<in>space (PiM I M). x \<in> extensional I} = space (PiM I M)"
   692     by (auto simp add: extensional_def space_PiM)
   693   then show ?thesis by simp
   694 qed
   695 
   696 lemma sets_in_extensional[measurable (raw)]:
   697   "f \<in> measurable N (PiM I M) \<Longrightarrow> Measurable.pred N (\<lambda>x. f x \<in> extensional I)"
   698   unfolding pred_def
   699   by (rule measurable_sets_Collect[of f N "PiM I M", OF _ sets_in_extensional_aux]) auto
   700 
   701 locale product_sigma_finite =
   702   fixes M :: "'i \<Rightarrow> 'a measure"
   703   assumes sigma_finite_measures: "\<And>i. sigma_finite_measure (M i)"
   704 
   705 sublocale product_sigma_finite \<subseteq> M: sigma_finite_measure "M i" for i
   706   by (rule sigma_finite_measures)
   707 
   708 locale finite_product_sigma_finite = product_sigma_finite M for M :: "'i \<Rightarrow> 'a measure" +
   709   fixes I :: "'i set"
   710   assumes finite_index: "finite I"
   711 
   712 lemma (in finite_product_sigma_finite) sigma_finite_pairs:
   713   "\<exists>F::'i \<Rightarrow> nat \<Rightarrow> 'a set.
   714     (\<forall>i\<in>I. range (F i) \<subseteq> sets (M i)) \<and>
   715     (\<forall>k. \<forall>i\<in>I. emeasure (M i) (F i k) \<noteq> \<infinity>) \<and> incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k) \<and>
   716     (\<Union>k. \<Pi>\<^sub>E i\<in>I. F i k) = space (PiM I M)"
   717 proof -
   718   have "\<forall>i::'i. \<exists>F::nat \<Rightarrow> 'a set. range F \<subseteq> sets (M i) \<and> incseq F \<and> (\<Union>i. F i) = space (M i) \<and> (\<forall>k. emeasure (M i) (F k) \<noteq> \<infinity>)"
   719     using M.sigma_finite_incseq by metis
   720   from choice[OF this] guess F :: "'i \<Rightarrow> nat \<Rightarrow> 'a set" ..
   721   then have F: "\<And>i. range (F i) \<subseteq> sets (M i)" "\<And>i. incseq (F i)" "\<And>i. (\<Union>j. F i j) = space (M i)" "\<And>i k. emeasure (M i) (F i k) \<noteq> \<infinity>"
   722     by auto
   723   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I. F i k"
   724   note space_PiM[simp]
   725   show ?thesis
   726   proof (intro exI[of _ F] conjI allI incseq_SucI set_eqI iffI ballI)
   727     fix i show "range (F i) \<subseteq> sets (M i)" by fact
   728   next
   729     fix i k show "emeasure (M i) (F i k) \<noteq> \<infinity>" by fact
   730   next
   731     fix x assume "x \<in> (\<Union>i. ?F i)" with F(1) show "x \<in> space (PiM I M)"
   732       by (auto simp: PiE_def dest!: sets.sets_into_space)
   733   next
   734     fix f assume "f \<in> space (PiM I M)"
   735     with Pi_UN[OF finite_index, of "\<lambda>k i. F i k"] F
   736     show "f \<in> (\<Union>i. ?F i)" by (auto simp: incseq_def PiE_def)
   737   next
   738     fix i show "?F i \<subseteq> ?F (Suc i)"
   739       using `\<And>i. incseq (F i)`[THEN incseq_SucD] by auto
   740   qed
   741 qed
   742 
   743 lemma emeasure_PiM_empty[simp]: "emeasure (PiM {} M) {\<lambda>_. undefined} = 1"
   744 proof -
   745   let ?\<mu> = "\<lambda>A. if A = {} then 0 else (1::ereal)"
   746   have "emeasure (Pi\<^sub>M {} M) (prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = 1"
   747   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   748     show "positive (PiM {} M) ?\<mu>"
   749       by (auto simp: positive_def)
   750     show "countably_additive (PiM {} M) ?\<mu>"
   751       by (rule sets.countably_additiveI_finite)
   752          (auto simp: additive_def positive_def sets_PiM_empty space_PiM_empty intro!: )
   753   qed (auto simp: prod_emb_def)
   754   also have "(prod_emb {} M {} (\<Pi>\<^sub>E i\<in>{}. {})) = {\<lambda>_. undefined}"
   755     by (auto simp: prod_emb_def)
   756   finally show ?thesis
   757     by simp
   758 qed
   759 
   760 lemma PiM_empty: "PiM {} M = count_space {\<lambda>_. undefined}"
   761   by (rule measure_eqI) (auto simp add: sets_PiM_empty one_ereal_def)
   762 
   763 lemma (in product_sigma_finite) emeasure_PiM:
   764   "finite I \<Longrightarrow> (\<And>i. i\<in>I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (PiM I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   765 proof (induct I arbitrary: A rule: finite_induct)
   766   case (insert i I)
   767   interpret finite_product_sigma_finite M I by default fact
   768   have "finite (insert i I)" using `finite I` by auto
   769   interpret I': finite_product_sigma_finite M "insert i I" by default fact
   770   let ?h = "(\<lambda>(f, y). f(i := y))"
   771 
   772   let ?P = "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) (Pi\<^sub>M (insert i I) M) ?h"
   773   let ?\<mu> = "emeasure ?P"
   774   let ?I = "{j \<in> insert i I. emeasure (M j) (space (M j)) \<noteq> 1}"
   775   let ?f = "\<lambda>J E j. if j \<in> J then emeasure (M j) (E j) else emeasure (M j) (space (M j))"
   776 
   777   have "emeasure (Pi\<^sub>M (insert i I) M) (prod_emb (insert i I) M (insert i I) (Pi\<^sub>E (insert i I) A)) =
   778     (\<Prod>i\<in>insert i I. emeasure (M i) (A i))"
   779   proof (subst emeasure_extend_measure_Pair[OF PiM_def])
   780     fix J E assume "(J \<noteq> {} \<or> insert i I = {}) \<and> finite J \<and> J \<subseteq> insert i I \<and> E \<in> (\<Pi> j\<in>J. sets (M j))"
   781     then have J: "J \<noteq> {}" "finite J" "J \<subseteq> insert i I" and E: "\<forall>j\<in>J. E j \<in> sets (M j)" by auto
   782     let ?p = "prod_emb (insert i I) M J (Pi\<^sub>E J E)"
   783     let ?p' = "prod_emb I M (J - {i}) (\<Pi>\<^sub>E j\<in>J-{i}. E j)"
   784     have "?\<mu> ?p =
   785       emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i))"
   786       by (intro emeasure_distr measurable_add_dim sets_PiM_I) fact+
   787     also have "?h -` ?p \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M M i) = ?p' \<times> (if i \<in> J then E i else space (M i))"
   788       using J E[rule_format, THEN sets.sets_into_space]
   789       by (force simp: space_pair_measure space_PiM prod_emb_iff PiE_def Pi_iff split: split_if_asm)
   790     also have "emeasure (Pi\<^sub>M I M \<Otimes>\<^sub>M (M i)) (?p' \<times> (if i \<in> J then E i else space (M i))) =
   791       emeasure (Pi\<^sub>M I M) ?p' * emeasure (M i) (if i \<in> J then (E i) else space (M i))"
   792       using J E by (intro M.emeasure_pair_measure_Times sets_PiM_I) auto
   793     also have "?p' = (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j))"
   794       using J E[rule_format, THEN sets.sets_into_space]
   795       by (auto simp: prod_emb_iff PiE_def Pi_iff split: split_if_asm) blast+
   796     also have "emeasure (Pi\<^sub>M I M) (\<Pi>\<^sub>E j\<in>I. if j \<in> J-{i} then E j else space (M j)) =
   797       (\<Prod> j\<in>I. if j \<in> J-{i} then emeasure (M j) (E j) else emeasure (M j) (space (M j)))"
   798       using E by (subst insert) (auto intro!: setprod.cong)
   799     also have "(\<Prod>j\<in>I. if j \<in> J - {i} then emeasure (M j) (E j) else emeasure (M j) (space (M j))) *
   800        emeasure (M i) (if i \<in> J then E i else space (M i)) = (\<Prod>j\<in>insert i I. ?f J E j)"
   801       using insert by (auto simp: mult.commute intro!: arg_cong2[where f="op *"] setprod.cong)
   802     also have "\<dots> = (\<Prod>j\<in>J \<union> ?I. ?f J E j)"
   803       using insert(1,2) J E by (intro setprod.mono_neutral_right) auto
   804     finally show "?\<mu> ?p = \<dots>" .
   805 
   806     show "prod_emb (insert i I) M J (Pi\<^sub>E J E) \<in> Pow (\<Pi>\<^sub>E i\<in>insert i I. space (M i))"
   807       using J E[rule_format, THEN sets.sets_into_space] by (auto simp: prod_emb_iff PiE_def)
   808   next
   809     show "positive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>" "countably_additive (sets (Pi\<^sub>M (insert i I) M)) ?\<mu>"
   810       using emeasure_positive[of ?P] emeasure_countably_additive[of ?P] by simp_all
   811   next
   812     show "(insert i I \<noteq> {} \<or> insert i I = {}) \<and> finite (insert i I) \<and>
   813       insert i I \<subseteq> insert i I \<and> A \<in> (\<Pi> j\<in>insert i I. sets (M j))"
   814       using insert by auto
   815   qed (auto intro!: setprod.cong)
   816   with insert show ?case
   817     by (subst (asm) prod_emb_PiE_same_index) (auto intro!: sets.sets_into_space)
   818 qed simp
   819 
   820 lemma (in product_sigma_finite) sigma_finite: 
   821   assumes "finite I"
   822   shows "sigma_finite_measure (PiM I M)"
   823 proof
   824   interpret finite_product_sigma_finite M I by default fact
   825 
   826   obtain F where F: "\<And>j. countable (F j)" "\<And>j f. f \<in> F j \<Longrightarrow> f \<in> sets (M j)"
   827     "\<And>j f. f \<in> F j \<Longrightarrow> emeasure (M j) f \<noteq> \<infinity>" and
   828     in_space: "\<And>j. space (M j) = (\<Union>F j)"
   829     using sigma_finite_countable by (metis subset_eq)
   830   moreover have "(\<Union>(PiE I ` PiE I F)) = space (Pi\<^sub>M I M)"
   831     using in_space by (auto simp: space_PiM PiE_iff intro!: PiE_choice[THEN iffD2])
   832   ultimately show "\<exists>A. countable A \<and> A \<subseteq> sets (Pi\<^sub>M I M) \<and> \<Union>A = space (Pi\<^sub>M I M) \<and> (\<forall>a\<in>A. emeasure (Pi\<^sub>M I M) a \<noteq> \<infinity>)"
   833     by (intro exI[of _ "PiE I ` PiE I F"])
   834        (auto intro!: countable_PiE sets_PiM_I_finite
   835              simp: PiE_iff emeasure_PiM finite_index setprod_PInf emeasure_nonneg)
   836 qed
   837 
   838 sublocale finite_product_sigma_finite \<subseteq> sigma_finite_measure "Pi\<^sub>M I M"
   839   using sigma_finite[OF finite_index] .
   840 
   841 lemma (in finite_product_sigma_finite) measure_times:
   842   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> emeasure (Pi\<^sub>M I M) (Pi\<^sub>E I A) = (\<Prod>i\<in>I. emeasure (M i) (A i))"
   843   using emeasure_PiM[OF finite_index] by auto
   844 
   845 lemma (in product_sigma_finite) nn_integral_empty:
   846   assumes pos: "0 \<le> f (\<lambda>k. undefined)"
   847   shows "integral\<^sup>N (Pi\<^sub>M {} M) f = f (\<lambda>k. undefined)"
   848 proof -
   849   interpret finite_product_sigma_finite M "{}" by default (fact finite.emptyI)
   850   have "\<And>A. emeasure (Pi\<^sub>M {} M) (Pi\<^sub>E {} A) = 1"
   851     using assms by (subst measure_times) auto
   852   then show ?thesis
   853     unfolding nn_integral_def simple_function_def simple_integral_def[abs_def]
   854   proof (simp add: space_PiM_empty sets_PiM_empty, intro antisym)
   855     show "f (\<lambda>k. undefined) \<le> (SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined))"
   856       by (intro SUP_upper) (auto simp: le_fun_def split: split_max)
   857     show "(SUP f:{g. g \<le> max 0 \<circ> f}. f (\<lambda>k. undefined)) \<le> f (\<lambda>k. undefined)" using pos
   858       by (intro SUP_least) (auto simp: le_fun_def simp: max_def split: split_if_asm)
   859   qed
   860 qed
   861 
   862 lemma (in product_sigma_finite) distr_merge:
   863   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
   864   shows "distr (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) (Pi\<^sub>M (I \<union> J) M) (merge I J) = Pi\<^sub>M (I \<union> J) M"
   865    (is "?D = ?P")
   866 proof -
   867   interpret I: finite_product_sigma_finite M I by default fact
   868   interpret J: finite_product_sigma_finite M J by default fact
   869   have "finite (I \<union> J)" using fin by auto
   870   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
   871   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by default
   872   let ?g = "merge I J"
   873 
   874   from IJ.sigma_finite_pairs obtain F where
   875     F: "\<And>i. i\<in> I \<union> J \<Longrightarrow> range (F i) \<subseteq> sets (M i)"
   876        "incseq (\<lambda>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k)"
   877        "(\<Union>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k) = space ?P"
   878        "\<And>k. \<forall>i\<in>I\<union>J. emeasure (M i) (F i k) \<noteq> \<infinity>"
   879     by auto
   880   let ?F = "\<lambda>k. \<Pi>\<^sub>E i\<in>I \<union> J. F i k"
   881   
   882   show ?thesis
   883   proof (rule measure_eqI_generator_eq[symmetric])
   884     show "Int_stable (prod_algebra (I \<union> J) M)"
   885       by (rule Int_stable_prod_algebra)
   886     show "prod_algebra (I \<union> J) M \<subseteq> Pow (\<Pi>\<^sub>E i \<in> I \<union> J. space (M i))"
   887       by (rule prod_algebra_sets_into_space)
   888     show "sets ?P = sigma_sets (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   889       by (rule sets_PiM)
   890     then show "sets ?D = sigma_sets (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i)) (prod_algebra (I \<union> J) M)"
   891       by simp
   892 
   893     show "range ?F \<subseteq> prod_algebra (I \<union> J) M" using F
   894       using fin by (auto simp: prod_algebra_eq_finite)
   895     show "(\<Union>i. \<Pi>\<^sub>E ia\<in>I \<union> J. F ia i) = (\<Pi>\<^sub>E i\<in>I \<union> J. space (M i))"
   896       using F(3) by (simp add: space_PiM)
   897   next
   898     fix k
   899     from F `finite I` setprod_PInf[of "I \<union> J", OF emeasure_nonneg, of M]
   900     show "emeasure ?P (?F k) \<noteq> \<infinity>" by (subst IJ.measure_times) auto
   901   next
   902     fix A assume A: "A \<in> prod_algebra (I \<union> J) M"
   903     with fin obtain F where A_eq: "A = (Pi\<^sub>E (I \<union> J) F)" and F: "\<forall>i\<in>J. F i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
   904       by (auto simp add: prod_algebra_eq_finite)
   905     let ?B = "Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M"
   906     let ?X = "?g -` A \<inter> space ?B"
   907     have "Pi\<^sub>E I F \<subseteq> space (Pi\<^sub>M I M)" "Pi\<^sub>E J F \<subseteq> space (Pi\<^sub>M J M)"
   908       using F[rule_format, THEN sets.sets_into_space] by (force simp: space_PiM)+
   909     then have X: "?X = (Pi\<^sub>E I F \<times> Pi\<^sub>E J F)"
   910       unfolding A_eq by (subst merge_vimage) (auto simp: space_pair_measure space_PiM)
   911     have "emeasure ?D A = emeasure ?B ?X"
   912       using A by (intro emeasure_distr measurable_merge) (auto simp: sets_PiM)
   913     also have "emeasure ?B ?X = (\<Prod>i\<in>I. emeasure (M i) (F i)) * (\<Prod>i\<in>J. emeasure (M i) (F i))"
   914       using `finite J` `finite I` F unfolding X
   915       by (simp add: J.emeasure_pair_measure_Times I.measure_times J.measure_times)
   916     also have "\<dots> = (\<Prod>i\<in>I \<union> J. emeasure (M i) (F i))"
   917       using `finite J` `finite I` `I \<inter> J = {}`  by (simp add: setprod.union_inter_neutral)
   918     also have "\<dots> = emeasure ?P (Pi\<^sub>E (I \<union> J) F)"
   919       using `finite J` `finite I` F unfolding A
   920       by (intro IJ.measure_times[symmetric]) auto
   921     finally show "emeasure ?P A = emeasure ?D A" using A_eq by simp
   922   qed
   923 qed
   924 
   925 lemma (in product_sigma_finite) product_nn_integral_fold:
   926   assumes IJ: "I \<inter> J = {}" "finite I" "finite J"
   927   and f: "f \<in> borel_measurable (Pi\<^sub>M (I \<union> J) M)"
   928   shows "integral\<^sup>N (Pi\<^sub>M (I \<union> J) M) f =
   929     (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (merge I J (x, y)) \<partial>(Pi\<^sub>M J M)) \<partial>(Pi\<^sub>M I M))"
   930 proof -
   931   interpret I: finite_product_sigma_finite M I by default fact
   932   interpret J: finite_product_sigma_finite M J by default fact
   933   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by default
   934   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
   935     using measurable_comp[OF measurable_merge f] by (simp add: comp_def)
   936   show ?thesis
   937     apply (subst distr_merge[OF IJ, symmetric])
   938     apply (subst nn_integral_distr[OF measurable_merge f])
   939     apply (subst J.nn_integral_fst[symmetric, OF P_borel])
   940     apply simp
   941     done
   942 qed
   943 
   944 lemma (in product_sigma_finite) distr_singleton:
   945   "distr (Pi\<^sub>M {i} M) (M i) (\<lambda>x. x i) = M i" (is "?D = _")
   946 proof (intro measure_eqI[symmetric])
   947   interpret I: finite_product_sigma_finite M "{i}" by default simp
   948   fix A assume A: "A \<in> sets (M i)"
   949   then have "(\<lambda>x. x i) -` A \<inter> space (Pi\<^sub>M {i} M) = (\<Pi>\<^sub>E i\<in>{i}. A)"
   950     using sets.sets_into_space by (auto simp: space_PiM)
   951   then show "emeasure (M i) A = emeasure ?D A"
   952     using A I.measure_times[of "\<lambda>_. A"]
   953     by (simp add: emeasure_distr measurable_component_singleton)
   954 qed simp
   955 
   956 lemma (in product_sigma_finite) product_nn_integral_singleton:
   957   assumes f: "f \<in> borel_measurable (M i)"
   958   shows "integral\<^sup>N (Pi\<^sub>M {i} M) (\<lambda>x. f (x i)) = integral\<^sup>N (M i) f"
   959 proof -
   960   interpret I: finite_product_sigma_finite M "{i}" by default simp
   961   from f show ?thesis
   962     apply (subst distr_singleton[symmetric])
   963     apply (subst nn_integral_distr[OF measurable_component_singleton])
   964     apply simp_all
   965     done
   966 qed
   967 
   968 lemma (in product_sigma_finite) product_nn_integral_insert:
   969   assumes I[simp]: "finite I" "i \<notin> I"
   970     and f: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
   971   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+ y. f (x(i := y)) \<partial>(M i)) \<partial>(Pi\<^sub>M I M))"
   972 proof -
   973   interpret I: finite_product_sigma_finite M I by default auto
   974   interpret i: finite_product_sigma_finite M "{i}" by default auto
   975   have IJ: "I \<inter> {i} = {}" and insert: "I \<union> {i} = insert i I"
   976     using f by auto
   977   show ?thesis
   978     unfolding product_nn_integral_fold[OF IJ, unfolded insert, OF I(1) i.finite_index f]
   979   proof (rule nn_integral_cong, subst product_nn_integral_singleton[symmetric])
   980     fix x assume x: "x \<in> space (Pi\<^sub>M I M)"
   981     let ?f = "\<lambda>y. f (x(i := y))"
   982     show "?f \<in> borel_measurable (M i)"
   983       using measurable_comp[OF measurable_component_update f, OF x `i \<notin> I`]
   984       unfolding comp_def .
   985     show "(\<integral>\<^sup>+ y. f (merge I {i} (x, y)) \<partial>Pi\<^sub>M {i} M) = (\<integral>\<^sup>+ y. f (x(i := y i)) \<partial>Pi\<^sub>M {i} M)"
   986       using x
   987       by (auto intro!: nn_integral_cong arg_cong[where f=f]
   988                simp add: space_PiM extensional_def PiE_def)
   989   qed
   990 qed
   991 
   992 lemma (in product_sigma_finite) product_nn_integral_insert_rev:
   993   assumes I[simp]: "finite I" "i \<notin> I"
   994     and [measurable]: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
   995   shows "integral\<^sup>N (Pi\<^sub>M (insert i I) M) f = (\<integral>\<^sup>+ y. (\<integral>\<^sup>+ x. f (x(i := y)) \<partial>(Pi\<^sub>M I M)) \<partial>(M i))"
   996   apply (subst product_nn_integral_insert[OF assms])
   997   apply (rule pair_sigma_finite.Fubini')
   998   apply intro_locales []
   999   apply (rule sigma_finite[OF I(1)])
  1000   apply measurable
  1001   done
  1002 
  1003 lemma (in product_sigma_finite) product_nn_integral_setprod:
  1004   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> ereal"
  1005   assumes "finite I" and borel: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> borel_measurable (M i)"
  1006   and pos: "\<And>i x. i \<in> I \<Longrightarrow> 0 \<le> f i x"
  1007   shows "(\<integral>\<^sup>+ x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^sub>M I M) = (\<Prod>i\<in>I. integral\<^sup>N (M i) (f i))"
  1008 using assms proof induct
  1009   case (insert i I)
  1010   note `finite I`[intro, simp]
  1011   interpret I: finite_product_sigma_finite M I by default auto
  1012   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
  1013     using insert by (auto intro!: setprod.cong)
  1014   have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow> (\<lambda>x. (\<Prod>i\<in>J. f i (x i))) \<in> borel_measurable (Pi\<^sub>M J M)"
  1015     using sets.sets_into_space insert
  1016     by (intro borel_measurable_ereal_setprod
  1017               measurable_comp[OF measurable_component_singleton, unfolded comp_def])
  1018        auto
  1019   then show ?case
  1020     apply (simp add: product_nn_integral_insert[OF insert(1,2) prod])
  1021     apply (simp add: insert(2-) * pos borel setprod_ereal_pos nn_integral_multc)
  1022     apply (subst nn_integral_cmult)
  1023     apply (auto simp add: pos borel insert(2-) setprod_ereal_pos nn_integral_nonneg)
  1024     done
  1025 qed (simp add: space_PiM)
  1026 
  1027 lemma (in product_sigma_finite) product_nn_integral_pair:
  1028   assumes [measurable]: "split f \<in> borel_measurable (M x \<Otimes>\<^sub>M M y)"
  1029   assumes xy: "x \<noteq> y"
  1030   shows "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {x, y} M) = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
  1031 proof-
  1032   interpret psm: pair_sigma_finite "M x" "M y"
  1033     unfolding pair_sigma_finite_def using sigma_finite_measures by simp_all
  1034   have "{x, y} = {y, x}" by auto
  1035   also have "(\<integral>\<^sup>+\<sigma>. f (\<sigma> x) (\<sigma> y) \<partial>PiM {y, x} M) = (\<integral>\<^sup>+y. \<integral>\<^sup>+\<sigma>. f (\<sigma> x) y \<partial>PiM {x} M \<partial>M y)"
  1036     using xy by (subst product_nn_integral_insert_rev) simp_all
  1037   also have "... = (\<integral>\<^sup>+y. \<integral>\<^sup>+x. f x y \<partial>M x \<partial>M y)"
  1038     by (intro nn_integral_cong, subst product_nn_integral_singleton) simp_all
  1039   also have "... = (\<integral>\<^sup>+z. f (fst z) (snd z) \<partial>(M x \<Otimes>\<^sub>M M y))"
  1040     by (subst psm.nn_integral_snd[symmetric]) simp_all
  1041   finally show ?thesis .
  1042 qed
  1043 
  1044 lemma (in product_sigma_finite) distr_component:
  1045   "distr (M i) (Pi\<^sub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^sub>M {i} M" (is "?D = ?P")
  1046 proof (intro measure_eqI[symmetric])
  1047   interpret I: finite_product_sigma_finite M "{i}" by default simp
  1048 
  1049   have eq: "\<And>x. x \<in> extensional {i} \<Longrightarrow> (\<lambda>j\<in>{i}. x i) = x"
  1050     by (auto simp: extensional_def restrict_def)
  1051 
  1052   have [measurable]: "\<And>j. j \<in> {i} \<Longrightarrow> (\<lambda>x. x) \<in> measurable (M i) (M j)" by simp
  1053 
  1054   fix A assume A: "A \<in> sets ?P"
  1055   then have "emeasure ?P A = (\<integral>\<^sup>+x. indicator A x \<partial>?P)" 
  1056     by simp
  1057   also have "\<dots> = (\<integral>\<^sup>+x. indicator ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i)) (x i) \<partial>PiM {i} M)" 
  1058     by (intro nn_integral_cong) (auto simp: space_PiM indicator_def PiE_def eq)
  1059   also have "\<dots> = emeasure ?D A"
  1060     using A by (simp add: product_nn_integral_singleton emeasure_distr)
  1061   finally show "emeasure (Pi\<^sub>M {i} M) A = emeasure ?D A" .
  1062 qed simp
  1063 
  1064 lemma (in product_sigma_finite)
  1065   assumes IJ: "I \<inter> J = {}" "finite I" "finite J" and A: "A \<in> sets (Pi\<^sub>M (I \<union> J) M)"
  1066   shows emeasure_fold_integral:
  1067     "emeasure (Pi\<^sub>M (I \<union> J) M) A = (\<integral>\<^sup>+x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M)) \<partial>Pi\<^sub>M I M)" (is ?I)
  1068     and emeasure_fold_measurable:
  1069     "(\<lambda>x. emeasure (Pi\<^sub>M J M) ((\<lambda>y. merge I J (x, y)) -` A \<inter> space (Pi\<^sub>M J M))) \<in> borel_measurable (Pi\<^sub>M I M)" (is ?B)
  1070 proof -
  1071   interpret I: finite_product_sigma_finite M I by default fact
  1072   interpret J: finite_product_sigma_finite M J by default fact
  1073   interpret IJ: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" ..
  1074   have merge: "merge I J -` A \<inter> space (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) \<in> sets (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
  1075     by (intro measurable_sets[OF _ A] measurable_merge assms)
  1076 
  1077   show ?I
  1078     apply (subst distr_merge[symmetric, OF IJ])
  1079     apply (subst emeasure_distr[OF measurable_merge A])
  1080     apply (subst J.emeasure_pair_measure_alt[OF merge])
  1081     apply (auto intro!: nn_integral_cong arg_cong2[where f=emeasure] simp: space_pair_measure)
  1082     done
  1083 
  1084   show ?B
  1085     using IJ.measurable_emeasure_Pair1[OF merge]
  1086     by (simp add: vimage_comp comp_def space_pair_measure cong: measurable_cong)
  1087 qed
  1088 
  1089 lemma sets_Collect_single:
  1090   "i \<in> I \<Longrightarrow> A \<in> sets (M i) \<Longrightarrow> { x \<in> space (Pi\<^sub>M I M). x i \<in> A } \<in> sets (Pi\<^sub>M I M)"
  1091   by simp
  1092 
  1093 lemma pair_measure_eq_distr_PiM:
  1094   fixes M1 :: "'a measure" and M2 :: "'a measure"
  1095   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1096   shows "(M1 \<Otimes>\<^sub>M M2) = distr (Pi\<^sub>M UNIV (case_bool M1 M2)) (M1 \<Otimes>\<^sub>M M2) (\<lambda>x. (x True, x False))"
  1097     (is "?P = ?D")
  1098 proof (rule pair_measure_eqI[OF assms])
  1099   interpret B: product_sigma_finite "case_bool M1 M2"
  1100     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
  1101   let ?B = "Pi\<^sub>M UNIV (case_bool M1 M2)"
  1102 
  1103   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
  1104     by auto
  1105   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
  1106   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (case_bool M1 M2 i) (case_bool A B i))"
  1107     by (simp add: UNIV_bool ac_simps)
  1108   also have "\<dots> = emeasure ?B (Pi\<^sub>E UNIV (case_bool A B))"
  1109     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
  1110   also have "Pi\<^sub>E UNIV (case_bool A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
  1111     using A[THEN sets.sets_into_space] B[THEN sets.sets_into_space]
  1112     by (auto simp: PiE_iff all_bool_eq space_PiM split: bool.split)
  1113   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
  1114     using A B
  1115       measurable_component_singleton[of True UNIV "case_bool M1 M2"]
  1116       measurable_component_singleton[of False UNIV "case_bool M1 M2"]
  1117     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
  1118 qed simp
  1119 
  1120 end