src/ZF/Constructible/Datatype_absolute.thy
author paulson
Thu Jul 25 18:29:04 2002 +0200 (2002-07-25)
changeset 13423 7ec771711c09
parent 13422 af9bc8d87a75
child 13428 99e52e78eb65
permissions -rw-r--r--
More lemmas, working towards relativization of "satisfies"
     1 header {*Absoluteness Properties for Recursive Datatypes*}
     2 
     3 theory Datatype_absolute = Formula + WF_absolute:
     4 
     5 
     6 subsection{*The lfp of a continuous function can be expressed as a union*}
     7 
     8 constdefs
     9   directed :: "i=>o"
    10    "directed(A) == A\<noteq>0 & (\<forall>x\<in>A. \<forall>y\<in>A. x \<union> y \<in> A)"
    11 
    12   contin :: "(i=>i) => o"
    13    "contin(h) == (\<forall>A. directed(A) --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    14 
    15 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    16 apply (induct_tac n) 
    17  apply (simp_all add: bnd_mono_def, blast) 
    18 done
    19 
    20 lemma bnd_mono_increasing [rule_format]:
    21      "[|i \<in> nat; j \<in> nat; bnd_mono(D,h)|] ==> i \<le> j --> h^i(0) \<subseteq> h^j(0)"
    22 apply (rule_tac m=i and n=j in diff_induct, simp_all)
    23 apply (blast del: subsetI
    24 	     intro: bnd_mono_iterates_subset bnd_monoD2 [of concl: h]) 
    25 done
    26 
    27 lemma directed_iterates: "bnd_mono(D,h) ==> directed({h^n (0). n\<in>nat})"
    28 apply (simp add: directed_def, clarify) 
    29 apply (rename_tac i j)
    30 apply (rule_tac x="i \<union> j" in bexI) 
    31 apply (rule_tac i = i and j = j in Ord_linear_le)
    32 apply (simp_all add: subset_Un_iff [THEN iffD1] le_imp_subset
    33                      subset_Un_iff2 [THEN iffD1])
    34 apply (simp_all add: subset_Un_iff [THEN iff_sym] bnd_mono_increasing
    35                      subset_Un_iff2 [THEN iff_sym])
    36 done
    37 
    38 
    39 lemma contin_iterates_eq: 
    40     "[|bnd_mono(D, h); contin(h)|] 
    41      ==> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    42 apply (simp add: contin_def directed_iterates) 
    43 apply (rule trans) 
    44 apply (rule equalityI) 
    45  apply (simp_all add: UN_subset_iff)
    46  apply safe
    47  apply (erule_tac [2] natE) 
    48   apply (rule_tac a="succ(x)" in UN_I) 
    49    apply simp_all 
    50 apply blast 
    51 done
    52 
    53 lemma lfp_subset_Union:
    54      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    55 apply (rule lfp_lowerbound) 
    56  apply (simp add: contin_iterates_eq) 
    57 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    58 done
    59 
    60 lemma Union_subset_lfp:
    61      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    62 apply (simp add: UN_subset_iff)
    63 apply (rule ballI)  
    64 apply (induct_tac n, simp_all) 
    65 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    66  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset])  
    67 apply (erule lfp_lemma2) 
    68 done
    69 
    70 lemma lfp_eq_Union:
    71      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    72 by (blast del: subsetI 
    73           intro: lfp_subset_Union Union_subset_lfp)
    74 
    75 
    76 subsubsection{*Some Standard Datatype Constructions Preserve Continuity*}
    77 
    78 lemma contin_imp_mono: "[|X\<subseteq>Y; contin(F)|] ==> F(X) \<subseteq> F(Y)"
    79 apply (simp add: contin_def) 
    80 apply (drule_tac x="{X,Y}" in spec) 
    81 apply (simp add: directed_def subset_Un_iff2 Un_commute) 
    82 done
    83 
    84 lemma sum_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) + G(X))"
    85 by (simp add: contin_def, blast)
    86 
    87 lemma prod_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) * G(X))" 
    88 apply (subgoal_tac "\<forall>B C. F(B) \<subseteq> F(B \<union> C)")
    89  prefer 2 apply (simp add: Un_upper1 contin_imp_mono) 
    90 apply (subgoal_tac "\<forall>B C. G(C) \<subseteq> G(B \<union> C)")
    91  prefer 2 apply (simp add: Un_upper2 contin_imp_mono) 
    92 apply (simp add: contin_def, clarify) 
    93 apply (rule equalityI) 
    94  prefer 2 apply blast 
    95 apply clarify 
    96 apply (rename_tac B C) 
    97 apply (rule_tac a="B \<union> C" in UN_I) 
    98  apply (simp add: directed_def, blast)  
    99 done
   100 
   101 lemma const_contin: "contin(\<lambda>X. A)"
   102 by (simp add: contin_def directed_def)
   103 
   104 lemma id_contin: "contin(\<lambda>X. X)"
   105 by (simp add: contin_def)
   106 
   107 
   108 
   109 subsection {*Absoluteness for "Iterates"*}
   110 
   111 constdefs
   112 
   113   iterates_MH :: "[i=>o, [i,i]=>o, i, i, i, i] => o"
   114    "iterates_MH(M,isF,v,n,g,z) ==
   115         is_nat_case(M, v, \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & isF(gm,u),
   116                     n, z)"
   117 
   118   iterates_replacement :: "[i=>o, [i,i]=>o, i] => o"
   119    "iterates_replacement(M,isF,v) ==
   120       \<forall>n[M]. n\<in>nat --> 
   121          wfrec_replacement(M, iterates_MH(M,isF,v), Memrel(succ(n)))"
   122 
   123 lemma (in M_axioms) iterates_MH_abs:
   124   "[| relativize1(M,isF,F); M(n); M(g); M(z) |] 
   125    ==> iterates_MH(M,isF,v,n,g,z) <-> z = nat_case(v, \<lambda>m. F(g`m), n)"
   126 by (simp add: nat_case_abs [of _ "\<lambda>m. F(g ` m)"]
   127               relativize1_def iterates_MH_def)  
   128 
   129 lemma (in M_axioms) iterates_imp_wfrec_replacement:
   130   "[|relativize1(M,isF,F); n \<in> nat; iterates_replacement(M,isF,v)|] 
   131    ==> wfrec_replacement(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   132                        Memrel(succ(n)))" 
   133 by (simp add: iterates_replacement_def iterates_MH_abs)
   134 
   135 theorem (in M_trancl) iterates_abs:
   136   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   137       n \<in> nat; M(v); M(z); \<forall>x[M]. M(F(x)) |] 
   138    ==> is_wfrec(M, iterates_MH(M,isF,v), Memrel(succ(n)), n, z) <->
   139        z = iterates(F,n,v)" 
   140 apply (frule iterates_imp_wfrec_replacement, assumption+)
   141 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   142                  relativize2_def iterates_MH_abs 
   143                  iterates_nat_def recursor_def transrec_def 
   144                  eclose_sing_Ord_eq nat_into_M
   145          trans_wfrec_abs [of _ _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   146 done
   147 
   148 
   149 lemma (in M_wfrank) iterates_closed [intro,simp]:
   150   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   151       n \<in> nat; M(v); \<forall>x[M]. M(F(x)) |] 
   152    ==> M(iterates(F,n,v))"
   153 apply (frule iterates_imp_wfrec_replacement, assumption+)
   154 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   155                  relativize2_def iterates_MH_abs 
   156                  iterates_nat_def recursor_def transrec_def 
   157                  eclose_sing_Ord_eq nat_into_M
   158          trans_wfrec_closed [of _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   159 done
   160 
   161 
   162 subsection {*lists without univ*}
   163 
   164 lemmas datatype_univs = Inl_in_univ Inr_in_univ 
   165                         Pair_in_univ nat_into_univ A_into_univ 
   166 
   167 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
   168 apply (rule bnd_monoI)
   169  apply (intro subset_refl zero_subset_univ A_subset_univ 
   170 	      sum_subset_univ Sigma_subset_univ) 
   171 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   172 done
   173 
   174 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
   175 by (intro sum_contin prod_contin id_contin const_contin) 
   176 
   177 text{*Re-expresses lists using sum and product*}
   178 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
   179 apply (simp add: list_def) 
   180 apply (rule equalityI) 
   181  apply (rule lfp_lowerbound) 
   182   prefer 2 apply (rule lfp_subset)
   183  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
   184  apply (simp add: Nil_def Cons_def)
   185  apply blast 
   186 txt{*Opposite inclusion*}
   187 apply (rule lfp_lowerbound) 
   188  prefer 2 apply (rule lfp_subset) 
   189 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
   190 apply (simp add: Nil_def Cons_def)
   191 apply (blast intro: datatype_univs
   192              dest: lfp_subset [THEN subsetD])
   193 done
   194 
   195 text{*Re-expresses lists using "iterates", no univ.*}
   196 lemma list_eq_Union:
   197      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
   198 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
   199 
   200 
   201 constdefs
   202   is_list_functor :: "[i=>o,i,i,i] => o"
   203     "is_list_functor(M,A,X,Z) == 
   204         \<exists>n1[M]. \<exists>AX[M]. 
   205          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   206 
   207 lemma (in M_axioms) list_functor_abs [simp]: 
   208      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   209 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   210 
   211 
   212 subsection {*formulas without univ*}
   213 
   214 lemma formula_fun_bnd_mono:
   215      "bnd_mono(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   216 apply (rule bnd_monoI)
   217  apply (intro subset_refl zero_subset_univ A_subset_univ 
   218 	      sum_subset_univ Sigma_subset_univ nat_subset_univ) 
   219 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   220 done
   221 
   222 lemma formula_fun_contin:
   223      "contin(\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   224 by (intro sum_contin prod_contin id_contin const_contin) 
   225 
   226 
   227 text{*Re-expresses formulas using sum and product*}
   228 lemma formula_eq_lfp2:
   229     "formula = lfp(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   230 apply (simp add: formula_def) 
   231 apply (rule equalityI) 
   232  apply (rule lfp_lowerbound) 
   233   prefer 2 apply (rule lfp_subset)
   234  apply (clarify, subst lfp_unfold [OF formula_fun_bnd_mono])
   235  apply (simp add: Member_def Equal_def Nand_def Forall_def)
   236  apply blast 
   237 txt{*Opposite inclusion*}
   238 apply (rule lfp_lowerbound) 
   239  prefer 2 apply (rule lfp_subset, clarify) 
   240 apply (subst lfp_unfold [OF formula.bnd_mono, simplified]) 
   241 apply (simp add: Member_def Equal_def Nand_def Forall_def)  
   242 apply (elim sumE SigmaE, simp_all) 
   243 apply (blast intro: datatype_univs dest: lfp_subset [THEN subsetD])+  
   244 done
   245 
   246 text{*Re-expresses formulas using "iterates", no univ.*}
   247 lemma formula_eq_Union:
   248      "formula = 
   249       (\<Union>n\<in>nat. (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0))"
   250 by (simp add: formula_eq_lfp2 lfp_eq_Union formula_fun_bnd_mono 
   251               formula_fun_contin)
   252 
   253 
   254 constdefs
   255   is_formula_functor :: "[i=>o,i,i] => o"
   256     "is_formula_functor(M,X,Z) == 
   257         \<exists>nat'[M]. \<exists>natnat[M]. \<exists>natnatsum[M]. \<exists>XX[M]. \<exists>X3[M]. 
   258           omega(M,nat') & cartprod(M,nat',nat',natnat) & 
   259           is_sum(M,natnat,natnat,natnatsum) &
   260           cartprod(M,X,X,XX) & is_sum(M,XX,X,X3) & 
   261           is_sum(M,natnatsum,X3,Z)"
   262 
   263 lemma (in M_axioms) formula_functor_abs [simp]: 
   264      "[| M(X); M(Z) |] 
   265       ==> is_formula_functor(M,X,Z) <-> 
   266           Z = ((nat*nat) + (nat*nat)) + (X*X + X)"
   267 by (simp add: is_formula_functor_def) 
   268 
   269 
   270 subsection{*@{term M} Contains the List and Formula Datatypes*}
   271 
   272 constdefs
   273   list_N :: "[i,i] => i"
   274     "list_N(A,n) == (\<lambda>X. {0} + A * X)^n (0)"
   275 
   276 lemma Nil_in_list_N [simp]: "[] \<in> list_N(A,succ(n))"
   277 by (simp add: list_N_def Nil_def)
   278 
   279 lemma Cons_in_list_N [simp]:
   280      "Cons(a,l) \<in> list_N(A,succ(n)) <-> a\<in>A & l \<in> list_N(A,n)"
   281 by (simp add: list_N_def Cons_def) 
   282 
   283 text{*These two aren't simprules because they reveal the underlying
   284 list representation.*}
   285 lemma list_N_0: "list_N(A,0) = 0"
   286 by (simp add: list_N_def)
   287 
   288 lemma list_N_succ: "list_N(A,succ(n)) = {0} + A * (list_N(A,n))"
   289 by (simp add: list_N_def)
   290 
   291 lemma list_N_imp_list:
   292   "[| l \<in> list_N(A,n); n \<in> nat |] ==> l \<in> list(A)"
   293 by (force simp add: list_eq_Union list_N_def)
   294 
   295 lemma list_N_imp_length_lt [rule_format]:
   296      "n \<in> nat ==> \<forall>l \<in> list_N(A,n). length(l) < n"
   297 apply (induct_tac n)  
   298 apply (auto simp add: list_N_0 list_N_succ 
   299                       Nil_def [symmetric] Cons_def [symmetric]) 
   300 done
   301 
   302 lemma list_imp_list_N [rule_format]:
   303      "l \<in> list(A) ==> \<forall>n\<in>nat. length(l) < n --> l \<in> list_N(A, n)"
   304 apply (induct_tac l)
   305 apply (force elim: natE)+
   306 done
   307 
   308 lemma list_N_imp_eq_length:
   309       "[|n \<in> nat; l \<notin> list_N(A, n); l \<in> list_N(A, succ(n))|] 
   310        ==> n = length(l)"
   311 apply (rule le_anti_sym) 
   312  prefer 2 apply (simp add: list_N_imp_length_lt) 
   313 apply (frule list_N_imp_list, simp)
   314 apply (simp add: not_lt_iff_le [symmetric]) 
   315 apply (blast intro: list_imp_list_N) 
   316 done
   317   
   318 text{*Express @{term list_rec} without using @{term rank} or @{term Vset},
   319 neither of which is absolute.*}
   320 lemma (in M_triv_axioms) list_rec_eq:
   321   "l \<in> list(A) ==>
   322    list_rec(a,g,l) = 
   323    transrec (succ(length(l)),
   324       \<lambda>x h. Lambda (list(A),
   325                     list_case' (a, 
   326                            \<lambda>a l. g(a, l, h ` succ(length(l)) ` l)))) ` l"
   327 apply (induct_tac l) 
   328 apply (subst transrec, simp) 
   329 apply (subst transrec) 
   330 apply (simp add: list_imp_list_N) 
   331 done
   332 
   333 constdefs
   334   is_list_N :: "[i=>o,i,i,i] => o"
   335     "is_list_N(M,A,n,Z) == 
   336       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   337        empty(M,zero) & 
   338        successor(M,n,sn) & membership(M,sn,msn) &
   339        is_wfrec(M, iterates_MH(M, is_list_functor(M,A),zero), msn, n, Z)"
   340   
   341   mem_list :: "[i=>o,i,i] => o"
   342     "mem_list(M,A,l) == 
   343       \<exists>n[M]. \<exists>listn[M]. 
   344        finite_ordinal(M,n) & is_list_N(M,A,n,listn) & l \<in> listn"
   345 
   346   is_list :: "[i=>o,i,i] => o"
   347     "is_list(M,A,Z) == \<forall>l[M]. l \<in> Z <-> mem_list(M,A,l)"
   348 
   349 constdefs
   350   is_formula_n :: "[i=>o,i,i] => o"
   351     "is_formula_n(M,n,Z) == 
   352       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   353        empty(M,zero) & 
   354        successor(M,n,sn) & membership(M,sn,msn) &
   355        is_wfrec(M, iterates_MH(M, is_formula_functor(M),zero), msn, n, Z)"
   356   
   357   mem_formula :: "[i=>o,i] => o"
   358     "mem_formula(M,p) == 
   359       \<exists>n[M]. \<exists>formn[M]. 
   360        finite_ordinal(M,n) & is_formula_n(M,n,formn) & p \<in> formn"
   361 
   362   is_formula :: "[i=>o,i] => o"
   363     "is_formula(M,Z) == \<forall>p[M]. p \<in> Z <-> mem_formula(M,p)"
   364 
   365 locale (open) M_datatypes = M_wfrank +
   366  assumes list_replacement1: 
   367    "M(A) ==> iterates_replacement(M, is_list_functor(M,A), 0)"
   368   and list_replacement2: 
   369    "M(A) ==> strong_replacement(M, 
   370          \<lambda>n y. n\<in>nat & 
   371                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   372                is_wfrec(M, iterates_MH(M,is_list_functor(M,A), 0), 
   373                         msn, n, y)))"
   374   and formula_replacement1: 
   375    "iterates_replacement(M, is_formula_functor(M), 0)"
   376   and formula_replacement2: 
   377    "strong_replacement(M, 
   378          \<lambda>n y. n\<in>nat & 
   379                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   380                is_wfrec(M, iterates_MH(M,is_formula_functor(M), 0), 
   381                         msn, n, y)))"
   382   and nth_replacement:
   383    "M(l) ==> iterates_replacement(M, %l t. is_tl(M,l,t), l)"
   384         
   385 
   386 subsubsection{*Absoluteness of the List Construction*}
   387 
   388 lemma (in M_datatypes) list_replacement2': 
   389   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. {0} + A * X)^n (0))"
   390 apply (insert list_replacement2 [of A]) 
   391 apply (rule strong_replacement_cong [THEN iffD1])  
   392 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_list_functor(M,A)"]]) 
   393 apply (simp_all add: list_replacement1 relativize1_def) 
   394 done
   395 
   396 lemma (in M_datatypes) list_closed [intro,simp]:
   397      "M(A) ==> M(list(A))"
   398 apply (insert list_replacement1)
   399 by  (simp add: RepFun_closed2 list_eq_Union 
   400                list_replacement2' relativize1_def
   401                iterates_closed [of "is_list_functor(M,A)"])
   402 
   403 text{*WARNING: use only with @{text "dest:"} or with variables fixed!*}
   404 lemmas (in M_datatypes) list_into_M = transM [OF _ list_closed]
   405 
   406 lemma (in M_datatypes) list_N_abs [simp]:
   407      "[|M(A); n\<in>nat; M(Z)|] 
   408       ==> is_list_N(M,A,n,Z) <-> Z = list_N(A,n)"
   409 apply (insert list_replacement1)
   410 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   411                  iterates_abs [of "is_list_functor(M,A)" _ "\<lambda>X. {0} + A*X"])
   412 done
   413 
   414 lemma (in M_datatypes) list_N_closed [intro,simp]:
   415      "[|M(A); n\<in>nat|] ==> M(list_N(A,n))"
   416 apply (insert list_replacement1)
   417 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   418                  iterates_closed [of "is_list_functor(M,A)"])
   419 done
   420 
   421 lemma (in M_datatypes) mem_list_abs [simp]:
   422      "M(A) ==> mem_list(M,A,l) <-> l \<in> list(A)"
   423 apply (insert list_replacement1)
   424 apply (simp add: mem_list_def list_N_def relativize1_def list_eq_Union
   425                  iterates_closed [of "is_list_functor(M,A)"]) 
   426 done
   427 
   428 lemma (in M_datatypes) list_abs [simp]:
   429      "[|M(A); M(Z)|] ==> is_list(M,A,Z) <-> Z = list(A)"
   430 apply (simp add: is_list_def, safe)
   431 apply (rule M_equalityI, simp_all)
   432 done
   433 
   434 subsubsection{*Absoluteness of Formulas*}
   435 
   436 lemma (in M_datatypes) formula_replacement2': 
   437   "strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))^n (0))"
   438 apply (insert formula_replacement2) 
   439 apply (rule strong_replacement_cong [THEN iffD1])  
   440 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_formula_functor(M)"]]) 
   441 apply (simp_all add: formula_replacement1 relativize1_def) 
   442 done
   443 
   444 lemma (in M_datatypes) formula_closed [intro,simp]:
   445      "M(formula)"
   446 apply (insert formula_replacement1)
   447 apply  (simp add: RepFun_closed2 formula_eq_Union 
   448                   formula_replacement2' relativize1_def
   449                   iterates_closed [of "is_formula_functor(M)"])
   450 done
   451 
   452 lemmas (in M_datatypes) formula_into_M = transM [OF _ formula_closed]
   453 
   454 lemma (in M_datatypes) is_formula_n_abs [simp]:
   455      "[|n\<in>nat; M(Z)|] 
   456       ==> is_formula_n(M,n,Z) <-> 
   457           Z = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))^n (0)"
   458 apply (insert formula_replacement1)
   459 apply (simp add: is_formula_n_def relativize1_def nat_into_M
   460                  iterates_abs [of "is_formula_functor(M)" _ 
   461                         "\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)"])
   462 done
   463 
   464 lemma (in M_datatypes) mem_formula_abs [simp]:
   465      "mem_formula(M,l) <-> l \<in> formula"
   466 apply (insert formula_replacement1)
   467 apply (simp add: mem_formula_def relativize1_def formula_eq_Union
   468                  iterates_closed [of "is_formula_functor(M)"]) 
   469 done
   470 
   471 lemma (in M_datatypes) formula_abs [simp]:
   472      "[|M(Z)|] ==> is_formula(M,Z) <-> Z = formula"
   473 apply (simp add: is_formula_def, safe)
   474 apply (rule M_equalityI, simp_all)
   475 done
   476 
   477 
   478 subsection{*Absoluteness for Some List Operators*}
   479 
   480 subsection{*Absoluteness for @{text \<epsilon>}-Closure: the @{term eclose} Operator*}
   481 
   482 text{*Re-expresses eclose using "iterates"*}
   483 lemma eclose_eq_Union:
   484      "eclose(A) = (\<Union>n\<in>nat. Union^n (A))"
   485 apply (simp add: eclose_def) 
   486 apply (rule UN_cong) 
   487 apply (rule refl)
   488 apply (induct_tac n)
   489 apply (simp add: nat_rec_0)  
   490 apply (simp add: nat_rec_succ) 
   491 done
   492 
   493 constdefs
   494   is_eclose_n :: "[i=>o,i,i,i] => o"
   495     "is_eclose_n(M,A,n,Z) == 
   496       \<exists>sn[M]. \<exists>msn[M]. 
   497        successor(M,n,sn) & membership(M,sn,msn) &
   498        is_wfrec(M, iterates_MH(M, big_union(M), A), msn, n, Z)"
   499   
   500   mem_eclose :: "[i=>o,i,i] => o"
   501     "mem_eclose(M,A,l) == 
   502       \<exists>n[M]. \<exists>eclosen[M]. 
   503        finite_ordinal(M,n) & is_eclose_n(M,A,n,eclosen) & l \<in> eclosen"
   504 
   505   is_eclose :: "[i=>o,i,i] => o"
   506     "is_eclose(M,A,Z) == \<forall>u[M]. u \<in> Z <-> mem_eclose(M,A,u)"
   507 
   508 
   509 locale (open) M_eclose = M_datatypes +
   510  assumes eclose_replacement1: 
   511    "M(A) ==> iterates_replacement(M, big_union(M), A)"
   512   and eclose_replacement2: 
   513    "M(A) ==> strong_replacement(M, 
   514          \<lambda>n y. n\<in>nat & 
   515                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   516                is_wfrec(M, iterates_MH(M,big_union(M), A), 
   517                         msn, n, y)))"
   518 
   519 lemma (in M_eclose) eclose_replacement2': 
   520   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = Union^n (A))"
   521 apply (insert eclose_replacement2 [of A]) 
   522 apply (rule strong_replacement_cong [THEN iffD1])  
   523 apply (rule conj_cong [OF iff_refl iterates_abs [of "big_union(M)"]]) 
   524 apply (simp_all add: eclose_replacement1 relativize1_def) 
   525 done
   526 
   527 lemma (in M_eclose) eclose_closed [intro,simp]:
   528      "M(A) ==> M(eclose(A))"
   529 apply (insert eclose_replacement1)
   530 by  (simp add: RepFun_closed2 eclose_eq_Union 
   531                eclose_replacement2' relativize1_def
   532                iterates_closed [of "big_union(M)"])
   533 
   534 lemma (in M_eclose) is_eclose_n_abs [simp]:
   535      "[|M(A); n\<in>nat; M(Z)|] ==> is_eclose_n(M,A,n,Z) <-> Z = Union^n (A)"
   536 apply (insert eclose_replacement1)
   537 apply (simp add: is_eclose_n_def relativize1_def nat_into_M
   538                  iterates_abs [of "big_union(M)" _ "Union"])
   539 done
   540 
   541 lemma (in M_eclose) mem_eclose_abs [simp]:
   542      "M(A) ==> mem_eclose(M,A,l) <-> l \<in> eclose(A)"
   543 apply (insert eclose_replacement1)
   544 apply (simp add: mem_eclose_def relativize1_def eclose_eq_Union
   545                  iterates_closed [of "big_union(M)"]) 
   546 done
   547 
   548 lemma (in M_eclose) eclose_abs [simp]:
   549      "[|M(A); M(Z)|] ==> is_eclose(M,A,Z) <-> Z = eclose(A)"
   550 apply (simp add: is_eclose_def, safe)
   551 apply (rule M_equalityI, simp_all)
   552 done
   553 
   554 
   555 
   556 
   557 subsection {*Absoluteness for @{term transrec}*}
   558 
   559 
   560 text{* @{term "transrec(a,H) \<equiv> wfrec(Memrel(eclose({a})), a, H)"} *}
   561 constdefs
   562 
   563   is_transrec :: "[i=>o, [i,i,i]=>o, i, i] => o"
   564    "is_transrec(M,MH,a,z) == 
   565       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   566        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   567        is_wfrec(M,MH,mesa,a,z)"
   568 
   569   transrec_replacement :: "[i=>o, [i,i,i]=>o, i] => o"
   570    "transrec_replacement(M,MH,a) ==
   571       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   572        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   573        wfrec_replacement(M,MH,mesa)"
   574 
   575 text{*The condition @{term "Ord(i)"} lets us use the simpler 
   576   @{text "trans_wfrec_abs"} rather than @{text "trans_wfrec_abs"},
   577   which I haven't even proved yet. *}
   578 theorem (in M_eclose) transrec_abs:
   579   "[|transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   580      Ord(i);  M(i);  M(z);
   581      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   582    ==> is_transrec(M,MH,i,z) <-> z = transrec(i,H)" 
   583 apply (rotate_tac 2) 
   584 apply (simp add: trans_wfrec_abs transrec_replacement_def is_transrec_def
   585        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   586 done
   587 
   588 
   589 theorem (in M_eclose) transrec_closed:
   590      "[|transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   591 	Ord(i);  M(i);  
   592 	\<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   593       ==> M(transrec(i,H))"
   594 apply (rotate_tac 2) 
   595 apply (simp add: trans_wfrec_closed transrec_replacement_def is_transrec_def
   596        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   597 done
   598 
   599 
   600 subsection{*Absoluteness for the List Operator @{term length}*}
   601 constdefs
   602 
   603   is_length :: "[i=>o,i,i,i] => o"
   604     "is_length(M,A,l,n) == 
   605        \<exists>sn[M]. \<exists>list_n[M]. \<exists>list_sn[M]. 
   606         is_list_N(M,A,n,list_n) & l \<notin> list_n &
   607         successor(M,n,sn) & is_list_N(M,A,sn,list_sn) & l \<in> list_sn"
   608 
   609 
   610 lemma (in M_datatypes) length_abs [simp]:
   611      "[|M(A); l \<in> list(A); n \<in> nat|] ==> is_length(M,A,l,n) <-> n = length(l)"
   612 apply (subgoal_tac "M(l) & M(n)")
   613  prefer 2 apply (blast dest: transM)  
   614 apply (simp add: is_length_def)
   615 apply (blast intro: list_imp_list_N nat_into_Ord list_N_imp_eq_length
   616              dest: list_N_imp_length_lt)
   617 done
   618 
   619 text{*Proof is trivial since @{term length} returns natural numbers.*}
   620 lemma (in M_triv_axioms) length_closed [intro,simp]:
   621      "l \<in> list(A) ==> M(length(l))"
   622 by (simp add: nat_into_M) 
   623 
   624 
   625 subsection {*Absoluteness for @{term nth}*}
   626 
   627 lemma nth_eq_hd_iterates_tl [rule_format]:
   628      "xs \<in> list(A) ==> \<forall>n \<in> nat. nth(n,xs) = hd' (tl'^n (xs))"
   629 apply (induct_tac xs) 
   630 apply (simp add: iterates_tl_Nil hd'_Nil, clarify) 
   631 apply (erule natE)
   632 apply (simp add: hd'_Cons) 
   633 apply (simp add: tl'_Cons iterates_commute) 
   634 done
   635 
   636 lemma (in M_axioms) iterates_tl'_closed:
   637      "[|n \<in> nat; M(x)|] ==> M(tl'^n (x))"
   638 apply (induct_tac n, simp) 
   639 apply (simp add: tl'_Cons tl'_closed) 
   640 done
   641 
   642 text{*Immediate by type-checking*}
   643 lemma (in M_datatypes) nth_closed [intro,simp]:
   644      "[|xs \<in> list(A); n \<in> nat; M(A)|] ==> M(nth(n,xs))" 
   645 apply (case_tac "n < length(xs)")
   646  apply (blast intro: nth_type transM)
   647 apply (simp add: not_lt_iff_le nth_eq_0)
   648 done
   649 
   650 constdefs
   651   is_nth :: "[i=>o,i,i,i] => o"
   652     "is_nth(M,n,l,Z) == 
   653       \<exists>X[M]. \<exists>sn[M]. \<exists>msn[M]. 
   654        successor(M,n,sn) & membership(M,sn,msn) &
   655        is_wfrec(M, iterates_MH(M, is_tl(M), l), msn, n, X) &
   656        is_hd(M,X,Z)"
   657  
   658 lemma (in M_datatypes) nth_abs [simp]:
   659      "[|M(A); n \<in> nat; l \<in> list(A); M(Z)|] 
   660       ==> is_nth(M,n,l,Z) <-> Z = nth(n,l)"
   661 apply (subgoal_tac "M(l)") 
   662  prefer 2 apply (blast intro: transM)
   663 apply (simp add: is_nth_def nth_eq_hd_iterates_tl nat_into_M
   664                  tl'_closed iterates_tl'_closed 
   665                  iterates_abs [OF _ relativize1_tl] nth_replacement)
   666 done
   667 
   668 
   669 subsection{*Relativization and Absoluteness for the @{term formula} Constructors*}
   670 
   671 constdefs
   672   is_Member :: "[i=>o,i,i,i] => o"
   673      --{* because @{term "Member(x,y) \<equiv> Inl(Inl(\<langle>x,y\<rangle>))"}*}
   674     "is_Member(M,x,y,Z) ==
   675 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inl(M,u,Z)"
   676 
   677 lemma (in M_triv_axioms) Member_abs [simp]:
   678      "[|M(x); M(y); M(Z)|] ==> is_Member(M,x,y,Z) <-> (Z = Member(x,y))"
   679 by (simp add: is_Member_def Member_def)
   680 
   681 lemma (in M_triv_axioms) Member_in_M_iff [iff]:
   682      "M(Member(x,y)) <-> M(x) & M(y)"
   683 by (simp add: Member_def) 
   684 
   685 constdefs
   686   is_Equal :: "[i=>o,i,i,i] => o"
   687      --{* because @{term "Equal(x,y) \<equiv> Inl(Inr(\<langle>x,y\<rangle>))"}*}
   688     "is_Equal(M,x,y,Z) ==
   689 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inr(M,p,u) & is_Inl(M,u,Z)"
   690 
   691 lemma (in M_triv_axioms) Equal_abs [simp]:
   692      "[|M(x); M(y); M(Z)|] ==> is_Equal(M,x,y,Z) <-> (Z = Equal(x,y))"
   693 by (simp add: is_Equal_def Equal_def)
   694 
   695 lemma (in M_triv_axioms) Equal_in_M_iff [iff]: "M(Equal(x,y)) <-> M(x) & M(y)"
   696 by (simp add: Equal_def) 
   697 
   698 constdefs
   699   is_Nand :: "[i=>o,i,i,i] => o"
   700      --{* because @{term "Nand(x,y) \<equiv> Inr(Inl(\<langle>x,y\<rangle>))"}*}
   701     "is_Nand(M,x,y,Z) ==
   702 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inr(M,u,Z)"
   703 
   704 lemma (in M_triv_axioms) Nand_abs [simp]:
   705      "[|M(x); M(y); M(Z)|] ==> is_Nand(M,x,y,Z) <-> (Z = Nand(x,y))"
   706 by (simp add: is_Nand_def Nand_def)
   707 
   708 lemma (in M_triv_axioms) Nand_in_M_iff [iff]: "M(Nand(x,y)) <-> M(x) & M(y)"
   709 by (simp add: Nand_def) 
   710 
   711 constdefs
   712   is_Forall :: "[i=>o,i,i] => o"
   713      --{* because @{term "Forall(x) \<equiv> Inr(Inr(p))"}*}
   714     "is_Forall(M,p,Z) == \<exists>u[M]. is_Inr(M,p,u) & is_Inr(M,u,Z)"
   715 
   716 lemma (in M_triv_axioms) Forall_abs [simp]:
   717      "[|M(x); M(Z)|] ==> is_Forall(M,x,Z) <-> (Z = Forall(x))"
   718 by (simp add: is_Forall_def Forall_def)
   719 
   720 lemma (in M_triv_axioms) Forall_in_M_iff [iff]: "M(Forall(x)) <-> M(x)"
   721 by (simp add: Forall_def)
   722 
   723 
   724 subsection {*Absoluteness for @{term formula_rec}*}
   725 
   726 subsubsection{*@{term is_formula_case}: relativization of @{term formula_case}*}
   727 
   728 constdefs
   729 
   730  is_formula_case :: 
   731     "[i=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i]=>o, i, i] => o"
   732   --{*no constraint on non-formulas*}
   733   "is_formula_case(M, is_a, is_b, is_c, is_d, p, z) == 
   734       (\<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> is_Member(M,x,y,p) --> is_a(x,y,z)) &
   735       (\<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> is_Equal(M,x,y,p) --> is_b(x,y,z)) &
   736       (\<forall>x[M]. \<forall>y[M]. x\<in>formula --> y\<in>formula --> 
   737                      is_Nand(M,x,y,p) --> is_c(x,y,z)) &
   738       (\<forall>x[M]. x\<in>formula --> is_Forall(M,x,p) --> is_d(x,z))"
   739 
   740 lemma (in M_datatypes) formula_case_abs [simp]: 
   741      "[| Relativize2(M,nat,nat,is_a,a); Relativize2(M,nat,nat,is_b,b); 
   742          Relativize2(M,formula,formula,is_c,c); Relativize1(M,formula,is_d,d); 
   743          p \<in> formula; M(z) |] 
   744       ==> is_formula_case(M,is_a,is_b,is_c,is_d,p,z) <-> 
   745           z = formula_case(a,b,c,d,p)"
   746 apply (simp add: formula_into_M is_formula_case_def)
   747 apply (erule formula.cases) 
   748    apply (simp_all add: Relativize1_def Relativize2_def) 
   749 done
   750 
   751 
   752 subsubsection{*@{term quasiformula}: For Case-Splitting with @{term formula_case'}*}
   753 
   754 constdefs
   755 
   756   quasiformula :: "i => o"
   757     "quasiformula(p) == 
   758 	(\<exists>x y. p = Member(x,y)) |
   759 	(\<exists>x y. p = Equal(x,y)) |
   760 	(\<exists>x y. p = Nand(x,y)) |
   761 	(\<exists>x. p = Forall(x))"
   762 
   763   is_quasiformula :: "[i=>o,i] => o"
   764     "is_quasiformula(M,p) == 
   765 	(\<exists>x[M]. \<exists>y[M]. is_Member(M,x,y,p)) |
   766 	(\<exists>x[M]. \<exists>y[M]. is_Equal(M,x,y,p)) |
   767 	(\<exists>x[M]. \<exists>y[M]. is_Nand(M,x,y,p)) |
   768 	(\<exists>x[M]. is_Forall(M,x,p))"
   769 
   770 lemma [iff]: "quasiformula(Member(x,y))"
   771 by (simp add: quasiformula_def)
   772 
   773 lemma [iff]: "quasiformula(Equal(x,y))"
   774 by (simp add: quasiformula_def)
   775 
   776 lemma [iff]: "quasiformula(Nand(x,y))"
   777 by (simp add: quasiformula_def)
   778 
   779 lemma [iff]: "quasiformula(Forall(x))"
   780 by (simp add: quasiformula_def)
   781 
   782 lemma formula_imp_quasiformula: "p \<in> formula ==> quasiformula(p)"
   783 by (erule formula.cases, simp_all)
   784 
   785 lemma (in M_triv_axioms) quasiformula_abs [simp]: 
   786      "M(z) ==> is_quasiformula(M,z) <-> quasiformula(z)"
   787 by (auto simp add: is_quasiformula_def quasiformula_def)
   788 
   789 constdefs
   790 
   791   formula_case' :: "[[i,i]=>i, [i,i]=>i, [i,i]=>i, i=>i, i] => i"
   792     --{*A version of @{term formula_case} that's always defined.*}
   793     "formula_case'(a,b,c,d,p) == 
   794        if quasiformula(p) then formula_case(a,b,c,d,p) else 0"  
   795 
   796   is_formula_case' :: 
   797       "[i=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i]=>o, i, i] => o"
   798     --{*Returns 0 for non-formulas*}
   799     "is_formula_case'(M, is_a, is_b, is_c, is_d, p, z) == 
   800 	(\<forall>x[M]. \<forall>y[M]. is_Member(M,x,y,p) --> is_a(x,y,z)) &
   801 	(\<forall>x[M]. \<forall>y[M]. is_Equal(M,x,y,p) --> is_b(x,y,z)) &
   802 	(\<forall>x[M]. \<forall>y[M]. is_Nand(M,x,y,p) --> is_c(x,y,z)) &
   803 	(\<forall>x[M]. is_Forall(M,x,p) --> is_d(x,z)) &
   804         (is_quasiformula(M,p) | empty(M,z))"
   805 
   806 subsubsection{*@{term formula_case'}, the Modified Version of @{term formula_case}*}
   807 
   808 lemma formula_case'_Member [simp]:
   809      "formula_case'(a,b,c,d,Member(x,y)) = a(x,y)"
   810 by (simp add: formula_case'_def)
   811 
   812 lemma formula_case'_Equal [simp]:
   813      "formula_case'(a,b,c,d,Equal(x,y)) = b(x,y)"
   814 by (simp add: formula_case'_def)
   815 
   816 lemma formula_case'_Nand [simp]:
   817      "formula_case'(a,b,c,d,Nand(x,y)) = c(x,y)"
   818 by (simp add: formula_case'_def)
   819 
   820 lemma formula_case'_Forall [simp]:
   821      "formula_case'(a,b,c,d,Forall(x)) = d(x)"
   822 by (simp add: formula_case'_def)
   823 
   824 lemma non_formula_case: "~ quasiformula(x) ==> formula_case'(a,b,c,d,x) = 0" 
   825 by (simp add: quasiformula_def formula_case'_def) 
   826 
   827 lemma formula_case'_eq_formula_case [simp]:
   828      "p \<in> formula ==>formula_case'(a,b,c,d,p) = formula_case(a,b,c,d,p)"
   829 by (erule formula.cases, simp_all)
   830 
   831 lemma (in M_axioms) formula_case'_closed [intro,simp]:
   832   "[|M(p); \<forall>x[M]. \<forall>y[M]. M(a(x,y)); 
   833            \<forall>x[M]. \<forall>y[M]. M(b(x,y)); 
   834            \<forall>x[M]. \<forall>y[M]. M(c(x,y)); 
   835            \<forall>x[M]. M(d(x))|] ==> M(formula_case'(a,b,c,d,p))"
   836 apply (case_tac "quasiformula(p)") 
   837  apply (simp add: quasiformula_def, force) 
   838 apply (simp add: non_formula_case) 
   839 done
   840 
   841 text{*Compared with @{text formula_case_closed'}, the premise on @{term p} is
   842       stronger while the other premises are weaker, incorporating typing 
   843       information.*}
   844 lemma (in M_datatypes) formula_case_closed [intro,simp]:
   845   "[|p \<in> formula; 
   846      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(a(x,y)); 
   847      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(b(x,y)); 
   848      \<forall>x[M]. \<forall>y[M]. x\<in>formula --> y\<in>formula --> M(c(x,y)); 
   849      \<forall>x[M]. x\<in>formula --> M(d(x))|] ==> M(formula_case(a,b,c,d,p))"
   850 by (erule formula.cases, simp_all) 
   851 
   852 lemma (in M_triv_axioms) formula_case'_abs [simp]: 
   853      "[| relativize2(M,is_a,a); relativize2(M,is_b,b); 
   854          relativize2(M,is_c,c); relativize1(M,is_d,d); M(p); M(z) |] 
   855       ==> is_formula_case'(M,is_a,is_b,is_c,is_d,p,z) <-> 
   856           z = formula_case'(a,b,c,d,p)"
   857 apply (case_tac "quasiformula(p)") 
   858  prefer 2 
   859  apply (simp add: is_formula_case'_def non_formula_case) 
   860  apply (force simp add: quasiformula_def) 
   861 apply (simp add: quasiformula_def is_formula_case'_def)
   862 apply (elim disjE exE) 
   863  apply (simp_all add: relativize1_def relativize2_def) 
   864 done
   865 
   866 
   867 subsubsection{*Towards Absoluteness of @{term formula_rec}*}
   868 
   869 consts   depth :: "i=>i"
   870 primrec
   871   "depth(Member(x,y)) = 0"
   872   "depth(Equal(x,y))  = 0"
   873   "depth(Nand(p,q)) = succ(depth(p) \<union> depth(q))"
   874   "depth(Forall(p)) = succ(depth(p))"
   875 
   876 lemma depth_type [TC]: "p \<in> formula ==> depth(p) \<in> nat"
   877 by (induct_tac p, simp_all) 
   878 
   879 
   880 constdefs
   881   formula_N :: "i => i"
   882     "formula_N(n) == (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0)"
   883 
   884 lemma Member_in_formula_N [simp]:
   885      "Member(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   886 by (simp add: formula_N_def Member_def) 
   887 
   888 lemma Equal_in_formula_N [simp]:
   889      "Equal(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   890 by (simp add: formula_N_def Equal_def) 
   891 
   892 lemma Nand_in_formula_N [simp]:
   893      "Nand(x,y) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n) & y \<in> formula_N(n)"
   894 by (simp add: formula_N_def Nand_def) 
   895 
   896 lemma Forall_in_formula_N [simp]:
   897      "Forall(x) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n)"
   898 by (simp add: formula_N_def Forall_def) 
   899 
   900 text{*These two aren't simprules because they reveal the underlying
   901 formula representation.*}
   902 lemma formula_N_0: "formula_N(0) = 0"
   903 by (simp add: formula_N_def)
   904 
   905 lemma formula_N_succ:
   906      "formula_N(succ(n)) = 
   907       ((nat*nat) + (nat*nat)) + (formula_N(n) * formula_N(n) + formula_N(n))"
   908 by (simp add: formula_N_def)
   909 
   910 lemma formula_N_imp_formula:
   911   "[| p \<in> formula_N(n); n \<in> nat |] ==> p \<in> formula"
   912 by (force simp add: formula_eq_Union formula_N_def)
   913 
   914 lemma formula_N_imp_depth_lt [rule_format]:
   915      "n \<in> nat ==> \<forall>p \<in> formula_N(n). depth(p) < n"
   916 apply (induct_tac n)  
   917 apply (auto simp add: formula_N_0 formula_N_succ 
   918                       depth_type formula_N_imp_formula Un_least_lt_iff
   919                       Member_def [symmetric] Equal_def [symmetric]
   920                       Nand_def [symmetric] Forall_def [symmetric]) 
   921 done
   922 
   923 lemma formula_imp_formula_N [rule_format]:
   924      "p \<in> formula ==> \<forall>n\<in>nat. depth(p) < n --> p \<in> formula_N(n)"
   925 apply (induct_tac p)
   926 apply (simp_all add: succ_Un_distrib Un_least_lt_iff) 
   927 apply (force elim: natE)+
   928 done
   929 
   930 lemma formula_N_imp_eq_depth:
   931       "[|n \<in> nat; p \<notin> formula_N(n); p \<in> formula_N(succ(n))|] 
   932        ==> n = depth(p)"
   933 apply (rule le_anti_sym) 
   934  prefer 2 apply (simp add: formula_N_imp_depth_lt) 
   935 apply (frule formula_N_imp_formula, simp)
   936 apply (simp add: not_lt_iff_le [symmetric]) 
   937 apply (blast intro: formula_imp_formula_N) 
   938 done
   939 
   940 
   941 
   942 lemma formula_N_mono [rule_format]:
   943   "[| m \<in> nat; n \<in> nat |] ==> m\<le>n --> formula_N(m) \<subseteq> formula_N(n)"
   944 apply (rule_tac m = m and n = n in diff_induct)
   945 apply (simp_all add: formula_N_0 formula_N_succ, blast) 
   946 done
   947 
   948 lemma formula_N_distrib:
   949   "[| m \<in> nat; n \<in> nat |] ==> formula_N(m \<union> n) = formula_N(m) \<union> formula_N(n)"
   950 apply (rule_tac i = m and j = n in Ord_linear_le, auto) 
   951 apply (simp_all add: subset_Un_iff [THEN iffD1] subset_Un_iff2 [THEN iffD1] 
   952                      le_imp_subset formula_N_mono)
   953 done
   954 
   955 text{*Express @{term formula_rec} without using @{term rank} or @{term Vset},
   956 neither of which is absolute.*}
   957 lemma (in M_triv_axioms) formula_rec_eq:
   958   "p \<in> formula ==>
   959    formula_rec(a,b,c,d,p) = 
   960    transrec (succ(depth(p)),
   961       \<lambda>x h. Lambda (formula,
   962              formula_case' (a, b,
   963                 \<lambda>u v. c(u, v, h ` succ(depth(u)) ` u, 
   964                               h ` succ(depth(v)) ` v),
   965                 \<lambda>u. d(u, h ` succ(depth(u)) ` u)))) 
   966    ` p"
   967 apply (induct_tac p)
   968    txt{*Base case for @{term Member}*}
   969    apply (subst transrec, simp add: formula.intros) 
   970   txt{*Base case for @{term Equal}*}
   971   apply (subst transrec, simp add: formula.intros)
   972  txt{*Inductive step for @{term Nand}*}
   973  apply (subst transrec) 
   974  apply (simp add: succ_Un_distrib formula.intros)
   975 txt{*Inductive step for @{term Forall}*}
   976 apply (subst transrec) 
   977 apply (simp add: formula_imp_formula_N formula.intros) 
   978 done
   979 
   980 
   981 constdefs
   982   is_formula_N :: "[i=>o,i,i] => o"
   983     "is_formula_N(M,n,Z) == 
   984       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   985        empty(M,zero) & 
   986        successor(M,n,sn) & membership(M,sn,msn) &
   987        is_wfrec(M, iterates_MH(M, is_formula_functor(M),zero), msn, n, Z)"
   988   
   989 
   990 lemma (in M_datatypes) formula_N_abs [simp]:
   991      "[|n\<in>nat; M(Z)|] 
   992       ==> is_formula_N(M,n,Z) <-> Z = formula_N(n)"
   993 apply (insert formula_replacement1)
   994 apply (simp add: is_formula_N_def formula_N_def relativize1_def nat_into_M
   995                  iterates_abs [of "is_formula_functor(M)" _ 
   996                                   "\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)"])
   997 done
   998 
   999 lemma (in M_datatypes) formula_N_closed [intro,simp]:
  1000      "n\<in>nat ==> M(formula_N(n))"
  1001 apply (insert formula_replacement1)
  1002 apply (simp add: is_formula_N_def formula_N_def relativize1_def nat_into_M
  1003                  iterates_closed [of "is_formula_functor(M)"])
  1004 done
  1005 
  1006 subsection{*Absoluteness for the Formula Operator @{term depth}*}
  1007 constdefs
  1008 
  1009   is_depth :: "[i=>o,i,i] => o"
  1010     "is_depth(M,p,n) == 
  1011        \<exists>sn[M]. \<exists>formula_n[M]. \<exists>formula_sn[M]. 
  1012         is_formula_N(M,n,formula_n) & p \<notin> formula_n &
  1013         successor(M,n,sn) & is_formula_N(M,sn,formula_sn) & p \<in> formula_sn"
  1014 
  1015 
  1016 lemma (in M_datatypes) depth_abs [simp]:
  1017      "[|p \<in> formula; n \<in> nat|] ==> is_depth(M,p,n) <-> n = depth(p)"
  1018 apply (subgoal_tac "M(p) & M(n)")
  1019  prefer 2 apply (blast dest: transM)  
  1020 apply (simp add: is_depth_def)
  1021 apply (blast intro: formula_imp_formula_N nat_into_Ord formula_N_imp_eq_depth
  1022              dest: formula_N_imp_depth_lt)
  1023 done
  1024 
  1025 text{*Proof is trivial since @{term depth} returns natural numbers.*}
  1026 lemma (in M_triv_axioms) depth_closed [intro,simp]:
  1027      "p \<in> formula ==> M(depth(p))"
  1028 by (simp add: nat_into_M) 
  1029 
  1030 end