src/HOL/Lifting_Set.thy
author Andreas Lochbihler
Mon Jul 21 17:51:29 2014 +0200 (2014-07-21)
changeset 57599 7ef939f89776
parent 57129 7edb7550663e
child 58104 c5316f843f72
permissions -rw-r--r--
add parametricity lemmas
     1 (*  Title:      HOL/Lifting_Set.thy
     2     Author:     Brian Huffman and Ondrej Kuncar
     3 *)
     4 
     5 header {* Setup for Lifting/Transfer for the set type *}
     6 
     7 theory Lifting_Set
     8 imports Lifting
     9 begin
    10 
    11 subsection {* Relator and predicator properties *}
    12 
    13 definition rel_set :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool"
    14   where "rel_set R = (\<lambda>A B. (\<forall>x\<in>A. \<exists>y\<in>B. R x y) \<and> (\<forall>y\<in>B. \<exists>x\<in>A. R x y))"
    15 
    16 lemma rel_setI:
    17   assumes "\<And>x. x \<in> A \<Longrightarrow> \<exists>y\<in>B. R x y"
    18   assumes "\<And>y. y \<in> B \<Longrightarrow> \<exists>x\<in>A. R x y"
    19   shows "rel_set R A B"
    20   using assms unfolding rel_set_def by simp
    21 
    22 lemma rel_setD1: "\<lbrakk> rel_set R A B; x \<in> A \<rbrakk> \<Longrightarrow> \<exists>y \<in> B. R x y"
    23   and rel_setD2: "\<lbrakk> rel_set R A B; y \<in> B \<rbrakk> \<Longrightarrow> \<exists>x \<in> A. R x y"
    24 by(simp_all add: rel_set_def)
    25 
    26 lemma rel_set_conversep [simp]: "rel_set A\<inverse>\<inverse> = (rel_set A)\<inverse>\<inverse>"
    27   unfolding rel_set_def by auto
    28 
    29 lemma rel_set_eq [relator_eq]: "rel_set (op =) = (op =)"
    30   unfolding rel_set_def fun_eq_iff by auto
    31 
    32 lemma rel_set_mono[relator_mono]:
    33   assumes "A \<le> B"
    34   shows "rel_set A \<le> rel_set B"
    35 using assms unfolding rel_set_def by blast
    36 
    37 lemma rel_set_OO[relator_distr]: "rel_set R OO rel_set S = rel_set (R OO S)"
    38   apply (rule sym)
    39   apply (intro ext, rename_tac X Z)
    40   apply (rule iffI)
    41   apply (rule_tac b="{y. (\<exists>x\<in>X. R x y) \<and> (\<exists>z\<in>Z. S y z)}" in relcomppI)
    42   apply (simp add: rel_set_def, fast)
    43   apply (simp add: rel_set_def, fast)
    44   apply (simp add: rel_set_def, fast)
    45   done
    46 
    47 lemma Domainp_set[relator_domain]:
    48   "Domainp (rel_set T) = (\<lambda>A. Ball A (Domainp T))"
    49 unfolding rel_set_def Domainp_iff[abs_def]
    50 apply (intro ext)
    51 apply (rule iffI) 
    52 apply blast
    53 apply (rename_tac A, rule_tac x="{y. \<exists>x\<in>A. T x y}" in exI, fast)
    54 done
    55 
    56 lemma left_total_rel_set[transfer_rule]: 
    57   "left_total A \<Longrightarrow> left_total (rel_set A)"
    58   unfolding left_total_def rel_set_def
    59   apply safe
    60   apply (rename_tac X, rule_tac x="{y. \<exists>x\<in>X. A x y}" in exI, fast)
    61 done
    62 
    63 lemma left_unique_rel_set[transfer_rule]: 
    64   "left_unique A \<Longrightarrow> left_unique (rel_set A)"
    65   unfolding left_unique_def rel_set_def
    66   by fast
    67 
    68 lemma right_total_rel_set [transfer_rule]:
    69   "right_total A \<Longrightarrow> right_total (rel_set A)"
    70 using left_total_rel_set[of "A\<inverse>\<inverse>"] by simp
    71 
    72 lemma right_unique_rel_set [transfer_rule]:
    73   "right_unique A \<Longrightarrow> right_unique (rel_set A)"
    74   unfolding right_unique_def rel_set_def by fast
    75 
    76 lemma bi_total_rel_set [transfer_rule]:
    77   "bi_total A \<Longrightarrow> bi_total (rel_set A)"
    78 by(simp add: bi_total_alt_def left_total_rel_set right_total_rel_set)
    79 
    80 lemma bi_unique_rel_set [transfer_rule]:
    81   "bi_unique A \<Longrightarrow> bi_unique (rel_set A)"
    82   unfolding bi_unique_def rel_set_def by fast
    83 
    84 lemma set_relator_eq_onp [relator_eq_onp]:
    85   "rel_set (eq_onp P) = eq_onp (\<lambda>A. Ball A P)"
    86   unfolding fun_eq_iff rel_set_def eq_onp_def Ball_def by fast
    87 
    88 lemma bi_unique_rel_set_lemma:
    89   assumes "bi_unique R" and "rel_set R X Y"
    90   obtains f where "Y = image f X" and "inj_on f X" and "\<forall>x\<in>X. R x (f x)"
    91 proof
    92   def f \<equiv> "\<lambda>x. THE y. R x y"
    93   { fix x assume "x \<in> X"
    94     with `rel_set R X Y` `bi_unique R` have "R x (f x)"
    95       by (simp add: bi_unique_def rel_set_def f_def) (metis theI)
    96     with assms `x \<in> X` 
    97     have  "R x (f x)" "\<forall>x'\<in>X. R x' (f x) \<longrightarrow> x = x'" "\<forall>y\<in>Y. R x y \<longrightarrow> y = f x" "f x \<in> Y"
    98       by (fastforce simp add: bi_unique_def rel_set_def)+ }
    99   note * = this
   100   moreover
   101   { fix y assume "y \<in> Y"
   102     with `rel_set R X Y` *(3) `y \<in> Y` have "\<exists>x\<in>X. y = f x"
   103       by (fastforce simp: rel_set_def) }
   104   ultimately show "\<forall>x\<in>X. R x (f x)" "Y = image f X" "inj_on f X"
   105     by (auto simp: inj_on_def image_iff)
   106 qed
   107 
   108 subsection {* Quotient theorem for the Lifting package *}
   109 
   110 lemma Quotient_set[quot_map]:
   111   assumes "Quotient R Abs Rep T"
   112   shows "Quotient (rel_set R) (image Abs) (image Rep) (rel_set T)"
   113   using assms unfolding Quotient_alt_def4
   114   apply (simp add: rel_set_OO[symmetric])
   115   apply (simp add: rel_set_def, fast)
   116   done
   117 
   118 subsection {* Transfer rules for the Transfer package *}
   119 
   120 subsubsection {* Unconditional transfer rules *}
   121 
   122 context
   123 begin
   124 interpretation lifting_syntax .
   125 
   126 lemma empty_transfer [transfer_rule]: "(rel_set A) {} {}"
   127   unfolding rel_set_def by simp
   128 
   129 lemma insert_transfer [transfer_rule]:
   130   "(A ===> rel_set A ===> rel_set A) insert insert"
   131   unfolding rel_fun_def rel_set_def by auto
   132 
   133 lemma union_transfer [transfer_rule]:
   134   "(rel_set A ===> rel_set A ===> rel_set A) union union"
   135   unfolding rel_fun_def rel_set_def by auto
   136 
   137 lemma Union_transfer [transfer_rule]:
   138   "(rel_set (rel_set A) ===> rel_set A) Union Union"
   139   unfolding rel_fun_def rel_set_def by simp fast
   140 
   141 lemma image_transfer [transfer_rule]:
   142   "((A ===> B) ===> rel_set A ===> rel_set B) image image"
   143   unfolding rel_fun_def rel_set_def by simp fast
   144 
   145 lemma UNION_transfer [transfer_rule]:
   146   "(rel_set A ===> (A ===> rel_set B) ===> rel_set B) UNION UNION"
   147   unfolding Union_image_eq [symmetric, abs_def] by transfer_prover
   148 
   149 lemma Ball_transfer [transfer_rule]:
   150   "(rel_set A ===> (A ===> op =) ===> op =) Ball Ball"
   151   unfolding rel_set_def rel_fun_def by fast
   152 
   153 lemma Bex_transfer [transfer_rule]:
   154   "(rel_set A ===> (A ===> op =) ===> op =) Bex Bex"
   155   unfolding rel_set_def rel_fun_def by fast
   156 
   157 lemma Pow_transfer [transfer_rule]:
   158   "(rel_set A ===> rel_set (rel_set A)) Pow Pow"
   159   apply (rule rel_funI, rename_tac X Y, rule rel_setI)
   160   apply (rename_tac X', rule_tac x="{y\<in>Y. \<exists>x\<in>X'. A x y}" in rev_bexI, clarsimp)
   161   apply (simp add: rel_set_def, fast)
   162   apply (rename_tac Y', rule_tac x="{x\<in>X. \<exists>y\<in>Y'. A x y}" in rev_bexI, clarsimp)
   163   apply (simp add: rel_set_def, fast)
   164   done
   165 
   166 lemma rel_set_transfer [transfer_rule]:
   167   "((A ===> B ===> op =) ===> rel_set A ===> rel_set B ===> op =) rel_set rel_set"
   168   unfolding rel_fun_def rel_set_def by fast
   169 
   170 lemma bind_transfer [transfer_rule]:
   171   "(rel_set A ===> (A ===> rel_set B) ===> rel_set B) Set.bind Set.bind"
   172   unfolding bind_UNION [abs_def] by transfer_prover
   173 
   174 lemma INF_parametric [transfer_rule]:
   175   "(rel_set A ===> (A ===> HOL.eq) ===> HOL.eq) INFIMUM INFIMUM"
   176   unfolding INF_def [abs_def] by transfer_prover
   177 
   178 lemma SUP_parametric [transfer_rule]:
   179   "(rel_set R ===> (R ===> HOL.eq) ===> HOL.eq) SUPREMUM SUPREMUM"
   180   unfolding SUP_def [abs_def] by transfer_prover
   181 
   182 
   183 subsubsection {* Rules requiring bi-unique, bi-total or right-total relations *}
   184 
   185 lemma member_transfer [transfer_rule]:
   186   assumes "bi_unique A"
   187   shows "(A ===> rel_set A ===> op =) (op \<in>) (op \<in>)"
   188   using assms unfolding rel_fun_def rel_set_def bi_unique_def by fast
   189 
   190 lemma right_total_Collect_transfer[transfer_rule]:
   191   assumes "right_total A"
   192   shows "((A ===> op =) ===> rel_set A) (\<lambda>P. Collect (\<lambda>x. P x \<and> Domainp A x)) Collect"
   193   using assms unfolding right_total_def rel_set_def rel_fun_def Domainp_iff by fast
   194 
   195 lemma Collect_transfer [transfer_rule]:
   196   assumes "bi_total A"
   197   shows "((A ===> op =) ===> rel_set A) Collect Collect"
   198   using assms unfolding rel_fun_def rel_set_def bi_total_def by fast
   199 
   200 lemma inter_transfer [transfer_rule]:
   201   assumes "bi_unique A"
   202   shows "(rel_set A ===> rel_set A ===> rel_set A) inter inter"
   203   using assms unfolding rel_fun_def rel_set_def bi_unique_def by fast
   204 
   205 lemma Diff_transfer [transfer_rule]:
   206   assumes "bi_unique A"
   207   shows "(rel_set A ===> rel_set A ===> rel_set A) (op -) (op -)"
   208   using assms unfolding rel_fun_def rel_set_def bi_unique_def
   209   unfolding Ball_def Bex_def Diff_eq
   210   by (safe, simp, metis, simp, metis)
   211 
   212 lemma subset_transfer [transfer_rule]:
   213   assumes [transfer_rule]: "bi_unique A"
   214   shows "(rel_set A ===> rel_set A ===> op =) (op \<subseteq>) (op \<subseteq>)"
   215   unfolding subset_eq [abs_def] by transfer_prover
   216 
   217 lemma right_total_UNIV_transfer[transfer_rule]: 
   218   assumes "right_total A"
   219   shows "(rel_set A) (Collect (Domainp A)) UNIV"
   220   using assms unfolding right_total_def rel_set_def Domainp_iff by blast
   221 
   222 lemma UNIV_transfer [transfer_rule]:
   223   assumes "bi_total A"
   224   shows "(rel_set A) UNIV UNIV"
   225   using assms unfolding rel_set_def bi_total_def by simp
   226 
   227 lemma right_total_Compl_transfer [transfer_rule]:
   228   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "right_total A"
   229   shows "(rel_set A ===> rel_set A) (\<lambda>S. uminus S \<inter> Collect (Domainp A)) uminus"
   230   unfolding Compl_eq [abs_def]
   231   by (subst Collect_conj_eq[symmetric]) transfer_prover
   232 
   233 lemma Compl_transfer [transfer_rule]:
   234   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "bi_total A"
   235   shows "(rel_set A ===> rel_set A) uminus uminus"
   236   unfolding Compl_eq [abs_def] by transfer_prover
   237 
   238 lemma right_total_Inter_transfer [transfer_rule]:
   239   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "right_total A"
   240   shows "(rel_set (rel_set A) ===> rel_set A) (\<lambda>S. Inter S \<inter> Collect (Domainp A)) Inter"
   241   unfolding Inter_eq[abs_def]
   242   by (subst Collect_conj_eq[symmetric]) transfer_prover
   243 
   244 lemma Inter_transfer [transfer_rule]:
   245   assumes [transfer_rule]: "bi_unique A" and [transfer_rule]: "bi_total A"
   246   shows "(rel_set (rel_set A) ===> rel_set A) Inter Inter"
   247   unfolding Inter_eq [abs_def] by transfer_prover
   248 
   249 lemma filter_transfer [transfer_rule]:
   250   assumes [transfer_rule]: "bi_unique A"
   251   shows "((A ===> op=) ===> rel_set A ===> rel_set A) Set.filter Set.filter"
   252   unfolding Set.filter_def[abs_def] rel_fun_def rel_set_def by blast
   253 
   254 lemma finite_transfer [transfer_rule]:
   255   "bi_unique A \<Longrightarrow> (rel_set A ===> op =) finite finite"
   256   by (rule rel_funI, erule (1) bi_unique_rel_set_lemma)
   257      (auto dest: finite_imageD)
   258 
   259 lemma card_transfer [transfer_rule]:
   260   "bi_unique A \<Longrightarrow> (rel_set A ===> op =) card card"
   261   by (rule rel_funI, erule (1) bi_unique_rel_set_lemma)
   262      (simp add: card_image)
   263 
   264 lemma vimage_parametric [transfer_rule]:
   265   assumes [transfer_rule]: "bi_total A" "bi_unique B"
   266   shows "((A ===> B) ===> rel_set B ===> rel_set A) vimage vimage"
   267   unfolding vimage_def[abs_def] by transfer_prover
   268 
   269 lemma Image_parametric [transfer_rule]:
   270   assumes "bi_unique A"
   271   shows "(rel_set (rel_prod A B) ===> rel_set A ===> rel_set B) op `` op ``"
   272 by(intro rel_funI rel_setI)
   273   (force dest: rel_setD1 bi_uniqueDr[OF assms], force dest: rel_setD2 bi_uniqueDl[OF assms])
   274 
   275 end
   276 
   277 lemma (in comm_monoid_set) F_parametric [transfer_rule]:
   278   fixes A :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
   279   assumes "bi_unique A"
   280   shows "rel_fun (rel_fun A (op =)) (rel_fun (rel_set A) (op =)) F F"
   281 proof(rule rel_funI)+
   282   fix f :: "'b \<Rightarrow> 'a" and g S T
   283   assume "rel_fun A (op =) f g" "rel_set A S T"
   284   with `bi_unique A` obtain i where "bij_betw i S T" "\<And>x. x \<in> S \<Longrightarrow> f x = g (i x)"
   285     by (auto elim: bi_unique_rel_set_lemma simp: rel_fun_def bij_betw_def)
   286   then show "F f S = F g T"
   287     by (simp add: reindex_bij_betw)
   288 qed
   289 
   290 lemmas setsum_parametric = setsum.F_parametric
   291 lemmas setprod_parametric = setprod.F_parametric
   292 
   293 end