src/HOL/Library/Product_Vector.thy
author huffman
Wed Jun 03 08:43:29 2009 -0700 (2009-06-03)
changeset 31415 80686a815b59
parent 31405 1f72869f1a2e
child 31417 c12b25b7f015
permissions -rw-r--r--
instance * :: topological_space
     1 (*  Title:      HOL/Library/Product_Vector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Cartesian Products as Vector Spaces *}
     6 
     7 theory Product_Vector
     8 imports Inner_Product Product_plus
     9 begin
    10 
    11 subsection {* Product is a real vector space *}
    12 
    13 instantiation "*" :: (real_vector, real_vector) real_vector
    14 begin
    15 
    16 definition scaleR_prod_def:
    17   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
    18 
    19 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
    20   unfolding scaleR_prod_def by simp
    21 
    22 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
    23   unfolding scaleR_prod_def by simp
    24 
    25 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
    26   unfolding scaleR_prod_def by simp
    27 
    28 instance proof
    29   fix a b :: real and x y :: "'a \<times> 'b"
    30   show "scaleR a (x + y) = scaleR a x + scaleR a y"
    31     by (simp add: expand_prod_eq scaleR_right_distrib)
    32   show "scaleR (a + b) x = scaleR a x + scaleR b x"
    33     by (simp add: expand_prod_eq scaleR_left_distrib)
    34   show "scaleR a (scaleR b x) = scaleR (a * b) x"
    35     by (simp add: expand_prod_eq)
    36   show "scaleR 1 x = x"
    37     by (simp add: expand_prod_eq)
    38 qed
    39 
    40 end
    41 
    42 subsection {* Product is a topological space *}
    43 
    44 instantiation
    45   "*" :: (topological_space, topological_space) topological_space
    46 begin
    47 
    48 definition open_prod_def:
    49   "open S = (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
    50 
    51 instance proof
    52   show "open (UNIV :: ('a \<times> 'b) set)"
    53     unfolding open_prod_def by (fast intro: open_UNIV)
    54 next
    55   fix S T :: "('a \<times> 'b) set"
    56   assume "open S" "open T" thus "open (S \<inter> T)"
    57     unfolding open_prod_def
    58     apply clarify
    59     apply (drule (1) bspec)+
    60     apply (clarify, rename_tac Sa Ta Sb Tb)
    61     apply (rule_tac x="Sa \<inter> Ta" in exI)
    62     apply (rule_tac x="Sb \<inter> Tb" in exI)
    63     apply (simp add: open_Int)
    64     apply fast
    65     done
    66 next
    67   fix T :: "('a \<times> 'b) set set"
    68   assume "\<forall>A\<in>T. open A" thus "open (\<Union>T)"
    69     unfolding open_prod_def by fast
    70 qed
    71 
    72 end
    73 
    74 subsection {* Product is a metric space *}
    75 
    76 instantiation
    77   "*" :: (metric_space, metric_space) metric_space
    78 begin
    79 
    80 definition dist_prod_def:
    81   "dist (x::'a \<times> 'b) y = sqrt ((dist (fst x) (fst y))\<twosuperior> + (dist (snd x) (snd y))\<twosuperior>)"
    82 
    83 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<twosuperior> + (dist b d)\<twosuperior>)"
    84   unfolding dist_prod_def by simp
    85 
    86 instance proof
    87   fix x y :: "'a \<times> 'b"
    88   show "dist x y = 0 \<longleftrightarrow> x = y"
    89     unfolding dist_prod_def
    90     by (simp add: expand_prod_eq)
    91 next
    92   fix x y z :: "'a \<times> 'b"
    93   show "dist x y \<le> dist x z + dist y z"
    94     unfolding dist_prod_def
    95     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
    96     apply (rule real_sqrt_le_mono)
    97     apply (rule order_trans [OF add_mono])
    98     apply (rule power_mono [OF dist_triangle2 [of _ _ "fst z"] zero_le_dist])
    99     apply (rule power_mono [OF dist_triangle2 [of _ _ "snd z"] zero_le_dist])
   100     apply (simp only: real_sum_squared_expand)
   101     done
   102 next
   103   (* FIXME: long proof! *)
   104   (* Maybe it would be easier to define topological spaces *)
   105   (* in terms of neighborhoods instead of open sets? *)
   106   fix S :: "('a \<times> 'b) set"
   107   show "open S = (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   108     unfolding open_prod_def open_dist
   109     apply safe
   110     apply (drule (1) bspec)
   111     apply clarify
   112     apply (drule (1) bspec)+
   113     apply (clarify, rename_tac r s)
   114     apply (rule_tac x="min r s" in exI, simp)
   115     apply (clarify, rename_tac c d)
   116     apply (erule subsetD)
   117     apply (simp add: dist_Pair_Pair)
   118     apply (rule conjI)
   119     apply (drule spec, erule mp)
   120     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge1])
   121     apply (drule spec, erule mp)
   122     apply (erule le_less_trans [OF real_sqrt_sum_squares_ge2])
   123 
   124     apply (drule (1) bspec)
   125     apply clarify
   126     apply (subgoal_tac "\<exists>r>0. \<exists>s>0. e = sqrt (r\<twosuperior> + s\<twosuperior>)")
   127     apply clarify
   128     apply (rule_tac x="{y. dist y a < r}" in exI)
   129     apply (rule_tac x="{y. dist y b < s}" in exI)
   130     apply (rule conjI)
   131     apply clarify
   132     apply (rule_tac x="r - dist x a" in exI, rule conjI, simp)
   133     apply clarify
   134     apply (rule le_less_trans [OF dist_triangle])
   135     apply (erule less_le_trans [OF add_strict_right_mono], simp)
   136     apply (rule conjI)
   137     apply clarify
   138     apply (rule_tac x="s - dist x b" in exI, rule conjI, simp)
   139     apply clarify
   140     apply (rule le_less_trans [OF dist_triangle])
   141     apply (erule less_le_trans [OF add_strict_right_mono], simp)
   142     apply (rule conjI)
   143     apply simp
   144     apply (clarify, rename_tac c d)
   145     apply (drule spec, erule mp)
   146     apply (simp add: dist_Pair_Pair add_strict_mono power_strict_mono)
   147     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   148     apply (rule_tac x="e / sqrt 2" in exI, simp add: divide_pos_pos)
   149     apply (simp add: power_divide)
   150     done
   151 qed
   152 
   153 end
   154 
   155 subsection {* Continuity of operations *}
   156 
   157 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
   158 unfolding dist_prod_def by simp
   159 
   160 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
   161 unfolding dist_prod_def by simp
   162 
   163 lemma tendsto_fst:
   164   assumes "tendsto f a net"
   165   shows "tendsto (\<lambda>x. fst (f x)) (fst a) net"
   166 proof (rule tendstoI)
   167   fix r :: real assume "0 < r"
   168   have "eventually (\<lambda>x. dist (f x) a < r) net"
   169     using `tendsto f a net` `0 < r` by (rule tendstoD)
   170   thus "eventually (\<lambda>x. dist (fst (f x)) (fst a) < r) net"
   171     by (rule eventually_elim1)
   172        (rule le_less_trans [OF dist_fst_le])
   173 qed
   174 
   175 lemma tendsto_snd:
   176   assumes "tendsto f a net"
   177   shows "tendsto (\<lambda>x. snd (f x)) (snd a) net"
   178 proof (rule tendstoI)
   179   fix r :: real assume "0 < r"
   180   have "eventually (\<lambda>x. dist (f x) a < r) net"
   181     using `tendsto f a net` `0 < r` by (rule tendstoD)
   182   thus "eventually (\<lambda>x. dist (snd (f x)) (snd a) < r) net"
   183     by (rule eventually_elim1)
   184        (rule le_less_trans [OF dist_snd_le])
   185 qed
   186 
   187 lemma tendsto_Pair:
   188   assumes "tendsto X a net" and "tendsto Y b net"
   189   shows "tendsto (\<lambda>i. (X i, Y i)) (a, b) net"
   190 proof (rule tendstoI)
   191   fix r :: real assume "0 < r"
   192   then have "0 < r / sqrt 2" (is "0 < ?s")
   193     by (simp add: divide_pos_pos)
   194   have "eventually (\<lambda>i. dist (X i) a < ?s) net"
   195     using `tendsto X a net` `0 < ?s` by (rule tendstoD)
   196   moreover
   197   have "eventually (\<lambda>i. dist (Y i) b < ?s) net"
   198     using `tendsto Y b net` `0 < ?s` by (rule tendstoD)
   199   ultimately
   200   show "eventually (\<lambda>i. dist (X i, Y i) (a, b) < r) net"
   201     by (rule eventually_elim2)
   202        (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   203 qed
   204 
   205 lemma LIMSEQ_fst: "(X ----> a) \<Longrightarrow> (\<lambda>n. fst (X n)) ----> fst a"
   206 unfolding LIMSEQ_conv_tendsto by (rule tendsto_fst)
   207 
   208 lemma LIMSEQ_snd: "(X ----> a) \<Longrightarrow> (\<lambda>n. snd (X n)) ----> snd a"
   209 unfolding LIMSEQ_conv_tendsto by (rule tendsto_snd)
   210 
   211 lemma LIMSEQ_Pair:
   212   assumes "X ----> a" and "Y ----> b"
   213   shows "(\<lambda>n. (X n, Y n)) ----> (a, b)"
   214 using assms unfolding LIMSEQ_conv_tendsto
   215 by (rule tendsto_Pair)
   216 
   217 lemma LIM_fst: "f -- x --> a \<Longrightarrow> (\<lambda>x. fst (f x)) -- x --> fst a"
   218 unfolding LIM_conv_tendsto by (rule tendsto_fst)
   219 
   220 lemma LIM_snd: "f -- x --> a \<Longrightarrow> (\<lambda>x. snd (f x)) -- x --> snd a"
   221 unfolding LIM_conv_tendsto by (rule tendsto_snd)
   222 
   223 lemma LIM_Pair:
   224   assumes "f -- x --> a" and "g -- x --> b"
   225   shows "(\<lambda>x. (f x, g x)) -- x --> (a, b)"
   226 using assms unfolding LIM_conv_tendsto
   227 by (rule tendsto_Pair)
   228 
   229 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
   230 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
   231 
   232 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
   233 unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
   234 
   235 lemma Cauchy_Pair:
   236   assumes "Cauchy X" and "Cauchy Y"
   237   shows "Cauchy (\<lambda>n. (X n, Y n))"
   238 proof (rule metric_CauchyI)
   239   fix r :: real assume "0 < r"
   240   then have "0 < r / sqrt 2" (is "0 < ?s")
   241     by (simp add: divide_pos_pos)
   242   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
   243     using metric_CauchyD [OF `Cauchy X` `0 < ?s`] ..
   244   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
   245     using metric_CauchyD [OF `Cauchy Y` `0 < ?s`] ..
   246   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
   247     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
   248   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
   249 qed
   250 
   251 lemma isCont_Pair [simp]:
   252   "\<lbrakk>isCont f x; isCont g x\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) x"
   253   unfolding isCont_def by (rule LIM_Pair)
   254 
   255 subsection {* Product is a complete metric space *}
   256 
   257 instance "*" :: (complete_space, complete_space) complete_space
   258 proof
   259   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
   260   have 1: "(\<lambda>n. fst (X n)) ----> lim (\<lambda>n. fst (X n))"
   261     using Cauchy_fst [OF `Cauchy X`]
   262     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   263   have 2: "(\<lambda>n. snd (X n)) ----> lim (\<lambda>n. snd (X n))"
   264     using Cauchy_snd [OF `Cauchy X`]
   265     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   266   have "X ----> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
   267     using LIMSEQ_Pair [OF 1 2] by simp
   268   then show "convergent X"
   269     by (rule convergentI)
   270 qed
   271 
   272 subsection {* Product is a normed vector space *}
   273 
   274 instantiation
   275   "*" :: (real_normed_vector, real_normed_vector) real_normed_vector
   276 begin
   277 
   278 definition norm_prod_def:
   279   "norm x = sqrt ((norm (fst x))\<twosuperior> + (norm (snd x))\<twosuperior>)"
   280 
   281 definition sgn_prod_def:
   282   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
   283 
   284 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<twosuperior> + (norm b)\<twosuperior>)"
   285   unfolding norm_prod_def by simp
   286 
   287 instance proof
   288   fix r :: real and x y :: "'a \<times> 'b"
   289   show "0 \<le> norm x"
   290     unfolding norm_prod_def by simp
   291   show "norm x = 0 \<longleftrightarrow> x = 0"
   292     unfolding norm_prod_def
   293     by (simp add: expand_prod_eq)
   294   show "norm (x + y) \<le> norm x + norm y"
   295     unfolding norm_prod_def
   296     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
   297     apply (simp add: add_mono power_mono norm_triangle_ineq)
   298     done
   299   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   300     unfolding norm_prod_def
   301     apply (simp add: norm_scaleR power_mult_distrib)
   302     apply (simp add: right_distrib [symmetric])
   303     apply (simp add: real_sqrt_mult_distrib)
   304     done
   305   show "sgn x = scaleR (inverse (norm x)) x"
   306     by (rule sgn_prod_def)
   307   show "dist x y = norm (x - y)"
   308     unfolding dist_prod_def norm_prod_def
   309     by (simp add: dist_norm)
   310 qed
   311 
   312 end
   313 
   314 instance "*" :: (banach, banach) banach ..
   315 
   316 subsection {* Product is an inner product space *}
   317 
   318 instantiation "*" :: (real_inner, real_inner) real_inner
   319 begin
   320 
   321 definition inner_prod_def:
   322   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
   323 
   324 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
   325   unfolding inner_prod_def by simp
   326 
   327 instance proof
   328   fix r :: real
   329   fix x y z :: "'a::real_inner * 'b::real_inner"
   330   show "inner x y = inner y x"
   331     unfolding inner_prod_def
   332     by (simp add: inner_commute)
   333   show "inner (x + y) z = inner x z + inner y z"
   334     unfolding inner_prod_def
   335     by (simp add: inner_left_distrib)
   336   show "inner (scaleR r x) y = r * inner x y"
   337     unfolding inner_prod_def
   338     by (simp add: inner_scaleR_left right_distrib)
   339   show "0 \<le> inner x x"
   340     unfolding inner_prod_def
   341     by (intro add_nonneg_nonneg inner_ge_zero)
   342   show "inner x x = 0 \<longleftrightarrow> x = 0"
   343     unfolding inner_prod_def expand_prod_eq
   344     by (simp add: add_nonneg_eq_0_iff)
   345   show "norm x = sqrt (inner x x)"
   346     unfolding norm_prod_def inner_prod_def
   347     by (simp add: power2_norm_eq_inner)
   348 qed
   349 
   350 end
   351 
   352 subsection {* Pair operations are linear *}
   353 
   354 interpretation fst: bounded_linear fst
   355   apply (unfold_locales)
   356   apply (rule fst_add)
   357   apply (rule fst_scaleR)
   358   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   359   done
   360 
   361 interpretation snd: bounded_linear snd
   362   apply (unfold_locales)
   363   apply (rule snd_add)
   364   apply (rule snd_scaleR)
   365   apply (rule_tac x="1" in exI, simp add: norm_Pair)
   366   done
   367 
   368 text {* TODO: move to NthRoot *}
   369 lemma sqrt_add_le_add_sqrt:
   370   assumes x: "0 \<le> x" and y: "0 \<le> y"
   371   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   372 apply (rule power2_le_imp_le)
   373 apply (simp add: real_sum_squared_expand add_nonneg_nonneg x y)
   374 apply (simp add: mult_nonneg_nonneg x y)
   375 apply (simp add: add_nonneg_nonneg x y)
   376 done
   377 
   378 lemma bounded_linear_Pair:
   379   assumes f: "bounded_linear f"
   380   assumes g: "bounded_linear g"
   381   shows "bounded_linear (\<lambda>x. (f x, g x))"
   382 proof
   383   interpret f: bounded_linear f by fact
   384   interpret g: bounded_linear g by fact
   385   fix x y and r :: real
   386   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
   387     by (simp add: f.add g.add)
   388   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
   389     by (simp add: f.scaleR g.scaleR)
   390   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
   391     using f.pos_bounded by fast
   392   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
   393     using g.pos_bounded by fast
   394   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
   395     apply (rule allI)
   396     apply (simp add: norm_Pair)
   397     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
   398     apply (simp add: right_distrib)
   399     apply (rule add_mono [OF norm_f norm_g])
   400     done
   401   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
   402 qed
   403 
   404 subsection {* Frechet derivatives involving pairs *}
   405 
   406 lemma FDERIV_Pair:
   407   assumes f: "FDERIV f x :> f'" and g: "FDERIV g x :> g'"
   408   shows "FDERIV (\<lambda>x. (f x, g x)) x :> (\<lambda>h. (f' h, g' h))"
   409 apply (rule FDERIV_I)
   410 apply (rule bounded_linear_Pair)
   411 apply (rule FDERIV_bounded_linear [OF f])
   412 apply (rule FDERIV_bounded_linear [OF g])
   413 apply (simp add: norm_Pair)
   414 apply (rule real_LIM_sandwich_zero)
   415 apply (rule LIM_add_zero)
   416 apply (rule FDERIV_D [OF f])
   417 apply (rule FDERIV_D [OF g])
   418 apply (rename_tac h)
   419 apply (simp add: divide_nonneg_pos)
   420 apply (rename_tac h)
   421 apply (subst add_divide_distrib [symmetric])
   422 apply (rule divide_right_mono [OF _ norm_ge_zero])
   423 apply (rule order_trans [OF sqrt_add_le_add_sqrt])
   424 apply simp
   425 apply simp
   426 apply simp
   427 done
   428 
   429 end