src/ZF/Constructible/Formula.thy
author paulson
Mon Oct 14 11:32:00 2002 +0200 (2002-10-14)
changeset 13647 7f6f0ffc45c3
parent 13634 99a593b49b04
child 13651 ac80e101306a
permissions -rw-r--r--
tidying and reorganization
     1 (*  Title:      ZF/Constructible/Formula.thy
     2     ID: $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4 *)
     5 
     6 header {* First-Order Formulas and the Definition of the Class L *}
     7 
     8 theory Formula = Main:
     9 
    10 subsection{*Internalized formulas of FOL*}
    11 
    12 text{*De Bruijn representation.
    13   Unbound variables get their denotations from an environment.*}
    14 
    15 consts   formula :: i
    16 datatype
    17   "formula" = Member ("x: nat", "y: nat")
    18             | Equal  ("x: nat", "y: nat")
    19             | Nand ("p: formula", "q: formula")
    20             | Forall ("p: formula")
    21 
    22 declare formula.intros [TC]
    23 
    24 constdefs Neg :: "i=>i"
    25     "Neg(p) == Nand(p,p)"
    26 
    27 constdefs And :: "[i,i]=>i"
    28     "And(p,q) == Neg(Nand(p,q))"
    29 
    30 constdefs Or :: "[i,i]=>i"
    31     "Or(p,q) == Nand(Neg(p),Neg(q))"
    32 
    33 constdefs Implies :: "[i,i]=>i"
    34     "Implies(p,q) == Nand(p,Neg(q))"
    35 
    36 constdefs Iff :: "[i,i]=>i"
    37     "Iff(p,q) == And(Implies(p,q), Implies(q,p))"
    38 
    39 constdefs Exists :: "i=>i"
    40     "Exists(p) == Neg(Forall(Neg(p)))";
    41 
    42 lemma Neg_type [TC]: "p \<in> formula ==> Neg(p) \<in> formula"
    43 by (simp add: Neg_def) 
    44 
    45 lemma And_type [TC]: "[| p \<in> formula; q \<in> formula |] ==> And(p,q) \<in> formula"
    46 by (simp add: And_def) 
    47 
    48 lemma Or_type [TC]: "[| p \<in> formula; q \<in> formula |] ==> Or(p,q) \<in> formula"
    49 by (simp add: Or_def) 
    50 
    51 lemma Implies_type [TC]:
    52      "[| p \<in> formula; q \<in> formula |] ==> Implies(p,q) \<in> formula"
    53 by (simp add: Implies_def) 
    54 
    55 lemma Iff_type [TC]:
    56      "[| p \<in> formula; q \<in> formula |] ==> Iff(p,q) \<in> formula"
    57 by (simp add: Iff_def) 
    58 
    59 lemma Exists_type [TC]: "p \<in> formula ==> Exists(p) \<in> formula"
    60 by (simp add: Exists_def) 
    61 
    62 
    63 consts   satisfies :: "[i,i]=>i"
    64 primrec (*explicit lambda is required because the environment varies*)
    65   "satisfies(A,Member(x,y)) = 
    66       (\<lambda>env \<in> list(A). bool_of_o (nth(x,env) \<in> nth(y,env)))"
    67 
    68   "satisfies(A,Equal(x,y)) = 
    69       (\<lambda>env \<in> list(A). bool_of_o (nth(x,env) = nth(y,env)))"
    70 
    71   "satisfies(A,Nand(p,q)) =
    72       (\<lambda>env \<in> list(A). not ((satisfies(A,p)`env) and (satisfies(A,q)`env)))"
    73 
    74   "satisfies(A,Forall(p)) = 
    75       (\<lambda>env \<in> list(A). bool_of_o (\<forall>x\<in>A. satisfies(A,p) ` (Cons(x,env)) = 1))"
    76 
    77 
    78 lemma "p \<in> formula ==> satisfies(A,p) \<in> list(A) -> bool"
    79 by (induct_tac p, simp_all) 
    80 
    81 syntax sats :: "[i,i,i] => o"
    82 translations "sats(A,p,env)" == "satisfies(A,p)`env = 1"
    83 
    84 lemma [simp]:
    85   "env \<in> list(A) 
    86    ==> sats(A, Member(x,y), env) <-> nth(x,env) \<in> nth(y,env)"
    87 by simp
    88 
    89 lemma [simp]:
    90   "env \<in> list(A) 
    91    ==> sats(A, Equal(x,y), env) <-> nth(x,env) = nth(y,env)"
    92 by simp
    93 
    94 lemma sats_Nand_iff [simp]:
    95   "env \<in> list(A) 
    96    ==> (sats(A, Nand(p,q), env)) <-> ~ (sats(A,p,env) & sats(A,q,env))" 
    97 by (simp add: Bool.and_def Bool.not_def cond_def) 
    98 
    99 lemma sats_Forall_iff [simp]:
   100   "env \<in> list(A) 
   101    ==> sats(A, Forall(p), env) <-> (\<forall>x\<in>A. sats(A, p, Cons(x,env)))"
   102 by simp
   103 
   104 declare satisfies.simps [simp del]; 
   105 
   106 subsection{*Dividing line between primitive and derived connectives*}
   107 
   108 lemma sats_Neg_iff [simp]:
   109   "env \<in> list(A) 
   110    ==> sats(A, Neg(p), env) <-> ~ sats(A,p,env)"
   111 by (simp add: Neg_def) 
   112 
   113 lemma sats_And_iff [simp]:
   114   "env \<in> list(A) 
   115    ==> (sats(A, And(p,q), env)) <-> sats(A,p,env) & sats(A,q,env)"
   116 by (simp add: And_def) 
   117 
   118 lemma sats_Or_iff [simp]:
   119   "env \<in> list(A) 
   120    ==> (sats(A, Or(p,q), env)) <-> sats(A,p,env) | sats(A,q,env)"
   121 by (simp add: Or_def)
   122 
   123 lemma sats_Implies_iff [simp]:
   124   "env \<in> list(A) 
   125    ==> (sats(A, Implies(p,q), env)) <-> (sats(A,p,env) --> sats(A,q,env))"
   126 by (simp add: Implies_def, blast) 
   127 
   128 lemma sats_Iff_iff [simp]:
   129   "env \<in> list(A) 
   130    ==> (sats(A, Iff(p,q), env)) <-> (sats(A,p,env) <-> sats(A,q,env))"
   131 by (simp add: Iff_def, blast) 
   132 
   133 lemma sats_Exists_iff [simp]:
   134   "env \<in> list(A) 
   135    ==> sats(A, Exists(p), env) <-> (\<exists>x\<in>A. sats(A, p, Cons(x,env)))"
   136 by (simp add: Exists_def)
   137 
   138 
   139 subsubsection{*Derived rules to help build up formulas*}
   140 
   141 lemma mem_iff_sats:
   142       "[| nth(i,env) = x; nth(j,env) = y; env \<in> list(A)|]
   143        ==> (x\<in>y) <-> sats(A, Member(i,j), env)" 
   144 by (simp add: satisfies.simps)
   145 
   146 lemma equal_iff_sats:
   147       "[| nth(i,env) = x; nth(j,env) = y; env \<in> list(A)|]
   148        ==> (x=y) <-> sats(A, Equal(i,j), env)" 
   149 by (simp add: satisfies.simps)
   150 
   151 lemma not_iff_sats:
   152       "[| P <-> sats(A,p,env); env \<in> list(A)|]
   153        ==> (~P) <-> sats(A, Neg(p), env)"
   154 by simp
   155 
   156 lemma conj_iff_sats:
   157       "[| P <-> sats(A,p,env); Q <-> sats(A,q,env); env \<in> list(A)|]
   158        ==> (P & Q) <-> sats(A, And(p,q), env)"
   159 by (simp add: sats_And_iff)
   160 
   161 lemma disj_iff_sats:
   162       "[| P <-> sats(A,p,env); Q <-> sats(A,q,env); env \<in> list(A)|]
   163        ==> (P | Q) <-> sats(A, Or(p,q), env)"
   164 by (simp add: sats_Or_iff)
   165 
   166 lemma iff_iff_sats:
   167       "[| P <-> sats(A,p,env); Q <-> sats(A,q,env); env \<in> list(A)|]
   168        ==> (P <-> Q) <-> sats(A, Iff(p,q), env)"
   169 by (simp add: sats_Forall_iff) 
   170 
   171 lemma imp_iff_sats:
   172       "[| P <-> sats(A,p,env); Q <-> sats(A,q,env); env \<in> list(A)|]
   173        ==> (P --> Q) <-> sats(A, Implies(p,q), env)"
   174 by (simp add: sats_Forall_iff) 
   175 
   176 lemma ball_iff_sats:
   177       "[| !!x. x\<in>A ==> P(x) <-> sats(A, p, Cons(x, env)); env \<in> list(A)|]
   178        ==> (\<forall>x\<in>A. P(x)) <-> sats(A, Forall(p), env)"
   179 by (simp add: sats_Forall_iff) 
   180 
   181 lemma bex_iff_sats:
   182       "[| !!x. x\<in>A ==> P(x) <-> sats(A, p, Cons(x, env)); env \<in> list(A)|]
   183        ==> (\<exists>x\<in>A. P(x)) <-> sats(A, Exists(p), env)"
   184 by (simp add: sats_Exists_iff) 
   185 
   186 lemmas FOL_iff_sats = 
   187         mem_iff_sats equal_iff_sats not_iff_sats conj_iff_sats
   188         disj_iff_sats imp_iff_sats iff_iff_sats imp_iff_sats ball_iff_sats
   189         bex_iff_sats
   190 
   191 
   192 subsection{*Arity of a Formula: Maximum Free de Bruijn Index*}
   193 
   194 consts   arity :: "i=>i"
   195 primrec
   196   "arity(Member(x,y)) = succ(x) \<union> succ(y)"
   197 
   198   "arity(Equal(x,y)) = succ(x) \<union> succ(y)"
   199 
   200   "arity(Nand(p,q)) = arity(p) \<union> arity(q)"
   201 
   202   "arity(Forall(p)) = Arith.pred(arity(p))"
   203 
   204 
   205 lemma arity_type [TC]: "p \<in> formula ==> arity(p) \<in> nat"
   206 by (induct_tac p, simp_all) 
   207 
   208 lemma arity_Neg [simp]: "arity(Neg(p)) = arity(p)"
   209 by (simp add: Neg_def) 
   210 
   211 lemma arity_And [simp]: "arity(And(p,q)) = arity(p) \<union> arity(q)"
   212 by (simp add: And_def) 
   213 
   214 lemma arity_Or [simp]: "arity(Or(p,q)) = arity(p) \<union> arity(q)"
   215 by (simp add: Or_def) 
   216 
   217 lemma arity_Implies [simp]: "arity(Implies(p,q)) = arity(p) \<union> arity(q)"
   218 by (simp add: Implies_def) 
   219 
   220 lemma arity_Iff [simp]: "arity(Iff(p,q)) = arity(p) \<union> arity(q)"
   221 by (simp add: Iff_def, blast)
   222 
   223 lemma arity_Exists [simp]: "arity(Exists(p)) = Arith.pred(arity(p))"
   224 by (simp add: Exists_def) 
   225 
   226 
   227 lemma arity_sats_iff [rule_format]:
   228   "[| p \<in> formula; extra \<in> list(A) |]
   229    ==> \<forall>env \<in> list(A). 
   230            arity(p) \<le> length(env) --> 
   231            sats(A, p, env @ extra) <-> sats(A, p, env)"
   232 apply (induct_tac p)
   233 apply (simp_all add: Arith.pred_def nth_append Un_least_lt_iff nat_imp_quasinat
   234                 split: split_nat_case, auto) 
   235 done
   236 
   237 lemma arity_sats1_iff:
   238   "[| arity(p) \<le> succ(length(env)); p \<in> formula; x \<in> A; env \<in> list(A); 
   239       extra \<in> list(A) |]
   240    ==> sats(A, p, Cons(x, env @ extra)) <-> sats(A, p, Cons(x, env))"
   241 apply (insert arity_sats_iff [of p extra A "Cons(x,env)"])
   242 apply simp 
   243 done
   244 
   245 
   246 subsection{*Renaming Some de Bruijn Variables*}
   247 
   248 constdefs incr_var :: "[i,i]=>i"
   249     "incr_var(x,lev) == if x<lev then x else succ(x)"
   250 
   251 lemma incr_var_lt: "x<lev ==> incr_var(x,lev) = x"
   252 by (simp add: incr_var_def)
   253 
   254 lemma incr_var_le: "lev\<le>x ==> incr_var(x,lev) = succ(x)"
   255 apply (simp add: incr_var_def) 
   256 apply (blast dest: lt_trans1) 
   257 done
   258 
   259 consts   incr_bv :: "i=>i"
   260 primrec
   261   "incr_bv(Member(x,y)) = 
   262       (\<lambda>lev \<in> nat. Member (incr_var(x,lev), incr_var(y,lev)))"
   263 
   264   "incr_bv(Equal(x,y)) = 
   265       (\<lambda>lev \<in> nat. Equal (incr_var(x,lev), incr_var(y,lev)))"
   266 
   267   "incr_bv(Nand(p,q)) =
   268       (\<lambda>lev \<in> nat. Nand (incr_bv(p)`lev, incr_bv(q)`lev))"
   269 
   270   "incr_bv(Forall(p)) = 
   271       (\<lambda>lev \<in> nat. Forall (incr_bv(p) ` succ(lev)))"
   272 
   273 
   274 lemma [TC]: "x \<in> nat ==> incr_var(x,lev) \<in> nat"
   275 by (simp add: incr_var_def) 
   276 
   277 lemma incr_bv_type [TC]: "p \<in> formula ==> incr_bv(p) \<in> nat -> formula"
   278 by (induct_tac p, simp_all) 
   279 
   280 text{*Obviously, @{term DPow} is closed under complements and finite
   281 intersections and unions.  Needs an inductive lemma to allow two lists of
   282 parameters to be combined.*}
   283 
   284 lemma sats_incr_bv_iff [rule_format]:
   285   "[| p \<in> formula; env \<in> list(A); x \<in> A |]
   286    ==> \<forall>bvs \<in> list(A). 
   287            sats(A, incr_bv(p) ` length(bvs), bvs @ Cons(x,env)) <-> 
   288            sats(A, p, bvs@env)"
   289 apply (induct_tac p)
   290 apply (simp_all add: incr_var_def nth_append succ_lt_iff length_type)
   291 apply (auto simp add: diff_succ not_lt_iff_le)
   292 done
   293 
   294 
   295 (*the following two lemmas prevent huge case splits in arity_incr_bv_lemma*)
   296 lemma incr_var_lemma:
   297      "[| x \<in> nat; y \<in> nat; lev \<le> x |]
   298       ==> succ(x) \<union> incr_var(y,lev) = succ(x \<union> y)"
   299 apply (simp add: incr_var_def Ord_Un_if, auto)
   300   apply (blast intro: leI)
   301  apply (simp add: not_lt_iff_le)  
   302  apply (blast intro: le_anti_sym) 
   303 apply (blast dest: lt_trans2) 
   304 done
   305 
   306 lemma incr_And_lemma:
   307      "y < x ==> y \<union> succ(x) = succ(x \<union> y)"
   308 apply (simp add: Ord_Un_if lt_Ord lt_Ord2 succ_lt_iff) 
   309 apply (blast dest: lt_asym) 
   310 done
   311 
   312 lemma arity_incr_bv_lemma [rule_format]:
   313   "p \<in> formula 
   314    ==> \<forall>n \<in> nat. arity (incr_bv(p) ` n) = 
   315                  (if n < arity(p) then succ(arity(p)) else arity(p))"
   316 apply (induct_tac p) 
   317 apply (simp_all add: imp_disj not_lt_iff_le Un_least_lt_iff lt_Un_iff le_Un_iff
   318                      succ_Un_distrib [symmetric] incr_var_lt incr_var_le
   319                      Un_commute incr_var_lemma Arith.pred_def nat_imp_quasinat
   320             split: split_nat_case) 
   321  txt{*the Forall case reduces to linear arithmetic*}
   322  prefer 2
   323  apply clarify 
   324  apply (blast dest: lt_trans1) 
   325 txt{*left with the And case*}
   326 apply safe
   327  apply (blast intro: incr_And_lemma lt_trans1) 
   328 apply (subst incr_And_lemma)
   329  apply (blast intro: lt_trans1) 
   330 apply (simp add: Un_commute)
   331 done
   332 
   333 
   334 subsection{*Renaming all but the First de Bruijn Variable*}
   335 
   336 constdefs incr_bv1 :: "i => i"
   337     "incr_bv1(p) == incr_bv(p)`1"
   338 
   339 
   340 lemma incr_bv1_type [TC]: "p \<in> formula ==> incr_bv1(p) \<in> formula"
   341 by (simp add: incr_bv1_def) 
   342 
   343 (*For renaming all but the bound variable at level 0*)
   344 lemma sats_incr_bv1_iff:
   345   "[| p \<in> formula; env \<in> list(A); x \<in> A; y \<in> A |]
   346    ==> sats(A, incr_bv1(p), Cons(x, Cons(y, env))) <-> 
   347        sats(A, p, Cons(x,env))"
   348 apply (insert sats_incr_bv_iff [of p env A y "Cons(x,Nil)"])
   349 apply (simp add: incr_bv1_def) 
   350 done
   351 
   352 lemma formula_add_params1 [rule_format]:
   353   "[| p \<in> formula; n \<in> nat; x \<in> A |]
   354    ==> \<forall>bvs \<in> list(A). \<forall>env \<in> list(A). 
   355           length(bvs) = n --> 
   356           sats(A, iterates(incr_bv1, n, p), Cons(x, bvs@env)) <-> 
   357           sats(A, p, Cons(x,env))"
   358 apply (induct_tac n, simp, clarify) 
   359 apply (erule list.cases)
   360 apply (simp_all add: sats_incr_bv1_iff) 
   361 done
   362 
   363 
   364 lemma arity_incr_bv1_eq:
   365   "p \<in> formula
   366    ==> arity(incr_bv1(p)) =
   367         (if 1 < arity(p) then succ(arity(p)) else arity(p))"
   368 apply (insert arity_incr_bv_lemma [of p 1])
   369 apply (simp add: incr_bv1_def) 
   370 done
   371 
   372 lemma arity_iterates_incr_bv1_eq:
   373   "[| p \<in> formula; n \<in> nat |]
   374    ==> arity(incr_bv1^n(p)) =
   375          (if 1 < arity(p) then n #+ arity(p) else arity(p))"
   376 apply (induct_tac n) 
   377 apply (simp_all add: arity_incr_bv1_eq)
   378 apply (simp add: not_lt_iff_le)
   379 apply (blast intro: le_trans add_le_self2 arity_type) 
   380 done
   381 
   382 
   383 
   384 subsection{*Definable Powerset*}
   385 
   386 text{*The definable powerset operation: Kunen's definition VI 1.1, page 165.*}
   387 constdefs DPow :: "i => i"
   388   "DPow(A) == {X \<in> Pow(A). 
   389                \<exists>env \<in> list(A). \<exists>p \<in> formula. 
   390                  arity(p) \<le> succ(length(env)) & 
   391                  X = {x\<in>A. sats(A, p, Cons(x,env))}}"
   392 
   393 lemma DPowI:
   394   "[|env \<in> list(A);  p \<in> formula;  arity(p) \<le> succ(length(env))|]
   395    ==> {x\<in>A. sats(A, p, Cons(x,env))} \<in> DPow(A)"
   396 by (simp add: DPow_def, blast) 
   397 
   398 text{*With this rule we can specify @{term p} later.*}
   399 lemma DPowI2 [rule_format]:
   400   "[|\<forall>x\<in>A. P(x) <-> sats(A, p, Cons(x,env));
   401      env \<in> list(A);  p \<in> formula;  arity(p) \<le> succ(length(env))|]
   402    ==> {x\<in>A. P(x)} \<in> DPow(A)"
   403 by (simp add: DPow_def, blast) 
   404 
   405 lemma DPowD:
   406   "X \<in> DPow(A) 
   407    ==> X <= A &
   408        (\<exists>env \<in> list(A). 
   409         \<exists>p \<in> formula. arity(p) \<le> succ(length(env)) & 
   410                       X = {x\<in>A. sats(A, p, Cons(x,env))})"
   411 by (simp add: DPow_def) 
   412 
   413 lemmas DPow_imp_subset = DPowD [THEN conjunct1]
   414 
   415 (*Kunen's Lemma VI 1.2*)
   416 lemma "[| p \<in> formula; env \<in> list(A); arity(p) \<le> succ(length(env)) |] 
   417        ==> {x\<in>A. sats(A, p, Cons(x,env))} \<in> DPow(A)"
   418 by (blast intro: DPowI)
   419 
   420 lemma DPow_subset_Pow: "DPow(A) <= Pow(A)"
   421 by (simp add: DPow_def, blast)
   422 
   423 lemma empty_in_DPow: "0 \<in> DPow(A)"
   424 apply (simp add: DPow_def)
   425 apply (rule_tac x=Nil in bexI) 
   426  apply (rule_tac x="Neg(Equal(0,0))" in bexI) 
   427   apply (auto simp add: Un_least_lt_iff) 
   428 done
   429 
   430 lemma Compl_in_DPow: "X \<in> DPow(A) ==> (A-X) \<in> DPow(A)"
   431 apply (simp add: DPow_def, clarify, auto) 
   432 apply (rule bexI) 
   433  apply (rule_tac x="Neg(p)" in bexI) 
   434   apply auto 
   435 done
   436 
   437 lemma Int_in_DPow: "[| X \<in> DPow(A); Y \<in> DPow(A) |] ==> X Int Y \<in> DPow(A)"
   438 apply (simp add: DPow_def, auto) 
   439 apply (rename_tac envp p envq q) 
   440 apply (rule_tac x="envp@envq" in bexI) 
   441  apply (rule_tac x="And(p, iterates(incr_bv1,length(envp),q))" in bexI)
   442   apply typecheck
   443 apply (rule conjI) 
   444 (*finally check the arity!*)
   445  apply (simp add: arity_iterates_incr_bv1_eq length_app Un_least_lt_iff)
   446  apply (force intro: add_le_self le_trans) 
   447 apply (simp add: arity_sats1_iff formula_add_params1, blast) 
   448 done
   449 
   450 lemma Un_in_DPow: "[| X \<in> DPow(A); Y \<in> DPow(A) |] ==> X Un Y \<in> DPow(A)"
   451 apply (subgoal_tac "X Un Y = A - ((A-X) Int (A-Y))") 
   452 apply (simp add: Int_in_DPow Compl_in_DPow) 
   453 apply (simp add: DPow_def, blast) 
   454 done
   455 
   456 lemma singleton_in_DPow: "x \<in> A ==> {x} \<in> DPow(A)"
   457 apply (simp add: DPow_def)
   458 apply (rule_tac x="Cons(x,Nil)" in bexI) 
   459  apply (rule_tac x="Equal(0,1)" in bexI) 
   460   apply typecheck
   461 apply (force simp add: succ_Un_distrib [symmetric])  
   462 done
   463 
   464 lemma cons_in_DPow: "[| a \<in> A; X \<in> DPow(A) |] ==> cons(a,X) \<in> DPow(A)"
   465 apply (rule cons_eq [THEN subst]) 
   466 apply (blast intro: singleton_in_DPow Un_in_DPow) 
   467 done
   468 
   469 (*Part of Lemma 1.3*)
   470 lemma Fin_into_DPow: "X \<in> Fin(A) ==> X \<in> DPow(A)"
   471 apply (erule Fin.induct) 
   472  apply (rule empty_in_DPow) 
   473 apply (blast intro: cons_in_DPow) 
   474 done
   475 
   476 (*DPow is not monotonic.  For example, let A be some non-constructible set
   477   of natural numbers, and let B be nat.  Then A<=B and obviously A : DPow(A)
   478   but A ~: DPow(B).*)
   479 lemma DPow_mono: "A : DPow(B) ==> DPow(A) <= DPow(B)"
   480 apply (simp add: DPow_def, auto) 
   481 (*must use the formula defining A in B to relativize the new formula...*)
   482 oops
   483 
   484 lemma DPow_0: "DPow(0) = {0}" 
   485 by (blast intro: empty_in_DPow dest: DPow_imp_subset)
   486 
   487 lemma Finite_Pow_subset_Pow: "Finite(A) ==> Pow(A) <= DPow(A)" 
   488 by (blast intro: Fin_into_DPow Finite_into_Fin Fin_subset)
   489 
   490 lemma Finite_DPow_eq_Pow: "Finite(A) ==> DPow(A) = Pow(A)"
   491 apply (rule equalityI) 
   492 apply (rule DPow_subset_Pow) 
   493 apply (erule Finite_Pow_subset_Pow) 
   494 done
   495 
   496 (*This may be true but the proof looks difficult, requiring relativization 
   497 lemma DPow_insert: "DPow (cons(a,A)) = DPow(A) Un {cons(a,X) . X: DPow(A)}"
   498 apply (rule equalityI, safe)
   499 oops
   500 *)
   501 
   502 
   503 subsection{*Internalized formulas for basic concepts*}
   504 
   505 subsubsection{*The subset relation*}
   506 
   507 constdefs subset_fm :: "[i,i]=>i"
   508     "subset_fm(x,y) == Forall(Implies(Member(0,succ(x)), Member(0,succ(y))))"
   509 
   510 lemma subset_type [TC]: "[| x \<in> nat; y \<in> nat |] ==> subset_fm(x,y) \<in> formula"
   511 by (simp add: subset_fm_def) 
   512 
   513 lemma arity_subset_fm [simp]:
   514      "[| x \<in> nat; y \<in> nat |] ==> arity(subset_fm(x,y)) = succ(x) \<union> succ(y)"
   515 by (simp add: subset_fm_def succ_Un_distrib [symmetric]) 
   516 
   517 lemma sats_subset_fm [simp]:
   518    "[|x < length(env); y \<in> nat; env \<in> list(A); Transset(A)|]
   519     ==> sats(A, subset_fm(x,y), env) <-> nth(x,env) \<subseteq> nth(y,env)"
   520 apply (frule lt_length_in_nat, assumption)  
   521 apply (simp add: subset_fm_def Transset_def) 
   522 apply (blast intro: nth_type) 
   523 done
   524 
   525 subsubsection{*Transitive sets*}
   526 
   527 constdefs transset_fm :: "i=>i"
   528    "transset_fm(x) == Forall(Implies(Member(0,succ(x)), subset_fm(0,succ(x))))"
   529 
   530 lemma transset_type [TC]: "x \<in> nat ==> transset_fm(x) \<in> formula"
   531 by (simp add: transset_fm_def) 
   532 
   533 lemma arity_transset_fm [simp]:
   534      "x \<in> nat ==> arity(transset_fm(x)) = succ(x)"
   535 by (simp add: transset_fm_def succ_Un_distrib [symmetric]) 
   536 
   537 lemma sats_transset_fm [simp]:
   538    "[|x < length(env); env \<in> list(A); Transset(A)|]
   539     ==> sats(A, transset_fm(x), env) <-> Transset(nth(x,env))"
   540 apply (frule lt_nat_in_nat, erule length_type) 
   541 apply (simp add: transset_fm_def Transset_def) 
   542 apply (blast intro: nth_type) 
   543 done
   544 
   545 subsubsection{*Ordinals*}
   546 
   547 constdefs ordinal_fm :: "i=>i"
   548    "ordinal_fm(x) == 
   549       And(transset_fm(x), Forall(Implies(Member(0,succ(x)), transset_fm(0))))"
   550 
   551 lemma ordinal_type [TC]: "x \<in> nat ==> ordinal_fm(x) \<in> formula"
   552 by (simp add: ordinal_fm_def) 
   553 
   554 lemma arity_ordinal_fm [simp]:
   555      "x \<in> nat ==> arity(ordinal_fm(x)) = succ(x)"
   556 by (simp add: ordinal_fm_def succ_Un_distrib [symmetric]) 
   557 
   558 lemma sats_ordinal_fm:
   559    "[|x < length(env); env \<in> list(A); Transset(A)|]
   560     ==> sats(A, ordinal_fm(x), env) <-> Ord(nth(x,env))"
   561 apply (frule lt_nat_in_nat, erule length_type) 
   562 apply (simp add: ordinal_fm_def Ord_def Transset_def)
   563 apply (blast intro: nth_type) 
   564 done
   565 
   566 
   567 subsection{* Constant Lset: Levels of the Constructible Universe *}
   568 
   569 constdefs Lset :: "i=>i"
   570     "Lset(i) == transrec(i, %x f. \<Union>y\<in>x. DPow(f`y))"
   571 
   572 text{*NOT SUITABLE FOR REWRITING -- RECURSIVE!*}
   573 lemma Lset: "Lset(i) = (UN j:i. DPow(Lset(j)))"
   574 by (subst Lset_def [THEN def_transrec], simp)
   575 
   576 lemma LsetI: "[|y\<in>x; A \<in> DPow(Lset(y))|] ==> A \<in> Lset(x)";
   577 by (subst Lset, blast)
   578 
   579 lemma LsetD: "A \<in> Lset(x) ==> \<exists>y\<in>x. A \<in> DPow(Lset(y))";
   580 apply (insert Lset [of x]) 
   581 apply (blast intro: elim: equalityE) 
   582 done
   583 
   584 subsubsection{* Transitivity *}
   585 
   586 lemma elem_subset_in_DPow: "[|X \<in> A; X \<subseteq> A|] ==> X \<in> DPow(A)"
   587 apply (simp add: Transset_def DPow_def)
   588 apply (rule_tac x="[X]" in bexI) 
   589  apply (rule_tac x="Member(0,1)" in bexI) 
   590   apply (auto simp add: Un_least_lt_iff) 
   591 done
   592 
   593 lemma Transset_subset_DPow: "Transset(A) ==> A <= DPow(A)"
   594 apply clarify  
   595 apply (simp add: Transset_def)
   596 apply (blast intro: elem_subset_in_DPow) 
   597 done
   598 
   599 lemma Transset_DPow: "Transset(A) ==> Transset(DPow(A))"
   600 apply (simp add: Transset_def) 
   601 apply (blast intro: elem_subset_in_DPow dest: DPowD) 
   602 done
   603 
   604 text{*Kunen's VI, 1.6 (a)*}
   605 lemma Transset_Lset: "Transset(Lset(i))"
   606 apply (rule_tac a=i in eps_induct)
   607 apply (subst Lset)
   608 apply (blast intro!: Transset_Union_family Transset_Un Transset_DPow)
   609 done
   610 
   611 lemma mem_Lset_imp_subset_Lset: "a \<in> Lset(i) ==> a \<subseteq> Lset(i)"
   612 apply (insert Transset_Lset) 
   613 apply (simp add: Transset_def) 
   614 done
   615 
   616 subsubsection{* Monotonicity *}
   617 
   618 text{*Kunen's VI, 1.6 (b)*}
   619 lemma Lset_mono [rule_format]:
   620      "ALL j. i<=j --> Lset(i) <= Lset(j)"
   621 apply (rule_tac a=i in eps_induct)
   622 apply (rule impI [THEN allI])
   623 apply (subst Lset)
   624 apply (subst Lset, blast) 
   625 done
   626 
   627 text{*This version lets us remove the premise @{term "Ord(i)"} sometimes.*}
   628 lemma Lset_mono_mem [rule_format]:
   629      "ALL j. i:j --> Lset(i) <= Lset(j)"
   630 apply (rule_tac a=i in eps_induct)
   631 apply (rule impI [THEN allI])
   632 apply (subst Lset, auto) 
   633 apply (rule rev_bexI, assumption)
   634 apply (blast intro: elem_subset_in_DPow dest: LsetD DPowD) 
   635 done
   636 
   637 text{*Useful with Reflection to bump up the ordinal*}
   638 lemma subset_Lset_ltD: "[|A \<subseteq> Lset(i); i < j|] ==> A \<subseteq> Lset(j)"
   639 by (blast dest: ltD [THEN Lset_mono_mem]) 
   640 
   641 subsubsection{* 0, successor and limit equations fof Lset *}
   642 
   643 lemma Lset_0 [simp]: "Lset(0) = 0"
   644 by (subst Lset, blast)
   645 
   646 lemma Lset_succ_subset1: "DPow(Lset(i)) <= Lset(succ(i))"
   647 by (subst Lset, rule succI1 [THEN RepFunI, THEN Union_upper])
   648 
   649 lemma Lset_succ_subset2: "Lset(succ(i)) <= DPow(Lset(i))"
   650 apply (subst Lset, rule UN_least)
   651 apply (erule succE) 
   652  apply blast 
   653 apply clarify
   654 apply (rule elem_subset_in_DPow)
   655  apply (subst Lset)
   656  apply blast 
   657 apply (blast intro: dest: DPowD Lset_mono_mem) 
   658 done
   659 
   660 lemma Lset_succ: "Lset(succ(i)) = DPow(Lset(i))"
   661 by (intro equalityI Lset_succ_subset1 Lset_succ_subset2) 
   662 
   663 lemma Lset_Union [simp]: "Lset(\<Union>(X)) = (\<Union>y\<in>X. Lset(y))"
   664 apply (subst Lset)
   665 apply (rule equalityI)
   666  txt{*first inclusion*}
   667  apply (rule UN_least)
   668  apply (erule UnionE)
   669  apply (rule subset_trans)
   670   apply (erule_tac [2] UN_upper, subst Lset, erule UN_upper)
   671 txt{*opposite inclusion*}
   672 apply (rule UN_least)
   673 apply (subst Lset, blast)
   674 done
   675 
   676 subsubsection{* Lset applied to Limit ordinals *}
   677 
   678 lemma Limit_Lset_eq:
   679     "Limit(i) ==> Lset(i) = (\<Union>y\<in>i. Lset(y))"
   680 by (simp add: Lset_Union [symmetric] Limit_Union_eq)
   681 
   682 lemma lt_LsetI: "[| a: Lset(j);  j<i |] ==> a : Lset(i)"
   683 by (blast dest: Lset_mono [OF le_imp_subset [OF leI]])
   684 
   685 lemma Limit_LsetE:
   686     "[| a: Lset(i);  ~R ==> Limit(i);
   687         !!x. [| x<i;  a: Lset(x) |] ==> R
   688      |] ==> R"
   689 apply (rule classical)
   690 apply (rule Limit_Lset_eq [THEN equalityD1, THEN subsetD, THEN UN_E])
   691   prefer 2 apply assumption
   692  apply blast 
   693 apply (blast intro: ltI  Limit_is_Ord)
   694 done
   695 
   696 subsubsection{* Basic closure properties *}
   697 
   698 lemma zero_in_Lset: "y:x ==> 0 : Lset(x)"
   699 by (subst Lset, blast intro: empty_in_DPow)
   700 
   701 lemma notin_Lset: "x \<notin> Lset(x)"
   702 apply (rule_tac a=x in eps_induct)
   703 apply (subst Lset)
   704 apply (blast dest: DPowD)  
   705 done
   706 
   707 
   708 subsection{*Constructible Ordinals: Kunen's VI, 1.9 (b)*}
   709 
   710 text{*The subset consisting of the ordinals is definable.*}
   711 lemma Ords_in_DPow: "Transset(A) ==> {x \<in> A. Ord(x)} \<in> DPow(A)"
   712 apply (simp add: DPow_def Collect_subset) 
   713 apply (rule_tac x=Nil in bexI) 
   714  apply (rule_tac x="ordinal_fm(0)" in bexI) 
   715 apply (simp_all add: sats_ordinal_fm)
   716 done 
   717 
   718 lemma Ords_of_Lset_eq: "Ord(i) ==> {x\<in>Lset(i). Ord(x)} = i"
   719 apply (erule trans_induct3)
   720   apply (simp_all add: Lset_succ Limit_Lset_eq Limit_Union_eq)
   721 txt{*The successor case remains.*} 
   722 apply (rule equalityI)
   723 txt{*First inclusion*}
   724  apply clarify  
   725  apply (erule Ord_linear_lt, assumption) 
   726    apply (blast dest: DPow_imp_subset ltD notE [OF notin_Lset]) 
   727   apply blast 
   728  apply (blast dest: ltD)
   729 txt{*Opposite inclusion, @{term "succ(x) \<subseteq> DPow(Lset(x)) \<inter> ON"}*}
   730 apply auto
   731 txt{*Key case: *}
   732   apply (erule subst, rule Ords_in_DPow [OF Transset_Lset]) 
   733  apply (blast intro: elem_subset_in_DPow dest: OrdmemD elim: equalityE) 
   734 apply (blast intro: Ord_in_Ord) 
   735 done
   736 
   737 
   738 lemma Ord_subset_Lset: "Ord(i) ==> i \<subseteq> Lset(i)"
   739 by (subst Ords_of_Lset_eq [symmetric], assumption, fast)
   740 
   741 lemma Ord_in_Lset: "Ord(i) ==> i \<in> Lset(succ(i))"
   742 apply (simp add: Lset_succ)
   743 apply (subst Ords_of_Lset_eq [symmetric], assumption, 
   744        rule Ords_in_DPow [OF Transset_Lset]) 
   745 done
   746 
   747 subsubsection{* Unions *}
   748 
   749 lemma Union_in_Lset:
   750      "X \<in> Lset(j) ==> Union(X) \<in> Lset(succ(j))"
   751 apply (insert Transset_Lset)
   752 apply (rule LsetI [OF succI1])
   753 apply (simp add: Transset_def DPow_def) 
   754 apply (intro conjI, blast)
   755 txt{*Now to create the formula @{term "\<exists>y. y \<in> X \<and> x \<in> y"} *}
   756 apply (rule_tac x="Cons(X,Nil)" in bexI) 
   757  apply (rule_tac x="Exists(And(Member(0,2), Member(1,0)))" in bexI) 
   758   apply typecheck
   759 apply (simp add: succ_Un_distrib [symmetric], blast) 
   760 done
   761 
   762 lemma Union_in_LLimit:
   763      "[| X: Lset(i);  Limit(i) |] ==> Union(X) : Lset(i)"
   764 apply (rule Limit_LsetE, assumption+)
   765 apply (blast intro: Limit_has_succ lt_LsetI Union_in_Lset)
   766 done
   767 
   768 subsubsection{* Finite sets and ordered pairs *}
   769 
   770 lemma singleton_in_Lset: "a: Lset(i) ==> {a} : Lset(succ(i))"
   771 by (simp add: Lset_succ singleton_in_DPow) 
   772 
   773 lemma doubleton_in_Lset:
   774      "[| a: Lset(i);  b: Lset(i) |] ==> {a,b} : Lset(succ(i))"
   775 by (simp add: Lset_succ empty_in_DPow cons_in_DPow) 
   776 
   777 lemma Pair_in_Lset:
   778     "[| a: Lset(i);  b: Lset(i); Ord(i) |] ==> <a,b> : Lset(succ(succ(i)))"
   779 apply (unfold Pair_def)
   780 apply (blast intro: doubleton_in_Lset) 
   781 done
   782 
   783 lemma singleton_in_LLimit:
   784     "[| a: Lset(i);  Limit(i) |] ==> {a} : Lset(i)"
   785 apply (erule Limit_LsetE, assumption)
   786 apply (erule singleton_in_Lset [THEN lt_LsetI])
   787 apply (blast intro: Limit_has_succ) 
   788 done
   789 
   790 lemmas Lset_UnI1 = Un_upper1 [THEN Lset_mono [THEN subsetD], standard]
   791 lemmas Lset_UnI2 = Un_upper2 [THEN Lset_mono [THEN subsetD], standard]
   792 
   793 text{*Hard work is finding a single j:i such that {a,b}<=Lset(j)*}
   794 lemma doubleton_in_LLimit:
   795     "[| a: Lset(i);  b: Lset(i);  Limit(i) |] ==> {a,b} : Lset(i)"
   796 apply (erule Limit_LsetE, assumption)
   797 apply (erule Limit_LsetE, assumption)
   798 apply (blast intro: lt_LsetI [OF doubleton_in_Lset]
   799                     Lset_UnI1 Lset_UnI2 Limit_has_succ Un_least_lt)
   800 done
   801 
   802 lemma Pair_in_LLimit:
   803     "[| a: Lset(i);  b: Lset(i);  Limit(i) |] ==> <a,b> : Lset(i)"
   804 txt{*Infer that a, b occur at ordinals x,xa < i.*}
   805 apply (erule Limit_LsetE, assumption)
   806 apply (erule Limit_LsetE, assumption)
   807 txt{*Infer that succ(succ(x Un xa)) < i *}
   808 apply (blast intro: lt_Ord lt_LsetI [OF Pair_in_Lset]
   809                     Lset_UnI1 Lset_UnI2 Limit_has_succ Un_least_lt)
   810 done
   811 
   812 lemma product_LLimit: "Limit(i) ==> Lset(i) * Lset(i) <= Lset(i)"
   813 by (blast intro: Pair_in_LLimit)
   814 
   815 lemmas Sigma_subset_LLimit = subset_trans [OF Sigma_mono product_LLimit]
   816 
   817 lemma nat_subset_LLimit: "Limit(i) ==> nat \<subseteq> Lset(i)"
   818 by (blast dest: Ord_subset_Lset nat_le_Limit le_imp_subset Limit_is_Ord)
   819 
   820 lemma nat_into_LLimit: "[| n: nat;  Limit(i) |] ==> n : Lset(i)"
   821 by (blast intro: nat_subset_LLimit [THEN subsetD])
   822 
   823 
   824 subsubsection{* Closure under disjoint union *}
   825 
   826 lemmas zero_in_LLimit = Limit_has_0 [THEN ltD, THEN zero_in_Lset, standard]
   827 
   828 lemma one_in_LLimit: "Limit(i) ==> 1 : Lset(i)"
   829 by (blast intro: nat_into_LLimit)
   830 
   831 lemma Inl_in_LLimit:
   832     "[| a: Lset(i); Limit(i) |] ==> Inl(a) : Lset(i)"
   833 apply (unfold Inl_def)
   834 apply (blast intro: zero_in_LLimit Pair_in_LLimit)
   835 done
   836 
   837 lemma Inr_in_LLimit:
   838     "[| b: Lset(i); Limit(i) |] ==> Inr(b) : Lset(i)"
   839 apply (unfold Inr_def)
   840 apply (blast intro: one_in_LLimit Pair_in_LLimit)
   841 done
   842 
   843 lemma sum_LLimit: "Limit(i) ==> Lset(i) + Lset(i) <= Lset(i)"
   844 by (blast intro!: Inl_in_LLimit Inr_in_LLimit)
   845 
   846 lemmas sum_subset_LLimit = subset_trans [OF sum_mono sum_LLimit]
   847 
   848 
   849 text{*The constructible universe and its rank function*}
   850 constdefs
   851   L :: "i=>o" --{*Kunen's definition VI, 1.5, page 167*}
   852     "L(x) == \<exists>i. Ord(i) & x \<in> Lset(i)"
   853   
   854   lrank :: "i=>i" --{*Kunen's definition VI, 1.7*}
   855     "lrank(x) == \<mu>i. x \<in> Lset(succ(i))"
   856 
   857 lemma L_I: "[|x \<in> Lset(i); Ord(i)|] ==> L(x)"
   858 by (simp add: L_def, blast)
   859 
   860 lemma L_D: "L(x) ==> \<exists>i. Ord(i) & x \<in> Lset(i)"
   861 by (simp add: L_def)
   862 
   863 lemma Ord_lrank [simp]: "Ord(lrank(a))"
   864 by (simp add: lrank_def)
   865 
   866 lemma Lset_lrank_lt [rule_format]: "Ord(i) ==> x \<in> Lset(i) --> lrank(x) < i"
   867 apply (erule trans_induct3)
   868   apply simp   
   869  apply (simp only: lrank_def) 
   870  apply (blast intro: Least_le) 
   871 apply (simp_all add: Limit_Lset_eq) 
   872 apply (blast intro: ltI Limit_is_Ord lt_trans) 
   873 done
   874 
   875 text{*Kunen's VI, 1.8, and the proof is much less trivial than the text
   876 would suggest.  For a start it need the previous lemma, proved by induction.*}
   877 lemma Lset_iff_lrank_lt: "Ord(i) ==> x \<in> Lset(i) <-> L(x) & lrank(x) < i"
   878 apply (simp add: L_def, auto) 
   879  apply (blast intro: Lset_lrank_lt) 
   880  apply (unfold lrank_def) 
   881 apply (drule succI1 [THEN Lset_mono_mem, THEN subsetD]) 
   882 apply (drule_tac P="\<lambda>i. x \<in> Lset(succ(i))" in LeastI, assumption) 
   883 apply (blast intro!: le_imp_subset Lset_mono [THEN subsetD]) 
   884 done
   885 
   886 lemma Lset_succ_lrank_iff [simp]: "x \<in> Lset(succ(lrank(x))) <-> L(x)"
   887 by (simp add: Lset_iff_lrank_lt)
   888 
   889 text{*Kunen's VI, 1.9 (a)*}
   890 lemma lrank_of_Ord: "Ord(i) ==> lrank(i) = i"
   891 apply (unfold lrank_def) 
   892 apply (rule Least_equality) 
   893   apply (erule Ord_in_Lset) 
   894  apply assumption
   895 apply (insert notin_Lset [of i]) 
   896 apply (blast intro!: le_imp_subset Lset_mono [THEN subsetD]) 
   897 done
   898 
   899 
   900 lemma Ord_in_L: "Ord(i) ==> L(i)"
   901 by (blast intro: Ord_in_Lset L_I)
   902 
   903 text{*This is lrank(lrank(a)) = lrank(a) *}
   904 declare Ord_lrank [THEN lrank_of_Ord, simp]
   905 
   906 text{*Kunen's VI, 1.10 *}
   907 lemma Lset_in_Lset_succ: "Lset(i) \<in> Lset(succ(i))";
   908 apply (simp add: Lset_succ DPow_def) 
   909 apply (rule_tac x=Nil in bexI) 
   910  apply (rule_tac x="Equal(0,0)" in bexI) 
   911 apply auto 
   912 done
   913 
   914 lemma lrank_Lset: "Ord(i) ==> lrank(Lset(i)) = i"
   915 apply (unfold lrank_def) 
   916 apply (rule Least_equality) 
   917   apply (rule Lset_in_Lset_succ) 
   918  apply assumption
   919 apply clarify 
   920 apply (subgoal_tac "Lset(succ(ia)) <= Lset(i)")
   921  apply (blast dest: mem_irrefl) 
   922 apply (blast intro!: le_imp_subset Lset_mono) 
   923 done
   924 
   925 text{*Kunen's VI, 1.11 *}
   926 lemma Lset_subset_Vset: "Ord(i) ==> Lset(i) <= Vset(i)";
   927 apply (erule trans_induct)
   928 apply (subst Lset) 
   929 apply (subst Vset) 
   930 apply (rule UN_mono [OF subset_refl]) 
   931 apply (rule subset_trans [OF DPow_subset_Pow]) 
   932 apply (rule Pow_mono, blast) 
   933 done
   934 
   935 text{*Kunen's VI, 1.12 *}
   936 lemma Lset_subset_Vset': "i \<in> nat ==> Lset(i) = Vset(i)";
   937 apply (erule nat_induct)
   938  apply (simp add: Vfrom_0) 
   939 apply (simp add: Lset_succ Vset_succ Finite_Vset Finite_DPow_eq_Pow) 
   940 done
   941 
   942 text{*Every set of constructible sets is included in some @{term Lset}*} 
   943 lemma subset_Lset:
   944      "(\<forall>x\<in>A. L(x)) ==> \<exists>i. Ord(i) & A \<subseteq> Lset(i)"
   945 by (rule_tac x = "\<Union>x\<in>A. succ(lrank(x))" in exI, force)
   946 
   947 lemma subset_LsetE:
   948      "[|\<forall>x\<in>A. L(x);
   949         !!i. [|Ord(i); A \<subseteq> Lset(i)|] ==> P|]
   950       ==> P"
   951 by (blast dest: subset_Lset) 
   952 
   953 subsection{*For L to satisfy the ZF axioms*}
   954 
   955 theorem Union_in_L: "L(X) ==> L(Union(X))"
   956 apply (simp add: L_def, clarify) 
   957 apply (drule Ord_imp_greater_Limit) 
   958 apply (blast intro: lt_LsetI Union_in_LLimit Limit_is_Ord) 
   959 done
   960 
   961 theorem doubleton_in_L: "[| L(a); L(b) |] ==> L({a, b})"
   962 apply (simp add: L_def, clarify) 
   963 apply (drule Ord2_imp_greater_Limit, assumption) 
   964 apply (blast intro: lt_LsetI doubleton_in_LLimit Limit_is_Ord) 
   965 done
   966 
   967 subsubsection{*For L to satisfy Powerset *}
   968 
   969 lemma LPow_env_typing:
   970     "[| y : Lset(i); Ord(i); y \<subseteq> X |] 
   971      ==> \<exists>z \<in> Pow(X). y \<in> Lset(succ(lrank(z)))"
   972 by (auto intro: L_I iff: Lset_succ_lrank_iff) 
   973 
   974 lemma LPow_in_Lset:
   975      "[|X \<in> Lset(i); Ord(i)|] ==> \<exists>j. Ord(j) & {y \<in> Pow(X). L(y)} \<in> Lset(j)"
   976 apply (rule_tac x="succ(\<Union>y \<in> Pow(X). succ(lrank(y)))" in exI)
   977 apply simp 
   978 apply (rule LsetI [OF succI1])
   979 apply (simp add: DPow_def) 
   980 apply (intro conjI, clarify) 
   981  apply (rule_tac a=x in UN_I, simp+)  
   982 txt{*Now to create the formula @{term "y \<subseteq> X"} *}
   983 apply (rule_tac x="Cons(X,Nil)" in bexI) 
   984  apply (rule_tac x="subset_fm(0,1)" in bexI) 
   985   apply typecheck
   986  apply (rule conjI) 
   987 apply (simp add: succ_Un_distrib [symmetric]) 
   988 apply (rule equality_iffI) 
   989 apply (simp add: Transset_UN [OF Transset_Lset] LPow_env_typing)
   990 apply (auto intro: L_I iff: Lset_succ_lrank_iff) 
   991 done
   992 
   993 theorem LPow_in_L: "L(X) ==> L({y \<in> Pow(X). L(y)})"
   994 by (blast intro: L_I dest: L_D LPow_in_Lset)
   995 
   996 
   997 subsection{*Eliminating @{term arity} from the Definition of @{term Lset}*}
   998 
   999 
  1000 lemma nth_zero_eq_0: "n \<in> nat ==> nth(n,[0]) = 0"
  1001 by (induct_tac n, auto)
  1002 
  1003 lemma sats_app_0_iff [rule_format]:
  1004   "[| p \<in> formula; 0 \<in> A |]
  1005    ==> \<forall>env \<in> list(A). sats(A,p, env@[0]) <-> sats(A,p,env)"
  1006 apply (induct_tac p)
  1007 apply (simp_all del: app_Cons add: app_Cons [symmetric]
  1008 		add: nth_zero_eq_0 nth_append not_lt_iff_le nth_eq_0)
  1009 done
  1010 
  1011 lemma sats_app_zeroes_iff:
  1012   "[| p \<in> formula; 0 \<in> A; env \<in> list(A); n \<in> nat |]
  1013    ==> sats(A,p,env @ repeat(0,n)) <-> sats(A,p,env)"
  1014 apply (induct_tac n, simp) 
  1015 apply (simp del: repeat.simps
  1016             add: repeat_succ_app sats_app_0_iff app_assoc [symmetric]) 
  1017 done
  1018 
  1019 lemma exists_bigger_env:
  1020   "[| p \<in> formula; 0 \<in> A; env \<in> list(A) |]
  1021    ==> \<exists>env' \<in> list(A). arity(p) \<le> succ(length(env')) & 
  1022               (\<forall>a\<in>A. sats(A,p,Cons(a,env')) <-> sats(A,p,Cons(a,env)))"
  1023 apply (rule_tac x="env @ repeat(0,arity(p))" in bexI) 
  1024 apply (simp del: app_Cons add: app_Cons [symmetric]
  1025 	    add: length_repeat sats_app_zeroes_iff, typecheck)
  1026 done
  1027 
  1028 
  1029 text{*A simpler version of @{term DPow}: no arity check!*}
  1030 constdefs DPow' :: "i => i"
  1031   "DPow'(A) == {X \<in> Pow(A). 
  1032                 \<exists>env \<in> list(A). \<exists>p \<in> formula. 
  1033                     X = {x\<in>A. sats(A, p, Cons(x,env))}}"
  1034 
  1035 lemma DPow_subset_DPow': "DPow(A) <= DPow'(A)";
  1036 by (simp add: DPow_def DPow'_def, blast)
  1037 
  1038 lemma DPow'_0: "DPow'(0) = {0}"
  1039 by (auto simp add: DPow'_def)
  1040 
  1041 lemma DPow'_subset_DPow: "0 \<in> A ==> DPow'(A) \<subseteq> DPow(A)"
  1042 apply (auto simp add: DPow'_def DPow_def) 
  1043 apply (frule exists_bigger_env, assumption+, force)  
  1044 done
  1045 
  1046 lemma DPow_eq_DPow': "Transset(A) ==> DPow(A) = DPow'(A)"
  1047 apply (drule Transset_0_disj) 
  1048 apply (erule disjE) 
  1049  apply (simp add: DPow'_0 DPow_0) 
  1050 apply (rule equalityI)
  1051  apply (rule DPow_subset_DPow') 
  1052 apply (erule DPow'_subset_DPow) 
  1053 done
  1054 
  1055 text{*And thus we can relativize @{term Lset} without bothering with
  1056       @{term arity} and @{term length}*}
  1057 lemma Lset_eq_transrec_DPow': "Lset(i) = transrec(i, %x f. \<Union>y\<in>x. DPow'(f`y))"
  1058 apply (rule_tac a=i in eps_induct)
  1059 apply (subst Lset)
  1060 apply (subst transrec)
  1061 apply (simp only: DPow_eq_DPow' [OF Transset_Lset], simp) 
  1062 done
  1063 
  1064 text{*With this rule we can specify @{term p} later and don't worry about
  1065       arities at all!*}
  1066 lemma DPow_LsetI [rule_format]:
  1067   "[|\<forall>x\<in>Lset(i). P(x) <-> sats(Lset(i), p, Cons(x,env));
  1068      env \<in> list(Lset(i));  p \<in> formula|]
  1069    ==> {x\<in>Lset(i). P(x)} \<in> DPow(Lset(i))"
  1070 by (simp add: DPow_eq_DPow' [OF Transset_Lset] DPow'_def, blast) 
  1071 
  1072 end