src/Pure/axclass.ML
author wenzelm
Thu May 31 17:57:02 2001 +0200 (2001-05-31)
changeset 11353 7f6eff7bc97a
parent 11101 014e7b5c77ba
child 11539 0f17da240450
permissions -rw-r--r--
invent_names
     1 (*  Title:      Pure/axclass.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Axiomatic type class package.
     6 *)
     7 
     8 signature AX_CLASS =
     9 sig
    10   val quiet_mode: bool ref
    11   val print_axclasses: theory -> unit
    12   val add_classrel_thms: thm list -> theory -> theory
    13   val add_arity_thms: thm list -> theory -> theory
    14   val add_axclass: bclass * xclass list -> ((bstring * string) * Args.src list) list
    15     -> theory -> theory * {intro: thm, axioms: thm list}
    16   val add_axclass_i: bclass * class list -> ((bstring * term) * theory attribute list) list
    17     -> theory -> theory * {intro: thm, axioms: thm list}
    18   val add_inst_subclass: xclass * xclass -> string list -> thm list
    19     -> tactic option -> theory -> theory
    20   val add_inst_subclass_i: class * class -> string list -> thm list
    21     -> tactic option -> theory -> theory
    22   val add_inst_arity: xstring * string list * string -> string list
    23     -> thm list -> tactic option -> theory -> theory
    24   val add_inst_arity_i: string * sort list * sort -> string list
    25     -> thm list -> tactic option -> theory -> theory
    26   val default_intro_classes_tac: thm list -> int -> tactic
    27   val axclass_tac: thm list -> tactic
    28   val prove_subclass: theory -> class * class -> thm list
    29     -> tactic option -> thm
    30   val prove_arity: theory -> string * sort list * class -> thm list
    31     -> tactic option -> thm
    32   val goal_subclass: theory -> xclass * xclass -> thm list
    33   val goal_arity: theory -> xstring * string list * xclass -> thm list
    34   val instance_subclass_proof: (xclass * xclass) * Comment.text -> bool -> theory -> ProofHistory.T
    35   val instance_subclass_proof_i: (class * class) * Comment.text -> bool -> theory -> ProofHistory.T
    36   val instance_arity_proof: (xstring * string list * xclass) * Comment.text
    37     -> bool -> theory -> ProofHistory.T
    38   val instance_arity_proof_i: (string * sort list * class) * Comment.text
    39     -> bool -> theory -> ProofHistory.T
    40   val setup: (theory -> theory) list
    41 end;
    42 
    43 structure AxClass : AX_CLASS =
    44 struct
    45 
    46 
    47 (** utilities **)
    48 
    49 (* messages *)
    50 
    51 val quiet_mode = ref false;
    52 fun message s = if ! quiet_mode then () else writeln s;
    53 
    54 
    55 (* type vars *)
    56 
    57 fun map_typ_frees f (Type (t, tys)) = Type (t, map (map_typ_frees f) tys)
    58   | map_typ_frees f (TFree a) = f a
    59   | map_typ_frees _ a = a;
    60 
    61 val map_term_tfrees = map_term_types o map_typ_frees;
    62 
    63 fun aT S = TFree ("'a", S);
    64 
    65 fun dest_varT (TFree (x, S)) = ((x, ~1), S)
    66   | dest_varT (TVar xi_S) = xi_S
    67   | dest_varT T = raise TYPE ("dest_varT", [T], []);
    68 
    69 
    70 (* get axioms and theorems *)
    71 
    72 val is_def = Logic.is_equals o #prop o rep_thm;
    73 
    74 fun witnesses thy names thms =
    75   PureThy.get_thmss thy names @ thms @ filter is_def (map snd (axioms_of thy));
    76 
    77 
    78 
    79 (** abstract syntax operations **)
    80 
    81 (* names *)
    82 
    83 fun intro_name c = c ^ "I";
    84 val introN = "intro";
    85 val axiomsN = "axioms";
    86 
    87 
    88 (* subclass relations as terms *)
    89 
    90 fun mk_classrel (c1, c2) = Logic.mk_inclass (aT [c1], c2);
    91 
    92 fun dest_classrel tm =
    93   let
    94     fun err () = raise TERM ("dest_classrel", [tm]);
    95 
    96     val (ty, c2) = Logic.dest_inclass tm handle TERM _ => err ();
    97     val c1 = (case dest_varT ty of (_, [c]) => c | _ => err ())
    98       handle TYPE _ => err ();
    99   in (c1, c2) end;
   100 
   101 
   102 (* arities as terms *)
   103 
   104 fun mk_arity (t, ss, c) =
   105   let
   106     val tfrees = ListPair.map TFree (Term.invent_names (length ss + 1) "'", ss);
   107   in Logic.mk_inclass (Type (t, tfrees), c) end;
   108 
   109 fun dest_arity tm =
   110   let
   111     fun err () = raise TERM ("dest_arity", [tm]);
   112 
   113     val (ty, c) = Logic.dest_inclass tm handle TERM _ => err ();
   114     val (t, tvars) =
   115       (case ty of
   116         Type (t, tys) => (t, map dest_varT tys handle TYPE _ => err ())
   117       | _ => err ());
   118     val ss =
   119       if null (gen_duplicates eq_fst tvars)
   120       then map snd tvars else err ();
   121   in (t, ss, c) end;
   122 
   123 
   124 
   125 (** add theorems as axioms **)
   126 
   127 fun prep_thm_axm thy thm =
   128   let
   129     fun err msg = raise THM ("prep_thm_axm: " ^ msg, 0, [thm]);
   130 
   131     val {sign, hyps, prop, ...} = rep_thm thm;
   132   in
   133     if not (Sign.subsig (sign, Theory.sign_of thy)) then
   134       err "theorem not of same theory"
   135     else if not (null (extra_shyps thm)) orelse not (null hyps) then
   136       err "theorem may not contain hypotheses"
   137     else prop
   138   end;
   139 
   140 (*theorems expressing class relations*)
   141 fun add_classrel_thms thms thy =
   142   let
   143     fun prep_thm thm =
   144       let
   145         val prop = prep_thm_axm thy thm;
   146         val (c1, c2) = dest_classrel prop handle TERM _ =>
   147           raise THM ("add_classrel_thms: theorem is not a class relation", 0, [thm]);
   148       in (c1, c2) end;
   149   in Theory.add_classrel_i (map prep_thm thms) thy end;
   150 
   151 (*theorems expressing arities*)
   152 fun add_arity_thms thms thy =
   153   let
   154     fun prep_thm thm =
   155       let
   156         val prop = prep_thm_axm thy thm;
   157         val (t, ss, c) = dest_arity prop handle TERM _ =>
   158           raise THM ("add_arity_thms: theorem is not an arity", 0, [thm]);
   159       in (t, ss, [c]) end;
   160   in Theory.add_arities_i (map prep_thm thms) thy end;
   161 
   162 
   163 
   164 (** axclass info **)
   165 
   166 (* data kind 'Pure/axclasses' *)
   167 
   168 type axclass_info =
   169   {super_classes: class list,
   170     intro: thm,
   171     axioms: thm list};
   172 
   173 structure AxclassesArgs =
   174 struct
   175   val name = "Pure/axclasses";
   176   type T = axclass_info Symtab.table;
   177 
   178   val empty = Symtab.empty;
   179   val copy = I;
   180   val prep_ext = I;
   181   fun merge (tab1, tab2) = Symtab.merge (K true) (tab1, tab2);
   182 
   183   fun print sg tab =
   184     let
   185       val ext_class = Sign.cond_extern sg Sign.classK;
   186       val ext_thm = PureThy.cond_extern_thm_sg sg;
   187 
   188       fun pretty_class c cs = Pretty.block
   189         (Pretty.str (ext_class c) :: Pretty.str " <" :: Pretty.brk 1 ::
   190           Pretty.breaks (map (Pretty.str o ext_class) cs));
   191 
   192       fun pretty_thms name thms = Pretty.big_list (name ^ ":")
   193         (map (Display.pretty_thm_sg sg) thms);
   194 
   195       fun pretty_axclass (name, {super_classes, intro, axioms}) = Pretty.block (Pretty.fbreaks
   196         [pretty_class name super_classes, pretty_thms introN [intro], pretty_thms axiomsN axioms]);
   197     in Pretty.writeln (Pretty.chunks (map pretty_axclass (Symtab.dest tab))) end;
   198 end;
   199 
   200 structure AxclassesData = TheoryDataFun(AxclassesArgs);
   201 val print_axclasses = AxclassesData.print;
   202 
   203 
   204 (* get and put data *)
   205 
   206 fun lookup_axclass_info_sg sg c = Symtab.lookup (AxclassesData.get_sg sg, c);
   207 
   208 fun get_axclass_info thy c =
   209   (case lookup_axclass_info_sg (Theory.sign_of thy) c of
   210     None => error ("Unknown axclass " ^ quote c)
   211   | Some info => info);
   212 
   213 fun put_axclass_info c info thy =
   214   thy |> AxclassesData.put (Symtab.update ((c, info), AxclassesData.get thy));
   215 
   216 
   217 
   218 (** add axiomatic type classes **)
   219 
   220 (* errors *)
   221 
   222 fun err_not_logic c =
   223   error ("Axiomatic class " ^ quote c ^ " not subclass of " ^ quote logicC);
   224 
   225 fun err_bad_axsort ax c =
   226   error ("Sort constraint in axiom " ^ quote ax ^ " not supersort of " ^ quote c);
   227 
   228 fun err_bad_tfrees ax =
   229   error ("More than one type variable in axiom " ^ quote ax);
   230 
   231 
   232 (* ext_axclass *)
   233 
   234 fun ext_axclass prep_class prep_axm prep_att (bclass, raw_super_classes) raw_axioms_atts thy =
   235   let
   236     val sign = Theory.sign_of thy;
   237 
   238     val class = Sign.full_name sign bclass;
   239     val super_classes = map (prep_class sign) raw_super_classes;
   240     val axms = map (prep_axm sign o fst) raw_axioms_atts;
   241     val atts = map (map (prep_att thy) o snd) raw_axioms_atts;
   242 
   243     (*declare class*)
   244     val class_thy =
   245       thy |> Theory.add_classes_i [(bclass, super_classes)];
   246     val class_sign = Theory.sign_of class_thy;
   247 
   248     (*prepare abstract axioms*)
   249     fun abs_axm ax =
   250       if null (term_tfrees ax) then
   251         Logic.mk_implies (Logic.mk_inclass (aT logicS, class), ax)
   252       else map_term_tfrees (K (aT [class])) ax;
   253     val abs_axms = map (abs_axm o #2) axms;
   254 
   255     (*prepare introduction rule*)
   256     val _ = if Sign.subsort class_sign ([class], logicS) then () else err_not_logic class;
   257 
   258     fun axm_sort (name, ax) =
   259       (case term_tfrees ax of
   260         [] => []
   261       | [(_, S)] => if Sign.subsort class_sign ([class], S) then S else err_bad_axsort name class
   262       | _ => err_bad_tfrees name);
   263     val axS = Sign.norm_sort class_sign (logicC :: flat (map axm_sort axms));
   264 
   265     val int_axm = Logic.close_form o map_term_tfrees (K (aT axS));
   266     fun inclass c = Logic.mk_inclass (aT axS, c);
   267 
   268     val intro_axm = Logic.list_implies
   269       (map inclass super_classes @ map (int_axm o #2) axms, inclass class);
   270 
   271     (*declare axioms and rule*)
   272     val (axms_thy, ([intro], [axioms])) =
   273       class_thy
   274       |> Theory.add_path bclass
   275       |> PureThy.add_axioms_i [Thm.no_attributes (introN, intro_axm)]
   276       |>>> PureThy.add_axiomss_i [Thm.no_attributes (axiomsN, abs_axms)];
   277     val info = {super_classes = super_classes, intro = intro, axioms = axioms};
   278 
   279     (*store info*)
   280     val final_thy =
   281       axms_thy
   282       |> (#1 o PureThy.add_thms ((map #1 axms ~~ axioms) ~~ atts))
   283       |> Theory.parent_path
   284       |> (#1 o PureThy.add_thms [Thm.no_attributes (intro_name bclass, intro)])
   285       |> put_axclass_info class info;
   286   in (final_thy, {intro = intro, axioms = axioms}) end;
   287 
   288 
   289 (* external interfaces *)
   290 
   291 val add_axclass = ext_axclass Sign.intern_class Theory.read_axm Attrib.global_attribute;
   292 val add_axclass_i = ext_axclass (K I) Theory.cert_axm (K I);
   293 
   294 
   295 
   296 (** prove class relations and type arities **)
   297 
   298 (* class_axms *)
   299 
   300 fun class_axms sign =
   301   let val classes = Sign.classes sign in
   302     map (Thm.class_triv sign) classes @
   303     mapfilter (apsome #intro o lookup_axclass_info_sg sign) classes
   304   end;
   305 
   306 
   307 (* intro_classes *)
   308 
   309 fun intro_classes_tac facts i st =
   310   ((Method.insert_tac facts THEN'
   311     REPEAT_ALL_NEW (resolve_tac (class_axms (Thm.sign_of_thm st)))) i
   312     THEN Tactic.distinct_subgoals_tac) st;    (*affects all subgoals!?*)
   313 
   314 val intro_classes_method =
   315   ("intro_classes", Method.no_args (Method.METHOD (HEADGOAL o intro_classes_tac)),
   316     "back-chain introduction rules of axiomatic type classes");
   317 
   318 
   319 (* default method *)
   320 
   321 fun default_intro_classes_tac [] i = intro_classes_tac [] i
   322   | default_intro_classes_tac _ _ = Tactical.no_tac;    (*no error message!*)
   323 
   324 fun default_tac rules ctxt facts =
   325   HEADGOAL (Method.some_rule_tac rules ctxt facts ORELSE' default_intro_classes_tac facts);
   326 
   327 val default_method =
   328   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac), "apply some rule")
   329 
   330 
   331 (* axclass_tac *)
   332 
   333 (*(1) repeatedly resolve goals of form "OFCLASS(ty, c_class)",
   334       try class_trivs first, then "cI" axioms
   335   (2) rewrite goals using user supplied definitions
   336   (3) repeatedly resolve goals with user supplied non-definitions*)
   337 
   338 fun axclass_tac thms =
   339   let
   340     val defs = filter is_def thms;
   341     val non_defs = filter_out is_def thms;
   342   in
   343     HEADGOAL (intro_classes_tac []) THEN
   344     TRY (rewrite_goals_tac defs) THEN
   345     TRY (REPEAT_FIRST (fn i => assume_tac i ORELSE resolve_tac non_defs i))
   346   end;
   347 
   348 
   349 (* provers *)
   350 
   351 fun prove mk_prop str_of thy sig_prop thms usr_tac =
   352   let
   353     val sign = Theory.sign_of thy;
   354     val goal = Thm.cterm_of sign (mk_prop sig_prop)
   355       handle TERM (msg, _) => error msg
   356         | TYPE (msg, _, _) => error msg;
   357     val tac = axclass_tac thms THEN (if_none usr_tac all_tac);
   358   in
   359     prove_goalw_cterm [] goal (K [tac])
   360   end
   361   handle ERROR => error ("The error(s) above occurred while trying to prove "
   362     ^ quote (str_of (Theory.sign_of thy, sig_prop)));
   363 
   364 val prove_subclass =
   365   prove mk_classrel (fn (sg, c1_c2) => Sign.str_of_classrel sg c1_c2);
   366 
   367 val prove_arity =
   368   prove mk_arity (fn (sg, (t, Ss, c)) => Sign.str_of_arity sg (t, Ss, [c]));
   369 
   370 
   371 
   372 (** add proved subclass relations and arities **)
   373 
   374 (* prepare classes and arities *)
   375 
   376 fun read_class sg c = Sign.certify_class sg (Sign.intern_class sg c);
   377 
   378 fun cert_classrel sg cc = Library.pairself (Sign.certify_class sg) cc;
   379 fun read_classrel sg cc = Library.pairself (read_class sg) cc;
   380 
   381 fun check_tycon sg t =
   382   let val {tycons, abbrs, ...} = Type.rep_tsig (Sign.tsig_of sg) in
   383     if is_some (Symtab.lookup (abbrs, t)) then
   384       error ("Illegal type abbreviation: " ^ quote t)
   385     else if is_none (Symtab.lookup (tycons, t)) then
   386       error ("Undeclared type constructor: " ^ quote t)
   387     else t
   388   end;
   389 
   390 fun prep_arity prep_tycon prep_sort prep_x sg (t, Ss, x) =
   391   (check_tycon sg (prep_tycon sg t), map (prep_sort sg) Ss, prep_x sg x);
   392 
   393 val read_arity = prep_arity Sign.intern_tycon Sign.read_sort Sign.read_sort;
   394 val cert_arity = prep_arity (K I) Sign.certify_sort Sign.certify_sort;
   395 val read_simple_arity = prep_arity Sign.intern_tycon Sign.read_sort Sign.intern_class;
   396 fun cert_simple_arity arg = prep_arity (K I) Sign.certify_sort (K I) arg;
   397 
   398 
   399 (* old-style instance declarations *)
   400 
   401 fun ext_inst_subclass prep_classrel raw_c1_c2 names thms usr_tac thy =
   402   let val c1_c2 = prep_classrel (Theory.sign_of thy) raw_c1_c2 in
   403     message ("Proving class inclusion " ^
   404       quote (Sign.str_of_classrel (Theory.sign_of thy) c1_c2) ^ " ...");
   405     thy |> add_classrel_thms [prove_subclass thy c1_c2 (witnesses thy names thms) usr_tac]
   406   end;
   407 
   408 fun ext_inst_arity prep_arity (raw_t, raw_Ss, raw_cs) names thms usr_tac thy =
   409   let
   410     val sign = Theory.sign_of thy;
   411     val (t, Ss, cs) = prep_arity sign (raw_t, raw_Ss, raw_cs);
   412     val wthms = witnesses thy names thms;
   413     fun prove c =
   414      (message ("Proving type arity " ^
   415         quote (Sign.str_of_arity sign (t, Ss, [c])) ^ " ...");
   416         prove_arity thy (t, Ss, c) wthms usr_tac);
   417   in add_arity_thms (map prove cs) thy end;
   418 
   419 
   420 val add_inst_subclass = ext_inst_subclass read_classrel;
   421 val add_inst_subclass_i = ext_inst_subclass cert_classrel;
   422 val add_inst_arity = ext_inst_arity read_arity;
   423 val add_inst_arity_i = ext_inst_arity cert_arity;
   424 
   425 
   426 (* make old-style interactive goals *)
   427 
   428 fun mk_goal mk_prop thy sig_prop =
   429   Goals.goalw_cterm [] (Thm.cterm_of (Theory.sign_of thy) (mk_prop (Theory.sign_of thy) sig_prop));
   430 
   431 val goal_subclass = mk_goal (mk_classrel oo read_classrel);
   432 val goal_arity = mk_goal (mk_arity oo read_simple_arity);
   433 
   434 
   435 
   436 (** instance proof interfaces **)
   437 
   438 fun inst_attribute add_thms (thy, thm) = (add_thms [thm] thy, thm);
   439 
   440 fun inst_proof mk_prop add_thms (sig_prop, comment) int thy =
   441   thy
   442   |> IsarThy.theorem_i ((("", [inst_attribute add_thms]),
   443     (mk_prop (Theory.sign_of thy) sig_prop, ([], []))), comment) int;
   444 
   445 val instance_subclass_proof = inst_proof (mk_classrel oo read_classrel) add_classrel_thms;
   446 val instance_subclass_proof_i = inst_proof (mk_classrel oo cert_classrel) add_classrel_thms;
   447 val instance_arity_proof = inst_proof (mk_arity oo read_simple_arity) add_arity_thms;
   448 val instance_arity_proof_i = inst_proof (mk_arity oo cert_simple_arity) add_arity_thms;
   449 
   450 
   451 
   452 (** package setup **)
   453 
   454 (* setup theory *)
   455 
   456 val setup =
   457  [AxclassesData.init,
   458   Method.add_methods [intro_classes_method, default_method]];
   459 
   460 
   461 (* outer syntax *)
   462 
   463 local structure P = OuterParse and K = OuterSyntax.Keyword in
   464 
   465 val axclassP =
   466   OuterSyntax.command "axclass" "define axiomatic type class" K.thy_decl
   467     (((P.name -- Scan.optional ((P.$$$ "\\<subseteq>" || P.$$$ "<") |--
   468         P.!!! (P.list1 P.xname)) []) --| P.marg_comment)
   469       -- Scan.repeat (P.spec_name --| P.marg_comment)
   470       >> (fn (cls, axs) => Toplevel.theory (#1 o add_axclass cls axs)));
   471 
   472 val instanceP =
   473   OuterSyntax.command "instance" "prove type arity or subclass relation" K.thy_goal
   474     ((P.xname -- ((P.$$$ "\\<subseteq>" || P.$$$ "<") |-- P.xname)
   475         -- P.marg_comment >> instance_subclass_proof ||
   476       (P.xname -- (P.$$$ "::" |-- P.simple_arity) >> P.triple2) -- P.marg_comment
   477         >> instance_arity_proof)
   478       >> (Toplevel.print oo Toplevel.theory_to_proof));
   479 
   480 val _ = OuterSyntax.add_parsers [axclassP, instanceP];
   481 
   482 end;
   483 
   484 
   485 end;