src/Pure/Thy/present.ML
author wenzelm
Sun Mar 20 19:10:09 2011 +0100 (2011-03-20)
changeset 42006 7eecd020e367
parent 42005 78bb3ec281c2
child 42007 2142883ec29f
permissions -rw-r--r--
renamed doc_prefix2 to dump_prefix;
     1 (*  Title:      Pure/Thy/present.ML
     2     Author:     Markus Wenzel and Stefan Berghofer, TU Muenchen
     3 
     4 Theory presentation: HTML, graph files, (PDF)LaTeX documents.
     5 *)
     6 
     7 signature BASIC_PRESENT =
     8 sig
     9   val no_document: ('a -> 'b) -> 'a -> 'b
    10 end;
    11 
    12 signature PRESENT =
    13 sig
    14   include BASIC_PRESENT
    15   val session_name: theory -> string
    16   val write_graph: {name: string, ID: string, dir: string, unfold: bool,
    17    path: string, parents: string list} list -> Path.T -> unit
    18   val display_graph: {name: string, ID: string, dir: string, unfold: bool,
    19    path: string, parents: string list} list -> unit
    20   val init: bool -> bool -> string -> bool -> string list -> string list ->
    21     string -> (bool * Path.T) option -> Url.T option * bool -> bool -> theory list -> unit
    22   val finish: unit -> unit
    23   val init_theory: string -> unit
    24   val theory_source: string -> (unit -> HTML.text) -> unit
    25   val theory_output: string -> string -> unit
    26   val begin_theory: int -> Path.T -> (Path.T * bool) list -> theory -> theory
    27   val drafts: string -> Path.T list -> Path.T
    28 end;
    29 
    30 structure Present: PRESENT =
    31 struct
    32 
    33 
    34 (** paths **)
    35 
    36 val output_path = Path.variable "ISABELLE_BROWSER_INFO";
    37 
    38 val tex_ext = Path.ext "tex";
    39 val tex_path = tex_ext o Path.basic;
    40 val html_ext = Path.ext "html";
    41 val html_path = html_ext o Path.basic;
    42 val index_path = Path.basic "index.html";
    43 val readme_html_path = Path.basic "README.html";
    44 val readme_path = Path.basic "README";
    45 val documentN = "document";
    46 val document_path = Path.basic documentN;
    47 val doc_indexN = "session";
    48 val graph_path = Path.basic "session.graph";
    49 val graph_pdf_path = Path.basic "session_graph.pdf";
    50 val graph_eps_path = Path.basic "session_graph.eps";
    51 
    52 val session_path = Path.basic ".session";
    53 val session_entries_path = Path.explode ".session/entries";
    54 val pre_index_path = Path.explode ".session/pre-index";
    55 
    56 fun mk_rel_path [] ys = Path.make ys
    57   | mk_rel_path xs [] = Path.appends (replicate (length xs) Path.parent)
    58   | mk_rel_path (ps as x :: xs) (qs as y :: ys) = if x = y then mk_rel_path xs ys else
    59       Path.appends (replicate (length ps) Path.parent @ [Path.make qs]);
    60 
    61 fun show_path path = Path.implode (Path.append (File.pwd ()) path);
    62 
    63 
    64 
    65 (** additional theory data **)
    66 
    67 structure BrowserInfoData = Theory_Data
    68 (
    69   type T = {name: string, session: string list, is_local: bool};
    70   val empty = {name = "", session = [], is_local = false}: T;
    71   fun extend _ = empty;
    72   fun merge _ = empty;
    73 );
    74 
    75 val put_info = BrowserInfoData.put;
    76 val get_info = BrowserInfoData.get;
    77 val session_name = #name o get_info;
    78 
    79 
    80 
    81 (** graphs **)
    82 
    83 type graph_node =
    84   {name: string, ID: string, dir: string, unfold: bool,
    85    path: string, parents: string list};
    86 
    87 fun write_graph gr path =
    88   File.write path (cat_lines (map (fn {name, ID, dir, unfold, path, parents} =>
    89     "\"" ^ name ^ "\" \"" ^ ID ^ "\" \"" ^ dir ^ (if unfold then "\" + \"" else "\" \"") ^
    90     path ^ "\" > " ^ space_implode " " (map quote parents) ^ " ;") gr));
    91 
    92 fun display_graph gr =
    93   let
    94     val _ = writeln "Displaying graph ...";
    95     val path = File.tmp_path (Path.explode "tmp.graph");
    96     val _ = write_graph gr path;
    97     val _ = Isabelle_System.isabelle_tool "browser" ("-c " ^ File.shell_path path ^ " &");
    98   in () end;
    99 
   100 
   101 fun ID_of sess s = space_implode "/" (sess @ [s]);
   102 fun ID_of_thy thy = ID_of (#session (get_info thy)) (Context.theory_name thy);
   103 
   104 
   105 (*retrieve graph data from initial collection of theories*)
   106 fun init_graph remote_path curr_sess = rev o map (fn thy =>
   107   let
   108     val name = Context.theory_name thy;
   109     val {name = sess_name, session, is_local} = get_info thy;
   110     val path' = Path.append (Path.make session) (html_path name);
   111     val entry =
   112      {name = name, ID = ID_of session name, dir = sess_name,
   113       path =
   114         if null session then "" else
   115         if is_some remote_path andalso not is_local then
   116           Url.implode (Url.append (the remote_path) (Url.File
   117             (Path.append (Path.make session) (html_path name))))
   118         else Path.implode (Path.append (mk_rel_path curr_sess session) (html_path name)),
   119       unfold = false,
   120       parents = map ID_of_thy (Theory.parents_of thy)};
   121   in (0, entry) end);
   122 
   123 fun ins_graph_entry (i, entry as {ID, ...}) (gr: (int * graph_node) list) =
   124   (i, entry) :: filter_out (fn (_, entry') => #ID entry' = ID) gr;
   125 
   126 
   127 
   128 (** global browser info state **)
   129 
   130 (* type theory_info *)
   131 
   132 type theory_info = {tex_source: Buffer.T, html_source: Buffer.T, html: Buffer.T};
   133 
   134 fun make_theory_info (tex_source, html_source, html) =
   135   {tex_source = tex_source, html_source = html_source, html = html}: theory_info;
   136 
   137 val empty_theory_info = make_theory_info (Buffer.empty, Buffer.empty, Buffer.empty);
   138 
   139 fun map_theory_info f {tex_source, html_source, html} =
   140   make_theory_info (f (tex_source, html_source, html));
   141 
   142 
   143 (* type browser_info *)
   144 
   145 type browser_info = {theories: theory_info Symtab.table, files: (Path.T * string) list,
   146   tex_index: (int * string) list, html_index: (int * string) list, graph: (int * graph_node) list};
   147 
   148 fun make_browser_info (theories, files, tex_index, html_index, graph) =
   149   {theories = theories, files = files, tex_index = tex_index, html_index = html_index,
   150     graph = graph}: browser_info;
   151 
   152 val empty_browser_info = make_browser_info (Symtab.empty, [], [], [], []);
   153 
   154 fun init_browser_info remote_path curr_sess thys = make_browser_info
   155   (Symtab.empty, [], [], [], init_graph remote_path curr_sess thys);
   156 
   157 fun map_browser_info f {theories, files, tex_index, html_index, graph} =
   158   make_browser_info (f (theories, files, tex_index, html_index, graph));
   159 
   160 
   161 (* state *)
   162 
   163 val browser_info = Unsynchronized.ref empty_browser_info;
   164 fun change_browser_info f =
   165   CRITICAL (fn () => Unsynchronized.change browser_info (map_browser_info f));
   166 
   167 val suppress_tex_source = Unsynchronized.ref false;
   168 fun no_document f x = Unsynchronized.setmp suppress_tex_source true f x;  (* FIXME unreliable *)
   169 
   170 fun init_theory_info name info =
   171   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   172     (Symtab.update (name, info) theories, files, tex_index, html_index, graph));
   173 
   174 fun change_theory_info name f =
   175   change_browser_info (fn (info as (theories, files, tex_index, html_index, graph)) =>
   176     (case Symtab.lookup theories name of
   177       NONE => error ("Browser info: cannot access theory document " ^ quote name)
   178     | SOME info => (Symtab.update (name, map_theory_info f info) theories, files,
   179         tex_index, html_index, graph)));
   180 
   181 
   182 fun add_file file =
   183   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   184     (theories, file :: files, tex_index, html_index, graph));
   185 
   186 fun add_tex_index txt =
   187   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   188     (theories, files, txt :: tex_index, html_index, graph));
   189 
   190 fun add_html_index txt =
   191   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   192     (theories, files, tex_index, txt :: html_index, graph));
   193 
   194 fun add_graph_entry entry =
   195   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   196     (theories, files, tex_index, html_index, ins_graph_entry entry graph));
   197 
   198 fun add_tex_source name txt =
   199   if ! suppress_tex_source then ()
   200   else change_theory_info name (fn (tex_source, html_source, html) =>
   201     (Buffer.add txt tex_source, html_source, html));
   202 
   203 fun add_html_source name txt = change_theory_info name (fn (tex_source, html_source, html) =>
   204   (tex_source, Buffer.add txt html_source, html));
   205 
   206 fun add_html name txt = change_theory_info name (fn (tex_source, html_source, html) =>
   207   (tex_source, html_source, Buffer.add txt html));
   208 
   209 
   210 
   211 (** global session state **)
   212 
   213 (* session_info *)
   214 
   215 type session_info =
   216   {name: string, parent: string, session: string, path: string list, html_prefix: Path.T,
   217     info: bool, doc_format: string, doc_graph: bool, documents: (string * string) list,
   218     doc_prefix1: (Path.T * Path.T) option, dump_prefix: (bool * Path.T) option,
   219     remote_path: Url.T option, verbose: bool, readme: Path.T option};
   220 
   221 fun make_session_info
   222   (name, parent, session, path, html_prefix, info, doc_format, doc_graph, documents,
   223     doc_prefix1, dump_prefix, remote_path, verbose, readme) =
   224   {name = name, parent = parent, session = session, path = path, html_prefix = html_prefix,
   225     info = info, doc_format = doc_format, doc_graph = doc_graph, documents = documents,
   226     doc_prefix1 = doc_prefix1, dump_prefix = dump_prefix, remote_path = remote_path,
   227     verbose = verbose, readme = readme}: session_info;
   228 
   229 
   230 (* state *)
   231 
   232 val session_info = Unsynchronized.ref (NONE: session_info option);
   233 
   234 fun with_session x f = (case ! session_info of NONE => x | SOME info => f info);
   235 fun with_context f = f (Context.theory_name (ML_Context.the_global_context ()));
   236 
   237 
   238 
   239 (** document preparation **)
   240 
   241 (* maintain index *)
   242 
   243 val session_entries =
   244   HTML.session_entries o
   245     map (fn name => (Url.File (Path.append (Path.basic name) index_path), name));
   246 
   247 fun get_entries dir =
   248   split_lines (File.read (Path.append dir session_entries_path));
   249 
   250 fun put_entries entries dir =
   251   File.write (Path.append dir session_entries_path) (cat_lines entries);
   252 
   253 
   254 fun create_index dir =
   255   File.read (Path.append dir pre_index_path) ^
   256     session_entries (get_entries dir) ^ HTML.end_document
   257   |> File.write (Path.append dir index_path);
   258 
   259 fun update_index dir name = CRITICAL (fn () =>
   260   (case try get_entries dir of
   261     NONE => warning ("Browser info: cannot access session index of " ^ Path.print dir)
   262   | SOME es => (put_entries ((remove (op =) name es) @ [name]) dir; create_index dir)));
   263 
   264 
   265 (* document variants *)
   266 
   267 fun read_variant str =
   268   (case space_explode "=" str of
   269     [name] => (name, "")
   270   | [name, tags] => (name, tags)
   271   | _ => error ("Malformed document variant specification: " ^ quote str));
   272 
   273 fun read_variants strs =
   274   rev (distinct (eq_fst (op =)) (rev ((documentN, "") :: map read_variant strs)))
   275   |> filter_out (fn (_, s) => s = "-");
   276 
   277 
   278 (* init session *)
   279 
   280 fun name_of_session elems = space_implode "/" ("Isabelle" :: elems);
   281 
   282 fun init build info doc doc_graph doc_variants path name dump_prefix
   283     (remote_path, first_time) verbose thys = CRITICAL (fn () =>
   284   if not build andalso not info andalso doc = "" andalso is_none dump_prefix then
   285     (browser_info := empty_browser_info; session_info := NONE)
   286   else
   287     let
   288       val parent_name = name_of_session (take (length path - 1) path);
   289       val session_name = name_of_session path;
   290       val sess_prefix = Path.make path;
   291       val html_prefix = Path.append (Path.expand output_path) sess_prefix;
   292 
   293       val (doc_prefix1, documents) =
   294         if doc = "" then (NONE, [])
   295         else if not (can File.check_dir document_path) then
   296           (if verbose then Output.raw_stderr "Warning: missing document directory\n" else ();
   297             (NONE, []))
   298         else (SOME (Path.append html_prefix document_path, html_prefix),
   299           read_variants doc_variants);
   300 
   301       val parent_index_path = Path.append Path.parent index_path;
   302       val index_up_lnk = if first_time then
   303           Url.append (the remote_path) (Url.File (Path.append sess_prefix parent_index_path))
   304         else Url.File parent_index_path;
   305       val readme =
   306         if File.exists readme_html_path then SOME readme_html_path
   307         else if File.exists readme_path then SOME readme_path
   308         else NONE;
   309 
   310       val docs =
   311         (case readme of NONE => [] | SOME p => [(Url.File p, "README")]) @
   312         map (fn (name, _) => (Url.File (Path.ext doc (Path.basic name)), name)) documents;
   313       val index_text = HTML.begin_index (index_up_lnk, parent_name)
   314         (Url.File index_path, session_name) docs (Url.explode "medium.html");
   315     in
   316       session_info := SOME (make_session_info (name, parent_name, session_name, path, html_prefix,
   317         info, doc, doc_graph, documents, doc_prefix1, dump_prefix, remote_path, verbose, readme));
   318       browser_info := init_browser_info remote_path path thys;
   319       add_html_index (0, index_text)
   320     end);
   321 
   322 
   323 (* isabelle tool wrappers *)
   324 
   325 fun isabelle_document verbose format name tags path result_path =
   326   let
   327     val s = "\"$ISABELLE_TOOL\" document -c -o '" ^ format ^ "' \
   328       \-n '" ^ name ^ "' -t '" ^ tags ^ "' " ^ File.shell_path path ^ " 2>&1";
   329     val doc_path = Path.append result_path (Path.ext format (Path.basic name));
   330     val _ = if verbose then writeln s else ();
   331     val (out, rc) = bash_output s;
   332     val _ =
   333       if not (File.exists doc_path) orelse rc <> 0 then
   334         cat_error out ("Failed to build document " ^ quote (show_path doc_path))
   335       else if verbose then writeln out
   336       else ();
   337   in doc_path end;
   338 
   339 fun isabelle_browser graph =
   340   let
   341     val pdf_path = File.tmp_path graph_pdf_path;
   342     val eps_path = File.tmp_path graph_eps_path;
   343     val gr_path = File.tmp_path graph_path;
   344     val args = "-o " ^ File.shell_path pdf_path ^ " " ^ File.shell_path gr_path;
   345   in
   346     write_graph graph gr_path;
   347     if Isabelle_System.isabelle_tool "browser" args <> 0 orelse
   348       not (File.exists eps_path) orelse not (File.exists pdf_path)
   349     then error "Failed to prepare dependency graph"
   350     else
   351       let val pdf = File.read pdf_path and eps = File.read eps_path
   352       in File.rm pdf_path; File.rm eps_path; File.rm gr_path; (pdf, eps) end
   353   end;
   354 
   355 
   356 (* finish session -- output all generated text *)
   357 
   358 fun sorted_index index = map snd (sort (int_ord o pairself fst) (rev index));
   359 fun index_buffer index = Buffer.add (implode (sorted_index index)) Buffer.empty;
   360 
   361 fun write_tex src name path =
   362   File.write_buffer (Path.append path (tex_path name)) src;
   363 
   364 fun write_tex_index tex_index path =
   365   write_tex (index_buffer tex_index |> Buffer.add Latex.tex_trailer) doc_indexN path;
   366 
   367 
   368 fun finish () = CRITICAL (fn () =>
   369     with_session () (fn {name, info, html_prefix, doc_format, doc_graph,
   370       documents, doc_prefix1, dump_prefix, path, verbose, readme, ...} =>
   371   let
   372     val {theories, files, tex_index, html_index, graph} = ! browser_info;
   373     val thys = Symtab.dest theories;
   374     val parent_html_prefix = Path.append html_prefix Path.parent;
   375 
   376     fun finish_tex path (a, {tex_source, ...}: theory_info) = write_tex tex_source a path;
   377     fun finish_html (a, {html, ...}: theory_info) =
   378       File.write_buffer (Path.append html_prefix (html_path a)) (Buffer.add HTML.end_document html);
   379 
   380     val sorted_graph = sorted_index graph;
   381     val opt_graphs =
   382       if doc_graph andalso (is_some doc_prefix1 orelse is_some dump_prefix) then
   383         SOME (isabelle_browser sorted_graph)
   384       else NONE;
   385 
   386     fun prepare_sources cp path =
   387      (Isabelle_System.mkdirs path;
   388       if cp then Isabelle_System.copy_dir document_path path else ();
   389       Isabelle_System.isabelle_tool "latex"
   390         ("-o sty " ^ File.shell_path (Path.append path (Path.basic "root.tex")));
   391       (case opt_graphs of NONE => () | SOME (pdf, eps) =>
   392         (File.write (Path.append path graph_pdf_path) pdf;
   393           File.write (Path.append path graph_eps_path) eps));
   394       write_tex_index tex_index path;
   395       List.app (finish_tex path) thys);
   396   in
   397     if info then
   398      (Isabelle_System.mkdirs (Path.append html_prefix session_path);
   399       File.write_buffer (Path.append html_prefix pre_index_path) (index_buffer html_index);
   400       File.write (Path.append html_prefix session_entries_path) "";
   401       create_index html_prefix;
   402       if length path > 1 then update_index parent_html_prefix name else ();
   403       (case readme of NONE => () | SOME path => File.copy path html_prefix);
   404       write_graph sorted_graph (Path.append html_prefix graph_path);
   405       Isabelle_System.isabelle_tool "browser" "-b";
   406       File.copy (Path.explode "~~/lib/browser/GraphBrowser.jar") html_prefix;
   407       List.app (fn (a, txt) => File.write (Path.append html_prefix (Path.basic a)) txt)
   408         (HTML.applet_pages name (Url.File index_path, name));
   409       File.copy (Path.explode "~~/lib/html/isabelle.css") html_prefix;
   410       List.app finish_html thys;
   411       List.app (uncurry File.write) files;
   412       if verbose then Output.raw_stderr ("Browser info at " ^ show_path html_prefix ^ "\n") else ())
   413     else ();
   414 
   415     (case dump_prefix of NONE => () | SOME (cp, path) =>
   416      (prepare_sources cp path;
   417       if verbose then Output.raw_stderr ("Document sources at " ^ show_path path ^ "\n") else ()));
   418 
   419     (case doc_prefix1 of NONE => () | SOME (path, result_path) =>
   420       documents |> List.app (fn (name, tags) =>
   421        let
   422          val _ = prepare_sources true path;
   423          val doc_path = isabelle_document true doc_format name tags path result_path;
   424        in
   425          if verbose then Output.raw_stderr ("Document at " ^ show_path doc_path ^ "\n") else ()
   426        end));
   427 
   428     browser_info := empty_browser_info;
   429     session_info := NONE
   430   end));
   431 
   432 
   433 (* theory elements *)
   434 
   435 fun init_theory name = with_session () (fn _ => init_theory_info name empty_theory_info);
   436 
   437 fun theory_source name mk_text =
   438   with_session () (fn _ => add_html_source name (HTML.theory_source (mk_text ())));
   439 
   440 fun theory_output name s =
   441   with_session () (fn _ => add_tex_source name (Latex.isabelle_file name s));
   442 
   443 
   444 fun parent_link remote_path curr_session thy =
   445   let
   446     val {name = _, session, is_local} = get_info thy;
   447     val name = Context.theory_name thy;
   448     val link =
   449       if null session then NONE
   450       else SOME
   451        (if is_some remote_path andalso not is_local then
   452          Url.append (the remote_path) (Url.File (Path.append (Path.make session) (html_path name)))
   453         else Url.File (Path.append (mk_rel_path curr_session session) (html_path name)));
   454   in (link, name) end;
   455 
   456 fun begin_theory update_time dir files thy =
   457     with_session thy (fn {name = sess_name, session, path, html_prefix, remote_path, ...} =>
   458   let
   459     val name = Context.theory_name thy;
   460     val parents = Theory.parents_of thy;
   461     val parent_specs = map (parent_link remote_path path) parents;
   462 
   463     val files_html = files |> map (fn (raw_path, loadit) =>
   464       let
   465         val path = Thy_Load.check_file dir raw_path;
   466         val base = Path.base path;
   467         val base_html = html_ext base;
   468         val _ = add_file (Path.append html_prefix base_html,
   469           HTML.external_file (Url.File base) (File.read path));
   470       in (Url.File base_html, Url.File raw_path, loadit) end);
   471 
   472     fun prep_html_source (tex_source, html_source, html) =
   473       let
   474         val txt = HTML.begin_theory (Url.File index_path, session)
   475           name parent_specs files_html (Buffer.content html_source)
   476       in (tex_source, Buffer.empty, Buffer.add txt html) end;
   477 
   478     val entry =
   479      {name = name, ID = ID_of path name, dir = sess_name, unfold = true,
   480       path = Path.implode (html_path name),
   481       parents = map ID_of_thy parents};
   482   in
   483     change_theory_info name prep_html_source;
   484     add_graph_entry (update_time, entry);
   485     add_html_index (update_time, HTML.theory_entry (Url.File (html_path name), name));
   486     add_tex_index (update_time, Latex.theory_entry name);
   487     put_info {name = sess_name, session = path, is_local = is_some remote_path} thy
   488   end);
   489 
   490 
   491 
   492 (** draft document output **)  (* FIXME doc_path etc. not thread-safe *)
   493 
   494 fun drafts doc_format src_paths =
   495   let
   496     fun prep_draft path i =
   497       let
   498         val base = Path.base path;
   499         val name =
   500           (case Path.implode (#1 (Path.split_ext base)) of
   501             "" => "DUMMY" ^ serial_string ()
   502           | s => s);
   503       in
   504         if File.exists path then
   505           (((name, base, File.read path), (i, Latex.theory_entry name)), i + 1)
   506         else error ("Bad file: " ^ Path.print path)
   507       end;
   508     val (srcs, tex_index) = split_list (fst (fold_map prep_draft src_paths 0));
   509 
   510     val doc_path = File.tmp_path document_path;
   511     val result_path = Path.append doc_path Path.parent;
   512     val _ = Isabelle_System.mkdirs doc_path;
   513     val root_path = Path.append doc_path (Path.basic "root.tex");
   514     val _ = File.copy (Path.explode "~~/lib/texinputs/draft.tex") root_path;
   515     val _ = Isabelle_System.isabelle_tool "latex" ("-o sty " ^ File.shell_path root_path);
   516     val _ = Isabelle_System.isabelle_tool "latex" ("-o syms " ^ File.shell_path root_path);
   517 
   518     fun known name =
   519       let val ss = split_lines (File.read (Path.append doc_path (Path.basic name)))
   520       in member (op =) ss end;
   521     val known_syms = known "syms.lst";
   522     val known_ctrls = known "ctrls.lst";
   523 
   524     val _ = srcs |> List.app (fn (name, base, txt) =>
   525       Symbol.explode txt
   526       |> Latex.symbol_source (known_syms, known_ctrls) (Path.implode base)
   527       |> File.write (Path.append doc_path (tex_path name)));
   528     val _ = write_tex_index tex_index doc_path;
   529   in isabelle_document false doc_format documentN "" doc_path result_path end;
   530 
   531 
   532 end;
   533 
   534 structure Basic_Present: BASIC_PRESENT = Present;
   535 open Basic_Present;