src/HOL/Library/FuncSet.thy
author nipkow
Sat Jun 20 14:00:36 2009 +0200 (2009-06-20)
changeset 31731 7ffc1a901eea
parent 31727 2621a957d417
child 31754 b5260f5272a4
child 31769 d5f39775edd2
permissions -rw-r--r--
tuned
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    67   by (simp add: Pi_def)
    68 
    69 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    70   by (auto simp add: Pi_def)
    71 
    72 lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    73 apply (simp add: Pi_def, auto)
    74 txt{*Converse direction requires Axiom of Choice to exhibit a function
    75 picking an element from each non-empty @{term "B x"}*}
    76 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    77 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    78 done
    79 
    80 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    81   by (simp add: Pi_def)
    82 
    83 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    84   by (simp add: Pi_def)
    85 (*
    86 lemma funcset_id [simp]: "(%x. x): A -> A"
    87   by (simp add: Pi_def)
    88 *)
    89 text{*Covariance of Pi-sets in their second argument*}
    90 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    91   by (simp add: Pi_def, blast)
    92 
    93 text{*Contravariance of Pi-sets in their first argument*}
    94 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    95   by (simp add: Pi_def, blast)
    96 
    97 
    98 subsection{*Composition With a Restricted Domain: @{term compose}*}
    99 
   100 lemma funcset_compose:
   101     "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   102   by (simp add: Pi_def compose_def restrict_def)
   103 
   104 lemma compose_assoc:
   105     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   106       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   107   by (simp add: expand_fun_eq Pi_def compose_def restrict_def)
   108 
   109 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   110   by (simp add: compose_def restrict_def)
   111 
   112 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   113   by (auto simp add: image_def compose_eq)
   114 
   115 
   116 subsection{*Bounded Abstraction: @{term restrict}*}
   117 
   118 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   119   by (simp add: Pi_def restrict_def)
   120 
   121 lemma restrictI: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   122   by (simp add: Pi_def restrict_def)
   123 
   124 lemma restrict_apply [simp]:
   125     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   126   by (simp add: restrict_def)
   127 
   128 lemma restrict_ext:
   129     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   130   by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)
   131 
   132 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   133   by (simp add: inj_on_def restrict_def)
   134 
   135 lemma Id_compose:
   136     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   137   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   138 
   139 lemma compose_Id:
   140     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   141   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   142 
   143 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   144   by (auto simp add: restrict_def)
   145 
   146 
   147 subsection{*Bijections Between Sets*}
   148 
   149 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   150 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   151 
   152 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   153   by (auto simp add: bij_betw_def inj_on_Inv Pi_def)
   154 
   155 lemma inj_on_compose:
   156     "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   157   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   158 
   159 lemma bij_betw_compose:
   160     "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   161   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   162   apply (auto simp add: compose_def image_def)
   163   done
   164 
   165 lemma bij_betw_restrict_eq [simp]:
   166      "bij_betw (restrict f A) A B = bij_betw f A B"
   167   by (simp add: bij_betw_def)
   168 
   169 
   170 subsection{*Extensionality*}
   171 
   172 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   173   by (simp add: extensional_def)
   174 
   175 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   176   by (simp add: restrict_def extensional_def)
   177 
   178 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   179   by (simp add: compose_def)
   180 
   181 lemma extensionalityI:
   182     "[| f \<in> extensional A; g \<in> extensional A;
   183       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   184   by (force simp add: expand_fun_eq extensional_def)
   185 
   186 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   187   by (unfold Inv_def) (fast intro: restrict_in_funcset someI2)
   188 
   189 lemma compose_Inv_id:
   190     "bij_betw f A B ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   191   apply (simp add: bij_betw_def compose_def)
   192   apply (rule restrict_ext, auto)
   193   apply (erule subst)
   194   apply (simp add: Inv_f_f)
   195   done
   196 
   197 lemma compose_id_Inv:
   198     "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   199   apply (simp add: compose_def)
   200   apply (rule restrict_ext)
   201   apply (simp add: f_Inv_f)
   202   done
   203 
   204 
   205 subsection{*Cardinality*}
   206 
   207 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   208   apply (rule card_inj_on_le)
   209     apply (auto simp add: Pi_def)
   210   done
   211 
   212 lemma card_bij:
   213      "[|f \<in> A\<rightarrow>B; inj_on f A;
   214         g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   215   by (blast intro: card_inj order_antisym)
   216 
   217 end