src/HOL/Multivariate_Analysis/Topology_Euclidean_Space.thy
author huffman
Wed Mar 26 11:05:25 2014 -0700 (2014-03-26)
changeset 56290 801a72ad52d3
parent 56189 c4daa97ac57a
child 56371 fb9ae0727548
permissions -rw-r--r--
tuned proofs
     1 (*  title:      HOL/Library/Topology_Euclidian_Space.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3     Author:     Robert Himmelmann, TU Muenchen
     4     Author:     Brian Huffman, Portland State University
     5 *)
     6 
     7 header {* Elementary topology in Euclidean space. *}
     8 
     9 theory Topology_Euclidean_Space
    10 imports
    11   Complex_Main
    12   "~~/src/HOL/Library/Countable_Set"
    13   "~~/src/HOL/Library/FuncSet"
    14   Linear_Algebra
    15   Norm_Arith
    16 begin
    17 
    18 lemma dist_0_norm:
    19   fixes x :: "'a::real_normed_vector"
    20   shows "dist 0 x = norm x"
    21 unfolding dist_norm by simp
    22 
    23 lemma dist_double: "dist x y < d / 2 \<Longrightarrow> dist x z < d / 2 \<Longrightarrow> dist y z < d"
    24   using dist_triangle[of y z x] by (simp add: dist_commute)
    25 
    26 (* LEGACY *)
    27 lemma lim_subseq: "subseq r \<Longrightarrow> s ----> l \<Longrightarrow> (s \<circ> r) ----> l"
    28   by (rule LIMSEQ_subseq_LIMSEQ)
    29 
    30 lemma countable_PiE:
    31   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> countable (F i)) \<Longrightarrow> countable (PiE I F)"
    32   by (induct I arbitrary: F rule: finite_induct) (auto simp: PiE_insert_eq)
    33 
    34 lemma Lim_within_open:
    35   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
    36   shows "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l)(at a within S) \<longleftrightarrow> (f ---> l)(at a)"
    37   by (fact tendsto_within_open)
    38 
    39 lemma continuous_on_union:
    40   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
    41   by (fact continuous_on_closed_Un)
    42 
    43 lemma continuous_on_cases:
    44   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t g \<Longrightarrow>
    45     \<forall>x. (x\<in>s \<and> \<not> P x) \<or> (x \<in> t \<and> P x) \<longrightarrow> f x = g x \<Longrightarrow>
    46     continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
    47   by (rule continuous_on_If) auto
    48 
    49 
    50 subsection {* Topological Basis *}
    51 
    52 context topological_space
    53 begin
    54 
    55 definition "topological_basis B \<longleftrightarrow>
    56   (\<forall>b\<in>B. open b) \<and> (\<forall>x. open x \<longrightarrow> (\<exists>B'. B' \<subseteq> B \<and> \<Union>B' = x))"
    57 
    58 lemma topological_basis:
    59   "topological_basis B \<longleftrightarrow> (\<forall>x. open x \<longleftrightarrow> (\<exists>B'. B' \<subseteq> B \<and> \<Union>B' = x))"
    60   unfolding topological_basis_def
    61   apply safe
    62      apply fastforce
    63     apply fastforce
    64    apply (erule_tac x="x" in allE)
    65    apply simp
    66    apply (rule_tac x="{x}" in exI)
    67   apply auto
    68   done
    69 
    70 lemma topological_basis_iff:
    71   assumes "\<And>B'. B' \<in> B \<Longrightarrow> open B'"
    72   shows "topological_basis B \<longleftrightarrow> (\<forall>O'. open O' \<longrightarrow> (\<forall>x\<in>O'. \<exists>B'\<in>B. x \<in> B' \<and> B' \<subseteq> O'))"
    73     (is "_ \<longleftrightarrow> ?rhs")
    74 proof safe
    75   fix O' and x::'a
    76   assume H: "topological_basis B" "open O'" "x \<in> O'"
    77   then have "(\<exists>B'\<subseteq>B. \<Union>B' = O')" by (simp add: topological_basis_def)
    78   then obtain B' where "B' \<subseteq> B" "O' = \<Union>B'" by auto
    79   then show "\<exists>B'\<in>B. x \<in> B' \<and> B' \<subseteq> O'" using H by auto
    80 next
    81   assume H: ?rhs
    82   show "topological_basis B"
    83     using assms unfolding topological_basis_def
    84   proof safe
    85     fix O' :: "'a set"
    86     assume "open O'"
    87     with H obtain f where "\<forall>x\<in>O'. f x \<in> B \<and> x \<in> f x \<and> f x \<subseteq> O'"
    88       by (force intro: bchoice simp: Bex_def)
    89     then show "\<exists>B'\<subseteq>B. \<Union>B' = O'"
    90       by (auto intro: exI[where x="{f x |x. x \<in> O'}"])
    91   qed
    92 qed
    93 
    94 lemma topological_basisI:
    95   assumes "\<And>B'. B' \<in> B \<Longrightarrow> open B'"
    96     and "\<And>O' x. open O' \<Longrightarrow> x \<in> O' \<Longrightarrow> \<exists>B'\<in>B. x \<in> B' \<and> B' \<subseteq> O'"
    97   shows "topological_basis B"
    98   using assms by (subst topological_basis_iff) auto
    99 
   100 lemma topological_basisE:
   101   fixes O'
   102   assumes "topological_basis B"
   103     and "open O'"
   104     and "x \<in> O'"
   105   obtains B' where "B' \<in> B" "x \<in> B'" "B' \<subseteq> O'"
   106 proof atomize_elim
   107   from assms have "\<And>B'. B'\<in>B \<Longrightarrow> open B'"
   108     by (simp add: topological_basis_def)
   109   with topological_basis_iff assms
   110   show  "\<exists>B'. B' \<in> B \<and> x \<in> B' \<and> B' \<subseteq> O'"
   111     using assms by (simp add: Bex_def)
   112 qed
   113 
   114 lemma topological_basis_open:
   115   assumes "topological_basis B"
   116     and "X \<in> B"
   117   shows "open X"
   118   using assms by (simp add: topological_basis_def)
   119 
   120 lemma topological_basis_imp_subbasis:
   121   assumes B: "topological_basis B"
   122   shows "open = generate_topology B"
   123 proof (intro ext iffI)
   124   fix S :: "'a set"
   125   assume "open S"
   126   with B obtain B' where "B' \<subseteq> B" "S = \<Union>B'"
   127     unfolding topological_basis_def by blast
   128   then show "generate_topology B S"
   129     by (auto intro: generate_topology.intros dest: topological_basis_open)
   130 next
   131   fix S :: "'a set"
   132   assume "generate_topology B S"
   133   then show "open S"
   134     by induct (auto dest: topological_basis_open[OF B])
   135 qed
   136 
   137 lemma basis_dense:
   138   fixes B :: "'a set set"
   139     and f :: "'a set \<Rightarrow> 'a"
   140   assumes "topological_basis B"
   141     and choosefrom_basis: "\<And>B'. B' \<noteq> {} \<Longrightarrow> f B' \<in> B'"
   142   shows "\<forall>X. open X \<longrightarrow> X \<noteq> {} \<longrightarrow> (\<exists>B' \<in> B. f B' \<in> X)"
   143 proof (intro allI impI)
   144   fix X :: "'a set"
   145   assume "open X" and "X \<noteq> {}"
   146   from topological_basisE[OF `topological_basis B` `open X` choosefrom_basis[OF `X \<noteq> {}`]]
   147   obtain B' where "B' \<in> B" "f X \<in> B'" "B' \<subseteq> X" .
   148   then show "\<exists>B'\<in>B. f B' \<in> X"
   149     by (auto intro!: choosefrom_basis)
   150 qed
   151 
   152 end
   153 
   154 lemma topological_basis_prod:
   155   assumes A: "topological_basis A"
   156     and B: "topological_basis B"
   157   shows "topological_basis ((\<lambda>(a, b). a \<times> b) ` (A \<times> B))"
   158   unfolding topological_basis_def
   159 proof (safe, simp_all del: ex_simps add: subset_image_iff ex_simps(1)[symmetric])
   160   fix S :: "('a \<times> 'b) set"
   161   assume "open S"
   162   then show "\<exists>X\<subseteq>A \<times> B. (\<Union>(a,b)\<in>X. a \<times> b) = S"
   163   proof (safe intro!: exI[of _ "{x\<in>A \<times> B. fst x \<times> snd x \<subseteq> S}"])
   164     fix x y
   165     assume "(x, y) \<in> S"
   166     from open_prod_elim[OF `open S` this]
   167     obtain a b where a: "open a""x \<in> a" and b: "open b" "y \<in> b" and "a \<times> b \<subseteq> S"
   168       by (metis mem_Sigma_iff)
   169     moreover
   170     from A a obtain A0 where "A0 \<in> A" "x \<in> A0" "A0 \<subseteq> a"
   171       by (rule topological_basisE)
   172     moreover
   173     from B b obtain B0 where "B0 \<in> B" "y \<in> B0" "B0 \<subseteq> b"
   174       by (rule topological_basisE)
   175     ultimately show "(x, y) \<in> (\<Union>(a, b)\<in>{X \<in> A \<times> B. fst X \<times> snd X \<subseteq> S}. a \<times> b)"
   176       by (intro UN_I[of "(A0, B0)"]) auto
   177   qed auto
   178 qed (metis A B topological_basis_open open_Times)
   179 
   180 
   181 subsection {* Countable Basis *}
   182 
   183 locale countable_basis =
   184   fixes B :: "'a::topological_space set set"
   185   assumes is_basis: "topological_basis B"
   186     and countable_basis: "countable B"
   187 begin
   188 
   189 lemma open_countable_basis_ex:
   190   assumes "open X"
   191   shows "\<exists>B' \<subseteq> B. X = Union B'"
   192   using assms countable_basis is_basis
   193   unfolding topological_basis_def by blast
   194 
   195 lemma open_countable_basisE:
   196   assumes "open X"
   197   obtains B' where "B' \<subseteq> B" "X = Union B'"
   198   using assms open_countable_basis_ex
   199   by (atomize_elim) simp
   200 
   201 lemma countable_dense_exists:
   202   "\<exists>D::'a set. countable D \<and> (\<forall>X. open X \<longrightarrow> X \<noteq> {} \<longrightarrow> (\<exists>d \<in> D. d \<in> X))"
   203 proof -
   204   let ?f = "(\<lambda>B'. SOME x. x \<in> B')"
   205   have "countable (?f ` B)" using countable_basis by simp
   206   with basis_dense[OF is_basis, of ?f] show ?thesis
   207     by (intro exI[where x="?f ` B"]) (metis (mono_tags) all_not_in_conv imageI someI)
   208 qed
   209 
   210 lemma countable_dense_setE:
   211   obtains D :: "'a set"
   212   where "countable D" "\<And>X. open X \<Longrightarrow> X \<noteq> {} \<Longrightarrow> \<exists>d \<in> D. d \<in> X"
   213   using countable_dense_exists by blast
   214 
   215 end
   216 
   217 lemma (in first_countable_topology) first_countable_basisE:
   218   obtains A where "countable A" "\<And>a. a \<in> A \<Longrightarrow> x \<in> a" "\<And>a. a \<in> A \<Longrightarrow> open a"
   219     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> (\<exists>a\<in>A. a \<subseteq> S)"
   220   using first_countable_basis[of x]
   221   apply atomize_elim
   222   apply (elim exE)
   223   apply (rule_tac x="range A" in exI)
   224   apply auto
   225   done
   226 
   227 lemma (in first_countable_topology) first_countable_basis_Int_stableE:
   228   obtains A where "countable A" "\<And>a. a \<in> A \<Longrightarrow> x \<in> a" "\<And>a. a \<in> A \<Longrightarrow> open a"
   229     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> (\<exists>a\<in>A. a \<subseteq> S)"
   230     "\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<inter> b \<in> A"
   231 proof atomize_elim
   232   obtain A' where A':
   233     "countable A'"
   234     "\<And>a. a \<in> A' \<Longrightarrow> x \<in> a"
   235     "\<And>a. a \<in> A' \<Longrightarrow> open a"
   236     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>a\<in>A'. a \<subseteq> S"
   237     by (rule first_countable_basisE) blast
   238   def A \<equiv> "(\<lambda>N. \<Inter>((\<lambda>n. from_nat_into A' n) ` N)) ` (Collect finite::nat set set)"
   239   then show "\<exists>A. countable A \<and> (\<forall>a. a \<in> A \<longrightarrow> x \<in> a) \<and> (\<forall>a. a \<in> A \<longrightarrow> open a) \<and>
   240         (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> (\<exists>a\<in>A. a \<subseteq> S)) \<and> (\<forall>a b. a \<in> A \<longrightarrow> b \<in> A \<longrightarrow> a \<inter> b \<in> A)"
   241   proof (safe intro!: exI[where x=A])
   242     show "countable A"
   243       unfolding A_def by (intro countable_image countable_Collect_finite)
   244     fix a
   245     assume "a \<in> A"
   246     then show "x \<in> a" "open a"
   247       using A'(4)[OF open_UNIV] by (auto simp: A_def intro: A' from_nat_into)
   248   next
   249     let ?int = "\<lambda>N. \<Inter>(from_nat_into A' ` N)"
   250     fix a b
   251     assume "a \<in> A" "b \<in> A"
   252     then obtain N M where "a = ?int N" "b = ?int M" "finite (N \<union> M)"
   253       by (auto simp: A_def)
   254     then show "a \<inter> b \<in> A"
   255       by (auto simp: A_def intro!: image_eqI[where x="N \<union> M"])
   256   next
   257     fix S
   258     assume "open S" "x \<in> S"
   259     then obtain a where a: "a\<in>A'" "a \<subseteq> S" using A' by blast
   260     then show "\<exists>a\<in>A. a \<subseteq> S" using a A'
   261       by (intro bexI[where x=a]) (auto simp: A_def intro: image_eqI[where x="{to_nat_on A' a}"])
   262   qed
   263 qed
   264 
   265 lemma (in topological_space) first_countableI:
   266   assumes "countable A"
   267     and 1: "\<And>a. a \<in> A \<Longrightarrow> x \<in> a" "\<And>a. a \<in> A \<Longrightarrow> open a"
   268     and 2: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>a\<in>A. a \<subseteq> S"
   269   shows "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   270 proof (safe intro!: exI[of _ "from_nat_into A"])
   271   fix i
   272   have "A \<noteq> {}" using 2[of UNIV] by auto
   273   show "x \<in> from_nat_into A i" "open (from_nat_into A i)"
   274     using range_from_nat_into_subset[OF `A \<noteq> {}`] 1 by auto
   275 next
   276   fix S
   277   assume "open S" "x\<in>S" from 2[OF this]
   278   show "\<exists>i. from_nat_into A i \<subseteq> S"
   279     using subset_range_from_nat_into[OF `countable A`] by auto
   280 qed
   281 
   282 instance prod :: (first_countable_topology, first_countable_topology) first_countable_topology
   283 proof
   284   fix x :: "'a \<times> 'b"
   285   obtain A where A:
   286       "countable A"
   287       "\<And>a. a \<in> A \<Longrightarrow> fst x \<in> a"
   288       "\<And>a. a \<in> A \<Longrightarrow> open a"
   289       "\<And>S. open S \<Longrightarrow> fst x \<in> S \<Longrightarrow> \<exists>a\<in>A. a \<subseteq> S"
   290     by (rule first_countable_basisE[of "fst x"]) blast
   291   obtain B where B:
   292       "countable B"
   293       "\<And>a. a \<in> B \<Longrightarrow> snd x \<in> a"
   294       "\<And>a. a \<in> B \<Longrightarrow> open a"
   295       "\<And>S. open S \<Longrightarrow> snd x \<in> S \<Longrightarrow> \<exists>a\<in>B. a \<subseteq> S"
   296     by (rule first_countable_basisE[of "snd x"]) blast
   297   show "\<exists>A::nat \<Rightarrow> ('a \<times> 'b) set.
   298     (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   299   proof (rule first_countableI[of "(\<lambda>(a, b). a \<times> b) ` (A \<times> B)"], safe)
   300     fix a b
   301     assume x: "a \<in> A" "b \<in> B"
   302     with A(2, 3)[of a] B(2, 3)[of b] show "x \<in> a \<times> b" and "open (a \<times> b)"
   303       unfolding mem_Times_iff
   304       by (auto intro: open_Times)
   305   next
   306     fix S
   307     assume "open S" "x \<in> S"
   308     then obtain a' b' where a'b': "open a'" "open b'" "x \<in> a' \<times> b'" "a' \<times> b' \<subseteq> S"
   309       by (rule open_prod_elim)
   310     moreover
   311     from a'b' A(4)[of a'] B(4)[of b']
   312     obtain a b where "a \<in> A" "a \<subseteq> a'" "b \<in> B" "b \<subseteq> b'"
   313       by auto
   314     ultimately
   315     show "\<exists>a\<in>(\<lambda>(a, b). a \<times> b) ` (A \<times> B). a \<subseteq> S"
   316       by (auto intro!: bexI[of _ "a \<times> b"] bexI[of _ a] bexI[of _ b])
   317   qed (simp add: A B)
   318 qed
   319 
   320 class second_countable_topology = topological_space +
   321   assumes ex_countable_subbasis:
   322     "\<exists>B::'a::topological_space set set. countable B \<and> open = generate_topology B"
   323 begin
   324 
   325 lemma ex_countable_basis: "\<exists>B::'a set set. countable B \<and> topological_basis B"
   326 proof -
   327   from ex_countable_subbasis obtain B where B: "countable B" "open = generate_topology B"
   328     by blast
   329   let ?B = "Inter ` {b. finite b \<and> b \<subseteq> B }"
   330 
   331   show ?thesis
   332   proof (intro exI conjI)
   333     show "countable ?B"
   334       by (intro countable_image countable_Collect_finite_subset B)
   335     {
   336       fix S
   337       assume "open S"
   338       then have "\<exists>B'\<subseteq>{b. finite b \<and> b \<subseteq> B}. (\<Union>b\<in>B'. \<Inter>b) = S"
   339         unfolding B
   340       proof induct
   341         case UNIV
   342         show ?case by (intro exI[of _ "{{}}"]) simp
   343       next
   344         case (Int a b)
   345         then obtain x y where x: "a = UNION x Inter" "\<And>i. i \<in> x \<Longrightarrow> finite i \<and> i \<subseteq> B"
   346           and y: "b = UNION y Inter" "\<And>i. i \<in> y \<Longrightarrow> finite i \<and> i \<subseteq> B"
   347           by blast
   348         show ?case
   349           unfolding x y Int_UN_distrib2
   350           by (intro exI[of _ "{i \<union> j| i j.  i \<in> x \<and> j \<in> y}"]) (auto dest: x(2) y(2))
   351       next
   352         case (UN K)
   353         then have "\<forall>k\<in>K. \<exists>B'\<subseteq>{b. finite b \<and> b \<subseteq> B}. UNION B' Inter = k" by auto
   354         then obtain k where
   355             "\<forall>ka\<in>K. k ka \<subseteq> {b. finite b \<and> b \<subseteq> B} \<and> UNION (k ka) Inter = ka"
   356           unfolding bchoice_iff ..
   357         then show "\<exists>B'\<subseteq>{b. finite b \<and> b \<subseteq> B}. UNION B' Inter = \<Union>K"
   358           by (intro exI[of _ "UNION K k"]) auto
   359       next
   360         case (Basis S)
   361         then show ?case
   362           by (intro exI[of _ "{{S}}"]) auto
   363       qed
   364       then have "(\<exists>B'\<subseteq>Inter ` {b. finite b \<and> b \<subseteq> B}. \<Union>B' = S)"
   365         unfolding subset_image_iff by blast }
   366     then show "topological_basis ?B"
   367       unfolding topological_space_class.topological_basis_def
   368       by (safe intro!: topological_space_class.open_Inter)
   369          (simp_all add: B generate_topology.Basis subset_eq)
   370   qed
   371 qed
   372 
   373 end
   374 
   375 sublocale second_countable_topology <
   376   countable_basis "SOME B. countable B \<and> topological_basis B"
   377   using someI_ex[OF ex_countable_basis]
   378   by unfold_locales safe
   379 
   380 instance prod :: (second_countable_topology, second_countable_topology) second_countable_topology
   381 proof
   382   obtain A :: "'a set set" where "countable A" "topological_basis A"
   383     using ex_countable_basis by auto
   384   moreover
   385   obtain B :: "'b set set" where "countable B" "topological_basis B"
   386     using ex_countable_basis by auto
   387   ultimately show "\<exists>B::('a \<times> 'b) set set. countable B \<and> open = generate_topology B"
   388     by (auto intro!: exI[of _ "(\<lambda>(a, b). a \<times> b) ` (A \<times> B)"] topological_basis_prod
   389       topological_basis_imp_subbasis)
   390 qed
   391 
   392 instance second_countable_topology \<subseteq> first_countable_topology
   393 proof
   394   fix x :: 'a
   395   def B \<equiv> "SOME B::'a set set. countable B \<and> topological_basis B"
   396   then have B: "countable B" "topological_basis B"
   397     using countable_basis is_basis
   398     by (auto simp: countable_basis is_basis)
   399   then show "\<exists>A::nat \<Rightarrow> 'a set.
   400     (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   401     by (intro first_countableI[of "{b\<in>B. x \<in> b}"])
   402        (fastforce simp: topological_space_class.topological_basis_def)+
   403 qed
   404 
   405 
   406 subsection {* Polish spaces *}
   407 
   408 text {* Textbooks define Polish spaces as completely metrizable.
   409   We assume the topology to be complete for a given metric. *}
   410 
   411 class polish_space = complete_space + second_countable_topology
   412 
   413 subsection {* General notion of a topology as a value *}
   414 
   415 definition "istopology L \<longleftrightarrow>
   416   L {} \<and> (\<forall>S T. L S \<longrightarrow> L T \<longrightarrow> L (S \<inter> T)) \<and> (\<forall>K. Ball K L \<longrightarrow> L (\<Union> K))"
   417 
   418 typedef 'a topology = "{L::('a set) \<Rightarrow> bool. istopology L}"
   419   morphisms "openin" "topology"
   420   unfolding istopology_def by blast
   421 
   422 lemma istopology_open_in[intro]: "istopology(openin U)"
   423   using openin[of U] by blast
   424 
   425 lemma topology_inverse': "istopology U \<Longrightarrow> openin (topology U) = U"
   426   using topology_inverse[unfolded mem_Collect_eq] .
   427 
   428 lemma topology_inverse_iff: "istopology U \<longleftrightarrow> openin (topology U) = U"
   429   using topology_inverse[of U] istopology_open_in[of "topology U"] by auto
   430 
   431 lemma topology_eq: "T1 = T2 \<longleftrightarrow> (\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S)"
   432 proof
   433   assume "T1 = T2"
   434   then show "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S" by simp
   435 next
   436   assume H: "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S"
   437   then have "openin T1 = openin T2" by (simp add: fun_eq_iff)
   438   then have "topology (openin T1) = topology (openin T2)" by simp
   439   then show "T1 = T2" unfolding openin_inverse .
   440 qed
   441 
   442 text{* Infer the "universe" from union of all sets in the topology. *}
   443 
   444 definition "topspace T = \<Union>{S. openin T S}"
   445 
   446 subsubsection {* Main properties of open sets *}
   447 
   448 lemma openin_clauses:
   449   fixes U :: "'a topology"
   450   shows
   451     "openin U {}"
   452     "\<And>S T. openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S\<inter>T)"
   453     "\<And>K. (\<forall>S \<in> K. openin U S) \<Longrightarrow> openin U (\<Union>K)"
   454   using openin[of U] unfolding istopology_def mem_Collect_eq by fast+
   455 
   456 lemma openin_subset[intro]: "openin U S \<Longrightarrow> S \<subseteq> topspace U"
   457   unfolding topspace_def by blast
   458 
   459 lemma openin_empty[simp]: "openin U {}"
   460   by (simp add: openin_clauses)
   461 
   462 lemma openin_Int[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<inter> T)"
   463   using openin_clauses by simp
   464 
   465 lemma openin_Union[intro]: "(\<forall>S \<in>K. openin U S) \<Longrightarrow> openin U (\<Union> K)"
   466   using openin_clauses by simp
   467 
   468 lemma openin_Un[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<union> T)"
   469   using openin_Union[of "{S,T}" U] by auto
   470 
   471 lemma openin_topspace[intro, simp]: "openin U (topspace U)"
   472   by (simp add: openin_Union topspace_def)
   473 
   474 lemma openin_subopen: "openin U S \<longleftrightarrow> (\<forall>x \<in> S. \<exists>T. openin U T \<and> x \<in> T \<and> T \<subseteq> S)"
   475   (is "?lhs \<longleftrightarrow> ?rhs")
   476 proof
   477   assume ?lhs
   478   then show ?rhs by auto
   479 next
   480   assume H: ?rhs
   481   let ?t = "\<Union>{T. openin U T \<and> T \<subseteq> S}"
   482   have "openin U ?t" by (simp add: openin_Union)
   483   also have "?t = S" using H by auto
   484   finally show "openin U S" .
   485 qed
   486 
   487 
   488 subsubsection {* Closed sets *}
   489 
   490 definition "closedin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> openin U (topspace U - S)"
   491 
   492 lemma closedin_subset: "closedin U S \<Longrightarrow> S \<subseteq> topspace U"
   493   by (metis closedin_def)
   494 
   495 lemma closedin_empty[simp]: "closedin U {}"
   496   by (simp add: closedin_def)
   497 
   498 lemma closedin_topspace[intro, simp]: "closedin U (topspace U)"
   499   by (simp add: closedin_def)
   500 
   501 lemma closedin_Un[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<union> T)"
   502   by (auto simp add: Diff_Un closedin_def)
   503 
   504 lemma Diff_Inter[intro]: "A - \<Inter>S = \<Union> {A - s|s. s\<in>S}"
   505   by auto
   506 
   507 lemma closedin_Inter[intro]:
   508   assumes Ke: "K \<noteq> {}"
   509     and Kc: "\<forall>S \<in>K. closedin U S"
   510   shows "closedin U (\<Inter> K)"
   511   using Ke Kc unfolding closedin_def Diff_Inter by auto
   512 
   513 lemma closedin_Int[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<inter> T)"
   514   using closedin_Inter[of "{S,T}" U] by auto
   515 
   516 lemma Diff_Diff_Int: "A - (A - B) = A \<inter> B"
   517   by blast
   518 
   519 lemma openin_closedin_eq: "openin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> closedin U (topspace U - S)"
   520   apply (auto simp add: closedin_def Diff_Diff_Int inf_absorb2)
   521   apply (metis openin_subset subset_eq)
   522   done
   523 
   524 lemma openin_closedin: "S \<subseteq> topspace U \<Longrightarrow> (openin U S \<longleftrightarrow> closedin U (topspace U - S))"
   525   by (simp add: openin_closedin_eq)
   526 
   527 lemma openin_diff[intro]:
   528   assumes oS: "openin U S"
   529     and cT: "closedin U T"
   530   shows "openin U (S - T)"
   531 proof -
   532   have "S - T = S \<inter> (topspace U - T)" using openin_subset[of U S]  oS cT
   533     by (auto simp add: topspace_def openin_subset)
   534   then show ?thesis using oS cT
   535     by (auto simp add: closedin_def)
   536 qed
   537 
   538 lemma closedin_diff[intro]:
   539   assumes oS: "closedin U S"
   540     and cT: "openin U T"
   541   shows "closedin U (S - T)"
   542 proof -
   543   have "S - T = S \<inter> (topspace U - T)"
   544     using closedin_subset[of U S] oS cT by (auto simp add: topspace_def)
   545   then show ?thesis
   546     using oS cT by (auto simp add: openin_closedin_eq)
   547 qed
   548 
   549 
   550 subsubsection {* Subspace topology *}
   551 
   552 definition "subtopology U V = topology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   553 
   554 lemma istopology_subtopology: "istopology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   555   (is "istopology ?L")
   556 proof -
   557   have "?L {}" by blast
   558   {
   559     fix A B
   560     assume A: "?L A" and B: "?L B"
   561     from A B obtain Sa and Sb where Sa: "openin U Sa" "A = Sa \<inter> V" and Sb: "openin U Sb" "B = Sb \<inter> V"
   562       by blast
   563     have "A \<inter> B = (Sa \<inter> Sb) \<inter> V" "openin U (Sa \<inter> Sb)"
   564       using Sa Sb by blast+
   565     then have "?L (A \<inter> B)" by blast
   566   }
   567   moreover
   568   {
   569     fix K
   570     assume K: "K \<subseteq> Collect ?L"
   571     have th0: "Collect ?L = (\<lambda>S. S \<inter> V) ` Collect (openin U)"
   572       by blast
   573     from K[unfolded th0 subset_image_iff]
   574     obtain Sk where Sk: "Sk \<subseteq> Collect (openin U)" "K = (\<lambda>S. S \<inter> V) ` Sk"
   575       by blast
   576     have "\<Union>K = (\<Union>Sk) \<inter> V"
   577       using Sk by auto
   578     moreover have "openin U (\<Union> Sk)"
   579       using Sk by (auto simp add: subset_eq)
   580     ultimately have "?L (\<Union>K)" by blast
   581   }
   582   ultimately show ?thesis
   583     unfolding subset_eq mem_Collect_eq istopology_def by blast
   584 qed
   585 
   586 lemma openin_subtopology: "openin (subtopology U V) S \<longleftrightarrow> (\<exists>T. openin U T \<and> S = T \<inter> V)"
   587   unfolding subtopology_def topology_inverse'[OF istopology_subtopology]
   588   by auto
   589 
   590 lemma topspace_subtopology: "topspace (subtopology U V) = topspace U \<inter> V"
   591   by (auto simp add: topspace_def openin_subtopology)
   592 
   593 lemma closedin_subtopology: "closedin (subtopology U V) S \<longleftrightarrow> (\<exists>T. closedin U T \<and> S = T \<inter> V)"
   594   unfolding closedin_def topspace_subtopology
   595   by (auto simp add: openin_subtopology)
   596 
   597 lemma openin_subtopology_refl: "openin (subtopology U V) V \<longleftrightarrow> V \<subseteq> topspace U"
   598   unfolding openin_subtopology
   599   by auto (metis IntD1 in_mono openin_subset)
   600 
   601 lemma subtopology_superset:
   602   assumes UV: "topspace U \<subseteq> V"
   603   shows "subtopology U V = U"
   604 proof -
   605   {
   606     fix S
   607     {
   608       fix T
   609       assume T: "openin U T" "S = T \<inter> V"
   610       from T openin_subset[OF T(1)] UV have eq: "S = T"
   611         by blast
   612       have "openin U S"
   613         unfolding eq using T by blast
   614     }
   615     moreover
   616     {
   617       assume S: "openin U S"
   618       then have "\<exists>T. openin U T \<and> S = T \<inter> V"
   619         using openin_subset[OF S] UV by auto
   620     }
   621     ultimately have "(\<exists>T. openin U T \<and> S = T \<inter> V) \<longleftrightarrow> openin U S"
   622       by blast
   623   }
   624   then show ?thesis
   625     unfolding topology_eq openin_subtopology by blast
   626 qed
   627 
   628 lemma subtopology_topspace[simp]: "subtopology U (topspace U) = U"
   629   by (simp add: subtopology_superset)
   630 
   631 lemma subtopology_UNIV[simp]: "subtopology U UNIV = U"
   632   by (simp add: subtopology_superset)
   633 
   634 
   635 subsubsection {* The standard Euclidean topology *}
   636 
   637 definition euclidean :: "'a::topological_space topology"
   638   where "euclidean = topology open"
   639 
   640 lemma open_openin: "open S \<longleftrightarrow> openin euclidean S"
   641   unfolding euclidean_def
   642   apply (rule cong[where x=S and y=S])
   643   apply (rule topology_inverse[symmetric])
   644   apply (auto simp add: istopology_def)
   645   done
   646 
   647 lemma topspace_euclidean: "topspace euclidean = UNIV"
   648   apply (simp add: topspace_def)
   649   apply (rule set_eqI)
   650   apply (auto simp add: open_openin[symmetric])
   651   done
   652 
   653 lemma topspace_euclidean_subtopology[simp]: "topspace (subtopology euclidean S) = S"
   654   by (simp add: topspace_euclidean topspace_subtopology)
   655 
   656 lemma closed_closedin: "closed S \<longleftrightarrow> closedin euclidean S"
   657   by (simp add: closed_def closedin_def topspace_euclidean open_openin Compl_eq_Diff_UNIV)
   658 
   659 lemma open_subopen: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S)"
   660   by (simp add: open_openin openin_subopen[symmetric])
   661 
   662 text {* Basic "localization" results are handy for connectedness. *}
   663 
   664 lemma openin_open: "openin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. open T \<and> (S = U \<inter> T))"
   665   by (auto simp add: openin_subtopology open_openin[symmetric])
   666 
   667 lemma openin_open_Int[intro]: "open S \<Longrightarrow> openin (subtopology euclidean U) (U \<inter> S)"
   668   by (auto simp add: openin_open)
   669 
   670 lemma open_openin_trans[trans]:
   671   "open S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> openin (subtopology euclidean S) T"
   672   by (metis Int_absorb1  openin_open_Int)
   673 
   674 lemma open_subset: "S \<subseteq> T \<Longrightarrow> open S \<Longrightarrow> openin (subtopology euclidean T) S"
   675   by (auto simp add: openin_open)
   676 
   677 lemma closedin_closed: "closedin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. closed T \<and> S = U \<inter> T)"
   678   by (simp add: closedin_subtopology closed_closedin Int_ac)
   679 
   680 lemma closedin_closed_Int: "closed S \<Longrightarrow> closedin (subtopology euclidean U) (U \<inter> S)"
   681   by (metis closedin_closed)
   682 
   683 lemma closed_closedin_trans:
   684   "closed S \<Longrightarrow> closed T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> closedin (subtopology euclidean S) T"
   685   by (metis closedin_closed inf.absorb2)
   686 
   687 lemma closed_subset: "S \<subseteq> T \<Longrightarrow> closed S \<Longrightarrow> closedin (subtopology euclidean T) S"
   688   by (auto simp add: closedin_closed)
   689 
   690 lemma openin_euclidean_subtopology_iff:
   691   fixes S U :: "'a::metric_space set"
   692   shows "openin (subtopology euclidean U) S \<longleftrightarrow>
   693     S \<subseteq> U \<and> (\<forall>x\<in>S. \<exists>e>0. \<forall>x'\<in>U. dist x' x < e \<longrightarrow> x'\<in> S)"
   694   (is "?lhs \<longleftrightarrow> ?rhs")
   695 proof
   696   assume ?lhs
   697   then show ?rhs
   698     unfolding openin_open open_dist by blast
   699 next
   700   def T \<equiv> "{x. \<exists>a\<in>S. \<exists>d>0. (\<forall>y\<in>U. dist y a < d \<longrightarrow> y \<in> S) \<and> dist x a < d}"
   701   have 1: "\<forall>x\<in>T. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> T"
   702     unfolding T_def
   703     apply clarsimp
   704     apply (rule_tac x="d - dist x a" in exI)
   705     apply (clarsimp simp add: less_diff_eq)
   706     by (metis dist_commute dist_triangle_lt)
   707   assume ?rhs then have 2: "S = U \<inter> T"
   708     unfolding T_def 
   709     by auto (metis dist_self)
   710   from 1 2 show ?lhs
   711     unfolding openin_open open_dist by fast
   712 qed
   713 
   714 text {* These "transitivity" results are handy too *}
   715 
   716 lemma openin_trans[trans]:
   717   "openin (subtopology euclidean T) S \<Longrightarrow> openin (subtopology euclidean U) T \<Longrightarrow>
   718     openin (subtopology euclidean U) S"
   719   unfolding open_openin openin_open by blast
   720 
   721 lemma openin_open_trans: "openin (subtopology euclidean T) S \<Longrightarrow> open T \<Longrightarrow> open S"
   722   by (auto simp add: openin_open intro: openin_trans)
   723 
   724 lemma closedin_trans[trans]:
   725   "closedin (subtopology euclidean T) S \<Longrightarrow> closedin (subtopology euclidean U) T \<Longrightarrow>
   726     closedin (subtopology euclidean U) S"
   727   by (auto simp add: closedin_closed closed_closedin closed_Inter Int_assoc)
   728 
   729 lemma closedin_closed_trans: "closedin (subtopology euclidean T) S \<Longrightarrow> closed T \<Longrightarrow> closed S"
   730   by (auto simp add: closedin_closed intro: closedin_trans)
   731 
   732 
   733 subsection {* Open and closed balls *}
   734 
   735 definition ball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set"
   736   where "ball x e = {y. dist x y < e}"
   737 
   738 definition cball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set"
   739   where "cball x e = {y. dist x y \<le> e}"
   740 
   741 lemma mem_ball [simp]: "y \<in> ball x e \<longleftrightarrow> dist x y < e"
   742   by (simp add: ball_def)
   743 
   744 lemma mem_cball [simp]: "y \<in> cball x e \<longleftrightarrow> dist x y \<le> e"
   745   by (simp add: cball_def)
   746 
   747 lemma mem_ball_0:
   748   fixes x :: "'a::real_normed_vector"
   749   shows "x \<in> ball 0 e \<longleftrightarrow> norm x < e"
   750   by (simp add: dist_norm)
   751 
   752 lemma mem_cball_0:
   753   fixes x :: "'a::real_normed_vector"
   754   shows "x \<in> cball 0 e \<longleftrightarrow> norm x \<le> e"
   755   by (simp add: dist_norm)
   756 
   757 lemma centre_in_ball: "x \<in> ball x e \<longleftrightarrow> 0 < e"
   758   by simp
   759 
   760 lemma centre_in_cball: "x \<in> cball x e \<longleftrightarrow> 0 \<le> e"
   761   by simp
   762 
   763 lemma ball_subset_cball[simp,intro]: "ball x e \<subseteq> cball x e"
   764   by (simp add: subset_eq)
   765 
   766 lemma subset_ball[intro]: "d \<le> e \<Longrightarrow> ball x d \<subseteq> ball x e"
   767   by (simp add: subset_eq)
   768 
   769 lemma subset_cball[intro]: "d \<le> e \<Longrightarrow> cball x d \<subseteq> cball x e"
   770   by (simp add: subset_eq)
   771 
   772 lemma ball_max_Un: "ball a (max r s) = ball a r \<union> ball a s"
   773   by (simp add: set_eq_iff) arith
   774 
   775 lemma ball_min_Int: "ball a (min r s) = ball a r \<inter> ball a s"
   776   by (simp add: set_eq_iff)
   777 
   778 lemma diff_less_iff:
   779   "(a::real) - b > 0 \<longleftrightarrow> a > b"
   780   "(a::real) - b < 0 \<longleftrightarrow> a < b"
   781   "a - b < c \<longleftrightarrow> a < c + b" "a - b > c \<longleftrightarrow> a > c + b"
   782   by arith+
   783 
   784 lemma diff_le_iff:
   785   "(a::real) - b \<ge> 0 \<longleftrightarrow> a \<ge> b"
   786   "(a::real) - b \<le> 0 \<longleftrightarrow> a \<le> b"
   787   "a - b \<le> c \<longleftrightarrow> a \<le> c + b"
   788   "a - b \<ge> c \<longleftrightarrow> a \<ge> c + b"
   789   by arith+
   790 
   791 lemma open_ball [intro, simp]: "open (ball x e)"
   792 proof -
   793   have "open (dist x -` {..<e})"
   794     by (intro open_vimage open_lessThan continuous_on_intros)
   795   also have "dist x -` {..<e} = ball x e"
   796     by auto
   797   finally show ?thesis .
   798 qed
   799 
   800 lemma open_contains_ball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. ball x e \<subseteq> S)"
   801   unfolding open_dist subset_eq mem_ball Ball_def dist_commute ..
   802 
   803 lemma openE[elim?]:
   804   assumes "open S" "x\<in>S"
   805   obtains e where "e>0" "ball x e \<subseteq> S"
   806   using assms unfolding open_contains_ball by auto
   807 
   808 lemma open_contains_ball_eq: "open S \<Longrightarrow> \<forall>x. x\<in>S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   809   by (metis open_contains_ball subset_eq centre_in_ball)
   810 
   811 lemma ball_eq_empty[simp]: "ball x e = {} \<longleftrightarrow> e \<le> 0"
   812   unfolding mem_ball set_eq_iff
   813   apply (simp add: not_less)
   814   apply (metis zero_le_dist order_trans dist_self)
   815   done
   816 
   817 lemma ball_empty[intro]: "e \<le> 0 \<Longrightarrow> ball x e = {}" by simp
   818 
   819 lemma euclidean_dist_l2:
   820   fixes x y :: "'a :: euclidean_space"
   821   shows "dist x y = setL2 (\<lambda>i. dist (x \<bullet> i) (y \<bullet> i)) Basis"
   822   unfolding dist_norm norm_eq_sqrt_inner setL2_def
   823   by (subst euclidean_inner) (simp add: power2_eq_square inner_diff_left)
   824 
   825 
   826 subsection {* Boxes *}
   827 
   828 definition (in euclidean_space) eucl_less (infix "<e" 50)
   829   where "eucl_less a b \<longleftrightarrow> (\<forall>i\<in>Basis. a \<bullet> i < b \<bullet> i)"
   830 
   831 definition box_eucl_less: "box a b = {x. a <e x \<and> x <e b}"
   832 definition "cbox a b = {x. \<forall>i\<in>Basis. a \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> b \<bullet> i}"
   833 
   834 lemma box_def: "box a b = {x. \<forall>i\<in>Basis. a \<bullet> i < x \<bullet> i \<and> x \<bullet> i < b \<bullet> i}"
   835   and in_box_eucl_less: "x \<in> box a b \<longleftrightarrow> a <e x \<and> x <e b"
   836   and mem_box: "x \<in> box a b \<longleftrightarrow> (\<forall>i\<in>Basis. a \<bullet> i < x \<bullet> i \<and> x \<bullet> i < b \<bullet> i)"
   837     "x \<in> cbox a b \<longleftrightarrow> (\<forall>i\<in>Basis. a \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> b \<bullet> i)"
   838   by (auto simp: box_eucl_less eucl_less_def cbox_def)
   839 
   840 lemma mem_box_real[simp]:
   841   "(x::real) \<in> box a b \<longleftrightarrow> a < x \<and> x < b"
   842   "(x::real) \<in> cbox a b \<longleftrightarrow> a \<le> x \<and> x \<le> b"
   843   by (auto simp: mem_box)
   844 
   845 lemma box_real[simp]:
   846   fixes a b:: real
   847   shows "box a b = {a <..< b}" "cbox a b = {a .. b}"
   848   by auto
   849 
   850 lemma rational_boxes:
   851   fixes x :: "'a\<Colon>euclidean_space"
   852   assumes "e > 0"
   853   shows "\<exists>a b. (\<forall>i\<in>Basis. a \<bullet> i \<in> \<rat> \<and> b \<bullet> i \<in> \<rat> ) \<and> x \<in> box a b \<and> box a b \<subseteq> ball x e"
   854 proof -
   855   def e' \<equiv> "e / (2 * sqrt (real (DIM ('a))))"
   856   then have e: "e' > 0"
   857     using assms by (auto intro!: divide_pos_pos simp: DIM_positive)
   858   have "\<forall>i. \<exists>y. y \<in> \<rat> \<and> y < x \<bullet> i \<and> x \<bullet> i - y < e'" (is "\<forall>i. ?th i")
   859   proof
   860     fix i
   861     from Rats_dense_in_real[of "x \<bullet> i - e'" "x \<bullet> i"] e
   862     show "?th i" by auto
   863   qed
   864   from choice[OF this] obtain a where
   865     a: "\<forall>xa. a xa \<in> \<rat> \<and> a xa < x \<bullet> xa \<and> x \<bullet> xa - a xa < e'" ..
   866   have "\<forall>i. \<exists>y. y \<in> \<rat> \<and> x \<bullet> i < y \<and> y - x \<bullet> i < e'" (is "\<forall>i. ?th i")
   867   proof
   868     fix i
   869     from Rats_dense_in_real[of "x \<bullet> i" "x \<bullet> i + e'"] e
   870     show "?th i" by auto
   871   qed
   872   from choice[OF this] obtain b where
   873     b: "\<forall>xa. b xa \<in> \<rat> \<and> x \<bullet> xa < b xa \<and> b xa - x \<bullet> xa < e'" ..
   874   let ?a = "\<Sum>i\<in>Basis. a i *\<^sub>R i" and ?b = "\<Sum>i\<in>Basis. b i *\<^sub>R i"
   875   show ?thesis
   876   proof (rule exI[of _ ?a], rule exI[of _ ?b], safe)
   877     fix y :: 'a
   878     assume *: "y \<in> box ?a ?b"
   879     have "dist x y = sqrt (\<Sum>i\<in>Basis. (dist (x \<bullet> i) (y \<bullet> i))\<^sup>2)"
   880       unfolding setL2_def[symmetric] by (rule euclidean_dist_l2)
   881     also have "\<dots> < sqrt (\<Sum>(i::'a)\<in>Basis. e^2 / real (DIM('a)))"
   882     proof (rule real_sqrt_less_mono, rule setsum_strict_mono)
   883       fix i :: "'a"
   884       assume i: "i \<in> Basis"
   885       have "a i < y\<bullet>i \<and> y\<bullet>i < b i"
   886         using * i by (auto simp: box_def)
   887       moreover have "a i < x\<bullet>i" "x\<bullet>i - a i < e'"
   888         using a by auto
   889       moreover have "x\<bullet>i < b i" "b i - x\<bullet>i < e'"
   890         using b by auto
   891       ultimately have "\<bar>x\<bullet>i - y\<bullet>i\<bar> < 2 * e'"
   892         by auto
   893       then have "dist (x \<bullet> i) (y \<bullet> i) < e/sqrt (real (DIM('a)))"
   894         unfolding e'_def by (auto simp: dist_real_def)
   895       then have "(dist (x \<bullet> i) (y \<bullet> i))\<^sup>2 < (e/sqrt (real (DIM('a))))\<^sup>2"
   896         by (rule power_strict_mono) auto
   897       then show "(dist (x \<bullet> i) (y \<bullet> i))\<^sup>2 < e\<^sup>2 / real DIM('a)"
   898         by (simp add: power_divide)
   899     qed auto
   900     also have "\<dots> = e"
   901       using `0 < e` by (simp add: real_eq_of_nat)
   902     finally show "y \<in> ball x e"
   903       by (auto simp: ball_def)
   904   qed (insert a b, auto simp: box_def)
   905 qed
   906 
   907 lemma open_UNION_box:
   908   fixes M :: "'a\<Colon>euclidean_space set"
   909   assumes "open M"
   910   defines "a' \<equiv> \<lambda>f :: 'a \<Rightarrow> real \<times> real. (\<Sum>(i::'a)\<in>Basis. fst (f i) *\<^sub>R i)"
   911   defines "b' \<equiv> \<lambda>f :: 'a \<Rightarrow> real \<times> real. (\<Sum>(i::'a)\<in>Basis. snd (f i) *\<^sub>R i)"
   912   defines "I \<equiv> {f\<in>Basis \<rightarrow>\<^sub>E \<rat> \<times> \<rat>. box (a' f) (b' f) \<subseteq> M}"
   913   shows "M = (\<Union>f\<in>I. box (a' f) (b' f))"
   914 proof -
   915   {
   916     fix x assume "x \<in> M"
   917     obtain e where e: "e > 0" "ball x e \<subseteq> M"
   918       using openE[OF `open M` `x \<in> M`] by auto
   919     moreover obtain a b where ab:
   920       "x \<in> box a b"
   921       "\<forall>i \<in> Basis. a \<bullet> i \<in> \<rat>"
   922       "\<forall>i\<in>Basis. b \<bullet> i \<in> \<rat>"
   923       "box a b \<subseteq> ball x e"
   924       using rational_boxes[OF e(1)] by metis
   925     ultimately have "x \<in> (\<Union>f\<in>I. box (a' f) (b' f))"
   926        by (intro UN_I[of "\<lambda>i\<in>Basis. (a \<bullet> i, b \<bullet> i)"])
   927           (auto simp: euclidean_representation I_def a'_def b'_def)
   928   }
   929   then show ?thesis by (auto simp: I_def)
   930 qed
   931 
   932 lemma box_eq_empty:
   933   fixes a :: "'a::euclidean_space"
   934   shows "(box a b = {} \<longleftrightarrow> (\<exists>i\<in>Basis. b\<bullet>i \<le> a\<bullet>i))" (is ?th1)
   935     and "(cbox a b = {} \<longleftrightarrow> (\<exists>i\<in>Basis. b\<bullet>i < a\<bullet>i))" (is ?th2)
   936 proof -
   937   {
   938     fix i x
   939     assume i: "i\<in>Basis" and as:"b\<bullet>i \<le> a\<bullet>i" and x:"x\<in>box a b"
   940     then have "a \<bullet> i < x \<bullet> i \<and> x \<bullet> i < b \<bullet> i"
   941       unfolding mem_box by (auto simp: box_def)
   942     then have "a\<bullet>i < b\<bullet>i" by auto
   943     then have False using as by auto
   944   }
   945   moreover
   946   {
   947     assume as: "\<forall>i\<in>Basis. \<not> (b\<bullet>i \<le> a\<bullet>i)"
   948     let ?x = "(1/2) *\<^sub>R (a + b)"
   949     {
   950       fix i :: 'a
   951       assume i: "i \<in> Basis"
   952       have "a\<bullet>i < b\<bullet>i"
   953         using as[THEN bspec[where x=i]] i by auto
   954       then have "a\<bullet>i < ((1/2) *\<^sub>R (a+b)) \<bullet> i" "((1/2) *\<^sub>R (a+b)) \<bullet> i < b\<bullet>i"
   955         by (auto simp: inner_add_left)
   956     }
   957     then have "box a b \<noteq> {}"
   958       using mem_box(1)[of "?x" a b] by auto
   959   }
   960   ultimately show ?th1 by blast
   961 
   962   {
   963     fix i x
   964     assume i: "i \<in> Basis" and as:"b\<bullet>i < a\<bullet>i" and x:"x\<in>cbox a b"
   965     then have "a \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> b \<bullet> i"
   966       unfolding mem_box by auto
   967     then have "a\<bullet>i \<le> b\<bullet>i" by auto
   968     then have False using as by auto
   969   }
   970   moreover
   971   {
   972     assume as:"\<forall>i\<in>Basis. \<not> (b\<bullet>i < a\<bullet>i)"
   973     let ?x = "(1/2) *\<^sub>R (a + b)"
   974     {
   975       fix i :: 'a
   976       assume i:"i \<in> Basis"
   977       have "a\<bullet>i \<le> b\<bullet>i"
   978         using as[THEN bspec[where x=i]] i by auto
   979       then have "a\<bullet>i \<le> ((1/2) *\<^sub>R (a+b)) \<bullet> i" "((1/2) *\<^sub>R (a+b)) \<bullet> i \<le> b\<bullet>i"
   980         by (auto simp: inner_add_left)
   981     }
   982     then have "cbox a b \<noteq> {}"
   983       using mem_box(2)[of "?x" a b] by auto
   984   }
   985   ultimately show ?th2 by blast
   986 qed
   987 
   988 lemma box_ne_empty:
   989   fixes a :: "'a::euclidean_space"
   990   shows "cbox a b \<noteq> {} \<longleftrightarrow> (\<forall>i\<in>Basis. a\<bullet>i \<le> b\<bullet>i)"
   991   and "box a b \<noteq> {} \<longleftrightarrow> (\<forall>i\<in>Basis. a\<bullet>i < b\<bullet>i)"
   992   unfolding box_eq_empty[of a b] by fastforce+
   993 
   994 lemma
   995   fixes a :: "'a::euclidean_space"
   996   shows cbox_sing: "cbox a a = {a}"
   997     and box_sing: "box a a = {}"
   998   unfolding set_eq_iff mem_box eq_iff [symmetric]
   999   by (auto intro!: euclidean_eqI[where 'a='a])
  1000      (metis all_not_in_conv nonempty_Basis)
  1001 
  1002 lemma subset_box_imp:
  1003   fixes a :: "'a::euclidean_space"
  1004   shows "(\<forall>i\<in>Basis. a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i) \<Longrightarrow> cbox c d \<subseteq> cbox a b"
  1005     and "(\<forall>i\<in>Basis. a\<bullet>i < c\<bullet>i \<and> d\<bullet>i < b\<bullet>i) \<Longrightarrow> cbox c d \<subseteq> box a b"
  1006     and "(\<forall>i\<in>Basis. a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i) \<Longrightarrow> box c d \<subseteq> cbox a b"
  1007      and "(\<forall>i\<in>Basis. a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i) \<Longrightarrow> box c d \<subseteq> box a b"
  1008   unfolding subset_eq[unfolded Ball_def] unfolding mem_box
  1009    by (best intro: order_trans less_le_trans le_less_trans less_imp_le)+
  1010 
  1011 lemma box_subset_cbox:
  1012   fixes a :: "'a::euclidean_space"
  1013   shows "box a b \<subseteq> cbox a b"
  1014   unfolding subset_eq [unfolded Ball_def] mem_box
  1015   by (fast intro: less_imp_le)
  1016 
  1017 lemma subset_box:
  1018   fixes a :: "'a::euclidean_space"
  1019   shows "cbox c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i\<in>Basis. c\<bullet>i \<le> d\<bullet>i) --> (\<forall>i\<in>Basis. a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i)" (is ?th1)
  1020     and "cbox c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i\<in>Basis. c\<bullet>i \<le> d\<bullet>i) --> (\<forall>i\<in>Basis. a\<bullet>i < c\<bullet>i \<and> d\<bullet>i < b\<bullet>i)" (is ?th2)
  1021     and "box c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i\<in>Basis. c\<bullet>i < d\<bullet>i) --> (\<forall>i\<in>Basis. a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i)" (is ?th3)
  1022     and "box c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i\<in>Basis. c\<bullet>i < d\<bullet>i) --> (\<forall>i\<in>Basis. a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i)" (is ?th4)
  1023 proof -
  1024   show ?th1
  1025     unfolding subset_eq and Ball_def and mem_box
  1026     by (auto intro: order_trans)
  1027   show ?th2
  1028     unfolding subset_eq and Ball_def and mem_box
  1029     by (auto intro: le_less_trans less_le_trans order_trans less_imp_le)
  1030   {
  1031     assume as: "box c d \<subseteq> cbox a b" "\<forall>i\<in>Basis. c\<bullet>i < d\<bullet>i"
  1032     then have "box c d \<noteq> {}"
  1033       unfolding box_eq_empty by auto
  1034     fix i :: 'a
  1035     assume i: "i \<in> Basis"
  1036     (** TODO combine the following two parts as done in the HOL_light version. **)
  1037     {
  1038       let ?x = "(\<Sum>j\<in>Basis. (if j=i then ((min (a\<bullet>j) (d\<bullet>j))+c\<bullet>j)/2 else (c\<bullet>j+d\<bullet>j)/2) *\<^sub>R j)::'a"
  1039       assume as2: "a\<bullet>i > c\<bullet>i"
  1040       {
  1041         fix j :: 'a
  1042         assume j: "j \<in> Basis"
  1043         then have "c \<bullet> j < ?x \<bullet> j \<and> ?x \<bullet> j < d \<bullet> j"
  1044           apply (cases "j = i")
  1045           using as(2)[THEN bspec[where x=j]] i
  1046           apply (auto simp add: as2)
  1047           done
  1048       }
  1049       then have "?x\<in>box c d"
  1050         using i unfolding mem_box by auto
  1051       moreover
  1052       have "?x \<notin> cbox a b"
  1053         unfolding mem_box
  1054         apply auto
  1055         apply (rule_tac x=i in bexI)
  1056         using as(2)[THEN bspec[where x=i]] and as2 i
  1057         apply auto
  1058         done
  1059       ultimately have False using as by auto
  1060     }
  1061     then have "a\<bullet>i \<le> c\<bullet>i" by (rule ccontr) auto
  1062     moreover
  1063     {
  1064       let ?x = "(\<Sum>j\<in>Basis. (if j=i then ((max (b\<bullet>j) (c\<bullet>j))+d\<bullet>j)/2 else (c\<bullet>j+d\<bullet>j)/2) *\<^sub>R j)::'a"
  1065       assume as2: "b\<bullet>i < d\<bullet>i"
  1066       {
  1067         fix j :: 'a
  1068         assume "j\<in>Basis"
  1069         then have "d \<bullet> j > ?x \<bullet> j \<and> ?x \<bullet> j > c \<bullet> j"
  1070           apply (cases "j = i")
  1071           using as(2)[THEN bspec[where x=j]]
  1072           apply (auto simp add: as2)
  1073           done
  1074       }
  1075       then have "?x\<in>box c d"
  1076         unfolding mem_box by auto
  1077       moreover
  1078       have "?x\<notin>cbox a b"
  1079         unfolding mem_box
  1080         apply auto
  1081         apply (rule_tac x=i in bexI)
  1082         using as(2)[THEN bspec[where x=i]] and as2 using i
  1083         apply auto
  1084         done
  1085       ultimately have False using as by auto
  1086     }
  1087     then have "b\<bullet>i \<ge> d\<bullet>i" by (rule ccontr) auto
  1088     ultimately
  1089     have "a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i" by auto
  1090   } note part1 = this
  1091   show ?th3
  1092     unfolding subset_eq and Ball_def and mem_box
  1093     apply (rule, rule, rule, rule)
  1094     apply (rule part1)
  1095     unfolding subset_eq and Ball_def and mem_box
  1096     prefer 4
  1097     apply auto
  1098     apply (erule_tac x=xa in allE, erule_tac x=xa in allE, fastforce)+
  1099     done
  1100   {
  1101     assume as: "box c d \<subseteq> box a b" "\<forall>i\<in>Basis. c\<bullet>i < d\<bullet>i"
  1102     fix i :: 'a
  1103     assume i:"i\<in>Basis"
  1104     from as(1) have "box c d \<subseteq> cbox a b"
  1105       using box_subset_cbox[of a b] by auto
  1106     then have "a\<bullet>i \<le> c\<bullet>i \<and> d\<bullet>i \<le> b\<bullet>i"
  1107       using part1 and as(2) using i by auto
  1108   } note * = this
  1109   show ?th4
  1110     unfolding subset_eq and Ball_def and mem_box
  1111     apply (rule, rule, rule, rule)
  1112     apply (rule *)
  1113     unfolding subset_eq and Ball_def and mem_box
  1114     prefer 4
  1115     apply auto
  1116     apply (erule_tac x=xa in allE, simp)+
  1117     done
  1118 qed
  1119 
  1120 lemma inter_interval:
  1121   fixes a :: "'a::euclidean_space"
  1122   shows "cbox a b \<inter> cbox c d =
  1123     cbox (\<Sum>i\<in>Basis. max (a\<bullet>i) (c\<bullet>i) *\<^sub>R i) (\<Sum>i\<in>Basis. min (b\<bullet>i) (d\<bullet>i) *\<^sub>R i)"
  1124   unfolding set_eq_iff and Int_iff and mem_box
  1125   by auto
  1126 
  1127 lemma disjoint_interval:
  1128   fixes a::"'a::euclidean_space"
  1129   shows "cbox a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i\<in>Basis. (b\<bullet>i < a\<bullet>i \<or> d\<bullet>i < c\<bullet>i \<or> b\<bullet>i < c\<bullet>i \<or> d\<bullet>i < a\<bullet>i))" (is ?th1)
  1130     and "cbox a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i\<in>Basis. (b\<bullet>i < a\<bullet>i \<or> d\<bullet>i \<le> c\<bullet>i \<or> b\<bullet>i \<le> c\<bullet>i \<or> d\<bullet>i \<le> a\<bullet>i))" (is ?th2)
  1131     and "box a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i\<in>Basis. (b\<bullet>i \<le> a\<bullet>i \<or> d\<bullet>i < c\<bullet>i \<or> b\<bullet>i \<le> c\<bullet>i \<or> d\<bullet>i \<le> a\<bullet>i))" (is ?th3)
  1132     and "box a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i\<in>Basis. (b\<bullet>i \<le> a\<bullet>i \<or> d\<bullet>i \<le> c\<bullet>i \<or> b\<bullet>i \<le> c\<bullet>i \<or> d\<bullet>i \<le> a\<bullet>i))" (is ?th4)
  1133 proof -
  1134   let ?z = "(\<Sum>i\<in>Basis. (((max (a\<bullet>i) (c\<bullet>i)) + (min (b\<bullet>i) (d\<bullet>i))) / 2) *\<^sub>R i)::'a"
  1135   have **: "\<And>P Q. (\<And>i :: 'a. i \<in> Basis \<Longrightarrow> Q ?z i \<Longrightarrow> P i) \<Longrightarrow>
  1136       (\<And>i x :: 'a. i \<in> Basis \<Longrightarrow> P i \<Longrightarrow> Q x i) \<Longrightarrow> (\<forall>x. \<exists>i\<in>Basis. Q x i) \<longleftrightarrow> (\<exists>i\<in>Basis. P i)"
  1137     by blast
  1138   note * = set_eq_iff Int_iff empty_iff mem_box ball_conj_distrib[symmetric] eq_False ball_simps(10)
  1139   show ?th1 unfolding * by (intro **) auto
  1140   show ?th2 unfolding * by (intro **) auto
  1141   show ?th3 unfolding * by (intro **) auto
  1142   show ?th4 unfolding * by (intro **) auto
  1143 qed
  1144 
  1145 text {* Intervals in general, including infinite and mixtures of open and closed. *}
  1146 
  1147 definition "is_interval (s::('a::euclidean_space) set) \<longleftrightarrow>
  1148   (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i\<in>Basis. ((a\<bullet>i \<le> x\<bullet>i \<and> x\<bullet>i \<le> b\<bullet>i) \<or> (b\<bullet>i \<le> x\<bullet>i \<and> x\<bullet>i \<le> a\<bullet>i))) \<longrightarrow> x \<in> s)"
  1149 
  1150 lemma is_interval_cbox: "is_interval (cbox a (b::'a::euclidean_space))" (is ?th1)
  1151   and is_interval_box: "is_interval (box a b)" (is ?th2)
  1152   unfolding is_interval_def mem_box Ball_def atLeastAtMost_iff
  1153   by (meson order_trans le_less_trans less_le_trans less_trans)+
  1154 
  1155 lemma is_interval_empty:
  1156  "is_interval {}"
  1157   unfolding is_interval_def
  1158   by simp
  1159 
  1160 lemma is_interval_univ:
  1161  "is_interval UNIV"
  1162   unfolding is_interval_def
  1163   by simp
  1164 
  1165 lemma mem_is_intervalI:
  1166   assumes "is_interval s"
  1167   assumes "a \<in> s" "b \<in> s"
  1168   assumes "\<And>i. i \<in> Basis \<Longrightarrow> a \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> b \<bullet> i \<or> b \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> a \<bullet> i"
  1169   shows "x \<in> s"
  1170   by (rule assms(1)[simplified is_interval_def, rule_format, OF assms(2,3,4)])
  1171 
  1172 lemma interval_subst:
  1173   fixes S::"'a::euclidean_space set"
  1174   assumes "is_interval S"
  1175   assumes "x \<in> S" "y j \<in> S"
  1176   assumes "j \<in> Basis"
  1177   shows "(\<Sum>i\<in>Basis. (if i = j then y i \<bullet> i else x \<bullet> i) *\<^sub>R i) \<in> S"
  1178   by (rule mem_is_intervalI[OF assms(1,2)]) (auto simp: assms)
  1179 
  1180 lemma mem_box_componentwiseI:
  1181   fixes S::"'a::euclidean_space set"
  1182   assumes "is_interval S"
  1183   assumes "\<And>i. i \<in> Basis \<Longrightarrow> x \<bullet> i \<in> ((\<lambda>x. x \<bullet> i) ` S)"
  1184   shows "x \<in> S"
  1185 proof -
  1186   from assms have "\<forall>i \<in> Basis. \<exists>s \<in> S. x \<bullet> i = s \<bullet> i"
  1187     by auto
  1188   with finite_Basis obtain s and bs::"'a list" where
  1189     s: "\<And>i. i \<in> Basis \<Longrightarrow> x \<bullet> i = s i \<bullet> i" "\<And>i. i \<in> Basis \<Longrightarrow> s i \<in> S" and
  1190     bs: "set bs = Basis" "distinct bs"
  1191     by (metis finite_distinct_list)
  1192   from nonempty_Basis s obtain j where j: "j \<in> Basis" "s j \<in> S" by blast
  1193   def y \<equiv> "rec_list
  1194     (s j)
  1195     (\<lambda>j _ Y. (\<Sum>i\<in>Basis. (if i = j then s i \<bullet> i else Y \<bullet> i) *\<^sub>R i))"
  1196   have "x = (\<Sum>i\<in>Basis. (if i \<in> set bs then s i \<bullet> i else s j \<bullet> i) *\<^sub>R i)"
  1197     using bs by (auto simp add: s(1)[symmetric] euclidean_representation)
  1198   also have [symmetric]: "y bs = \<dots>"
  1199     using bs(2) bs(1)[THEN equalityD1]
  1200     by (induct bs) (auto simp: y_def euclidean_representation intro!: euclidean_eqI[where 'a='a])
  1201   also have "y bs \<in> S"
  1202     using bs(1)[THEN equalityD1]
  1203     apply (induct bs)
  1204     apply (auto simp: y_def j)
  1205     apply (rule interval_subst[OF assms(1)])
  1206     apply (auto simp: s)
  1207     done
  1208   finally show ?thesis .
  1209 qed
  1210 
  1211 
  1212 subsection{* Connectedness *}
  1213 
  1214 lemma connected_local:
  1215  "connected S \<longleftrightarrow>
  1216   \<not> (\<exists>e1 e2.
  1217       openin (subtopology euclidean S) e1 \<and>
  1218       openin (subtopology euclidean S) e2 \<and>
  1219       S \<subseteq> e1 \<union> e2 \<and>
  1220       e1 \<inter> e2 = {} \<and>
  1221       e1 \<noteq> {} \<and>
  1222       e2 \<noteq> {})"
  1223   unfolding connected_def openin_open
  1224   by blast
  1225 
  1226 lemma exists_diff:
  1227   fixes P :: "'a set \<Rightarrow> bool"
  1228   shows "(\<exists>S. P(- S)) \<longleftrightarrow> (\<exists>S. P S)" (is "?lhs \<longleftrightarrow> ?rhs")
  1229 proof -
  1230   {
  1231     assume "?lhs"
  1232     then have ?rhs by blast
  1233   }
  1234   moreover
  1235   {
  1236     fix S
  1237     assume H: "P S"
  1238     have "S = - (- S)" by auto
  1239     with H have "P (- (- S))" by metis
  1240   }
  1241   ultimately show ?thesis by metis
  1242 qed
  1243 
  1244 lemma connected_clopen: "connected S \<longleftrightarrow>
  1245   (\<forall>T. openin (subtopology euclidean S) T \<and>
  1246      closedin (subtopology euclidean S) T \<longrightarrow> T = {} \<or> T = S)" (is "?lhs \<longleftrightarrow> ?rhs")
  1247 proof -
  1248   have "\<not> connected S \<longleftrightarrow>
  1249     (\<exists>e1 e2. open e1 \<and> open (- e2) \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
  1250     unfolding connected_def openin_open closedin_closed
  1251     by (metis double_complement)
  1252   then have th0: "connected S \<longleftrightarrow>
  1253     \<not> (\<exists>e2 e1. closed e2 \<and> open e1 \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
  1254     (is " _ \<longleftrightarrow> \<not> (\<exists>e2 e1. ?P e2 e1)")
  1255     apply (simp add: closed_def)
  1256     apply metis
  1257     done
  1258   have th1: "?rhs \<longleftrightarrow> \<not> (\<exists>t' t. closed t'\<and>t = S\<inter>t' \<and> t\<noteq>{} \<and> t\<noteq>S \<and> (\<exists>t'. open t' \<and> t = S \<inter> t'))"
  1259     (is "_ \<longleftrightarrow> \<not> (\<exists>t' t. ?Q t' t)")
  1260     unfolding connected_def openin_open closedin_closed by auto
  1261   {
  1262     fix e2
  1263     {
  1264       fix e1
  1265       have "?P e2 e1 \<longleftrightarrow> (\<exists>t. closed e2 \<and> t = S\<inter>e2 \<and> open e1 \<and> t = S\<inter>e1 \<and> t\<noteq>{} \<and> t \<noteq> S)"
  1266         by auto
  1267     }
  1268     then have "(\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)"
  1269       by metis
  1270   }
  1271   then have "\<forall>e2. (\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)"
  1272     by blast
  1273   then show ?thesis
  1274     unfolding th0 th1 by simp
  1275 qed
  1276 
  1277 
  1278 subsection{* Limit points *}
  1279 
  1280 definition (in topological_space) islimpt:: "'a \<Rightarrow> 'a set \<Rightarrow> bool"  (infixr "islimpt" 60)
  1281   where "x islimpt S \<longleftrightarrow> (\<forall>T. x\<in>T \<longrightarrow> open T \<longrightarrow> (\<exists>y\<in>S. y\<in>T \<and> y\<noteq>x))"
  1282 
  1283 lemma islimptI:
  1284   assumes "\<And>T. x \<in> T \<Longrightarrow> open T \<Longrightarrow> \<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
  1285   shows "x islimpt S"
  1286   using assms unfolding islimpt_def by auto
  1287 
  1288 lemma islimptE:
  1289   assumes "x islimpt S" and "x \<in> T" and "open T"
  1290   obtains y where "y \<in> S" and "y \<in> T" and "y \<noteq> x"
  1291   using assms unfolding islimpt_def by auto
  1292 
  1293 lemma islimpt_iff_eventually: "x islimpt S \<longleftrightarrow> \<not> eventually (\<lambda>y. y \<notin> S) (at x)"
  1294   unfolding islimpt_def eventually_at_topological by auto
  1295 
  1296 lemma islimpt_subset: "x islimpt S \<Longrightarrow> S \<subseteq> T \<Longrightarrow> x islimpt T"
  1297   unfolding islimpt_def by fast
  1298 
  1299 lemma islimpt_approachable:
  1300   fixes x :: "'a::metric_space"
  1301   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e)"
  1302   unfolding islimpt_iff_eventually eventually_at by fast
  1303 
  1304 lemma islimpt_approachable_le:
  1305   fixes x :: "'a::metric_space"
  1306   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in> S. x' \<noteq> x \<and> dist x' x \<le> e)"
  1307   unfolding islimpt_approachable
  1308   using approachable_lt_le [where f="\<lambda>y. dist y x" and P="\<lambda>y. y \<notin> S \<or> y = x",
  1309     THEN arg_cong [where f=Not]]
  1310   by (simp add: Bex_def conj_commute conj_left_commute)
  1311 
  1312 lemma islimpt_UNIV_iff: "x islimpt UNIV \<longleftrightarrow> \<not> open {x}"
  1313   unfolding islimpt_def by (safe, fast, case_tac "T = {x}", fast, fast)
  1314 
  1315 lemma islimpt_punctured: "x islimpt S = x islimpt (S-{x})"
  1316   unfolding islimpt_def by blast
  1317 
  1318 text {* A perfect space has no isolated points. *}
  1319 
  1320 lemma islimpt_UNIV [simp, intro]: "(x::'a::perfect_space) islimpt UNIV"
  1321   unfolding islimpt_UNIV_iff by (rule not_open_singleton)
  1322 
  1323 lemma perfect_choose_dist:
  1324   fixes x :: "'a::{perfect_space, metric_space}"
  1325   shows "0 < r \<Longrightarrow> \<exists>a. a \<noteq> x \<and> dist a x < r"
  1326   using islimpt_UNIV [of x]
  1327   by (simp add: islimpt_approachable)
  1328 
  1329 lemma closed_limpt: "closed S \<longleftrightarrow> (\<forall>x. x islimpt S \<longrightarrow> x \<in> S)"
  1330   unfolding closed_def
  1331   apply (subst open_subopen)
  1332   apply (simp add: islimpt_def subset_eq)
  1333   apply (metis ComplE ComplI)
  1334   done
  1335 
  1336 lemma islimpt_EMPTY[simp]: "\<not> x islimpt {}"
  1337   unfolding islimpt_def by auto
  1338 
  1339 lemma finite_set_avoid:
  1340   fixes a :: "'a::metric_space"
  1341   assumes fS: "finite S"
  1342   shows  "\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<longrightarrow> d \<le> dist a x"
  1343 proof (induct rule: finite_induct[OF fS])
  1344   case 1
  1345   then show ?case by (auto intro: zero_less_one)
  1346 next
  1347   case (2 x F)
  1348   from 2 obtain d where d: "d >0" "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> d \<le> dist a x"
  1349     by blast
  1350   show ?case
  1351   proof (cases "x = a")
  1352     case True
  1353     then show ?thesis using d by auto
  1354   next
  1355     case False
  1356     let ?d = "min d (dist a x)"
  1357     have dp: "?d > 0"
  1358       using False d(1) using dist_nz by auto
  1359     from d have d': "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> ?d \<le> dist a x"
  1360       by auto
  1361     with dp False show ?thesis
  1362       by (auto intro!: exI[where x="?d"])
  1363   qed
  1364 qed
  1365 
  1366 lemma islimpt_Un: "x islimpt (S \<union> T) \<longleftrightarrow> x islimpt S \<or> x islimpt T"
  1367   by (simp add: islimpt_iff_eventually eventually_conj_iff)
  1368 
  1369 lemma discrete_imp_closed:
  1370   fixes S :: "'a::metric_space set"
  1371   assumes e: "0 < e"
  1372     and d: "\<forall>x \<in> S. \<forall>y \<in> S. dist y x < e \<longrightarrow> y = x"
  1373   shows "closed S"
  1374 proof -
  1375   {
  1376     fix x
  1377     assume C: "\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e"
  1378     from e have e2: "e/2 > 0" by arith
  1379     from C[rule_format, OF e2] obtain y where y: "y \<in> S" "y \<noteq> x" "dist y x < e/2"
  1380       by blast
  1381     let ?m = "min (e/2) (dist x y) "
  1382     from e2 y(2) have mp: "?m > 0"
  1383       by (simp add: dist_nz[symmetric])
  1384     from C[rule_format, OF mp] obtain z where z: "z \<in> S" "z \<noteq> x" "dist z x < ?m"
  1385       by blast
  1386     have th: "dist z y < e" using z y
  1387       by (intro dist_triangle_lt [where z=x], simp)
  1388     from d[rule_format, OF y(1) z(1) th] y z
  1389     have False by (auto simp add: dist_commute)}
  1390   then show ?thesis
  1391     by (metis islimpt_approachable closed_limpt [where 'a='a])
  1392 qed
  1393 
  1394 
  1395 subsection {* Interior of a Set *}
  1396 
  1397 definition "interior S = \<Union>{T. open T \<and> T \<subseteq> S}"
  1398 
  1399 lemma interiorI [intro?]:
  1400   assumes "open T" and "x \<in> T" and "T \<subseteq> S"
  1401   shows "x \<in> interior S"
  1402   using assms unfolding interior_def by fast
  1403 
  1404 lemma interiorE [elim?]:
  1405   assumes "x \<in> interior S"
  1406   obtains T where "open T" and "x \<in> T" and "T \<subseteq> S"
  1407   using assms unfolding interior_def by fast
  1408 
  1409 lemma open_interior [simp, intro]: "open (interior S)"
  1410   by (simp add: interior_def open_Union)
  1411 
  1412 lemma interior_subset: "interior S \<subseteq> S"
  1413   by (auto simp add: interior_def)
  1414 
  1415 lemma interior_maximal: "T \<subseteq> S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> interior S"
  1416   by (auto simp add: interior_def)
  1417 
  1418 lemma interior_open: "open S \<Longrightarrow> interior S = S"
  1419   by (intro equalityI interior_subset interior_maximal subset_refl)
  1420 
  1421 lemma interior_eq: "interior S = S \<longleftrightarrow> open S"
  1422   by (metis open_interior interior_open)
  1423 
  1424 lemma open_subset_interior: "open S \<Longrightarrow> S \<subseteq> interior T \<longleftrightarrow> S \<subseteq> T"
  1425   by (metis interior_maximal interior_subset subset_trans)
  1426 
  1427 lemma interior_empty [simp]: "interior {} = {}"
  1428   using open_empty by (rule interior_open)
  1429 
  1430 lemma interior_UNIV [simp]: "interior UNIV = UNIV"
  1431   using open_UNIV by (rule interior_open)
  1432 
  1433 lemma interior_interior [simp]: "interior (interior S) = interior S"
  1434   using open_interior by (rule interior_open)
  1435 
  1436 lemma interior_mono: "S \<subseteq> T \<Longrightarrow> interior S \<subseteq> interior T"
  1437   by (auto simp add: interior_def)
  1438 
  1439 lemma interior_unique:
  1440   assumes "T \<subseteq> S" and "open T"
  1441   assumes "\<And>T'. T' \<subseteq> S \<Longrightarrow> open T' \<Longrightarrow> T' \<subseteq> T"
  1442   shows "interior S = T"
  1443   by (intro equalityI assms interior_subset open_interior interior_maximal)
  1444 
  1445 lemma interior_inter [simp]: "interior (S \<inter> T) = interior S \<inter> interior T"
  1446   by (intro equalityI Int_mono Int_greatest interior_mono Int_lower1
  1447     Int_lower2 interior_maximal interior_subset open_Int open_interior)
  1448 
  1449 lemma mem_interior: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
  1450   using open_contains_ball_eq [where S="interior S"]
  1451   by (simp add: open_subset_interior)
  1452 
  1453 lemma interior_limit_point [intro]:
  1454   fixes x :: "'a::perfect_space"
  1455   assumes x: "x \<in> interior S"
  1456   shows "x islimpt S"
  1457   using x islimpt_UNIV [of x]
  1458   unfolding interior_def islimpt_def
  1459   apply (clarsimp, rename_tac T T')
  1460   apply (drule_tac x="T \<inter> T'" in spec)
  1461   apply (auto simp add: open_Int)
  1462   done
  1463 
  1464 lemma interior_closed_Un_empty_interior:
  1465   assumes cS: "closed S"
  1466     and iT: "interior T = {}"
  1467   shows "interior (S \<union> T) = interior S"
  1468 proof
  1469   show "interior S \<subseteq> interior (S \<union> T)"
  1470     by (rule interior_mono) (rule Un_upper1)
  1471   show "interior (S \<union> T) \<subseteq> interior S"
  1472   proof
  1473     fix x
  1474     assume "x \<in> interior (S \<union> T)"
  1475     then obtain R where "open R" "x \<in> R" "R \<subseteq> S \<union> T" ..
  1476     show "x \<in> interior S"
  1477     proof (rule ccontr)
  1478       assume "x \<notin> interior S"
  1479       with `x \<in> R` `open R` obtain y where "y \<in> R - S"
  1480         unfolding interior_def by fast
  1481       from `open R` `closed S` have "open (R - S)"
  1482         by (rule open_Diff)
  1483       from `R \<subseteq> S \<union> T` have "R - S \<subseteq> T"
  1484         by fast
  1485       from `y \<in> R - S` `open (R - S)` `R - S \<subseteq> T` `interior T = {}` show False
  1486         unfolding interior_def by fast
  1487     qed
  1488   qed
  1489 qed
  1490 
  1491 lemma interior_Times: "interior (A \<times> B) = interior A \<times> interior B"
  1492 proof (rule interior_unique)
  1493   show "interior A \<times> interior B \<subseteq> A \<times> B"
  1494     by (intro Sigma_mono interior_subset)
  1495   show "open (interior A \<times> interior B)"
  1496     by (intro open_Times open_interior)
  1497   fix T
  1498   assume "T \<subseteq> A \<times> B" and "open T"
  1499   then show "T \<subseteq> interior A \<times> interior B"
  1500   proof safe
  1501     fix x y
  1502     assume "(x, y) \<in> T"
  1503     then obtain C D where "open C" "open D" "C \<times> D \<subseteq> T" "x \<in> C" "y \<in> D"
  1504       using `open T` unfolding open_prod_def by fast
  1505     then have "open C" "open D" "C \<subseteq> A" "D \<subseteq> B" "x \<in> C" "y \<in> D"
  1506       using `T \<subseteq> A \<times> B` by auto
  1507     then show "x \<in> interior A" and "y \<in> interior B"
  1508       by (auto intro: interiorI)
  1509   qed
  1510 qed
  1511 
  1512 
  1513 subsection {* Closure of a Set *}
  1514 
  1515 definition "closure S = S \<union> {x | x. x islimpt S}"
  1516 
  1517 lemma interior_closure: "interior S = - (closure (- S))"
  1518   unfolding interior_def closure_def islimpt_def by auto
  1519 
  1520 lemma closure_interior: "closure S = - interior (- S)"
  1521   unfolding interior_closure by simp
  1522 
  1523 lemma closed_closure[simp, intro]: "closed (closure S)"
  1524   unfolding closure_interior by (simp add: closed_Compl)
  1525 
  1526 lemma closure_subset: "S \<subseteq> closure S"
  1527   unfolding closure_def by simp
  1528 
  1529 lemma closure_hull: "closure S = closed hull S"
  1530   unfolding hull_def closure_interior interior_def by auto
  1531 
  1532 lemma closure_eq: "closure S = S \<longleftrightarrow> closed S"
  1533   unfolding closure_hull using closed_Inter by (rule hull_eq)
  1534 
  1535 lemma closure_closed [simp]: "closed S \<Longrightarrow> closure S = S"
  1536   unfolding closure_eq .
  1537 
  1538 lemma closure_closure [simp]: "closure (closure S) = closure S"
  1539   unfolding closure_hull by (rule hull_hull)
  1540 
  1541 lemma closure_mono: "S \<subseteq> T \<Longrightarrow> closure S \<subseteq> closure T"
  1542   unfolding closure_hull by (rule hull_mono)
  1543 
  1544 lemma closure_minimal: "S \<subseteq> T \<Longrightarrow> closed T \<Longrightarrow> closure S \<subseteq> T"
  1545   unfolding closure_hull by (rule hull_minimal)
  1546 
  1547 lemma closure_unique:
  1548   assumes "S \<subseteq> T"
  1549     and "closed T"
  1550     and "\<And>T'. S \<subseteq> T' \<Longrightarrow> closed T' \<Longrightarrow> T \<subseteq> T'"
  1551   shows "closure S = T"
  1552   using assms unfolding closure_hull by (rule hull_unique)
  1553 
  1554 lemma closure_empty [simp]: "closure {} = {}"
  1555   using closed_empty by (rule closure_closed)
  1556 
  1557 lemma closure_UNIV [simp]: "closure UNIV = UNIV"
  1558   using closed_UNIV by (rule closure_closed)
  1559 
  1560 lemma closure_union [simp]: "closure (S \<union> T) = closure S \<union> closure T"
  1561   unfolding closure_interior by simp
  1562 
  1563 lemma closure_eq_empty: "closure S = {} \<longleftrightarrow> S = {}"
  1564   using closure_empty closure_subset[of S]
  1565   by blast
  1566 
  1567 lemma closure_subset_eq: "closure S \<subseteq> S \<longleftrightarrow> closed S"
  1568   using closure_eq[of S] closure_subset[of S]
  1569   by simp
  1570 
  1571 lemma open_inter_closure_eq_empty:
  1572   "open S \<Longrightarrow> (S \<inter> closure T) = {} \<longleftrightarrow> S \<inter> T = {}"
  1573   using open_subset_interior[of S "- T"]
  1574   using interior_subset[of "- T"]
  1575   unfolding closure_interior
  1576   by auto
  1577 
  1578 lemma open_inter_closure_subset:
  1579   "open S \<Longrightarrow> (S \<inter> (closure T)) \<subseteq> closure(S \<inter> T)"
  1580 proof
  1581   fix x
  1582   assume as: "open S" "x \<in> S \<inter> closure T"
  1583   {
  1584     assume *: "x islimpt T"
  1585     have "x islimpt (S \<inter> T)"
  1586     proof (rule islimptI)
  1587       fix A
  1588       assume "x \<in> A" "open A"
  1589       with as have "x \<in> A \<inter> S" "open (A \<inter> S)"
  1590         by (simp_all add: open_Int)
  1591       with * obtain y where "y \<in> T" "y \<in> A \<inter> S" "y \<noteq> x"
  1592         by (rule islimptE)
  1593       then have "y \<in> S \<inter> T" "y \<in> A \<and> y \<noteq> x"
  1594         by simp_all
  1595       then show "\<exists>y\<in>(S \<inter> T). y \<in> A \<and> y \<noteq> x" ..
  1596     qed
  1597   }
  1598   then show "x \<in> closure (S \<inter> T)" using as
  1599     unfolding closure_def
  1600     by blast
  1601 qed
  1602 
  1603 lemma closure_complement: "closure (- S) = - interior S"
  1604   unfolding closure_interior by simp
  1605 
  1606 lemma interior_complement: "interior (- S) = - closure S"
  1607   unfolding closure_interior by simp
  1608 
  1609 lemma closure_Times: "closure (A \<times> B) = closure A \<times> closure B"
  1610 proof (rule closure_unique)
  1611   show "A \<times> B \<subseteq> closure A \<times> closure B"
  1612     by (intro Sigma_mono closure_subset)
  1613   show "closed (closure A \<times> closure B)"
  1614     by (intro closed_Times closed_closure)
  1615   fix T
  1616   assume "A \<times> B \<subseteq> T" and "closed T"
  1617   then show "closure A \<times> closure B \<subseteq> T"
  1618     apply (simp add: closed_def open_prod_def, clarify)
  1619     apply (rule ccontr)
  1620     apply (drule_tac x="(a, b)" in bspec, simp, clarify, rename_tac C D)
  1621     apply (simp add: closure_interior interior_def)
  1622     apply (drule_tac x=C in spec)
  1623     apply (drule_tac x=D in spec)
  1624     apply auto
  1625     done
  1626 qed
  1627 
  1628 lemma islimpt_in_closure: "(x islimpt S) = (x:closure(S-{x}))"
  1629   unfolding closure_def using islimpt_punctured by blast
  1630 
  1631 
  1632 subsection {* Frontier (aka boundary) *}
  1633 
  1634 definition "frontier S = closure S - interior S"
  1635 
  1636 lemma frontier_closed: "closed (frontier S)"
  1637   by (simp add: frontier_def closed_Diff)
  1638 
  1639 lemma frontier_closures: "frontier S = (closure S) \<inter> (closure(- S))"
  1640   by (auto simp add: frontier_def interior_closure)
  1641 
  1642 lemma frontier_straddle:
  1643   fixes a :: "'a::metric_space"
  1644   shows "a \<in> frontier S \<longleftrightarrow> (\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e))"
  1645   unfolding frontier_def closure_interior
  1646   by (auto simp add: mem_interior subset_eq ball_def)
  1647 
  1648 lemma frontier_subset_closed: "closed S \<Longrightarrow> frontier S \<subseteq> S"
  1649   by (metis frontier_def closure_closed Diff_subset)
  1650 
  1651 lemma frontier_empty[simp]: "frontier {} = {}"
  1652   by (simp add: frontier_def)
  1653 
  1654 lemma frontier_subset_eq: "frontier S \<subseteq> S \<longleftrightarrow> closed S"
  1655 proof-
  1656   {
  1657     assume "frontier S \<subseteq> S"
  1658     then have "closure S \<subseteq> S"
  1659       using interior_subset unfolding frontier_def by auto
  1660     then have "closed S"
  1661       using closure_subset_eq by auto
  1662   }
  1663   then show ?thesis using frontier_subset_closed[of S] ..
  1664 qed
  1665 
  1666 lemma frontier_complement: "frontier(- S) = frontier S"
  1667   by (auto simp add: frontier_def closure_complement interior_complement)
  1668 
  1669 lemma frontier_disjoint_eq: "frontier S \<inter> S = {} \<longleftrightarrow> open S"
  1670   using frontier_complement frontier_subset_eq[of "- S"]
  1671   unfolding open_closed by auto
  1672 
  1673 subsection {* Filters and the ``eventually true'' quantifier *}
  1674 
  1675 definition indirection :: "'a::real_normed_vector \<Rightarrow> 'a \<Rightarrow> 'a filter"
  1676     (infixr "indirection" 70)
  1677   where "a indirection v = at a within {b. \<exists>c\<ge>0. b - a = scaleR c v}"
  1678 
  1679 text {* Identify Trivial limits, where we can't approach arbitrarily closely. *}
  1680 
  1681 lemma trivial_limit_within: "trivial_limit (at a within S) \<longleftrightarrow> \<not> a islimpt S"
  1682 proof
  1683   assume "trivial_limit (at a within S)"
  1684   then show "\<not> a islimpt S"
  1685     unfolding trivial_limit_def
  1686     unfolding eventually_at_topological
  1687     unfolding islimpt_def
  1688     apply (clarsimp simp add: set_eq_iff)
  1689     apply (rename_tac T, rule_tac x=T in exI)
  1690     apply (clarsimp, drule_tac x=y in bspec, simp_all)
  1691     done
  1692 next
  1693   assume "\<not> a islimpt S"
  1694   then show "trivial_limit (at a within S)"
  1695     unfolding trivial_limit_def eventually_at_topological islimpt_def
  1696     by metis
  1697 qed
  1698 
  1699 lemma trivial_limit_at_iff: "trivial_limit (at a) \<longleftrightarrow> \<not> a islimpt UNIV"
  1700   using trivial_limit_within [of a UNIV] by simp
  1701 
  1702 lemma trivial_limit_at:
  1703   fixes a :: "'a::perfect_space"
  1704   shows "\<not> trivial_limit (at a)"
  1705   by (rule at_neq_bot)
  1706 
  1707 lemma trivial_limit_at_infinity:
  1708   "\<not> trivial_limit (at_infinity :: ('a::{real_normed_vector,perfect_space}) filter)"
  1709   unfolding trivial_limit_def eventually_at_infinity
  1710   apply clarsimp
  1711   apply (subgoal_tac "\<exists>x::'a. x \<noteq> 0", clarify)
  1712    apply (rule_tac x="scaleR (b / norm x) x" in exI, simp)
  1713   apply (cut_tac islimpt_UNIV [of "0::'a", unfolded islimpt_def])
  1714   apply (drule_tac x=UNIV in spec, simp)
  1715   done
  1716 
  1717 lemma not_trivial_limit_within: "\<not> trivial_limit (at x within S) = (x \<in> closure (S - {x}))"
  1718   using islimpt_in_closure
  1719   by (metis trivial_limit_within)
  1720 
  1721 text {* Some property holds "sufficiently close" to the limit point. *}
  1722 
  1723 lemma eventually_at2:
  1724   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
  1725   unfolding eventually_at dist_nz by auto
  1726 
  1727 lemma eventually_happens: "eventually P net \<Longrightarrow> trivial_limit net \<or> (\<exists>x. P x)"
  1728   unfolding trivial_limit_def
  1729   by (auto elim: eventually_rev_mp)
  1730 
  1731 lemma trivial_limit_eventually: "trivial_limit net \<Longrightarrow> eventually P net"
  1732   by simp
  1733 
  1734 lemma trivial_limit_eq: "trivial_limit net \<longleftrightarrow> (\<forall>P. eventually P net)"
  1735   by (simp add: filter_eq_iff)
  1736 
  1737 text{* Combining theorems for "eventually" *}
  1738 
  1739 lemma eventually_rev_mono:
  1740   "eventually P net \<Longrightarrow> (\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually Q net"
  1741   using eventually_mono [of P Q] by fast
  1742 
  1743 lemma not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
  1744   by (simp add: eventually_False)
  1745 
  1746 
  1747 subsection {* Limits *}
  1748 
  1749 lemma Lim:
  1750   "(f ---> l) net \<longleftrightarrow>
  1751         trivial_limit net \<or>
  1752         (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
  1753   unfolding tendsto_iff trivial_limit_eq by auto
  1754 
  1755 text{* Show that they yield usual definitions in the various cases. *}
  1756 
  1757 lemma Lim_within_le: "(f ---> l)(at a within S) \<longleftrightarrow>
  1758     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a \<le> d \<longrightarrow> dist (f x) l < e)"
  1759   by (auto simp add: tendsto_iff eventually_at_le dist_nz)
  1760 
  1761 lemma Lim_within: "(f ---> l) (at a within S) \<longleftrightarrow>
  1762     (\<forall>e >0. \<exists>d>0. \<forall>x \<in> S. 0 < dist x a \<and> dist x a  < d \<longrightarrow> dist (f x) l < e)"
  1763   by (auto simp add: tendsto_iff eventually_at dist_nz)
  1764 
  1765 lemma Lim_at: "(f ---> l) (at a) \<longleftrightarrow>
  1766     (\<forall>e >0. \<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d  \<longrightarrow> dist (f x) l < e)"
  1767   by (auto simp add: tendsto_iff eventually_at2)
  1768 
  1769 lemma Lim_at_infinity:
  1770   "(f ---> l) at_infinity \<longleftrightarrow> (\<forall>e>0. \<exists>b. \<forall>x. norm x \<ge> b \<longrightarrow> dist (f x) l < e)"
  1771   by (auto simp add: tendsto_iff eventually_at_infinity)
  1772 
  1773 lemma Lim_eventually: "eventually (\<lambda>x. f x = l) net \<Longrightarrow> (f ---> l) net"
  1774   by (rule topological_tendstoI, auto elim: eventually_rev_mono)
  1775 
  1776 text{* The expected monotonicity property. *}
  1777 
  1778 lemma Lim_Un:
  1779   assumes "(f ---> l) (at x within S)" "(f ---> l) (at x within T)"
  1780   shows "(f ---> l) (at x within (S \<union> T))"
  1781   using assms unfolding at_within_union by (rule filterlim_sup)
  1782 
  1783 lemma Lim_Un_univ:
  1784   "(f ---> l) (at x within S) \<Longrightarrow> (f ---> l) (at x within T) \<Longrightarrow>
  1785     S \<union> T = UNIV \<Longrightarrow> (f ---> l) (at x)"
  1786   by (metis Lim_Un)
  1787 
  1788 text{* Interrelations between restricted and unrestricted limits. *}
  1789 
  1790 lemma Lim_at_within: (* FIXME: rename *)
  1791   "(f ---> l) (at x) \<Longrightarrow> (f ---> l) (at x within S)"
  1792   by (metis order_refl filterlim_mono subset_UNIV at_le)
  1793 
  1794 lemma eventually_within_interior:
  1795   assumes "x \<in> interior S"
  1796   shows "eventually P (at x within S) \<longleftrightarrow> eventually P (at x)"
  1797   (is "?lhs = ?rhs")
  1798 proof
  1799   from assms obtain T where T: "open T" "x \<in> T" "T \<subseteq> S" ..
  1800   {
  1801     assume "?lhs"
  1802     then obtain A where "open A" and "x \<in> A" and "\<forall>y\<in>A. y \<noteq> x \<longrightarrow> y \<in> S \<longrightarrow> P y"
  1803       unfolding eventually_at_topological
  1804       by auto
  1805     with T have "open (A \<inter> T)" and "x \<in> A \<inter> T" and "\<forall>y \<in> A \<inter> T. y \<noteq> x \<longrightarrow> P y"
  1806       by auto
  1807     then show "?rhs"
  1808       unfolding eventually_at_topological by auto
  1809   next
  1810     assume "?rhs"
  1811     then show "?lhs"
  1812       by (auto elim: eventually_elim1 simp: eventually_at_filter)
  1813   }
  1814 qed
  1815 
  1816 lemma at_within_interior:
  1817   "x \<in> interior S \<Longrightarrow> at x within S = at x"
  1818   unfolding filter_eq_iff by (intro allI eventually_within_interior)
  1819 
  1820 lemma Lim_within_LIMSEQ:
  1821   fixes a :: "'a::first_countable_topology"
  1822   assumes "\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1823   shows "(X ---> L) (at a within T)"
  1824   using assms unfolding tendsto_def [where l=L]
  1825   by (simp add: sequentially_imp_eventually_within)
  1826 
  1827 lemma Lim_right_bound:
  1828   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder, no_top} \<Rightarrow>
  1829     'b::{linorder_topology, conditionally_complete_linorder}"
  1830   assumes mono: "\<And>a b. a \<in> I \<Longrightarrow> b \<in> I \<Longrightarrow> x < a \<Longrightarrow> a \<le> b \<Longrightarrow> f a \<le> f b"
  1831     and bnd: "\<And>a. a \<in> I \<Longrightarrow> x < a \<Longrightarrow> K \<le> f a"
  1832   shows "(f ---> Inf (f ` ({x<..} \<inter> I))) (at x within ({x<..} \<inter> I))"
  1833 proof (cases "{x<..} \<inter> I = {}")
  1834   case True
  1835   then show ?thesis by simp
  1836 next
  1837   case False
  1838   show ?thesis
  1839   proof (rule order_tendstoI)
  1840     fix a
  1841     assume a: "a < Inf (f ` ({x<..} \<inter> I))"
  1842     {
  1843       fix y
  1844       assume "y \<in> {x<..} \<inter> I"
  1845       with False bnd have "Inf (f ` ({x<..} \<inter> I)) \<le> f y"
  1846         by (auto intro!: cInf_lower bdd_belowI2 simp del: Inf_image_eq)
  1847       with a have "a < f y"
  1848         by (blast intro: less_le_trans)
  1849     }
  1850     then show "eventually (\<lambda>x. a < f x) (at x within ({x<..} \<inter> I))"
  1851       by (auto simp: eventually_at_filter intro: exI[of _ 1] zero_less_one)
  1852   next
  1853     fix a
  1854     assume "Inf (f ` ({x<..} \<inter> I)) < a"
  1855     from cInf_lessD[OF _ this] False obtain y where y: "x < y" "y \<in> I" "f y < a"
  1856       by auto
  1857     then have "eventually (\<lambda>x. x \<in> I \<longrightarrow> f x < a) (at_right x)"
  1858       unfolding eventually_at_right by (metis less_imp_le le_less_trans mono)
  1859     then show "eventually (\<lambda>x. f x < a) (at x within ({x<..} \<inter> I))"
  1860       unfolding eventually_at_filter by eventually_elim simp
  1861   qed
  1862 qed
  1863 
  1864 text{* Another limit point characterization. *}
  1865 
  1866 lemma islimpt_sequential:
  1867   fixes x :: "'a::first_countable_topology"
  1868   shows "x islimpt S \<longleftrightarrow> (\<exists>f. (\<forall>n::nat. f n \<in> S - {x}) \<and> (f ---> x) sequentially)"
  1869     (is "?lhs = ?rhs")
  1870 proof
  1871   assume ?lhs
  1872   from countable_basis_at_decseq[of x] obtain A where A:
  1873       "\<And>i. open (A i)"
  1874       "\<And>i. x \<in> A i"
  1875       "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1876     by blast
  1877   def f \<equiv> "\<lambda>n. SOME y. y \<in> S \<and> y \<in> A n \<and> x \<noteq> y"
  1878   {
  1879     fix n
  1880     from `?lhs` have "\<exists>y. y \<in> S \<and> y \<in> A n \<and> x \<noteq> y"
  1881       unfolding islimpt_def using A(1,2)[of n] by auto
  1882     then have "f n \<in> S \<and> f n \<in> A n \<and> x \<noteq> f n"
  1883       unfolding f_def by (rule someI_ex)
  1884     then have "f n \<in> S" "f n \<in> A n" "x \<noteq> f n" by auto
  1885   }
  1886   then have "\<forall>n. f n \<in> S - {x}" by auto
  1887   moreover have "(\<lambda>n. f n) ----> x"
  1888   proof (rule topological_tendstoI)
  1889     fix S
  1890     assume "open S" "x \<in> S"
  1891     from A(3)[OF this] `\<And>n. f n \<in> A n`
  1892     show "eventually (\<lambda>x. f x \<in> S) sequentially"
  1893       by (auto elim!: eventually_elim1)
  1894   qed
  1895   ultimately show ?rhs by fast
  1896 next
  1897   assume ?rhs
  1898   then obtain f :: "nat \<Rightarrow> 'a" where f: "\<And>n. f n \<in> S - {x}" and lim: "f ----> x"
  1899     by auto
  1900   show ?lhs
  1901     unfolding islimpt_def
  1902   proof safe
  1903     fix T
  1904     assume "open T" "x \<in> T"
  1905     from lim[THEN topological_tendstoD, OF this] f
  1906     show "\<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
  1907       unfolding eventually_sequentially by auto
  1908   qed
  1909 qed
  1910 
  1911 lemma Lim_null:
  1912   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1913   shows "(f ---> l) net \<longleftrightarrow> ((\<lambda>x. f(x) - l) ---> 0) net"
  1914   by (simp add: Lim dist_norm)
  1915 
  1916 lemma Lim_null_comparison:
  1917   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1918   assumes "eventually (\<lambda>x. norm (f x) \<le> g x) net" "(g ---> 0) net"
  1919   shows "(f ---> 0) net"
  1920   using assms(2)
  1921 proof (rule metric_tendsto_imp_tendsto)
  1922   show "eventually (\<lambda>x. dist (f x) 0 \<le> dist (g x) 0) net"
  1923     using assms(1) by (rule eventually_elim1) (simp add: dist_norm)
  1924 qed
  1925 
  1926 lemma Lim_transform_bound:
  1927   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1928     and g :: "'a \<Rightarrow> 'c::real_normed_vector"
  1929   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) net"
  1930     and "(g ---> 0) net"
  1931   shows "(f ---> 0) net"
  1932   using assms(1) tendsto_norm_zero [OF assms(2)]
  1933   by (rule Lim_null_comparison)
  1934 
  1935 text{* Deducing things about the limit from the elements. *}
  1936 
  1937 lemma Lim_in_closed_set:
  1938   assumes "closed S"
  1939     and "eventually (\<lambda>x. f(x) \<in> S) net"
  1940     and "\<not> trivial_limit net" "(f ---> l) net"
  1941   shows "l \<in> S"
  1942 proof (rule ccontr)
  1943   assume "l \<notin> S"
  1944   with `closed S` have "open (- S)" "l \<in> - S"
  1945     by (simp_all add: open_Compl)
  1946   with assms(4) have "eventually (\<lambda>x. f x \<in> - S) net"
  1947     by (rule topological_tendstoD)
  1948   with assms(2) have "eventually (\<lambda>x. False) net"
  1949     by (rule eventually_elim2) simp
  1950   with assms(3) show "False"
  1951     by (simp add: eventually_False)
  1952 qed
  1953 
  1954 text{* Need to prove closed(cball(x,e)) before deducing this as a corollary. *}
  1955 
  1956 lemma Lim_dist_ubound:
  1957   assumes "\<not>(trivial_limit net)"
  1958     and "(f ---> l) net"
  1959     and "eventually (\<lambda>x. dist a (f x) \<le> e) net"
  1960   shows "dist a l \<le> e"
  1961   using assms by (fast intro: tendsto_le tendsto_intros)
  1962 
  1963 lemma Lim_norm_ubound:
  1964   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1965   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. norm(f x) \<le> e) net"
  1966   shows "norm(l) \<le> e"
  1967   using assms by (fast intro: tendsto_le tendsto_intros)
  1968 
  1969 lemma Lim_norm_lbound:
  1970   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1971   assumes "\<not> trivial_limit net"
  1972     and "(f ---> l) net"
  1973     and "eventually (\<lambda>x. e \<le> norm (f x)) net"
  1974   shows "e \<le> norm l"
  1975   using assms by (fast intro: tendsto_le tendsto_intros)
  1976 
  1977 text{* Limit under bilinear function *}
  1978 
  1979 lemma Lim_bilinear:
  1980   assumes "(f ---> l) net"
  1981     and "(g ---> m) net"
  1982     and "bounded_bilinear h"
  1983   shows "((\<lambda>x. h (f x) (g x)) ---> (h l m)) net"
  1984   using `bounded_bilinear h` `(f ---> l) net` `(g ---> m) net`
  1985   by (rule bounded_bilinear.tendsto)
  1986 
  1987 text{* These are special for limits out of the same vector space. *}
  1988 
  1989 lemma Lim_within_id: "(id ---> a) (at a within s)"
  1990   unfolding id_def by (rule tendsto_ident_at)
  1991 
  1992 lemma Lim_at_id: "(id ---> a) (at a)"
  1993   unfolding id_def by (rule tendsto_ident_at)
  1994 
  1995 lemma Lim_at_zero:
  1996   fixes a :: "'a::real_normed_vector"
  1997     and l :: "'b::topological_space"
  1998   shows "(f ---> l) (at a) \<longleftrightarrow> ((\<lambda>x. f(a + x)) ---> l) (at 0)"
  1999   using LIM_offset_zero LIM_offset_zero_cancel ..
  2000 
  2001 text{* It's also sometimes useful to extract the limit point from the filter. *}
  2002 
  2003 abbreviation netlimit :: "'a::t2_space filter \<Rightarrow> 'a"
  2004   where "netlimit F \<equiv> Lim F (\<lambda>x. x)"
  2005 
  2006 lemma netlimit_within: "\<not> trivial_limit (at a within S) \<Longrightarrow> netlimit (at a within S) = a"
  2007   by (rule tendsto_Lim) (auto intro: tendsto_intros)
  2008 
  2009 lemma netlimit_at:
  2010   fixes a :: "'a::{perfect_space,t2_space}"
  2011   shows "netlimit (at a) = a"
  2012   using netlimit_within [of a UNIV] by simp
  2013 
  2014 lemma lim_within_interior:
  2015   "x \<in> interior S \<Longrightarrow> (f ---> l) (at x within S) \<longleftrightarrow> (f ---> l) (at x)"
  2016   by (metis at_within_interior)
  2017 
  2018 lemma netlimit_within_interior:
  2019   fixes x :: "'a::{t2_space,perfect_space}"
  2020   assumes "x \<in> interior S"
  2021   shows "netlimit (at x within S) = x"
  2022   using assms by (metis at_within_interior netlimit_at)
  2023 
  2024 text{* Transformation of limit. *}
  2025 
  2026 lemma Lim_transform:
  2027   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
  2028   assumes "((\<lambda>x. f x - g x) ---> 0) net" "(f ---> l) net"
  2029   shows "(g ---> l) net"
  2030   using tendsto_diff [OF assms(2) assms(1)] by simp
  2031 
  2032 lemma Lim_transform_eventually:
  2033   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  2034   apply (rule topological_tendstoI)
  2035   apply (drule (2) topological_tendstoD)
  2036   apply (erule (1) eventually_elim2, simp)
  2037   done
  2038 
  2039 lemma Lim_transform_within:
  2040   assumes "0 < d"
  2041     and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  2042     and "(f ---> l) (at x within S)"
  2043   shows "(g ---> l) (at x within S)"
  2044 proof (rule Lim_transform_eventually)
  2045   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  2046     using assms(1,2) by (auto simp: dist_nz eventually_at)
  2047   show "(f ---> l) (at x within S)" by fact
  2048 qed
  2049 
  2050 lemma Lim_transform_at:
  2051   assumes "0 < d"
  2052     and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  2053     and "(f ---> l) (at x)"
  2054   shows "(g ---> l) (at x)"
  2055   using _ assms(3)
  2056 proof (rule Lim_transform_eventually)
  2057   show "eventually (\<lambda>x. f x = g x) (at x)"
  2058     unfolding eventually_at2
  2059     using assms(1,2) by auto
  2060 qed
  2061 
  2062 text{* Common case assuming being away from some crucial point like 0. *}
  2063 
  2064 lemma Lim_transform_away_within:
  2065   fixes a b :: "'a::t1_space"
  2066   assumes "a \<noteq> b"
  2067     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  2068     and "(f ---> l) (at a within S)"
  2069   shows "(g ---> l) (at a within S)"
  2070 proof (rule Lim_transform_eventually)
  2071   show "(f ---> l) (at a within S)" by fact
  2072   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  2073     unfolding eventually_at_topological
  2074     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  2075 qed
  2076 
  2077 lemma Lim_transform_away_at:
  2078   fixes a b :: "'a::t1_space"
  2079   assumes ab: "a\<noteq>b"
  2080     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  2081     and fl: "(f ---> l) (at a)"
  2082   shows "(g ---> l) (at a)"
  2083   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  2084 
  2085 text{* Alternatively, within an open set. *}
  2086 
  2087 lemma Lim_transform_within_open:
  2088   assumes "open S" and "a \<in> S"
  2089     and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  2090     and "(f ---> l) (at a)"
  2091   shows "(g ---> l) (at a)"
  2092 proof (rule Lim_transform_eventually)
  2093   show "eventually (\<lambda>x. f x = g x) (at a)"
  2094     unfolding eventually_at_topological
  2095     using assms(1,2,3) by auto
  2096   show "(f ---> l) (at a)" by fact
  2097 qed
  2098 
  2099 text{* A congruence rule allowing us to transform limits assuming not at point. *}
  2100 
  2101 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  2102 
  2103 lemma Lim_cong_within(*[cong add]*):
  2104   assumes "a = b"
  2105     and "x = y"
  2106     and "S = T"
  2107     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  2108   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  2109   unfolding tendsto_def eventually_at_topological
  2110   using assms by simp
  2111 
  2112 lemma Lim_cong_at(*[cong add]*):
  2113   assumes "a = b" "x = y"
  2114     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  2115   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  2116   unfolding tendsto_def eventually_at_topological
  2117   using assms by simp
  2118 
  2119 text{* Useful lemmas on closure and set of possible sequential limits.*}
  2120 
  2121 lemma closure_sequential:
  2122   fixes l :: "'a::first_countable_topology"
  2123   shows "l \<in> closure S \<longleftrightarrow> (\<exists>x. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially)"
  2124   (is "?lhs = ?rhs")
  2125 proof
  2126   assume "?lhs"
  2127   moreover
  2128   {
  2129     assume "l \<in> S"
  2130     then have "?rhs" using tendsto_const[of l sequentially] by auto
  2131   }
  2132   moreover
  2133   {
  2134     assume "l islimpt S"
  2135     then have "?rhs" unfolding islimpt_sequential by auto
  2136   }
  2137   ultimately show "?rhs"
  2138     unfolding closure_def by auto
  2139 next
  2140   assume "?rhs"
  2141   then show "?lhs" unfolding closure_def islimpt_sequential by auto
  2142 qed
  2143 
  2144 lemma closed_sequential_limits:
  2145   fixes S :: "'a::first_countable_topology set"
  2146   shows "closed S \<longleftrightarrow> (\<forall>x l. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially \<longrightarrow> l \<in> S)"
  2147 by (metis closure_sequential closure_subset_eq subset_iff)
  2148 
  2149 lemma closure_approachable:
  2150   fixes S :: "'a::metric_space set"
  2151   shows "x \<in> closure S \<longleftrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e)"
  2152   apply (auto simp add: closure_def islimpt_approachable)
  2153   apply (metis dist_self)
  2154   done
  2155 
  2156 lemma closed_approachable:
  2157   fixes S :: "'a::metric_space set"
  2158   shows "closed S \<Longrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e) \<longleftrightarrow> x \<in> S"
  2159   by (metis closure_closed closure_approachable)
  2160 
  2161 lemma closure_contains_Inf:
  2162   fixes S :: "real set"
  2163   assumes "S \<noteq> {}" "bdd_below S"
  2164   shows "Inf S \<in> closure S"
  2165 proof -
  2166   have *: "\<forall>x\<in>S. Inf S \<le> x"
  2167     using cInf_lower[of _ S] assms by metis
  2168   {
  2169     fix e :: real
  2170     assume "e > 0"
  2171     then have "Inf S < Inf S + e" by simp
  2172     with assms obtain x where "x \<in> S" "x < Inf S + e"
  2173       by (subst (asm) cInf_less_iff) auto
  2174     with * have "\<exists>x\<in>S. dist x (Inf S) < e"
  2175       by (intro bexI[of _ x]) (auto simp add: dist_real_def)
  2176   }
  2177   then show ?thesis unfolding closure_approachable by auto
  2178 qed
  2179 
  2180 lemma closed_contains_Inf:
  2181   fixes S :: "real set"
  2182   shows "S \<noteq> {} \<Longrightarrow> bdd_below S \<Longrightarrow> closed S \<Longrightarrow> Inf S \<in> S"
  2183   by (metis closure_contains_Inf closure_closed assms)
  2184 
  2185 lemma not_trivial_limit_within_ball:
  2186   "\<not> trivial_limit (at x within S) \<longleftrightarrow> (\<forall>e>0. S \<inter> ball x e - {x} \<noteq> {})"
  2187   (is "?lhs = ?rhs")
  2188 proof -
  2189   {
  2190     assume "?lhs"
  2191     {
  2192       fix e :: real
  2193       assume "e > 0"
  2194       then obtain y where "y \<in> S - {x}" and "dist y x < e"
  2195         using `?lhs` not_trivial_limit_within[of x S] closure_approachable[of x "S - {x}"]
  2196         by auto
  2197       then have "y \<in> S \<inter> ball x e - {x}"
  2198         unfolding ball_def by (simp add: dist_commute)
  2199       then have "S \<inter> ball x e - {x} \<noteq> {}" by blast
  2200     }
  2201     then have "?rhs" by auto
  2202   }
  2203   moreover
  2204   {
  2205     assume "?rhs"
  2206     {
  2207       fix e :: real
  2208       assume "e > 0"
  2209       then obtain y where "y \<in> S \<inter> ball x e - {x}"
  2210         using `?rhs` by blast
  2211       then have "y \<in> S - {x}" and "dist y x < e"
  2212         unfolding ball_def by (simp_all add: dist_commute)
  2213       then have "\<exists>y \<in> S - {x}. dist y x < e"
  2214         by auto
  2215     }
  2216     then have "?lhs"
  2217       using not_trivial_limit_within[of x S] closure_approachable[of x "S - {x}"]
  2218       by auto
  2219   }
  2220   ultimately show ?thesis by auto
  2221 qed
  2222 
  2223 
  2224 subsection {* Infimum Distance *}
  2225 
  2226 definition "infdist x A = (if A = {} then 0 else INF a:A. dist x a)"
  2227 
  2228 lemma bdd_below_infdist[intro, simp]: "bdd_below (dist x`A)"
  2229   by (auto intro!: zero_le_dist)
  2230 
  2231 lemma infdist_notempty: "A \<noteq> {} \<Longrightarrow> infdist x A = (INF a:A. dist x a)"
  2232   by (simp add: infdist_def)
  2233 
  2234 lemma infdist_nonneg: "0 \<le> infdist x A"
  2235   by (auto simp add: infdist_def intro: cINF_greatest)
  2236 
  2237 lemma infdist_le: "a \<in> A \<Longrightarrow> infdist x A \<le> dist x a"
  2238   by (auto intro: cINF_lower simp add: infdist_def)
  2239 
  2240 lemma infdist_le2: "a \<in> A \<Longrightarrow> dist x a \<le> d \<Longrightarrow> infdist x A \<le> d"
  2241   by (auto intro!: cINF_lower2 simp add: infdist_def)
  2242 
  2243 lemma infdist_zero[simp]: "a \<in> A \<Longrightarrow> infdist a A = 0"
  2244   by (auto intro!: antisym infdist_nonneg infdist_le2)
  2245 
  2246 lemma infdist_triangle: "infdist x A \<le> infdist y A + dist x y"
  2247 proof (cases "A = {}")
  2248   case True
  2249   then show ?thesis by (simp add: infdist_def)
  2250 next
  2251   case False
  2252   then obtain a where "a \<in> A" by auto
  2253   have "infdist x A \<le> Inf {dist x y + dist y a |a. a \<in> A}"
  2254   proof (rule cInf_greatest)
  2255     from `A \<noteq> {}` show "{dist x y + dist y a |a. a \<in> A} \<noteq> {}"
  2256       by simp
  2257     fix d
  2258     assume "d \<in> {dist x y + dist y a |a. a \<in> A}"
  2259     then obtain a where d: "d = dist x y + dist y a" "a \<in> A"
  2260       by auto
  2261     show "infdist x A \<le> d"
  2262       unfolding infdist_notempty[OF `A \<noteq> {}`]
  2263     proof (rule cINF_lower2)
  2264       show "a \<in> A" by fact
  2265       show "dist x a \<le> d"
  2266         unfolding d by (rule dist_triangle)
  2267     qed simp
  2268   qed
  2269   also have "\<dots> = dist x y + infdist y A"
  2270   proof (rule cInf_eq, safe)
  2271     fix a
  2272     assume "a \<in> A"
  2273     then show "dist x y + infdist y A \<le> dist x y + dist y a"
  2274       by (auto intro: infdist_le)
  2275   next
  2276     fix i
  2277     assume inf: "\<And>d. d \<in> {dist x y + dist y a |a. a \<in> A} \<Longrightarrow> i \<le> d"
  2278     then have "i - dist x y \<le> infdist y A"
  2279       unfolding infdist_notempty[OF `A \<noteq> {}`] using `a \<in> A`
  2280       by (intro cINF_greatest) (auto simp: field_simps)
  2281     then show "i \<le> dist x y + infdist y A"
  2282       by simp
  2283   qed
  2284   finally show ?thesis by simp
  2285 qed
  2286 
  2287 lemma in_closure_iff_infdist_zero:
  2288   assumes "A \<noteq> {}"
  2289   shows "x \<in> closure A \<longleftrightarrow> infdist x A = 0"
  2290 proof
  2291   assume "x \<in> closure A"
  2292   show "infdist x A = 0"
  2293   proof (rule ccontr)
  2294     assume "infdist x A \<noteq> 0"
  2295     with infdist_nonneg[of x A] have "infdist x A > 0"
  2296       by auto
  2297     then have "ball x (infdist x A) \<inter> closure A = {}"
  2298       apply auto
  2299       apply (metis `x \<in> closure A` closure_approachable dist_commute infdist_le not_less)
  2300       done
  2301     then have "x \<notin> closure A"
  2302       by (metis `0 < infdist x A` centre_in_ball disjoint_iff_not_equal)
  2303     then show False using `x \<in> closure A` by simp
  2304   qed
  2305 next
  2306   assume x: "infdist x A = 0"
  2307   then obtain a where "a \<in> A"
  2308     by atomize_elim (metis all_not_in_conv assms)
  2309   show "x \<in> closure A"
  2310     unfolding closure_approachable
  2311     apply safe
  2312   proof (rule ccontr)
  2313     fix e :: real
  2314     assume "e > 0"
  2315     assume "\<not> (\<exists>y\<in>A. dist y x < e)"
  2316     then have "infdist x A \<ge> e" using `a \<in> A`
  2317       unfolding infdist_def
  2318       by (force simp: dist_commute intro: cINF_greatest)
  2319     with x `e > 0` show False by auto
  2320   qed
  2321 qed
  2322 
  2323 lemma in_closed_iff_infdist_zero:
  2324   assumes "closed A" "A \<noteq> {}"
  2325   shows "x \<in> A \<longleftrightarrow> infdist x A = 0"
  2326 proof -
  2327   have "x \<in> closure A \<longleftrightarrow> infdist x A = 0"
  2328     by (rule in_closure_iff_infdist_zero) fact
  2329   with assms show ?thesis by simp
  2330 qed
  2331 
  2332 lemma tendsto_infdist [tendsto_intros]:
  2333   assumes f: "(f ---> l) F"
  2334   shows "((\<lambda>x. infdist (f x) A) ---> infdist l A) F"
  2335 proof (rule tendstoI)
  2336   fix e ::real
  2337   assume "e > 0"
  2338   from tendstoD[OF f this]
  2339   show "eventually (\<lambda>x. dist (infdist (f x) A) (infdist l A) < e) F"
  2340   proof (eventually_elim)
  2341     fix x
  2342     from infdist_triangle[of l A "f x"] infdist_triangle[of "f x" A l]
  2343     have "dist (infdist (f x) A) (infdist l A) \<le> dist (f x) l"
  2344       by (simp add: dist_commute dist_real_def)
  2345     also assume "dist (f x) l < e"
  2346     finally show "dist (infdist (f x) A) (infdist l A) < e" .
  2347   qed
  2348 qed
  2349 
  2350 text{* Some other lemmas about sequences. *}
  2351 
  2352 lemma sequentially_offset: (* TODO: move to Topological_Spaces.thy *)
  2353   assumes "eventually (\<lambda>i. P i) sequentially"
  2354   shows "eventually (\<lambda>i. P (i + k)) sequentially"
  2355   using assms by (rule eventually_sequentially_seg [THEN iffD2])
  2356 
  2357 lemma seq_offset_neg: (* TODO: move to Topological_Spaces.thy *)
  2358   "(f ---> l) sequentially \<Longrightarrow> ((\<lambda>i. f(i - k)) ---> l) sequentially"
  2359   apply (erule filterlim_compose)
  2360   apply (simp add: filterlim_def le_sequentially eventually_filtermap eventually_sequentially)
  2361   apply arith
  2362   done
  2363 
  2364 lemma seq_harmonic: "((\<lambda>n. inverse (real n)) ---> 0) sequentially"
  2365   using LIMSEQ_inverse_real_of_nat by (rule LIMSEQ_imp_Suc) (* TODO: move to Limits.thy *)
  2366 
  2367 subsection {* More properties of closed balls *}
  2368 
  2369 lemma closed_vimage: (* TODO: move to Topological_Spaces.thy *)
  2370   assumes "closed s" and "continuous_on UNIV f"
  2371   shows "closed (vimage f s)"
  2372   using assms unfolding continuous_on_closed_vimage [OF closed_UNIV]
  2373   by simp
  2374 
  2375 lemma closed_cball: "closed (cball x e)"
  2376 proof -
  2377   have "closed (dist x -` {..e})"
  2378     by (intro closed_vimage closed_atMost continuous_on_intros)
  2379   also have "dist x -` {..e} = cball x e"
  2380     by auto
  2381   finally show ?thesis .
  2382 qed
  2383 
  2384 lemma open_contains_cball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0.  cball x e \<subseteq> S)"
  2385 proof -
  2386   {
  2387     fix x and e::real
  2388     assume "x\<in>S" "e>0" "ball x e \<subseteq> S"
  2389     then have "\<exists>d>0. cball x d \<subseteq> S" unfolding subset_eq by (rule_tac x="e/2" in exI, auto)
  2390   }
  2391   moreover
  2392   {
  2393     fix x and e::real
  2394     assume "x\<in>S" "e>0" "cball x e \<subseteq> S"
  2395     then have "\<exists>d>0. ball x d \<subseteq> S"
  2396       unfolding subset_eq
  2397       apply(rule_tac x="e/2" in exI)
  2398       apply auto
  2399       done
  2400   }
  2401   ultimately show ?thesis
  2402     unfolding open_contains_ball by auto
  2403 qed
  2404 
  2405 lemma open_contains_cball_eq: "open S \<Longrightarrow> (\<forall>x. x \<in> S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S))"
  2406   by (metis open_contains_cball subset_eq order_less_imp_le centre_in_cball)
  2407 
  2408 lemma mem_interior_cball: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S)"
  2409   apply (simp add: interior_def, safe)
  2410   apply (force simp add: open_contains_cball)
  2411   apply (rule_tac x="ball x e" in exI)
  2412   apply (simp add: subset_trans [OF ball_subset_cball])
  2413   done
  2414 
  2415 lemma islimpt_ball:
  2416   fixes x y :: "'a::{real_normed_vector,perfect_space}"
  2417   shows "y islimpt ball x e \<longleftrightarrow> 0 < e \<and> y \<in> cball x e"
  2418   (is "?lhs = ?rhs")
  2419 proof
  2420   assume "?lhs"
  2421   {
  2422     assume "e \<le> 0"
  2423     then have *:"ball x e = {}"
  2424       using ball_eq_empty[of x e] by auto
  2425     have False using `?lhs`
  2426       unfolding * using islimpt_EMPTY[of y] by auto
  2427   }
  2428   then have "e > 0" by (metis not_less)
  2429   moreover
  2430   have "y \<in> cball x e"
  2431     using closed_cball[of x e] islimpt_subset[of y "ball x e" "cball x e"]
  2432       ball_subset_cball[of x e] `?lhs`
  2433     unfolding closed_limpt by auto
  2434   ultimately show "?rhs" by auto
  2435 next
  2436   assume "?rhs"
  2437   then have "e > 0" by auto
  2438   {
  2439     fix d :: real
  2440     assume "d > 0"
  2441     have "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2442     proof (cases "d \<le> dist x y")
  2443       case True
  2444       then show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2445       proof (cases "x = y")
  2446         case True
  2447         then have False
  2448           using `d \<le> dist x y` `d>0` by auto
  2449         then show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2450           by auto
  2451       next
  2452         case False
  2453         have "dist x (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) =
  2454           norm (x - y + (d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  2455           unfolding mem_cball mem_ball dist_norm diff_diff_eq2 diff_add_eq[symmetric]
  2456           by auto
  2457         also have "\<dots> = \<bar>- 1 + d / (2 * norm (x - y))\<bar> * norm (x - y)"
  2458           using scaleR_left_distrib[of "- 1" "d / (2 * norm (y - x))", symmetric, of "y - x"]
  2459           unfolding scaleR_minus_left scaleR_one
  2460           by (auto simp add: norm_minus_commute)
  2461         also have "\<dots> = \<bar>- norm (x - y) + d / 2\<bar>"
  2462           unfolding abs_mult_pos[of "norm (x - y)", OF norm_ge_zero[of "x - y"]]
  2463           unfolding distrib_right using `x\<noteq>y`[unfolded dist_nz, unfolded dist_norm]
  2464           by auto
  2465         also have "\<dots> \<le> e - d/2" using `d \<le> dist x y` and `d>0` and `?rhs`
  2466           by (auto simp add: dist_norm)
  2467         finally have "y - (d / (2 * dist y x)) *\<^sub>R (y - x) \<in> ball x e" using `d>0`
  2468           by auto
  2469         moreover
  2470         have "(d / (2*dist y x)) *\<^sub>R (y - x) \<noteq> 0"
  2471           using `x\<noteq>y`[unfolded dist_nz] `d>0` unfolding scaleR_eq_0_iff
  2472           by (auto simp add: dist_commute)
  2473         moreover
  2474         have "dist (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) y < d"
  2475           unfolding dist_norm
  2476           apply simp
  2477           unfolding norm_minus_cancel
  2478           using `d > 0` `x\<noteq>y`[unfolded dist_nz] dist_commute[of x y]
  2479           unfolding dist_norm
  2480           apply auto
  2481           done
  2482         ultimately show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2483           apply (rule_tac x = "y - (d / (2*dist y x)) *\<^sub>R (y - x)" in bexI)
  2484           apply auto
  2485           done
  2486       qed
  2487     next
  2488       case False
  2489       then have "d > dist x y" by auto
  2490       show "\<exists>x' \<in> ball x e. x' \<noteq> y \<and> dist x' y < d"
  2491       proof (cases "x = y")
  2492         case True
  2493         obtain z where **: "z \<noteq> y" "dist z y < min e d"
  2494           using perfect_choose_dist[of "min e d" y]
  2495           using `d > 0` `e>0` by auto
  2496         show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2497           unfolding `x = y`
  2498           using `z \<noteq> y` **
  2499           apply (rule_tac x=z in bexI)
  2500           apply (auto simp add: dist_commute)
  2501           done
  2502       next
  2503         case False
  2504         then show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  2505           using `d>0` `d > dist x y` `?rhs`
  2506           apply (rule_tac x=x in bexI)
  2507           apply auto
  2508           done
  2509       qed
  2510     qed
  2511   }
  2512   then show "?lhs"
  2513     unfolding mem_cball islimpt_approachable mem_ball by auto
  2514 qed
  2515 
  2516 lemma closure_ball_lemma:
  2517   fixes x y :: "'a::real_normed_vector"
  2518   assumes "x \<noteq> y"
  2519   shows "y islimpt ball x (dist x y)"
  2520 proof (rule islimptI)
  2521   fix T
  2522   assume "y \<in> T" "open T"
  2523   then obtain r where "0 < r" "\<forall>z. dist z y < r \<longrightarrow> z \<in> T"
  2524     unfolding open_dist by fast
  2525   (* choose point between x and y, within distance r of y. *)
  2526   def k \<equiv> "min 1 (r / (2 * dist x y))"
  2527   def z \<equiv> "y + scaleR k (x - y)"
  2528   have z_def2: "z = x + scaleR (1 - k) (y - x)"
  2529     unfolding z_def by (simp add: algebra_simps)
  2530   have "dist z y < r"
  2531     unfolding z_def k_def using `0 < r`
  2532     by (simp add: dist_norm min_def)
  2533   then have "z \<in> T"
  2534     using `\<forall>z. dist z y < r \<longrightarrow> z \<in> T` by simp
  2535   have "dist x z < dist x y"
  2536     unfolding z_def2 dist_norm
  2537     apply (simp add: norm_minus_commute)
  2538     apply (simp only: dist_norm [symmetric])
  2539     apply (subgoal_tac "\<bar>1 - k\<bar> * dist x y < 1 * dist x y", simp)
  2540     apply (rule mult_strict_right_mono)
  2541     apply (simp add: k_def divide_pos_pos zero_less_dist_iff `0 < r` `x \<noteq> y`)
  2542     apply (simp add: zero_less_dist_iff `x \<noteq> y`)
  2543     done
  2544   then have "z \<in> ball x (dist x y)"
  2545     by simp
  2546   have "z \<noteq> y"
  2547     unfolding z_def k_def using `x \<noteq> y` `0 < r`
  2548     by (simp add: min_def)
  2549   show "\<exists>z\<in>ball x (dist x y). z \<in> T \<and> z \<noteq> y"
  2550     using `z \<in> ball x (dist x y)` `z \<in> T` `z \<noteq> y`
  2551     by fast
  2552 qed
  2553 
  2554 lemma closure_ball:
  2555   fixes x :: "'a::real_normed_vector"
  2556   shows "0 < e \<Longrightarrow> closure (ball x e) = cball x e"
  2557   apply (rule equalityI)
  2558   apply (rule closure_minimal)
  2559   apply (rule ball_subset_cball)
  2560   apply (rule closed_cball)
  2561   apply (rule subsetI, rename_tac y)
  2562   apply (simp add: le_less [where 'a=real])
  2563   apply (erule disjE)
  2564   apply (rule subsetD [OF closure_subset], simp)
  2565   apply (simp add: closure_def)
  2566   apply clarify
  2567   apply (rule closure_ball_lemma)
  2568   apply (simp add: zero_less_dist_iff)
  2569   done
  2570 
  2571 (* In a trivial vector space, this fails for e = 0. *)
  2572 lemma interior_cball:
  2573   fixes x :: "'a::{real_normed_vector, perfect_space}"
  2574   shows "interior (cball x e) = ball x e"
  2575 proof (cases "e \<ge> 0")
  2576   case False note cs = this
  2577   from cs have "ball x e = {}"
  2578     using ball_empty[of e x] by auto
  2579   moreover
  2580   {
  2581     fix y
  2582     assume "y \<in> cball x e"
  2583     then have False
  2584       unfolding mem_cball using dist_nz[of x y] cs by auto
  2585   }
  2586   then have "cball x e = {}" by auto
  2587   then have "interior (cball x e) = {}"
  2588     using interior_empty by auto
  2589   ultimately show ?thesis by blast
  2590 next
  2591   case True note cs = this
  2592   have "ball x e \<subseteq> cball x e"
  2593     using ball_subset_cball by auto
  2594   moreover
  2595   {
  2596     fix S y
  2597     assume as: "S \<subseteq> cball x e" "open S" "y\<in>S"
  2598     then obtain d where "d>0" and d: "\<forall>x'. dist x' y < d \<longrightarrow> x' \<in> S"
  2599       unfolding open_dist by blast
  2600     then obtain xa where xa_y: "xa \<noteq> y" and xa: "dist xa y < d"
  2601       using perfect_choose_dist [of d] by auto
  2602     have "xa \<in> S"
  2603       using d[THEN spec[where x = xa]]
  2604       using xa by (auto simp add: dist_commute)
  2605     then have xa_cball: "xa \<in> cball x e"
  2606       using as(1) by auto
  2607     then have "y \<in> ball x e"
  2608     proof (cases "x = y")
  2609       case True
  2610       then have "e > 0"
  2611         using xa_y[unfolded dist_nz] xa_cball[unfolded mem_cball]
  2612         by (auto simp add: dist_commute)
  2613       then show "y \<in> ball x e"
  2614         using `x = y ` by simp
  2615     next
  2616       case False
  2617       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) y < d"
  2618         unfolding dist_norm
  2619         using `d>0` norm_ge_zero[of "y - x"] `x \<noteq> y` by auto
  2620       then have *: "y + (d / 2 / dist y x) *\<^sub>R (y - x) \<in> cball x e"
  2621         using d as(1)[unfolded subset_eq] by blast
  2622       have "y - x \<noteq> 0" using `x \<noteq> y` by auto
  2623       then have **:"d / (2 * norm (y - x)) > 0"
  2624         unfolding zero_less_norm_iff[symmetric]
  2625         using `d>0` divide_pos_pos[of d "2*norm (y - x)"] by auto
  2626       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) x =
  2627         norm (y + (d / (2 * norm (y - x))) *\<^sub>R y - (d / (2 * norm (y - x))) *\<^sub>R x - x)"
  2628         by (auto simp add: dist_norm algebra_simps)
  2629       also have "\<dots> = norm ((1 + d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  2630         by (auto simp add: algebra_simps)
  2631       also have "\<dots> = \<bar>1 + d / (2 * norm (y - x))\<bar> * norm (y - x)"
  2632         using ** by auto
  2633       also have "\<dots> = (dist y x) + d/2"
  2634         using ** by (auto simp add: distrib_right dist_norm)
  2635       finally have "e \<ge> dist x y +d/2"
  2636         using *[unfolded mem_cball] by (auto simp add: dist_commute)
  2637       then show "y \<in> ball x e"
  2638         unfolding mem_ball using `d>0` by auto
  2639     qed
  2640   }
  2641   then have "\<forall>S \<subseteq> cball x e. open S \<longrightarrow> S \<subseteq> ball x e"
  2642     by auto
  2643   ultimately show ?thesis
  2644     using interior_unique[of "ball x e" "cball x e"]
  2645     using open_ball[of x e]
  2646     by auto
  2647 qed
  2648 
  2649 lemma frontier_ball:
  2650   fixes a :: "'a::real_normed_vector"
  2651   shows "0 < e \<Longrightarrow> frontier(ball a e) = {x. dist a x = e}"
  2652   apply (simp add: frontier_def closure_ball interior_open order_less_imp_le)
  2653   apply (simp add: set_eq_iff)
  2654   apply arith
  2655   done
  2656 
  2657 lemma frontier_cball:
  2658   fixes a :: "'a::{real_normed_vector, perfect_space}"
  2659   shows "frontier (cball a e) = {x. dist a x = e}"
  2660   apply (simp add: frontier_def interior_cball closed_cball order_less_imp_le)
  2661   apply (simp add: set_eq_iff)
  2662   apply arith
  2663   done
  2664 
  2665 lemma cball_eq_empty: "cball x e = {} \<longleftrightarrow> e < 0"
  2666   apply (simp add: set_eq_iff not_le)
  2667   apply (metis zero_le_dist dist_self order_less_le_trans)
  2668   done
  2669 
  2670 lemma cball_empty: "e < 0 \<Longrightarrow> cball x e = {}"
  2671   by (simp add: cball_eq_empty)
  2672 
  2673 lemma cball_eq_sing:
  2674   fixes x :: "'a::{metric_space,perfect_space}"
  2675   shows "cball x e = {x} \<longleftrightarrow> e = 0"
  2676 proof (rule linorder_cases)
  2677   assume e: "0 < e"
  2678   obtain a where "a \<noteq> x" "dist a x < e"
  2679     using perfect_choose_dist [OF e] by auto
  2680   then have "a \<noteq> x" "dist x a \<le> e"
  2681     by (auto simp add: dist_commute)
  2682   with e show ?thesis by (auto simp add: set_eq_iff)
  2683 qed auto
  2684 
  2685 lemma cball_sing:
  2686   fixes x :: "'a::metric_space"
  2687   shows "e = 0 \<Longrightarrow> cball x e = {x}"
  2688   by (auto simp add: set_eq_iff)
  2689 
  2690 
  2691 subsection {* Boundedness *}
  2692 
  2693   (* FIXME: This has to be unified with BSEQ!! *)
  2694 definition (in metric_space) bounded :: "'a set \<Rightarrow> bool"
  2695   where "bounded S \<longleftrightarrow> (\<exists>x e. \<forall>y\<in>S. dist x y \<le> e)"
  2696 
  2697 lemma bounded_subset_cball: "bounded S \<longleftrightarrow> (\<exists>e x. S \<subseteq> cball x e)"
  2698   unfolding bounded_def subset_eq by auto
  2699 
  2700 lemma bounded_any_center: "bounded S \<longleftrightarrow> (\<exists>e. \<forall>y\<in>S. dist a y \<le> e)"
  2701   unfolding bounded_def
  2702   by auto (metis add_commute add_le_cancel_right dist_commute dist_triangle_le)
  2703 
  2704 lemma bounded_iff: "bounded S \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. norm x \<le> a)"
  2705   unfolding bounded_any_center [where a=0]
  2706   by (simp add: dist_norm)
  2707 
  2708 lemma bounded_realI:
  2709   assumes "\<forall>x\<in>s. abs (x::real) \<le> B"
  2710   shows "bounded s"
  2711   unfolding bounded_def dist_real_def
  2712   by (metis abs_minus_commute assms diff_0_right)
  2713 
  2714 lemma bounded_empty [simp]: "bounded {}"
  2715   by (simp add: bounded_def)
  2716 
  2717 lemma bounded_subset: "bounded T \<Longrightarrow> S \<subseteq> T \<Longrightarrow> bounded S"
  2718   by (metis bounded_def subset_eq)
  2719 
  2720 lemma bounded_interior[intro]: "bounded S \<Longrightarrow> bounded(interior S)"
  2721   by (metis bounded_subset interior_subset)
  2722 
  2723 lemma bounded_closure[intro]:
  2724   assumes "bounded S"
  2725   shows "bounded (closure S)"
  2726 proof -
  2727   from assms obtain x and a where a: "\<forall>y\<in>S. dist x y \<le> a"
  2728     unfolding bounded_def by auto
  2729   {
  2730     fix y
  2731     assume "y \<in> closure S"
  2732     then obtain f where f: "\<forall>n. f n \<in> S"  "(f ---> y) sequentially"
  2733       unfolding closure_sequential by auto
  2734     have "\<forall>n. f n \<in> S \<longrightarrow> dist x (f n) \<le> a" using a by simp
  2735     then have "eventually (\<lambda>n. dist x (f n) \<le> a) sequentially"
  2736       by (rule eventually_mono, simp add: f(1))
  2737     have "dist x y \<le> a"
  2738       apply (rule Lim_dist_ubound [of sequentially f])
  2739       apply (rule trivial_limit_sequentially)
  2740       apply (rule f(2))
  2741       apply fact
  2742       done
  2743   }
  2744   then show ?thesis
  2745     unfolding bounded_def by auto
  2746 qed
  2747 
  2748 lemma bounded_cball[simp,intro]: "bounded (cball x e)"
  2749   apply (simp add: bounded_def)
  2750   apply (rule_tac x=x in exI)
  2751   apply (rule_tac x=e in exI)
  2752   apply auto
  2753   done
  2754 
  2755 lemma bounded_ball[simp,intro]: "bounded (ball x e)"
  2756   by (metis ball_subset_cball bounded_cball bounded_subset)
  2757 
  2758 lemma bounded_Un[simp]: "bounded (S \<union> T) \<longleftrightarrow> bounded S \<and> bounded T"
  2759   apply (auto simp add: bounded_def)
  2760   by (metis Un_iff add_le_cancel_left dist_triangle le_max_iff_disj max.order_iff)
  2761 
  2762 lemma bounded_Union[intro]: "finite F \<Longrightarrow> \<forall>S\<in>F. bounded S \<Longrightarrow> bounded (\<Union>F)"
  2763   by (induct rule: finite_induct[of F]) auto
  2764 
  2765 lemma bounded_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. bounded (B x) \<Longrightarrow> bounded (\<Union>x\<in>A. B x)"
  2766   by (induct set: finite) auto
  2767 
  2768 lemma bounded_insert [simp]: "bounded (insert x S) \<longleftrightarrow> bounded S"
  2769 proof -
  2770   have "\<forall>y\<in>{x}. dist x y \<le> 0"
  2771     by simp
  2772   then have "bounded {x}"
  2773     unfolding bounded_def by fast
  2774   then show ?thesis
  2775     by (metis insert_is_Un bounded_Un)
  2776 qed
  2777 
  2778 lemma finite_imp_bounded [intro]: "finite S \<Longrightarrow> bounded S"
  2779   by (induct set: finite) simp_all
  2780 
  2781 lemma bounded_pos: "bounded S \<longleftrightarrow> (\<exists>b>0. \<forall>x\<in> S. norm x \<le> b)"
  2782   apply (simp add: bounded_iff)
  2783   apply (subgoal_tac "\<And>x (y::real). 0 < 1 + abs y \<and> (x \<le> y \<longrightarrow> x \<le> 1 + abs y)")
  2784   apply metis
  2785   apply arith
  2786   done
  2787 
  2788 lemma Bseq_eq_bounded:
  2789   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
  2790   shows "Bseq f \<longleftrightarrow> bounded (range f)"
  2791   unfolding Bseq_def bounded_pos by auto
  2792 
  2793 lemma bounded_Int[intro]: "bounded S \<or> bounded T \<Longrightarrow> bounded (S \<inter> T)"
  2794   by (metis Int_lower1 Int_lower2 bounded_subset)
  2795 
  2796 lemma bounded_diff[intro]: "bounded S \<Longrightarrow> bounded (S - T)"
  2797   by (metis Diff_subset bounded_subset)
  2798 
  2799 lemma not_bounded_UNIV[simp, intro]:
  2800   "\<not> bounded (UNIV :: 'a::{real_normed_vector, perfect_space} set)"
  2801 proof (auto simp add: bounded_pos not_le)
  2802   obtain x :: 'a where "x \<noteq> 0"
  2803     using perfect_choose_dist [OF zero_less_one] by fast
  2804   fix b :: real
  2805   assume b: "b >0"
  2806   have b1: "b +1 \<ge> 0"
  2807     using b by simp
  2808   with `x \<noteq> 0` have "b < norm (scaleR (b + 1) (sgn x))"
  2809     by (simp add: norm_sgn)
  2810   then show "\<exists>x::'a. b < norm x" ..
  2811 qed
  2812 
  2813 lemma bounded_linear_image:
  2814   assumes "bounded S"
  2815     and "bounded_linear f"
  2816   shows "bounded (f ` S)"
  2817 proof -
  2818   from assms(1) obtain b where b: "b > 0" "\<forall>x\<in>S. norm x \<le> b"
  2819     unfolding bounded_pos by auto
  2820   from assms(2) obtain B where B: "B > 0" "\<forall>x. norm (f x) \<le> B * norm x"
  2821     using bounded_linear.pos_bounded by (auto simp add: mult_ac)
  2822   {
  2823     fix x
  2824     assume "x \<in> S"
  2825     then have "norm x \<le> b"
  2826       using b by auto
  2827     then have "norm (f x) \<le> B * b"
  2828       using B(2)
  2829       apply (erule_tac x=x in allE)
  2830       apply (metis B(1) B(2) order_trans mult_le_cancel_left_pos)
  2831       done
  2832   }
  2833   then show ?thesis
  2834     unfolding bounded_pos
  2835     apply (rule_tac x="b*B" in exI)
  2836     using b B mult_pos_pos [of b B]
  2837     apply (auto simp add: mult_commute)
  2838     done
  2839 qed
  2840 
  2841 lemma bounded_scaling:
  2842   fixes S :: "'a::real_normed_vector set"
  2843   shows "bounded S \<Longrightarrow> bounded ((\<lambda>x. c *\<^sub>R x) ` S)"
  2844   apply (rule bounded_linear_image)
  2845   apply assumption
  2846   apply (rule bounded_linear_scaleR_right)
  2847   done
  2848 
  2849 lemma bounded_translation:
  2850   fixes S :: "'a::real_normed_vector set"
  2851   assumes "bounded S"
  2852   shows "bounded ((\<lambda>x. a + x) ` S)"
  2853 proof -
  2854   from assms obtain b where b: "b > 0" "\<forall>x\<in>S. norm x \<le> b"
  2855     unfolding bounded_pos by auto
  2856   {
  2857     fix x
  2858     assume "x \<in> S"
  2859     then have "norm (a + x) \<le> b + norm a"
  2860       using norm_triangle_ineq[of a x] b by auto
  2861   }
  2862   then show ?thesis
  2863     unfolding bounded_pos
  2864     using norm_ge_zero[of a] b(1) and add_strict_increasing[of b 0 "norm a"]
  2865     by (auto intro!: exI[of _ "b + norm a"])
  2866 qed
  2867 
  2868 
  2869 text{* Some theorems on sups and infs using the notion "bounded". *}
  2870 
  2871 lemma bounded_real: "bounded (S::real set) \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. \<bar>x\<bar> \<le> a)"
  2872   by (simp add: bounded_iff)
  2873 
  2874 lemma bounded_imp_bdd_above: "bounded S \<Longrightarrow> bdd_above (S :: real set)"
  2875   by (auto simp: bounded_def bdd_above_def dist_real_def)
  2876      (metis abs_le_D1 abs_minus_commute diff_le_eq)
  2877 
  2878 lemma bounded_imp_bdd_below: "bounded S \<Longrightarrow> bdd_below (S :: real set)"
  2879   by (auto simp: bounded_def bdd_below_def dist_real_def)
  2880      (metis abs_le_D1 add_commute diff_le_eq)
  2881 
  2882 (* TODO: remove the following lemmas about Inf and Sup, is now in conditionally complete lattice *)
  2883 
  2884 lemma bounded_has_Sup:
  2885   fixes S :: "real set"
  2886   assumes "bounded S"
  2887     and "S \<noteq> {}"
  2888   shows "\<forall>x\<in>S. x \<le> Sup S"
  2889     and "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b"
  2890 proof
  2891   show "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b"
  2892     using assms by (metis cSup_least)
  2893 qed (metis cSup_upper assms(1) bounded_imp_bdd_above)
  2894 
  2895 lemma Sup_insert:
  2896   fixes S :: "real set"
  2897   shows "bounded S \<Longrightarrow> Sup (insert x S) = (if S = {} then x else max x (Sup S))"
  2898   by (auto simp: bounded_imp_bdd_above sup_max cSup_insert_If)
  2899 
  2900 lemma Sup_insert_finite:
  2901   fixes S :: "real set"
  2902   shows "finite S \<Longrightarrow> Sup (insert x S) = (if S = {} then x else max x (Sup S))"
  2903   apply (rule Sup_insert)
  2904   apply (rule finite_imp_bounded)
  2905   apply simp
  2906   done
  2907 
  2908 lemma bounded_has_Inf:
  2909   fixes S :: "real set"
  2910   assumes "bounded S"
  2911     and "S \<noteq> {}"
  2912   shows "\<forall>x\<in>S. x \<ge> Inf S"
  2913     and "\<forall>b. (\<forall>x\<in>S. x \<ge> b) \<longrightarrow> Inf S \<ge> b"
  2914 proof
  2915   show "\<forall>b. (\<forall>x\<in>S. x \<ge> b) \<longrightarrow> Inf S \<ge> b"
  2916     using assms by (metis cInf_greatest)
  2917 qed (metis cInf_lower assms(1) bounded_imp_bdd_below)
  2918 
  2919 lemma Inf_insert:
  2920   fixes S :: "real set"
  2921   shows "bounded S \<Longrightarrow> Inf (insert x S) = (if S = {} then x else min x (Inf S))"
  2922   by (auto simp: bounded_imp_bdd_below inf_min cInf_insert_If)
  2923 
  2924 lemma Inf_insert_finite:
  2925   fixes S :: "real set"
  2926   shows "finite S \<Longrightarrow> Inf (insert x S) = (if S = {} then x else min x (Inf S))"
  2927   apply (rule Inf_insert)
  2928   apply (rule finite_imp_bounded)
  2929   apply simp
  2930   done
  2931 
  2932 subsection {* Compactness *}
  2933 
  2934 subsubsection {* Bolzano-Weierstrass property *}
  2935 
  2936 lemma heine_borel_imp_bolzano_weierstrass:
  2937   assumes "compact s"
  2938     and "infinite t"
  2939     and "t \<subseteq> s"
  2940   shows "\<exists>x \<in> s. x islimpt t"
  2941 proof (rule ccontr)
  2942   assume "\<not> (\<exists>x \<in> s. x islimpt t)"
  2943   then obtain f where f: "\<forall>x\<in>s. x \<in> f x \<and> open (f x) \<and> (\<forall>y\<in>t. y \<in> f x \<longrightarrow> y = x)"
  2944     unfolding islimpt_def
  2945     using bchoice[of s "\<lambda> x T. x \<in> T \<and> open T \<and> (\<forall>y\<in>t. y \<in> T \<longrightarrow> y = x)"]
  2946     by auto
  2947   obtain g where g: "g \<subseteq> {t. \<exists>x. x \<in> s \<and> t = f x}" "finite g" "s \<subseteq> \<Union>g"
  2948     using assms(1)[unfolded compact_eq_heine_borel, THEN spec[where x="{t. \<exists>x. x\<in>s \<and> t = f x}"]]
  2949     using f by auto
  2950   from g(1,3) have g':"\<forall>x\<in>g. \<exists>xa \<in> s. x = f xa"
  2951     by auto
  2952   {
  2953     fix x y
  2954     assume "x \<in> t" "y \<in> t" "f x = f y"
  2955     then have "x \<in> f x"  "y \<in> f x \<longrightarrow> y = x"
  2956       using f[THEN bspec[where x=x]] and `t \<subseteq> s` by auto
  2957     then have "x = y"
  2958       using `f x = f y` and f[THEN bspec[where x=y]] and `y \<in> t` and `t \<subseteq> s`
  2959       by auto
  2960   }
  2961   then have "inj_on f t"
  2962     unfolding inj_on_def by simp
  2963   then have "infinite (f ` t)"
  2964     using assms(2) using finite_imageD by auto
  2965   moreover
  2966   {
  2967     fix x
  2968     assume "x \<in> t" "f x \<notin> g"
  2969     from g(3) assms(3) `x \<in> t` obtain h where "h \<in> g" and "x \<in> h"
  2970       by auto
  2971     then obtain y where "y \<in> s" "h = f y"
  2972       using g'[THEN bspec[where x=h]] by auto
  2973     then have "y = x"
  2974       using f[THEN bspec[where x=y]] and `x\<in>t` and `x\<in>h`[unfolded `h = f y`]
  2975       by auto
  2976     then have False
  2977       using `f x \<notin> g` `h \<in> g` unfolding `h = f y`
  2978       by auto
  2979   }
  2980   then have "f ` t \<subseteq> g" by auto
  2981   ultimately show False
  2982     using g(2) using finite_subset by auto
  2983 qed
  2984 
  2985 lemma acc_point_range_imp_convergent_subsequence:
  2986   fixes l :: "'a :: first_countable_topology"
  2987   assumes l: "\<forall>U. l\<in>U \<longrightarrow> open U \<longrightarrow> infinite (U \<inter> range f)"
  2988   shows "\<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  2989 proof -
  2990   from countable_basis_at_decseq[of l]
  2991   obtain A where A:
  2992       "\<And>i. open (A i)"
  2993       "\<And>i. l \<in> A i"
  2994       "\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  2995     by blast
  2996   def s \<equiv> "\<lambda>n i. SOME j. i < j \<and> f j \<in> A (Suc n)"
  2997   {
  2998     fix n i
  2999     have "infinite (A (Suc n) \<inter> range f - f`{.. i})"
  3000       using l A by auto
  3001     then have "\<exists>x. x \<in> A (Suc n) \<inter> range f - f`{.. i}"
  3002       unfolding ex_in_conv by (intro notI) simp
  3003     then have "\<exists>j. f j \<in> A (Suc n) \<and> j \<notin> {.. i}"
  3004       by auto
  3005     then have "\<exists>a. i < a \<and> f a \<in> A (Suc n)"
  3006       by (auto simp: not_le)
  3007     then have "i < s n i" "f (s n i) \<in> A (Suc n)"
  3008       unfolding s_def by (auto intro: someI2_ex)
  3009   }
  3010   note s = this
  3011   def r \<equiv> "rec_nat (s 0 0) s"
  3012   have "subseq r"
  3013     by (auto simp: r_def s subseq_Suc_iff)
  3014   moreover
  3015   have "(\<lambda>n. f (r n)) ----> l"
  3016   proof (rule topological_tendstoI)
  3017     fix S
  3018     assume "open S" "l \<in> S"
  3019     with A(3) have "eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  3020       by auto
  3021     moreover
  3022     {
  3023       fix i
  3024       assume "Suc 0 \<le> i"
  3025       then have "f (r i) \<in> A i"
  3026         by (cases i) (simp_all add: r_def s)
  3027     }
  3028     then have "eventually (\<lambda>i. f (r i) \<in> A i) sequentially"
  3029       by (auto simp: eventually_sequentially)
  3030     ultimately show "eventually (\<lambda>i. f (r i) \<in> S) sequentially"
  3031       by eventually_elim auto
  3032   qed
  3033   ultimately show "\<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  3034     by (auto simp: convergent_def comp_def)
  3035 qed
  3036 
  3037 lemma sequence_infinite_lemma:
  3038   fixes f :: "nat \<Rightarrow> 'a::t1_space"
  3039   assumes "\<forall>n. f n \<noteq> l"
  3040     and "(f ---> l) sequentially"
  3041   shows "infinite (range f)"
  3042 proof
  3043   assume "finite (range f)"
  3044   then have "closed (range f)"
  3045     by (rule finite_imp_closed)
  3046   then have "open (- range f)"
  3047     by (rule open_Compl)
  3048   from assms(1) have "l \<in> - range f"
  3049     by auto
  3050   from assms(2) have "eventually (\<lambda>n. f n \<in> - range f) sequentially"
  3051     using `open (- range f)` `l \<in> - range f`
  3052     by (rule topological_tendstoD)
  3053   then show False
  3054     unfolding eventually_sequentially
  3055     by auto
  3056 qed
  3057 
  3058 lemma closure_insert:
  3059   fixes x :: "'a::t1_space"
  3060   shows "closure (insert x s) = insert x (closure s)"
  3061   apply (rule closure_unique)
  3062   apply (rule insert_mono [OF closure_subset])
  3063   apply (rule closed_insert [OF closed_closure])
  3064   apply (simp add: closure_minimal)
  3065   done
  3066 
  3067 lemma islimpt_insert:
  3068   fixes x :: "'a::t1_space"
  3069   shows "x islimpt (insert a s) \<longleftrightarrow> x islimpt s"
  3070 proof
  3071   assume *: "x islimpt (insert a s)"
  3072   show "x islimpt s"
  3073   proof (rule islimptI)
  3074     fix t
  3075     assume t: "x \<in> t" "open t"
  3076     show "\<exists>y\<in>s. y \<in> t \<and> y \<noteq> x"
  3077     proof (cases "x = a")
  3078       case True
  3079       obtain y where "y \<in> insert a s" "y \<in> t" "y \<noteq> x"
  3080         using * t by (rule islimptE)
  3081       with `x = a` show ?thesis by auto
  3082     next
  3083       case False
  3084       with t have t': "x \<in> t - {a}" "open (t - {a})"
  3085         by (simp_all add: open_Diff)
  3086       obtain y where "y \<in> insert a s" "y \<in> t - {a}" "y \<noteq> x"
  3087         using * t' by (rule islimptE)
  3088       then show ?thesis by auto
  3089     qed
  3090   qed
  3091 next
  3092   assume "x islimpt s"
  3093   then show "x islimpt (insert a s)"
  3094     by (rule islimpt_subset) auto
  3095 qed
  3096 
  3097 lemma islimpt_finite:
  3098   fixes x :: "'a::t1_space"
  3099   shows "finite s \<Longrightarrow> \<not> x islimpt s"
  3100   by (induct set: finite) (simp_all add: islimpt_insert)
  3101 
  3102 lemma islimpt_union_finite:
  3103   fixes x :: "'a::t1_space"
  3104   shows "finite s \<Longrightarrow> x islimpt (s \<union> t) \<longleftrightarrow> x islimpt t"
  3105   by (simp add: islimpt_Un islimpt_finite)
  3106 
  3107 lemma islimpt_eq_acc_point:
  3108   fixes l :: "'a :: t1_space"
  3109   shows "l islimpt S \<longleftrightarrow> (\<forall>U. l\<in>U \<longrightarrow> open U \<longrightarrow> infinite (U \<inter> S))"
  3110 proof (safe intro!: islimptI)
  3111   fix U
  3112   assume "l islimpt S" "l \<in> U" "open U" "finite (U \<inter> S)"
  3113   then have "l islimpt S" "l \<in> (U - (U \<inter> S - {l}))" "open (U - (U \<inter> S - {l}))"
  3114     by (auto intro: finite_imp_closed)
  3115   then show False
  3116     by (rule islimptE) auto
  3117 next
  3118   fix T
  3119   assume *: "\<forall>U. l\<in>U \<longrightarrow> open U \<longrightarrow> infinite (U \<inter> S)" "l \<in> T" "open T"
  3120   then have "infinite (T \<inter> S - {l})"
  3121     by auto
  3122   then have "\<exists>x. x \<in> (T \<inter> S - {l})"
  3123     unfolding ex_in_conv by (intro notI) simp
  3124   then show "\<exists>y\<in>S. y \<in> T \<and> y \<noteq> l"
  3125     by auto
  3126 qed
  3127 
  3128 lemma islimpt_range_imp_convergent_subsequence:
  3129   fixes l :: "'a :: {t1_space, first_countable_topology}"
  3130   assumes l: "l islimpt (range f)"
  3131   shows "\<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  3132   using l unfolding islimpt_eq_acc_point
  3133   by (rule acc_point_range_imp_convergent_subsequence)
  3134 
  3135 lemma sequence_unique_limpt:
  3136   fixes f :: "nat \<Rightarrow> 'a::t2_space"
  3137   assumes "(f ---> l) sequentially"
  3138     and "l' islimpt (range f)"
  3139   shows "l' = l"
  3140 proof (rule ccontr)
  3141   assume "l' \<noteq> l"
  3142   obtain s t where "open s" "open t" "l' \<in> s" "l \<in> t" "s \<inter> t = {}"
  3143     using hausdorff [OF `l' \<noteq> l`] by auto
  3144   have "eventually (\<lambda>n. f n \<in> t) sequentially"
  3145     using assms(1) `open t` `l \<in> t` by (rule topological_tendstoD)
  3146   then obtain N where "\<forall>n\<ge>N. f n \<in> t"
  3147     unfolding eventually_sequentially by auto
  3148 
  3149   have "UNIV = {..<N} \<union> {N..}"
  3150     by auto
  3151   then have "l' islimpt (f ` ({..<N} \<union> {N..}))"
  3152     using assms(2) by simp
  3153   then have "l' islimpt (f ` {..<N} \<union> f ` {N..})"
  3154     by (simp add: image_Un)
  3155   then have "l' islimpt (f ` {N..})"
  3156     by (simp add: islimpt_union_finite)
  3157   then obtain y where "y \<in> f ` {N..}" "y \<in> s" "y \<noteq> l'"
  3158     using `l' \<in> s` `open s` by (rule islimptE)
  3159   then obtain n where "N \<le> n" "f n \<in> s" "f n \<noteq> l'"
  3160     by auto
  3161   with `\<forall>n\<ge>N. f n \<in> t` have "f n \<in> s \<inter> t"
  3162     by simp
  3163   with `s \<inter> t = {}` show False
  3164     by simp
  3165 qed
  3166 
  3167 lemma bolzano_weierstrass_imp_closed:
  3168   fixes s :: "'a::{first_countable_topology,t2_space} set"
  3169   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  3170   shows "closed s"
  3171 proof -
  3172   {
  3173     fix x l
  3174     assume as: "\<forall>n::nat. x n \<in> s" "(x ---> l) sequentially"
  3175     then have "l \<in> s"
  3176     proof (cases "\<forall>n. x n \<noteq> l")
  3177       case False
  3178       then show "l\<in>s" using as(1) by auto
  3179     next
  3180       case True note cas = this
  3181       with as(2) have "infinite (range x)"
  3182         using sequence_infinite_lemma[of x l] by auto
  3183       then obtain l' where "l'\<in>s" "l' islimpt (range x)"
  3184         using assms[THEN spec[where x="range x"]] as(1) by auto
  3185       then show "l\<in>s" using sequence_unique_limpt[of x l l']
  3186         using as cas by auto
  3187     qed
  3188   }
  3189   then show ?thesis
  3190     unfolding closed_sequential_limits by fast
  3191 qed
  3192 
  3193 lemma compact_imp_bounded:
  3194   assumes "compact U"
  3195   shows "bounded U"
  3196 proof -
  3197   have "compact U" "\<forall>x\<in>U. open (ball x 1)" "U \<subseteq> (\<Union>x\<in>U. ball x 1)"
  3198     using assms by auto
  3199   then obtain D where D: "D \<subseteq> U" "finite D" "U \<subseteq> (\<Union>x\<in>D. ball x 1)"
  3200     by (rule compactE_image)
  3201   from `finite D` have "bounded (\<Union>x\<in>D. ball x 1)"
  3202     by (simp add: bounded_UN)
  3203   then show "bounded U" using `U \<subseteq> (\<Union>x\<in>D. ball x 1)`
  3204     by (rule bounded_subset)
  3205 qed
  3206 
  3207 text{* In particular, some common special cases. *}
  3208 
  3209 lemma compact_union [intro]:
  3210   assumes "compact s"
  3211     and "compact t"
  3212   shows " compact (s \<union> t)"
  3213 proof (rule compactI)
  3214   fix f
  3215   assume *: "Ball f open" "s \<union> t \<subseteq> \<Union>f"
  3216   from * `compact s` obtain s' where "s' \<subseteq> f \<and> finite s' \<and> s \<subseteq> \<Union>s'"
  3217     unfolding compact_eq_heine_borel by (auto elim!: allE[of _ f])
  3218   moreover
  3219   from * `compact t` obtain t' where "t' \<subseteq> f \<and> finite t' \<and> t \<subseteq> \<Union>t'"
  3220     unfolding compact_eq_heine_borel by (auto elim!: allE[of _ f])
  3221   ultimately show "\<exists>f'\<subseteq>f. finite f' \<and> s \<union> t \<subseteq> \<Union>f'"
  3222     by (auto intro!: exI[of _ "s' \<union> t'"])
  3223 qed
  3224 
  3225 lemma compact_Union [intro]: "finite S \<Longrightarrow> (\<And>T. T \<in> S \<Longrightarrow> compact T) \<Longrightarrow> compact (\<Union>S)"
  3226   by (induct set: finite) auto
  3227 
  3228 lemma compact_UN [intro]:
  3229   "finite A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> compact (B x)) \<Longrightarrow> compact (\<Union>x\<in>A. B x)"
  3230   unfolding SUP_def by (rule compact_Union) auto
  3231 
  3232 lemma closed_inter_compact [intro]:
  3233   assumes "closed s"
  3234     and "compact t"
  3235   shows "compact (s \<inter> t)"
  3236   using compact_inter_closed [of t s] assms
  3237   by (simp add: Int_commute)
  3238 
  3239 lemma compact_inter [intro]:
  3240   fixes s t :: "'a :: t2_space set"
  3241   assumes "compact s"
  3242     and "compact t"
  3243   shows "compact (s \<inter> t)"
  3244   using assms by (intro compact_inter_closed compact_imp_closed)
  3245 
  3246 lemma compact_sing [simp]: "compact {a}"
  3247   unfolding compact_eq_heine_borel by auto
  3248 
  3249 lemma compact_insert [simp]:
  3250   assumes "compact s"
  3251   shows "compact (insert x s)"
  3252 proof -
  3253   have "compact ({x} \<union> s)"
  3254     using compact_sing assms by (rule compact_union)
  3255   then show ?thesis by simp
  3256 qed
  3257 
  3258 lemma finite_imp_compact: "finite s \<Longrightarrow> compact s"
  3259   by (induct set: finite) simp_all
  3260 
  3261 lemma open_delete:
  3262   fixes s :: "'a::t1_space set"
  3263   shows "open s \<Longrightarrow> open (s - {x})"
  3264   by (simp add: open_Diff)
  3265 
  3266 text{*Compactness expressed with filters*}
  3267 
  3268 definition "filter_from_subbase B = Abs_filter (\<lambda>P. \<exists>X \<subseteq> B. finite X \<and> Inf X \<le> P)"
  3269 
  3270 lemma eventually_filter_from_subbase:
  3271   "eventually P (filter_from_subbase B) \<longleftrightarrow> (\<exists>X \<subseteq> B. finite X \<and> Inf X \<le> P)"
  3272     (is "_ \<longleftrightarrow> ?R P")
  3273   unfolding filter_from_subbase_def
  3274 proof (rule eventually_Abs_filter is_filter.intro)+
  3275   show "?R (\<lambda>x. True)"
  3276     by (rule exI[of _ "{}"]) (simp add: le_fun_def)
  3277 next
  3278   fix P Q
  3279   assume "?R P" then guess X ..
  3280   moreover
  3281   assume "?R Q" then guess Y ..
  3282   ultimately show "?R (\<lambda>x. P x \<and> Q x)"
  3283     by (intro exI[of _ "X \<union> Y"]) auto
  3284 next
  3285   fix P Q
  3286   assume "?R P" then guess X ..
  3287   moreover assume "\<forall>x. P x \<longrightarrow> Q x"
  3288   ultimately show "?R Q"
  3289     by (intro exI[of _ X]) auto
  3290 qed
  3291 
  3292 lemma eventually_filter_from_subbaseI: "P \<in> B \<Longrightarrow> eventually P (filter_from_subbase B)"
  3293   by (subst eventually_filter_from_subbase) (auto intro!: exI[of _ "{P}"])
  3294 
  3295 lemma filter_from_subbase_not_bot:
  3296   "\<forall>X \<subseteq> B. finite X \<longrightarrow> Inf X \<noteq> bot \<Longrightarrow> filter_from_subbase B \<noteq> bot"
  3297   unfolding trivial_limit_def eventually_filter_from_subbase by auto
  3298 
  3299 lemma closure_iff_nhds_not_empty:
  3300   "x \<in> closure X \<longleftrightarrow> (\<forall>A. \<forall>S\<subseteq>A. open S \<longrightarrow> x \<in> S \<longrightarrow> X \<inter> A \<noteq> {})"
  3301 proof safe
  3302   assume x: "x \<in> closure X"
  3303   fix S A
  3304   assume "open S" "x \<in> S" "X \<inter> A = {}" "S \<subseteq> A"
  3305   then have "x \<notin> closure (-S)"
  3306     by (auto simp: closure_complement subset_eq[symmetric] intro: interiorI)
  3307   with x have "x \<in> closure X - closure (-S)"
  3308     by auto
  3309   also have "\<dots> \<subseteq> closure (X \<inter> S)"
  3310     using `open S` open_inter_closure_subset[of S X] by (simp add: closed_Compl ac_simps)
  3311   finally have "X \<inter> S \<noteq> {}" by auto
  3312   then show False using `X \<inter> A = {}` `S \<subseteq> A` by auto
  3313 next
  3314   assume "\<forall>A S. S \<subseteq> A \<longrightarrow> open S \<longrightarrow> x \<in> S \<longrightarrow> X \<inter> A \<noteq> {}"
  3315   from this[THEN spec, of "- X", THEN spec, of "- closure X"]
  3316   show "x \<in> closure X"
  3317     by (simp add: closure_subset open_Compl)
  3318 qed
  3319 
  3320 lemma compact_filter:
  3321   "compact U \<longleftrightarrow> (\<forall>F. F \<noteq> bot \<longrightarrow> eventually (\<lambda>x. x \<in> U) F \<longrightarrow> (\<exists>x\<in>U. inf (nhds x) F \<noteq> bot))"
  3322 proof (intro allI iffI impI compact_fip[THEN iffD2] notI)
  3323   fix F
  3324   assume "compact U"
  3325   assume F: "F \<noteq> bot" "eventually (\<lambda>x. x \<in> U) F"
  3326   then have "U \<noteq> {}"
  3327     by (auto simp: eventually_False)
  3328 
  3329   def Z \<equiv> "closure ` {A. eventually (\<lambda>x. x \<in> A) F}"
  3330   then have "\<forall>z\<in>Z. closed z"
  3331     by auto
  3332   moreover
  3333   have ev_Z: "\<And>z. z \<in> Z \<Longrightarrow> eventually (\<lambda>x. x \<in> z) F"
  3334     unfolding Z_def by (auto elim: eventually_elim1 intro: set_mp[OF closure_subset])
  3335   have "(\<forall>B \<subseteq> Z. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {})"
  3336   proof (intro allI impI)
  3337     fix B assume "finite B" "B \<subseteq> Z"
  3338     with `finite B` ev_Z have "eventually (\<lambda>x. \<forall>b\<in>B. x \<in> b) F"
  3339       by (auto intro!: eventually_Ball_finite)
  3340     with F(2) have "eventually (\<lambda>x. x \<in> U \<inter> (\<Inter>B)) F"
  3341       by eventually_elim auto
  3342     with F show "U \<inter> \<Inter>B \<noteq> {}"
  3343       by (intro notI) (simp add: eventually_False)
  3344   qed
  3345   ultimately have "U \<inter> \<Inter>Z \<noteq> {}"
  3346     using `compact U` unfolding compact_fip by blast
  3347   then obtain x where "x \<in> U" and x: "\<And>z. z \<in> Z \<Longrightarrow> x \<in> z"
  3348     by auto
  3349 
  3350   have "\<And>P. eventually P (inf (nhds x) F) \<Longrightarrow> P \<noteq> bot"
  3351     unfolding eventually_inf eventually_nhds
  3352   proof safe
  3353     fix P Q R S
  3354     assume "eventually R F" "open S" "x \<in> S"
  3355     with open_inter_closure_eq_empty[of S "{x. R x}"] x[of "closure {x. R x}"]
  3356     have "S \<inter> {x. R x} \<noteq> {}" by (auto simp: Z_def)
  3357     moreover assume "Ball S Q" "\<forall>x. Q x \<and> R x \<longrightarrow> bot x"
  3358     ultimately show False by (auto simp: set_eq_iff)
  3359   qed
  3360   with `x \<in> U` show "\<exists>x\<in>U. inf (nhds x) F \<noteq> bot"
  3361     by (metis eventually_bot)
  3362 next
  3363   fix A
  3364   assume A: "\<forall>a\<in>A. closed a" "\<forall>B\<subseteq>A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}" "U \<inter> \<Inter>A = {}"
  3365   def P' \<equiv> "(\<lambda>a (x::'a). x \<in> a)"
  3366   then have inj_P': "\<And>A. inj_on P' A"
  3367     by (auto intro!: inj_onI simp: fun_eq_iff)
  3368   def F \<equiv> "filter_from_subbase (P' ` insert U A)"
  3369   have "F \<noteq> bot"
  3370     unfolding F_def
  3371   proof (safe intro!: filter_from_subbase_not_bot)
  3372     fix X
  3373     assume "X \<subseteq> P' ` insert U A" "finite X" "Inf X = bot"
  3374     then obtain B where "B \<subseteq> insert U A" "finite B" and B: "Inf (P' ` B) = bot"
  3375       unfolding subset_image_iff by (auto intro: inj_P' finite_imageD simp del: Inf_image_eq)
  3376     with A(2)[THEN spec, of "B - {U}"] have "U \<inter> \<Inter>(B - {U}) \<noteq> {}"
  3377       by auto
  3378     with B show False
  3379       by (auto simp: P'_def fun_eq_iff)
  3380   qed
  3381   moreover have "eventually (\<lambda>x. x \<in> U) F"
  3382     unfolding F_def by (rule eventually_filter_from_subbaseI) (auto simp: P'_def)
  3383   moreover
  3384   assume "\<forall>F. F \<noteq> bot \<longrightarrow> eventually (\<lambda>x. x \<in> U) F \<longrightarrow> (\<exists>x\<in>U. inf (nhds x) F \<noteq> bot)"
  3385   ultimately obtain x where "x \<in> U" and x: "inf (nhds x) F \<noteq> bot"
  3386     by auto
  3387 
  3388   {
  3389     fix V
  3390     assume "V \<in> A"
  3391     then have V: "eventually (\<lambda>x. x \<in> V) F"
  3392       by (auto simp add: F_def image_iff P'_def intro!: eventually_filter_from_subbaseI)
  3393     have "x \<in> closure V"
  3394       unfolding closure_iff_nhds_not_empty
  3395     proof (intro impI allI)
  3396       fix S A
  3397       assume "open S" "x \<in> S" "S \<subseteq> A"
  3398       then have "eventually (\<lambda>x. x \<in> A) (nhds x)"
  3399         by (auto simp: eventually_nhds)
  3400       with V have "eventually (\<lambda>x. x \<in> V \<inter> A) (inf (nhds x) F)"
  3401         by (auto simp: eventually_inf)
  3402       with x show "V \<inter> A \<noteq> {}"
  3403         by (auto simp del: Int_iff simp add: trivial_limit_def)
  3404     qed
  3405     then have "x \<in> V"
  3406       using `V \<in> A` A(1) by simp
  3407   }
  3408   with `x\<in>U` have "x \<in> U \<inter> \<Inter>A" by auto
  3409   with `U \<inter> \<Inter>A = {}` show False by auto
  3410 qed
  3411 
  3412 definition "countably_compact U \<longleftrightarrow>
  3413     (\<forall>A. countable A \<longrightarrow> (\<forall>a\<in>A. open a) \<longrightarrow> U \<subseteq> \<Union>A \<longrightarrow> (\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T))"
  3414 
  3415 lemma countably_compactE:
  3416   assumes "countably_compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C" "countable C"
  3417   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  3418   using assms unfolding countably_compact_def by metis
  3419 
  3420 lemma countably_compactI:
  3421   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union>C \<Longrightarrow> countable C \<Longrightarrow> (\<exists>C'\<subseteq>C. finite C' \<and> s \<subseteq> \<Union>C')"
  3422   shows "countably_compact s"
  3423   using assms unfolding countably_compact_def by metis
  3424 
  3425 lemma compact_imp_countably_compact: "compact U \<Longrightarrow> countably_compact U"
  3426   by (auto simp: compact_eq_heine_borel countably_compact_def)
  3427 
  3428 lemma countably_compact_imp_compact:
  3429   assumes "countably_compact U"
  3430     and ccover: "countable B" "\<forall>b\<in>B. open b"
  3431     and basis: "\<And>T x. open T \<Longrightarrow> x \<in> T \<Longrightarrow> x \<in> U \<Longrightarrow> \<exists>b\<in>B. x \<in> b \<and> b \<inter> U \<subseteq> T"
  3432   shows "compact U"
  3433   using `countably_compact U`
  3434   unfolding compact_eq_heine_borel countably_compact_def
  3435 proof safe
  3436   fix A
  3437   assume A: "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  3438   assume *: "\<forall>A. countable A \<longrightarrow> (\<forall>a\<in>A. open a) \<longrightarrow> U \<subseteq> \<Union>A \<longrightarrow> (\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T)"
  3439 
  3440   moreover def C \<equiv> "{b\<in>B. \<exists>a\<in>A. b \<inter> U \<subseteq> a}"
  3441   ultimately have "countable C" "\<forall>a\<in>C. open a"
  3442     unfolding C_def using ccover by auto
  3443   moreover
  3444   have "\<Union>A \<inter> U \<subseteq> \<Union>C"
  3445   proof safe
  3446     fix x a
  3447     assume "x \<in> U" "x \<in> a" "a \<in> A"
  3448     with basis[of a x] A obtain b where "b \<in> B" "x \<in> b" "b \<inter> U \<subseteq> a"
  3449       by blast
  3450     with `a \<in> A` show "x \<in> \<Union>C"
  3451       unfolding C_def by auto
  3452   qed
  3453   then have "U \<subseteq> \<Union>C" using `U \<subseteq> \<Union>A` by auto
  3454   ultimately obtain T where T: "T\<subseteq>C" "finite T" "U \<subseteq> \<Union>T"
  3455     using * by metis
  3456   then have "\<forall>t\<in>T. \<exists>a\<in>A. t \<inter> U \<subseteq> a"
  3457     by (auto simp: C_def)
  3458   then obtain f where "\<forall>t\<in>T. f t \<in> A \<and> t \<inter> U \<subseteq> f t"
  3459     unfolding bchoice_iff Bex_def ..
  3460   with T show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  3461     unfolding C_def by (intro exI[of _ "f`T"]) fastforce
  3462 qed
  3463 
  3464 lemma countably_compact_imp_compact_second_countable:
  3465   "countably_compact U \<Longrightarrow> compact (U :: 'a :: second_countable_topology set)"
  3466 proof (rule countably_compact_imp_compact)
  3467   fix T and x :: 'a
  3468   assume "open T" "x \<in> T"
  3469   from topological_basisE[OF is_basis this] obtain b where
  3470     "b \<in> (SOME B. countable B \<and> topological_basis B)" "x \<in> b" "b \<subseteq> T" .
  3471   then show "\<exists>b\<in>SOME B. countable B \<and> topological_basis B. x \<in> b \<and> b \<inter> U \<subseteq> T"
  3472     by blast
  3473 qed (insert countable_basis topological_basis_open[OF is_basis], auto)
  3474 
  3475 lemma countably_compact_eq_compact:
  3476   "countably_compact U \<longleftrightarrow> compact (U :: 'a :: second_countable_topology set)"
  3477   using countably_compact_imp_compact_second_countable compact_imp_countably_compact by blast
  3478 
  3479 subsubsection{* Sequential compactness *}
  3480 
  3481 definition seq_compact :: "'a::topological_space set \<Rightarrow> bool"
  3482   where "seq_compact S \<longleftrightarrow>
  3483     (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow> (\<exists>l\<in>S. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially))"
  3484 
  3485 lemma seq_compactI:
  3486   assumes "\<And>f. \<forall>n. f n \<in> S \<Longrightarrow> \<exists>l\<in>S. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3487   shows "seq_compact S"
  3488   unfolding seq_compact_def using assms by fast
  3489 
  3490 lemma seq_compactE:
  3491   assumes "seq_compact S" "\<forall>n. f n \<in> S"
  3492   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) ---> l) sequentially"
  3493   using assms unfolding seq_compact_def by fast
  3494 
  3495 lemma closed_sequentially: (* TODO: move upwards *)
  3496   assumes "closed s" and "\<forall>n. f n \<in> s" and "f ----> l"
  3497   shows "l \<in> s"
  3498 proof (rule ccontr)
  3499   assume "l \<notin> s"
  3500   with `closed s` and `f ----> l` have "eventually (\<lambda>n. f n \<in> - s) sequentially"
  3501     by (fast intro: topological_tendstoD)
  3502   with `\<forall>n. f n \<in> s` show "False"
  3503     by simp
  3504 qed
  3505 
  3506 lemma seq_compact_inter_closed:
  3507   assumes "seq_compact s" and "closed t"
  3508   shows "seq_compact (s \<inter> t)"
  3509 proof (rule seq_compactI)
  3510   fix f assume "\<forall>n::nat. f n \<in> s \<inter> t"
  3511   hence "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t"
  3512     by simp_all
  3513   from `seq_compact s` and `\<forall>n. f n \<in> s`
  3514   obtain l r where "l \<in> s" and r: "subseq r" and l: "(f \<circ> r) ----> l"
  3515     by (rule seq_compactE)
  3516   from `\<forall>n. f n \<in> t` have "\<forall>n. (f \<circ> r) n \<in> t"
  3517     by simp
  3518   from `closed t` and this and l have "l \<in> t"
  3519     by (rule closed_sequentially)
  3520   with `l \<in> s` and r and l show "\<exists>l\<in>s \<inter> t. \<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  3521     by fast
  3522 qed
  3523 
  3524 lemma seq_compact_closed_subset:
  3525   assumes "closed s" and "s \<subseteq> t" and "seq_compact t"
  3526   shows "seq_compact s"
  3527   using assms seq_compact_inter_closed [of t s] by (simp add: Int_absorb1)
  3528 
  3529 lemma seq_compact_imp_countably_compact:
  3530   fixes U :: "'a :: first_countable_topology set"
  3531   assumes "seq_compact U"
  3532   shows "countably_compact U"
  3533 proof (safe intro!: countably_compactI)
  3534   fix A
  3535   assume A: "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A" "countable A"
  3536   have subseq: "\<And>X. range X \<subseteq> U \<Longrightarrow> \<exists>r x. x \<in> U \<and> subseq r \<and> (X \<circ> r) ----> x"
  3537     using `seq_compact U` by (fastforce simp: seq_compact_def subset_eq)
  3538   show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  3539   proof cases
  3540     assume "finite A"
  3541     with A show ?thesis by auto
  3542   next
  3543     assume "infinite A"
  3544     then have "A \<noteq> {}" by auto
  3545     show ?thesis
  3546     proof (rule ccontr)
  3547       assume "\<not> (\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T)"
  3548       then have "\<forall>T. \<exists>x. T \<subseteq> A \<and> finite T \<longrightarrow> (x \<in> U - \<Union>T)"
  3549         by auto
  3550       then obtain X' where T: "\<And>T. T \<subseteq> A \<Longrightarrow> finite T \<Longrightarrow> X' T \<in> U - \<Union>T"
  3551         by metis
  3552       def X \<equiv> "\<lambda>n. X' (from_nat_into A ` {.. n})"
  3553       have X: "\<And>n. X n \<in> U - (\<Union>i\<le>n. from_nat_into A i)"
  3554         using `A \<noteq> {}` unfolding X_def SUP_def by (intro T) (auto intro: from_nat_into)
  3555       then have "range X \<subseteq> U"
  3556         by auto
  3557       with subseq[of X] obtain r x where "x \<in> U" and r: "subseq r" "(X \<circ> r) ----> x"
  3558         by auto
  3559       from `x\<in>U` `U \<subseteq> \<Union>A` from_nat_into_surj[OF `countable A`]
  3560       obtain n where "x \<in> from_nat_into A n" by auto
  3561       with r(2) A(1) from_nat_into[OF `A \<noteq> {}`, of n]
  3562       have "eventually (\<lambda>i. X (r i) \<in> from_nat_into A n) sequentially"
  3563         unfolding tendsto_def by (auto simp: comp_def)
  3564       then obtain N where "\<And>i. N \<le> i \<Longrightarrow> X (r i) \<in> from_nat_into A n"
  3565         by (auto simp: eventually_sequentially)
  3566       moreover from X have "\<And>i. n \<le> r i \<Longrightarrow> X (r i) \<notin> from_nat_into A n"
  3567         by auto
  3568       moreover from `subseq r`[THEN seq_suble, of "max n N"] have "\<exists>i. n \<le> r i \<and> N \<le> i"
  3569         by (auto intro!: exI[of _ "max n N"])
  3570       ultimately show False
  3571         by auto
  3572     qed
  3573   qed
  3574 qed
  3575 
  3576 lemma compact_imp_seq_compact:
  3577   fixes U :: "'a :: first_countable_topology set"
  3578   assumes "compact U"
  3579   shows "seq_compact U"
  3580   unfolding seq_compact_def
  3581 proof safe
  3582   fix X :: "nat \<Rightarrow> 'a"
  3583   assume "\<forall>n. X n \<in> U"
  3584   then have "eventually (\<lambda>x. x \<in> U) (filtermap X sequentially)"
  3585     by (auto simp: eventually_filtermap)
  3586   moreover
  3587   have "filtermap X sequentially \<noteq> bot"
  3588     by (simp add: trivial_limit_def eventually_filtermap)
  3589   ultimately
  3590   obtain x where "x \<in> U" and x: "inf (nhds x) (filtermap X sequentially) \<noteq> bot" (is "?F \<noteq> _")
  3591     using `compact U` by (auto simp: compact_filter)
  3592 
  3593   from countable_basis_at_decseq[of x]
  3594   obtain A where A:
  3595       "\<And>i. open (A i)"
  3596       "\<And>i. x \<in> A i"
  3597       "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  3598     by blast
  3599   def s \<equiv> "\<lambda>n i. SOME j. i < j \<and> X j \<in> A (Suc n)"
  3600   {
  3601     fix n i
  3602     have "\<exists>a. i < a \<and> X a \<in> A (Suc n)"
  3603     proof (rule ccontr)
  3604       assume "\<not> (\<exists>a>i. X a \<in> A (Suc n))"
  3605       then have "\<And>a. Suc i \<le> a \<Longrightarrow> X a \<notin> A (Suc n)"
  3606         by auto
  3607       then have "eventually (\<lambda>x. x \<notin> A (Suc n)) (filtermap X sequentially)"
  3608         by (auto simp: eventually_filtermap eventually_sequentially)
  3609       moreover have "eventually (\<lambda>x. x \<in> A (Suc n)) (nhds x)"
  3610         using A(1,2)[of "Suc n"] by (auto simp: eventually_nhds)
  3611       ultimately have "eventually (\<lambda>x. False) ?F"
  3612         by (auto simp add: eventually_inf)
  3613       with x show False
  3614         by (simp add: eventually_False)
  3615     qed
  3616     then have "i < s n i" "X (s n i) \<in> A (Suc n)"
  3617       unfolding s_def by (auto intro: someI2_ex)
  3618   }
  3619   note s = this
  3620   def r \<equiv> "rec_nat (s 0 0) s"
  3621   have "subseq r"
  3622     by (auto simp: r_def s subseq_Suc_iff)
  3623   moreover
  3624   have "(\<lambda>n. X (r n)) ----> x"
  3625   proof (rule topological_tendstoI)
  3626     fix S
  3627     assume "open S" "x \<in> S"
  3628     with A(3) have "eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  3629       by auto
  3630     moreover
  3631     {
  3632       fix i
  3633       assume "Suc 0 \<le> i"
  3634       then have "X (r i) \<in> A i"
  3635         by (cases i) (simp_all add: r_def s)
  3636     }
  3637     then have "eventually (\<lambda>i. X (r i) \<in> A i) sequentially"
  3638       by (auto simp: eventually_sequentially)
  3639     ultimately show "eventually (\<lambda>i. X (r i) \<in> S) sequentially"
  3640       by eventually_elim auto
  3641   qed
  3642   ultimately show "\<exists>x \<in> U. \<exists>r. subseq r \<and> (X \<circ> r) ----> x"
  3643     using `x \<in> U` by (auto simp: convergent_def comp_def)
  3644 qed
  3645 
  3646 lemma countably_compact_imp_acc_point:
  3647   assumes "countably_compact s"
  3648     and "countable t"
  3649     and "infinite t"
  3650     and "t \<subseteq> s"
  3651   shows "\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t)"
  3652 proof (rule ccontr)
  3653   def C \<equiv> "(\<lambda>F. interior (F \<union> (- t))) ` {F. finite F \<and> F \<subseteq> t }"
  3654   note `countably_compact s`
  3655   moreover have "\<forall>t\<in>C. open t"
  3656     by (auto simp: C_def)
  3657   moreover
  3658   assume "\<not> (\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t))"
  3659   then have s: "\<And>x. x \<in> s \<Longrightarrow> \<exists>U. x\<in>U \<and> open U \<and> finite (U \<inter> t)" by metis
  3660   have "s \<subseteq> \<Union>C"
  3661     using `t \<subseteq> s`
  3662     unfolding C_def Union_image_eq
  3663     apply (safe dest!: s)
  3664     apply (rule_tac a="U \<inter> t" in UN_I)
  3665     apply (auto intro!: interiorI simp add: finite_subset)
  3666     done
  3667   moreover
  3668   from `countable t` have "countable C"
  3669     unfolding C_def by (auto intro: countable_Collect_finite_subset)
  3670   ultimately
  3671   obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> \<Union>D"
  3672     by (rule countably_compactE)
  3673   then obtain E where E: "E \<subseteq> {F. finite F \<and> F \<subseteq> t }" "finite E"
  3674     and s: "s \<subseteq> (\<Union>F\<in>E. interior (F \<union> (- t)))"
  3675     by (metis (lifting) Union_image_eq finite_subset_image C_def)
  3676   from s `t \<subseteq> s` have "t \<subseteq> \<Union>E"
  3677     using interior_subset by blast
  3678   moreover have "finite (\<Union>E)"
  3679     using E by auto
  3680   ultimately show False using `infinite t`
  3681     by (auto simp: finite_subset)
  3682 qed
  3683 
  3684 lemma countable_acc_point_imp_seq_compact:
  3685   fixes s :: "'a::first_countable_topology set"
  3686   assumes "\<forall>t. infinite t \<and> countable t \<and> t \<subseteq> s \<longrightarrow>
  3687     (\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t))"
  3688   shows "seq_compact s"
  3689 proof -
  3690   {
  3691     fix f :: "nat \<Rightarrow> 'a"
  3692     assume f: "\<forall>n. f n \<in> s"
  3693     have "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3694     proof (cases "finite (range f)")
  3695       case True
  3696       obtain l where "infinite {n. f n = f l}"
  3697         using pigeonhole_infinite[OF _ True] by auto
  3698       then obtain r where "subseq r" and fr: "\<forall>n. f (r n) = f l"
  3699         using infinite_enumerate by blast
  3700       then have "subseq r \<and> (f \<circ> r) ----> f l"
  3701         by (simp add: fr tendsto_const o_def)
  3702       with f show "\<exists>l\<in>s. \<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  3703         by auto
  3704     next
  3705       case False
  3706       with f assms have "\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> range f)"
  3707         by auto
  3708       then obtain l where "l \<in> s" "\<forall>U. l\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> range f)" ..
  3709       from this(2) have "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3710         using acc_point_range_imp_convergent_subsequence[of l f] by auto
  3711       with `l \<in> s` show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" ..
  3712     qed
  3713   }
  3714   then show ?thesis
  3715     unfolding seq_compact_def by auto
  3716 qed
  3717 
  3718 lemma seq_compact_eq_countably_compact:
  3719   fixes U :: "'a :: first_countable_topology set"
  3720   shows "seq_compact U \<longleftrightarrow> countably_compact U"
  3721   using
  3722     countable_acc_point_imp_seq_compact
  3723     countably_compact_imp_acc_point
  3724     seq_compact_imp_countably_compact
  3725   by metis
  3726 
  3727 lemma seq_compact_eq_acc_point:
  3728   fixes s :: "'a :: first_countable_topology set"
  3729   shows "seq_compact s \<longleftrightarrow>
  3730     (\<forall>t. infinite t \<and> countable t \<and> t \<subseteq> s --> (\<exists>x\<in>s. \<forall>U. x\<in>U \<and> open U \<longrightarrow> infinite (U \<inter> t)))"
  3731   using
  3732     countable_acc_point_imp_seq_compact[of s]
  3733     countably_compact_imp_acc_point[of s]
  3734     seq_compact_imp_countably_compact[of s]
  3735   by metis
  3736 
  3737 lemma seq_compact_eq_compact:
  3738   fixes U :: "'a :: second_countable_topology set"
  3739   shows "seq_compact U \<longleftrightarrow> compact U"
  3740   using seq_compact_eq_countably_compact countably_compact_eq_compact by blast
  3741 
  3742 lemma bolzano_weierstrass_imp_seq_compact:
  3743   fixes s :: "'a::{t1_space, first_countable_topology} set"
  3744   shows "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t) \<Longrightarrow> seq_compact s"
  3745   by (rule countable_acc_point_imp_seq_compact) (metis islimpt_eq_acc_point)
  3746 
  3747 subsubsection{* Total boundedness *}
  3748 
  3749 lemma cauchy_def: "Cauchy s \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m n. m \<ge> N \<and> n \<ge> N --> dist(s m)(s n) < e)"
  3750   unfolding Cauchy_def by metis
  3751 
  3752 fun helper_1 :: "('a::metric_space set) \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> 'a"
  3753 where
  3754   "helper_1 s e n = (SOME y::'a. y \<in> s \<and> (\<forall>m<n. \<not> (dist (helper_1 s e m) y < e)))"
  3755 declare helper_1.simps[simp del]
  3756 
  3757 lemma seq_compact_imp_totally_bounded:
  3758   assumes "seq_compact s"
  3759   shows "\<forall>e>0. \<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k))"
  3760 proof (rule, rule, rule ccontr)
  3761   fix e::real
  3762   assume "e > 0"
  3763   assume assm: "\<not> (\<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>((\<lambda>x. ball x e) ` k))"
  3764   def x \<equiv> "helper_1 s e"
  3765   {
  3766     fix n
  3767     have "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  3768     proof (induct n rule: nat_less_induct)
  3769       fix n
  3770       def Q \<equiv> "(\<lambda>y. y \<in> s \<and> (\<forall>m<n. \<not> dist (x m) y < e))"
  3771       assume as: "\<forall>m<n. x m \<in> s \<and> (\<forall>ma<m. \<not> dist (x ma) (x m) < e)"
  3772       have "\<not> s \<subseteq> (\<Union>x\<in>x ` {0..<n}. ball x e)"
  3773         using assm
  3774         apply simp
  3775         apply (erule_tac x="x ` {0 ..< n}" in allE)
  3776         using as
  3777         apply auto
  3778         done
  3779       then obtain z where z:"z\<in>s" "z \<notin> (\<Union>x\<in>x ` {0..<n}. ball x e)"
  3780         unfolding subset_eq by auto
  3781       have "Q (x n)"
  3782         unfolding x_def and helper_1.simps[of s e n]
  3783         apply (rule someI2[where a=z])
  3784         unfolding x_def[symmetric] and Q_def
  3785         using z
  3786         apply auto
  3787         done
  3788       then show "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  3789         unfolding Q_def by auto
  3790     qed
  3791   }
  3792   then have "\<forall>n::nat. x n \<in> s" and x:"\<forall>n. \<forall>m < n. \<not> (dist (x m) (x n) < e)"
  3793     by blast+
  3794   then obtain l r where "l\<in>s" and r:"subseq r" and "((x \<circ> r) ---> l) sequentially"
  3795     using assms(1)[unfolded seq_compact_def, THEN spec[where x=x]] by auto
  3796   from this(3) have "Cauchy (x \<circ> r)"
  3797     using LIMSEQ_imp_Cauchy by auto
  3798   then obtain N::nat where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist ((x \<circ> r) m) ((x \<circ> r) n) < e"
  3799     unfolding cauchy_def using `e>0` by auto
  3800   show False
  3801     using N[THEN spec[where x=N], THEN spec[where x="N+1"]]
  3802     using r[unfolded subseq_def, THEN spec[where x=N], THEN spec[where x="N+1"]]
  3803     using x[THEN spec[where x="r (N+1)"], THEN spec[where x="r (N)"]]
  3804     by auto
  3805 qed
  3806 
  3807 subsubsection{* Heine-Borel theorem *}
  3808 
  3809 lemma seq_compact_imp_heine_borel:
  3810   fixes s :: "'a :: metric_space set"
  3811   assumes "seq_compact s"
  3812   shows "compact s"
  3813 proof -
  3814   from seq_compact_imp_totally_bounded[OF `seq_compact s`]
  3815   obtain f where f: "\<forall>e>0. finite (f e) \<and> f e \<subseteq> s \<and> s \<subseteq> \<Union>((\<lambda>x. ball x e) ` f e)"
  3816     unfolding choice_iff' ..
  3817   def K \<equiv> "(\<lambda>(x, r). ball x r) ` ((\<Union>e \<in> \<rat> \<inter> {0 <..}. f e) \<times> \<rat>)"
  3818   have "countably_compact s"
  3819     using `seq_compact s` by (rule seq_compact_imp_countably_compact)
  3820   then show "compact s"
  3821   proof (rule countably_compact_imp_compact)
  3822     show "countable K"
  3823       unfolding K_def using f
  3824       by (auto intro: countable_finite countable_subset countable_rat
  3825                intro!: countable_image countable_SIGMA countable_UN)
  3826     show "\<forall>b\<in>K. open b" by (auto simp: K_def)
  3827   next
  3828     fix T x
  3829     assume T: "open T" "x \<in> T" and x: "x \<in> s"
  3830     from openE[OF T] obtain e where "0 < e" "ball x e \<subseteq> T"
  3831       by auto
  3832     then have "0 < e / 2" "ball x (e / 2) \<subseteq> T"
  3833       by auto
  3834     from Rats_dense_in_real[OF `0 < e / 2`] obtain r where "r \<in> \<rat>" "0 < r" "r < e / 2"
  3835       by auto
  3836     from f[rule_format, of r] `0 < r` `x \<in> s` obtain k where "k \<in> f r" "x \<in> ball k r"
  3837       unfolding Union_image_eq by auto
  3838     from `r \<in> \<rat>` `0 < r` `k \<in> f r` have "ball k r \<in> K"
  3839       by (auto simp: K_def)
  3840     then show "\<exists>b\<in>K. x \<in> b \<and> b \<inter> s \<subseteq> T"
  3841     proof (rule bexI[rotated], safe)
  3842       fix y
  3843       assume "y \<in> ball k r"
  3844       with `r < e / 2` `x \<in> ball k r` have "dist x y < e"
  3845         by (intro dist_double[where x = k and d=e]) (auto simp: dist_commute)
  3846       with `ball x e \<subseteq> T` show "y \<in> T"
  3847         by auto
  3848     next
  3849       show "x \<in> ball k r" by fact
  3850     qed
  3851   qed
  3852 qed
  3853 
  3854 lemma compact_eq_seq_compact_metric:
  3855   "compact (s :: 'a::metric_space set) \<longleftrightarrow> seq_compact s"
  3856   using compact_imp_seq_compact seq_compact_imp_heine_borel by blast
  3857 
  3858 lemma compact_def:
  3859   "compact (S :: 'a::metric_space set) \<longleftrightarrow>
  3860    (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow> (\<exists>l\<in>S. \<exists>r. subseq r \<and> (f \<circ> r) ----> l))"
  3861   unfolding compact_eq_seq_compact_metric seq_compact_def by auto
  3862 
  3863 subsubsection {* Complete the chain of compactness variants *}
  3864 
  3865 lemma compact_eq_bolzano_weierstrass:
  3866   fixes s :: "'a::metric_space set"
  3867   shows "compact s \<longleftrightarrow> (\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t))"
  3868   (is "?lhs = ?rhs")
  3869 proof
  3870   assume ?lhs
  3871   then show ?rhs
  3872     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  3873 next
  3874   assume ?rhs
  3875   then show ?lhs
  3876     unfolding compact_eq_seq_compact_metric by (rule bolzano_weierstrass_imp_seq_compact)
  3877 qed
  3878 
  3879 lemma bolzano_weierstrass_imp_bounded:
  3880   "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t) \<Longrightarrow> bounded s"
  3881   using compact_imp_bounded unfolding compact_eq_bolzano_weierstrass .
  3882 
  3883 subsection {* Metric spaces with the Heine-Borel property *}
  3884 
  3885 text {*
  3886   A metric space (or topological vector space) is said to have the
  3887   Heine-Borel property if every closed and bounded subset is compact.
  3888 *}
  3889 
  3890 class heine_borel = metric_space +
  3891   assumes bounded_imp_convergent_subsequence:
  3892     "bounded (range f) \<Longrightarrow> \<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3893 
  3894 lemma bounded_closed_imp_seq_compact:
  3895   fixes s::"'a::heine_borel set"
  3896   assumes "bounded s"
  3897     and "closed s"
  3898   shows "seq_compact s"
  3899 proof (unfold seq_compact_def, clarify)
  3900   fix f :: "nat \<Rightarrow> 'a"
  3901   assume f: "\<forall>n. f n \<in> s"
  3902   with `bounded s` have "bounded (range f)"
  3903     by (auto intro: bounded_subset)
  3904   obtain l r where r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  3905     using bounded_imp_convergent_subsequence [OF `bounded (range f)`] by auto
  3906   from f have fr: "\<forall>n. (f \<circ> r) n \<in> s"
  3907     by simp
  3908   have "l \<in> s" using `closed s` fr l
  3909     by (rule closed_sequentially)
  3910   show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  3911     using `l \<in> s` r l by blast
  3912 qed
  3913 
  3914 lemma compact_eq_bounded_closed:
  3915   fixes s :: "'a::heine_borel set"
  3916   shows "compact s \<longleftrightarrow> bounded s \<and> closed s"
  3917   (is "?lhs = ?rhs")
  3918 proof
  3919   assume ?lhs
  3920   then show ?rhs
  3921     using compact_imp_closed compact_imp_bounded
  3922     by blast
  3923 next
  3924   assume ?rhs
  3925   then show ?lhs
  3926     using bounded_closed_imp_seq_compact[of s]
  3927     unfolding compact_eq_seq_compact_metric
  3928     by auto
  3929 qed
  3930 
  3931 (* TODO: is this lemma necessary? *)
  3932 lemma bounded_increasing_convergent:
  3933   fixes s :: "nat \<Rightarrow> real"
  3934   shows "bounded {s n| n. True} \<Longrightarrow> \<forall>n. s n \<le> s (Suc n) \<Longrightarrow> \<exists>l. s ----> l"
  3935   using Bseq_mono_convergent[of s] incseq_Suc_iff[of s]
  3936   by (auto simp: image_def Bseq_eq_bounded convergent_def incseq_def)
  3937 
  3938 instance real :: heine_borel
  3939 proof
  3940   fix f :: "nat \<Rightarrow> real"
  3941   assume f: "bounded (range f)"
  3942   obtain r where r: "subseq r" "monoseq (f \<circ> r)"
  3943     unfolding comp_def by (metis seq_monosub)
  3944   then have "Bseq (f \<circ> r)"
  3945     unfolding Bseq_eq_bounded using f by (auto intro: bounded_subset)
  3946   with r show "\<exists>l r. subseq r \<and> (f \<circ> r) ----> l"
  3947     using Bseq_monoseq_convergent[of "f \<circ> r"] by (auto simp: convergent_def)
  3948 qed
  3949 
  3950 lemma compact_lemma:
  3951   fixes f :: "nat \<Rightarrow> 'a::euclidean_space"
  3952   assumes "bounded (range f)"
  3953   shows "\<forall>d\<subseteq>Basis. \<exists>l::'a. \<exists> r.
  3954     subseq r \<and> (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially)"
  3955 proof safe
  3956   fix d :: "'a set"
  3957   assume d: "d \<subseteq> Basis"
  3958   with finite_Basis have "finite d"
  3959     by (blast intro: finite_subset)
  3960   from this d show "\<exists>l::'a. \<exists>r. subseq r \<and>
  3961     (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially)"
  3962   proof (induct d)
  3963     case empty
  3964     then show ?case
  3965       unfolding subseq_def by auto
  3966   next
  3967     case (insert k d)
  3968     have k[intro]: "k \<in> Basis"
  3969       using insert by auto
  3970     have s': "bounded ((\<lambda>x. x \<bullet> k) ` range f)"
  3971       using `bounded (range f)`
  3972       by (auto intro!: bounded_linear_image bounded_linear_inner_left)
  3973     obtain l1::"'a" and r1 where r1: "subseq r1"
  3974       and lr1: "\<forall>e > 0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) \<bullet> i) (l1 \<bullet> i) < e) sequentially"
  3975       using insert(3) using insert(4) by auto
  3976     have f': "\<forall>n. f (r1 n) \<bullet> k \<in> (\<lambda>x. x \<bullet> k) ` range f"
  3977       by simp
  3978     have "bounded (range (\<lambda>i. f (r1 i) \<bullet> k))"
  3979       by (metis (lifting) bounded_subset f' image_subsetI s')
  3980     then obtain l2 r2 where r2:"subseq r2" and lr2:"((\<lambda>i. f (r1 (r2 i)) \<bullet> k) ---> l2) sequentially"
  3981       using bounded_imp_convergent_subsequence[of "\<lambda>i. f (r1 i) \<bullet> k"]
  3982       by (auto simp: o_def)
  3983     def r \<equiv> "r1 \<circ> r2"
  3984     have r:"subseq r"
  3985       using r1 and r2 unfolding r_def o_def subseq_def by auto
  3986     moreover
  3987     def l \<equiv> "(\<Sum>i\<in>Basis. (if i = k then l2 else l1\<bullet>i) *\<^sub>R i)::'a"
  3988     {
  3989       fix e::real
  3990       assume "e > 0"
  3991       from lr1 `e > 0` have N1: "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) \<bullet> i) (l1 \<bullet> i) < e) sequentially"
  3992         by blast
  3993       from lr2 `e > 0` have N2:"eventually (\<lambda>n. dist (f (r1 (r2 n)) \<bullet> k) l2 < e) sequentially"
  3994         by (rule tendstoD)
  3995       from r2 N1 have N1': "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 (r2 n)) \<bullet> i) (l1 \<bullet> i) < e) sequentially"
  3996         by (rule eventually_subseq)
  3997       have "eventually (\<lambda>n. \<forall>i\<in>(insert k d). dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially"
  3998         using N1' N2
  3999         by eventually_elim (insert insert.prems, auto simp: l_def r_def o_def)
  4000     }
  4001     ultimately show ?case by auto
  4002   qed
  4003 qed
  4004 
  4005 instance euclidean_space \<subseteq> heine_borel
  4006 proof
  4007   fix f :: "nat \<Rightarrow> 'a"
  4008   assume f: "bounded (range f)"
  4009   then obtain l::'a and r where r: "subseq r"
  4010     and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i) < e) sequentially"
  4011     using compact_lemma [OF f] by blast
  4012   {
  4013     fix e::real
  4014     assume "e > 0"
  4015     then have "e / real_of_nat DIM('a) > 0"
  4016       by (auto intro!: divide_pos_pos DIM_positive)
  4017     with l have "eventually (\<lambda>n. \<forall>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i) < e / (real_of_nat DIM('a))) sequentially"
  4018       by simp
  4019     moreover
  4020     {
  4021       fix n
  4022       assume n: "\<forall>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i) < e / (real_of_nat DIM('a))"
  4023       have "dist (f (r n)) l \<le> (\<Sum>i\<in>Basis. dist (f (r n) \<bullet> i) (l \<bullet> i))"
  4024         apply (subst euclidean_dist_l2)
  4025         using zero_le_dist
  4026         apply (rule setL2_le_setsum)
  4027         done
  4028       also have "\<dots> < (\<Sum>i\<in>(Basis::'a set). e / (real_of_nat DIM('a)))"
  4029         apply (rule setsum_strict_mono)
  4030         using n
  4031         apply auto
  4032         done
  4033       finally have "dist (f (r n)) l < e"
  4034         by auto
  4035     }
  4036     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  4037       by (rule eventually_elim1)
  4038   }
  4039   then have *: "((f \<circ> r) ---> l) sequentially"
  4040     unfolding o_def tendsto_iff by simp
  4041   with r show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  4042     by auto
  4043 qed
  4044 
  4045 lemma bounded_fst: "bounded s \<Longrightarrow> bounded (fst ` s)"
  4046   unfolding bounded_def
  4047   by (metis (erased, hide_lams) dist_fst_le image_iff order_trans)
  4048 
  4049 lemma bounded_snd: "bounded s \<Longrightarrow> bounded (snd ` s)"
  4050   unfolding bounded_def
  4051   by (metis (no_types, hide_lams) dist_snd_le image_iff order.trans)
  4052 
  4053 instance prod :: (heine_borel, heine_borel) heine_borel
  4054 proof
  4055   fix f :: "nat \<Rightarrow> 'a \<times> 'b"
  4056   assume f: "bounded (range f)"
  4057   then have "bounded (fst ` range f)"
  4058     by (rule bounded_fst)
  4059   then have s1: "bounded (range (fst \<circ> f))"
  4060     by (simp add: image_comp)
  4061   obtain l1 r1 where r1: "subseq r1" and l1: "(\<lambda>n. fst (f (r1 n))) ----> l1"
  4062     using bounded_imp_convergent_subsequence [OF s1] unfolding o_def by fast
  4063   from f have s2: "bounded (range (snd \<circ> f \<circ> r1))"
  4064     by (auto simp add: image_comp intro: bounded_snd bounded_subset)
  4065   obtain l2 r2 where r2: "subseq r2" and l2: "((\<lambda>n. snd (f (r1 (r2 n)))) ---> l2) sequentially"
  4066     using bounded_imp_convergent_subsequence [OF s2]
  4067     unfolding o_def by fast
  4068   have l1': "((\<lambda>n. fst (f (r1 (r2 n)))) ---> l1) sequentially"
  4069     using LIMSEQ_subseq_LIMSEQ [OF l1 r2] unfolding o_def .
  4070   have l: "((f \<circ> (r1 \<circ> r2)) ---> (l1, l2)) sequentially"
  4071     using tendsto_Pair [OF l1' l2] unfolding o_def by simp
  4072   have r: "subseq (r1 \<circ> r2)"
  4073     using r1 r2 unfolding subseq_def by simp
  4074   show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  4075     using l r by fast
  4076 qed
  4077 
  4078 subsubsection {* Completeness *}
  4079 
  4080 definition complete :: "'a::metric_space set \<Rightarrow> bool"
  4081   where "complete s \<longleftrightarrow> (\<forall>f. (\<forall>n. f n \<in> s) \<and> Cauchy f \<longrightarrow> (\<exists>l\<in>s. f ----> l))"
  4082 
  4083 lemma completeI:
  4084   assumes "\<And>f. \<forall>n. f n \<in> s \<Longrightarrow> Cauchy f \<Longrightarrow> \<exists>l\<in>s. f ----> l"
  4085   shows "complete s"
  4086   using assms unfolding complete_def by fast
  4087 
  4088 lemma completeE:
  4089   assumes "complete s" and "\<forall>n. f n \<in> s" and "Cauchy f"
  4090   obtains l where "l \<in> s" and "f ----> l"
  4091   using assms unfolding complete_def by fast
  4092 
  4093 lemma compact_imp_complete:
  4094   assumes "compact s"
  4095   shows "complete s"
  4096 proof -
  4097   {
  4098     fix f
  4099     assume as: "(\<forall>n::nat. f n \<in> s)" "Cauchy f"
  4100     from as(1) obtain l r where lr: "l\<in>s" "subseq r" "(f \<circ> r) ----> l"
  4101       using assms unfolding compact_def by blast
  4102 
  4103     note lr' = seq_suble [OF lr(2)]
  4104     {
  4105       fix e :: real
  4106       assume "e > 0"
  4107       from as(2) obtain N where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (f m) (f n) < e/2"
  4108         unfolding cauchy_def
  4109         using `e > 0`
  4110         apply (erule_tac x="e/2" in allE)
  4111         apply auto
  4112         done
  4113       from lr(3)[unfolded LIMSEQ_def, THEN spec[where x="e/2"]]
  4114       obtain M where M:"\<forall>n\<ge>M. dist ((f \<circ> r) n) l < e/2"
  4115         using `e > 0` by auto
  4116       {
  4117         fix n :: nat
  4118         assume n: "n \<ge> max N M"
  4119         have "dist ((f \<circ> r) n) l < e/2"
  4120           using n M by auto
  4121         moreover have "r n \<ge> N"
  4122           using lr'[of n] n by auto
  4123         then have "dist (f n) ((f \<circ> r) n) < e / 2"
  4124           using N and n by auto
  4125         ultimately have "dist (f n) l < e"
  4126           using dist_triangle_half_r[of "f (r n)" "f n" e l]
  4127           by (auto simp add: dist_commute)
  4128       }
  4129       then have "\<exists>N. \<forall>n\<ge>N. dist (f n) l < e" by blast
  4130     }
  4131     then have "\<exists>l\<in>s. (f ---> l) sequentially" using `l\<in>s`
  4132       unfolding LIMSEQ_def by auto
  4133   }
  4134   then show ?thesis unfolding complete_def by auto
  4135 qed
  4136 
  4137 lemma nat_approx_posE:
  4138   fixes e::real
  4139   assumes "0 < e"
  4140   obtains n :: nat where "1 / (Suc n) < e"
  4141 proof atomize_elim
  4142   have " 1 / real (Suc (nat (ceiling (1/e)))) < 1 / (ceiling (1/e))"
  4143     by (rule divide_strict_left_mono) (auto intro!: mult_pos_pos simp: `0 < e`)
  4144   also have "1 / (ceiling (1/e)) \<le> 1 / (1/e)"
  4145     by (rule divide_left_mono) (auto intro!: divide_pos_pos simp: `0 < e`)
  4146   also have "\<dots> = e" by simp
  4147   finally show  "\<exists>n. 1 / real (Suc n) < e" ..
  4148 qed
  4149 
  4150 lemma compact_eq_totally_bounded:
  4151   "compact s \<longleftrightarrow> complete s \<and> (\<forall>e>0. \<exists>k. finite k \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k)))"
  4152     (is "_ \<longleftrightarrow> ?rhs")
  4153 proof
  4154   assume assms: "?rhs"
  4155   then obtain k where k: "\<And>e. 0 < e \<Longrightarrow> finite (k e)" "\<And>e. 0 < e \<Longrightarrow> s \<subseteq> (\<Union>x\<in>k e. ball x e)"
  4156     by (auto simp: choice_iff')
  4157 
  4158   show "compact s"
  4159   proof cases
  4160     assume "s = {}"
  4161     then show "compact s" by (simp add: compact_def)
  4162   next
  4163     assume "s \<noteq> {}"
  4164     show ?thesis
  4165       unfolding compact_def
  4166     proof safe
  4167       fix f :: "nat \<Rightarrow> 'a"
  4168       assume f: "\<forall>n. f n \<in> s"
  4169 
  4170       def e \<equiv> "\<lambda>n. 1 / (2 * Suc n)"
  4171       then have [simp]: "\<And>n. 0 < e n" by auto
  4172       def B \<equiv> "\<lambda>n U. SOME b. infinite {n. f n \<in> b} \<and> (\<exists>x. b \<subseteq> ball x (e n) \<inter> U)"
  4173       {
  4174         fix n U
  4175         assume "infinite {n. f n \<in> U}"
  4176         then have "\<exists>b\<in>k (e n). infinite {i\<in>{n. f n \<in> U}. f i \<in> ball b (e n)}"
  4177           using k f by (intro pigeonhole_infinite_rel) (auto simp: subset_eq)
  4178         then obtain a where
  4179           "a \<in> k (e n)"
  4180           "infinite {i \<in> {n. f n \<in> U}. f i \<in> ball a (e n)}" ..
  4181         then have "\<exists>b. infinite {i. f i \<in> b} \<and> (\<exists>x. b \<subseteq> ball x (e n) \<inter> U)"
  4182           by (intro exI[of _ "ball a (e n) \<inter> U"] exI[of _ a]) (auto simp: ac_simps)
  4183         from someI_ex[OF this]
  4184         have "infinite {i. f i \<in> B n U}" "\<exists>x. B n U \<subseteq> ball x (e n) \<inter> U"
  4185           unfolding B_def by auto
  4186       }
  4187       note B = this
  4188 
  4189       def F \<equiv> "rec_nat (B 0 UNIV) B"
  4190       {
  4191         fix n
  4192         have "infinite {i. f i \<in> F n}"
  4193           by (induct n) (auto simp: F_def B)
  4194       }
  4195       then have F: "\<And>n. \<exists>x. F (Suc n) \<subseteq> ball x (e n) \<inter> F n"
  4196         using B by (simp add: F_def)
  4197       then have F_dec: "\<And>m n. m \<le> n \<Longrightarrow> F n \<subseteq> F m"
  4198         using decseq_SucI[of F] by (auto simp: decseq_def)
  4199 
  4200       obtain sel where sel: "\<And>k i. i < sel k i" "\<And>k i. f (sel k i) \<in> F k"
  4201       proof (atomize_elim, unfold all_conj_distrib[symmetric], intro choice allI)
  4202         fix k i
  4203         have "infinite ({n. f n \<in> F k} - {.. i})"
  4204           using `infinite {n. f n \<in> F k}` by auto
  4205         from infinite_imp_nonempty[OF this]
  4206         show "\<exists>x>i. f x \<in> F k"
  4207           by (simp add: set_eq_iff not_le conj_commute)
  4208       qed
  4209 
  4210       def t \<equiv> "rec_nat (sel 0 0) (\<lambda>n i. sel (Suc n) i)"
  4211       have "subseq t"
  4212         unfolding subseq_Suc_iff by (simp add: t_def sel)
  4213       moreover have "\<forall>i. (f \<circ> t) i \<in> s"
  4214         using f by auto
  4215       moreover
  4216       {
  4217         fix n
  4218         have "(f \<circ> t) n \<in> F n"
  4219           by (cases n) (simp_all add: t_def sel)
  4220       }
  4221       note t = this
  4222 
  4223       have "Cauchy (f \<circ> t)"
  4224       proof (safe intro!: metric_CauchyI exI elim!: nat_approx_posE)
  4225         fix r :: real and N n m
  4226         assume "1 / Suc N < r" "Suc N \<le> n" "Suc N \<le> m"
  4227         then have "(f \<circ> t) n \<in> F (Suc N)" "(f \<circ> t) m \<in> F (Suc N)" "2 * e N < r"
  4228           using F_dec t by (auto simp: e_def field_simps real_of_nat_Suc)
  4229         with F[of N] obtain x where "dist x ((f \<circ> t) n) < e N" "dist x ((f \<circ> t) m) < e N"
  4230           by (auto simp: subset_eq)
  4231         with dist_triangle[of "(f \<circ> t) m" "(f \<circ> t) n" x] `2 * e N < r`
  4232         show "dist ((f \<circ> t) m) ((f \<circ> t) n) < r"
  4233           by (simp add: dist_commute)
  4234       qed
  4235 
  4236       ultimately show "\<exists>l\<in>s. \<exists>r. subseq r \<and> (f \<circ> r) ----> l"
  4237         using assms unfolding complete_def by blast
  4238     qed
  4239   qed
  4240 qed (metis compact_imp_complete compact_imp_seq_compact seq_compact_imp_totally_bounded)
  4241 
  4242 lemma cauchy: "Cauchy s \<longleftrightarrow> (\<forall>e>0.\<exists> N::nat. \<forall>n\<ge>N. dist(s n)(s N) < e)" (is "?lhs = ?rhs")
  4243 proof -
  4244   {
  4245     assume ?rhs
  4246     {
  4247       fix e::real
  4248       assume "e>0"
  4249       with `?rhs` obtain N where N:"\<forall>n\<ge>N. dist (s n) (s N) < e/2"
  4250         by (erule_tac x="e/2" in allE) auto
  4251       {
  4252         fix n m
  4253         assume nm:"N \<le> m \<and> N \<le> n"
  4254         then have "dist (s m) (s n) < e" using N
  4255           using dist_triangle_half_l[of "s m" "s N" "e" "s n"]
  4256           by blast
  4257       }
  4258       then have "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"
  4259         by blast
  4260     }
  4261     then have ?lhs
  4262       unfolding cauchy_def
  4263       by blast
  4264   }
  4265   then show ?thesis
  4266     unfolding cauchy_def
  4267     using dist_triangle_half_l
  4268     by blast
  4269 qed
  4270 
  4271 lemma cauchy_imp_bounded:
  4272   assumes "Cauchy s"
  4273   shows "bounded (range s)"
  4274 proof -
  4275   from assms obtain N :: nat where "\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < 1"
  4276     unfolding cauchy_def
  4277     apply (erule_tac x= 1 in allE)
  4278     apply auto
  4279     done
  4280   then have N:"\<forall>n. N \<le> n \<longrightarrow> dist (s N) (s n) < 1" by auto
  4281   moreover
  4282   have "bounded (s ` {0..N})"
  4283     using finite_imp_bounded[of "s ` {1..N}"] by auto
  4284   then obtain a where a:"\<forall>x\<in>s ` {0..N}. dist (s N) x \<le> a"
  4285     unfolding bounded_any_center [where a="s N"] by auto
  4286   ultimately show "?thesis"
  4287     unfolding bounded_any_center [where a="s N"]
  4288     apply (rule_tac x="max a 1" in exI)
  4289     apply auto
  4290     apply (erule_tac x=y in allE)
  4291     apply (erule_tac x=y in ballE)
  4292     apply auto
  4293     done
  4294 qed
  4295 
  4296 instance heine_borel < complete_space
  4297 proof
  4298   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  4299   then have "bounded (range f)"
  4300     by (rule cauchy_imp_bounded)
  4301   then have "compact (closure (range f))"
  4302     unfolding compact_eq_bounded_closed by auto
  4303   then have "complete (closure (range f))"
  4304     by (rule compact_imp_complete)
  4305   moreover have "\<forall>n. f n \<in> closure (range f)"
  4306     using closure_subset [of "range f"] by auto
  4307   ultimately have "\<exists>l\<in>closure (range f). (f ---> l) sequentially"
  4308     using `Cauchy f` unfolding complete_def by auto
  4309   then show "convergent f"
  4310     unfolding convergent_def by auto
  4311 qed
  4312 
  4313 instance euclidean_space \<subseteq> banach ..
  4314 
  4315 lemma complete_UNIV: "complete (UNIV :: ('a::complete_space) set)"
  4316 proof (rule completeI)
  4317   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  4318   then have "convergent f" by (rule Cauchy_convergent)
  4319   then show "\<exists>l\<in>UNIV. f ----> l" unfolding convergent_def by simp
  4320 qed
  4321 
  4322 lemma complete_imp_closed:
  4323   assumes "complete s"
  4324   shows "closed s"
  4325 proof (unfold closed_sequential_limits, clarify)
  4326   fix f x assume "\<forall>n. f n \<in> s" and "f ----> x"
  4327   from `f ----> x` have "Cauchy f"
  4328     by (rule LIMSEQ_imp_Cauchy)
  4329   with `complete s` and `\<forall>n. f n \<in> s` obtain l where "l \<in> s" and "f ----> l"
  4330     by (rule completeE)
  4331   from `f ----> x` and `f ----> l` have "x = l"
  4332     by (rule LIMSEQ_unique)
  4333   with `l \<in> s` show "x \<in> s"
  4334     by simp
  4335 qed
  4336 
  4337 lemma complete_inter_closed:
  4338   assumes "complete s" and "closed t"
  4339   shows "complete (s \<inter> t)"
  4340 proof (rule completeI)
  4341   fix f assume "\<forall>n. f n \<in> s \<inter> t" and "Cauchy f"
  4342   then have "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t"
  4343     by simp_all
  4344   from `complete s` obtain l where "l \<in> s" and "f ----> l"
  4345     using `\<forall>n. f n \<in> s` and `Cauchy f` by (rule completeE)
  4346   from `closed t` and `\<forall>n. f n \<in> t` and `f ----> l` have "l \<in> t"
  4347     by (rule closed_sequentially)
  4348   with `l \<in> s` and `f ----> l` show "\<exists>l\<in>s \<inter> t. f ----> l"
  4349     by fast
  4350 qed
  4351 
  4352 lemma complete_closed_subset:
  4353   assumes "closed s" and "s \<subseteq> t" and "complete t"
  4354   shows "complete s"
  4355   using assms complete_inter_closed [of t s] by (simp add: Int_absorb1)
  4356 
  4357 lemma complete_eq_closed:
  4358   fixes s :: "('a::complete_space) set"
  4359   shows "complete s \<longleftrightarrow> closed s"
  4360 proof
  4361   assume "closed s" then show "complete s"
  4362     using subset_UNIV complete_UNIV by (rule complete_closed_subset)
  4363 next
  4364   assume "complete s" then show "closed s"
  4365     by (rule complete_imp_closed)
  4366 qed
  4367 
  4368 lemma convergent_eq_cauchy:
  4369   fixes s :: "nat \<Rightarrow> 'a::complete_space"
  4370   shows "(\<exists>l. (s ---> l) sequentially) \<longleftrightarrow> Cauchy s"
  4371   unfolding Cauchy_convergent_iff convergent_def ..
  4372 
  4373 lemma convergent_imp_bounded:
  4374   fixes s :: "nat \<Rightarrow> 'a::metric_space"
  4375   shows "(s ---> l) sequentially \<Longrightarrow> bounded (range s)"
  4376   by (intro cauchy_imp_bounded LIMSEQ_imp_Cauchy)
  4377 
  4378 lemma compact_cball[simp]:
  4379   fixes x :: "'a::heine_borel"
  4380   shows "compact (cball x e)"
  4381   using compact_eq_bounded_closed bounded_cball closed_cball
  4382   by blast
  4383 
  4384 lemma compact_frontier_bounded[intro]:
  4385   fixes s :: "'a::heine_borel set"
  4386   shows "bounded s \<Longrightarrow> compact (frontier s)"
  4387   unfolding frontier_def
  4388   using compact_eq_bounded_closed
  4389   by blast
  4390 
  4391 lemma compact_frontier[intro]:
  4392   fixes s :: "'a::heine_borel set"
  4393   shows "compact s \<Longrightarrow> compact (frontier s)"
  4394   using compact_eq_bounded_closed compact_frontier_bounded
  4395   by blast
  4396 
  4397 lemma frontier_subset_compact:
  4398   fixes s :: "'a::heine_borel set"
  4399   shows "compact s \<Longrightarrow> frontier s \<subseteq> s"
  4400   using frontier_subset_closed compact_eq_bounded_closed
  4401   by blast
  4402 
  4403 subsection {* Bounded closed nest property (proof does not use Heine-Borel) *}
  4404 
  4405 lemma bounded_closed_nest:
  4406   fixes s :: "nat \<Rightarrow> ('a::heine_borel) set"
  4407   assumes "\<forall>n. closed (s n)"
  4408     and "\<forall>n. s n \<noteq> {}"
  4409     and "\<forall>m n. m \<le> n \<longrightarrow> s n \<subseteq> s m"
  4410     and "bounded (s 0)"
  4411   shows "\<exists>a. \<forall>n. a \<in> s n"
  4412 proof -
  4413   from assms(2) obtain x where x: "\<forall>n. x n \<in> s n"
  4414     using choice[of "\<lambda>n x. x \<in> s n"] by auto
  4415   from assms(4,1) have "seq_compact (s 0)"
  4416     by (simp add: bounded_closed_imp_seq_compact)
  4417   then obtain l r where lr: "l \<in> s 0" "subseq r" "(x \<circ> r) ----> l"
  4418     using x and assms(3) unfolding seq_compact_def by blast
  4419   have "\<forall>n. l \<in> s n"
  4420   proof
  4421     fix n :: nat
  4422     have "closed (s n)"
  4423       using assms(1) by simp
  4424     moreover have "\<forall>i. (x \<circ> r) i \<in> s i"
  4425       using x and assms(3) and lr(2) [THEN seq_suble] by auto
  4426     then have "\<forall>i. (x \<circ> r) (i + n) \<in> s n"
  4427       using assms(3) by (fast intro!: le_add2)
  4428     moreover have "(\<lambda>i. (x \<circ> r) (i + n)) ----> l"
  4429       using lr(3) by (rule LIMSEQ_ignore_initial_segment)
  4430     ultimately show "l \<in> s n"
  4431       by (rule closed_sequentially)
  4432   qed
  4433   then show ?thesis ..
  4434 qed
  4435 
  4436 text {* Decreasing case does not even need compactness, just completeness. *}
  4437 
  4438 lemma decreasing_closed_nest:
  4439   fixes s :: "nat \<Rightarrow> ('a::complete_space) set"
  4440   assumes
  4441     "\<forall>n. closed (s n)"
  4442     "\<forall>n. s n \<noteq> {}"
  4443     "\<forall>m n. m \<le> n \<longrightarrow> s n \<subseteq> s m"
  4444     "\<forall>e>0. \<exists>n. \<forall>x\<in>s n. \<forall>y\<in>s n. dist x y < e"
  4445   shows "\<exists>a. \<forall>n. a \<in> s n"
  4446 proof -
  4447   have "\<forall>n. \<exists>x. x \<in> s n"
  4448     using assms(2) by auto
  4449   then have "\<exists>t. \<forall>n. t n \<in> s n"
  4450     using choice[of "\<lambda>n x. x \<in> s n"] by auto
  4451   then obtain t where t: "\<forall>n. t n \<in> s n" by auto
  4452   {
  4453     fix e :: real
  4454     assume "e > 0"
  4455     then obtain N where N:"\<forall>x\<in>s N. \<forall>y\<in>s N. dist x y < e"
  4456       using assms(4) by auto
  4457     {
  4458       fix m n :: nat
  4459       assume "N \<le> m \<and> N \<le> n"
  4460       then have "t m \<in> s N" "t n \<in> s N"
  4461         using assms(3) t unfolding  subset_eq t by blast+
  4462       then have "dist (t m) (t n) < e"
  4463         using N by auto
  4464     }
  4465     then have "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (t m) (t n) < e"
  4466       by auto
  4467   }
  4468   then have "Cauchy t"
  4469     unfolding cauchy_def by auto
  4470   then obtain l where l:"(t ---> l) sequentially"
  4471     using complete_UNIV unfolding complete_def by auto
  4472   {
  4473     fix n :: nat
  4474     {
  4475       fix e :: real
  4476       assume "e > 0"
  4477       then obtain N :: nat where N: "\<forall>n\<ge>N. dist (t n) l < e"
  4478         using l[unfolded LIMSEQ_def] by auto
  4479       have "t (max n N) \<in> s n"
  4480         using assms(3)
  4481         unfolding subset_eq
  4482         apply (erule_tac x=n in allE)
  4483         apply (erule_tac x="max n N" in allE)
  4484         using t
  4485         apply auto
  4486         done
  4487       then have "\<exists>y\<in>s n. dist y l < e"
  4488         apply (rule_tac x="t (max n N)" in bexI)
  4489         using N
  4490         apply auto
  4491         done
  4492     }
  4493     then have "l \<in> s n"
  4494       using closed_approachable[of "s n" l] assms(1) by auto
  4495   }
  4496   then show ?thesis by auto
  4497 qed
  4498 
  4499 text {* Strengthen it to the intersection actually being a singleton. *}
  4500 
  4501 lemma decreasing_closed_nest_sing:
  4502   fixes s :: "nat \<Rightarrow> 'a::complete_space set"
  4503   assumes
  4504     "\<forall>n. closed(s n)"
  4505     "\<forall>n. s n \<noteq> {}"
  4506     "\<forall>m n. m \<le> n \<longrightarrow> s n \<subseteq> s m"
  4507     "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y\<in>(s n). dist x y < e"
  4508   shows "\<exists>a. \<Inter>(range s) = {a}"
  4509 proof -
  4510   obtain a where a: "\<forall>n. a \<in> s n"
  4511     using decreasing_closed_nest[of s] using assms by auto
  4512   {
  4513     fix b
  4514     assume b: "b \<in> \<Inter>(range s)"
  4515     {
  4516       fix e :: real
  4517       assume "e > 0"
  4518       then have "dist a b < e"
  4519         using assms(4) and b and a by blast
  4520     }
  4521     then have "dist a b = 0"
  4522       by (metis dist_eq_0_iff dist_nz less_le)
  4523   }
  4524   with a have "\<Inter>(range s) = {a}"
  4525     unfolding image_def by auto
  4526   then show ?thesis ..
  4527 qed
  4528 
  4529 text{* Cauchy-type criteria for uniform convergence. *}
  4530 
  4531 lemma uniformly_convergent_eq_cauchy:
  4532   fixes s::"nat \<Rightarrow> 'b \<Rightarrow> 'a::complete_space"
  4533   shows
  4534     "(\<exists>l. \<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e) \<longleftrightarrow>
  4535       (\<forall>e>0. \<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  \<longrightarrow> dist (s m x) (s n x) < e)"
  4536   (is "?lhs = ?rhs")
  4537 proof
  4538   assume ?lhs
  4539   then obtain l where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e"
  4540     by auto
  4541   {
  4542     fix e :: real
  4543     assume "e > 0"
  4544     then obtain N :: nat where N: "\<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e / 2"
  4545       using l[THEN spec[where x="e/2"]] by auto
  4546     {
  4547       fix n m :: nat and x :: "'b"
  4548       assume "N \<le> m \<and> N \<le> n \<and> P x"
  4549       then have "dist (s m x) (s n x) < e"
  4550         using N[THEN spec[where x=m], THEN spec[where x=x]]
  4551         using N[THEN spec[where x=n], THEN spec[where x=x]]
  4552         using dist_triangle_half_l[of "s m x" "l x" e "s n x"] by auto
  4553     }
  4554     then have "\<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e"  by auto
  4555   }
  4556   then show ?rhs by auto
  4557 next
  4558   assume ?rhs
  4559   then have "\<forall>x. P x \<longrightarrow> Cauchy (\<lambda>n. s n x)"
  4560     unfolding cauchy_def
  4561     apply auto
  4562     apply (erule_tac x=e in allE)
  4563     apply auto
  4564     done
  4565   then obtain l where l: "\<forall>x. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l x) sequentially"
  4566     unfolding convergent_eq_cauchy[symmetric]
  4567     using choice[of "\<lambda>x l. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l) sequentially"]
  4568     by auto
  4569   {
  4570     fix e :: real
  4571     assume "e > 0"
  4572     then obtain N where N:"\<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x \<longrightarrow> dist (s m x) (s n x) < e/2"
  4573       using `?rhs`[THEN spec[where x="e/2"]] by auto
  4574     {
  4575       fix x
  4576       assume "P x"
  4577       then obtain M where M:"\<forall>n\<ge>M. dist (s n x) (l x) < e/2"
  4578         using l[THEN spec[where x=x], unfolded LIMSEQ_def] and `e > 0`
  4579         by (auto elim!: allE[where x="e/2"])
  4580       fix n :: nat
  4581       assume "n \<ge> N"
  4582       then have "dist(s n x)(l x) < e"
  4583         using `P x`and N[THEN spec[where x=n], THEN spec[where x="N+M"], THEN spec[where x=x]]
  4584         using M[THEN spec[where x="N+M"]] and dist_triangle_half_l[of "s n x" "s (N+M) x" e "l x"]
  4585         by (auto simp add: dist_commute)
  4586     }
  4587     then have "\<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e"
  4588       by auto
  4589   }
  4590   then show ?lhs by auto
  4591 qed
  4592 
  4593 lemma uniformly_cauchy_imp_uniformly_convergent:
  4594   fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b::complete_space"
  4595   assumes "\<forall>e>0.\<exists>N. \<forall>m (n::nat) x. N \<le> m \<and> N \<le> n \<and> P x --> dist(s m x)(s n x) < e"
  4596     and "\<forall>x. P x --> (\<forall>e>0. \<exists>N. \<forall>n. N \<le> n \<longrightarrow> dist(s n x)(l x) < e)"
  4597   shows "\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e"
  4598 proof -
  4599   obtain l' where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l' x) < e"
  4600     using assms(1) unfolding uniformly_convergent_eq_cauchy[symmetric] by auto
  4601   moreover
  4602   {
  4603     fix x
  4604     assume "P x"
  4605     then have "l x = l' x"
  4606       using tendsto_unique[OF trivial_limit_sequentially, of "\<lambda>n. s n x" "l x" "l' x"]
  4607       using l and assms(2) unfolding LIMSEQ_def by blast
  4608   }
  4609   ultimately show ?thesis by auto
  4610 qed
  4611 
  4612 
  4613 subsection {* Continuity *}
  4614 
  4615 text{* Derive the epsilon-delta forms, which we often use as "definitions" *}
  4616 
  4617 lemma continuous_within_eps_delta:
  4618   "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'\<in> s.  dist x' x < d --> dist (f x') (f x) < e)"
  4619   unfolding continuous_within and Lim_within
  4620   apply auto
  4621   apply (metis dist_nz dist_self)
  4622   apply blast
  4623   done
  4624 
  4625 lemma continuous_at_eps_delta:
  4626   "continuous (at x) f \<longleftrightarrow> (\<forall>e > 0. \<exists>d > 0. \<forall>x'. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  4627   using continuous_within_eps_delta [of x UNIV f] by simp
  4628 
  4629 text{* Versions in terms of open balls. *}
  4630 
  4631 lemma continuous_within_ball:
  4632   "continuous (at x within s) f \<longleftrightarrow>
  4633     (\<forall>e > 0. \<exists>d > 0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e)"
  4634   (is "?lhs = ?rhs")
  4635 proof
  4636   assume ?lhs
  4637   {
  4638     fix e :: real
  4639     assume "e > 0"
  4640     then obtain d where d: "d>0" "\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < e"
  4641       using `?lhs`[unfolded continuous_within Lim_within] by auto
  4642     {
  4643       fix y
  4644       assume "y \<in> f ` (ball x d \<inter> s)"
  4645       then have "y \<in> ball (f x) e"
  4646         using d(2)
  4647         unfolding dist_nz[symmetric]
  4648         apply (auto simp add: dist_commute)
  4649         apply (erule_tac x=xa in ballE)
  4650         apply auto
  4651         using `e > 0`
  4652         apply auto
  4653         done
  4654     }
  4655     then have "\<exists>d>0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e"
  4656       using `d > 0`
  4657       unfolding subset_eq ball_def by (auto simp add: dist_commute)
  4658   }
  4659   then show ?rhs by auto
  4660 next
  4661   assume ?rhs
  4662   then show ?lhs
  4663     unfolding continuous_within Lim_within ball_def subset_eq
  4664     apply (auto simp add: dist_commute)
  4665     apply (erule_tac x=e in allE)
  4666     apply auto
  4667     done
  4668 qed
  4669 
  4670 lemma continuous_at_ball:
  4671   "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. f ` (ball x d) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  4672 proof
  4673   assume ?lhs
  4674   then show ?rhs
  4675     unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  4676     apply auto
  4677     apply (erule_tac x=e in allE)
  4678     apply auto
  4679     apply (rule_tac x=d in exI)
  4680     apply auto
  4681     apply (erule_tac x=xa in allE)
  4682     apply (auto simp add: dist_commute dist_nz)
  4683     unfolding dist_nz[symmetric]
  4684     apply auto
  4685     done
  4686 next
  4687   assume ?rhs
  4688   then show ?lhs
  4689     unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  4690     apply auto
  4691     apply (erule_tac x=e in allE)
  4692     apply auto
  4693     apply (rule_tac x=d in exI)
  4694     apply auto
  4695     apply (erule_tac x="f xa" in allE)
  4696     apply (auto simp add: dist_commute dist_nz)
  4697     done
  4698 qed
  4699 
  4700 text{* Define setwise continuity in terms of limits within the set. *}
  4701 
  4702 lemma continuous_on_iff:
  4703   "continuous_on s f \<longleftrightarrow>
  4704     (\<forall>x\<in>s. \<forall>e>0. \<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  4705   unfolding continuous_on_def Lim_within
  4706   by (metis dist_pos_lt dist_self)
  4707 
  4708 definition uniformly_continuous_on :: "'a set \<Rightarrow> ('a::metric_space \<Rightarrow> 'b::metric_space) \<Rightarrow> bool"
  4709   where "uniformly_continuous_on s f \<longleftrightarrow>
  4710     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  4711 
  4712 text{* Some simple consequential lemmas. *}
  4713 
  4714 lemma uniformly_continuous_imp_continuous:
  4715   "uniformly_continuous_on s f \<Longrightarrow> continuous_on s f"
  4716   unfolding uniformly_continuous_on_def continuous_on_iff by blast
  4717 
  4718 lemma continuous_at_imp_continuous_within:
  4719   "continuous (at x) f \<Longrightarrow> continuous (at x within s) f"
  4720   unfolding continuous_within continuous_at using Lim_at_within by auto
  4721 
  4722 lemma Lim_trivial_limit: "trivial_limit net \<Longrightarrow> (f ---> l) net"
  4723   by simp
  4724 
  4725 lemmas continuous_on = continuous_on_def -- "legacy theorem name"
  4726 
  4727 lemma continuous_within_subset:
  4728   "continuous (at x within s) f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous (at x within t) f"
  4729   unfolding continuous_within by(metis tendsto_within_subset)
  4730 
  4731 lemma continuous_on_interior:
  4732   "continuous_on s f \<Longrightarrow> x \<in> interior s \<Longrightarrow> continuous (at x) f"
  4733   by (metis continuous_on_eq_continuous_at continuous_on_subset interiorE)
  4734 
  4735 lemma continuous_on_eq:
  4736   "(\<forall>x \<in> s. f x = g x) \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on s g"
  4737   unfolding continuous_on_def tendsto_def eventually_at_topological
  4738   by simp
  4739 
  4740 text {* Characterization of various kinds of continuity in terms of sequences. *}
  4741 
  4742 lemma continuous_within_sequentially:
  4743   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4744   shows "continuous (at a within s) f \<longleftrightarrow>
  4745     (\<forall>x. (\<forall>n::nat. x n \<in> s) \<and> (x ---> a) sequentially
  4746          \<longrightarrow> ((f \<circ> x) ---> f a) sequentially)"
  4747   (is "?lhs = ?rhs")
  4748 proof
  4749   assume ?lhs
  4750   {
  4751     fix x :: "nat \<Rightarrow> 'a"
  4752     assume x: "\<forall>n. x n \<in> s" "\<forall>e>0. eventually (\<lambda>n. dist (x n) a < e) sequentially"
  4753     fix T :: "'b set"
  4754     assume "open T" and "f a \<in> T"
  4755     with `?lhs` obtain d where "d>0" and d:"\<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> f x \<in> T"
  4756       unfolding continuous_within tendsto_def eventually_at by (auto simp: dist_nz)
  4757     have "eventually (\<lambda>n. dist (x n) a < d) sequentially"
  4758       using x(2) `d>0` by simp
  4759     then have "eventually (\<lambda>n. (f \<circ> x) n \<in> T) sequentially"
  4760     proof eventually_elim
  4761       case (elim n)
  4762       then show ?case
  4763         using d x(1) `f a \<in> T` unfolding dist_nz[symmetric] by auto
  4764     qed
  4765   }
  4766   then show ?rhs
  4767     unfolding tendsto_iff tendsto_def by simp
  4768 next
  4769   assume ?rhs
  4770   then show ?lhs
  4771     unfolding continuous_within tendsto_def [where l="f a"]
  4772     by (simp add: sequentially_imp_eventually_within)
  4773 qed
  4774 
  4775 lemma continuous_at_sequentially:
  4776   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4777   shows "continuous (at a) f \<longleftrightarrow>
  4778     (\<forall>x. (x ---> a) sequentially --> ((f \<circ> x) ---> f a) sequentially)"
  4779   using continuous_within_sequentially[of a UNIV f] by simp
  4780 
  4781 lemma continuous_on_sequentially:
  4782   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4783   shows "continuous_on s f \<longleftrightarrow>
  4784     (\<forall>x. \<forall>a \<in> s. (\<forall>n. x(n) \<in> s) \<and> (x ---> a) sequentially
  4785       --> ((f \<circ> x) ---> f a) sequentially)"
  4786   (is "?lhs = ?rhs")
  4787 proof
  4788   assume ?rhs
  4789   then show ?lhs
  4790     using continuous_within_sequentially[of _ s f]
  4791     unfolding continuous_on_eq_continuous_within
  4792     by auto
  4793 next
  4794   assume ?lhs
  4795   then show ?rhs
  4796     unfolding continuous_on_eq_continuous_within
  4797     using continuous_within_sequentially[of _ s f]
  4798     by auto
  4799 qed
  4800 
  4801 lemma uniformly_continuous_on_sequentially:
  4802   "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  4803                     ((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially
  4804                     \<longrightarrow> ((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially)" (is "?lhs = ?rhs")
  4805 proof
  4806   assume ?lhs
  4807   {
  4808     fix x y
  4809     assume x: "\<forall>n. x n \<in> s"
  4810       and y: "\<forall>n. y n \<in> s"
  4811       and xy: "((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially"
  4812     {
  4813       fix e :: real
  4814       assume "e > 0"
  4815       then obtain d where "d > 0" and d: "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  4816         using `?lhs`[unfolded uniformly_continuous_on_def, THEN spec[where x=e]] by auto
  4817       obtain N where N: "\<forall>n\<ge>N. dist (x n) (y n) < d"
  4818         using xy[unfolded LIMSEQ_def dist_norm] and `d>0` by auto
  4819       {
  4820         fix n
  4821         assume "n\<ge>N"
  4822         then have "dist (f (x n)) (f (y n)) < e"
  4823           using N[THEN spec[where x=n]]
  4824           using d[THEN bspec[where x="x n"], THEN bspec[where x="y n"]]
  4825           using x and y
  4826           unfolding dist_commute
  4827           by simp
  4828       }
  4829       then have "\<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"
  4830         by auto
  4831     }
  4832     then have "((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially"
  4833       unfolding LIMSEQ_def and dist_real_def by auto
  4834   }
  4835   then show ?rhs by auto
  4836 next
  4837   assume ?rhs
  4838   {
  4839     assume "\<not> ?lhs"
  4840     then obtain e where "e > 0" "\<forall>d>0. \<exists>x\<in>s. \<exists>x'\<in>s. dist x' x < d \<and> \<not> dist (f x') (f x) < e"
  4841       unfolding uniformly_continuous_on_def by auto
  4842     then obtain fa where fa:
  4843       "\<forall>x. 0 < x \<longrightarrow> fst (fa x) \<in> s \<and> snd (fa x) \<in> s \<and> dist (fst (fa x)) (snd (fa x)) < x \<and> \<not> dist (f (fst (fa x))) (f (snd (fa x))) < e"
  4844       using choice[of "\<lambda>d x. d>0 \<longrightarrow> fst x \<in> s \<and> snd x \<in> s \<and> dist (snd x) (fst x) < d \<and> \<not> dist (f (snd x)) (f (fst x)) < e"]
  4845       unfolding Bex_def
  4846       by (auto simp add: dist_commute)
  4847     def x \<equiv> "\<lambda>n::nat. fst (fa (inverse (real n + 1)))"
  4848     def y \<equiv> "\<lambda>n::nat. snd (fa (inverse (real n + 1)))"
  4849     have xyn: "\<forall>n. x n \<in> s \<and> y n \<in> s"
  4850       and xy0: "\<forall>n. dist (x n) (y n) < inverse (real n + 1)"
  4851       and fxy:"\<forall>n. \<not> dist (f (x n)) (f (y n)) < e"
  4852       unfolding x_def and y_def using fa
  4853       by auto
  4854     {
  4855       fix e :: real
  4856       assume "e > 0"
  4857       then obtain N :: nat where "N \<noteq> 0" and N: "0 < inverse (real N) \<and> inverse (real N) < e"
  4858         unfolding real_arch_inv[of e] by auto
  4859       {
  4860         fix n :: nat
  4861         assume "n \<ge> N"
  4862         then have "inverse (real n + 1) < inverse (real N)"
  4863           using real_of_nat_ge_zero and `N\<noteq>0` by auto
  4864         also have "\<dots> < e" using N by auto
  4865         finally have "inverse (real n + 1) < e" by auto
  4866         then have "dist (x n) (y n) < e"
  4867           using xy0[THEN spec[where x=n]] by auto
  4868       }
  4869       then have "\<exists>N. \<forall>n\<ge>N. dist (x n) (y n) < e" by auto
  4870     }
  4871     then have "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"
  4872       using `?rhs`[THEN spec[where x=x], THEN spec[where x=y]] and xyn
  4873       unfolding LIMSEQ_def dist_real_def by auto
  4874     then have False using fxy and `e>0` by auto
  4875   }
  4876   then show ?lhs
  4877     unfolding uniformly_continuous_on_def by blast
  4878 qed
  4879 
  4880 text{* The usual transformation theorems. *}
  4881 
  4882 lemma continuous_transform_within:
  4883   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4884   assumes "0 < d"
  4885     and "x \<in> s"
  4886     and "\<forall>x' \<in> s. dist x' x < d --> f x' = g x'"
  4887     and "continuous (at x within s) f"
  4888   shows "continuous (at x within s) g"
  4889   unfolding continuous_within
  4890 proof (rule Lim_transform_within)
  4891   show "0 < d" by fact
  4892   show "\<forall>x'\<in>s. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  4893     using assms(3) by auto
  4894   have "f x = g x"
  4895     using assms(1,2,3) by auto
  4896   then show "(f ---> g x) (at x within s)"
  4897     using assms(4) unfolding continuous_within by simp
  4898 qed
  4899 
  4900 lemma continuous_transform_at:
  4901   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  4902   assumes "0 < d"
  4903     and "\<forall>x'. dist x' x < d --> f x' = g x'"
  4904     and "continuous (at x) f"
  4905   shows "continuous (at x) g"
  4906   using continuous_transform_within [of d x UNIV f g] assms by simp
  4907 
  4908 
  4909 subsubsection {* Structural rules for pointwise continuity *}
  4910 
  4911 lemmas continuous_within_id = continuous_ident
  4912 
  4913 lemmas continuous_at_id = isCont_ident
  4914 
  4915 lemma continuous_infdist[continuous_intros]:
  4916   assumes "continuous F f"
  4917   shows "continuous F (\<lambda>x. infdist (f x) A)"
  4918   using assms unfolding continuous_def by (rule tendsto_infdist)
  4919 
  4920 lemma continuous_infnorm[continuous_intros]:
  4921   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. infnorm (f x))"
  4922   unfolding continuous_def by (rule tendsto_infnorm)
  4923 
  4924 lemma continuous_inner[continuous_intros]:
  4925   assumes "continuous F f"
  4926     and "continuous F g"
  4927   shows "continuous F (\<lambda>x. inner (f x) (g x))"
  4928   using assms unfolding continuous_def by (rule tendsto_inner)
  4929 
  4930 lemmas continuous_at_inverse = isCont_inverse
  4931 
  4932 subsubsection {* Structural rules for setwise continuity *}
  4933 
  4934 lemma continuous_on_infnorm[continuous_on_intros]:
  4935   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. infnorm (f x))"
  4936   unfolding continuous_on by (fast intro: tendsto_infnorm)
  4937 
  4938 lemma continuous_on_inner[continuous_on_intros]:
  4939   fixes g :: "'a::topological_space \<Rightarrow> 'b::real_inner"
  4940   assumes "continuous_on s f"
  4941     and "continuous_on s g"
  4942   shows "continuous_on s (\<lambda>x. inner (f x) (g x))"
  4943   using bounded_bilinear_inner assms
  4944   by (rule bounded_bilinear.continuous_on)
  4945 
  4946 subsubsection {* Structural rules for uniform continuity *}
  4947 
  4948 lemma uniformly_continuous_on_id[continuous_on_intros]:
  4949   "uniformly_continuous_on s (\<lambda>x. x)"
  4950   unfolding uniformly_continuous_on_def by auto
  4951 
  4952 lemma uniformly_continuous_on_const[continuous_on_intros]:
  4953   "uniformly_continuous_on s (\<lambda>x. c)"
  4954   unfolding uniformly_continuous_on_def by simp
  4955 
  4956 lemma uniformly_continuous_on_dist[continuous_on_intros]:
  4957   fixes f g :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  4958   assumes "uniformly_continuous_on s f"
  4959     and "uniformly_continuous_on s g"
  4960   shows "uniformly_continuous_on s (\<lambda>x. dist (f x) (g x))"
  4961 proof -
  4962   {
  4963     fix a b c d :: 'b
  4964     have "\<bar>dist a b - dist c d\<bar> \<le> dist a c + dist b d"
  4965       using dist_triangle2 [of a b c] dist_triangle2 [of b c d]
  4966       using dist_triangle3 [of c d a] dist_triangle [of a d b]
  4967       by arith
  4968   } note le = this
  4969   {
  4970     fix x y
  4971     assume f: "(\<lambda>n. dist (f (x n)) (f (y n))) ----> 0"
  4972     assume g: "(\<lambda>n. dist (g (x n)) (g (y n))) ----> 0"
  4973     have "(\<lambda>n. \<bar>dist (f (x n)) (g (x n)) - dist (f (y n)) (g (y n))\<bar>) ----> 0"
  4974       by (rule Lim_transform_bound [OF _ tendsto_add_zero [OF f g]],
  4975         simp add: le)
  4976   }
  4977   then show ?thesis
  4978     using assms unfolding uniformly_continuous_on_sequentially
  4979     unfolding dist_real_def by simp
  4980 qed
  4981 
  4982 lemma uniformly_continuous_on_norm[continuous_on_intros]:
  4983   assumes "uniformly_continuous_on s f"
  4984   shows "uniformly_continuous_on s (\<lambda>x. norm (f x))"
  4985   unfolding norm_conv_dist using assms
  4986   by (intro uniformly_continuous_on_dist uniformly_continuous_on_const)
  4987 
  4988 lemma (in bounded_linear) uniformly_continuous_on[continuous_on_intros]:
  4989   assumes "uniformly_continuous_on s g"
  4990   shows "uniformly_continuous_on s (\<lambda>x. f (g x))"
  4991   using assms unfolding uniformly_continuous_on_sequentially
  4992   unfolding dist_norm tendsto_norm_zero_iff diff[symmetric]
  4993   by (auto intro: tendsto_zero)
  4994 
  4995 lemma uniformly_continuous_on_cmul[continuous_on_intros]:
  4996   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  4997   assumes "uniformly_continuous_on s f"
  4998   shows "uniformly_continuous_on s (\<lambda>x. c *\<^sub>R f(x))"
  4999   using bounded_linear_scaleR_right assms
  5000   by (rule bounded_linear.uniformly_continuous_on)
  5001 
  5002 lemma dist_minus:
  5003   fixes x y :: "'a::real_normed_vector"
  5004   shows "dist (- x) (- y) = dist x y"
  5005   unfolding dist_norm minus_diff_minus norm_minus_cancel ..
  5006 
  5007 lemma uniformly_continuous_on_minus[continuous_on_intros]:
  5008   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  5009   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. - f x)"
  5010   unfolding uniformly_continuous_on_def dist_minus .
  5011 
  5012 lemma uniformly_continuous_on_add[continuous_on_intros]:
  5013   fixes f g :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  5014   assumes "uniformly_continuous_on s f"
  5015     and "uniformly_continuous_on s g"
  5016   shows "uniformly_continuous_on s (\<lambda>x. f x + g x)"
  5017   using assms
  5018   unfolding uniformly_continuous_on_sequentially
  5019   unfolding dist_norm tendsto_norm_zero_iff add_diff_add
  5020   by (auto intro: tendsto_add_zero)
  5021 
  5022 lemma uniformly_continuous_on_diff[continuous_on_intros]:
  5023   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  5024   assumes "uniformly_continuous_on s f"
  5025     and "uniformly_continuous_on s g"
  5026   shows "uniformly_continuous_on s (\<lambda>x. f x - g x)"
  5027   using assms uniformly_continuous_on_add [of s f "- g"]
  5028     by (simp add: fun_Compl_def uniformly_continuous_on_minus)
  5029 
  5030 text{* Continuity of all kinds is preserved under composition. *}
  5031 
  5032 lemmas continuous_at_compose = isCont_o
  5033 
  5034 lemma uniformly_continuous_on_compose[continuous_on_intros]:
  5035   assumes "uniformly_continuous_on s f"  "uniformly_continuous_on (f ` s) g"
  5036   shows "uniformly_continuous_on s (g \<circ> f)"
  5037 proof -
  5038   {
  5039     fix e :: real
  5040     assume "e > 0"
  5041     then obtain d where "d > 0"
  5042       and d: "\<forall>x\<in>f ` s. \<forall>x'\<in>f ` s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  5043       using assms(2) unfolding uniformly_continuous_on_def by auto
  5044     obtain d' where "d'>0" "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d' \<longrightarrow> dist (f x') (f x) < d"
  5045       using `d > 0` using assms(1) unfolding uniformly_continuous_on_def by auto
  5046     then have "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist ((g \<circ> f) x') ((g \<circ> f) x) < e"
  5047       using `d>0` using d by auto
  5048   }
  5049   then show ?thesis
  5050     using assms unfolding uniformly_continuous_on_def by auto
  5051 qed
  5052 
  5053 text{* Continuity in terms of open preimages. *}
  5054 
  5055 lemma continuous_at_open:
  5056   "continuous (at x) f \<longleftrightarrow> (\<forall>t. open t \<and> f x \<in> t --> (\<exists>s. open s \<and> x \<in> s \<and> (\<forall>x' \<in> s. (f x') \<in> t)))"
  5057   unfolding continuous_within_topological [of x UNIV f]
  5058   unfolding imp_conjL
  5059   by (intro all_cong imp_cong ex_cong conj_cong refl) auto
  5060 
  5061 lemma continuous_imp_tendsto:
  5062   assumes "continuous (at x0) f"
  5063     and "x ----> x0"
  5064   shows "(f \<circ> x) ----> (f x0)"
  5065 proof (rule topological_tendstoI)
  5066   fix S
  5067   assume "open S" "f x0 \<in> S"
  5068   then obtain T where T_def: "open T" "x0 \<in> T" "\<forall>x\<in>T. f x \<in> S"
  5069      using assms continuous_at_open by metis
  5070   then have "eventually (\<lambda>n. x n \<in> T) sequentially"
  5071     using assms T_def by (auto simp: tendsto_def)
  5072   then show "eventually (\<lambda>n. (f \<circ> x) n \<in> S) sequentially"
  5073     using T_def by (auto elim!: eventually_elim1)
  5074 qed
  5075 
  5076 lemma continuous_on_open:
  5077   "continuous_on s f \<longleftrightarrow>
  5078     (\<forall>t. openin (subtopology euclidean (f ` s)) t \<longrightarrow>
  5079       openin (subtopology euclidean s) {x \<in> s. f x \<in> t})"
  5080   unfolding continuous_on_open_invariant openin_open Int_def vimage_def Int_commute
  5081   by (simp add: imp_ex imageI conj_commute eq_commute cong: conj_cong)
  5082 
  5083 text {* Similarly in terms of closed sets. *}
  5084 
  5085 lemma continuous_on_closed:
  5086   "continuous_on s f \<longleftrightarrow>
  5087     (\<forall>t. closedin (subtopology euclidean (f ` s)) t \<longrightarrow>
  5088       closedin (subtopology euclidean s) {x \<in> s. f x \<in> t})"
  5089   unfolding continuous_on_closed_invariant closedin_closed Int_def vimage_def Int_commute
  5090   by (simp add: imp_ex imageI conj_commute eq_commute cong: conj_cong)
  5091 
  5092 text {* Half-global and completely global cases. *}
  5093 
  5094 lemma continuous_open_in_preimage:
  5095   assumes "continuous_on s f"  "open t"
  5096   shows "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  5097 proof -
  5098   have *: "\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)"
  5099     by auto
  5100   have "openin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  5101     using openin_open_Int[of t "f ` s", OF assms(2)] unfolding openin_open by auto
  5102   then show ?thesis
  5103     using assms(1)[unfolded continuous_on_open, THEN spec[where x="t \<inter> f ` s"]]
  5104     using * by auto
  5105 qed
  5106 
  5107 lemma continuous_closed_in_preimage:
  5108   assumes "continuous_on s f" and "closed t"
  5109   shows "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  5110 proof -
  5111   have *: "\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)"
  5112     by auto
  5113   have "closedin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  5114     using closedin_closed_Int[of t "f ` s", OF assms(2)] unfolding Int_commute
  5115     by auto
  5116   then show ?thesis
  5117     using assms(1)[unfolded continuous_on_closed, THEN spec[where x="t \<inter> f ` s"]]
  5118     using * by auto
  5119 qed
  5120 
  5121 lemma continuous_open_preimage:
  5122   assumes "continuous_on s f"
  5123     and "open s"
  5124     and "open t"
  5125   shows "open {x \<in> s. f x \<in> t}"
  5126 proof-
  5127   obtain T where T: "open T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  5128     using continuous_open_in_preimage[OF assms(1,3)] unfolding openin_open by auto
  5129   then show ?thesis
  5130     using open_Int[of s T, OF assms(2)] by auto
  5131 qed
  5132 
  5133 lemma continuous_closed_preimage:
  5134   assumes "continuous_on s f"
  5135     and "closed s"
  5136     and "closed t"
  5137   shows "closed {x \<in> s. f x \<in> t}"
  5138 proof-
  5139   obtain T where "closed T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  5140     using continuous_closed_in_preimage[OF assms(1,3)]
  5141     unfolding closedin_closed by auto
  5142   then show ?thesis using closed_Int[of s T, OF assms(2)] by auto
  5143 qed
  5144 
  5145 lemma continuous_open_preimage_univ:
  5146   "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open {x. f x \<in> s}"
  5147   using continuous_open_preimage[of UNIV f s] open_UNIV continuous_at_imp_continuous_on by auto
  5148 
  5149 lemma continuous_closed_preimage_univ:
  5150   "(\<forall>x. continuous (at x) f) \<Longrightarrow> closed s \<Longrightarrow> closed {x. f x \<in> s}"
  5151   using continuous_closed_preimage[of UNIV f s] closed_UNIV continuous_at_imp_continuous_on by auto
  5152 
  5153 lemma continuous_open_vimage: "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open (f -` s)"
  5154   unfolding vimage_def by (rule continuous_open_preimage_univ)
  5155 
  5156 lemma continuous_closed_vimage: "\<forall>x. continuous (at x) f \<Longrightarrow> closed s \<Longrightarrow> closed (f -` s)"
  5157   unfolding vimage_def by (rule continuous_closed_preimage_univ)
  5158 
  5159 lemma interior_image_subset:
  5160   assumes "\<forall>x. continuous (at x) f"
  5161     and "inj f"
  5162   shows "interior (f ` s) \<subseteq> f ` (interior s)"
  5163 proof
  5164   fix x assume "x \<in> interior (f ` s)"
  5165   then obtain T where as: "open T" "x \<in> T" "T \<subseteq> f ` s" ..
  5166   then have "x \<in> f ` s" by auto
  5167   then obtain y where y: "y \<in> s" "x = f y" by auto
  5168   have "open (vimage f T)"
  5169     using assms(1) `open T` by (rule continuous_open_vimage)
  5170   moreover have "y \<in> vimage f T"
  5171     using `x = f y` `x \<in> T` by simp
  5172   moreover have "vimage f T \<subseteq> s"
  5173     using `T \<subseteq> image f s` `inj f` unfolding inj_on_def subset_eq by auto
  5174   ultimately have "y \<in> interior s" ..
  5175   with `x = f y` show "x \<in> f ` interior s" ..
  5176 qed
  5177 
  5178 text {* Equality of continuous functions on closure and related results. *}
  5179 
  5180 lemma continuous_closed_in_preimage_constant:
  5181   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5182   shows "continuous_on s f \<Longrightarrow> closedin (subtopology euclidean s) {x \<in> s. f x = a}"
  5183   using continuous_closed_in_preimage[of s f "{a}"] by auto
  5184 
  5185 lemma continuous_closed_preimage_constant:
  5186   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5187   shows "continuous_on s f \<Longrightarrow> closed s \<Longrightarrow> closed {x \<in> s. f x = a}"
  5188   using continuous_closed_preimage[of s f "{a}"] by auto
  5189 
  5190 lemma continuous_constant_on_closure:
  5191   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5192   assumes "continuous_on (closure s) f"
  5193     and "\<forall>x \<in> s. f x = a"
  5194   shows "\<forall>x \<in> (closure s). f x = a"
  5195     using continuous_closed_preimage_constant[of "closure s" f a]
  5196       assms closure_minimal[of s "{x \<in> closure s. f x = a}"] closure_subset
  5197     unfolding subset_eq
  5198     by auto
  5199 
  5200 lemma image_closure_subset:
  5201   assumes "continuous_on (closure s) f"
  5202     and "closed t"
  5203     and "(f ` s) \<subseteq> t"
  5204   shows "f ` (closure s) \<subseteq> t"
  5205 proof -
  5206   have "s \<subseteq> {x \<in> closure s. f x \<in> t}"
  5207     using assms(3) closure_subset by auto
  5208   moreover have "closed {x \<in> closure s. f x \<in> t}"
  5209     using continuous_closed_preimage[OF assms(1)] and assms(2) by auto
  5210   ultimately have "closure s = {x \<in> closure s . f x \<in> t}"
  5211     using closure_minimal[of s "{x \<in> closure s. f x \<in> t}"] by auto
  5212   then show ?thesis by auto
  5213 qed
  5214 
  5215 lemma continuous_on_closure_norm_le:
  5216   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  5217   assumes "continuous_on (closure s) f"
  5218     and "\<forall>y \<in> s. norm(f y) \<le> b"
  5219     and "x \<in> (closure s)"
  5220   shows "norm (f x) \<le> b"
  5221 proof -
  5222   have *: "f ` s \<subseteq> cball 0 b"
  5223     using assms(2)[unfolded mem_cball_0[symmetric]] by auto
  5224   show ?thesis
  5225     using image_closure_subset[OF assms(1) closed_cball[of 0 b] *] assms(3)
  5226     unfolding subset_eq
  5227     apply (erule_tac x="f x" in ballE)
  5228     apply (auto simp add: dist_norm)
  5229     done
  5230 qed
  5231 
  5232 text {* Making a continuous function avoid some value in a neighbourhood. *}
  5233 
  5234 lemma continuous_within_avoid:
  5235   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5236   assumes "continuous (at x within s) f"
  5237     and "f x \<noteq> a"
  5238   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e --> f y \<noteq> a"
  5239 proof -
  5240   obtain U where "open U" and "f x \<in> U" and "a \<notin> U"
  5241     using t1_space [OF `f x \<noteq> a`] by fast
  5242   have "(f ---> f x) (at x within s)"
  5243     using assms(1) by (simp add: continuous_within)
  5244   then have "eventually (\<lambda>y. f y \<in> U) (at x within s)"
  5245     using `open U` and `f x \<in> U`
  5246     unfolding tendsto_def by fast
  5247   then have "eventually (\<lambda>y. f y \<noteq> a) (at x within s)"
  5248     using `a \<notin> U` by (fast elim: eventually_mono [rotated])
  5249   then show ?thesis
  5250     using `f x \<noteq> a` by (auto simp: dist_commute zero_less_dist_iff eventually_at)
  5251 qed
  5252 
  5253 lemma continuous_at_avoid:
  5254   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5255   assumes "continuous (at x) f"
  5256     and "f x \<noteq> a"
  5257   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  5258   using assms continuous_within_avoid[of x UNIV f a] by simp
  5259 
  5260 lemma continuous_on_avoid:
  5261   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5262   assumes "continuous_on s f"
  5263     and "x \<in> s"
  5264     and "f x \<noteq> a"
  5265   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e \<longrightarrow> f y \<noteq> a"
  5266   using assms(1)[unfolded continuous_on_eq_continuous_within, THEN bspec[where x=x],
  5267     OF assms(2)] continuous_within_avoid[of x s f a]
  5268   using assms(3)
  5269   by auto
  5270 
  5271 lemma continuous_on_open_avoid:
  5272   fixes f :: "'a::metric_space \<Rightarrow> 'b::t1_space"
  5273   assumes "continuous_on s f"
  5274     and "open s"
  5275     and "x \<in> s"
  5276     and "f x \<noteq> a"
  5277   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  5278   using assms(1)[unfolded continuous_on_eq_continuous_at[OF assms(2)], THEN bspec[where x=x], OF assms(3)]
  5279   using continuous_at_avoid[of x f a] assms(4)
  5280   by auto
  5281 
  5282 text {* Proving a function is constant by proving open-ness of level set. *}
  5283 
  5284 lemma continuous_levelset_open_in_cases:
  5285   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5286   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  5287         openin (subtopology euclidean s) {x \<in> s. f x = a}
  5288         \<Longrightarrow> (\<forall>x \<in> s. f x \<noteq> a) \<or> (\<forall>x \<in> s. f x = a)"
  5289   unfolding connected_clopen
  5290   using continuous_closed_in_preimage_constant by auto
  5291 
  5292 lemma continuous_levelset_open_in:
  5293   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5294   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  5295         openin (subtopology euclidean s) {x \<in> s. f x = a} \<Longrightarrow>
  5296         (\<exists>x \<in> s. f x = a)  \<Longrightarrow> (\<forall>x \<in> s. f x = a)"
  5297   using continuous_levelset_open_in_cases[of s f ]
  5298   by meson
  5299 
  5300 lemma continuous_levelset_open:
  5301   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  5302   assumes "connected s"
  5303     and "continuous_on s f"
  5304     and "open {x \<in> s. f x = a}"
  5305     and "\<exists>x \<in> s.  f x = a"
  5306   shows "\<forall>x \<in> s. f x = a"
  5307   using continuous_levelset_open_in[OF assms(1,2), of a, unfolded openin_open]
  5308   using assms (3,4)
  5309   by fast
  5310 
  5311 text {* Some arithmetical combinations (more to prove). *}
  5312 
  5313 lemma open_scaling[intro]:
  5314   fixes s :: "'a::real_normed_vector set"
  5315   assumes "c \<noteq> 0"
  5316     and "open s"
  5317   shows "open((\<lambda>x. c *\<^sub>R x) ` s)"
  5318 proof -
  5319   {
  5320     fix x
  5321     assume "x \<in> s"
  5322     then obtain e where "e>0"
  5323       and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> s" using assms(2)[unfolded open_dist, THEN bspec[where x=x]]
  5324       by auto
  5325     have "e * abs c > 0"
  5326       using assms(1)[unfolded zero_less_abs_iff[symmetric]]
  5327       using mult_pos_pos[OF `e>0`]
  5328       by auto
  5329     moreover
  5330     {
  5331       fix y
  5332       assume "dist y (c *\<^sub>R x) < e * \<bar>c\<bar>"
  5333       then have "norm ((1 / c) *\<^sub>R y - x) < e"
  5334         unfolding dist_norm
  5335         using norm_scaleR[of c "(1 / c) *\<^sub>R y - x", unfolded scaleR_right_diff_distrib, unfolded scaleR_scaleR] assms(1)
  5336           assms(1)[unfolded zero_less_abs_iff[symmetric]] by (simp del:zero_less_abs_iff)
  5337       then have "y \<in> op *\<^sub>R c ` s"
  5338         using rev_image_eqI[of "(1 / c) *\<^sub>R y" s y "op *\<^sub>R c"]
  5339         using e[THEN spec[where x="(1 / c) *\<^sub>R y"]]
  5340         using assms(1)
  5341         unfolding dist_norm scaleR_scaleR
  5342         by auto
  5343     }
  5344     ultimately have "\<exists>e>0. \<forall>x'. dist x' (c *\<^sub>R x) < e \<longrightarrow> x' \<in> op *\<^sub>R c ` s"
  5345       apply (rule_tac x="e * abs c" in exI)
  5346       apply auto
  5347       done
  5348   }
  5349   then show ?thesis unfolding open_dist by auto
  5350 qed
  5351 
  5352 lemma minus_image_eq_vimage:
  5353   fixes A :: "'a::ab_group_add set"
  5354   shows "(\<lambda>x. - x) ` A = (\<lambda>x. - x) -` A"
  5355   by (auto intro!: image_eqI [where f="\<lambda>x. - x"])
  5356 
  5357 lemma open_negations:
  5358   fixes s :: "'a::real_normed_vector set"
  5359   shows "open s \<Longrightarrow> open ((\<lambda>x. - x) ` s)"
  5360   using open_scaling [of "- 1" s] by simp
  5361 
  5362 lemma open_translation:
  5363   fixes s :: "'a::real_normed_vector set"
  5364   assumes "open s"
  5365   shows "open((\<lambda>x. a + x) ` s)"
  5366 proof -
  5367   {
  5368     fix x
  5369     have "continuous (at x) (\<lambda>x. x - a)"
  5370       by (intro continuous_diff continuous_at_id continuous_const)
  5371   }
  5372   moreover have "{x. x - a \<in> s} = op + a ` s"
  5373     by force
  5374   ultimately show ?thesis using continuous_open_preimage_univ[of "\<lambda>x. x - a" s]
  5375     using assms by auto
  5376 qed
  5377 
  5378 lemma open_affinity:
  5379   fixes s :: "'a::real_normed_vector set"
  5380   assumes "open s"  "c \<noteq> 0"
  5381   shows "open ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5382 proof -
  5383   have *: "(\<lambda>x. a + c *\<^sub>R x) = (\<lambda>x. a + x) \<circ> (\<lambda>x. c *\<^sub>R x)"
  5384     unfolding o_def ..
  5385   have "op + a ` op *\<^sub>R c ` s = (op + a \<circ> op *\<^sub>R c) ` s"
  5386     by auto
  5387   then show ?thesis
  5388     using assms open_translation[of "op *\<^sub>R c ` s" a]
  5389     unfolding *
  5390     by auto
  5391 qed
  5392 
  5393 lemma interior_translation:
  5394   fixes s :: "'a::real_normed_vector set"
  5395   shows "interior ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (interior s)"
  5396 proof (rule set_eqI, rule)
  5397   fix x
  5398   assume "x \<in> interior (op + a ` s)"
  5399   then obtain e where "e > 0" and e: "ball x e \<subseteq> op + a ` s"
  5400     unfolding mem_interior by auto
  5401   then have "ball (x - a) e \<subseteq> s"
  5402     unfolding subset_eq Ball_def mem_ball dist_norm
  5403     apply auto
  5404     apply (erule_tac x="a + xa" in allE)
  5405     unfolding ab_group_add_class.diff_diff_eq[symmetric]
  5406     apply auto
  5407     done
  5408   then show "x \<in> op + a ` interior s"
  5409     unfolding image_iff
  5410     apply (rule_tac x="x - a" in bexI)
  5411     unfolding mem_interior
  5412     using `e > 0`
  5413     apply auto
  5414     done
  5415 next
  5416   fix x
  5417   assume "x \<in> op + a ` interior s"
  5418   then obtain y e where "e > 0" and e: "ball y e \<subseteq> s" and y: "x = a + y"
  5419     unfolding image_iff Bex_def mem_interior by auto
  5420   {
  5421     fix z
  5422     have *: "a + y - z = y + a - z" by auto
  5423     assume "z \<in> ball x e"
  5424     then have "z - a \<in> s"
  5425       using e[unfolded subset_eq, THEN bspec[where x="z - a"]]
  5426       unfolding mem_ball dist_norm y group_add_class.diff_diff_eq2 *
  5427       by auto
  5428     then have "z \<in> op + a ` s"
  5429       unfolding image_iff by (auto intro!: bexI[where x="z - a"])
  5430   }
  5431   then have "ball x e \<subseteq> op + a ` s"
  5432     unfolding subset_eq by auto
  5433   then show "x \<in> interior (op + a ` s)"
  5434     unfolding mem_interior using `e > 0` by auto
  5435 qed
  5436 
  5437 text {* Topological properties of linear functions. *}
  5438 
  5439 lemma linear_lim_0:
  5440   assumes "bounded_linear f"
  5441   shows "(f ---> 0) (at (0))"
  5442 proof -
  5443   interpret f: bounded_linear f by fact
  5444   have "(f ---> f 0) (at 0)"
  5445     using tendsto_ident_at by (rule f.tendsto)
  5446   then show ?thesis unfolding f.zero .
  5447 qed
  5448 
  5449 lemma linear_continuous_at:
  5450   assumes "bounded_linear f"
  5451   shows "continuous (at a) f"
  5452   unfolding continuous_at using assms
  5453   apply (rule bounded_linear.tendsto)
  5454   apply (rule tendsto_ident_at)
  5455   done
  5456 
  5457 lemma linear_continuous_within:
  5458   "bounded_linear f \<Longrightarrow> continuous (at x within s) f"
  5459   using continuous_at_imp_continuous_within[of x f s] using linear_continuous_at[of f] by auto
  5460 
  5461 lemma linear_continuous_on:
  5462   "bounded_linear f \<Longrightarrow> continuous_on s f"
  5463   using continuous_at_imp_continuous_on[of s f] using linear_continuous_at[of f] by auto
  5464 
  5465 text {* Also bilinear functions, in composition form. *}
  5466 
  5467 lemma bilinear_continuous_at_compose:
  5468   "continuous (at x) f \<Longrightarrow> continuous (at x) g \<Longrightarrow> bounded_bilinear h \<Longrightarrow>
  5469     continuous (at x) (\<lambda>x. h (f x) (g x))"
  5470   unfolding continuous_at
  5471   using Lim_bilinear[of f "f x" "(at x)" g "g x" h]
  5472   by auto
  5473 
  5474 lemma bilinear_continuous_within_compose:
  5475   "continuous (at x within s) f \<Longrightarrow> continuous (at x within s) g \<Longrightarrow> bounded_bilinear h \<Longrightarrow>
  5476     continuous (at x within s) (\<lambda>x. h (f x) (g x))"
  5477   unfolding continuous_within
  5478   using Lim_bilinear[of f "f x"]
  5479   by auto
  5480 
  5481 lemma bilinear_continuous_on_compose:
  5482   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> bounded_bilinear h \<Longrightarrow>
  5483     continuous_on s (\<lambda>x. h (f x) (g x))"
  5484   unfolding continuous_on_def
  5485   by (fast elim: bounded_bilinear.tendsto)
  5486 
  5487 text {* Preservation of compactness and connectedness under continuous function. *}
  5488 
  5489 lemma compact_eq_openin_cover:
  5490   "compact S \<longleftrightarrow>
  5491     (\<forall>C. (\<forall>c\<in>C. openin (subtopology euclidean S) c) \<and> S \<subseteq> \<Union>C \<longrightarrow>
  5492       (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  5493 proof safe
  5494   fix C
  5495   assume "compact S" and "\<forall>c\<in>C. openin (subtopology euclidean S) c" and "S \<subseteq> \<Union>C"
  5496   then have "\<forall>c\<in>{T. open T \<and> S \<inter> T \<in> C}. open c" and "S \<subseteq> \<Union>{T. open T \<and> S \<inter> T \<in> C}"
  5497     unfolding openin_open by force+
  5498   with `compact S` obtain D where "D \<subseteq> {T. open T \<and> S \<inter> T \<in> C}" and "finite D" and "S \<subseteq> \<Union>D"
  5499     by (rule compactE)
  5500   then have "image (\<lambda>T. S \<inter> T) D \<subseteq> C \<and> finite (image (\<lambda>T. S \<inter> T) D) \<and> S \<subseteq> \<Union>(image (\<lambda>T. S \<inter> T) D)"
  5501     by auto
  5502   then show "\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D" ..
  5503 next
  5504   assume 1: "\<forall>C. (\<forall>c\<in>C. openin (subtopology euclidean S) c) \<and> S \<subseteq> \<Union>C \<longrightarrow>
  5505         (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D)"
  5506   show "compact S"
  5507   proof (rule compactI)
  5508     fix C
  5509     let ?C = "image (\<lambda>T. S \<inter> T) C"
  5510     assume "\<forall>t\<in>C. open t" and "S \<subseteq> \<Union>C"
  5511     then have "(\<forall>c\<in>?C. openin (subtopology euclidean S) c) \<and> S \<subseteq> \<Union>?C"
  5512       unfolding openin_open by auto
  5513     with 1 obtain D where "D \<subseteq> ?C" and "finite D" and "S \<subseteq> \<Union>D"
  5514       by metis
  5515     let ?D = "inv_into C (\<lambda>T. S \<inter> T) ` D"
  5516     have "?D \<subseteq> C \<and> finite ?D \<and> S \<subseteq> \<Union>?D"
  5517     proof (intro conjI)
  5518       from `D \<subseteq> ?C` show "?D \<subseteq> C"
  5519         by (fast intro: inv_into_into)
  5520       from `finite D` show "finite ?D"
  5521         by (rule finite_imageI)
  5522       from `S \<subseteq> \<Union>D` show "S \<subseteq> \<Union>?D"
  5523         apply (rule subset_trans)
  5524         apply clarsimp
  5525         apply (frule subsetD [OF `D \<subseteq> ?C`, THEN f_inv_into_f])
  5526         apply (erule rev_bexI, fast)
  5527         done
  5528     qed
  5529     then show "\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D" ..
  5530   qed
  5531 qed
  5532 
  5533 lemma connected_continuous_image:
  5534   assumes "continuous_on s f"
  5535     and "connected s"
  5536   shows "connected(f ` s)"
  5537 proof -
  5538   {
  5539     fix T
  5540     assume as:
  5541       "T \<noteq> {}"
  5542       "T \<noteq> f ` s"
  5543       "openin (subtopology euclidean (f ` s)) T"
  5544       "closedin (subtopology euclidean (f ` s)) T"
  5545     have "{x \<in> s. f x \<in> T} = {} \<or> {x \<in> s. f x \<in> T} = s"
  5546       using assms(1)[unfolded continuous_on_open, THEN spec[where x=T]]
  5547       using assms(1)[unfolded continuous_on_closed, THEN spec[where x=T]]
  5548       using assms(2)[unfolded connected_clopen, THEN spec[where x="{x \<in> s. f x \<in> T}"]] as(3,4) by auto
  5549     then have False using as(1,2)
  5550       using as(4)[unfolded closedin_def topspace_euclidean_subtopology] by auto
  5551   }
  5552   then show ?thesis
  5553     unfolding connected_clopen by auto
  5554 qed
  5555 
  5556 text {* Continuity implies uniform continuity on a compact domain. *}
  5557 
  5558 lemma compact_uniformly_continuous:
  5559   assumes f: "continuous_on s f"
  5560     and s: "compact s"
  5561   shows "uniformly_continuous_on s f"
  5562   unfolding uniformly_continuous_on_def
  5563 proof (cases, safe)
  5564   fix e :: real
  5565   assume "0 < e" "s \<noteq> {}"
  5566   def [simp]: R \<equiv> "{(y, d). y \<in> s \<and> 0 < d \<and> ball y d \<inter> s \<subseteq> {x \<in> s. f x \<in> ball (f y) (e/2) } }"
  5567   let ?b = "(\<lambda>(y, d). ball y (d/2))"
  5568   have "(\<forall>r\<in>R. open (?b r))" "s \<subseteq> (\<Union>r\<in>R. ?b r)"
  5569   proof safe
  5570     fix y
  5571     assume "y \<in> s"
  5572     from continuous_open_in_preimage[OF f open_ball]
  5573     obtain T where "open T" and T: "{x \<in> s. f x \<in> ball (f y) (e/2)} = T \<inter> s"
  5574       unfolding openin_subtopology open_openin by metis
  5575     then obtain d where "ball y d \<subseteq> T" "0 < d"
  5576       using `0 < e` `y \<in> s` by (auto elim!: openE)
  5577     with T `y \<in> s` show "y \<in> (\<Union>r\<in>R. ?b r)"
  5578       by (intro UN_I[of "(y, d)"]) auto
  5579   qed auto
  5580   with s obtain D where D: "finite D" "D \<subseteq> R" "s \<subseteq> (\<Union>(y, d)\<in>D. ball y (d/2))"
  5581     by (rule compactE_image)
  5582   with `s \<noteq> {}` have [simp]: "\<And>x. x < Min (snd ` D) \<longleftrightarrow> (\<forall>(y, d)\<in>D. x < d)"
  5583     by (subst Min_gr_iff) auto
  5584   show "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  5585   proof (rule, safe)
  5586     fix x x'
  5587     assume in_s: "x' \<in> s" "x \<in> s"
  5588     with D obtain y d where x: "x \<in> ball y (d/2)" "(y, d) \<in> D"
  5589       by blast
  5590     moreover assume "dist x x' < Min (snd`D) / 2"
  5591     ultimately have "dist y x' < d"
  5592       by (intro dist_double[where x=x and d=d]) (auto simp: dist_commute)
  5593     with D x in_s show  "dist (f x) (f x') < e"
  5594       by (intro dist_double[where x="f y" and d=e]) (auto simp: dist_commute subset_eq)
  5595   qed (insert D, auto)
  5596 qed auto
  5597 
  5598 text {* A uniformly convergent limit of continuous functions is continuous. *}
  5599 
  5600 lemma continuous_uniform_limit:
  5601   fixes f :: "'a \<Rightarrow> 'b::metric_space \<Rightarrow> 'c::metric_space"
  5602   assumes "\<not> trivial_limit F"
  5603     and "eventually (\<lambda>n. continuous_on s (f n)) F"
  5604     and "\<forall>e>0. eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e) F"
  5605   shows "continuous_on s g"
  5606 proof -
  5607   {
  5608     fix x and e :: real
  5609     assume "x\<in>s" "e>0"
  5610     have "eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e / 3) F"
  5611       using `e>0` assms(3)[THEN spec[where x="e/3"]] by auto
  5612     from eventually_happens [OF eventually_conj [OF this assms(2)]]
  5613     obtain n where n:"\<forall>x\<in>s. dist (f n x) (g x) < e / 3"  "continuous_on s (f n)"
  5614       using assms(1) by blast
  5615     have "e / 3 > 0" using `e>0` by auto
  5616     then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f n x') (f n x) < e / 3"
  5617       using n(2)[unfolded continuous_on_iff, THEN bspec[where x=x], OF `x\<in>s`, THEN spec[where x="e/3"]] by blast
  5618     {
  5619       fix y
  5620       assume "y \<in> s" and "dist y x < d"
  5621       then have "dist (f n y) (f n x) < e / 3"
  5622         by (rule d [rule_format])
  5623       then have "dist (f n y) (g x) < 2 * e / 3"
  5624         using dist_triangle [of "f n y" "g x" "f n x"]
  5625         using n(1)[THEN bspec[where x=x], OF `x\<in>s`]
  5626         by auto
  5627       then have "dist (g y) (g x) < e"
  5628         using n(1)[THEN bspec[where x=y], OF `y\<in>s`]
  5629         using dist_triangle3 [of "g y" "g x" "f n y"]
  5630         by auto
  5631     }
  5632     then have "\<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  5633       using `d>0` by auto
  5634   }
  5635   then show ?thesis
  5636     unfolding continuous_on_iff by auto
  5637 qed
  5638 
  5639 
  5640 subsection {* Topological stuff lifted from and dropped to R *}
  5641 
  5642 lemma open_real:
  5643   fixes s :: "real set"
  5644   shows "open s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>e>0. \<forall>x'. abs(x' - x) < e --> x' \<in> s)"
  5645   unfolding open_dist dist_norm by simp
  5646 
  5647 lemma islimpt_approachable_real:
  5648   fixes s :: "real set"
  5649   shows "x islimpt s \<longleftrightarrow> (\<forall>e>0.  \<exists>x'\<in> s. x' \<noteq> x \<and> abs(x' - x) < e)"
  5650   unfolding islimpt_approachable dist_norm by simp
  5651 
  5652 lemma closed_real:
  5653   fixes s :: "real set"
  5654   shows "closed s \<longleftrightarrow> (\<forall>x. (\<forall>e>0.  \<exists>x' \<in> s. x' \<noteq> x \<and> abs(x' - x) < e) \<longrightarrow> x \<in> s)"
  5655   unfolding closed_limpt islimpt_approachable dist_norm by simp
  5656 
  5657 lemma continuous_at_real_range:
  5658   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  5659   shows "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'. norm(x' - x) < d --> abs(f x' - f x) < e)"
  5660   unfolding continuous_at
  5661   unfolding Lim_at
  5662   unfolding dist_nz[symmetric]
  5663   unfolding dist_norm
  5664   apply auto
  5665   apply (erule_tac x=e in allE)
  5666   apply auto
  5667   apply (rule_tac x=d in exI)
  5668   apply auto
  5669   apply (erule_tac x=x' in allE)
  5670   apply auto
  5671   apply (erule_tac x=e in allE)
  5672   apply auto
  5673   done
  5674 
  5675 lemma continuous_on_real_range:
  5676   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  5677   shows "continuous_on s f \<longleftrightarrow>
  5678     (\<forall>x \<in> s. \<forall>e>0. \<exists>d>0. (\<forall>x' \<in> s. norm(x' - x) < d \<longrightarrow> abs(f x' - f x) < e))"
  5679   unfolding continuous_on_iff dist_norm by simp
  5680 
  5681 text {* Hence some handy theorems on distance, diameter etc. of/from a set. *}
  5682 
  5683 lemma distance_attains_sup:
  5684   assumes "compact s" "s \<noteq> {}"
  5685   shows "\<exists>x\<in>s. \<forall>y\<in>s. dist a y \<le> dist a x"
  5686 proof (rule continuous_attains_sup [OF assms])
  5687   {
  5688     fix x
  5689     assume "x\<in>s"
  5690     have "(dist a ---> dist a x) (at x within s)"
  5691       by (intro tendsto_dist tendsto_const tendsto_ident_at)
  5692   }
  5693   then show "continuous_on s (dist a)"
  5694     unfolding continuous_on ..
  5695 qed
  5696 
  5697 text {* For \emph{minimal} distance, we only need closure, not compactness. *}
  5698 
  5699 lemma distance_attains_inf:
  5700   fixes a :: "'a::heine_borel"
  5701   assumes "closed s"
  5702     and "s \<noteq> {}"
  5703   shows "\<exists>x\<in>s. \<forall>y\<in>s. dist a x \<le> dist a y"
  5704 proof -
  5705   from assms(2) obtain b where "b \<in> s" by auto
  5706   let ?B = "s \<inter> cball a (dist b a)"
  5707   have "?B \<noteq> {}" using `b \<in> s`
  5708     by (auto simp add: dist_commute)
  5709   moreover have "continuous_on ?B (dist a)"
  5710     by (auto intro!: continuous_at_imp_continuous_on continuous_dist continuous_at_id continuous_const)
  5711   moreover have "compact ?B"
  5712     by (intro closed_inter_compact `closed s` compact_cball)
  5713   ultimately obtain x where "x \<in> ?B" "\<forall>y\<in>?B. dist a x \<le> dist a y"
  5714     by (metis continuous_attains_inf)
  5715   then show ?thesis by fastforce
  5716 qed
  5717 
  5718 
  5719 subsection {* Pasted sets *}
  5720 
  5721 lemma bounded_Times:
  5722   assumes "bounded s" "bounded t"
  5723   shows "bounded (s \<times> t)"
  5724 proof -
  5725   obtain x y a b where "\<forall>z\<in>s. dist x z \<le> a" "\<forall>z\<in>t. dist y z \<le> b"
  5726     using assms [unfolded bounded_def] by auto
  5727   then have "\<forall>z\<in>s \<times> t. dist (x, y) z \<le> sqrt (a\<^sup>2 + b\<^sup>2)"
  5728     by (auto simp add: dist_Pair_Pair real_sqrt_le_mono add_mono power_mono)
  5729   then show ?thesis unfolding bounded_any_center [where a="(x, y)"] by auto
  5730 qed
  5731 
  5732 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
  5733   by (induct x) simp
  5734 
  5735 lemma seq_compact_Times: "seq_compact s \<Longrightarrow> seq_compact t \<Longrightarrow> seq_compact (s \<times> t)"
  5736   unfolding seq_compact_def
  5737   apply clarify
  5738   apply (drule_tac x="fst \<circ> f" in spec)
  5739   apply (drule mp, simp add: mem_Times_iff)
  5740   apply (clarify, rename_tac l1 r1)
  5741   apply (drule_tac x="snd \<circ> f \<circ> r1" in spec)
  5742   apply (drule mp, simp add: mem_Times_iff)
  5743   apply (clarify, rename_tac l2 r2)
  5744   apply (rule_tac x="(l1, l2)" in rev_bexI, simp)
  5745   apply (rule_tac x="r1 \<circ> r2" in exI)
  5746   apply (rule conjI, simp add: subseq_def)
  5747   apply (drule_tac f=r2 in LIMSEQ_subseq_LIMSEQ, assumption)
  5748   apply (drule (1) tendsto_Pair) back
  5749   apply (simp add: o_def)
  5750   done
  5751 
  5752 lemma compact_Times:
  5753   assumes "compact s" "compact t"
  5754   shows "compact (s \<times> t)"
  5755 proof (rule compactI)
  5756   fix C
  5757   assume C: "\<forall>t\<in>C. open t" "s \<times> t \<subseteq> \<Union>C"
  5758   have "\<forall>x\<in>s. \<exists>a. open a \<and> x \<in> a \<and> (\<exists>d\<subseteq>C. finite d \<and> a \<times> t \<subseteq> \<Union>d)"
  5759   proof
  5760     fix x
  5761     assume "x \<in> s"
  5762     have "\<forall>y\<in>t. \<exists>a b c. c \<in> C \<and> open a \<and> open b \<and> x \<in> a \<and> y \<in> b \<and> a \<times> b \<subseteq> c" (is "\<forall>y\<in>t. ?P y")
  5763     proof
  5764       fix y
  5765       assume "y \<in> t"
  5766       with `x \<in> s` C obtain c where "c \<in> C" "(x, y) \<in> c" "open c" by auto
  5767       then show "?P y" by (auto elim!: open_prod_elim)
  5768     qed
  5769     then obtain a b c where b: "\<And>y. y \<in> t \<Longrightarrow> open (b y)"
  5770       and c: "\<And>y. y \<in> t \<Longrightarrow> c y \<in> C \<and> open (a y) \<and> open (b y) \<and> x \<in> a y \<and> y \<in> b y \<and> a y \<times> b y \<subseteq> c y"
  5771       by metis
  5772     then have "\<forall>y\<in>t. open (b y)" "t \<subseteq> (\<Union>y\<in>t. b y)" by auto
  5773     from compactE_image[OF `compact t` this] obtain D where D: "D \<subseteq> t" "finite D" "t \<subseteq> (\<Union>y\<in>D. b y)"
  5774       by auto
  5775     moreover from D c have "(\<Inter>y\<in>D. a y) \<times> t \<subseteq> (\<Union>y\<in>D. c y)"
  5776       by (fastforce simp: subset_eq)
  5777     ultimately show "\<exists>a. open a \<and> x \<in> a \<and> (\<exists>d\<subseteq>C. finite d \<and> a \<times> t \<subseteq> \<Union>d)"
  5778       using c by (intro exI[of _ "c`D"] exI[of _ "\<Inter>(a`D)"] conjI) (auto intro!: open_INT)
  5779   qed
  5780   then obtain a d where a: "\<forall>x\<in>s. open (a x)" "s \<subseteq> (\<Union>x\<in>s. a x)"
  5781     and d: "\<And>x. x \<in> s \<Longrightarrow> d x \<subseteq> C \<and> finite (d x) \<and> a x \<times> t \<subseteq> \<Union>d x"
  5782     unfolding subset_eq UN_iff by metis
  5783   moreover
  5784   from compactE_image[OF `compact s` a]
  5785   obtain e where e: "e \<subseteq> s" "finite e" and s: "s \<subseteq> (\<Union>x\<in>e. a x)"
  5786     by auto
  5787   moreover
  5788   {
  5789     from s have "s \<times> t \<subseteq> (\<Union>x\<in>e. a x \<times> t)"
  5790       by auto
  5791     also have "\<dots> \<subseteq> (\<Union>x\<in>e. \<Union>d x)"
  5792       using d `e \<subseteq> s` by (intro UN_mono) auto
  5793     finally have "s \<times> t \<subseteq> (\<Union>x\<in>e. \<Union>d x)" .
  5794   }
  5795   ultimately show "\<exists>C'\<subseteq>C. finite C' \<and> s \<times> t \<subseteq> \<Union>C'"
  5796     by (intro exI[of _ "(\<Union>x\<in>e. d x)"]) (auto simp add: subset_eq)
  5797 qed
  5798 
  5799 text{* Hence some useful properties follow quite easily. *}
  5800 
  5801 lemma compact_scaling:
  5802   fixes s :: "'a::real_normed_vector set"
  5803   assumes "compact s"
  5804   shows "compact ((\<lambda>x. c *\<^sub>R x) ` s)"
  5805 proof -
  5806   let ?f = "\<lambda>x. scaleR c x"
  5807   have *: "bounded_linear ?f" by (rule bounded_linear_scaleR_right)
  5808   show ?thesis
  5809     using compact_continuous_image[of s ?f] continuous_at_imp_continuous_on[of s ?f]
  5810     using linear_continuous_at[OF *] assms
  5811     by auto
  5812 qed
  5813 
  5814 lemma compact_negations:
  5815   fixes s :: "'a::real_normed_vector set"
  5816   assumes "compact s"
  5817   shows "compact ((\<lambda>x. - x) ` s)"
  5818   using compact_scaling [OF assms, of "- 1"] by auto
  5819 
  5820 lemma compact_sums:
  5821   fixes s t :: "'a::real_normed_vector set"
  5822   assumes "compact s"
  5823     and "compact t"
  5824   shows "compact {x + y | x y. x \<in> s \<and> y \<in> t}"
  5825 proof -
  5826   have *: "{x + y | x y. x \<in> s \<and> y \<in> t} = (\<lambda>z. fst z + snd z) ` (s \<times> t)"
  5827     apply auto
  5828     unfolding image_iff
  5829     apply (rule_tac x="(xa, y)" in bexI)
  5830     apply auto
  5831     done
  5832   have "continuous_on (s \<times> t) (\<lambda>z. fst z + snd z)"
  5833     unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  5834   then show ?thesis
  5835     unfolding * using compact_continuous_image compact_Times [OF assms] by auto
  5836 qed
  5837 
  5838 lemma compact_differences:
  5839   fixes s t :: "'a::real_normed_vector set"
  5840   assumes "compact s"
  5841     and "compact t"
  5842   shows "compact {x - y | x y. x \<in> s \<and> y \<in> t}"
  5843 proof-
  5844   have "{x - y | x y. x\<in>s \<and> y \<in> t} =  {x + y | x y. x \<in> s \<and> y \<in> (uminus ` t)}"
  5845     apply auto
  5846     apply (rule_tac x= xa in exI)
  5847     apply auto
  5848     done
  5849   then show ?thesis
  5850     using compact_sums[OF assms(1) compact_negations[OF assms(2)]] by auto
  5851 qed
  5852 
  5853 lemma compact_translation:
  5854   fixes s :: "'a::real_normed_vector set"
  5855   assumes "compact s"
  5856   shows "compact ((\<lambda>x. a + x) ` s)"
  5857 proof -
  5858   have "{x + y |x y. x \<in> s \<and> y \<in> {a}} = (\<lambda>x. a + x) ` s"
  5859     by auto
  5860   then show ?thesis
  5861     using compact_sums[OF assms compact_sing[of a]] by auto
  5862 qed
  5863 
  5864 lemma compact_affinity:
  5865   fixes s :: "'a::real_normed_vector set"
  5866   assumes "compact s"
  5867   shows "compact ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5868 proof -
  5869   have "op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s"
  5870     by auto
  5871   then show ?thesis
  5872     using compact_translation[OF compact_scaling[OF assms], of a c] by auto
  5873 qed
  5874 
  5875 text {* Hence we get the following. *}
  5876 
  5877 lemma compact_sup_maxdistance:
  5878   fixes s :: "'a::metric_space set"
  5879   assumes "compact s"
  5880     and "s \<noteq> {}"
  5881   shows "\<exists>x\<in>s. \<exists>y\<in>s. \<forall>u\<in>s. \<forall>v\<in>s. dist u v \<le> dist x y"
  5882 proof -
  5883   have "compact (s \<times> s)"
  5884     using `compact s` by (intro compact_Times)
  5885   moreover have "s \<times> s \<noteq> {}"
  5886     using `s \<noteq> {}` by auto
  5887   moreover have "continuous_on (s \<times> s) (\<lambda>x. dist (fst x) (snd x))"
  5888     by (intro continuous_at_imp_continuous_on ballI continuous_intros)
  5889   ultimately show ?thesis
  5890     using continuous_attains_sup[of "s \<times> s" "\<lambda>x. dist (fst x) (snd x)"] by auto
  5891 qed
  5892 
  5893 text {* We can state this in terms of diameter of a set. *}
  5894 
  5895 definition diameter :: "'a::metric_space set \<Rightarrow> real" where
  5896   "diameter S = (if S = {} then 0 else SUP (x,y):S\<times>S. dist x y)"
  5897 
  5898 lemma diameter_bounded_bound:
  5899   fixes s :: "'a :: metric_space set"
  5900   assumes s: "bounded s" "x \<in> s" "y \<in> s"
  5901   shows "dist x y \<le> diameter s"
  5902 proof -
  5903   from s obtain z d where z: "\<And>x. x \<in> s \<Longrightarrow> dist z x \<le> d"
  5904     unfolding bounded_def by auto
  5905   have "bdd_above (split dist ` (s\<times>s))"
  5906   proof (intro bdd_aboveI, safe)
  5907     fix a b
  5908     assume "a \<in> s" "b \<in> s"
  5909     with z[of a] z[of b] dist_triangle[of a b z]
  5910     show "dist a b \<le> 2 * d"
  5911       by (simp add: dist_commute)
  5912   qed
  5913   moreover have "(x,y) \<in> s\<times>s" using s by auto
  5914   ultimately have "dist x y \<le> (SUP (x,y):s\<times>s. dist x y)"
  5915     by (rule cSUP_upper2) simp
  5916   with `x \<in> s` show ?thesis
  5917     by (auto simp add: diameter_def)
  5918 qed
  5919 
  5920 lemma diameter_lower_bounded:
  5921   fixes s :: "'a :: metric_space set"
  5922   assumes s: "bounded s"
  5923     and d: "0 < d" "d < diameter s"
  5924   shows "\<exists>x\<in>s. \<exists>y\<in>s. d < dist x y"
  5925 proof (rule ccontr)
  5926   assume contr: "\<not> ?thesis"
  5927   moreover have "s \<noteq> {}"
  5928     using d by (auto simp add: diameter_def)
  5929   ultimately have "diameter s \<le> d"
  5930     by (auto simp: not_less diameter_def intro!: cSUP_least)
  5931   with `d < diameter s` show False by auto
  5932 qed
  5933 
  5934 lemma diameter_bounded:
  5935   assumes "bounded s"
  5936   shows "\<forall>x\<in>s. \<forall>y\<in>s. dist x y \<le> diameter s"
  5937     and "\<forall>d>0. d < diameter s \<longrightarrow> (\<exists>x\<in>s. \<exists>y\<in>s. dist x y > d)"
  5938   using diameter_bounded_bound[of s] diameter_lower_bounded[of s] assms
  5939   by auto
  5940 
  5941 lemma diameter_compact_attained:
  5942   assumes "compact s"
  5943     and "s \<noteq> {}"
  5944   shows "\<exists>x\<in>s. \<exists>y\<in>s. dist x y = diameter s"
  5945 proof -
  5946   have b: "bounded s" using assms(1)
  5947     by (rule compact_imp_bounded)
  5948   then obtain x y where xys: "x\<in>s" "y\<in>s"
  5949     and xy: "\<forall>u\<in>s. \<forall>v\<in>s. dist u v \<le> dist x y"
  5950     using compact_sup_maxdistance[OF assms] by auto
  5951   then have "diameter s \<le> dist x y"
  5952     unfolding diameter_def
  5953     apply clarsimp
  5954     apply (rule cSUP_least)
  5955     apply fast+
  5956     done
  5957   then show ?thesis
  5958     by (metis b diameter_bounded_bound order_antisym xys)
  5959 qed
  5960 
  5961 text {* Related results with closure as the conclusion. *}
  5962 
  5963 lemma closed_scaling:
  5964   fixes s :: "'a::real_normed_vector set"
  5965   assumes "closed s"
  5966   shows "closed ((\<lambda>x. c *\<^sub>R x) ` s)"
  5967 proof (cases "c = 0")
  5968   case True then show ?thesis
  5969     by (auto simp add: image_constant_conv)
  5970 next
  5971   case False
  5972   from assms have "closed ((\<lambda>x. inverse c *\<^sub>R x) -` s)"
  5973     by (simp add: continuous_closed_vimage)
  5974   also have "(\<lambda>x. inverse c *\<^sub>R x) -` s = (\<lambda>x. c *\<^sub>R x) ` s"
  5975     using `c \<noteq> 0` by (auto elim: image_eqI [rotated])
  5976   finally show ?thesis .
  5977 qed
  5978 
  5979 lemma closed_negations:
  5980   fixes s :: "'a::real_normed_vector set"
  5981   assumes "closed s"
  5982   shows "closed ((\<lambda>x. -x) ` s)"
  5983   using closed_scaling[OF assms, of "- 1"] by simp
  5984 
  5985 lemma compact_closed_sums:
  5986   fixes s :: "'a::real_normed_vector set"
  5987   assumes "compact s" and "closed t"
  5988   shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  5989 proof -
  5990   let ?S = "{x + y |x y. x \<in> s \<and> y \<in> t}"
  5991   {
  5992     fix x l
  5993     assume as: "\<forall>n. x n \<in> ?S"  "(x ---> l) sequentially"
  5994     from as(1) obtain f where f: "\<forall>n. x n = fst (f n) + snd (f n)"  "\<forall>n. fst (f n) \<in> s"  "\<forall>n. snd (f n) \<in> t"
  5995       using choice[of "\<lambda>n y. x n = (fst y) + (snd y) \<and> fst y \<in> s \<and> snd y \<in> t"] by auto
  5996     obtain l' r where "l'\<in>s" and r: "subseq r" and lr: "(((\<lambda>n. fst (f n)) \<circ> r) ---> l') sequentially"
  5997       using assms(1)[unfolded compact_def, THEN spec[where x="\<lambda> n. fst (f n)"]] using f(2) by auto
  5998     have "((\<lambda>n. snd (f (r n))) ---> l - l') sequentially"
  5999       using tendsto_diff[OF LIMSEQ_subseq_LIMSEQ[OF as(2) r] lr] and f(1)
  6000       unfolding o_def
  6001       by auto
  6002     then have "l - l' \<in> t"
  6003       using assms(2)[unfolded closed_sequential_limits,
  6004         THEN spec[where x="\<lambda> n. snd (f (r n))"],
  6005         THEN spec[where x="l - l'"]]
  6006       using f(3)
  6007       by auto
  6008     then have "l \<in> ?S"
  6009       using `l' \<in> s`
  6010       apply auto
  6011       apply (rule_tac x=l' in exI)
  6012       apply (rule_tac x="l - l'" in exI)
  6013       apply auto
  6014       done
  6015   }
  6016   then show ?thesis
  6017     unfolding closed_sequential_limits by fast
  6018 qed