src/HOL/Semiring_Normalization.thy
author haftmann
Fri May 07 15:05:52 2010 +0200 (2010-05-07)
changeset 36751 7f1da69cacb3
parent 36720 src/HOL/Groebner_Basis.thy@41da7025e59c
child 36753 5cf4e9128f22
permissions -rw-r--r--
split of semiring normalization from Groebner theory; moved field_comp_conv to Numeral_Simproces
     1 (*  Title:      HOL/Semiring_Normalization.thy
     2     Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 header {* Semiring normalization *}
     6 
     7 theory Semiring_Normalization
     8 imports Numeral_Simprocs Nat_Transfer
     9 uses
    10   "Tools/Groebner_Basis/normalizer.ML"
    11 begin
    12 
    13 setup Normalizer.setup
    14 
    15 locale normalizing_semiring =
    16   fixes add mul pwr r0 r1
    17   assumes add_a:"(add x (add y z) = add (add x y) z)"
    18     and add_c: "add x y = add y x" and add_0:"add r0 x = x"
    19     and mul_a:"mul x (mul y z) = mul (mul x y) z" and mul_c:"mul x y = mul y x"
    20     and mul_1:"mul r1 x = x" and  mul_0:"mul r0 x = r0"
    21     and mul_d:"mul x (add y z) = add (mul x y) (mul x z)"
    22     and pwr_0:"pwr x 0 = r1" and pwr_Suc:"pwr x (Suc n) = mul x (pwr x n)"
    23 begin
    24 
    25 lemma mul_pwr:"mul (pwr x p) (pwr x q) = pwr x (p + q)"
    26 proof (induct p)
    27   case 0
    28   then show ?case by (auto simp add: pwr_0 mul_1)
    29 next
    30   case Suc
    31   from this [symmetric] show ?case
    32     by (auto simp add: pwr_Suc mul_1 mul_a)
    33 qed
    34 
    35 lemma pwr_mul: "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    36 proof (induct q arbitrary: x y, auto simp add:pwr_0 pwr_Suc mul_1)
    37   fix q x y
    38   assume "\<And>x y. pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    39   have "mul (mul x y) (mul (pwr x q) (pwr y q)) = mul x (mul y (mul (pwr x q) (pwr y q)))"
    40     by (simp add: mul_a)
    41   also have "\<dots> = (mul (mul y (mul (pwr y q) (pwr x q))) x)" by (simp add: mul_c)
    42   also have "\<dots> = (mul (mul y (pwr y q)) (mul (pwr x q) x))" by (simp add: mul_a)
    43   finally show "mul (mul x y) (mul (pwr x q) (pwr y q)) =
    44     mul (mul x (pwr x q)) (mul y (pwr y q))" by (simp add: mul_c)
    45 qed
    46 
    47 lemma pwr_pwr: "pwr (pwr x p) q = pwr x (p * q)"
    48 proof (induct p arbitrary: q)
    49   case 0
    50   show ?case using pwr_Suc mul_1 pwr_0 by (induct q) auto
    51 next
    52   case Suc
    53   thus ?case by (auto simp add: mul_pwr [symmetric] pwr_mul pwr_Suc)
    54 qed
    55 
    56 lemma semiring_ops:
    57   shows "TERM (add x y)" and "TERM (mul x y)" and "TERM (pwr x n)"
    58     and "TERM r0" and "TERM r1" .
    59 
    60 lemma semiring_rules:
    61   "add (mul a m) (mul b m) = mul (add a b) m"
    62   "add (mul a m) m = mul (add a r1) m"
    63   "add m (mul a m) = mul (add a r1) m"
    64   "add m m = mul (add r1 r1) m"
    65   "add r0 a = a"
    66   "add a r0 = a"
    67   "mul a b = mul b a"
    68   "mul (add a b) c = add (mul a c) (mul b c)"
    69   "mul r0 a = r0"
    70   "mul a r0 = r0"
    71   "mul r1 a = a"
    72   "mul a r1 = a"
    73   "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
    74   "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
    75   "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
    76   "mul (mul lx ly) rx = mul (mul lx rx) ly"
    77   "mul (mul lx ly) rx = mul lx (mul ly rx)"
    78   "mul lx (mul rx ry) = mul (mul lx rx) ry"
    79   "mul lx (mul rx ry) = mul rx (mul lx ry)"
    80   "add (add a b) (add c d) = add (add a c) (add b d)"
    81   "add (add a b) c = add a (add b c)"
    82   "add a (add c d) = add c (add a d)"
    83   "add (add a b) c = add (add a c) b"
    84   "add a c = add c a"
    85   "add a (add c d) = add (add a c) d"
    86   "mul (pwr x p) (pwr x q) = pwr x (p + q)"
    87   "mul x (pwr x q) = pwr x (Suc q)"
    88   "mul (pwr x q) x = pwr x (Suc q)"
    89   "mul x x = pwr x 2"
    90   "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    91   "pwr (pwr x p) q = pwr x (p * q)"
    92   "pwr x 0 = r1"
    93   "pwr x 1 = x"
    94   "mul x (add y z) = add (mul x y) (mul x z)"
    95   "pwr x (Suc q) = mul x (pwr x q)"
    96   "pwr x (2*n) = mul (pwr x n) (pwr x n)"
    97   "pwr x (Suc (2*n)) = mul x (mul (pwr x n) (pwr x n))"
    98 proof -
    99   show "add (mul a m) (mul b m) = mul (add a b) m" using mul_d mul_c by simp
   100 next show"add (mul a m) m = mul (add a r1) m" using mul_d mul_c mul_1 by simp
   101 next show "add m (mul a m) = mul (add a r1) m" using mul_c mul_d mul_1 add_c by simp
   102 next show "add m m = mul (add r1 r1) m" using mul_c mul_d mul_1 by simp
   103 next show "add r0 a = a" using add_0 by simp
   104 next show "add a r0 = a" using add_0 add_c by simp
   105 next show "mul a b = mul b a" using mul_c by simp
   106 next show "mul (add a b) c = add (mul a c) (mul b c)" using mul_c mul_d by simp
   107 next show "mul r0 a = r0" using mul_0 by simp
   108 next show "mul a r0 = r0" using mul_0 mul_c by simp
   109 next show "mul r1 a = a" using mul_1 by simp
   110 next show "mul a r1 = a" using mul_1 mul_c by simp
   111 next show "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
   112     using mul_c mul_a by simp
   113 next show "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
   114     using mul_a by simp
   115 next
   116   have "mul (mul lx ly) (mul rx ry) = mul (mul rx ry) (mul lx ly)" by (rule mul_c)
   117   also have "\<dots> = mul rx (mul ry (mul lx ly))" using mul_a by simp
   118   finally
   119   show "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
   120     using mul_c by simp
   121 next show "mul (mul lx ly) rx = mul (mul lx rx) ly" using mul_c mul_a by simp
   122 next
   123   show "mul (mul lx ly) rx = mul lx (mul ly rx)" by (simp add: mul_a)
   124 next show "mul lx (mul rx ry) = mul (mul lx rx) ry" by (simp add: mul_a )
   125 next show "mul lx (mul rx ry) = mul rx (mul lx ry)" by (simp add: mul_a,simp add: mul_c)
   126 next show "add (add a b) (add c d) = add (add a c) (add b d)"
   127     using add_c add_a by simp
   128 next show "add (add a b) c = add a (add b c)" using add_a by simp
   129 next show "add a (add c d) = add c (add a d)"
   130     apply (simp add: add_a) by (simp only: add_c)
   131 next show "add (add a b) c = add (add a c) b" using add_a add_c by simp
   132 next show "add a c = add c a" by (rule add_c)
   133 next show "add a (add c d) = add (add a c) d" using add_a by simp
   134 next show "mul (pwr x p) (pwr x q) = pwr x (p + q)" by (rule mul_pwr)
   135 next show "mul x (pwr x q) = pwr x (Suc q)" using pwr_Suc by simp
   136 next show "mul (pwr x q) x = pwr x (Suc q)" using pwr_Suc mul_c by simp
   137 next show "mul x x = pwr x 2" by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   138 next show "pwr (mul x y) q = mul (pwr x q) (pwr y q)" by (rule pwr_mul)
   139 next show "pwr (pwr x p) q = pwr x (p * q)" by (rule pwr_pwr)
   140 next show "pwr x 0 = r1" using pwr_0 .
   141 next show "pwr x 1 = x" unfolding One_nat_def by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   142 next show "mul x (add y z) = add (mul x y) (mul x z)" using mul_d by simp
   143 next show "pwr x (Suc q) = mul x (pwr x q)" using pwr_Suc by simp
   144 next show "pwr x (2 * n) = mul (pwr x n) (pwr x n)" by (simp add: nat_number' mul_pwr)
   145 next show "pwr x (Suc (2 * n)) = mul x (mul (pwr x n) (pwr x n))"
   146     by (simp add: nat_number' pwr_Suc mul_pwr)
   147 qed
   148 
   149 
   150 lemmas normalizing_semiring_axioms' =
   151   normalizing_semiring_axioms [normalizer
   152     semiring ops: semiring_ops
   153     semiring rules: semiring_rules]
   154 
   155 end
   156 
   157 sublocale comm_semiring_1
   158   < normalizing!: normalizing_semiring plus times power zero one
   159 proof
   160 qed (simp_all add: algebra_simps)
   161 
   162 declaration {* Normalizer.semiring_funs @{thm normalizing.normalizing_semiring_axioms'} *}
   163 
   164 locale normalizing_ring = normalizing_semiring +
   165   fixes sub :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   166     and neg :: "'a \<Rightarrow> 'a"
   167   assumes neg_mul: "neg x = mul (neg r1) x"
   168     and sub_add: "sub x y = add x (neg y)"
   169 begin
   170 
   171 lemma ring_ops: shows "TERM (sub x y)" and "TERM (neg x)" .
   172 
   173 lemmas ring_rules = neg_mul sub_add
   174 
   175 lemmas normalizing_ring_axioms' =
   176   normalizing_ring_axioms [normalizer
   177     semiring ops: semiring_ops
   178     semiring rules: semiring_rules
   179     ring ops: ring_ops
   180     ring rules: ring_rules]
   181 
   182 end
   183 
   184 sublocale comm_ring_1
   185   < normalizing!: normalizing_ring plus times power zero one minus uminus
   186 proof
   187 qed (simp_all add: diff_minus)
   188 
   189 declaration {* Normalizer.semiring_funs @{thm normalizing.normalizing_ring_axioms'} *}
   190 
   191 locale normalizing_field = normalizing_ring +
   192   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   193     and inverse:: "'a \<Rightarrow> 'a"
   194   assumes divide_inverse: "divide x y = mul x (inverse y)"
   195      and inverse_divide: "inverse x = divide r1 x"
   196 begin
   197 
   198 lemma field_ops: shows "TERM (divide x y)" and "TERM (inverse x)" .
   199 
   200 lemmas field_rules = divide_inverse inverse_divide
   201 
   202 lemmas normalizing_field_axioms' =
   203   normalizing_field_axioms [normalizer
   204     semiring ops: semiring_ops
   205     semiring rules: semiring_rules
   206     ring ops: ring_ops
   207     ring rules: ring_rules
   208     field ops: field_ops
   209     field rules: field_rules]
   210 
   211 end
   212 
   213 locale normalizing_semiring_cancel = normalizing_semiring +
   214   assumes add_cancel: "add (x::'a) y = add x z \<longleftrightarrow> y = z"
   215   and add_mul_solve: "add (mul w y) (mul x z) =
   216     add (mul w z) (mul x y) \<longleftrightarrow> w = x \<or> y = z"
   217 begin
   218 
   219 lemma noteq_reduce: "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   220 proof-
   221   have "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> \<not> (a = b \<or> c = d)" by simp
   222   also have "\<dots> \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   223     using add_mul_solve by blast
   224   finally show "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   225     by simp
   226 qed
   227 
   228 lemma add_scale_eq_noteq: "\<lbrakk>r \<noteq> r0 ; (a = b) \<and> ~(c = d)\<rbrakk>
   229   \<Longrightarrow> add a (mul r c) \<noteq> add b (mul r d)"
   230 proof(clarify)
   231   assume nz: "r\<noteq> r0" and cnd: "c\<noteq>d"
   232     and eq: "add b (mul r c) = add b (mul r d)"
   233   hence "mul r c = mul r d" using cnd add_cancel by simp
   234   hence "add (mul r0 d) (mul r c) = add (mul r0 c) (mul r d)"
   235     using mul_0 add_cancel by simp
   236   thus "False" using add_mul_solve nz cnd by simp
   237 qed
   238 
   239 lemma add_r0_iff: " x = add x a \<longleftrightarrow> a = r0"
   240 proof-
   241   have "a = r0 \<longleftrightarrow> add x a = add x r0" by (simp add: add_cancel)
   242   thus "x = add x a \<longleftrightarrow> a = r0" by (auto simp add: add_c add_0)
   243 qed
   244 
   245 declare normalizing_semiring_axioms' [normalizer del]
   246 
   247 lemmas normalizing_semiring_cancel_axioms' =
   248   normalizing_semiring_cancel_axioms [normalizer
   249     semiring ops: semiring_ops
   250     semiring rules: semiring_rules
   251     idom rules: noteq_reduce add_scale_eq_noteq]
   252 
   253 end
   254 
   255 locale normalizing_ring_cancel = normalizing_semiring_cancel + normalizing_ring + 
   256   assumes subr0_iff: "sub x y = r0 \<longleftrightarrow> x = y"
   257 begin
   258 
   259 declare normalizing_ring_axioms' [normalizer del]
   260 
   261 lemmas normalizing_ring_cancel_axioms' = normalizing_ring_cancel_axioms [normalizer
   262   semiring ops: semiring_ops
   263   semiring rules: semiring_rules
   264   ring ops: ring_ops
   265   ring rules: ring_rules
   266   idom rules: noteq_reduce add_scale_eq_noteq
   267   ideal rules: subr0_iff add_r0_iff]
   268 
   269 end
   270 
   271 sublocale idom
   272   < normalizing!: normalizing_ring_cancel plus times power zero one minus uminus
   273 proof
   274   fix w x y z
   275   show "w * y + x * z = w * z + x * y \<longleftrightarrow> w = x \<or> y = z"
   276   proof
   277     assume "w * y + x * z = w * z + x * y"
   278     then have "w * y + x * z - w * z - x * y = 0" by (simp add: algebra_simps)
   279     then have "w * (y - z) - x * (y - z) = 0" by (simp add: algebra_simps)
   280     then have "(y - z) * (w - x) = 0" by (simp add: algebra_simps)
   281     then have "y - z = 0 \<or> w - x = 0" by (rule divisors_zero)
   282     then show "w = x \<or> y = z" by auto
   283   qed (auto simp add: add_ac)
   284 qed (simp_all add: algebra_simps)
   285 
   286 declaration {* Normalizer.semiring_funs @{thm normalizing.normalizing_ring_cancel_axioms'} *}
   287 
   288 interpretation normalizing_nat!: normalizing_semiring_cancel
   289   "op +" "op *" "op ^" "0::nat" "1"
   290 proof (unfold_locales, simp add: algebra_simps)
   291   fix w x y z ::"nat"
   292   { assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   293     hence "y < z \<or> y > z" by arith
   294     moreover {
   295       assume lt:"y <z" hence "\<exists>k. z = y + k \<and> k > 0" by (rule_tac x="z - y" in exI, auto)
   296       then obtain k where kp: "k>0" and yz:"z = y + k" by blast
   297       from p have "(w * y + x *y) + x*k = (w * y + x*y) + w*k" by (simp add: yz algebra_simps)
   298       hence "x*k = w*k" by simp
   299       hence "w = x" using kp by simp }
   300     moreover {
   301       assume lt: "y >z" hence "\<exists>k. y = z + k \<and> k>0" by (rule_tac x="y - z" in exI, auto)
   302       then obtain k where kp: "k>0" and yz:"y = z + k" by blast
   303       from p have "(w * z + x *z) + w*k = (w * z + x*z) + x*k" by (simp add: yz algebra_simps)
   304       hence "w*k = x*k" by simp
   305       hence "w = x" using kp by simp }
   306     ultimately have "w=x" by blast }
   307   thus "(w * y + x * z = w * z + x * y) = (w = x \<or> y = z)" by auto
   308 qed
   309 
   310 declaration {* Normalizer.semiring_funs @{thm normalizing_nat.normalizing_semiring_cancel_axioms'} *}
   311 
   312 locale normalizing_field_cancel = normalizing_ring_cancel + normalizing_field
   313 begin
   314 
   315 declare normalizing_field_axioms' [normalizer del]
   316 
   317 lemmas normalizing_field_cancel_axioms' = normalizing_field_cancel_axioms [normalizer
   318   semiring ops: semiring_ops
   319   semiring rules: semiring_rules
   320   ring ops: ring_ops
   321   ring rules: ring_rules
   322   field ops: field_ops
   323   field rules: field_rules
   324   idom rules: noteq_reduce add_scale_eq_noteq
   325   ideal rules: subr0_iff add_r0_iff]
   326 
   327 end
   328 
   329 sublocale field 
   330   < normalizing!: normalizing_field_cancel plus times power zero one minus uminus divide inverse
   331 proof
   332 qed (simp_all add: divide_inverse)
   333 
   334 declaration {* Normalizer.field_funs @{thm normalizing.normalizing_field_cancel_axioms'} *}
   335 
   336 end