src/Pure/Isar/expression.ML
author ballarin
Sun Mar 29 17:22:17 2009 +0200 (2009-03-29)
changeset 30781 7fb900cad123
parent 30725 c23a5b3cd1b9
child 30783 275577cefaa8
permissions -rw-r--r--
Normalise equation only for morphism, not thm stored in theory.
     1 (*  Title:      Pure/Isar/expression.ML
     2     Author:     Clemens Ballarin, TU Muenchen
     3 
     4 Locale expressions.
     5 *)
     6 
     7 signature EXPRESSION =
     8 sig
     9   (* Locale expressions *)
    10   datatype 'term map = Positional of 'term option list | Named of (string * 'term) list
    11   type 'term expr = (string * ((string * bool) * 'term map)) list
    12   type expression_i = term expr * (binding * typ option * mixfix) list
    13   type expression = string expr * (binding * string option * mixfix) list
    14 
    15   (* Processing of context statements *)
    16   val cert_statement: Element.context_i list -> (term * term list) list list ->
    17     Proof.context -> (term * term list) list list * Proof.context
    18   val read_statement: Element.context list -> (string * string list) list list ->
    19     Proof.context -> (term * term list) list list * Proof.context
    20 
    21   (* Declaring locales *)
    22   val cert_declaration: expression_i -> (Proof.context -> Proof.context) -> Element.context_i list ->
    23     Proof.context -> ((binding * typ option * mixfix) list * (string * morphism) list
    24       * Element.context_i list) * ((string * typ) list * Proof.context)
    25   val cert_read_declaration: expression_i -> (Proof.context -> Proof.context) -> Element.context list ->
    26     Proof.context -> ((binding * typ option * mixfix) list * (string * morphism) list
    27       * Element.context_i list) * ((string * typ) list * Proof.context)
    28       (*FIXME*)
    29   val read_declaration: expression -> (Proof.context -> Proof.context) -> Element.context list ->
    30     Proof.context -> ((binding * typ option * mixfix) list * (string * morphism) list
    31       * Element.context_i list) * ((string * typ) list * Proof.context)
    32   val add_locale: binding -> binding -> expression_i -> Element.context_i list ->
    33     theory -> string * local_theory
    34   val add_locale_cmd: binding -> binding -> expression -> Element.context list ->
    35     theory -> string * local_theory
    36 
    37   (* Interpretation *)
    38   val cert_goal_expression: expression_i -> Proof.context ->
    39     (term list list * (string * morphism) list * morphism) * Proof.context
    40   val read_goal_expression: expression -> Proof.context ->
    41     (term list list * (string * morphism) list * morphism) * Proof.context
    42   val sublocale: string -> expression_i -> theory -> Proof.state
    43   val sublocale_cmd: string -> expression -> theory -> Proof.state
    44   val interpretation: expression_i -> (Attrib.binding * term) list -> theory -> Proof.state
    45   val interpretation_cmd: expression -> (Attrib.binding * string) list -> theory -> Proof.state
    46   val interpret: expression_i -> bool -> Proof.state -> Proof.state
    47   val interpret_cmd: expression -> bool -> Proof.state -> Proof.state
    48 end;
    49 
    50 structure Expression : EXPRESSION =
    51 struct
    52 
    53 datatype ctxt = datatype Element.ctxt;
    54 
    55 
    56 (*** Expressions ***)
    57 
    58 datatype 'term map =
    59   Positional of 'term option list |
    60   Named of (string * 'term) list;
    61 
    62 type 'term expr = (string * ((string * bool) * 'term map)) list;
    63 
    64 type expression = string expr * (binding * string option * mixfix) list;
    65 type expression_i = term expr * (binding * typ option * mixfix) list;
    66 
    67 
    68 (** Internalise locale names in expr **)
    69 
    70 fun intern thy instances =  map (apfst (Locale.intern thy)) instances;
    71 
    72 
    73 (** Parameters of expression.
    74 
    75    Sanity check of instantiations and extraction of implicit parameters.
    76    The latter only occurs iff strict = false.
    77    Positional instantiations are extended to match full length of parameter list
    78    of instantiated locale. **)
    79 
    80 fun parameters_of thy strict (expr, fixed) =
    81   let
    82     fun reject_dups message xs =
    83       let val dups = duplicates (op =) xs
    84       in
    85         if null dups then () else error (message ^ commas dups)
    86       end;
    87 
    88     fun match_bind (n, b) = (n = Binding.name_of b);
    89     fun parm_eq ((b1, mx1: mixfix), (b2, mx2)) =
    90       Binding.eq_name (b1, b2) andalso
    91         (mx1 = mx2 orelse
    92           error ("Conflicting syntax for parameter " ^ quote (Binding.str_of b1) ^ " in expression"));
    93 
    94     fun params_loc loc =
    95       (Locale.params_of thy loc |> map (fn (p, _, mx) => (p, mx)), loc);
    96     fun params_inst (expr as (loc, (prfx, Positional insts))) =
    97           let
    98             val (ps, loc') = params_loc loc;
    99             val d = length ps - length insts;
   100             val insts' =
   101               if d < 0 then error ("More arguments than parameters in instantiation of locale " ^
   102                 quote (Locale.extern thy loc))
   103               else insts @ replicate d NONE;
   104             val ps' = (ps ~~ insts') |>
   105               map_filter (fn (p, NONE) => SOME p | (_, SOME _) => NONE);
   106           in (ps', (loc', (prfx, Positional insts'))) end
   107       | params_inst (expr as (loc, (prfx, Named insts))) =
   108           let
   109             val _ = reject_dups "Duplicate instantiation of the following parameter(s): "
   110               (map fst insts);
   111 
   112             val (ps, loc') = params_loc loc;
   113             val ps' = fold (fn (p, _) => fn ps =>
   114               if AList.defined match_bind ps p then AList.delete match_bind p ps
   115               else error (quote p ^" not a parameter of instantiated expression.")) insts ps;
   116           in (ps', (loc', (prfx, Named insts))) end;
   117     fun params_expr is =
   118           let
   119             val (is', ps') = fold_map (fn i => fn ps =>
   120               let
   121                 val (ps', i') = params_inst i;
   122                 val ps'' = distinct parm_eq (ps @ ps');
   123               in (i', ps'') end) is []
   124           in (ps', is') end;
   125 
   126     val (implicit, expr') = params_expr expr;
   127 
   128     val implicit' = map (#1 #> Name.of_binding) implicit;
   129     val fixed' = map (#1 #> Name.of_binding) fixed;
   130     val _ = reject_dups "Duplicate fixed parameter(s): " fixed';
   131     val implicit'' =
   132       if strict then []
   133       else
   134         let val _ = reject_dups
   135           "Parameter(s) declared simultaneously in expression and for clause: " (implicit' @ fixed')
   136         in map (fn (b, mx) => (b, NONE, mx)) implicit end;
   137 
   138   in (expr', implicit'' @ fixed) end;
   139 
   140 
   141 (** Read instantiation **)
   142 
   143 (* Parse positional or named instantiation *)
   144 
   145 local
   146 
   147 fun prep_inst prep_term ctxt parms (Positional insts) =
   148       (insts ~~ parms) |> map (fn
   149         (NONE, p) => Free (p, dummyT) |
   150         (SOME t, _) => prep_term ctxt t)
   151   | prep_inst prep_term ctxt parms (Named insts) =
   152       parms |> map (fn p => case AList.lookup (op =) insts p of
   153         SOME t => prep_term ctxt t |
   154         NONE => Free (p, dummyT));
   155 
   156 in
   157 
   158 fun parse_inst x = prep_inst Syntax.parse_term x;
   159 fun make_inst x = prep_inst (K I) x;
   160 
   161 end;
   162 
   163 
   164 (* Instantiation morphism *)
   165 
   166 fun inst_morph (parm_names, parm_types) ((prfx, strict), insts') ctxt =
   167   let
   168     (* parameters *)
   169     val type_parm_names = fold Term.add_tfreesT parm_types [] |> map fst;
   170 
   171     (* type inference and contexts *)
   172     val parm_types' = map (TypeInfer.paramify_vars o Logic.varifyT) parm_types;
   173     val type_parms = fold Term.add_tvarsT parm_types' [] |> map (Logic.mk_type o TVar);
   174     val arg = type_parms @ map2 TypeInfer.constrain parm_types' insts';
   175     val res = Syntax.check_terms ctxt arg;
   176     val ctxt' = ctxt |> fold Variable.auto_fixes res;
   177 
   178     (* instantiation *)
   179     val (type_parms'', res') = chop (length type_parms) res;
   180     val insts'' = (parm_names ~~ res') |> map_filter
   181       (fn (inst as (x, Free (y, _))) => if x = y then NONE else SOME inst |
   182         inst => SOME inst);
   183     val instT = Symtab.make (type_parm_names ~~ map Logic.dest_type type_parms'');
   184     val inst = Symtab.make insts'';
   185   in
   186     (Element.inst_morphism (ProofContext.theory_of ctxt) (instT, inst) $>
   187       Morphism.binding_morphism (Binding.prefix strict prfx), ctxt')
   188   end;
   189 
   190 
   191 (*** Locale processing ***)
   192 
   193 (** Parsing **)
   194 
   195 fun parse_elem prep_typ prep_term ctxt =
   196   Element.map_ctxt
   197    {binding = I,
   198     typ = prep_typ ctxt,
   199     term = prep_term (ProofContext.set_mode ProofContext.mode_schematic ctxt),
   200     pattern = prep_term (ProofContext.set_mode ProofContext.mode_pattern ctxt),
   201     fact = I,
   202     attrib = I};
   203 
   204 fun parse_concl prep_term ctxt concl =
   205   (map o map) (fn (t, ps) =>
   206     (prep_term (ProofContext.set_mode ProofContext.mode_schematic ctxt) t,
   207       map (prep_term (ProofContext.set_mode ProofContext.mode_pattern ctxt)) ps)) concl;
   208 
   209 
   210 (** Simultaneous type inference: instantiations + elements + conclusion **)
   211 
   212 local
   213 
   214 fun mk_type T = (Logic.mk_type T, []);
   215 fun mk_term t = (t, []);
   216 fun mk_propp (p, pats) = (Syntax.type_constraint propT p, pats);
   217 
   218 fun dest_type (T, []) = Logic.dest_type T;
   219 fun dest_term (t, []) = t;
   220 fun dest_propp (p, pats) = (p, pats);
   221 
   222 fun extract_inst (_, (_, ts)) = map mk_term ts;
   223 fun restore_inst ((l, (p, _)), cs) = (l, (p, map dest_term cs));
   224 
   225 fun extract_elem (Fixes fixes) = map (#2 #> the_list #> map mk_type) fixes
   226   | extract_elem (Constrains csts) = map (#2 #> single #> map mk_type) csts
   227   | extract_elem (Assumes asms) = map (#2 #> map mk_propp) asms
   228   | extract_elem (Defines defs) = map (fn (_, (t, ps)) => [mk_propp (t, ps)]) defs
   229   | extract_elem (Notes _) = [];
   230 
   231 fun restore_elem (Fixes fixes, css) =
   232       (fixes ~~ css) |> map (fn ((x, _, mx), cs) =>
   233         (x, cs |> map dest_type |> try hd, mx)) |> Fixes
   234   | restore_elem (Constrains csts, css) =
   235       (csts ~~ css) |> map (fn ((x, _), cs) =>
   236         (x, cs |> map dest_type |> hd)) |> Constrains
   237   | restore_elem (Assumes asms, css) =
   238       (asms ~~ css) |> map (fn ((b, _), cs) => (b, map dest_propp cs)) |> Assumes
   239   | restore_elem (Defines defs, css) =
   240       (defs ~~ css) |> map (fn ((b, _), [c]) => (b, dest_propp c)) |> Defines
   241   | restore_elem (Notes notes, _) = Notes notes;
   242 
   243 fun check cs context =
   244   let
   245     fun prep (_, pats) (ctxt, t :: ts) =
   246       let val ctxt' = Variable.auto_fixes t ctxt
   247       in
   248         ((t, Syntax.check_props (ProofContext.set_mode ProofContext.mode_pattern ctxt') pats),
   249           (ctxt', ts))
   250       end
   251     val (cs', (context', _)) = fold_map prep cs
   252       (context, Syntax.check_terms
   253         (ProofContext.set_mode ProofContext.mode_schematic context) (map fst cs));
   254   in (cs', context') end;
   255 
   256 in
   257 
   258 fun check_autofix insts elems concl ctxt =
   259   let
   260     val inst_cs = map extract_inst insts;
   261     val elem_css = map extract_elem elems;
   262     val concl_cs = (map o map) mk_propp concl;
   263     (* Type inference *)
   264     val (inst_cs' :: css', ctxt') =
   265       (fold_burrow o fold_burrow) check (inst_cs :: elem_css @ [concl_cs]) ctxt;
   266     val (elem_css', [concl_cs']) = chop (length elem_css) css';
   267   in
   268     (map restore_inst (insts ~~ inst_cs'), map restore_elem (elems ~~ elem_css'),
   269       concl_cs', ctxt')
   270   end;
   271 
   272 end;
   273 
   274 
   275 (** Prepare locale elements **)
   276 
   277 fun declare_elem prep_vars (Fixes fixes) ctxt =
   278       let val (vars, _) = prep_vars fixes ctxt
   279       in ctxt |> ProofContext.add_fixes_i vars |> snd end
   280   | declare_elem prep_vars (Constrains csts) ctxt =
   281       ctxt |> prep_vars (map (fn (x, T) => (Binding.name x, SOME T, NoSyn)) csts) |> snd
   282   | declare_elem _ (Assumes _) ctxt = ctxt
   283   | declare_elem _ (Defines _) ctxt = ctxt
   284   | declare_elem _ (Notes _) ctxt = ctxt;
   285 
   286 (** Finish locale elements **)
   287 
   288 fun closeup _ _ false elem = elem
   289   | closeup ctxt parms true elem =
   290       let
   291         (* FIXME consider closing in syntactic phase -- before type checking *)
   292         fun close_frees t =
   293           let
   294             val rev_frees =
   295               Term.fold_aterms (fn Free (x, T) =>
   296                 if AList.defined (op =) parms x then I else insert (op =) (x, T) | _ => I) t [];
   297           in fold (Logic.all o Free) rev_frees t end;
   298 
   299         fun no_binds [] = []
   300           | no_binds _ = error "Illegal term bindings in context element";
   301       in
   302         (case elem of
   303           Assumes asms => Assumes (asms |> map (fn (a, propps) =>
   304             (a, map (fn (t, ps) => (close_frees t, no_binds ps)) propps)))
   305         | Defines defs => Defines (defs |> map (fn ((name, atts), (t, ps)) =>
   306             let val ((c, _), t') = LocalDefs.cert_def ctxt (close_frees t)
   307             in ((Thm.def_binding_optional (Binding.name c) name, atts), (t', no_binds ps)) end))
   308         | e => e)
   309       end;
   310 
   311 fun finish_primitive parms _ (Fixes fixes) = Fixes (map (fn (binding, _, mx) =>
   312       let val x = Binding.name_of binding
   313       in (binding, AList.lookup (op =) parms x, mx) end) fixes)
   314   | finish_primitive _ _ (Constrains _) = Constrains []
   315   | finish_primitive _ close (Assumes asms) = close (Assumes asms)
   316   | finish_primitive _ close (Defines defs) = close (Defines defs)
   317   | finish_primitive _ _ (Notes facts) = Notes facts;
   318 
   319 fun finish_inst ctxt parms do_close (loc, (prfx, inst)) =
   320   let
   321     val thy = ProofContext.theory_of ctxt;
   322     val (parm_names, parm_types) = Locale.params_of thy loc |>
   323       map_split (fn (b, SOME T, _) => (Binding.name_of b, T));
   324     val (morph, _) = inst_morph (parm_names, parm_types) (prfx, inst) ctxt;
   325   in (loc, morph) end;
   326 
   327 fun finish_elem ctxt parms do_close elem =
   328   finish_primitive parms (closeup ctxt parms do_close) elem;
   329 
   330 fun finish ctxt parms do_close insts elems =
   331   let
   332     val deps = map (finish_inst ctxt parms do_close) insts;
   333     val elems' = map (finish_elem ctxt parms do_close) elems;
   334   in (deps, elems') end;
   335 
   336 
   337 (** Process full context statement: instantiations + elements + conclusion **)
   338 
   339 (* Interleave incremental parsing and type inference over entire parsed stretch. *)
   340 
   341 local
   342 
   343 fun prep_full_context_statement parse_typ parse_prop prep_vars_elem prep_inst prep_vars_inst prep_expr
   344     strict do_close raw_import init_body raw_elems raw_concl ctxt1 =
   345   let
   346     val thy = ProofContext.theory_of ctxt1;
   347 
   348     val (raw_insts, fixed) = parameters_of thy strict (apfst (prep_expr thy) raw_import);
   349 
   350     fun prep_insts (loc, (prfx, inst)) (i, insts, ctxt) =
   351       let
   352         val (parm_names, parm_types) = Locale.params_of thy loc |>
   353           map_split (fn (b, SOME T, _) => (Name.of_binding b, T))
   354             (*FIXME return value of Locale.params_of has strange type*)
   355         val inst' = prep_inst ctxt parm_names inst;
   356         val parm_types' = map (TypeInfer.paramify_vars o
   357           Term.map_type_tvar (fn ((x, _), S) => TVar ((x, i), S)) o Logic.varifyT) parm_types;
   358         val inst'' = map2 TypeInfer.constrain parm_types' inst';
   359         val insts' = insts @ [(loc, (prfx, inst''))];
   360         val (insts'', _, _, ctxt' (* FIXME not used *) ) = check_autofix insts' [] [] ctxt;
   361         val inst''' = insts'' |> List.last |> snd |> snd;
   362         val (morph, _) = inst_morph (parm_names, parm_types) (prfx, inst''') ctxt;
   363         val ctxt'' = Locale.activate_declarations thy (loc, morph) ctxt;
   364       in (i + 1, insts', ctxt'') end;
   365 
   366     fun prep_elem insts raw_elem (elems, ctxt) =
   367       let
   368         val ctxt' = declare_elem prep_vars_elem raw_elem ctxt;
   369         val elems' = elems @ [parse_elem parse_typ parse_prop ctxt' raw_elem];
   370         val (_, _, _, ctxt'') = check_autofix insts elems' [] ctxt';
   371       in (elems', ctxt') end;
   372 
   373     fun prep_concl raw_concl (insts, elems, ctxt) =
   374       let
   375         val concl = parse_concl parse_prop ctxt raw_concl;
   376       in check_autofix insts elems concl ctxt end;
   377 
   378     val fors = prep_vars_inst fixed ctxt1 |> fst;
   379     val ctxt2 = ctxt1 |> ProofContext.add_fixes_i fors |> snd;
   380     val (_, insts', ctxt3) = fold prep_insts raw_insts (0, [], ctxt2);
   381     val ctxt4 = init_body ctxt3;
   382     val (elems, ctxt5) = fold (prep_elem insts') raw_elems ([], ctxt4);
   383     val (insts, elems', concl, ctxt6) =
   384       prep_concl raw_concl (insts', elems, ctxt5);
   385 
   386     (* Retrieve parameter types *)
   387     val xs = fold (fn Fixes fixes => (fn ps => ps @ map (Name.of_binding o #1) fixes)
   388       | _ => fn ps => ps) (Fixes fors :: elems') [];
   389     val (Ts, ctxt7) = fold_map ProofContext.inferred_param xs ctxt6;
   390     val parms = xs ~~ Ts;  (* params from expression and elements *)
   391 
   392     val Fixes fors' = finish_primitive parms I (Fixes fors);
   393     val (deps, elems'') = finish ctxt6 parms do_close insts elems';
   394 
   395   in ((fors', deps, elems'', concl), (parms, ctxt7)) end
   396 
   397 in
   398 
   399 fun cert_full_context_statement x =
   400   prep_full_context_statement (K I) (K I) ProofContext.cert_vars
   401   make_inst ProofContext.cert_vars (K I) x;
   402 fun cert_read_full_context_statement x =
   403   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop ProofContext.read_vars
   404   make_inst ProofContext.cert_vars (K I) x;
   405 fun read_full_context_statement x =
   406   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop ProofContext.read_vars
   407   parse_inst ProofContext.read_vars intern x;
   408 
   409 end;
   410 
   411 
   412 (* Context statement: elements + conclusion *)
   413 
   414 local
   415 
   416 fun prep_statement prep activate raw_elems raw_concl context =
   417   let
   418      val ((_, _, elems, concl), _) =
   419        prep true false ([], []) I raw_elems raw_concl context;
   420      val (_, context') = context |>
   421        ProofContext.set_stmt true |>
   422        activate elems;
   423   in (concl, context') end;
   424 
   425 in
   426 
   427 fun cert_statement x = prep_statement cert_full_context_statement Element.activate_i x;
   428 fun read_statement x = prep_statement read_full_context_statement Element.activate x;
   429 
   430 end;
   431 
   432 
   433 (* Locale declaration: import + elements *)
   434 
   435 local
   436 
   437 fun prep_declaration prep activate raw_import init_body raw_elems context =
   438   let
   439     val ((fixed, deps, elems, _), (parms, ctxt')) =
   440       prep false true raw_import init_body raw_elems [] context ;
   441     (* Declare parameters and imported facts *)
   442     val context' = context |>
   443       ProofContext.add_fixes_i fixed |> snd |>
   444       fold Locale.activate_local_facts deps;
   445     val (elems', _) = context' |>
   446       ProofContext.set_stmt true |>
   447       activate elems;
   448   in ((fixed, deps, elems'), (parms, ctxt')) end;
   449 
   450 in
   451 
   452 fun cert_declaration x = prep_declaration cert_full_context_statement Element.activate_i x;
   453 fun cert_read_declaration x = prep_declaration cert_read_full_context_statement Element.activate x;
   454 fun read_declaration x = prep_declaration read_full_context_statement Element.activate x;
   455 
   456 end;
   457 
   458 
   459 (* Locale expression to set up a goal *)
   460 
   461 local
   462 
   463 fun props_of thy (name, morph) =
   464   let
   465     val (asm, defs) = Locale.specification_of thy name;
   466   in
   467     (case asm of NONE => defs | SOME asm => asm :: defs) |> map (Morphism.term morph)
   468   end;
   469 
   470 fun prep_goal_expression prep expression context =
   471   let
   472     val thy = ProofContext.theory_of context;
   473 
   474     val ((fixed, deps, _, _), _) =
   475       prep true true expression I [] [] context;
   476     (* proof obligations *)
   477     val propss = map (props_of thy) deps;
   478 
   479     val goal_ctxt = context |>
   480       ProofContext.add_fixes_i fixed |> snd |>
   481       (fold o fold) Variable.auto_fixes propss;
   482 
   483     val export = Variable.export_morphism goal_ctxt context;
   484     val exp_fact = Drule.zero_var_indexes_list o map Thm.strip_shyps o Morphism.fact export;
   485     val exp_term = TermSubst.zero_var_indexes o Morphism.term export;
   486     val exp_typ = Logic.type_map exp_term;
   487     val export' = Morphism.morphism {binding = I, typ = exp_typ, term = exp_term, fact = exp_fact};
   488   in ((propss, deps, export'), goal_ctxt) end;
   489 
   490 in
   491 
   492 fun cert_goal_expression x = prep_goal_expression cert_full_context_statement x;
   493 fun read_goal_expression x = prep_goal_expression read_full_context_statement x;
   494 
   495 end;
   496 
   497 
   498 (*** Locale declarations ***)
   499 
   500 (* extract specification text *)
   501 
   502 val norm_term = Envir.beta_norm oo Term.subst_atomic;
   503 
   504 fun bind_def ctxt eq (xs, env, eqs) =
   505   let
   506     val _ = LocalDefs.cert_def ctxt eq;
   507     val ((y, T), b) = LocalDefs.abs_def eq;
   508     val b' = norm_term env b;
   509     fun err msg = error (msg ^ ": " ^ quote y);
   510   in
   511     case filter (fn (Free (y', _), _) => y = y' | _ => false) env of
   512       [] => (Term.add_frees b' xs, (Free (y, T), b') :: env, eq :: eqs) |
   513       dups => if forall (fn (_, b'') => b' aconv b'') dups
   514         then (xs, env, eqs)
   515         else err "Attempt to redefine variable"
   516   end;
   517 
   518 (* text has the following structure:
   519        (((exts, exts'), (ints, ints')), (xs, env, defs))
   520    where
   521      exts: external assumptions (terms in assumes elements)
   522      exts': dito, normalised wrt. env
   523      ints: internal assumptions (terms in assumptions from insts)
   524      ints': dito, normalised wrt. env
   525      xs: the free variables in exts' and ints' and rhss of definitions,
   526        this includes parameters except defined parameters
   527      env: list of term pairs encoding substitutions, where the first term
   528        is a free variable; substitutions represent defines elements and
   529        the rhs is normalised wrt. the previous env
   530      defs: the equations from the defines elements
   531    *)
   532 
   533 fun eval_text _ _ (Fixes _) text = text
   534   | eval_text _ _ (Constrains _) text = text
   535   | eval_text _ is_ext (Assumes asms)
   536         (((exts, exts'), (ints, ints')), (xs, env, defs)) =
   537       let
   538         val ts = maps (map #1 o #2) asms;
   539         val ts' = map (norm_term env) ts;
   540         val spec' =
   541           if is_ext then ((exts @ ts, exts' @ ts'), (ints, ints'))
   542           else ((exts, exts'), (ints @ ts, ints' @ ts'));
   543       in (spec', (fold Term.add_frees ts' xs, env, defs)) end
   544   | eval_text ctxt _ (Defines defs) (spec, binds) =
   545       (spec, fold (bind_def ctxt o #1 o #2) defs binds)
   546   | eval_text _ _ (Notes _) text = text;
   547 
   548 fun eval_inst ctxt (loc, morph) text =
   549   let
   550     val thy = ProofContext.theory_of ctxt;
   551     val (asm, defs) = Locale.specification_of thy loc;
   552     val asm' = Option.map (Morphism.term morph) asm;
   553     val defs' = map (Morphism.term morph) defs;
   554     val text' = text |>
   555       (if is_some asm
   556         then eval_text ctxt false (Assumes [(Attrib.empty_binding, [(the asm', [])])])
   557         else I) |>
   558       (if not (null defs)
   559         then eval_text ctxt false (Defines (map (fn def => (Attrib.empty_binding, (def, []))) defs'))
   560         else I)
   561 (* FIXME clone from locale.ML *)
   562   in text' end;
   563 
   564 fun eval_elem ctxt elem text =
   565   eval_text ctxt true elem text;
   566 
   567 fun eval ctxt deps elems =
   568   let
   569     val text' = fold (eval_inst ctxt) deps ((([], []), ([], [])), ([], [], []));
   570     val ((spec, (_, _, defs))) = fold (eval_elem ctxt) elems text';
   571   in (spec, defs) end;
   572 
   573 (* axiomsN: name of theorem set with destruct rules for locale predicates,
   574      also name suffix of delta predicates and assumptions. *)
   575 
   576 val axiomsN = "axioms";
   577 
   578 local
   579 
   580 (* introN: name of theorems for introduction rules of locale and
   581      delta predicates *)
   582 
   583 val introN = "intro";
   584 
   585 fun atomize_spec thy ts =
   586   let
   587     val t = Logic.mk_conjunction_balanced ts;
   588     val body = ObjectLogic.atomize_term thy t;
   589     val bodyT = Term.fastype_of body;
   590   in
   591     if bodyT = propT then (t, propT, Thm.reflexive (Thm.cterm_of thy t))
   592     else (body, bodyT, ObjectLogic.atomize (Thm.cterm_of thy t))
   593   end;
   594 
   595 (* achieve plain syntax for locale predicates (without "PROP") *)
   596 
   597 fun aprop_tr' n c = (Syntax.constN ^ c, fn ctxt => fn args =>
   598   if length args = n then
   599     Syntax.const "_aprop" $
   600       Term.list_comb (Syntax.free (Consts.extern (ProofContext.consts_of ctxt) c), args)
   601   else raise Match);
   602 
   603 (* define one predicate including its intro rule and axioms
   604    - bname: predicate name
   605    - parms: locale parameters
   606    - defs: thms representing substitutions from defines elements
   607    - ts: terms representing locale assumptions (not normalised wrt. defs)
   608    - norm_ts: terms representing locale assumptions (normalised wrt. defs)
   609    - thy: the theory
   610 *)
   611 
   612 fun def_pred bname parms defs ts norm_ts thy =
   613   let
   614     val name = Sign.full_name thy bname;
   615 
   616     val (body, bodyT, body_eq) = atomize_spec thy norm_ts;
   617     val env = Term.add_free_names body [];
   618     val xs = filter (member (op =) env o #1) parms;
   619     val Ts = map #2 xs;
   620     val extraTs =
   621       (Term.add_tfrees body [] \\ fold Term.add_tfreesT Ts [])
   622       |> Library.sort_wrt #1 |> map TFree;
   623     val predT = map Term.itselfT extraTs ---> Ts ---> bodyT;
   624 
   625     val args = map Logic.mk_type extraTs @ map Free xs;
   626     val head = Term.list_comb (Const (name, predT), args);
   627     val statement = ObjectLogic.ensure_propT thy head;
   628 
   629     val ([pred_def], defs_thy) =
   630       thy
   631       |> bodyT = propT ? Sign.add_advanced_trfuns ([], [], [aprop_tr' (length args) name], [])
   632       |> Sign.declare_const [] ((bname, predT), NoSyn) |> snd
   633       |> PureThy.add_defs false
   634         [((Binding.map_name Thm.def_name bname, Logic.mk_equals (head, body)), [Thm.kind_internal])];
   635     val defs_ctxt = ProofContext.init defs_thy |> Variable.declare_term head;
   636 
   637     val cert = Thm.cterm_of defs_thy;
   638 
   639     val intro = Goal.prove_global defs_thy [] norm_ts statement (fn _ =>
   640       MetaSimplifier.rewrite_goals_tac [pred_def] THEN
   641       Tactic.compose_tac (false, body_eq RS Drule.equal_elim_rule1, 1) 1 THEN
   642       Tactic.compose_tac (false,
   643         Conjunction.intr_balanced (map (Thm.assume o cert) norm_ts), 0) 1);
   644 
   645     val conjuncts =
   646       (Drule.equal_elim_rule2 OF [body_eq,
   647         MetaSimplifier.rewrite_rule [pred_def] (Thm.assume (cert statement))])
   648       |> Conjunction.elim_balanced (length ts);
   649     val axioms = ts ~~ conjuncts |> map (fn (t, ax) =>
   650       Element.prove_witness defs_ctxt t
   651        (MetaSimplifier.rewrite_goals_tac defs THEN
   652         Tactic.compose_tac (false, ax, 0) 1));
   653   in ((statement, intro, axioms), defs_thy) end;
   654 
   655 in
   656 
   657 (* main predicate definition function *)
   658 
   659 fun define_preds pname parms (((exts, exts'), (ints, ints')), defs) thy =
   660   let
   661     val defs' = map (cterm_of thy #> Assumption.assume #> Drule.gen_all #> Drule.abs_def) defs;
   662 
   663     val (a_pred, a_intro, a_axioms, thy'') =
   664       if null exts then (NONE, NONE, [], thy)
   665       else
   666         let
   667           val aname = if null ints then pname else Binding.suffix_name ("_" ^ axiomsN) pname
   668           val ((statement, intro, axioms), thy') =
   669             thy
   670             |> def_pred aname parms defs' exts exts';
   671           val (_, thy'') =
   672             thy'
   673             |> Sign.mandatory_path (Binding.name_of aname)
   674             |> PureThy.note_thmss Thm.internalK
   675               [((Binding.name introN, []), [([intro], [Locale.unfold_add])])]
   676             ||> Sign.restore_naming thy';
   677           in (SOME statement, SOME intro, axioms, thy'') end;
   678     val (b_pred, b_intro, b_axioms, thy'''') =
   679       if null ints then (NONE, NONE, [], thy'')
   680       else
   681         let
   682           val ((statement, intro, axioms), thy''') =
   683             thy''
   684             |> def_pred pname parms defs' (ints @ the_list a_pred) (ints' @ the_list a_pred);
   685           val (_, thy'''') =
   686             thy'''
   687             |> Sign.mandatory_path (Binding.name_of pname)
   688             |> PureThy.note_thmss Thm.internalK
   689                  [((Binding.name introN, []), [([intro], [Locale.intro_add])]),
   690                   ((Binding.name axiomsN, []),
   691                     [(map (Drule.standard o Element.conclude_witness) axioms, [])])]
   692             ||> Sign.restore_naming thy''';
   693         in (SOME statement, SOME intro, axioms, thy'''') end;
   694   in ((a_pred, a_intro, a_axioms), (b_pred, b_intro, b_axioms), thy'''') end;
   695 
   696 end;
   697 
   698 
   699 local
   700 
   701 fun assumes_to_notes (Assumes asms) axms =
   702       fold_map (fn (a, spec) => fn axs =>
   703           let val (ps, qs) = chop (length spec) axs
   704           in ((a, [(ps, [])]), qs) end) asms axms
   705       |> apfst (curry Notes Thm.assumptionK)
   706   | assumes_to_notes e axms = (e, axms);
   707 
   708 fun defines_to_notes thy (Defines defs) =
   709       Notes (Thm.definitionK, map (fn (a, (def, _)) =>
   710         (a, [([Assumption.assume (cterm_of thy def)],
   711           [(Attrib.internal o K) Locale.witness_add])])) defs)
   712   | defines_to_notes _ e = e;
   713 
   714 fun gen_add_locale prep_decl
   715     bname raw_predicate_bname raw_import raw_body thy =
   716   let
   717     val name = Sign.full_name thy bname;
   718     val _ = Locale.defined thy name andalso
   719       error ("Duplicate definition of locale " ^ quote name);
   720 
   721     val ((fixed, deps, body_elems), (parms, ctxt')) =
   722       prep_decl raw_import I raw_body (ProofContext.init thy);
   723     val text as (((_, exts'), _), defs) = eval ctxt' deps body_elems;
   724 
   725     val predicate_bname =
   726       if Binding.is_empty raw_predicate_bname then bname
   727       else raw_predicate_bname;
   728     val ((a_statement, a_intro, a_axioms), (b_statement, b_intro, b_axioms), thy') =
   729       define_preds predicate_bname parms text thy;
   730 
   731     val extraTs = fold Term.add_tfrees exts' [] \\ fold Term.add_tfreesT (map snd parms) [];
   732     val _ =
   733       if null extraTs then ()
   734       else warning ("Additional type variable(s) in locale specification " ^ quote (Binding.str_of bname));
   735 
   736     val a_satisfy = Element.satisfy_morphism a_axioms;
   737     val b_satisfy = Element.satisfy_morphism b_axioms;
   738 
   739     val params = fixed @
   740       (body_elems |> map_filter (fn Fixes fixes => SOME fixes | _ => NONE) |> flat);
   741     val asm = if is_some b_statement then b_statement else a_statement;
   742 
   743     val notes =
   744       if is_some asm
   745       then [(Thm.internalK, [((Binding.suffix_name ("_" ^ axiomsN) bname, []),
   746         [([Assumption.assume (cterm_of thy' (the asm))],
   747           [(Attrib.internal o K) Locale.witness_add])])])]
   748       else [];
   749 
   750     val notes' = body_elems |>
   751       map (defines_to_notes thy') |>
   752       map (Element.morph_ctxt a_satisfy) |>
   753       (fn elems => fold_map assumes_to_notes elems (map Element.conclude_witness a_axioms)) |>
   754       fst |>
   755       map (Element.morph_ctxt b_satisfy) |>
   756       map_filter (fn Notes notes => SOME notes | _ => NONE);
   757 
   758     val deps' = map (fn (l, morph) => (l, morph $> b_satisfy)) deps;
   759     val axioms = map Element.conclude_witness b_axioms;
   760 
   761     val loc_ctxt = thy'
   762       |> Locale.register_locale bname (extraTs, params)
   763           (asm, rev defs) (a_intro, b_intro) axioms ([], []) (rev notes) (rev deps')
   764       |> TheoryTarget.init (SOME name)
   765       |> fold (fn (kind, facts) => LocalTheory.notes kind facts #> snd) notes';
   766 
   767   in (name, loc_ctxt) end;
   768 
   769 in
   770 
   771 val add_locale = gen_add_locale cert_declaration;
   772 val add_locale_cmd = gen_add_locale read_declaration;
   773 
   774 end;
   775 
   776 
   777 (*** Interpretation ***)
   778 
   779 (** Interpretation between locales: declaring sublocale relationships **)
   780 
   781 local
   782 
   783 fun gen_sublocale prep_expr intern raw_target expression thy =
   784   let
   785     val target = intern thy raw_target;
   786     val target_ctxt = Locale.init target thy;
   787 
   788     val ((propss, deps, export), goal_ctxt) = prep_expr expression target_ctxt;
   789 
   790     fun after_qed witss = ProofContext.theory
   791       (fold2 (fn (name, morph) => fn wits => Locale.add_dependency target
   792         (name, morph $> Element.satisfy_morphism wits $> export)) deps witss #>
   793       (fn thy => fold_rev Locale.activate_global_facts
   794         (Locale.get_registrations thy) thy));
   795   in Element.witness_proof after_qed propss goal_ctxt end;
   796 
   797 in
   798 
   799 fun sublocale x = gen_sublocale cert_goal_expression (K I) x;
   800 fun sublocale_cmd x = gen_sublocale read_goal_expression Locale.intern x;
   801 
   802 end;
   803 
   804 
   805 (** Interpretation in theories **)
   806 
   807 local
   808 
   809 fun gen_interpretation prep_expr parse_prop prep_attr
   810     expression equations theory =
   811   let
   812     val ((propss, regs, export), expr_ctxt) = ProofContext.init theory
   813       |> prep_expr expression;
   814 
   815     val eqns = map (parse_prop expr_ctxt o snd) equations |> Syntax.check_terms expr_ctxt;
   816     val eq_attns = map ((apsnd o map) (prep_attr theory) o fst) equations;
   817     val goal_ctxt = fold Variable.auto_fixes eqns expr_ctxt;
   818     val export' = Variable.export_morphism goal_ctxt expr_ctxt;
   819 
   820     fun store_reg ((name, morph), wits) thy =
   821       let
   822         val wits' = map (Element.morph_witness export') wits;
   823         val morph' = morph $> Element.satisfy_morphism wits';
   824       in
   825         thy
   826         |> Locale.add_registration (name, (morph', export))
   827         |> pair (name, morph')
   828       end;
   829 
   830     fun store_eqns_activate regs [] thy =
   831           thy
   832           |> fold (fn (name, morph) =>
   833                Locale.activate_global_facts (name, morph $> export)) regs
   834       | store_eqns_activate regs eqs thy =
   835           let
   836             val eqs' = eqs |> map (Morphism.thm (export' $> export));
   837             val morph_eqs = eqs' |> map (LocalDefs.meta_rewrite_rule (ProofContext.init thy) #>
   838               Drule.abs_def);
   839             val eq_morph = Element.eq_morphism thy morph_eqs;
   840             val eq_attns' = map ((apsnd o map) (Attrib.attribute_i thy)) eq_attns;
   841           in
   842             thy
   843             |> fold (fn (name, morph) =>
   844                 Locale.amend_registration eq_morph (name, morph) #>
   845                 Locale.activate_global_facts (name, morph $> eq_morph $> export)) regs
   846             |> PureThy.note_thmss Thm.lemmaK (eq_attns' ~~ map (fn eq => [([eq], [])]) eqs')
   847             |> snd
   848           end;
   849 
   850     fun after_qed wits eqs = ProofContext.theory (fold_map store_reg (regs ~~ wits)
   851         #-> (fn regs => store_eqns_activate regs eqs));
   852 
   853   in Element.witness_proof_eqs after_qed propss eqns goal_ctxt end;
   854 
   855 in
   856 
   857 fun interpretation x = gen_interpretation cert_goal_expression (K I) (K I) x;
   858 fun interpretation_cmd x = gen_interpretation read_goal_expression
   859   Syntax.parse_prop Attrib.intern_src x;
   860 
   861 end;
   862 
   863 
   864 (** Interpretation in proof contexts **)
   865 
   866 local
   867 
   868 fun gen_interpret prep_expr
   869     expression int state =
   870   let
   871     val _ = Proof.assert_forward_or_chain state;
   872     val ctxt = Proof.context_of state;
   873 
   874     val ((propss, regs, export), goal_ctxt) = prep_expr expression ctxt;
   875 
   876     fun store_reg (name, morph) thms =
   877       let
   878         val morph' = morph $> Element.satisfy_morphism thms $> export;
   879       in Locale.activate_local_facts (name, morph') end;
   880 
   881     fun after_qed wits =
   882       Proof.map_context (fold2 store_reg regs wits);
   883   in
   884     state
   885     |> Element.witness_local_proof after_qed "interpret" propss goal_ctxt int
   886   end;
   887 
   888 in
   889 
   890 fun interpret x = gen_interpret cert_goal_expression x;
   891 fun interpret_cmd x = gen_interpret read_goal_expression x;
   892 
   893 end;
   894 
   895 end;
   896