src/HOL/Probability/Probability_Mass_Function.thy
author paulson <lp15@cam.ac.uk>
Tue Mar 17 12:23:56 2015 +0000 (2015-03-17)
changeset 59731 7fccaeec22f0
parent 59730 b7c394c7a619
parent 59681 f24ab09e4c37
child 60068 ef2123db900c
permissions -rw-r--r--
Merge
     1 (*  Title:      HOL/Probability/Probability_Mass_Function.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Andreas Lochbihler, ETH Zurich
     4 *)
     5 
     6 section \<open> Probability mass function \<close>
     7 
     8 theory Probability_Mass_Function
     9 imports
    10   Giry_Monad
    11   "~~/src/HOL/Library/Multiset"
    12 begin
    13 
    14 lemma AE_emeasure_singleton:
    15   assumes x: "emeasure M {x} \<noteq> 0" and ae: "AE x in M. P x" shows "P x"
    16 proof -
    17   from x have x_M: "{x} \<in> sets M"
    18     by (auto intro: emeasure_notin_sets)
    19   from ae obtain N where N: "{x\<in>space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
    20     by (auto elim: AE_E)
    21   { assume "\<not> P x"
    22     with x_M[THEN sets.sets_into_space] N have "emeasure M {x} \<le> emeasure M N"
    23       by (intro emeasure_mono) auto
    24     with x N have False
    25       by (auto simp: emeasure_le_0_iff) }
    26   then show "P x" by auto
    27 qed
    28 
    29 lemma AE_measure_singleton: "measure M {x} \<noteq> 0 \<Longrightarrow> AE x in M. P x \<Longrightarrow> P x"
    30   by (metis AE_emeasure_singleton measure_def emeasure_empty measure_empty)
    31 
    32 lemma ereal_divide': "b \<noteq> 0 \<Longrightarrow> ereal (a / b) = ereal a / ereal b"
    33   using ereal_divide[of a b] by simp
    34 
    35 lemma (in finite_measure) countable_support:
    36   "countable {x. measure M {x} \<noteq> 0}"
    37 proof cases
    38   assume "measure M (space M) = 0"
    39   with bounded_measure measure_le_0_iff have "{x. measure M {x} \<noteq> 0} = {}"
    40     by auto
    41   then show ?thesis
    42     by simp
    43 next
    44   let ?M = "measure M (space M)" and ?m = "\<lambda>x. measure M {x}"
    45   assume "?M \<noteq> 0"
    46   then have *: "{x. ?m x \<noteq> 0} = (\<Union>n. {x. ?M / Suc n < ?m x})"
    47     using reals_Archimedean[of "?m x / ?M" for x]
    48     by (auto simp: field_simps not_le[symmetric] measure_nonneg divide_le_0_iff measure_le_0_iff)
    49   have **: "\<And>n. finite {x. ?M / Suc n < ?m x}"
    50   proof (rule ccontr)
    51     fix n assume "infinite {x. ?M / Suc n < ?m x}" (is "infinite ?X")
    52     then obtain X where "finite X" "card X = Suc (Suc n)" "X \<subseteq> ?X"
    53       by (metis infinite_arbitrarily_large)
    54     from this(3) have *: "\<And>x. x \<in> X \<Longrightarrow> ?M / Suc n \<le> ?m x"
    55       by auto
    56     { fix x assume "x \<in> X"
    57       from `?M \<noteq> 0` *[OF this] have "?m x \<noteq> 0" by (auto simp: field_simps measure_le_0_iff)
    58       then have "{x} \<in> sets M" by (auto dest: measure_notin_sets) }
    59     note singleton_sets = this
    60     have "?M < (\<Sum>x\<in>X. ?M / Suc n)"
    61       using `?M \<noteq> 0`
    62       by (simp add: `card X = Suc (Suc n)` real_eq_of_nat[symmetric] real_of_nat_Suc field_simps less_le measure_nonneg)
    63     also have "\<dots> \<le> (\<Sum>x\<in>X. ?m x)"
    64       by (rule setsum_mono) fact
    65     also have "\<dots> = measure M (\<Union>x\<in>X. {x})"
    66       using singleton_sets `finite X`
    67       by (intro finite_measure_finite_Union[symmetric]) (auto simp: disjoint_family_on_def)
    68     finally have "?M < measure M (\<Union>x\<in>X. {x})" .
    69     moreover have "measure M (\<Union>x\<in>X. {x}) \<le> ?M"
    70       using singleton_sets[THEN sets.sets_into_space] by (intro finite_measure_mono) auto
    71     ultimately show False by simp
    72   qed
    73   show ?thesis
    74     unfolding * by (intro countable_UN countableI_type countable_finite[OF **])
    75 qed
    76 
    77 lemma (in finite_measure) AE_support_countable:
    78   assumes [simp]: "sets M = UNIV"
    79   shows "(AE x in M. measure M {x} \<noteq> 0) \<longleftrightarrow> (\<exists>S. countable S \<and> (AE x in M. x \<in> S))"
    80 proof
    81   assume "\<exists>S. countable S \<and> (AE x in M. x \<in> S)"
    82   then obtain S where S[intro]: "countable S" and ae: "AE x in M. x \<in> S"
    83     by auto
    84   then have "emeasure M (\<Union>x\<in>{x\<in>S. emeasure M {x} \<noteq> 0}. {x}) =
    85     (\<integral>\<^sup>+ x. emeasure M {x} * indicator {x\<in>S. emeasure M {x} \<noteq> 0} x \<partial>count_space UNIV)"
    86     by (subst emeasure_UN_countable)
    87        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    88   also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} * indicator S x \<partial>count_space UNIV)"
    89     by (auto intro!: nn_integral_cong split: split_indicator)
    90   also have "\<dots> = emeasure M (\<Union>x\<in>S. {x})"
    91     by (subst emeasure_UN_countable)
    92        (auto simp: disjoint_family_on_def nn_integral_restrict_space[symmetric] restrict_count_space)
    93   also have "\<dots> = emeasure M (space M)"
    94     using ae by (intro emeasure_eq_AE) auto
    95   finally have "emeasure M {x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0} = emeasure M (space M)"
    96     by (simp add: emeasure_single_in_space cong: rev_conj_cong)
    97   with finite_measure_compl[of "{x \<in> space M. x\<in>S \<and> emeasure M {x} \<noteq> 0}"]
    98   have "AE x in M. x \<in> S \<and> emeasure M {x} \<noteq> 0"
    99     by (intro AE_I[OF order_refl]) (auto simp: emeasure_eq_measure set_diff_eq cong: conj_cong)
   100   then show "AE x in M. measure M {x} \<noteq> 0"
   101     by (auto simp: emeasure_eq_measure)
   102 qed (auto intro!: exI[of _ "{x. measure M {x} \<noteq> 0}"] countable_support)
   103 
   104 subsection \<open> PMF as measure \<close>
   105 
   106 typedef 'a pmf = "{M :: 'a measure. prob_space M \<and> sets M = UNIV \<and> (AE x in M. measure M {x} \<noteq> 0)}"
   107   morphisms measure_pmf Abs_pmf
   108   by (intro exI[of _ "uniform_measure (count_space UNIV) {undefined}"])
   109      (auto intro!: prob_space_uniform_measure AE_uniform_measureI)
   110 
   111 declare [[coercion measure_pmf]]
   112 
   113 lemma prob_space_measure_pmf: "prob_space (measure_pmf p)"
   114   using pmf.measure_pmf[of p] by auto
   115 
   116 interpretation measure_pmf!: prob_space "measure_pmf M" for M
   117   by (rule prob_space_measure_pmf)
   118 
   119 interpretation measure_pmf!: subprob_space "measure_pmf M" for M
   120   by (rule prob_space_imp_subprob_space) unfold_locales
   121 
   122 lemma subprob_space_measure_pmf: "subprob_space (measure_pmf x)"
   123   by unfold_locales
   124 
   125 locale pmf_as_measure
   126 begin
   127 
   128 setup_lifting type_definition_pmf
   129 
   130 end
   131 
   132 context
   133 begin
   134 
   135 interpretation pmf_as_measure .
   136 
   137 lemma sets_measure_pmf[simp]: "sets (measure_pmf p) = UNIV"
   138   by transfer blast
   139 
   140 lemma sets_measure_pmf_count_space[measurable_cong]:
   141   "sets (measure_pmf M) = sets (count_space UNIV)"
   142   by simp
   143 
   144 lemma space_measure_pmf[simp]: "space (measure_pmf p) = UNIV"
   145   using sets_eq_imp_space_eq[of "measure_pmf p" "count_space UNIV"] by simp
   146 
   147 lemma measure_pmf_in_subprob_algebra[measurable (raw)]: "measure_pmf x \<in> space (subprob_algebra (count_space UNIV))"
   148   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   149 
   150 lemma measurable_pmf_measure1[simp]: "measurable (M :: 'a pmf) N = UNIV \<rightarrow> space N"
   151   by (auto simp: measurable_def)
   152 
   153 lemma measurable_pmf_measure2[simp]: "measurable N (M :: 'a pmf) = measurable N (count_space UNIV)"
   154   by (intro measurable_cong_sets) simp_all
   155 
   156 lemma measurable_pair_restrict_pmf2:
   157   assumes "countable A"
   158   assumes [measurable]: "\<And>y. y \<in> A \<Longrightarrow> (\<lambda>x. f (x, y)) \<in> measurable M L"
   159   shows "f \<in> measurable (M \<Otimes>\<^sub>M restrict_space (measure_pmf N) A) L" (is "f \<in> measurable ?M _")
   160 proof -
   161   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   162     by (simp add: restrict_count_space)
   163 
   164   show ?thesis
   165     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (fst b, a)" and g=snd and I=A,
   166                                             unfolded pair_collapse] assms)
   167         measurable
   168 qed
   169 
   170 lemma measurable_pair_restrict_pmf1:
   171   assumes "countable A"
   172   assumes [measurable]: "\<And>x. x \<in> A \<Longrightarrow> (\<lambda>y. f (x, y)) \<in> measurable N L"
   173   shows "f \<in> measurable (restrict_space (measure_pmf M) A \<Otimes>\<^sub>M N) L"
   174 proof -
   175   have [measurable_cong]: "sets (restrict_space (count_space UNIV) A) = sets (count_space A)"
   176     by (simp add: restrict_count_space)
   177 
   178   show ?thesis
   179     by (intro measurable_compose_countable'[where f="\<lambda>a b. f (a, snd b)" and g=fst and I=A,
   180                                             unfolded pair_collapse] assms)
   181         measurable
   182 qed
   183 
   184 lift_definition pmf :: "'a pmf \<Rightarrow> 'a \<Rightarrow> real" is "\<lambda>M x. measure M {x}" .
   185 
   186 lift_definition set_pmf :: "'a pmf \<Rightarrow> 'a set" is "\<lambda>M. {x. measure M {x} \<noteq> 0}" .
   187 declare [[coercion set_pmf]]
   188 
   189 lemma AE_measure_pmf: "AE x in (M::'a pmf). x \<in> M"
   190   by transfer simp
   191 
   192 lemma emeasure_pmf_single_eq_zero_iff:
   193   fixes M :: "'a pmf"
   194   shows "emeasure M {y} = 0 \<longleftrightarrow> y \<notin> M"
   195   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   196 
   197 lemma AE_measure_pmf_iff: "(AE x in measure_pmf M. P x) \<longleftrightarrow> (\<forall>y\<in>M. P y)"
   198   using AE_measure_singleton[of M] AE_measure_pmf[of M]
   199   by (auto simp: set_pmf.rep_eq)
   200 
   201 lemma countable_set_pmf [simp]: "countable (set_pmf p)"
   202   by transfer (metis prob_space.finite_measure finite_measure.countable_support)
   203 
   204 lemma pmf_positive: "x \<in> set_pmf p \<Longrightarrow> 0 < pmf p x"
   205   by transfer (simp add: less_le measure_nonneg)
   206 
   207 lemma pmf_nonneg: "0 \<le> pmf p x"
   208   by transfer (simp add: measure_nonneg)
   209 
   210 lemma pmf_le_1: "pmf p x \<le> 1"
   211   by (simp add: pmf.rep_eq)
   212 
   213 lemma set_pmf_not_empty: "set_pmf M \<noteq> {}"
   214   using AE_measure_pmf[of M] by (intro notI) simp
   215 
   216 lemma set_pmf_iff: "x \<in> set_pmf M \<longleftrightarrow> pmf M x \<noteq> 0"
   217   by transfer simp
   218 
   219 lemma set_pmf_eq: "set_pmf M = {x. pmf M x \<noteq> 0}"
   220   by (auto simp: set_pmf_iff)
   221 
   222 lemma emeasure_pmf_single:
   223   fixes M :: "'a pmf"
   224   shows "emeasure M {x} = pmf M x"
   225   by transfer (simp add: finite_measure.emeasure_eq_measure[OF prob_space.finite_measure])
   226 
   227 lemma emeasure_measure_pmf_finite: "finite S \<Longrightarrow> emeasure (measure_pmf M) S = (\<Sum>s\<in>S. pmf M s)"
   228   by (subst emeasure_eq_setsum_singleton) (auto simp: emeasure_pmf_single)
   229 
   230 lemma measure_measure_pmf_finite: "finite S \<Longrightarrow> measure (measure_pmf M) S = setsum (pmf M) S"
   231   using emeasure_measure_pmf_finite[of S M] by(simp add: measure_pmf.emeasure_eq_measure)
   232 
   233 lemma nn_integral_measure_pmf_support:
   234   fixes f :: "'a \<Rightarrow> ereal"
   235   assumes f: "finite A" and nn: "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x" "\<And>x. x \<in> set_pmf M \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = 0"
   236   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>A. f x * pmf M x)"
   237 proof -
   238   have "(\<integral>\<^sup>+x. f x \<partial>M) = (\<integral>\<^sup>+x. f x * indicator A x \<partial>M)"
   239     using nn by (intro nn_integral_cong_AE) (auto simp: AE_measure_pmf_iff split: split_indicator)
   240   also have "\<dots> = (\<Sum>x\<in>A. f x * emeasure M {x})"
   241     using assms by (intro nn_integral_indicator_finite) auto
   242   finally show ?thesis
   243     by (simp add: emeasure_measure_pmf_finite)
   244 qed
   245 
   246 lemma nn_integral_measure_pmf_finite:
   247   fixes f :: "'a \<Rightarrow> ereal"
   248   assumes f: "finite (set_pmf M)" and nn: "\<And>x. x \<in> set_pmf M \<Longrightarrow> 0 \<le> f x"
   249   shows "(\<integral>\<^sup>+x. f x \<partial>measure_pmf M) = (\<Sum>x\<in>set_pmf M. f x * pmf M x)"
   250   using assms by (intro nn_integral_measure_pmf_support) auto
   251 lemma integrable_measure_pmf_finite:
   252   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
   253   shows "finite (set_pmf M) \<Longrightarrow> integrable M f"
   254   by (auto intro!: integrableI_bounded simp: nn_integral_measure_pmf_finite)
   255 
   256 lemma integral_measure_pmf:
   257   assumes [simp]: "finite A" and "\<And>a. a \<in> set_pmf M \<Longrightarrow> f a \<noteq> 0 \<Longrightarrow> a \<in> A"
   258   shows "(\<integral>x. f x \<partial>measure_pmf M) = (\<Sum>a\<in>A. f a * pmf M a)"
   259 proof -
   260   have "(\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x * indicator A x \<partial>measure_pmf M)"
   261     using assms(2) by (intro integral_cong_AE) (auto split: split_indicator simp: AE_measure_pmf_iff)
   262   also have "\<dots> = (\<Sum>a\<in>A. f a * pmf M a)"
   263     by (subst integral_indicator_finite_real) (auto simp: measure_def emeasure_measure_pmf_finite)
   264   finally show ?thesis .
   265 qed
   266 
   267 lemma integrable_pmf: "integrable (count_space X) (pmf M)"
   268 proof -
   269   have " (\<integral>\<^sup>+ x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+ x. pmf M x \<partial>count_space (M \<inter> X))"
   270     by (auto simp add: nn_integral_count_space_indicator set_pmf_iff intro!: nn_integral_cong split: split_indicator)
   271   then have "integrable (count_space X) (pmf M) = integrable (count_space (M \<inter> X)) (pmf M)"
   272     by (simp add: integrable_iff_bounded pmf_nonneg)
   273   then show ?thesis
   274     by (simp add: pmf.rep_eq measure_pmf.integrable_measure disjoint_family_on_def)
   275 qed
   276 
   277 lemma integral_pmf: "(\<integral>x. pmf M x \<partial>count_space X) = measure M X"
   278 proof -
   279   have "(\<integral>x. pmf M x \<partial>count_space X) = (\<integral>\<^sup>+x. pmf M x \<partial>count_space X)"
   280     by (simp add: pmf_nonneg integrable_pmf nn_integral_eq_integral)
   281   also have "\<dots> = (\<integral>\<^sup>+x. emeasure M {x} \<partial>count_space (X \<inter> M))"
   282     by (auto intro!: nn_integral_cong_AE split: split_indicator
   283              simp: pmf.rep_eq measure_pmf.emeasure_eq_measure nn_integral_count_space_indicator
   284                    AE_count_space set_pmf_iff)
   285   also have "\<dots> = emeasure M (X \<inter> M)"
   286     by (rule emeasure_countable_singleton[symmetric]) (auto intro: countable_set_pmf)
   287   also have "\<dots> = emeasure M X"
   288     by (auto intro!: emeasure_eq_AE simp: AE_measure_pmf_iff)
   289   finally show ?thesis
   290     by (simp add: measure_pmf.emeasure_eq_measure)
   291 qed
   292 
   293 lemma integral_pmf_restrict:
   294   "(f::'a \<Rightarrow> 'b::{banach, second_countable_topology}) \<in> borel_measurable (count_space UNIV) \<Longrightarrow>
   295     (\<integral>x. f x \<partial>measure_pmf M) = (\<integral>x. f x \<partial>restrict_space M M)"
   296   by (auto intro!: integral_cong_AE simp add: integral_restrict_space AE_measure_pmf_iff)
   297 
   298 lemma emeasure_pmf: "emeasure (M::'a pmf) M = 1"
   299 proof -
   300   have "emeasure (M::'a pmf) M = emeasure (M::'a pmf) (space M)"
   301     by (intro emeasure_eq_AE) (simp_all add: AE_measure_pmf)
   302   then show ?thesis
   303     using measure_pmf.emeasure_space_1 by simp
   304 qed
   305 
   306 lemma emeasure_pmf_UNIV [simp]: "emeasure (measure_pmf M) UNIV = 1"
   307 using measure_pmf.emeasure_space_1[of M] by simp
   308 
   309 lemma in_null_sets_measure_pmfI:
   310   "A \<inter> set_pmf p = {} \<Longrightarrow> A \<in> null_sets (measure_pmf p)"
   311 using emeasure_eq_0_AE[where ?P="\<lambda>x. x \<in> A" and M="measure_pmf p"]
   312 by(auto simp add: null_sets_def AE_measure_pmf_iff)
   313 
   314 lemma measure_subprob: "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   315   by (simp add: space_subprob_algebra subprob_space_measure_pmf)
   316 
   317 subsection \<open> Monad Interpretation \<close>
   318 
   319 lemma measurable_measure_pmf[measurable]:
   320   "(\<lambda>x. measure_pmf (M x)) \<in> measurable (count_space UNIV) (subprob_algebra (count_space UNIV))"
   321   by (auto simp: space_subprob_algebra intro!: prob_space_imp_subprob_space) unfold_locales
   322 
   323 lemma bind_measure_pmf_cong:
   324   assumes "\<And>x. A x \<in> space (subprob_algebra N)" "\<And>x. B x \<in> space (subprob_algebra N)"
   325   assumes "\<And>i. i \<in> set_pmf x \<Longrightarrow> A i = B i"
   326   shows "bind (measure_pmf x) A = bind (measure_pmf x) B"
   327 proof (rule measure_eqI)
   328   show "sets (measure_pmf x \<guillemotright>= A) = sets (measure_pmf x \<guillemotright>= B)"
   329     using assms by (subst (1 2) sets_bind) (auto simp: space_subprob_algebra)
   330 next
   331   fix X assume "X \<in> sets (measure_pmf x \<guillemotright>= A)"
   332   then have X: "X \<in> sets N"
   333     using assms by (subst (asm) sets_bind) (auto simp: space_subprob_algebra)
   334   show "emeasure (measure_pmf x \<guillemotright>= A) X = emeasure (measure_pmf x \<guillemotright>= B) X"
   335     using assms
   336     by (subst (1 2) emeasure_bind[where N=N, OF _ _ X])
   337        (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   338 qed
   339 
   340 lift_definition bind_pmf :: "'a pmf \<Rightarrow> ('a \<Rightarrow> 'b pmf ) \<Rightarrow> 'b pmf" is bind
   341 proof (clarify, intro conjI)
   342   fix f :: "'a measure" and g :: "'a \<Rightarrow> 'b measure"
   343   assume "prob_space f"
   344   then interpret f: prob_space f .
   345   assume "sets f = UNIV" and ae_f: "AE x in f. measure f {x} \<noteq> 0"
   346   then have s_f[simp]: "sets f = sets (count_space UNIV)"
   347     by simp
   348   assume g: "\<And>x. prob_space (g x) \<and> sets (g x) = UNIV \<and> (AE y in g x. measure (g x) {y} \<noteq> 0)"
   349   then have g: "\<And>x. prob_space (g x)" and s_g[simp]: "\<And>x. sets (g x) = sets (count_space UNIV)"
   350     and ae_g: "\<And>x. AE y in g x. measure (g x) {y} \<noteq> 0"
   351     by auto
   352 
   353   have [measurable]: "g \<in> measurable f (subprob_algebra (count_space UNIV))"
   354     by (auto simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space g)
   355 
   356   show "prob_space (f \<guillemotright>= g)"
   357     using g by (intro f.prob_space_bind[where S="count_space UNIV"]) auto
   358   then interpret fg: prob_space "f \<guillemotright>= g" .
   359   show [simp]: "sets (f \<guillemotright>= g) = UNIV"
   360     using sets_eq_imp_space_eq[OF s_f]
   361     by (subst sets_bind[where N="count_space UNIV"]) auto
   362   show "AE x in f \<guillemotright>= g. measure (f \<guillemotright>= g) {x} \<noteq> 0"
   363     apply (simp add: fg.prob_eq_0 AE_bind[where B="count_space UNIV"])
   364     using ae_f
   365     apply eventually_elim
   366     using ae_g
   367     apply eventually_elim
   368     apply (auto dest: AE_measure_singleton)
   369     done
   370 qed
   371 
   372 lemma ereal_pmf_bind: "pmf (bind_pmf N f) i = (\<integral>\<^sup>+x. pmf (f x) i \<partial>measure_pmf N)"
   373   unfolding pmf.rep_eq bind_pmf.rep_eq
   374   by (auto simp: measure_pmf.measure_bind[where N="count_space UNIV"] measure_subprob measure_nonneg
   375            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   376 
   377 lemma pmf_bind: "pmf (bind_pmf N f) i = (\<integral>x. pmf (f x) i \<partial>measure_pmf N)"
   378   using ereal_pmf_bind[of N f i]
   379   by (subst (asm) nn_integral_eq_integral)
   380      (auto simp: pmf_nonneg pmf_le_1
   381            intro!: nn_integral_eq_integral[symmetric] measure_pmf.integrable_const_bound[where B=1])
   382 
   383 lemma bind_pmf_const[simp]: "bind_pmf M (\<lambda>x. c) = c"
   384   by transfer (simp add: bind_const' prob_space_imp_subprob_space)
   385 
   386 lemma set_bind_pmf[simp]: "set_pmf (bind_pmf M N) = (\<Union>M\<in>set_pmf M. set_pmf (N M))"
   387   unfolding set_pmf_eq ereal_eq_0(1)[symmetric] ereal_pmf_bind
   388   by (auto simp add: nn_integral_0_iff_AE AE_measure_pmf_iff set_pmf_eq not_le less_le pmf_nonneg)
   389 
   390 lemma bind_pmf_cong:
   391   assumes "p = q"
   392   shows "(\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   393   unfolding `p = q`[symmetric] measure_pmf_inject[symmetric] bind_pmf.rep_eq
   394   by (auto simp: AE_measure_pmf_iff Pi_iff space_subprob_algebra subprob_space_measure_pmf
   395                  sets_bind[where N="count_space UNIV"] emeasure_bind[where N="count_space UNIV"]
   396            intro!: nn_integral_cong_AE measure_eqI)
   397 
   398 lemma bind_pmf_cong_simp:
   399   "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q =simp=> f x = g x) \<Longrightarrow> bind_pmf p f = bind_pmf q g"
   400   by (simp add: simp_implies_def cong: bind_pmf_cong)
   401 
   402 lemma measure_pmf_bind: "measure_pmf (bind_pmf M f) = (measure_pmf M \<guillemotright>= (\<lambda>x. measure_pmf (f x)))"
   403   by transfer simp
   404 
   405 lemma nn_integral_bind_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>bind_pmf M N) = (\<integral>\<^sup>+x. \<integral>\<^sup>+y. f y \<partial>N x \<partial>M)"
   406   using measurable_measure_pmf[of N]
   407   unfolding measure_pmf_bind
   408   apply (subst (1 3) nn_integral_max_0[symmetric])
   409   apply (intro nn_integral_bind[where B="count_space UNIV"])
   410   apply auto
   411   done
   412 
   413 lemma emeasure_bind_pmf[simp]: "emeasure (bind_pmf M N) X = (\<integral>\<^sup>+x. emeasure (N x) X \<partial>M)"
   414   using measurable_measure_pmf[of N]
   415   unfolding measure_pmf_bind
   416   by (subst emeasure_bind[where N="count_space UNIV"]) auto
   417 
   418 lift_definition return_pmf :: "'a \<Rightarrow> 'a pmf" is "return (count_space UNIV)"
   419   by (auto intro!: prob_space_return simp: AE_return measure_return)
   420 
   421 lemma bind_return_pmf: "bind_pmf (return_pmf x) f = f x"
   422   by transfer
   423      (auto intro!: prob_space_imp_subprob_space bind_return[where N="count_space UNIV"]
   424            simp: space_subprob_algebra)
   425 
   426 lemma set_return_pmf[simp]: "set_pmf (return_pmf x) = {x}"
   427   by transfer (auto simp add: measure_return split: split_indicator)
   428 
   429 lemma bind_return_pmf': "bind_pmf N return_pmf = N"
   430 proof (transfer, clarify)
   431   fix N :: "'a measure" assume "sets N = UNIV" then show "N \<guillemotright>= return (count_space UNIV) = N"
   432     by (subst return_sets_cong[where N=N]) (simp_all add: bind_return')
   433 qed
   434 
   435 lemma bind_assoc_pmf: "bind_pmf (bind_pmf A B) C = bind_pmf A (\<lambda>x. bind_pmf (B x) C)"
   436   by transfer
   437      (auto intro!: bind_assoc[where N="count_space UNIV" and R="count_space UNIV"]
   438            simp: measurable_def space_subprob_algebra prob_space_imp_subprob_space)
   439 
   440 definition "map_pmf f M = bind_pmf M (\<lambda>x. return_pmf (f x))"
   441 
   442 lemma map_bind_pmf: "map_pmf f (bind_pmf M g) = bind_pmf M (\<lambda>x. map_pmf f (g x))"
   443   by (simp add: map_pmf_def bind_assoc_pmf)
   444 
   445 lemma bind_map_pmf: "bind_pmf (map_pmf f M) g = bind_pmf M (\<lambda>x. g (f x))"
   446   by (simp add: map_pmf_def bind_assoc_pmf bind_return_pmf)
   447 
   448 lemma map_pmf_transfer[transfer_rule]:
   449   "rel_fun op = (rel_fun cr_pmf cr_pmf) (\<lambda>f M. distr M (count_space UNIV) f) map_pmf"
   450 proof -
   451   have "rel_fun op = (rel_fun pmf_as_measure.cr_pmf pmf_as_measure.cr_pmf)
   452      (\<lambda>f M. M \<guillemotright>= (return (count_space UNIV) o f)) map_pmf"
   453     unfolding map_pmf_def[abs_def] comp_def by transfer_prover
   454   then show ?thesis
   455     by (force simp: rel_fun_def cr_pmf_def bind_return_distr)
   456 qed
   457 
   458 lemma map_pmf_rep_eq:
   459   "measure_pmf (map_pmf f M) = distr (measure_pmf M) (count_space UNIV) f"
   460   unfolding map_pmf_def bind_pmf.rep_eq comp_def return_pmf.rep_eq
   461   using bind_return_distr[of M f "count_space UNIV"] by (simp add: comp_def)
   462 
   463 lemma map_pmf_id[simp]: "map_pmf id = id"
   464   by (rule, transfer) (auto simp: emeasure_distr measurable_def intro!: measure_eqI)
   465 
   466 lemma map_pmf_ident[simp]: "map_pmf (\<lambda>x. x) = (\<lambda>x. x)"
   467   using map_pmf_id unfolding id_def .
   468 
   469 lemma map_pmf_compose: "map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g"
   470   by (rule, transfer) (simp add: distr_distr[symmetric, where N="count_space UNIV"] measurable_def)
   471 
   472 lemma map_pmf_comp: "map_pmf f (map_pmf g M) = map_pmf (\<lambda>x. f (g x)) M"
   473   using map_pmf_compose[of f g] by (simp add: comp_def)
   474 
   475 lemma map_pmf_cong: "p = q \<Longrightarrow> (\<And>x. x \<in> set_pmf q \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g q"
   476   unfolding map_pmf_def by (rule bind_pmf_cong) auto
   477 
   478 lemma pmf_set_map: "set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
   479   by (auto simp add: comp_def fun_eq_iff map_pmf_def)
   480 
   481 lemma set_map_pmf[simp]: "set_pmf (map_pmf f M) = f`set_pmf M"
   482   using pmf_set_map[of f] by (auto simp: comp_def fun_eq_iff)
   483 
   484 lemma emeasure_map_pmf[simp]: "emeasure (map_pmf f M) X = emeasure M (f -` X)"
   485   unfolding map_pmf_rep_eq by (subst emeasure_distr) auto
   486 
   487 lemma nn_integral_map_pmf[simp]: "(\<integral>\<^sup>+x. f x \<partial>map_pmf g M) = (\<integral>\<^sup>+x. f (g x) \<partial>M)"
   488   unfolding map_pmf_rep_eq by (intro nn_integral_distr) auto
   489 
   490 lemma ereal_pmf_map: "pmf (map_pmf f p) x = (\<integral>\<^sup>+ y. indicator (f -` {x}) y \<partial>measure_pmf p)"
   491 proof (transfer fixing: f x)
   492   fix p :: "'b measure"
   493   presume "prob_space p"
   494   then interpret prob_space p .
   495   presume "sets p = UNIV"
   496   then show "ereal (measure (distr p (count_space UNIV) f) {x}) = integral\<^sup>N p (indicator (f -` {x}))"
   497     by(simp add: measure_distr measurable_def emeasure_eq_measure)
   498 qed simp_all
   499 
   500 lemma nn_integral_pmf: "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = emeasure (measure_pmf p) A"
   501 proof -
   502   have "(\<integral>\<^sup>+ x. pmf p x \<partial>count_space A) = (\<integral>\<^sup>+ x. pmf p x \<partial>count_space (A \<inter> set_pmf p))"
   503     by(auto simp add: nn_integral_count_space_indicator indicator_def set_pmf_iff intro: nn_integral_cong)
   504   also have "\<dots> = emeasure (measure_pmf p) (\<Union>x\<in>A \<inter> set_pmf p. {x})"
   505     by(subst emeasure_UN_countable)(auto simp add: emeasure_pmf_single disjoint_family_on_def)
   506   also have "\<dots> = emeasure (measure_pmf p) ((\<Union>x\<in>A \<inter> set_pmf p. {x}) \<union> {x. x \<in> A \<and> x \<notin> set_pmf p})"
   507     by(rule emeasure_Un_null_set[symmetric])(auto intro: in_null_sets_measure_pmfI)
   508   also have "\<dots> = emeasure (measure_pmf p) A"
   509     by(auto intro: arg_cong2[where f=emeasure])
   510   finally show ?thesis .
   511 qed
   512 
   513 lemma map_return_pmf: "map_pmf f (return_pmf x) = return_pmf (f x)"
   514   by transfer (simp add: distr_return)
   515 
   516 lemma map_pmf_const[simp]: "map_pmf (\<lambda>_. c) M = return_pmf c"
   517   by transfer (auto simp: prob_space.distr_const)
   518 
   519 lemma pmf_return: "pmf (return_pmf x) y = indicator {y} x"
   520   by transfer (simp add: measure_return)
   521 
   522 lemma nn_integral_return_pmf[simp]: "0 \<le> f x \<Longrightarrow> (\<integral>\<^sup>+x. f x \<partial>return_pmf x) = f x"
   523   unfolding return_pmf.rep_eq by (intro nn_integral_return) auto
   524 
   525 lemma emeasure_return_pmf[simp]: "emeasure (return_pmf x) X = indicator X x"
   526   unfolding return_pmf.rep_eq by (intro emeasure_return) auto
   527 
   528 lemma return_pmf_inj[simp]: "return_pmf x = return_pmf y \<longleftrightarrow> x = y"
   529   by (metis insertI1 set_return_pmf singletonD)
   530 
   531 lemma map_pmf_eq_return_pmf_iff:
   532   "map_pmf f p = return_pmf x \<longleftrightarrow> (\<forall>y \<in> set_pmf p. f y = x)"
   533 proof
   534   assume "map_pmf f p = return_pmf x"
   535   then have "set_pmf (map_pmf f p) = set_pmf (return_pmf x)" by simp
   536   then show "\<forall>y \<in> set_pmf p. f y = x" by auto
   537 next
   538   assume "\<forall>y \<in> set_pmf p. f y = x"
   539   then show "map_pmf f p = return_pmf x"
   540     unfolding map_pmf_const[symmetric, of _ p] by (intro map_pmf_cong) auto
   541 qed
   542 
   543 definition "pair_pmf A B = bind_pmf A (\<lambda>x. bind_pmf B (\<lambda>y. return_pmf (x, y)))"
   544 
   545 lemma pmf_pair: "pmf (pair_pmf M N) (a, b) = pmf M a * pmf N b"
   546   unfolding pair_pmf_def pmf_bind pmf_return
   547   apply (subst integral_measure_pmf[where A="{b}"])
   548   apply (auto simp: indicator_eq_0_iff)
   549   apply (subst integral_measure_pmf[where A="{a}"])
   550   apply (auto simp: indicator_eq_0_iff setsum_nonneg_eq_0_iff pmf_nonneg)
   551   done
   552 
   553 lemma set_pair_pmf[simp]: "set_pmf (pair_pmf A B) = set_pmf A \<times> set_pmf B"
   554   unfolding pair_pmf_def set_bind_pmf set_return_pmf by auto
   555 
   556 lemma measure_pmf_in_subprob_space[measurable (raw)]:
   557   "measure_pmf M \<in> space (subprob_algebra (count_space UNIV))"
   558   by (simp add: space_subprob_algebra) intro_locales
   559 
   560 lemma nn_integral_pair_pmf': "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. f (a, b) \<partial>B \<partial>A)"
   561 proof -
   562   have "(\<integral>\<^sup>+x. f x \<partial>pair_pmf A B) = (\<integral>\<^sup>+x. max 0 (f x) * indicator (A \<times> B) x \<partial>pair_pmf A B)"
   563     by (subst nn_integral_max_0[symmetric])
   564        (auto simp: AE_measure_pmf_iff intro!: nn_integral_cong_AE)
   565   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) * indicator (A \<times> B) (a, b) \<partial>B \<partial>A)"
   566     by (simp add: pair_pmf_def)
   567   also have "\<dots> = (\<integral>\<^sup>+a. \<integral>\<^sup>+b. max 0 (f (a, b)) \<partial>B \<partial>A)"
   568     by (auto intro!: nn_integral_cong_AE simp: AE_measure_pmf_iff)
   569   finally show ?thesis
   570     unfolding nn_integral_max_0 .
   571 qed
   572 
   573 lemma bind_pair_pmf:
   574   assumes M[measurable]: "M \<in> measurable (count_space UNIV \<Otimes>\<^sub>M count_space UNIV) (subprob_algebra N)"
   575   shows "measure_pmf (pair_pmf A B) \<guillemotright>= M = (measure_pmf A \<guillemotright>= (\<lambda>x. measure_pmf B \<guillemotright>= (\<lambda>y. M (x, y))))"
   576     (is "?L = ?R")
   577 proof (rule measure_eqI)
   578   have M'[measurable]: "M \<in> measurable (pair_pmf A B) (subprob_algebra N)"
   579     using M[THEN measurable_space] by (simp_all add: space_pair_measure)
   580 
   581   note measurable_bind[where N="count_space UNIV", measurable]
   582   note measure_pmf_in_subprob_space[simp]
   583 
   584   have sets_eq_N: "sets ?L = N"
   585     by (subst sets_bind[OF sets_kernel[OF M']]) auto
   586   show "sets ?L = sets ?R"
   587     using measurable_space[OF M]
   588     by (simp add: sets_eq_N space_pair_measure space_subprob_algebra)
   589   fix X assume "X \<in> sets ?L"
   590   then have X[measurable]: "X \<in> sets N"
   591     unfolding sets_eq_N .
   592   then show "emeasure ?L X = emeasure ?R X"
   593     apply (simp add: emeasure_bind[OF _ M' X])
   594     apply (simp add: nn_integral_bind[where B="count_space UNIV"] pair_pmf_def measure_pmf_bind[of A]
   595                      nn_integral_measure_pmf_finite emeasure_nonneg pmf_return one_ereal_def[symmetric])
   596     apply (subst emeasure_bind[OF _ _ X])
   597     apply measurable
   598     apply (subst emeasure_bind[OF _ _ X])
   599     apply measurable
   600     done
   601 qed
   602 
   603 lemma map_fst_pair_pmf: "map_pmf fst (pair_pmf A B) = A"
   604   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   605 
   606 lemma map_snd_pair_pmf: "map_pmf snd (pair_pmf A B) = B"
   607   by (simp add: pair_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
   608 
   609 lemma nn_integral_pmf':
   610   "inj_on f A \<Longrightarrow> (\<integral>\<^sup>+x. pmf p (f x) \<partial>count_space A) = emeasure p (f ` A)"
   611   by (subst nn_integral_bij_count_space[where g=f and B="f`A"])
   612      (auto simp: bij_betw_def nn_integral_pmf)
   613 
   614 lemma pmf_le_0_iff[simp]: "pmf M p \<le> 0 \<longleftrightarrow> pmf M p = 0"
   615   using pmf_nonneg[of M p] by simp
   616 
   617 lemma min_pmf_0[simp]: "min (pmf M p) 0 = 0" "min 0 (pmf M p) = 0"
   618   using pmf_nonneg[of M p] by simp_all
   619 
   620 lemma pmf_eq_0_set_pmf: "pmf M p = 0 \<longleftrightarrow> p \<notin> set_pmf M"
   621   unfolding set_pmf_iff by simp
   622 
   623 lemma pmf_map_inj: "inj_on f (set_pmf M) \<Longrightarrow> x \<in> set_pmf M \<Longrightarrow> pmf (map_pmf f M) (f x) = pmf M x"
   624   by (auto simp: pmf.rep_eq map_pmf_rep_eq measure_distr AE_measure_pmf_iff inj_onD
   625            intro!: measure_pmf.finite_measure_eq_AE)
   626 
   627 subsection \<open> PMFs as function \<close>
   628 
   629 context
   630   fixes f :: "'a \<Rightarrow> real"
   631   assumes nonneg: "\<And>x. 0 \<le> f x"
   632   assumes prob: "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   633 begin
   634 
   635 lift_definition embed_pmf :: "'a pmf" is "density (count_space UNIV) (ereal \<circ> f)"
   636 proof (intro conjI)
   637   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   638     by (simp split: split_indicator)
   639   show "AE x in density (count_space UNIV) (ereal \<circ> f).
   640     measure (density (count_space UNIV) (ereal \<circ> f)) {x} \<noteq> 0"
   641     by (simp add: AE_density nonneg measure_def emeasure_density max_def)
   642   show "prob_space (density (count_space UNIV) (ereal \<circ> f))"
   643     by default (simp add: emeasure_density prob)
   644 qed simp
   645 
   646 lemma pmf_embed_pmf: "pmf embed_pmf x = f x"
   647 proof transfer
   648   have *[simp]: "\<And>x y. ereal (f y) * indicator {x} y = ereal (f x) * indicator {x} y"
   649     by (simp split: split_indicator)
   650   fix x show "measure (density (count_space UNIV) (ereal \<circ> f)) {x} = f x"
   651     by transfer (simp add: measure_def emeasure_density nonneg max_def)
   652 qed
   653 
   654 end
   655 
   656 lemma embed_pmf_transfer:
   657   "rel_fun (eq_onp (\<lambda>f. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1)) pmf_as_measure.cr_pmf (\<lambda>f. density (count_space UNIV) (ereal \<circ> f)) embed_pmf"
   658   by (auto simp: rel_fun_def eq_onp_def embed_pmf.transfer)
   659 
   660 lemma measure_pmf_eq_density: "measure_pmf p = density (count_space UNIV) (pmf p)"
   661 proof (transfer, elim conjE)
   662   fix M :: "'a measure" assume [simp]: "sets M = UNIV" and ae: "AE x in M. measure M {x} \<noteq> 0"
   663   assume "prob_space M" then interpret prob_space M .
   664   show "M = density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))"
   665   proof (rule measure_eqI)
   666     fix A :: "'a set"
   667     have "(\<integral>\<^sup>+ x. ereal (measure M {x}) * indicator A x \<partial>count_space UNIV) =
   668       (\<integral>\<^sup>+ x. emeasure M {x} * indicator (A \<inter> {x. measure M {x} \<noteq> 0}) x \<partial>count_space UNIV)"
   669       by (auto intro!: nn_integral_cong simp: emeasure_eq_measure split: split_indicator)
   670     also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} \<partial>count_space (A \<inter> {x. measure M {x} \<noteq> 0}))"
   671       by (subst nn_integral_restrict_space[symmetric]) (auto simp: restrict_count_space)
   672     also have "\<dots> = emeasure M (\<Union>x\<in>(A \<inter> {x. measure M {x} \<noteq> 0}). {x})"
   673       by (intro emeasure_UN_countable[symmetric] countable_Int2 countable_support)
   674          (auto simp: disjoint_family_on_def)
   675     also have "\<dots> = emeasure M A"
   676       using ae by (intro emeasure_eq_AE) auto
   677     finally show " emeasure M A = emeasure (density (count_space UNIV) (\<lambda>x. ereal (measure M {x}))) A"
   678       using emeasure_space_1 by (simp add: emeasure_density)
   679   qed simp
   680 qed
   681 
   682 lemma td_pmf_embed_pmf:
   683   "type_definition pmf embed_pmf {f::'a \<Rightarrow> real. (\<forall>x. 0 \<le> f x) \<and> (\<integral>\<^sup>+x. ereal (f x) \<partial>count_space UNIV) = 1}"
   684   unfolding type_definition_def
   685 proof safe
   686   fix p :: "'a pmf"
   687   have "(\<integral>\<^sup>+ x. 1 \<partial>measure_pmf p) = 1"
   688     using measure_pmf.emeasure_space_1[of p] by simp
   689   then show *: "(\<integral>\<^sup>+ x. ereal (pmf p x) \<partial>count_space UNIV) = 1"
   690     by (simp add: measure_pmf_eq_density nn_integral_density pmf_nonneg del: nn_integral_const)
   691 
   692   show "embed_pmf (pmf p) = p"
   693     by (intro measure_pmf_inject[THEN iffD1])
   694        (simp add: * embed_pmf.rep_eq pmf_nonneg measure_pmf_eq_density[of p] comp_def)
   695 next
   696   fix f :: "'a \<Rightarrow> real" assume "\<forall>x. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>count_space UNIV) = 1"
   697   then show "pmf (embed_pmf f) = f"
   698     by (auto intro!: pmf_embed_pmf)
   699 qed (rule pmf_nonneg)
   700 
   701 end
   702 
   703 locale pmf_as_function
   704 begin
   705 
   706 setup_lifting td_pmf_embed_pmf
   707 
   708 lemma set_pmf_transfer[transfer_rule]:
   709   assumes "bi_total A"
   710   shows "rel_fun (pcr_pmf A) (rel_set A) (\<lambda>f. {x. f x \<noteq> 0}) set_pmf"
   711   using `bi_total A`
   712   by (auto simp: pcr_pmf_def cr_pmf_def rel_fun_def rel_set_def bi_total_def Bex_def set_pmf_iff)
   713      metis+
   714 
   715 end
   716 
   717 context
   718 begin
   719 
   720 interpretation pmf_as_function .
   721 
   722 lemma pmf_eqI: "(\<And>i. pmf M i = pmf N i) \<Longrightarrow> M = N"
   723   by transfer auto
   724 
   725 lemma pmf_eq_iff: "M = N \<longleftrightarrow> (\<forall>i. pmf M i = pmf N i)"
   726   by (auto intro: pmf_eqI)
   727 
   728 lemma bind_commute_pmf: "bind_pmf A (\<lambda>x. bind_pmf B (C x)) = bind_pmf B (\<lambda>y. bind_pmf A (\<lambda>x. C x y))"
   729   unfolding pmf_eq_iff pmf_bind
   730 proof
   731   fix i
   732   interpret B: prob_space "restrict_space B B"
   733     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   734        (auto simp: AE_measure_pmf_iff)
   735   interpret A: prob_space "restrict_space A A"
   736     by (intro prob_space_restrict_space measure_pmf.emeasure_eq_1_AE)
   737        (auto simp: AE_measure_pmf_iff)
   738 
   739   interpret AB: pair_prob_space "restrict_space A A" "restrict_space B B"
   740     by unfold_locales
   741 
   742   have "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>A)"
   743     by (rule integral_cong) (auto intro!: integral_pmf_restrict)
   744   also have "\<dots> = (\<integral> x. (\<integral> y. pmf (C x y) i \<partial>restrict_space B B) \<partial>restrict_space A A)"
   745     by (intro integral_pmf_restrict B.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   746               countable_set_pmf borel_measurable_count_space)
   747   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>restrict_space B B)"
   748     by (rule AB.Fubini_integral[symmetric])
   749        (auto intro!: AB.integrable_const_bound[where B=1] measurable_pair_restrict_pmf2
   750              simp: pmf_nonneg pmf_le_1 measurable_restrict_space1)
   751   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>restrict_space A A \<partial>B)"
   752     by (intro integral_pmf_restrict[symmetric] A.borel_measurable_lebesgue_integral measurable_pair_restrict_pmf2
   753               countable_set_pmf borel_measurable_count_space)
   754   also have "\<dots> = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)"
   755     by (rule integral_cong) (auto intro!: integral_pmf_restrict[symmetric])
   756   finally show "(\<integral> x. \<integral> y. pmf (C x y) i \<partial>B \<partial>A) = (\<integral> y. \<integral> x. pmf (C x y) i \<partial>A \<partial>B)" .
   757 qed
   758 
   759 lemma pair_map_pmf1: "pair_pmf (map_pmf f A) B = map_pmf (apfst f) (pair_pmf A B)"
   760 proof (safe intro!: pmf_eqI)
   761   fix a :: "'a" and b :: "'b"
   762   have [simp]: "\<And>c d. indicator (apfst f -` {(a, b)}) (c, d) = indicator (f -` {a}) c * (indicator {b} d::ereal)"
   763     by (auto split: split_indicator)
   764 
   765   have "ereal (pmf (pair_pmf (map_pmf f A) B) (a, b)) =
   766          ereal (pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b))"
   767     unfolding pmf_pair ereal_pmf_map
   768     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_multc pmf_nonneg
   769                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   770   then show "pmf (pair_pmf (map_pmf f A) B) (a, b) = pmf (map_pmf (apfst f) (pair_pmf A B)) (a, b)"
   771     by simp
   772 qed
   773 
   774 lemma pair_map_pmf2: "pair_pmf A (map_pmf f B) = map_pmf (apsnd f) (pair_pmf A B)"
   775 proof (safe intro!: pmf_eqI)
   776   fix a :: "'a" and b :: "'b"
   777   have [simp]: "\<And>c d. indicator (apsnd f -` {(a, b)}) (c, d) = indicator {a} c * (indicator (f -` {b}) d::ereal)"
   778     by (auto split: split_indicator)
   779 
   780   have "ereal (pmf (pair_pmf A (map_pmf f B)) (a, b)) =
   781          ereal (pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b))"
   782     unfolding pmf_pair ereal_pmf_map
   783     by (simp add: nn_integral_pair_pmf' max_def emeasure_pmf_single nn_integral_cmult nn_integral_multc pmf_nonneg
   784                   emeasure_map_pmf[symmetric] del: emeasure_map_pmf)
   785   then show "pmf (pair_pmf A (map_pmf f B)) (a, b) = pmf (map_pmf (apsnd f) (pair_pmf A B)) (a, b)"
   786     by simp
   787 qed
   788 
   789 lemma map_pair: "map_pmf (\<lambda>(a, b). (f a, g b)) (pair_pmf A B) = pair_pmf (map_pmf f A) (map_pmf g B)"
   790   by (simp add: pair_map_pmf2 pair_map_pmf1 map_pmf_comp split_beta')
   791 
   792 end
   793 
   794 subsection \<open> Conditional Probabilities \<close>
   795 
   796 lemma measure_pmf_zero_iff: "measure (measure_pmf p) s = 0 \<longleftrightarrow> set_pmf p \<inter> s = {}"
   797   by (subst measure_pmf.prob_eq_0) (auto simp: AE_measure_pmf_iff)
   798 
   799 context
   800   fixes p :: "'a pmf" and s :: "'a set"
   801   assumes not_empty: "set_pmf p \<inter> s \<noteq> {}"
   802 begin
   803 
   804 interpretation pmf_as_measure .
   805 
   806 lemma emeasure_measure_pmf_not_zero: "emeasure (measure_pmf p) s \<noteq> 0"
   807 proof
   808   assume "emeasure (measure_pmf p) s = 0"
   809   then have "AE x in measure_pmf p. x \<notin> s"
   810     by (rule AE_I[rotated]) auto
   811   with not_empty show False
   812     by (auto simp: AE_measure_pmf_iff)
   813 qed
   814 
   815 lemma measure_measure_pmf_not_zero: "measure (measure_pmf p) s \<noteq> 0"
   816   using emeasure_measure_pmf_not_zero unfolding measure_pmf.emeasure_eq_measure by simp
   817 
   818 lift_definition cond_pmf :: "'a pmf" is
   819   "uniform_measure (measure_pmf p) s"
   820 proof (intro conjI)
   821   show "prob_space (uniform_measure (measure_pmf p) s)"
   822     by (intro prob_space_uniform_measure) (auto simp: emeasure_measure_pmf_not_zero)
   823   show "AE x in uniform_measure (measure_pmf p) s. measure (uniform_measure (measure_pmf p) s) {x} \<noteq> 0"
   824     by (simp add: emeasure_measure_pmf_not_zero measure_measure_pmf_not_zero AE_uniform_measure
   825                   AE_measure_pmf_iff set_pmf.rep_eq)
   826 qed simp
   827 
   828 lemma pmf_cond: "pmf cond_pmf x = (if x \<in> s then pmf p x / measure p s else 0)"
   829   by transfer (simp add: emeasure_measure_pmf_not_zero pmf.rep_eq)
   830 
   831 lemma set_cond_pmf[simp]: "set_pmf cond_pmf = set_pmf p \<inter> s"
   832   by (auto simp add: set_pmf_iff pmf_cond measure_measure_pmf_not_zero split: split_if_asm)
   833 
   834 end
   835 
   836 lemma cond_map_pmf:
   837   assumes "set_pmf p \<inter> f -` s \<noteq> {}"
   838   shows "cond_pmf (map_pmf f p) s = map_pmf f (cond_pmf p (f -` s))"
   839 proof -
   840   have *: "set_pmf (map_pmf f p) \<inter> s \<noteq> {}"
   841     using assms by auto
   842   { fix x
   843     have "ereal (pmf (map_pmf f (cond_pmf p (f -` s))) x) =
   844       emeasure p (f -` s \<inter> f -` {x}) / emeasure p (f -` s)"
   845       unfolding ereal_pmf_map cond_pmf.rep_eq[OF assms] by (simp add: nn_integral_uniform_measure)
   846     also have "f -` s \<inter> f -` {x} = (if x \<in> s then f -` {x} else {})"
   847       by auto
   848     also have "emeasure p (if x \<in> s then f -` {x} else {}) / emeasure p (f -` s) =
   849       ereal (pmf (cond_pmf (map_pmf f p) s) x)"
   850       using measure_measure_pmf_not_zero[OF *]
   851       by (simp add: pmf_cond[OF *] ereal_divide' ereal_pmf_map measure_pmf.emeasure_eq_measure[symmetric]
   852                del: ereal_divide)
   853     finally have "ereal (pmf (cond_pmf (map_pmf f p) s) x) = ereal (pmf (map_pmf f (cond_pmf p (f -` s))) x)"
   854       by simp }
   855   then show ?thesis
   856     by (intro pmf_eqI) simp
   857 qed
   858 
   859 lemma bind_cond_pmf_cancel:
   860   assumes [simp]: "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
   861   assumes [simp]: "\<And>y. y \<in> set_pmf q \<Longrightarrow> set_pmf p \<inter> {x. R x y} \<noteq> {}"
   862   assumes [simp]: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow> measure q {y. R x y} = measure p {x. R x y}"
   863   shows "bind_pmf p (\<lambda>x. cond_pmf q {y. R x y}) = q"
   864 proof (rule pmf_eqI)
   865   fix i
   866   have "ereal (pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i) =
   867     (\<integral>\<^sup>+x. ereal (pmf q i / measure p {x. R x i}) * ereal (indicator {x. R x i} x) \<partial>p)"
   868     by (auto simp add: ereal_pmf_bind AE_measure_pmf_iff pmf_cond pmf_eq_0_set_pmf intro!: nn_integral_cong_AE)
   869   also have "\<dots> = (pmf q i * measure p {x. R x i}) / measure p {x. R x i}"
   870     by (simp add: pmf_nonneg measure_nonneg zero_ereal_def[symmetric] ereal_indicator
   871                   nn_integral_cmult measure_pmf.emeasure_eq_measure)
   872   also have "\<dots> = pmf q i"
   873     by (cases "pmf q i = 0") (simp_all add: pmf_eq_0_set_pmf measure_measure_pmf_not_zero)
   874   finally show "pmf (bind_pmf p (\<lambda>x. cond_pmf q {y. R x y})) i = pmf q i"
   875     by simp
   876 qed
   877 
   878 subsection \<open> Relator \<close>
   879 
   880 inductive rel_pmf :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a pmf \<Rightarrow> 'b pmf \<Rightarrow> bool"
   881 for R p q
   882 where
   883   "\<lbrakk> \<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y;
   884      map_pmf fst pq = p; map_pmf snd pq = q \<rbrakk>
   885   \<Longrightarrow> rel_pmf R p q"
   886 
   887 lemma rel_pmfI:
   888   assumes R: "rel_set R (set_pmf p) (set_pmf q)"
   889   assumes eq: "\<And>x y. x \<in> set_pmf p \<Longrightarrow> y \<in> set_pmf q \<Longrightarrow> R x y \<Longrightarrow>
   890     measure p {x. R x y} = measure q {y. R x y}"
   891   shows "rel_pmf R p q"
   892 proof
   893   let ?pq = "bind_pmf p (\<lambda>x. bind_pmf (cond_pmf q {y. R x y}) (\<lambda>y. return_pmf (x, y)))"
   894   have "\<And>x. x \<in> set_pmf p \<Longrightarrow> set_pmf q \<inter> {y. R x y} \<noteq> {}"
   895     using R by (auto simp: rel_set_def)
   896   then show "\<And>x y. (x, y) \<in> set_pmf ?pq \<Longrightarrow> R x y"
   897     by auto
   898   show "map_pmf fst ?pq = p"
   899     by (simp add: map_bind_pmf map_return_pmf bind_return_pmf')
   900 
   901   show "map_pmf snd ?pq = q"
   902     using R eq
   903     apply (simp add: bind_cond_pmf_cancel map_bind_pmf map_return_pmf bind_return_pmf')
   904     apply (rule bind_cond_pmf_cancel)
   905     apply (auto simp: rel_set_def)
   906     done
   907 qed
   908 
   909 lemma rel_pmf_imp_rel_set: "rel_pmf R p q \<Longrightarrow> rel_set R (set_pmf p) (set_pmf q)"
   910   by (force simp add: rel_pmf.simps rel_set_def)
   911 
   912 lemma rel_pmfD_measure:
   913   assumes rel_R: "rel_pmf R p q" and R: "\<And>a b. R a b \<Longrightarrow> R a y \<longleftrightarrow> R x b"
   914   assumes "x \<in> set_pmf p" "y \<in> set_pmf q"
   915   shows "measure p {x. R x y} = measure q {y. R x y}"
   916 proof -
   917   from rel_R obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
   918     and eq: "p = map_pmf fst pq" "q = map_pmf snd pq"
   919     by (auto elim: rel_pmf.cases)
   920   have "measure p {x. R x y} = measure pq {x. R (fst x) y}"
   921     by (simp add: eq map_pmf_rep_eq measure_distr)
   922   also have "\<dots> = measure pq {y. R x (snd y)}"
   923     by (intro measure_pmf.finite_measure_eq_AE)
   924        (auto simp: AE_measure_pmf_iff R dest!: pq)
   925   also have "\<dots> = measure q {y. R x y}"
   926     by (simp add: eq map_pmf_rep_eq measure_distr)
   927   finally show "measure p {x. R x y} = measure q {y. R x y}" .
   928 qed
   929 
   930 lemma rel_pmf_iff_measure:
   931   assumes "symp R" "transp R"
   932   shows "rel_pmf R p q \<longleftrightarrow>
   933     rel_set R (set_pmf p) (set_pmf q) \<and>
   934     (\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y})"
   935   by (safe intro!: rel_pmf_imp_rel_set rel_pmfI)
   936      (auto intro!: rel_pmfD_measure dest: sympD[OF \<open>symp R\<close>] transpD[OF \<open>transp R\<close>])
   937 
   938 lemma quotient_rel_set_disjoint:
   939   "equivp R \<Longrightarrow> C \<in> UNIV // {(x, y). R x y} \<Longrightarrow> rel_set R A B \<Longrightarrow> A \<inter> C = {} \<longleftrightarrow> B \<inter> C = {}"
   940   using in_quotient_imp_closed[of UNIV "{(x, y). R x y}" C] 
   941   by (auto 0 0 simp: equivp_equiv rel_set_def set_eq_iff elim: equivpE)
   942      (blast dest: equivp_symp)+
   943 
   944 lemma quotientD: "equiv X R \<Longrightarrow> A \<in> X // R \<Longrightarrow> x \<in> A \<Longrightarrow> A = R `` {x}"
   945   by (metis Image_singleton_iff equiv_class_eq_iff quotientE)
   946 
   947 lemma rel_pmf_iff_equivp:
   948   assumes "equivp R"
   949   shows "rel_pmf R p q \<longleftrightarrow> (\<forall>C\<in>UNIV // {(x, y). R x y}. measure p C = measure q C)"
   950     (is "_ \<longleftrightarrow>   (\<forall>C\<in>_//?R. _)")
   951 proof (subst rel_pmf_iff_measure, safe)
   952   show "symp R" "transp R"
   953     using assms by (auto simp: equivp_reflp_symp_transp)
   954 next
   955   fix C assume C: "C \<in> UNIV // ?R" and R: "rel_set R (set_pmf p) (set_pmf q)"
   956   assume eq: "\<forall>x\<in>set_pmf p. \<forall>y\<in>set_pmf q. R x y \<longrightarrow> measure p {x. R x y} = measure q {y. R x y}"
   957   
   958   show "measure p C = measure q C"
   959   proof cases
   960     assume "p \<inter> C = {}"
   961     moreover then have "q \<inter> C = {}"  
   962       using quotient_rel_set_disjoint[OF assms C R] by simp
   963     ultimately show ?thesis
   964       unfolding measure_pmf_zero_iff[symmetric] by simp
   965   next
   966     assume "p \<inter> C \<noteq> {}"
   967     moreover then have "q \<inter> C \<noteq> {}"  
   968       using quotient_rel_set_disjoint[OF assms C R] by simp
   969     ultimately obtain x y where in_set: "x \<in> set_pmf p" "y \<in> set_pmf q" and in_C: "x \<in> C" "y \<in> C"
   970       by auto
   971     then have "R x y"
   972       using in_quotient_imp_in_rel[of UNIV ?R C x y] C assms
   973       by (simp add: equivp_equiv)
   974     with in_set eq have "measure p {x. R x y} = measure q {y. R x y}"
   975       by auto
   976     moreover have "{y. R x y} = C"
   977       using assms `x \<in> C` C quotientD[of UNIV ?R C x] by (simp add: equivp_equiv)
   978     moreover have "{x. R x y} = C"
   979       using assms `y \<in> C` C quotientD[of UNIV "?R" C y] sympD[of R]
   980       by (auto simp add: equivp_equiv elim: equivpE)
   981     ultimately show ?thesis
   982       by auto
   983   qed
   984 next
   985   assume eq: "\<forall>C\<in>UNIV // ?R. measure p C = measure q C"
   986   show "rel_set R (set_pmf p) (set_pmf q)"
   987     unfolding rel_set_def
   988   proof safe
   989     fix x assume x: "x \<in> set_pmf p"
   990     have "{y. R x y} \<in> UNIV // ?R"
   991       by (auto simp: quotient_def)
   992     with eq have *: "measure q {y. R x y} = measure p {y. R x y}"
   993       by auto
   994     have "measure q {y. R x y} \<noteq> 0"
   995       using x assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
   996     then show "\<exists>y\<in>set_pmf q. R x y"
   997       unfolding measure_pmf_zero_iff by auto
   998   next
   999     fix y assume y: "y \<in> set_pmf q"
  1000     have "{x. R x y} \<in> UNIV // ?R"
  1001       using assms by (auto simp: quotient_def dest: equivp_symp)
  1002     with eq have *: "measure p {x. R x y} = measure q {x. R x y}"
  1003       by auto
  1004     have "measure p {x. R x y} \<noteq> 0"
  1005       using y assms unfolding * by (auto simp: measure_pmf_zero_iff set_eq_iff dest: equivp_reflp)
  1006     then show "\<exists>x\<in>set_pmf p. R x y"
  1007       unfolding measure_pmf_zero_iff by auto
  1008   qed
  1009 
  1010   fix x y assume "x \<in> set_pmf p" "y \<in> set_pmf q" "R x y"
  1011   have "{y. R x y} \<in> UNIV // ?R" "{x. R x y} = {y. R x y}"
  1012     using assms `R x y` by (auto simp: quotient_def dest: equivp_symp equivp_transp)
  1013   with eq show "measure p {x. R x y} = measure q {y. R x y}"
  1014     by auto
  1015 qed
  1016 
  1017 bnf pmf: "'a pmf" map: map_pmf sets: set_pmf bd : "natLeq" rel: rel_pmf
  1018 proof -
  1019   show "map_pmf id = id" by (rule map_pmf_id)
  1020   show "\<And>f g. map_pmf (f \<circ> g) = map_pmf f \<circ> map_pmf g" by (rule map_pmf_compose)
  1021   show "\<And>f g::'a \<Rightarrow> 'b. \<And>p. (\<And>x. x \<in> set_pmf p \<Longrightarrow> f x = g x) \<Longrightarrow> map_pmf f p = map_pmf g p"
  1022     by (intro map_pmf_cong refl)
  1023 
  1024   show "\<And>f::'a \<Rightarrow> 'b. set_pmf \<circ> map_pmf f = op ` f \<circ> set_pmf"
  1025     by (rule pmf_set_map)
  1026 
  1027   { fix p :: "'s pmf"
  1028     have "(card_of (set_pmf p), card_of (UNIV :: nat set)) \<in> ordLeq"
  1029       by (rule card_of_ordLeqI[where f="to_nat_on (set_pmf p)"])
  1030          (auto intro: countable_set_pmf)
  1031     also have "(card_of (UNIV :: nat set), natLeq) \<in> ordLeq"
  1032       by (metis Field_natLeq card_of_least natLeq_Well_order)
  1033     finally show "(card_of (set_pmf p), natLeq) \<in> ordLeq" . }
  1034 
  1035   show "\<And>R. rel_pmf R =
  1036          (BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf fst))\<inverse>\<inverse> OO
  1037          BNF_Def.Grp {x. set_pmf x \<subseteq> {(x, y). R x y}} (map_pmf snd)"
  1038      by (auto simp add: fun_eq_iff BNF_Def.Grp_def OO_def rel_pmf.simps)
  1039 
  1040   { fix p :: "'a pmf" and f :: "'a \<Rightarrow> 'b" and g x
  1041     assume p: "\<And>z. z \<in> set_pmf p \<Longrightarrow> f z = g z"
  1042       and x: "x \<in> set_pmf p"
  1043     thus "f x = g x" by simp }
  1044 
  1045   fix R :: "'a \<Rightarrow> 'b \<Rightarrow> bool" and S :: "'b \<Rightarrow> 'c \<Rightarrow> bool"
  1046   { fix p q r
  1047     assume pq: "rel_pmf R p q"
  1048       and qr:"rel_pmf S q r"
  1049     from pq obtain pq where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1050       and p: "p = map_pmf fst pq" and q: "q = map_pmf snd pq" by cases auto
  1051     from qr obtain qr where qr: "\<And>y z. (y, z) \<in> set_pmf qr \<Longrightarrow> S y z"
  1052       and q': "q = map_pmf fst qr" and r: "r = map_pmf snd qr" by cases auto
  1053 
  1054     def pr \<equiv> "bind_pmf pq (\<lambda>xy. bind_pmf (cond_pmf qr {yz. fst yz = snd xy}) (\<lambda>yz. return_pmf (fst xy, snd yz)))"
  1055     have pr_welldefined: "\<And>y. y \<in> q \<Longrightarrow> qr \<inter> {yz. fst yz = y} \<noteq> {}"
  1056       by (force simp: q')
  1057 
  1058     have "rel_pmf (R OO S) p r"
  1059     proof (rule rel_pmf.intros)
  1060       fix x z assume "(x, z) \<in> pr"
  1061       then have "\<exists>y. (x, y) \<in> pq \<and> (y, z) \<in> qr"
  1062         by (auto simp: q pr_welldefined pr_def split_beta)
  1063       with pq qr show "(R OO S) x z"
  1064         by blast
  1065     next
  1066       have "map_pmf snd pr = map_pmf snd (bind_pmf q (\<lambda>y. cond_pmf qr {yz. fst yz = y}))"
  1067         by (simp add: pr_def q split_beta bind_map_pmf map_pmf_def[symmetric] map_bind_pmf map_return_pmf map_pmf_comp)
  1068       then show "map_pmf snd pr = r"
  1069         unfolding r q' bind_map_pmf by (subst (asm) bind_cond_pmf_cancel) (auto simp: eq_commute)
  1070     qed (simp add: pr_def map_bind_pmf split_beta map_return_pmf map_pmf_def[symmetric] p map_pmf_comp) }
  1071   then show "rel_pmf R OO rel_pmf S \<le> rel_pmf (R OO S)"
  1072     by(auto simp add: le_fun_def)
  1073 qed (fact natLeq_card_order natLeq_cinfinite)+
  1074 
  1075 lemma rel_pmf_conj[simp]:
  1076   "rel_pmf (\<lambda>x y. P \<and> Q x y) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1077   "rel_pmf (\<lambda>x y. Q x y \<and> P) x y \<longleftrightarrow> P \<and> rel_pmf Q x y"
  1078   using set_pmf_not_empty by (fastforce simp: pmf.in_rel subset_eq)+
  1079 
  1080 lemma rel_pmf_top[simp]: "rel_pmf top = top"
  1081   by (auto simp: pmf.in_rel[abs_def] fun_eq_iff map_fst_pair_pmf map_snd_pair_pmf
  1082            intro: exI[of _ "pair_pmf x y" for x y])
  1083 
  1084 lemma rel_pmf_return_pmf1: "rel_pmf R (return_pmf x) M \<longleftrightarrow> (\<forall>a\<in>M. R x a)"
  1085 proof safe
  1086   fix a assume "a \<in> M" "rel_pmf R (return_pmf x) M"
  1087   then obtain pq where *: "\<And>a b. (a, b) \<in> set_pmf pq \<Longrightarrow> R a b"
  1088     and eq: "return_pmf x = map_pmf fst pq" "M = map_pmf snd pq"
  1089     by (force elim: rel_pmf.cases)
  1090   moreover have "set_pmf (return_pmf x) = {x}"
  1091     by simp
  1092   with `a \<in> M` have "(x, a) \<in> pq"
  1093     by (force simp: eq)
  1094   with * show "R x a"
  1095     by auto
  1096 qed (auto intro!: rel_pmf.intros[where pq="pair_pmf (return_pmf x) M"]
  1097           simp: map_fst_pair_pmf map_snd_pair_pmf)
  1098 
  1099 lemma rel_pmf_return_pmf2: "rel_pmf R M (return_pmf x) \<longleftrightarrow> (\<forall>a\<in>M. R a x)"
  1100   by (subst pmf.rel_flip[symmetric]) (simp add: rel_pmf_return_pmf1)
  1101 
  1102 lemma rel_return_pmf[simp]: "rel_pmf R (return_pmf x1) (return_pmf x2) = R x1 x2"
  1103   unfolding rel_pmf_return_pmf2 set_return_pmf by simp
  1104 
  1105 lemma rel_pmf_False[simp]: "rel_pmf (\<lambda>x y. False) x y = False"
  1106   unfolding pmf.in_rel fun_eq_iff using set_pmf_not_empty by fastforce
  1107 
  1108 lemma rel_pmf_rel_prod:
  1109   "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B') \<longleftrightarrow> rel_pmf R A B \<and> rel_pmf S A' B'"
  1110 proof safe
  1111   assume "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1112   then obtain pq where pq: "\<And>a b c d. ((a, c), (b, d)) \<in> set_pmf pq \<Longrightarrow> R a b \<and> S c d"
  1113     and eq: "map_pmf fst pq = pair_pmf A A'" "map_pmf snd pq = pair_pmf B B'"
  1114     by (force elim: rel_pmf.cases)
  1115   show "rel_pmf R A B"
  1116   proof (rule rel_pmf.intros)
  1117     let ?f = "\<lambda>(a, b). (fst a, fst b)"
  1118     have [simp]: "(\<lambda>x. fst (?f x)) = fst o fst" "(\<lambda>x. snd (?f x)) = fst o snd"
  1119       by auto
  1120 
  1121     show "map_pmf fst (map_pmf ?f pq) = A"
  1122       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1123     show "map_pmf snd (map_pmf ?f pq) = B"
  1124       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_fst_pair_pmf)
  1125 
  1126     fix a b assume "(a, b) \<in> set_pmf (map_pmf ?f pq)"
  1127     then obtain c d where "((a, c), (b, d)) \<in> set_pmf pq"
  1128       by auto
  1129     from pq[OF this] show "R a b" ..
  1130   qed
  1131   show "rel_pmf S A' B'"
  1132   proof (rule rel_pmf.intros)
  1133     let ?f = "\<lambda>(a, b). (snd a, snd b)"
  1134     have [simp]: "(\<lambda>x. fst (?f x)) = snd o fst" "(\<lambda>x. snd (?f x)) = snd o snd"
  1135       by auto
  1136 
  1137     show "map_pmf fst (map_pmf ?f pq) = A'"
  1138       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1139     show "map_pmf snd (map_pmf ?f pq) = B'"
  1140       by (simp add: map_pmf_comp pmf.map_comp[symmetric] eq map_snd_pair_pmf)
  1141 
  1142     fix c d assume "(c, d) \<in> set_pmf (map_pmf ?f pq)"
  1143     then obtain a b where "((a, c), (b, d)) \<in> set_pmf pq"
  1144       by auto
  1145     from pq[OF this] show "S c d" ..
  1146   qed
  1147 next
  1148   assume "rel_pmf R A B" "rel_pmf S A' B'"
  1149   then obtain Rpq Spq
  1150     where Rpq: "\<And>a b. (a, b) \<in> set_pmf Rpq \<Longrightarrow> R a b"
  1151         "map_pmf fst Rpq = A" "map_pmf snd Rpq = B"
  1152       and Spq: "\<And>a b. (a, b) \<in> set_pmf Spq \<Longrightarrow> S a b"
  1153         "map_pmf fst Spq = A'" "map_pmf snd Spq = B'"
  1154     by (force elim: rel_pmf.cases)
  1155 
  1156   let ?f = "(\<lambda>((a, c), (b, d)). ((a, b), (c, d)))"
  1157   let ?pq = "map_pmf ?f (pair_pmf Rpq Spq)"
  1158   have [simp]: "(\<lambda>x. fst (?f x)) = (\<lambda>(a, b). (fst a, fst b))" "(\<lambda>x. snd (?f x)) = (\<lambda>(a, b). (snd a, snd b))"
  1159     by auto
  1160 
  1161   show "rel_pmf (rel_prod R S) (pair_pmf A A') (pair_pmf B B')"
  1162     by (rule rel_pmf.intros[where pq="?pq"])
  1163        (auto simp: map_snd_pair_pmf map_fst_pair_pmf map_pmf_comp Rpq Spq
  1164                    map_pair)
  1165 qed
  1166 
  1167 lemma rel_pmf_reflI:
  1168   assumes "\<And>x. x \<in> set_pmf p \<Longrightarrow> P x x"
  1169   shows "rel_pmf P p p"
  1170   by (rule rel_pmf.intros[where pq="map_pmf (\<lambda>x. (x, x)) p"])
  1171      (auto simp add: pmf.map_comp o_def assms)
  1172 
  1173 context
  1174 begin
  1175 
  1176 interpretation pmf_as_measure .
  1177 
  1178 definition "join_pmf M = bind_pmf M (\<lambda>x. x)"
  1179 
  1180 lemma bind_eq_join_pmf: "bind_pmf M f = join_pmf (map_pmf f M)"
  1181   unfolding join_pmf_def bind_map_pmf ..
  1182 
  1183 lemma join_eq_bind_pmf: "join_pmf M = bind_pmf M id"
  1184   by (simp add: join_pmf_def id_def)
  1185 
  1186 lemma pmf_join: "pmf (join_pmf N) i = (\<integral>M. pmf M i \<partial>measure_pmf N)"
  1187   unfolding join_pmf_def pmf_bind ..
  1188 
  1189 lemma ereal_pmf_join: "ereal (pmf (join_pmf N) i) = (\<integral>\<^sup>+M. pmf M i \<partial>measure_pmf N)"
  1190   unfolding join_pmf_def ereal_pmf_bind ..
  1191 
  1192 lemma set_pmf_join_pmf[simp]: "set_pmf (join_pmf f) = (\<Union>p\<in>set_pmf f. set_pmf p)"
  1193   by (simp add: join_pmf_def)
  1194 
  1195 lemma join_return_pmf: "join_pmf (return_pmf M) = M"
  1196   by (simp add: integral_return pmf_eq_iff pmf_join return_pmf.rep_eq)
  1197 
  1198 lemma map_join_pmf: "map_pmf f (join_pmf AA) = join_pmf (map_pmf (map_pmf f) AA)"
  1199   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf)
  1200 
  1201 lemma join_map_return_pmf: "join_pmf (map_pmf return_pmf A) = A"
  1202   by (simp add: join_pmf_def map_pmf_def bind_assoc_pmf bind_return_pmf bind_return_pmf')
  1203 
  1204 end
  1205 
  1206 lemma rel_pmf_joinI:
  1207   assumes "rel_pmf (rel_pmf P) p q"
  1208   shows "rel_pmf P (join_pmf p) (join_pmf q)"
  1209 proof -
  1210   from assms obtain pq where p: "p = map_pmf fst pq"
  1211     and q: "q = map_pmf snd pq"
  1212     and P: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> rel_pmf P x y"
  1213     by cases auto
  1214   from P obtain PQ
  1215     where PQ: "\<And>x y a b. \<lbrakk> (x, y) \<in> set_pmf pq; (a, b) \<in> set_pmf (PQ x y) \<rbrakk> \<Longrightarrow> P a b"
  1216     and x: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf fst (PQ x y) = x"
  1217     and y: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> map_pmf snd (PQ x y) = y"
  1218     by(metis rel_pmf.simps)
  1219 
  1220   let ?r = "bind_pmf pq (\<lambda>(x, y). PQ x y)"
  1221   have "\<And>a b. (a, b) \<in> set_pmf ?r \<Longrightarrow> P a b" by (auto intro: PQ)
  1222   moreover have "map_pmf fst ?r = join_pmf p" "map_pmf snd ?r = join_pmf q"
  1223     by (simp_all add: p q x y join_pmf_def map_bind_pmf bind_map_pmf split_def cong: bind_pmf_cong)
  1224   ultimately show ?thesis ..
  1225 qed
  1226 
  1227 lemma rel_pmf_bindI:
  1228   assumes pq: "rel_pmf R p q"
  1229   and fg: "\<And>x y. R x y \<Longrightarrow> rel_pmf P (f x) (g y)"
  1230   shows "rel_pmf P (bind_pmf p f) (bind_pmf q g)"
  1231   unfolding bind_eq_join_pmf
  1232   by (rule rel_pmf_joinI)
  1233      (auto simp add: pmf.rel_map intro: pmf.rel_mono[THEN le_funD, THEN le_funD, THEN le_boolD, THEN mp, OF _ pq] fg)
  1234 
  1235 text {*
  1236   Proof that @{const rel_pmf} preserves orders.
  1237   Antisymmetry proof follows Thm. 1 in N. Saheb-Djahromi, Cpo's of measures for nondeterminism,
  1238   Theoretical Computer Science 12(1):19--37, 1980,
  1239   @{url "http://dx.doi.org/10.1016/0304-3975(80)90003-1"}
  1240 *}
  1241 
  1242 lemma
  1243   assumes *: "rel_pmf R p q"
  1244   and refl: "reflp R" and trans: "transp R"
  1245   shows measure_Ici: "measure p {y. R x y} \<le> measure q {y. R x y}" (is ?thesis1)
  1246   and measure_Ioi: "measure p {y. R x y \<and> \<not> R y x} \<le> measure q {y. R x y \<and> \<not> R y x}" (is ?thesis2)
  1247 proof -
  1248   from * obtain pq
  1249     where pq: "\<And>x y. (x, y) \<in> set_pmf pq \<Longrightarrow> R x y"
  1250     and p: "p = map_pmf fst pq"
  1251     and q: "q = map_pmf snd pq"
  1252     by cases auto
  1253   show ?thesis1 ?thesis2 unfolding p q map_pmf_rep_eq using refl trans
  1254     by(auto 4 3 simp add: measure_distr reflpD AE_measure_pmf_iff intro!: measure_pmf.finite_measure_mono_AE dest!: pq elim: transpE)
  1255 qed
  1256 
  1257 lemma rel_pmf_inf:
  1258   fixes p q :: "'a pmf"
  1259   assumes 1: "rel_pmf R p q"
  1260   assumes 2: "rel_pmf R q p"
  1261   and refl: "reflp R" and trans: "transp R"
  1262   shows "rel_pmf (inf R R\<inverse>\<inverse>) p q"
  1263 proof (subst rel_pmf_iff_equivp, safe)
  1264   show "equivp (inf R R\<inverse>\<inverse>)"
  1265     using trans refl by (auto simp: equivp_reflp_symp_transp intro: sympI transpI reflpI dest: transpD reflpD)
  1266   
  1267   fix C assume "C \<in> UNIV // {(x, y). inf R R\<inverse>\<inverse> x y}"
  1268   then obtain x where C: "C = {y. R x y \<and> R y x}"
  1269     by (auto elim: quotientE)
  1270 
  1271   let ?R = "\<lambda>x y. R x y \<and> R y x"
  1272   let ?\<mu>R = "\<lambda>y. measure q {x. ?R x y}"
  1273   have "measure p {y. ?R x y} = measure p ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1274     by(auto intro!: arg_cong[where f="measure p"])
  1275   also have "\<dots> = measure p {y. R x y} - measure p {y. R x y \<and> \<not> R y x}"
  1276     by (rule measure_pmf.finite_measure_Diff) auto
  1277   also have "measure p {y. R x y \<and> \<not> R y x} = measure q {y. R x y \<and> \<not> R y x}"
  1278     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ioi)
  1279   also have "measure p {y. R x y} = measure q {y. R x y}"
  1280     using 1 2 refl trans by(auto intro!: Orderings.antisym measure_Ici)
  1281   also have "measure q {y. R x y} - measure q {y. R x y \<and> \<not> R y x} =
  1282     measure q ({y. R x y} - {y. R x y \<and> \<not> R y x})"
  1283     by(rule measure_pmf.finite_measure_Diff[symmetric]) auto
  1284   also have "\<dots> = ?\<mu>R x"
  1285     by(auto intro!: arg_cong[where f="measure q"])
  1286   finally show "measure p C = measure q C"
  1287     by (simp add: C conj_commute)
  1288 qed
  1289 
  1290 lemma rel_pmf_antisym:
  1291   fixes p q :: "'a pmf"
  1292   assumes 1: "rel_pmf R p q"
  1293   assumes 2: "rel_pmf R q p"
  1294   and refl: "reflp R" and trans: "transp R" and antisym: "antisymP R"
  1295   shows "p = q"
  1296 proof -
  1297   from 1 2 refl trans have "rel_pmf (inf R R\<inverse>\<inverse>) p q" by(rule rel_pmf_inf)
  1298   also have "inf R R\<inverse>\<inverse> = op ="
  1299     using refl antisym by (auto intro!: ext simp add: reflpD dest: antisymD)
  1300   finally show ?thesis unfolding pmf.rel_eq .
  1301 qed
  1302 
  1303 lemma reflp_rel_pmf: "reflp R \<Longrightarrow> reflp (rel_pmf R)"
  1304 by(blast intro: reflpI rel_pmf_reflI reflpD)
  1305 
  1306 lemma antisymP_rel_pmf:
  1307   "\<lbrakk> reflp R; transp R; antisymP R \<rbrakk>
  1308   \<Longrightarrow> antisymP (rel_pmf R)"
  1309 by(rule antisymI)(blast intro: rel_pmf_antisym)
  1310 
  1311 lemma transp_rel_pmf:
  1312   assumes "transp R"
  1313   shows "transp (rel_pmf R)"
  1314 proof (rule transpI)
  1315   fix x y z
  1316   assume "rel_pmf R x y" and "rel_pmf R y z"
  1317   hence "rel_pmf (R OO R) x z" by (simp add: pmf.rel_compp relcompp.relcompI)
  1318   thus "rel_pmf R x z"
  1319     using assms by (metis (no_types) pmf.rel_mono rev_predicate2D transp_relcompp_less_eq)
  1320 qed
  1321 
  1322 subsection \<open> Distributions \<close>
  1323 
  1324 context
  1325 begin
  1326 
  1327 interpretation pmf_as_function .
  1328 
  1329 subsubsection \<open> Bernoulli Distribution \<close>
  1330 
  1331 lift_definition bernoulli_pmf :: "real \<Rightarrow> bool pmf" is
  1332   "\<lambda>p b. ((\<lambda>p. if b then p else 1 - p) \<circ> min 1 \<circ> max 0) p"
  1333   by (auto simp: nn_integral_count_space_finite[where A="{False, True}"] UNIV_bool
  1334            split: split_max split_min)
  1335 
  1336 lemma pmf_bernoulli_True[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) True = p"
  1337   by transfer simp
  1338 
  1339 lemma pmf_bernoulli_False[simp]: "0 \<le> p \<Longrightarrow> p \<le> 1 \<Longrightarrow> pmf (bernoulli_pmf p) False = 1 - p"
  1340   by transfer simp
  1341 
  1342 lemma set_pmf_bernoulli: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (bernoulli_pmf p) = UNIV"
  1343   by (auto simp add: set_pmf_iff UNIV_bool)
  1344 
  1345 lemma nn_integral_bernoulli_pmf[simp]:
  1346   assumes [simp]: "0 \<le> p" "p \<le> 1" "\<And>x. 0 \<le> f x"
  1347   shows "(\<integral>\<^sup>+x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1348   by (subst nn_integral_measure_pmf_support[of UNIV])
  1349      (auto simp: UNIV_bool field_simps)
  1350 
  1351 lemma integral_bernoulli_pmf[simp]:
  1352   assumes [simp]: "0 \<le> p" "p \<le> 1"
  1353   shows "(\<integral>x. f x \<partial>bernoulli_pmf p) = f True * p + f False * (1 - p)"
  1354   by (subst integral_measure_pmf[of UNIV]) (auto simp: UNIV_bool)
  1355 
  1356 lemma pmf_bernoulli_half [simp]: "pmf (bernoulli_pmf (1 / 2)) x = 1 / 2"
  1357 by(cases x) simp_all
  1358 
  1359 lemma measure_pmf_bernoulli_half: "measure_pmf (bernoulli_pmf (1 / 2)) = uniform_count_measure UNIV"
  1360 by(rule measure_eqI)(simp_all add: nn_integral_pmf[symmetric] emeasure_uniform_count_measure nn_integral_count_space_finite sets_uniform_count_measure)
  1361 
  1362 subsubsection \<open> Geometric Distribution \<close>
  1363 
  1364 lift_definition geometric_pmf :: "nat pmf" is "\<lambda>n. 1 / 2^Suc n"
  1365 proof
  1366   note geometric_sums[of "1 / 2"]
  1367   note sums_mult[OF this, of "1 / 2"]
  1368   from sums_suminf_ereal[OF this]
  1369   show "(\<integral>\<^sup>+ x. ereal (1 / 2 ^ Suc x) \<partial>count_space UNIV) = 1"
  1370     by (simp add: nn_integral_count_space_nat field_simps)
  1371 qed simp
  1372 
  1373 lemma pmf_geometric[simp]: "pmf geometric_pmf n = 1 / 2^Suc n"
  1374   by transfer rule
  1375 
  1376 lemma set_pmf_geometric[simp]: "set_pmf geometric_pmf = UNIV"
  1377   by (auto simp: set_pmf_iff)
  1378 
  1379 subsubsection \<open> Uniform Multiset Distribution \<close>
  1380 
  1381 context
  1382   fixes M :: "'a multiset" assumes M_not_empty: "M \<noteq> {#}"
  1383 begin
  1384 
  1385 lift_definition pmf_of_multiset :: "'a pmf" is "\<lambda>x. count M x / size M"
  1386 proof
  1387   show "(\<integral>\<^sup>+ x. ereal (real (count M x) / real (size M)) \<partial>count_space UNIV) = 1"
  1388     using M_not_empty
  1389     by (simp add: zero_less_divide_iff nn_integral_count_space nonempty_has_size
  1390                   setsum_divide_distrib[symmetric])
  1391        (auto simp: size_multiset_overloaded_eq intro!: setsum.cong)
  1392 qed simp
  1393 
  1394 lemma pmf_of_multiset[simp]: "pmf pmf_of_multiset x = count M x / size M"
  1395   by transfer rule
  1396 
  1397 lemma set_pmf_of_multiset[simp]: "set_pmf pmf_of_multiset = set_of M"
  1398   by (auto simp: set_pmf_iff)
  1399 
  1400 end
  1401 
  1402 subsubsection \<open> Uniform Distribution \<close>
  1403 
  1404 context
  1405   fixes S :: "'a set" assumes S_not_empty: "S \<noteq> {}" and S_finite: "finite S"
  1406 begin
  1407 
  1408 lift_definition pmf_of_set :: "'a pmf" is "\<lambda>x. indicator S x / card S"
  1409 proof
  1410   show "(\<integral>\<^sup>+ x. ereal (indicator S x / real (card S)) \<partial>count_space UNIV) = 1"
  1411     using S_not_empty S_finite by (subst nn_integral_count_space'[of S]) auto
  1412 qed simp
  1413 
  1414 lemma pmf_of_set[simp]: "pmf pmf_of_set x = indicator S x / card S"
  1415   by transfer rule
  1416 
  1417 lemma set_pmf_of_set[simp]: "set_pmf pmf_of_set = S"
  1418   using S_finite S_not_empty by (auto simp: set_pmf_iff)
  1419 
  1420 lemma emeasure_pmf_of_set[simp]: "emeasure pmf_of_set S = 1"
  1421   by (rule measure_pmf.emeasure_eq_1_AE) (auto simp: AE_measure_pmf_iff)
  1422 
  1423 end
  1424 
  1425 subsubsection \<open> Poisson Distribution \<close>
  1426 
  1427 context
  1428   fixes rate :: real assumes rate_pos: "0 < rate"
  1429 begin
  1430 
  1431 lift_definition poisson_pmf :: "nat pmf" is "\<lambda>k. rate ^ k / fact k * exp (-rate)"
  1432 proof  (* by Manuel Eberl *)
  1433   have summable: "summable (\<lambda>x::nat. rate ^ x / fact x)" using summable_exp
  1434     by (simp add: field_simps divide_inverse [symmetric])
  1435   have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x * exp (-rate) \<partial>count_space UNIV) =
  1436           exp (-rate) * (\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV)"
  1437     by (simp add: field_simps nn_integral_cmult[symmetric])
  1438   also from rate_pos have "(\<integral>\<^sup>+(x::nat). rate ^ x / fact x \<partial>count_space UNIV) = (\<Sum>x. rate ^ x / fact x)"
  1439     by (simp_all add: nn_integral_count_space_nat suminf_ereal summable suminf_ereal_finite)
  1440   also have "... = exp rate" unfolding exp_def
  1441     by (simp add: field_simps divide_inverse [symmetric])
  1442   also have "ereal (exp (-rate)) * ereal (exp rate) = 1"
  1443     by (simp add: mult_exp_exp)
  1444   finally show "(\<integral>\<^sup>+ x. ereal (rate ^ x / (fact x) * exp (- rate)) \<partial>count_space UNIV) = 1" .
  1445 qed (simp add: rate_pos[THEN less_imp_le])
  1446 
  1447 lemma pmf_poisson[simp]: "pmf poisson_pmf k = rate ^ k / fact k * exp (-rate)"
  1448   by transfer rule
  1449 
  1450 lemma set_pmf_poisson[simp]: "set_pmf poisson_pmf = UNIV"
  1451   using rate_pos by (auto simp: set_pmf_iff)
  1452 
  1453 end
  1454 
  1455 subsubsection \<open> Binomial Distribution \<close>
  1456 
  1457 context
  1458   fixes n :: nat and p :: real assumes p_nonneg: "0 \<le> p" and p_le_1: "p \<le> 1"
  1459 begin
  1460 
  1461 lift_definition binomial_pmf :: "nat pmf" is "\<lambda>k. (n choose k) * p^k * (1 - p)^(n - k)"
  1462 proof
  1463   have "(\<integral>\<^sup>+k. ereal (real (n choose k) * p ^ k * (1 - p) ^ (n - k)) \<partial>count_space UNIV) =
  1464     ereal (\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k))"
  1465     using p_le_1 p_nonneg by (subst nn_integral_count_space') auto
  1466   also have "(\<Sum>k\<le>n. real (n choose k) * p ^ k * (1 - p) ^ (n - k)) = (p + (1 - p)) ^ n"
  1467     by (subst binomial_ring) (simp add: atLeast0AtMost real_of_nat_def)
  1468   finally show "(\<integral>\<^sup>+ x. ereal (real (n choose x) * p ^ x * (1 - p) ^ (n - x)) \<partial>count_space UNIV) = 1"
  1469     by simp
  1470 qed (insert p_nonneg p_le_1, simp)
  1471 
  1472 lemma pmf_binomial[simp]: "pmf binomial_pmf k = (n choose k) * p^k * (1 - p)^(n - k)"
  1473   by transfer rule
  1474 
  1475 lemma set_pmf_binomial_eq: "set_pmf binomial_pmf = (if p = 0 then {0} else if p = 1 then {n} else {.. n})"
  1476   using p_nonneg p_le_1 unfolding set_eq_iff set_pmf_iff pmf_binomial by (auto simp: set_pmf_iff)
  1477 
  1478 end
  1479 
  1480 end
  1481 
  1482 lemma set_pmf_binomial_0[simp]: "set_pmf (binomial_pmf n 0) = {0}"
  1483   by (simp add: set_pmf_binomial_eq)
  1484 
  1485 lemma set_pmf_binomial_1[simp]: "set_pmf (binomial_pmf n 1) = {n}"
  1486   by (simp add: set_pmf_binomial_eq)
  1487 
  1488 lemma set_pmf_binomial[simp]: "0 < p \<Longrightarrow> p < 1 \<Longrightarrow> set_pmf (binomial_pmf n p) = {..n}"
  1489   by (simp add: set_pmf_binomial_eq)
  1490 
  1491 end