src/HOLCF/Cfun.thy
author huffman
Thu Dec 20 03:06:20 2007 +0100 (2007-12-20)
changeset 25723 80c06e4d4db6
parent 25701 73fbe868b4e7
child 25786 6b3c79acac1f
permissions -rw-r--r--
move bottom-related stuff back into Pcpo.thy
     1 (*  Title:      HOLCF/Cfun.thy
     2     ID:         $Id$
     3     Author:     Franz Regensburger
     4 
     5 Definition of the type ->  of continuous functions.
     6 *)
     7 
     8 header {* The type of continuous functions *}
     9 
    10 theory Cfun
    11 imports Pcpodef
    12 uses ("Tools/cont_proc.ML")
    13 begin
    14 
    15 defaultsort cpo
    16 
    17 subsection {* Definition of continuous function type *}
    18 
    19 lemma Ex_cont: "\<exists>f. cont f"
    20 by (rule exI, rule cont_const)
    21 
    22 lemma adm_cont: "adm cont"
    23 by (rule admI, rule cont_lub_fun)
    24 
    25 cpodef (CFun)  ('a, 'b) "->" (infixr "->" 0) = "{f::'a => 'b. cont f}"
    26 by (simp add: Ex_cont adm_cont)
    27 
    28 syntax (xsymbols)
    29   "->"     :: "[type, type] => type"      ("(_ \<rightarrow>/ _)" [1,0]0)
    30 
    31 notation
    32   Rep_CFun  ("(_$/_)" [999,1000] 999)
    33 
    34 notation (xsymbols)
    35   Rep_CFun  ("(_\<cdot>/_)" [999,1000] 999)
    36 
    37 notation (HTML output)
    38   Rep_CFun  ("(_\<cdot>/_)" [999,1000] 999)
    39 
    40 subsection {* Syntax for continuous lambda abstraction *}
    41 
    42 syntax "_cabs" :: "'a"
    43 
    44 parse_translation {*
    45 (* rewrites (_cabs x t) => (Abs_CFun (%x. t)) *)
    46   [mk_binder_tr ("_cabs", @{const_syntax Abs_CFun})];
    47 *}
    48 
    49 text {* To avoid eta-contraction of body: *}
    50 typed_print_translation {*
    51   let
    52     fun cabs_tr' _ _ [Abs abs] = let
    53           val (x,t) = atomic_abs_tr' abs
    54         in Syntax.const "_cabs" $ x $ t end
    55 
    56       | cabs_tr' _ T [t] = let
    57           val xT = domain_type (domain_type T);
    58           val abs' = ("x",xT,(incr_boundvars 1 t)$Bound 0);
    59           val (x,t') = atomic_abs_tr' abs';
    60         in Syntax.const "_cabs" $ x $ t' end;
    61 
    62   in [(@{const_syntax Abs_CFun}, cabs_tr')] end;
    63 *}
    64 
    65 text {* Syntax for nested abstractions *}
    66 
    67 syntax
    68   "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic"  ("(3LAM _./ _)" [1000, 10] 10)
    69 
    70 syntax (xsymbols)
    71   "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic" ("(3\<Lambda>_./ _)" [1000, 10] 10)
    72 
    73 parse_ast_translation {*
    74 (* rewrites (LAM x y z. t) => (_cabs x (_cabs y (_cabs z t))) *)
    75 (* cf. Syntax.lambda_ast_tr from Syntax/syn_trans.ML *)
    76   let
    77     fun Lambda_ast_tr [pats, body] =
    78           Syntax.fold_ast_p "_cabs" (Syntax.unfold_ast "_cargs" pats, body)
    79       | Lambda_ast_tr asts = raise Syntax.AST ("Lambda_ast_tr", asts);
    80   in [("_Lambda", Lambda_ast_tr)] end;
    81 *}
    82 
    83 print_ast_translation {*
    84 (* rewrites (_cabs x (_cabs y (_cabs z t))) => (LAM x y z. t) *)
    85 (* cf. Syntax.abs_ast_tr' from Syntax/syn_trans.ML *)
    86   let
    87     fun cabs_ast_tr' asts =
    88       (case Syntax.unfold_ast_p "_cabs"
    89           (Syntax.Appl (Syntax.Constant "_cabs" :: asts)) of
    90         ([], _) => raise Syntax.AST ("cabs_ast_tr'", asts)
    91       | (xs, body) => Syntax.Appl
    92           [Syntax.Constant "_Lambda", Syntax.fold_ast "_cargs" xs, body]);
    93   in [("_cabs", cabs_ast_tr')] end;
    94 *}
    95 
    96 text {* Dummy patterns for continuous abstraction *}
    97 translations
    98   "\<Lambda> _. t" => "CONST Abs_CFun (\<lambda> _. t)"
    99 
   100 
   101 subsection {* Continuous function space is pointed *}
   102 
   103 lemma UU_CFun: "\<bottom> \<in> CFun"
   104 by (simp add: CFun_def inst_fun_pcpo cont_const)
   105 
   106 instance "->" :: (cpo, pcpo) pcpo
   107 by (rule typedef_pcpo [OF type_definition_CFun less_CFun_def UU_CFun])
   108 
   109 lemmas Rep_CFun_strict =
   110   typedef_Rep_strict [OF type_definition_CFun less_CFun_def UU_CFun]
   111 
   112 lemmas Abs_CFun_strict =
   113   typedef_Abs_strict [OF type_definition_CFun less_CFun_def UU_CFun]
   114 
   115 text {* function application is strict in its first argument *}
   116 
   117 lemma Rep_CFun_strict1 [simp]: "\<bottom>\<cdot>x = \<bottom>"
   118 by (simp add: Rep_CFun_strict)
   119 
   120 text {* for compatibility with old HOLCF-Version *}
   121 lemma inst_cfun_pcpo: "\<bottom> = (\<Lambda> x. \<bottom>)"
   122 by (simp add: inst_fun_pcpo [symmetric] Abs_CFun_strict)
   123 
   124 subsection {* Basic properties of continuous functions *}
   125 
   126 text {* Beta-equality for continuous functions *}
   127 
   128 lemma Abs_CFun_inverse2: "cont f \<Longrightarrow> Rep_CFun (Abs_CFun f) = f"
   129 by (simp add: Abs_CFun_inverse CFun_def)
   130 
   131 lemma beta_cfun [simp]: "cont f \<Longrightarrow> (\<Lambda> x. f x)\<cdot>u = f u"
   132 by (simp add: Abs_CFun_inverse2)
   133 
   134 text {* Eta-equality for continuous functions *}
   135 
   136 lemma eta_cfun: "(\<Lambda> x. f\<cdot>x) = f"
   137 by (rule Rep_CFun_inverse)
   138 
   139 text {* Extensionality for continuous functions *}
   140 
   141 lemma expand_cfun_eq: "(f = g) = (\<forall>x. f\<cdot>x = g\<cdot>x)"
   142 by (simp add: Rep_CFun_inject [symmetric] expand_fun_eq)
   143 
   144 lemma ext_cfun: "(\<And>x. f\<cdot>x = g\<cdot>x) \<Longrightarrow> f = g"
   145 by (simp add: expand_cfun_eq)
   146 
   147 text {* Extensionality wrt. ordering for continuous functions *}
   148 
   149 lemma expand_cfun_less: "f \<sqsubseteq> g = (\<forall>x. f\<cdot>x \<sqsubseteq> g\<cdot>x)" 
   150 by (simp add: less_CFun_def expand_fun_less)
   151 
   152 lemma less_cfun_ext: "(\<And>x. f\<cdot>x \<sqsubseteq> g\<cdot>x) \<Longrightarrow> f \<sqsubseteq> g"
   153 by (simp add: expand_cfun_less)
   154 
   155 text {* Congruence for continuous function application *}
   156 
   157 lemma cfun_cong: "\<lbrakk>f = g; x = y\<rbrakk> \<Longrightarrow> f\<cdot>x = g\<cdot>y"
   158 by simp
   159 
   160 lemma cfun_fun_cong: "f = g \<Longrightarrow> f\<cdot>x = g\<cdot>x"
   161 by simp
   162 
   163 lemma cfun_arg_cong: "x = y \<Longrightarrow> f\<cdot>x = f\<cdot>y"
   164 by simp
   165 
   166 subsection {* Continuity of application *}
   167 
   168 lemma cont_Rep_CFun1: "cont (\<lambda>f. f\<cdot>x)"
   169 by (rule cont_Rep_CFun [THEN cont2cont_fun])
   170 
   171 lemma cont_Rep_CFun2: "cont (\<lambda>x. f\<cdot>x)"
   172 apply (cut_tac x=f in Rep_CFun)
   173 apply (simp add: CFun_def)
   174 done
   175 
   176 lemmas monofun_Rep_CFun = cont_Rep_CFun [THEN cont2mono]
   177 lemmas contlub_Rep_CFun = cont_Rep_CFun [THEN cont2contlub]
   178 
   179 lemmas monofun_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2mono, standard]
   180 lemmas contlub_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2contlub, standard]
   181 lemmas monofun_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2mono, standard]
   182 lemmas contlub_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2contlub, standard]
   183 
   184 text {* contlub, cont properties of @{term Rep_CFun} in each argument *}
   185 
   186 lemma contlub_cfun_arg: "chain Y \<Longrightarrow> f\<cdot>(lub (range Y)) = (\<Squnion>i. f\<cdot>(Y i))"
   187 by (rule contlub_Rep_CFun2 [THEN contlubE])
   188 
   189 lemma cont_cfun_arg: "chain Y \<Longrightarrow> range (\<lambda>i. f\<cdot>(Y i)) <<| f\<cdot>(lub (range Y))"
   190 by (rule cont_Rep_CFun2 [THEN contE])
   191 
   192 lemma contlub_cfun_fun: "chain F \<Longrightarrow> lub (range F)\<cdot>x = (\<Squnion>i. F i\<cdot>x)"
   193 by (rule contlub_Rep_CFun1 [THEN contlubE])
   194 
   195 lemma cont_cfun_fun: "chain F \<Longrightarrow> range (\<lambda>i. F i\<cdot>x) <<| lub (range F)\<cdot>x"
   196 by (rule cont_Rep_CFun1 [THEN contE])
   197 
   198 text {* monotonicity of application *}
   199 
   200 lemma monofun_cfun_fun: "f \<sqsubseteq> g \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>x"
   201 by (simp add: expand_cfun_less)
   202 
   203 lemma monofun_cfun_arg: "x \<sqsubseteq> y \<Longrightarrow> f\<cdot>x \<sqsubseteq> f\<cdot>y"
   204 by (rule monofun_Rep_CFun2 [THEN monofunE])
   205 
   206 lemma monofun_cfun: "\<lbrakk>f \<sqsubseteq> g; x \<sqsubseteq> y\<rbrakk> \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>y"
   207 by (rule trans_less [OF monofun_cfun_fun monofun_cfun_arg])
   208 
   209 text {* ch2ch - rules for the type @{typ "'a -> 'b"} *}
   210 
   211 lemma chain_monofun: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   212 by (erule monofun_Rep_CFun2 [THEN ch2ch_monofun])
   213 
   214 lemma ch2ch_Rep_CFunR: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   215 by (rule monofun_Rep_CFun2 [THEN ch2ch_monofun])
   216 
   217 lemma ch2ch_Rep_CFunL: "chain F \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>x)"
   218 by (rule monofun_Rep_CFun1 [THEN ch2ch_monofun])
   219 
   220 lemma ch2ch_Rep_CFun [simp]:
   221   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>(Y i))"
   222 apply (rule chainI)
   223 apply (rule monofun_cfun)
   224 apply (erule chainE)
   225 apply (erule chainE)
   226 done
   227 
   228 lemma ch2ch_LAM: "\<lbrakk>\<And>x. chain (\<lambda>i. S i x); \<And>i. cont (\<lambda>x. S i x)\<rbrakk>
   229     \<Longrightarrow> chain (\<lambda>i. \<Lambda> x. S i x)"
   230 by (simp add: chain_def expand_cfun_less)
   231 
   232 text {* contlub, cont properties of @{term Rep_CFun} in both arguments *}
   233 
   234 lemma contlub_cfun: 
   235   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i) = (\<Squnion>i. F i\<cdot>(Y i))"
   236 by (simp add: contlub_cfun_fun contlub_cfun_arg diag_lub)
   237 
   238 lemma cont_cfun: 
   239   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> range (\<lambda>i. F i\<cdot>(Y i)) <<| (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i)"
   240 apply (rule thelubE)
   241 apply (simp only: ch2ch_Rep_CFun)
   242 apply (simp only: contlub_cfun)
   243 done
   244 
   245 lemma contlub_LAM:
   246   "\<lbrakk>\<And>x. chain (\<lambda>i. F i x); \<And>i. cont (\<lambda>x. F i x)\<rbrakk>
   247     \<Longrightarrow> (\<Lambda> x. \<Squnion>i. F i x) = (\<Squnion>i. \<Lambda> x. F i x)"
   248 apply (simp add: thelub_CFun ch2ch_LAM)
   249 apply (simp add: Abs_CFun_inverse2)
   250 apply (simp add: thelub_fun ch2ch_lambda)
   251 done
   252 
   253 text {* strictness *}
   254 
   255 lemma strictI: "f\<cdot>x = \<bottom> \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   256 apply (rule UU_I)
   257 apply (erule subst)
   258 apply (rule minimal [THEN monofun_cfun_arg])
   259 done
   260 
   261 text {* the lub of a chain of continous functions is monotone *}
   262 
   263 lemma lub_cfun_mono: "chain F \<Longrightarrow> monofun (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
   264 apply (drule ch2ch_monofun [OF monofun_Rep_CFun])
   265 apply (simp add: thelub_fun [symmetric])
   266 apply (erule monofun_lub_fun)
   267 apply (simp add: monofun_Rep_CFun2)
   268 done
   269 
   270 text {* a lemma about the exchange of lubs for type @{typ "'a -> 'b"} *}
   271 
   272 lemma ex_lub_cfun:
   273   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>j. \<Squnion>i. F j\<cdot>(Y i)) = (\<Squnion>i. \<Squnion>j. F j\<cdot>(Y i))"
   274 by (simp add: diag_lub)
   275 
   276 text {* the lub of a chain of cont. functions is continuous *}
   277 
   278 lemma cont_lub_cfun: "chain F \<Longrightarrow> cont (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
   279 apply (rule cont2cont_lub)
   280 apply (erule monofun_Rep_CFun [THEN ch2ch_monofun])
   281 apply (rule cont_Rep_CFun2)
   282 done
   283 
   284 text {* type @{typ "'a -> 'b"} is chain complete *}
   285 
   286 lemma lub_cfun: "chain F \<Longrightarrow> range F <<| (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
   287 by (simp only: contlub_cfun_fun [symmetric] eta_cfun thelubE)
   288 
   289 lemma thelub_cfun: "chain F \<Longrightarrow> lub (range F) = (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
   290 by (rule lub_cfun [THEN thelubI])
   291 
   292 subsection {* Continuity simplification procedure *}
   293 
   294 text {* cont2cont lemma for @{term Rep_CFun} *}
   295 
   296 lemma cont2cont_Rep_CFun:
   297   "\<lbrakk>cont f; cont t\<rbrakk> \<Longrightarrow> cont (\<lambda>x. (f x)\<cdot>(t x))"
   298 by (best intro: cont2cont_app2 cont_const cont_Rep_CFun cont_Rep_CFun2)
   299 
   300 text {* cont2mono Lemma for @{term "%x. LAM y. c1(x)(y)"} *}
   301 
   302 lemma cont2mono_LAM:
   303 assumes p1: "!!x. cont(c1 x)"
   304 assumes p2: "!!y. monofun(%x. c1 x y)"
   305 shows "monofun(%x. LAM y. c1 x y)"
   306 apply (rule monofunI)
   307 apply (rule less_cfun_ext)
   308 apply (simp add: p1)
   309 apply (erule p2 [THEN monofunE])
   310 done
   311 
   312 text {* cont2cont Lemma for @{term "%x. LAM y. c1 x y"} *}
   313 
   314 lemma cont2cont_LAM:
   315 assumes p1: "!!x. cont(c1 x)"
   316 assumes p2: "!!y. cont(%x. c1 x y)"
   317 shows "cont(%x. LAM y. c1 x y)"
   318 apply (rule cont_Abs_CFun)
   319 apply (simp add: p1 CFun_def)
   320 apply (simp add: p2 cont2cont_lambda)
   321 done
   322 
   323 text {* continuity simplification procedure *}
   324 
   325 lemmas cont_lemmas1 =
   326   cont_const cont_id cont_Rep_CFun2 cont2cont_Rep_CFun cont2cont_LAM
   327 
   328 use "Tools/cont_proc.ML";
   329 setup ContProc.setup;
   330 
   331 (*val cont_tac = (fn i => (resolve_tac cont_lemmas i));*)
   332 (*val cont_tacR = (fn i => (REPEAT (cont_tac i)));*)
   333 
   334 subsection {* Miscellaneous *}
   335 
   336 text {* Monotonicity of @{term Abs_CFun} *}
   337 
   338 lemma semi_monofun_Abs_CFun:
   339   "\<lbrakk>cont f; cont g; f \<sqsubseteq> g\<rbrakk> \<Longrightarrow> Abs_CFun f \<sqsubseteq> Abs_CFun g"
   340 by (simp add: less_CFun_def Abs_CFun_inverse2)
   341 
   342 text {* some lemmata for functions with flat/chfin domain/range types *}
   343 
   344 lemma chfin_Rep_CFunR: "chain (Y::nat => 'a::cpo->'b::chfin)  
   345       ==> !s. ? n. lub(range(Y))$s = Y n$s"
   346 apply (rule allI)
   347 apply (subst contlub_cfun_fun)
   348 apply assumption
   349 apply (fast intro!: thelubI chfin lub_finch2 chfin2finch ch2ch_Rep_CFunL)
   350 done
   351 
   352 lemma adm_chfindom: "adm (\<lambda>(u::'a::cpo \<rightarrow> 'b::chfin). P(u\<cdot>s))"
   353 by (rule adm_subst, simp, rule adm_chfin)
   354 
   355 subsection {* Continuous injection-retraction pairs *}
   356 
   357 text {* Continuous retractions are strict. *}
   358 
   359 lemma retraction_strict:
   360   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   361 apply (rule UU_I)
   362 apply (drule_tac x="\<bottom>" in spec)
   363 apply (erule subst)
   364 apply (rule monofun_cfun_arg)
   365 apply (rule minimal)
   366 done
   367 
   368 lemma injection_eq:
   369   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x = g\<cdot>y) = (x = y)"
   370 apply (rule iffI)
   371 apply (drule_tac f=f in cfun_arg_cong)
   372 apply simp
   373 apply simp
   374 done
   375 
   376 lemma injection_less:
   377   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x \<sqsubseteq> g\<cdot>y) = (x \<sqsubseteq> y)"
   378 apply (rule iffI)
   379 apply (drule_tac f=f in monofun_cfun_arg)
   380 apply simp
   381 apply (erule monofun_cfun_arg)
   382 done
   383 
   384 lemma injection_defined_rev:
   385   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; g\<cdot>z = \<bottom>\<rbrakk> \<Longrightarrow> z = \<bottom>"
   386 apply (drule_tac f=f in cfun_arg_cong)
   387 apply (simp add: retraction_strict)
   388 done
   389 
   390 lemma injection_defined:
   391   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; z \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> g\<cdot>z \<noteq> \<bottom>"
   392 by (erule contrapos_nn, rule injection_defined_rev)
   393 
   394 text {* propagation of flatness and chain-finiteness by retractions *}
   395 
   396 lemma chfin2chfin:
   397   "\<forall>y. (f::'a::chfin \<rightarrow> 'b)\<cdot>(g\<cdot>y) = y
   398     \<Longrightarrow> \<forall>Y::nat \<Rightarrow> 'b. chain Y \<longrightarrow> (\<exists>n. max_in_chain n Y)"
   399 apply clarify
   400 apply (drule_tac f=g in chain_monofun)
   401 apply (drule chfin [rule_format])
   402 apply (unfold max_in_chain_def)
   403 apply (simp add: injection_eq)
   404 done
   405 
   406 lemma flat2flat:
   407   "\<forall>y. (f::'a::flat \<rightarrow> 'b::pcpo)\<cdot>(g\<cdot>y) = y
   408     \<Longrightarrow> \<forall>x y::'b. x \<sqsubseteq> y \<longrightarrow> x = \<bottom> \<or> x = y"
   409 apply clarify
   410 apply (drule_tac f=g in monofun_cfun_arg)
   411 apply (drule ax_flat [rule_format])
   412 apply (erule disjE)
   413 apply (simp add: injection_defined_rev)
   414 apply (simp add: injection_eq)
   415 done
   416 
   417 text {* a result about functions with flat codomain *}
   418 
   419 lemma flat_eqI: "\<lbrakk>(x::'a::flat) \<sqsubseteq> y; x \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> x = y"
   420 by (drule ax_flat [rule_format], simp)
   421 
   422 lemma flat_codom:
   423   "f\<cdot>x = (c::'b::flat) \<Longrightarrow> f\<cdot>\<bottom> = \<bottom> \<or> (\<forall>z. f\<cdot>z = c)"
   424 apply (case_tac "f\<cdot>x = \<bottom>")
   425 apply (rule disjI1)
   426 apply (rule UU_I)
   427 apply (erule_tac t="\<bottom>" in subst)
   428 apply (rule minimal [THEN monofun_cfun_arg])
   429 apply clarify
   430 apply (rule_tac a = "f\<cdot>\<bottom>" in refl [THEN box_equals])
   431 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   432 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   433 done
   434 
   435 
   436 subsection {* Identity and composition *}
   437 
   438 definition
   439   ID :: "'a \<rightarrow> 'a" where
   440   "ID = (\<Lambda> x. x)"
   441 
   442 definition
   443   cfcomp  :: "('b \<rightarrow> 'c) \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'c" where
   444   oo_def: "cfcomp = (\<Lambda> f g x. f\<cdot>(g\<cdot>x))"
   445 
   446 abbreviation
   447   cfcomp_syn :: "['b \<rightarrow> 'c, 'a \<rightarrow> 'b] \<Rightarrow> 'a \<rightarrow> 'c"  (infixr "oo" 100)  where
   448   "f oo g == cfcomp\<cdot>f\<cdot>g"
   449 
   450 lemma ID1 [simp]: "ID\<cdot>x = x"
   451 by (simp add: ID_def)
   452 
   453 lemma cfcomp1: "(f oo g) = (\<Lambda> x. f\<cdot>(g\<cdot>x))"
   454 by (simp add: oo_def)
   455 
   456 lemma cfcomp2 [simp]: "(f oo g)\<cdot>x = f\<cdot>(g\<cdot>x)"
   457 by (simp add: cfcomp1)
   458 
   459 lemma cfcomp_strict [simp]: "\<bottom> oo f = \<bottom>"
   460 by (simp add: expand_cfun_eq)
   461 
   462 text {*
   463   Show that interpretation of (pcpo,@{text "_->_"}) is a category.
   464   The class of objects is interpretation of syntactical class pcpo.
   465   The class of arrows  between objects @{typ 'a} and @{typ 'b} is interpret. of @{typ "'a -> 'b"}.
   466   The identity arrow is interpretation of @{term ID}.
   467   The composition of f and g is interpretation of @{text "oo"}.
   468 *}
   469 
   470 lemma ID2 [simp]: "f oo ID = f"
   471 by (rule ext_cfun, simp)
   472 
   473 lemma ID3 [simp]: "ID oo f = f"
   474 by (rule ext_cfun, simp)
   475 
   476 lemma assoc_oo: "f oo (g oo h) = (f oo g) oo h"
   477 by (rule ext_cfun, simp)
   478 
   479 
   480 subsection {* Strictified functions *}
   481 
   482 defaultsort pcpo
   483 
   484 definition
   485   strictify  :: "('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'b" where
   486   "strictify = (\<Lambda> f x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   487 
   488 text {* results about strictify *}
   489 
   490 lemma cont_strictify1: "cont (\<lambda>f. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   491 by (simp add: cont_if)
   492 
   493 lemma monofun_strictify2: "monofun (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   494 apply (rule monofunI)
   495 apply (auto simp add: monofun_cfun_arg eq_UU_iff [symmetric])
   496 done
   497 
   498 (*FIXME: long proof*)
   499 lemma contlub_strictify2: "contlub (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   500 apply (rule contlubI)
   501 apply (case_tac "lub (range Y) = \<bottom>")
   502 apply (drule (1) chain_UU_I)
   503 apply simp
   504 apply (simp del: if_image_distrib)
   505 apply (simp only: contlub_cfun_arg)
   506 apply (rule lub_equal2)
   507 apply (rule chain_mono2 [THEN exE])
   508 apply (erule chain_UU_I_inverse2)
   509 apply (assumption)
   510 apply (rule_tac x=x in exI, clarsimp)
   511 apply (erule chain_monofun)
   512 apply (erule monofun_strictify2 [THEN ch2ch_monofun])
   513 done
   514 
   515 lemmas cont_strictify2 =
   516   monocontlub2cont [OF monofun_strictify2 contlub_strictify2, standard]
   517 
   518 lemma strictify_conv_if: "strictify\<cdot>f\<cdot>x = (if x = \<bottom> then \<bottom> else f\<cdot>x)"
   519 by (unfold strictify_def, simp add: cont_strictify1 cont_strictify2)
   520 
   521 lemma strictify1 [simp]: "strictify\<cdot>f\<cdot>\<bottom> = \<bottom>"
   522 by (simp add: strictify_conv_if)
   523 
   524 lemma strictify2 [simp]: "x \<noteq> \<bottom> \<Longrightarrow> strictify\<cdot>f\<cdot>x = f\<cdot>x"
   525 by (simp add: strictify_conv_if)
   526 
   527 subsection {* Continuous let-bindings *}
   528 
   529 definition
   530   CLet :: "'a \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'b" where
   531   "CLet = (\<Lambda> s f. f\<cdot>s)"
   532 
   533 syntax
   534   "_CLet" :: "[letbinds, 'a] => 'a" ("(Let (_)/ in (_))" 10)
   535 
   536 translations
   537   "_CLet (_binds b bs) e" == "_CLet b (_CLet bs e)"
   538   "Let x = a in e" == "CONST CLet\<cdot>a\<cdot>(\<Lambda> x. e)"
   539 
   540 end