src/HOL/Transcendental.thy
author huffman
Fri Aug 19 18:42:41 2011 -0700 (2011-08-19)
changeset 44319 806e0390de53
parent 44318 425c1f8f9487
child 44568 e6f291cb5810
permissions -rw-r--r--
move sin_coeff and cos_coeff lemmas to Transcendental.thy; simplify some proofs
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4 *)
     5 
     6 header{*Power Series, Transcendental Functions etc.*}
     7 
     8 theory Transcendental
     9 imports Fact Series Deriv NthRoot
    10 begin
    11 
    12 subsection {* Properties of Power Series *}
    13 
    14 lemma lemma_realpow_diff:
    15   fixes y :: "'a::monoid_mult"
    16   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    17 proof -
    18   assume "p \<le> n"
    19   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    20   thus ?thesis by (simp add: power_commutes)
    21 qed
    22 
    23 lemma lemma_realpow_diff_sumr:
    24   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    25      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =
    26       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    27 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    28          del: setsum_op_ivl_Suc)
    29 
    30 lemma lemma_realpow_diff_sumr2:
    31   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    32      "x ^ (Suc n) - y ^ (Suc n) =
    33       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    34 apply (induct n, simp)
    35 apply (simp del: setsum_op_ivl_Suc)
    36 apply (subst setsum_op_ivl_Suc)
    37 apply (subst lemma_realpow_diff_sumr)
    38 apply (simp add: right_distrib del: setsum_op_ivl_Suc)
    39 apply (subst mult_left_commute [of "x - y"])
    40 apply (erule subst)
    41 apply (simp add: algebra_simps)
    42 done
    43 
    44 lemma lemma_realpow_rev_sumr:
    45      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =
    46       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    47 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    48 apply (rule inj_onI, simp)
    49 apply auto
    50 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    51 done
    52 
    53 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    54 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    55 
    56 lemma powser_insidea:
    57   fixes x z :: "'a::{real_normed_field,banach}"
    58   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    59   assumes 2: "norm z < norm x"
    60   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    61 proof -
    62   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    63   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    64     by (rule summable_LIMSEQ_zero)
    65   hence "convergent (\<lambda>n. f n * x ^ n)"
    66     by (rule convergentI)
    67   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    68     by (simp add: Cauchy_convergent_iff)
    69   hence "Bseq (\<lambda>n. f n * x ^ n)"
    70     by (rule Cauchy_Bseq)
    71   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    72     by (simp add: Bseq_def, safe)
    73   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    74                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    75   proof (intro exI allI impI)
    76     fix n::nat assume "0 \<le> n"
    77     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    78           norm (f n * x ^ n) * norm (z ^ n)"
    79       by (simp add: norm_mult abs_mult)
    80     also have "\<dots> \<le> K * norm (z ^ n)"
    81       by (simp only: mult_right_mono 4 norm_ge_zero)
    82     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    83       by (simp add: x_neq_0)
    84     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    85       by (simp only: mult_assoc)
    86     finally show "norm (norm (f n * z ^ n)) \<le>
    87                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    88       by (simp add: mult_le_cancel_right x_neq_0)
    89   qed
    90   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    91   proof -
    92     from 2 have "norm (norm (z * inverse x)) < 1"
    93       using x_neq_0
    94       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    95     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    96       by (rule summable_geometric)
    97     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
    98       by (rule summable_mult)
    99     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   100       using x_neq_0
   101       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   102                     power_inverse norm_power mult_assoc)
   103   qed
   104   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   105     by (rule summable_comparison_test)
   106 qed
   107 
   108 lemma powser_inside:
   109   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   110      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]
   111       ==> summable (%n. f(n) * (z ^ n))"
   112 by (rule powser_insidea [THEN summable_norm_cancel])
   113 
   114 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   115   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) =
   116    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   117 proof (induct n)
   118   case (Suc n)
   119   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) =
   120         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   121     using Suc.hyps unfolding One_nat_def by auto
   122   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   123   finally show ?case .
   124 qed auto
   125 
   126 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   127   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   128   unfolding sums_def
   129 proof (rule LIMSEQ_I)
   130   fix r :: real assume "0 < r"
   131   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   132   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   133 
   134   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   135   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   136     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }"
   137       using sum_split_even_odd by auto
   138     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   139     moreover
   140     have "?SUM (2 * (m div 2)) = ?SUM m"
   141     proof (cases "even m")
   142       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   143     next
   144       case False hence "even (Suc m)" by auto
   145       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   146       have eq: "Suc (2 * (m div 2)) = m" by auto
   147       hence "even (2 * (m div 2))" using `odd m` by auto
   148       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   149       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   150       finally show ?thesis by auto
   151     qed
   152     ultimately have "(norm (?SUM m - x) < r)" by auto
   153   }
   154   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   155 qed
   156 
   157 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   158   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   159 proof -
   160   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   161   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   162       by (cases B) auto } note if_sum = this
   163   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   164   {
   165     have "?s 0 = 0" by auto
   166     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   167     have if_eq: "\<And>B T E. (if \<not> B then T else E) = (if B then E else T)" by auto
   168 
   169     have "?s sums y" using sums_if'[OF `f sums y`] .
   170     from this[unfolded sums_def, THEN LIMSEQ_Suc]
   171     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   172       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   173                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   174                 even_Suc Suc_m1 if_eq .
   175   } from sums_add[OF g_sums this]
   176   show ?thesis unfolding if_sum .
   177 qed
   178 
   179 subsection {* Alternating series test / Leibniz formula *}
   180 
   181 lemma sums_alternating_upper_lower:
   182   fixes a :: "nat \<Rightarrow> real"
   183   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   184   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and>
   185              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   186   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   187 proof -
   188   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   189 
   190   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   191   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   192   moreover
   193   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   194   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   195     unfolding One_nat_def by auto qed
   196   moreover
   197   have "\<forall> n. ?f n \<le> ?g n"
   198   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   199     unfolding One_nat_def by auto qed
   200   moreover
   201   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   202   proof (rule LIMSEQ_I)
   203     fix r :: real assume "0 < r"
   204     with `a ----> 0`[THEN LIMSEQ_D]
   205     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   206     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   207     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   208   qed
   209   ultimately
   210   show ?thesis by (rule lemma_nest_unique)
   211 qed
   212 
   213 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   214   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   215   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   216   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   217   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   218   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   219   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221 proof -
   222   let "?S n" = "(-1)^n * a n"
   223   let "?P n" = "\<Sum>i=0..<n. ?S i"
   224   let "?f n" = "?P (2 * n)"
   225   let "?g n" = "?P (2 * n + 1)"
   226   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   227     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   228 
   229   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   230   have "?Sa ----> l"
   231   proof (rule LIMSEQ_I)
   232     fix r :: real assume "0 < r"
   233 
   234     with `?f ----> l`[THEN LIMSEQ_D]
   235     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   236 
   237     from `0 < r` `?g ----> l`[THEN LIMSEQ_D]
   238     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   239 
   240     { fix n :: nat
   241       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   242       have "norm (?Sa n - l) < r"
   243       proof (cases "even n")
   244         case True from even_nat_div_two_times_two[OF this]
   245         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   246         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   247         from f[OF this]
   248         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   249       next
   250         case False hence "even (n - 1)" by simp
   251         from even_nat_div_two_times_two[OF this]
   252         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   253         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   254 
   255         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   256         from g[OF this]
   257         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   258       qed
   259     }
   260     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   261   qed
   262   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   263   thus "summable ?S" using summable_def by auto
   264 
   265   have "l = suminf ?S" using sums_unique[OF sums_l] .
   266 
   267   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   268   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   269   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   270   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   271 qed
   272 
   273 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   274   assumes a_zero: "a ----> 0" and "monoseq a"
   275   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   276   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   277   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   278   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   279   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   280 proof -
   281   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   282   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   283     case True
   284     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   285     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   286     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   287     from leibniz[OF mono]
   288     show ?thesis using `0 \<le> a 0` by auto
   289   next
   290     let ?a = "\<lambda> n. - a n"
   291     case False
   292     with monoseq_le[OF `monoseq a` `a ----> 0`]
   293     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   294     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   295     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   296     note monotone = this
   297     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF LIMSEQ_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   298     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   299     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   300     from this[THEN sums_minus]
   301     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   302     hence ?summable unfolding summable_def by auto
   303     moreover
   304     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   305 
   306     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   307     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   308 
   309     have ?pos using `0 \<le> ?a 0` by auto
   310     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   311     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN LIMSEQ_minus_cancel] by auto
   312     ultimately show ?thesis by auto
   313   qed
   314   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   315        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   316   show ?summable and ?pos and ?neg and ?f and ?g .
   317 qed
   318 
   319 subsection {* Term-by-Term Differentiability of Power Series *}
   320 
   321 definition
   322   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   323   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   324 
   325 text{*Lemma about distributing negation over it*}
   326 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   327 by (simp add: diffs_def)
   328 
   329 lemma sums_Suc_imp:
   330   assumes f: "f 0 = 0"
   331   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   332 unfolding sums_def
   333 apply (rule LIMSEQ_imp_Suc)
   334 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   335 apply (simp only: setsum_shift_bounds_Suc_ivl)
   336 done
   337 
   338 lemma diffs_equiv:
   339   fixes x :: "'a::{real_normed_vector, ring_1}"
   340   shows "summable (%n. (diffs c)(n) * (x ^ n)) ==>
   341       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums
   342          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   343 unfolding diffs_def
   344 apply (drule summable_sums)
   345 apply (rule sums_Suc_imp, simp_all)
   346 done
   347 
   348 lemma lemma_termdiff1:
   349   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   350   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =
   351    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   352 by(auto simp add: algebra_simps power_add [symmetric])
   353 
   354 lemma sumr_diff_mult_const2:
   355   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   356 by (simp add: setsum_subtractf)
   357 
   358 lemma lemma_termdiff2:
   359   fixes h :: "'a :: {field}"
   360   assumes h: "h \<noteq> 0" shows
   361   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   362    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   363         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   364 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   365 apply (simp add: right_diff_distrib diff_divide_distrib h)
   366 apply (simp add: mult_assoc [symmetric])
   367 apply (cases "n", simp)
   368 apply (simp add: lemma_realpow_diff_sumr2 h
   369                  right_diff_distrib [symmetric] mult_assoc
   370             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   371 apply (subst lemma_realpow_rev_sumr)
   372 apply (subst sumr_diff_mult_const2)
   373 apply simp
   374 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   375 apply (rule setsum_cong [OF refl])
   376 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   377 apply (clarify)
   378 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   379             del: setsum_op_ivl_Suc power_Suc)
   380 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   381 apply (simp add: mult_ac)
   382 done
   383 
   384 lemma real_setsum_nat_ivl_bounded2:
   385   fixes K :: "'a::linordered_semidom"
   386   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   387   assumes K: "0 \<le> K"
   388   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   389 apply (rule order_trans [OF setsum_mono])
   390 apply (rule f, simp)
   391 apply (simp add: mult_right_mono K)
   392 done
   393 
   394 lemma lemma_termdiff3:
   395   fixes h z :: "'a::{real_normed_field}"
   396   assumes 1: "h \<noteq> 0"
   397   assumes 2: "norm z \<le> K"
   398   assumes 3: "norm (z + h) \<le> K"
   399   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   400           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   401 proof -
   402   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   403         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   404           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   405     apply (subst lemma_termdiff2 [OF 1])
   406     apply (subst norm_mult)
   407     apply (rule mult_commute)
   408     done
   409   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   410   proof (rule mult_right_mono [OF _ norm_ge_zero])
   411     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   412     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   413       apply (erule subst)
   414       apply (simp only: norm_mult norm_power power_add)
   415       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   416       done
   417     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   418               (z + h) ^ q * z ^ (n - 2 - q))
   419           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   420       apply (intro
   421          order_trans [OF norm_setsum]
   422          real_setsum_nat_ivl_bounded2
   423          mult_nonneg_nonneg
   424          zero_le_imp_of_nat
   425          zero_le_power K)
   426       apply (rule le_Kn, simp)
   427       done
   428   qed
   429   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   430     by (simp only: mult_assoc)
   431   finally show ?thesis .
   432 qed
   433 
   434 lemma lemma_termdiff4:
   435   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   436               'b::real_normed_vector"
   437   assumes k: "0 < (k::real)"
   438   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   439   shows "f -- 0 --> 0"
   440 unfolding LIM_eq diff_0_right
   441 proof (safe)
   442   let ?h = "of_real (k / 2)::'a"
   443   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   444   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   445   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   446   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   447 
   448   fix r::real assume r: "0 < r"
   449   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   450   proof (cases)
   451     assume "K = 0"
   452     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   453       by simp
   454     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   455   next
   456     assume K_neq_zero: "K \<noteq> 0"
   457     with zero_le_K have K: "0 < K" by simp
   458     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   459     proof (rule exI, safe)
   460       from k r K show "0 < min k (r * inverse K / 2)"
   461         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   462     next
   463       fix x::'a
   464       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   465       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   466         by simp_all
   467       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   468       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   469         by (rule mult_strict_left_mono)
   470       also have "\<dots> = r / 2"
   471         using K_neq_zero by simp
   472       also have "r / 2 < r"
   473         using r by simp
   474       finally show "norm (f x) < r" .
   475     qed
   476   qed
   477 qed
   478 
   479 lemma lemma_termdiff5:
   480   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   481               nat \<Rightarrow> 'b::banach"
   482   assumes k: "0 < (k::real)"
   483   assumes f: "summable f"
   484   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   485   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   486 proof (rule lemma_termdiff4 [OF k])
   487   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   488   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   489     by (simp add: le)
   490   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   491     by simp
   492   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   493     by (rule summable_mult2)
   494   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   495     by (rule summable_comparison_test)
   496   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   497     by (rule summable_norm)
   498   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   499     by (rule summable_le)
   500   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   501     by (rule suminf_mult2 [symmetric])
   502   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   503 qed
   504 
   505 
   506 text{* FIXME: Long proofs*}
   507 
   508 lemma termdiffs_aux:
   509   fixes x :: "'a::{real_normed_field,banach}"
   510   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   511   assumes 2: "norm x < norm K"
   512   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   513              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   514 proof -
   515   from dense [OF 2]
   516   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   517   from norm_ge_zero r1 have r: "0 < r"
   518     by (rule order_le_less_trans)
   519   hence r_neq_0: "r \<noteq> 0" by simp
   520   show ?thesis
   521   proof (rule lemma_termdiff5)
   522     show "0 < r - norm x" using r1 by simp
   523   next
   524     from r r2 have "norm (of_real r::'a) < norm K"
   525       by simp
   526     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   527       by (rule powser_insidea)
   528     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   529       using r
   530       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   531     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   532       by (rule diffs_equiv [THEN sums_summable])
   533     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   534       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   535       apply (rule ext)
   536       apply (simp add: diffs_def)
   537       apply (case_tac n, simp_all add: r_neq_0)
   538       done
   539     finally have "summable
   540       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   541       by (rule diffs_equiv [THEN sums_summable])
   542     also have
   543       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   544            r ^ (n - Suc 0)) =
   545        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   546       apply (rule ext)
   547       apply (case_tac "n", simp)
   548       apply (case_tac "nat", simp)
   549       apply (simp add: r_neq_0)
   550       done
   551     finally show
   552       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   553   next
   554     fix h::'a and n::nat
   555     assume h: "h \<noteq> 0"
   556     assume "norm h < r - norm x"
   557     hence "norm x + norm h < r" by simp
   558     with norm_triangle_ineq have xh: "norm (x + h) < r"
   559       by (rule order_le_less_trans)
   560     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   561           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   562       apply (simp only: norm_mult mult_assoc)
   563       apply (rule mult_left_mono [OF _ norm_ge_zero])
   564       apply (simp (no_asm) add: mult_assoc [symmetric])
   565       apply (rule lemma_termdiff3)
   566       apply (rule h)
   567       apply (rule r1 [THEN order_less_imp_le])
   568       apply (rule xh [THEN order_less_imp_le])
   569       done
   570   qed
   571 qed
   572 
   573 lemma termdiffs:
   574   fixes K x :: "'a::{real_normed_field,banach}"
   575   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   576   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   577   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   578   assumes 4: "norm x < norm K"
   579   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   580 unfolding deriv_def
   581 proof (rule LIM_zero_cancel)
   582   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   583             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   584   proof (rule LIM_equal2)
   585     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   586   next
   587     fix h :: 'a
   588     assume "h \<noteq> 0"
   589     assume "norm (h - 0) < norm K - norm x"
   590     hence "norm x + norm h < norm K" by simp
   591     hence 5: "norm (x + h) < norm K"
   592       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   593     have A: "summable (\<lambda>n. c n * x ^ n)"
   594       by (rule powser_inside [OF 1 4])
   595     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   596       by (rule powser_inside [OF 1 5])
   597     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   598       by (rule powser_inside [OF 2 4])
   599     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   600              - (\<Sum>n. diffs c n * x ^ n) =
   601           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   602       apply (subst sums_unique [OF diffs_equiv [OF C]])
   603       apply (subst suminf_diff [OF B A])
   604       apply (subst suminf_divide [symmetric])
   605       apply (rule summable_diff [OF B A])
   606       apply (subst suminf_diff)
   607       apply (rule summable_divide)
   608       apply (rule summable_diff [OF B A])
   609       apply (rule sums_summable [OF diffs_equiv [OF C]])
   610       apply (rule arg_cong [where f="suminf"], rule ext)
   611       apply (simp add: algebra_simps)
   612       done
   613   next
   614     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   615                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   616         by (rule termdiffs_aux [OF 3 4])
   617   qed
   618 qed
   619 
   620 
   621 subsection {* Derivability of power series *}
   622 
   623 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   624   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   625   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   626   and "summable (f' x0)"
   627   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   628   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   629   unfolding deriv_def
   630 proof (rule LIM_I)
   631   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   632 
   633   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3"
   634     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   635 
   636   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3"
   637     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   638 
   639   let ?N = "Suc (max N_L N_f')"
   640   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   641     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   642 
   643   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   644 
   645   let ?r = "r / (3 * real ?N)"
   646   have "0 < 3 * real ?N" by auto
   647   from divide_pos_pos[OF `0 < r` this]
   648   have "0 < ?r" .
   649 
   650   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   651   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   652 
   653   have "0 < S'" unfolding S'_def
   654   proof (rule iffD2[OF Min_gr_iff])
   655     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   656     proof (rule ballI)
   657       fix x assume "x \<in> ?s ` {0..<?N}"
   658       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   659       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def]
   660       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   661       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   662       thus "0 < x" unfolding `x = ?s n` .
   663     qed
   664   qed auto
   665 
   666   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   667   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   668     by auto
   669 
   670   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   671     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   672 
   673     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   674     note div_smbl = summable_divide[OF diff_smbl]
   675     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   676     note ign = summable_ignore_initial_segment[where k="?N"]
   677     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   678     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   679     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   680 
   681     { fix n
   682       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>"
   683         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   684       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   685     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   686     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   687     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   688     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   689 
   690     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   691     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   692     proof (rule setsum_strict_mono)
   693       fix n assume "n \<in> { 0 ..< ?N}"
   694       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   695       also have "S \<le> S'" using `S \<le> S'` .
   696       also have "S' \<le> ?s n" unfolding S'_def
   697       proof (rule Min_le_iff[THEN iffD2])
   698         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   699         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   700       qed auto
   701       finally have "\<bar> x \<bar> < ?s n" .
   702 
   703       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   704       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   705       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   706       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   707     qed auto
   708     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   709     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   710     also have "\<dots> = r/3" by auto
   711     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   712 
   713     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   714     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> =
   715                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   716     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   717     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   718     also have "\<dots> < r /3 + r/3 + r/3"
   719       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3`
   720       by (rule add_strict_mono [OF add_less_le_mono])
   721     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   722       by auto
   723   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow>
   724       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   725     unfolding real_norm_def diff_0_right by blast
   726 qed
   727 
   728 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   729   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   730   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   731   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   732   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   733 proof -
   734   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   735     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   736     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   737     proof (rule DERIV_series')
   738       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   739       proof -
   740         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   741         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   742         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   743         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   744       qed
   745       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   746         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   747         proof -
   748           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>"
   749             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   750           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)"
   751           proof (rule mult_left_mono)
   752             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   753             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   754             proof (rule setsum_mono)
   755               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   756               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   757                 hence "\<bar>x\<bar> \<le> R'"  by auto
   758                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   759               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   760               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   761               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   762             qed
   763             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   764             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   765             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   766           qed
   767           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult mult_assoc[symmetric] by algebra
   768           finally show ?thesis .
   769         qed }
   770       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   771           by (auto intro!: DERIV_intros simp del: power_Suc) }
   772       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   773         have "summable (\<lambda> n. f n * x^n)"
   774         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   775           fix n
   776           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   777           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   778             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   779         qed
   780         from this[THEN summable_mult2[where c=x], unfolded mult_assoc, unfolded mult_commute]
   781         show "summable (?f x)" by auto }
   782       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   783       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   784     qed
   785   } note for_subinterval = this
   786   let ?R = "(R + \<bar>x0\<bar>) / 2"
   787   have "\<bar>x0\<bar> < ?R" using assms by auto
   788   hence "- ?R < x0"
   789   proof (cases "x0 < 0")
   790     case True
   791     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   792     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   793   next
   794     case False
   795     have "- ?R < 0" using assms by auto
   796     also have "\<dots> \<le> x0" using False by auto
   797     finally show ?thesis .
   798   qed
   799   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   800   from for_subinterval[OF this]
   801   show ?thesis .
   802 qed
   803 
   804 subsection {* Exponential Function *}
   805 
   806 definition exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   807   "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   808 
   809 lemma summable_exp_generic:
   810   fixes x :: "'a::{real_normed_algebra_1,banach}"
   811   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   812   shows "summable S"
   813 proof -
   814   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   815     unfolding S_def by (simp del: mult_Suc)
   816   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   817     using dense [OF zero_less_one] by fast
   818   obtain N :: nat where N: "norm x < real N * r"
   819     using reals_Archimedean3 [OF r0] by fast
   820   from r1 show ?thesis
   821   proof (rule ratio_test [rule_format])
   822     fix n :: nat
   823     assume n: "N \<le> n"
   824     have "norm x \<le> real N * r"
   825       using N by (rule order_less_imp_le)
   826     also have "real N * r \<le> real (Suc n) * r"
   827       using r0 n by (simp add: mult_right_mono)
   828     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   829       using norm_ge_zero by (rule mult_right_mono)
   830     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   831       by (rule order_trans [OF norm_mult_ineq])
   832     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   833       by (simp add: pos_divide_le_eq mult_ac)
   834     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   835       by (simp add: S_Suc inverse_eq_divide)
   836   qed
   837 qed
   838 
   839 lemma summable_norm_exp:
   840   fixes x :: "'a::{real_normed_algebra_1,banach}"
   841   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   842 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   843   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   844     by (rule summable_exp_generic)
   845 next
   846   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   847     by (simp add: norm_power_ineq)
   848 qed
   849 
   850 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   851 by (insert summable_exp_generic [where x=x], simp)
   852 
   853 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   854 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   855 
   856 
   857 lemma exp_fdiffs:
   858       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   859 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   860          del: mult_Suc of_nat_Suc)
   861 
   862 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   863 by (simp add: diffs_def)
   864 
   865 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   866 unfolding exp_def scaleR_conv_of_real
   867 apply (rule DERIV_cong)
   868 apply (rule termdiffs [where K="of_real (1 + norm x)"])
   869 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   870 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   871 apply (simp del: of_real_add)
   872 done
   873 
   874 lemma isCont_exp: "isCont exp x"
   875   by (rule DERIV_exp [THEN DERIV_isCont])
   876 
   877 lemma isCont_exp' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. exp (f x)) a"
   878   by (rule isCont_o2 [OF _ isCont_exp])
   879 
   880 lemma tendsto_exp [tendsto_intros]:
   881   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. exp (f x)) ---> exp a) F"
   882   by (rule isCont_tendsto_compose [OF isCont_exp])
   883 
   884 
   885 subsubsection {* Properties of the Exponential Function *}
   886 
   887 lemma powser_zero:
   888   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   889   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   890 proof -
   891   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   892     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   893   thus ?thesis unfolding One_nat_def by simp
   894 qed
   895 
   896 lemma exp_zero [simp]: "exp 0 = 1"
   897 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   898 
   899 lemma setsum_cl_ivl_Suc2:
   900   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   901 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   902          del: setsum_cl_ivl_Suc)
   903 
   904 lemma exp_series_add:
   905   fixes x y :: "'a::{real_field}"
   906   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   907   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   908 proof (induct n)
   909   case 0
   910   show ?case
   911     unfolding S_def by simp
   912 next
   913   case (Suc n)
   914   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   915     unfolding S_def by (simp del: mult_Suc)
   916   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   917     by simp
   918 
   919   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   920     by (simp only: times_S)
   921   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   922     by (simp only: Suc)
   923   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   924                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   925     by (rule left_distrib)
   926   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   927                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   928     by (simp only: setsum_right_distrib mult_ac)
   929   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   930                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   931     by (simp add: times_S Suc_diff_le)
   932   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   933              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   934     by (subst setsum_cl_ivl_Suc2, simp)
   935   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   936              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   937     by (subst setsum_cl_ivl_Suc, simp)
   938   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   939              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   940              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   941     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   942               real_of_nat_add [symmetric], simp)
   943   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   944     by (simp only: scaleR_right.setsum)
   945   finally show
   946     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   947     by (simp del: setsum_cl_ivl_Suc)
   948 qed
   949 
   950 lemma exp_add: "exp (x + y) = exp x * exp y"
   951 unfolding exp_def
   952 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   953 
   954 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   955 by (rule exp_add [symmetric])
   956 
   957 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   958 unfolding exp_def
   959 apply (subst suminf_of_real)
   960 apply (rule summable_exp_generic)
   961 apply (simp add: scaleR_conv_of_real)
   962 done
   963 
   964 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   965 proof
   966   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   967   also assume "exp x = 0"
   968   finally show "False" by simp
   969 qed
   970 
   971 lemma exp_minus: "exp (- x) = inverse (exp x)"
   972 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   973 
   974 lemma exp_diff: "exp (x - y) = exp x / exp y"
   975   unfolding diff_minus divide_inverse
   976   by (simp add: exp_add exp_minus)
   977 
   978 
   979 subsubsection {* Properties of the Exponential Function on Reals *}
   980 
   981 text {* Comparisons of @{term "exp x"} with zero. *}
   982 
   983 text{*Proof: because every exponential can be seen as a square.*}
   984 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   985 proof -
   986   have "0 \<le> exp (x/2) * exp (x/2)" by simp
   987   thus ?thesis by (simp add: exp_add [symmetric])
   988 qed
   989 
   990 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
   991 by (simp add: order_less_le)
   992 
   993 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
   994 by (simp add: not_less)
   995 
   996 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
   997 by (simp add: not_le)
   998 
   999 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
  1000 by simp
  1001 
  1002 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1003 apply (induct "n")
  1004 apply (auto simp add: real_of_nat_Suc right_distrib exp_add mult_commute)
  1005 done
  1006 
  1007 text {* Strict monotonicity of exponential. *}
  1008 
  1009 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1010 apply (drule order_le_imp_less_or_eq, auto)
  1011 apply (simp add: exp_def)
  1012 apply (rule order_trans)
  1013 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1014 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1015 done
  1016 
  1017 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1018 proof -
  1019   assume x: "0 < x"
  1020   hence "1 < 1 + x" by simp
  1021   also from x have "1 + x \<le> exp x"
  1022     by (simp add: exp_ge_add_one_self_aux)
  1023   finally show ?thesis .
  1024 qed
  1025 
  1026 lemma exp_less_mono:
  1027   fixes x y :: real
  1028   assumes "x < y" shows "exp x < exp y"
  1029 proof -
  1030   from `x < y` have "0 < y - x" by simp
  1031   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1032   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1033   thus "exp x < exp y" by simp
  1034 qed
  1035 
  1036 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1037 apply (simp add: linorder_not_le [symmetric])
  1038 apply (auto simp add: order_le_less exp_less_mono)
  1039 done
  1040 
  1041 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1042 by (auto intro: exp_less_mono exp_less_cancel)
  1043 
  1044 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1045 by (auto simp add: linorder_not_less [symmetric])
  1046 
  1047 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1048 by (simp add: order_eq_iff)
  1049 
  1050 text {* Comparisons of @{term "exp x"} with one. *}
  1051 
  1052 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1053   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1054 
  1055 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1056   using exp_less_cancel_iff [where x=x and y=0] by simp
  1057 
  1058 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1059   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1060 
  1061 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1062   using exp_le_cancel_iff [where x=x and y=0] by simp
  1063 
  1064 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1065   using exp_inj_iff [where x=x and y=0] by simp
  1066 
  1067 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1068 apply (rule IVT)
  1069 apply (auto intro: isCont_exp simp add: le_diff_eq)
  1070 apply (subgoal_tac "1 + (y - 1) \<le> exp (y - 1)")
  1071 apply simp
  1072 apply (rule exp_ge_add_one_self_aux, simp)
  1073 done
  1074 
  1075 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1076 apply (rule_tac x = 1 and y = y in linorder_cases)
  1077 apply (drule order_less_imp_le [THEN lemma_exp_total])
  1078 apply (rule_tac [2] x = 0 in exI)
  1079 apply (frule_tac [3] one_less_inverse)
  1080 apply (drule_tac [4] order_less_imp_le [THEN lemma_exp_total], auto)
  1081 apply (rule_tac x = "-x" in exI)
  1082 apply (simp add: exp_minus)
  1083 done
  1084 
  1085 
  1086 subsection {* Natural Logarithm *}
  1087 
  1088 definition ln :: "real \<Rightarrow> real" where
  1089   "ln x = (THE u. exp u = x)"
  1090 
  1091 lemma ln_exp [simp]: "ln (exp x) = x"
  1092   by (simp add: ln_def)
  1093 
  1094 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1095   by (auto dest: exp_total)
  1096 
  1097 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1098   by (metis exp_gt_zero exp_ln)
  1099 
  1100 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1101   by (erule subst, rule ln_exp)
  1102 
  1103 lemma ln_one [simp]: "ln 1 = 0"
  1104   by (rule ln_unique, simp)
  1105 
  1106 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1107   by (rule ln_unique, simp add: exp_add)
  1108 
  1109 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1110   by (rule ln_unique, simp add: exp_minus)
  1111 
  1112 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1113   by (rule ln_unique, simp add: exp_diff)
  1114 
  1115 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1116   by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1117 
  1118 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1119   by (subst exp_less_cancel_iff [symmetric], simp)
  1120 
  1121 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1122   by (simp add: linorder_not_less [symmetric])
  1123 
  1124 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1125   by (simp add: order_eq_iff)
  1126 
  1127 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1128   apply (rule exp_le_cancel_iff [THEN iffD1])
  1129   apply (simp add: exp_ge_add_one_self_aux)
  1130   done
  1131 
  1132 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1133   by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1134 
  1135 lemma ln_ge_zero [simp]: "1 \<le> x \<Longrightarrow> 0 \<le> ln x"
  1136   using ln_le_cancel_iff [of 1 x] by simp
  1137 
  1138 lemma ln_ge_zero_imp_ge_one: "\<lbrakk>0 \<le> ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 \<le> x"
  1139   using ln_le_cancel_iff [of 1 x] by simp
  1140 
  1141 lemma ln_ge_zero_iff [simp]: "0 < x \<Longrightarrow> (0 \<le> ln x) = (1 \<le> x)"
  1142   using ln_le_cancel_iff [of 1 x] by simp
  1143 
  1144 lemma ln_less_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x < 0) = (x < 1)"
  1145   using ln_less_cancel_iff [of x 1] by simp
  1146 
  1147 lemma ln_gt_zero: "1 < x \<Longrightarrow> 0 < ln x"
  1148   using ln_less_cancel_iff [of 1 x] by simp
  1149 
  1150 lemma ln_gt_zero_imp_gt_one: "\<lbrakk>0 < ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 < x"
  1151   using ln_less_cancel_iff [of 1 x] by simp
  1152 
  1153 lemma ln_gt_zero_iff [simp]: "0 < x \<Longrightarrow> (0 < ln x) = (1 < x)"
  1154   using ln_less_cancel_iff [of 1 x] by simp
  1155 
  1156 lemma ln_eq_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x = 0) = (x = 1)"
  1157   using ln_inj_iff [of x 1] by simp
  1158 
  1159 lemma ln_less_zero: "\<lbrakk>0 < x; x < 1\<rbrakk> \<Longrightarrow> ln x < 0"
  1160   by simp
  1161 
  1162 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1163   apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1164   apply (rule isCont_inverse_function [where f=exp], simp_all)
  1165   done
  1166 
  1167 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1168   apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1169   apply (erule DERIV_cong [OF DERIV_exp exp_ln])
  1170   apply (simp_all add: abs_if isCont_ln)
  1171   done
  1172 
  1173 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1174   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1175 
  1176 lemma ln_series: assumes "0 < x" and "x < 2"
  1177   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1178 proof -
  1179   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1180 
  1181   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1182   proof (rule DERIV_isconst3[where x=x])
  1183     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1184     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1185     have "1 / x = 1 / (1 - (1 - x))" by auto
  1186     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1187     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1188     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding divide_inverse by auto
  1189     moreover
  1190     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1191     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1192     proof (rule DERIV_power_series')
  1193       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1194       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1195         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1196           unfolding One_nat_def
  1197           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1198       }
  1199     qed
  1200     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1201     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1202     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1203       by (rule DERIV_diff)
  1204     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1205   qed (auto simp add: assms)
  1206   thus ?thesis by auto
  1207 qed
  1208 
  1209 subsection {* Sine and Cosine *}
  1210 
  1211 definition sin_coeff :: "nat \<Rightarrow> real" where
  1212   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1213 
  1214 definition cos_coeff :: "nat \<Rightarrow> real" where
  1215   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1216 
  1217 definition sin :: "real \<Rightarrow> real" where
  1218   "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1219 
  1220 definition cos :: "real \<Rightarrow> real" where
  1221   "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1222 
  1223 lemma sin_coeff_0 [simp]: "sin_coeff 0 = 0"
  1224   unfolding sin_coeff_def by simp
  1225 
  1226 lemma cos_coeff_0 [simp]: "cos_coeff 0 = 1"
  1227   unfolding cos_coeff_def by simp
  1228 
  1229 lemma sin_coeff_Suc: "sin_coeff (Suc n) = cos_coeff n / real (Suc n)"
  1230   unfolding cos_coeff_def sin_coeff_def
  1231   by (simp del: mult_Suc)
  1232 
  1233 lemma cos_coeff_Suc: "cos_coeff (Suc n) = - sin_coeff n / real (Suc n)"
  1234   unfolding cos_coeff_def sin_coeff_def
  1235   by (simp del: mult_Suc, auto simp add: odd_Suc_mult_two_ex)
  1236 
  1237 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1238 unfolding sin_coeff_def
  1239 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1240 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1241 done
  1242 
  1243 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1244 unfolding cos_coeff_def
  1245 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1246 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1247 done
  1248 
  1249 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1250 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1251 
  1252 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1253 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1254 
  1255 lemma diffs_sin_coeff: "diffs sin_coeff = cos_coeff"
  1256   by (simp add: diffs_def sin_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1257 
  1258 lemma diffs_cos_coeff: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1259   by (simp add: diffs_def cos_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1260 
  1261 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1262 
  1263 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1264   unfolding sin_def cos_def
  1265   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1266   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff
  1267     summable_minus summable_sin summable_cos)
  1268   done
  1269 
  1270 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1271   unfolding cos_def sin_def
  1272   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1273   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff diffs_minus
  1274     summable_minus summable_sin summable_cos suminf_minus)
  1275   done
  1276 
  1277 lemma isCont_sin: "isCont sin x"
  1278   by (rule DERIV_sin [THEN DERIV_isCont])
  1279 
  1280 lemma isCont_cos: "isCont cos x"
  1281   by (rule DERIV_cos [THEN DERIV_isCont])
  1282 
  1283 lemma isCont_sin' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. sin (f x)) a"
  1284   by (rule isCont_o2 [OF _ isCont_sin])
  1285 
  1286 lemma isCont_cos' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. cos (f x)) a"
  1287   by (rule isCont_o2 [OF _ isCont_cos])
  1288 
  1289 lemma tendsto_sin [tendsto_intros]:
  1290   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. sin (f x)) ---> sin a) F"
  1291   by (rule isCont_tendsto_compose [OF isCont_sin])
  1292 
  1293 lemma tendsto_cos [tendsto_intros]:
  1294   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. cos (f x)) ---> cos a) F"
  1295   by (rule isCont_tendsto_compose [OF isCont_cos])
  1296 
  1297 declare
  1298   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1299   DERIV_ln_divide[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1300   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1301   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1302 
  1303 subsection {* Properties of Sine and Cosine *}
  1304 
  1305 lemma sin_zero [simp]: "sin 0 = 0"
  1306   unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1307 
  1308 lemma cos_zero [simp]: "cos 0 = 1"
  1309   unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1310 
  1311 lemma sin_cos_squared_add [simp]: "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1"
  1312 proof -
  1313   have "\<forall>x. DERIV (\<lambda>x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1314     by (auto intro!: DERIV_intros)
  1315   hence "(sin x)\<twosuperior> + (cos x)\<twosuperior> = (sin 0)\<twosuperior> + (cos 0)\<twosuperior>"
  1316     by (rule DERIV_isconst_all)
  1317   thus "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1" by simp
  1318 qed
  1319 
  1320 lemma sin_cos_squared_add2 [simp]: "(cos x)\<twosuperior> + (sin x)\<twosuperior> = 1"
  1321   by (subst add_commute, rule sin_cos_squared_add)
  1322 
  1323 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1324   using sin_cos_squared_add2 [unfolded power2_eq_square] .
  1325 
  1326 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1327   unfolding eq_diff_eq by (rule sin_cos_squared_add)
  1328 
  1329 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1330   unfolding eq_diff_eq by (rule sin_cos_squared_add2)
  1331 
  1332 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1333   by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1334 
  1335 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1336   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1337 
  1338 lemma sin_le_one [simp]: "sin x \<le> 1"
  1339   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1340 
  1341 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1342   by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1343 
  1344 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1345   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1346 
  1347 lemma cos_le_one [simp]: "cos x \<le> 1"
  1348   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1349 
  1350 lemma DERIV_fun_pow: "DERIV g x :> m ==>
  1351       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1352   by (auto intro!: DERIV_intros)
  1353 
  1354 lemma DERIV_fun_exp:
  1355      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1356   by (auto intro!: DERIV_intros)
  1357 
  1358 lemma DERIV_fun_sin:
  1359      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1360   by (auto intro!: DERIV_intros)
  1361 
  1362 lemma DERIV_fun_cos:
  1363      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1364   by (auto intro!: DERIV_intros)
  1365 
  1366 lemma sin_cos_add_lemma:
  1367      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +
  1368       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1369   (is "?f x = 0")
  1370 proof -
  1371   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1372     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1373   hence "?f x = ?f 0"
  1374     by (rule DERIV_isconst_all)
  1375   thus ?thesis by simp
  1376 qed
  1377 
  1378 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1379   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1380 
  1381 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1382   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1383 
  1384 lemma sin_cos_minus_lemma:
  1385   "(sin(-x) + sin(x))\<twosuperior> + (cos(-x) - cos(x))\<twosuperior> = 0" (is "?f x = 0")
  1386 proof -
  1387   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1388     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1389   hence "?f x = ?f 0"
  1390     by (rule DERIV_isconst_all)
  1391   thus ?thesis by simp
  1392 qed
  1393 
  1394 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1395   using sin_cos_minus_lemma [where x=x] by simp
  1396 
  1397 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1398   using sin_cos_minus_lemma [where x=x] by simp
  1399 
  1400 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1401   by (simp add: diff_minus sin_add)
  1402 
  1403 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1404   by (simp add: sin_diff mult_commute)
  1405 
  1406 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1407   by (simp add: diff_minus cos_add)
  1408 
  1409 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1410   by (simp add: cos_diff mult_commute)
  1411 
  1412 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1413   using sin_add [where x=x and y=x] by simp
  1414 
  1415 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1416   using cos_add [where x=x and y=x]
  1417   by (simp add: power2_eq_square)
  1418 
  1419 
  1420 subsection {* The Constant Pi *}
  1421 
  1422 definition pi :: "real" where
  1423   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1424 
  1425 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"};
  1426    hence define pi.*}
  1427 
  1428 lemma sin_paired:
  1429      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1))
  1430       sums  sin x"
  1431 proof -
  1432   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1433     unfolding sin_def
  1434     by (rule sin_converges [THEN sums_summable, THEN sums_group], simp)
  1435   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1436 qed
  1437 
  1438 text {* FIXME: This is a long, ugly proof! *}
  1439 lemma sin_gt_zero: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1440 apply (subgoal_tac
  1441        "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2.
  1442               -1 ^ k / real (fact (2 * k + 1)) * x ^ (2 * k + 1))
  1443      sums (\<Sum>n. -1 ^ n / real (fact (2 * n + 1)) * x ^ (2 * n + 1))")
  1444  prefer 2
  1445  apply (rule sin_paired [THEN sums_summable, THEN sums_group], simp)
  1446 apply (rotate_tac 2)
  1447 apply (drule sin_paired [THEN sums_unique, THEN ssubst])
  1448 unfolding One_nat_def
  1449 apply (auto simp del: fact_Suc)
  1450 apply (frule sums_unique)
  1451 apply (auto simp del: fact_Suc)
  1452 apply (rule_tac n1 = 0 in series_pos_less [THEN [2] order_le_less_trans])
  1453 apply (auto simp del: fact_Suc)
  1454 apply (erule sums_summable)
  1455 apply (case_tac "m=0")
  1456 apply (simp (no_asm_simp))
  1457 apply (subgoal_tac "6 * (x * (x * x) / real (Suc (Suc (Suc (Suc (Suc (Suc 0))))))) < 6 * x")
  1458 apply (simp only: mult_less_cancel_left, simp)
  1459 apply (simp (no_asm_simp) add: numeral_2_eq_2 [symmetric] mult_assoc [symmetric])
  1460 apply (subgoal_tac "x*x < 2*3", simp)
  1461 apply (rule mult_strict_mono)
  1462 apply (auto simp add: real_0_less_add_iff real_of_nat_Suc simp del: fact_Suc)
  1463 apply (subst fact_Suc)
  1464 apply (subst fact_Suc)
  1465 apply (subst fact_Suc)
  1466 apply (subst fact_Suc)
  1467 apply (subst real_of_nat_mult)
  1468 apply (subst real_of_nat_mult)
  1469 apply (subst real_of_nat_mult)
  1470 apply (subst real_of_nat_mult)
  1471 apply (simp (no_asm) add: divide_inverse del: fact_Suc)
  1472 apply (auto simp add: mult_assoc [symmetric] simp del: fact_Suc)
  1473 apply (rule_tac c="real (Suc (Suc (4*m)))" in mult_less_imp_less_right)
  1474 apply (auto simp add: mult_assoc simp del: fact_Suc)
  1475 apply (rule_tac c="real (Suc (Suc (Suc (4*m))))" in mult_less_imp_less_right)
  1476 apply (auto simp add: mult_assoc mult_less_cancel_left simp del: fact_Suc)
  1477 apply (subgoal_tac "x * (x * x ^ (4*m)) = (x ^ (4*m)) * (x * x)")
  1478 apply (erule ssubst)+
  1479 apply (auto simp del: fact_Suc)
  1480 apply (subgoal_tac "0 < x ^ (4 * m) ")
  1481  prefer 2 apply (simp only: zero_less_power)
  1482 apply (simp (no_asm_simp) add: mult_less_cancel_left)
  1483 apply (rule mult_strict_mono)
  1484 apply (simp_all (no_asm_simp))
  1485 done
  1486 
  1487 lemma sin_gt_zero1: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1488   by (rule sin_gt_zero)
  1489 
  1490 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1491 apply (cut_tac x = x in sin_gt_zero)
  1492 apply (auto simp add: cos_squared_eq cos_double)
  1493 done
  1494 
  1495 lemma cos_paired:
  1496      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1497 proof -
  1498   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1499     unfolding cos_def
  1500     by (rule cos_converges [THEN sums_summable, THEN sums_group], simp)
  1501   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1502 qed
  1503 
  1504 lemma fact_lemma: "real (n::nat) * 4 = real (4 * n)"
  1505 by simp
  1506 
  1507 lemma real_mult_inverse_cancel:
  1508      "[|(0::real) < x; 0 < x1; x1 * y < x * u |]
  1509       ==> inverse x * y < inverse x1 * u"
  1510 apply (rule_tac c=x in mult_less_imp_less_left)
  1511 apply (auto simp add: mult_assoc [symmetric])
  1512 apply (simp (no_asm) add: mult_ac)
  1513 apply (rule_tac c=x1 in mult_less_imp_less_right)
  1514 apply (auto simp add: mult_ac)
  1515 done
  1516 
  1517 lemma real_mult_inverse_cancel2:
  1518      "[|(0::real) < x;0 < x1; x1 * y < x * u |] ==> y * inverse x < u * inverse x1"
  1519 apply (auto dest: real_mult_inverse_cancel simp add: mult_ac)
  1520 done
  1521 
  1522 lemma realpow_num_eq_if:
  1523   fixes m :: "'a::power"
  1524   shows "m ^ n = (if n=0 then 1 else m * m ^ (n - 1))"
  1525 by (cases n, auto)
  1526 
  1527 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1528 apply (cut_tac x = 2 in cos_paired)
  1529 apply (drule sums_minus)
  1530 apply (rule neg_less_iff_less [THEN iffD1])
  1531 apply (frule sums_unique, auto)
  1532 apply (rule_tac y =
  1533  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1534        in order_less_trans)
  1535 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1536 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1537 apply (rule sumr_pos_lt_pair)
  1538 apply (erule sums_summable, safe)
  1539 unfolding One_nat_def
  1540 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric]
  1541             del: fact_Suc)
  1542 apply (rule real_mult_inverse_cancel2)
  1543 apply (simp del: fact_Suc)
  1544 apply (simp del: fact_Suc)
  1545 apply (simp (no_asm) add: mult_assoc [symmetric] del: fact_Suc)
  1546 apply (subst fact_lemma)
  1547 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1548 apply (simp only: real_of_nat_mult)
  1549 apply (rule mult_strict_mono, force)
  1550   apply (rule_tac [3] real_of_nat_ge_zero)
  1551  prefer 2 apply force
  1552 apply (rule real_of_nat_less_iff [THEN iffD2])
  1553 apply (rule fact_less_mono_nat, auto)
  1554 done
  1555 
  1556 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1557 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1558 
  1559 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1560 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0")
  1561 apply (rule_tac [2] IVT2)
  1562 apply (auto intro: DERIV_isCont DERIV_cos)
  1563 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1564 apply (rule ccontr)
  1565 apply (subgoal_tac " (\<forall>x. cos differentiable x) & (\<forall>x. isCont cos x) ")
  1566 apply (auto intro: DERIV_cos DERIV_isCont simp add: differentiable_def)
  1567 apply (drule_tac f = cos in Rolle)
  1568 apply (drule_tac [5] f = cos in Rolle)
  1569 apply (auto dest!: DERIV_cos [THEN DERIV_unique] simp add: differentiable_def)
  1570 apply (metis order_less_le_trans less_le sin_gt_zero)
  1571 apply (metis order_less_le_trans less_le sin_gt_zero)
  1572 done
  1573 
  1574 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1575 by (simp add: pi_def)
  1576 
  1577 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1578 by (simp add: pi_half cos_is_zero [THEN theI'])
  1579 
  1580 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1581 apply (rule order_le_neq_trans)
  1582 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1583 apply (rule notI, drule arg_cong [where f=cos], simp)
  1584 done
  1585 
  1586 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1587 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1588 
  1589 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1590 apply (rule order_le_neq_trans)
  1591 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1592 apply (rule notI, drule arg_cong [where f=cos], simp)
  1593 done
  1594 
  1595 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1596 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1597 
  1598 lemma pi_gt_zero [simp]: "0 < pi"
  1599 by (insert pi_half_gt_zero, simp)
  1600 
  1601 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1602 by (rule pi_gt_zero [THEN order_less_imp_le])
  1603 
  1604 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1605 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1606 
  1607 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1608 by (simp add: linorder_not_less)
  1609 
  1610 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1611 by simp
  1612 
  1613 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1614 proof -
  1615   have "- (2 * pi) < 0" and "0 < pi" by auto
  1616   from order_less_trans[OF this] show ?thesis .
  1617 qed
  1618 
  1619 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1620 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1621 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1622 apply (simp add: power2_eq_1_iff)
  1623 done
  1624 
  1625 lemma cos_pi [simp]: "cos pi = -1"
  1626 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1627 
  1628 lemma sin_pi [simp]: "sin pi = 0"
  1629 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1630 
  1631 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1632 by (simp add: diff_minus cos_add)
  1633 declare sin_cos_eq [symmetric, simp]
  1634 
  1635 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1636 by (simp add: cos_add)
  1637 declare minus_sin_cos_eq [symmetric, simp]
  1638 
  1639 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1640 by (simp add: diff_minus sin_add)
  1641 declare cos_sin_eq [symmetric, simp]
  1642 
  1643 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1644 by (simp add: sin_add)
  1645 
  1646 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1647 by (simp add: sin_add)
  1648 
  1649 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1650 by (simp add: cos_add)
  1651 
  1652 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1653 by (simp add: sin_add cos_double)
  1654 
  1655 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1656 by (simp add: cos_add cos_double)
  1657 
  1658 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1659 apply (induct "n")
  1660 apply (auto simp add: real_of_nat_Suc left_distrib)
  1661 done
  1662 
  1663 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1664 proof -
  1665   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1666   also have "... = -1 ^ n" by (rule cos_npi)
  1667   finally show ?thesis .
  1668 qed
  1669 
  1670 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1671 apply (induct "n")
  1672 apply (auto simp add: real_of_nat_Suc left_distrib)
  1673 done
  1674 
  1675 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1676 by (simp add: mult_commute [of pi])
  1677 
  1678 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1679 by (simp add: cos_double)
  1680 
  1681 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1682 by simp
  1683 
  1684 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1685 apply (rule sin_gt_zero, assumption)
  1686 apply (rule order_less_trans, assumption)
  1687 apply (rule pi_half_less_two)
  1688 done
  1689 
  1690 lemma sin_less_zero:
  1691   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1692 proof -
  1693   have "0 < sin (- x)" using assms by (simp only: sin_gt_zero2)
  1694   thus ?thesis by simp
  1695 qed
  1696 
  1697 lemma pi_less_4: "pi < 4"
  1698 by (cut_tac pi_half_less_two, auto)
  1699 
  1700 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1701 apply (cut_tac pi_less_4)
  1702 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1703 apply (cut_tac cos_is_zero, safe)
  1704 apply (rename_tac y z)
  1705 apply (drule_tac x = y in spec)
  1706 apply (drule_tac x = "pi/2" in spec, simp)
  1707 done
  1708 
  1709 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1710 apply (rule_tac x = x and y = 0 in linorder_cases)
  1711 apply (rule cos_minus [THEN subst])
  1712 apply (rule cos_gt_zero)
  1713 apply (auto intro: cos_gt_zero)
  1714 done
  1715 
  1716 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1717 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1718 apply (subgoal_tac "x = pi/2", auto)
  1719 done
  1720 
  1721 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1722 apply (subst sin_cos_eq)
  1723 apply (rotate_tac 1)
  1724 apply (drule real_sum_of_halves [THEN ssubst])
  1725 apply (auto intro!: cos_gt_zero_pi simp del: sin_cos_eq [symmetric])
  1726 done
  1727 
  1728 
  1729 lemma pi_ge_two: "2 \<le> pi"
  1730 proof (rule ccontr)
  1731   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1732   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1733   proof (cases "2 < 2 * pi")
  1734     case True with dense[OF `pi < 2`] show ?thesis by auto
  1735   next
  1736     case False have "pi < 2 * pi" by auto
  1737     from dense[OF this] and False show ?thesis by auto
  1738   qed
  1739   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1740   hence "0 < sin y" using sin_gt_zero by auto
  1741   moreover
  1742   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1743   ultimately show False by auto
  1744 qed
  1745 
  1746 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1747 by (auto simp add: order_le_less sin_gt_zero_pi)
  1748 
  1749 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1750 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y")
  1751 apply (rule_tac [2] IVT2)
  1752 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos)
  1753 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1754 apply (rule ccontr, auto)
  1755 apply (drule_tac f = cos in Rolle)
  1756 apply (drule_tac [5] f = cos in Rolle)
  1757 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos
  1758             dest!: DERIV_cos [THEN DERIV_unique]
  1759             simp add: differentiable_def)
  1760 apply (auto dest: sin_gt_zero_pi [OF order_le_less_trans order_less_le_trans])
  1761 done
  1762 
  1763 lemma sin_total:
  1764      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1765 apply (rule ccontr)
  1766 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1767 apply (erule contrapos_np)
  1768 apply (simp del: minus_sin_cos_eq [symmetric])
  1769 apply (cut_tac y="-y" in cos_total, simp) apply simp
  1770 apply (erule ex1E)
  1771 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1772 apply (simp (no_asm) add: add_assoc)
  1773 apply (rotate_tac 3)
  1774 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all)
  1775 done
  1776 
  1777 lemma reals_Archimedean4:
  1778      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1779 apply (auto dest!: reals_Archimedean3)
  1780 apply (drule_tac x = x in spec, clarify)
  1781 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1782  prefer 2 apply (erule LeastI)
  1783 apply (case_tac "LEAST m::nat. x < real m * y", simp)
  1784 apply (subgoal_tac "~ x < real nat * y")
  1785  prefer 2 apply (rule not_less_Least, simp, force)
  1786 done
  1787 
  1788 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic
  1789    now causes some unwanted re-arrangements of literals!   *)
  1790 lemma cos_zero_lemma:
  1791      "[| 0 \<le> x; cos x = 0 |] ==>
  1792       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1793 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1794 apply (subgoal_tac "0 \<le> x - real n * pi &
  1795                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1796 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1797  prefer 2 apply (simp add: cos_diff)
  1798 apply (simp add: cos_diff)
  1799 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1800 apply (rule_tac [2] cos_total, safe)
  1801 apply (drule_tac x = "x - real n * pi" in spec)
  1802 apply (drule_tac x = "pi/2" in spec)
  1803 apply (simp add: cos_diff)
  1804 apply (rule_tac x = "Suc (2 * n)" in exI)
  1805 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1806 done
  1807 
  1808 lemma sin_zero_lemma:
  1809      "[| 0 \<le> x; sin x = 0 |] ==>
  1810       \<exists>n::nat. even n & x = real n * (pi/2)"
  1811 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1812  apply (clarify, rule_tac x = "n - 1" in exI)
  1813  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1814 apply (rule cos_zero_lemma)
  1815 apply (simp_all add: add_increasing)
  1816 done
  1817 
  1818 
  1819 lemma cos_zero_iff:
  1820      "(cos x = 0) =
  1821       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |
  1822        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1823 apply (rule iffI)
  1824 apply (cut_tac linorder_linear [of 0 x], safe)
  1825 apply (drule cos_zero_lemma, assumption+)
  1826 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp)
  1827 apply (force simp add: minus_equation_iff [of x])
  1828 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1829 apply (auto simp add: cos_add)
  1830 done
  1831 
  1832 (* ditto: but to a lesser extent *)
  1833 lemma sin_zero_iff:
  1834      "(sin x = 0) =
  1835       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |
  1836        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1837 apply (rule iffI)
  1838 apply (cut_tac linorder_linear [of 0 x], safe)
  1839 apply (drule sin_zero_lemma, assumption+)
  1840 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1841 apply (force simp add: minus_equation_iff [of x])
  1842 apply (auto simp add: even_mult_two_ex)
  1843 done
  1844 
  1845 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1846   shows "cos x < cos y"
  1847 proof -
  1848   have "- (x - y) < 0" using assms by auto
  1849 
  1850   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  1851   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  1852   hence "0 < z" and "z < pi" using assms by auto
  1853   hence "0 < sin z" using sin_gt_zero_pi by auto
  1854   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  1855   thus ?thesis by auto
  1856 qed
  1857 
  1858 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  1859 proof (cases "y < x")
  1860   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  1861 next
  1862   case False hence "y = x" using `y \<le> x` by auto
  1863   thus ?thesis by auto
  1864 qed
  1865 
  1866 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  1867   shows "cos y < cos x"
  1868 proof -
  1869   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  1870   from cos_monotone_0_pi[OF this]
  1871   show ?thesis unfolding cos_minus .
  1872 qed
  1873 
  1874 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  1875 proof (cases "y < x")
  1876   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  1877 next
  1878   case False hence "y = x" using `y \<le> x` by auto
  1879   thus ?thesis by auto
  1880 qed
  1881 
  1882 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  1883 proof -
  1884   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  1885     using pi_ge_two and assms by auto
  1886   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  1887 qed
  1888 
  1889 subsection {* Tangent *}
  1890 
  1891 definition tan :: "real \<Rightarrow> real" where
  1892   "tan = (\<lambda>x. sin x / cos x)"
  1893 
  1894 lemma tan_zero [simp]: "tan 0 = 0"
  1895   by (simp add: tan_def)
  1896 
  1897 lemma tan_pi [simp]: "tan pi = 0"
  1898   by (simp add: tan_def)
  1899 
  1900 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  1901   by (simp add: tan_def)
  1902 
  1903 lemma tan_minus [simp]: "tan (-x) = - tan x"
  1904   by (simp add: tan_def)
  1905 
  1906 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  1907   by (simp add: tan_def)
  1908 
  1909 lemma lemma_tan_add1:
  1910   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> 1 - tan x * tan y = cos (x + y)/(cos x * cos y)"
  1911   by (simp add: tan_def cos_add field_simps)
  1912 
  1913 lemma add_tan_eq:
  1914   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> tan x + tan y = sin(x + y)/(cos x * cos y)"
  1915   by (simp add: tan_def sin_add field_simps)
  1916 
  1917 lemma tan_add:
  1918      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]
  1919       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  1920   by (simp add: add_tan_eq lemma_tan_add1, simp add: tan_def)
  1921 
  1922 lemma tan_double:
  1923      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]
  1924       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  1925   using tan_add [of x x] by (simp add: power2_eq_square)
  1926 
  1927 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  1928 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi)
  1929 
  1930 lemma tan_less_zero:
  1931   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  1932 proof -
  1933   have "0 < tan (- x)" using assms by (simp only: tan_gt_zero)
  1934   thus ?thesis by simp
  1935 qed
  1936 
  1937 lemma tan_half: fixes x :: real assumes "- (pi / 2) < x" and "x < pi / 2"
  1938   shows "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  1939 proof -
  1940   from cos_gt_zero_pi[OF `- (pi / 2) < x` `x < pi / 2`]
  1941   have "cos x \<noteq> 0" by auto
  1942 
  1943   have minus_cos_2x: "\<And>X. X - cos (2*x) = X - (cos x) ^ 2 + (sin x) ^ 2" unfolding cos_double by algebra
  1944 
  1945   have "tan x = (tan x + tan x) / 2" by auto
  1946   also have "\<dots> = sin (x + x) / (cos x * cos x) / 2" unfolding add_tan_eq[OF `cos x \<noteq> 0` `cos x \<noteq> 0`] ..
  1947   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + (cos x) ^ 2 + cos (2*x) - cos (2*x))" unfolding divide_divide_eq_left numeral_2_eq_2 by auto
  1948   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + cos (2*x) + (sin x)^2)" unfolding minus_cos_2x by auto
  1949   also have "\<dots> = sin (2 * x) / (cos (2*x) + 1)" by auto
  1950   finally show ?thesis .
  1951 qed
  1952 
  1953 lemma DERIV_tan [simp]: "cos x \<noteq> 0 \<Longrightarrow> DERIV tan x :> inverse ((cos x)\<twosuperior>)"
  1954   unfolding tan_def
  1955   by (auto intro!: DERIV_intros, simp add: divide_inverse power2_eq_square)
  1956 
  1957 lemma isCont_tan: "cos x \<noteq> 0 \<Longrightarrow> isCont tan x"
  1958   by (rule DERIV_tan [THEN DERIV_isCont])
  1959 
  1960 lemma isCont_tan' [simp]:
  1961   "\<lbrakk>isCont f a; cos (f a) \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. tan (f x)) a"
  1962   by (rule isCont_o2 [OF _ isCont_tan])
  1963 
  1964 lemma tendsto_tan [tendsto_intros]:
  1965   "\<lbrakk>(f ---> a) F; cos a \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. tan (f x)) ---> tan a) F"
  1966   by (rule isCont_tendsto_compose [OF isCont_tan])
  1967 
  1968 lemma LIM_cos_div_sin: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  1969   by (rule LIM_cong_limit, (rule tendsto_intros)+, simp_all)
  1970 
  1971 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  1972 apply (cut_tac LIM_cos_div_sin)
  1973 apply (simp only: LIM_eq)
  1974 apply (drule_tac x = "inverse y" in spec, safe, force)
  1975 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  1976 apply (rule_tac x = "(pi/2) - e" in exI)
  1977 apply (simp (no_asm_simp))
  1978 apply (drule_tac x = "(pi/2) - e" in spec)
  1979 apply (auto simp add: tan_def)
  1980 apply (rule inverse_less_iff_less [THEN iffD1])
  1981 apply (auto simp add: divide_inverse)
  1982 apply (rule mult_pos_pos)
  1983 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  1984 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute)
  1985 done
  1986 
  1987 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  1988 apply (frule order_le_imp_less_or_eq, safe)
  1989  prefer 2 apply force
  1990 apply (drule lemma_tan_total, safe)
  1991 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  1992 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  1993 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  1994 apply (auto dest: cos_gt_zero)
  1995 done
  1996 
  1997 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  1998 apply (cut_tac linorder_linear [of 0 y], safe)
  1999 apply (drule tan_total_pos)
  2000 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2001 apply (rule_tac [3] x = "-x" in exI)
  2002 apply (auto intro!: exI)
  2003 done
  2004 
  2005 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2006 apply (cut_tac y = y in lemma_tan_total1, auto)
  2007 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2008 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2009 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2010 apply (rule_tac [4] Rolle)
  2011 apply (rule_tac [2] Rolle)
  2012 apply (auto intro!: DERIV_tan DERIV_isCont exI
  2013             simp add: differentiable_def)
  2014 txt{*Now, simulate TRYALL*}
  2015 apply (rule_tac [!] DERIV_tan asm_rl)
  2016 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2017             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym])
  2018 done
  2019 
  2020 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2021   shows "tan y < tan x"
  2022 proof -
  2023   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2024   proof (rule allI, rule impI)
  2025     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2026     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  2027     from cos_gt_zero_pi[OF this]
  2028     have "cos x' \<noteq> 0" by auto
  2029     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2030   qed
  2031   from MVT2[OF `y < x` this]
  2032   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2033   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  2034   hence "0 < cos z" using cos_gt_zero_pi by auto
  2035   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2036   have "0 < x - y" using `y < x` by auto
  2037   from mult_pos_pos [OF this inv_pos]
  2038   have "0 < tan x - tan y" unfolding tan_diff by auto
  2039   thus ?thesis by auto
  2040 qed
  2041 
  2042 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2043   shows "(y < x) = (tan y < tan x)"
  2044 proof
  2045   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2046 next
  2047   assume "tan y < tan x"
  2048   show "y < x"
  2049   proof (rule ccontr)
  2050     assume "\<not> y < x" hence "x \<le> y" by auto
  2051     hence "tan x \<le> tan y"
  2052     proof (cases "x = y")
  2053       case True thus ?thesis by auto
  2054     next
  2055       case False hence "x < y" using `x \<le> y` by auto
  2056       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2057     qed
  2058     thus False using `tan y < tan x` by auto
  2059   qed
  2060 qed
  2061 
  2062 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2063 
  2064 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x"
  2065   by (simp add: tan_def)
  2066 
  2067 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x"
  2068 proof (induct n arbitrary: x)
  2069   case (Suc n)
  2070   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one left_distrib by auto
  2071   show ?case unfolding split_pi_off using Suc by auto
  2072 qed auto
  2073 
  2074 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2075 proof (cases "0 \<le> i")
  2076   case True hence i_nat: "real i = real (nat i)" by auto
  2077   show ?thesis unfolding i_nat by auto
  2078 next
  2079   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2080   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2081   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2082   finally show ?thesis by auto
  2083 qed
  2084 
  2085 lemma tan_periodic_n[simp]: "tan (x + number_of n * pi) = tan x"
  2086   using tan_periodic_int[of _ "number_of n" ] unfolding real_number_of .
  2087 
  2088 subsection {* Inverse Trigonometric Functions *}
  2089 
  2090 definition
  2091   arcsin :: "real => real" where
  2092   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2093 
  2094 definition
  2095   arccos :: "real => real" where
  2096   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2097 
  2098 definition
  2099   arctan :: "real => real" where
  2100   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2101 
  2102 lemma arcsin:
  2103      "[| -1 \<le> y; y \<le> 1 |]
  2104       ==> -(pi/2) \<le> arcsin y &
  2105            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2106 unfolding arcsin_def by (rule theI' [OF sin_total])
  2107 
  2108 lemma arcsin_pi:
  2109      "[| -1 \<le> y; y \<le> 1 |]
  2110       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2111 apply (drule (1) arcsin)
  2112 apply (force intro: order_trans)
  2113 done
  2114 
  2115 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2116 by (blast dest: arcsin)
  2117 
  2118 lemma arcsin_bounded:
  2119      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2120 by (blast dest: arcsin)
  2121 
  2122 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2123 by (blast dest: arcsin)
  2124 
  2125 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2126 by (blast dest: arcsin)
  2127 
  2128 lemma arcsin_lt_bounded:
  2129      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2130 apply (frule order_less_imp_le)
  2131 apply (frule_tac y = y in order_less_imp_le)
  2132 apply (frule arcsin_bounded)
  2133 apply (safe, simp)
  2134 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2135 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2136 apply (drule_tac [!] f = sin in arg_cong, auto)
  2137 done
  2138 
  2139 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2140 apply (unfold arcsin_def)
  2141 apply (rule the1_equality)
  2142 apply (rule sin_total, auto)
  2143 done
  2144 
  2145 lemma arccos:
  2146      "[| -1 \<le> y; y \<le> 1 |]
  2147       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2148 unfolding arccos_def by (rule theI' [OF cos_total])
  2149 
  2150 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2151 by (blast dest: arccos)
  2152 
  2153 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2154 by (blast dest: arccos)
  2155 
  2156 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2157 by (blast dest: arccos)
  2158 
  2159 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2160 by (blast dest: arccos)
  2161 
  2162 lemma arccos_lt_bounded:
  2163      "[| -1 < y; y < 1 |]
  2164       ==> 0 < arccos y & arccos y < pi"
  2165 apply (frule order_less_imp_le)
  2166 apply (frule_tac y = y in order_less_imp_le)
  2167 apply (frule arccos_bounded, auto)
  2168 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2169 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2170 apply (drule_tac [!] f = cos in arg_cong, auto)
  2171 done
  2172 
  2173 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2174 apply (simp add: arccos_def)
  2175 apply (auto intro!: the1_equality cos_total)
  2176 done
  2177 
  2178 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2179 apply (simp add: arccos_def)
  2180 apply (auto intro!: the1_equality cos_total)
  2181 done
  2182 
  2183 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2184 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2185 apply (rule power2_eq_imp_eq)
  2186 apply (simp add: cos_squared_eq)
  2187 apply (rule cos_ge_zero)
  2188 apply (erule (1) arcsin_lbound)
  2189 apply (erule (1) arcsin_ubound)
  2190 apply simp
  2191 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2192 apply (rule power_mono, simp, simp)
  2193 done
  2194 
  2195 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2196 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2197 apply (rule power2_eq_imp_eq)
  2198 apply (simp add: sin_squared_eq)
  2199 apply (rule sin_ge_zero)
  2200 apply (erule (1) arccos_lbound)
  2201 apply (erule (1) arccos_ubound)
  2202 apply simp
  2203 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2204 apply (rule power_mono, simp, simp)
  2205 done
  2206 
  2207 lemma arctan [simp]:
  2208      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2209 unfolding arctan_def by (rule theI' [OF tan_total])
  2210 
  2211 lemma tan_arctan: "tan(arctan y) = y"
  2212 by auto
  2213 
  2214 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2215 by (auto simp only: arctan)
  2216 
  2217 lemma arctan_lbound: "- (pi/2) < arctan y"
  2218 by auto
  2219 
  2220 lemma arctan_ubound: "arctan y < pi/2"
  2221 by (auto simp only: arctan)
  2222 
  2223 lemma arctan_tan:
  2224       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2225 apply (unfold arctan_def)
  2226 apply (rule the1_equality)
  2227 apply (rule tan_total, auto)
  2228 done
  2229 
  2230 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2231 by (insert arctan_tan [of 0], simp)
  2232 
  2233 lemma cos_arctan_not_zero [simp]: "cos(arctan x) \<noteq> 0"
  2234 apply (auto simp add: cos_zero_iff)
  2235 apply (case_tac "n")
  2236 apply (case_tac [3] "n")
  2237 apply (cut_tac [2] y = x in arctan_ubound)
  2238 apply (cut_tac [4] y = x in arctan_lbound)
  2239 apply (auto simp add: real_of_nat_Suc left_distrib mult_less_0_iff)
  2240 done
  2241 
  2242 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2243 apply (rule power_inverse [THEN subst])
  2244 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2245 apply (auto dest: field_power_not_zero
  2246         simp add: power_mult_distrib left_distrib power_divide tan_def
  2247                   mult_assoc power_inverse [symmetric])
  2248 done
  2249 
  2250 lemma isCont_inverse_function2:
  2251   fixes f g :: "real \<Rightarrow> real" shows
  2252   "\<lbrakk>a < x; x < b;
  2253     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2254     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2255    \<Longrightarrow> isCont g (f x)"
  2256 apply (rule isCont_inverse_function
  2257        [where f=f and d="min (x - a) (b - x)"])
  2258 apply (simp_all add: abs_le_iff)
  2259 done
  2260 
  2261 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2262 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2263 apply (rule isCont_inverse_function2 [where f=sin])
  2264 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2265 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2266 apply (fast intro: arcsin_sin, simp)
  2267 done
  2268 
  2269 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2270 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2271 apply (rule isCont_inverse_function2 [where f=cos])
  2272 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2273 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2274 apply (fast intro: arccos_cos, simp)
  2275 done
  2276 
  2277 lemma isCont_arctan: "isCont arctan x"
  2278 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2279 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2280 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2281 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2282 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  2283 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans less_le)
  2284 done
  2285 
  2286 lemma DERIV_arcsin:
  2287   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2288 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2289 apply (rule DERIV_cong [OF DERIV_sin])
  2290 apply (simp add: cos_arcsin)
  2291 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2292 apply (rule power_strict_mono, simp, simp, simp)
  2293 apply assumption
  2294 apply assumption
  2295 apply simp
  2296 apply (erule (1) isCont_arcsin)
  2297 done
  2298 
  2299 lemma DERIV_arccos:
  2300   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2301 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2302 apply (rule DERIV_cong [OF DERIV_cos])
  2303 apply (simp add: sin_arccos)
  2304 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2305 apply (rule power_strict_mono, simp, simp, simp)
  2306 apply assumption
  2307 apply assumption
  2308 apply simp
  2309 apply (erule (1) isCont_arccos)
  2310 done
  2311 
  2312 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2313 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2314 apply (rule DERIV_cong [OF DERIV_tan])
  2315 apply (rule cos_arctan_not_zero)
  2316 apply (simp add: power_inverse tan_sec [symmetric])
  2317 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2318 apply (simp add: add_pos_nonneg)
  2319 apply (simp, simp, simp, rule isCont_arctan)
  2320 done
  2321 
  2322 declare
  2323   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2324   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2325   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2326 
  2327 subsection {* More Theorems about Sin and Cos *}
  2328 
  2329 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2330 proof -
  2331   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2332   have nonneg: "0 \<le> ?c"
  2333     by (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2334   have "0 = cos (pi / 4 + pi / 4)"
  2335     by simp
  2336   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2337     by (simp only: cos_add power2_eq_square)
  2338   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2339     by (simp add: sin_squared_eq)
  2340   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2341     by (simp add: power_divide)
  2342   thus ?thesis
  2343     using nonneg by (rule power2_eq_imp_eq) simp
  2344 qed
  2345 
  2346 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2347 proof -
  2348   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2349   have pos_c: "0 < ?c"
  2350     by (rule cos_gt_zero, simp, simp)
  2351   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2352     by simp
  2353   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2354     by (simp only: cos_add sin_add)
  2355   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2356     by (simp add: algebra_simps power2_eq_square)
  2357   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2358     using pos_c by (simp add: sin_squared_eq power_divide)
  2359   thus ?thesis
  2360     using pos_c [THEN order_less_imp_le]
  2361     by (rule power2_eq_imp_eq) simp
  2362 qed
  2363 
  2364 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2365 proof -
  2366   have "sin (pi / 4) = cos (pi / 2 - pi / 4)" by (rule sin_cos_eq)
  2367   also have "pi / 2 - pi / 4 = pi / 4" by simp
  2368   also have "cos (pi / 4) = sqrt 2 / 2" by (rule cos_45)
  2369   finally show ?thesis .
  2370 qed
  2371 
  2372 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2373 proof -
  2374   have "sin (pi / 3) = cos (pi / 2 - pi / 3)" by (rule sin_cos_eq)
  2375   also have "pi / 2 - pi / 3 = pi / 6" by simp
  2376   also have "cos (pi / 6) = sqrt 3 / 2" by (rule cos_30)
  2377   finally show ?thesis .
  2378 qed
  2379 
  2380 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2381 apply (rule power2_eq_imp_eq)
  2382 apply (simp add: cos_squared_eq sin_60 power_divide)
  2383 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2384 done
  2385 
  2386 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2387 proof -
  2388   have "sin (pi / 6) = cos (pi / 2 - pi / 6)" by (rule sin_cos_eq)
  2389   also have "pi / 2 - pi / 6 = pi / 3" by simp
  2390   also have "cos (pi / 3) = 1 / 2" by (rule cos_60)
  2391   finally show ?thesis .
  2392 qed
  2393 
  2394 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2395 unfolding tan_def by (simp add: sin_30 cos_30)
  2396 
  2397 lemma tan_45: "tan (pi / 4) = 1"
  2398 unfolding tan_def by (simp add: sin_45 cos_45)
  2399 
  2400 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2401 unfolding tan_def by (simp add: sin_60 cos_60)
  2402 
  2403 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2404 proof -
  2405   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2406     by (auto simp add: algebra_simps sin_add)
  2407   thus ?thesis
  2408     by (simp add: real_of_nat_Suc left_distrib add_divide_distrib
  2409                   mult_commute [of pi])
  2410 qed
  2411 
  2412 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2413 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2414 
  2415 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2416 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2417 apply (subst cos_add, simp)
  2418 done
  2419 
  2420 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2421 by (auto simp add: mult_assoc)
  2422 
  2423 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2424 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2425 apply (subst sin_add, simp)
  2426 done
  2427 
  2428 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2429 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib add_divide_distrib, auto)
  2430 
  2431 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2432   by (auto intro!: DERIV_intros)
  2433 
  2434 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2435 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2436 
  2437 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2438 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2439 
  2440 subsection {* Machins formula *}
  2441 
  2442 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2443   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2444 proof -
  2445   obtain z where "- (pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  2446   have "tan (pi / 4) = 1" and "tan (- (pi / 4)) = - 1" using tan_45 tan_minus by auto
  2447   have "z \<noteq> pi / 4"
  2448   proof (rule ccontr)
  2449     assume "\<not> (z \<noteq> pi / 4)" hence "z = pi / 4" by auto
  2450     have "tan z = 1" unfolding `z = pi / 4` `tan (pi / 4) = 1` ..
  2451     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2452   qed
  2453   have "z \<noteq> - (pi / 4)"
  2454   proof (rule ccontr)
  2455     assume "\<not> (z \<noteq> - (pi / 4))" hence "z = - (pi / 4)" by auto
  2456     have "tan z = - 1" unfolding `z = - (pi / 4)` `tan (- (pi / 4)) = - 1` ..
  2457     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2458   qed
  2459 
  2460   have "z < pi / 4"
  2461   proof (rule ccontr)
  2462     assume "\<not> (z < pi / 4)" hence "pi / 4 < z" using `z \<noteq> pi / 4` by auto
  2463     have "- (pi / 2) < pi / 4" using m2pi_less_pi by auto
  2464     from tan_monotone[OF this `pi / 4 < z` `z < pi / 2`]
  2465     have "1 < x" unfolding `tan z = x` `tan (pi / 4) = 1` .
  2466     thus False using `\<bar>x\<bar> < 1` by auto
  2467   qed
  2468   moreover
  2469   have "-(pi / 4) < z"
  2470   proof (rule ccontr)
  2471     assume "\<not> (-(pi / 4) < z)" hence "z < - (pi / 4)" using `z \<noteq> - (pi / 4)` by auto
  2472     have "-(pi / 4) < pi / 2" using m2pi_less_pi by auto
  2473     from tan_monotone[OF `-(pi / 2) < z` `z < -(pi / 4)` this]
  2474     have "x < - 1" unfolding `tan z = x` `tan (-(pi / 4)) = - 1` .
  2475     thus False using `\<bar>x\<bar> < 1` by auto
  2476   qed
  2477   ultimately show ?thesis using `tan z = x` by auto
  2478 qed
  2479 
  2480 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2481   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2482 proof -
  2483   obtain y' where "-(pi/4) < y'" and "y' < pi/4" and "tan y' = y" using tan_total_pi4[OF `\<bar>y\<bar> < 1`] by blast
  2484 
  2485   have "pi / 4 < pi / 2" by auto
  2486 
  2487   have "\<exists> x'. -(pi/4) \<le> x' \<and> x' \<le> pi/4 \<and> tan x' = x"
  2488   proof (cases "\<bar>x\<bar> < 1")
  2489     case True from tan_total_pi4[OF this] obtain x' where "-(pi/4) < x'" and "x' < pi/4" and "tan x' = x" by blast
  2490     hence "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by auto
  2491     thus ?thesis by auto
  2492   next
  2493     case False
  2494     show ?thesis
  2495     proof (cases "x = 1")
  2496       case True hence "tan (pi/4) = x" using tan_45 by auto
  2497       moreover
  2498       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2499       hence "-(pi/4) \<le> pi/4" and "pi/4 \<le> pi/4" by auto
  2500       ultimately show ?thesis by blast
  2501     next
  2502       case False hence "x = -1" using `\<not> \<bar>x\<bar> < 1` and `\<bar>x\<bar> \<le> 1` by auto
  2503       hence "tan (-(pi/4)) = x" using tan_45 tan_minus by auto
  2504       moreover
  2505       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2506       hence "-(pi/4) \<le> pi/4" and "-(pi/4) \<le> -(pi/4)" by auto
  2507       ultimately show ?thesis by blast
  2508     qed
  2509   qed
  2510   then obtain x' where "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by blast
  2511   hence "-(pi/2) < x'" and "x' < pi/2" using order_le_less_trans[OF `x' \<le> pi/4` `pi / 4 < pi / 2`] by auto
  2512 
  2513   have "cos x' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/2) < x'` and `x' < pi/2` by auto
  2514   moreover have "cos y' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/4) < y'` and `y' < pi/4` by auto
  2515   ultimately have "cos x' * cos y' \<noteq> 0" by auto
  2516 
  2517   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> (A / C) / (B / C) = A / B" by auto
  2518   have divide_mult_commute: "\<And> A B C D :: real. A * B / (C * D) = (A / C) * (B / D)" by auto
  2519 
  2520   have "tan (x' + y') = sin (x' + y') / (cos x' * cos y' - sin x' * sin y')" unfolding tan_def cos_add ..
  2521   also have "\<dots> = (tan x' + tan y') / ((cos x' * cos y' - sin x' * sin y') / (cos x' * cos y'))" unfolding add_tan_eq[OF `cos x' \<noteq> 0` `cos y' \<noteq> 0`] divide_nonzero_divide[OF `cos x' * cos y' \<noteq> 0`] ..
  2522   also have "\<dots> = (tan x' + tan y') / (1 - tan x' * tan y')" unfolding tan_def diff_divide_distrib divide_self[OF `cos x' * cos y' \<noteq> 0`] unfolding divide_mult_commute ..
  2523   finally have tan_eq: "tan (x' + y') = (x + y) / (1 - x * y)" unfolding `tan y' = y` `tan x' = x` .
  2524 
  2525   have "arctan (tan (x' + y')) = x' + y'" using `-(pi/4) < y'` `-(pi/4) \<le> x'` `y' < pi/4` and `x' \<le> pi/4` by (auto intro!: arctan_tan)
  2526   moreover have "arctan (tan (x')) = x'" using `-(pi/2) < x'` and `x' < pi/2` by (auto intro!: arctan_tan)
  2527   moreover have "arctan (tan (y')) = y'" using `-(pi/4) < y'` and `y' < pi/4` by (auto intro!: arctan_tan)
  2528   ultimately have "arctan x + arctan y = arctan (tan (x' + y'))" unfolding `tan y' = y` [symmetric] `tan x' = x`[symmetric] by auto
  2529   thus "arctan x + arctan y = arctan ((x + y) / (1 - x * y))" unfolding tan_eq .
  2530 qed
  2531 
  2532 lemma arctan1_eq_pi4: "arctan 1 = pi / 4" unfolding tan_45[symmetric] by (rule arctan_tan, auto simp add: m2pi_less_pi)
  2533 
  2534 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2535 proof -
  2536   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2537   from arctan_add[OF less_imp_le[OF this] this]
  2538   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2539   moreover
  2540   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2541   from arctan_add[OF less_imp_le[OF this] this]
  2542   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2543   moreover
  2544   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2545   from arctan_add[OF this]
  2546   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2547   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2548   thus ?thesis unfolding arctan1_eq_pi4 by algebra
  2549 qed
  2550 subsection {* Introducing the arcus tangens power series *}
  2551 
  2552 lemma monoseq_arctan_series: fixes x :: real
  2553   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2554 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2555 next
  2556   case False
  2557   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2558   show "monoseq ?a"
  2559   proof -
  2560     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2561       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2562       proof (rule mult_mono)
  2563         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2564         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2565         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2566         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2567       qed
  2568     } note mono = this
  2569 
  2570     show ?thesis
  2571     proof (cases "0 \<le> x")
  2572       case True from mono[OF this `x \<le> 1`, THEN allI]
  2573       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2574     next
  2575       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2576       from mono[OF this]
  2577       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2578       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2579     qed
  2580   qed
  2581 qed
  2582 
  2583 lemma zeroseq_arctan_series: fixes x :: real
  2584   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2585 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: LIMSEQ_const)
  2586 next
  2587   case False
  2588   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2589   show "?a ----> 0"
  2590   proof (cases "\<bar>x\<bar> < 1")
  2591     case True hence "norm x < 1" by auto
  2592     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2593     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2594       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2595     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2596   next
  2597     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2598     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2599     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] LIMSEQ_const[of x]]
  2600     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2601   qed
  2602 qed
  2603 
  2604 lemma summable_arctan_series: fixes x :: real and n :: nat
  2605   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2606   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2607 
  2608 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2609 proof -
  2610   from mult_left_mono[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2611   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2612   thus ?thesis using zero_le_power2 by auto
  2613 qed
  2614 
  2615 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2616   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2617 proof -
  2618   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2619 
  2620   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2621   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2622 
  2623   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2624     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2625       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2626     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2627   } note summable_Integral = this
  2628 
  2629   { fix f :: "nat \<Rightarrow> real"
  2630     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2631     proof
  2632       fix x :: real assume "f sums x"
  2633       from sums_if[OF sums_zero this]
  2634       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2635     next
  2636       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2637       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2638       show "f sums x" unfolding sums_def by auto
  2639     qed
  2640     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2641   } note sums_even = this
  2642 
  2643   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2644     by auto
  2645 
  2646   { fix x :: real
  2647     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n =
  2648       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2649       using n_even by auto
  2650     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto
  2651     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2652       by auto
  2653   } note arctan_eq = this
  2654 
  2655   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2656   proof (rule DERIV_power_series')
  2657     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2658     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2659       hence "\<bar>x'\<bar> < 1" by auto
  2660 
  2661       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2662       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2663         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2664     }
  2665   qed auto
  2666   thus ?thesis unfolding Int_eq arctan_eq .
  2667 qed
  2668 
  2669 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2670   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2671 proof -
  2672   let "?c' x n" = "(-1)^n * x^(n*2)"
  2673 
  2674   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2675     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2676     from DERIV_arctan_series[OF this]
  2677     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2678   } note DERIV_arctan_suminf = this
  2679 
  2680   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2681   note arctan_series_borders = this
  2682 
  2683   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2684   proof -
  2685     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2686     hence "0 < r" and "-r < x" and "x < r" by auto
  2687 
  2688     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2689     proof -
  2690       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2691       hence "\<bar>x\<bar> < r" by auto
  2692       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2693       proof (rule DERIV_isconst2[of "a" "b"])
  2694         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2695         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2696         proof (rule allI, rule impI)
  2697           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2698           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2699           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2700           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2701           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2702           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2703           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2704             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2705           from DERIV_add_minus[OF this DERIV_arctan]
  2706           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2707         qed
  2708         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2709         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2710         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2711       qed
  2712     qed
  2713 
  2714     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2715       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2716 
  2717     have "suminf (?c x) - arctan x = 0"
  2718     proof (cases "x = 0")
  2719       case True thus ?thesis using suminf_arctan_zero by auto
  2720     next
  2721       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2722       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2723         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  2724           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2725       moreover
  2726       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2727         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  2728           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2729       ultimately
  2730       show ?thesis using suminf_arctan_zero by auto
  2731     qed
  2732     thus ?thesis by auto
  2733   qed } note when_less_one = this
  2734 
  2735   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2736   proof (cases "\<bar>x\<bar> < 1")
  2737     case True thus ?thesis by (rule when_less_one)
  2738   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2739     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2740     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2741     { fix n :: nat
  2742       have "0 < (1 :: real)" by auto
  2743       moreover
  2744       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2745         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2746         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2747         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2748         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2749         have "?diff x n \<le> ?a x n"
  2750         proof (cases "even n")
  2751           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2752           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2753           from bounds[of m, unfolded this atLeastAtMost_iff]
  2754           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2755           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2756           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2757           finally show ?thesis .
  2758         next
  2759           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2760           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2761           hence m_plus: "2 * (m + 1) = n + 1" by auto
  2762           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2763           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2764           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2765           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2766           finally show ?thesis .
  2767         qed
  2768         hence "0 \<le> ?a x n - ?diff x n" by auto
  2769       }
  2770       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2771       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2772         unfolding diff_minus divide_inverse
  2773         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2774       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2775       hence "?diff 1 n \<le> ?a 1 n" by auto
  2776     }
  2777     have "?a 1 ----> 0"
  2778       unfolding LIMSEQ_rabs_zero power_one divide_inverse One_nat_def
  2779       by (auto intro!: LIMSEQ_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2780     have "?diff 1 ----> 0"
  2781     proof (rule LIMSEQ_I)
  2782       fix r :: real assume "0 < r"
  2783       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2784       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2785         have "norm (?diff 1 n - 0) < r" by auto }
  2786       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2787     qed
  2788     from this[unfolded LIMSEQ_rabs_zero diff_minus add_commute[of "arctan 1"], THEN LIMSEQ_add_const, of "- arctan 1", THEN LIMSEQ_minus]
  2789     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2790     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2791 
  2792     show ?thesis
  2793     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2794       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2795 
  2796       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2797       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2798 
  2799       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2800 
  2801       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2802       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2803       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2804       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2805       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2806       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2807       finally show ?thesis using `x = -1` by auto
  2808     qed
  2809   qed
  2810 qed
  2811 
  2812 lemma arctan_half: fixes x :: real
  2813   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  2814 proof -
  2815   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  2816   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  2817 
  2818   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  2819 
  2820   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  2821   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  2822 
  2823   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  2824   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  2825   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  2826   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  2827 
  2828   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  2829   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  2830   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  2831   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  2832   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  2833 
  2834   have "arctan x = y" using arctan_tan low high y_eq by auto
  2835   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  2836   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half[OF low2 high2] by auto
  2837   finally show ?thesis unfolding eq `tan y = x` .
  2838 qed
  2839 
  2840 lemma arctan_monotone: assumes "x < y"
  2841   shows "arctan x < arctan y"
  2842 proof -
  2843   obtain z where "-(pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  2844   obtain w where "-(pi / 2) < w" and "w < pi / 2" and "tan w = y" using tan_total by blast
  2845   have "z < w" unfolding tan_monotone'[OF `-(pi / 2) < z` `z < pi / 2` `-(pi / 2) < w` `w < pi / 2`] `tan z = x` `tan w = y` using `x < y` .
  2846   thus ?thesis
  2847     unfolding `tan z = x`[symmetric] arctan_tan[OF `-(pi / 2) < z` `z < pi / 2`]
  2848     unfolding `tan w = y`[symmetric] arctan_tan[OF `-(pi / 2) < w` `w < pi / 2`] .
  2849 qed
  2850 
  2851 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  2852 proof (cases "x = y")
  2853   case False hence "x < y" using `x \<le> y` by auto from arctan_monotone[OF this] show ?thesis by auto
  2854 qed auto
  2855 
  2856 lemma arctan_minus: "arctan (- x) = - arctan x"
  2857 proof -
  2858   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  2859   thus ?thesis unfolding `tan y = x`[symmetric] tan_minus[symmetric] using arctan_tan[of y] arctan_tan[of "-y"] by auto
  2860 qed
  2861 
  2862 lemma arctan_inverse: assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  2863 proof -
  2864   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  2865   hence "y = arctan x" unfolding `tan y = x`[symmetric] using arctan_tan by auto
  2866 
  2867   { fix y x :: real assume "0 < y" and "y < pi /2" and "y = arctan x" and "tan y = x" hence "- (pi / 2) < y" by auto
  2868     have "tan y > 0" using tan_monotone'[OF _ _ `- (pi / 2) < y` `y < pi / 2`, of 0] tan_zero `0 < y` by auto
  2869     hence "x > 0" using `tan y = x` by auto
  2870 
  2871     have "- (pi / 2) < pi / 2 - y" using `y > 0` `y < pi / 2` by auto
  2872     moreover have "pi / 2 - y < pi / 2" using `y > 0` `y < pi / 2` by auto
  2873     ultimately have "arctan (1 / x) = pi / 2 - y" unfolding `tan y = x`[symmetric] tan_inverse using arctan_tan by auto
  2874     hence "arctan (1 / x) = sgn x * pi / 2 - arctan x" unfolding `y = arctan x` real_sgn_pos[OF `x > 0`] by auto
  2875   } note pos_y = this
  2876 
  2877   show ?thesis
  2878   proof (cases "y > 0")
  2879     case True from pos_y[OF this `y < pi / 2` `y = arctan x` `tan y = x`] show ?thesis .
  2880   next
  2881     case False hence "y \<le> 0" by auto
  2882     moreover have "y \<noteq> 0"
  2883     proof (rule ccontr)
  2884       assume "\<not> y \<noteq> 0" hence "y = 0" by auto
  2885       have "x = 0" unfolding `tan y = x`[symmetric] `y = 0` tan_zero ..
  2886       thus False using `x \<noteq> 0` by auto
  2887     qed
  2888     ultimately have "y < 0" by auto
  2889     hence "0 < - y" and "-y < pi / 2" using `- (pi / 2) < y` by auto
  2890     moreover have "-y = arctan (-x)" unfolding arctan_minus `y = arctan x` ..
  2891     moreover have "tan (-y) = -x" unfolding tan_minus `tan y = x` ..
  2892     ultimately have "arctan (1 / -x) = sgn (-x) * pi / 2 - arctan (-x)" using pos_y by blast
  2893     hence "arctan (- (1 / x)) = - (sgn x * pi / 2 - arctan x)" unfolding arctan_minus[of x] divide_minus_right sgn_minus by auto
  2894     thus ?thesis unfolding arctan_minus neg_equal_iff_equal .
  2895   qed
  2896 qed
  2897 
  2898 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  2899 proof -
  2900   have "pi / 4 = arctan 1" using arctan1_eq_pi4 by auto
  2901   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  2902   finally show ?thesis by auto
  2903 qed
  2904 
  2905 subsection {* Existence of Polar Coordinates *}
  2906 
  2907 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  2908 apply (rule power2_le_imp_le [OF _ zero_le_one])
  2909 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  2910 done
  2911 
  2912 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  2913 by (simp add: abs_le_iff)
  2914 
  2915 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  2916 by (simp add: sin_arccos abs_le_iff)
  2917 
  2918 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  2919 
  2920 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  2921 
  2922 lemma polar_ex1:
  2923      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  2924 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  2925 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  2926 apply (simp add: cos_arccos_lemma1)
  2927 apply (simp add: sin_arccos_lemma1)
  2928 apply (simp add: power_divide)
  2929 apply (simp add: real_sqrt_mult [symmetric])
  2930 apply (simp add: right_diff_distrib)
  2931 done
  2932 
  2933 lemma polar_ex2:
  2934      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  2935 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  2936 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  2937 done
  2938 
  2939 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  2940 apply (rule_tac x=0 and y=y in linorder_cases)
  2941 apply (erule polar_ex1)
  2942 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  2943 apply (erule polar_ex2)
  2944 done
  2945 
  2946 end