src/Pure/library.ML
author paulson
Tue May 20 11:53:20 1997 +0200 (1997-05-20)
changeset 3246 7f783705c7a4
parent 3063 963e3bf01799
child 3365 86c0d1988622
permissions -rw-r--r--
Declares Option_ as synonym for structure Option
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic tables, balanced trees,
     8 orders, input / output, timing, filenames, misc functions.
     9 *)
    10 
    11 infix |> ~~ \ \\ orelf ins ins_string ins_int orf andf prefix upto downto
    12       mem mem_int mem_string union union_int union_string  
    13       inter inter_int inter_string subset subset_int subset_string subdir_of;
    14 
    15 
    16 structure Library =
    17 struct
    18 
    19 (** functions **)
    20 
    21 (*handy combinators*)
    22 fun curry f x y = f (x, y);
    23 fun uncurry f (x, y) = f x y;
    24 fun I x = x;
    25 fun K x y = x;
    26 
    27 (*reverse apply*)
    28 fun (x |> f) = f x;
    29 
    30 (*combine two functions forming the union of their domains*)
    31 fun (f orelf g) = fn x => f x handle Match => g x;
    32 
    33 (*application of (infix) operator to its left or right argument*)
    34 fun apl (x, f) y = f (x, y);
    35 fun apr (f, y) x = f (x, y);
    36 
    37 (*functional for pairs*)
    38 fun pairself f (x, y) = (f x, f y);
    39 
    40 (*function exponentiation: f(...(f x)...) with n applications of f*)
    41 fun funpow n f x =
    42   let fun rep (0, x) = x
    43         | rep (n, x) = rep (n - 1, f x)
    44   in rep (n, x) end;
    45 
    46 
    47 
    48 (** stamps **)
    49 
    50 type stamp = unit ref;
    51 val stamp: unit -> stamp = ref;
    52 
    53 
    54 
    55 (** options **)
    56 
    57 datatype 'a option = None | Some of 'a;
    58 
    59 exception OPTION of string;
    60 
    61 fun the (Some x) = x
    62   | the None = raise OPTION "the";
    63 
    64 fun if_none None y = y
    65   | if_none (Some x) _ = x;
    66 
    67 fun is_some (Some _) = true
    68   | is_some None = false;
    69 
    70 fun is_none (Some _) = false
    71   | is_none None = true;
    72 
    73 fun apsome f (Some x) = Some (f x)
    74   | apsome _ None = None;
    75 
    76 
    77 
    78 (** pairs **)
    79 
    80 fun pair x y = (x, y);
    81 fun rpair x y = (y, x);
    82 
    83 fun fst (x, y) = x;
    84 fun snd (x, y) = y;
    85 
    86 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
    87 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
    88 
    89 fun swap (x, y) = (y, x);
    90 
    91 (*apply the function to a component of a pair*)
    92 fun apfst f (x, y) = (f x, y);
    93 fun apsnd f (x, y) = (x, f y);
    94 
    95 
    96 
    97 (** booleans **)
    98 
    99 (* equality *)
   100 
   101 fun equal x y = x = y;
   102 fun not_equal x y = x <> y;
   103 
   104 
   105 (* operators for combining predicates *)
   106 
   107 fun (p orf q) = fn x => p x orelse q x;
   108 
   109 fun (p andf q) = fn x => p x andalso q x;
   110 
   111 fun notf p x = not (p x);
   112 
   113 
   114 (* predicates on lists *)
   115 
   116 fun orl [] = false
   117   | orl (x :: xs) = x orelse orl xs;
   118 
   119 fun andl [] = true
   120   | andl (x :: xs) = x andalso andl xs;
   121 
   122 (*Several object-logics declare theories named List or Option, hiding the
   123   eponymous basis library structures.*)
   124 structure List_ = List
   125 and       Option_ = Option;
   126 
   127 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   128 fun exists (pred: 'a -> bool) : 'a list -> bool =
   129   let fun boolf [] = false
   130         | boolf (x :: xs) = pred x orelse boolf xs
   131   in boolf end;
   132 
   133 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   134 fun forall (pred: 'a -> bool) : 'a list -> bool =
   135   let fun boolf [] = true
   136         | boolf (x :: xs) = pred x andalso boolf xs
   137   in boolf end;
   138 
   139 
   140 (* flags *)
   141 
   142 fun set flag = (flag := true; true);
   143 fun reset flag = (flag := false; false);
   144 fun toggle flag = (flag := not (! flag); ! flag);
   145 
   146 fun setmp flag value f x =
   147   let
   148     val orig_value = ! flag;
   149     fun return y = (flag := orig_value; y);
   150   in
   151     flag := value;
   152     return (f x handle exn => (return (); raise exn))
   153   end;
   154 
   155 
   156 
   157 (** lists **)
   158 
   159 exception LIST of string;
   160 
   161 fun null [] = true
   162   | null (_ :: _) = false;
   163 
   164 fun hd [] = raise LIST "hd"
   165   | hd (x :: _) = x;
   166 
   167 fun tl [] = raise LIST "tl"
   168   | tl (_ :: xs) = xs;
   169 
   170 fun cons x xs = x :: xs;
   171 
   172 
   173 (* fold *)
   174 
   175 (*the following versions of fold are designed to fit nicely with infixes*)
   176 
   177 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   178     for operators that associate to the left (TAIL RECURSIVE)*)
   179 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   180   let fun itl (e, [])  = e
   181         | itl (e, a::l) = itl (f(e, a), l)
   182   in  itl end;
   183 
   184 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   185     for operators that associate to the right (not tail recursive)*)
   186 fun foldr f (l, e) =
   187   let fun itr [] = e
   188         | itr (a::l) = f(a, itr l)
   189   in  itr l  end;
   190 
   191 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   192     for n > 0, operators that associate to the right (not tail recursive)*)
   193 fun foldr1 f l =
   194   let fun itr [x] = x                       (* FIXME [] case: elim warn (?) *)
   195         | itr (x::l) = f(x, itr l)
   196   in  itr l  end;
   197 
   198 
   199 (* basic list functions *)
   200 
   201 (*length of a list, should unquestionably be a standard function*)
   202 local fun length1 (n, [])  = n   (*TAIL RECURSIVE*)
   203         | length1 (n, x :: xs) = length1 (n + 1, xs)
   204 in  fun length l = length1 (0, l) end;
   205 
   206 (*take the first n elements from a list*)
   207 fun take (n, []) = []
   208   | take (n, x :: xs) =
   209       if n > 0 then x :: take (n - 1, xs) else [];
   210 
   211 (*drop the first n elements from a list*)
   212 fun drop (n, []) = []
   213   | drop (n, x :: xs) =
   214       if n > 0 then drop (n - 1, xs) else x :: xs;
   215 
   216 (*return nth element of a list, where 0 designates the first element;
   217   raise EXCEPTION if list too short*)
   218 fun nth_elem NL =
   219   (case drop NL of
   220     [] => raise LIST "nth_elem"
   221   | x :: _ => x);
   222 
   223 (*last element of a list*)
   224 fun last_elem [] = raise LIST "last_elem"
   225   | last_elem [x] = x
   226   | last_elem (_ :: xs) = last_elem xs;
   227 
   228 (*find the position of an element in a list*)
   229 fun find (x, ys) =
   230   let fun f (y :: ys, i) = if x = y then i else f (ys, i + 1)
   231         | f (_, _) = raise LIST "find"
   232   in f (ys, 0) end;
   233 
   234 (*flatten a list of lists to a list*)
   235 fun flat (ls: 'c list list) : 'c list = foldr (op @) (ls, []);
   236 
   237 
   238 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   239   (proc x1; ...; proc xn) for side effects*)
   240 fun seq (proc: 'a -> unit) : 'a list -> unit =
   241   let fun seqf [] = ()
   242         | seqf (x :: xs) = (proc x; seqf xs)
   243   in seqf end;
   244 
   245 
   246 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   247 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   248   | separate _ xs = xs;
   249 
   250 (*make the list [x, x, ..., x] of length n*)
   251 fun replicate n (x: 'a) : 'a list =
   252   let fun rep (0, xs) = xs
   253         | rep (n, xs) = rep (n - 1, x :: xs)
   254   in
   255     if n < 0 then raise LIST "replicate"
   256     else rep (n, [])
   257   end;
   258 
   259 
   260 (* filter *)
   261 
   262 (*copy the list preserving elements that satisfy the predicate*)
   263 fun filter (pred: 'a->bool) : 'a list -> 'a list =
   264   let fun filt [] = []
   265         | filt (x :: xs) = if pred x then x :: filt xs else filt xs
   266   in filt end;
   267 
   268 fun filter_out f = filter (not o f);
   269 
   270 
   271 fun mapfilter (f: 'a -> 'b option) ([]: 'a list) = [] : 'b list
   272   | mapfilter f (x :: xs) =
   273       (case f x of
   274         None => mapfilter f xs
   275       | Some y => y :: mapfilter f xs);
   276 
   277 
   278 fun find_first _ [] = None
   279   | find_first pred (x :: xs) =
   280       if pred x then Some x else find_first pred xs;
   281 
   282 
   283 (* lists of pairs *)
   284 
   285 fun map2 _ ([], []) = []
   286   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   287   | map2 _ _ = raise LIST "map2";
   288 
   289 fun exists2 _ ([], []) = false
   290   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   291   | exists2 _ _ = raise LIST "exists2";
   292 
   293 fun forall2 _ ([], []) = true
   294   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   295   | forall2 _ _ = raise LIST "forall2";
   296 
   297 (*combine two lists forming a list of pairs:
   298   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   299 fun [] ~~ [] = []
   300   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   301   | _ ~~ _ = raise LIST "~~";
   302 
   303 
   304 (*inverse of ~~; the old 'split':
   305   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   306 fun split_list (l: ('a * 'b) list) = (map #1 l, map #2 l);
   307 
   308 
   309 (* prefixes, suffixes *)
   310 
   311 fun [] prefix _ = true
   312   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   313   | _ prefix _ = false;
   314 
   315 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   316    where xi is the first element that does not satisfy the predicate*)
   317 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   318   let fun take (rxs, []) = (rev rxs, [])
   319         | take (rxs, x :: xs) =
   320             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   321   in  take([], xs)  end;
   322 
   323 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   324    where xi is the last element that does not satisfy the predicate*)
   325 fun take_suffix _ [] = ([], [])
   326   | take_suffix pred (x :: xs) =
   327       (case take_suffix pred xs of
   328         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   329       | (prfx, sffx) => (x :: prfx, sffx));
   330 
   331 
   332 
   333 (** integers **)
   334 
   335 fun inc i = (i := ! i + 1; ! i);
   336 fun dec i = (i := ! i - 1; ! i);
   337 
   338 
   339 (* lists of integers *)
   340 
   341 (*make the list [from, from + 1, ..., to]*)
   342 fun (from upto to) =
   343   if from > to then [] else from :: ((from + 1) upto to);
   344 
   345 (*make the list [from, from - 1, ..., to]*)
   346 fun (from downto to) =
   347   if from < to then [] else from :: ((from - 1) downto to);
   348 
   349 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   350 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   351   | downto0 ([], n) = n = ~1;
   352 
   353 
   354 (* convert integers to strings *)
   355 
   356 (*expand the number in the given base;
   357   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   358 fun radixpand (base, num) : int list =
   359   let
   360     fun radix (n, tail) =
   361       if n < base then n :: tail
   362       else radix (n div base, (n mod base) :: tail)
   363   in radix (num, []) end;
   364 
   365 (*expands a number into a string of characters starting from "zerochar";
   366   example: radixstring (2, "0", 8) gives "1000"*)
   367 fun radixstring (base, zerochar, num) =
   368   let val offset = ord zerochar;
   369       fun chrof n = chr (offset + n)
   370   in implode (map chrof (radixpand (base, num))) end;
   371 
   372 
   373 fun string_of_int n =
   374   if n < 0 then "~" ^ radixstring (10, "0", ~n) else radixstring (10, "0", n);
   375 
   376 
   377 
   378 (** strings **)
   379 
   380 fun is_letter ch =
   381   ord "A" <= ord ch andalso ord ch <= ord "Z" orelse
   382   ord "a" <= ord ch andalso ord ch <= ord "z";
   383 
   384 fun is_digit ch =
   385   ord "0" <= ord ch andalso ord ch <= ord "9";
   386 
   387 (*letter or _ or prime (')*)
   388 fun is_quasi_letter "_" = true
   389   | is_quasi_letter "'" = true
   390   | is_quasi_letter ch = is_letter ch;
   391 
   392 (*white space: blanks, tabs, newlines, formfeeds*)
   393 val is_blank : string -> bool =
   394   fn " " => true | "\t" => true | "\n" => true | "\^L" => true | "160" => true
   395     | _ => false;
   396 
   397 val is_letdig = is_quasi_letter orf is_digit;
   398 
   399 (*printable chars*)
   400 fun is_printable c = ord c > ord " " andalso ord c <= ord "~";
   401 
   402 
   403 (*lower all chars of string*)
   404 val to_lower =
   405   let
   406     fun lower ch =
   407       if ch >= "A" andalso ch <= "Z" then
   408         chr (ord ch - ord "A" + ord "a")
   409       else ch;
   410   in implode o (map lower) o explode end;
   411 
   412 
   413 (*enclose in brackets*)
   414 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   415 
   416 (*simple quoting (does not escape special chars)*)
   417 val quote = enclose "\"" "\"";
   418 
   419 (*space_implode "..." (explode "hello"); gives "h...e...l...l...o"*)
   420 fun space_implode a bs = implode (separate a bs);
   421 
   422 val commas = space_implode ", ";
   423 val commas_quote = commas o map quote;
   424 
   425 (*concatenate messages, one per line, into a string*)
   426 val cat_lines = space_implode "\n";
   427 
   428 (*space_explode "." "h.e..l.lo"; gives ["h", "e", "l", "lo"]*)
   429 fun space_explode sep s =
   430   let fun divide [] "" = []
   431         | divide [] part = [part]
   432         | divide (c::s) part =
   433             if c = sep then
   434               (if part = "" then divide s "" else part :: divide s "")
   435             else divide s (part ^ c)
   436   in divide (explode s) "" end;
   437 
   438 
   439 (** lists as sets **)
   440 
   441 (*membership in a list*)
   442 fun x mem [] = false
   443   | x mem (y :: ys) = x = y orelse x mem ys;
   444 
   445 (*membership in a list, optimized version for ints*)
   446 fun (x:int) mem_int [] = false
   447   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   448 
   449 (*membership in a list, optimized version for strings*)
   450 fun (x:string) mem_string [] = false
   451   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   452 
   453 (*generalized membership test*)
   454 fun gen_mem eq (x, []) = false
   455   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   456 
   457 
   458 (*insertion into list if not already there*)
   459 fun (x ins xs) = if x mem xs then xs else x :: xs;
   460 
   461 (*insertion into list, optimized version for ints*)
   462 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   463 
   464 (*insertion into list, optimized version for strings*)
   465 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   466 
   467 (*generalized insertion*)
   468 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   469 
   470 
   471 (*union of sets represented as lists: no repetitions*)
   472 fun xs union [] = xs
   473   | [] union ys = ys
   474   | (x :: xs) union ys = xs union (x ins ys);
   475 
   476 (*union of sets, optimized version for ints*)
   477 fun (xs:int list) union_int [] = xs
   478   | [] union_int ys = ys
   479   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   480 
   481 (*union of sets, optimized version for strings*)
   482 fun (xs:string list) union_string [] = xs
   483   | [] union_string ys = ys
   484   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   485 
   486 (*generalized union*)
   487 fun gen_union eq (xs, []) = xs
   488   | gen_union eq ([], ys) = ys
   489   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   490 
   491 
   492 (*intersection*)
   493 fun [] inter ys = []
   494   | (x :: xs) inter ys =
   495       if x mem ys then x :: (xs inter ys) else xs inter ys;
   496 
   497 (*intersection, optimized version for ints*)
   498 fun ([]:int list) inter_int ys = []
   499   | (x :: xs) inter_int ys =
   500       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   501 
   502 (*intersection, optimized version for strings *)
   503 fun ([]:string list) inter_string ys = []
   504   | (x :: xs) inter_string ys =
   505       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   506 
   507 
   508 (*subset*)
   509 fun [] subset ys = true
   510   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   511 
   512 (*subset, optimized version for ints*)
   513 fun ([]:int list) subset_int ys = true
   514   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   515 
   516 (*subset, optimized version for strings*)
   517 fun ([]:string list) subset_string ys = true
   518   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   519 
   520 (*set equality for strings*)
   521 fun eq_set_string ((xs:string list), ys) =
   522   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   523 
   524 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   525 
   526 
   527 (*removing an element from a list WITHOUT duplicates*)
   528 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   529   | [] \ x = [];
   530 
   531 fun ys \\ xs = foldl (op \) (ys,xs);
   532 
   533 (*removing an element from a list -- possibly WITH duplicates*)
   534 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   535 
   536 fun gen_rems eq = foldl (gen_rem eq);
   537 
   538 
   539 (*makes a list of the distinct members of the input; preserves order, takes
   540   first of equal elements*)
   541 fun gen_distinct eq lst =
   542   let
   543     val memb = gen_mem eq;
   544 
   545     fun dist (rev_seen, []) = rev rev_seen
   546       | dist (rev_seen, x :: xs) =
   547           if memb (x, rev_seen) then dist (rev_seen, xs)
   548           else dist (x :: rev_seen, xs);
   549   in
   550     dist ([], lst)
   551   end;
   552 
   553 fun distinct l = gen_distinct (op =) l;
   554 
   555 
   556 (*returns the tail beginning with the first repeated element, or []*)
   557 fun findrep [] = []
   558   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   559 
   560 
   561 (*returns a list containing all repeated elements exactly once; preserves
   562   order, takes first of equal elements*)
   563 fun gen_duplicates eq lst =
   564   let
   565     val memb = gen_mem eq;
   566 
   567     fun dups (rev_dups, []) = rev rev_dups
   568       | dups (rev_dups, x :: xs) =
   569           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   570             dups (rev_dups, xs)
   571           else dups (x :: rev_dups, xs);
   572   in
   573     dups ([], lst)
   574   end;
   575 
   576 fun duplicates l = gen_duplicates (op =) l;
   577 
   578 
   579 
   580 (** association lists **)
   581 
   582 (*association list lookup*)
   583 fun assoc ([], key) = None
   584   | assoc ((keyi, xi) :: pairs, key) =
   585       if key = keyi then Some xi else assoc (pairs, key);
   586 
   587 (*association list lookup, optimized version for ints*)
   588 fun assoc_int ([], (key:int)) = None
   589   | assoc_int ((keyi, xi) :: pairs, key) =
   590       if key = keyi then Some xi else assoc_int (pairs, key);
   591 
   592 (*association list lookup, optimized version for strings*)
   593 fun assoc_string ([], (key:string)) = None
   594   | assoc_string ((keyi, xi) :: pairs, key) =
   595       if key = keyi then Some xi else assoc_string (pairs, key);
   596 
   597 (*association list lookup, optimized version for string*ints*)
   598 fun assoc_string_int ([], (key:string*int)) = None
   599   | assoc_string_int ((keyi, xi) :: pairs, key) =
   600       if key = keyi then Some xi else assoc_string_int (pairs, key);
   601 
   602 fun assocs ps x =
   603   (case assoc (ps, x) of
   604     None => []
   605   | Some ys => ys);
   606 
   607 (*two-fold association list lookup*)
   608 fun assoc2 (aal, (key1, key2)) =
   609   (case assoc (aal, key1) of
   610     Some al => assoc (al, key2)
   611   | None => None);
   612 
   613 (*generalized association list lookup*)
   614 fun gen_assoc eq ([], key) = None
   615   | gen_assoc eq ((keyi, xi) :: pairs, key) =
   616       if eq (key, keyi) then Some xi else gen_assoc eq (pairs, key);
   617 
   618 (*association list update*)
   619 fun overwrite (al, p as (key, _)) =
   620   let fun over ((q as (keyi, _)) :: pairs) =
   621             if keyi = key then p :: pairs else q :: (over pairs)
   622         | over [] = [p]
   623   in over al end;
   624 
   625 fun gen_overwrite eq (al, p as (key, _)) =
   626   let fun over ((q as (keyi, _)) :: pairs) =
   627             if eq (keyi, key) then p :: pairs else q :: (over pairs)
   628         | over [] = [p]
   629   in over al end;
   630 
   631 
   632 
   633 (** generic tables **)
   634 
   635 (*Tables are supposed to be 'efficient' encodings of lists of elements distinct
   636   wrt. an equality "eq". The extend and merge operations below are optimized
   637   for long-term space efficiency.*)
   638 
   639 (*append (new) elements to a table*)
   640 fun generic_extend _ _ _ tab [] = tab
   641   | generic_extend eq dest_tab mk_tab tab1 lst2 =
   642       let
   643         val lst1 = dest_tab tab1;
   644         val new_lst2 = gen_rems eq (lst2, lst1);
   645       in
   646         if null new_lst2 then tab1
   647         else mk_tab (lst1 @ new_lst2)
   648       end;
   649 
   650 (*append (new) elements of 2nd table to 1st table*)
   651 fun generic_merge eq dest_tab mk_tab tab1 tab2 =
   652   let
   653     val lst1 = dest_tab tab1;
   654     val lst2 = dest_tab tab2;
   655     val new_lst2 = gen_rems eq (lst2, lst1);
   656   in
   657     if null new_lst2 then tab1
   658     else if gen_subset eq (lst1, lst2) then tab2
   659     else mk_tab (lst1 @ new_lst2)
   660   end;
   661 
   662 
   663 (*lists as tables*)
   664 fun extend_list tab = generic_extend (op =) I I tab;
   665 fun merge_lists tab = generic_merge (op =) I I tab;
   666 
   667 fun merge_rev_lists xs [] = xs
   668   | merge_rev_lists [] ys = ys
   669   | merge_rev_lists xs (y :: ys) =
   670       (if y mem xs then I else cons y) (merge_rev_lists xs ys);
   671 
   672 
   673 
   674 (** balanced trees **)
   675 
   676 exception Balance;      (*indicates non-positive argument to balancing fun*)
   677 
   678 (*balanced folding; avoids deep nesting*)
   679 fun fold_bal f [x] = x
   680   | fold_bal f [] = raise Balance
   681   | fold_bal f xs =
   682       let val k = length xs div 2
   683       in  f (fold_bal f (take(k, xs)),
   684              fold_bal f (drop(k, xs)))
   685       end;
   686 
   687 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   688 fun access_bal (f, g, x) n i =
   689   let fun acc n i =     (*1<=i<=n*)
   690           if n=1 then x else
   691           let val n2 = n div 2
   692           in  if i<=n2 then f (acc n2 i)
   693                        else g (acc (n-n2) (i-n2))
   694           end
   695   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   696 
   697 (*construct ALL such accesses; could try harder to share recursive calls!*)
   698 fun accesses_bal (f, g, x) n =
   699   let fun acc n =
   700           if n=1 then [x] else
   701           let val n2 = n div 2
   702               val acc2 = acc n2
   703           in  if n-n2=n2 then map f acc2 @ map g acc2
   704                          else map f acc2 @ map g (acc (n-n2)) end
   705   in  if 1<=n then acc n else raise Balance  end;
   706 
   707 
   708 
   709 (** orders **)
   710 
   711 datatype order = LESS | EQUAL | GREATER;
   712 
   713 fun intord (i, j: int) =
   714   if i < j then LESS
   715   else if i = j then EQUAL
   716   else GREATER;
   717 
   718 fun stringord (a, b: string) =
   719   if a < b then LESS
   720   else if a = b then EQUAL
   721   else GREATER;
   722 
   723 
   724 
   725 (** input / output **)
   726 
   727 val cd = OS.FileSys.chDir;
   728 val pwd = OS.FileSys.getDir;
   729 
   730 val prs_fn = ref(fn s => TextIO.output (TextIO.stdOut, s));
   731 
   732 fun prs s = !prs_fn s;
   733 fun writeln s = prs (s ^ "\n");
   734 
   735 (* TextIO.output to LaTeX / xdvi *)
   736 fun latex s = 
   737         execute ( "( cd /tmp ; echo \"" ^ s ^
   738         "\" | isa2latex -s > $$.tex ; latex $$.tex ; xdvi $$.dvi ; rm $$.* ) > /dev/null &" ) ;
   739 
   740 (*print warning*)
   741 val warning_fn = ref(fn s => TextIO.output (TextIO.stdOut, s ^ "\n"));
   742 fun warning s = !warning_fn ("Warning: " ^ s);
   743 
   744 (*print error message and abort to top level*)
   745 
   746 val error_fn = ref(fn s => TextIO.output 
   747 		            (TextIO.stdOut, "\n*** " ^ s ^ "\n\n"));
   748 
   749 exception ERROR;
   750 fun error msg = (!error_fn msg; raise ERROR);
   751 fun sys_error msg = (!error_fn "*** SYSTEM ERROR ***"; error msg);
   752 
   753 fun assert p msg = if p then () else error msg;
   754 fun deny p msg = if p then error msg else ();
   755 
   756 (*Assert pred for every member of l, generating a message if pred fails*)
   757 fun assert_all pred l msg_fn = 
   758   let fun asl [] = ()
   759         | asl (x::xs) = if pred x then asl xs
   760                         else error (msg_fn x)
   761   in  asl l  end;
   762 
   763 (*for the "test" target in Makefiles -- signifies successful termination*)
   764 fun maketest msg =
   765   (writeln msg; 
   766    let val os = TextIO.openOut "test" 
   767    in  TextIO.output (os, "Test examples ran successfully\n");
   768        TextIO.closeOut os
   769    end);
   770 
   771 
   772 (*print a list surrounded by the brackets lpar and rpar, with comma separator
   773   print nothing for empty list*)
   774 fun print_list (lpar, rpar, pre: 'a -> unit) (l : 'a list) =
   775   let fun prec x = (prs ","; pre x)
   776   in
   777     (case l of
   778       [] => ()
   779     | x::l => (prs lpar; pre x; seq prec l; prs rpar))
   780   end;
   781 
   782 (*print a list of items separated by newlines*)
   783 fun print_list_ln (pre: 'a -> unit) : 'a list -> unit =
   784   seq (fn x => (pre x; writeln ""));
   785 
   786 
   787 val print_int = prs o string_of_int;
   788 
   789 
   790 
   791 (** timing **)
   792 
   793 (*unconditional timing function*)
   794 fun timeit x = cond_timeit true x;
   795 
   796 (*timed application function*)
   797 fun timeap f x = timeit (fn () => f x);
   798 
   799 (*timed "use" function, printing filenames*)
   800 fun time_use fname = timeit (fn () =>
   801   (writeln ("\n**** Starting " ^ fname ^ " ****"); use fname;
   802    writeln ("\n**** Finished " ^ fname ^ " ****")));
   803 
   804 (*For Makefiles: use the file, but exit with error code if errors found.*)
   805 fun exit_use fname = use fname handle _ => exit 1;
   806 
   807 
   808 (** filenames and paths **)
   809 
   810 (*Convert UNIX filename of the form "path/file" to "path/" and "file";
   811   if filename contains no slash, then it returns "" and "file"*)
   812 val split_filename =
   813   (pairself implode) o take_suffix (not_equal "/") o explode;
   814 
   815 val base_name = #2 o split_filename;
   816 
   817 (*Merge splitted filename (path and file);
   818   if path does not end with one a slash is appended*)
   819 fun tack_on "" name = name
   820   | tack_on path name =
   821       if last_elem (explode path) = "/" then path ^ name
   822       else path ^ "/" ^ name;
   823 
   824 (*Remove the extension of a filename, i.e. the part after the last '.'*)
   825 val remove_ext = implode o #1 o take_suffix (not_equal ".") o explode;
   826 
   827 (*Make relative path to reach an absolute location from a different one*)
   828 fun relative_path cur_path dest_path =
   829   let (*Remove common beginning of both paths and make relative path*)
   830       fun mk_relative [] [] = []
   831         | mk_relative [] ds = ds
   832         | mk_relative cs [] = map (fn _ => "..") cs
   833         | mk_relative (c::cs) (d::ds) =
   834             if c = d then mk_relative cs ds
   835             else ".." :: map (fn _ => "..") cs @ (d::ds);
   836   in if cur_path = "" orelse hd (explode cur_path) <> "/" orelse
   837         dest_path = "" orelse hd (explode dest_path) <> "/" then
   838        error "Relative or empty path passed to relative_path"
   839      else ();
   840      space_implode "/" (mk_relative (space_explode "/" cur_path)
   841                                     (space_explode "/" dest_path))
   842   end;
   843 
   844 (*Determine if absolute path1 is a subdirectory of absolute path2*)
   845 fun path1 subdir_of path2 =
   846   if hd (explode path1) <> "/" orelse hd (explode path2) <> "/" then
   847     error "Relative or empty path passed to subdir_of"
   848   else (space_explode "/" path2) prefix (space_explode "/" path1);
   849 
   850 fun absolute_path cwd file =
   851   let fun rm_points [] result = rev result
   852         | rm_points (".."::ds) result = rm_points ds (tl result)
   853         | rm_points ("."::ds) result = rm_points ds result
   854         | rm_points (d::ds) result = rm_points ds (d::result);
   855   in if file = "" then ""
   856      else if hd (explode file) = "/" then file
   857      else "/" ^ space_implode "/"
   858                   (rm_points (space_explode "/" (tack_on cwd file)) [])
   859   end;
   860 
   861 
   862 (** misc functions **)
   863 
   864 (*use the keyfun to make a list of (x, key) pairs*)
   865 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
   866   let fun keypair x = (x, keyfun x)
   867   in map keypair end;
   868 
   869 (*given a list of (x, key) pairs and a searchkey
   870   return the list of xs from each pair whose key equals searchkey*)
   871 fun keyfilter [] searchkey = []
   872   | keyfilter ((x, key) :: pairs) searchkey =
   873       if key = searchkey then x :: keyfilter pairs searchkey
   874       else keyfilter pairs searchkey;
   875 
   876 
   877 (*Partition list into elements that satisfy predicate and those that don't.
   878   Preserves order of elements in both lists.*)
   879 fun partition (pred: 'a->bool) (ys: 'a list) : ('a list * 'a list) =
   880     let fun part ([], answer) = answer
   881           | part (x::xs, (ys, ns)) = if pred(x)
   882             then  part (xs, (x::ys, ns))
   883             else  part (xs, (ys, x::ns))
   884     in  part (rev ys, ([], []))  end;
   885 
   886 
   887 fun partition_eq (eq:'a * 'a -> bool) =
   888     let fun part [] = []
   889           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
   890                            in (x::xs)::(part xs') end
   891     in part end;
   892 
   893 
   894 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   895    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   896 fun partition_list p i j =
   897   let fun part k xs =
   898             if k>j then
   899               (case xs of [] => []
   900                          | _ => raise LIST "partition_list")
   901             else
   902             let val (ns, rest) = partition (p k) xs;
   903             in  ns :: part(k+1)rest  end
   904   in  part i end;
   905 
   906 
   907 (* sorting *)
   908 
   909 (*insertion sort; stable (does not reorder equal elements)
   910   'less' is less-than test on type 'a*)
   911 fun sort (less: 'a*'a -> bool) =
   912   let fun insert (x, []) = [x]
   913         | insert (x, y::ys) =
   914               if less(y, x) then y :: insert (x, ys) else x::y::ys;
   915       fun sort1 [] = []
   916         | sort1 (x::xs) = insert (x, sort1 xs)
   917   in  sort1  end;
   918 
   919 (*sort strings*)
   920 val sort_strings = sort (op <= : string * string -> bool);
   921 
   922 
   923 (* transitive closure (not Warshall's algorithm) *)
   924 
   925 fun transitive_closure [] = []
   926   | transitive_closure ((x, ys)::ps) =
   927       let val qs = transitive_closure ps
   928           val zs = foldl (fn (zs, y) => assocs qs y union_string zs) (ys, ys)
   929           fun step(u, us) = (u, if x mem_string us then zs union_string us 
   930                                 else us)
   931       in (x, zs) :: map step qs end;
   932 
   933 
   934 (* generating identifiers *)
   935 
   936 local
   937   val a = ord "a" and z = ord "z" and A = ord "A" and Z = ord "Z"
   938   and k0 = ord "0" and k9 = ord "9"
   939 
   940   val seedr = ref 0;
   941 in
   942 
   943 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
   944 fun newid n = 
   945   let fun char i =
   946                if i<26 then chr (A+i)
   947           else if i<52 then chr (a+i-26)
   948           else if i<62 then chr (k0+i-52)
   949           else if i=62 then "_"
   950           else  (*i=63*)    "'"
   951   in  implode (map char (radixpand (64,n)))  end;
   952 
   953 (*Freshly generated identifiers with given prefix; MUST start with a letter*)
   954 fun gensym pre = pre ^ 
   955                  (#1(newid (!seedr), 
   956                      seedr := 1+ !seedr))
   957 
   958 (*Increment a list of letters like a reversed base 26 number.
   959   If head is "z", bumps chars in tail.
   960   Digits are incremented as if they were integers.
   961   "_" and "'" are not changed.
   962   For making variants of identifiers.*)
   963 
   964 fun bump_int_list(c::cs) = if c="9" then "0" :: bump_int_list cs else
   965         if k0 <= ord(c) andalso ord(c) < k9 then chr(ord(c)+1) :: cs
   966         else "1" :: c :: cs
   967   | bump_int_list([]) = error("bump_int_list: not an identifier");
   968 
   969 fun bump_list([], d) = [d]
   970   | bump_list(["'"], d) = [d, "'"]
   971   | bump_list("z"::cs, _) = "a" :: bump_list(cs, "a")
   972   | bump_list("Z"::cs, _) = "A" :: bump_list(cs, "A")
   973   | bump_list("9"::cs, _) = "0" :: bump_int_list cs
   974   | bump_list(c::cs, _) = let val k = ord(c)
   975         in if (a <= k andalso k < z) orelse (A <= k andalso k < Z) orelse
   976               (k0 <= k andalso k < k9) then chr(k+1) :: cs else
   977            if c="'" orelse c="_" then c :: bump_list(cs, "") else
   978                 error("bump_list: not legal in identifier: " ^
   979                         implode(rev(c::cs)))
   980         end;
   981 
   982 end;
   983 
   984 fun bump_string s : string = implode (rev (bump_list(rev(explode s), "")));
   985 
   986 
   987 (* lexical scanning *)
   988 
   989 (*scan a list of characters into "words" composed of "letters" (recognized by
   990   is_let) and separated by any number of non-"letters"*)
   991 fun scanwords is_let cs =
   992   let fun scan1 [] = []
   993         | scan1 cs =
   994             let val (lets, rest) = take_prefix is_let cs
   995             in implode lets :: scanwords is_let rest end;
   996   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
   997 
   998 end;
   999 
  1000 (*Variable-branching trees: for proof terms*)
  1001 datatype 'a mtree = Join of 'a * 'a mtree list;
  1002 
  1003 open Library;