src/Pure/sign.ML
author wenzelm
Thu Aug 03 00:41:07 2000 +0200 (2000-08-03)
changeset 9504 8168600e88a5
parent 9031 8f75b9ce2f06
child 10404 93efbb62667c
permissions -rw-r--r--
typ_no_norm;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 (*base names*)
     9 type bstring = string;
    10 type bclass = class;
    11 (*external forms -- partially qualified names*)
    12 type xstring = string;
    13 type xclass = class;
    14 type xsort = sort;
    15 type xtyp = typ;
    16 type xterm = term;
    17 
    18 signature SIGN =
    19 sig
    20   type sg
    21   type sg_ref
    22   type data
    23   val rep_sg: sg ->
    24    {self: sg_ref,
    25     tsig: Type.type_sig,
    26     const_tab: typ Symtab.table,
    27     syn: Syntax.syntax,
    28     path: string list,
    29     spaces: (string * NameSpace.T) list,
    30     data: data}
    31   val name_of: sg -> string
    32   val stamp_names_of: sg -> string list
    33   val tsig_of: sg -> Type.type_sig
    34   val deref: sg_ref -> sg
    35   val self_ref: sg -> sg_ref
    36   val subsig: sg * sg -> bool
    37   val joinable: sg * sg -> bool
    38   val eq_sg: sg * sg -> bool
    39   val same_sg: sg * sg -> bool
    40   val is_draft: sg -> bool
    41   val is_stale: sg -> bool
    42   val const_type: sg -> string -> typ option
    43   val classes: sg -> class list
    44   val defaultS: sg -> sort
    45   val subsort: sg -> sort * sort -> bool
    46   val nodup_vars: term -> term
    47   val norm_sort: sg -> sort -> sort
    48   val of_sort: sg -> typ * sort -> bool
    49   val witness_sorts: sg -> sort list -> sort list -> (typ * sort) list
    50   val univ_witness: sg -> (typ * sort) option
    51   val classK: string
    52   val typeK: string
    53   val constK: string
    54   val full_name: sg -> bstring -> string
    55   val full_name_path: sg -> string -> bstring -> string
    56   val base_name: string -> bstring
    57   val intern: sg -> string -> xstring -> string
    58   val extern: sg -> string -> string -> xstring
    59   val cond_extern: sg -> string -> string -> xstring
    60   val cond_extern_table: sg -> string -> 'a Symtab.table -> (xstring * 'a) list
    61   val intern_class: sg -> xclass -> class
    62   val intern_tycon: sg -> xstring -> string
    63   val intern_const: sg -> xstring -> string
    64   val intern_sort: sg -> xsort -> sort
    65   val intern_typ: sg -> xtyp -> typ
    66   val intern_term: sg -> xterm -> term
    67   val intern_tycons: sg -> xtyp -> typ
    68   val pretty_sg: sg -> Pretty.T
    69   val str_of_sg: sg -> string
    70   val pprint_sg: sg -> pprint_args -> unit
    71   val pretty_term: sg -> term -> Pretty.T
    72   val pretty_typ: sg -> typ -> Pretty.T
    73   val pretty_sort: sg -> sort -> Pretty.T
    74   val pretty_classrel: sg -> class * class -> Pretty.T
    75   val pretty_arity: sg -> string * sort list * sort -> Pretty.T
    76   val string_of_term: sg -> term -> string
    77   val string_of_typ: sg -> typ -> string
    78   val string_of_sort: sg -> sort -> string
    79   val str_of_sort: sg -> sort -> string
    80   val str_of_classrel: sg -> class * class -> string
    81   val str_of_arity: sg -> string * sort list * sort -> string
    82   val pprint_term: sg -> term -> pprint_args -> unit
    83   val pprint_typ: sg -> typ -> pprint_args -> unit
    84   val certify_class: sg -> class -> class
    85   val certify_sort: sg -> sort -> sort
    86   val certify_typ: sg -> typ -> typ
    87   val certify_typ_no_norm: sg -> typ -> typ
    88   val certify_term: sg -> term -> term * typ * int
    89   val read_sort: sg -> string -> sort
    90   val read_raw_typ: sg * (indexname -> sort option) -> string -> typ
    91   val read_typ: sg * (indexname -> sort option) -> string -> typ
    92   val read_typ_no_norm: sg * (indexname -> sort option) -> string -> typ
    93   val infer_types: sg -> (indexname -> typ option) ->
    94     (indexname -> sort option) -> string list -> bool
    95     -> xterm list * typ -> term * (indexname * typ) list
    96   val infer_types_simult: sg -> (indexname -> typ option) ->
    97     (indexname -> sort option) -> string list -> bool
    98     -> (xterm list * typ) list -> term list * (indexname * typ) list
    99   val read_def_terms:
   100     sg * (indexname -> typ option) * (indexname -> sort option) ->
   101     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   102   val simple_read_term: sg -> typ -> string -> term
   103   val add_classes: (bclass * xclass list) list -> sg -> sg
   104   val add_classes_i: (bclass * class list) list -> sg -> sg
   105   val add_classrel: (xclass * xclass) list -> sg -> sg
   106   val add_classrel_i: (class * class) list -> sg -> sg
   107   val add_defsort: string -> sg -> sg
   108   val add_defsort_i: sort -> sg -> sg
   109   val add_types: (bstring * int * mixfix) list -> sg -> sg
   110   val add_nonterminals: bstring list -> sg -> sg
   111   val add_tyabbrs: (bstring * string list * string * mixfix) list -> sg -> sg
   112   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> sg -> sg
   113   val add_arities: (xstring * string list * string) list -> sg -> sg
   114   val add_arities_i: (string * sort list * sort) list -> sg -> sg
   115   val add_consts: (bstring * string * mixfix) list -> sg -> sg
   116   val add_consts_i: (bstring * typ * mixfix) list -> sg -> sg
   117   val add_syntax: (bstring * string * mixfix) list -> sg -> sg
   118   val add_syntax_i: (bstring * typ * mixfix) list -> sg -> sg
   119   val add_modesyntax: (string * bool) * (bstring * string * mixfix) list -> sg -> sg
   120   val add_modesyntax_i: (string * bool) * (bstring * typ * mixfix) list -> sg -> sg
   121   val add_trfuns:
   122     (string * (ast list -> ast)) list *
   123     (string * (term list -> term)) list *
   124     (string * (term list -> term)) list *
   125     (string * (ast list -> ast)) list -> sg -> sg
   126   val add_trfunsT:
   127     (string * (bool -> typ -> term list -> term)) list -> sg -> sg
   128   val add_tokentrfuns:
   129     (string * string * (string -> string * real)) list -> sg -> sg
   130   val add_trrules: (xstring * string) Syntax.trrule list -> sg -> sg
   131   val add_trrules_i: ast Syntax.trrule list -> sg -> sg
   132   val add_path: string -> sg -> sg
   133   val add_space: string * string list -> sg -> sg
   134   val hide_space: string * string list -> sg -> sg
   135   val hide_space_i: string * string list -> sg -> sg
   136   val add_name: string -> sg -> sg
   137   val data_kinds: data -> string list
   138   val merge_refs: sg_ref * sg_ref -> sg_ref
   139   val merge: sg * sg -> sg
   140   val prep_ext: sg -> sg
   141   val copy: sg -> sg
   142   val nontriv_merge: sg * sg -> sg
   143   val pre_pure: sg
   144   val const_of_class: class -> string
   145   val class_of_const: string -> class
   146 end;
   147 
   148 signature PRIVATE_SIGN =
   149 sig
   150   include SIGN
   151   val init_data: Object.kind * (Object.T * (Object.T -> Object.T) * (Object.T -> Object.T) *
   152     (Object.T * Object.T -> Object.T) * (sg -> Object.T -> unit)) -> sg -> sg
   153   val get_data: Object.kind -> (Object.T -> 'a) -> sg -> 'a
   154   val put_data: Object.kind -> ('a -> Object.T) -> 'a -> sg -> sg
   155   val print_data: Object.kind -> sg -> unit
   156 end;
   157 
   158 structure Sign: PRIVATE_SIGN =
   159 struct
   160 
   161 
   162 (** datatype sg **)
   163 
   164 (* types sg, data, sg_ref *)
   165 
   166 datatype sg =
   167   Sg of
   168    {id: string ref,                             (*id*)
   169     stamps: string ref list} *                  (*unique theory indentifier*)
   170    {self: sg_ref,                               (*mutable self reference*)
   171     tsig: Type.type_sig,                        (*order-sorted signature of types*)
   172     const_tab: typ Symtab.table,                (*type schemes of constants*)
   173     syn: Syntax.syntax,                         (*syntax for parsing and printing*)
   174     path: string list,                          (*current name space entry prefix*)
   175     spaces: (string * NameSpace.T) list,        (*name spaces for consts, types etc.*)
   176     data: data}                                 (*anytype data*)
   177 and data =
   178   Data of
   179     (Object.kind *				(*kind (for authorization)*)
   180       (Object.T *				(*value*)
   181         ((Object.T -> Object.T) *               (*prepare extend method*)
   182           (Object.T -> Object.T) *              (*copy method*)
   183           (Object.T * Object.T -> Object.T) *   (*merge and prepare extend method*)
   184           (sg -> Object.T -> unit))))           (*print method*)
   185     Symtab.table
   186 and sg_ref =
   187   SgRef of sg ref option;
   188 
   189 (*make signature*)
   190 fun make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps) =
   191   Sg ({id = id, stamps = stamps}, {self = self, tsig = tsig, const_tab = const_tab,
   192     syn = syn, path = path, spaces = spaces, data = data});
   193 
   194 
   195 (* basic operations *)
   196 
   197 fun rep_sg (Sg (_, args)) = args;
   198 
   199 (*show stamps*)
   200 fun stamp_names_of (Sg ({stamps, ...}, _)) = rev (map ! stamps);
   201 fun pretty_sg sg = Pretty.str_list "{" "}" (stamp_names_of sg);
   202 val str_of_sg = Pretty.str_of o pretty_sg;
   203 val pprint_sg = Pretty.pprint o pretty_sg;
   204 
   205 val tsig_of = #tsig o rep_sg;
   206 
   207 fun const_type (Sg (_, {const_tab, ...})) c = Symtab.lookup (const_tab, c);
   208 
   209 
   210 (* id and self *)
   211 
   212 fun check_stale (sg as Sg ({id, ...},
   213         {self = SgRef (Some (ref (Sg ({id = id', ...}, _)))), ...})) =
   214       if id = id' then sg
   215       else raise TERM ("Stale signature: " ^ str_of_sg sg, [])
   216   | check_stale _ = sys_error "Sign.check_stale";
   217 
   218 fun is_stale sg = (check_stale sg; false) handle TERM _ => true;
   219 
   220 fun self_ref (sg as Sg (_, {self, ...})) = (check_stale sg; self);
   221 
   222 fun deref (SgRef (Some (ref sg))) = sg
   223   | deref (SgRef None) = sys_error "Sign.deref";
   224 
   225 fun name_of (sg as Sg ({id = ref name, ...}, _)) =
   226   if name = "" orelse ord name = ord "#" then
   227     raise TERM ("Nameless signature " ^ str_of_sg sg, [])
   228   else name;
   229 
   230 
   231 (* inclusion and equality *)
   232 
   233 local
   234   (*avoiding polymorphic equality: factor 10 speedup*)
   235   fun mem_stamp (_:string ref, []) = false
   236     | mem_stamp (x, y :: ys) = x = y orelse mem_stamp (x, ys);
   237 
   238   fun subset_stamp ([], ys) = true
   239     | subset_stamp (x :: xs, ys) =
   240         mem_stamp (x, ys) andalso subset_stamp (xs, ys);
   241 
   242   (*fast partial test*)
   243   fun fast_sub ([]: string ref list, _) = true
   244     | fast_sub (_, []) = false
   245     | fast_sub (x :: xs, y :: ys) =
   246         if x = y then fast_sub (xs, ys)
   247         else fast_sub (x :: xs, ys);
   248 in
   249   fun eq_sg (sg1 as Sg ({id = id1, ...}, _), sg2 as Sg ({id = id2, ...}, _)) =
   250     (check_stale sg1; check_stale sg2; id1 = id2);
   251 
   252   fun subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   253     eq_sg (sg1, sg2) orelse subset_stamp (s1, s2);
   254 
   255   fun fast_subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   256     eq_sg (sg1, sg2) orelse fast_sub (s1, s2);
   257 end;
   258 
   259 
   260 fun joinable (sg1, sg2) = subsig (sg1, sg2) orelse subsig (sg2, sg1);
   261 
   262 (*test if same theory names are contained in signatures' stamps,
   263   i.e. if signatures belong to same theory but not necessarily to the
   264   same version of it*)
   265 fun same_sg (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   266   eq_sg (sg1, sg2) orelse eq_set_string (pairself (map (op !)) (s1, s2));
   267 
   268 (*test for drafts*)
   269 fun is_draft (Sg ({stamps = ref name :: _, ...}, _)) = name = "" orelse ord name = ord "#";
   270 
   271 
   272 (* classes and sorts *)
   273 
   274 val classes = Type.classes o tsig_of;
   275 val defaultS = Type.defaultS o tsig_of;
   276 val subsort = Type.subsort o tsig_of;
   277 val norm_sort = Type.norm_sort o tsig_of;
   278 val of_sort = Type.of_sort o tsig_of;
   279 val witness_sorts = Type.witness_sorts o tsig_of;
   280 val univ_witness = Type.univ_witness o tsig_of;
   281 
   282 
   283 
   284 (** signature data **)
   285 
   286 (* errors *)
   287 
   288 fun of_theory sg = "\nof theory " ^ str_of_sg sg;
   289 
   290 fun err_inconsistent kinds =
   291   error ("Attempt to merge different versions of " ^ commas_quote kinds ^ " data");
   292 
   293 fun err_method name kind e =
   294   (writeln ("Error while invoking " ^ quote kind ^ " " ^ name ^ " method"); raise e);
   295 
   296 fun err_dup_init sg kind =
   297   error ("Duplicate initialization of " ^ quote kind ^ " data" ^ of_theory sg);
   298 
   299 fun err_uninit sg kind =
   300   error ("Tried to access uninitialized " ^ quote kind ^ " data" ^ 
   301 	 of_theory sg);
   302 
   303 (*Trying to access theory data using get / put operations from a different
   304   instance of the TheoryDataFun result.  Typical cure: re-load all files*)
   305 fun err_access sg kind =
   306   error ("Unauthorized access to " ^ quote kind ^ " data" ^ of_theory sg);
   307 
   308 
   309 (* prepare data *)
   310 
   311 val empty_data = Data Symtab.empty;
   312 
   313 fun merge_data (Data tab1, Data tab2) =
   314   let
   315     val data1 = map snd (Symtab.dest tab1);
   316     val data2 = map snd (Symtab.dest tab2);
   317     val all_data = data1 @ data2;
   318     val kinds = gen_distinct Object.eq_kind (map fst all_data);
   319 
   320    fun entry data kind =
   321      (case gen_assoc Object.eq_kind (data, kind) of
   322        None => []
   323      | Some x => [(kind, x)]);
   324 
   325     fun merge_entries [(kind, (e, mths as (_, ext, _, _)))] =
   326           (kind, (ext e handle exn => err_method "prep_ext" (Object.name_of_kind kind) exn, mths))
   327       | merge_entries [(kind, (e1, mths as (_, _, mrg, _))), (_, (e2, _))] =
   328           (kind, (mrg (e1, e2)
   329             handle exn => err_method "merge" (Object.name_of_kind kind) exn, mths))
   330       | merge_entries _ = sys_error "merge_entries";
   331 
   332     val data = map (fn k => merge_entries (entry data1 k @ entry data2 k)) kinds;
   333     val data_idx = map (fn (k, x) => (Object.name_of_kind k, (k, x))) data;
   334   in
   335     Data (Symtab.make data_idx)
   336       handle Symtab.DUPS dups => err_inconsistent dups
   337   end;
   338 
   339 fun prep_ext_data data = merge_data (data, empty_data);
   340 
   341 fun init_data_sg sg (Data tab) kind e cp ext mrg prt =
   342   let val name = Object.name_of_kind kind in
   343     Data (Symtab.update_new ((name, (kind, (e, (cp, ext, mrg, prt)))), tab))
   344       handle Symtab.DUP _ => err_dup_init sg name
   345   end;
   346 
   347 
   348 (* access data *)
   349 
   350 fun data_kinds (Data tab) = map fst (Symtab.dest tab);
   351 
   352 fun lookup_data sg tab kind =
   353   let val name = Object.name_of_kind kind in
   354     (case Symtab.lookup (tab, name) of
   355       Some (k, x) =>
   356         if Object.eq_kind (kind, k) then x
   357         else err_access sg name
   358     | None => err_uninit sg name)
   359   end;
   360 
   361 fun get_data kind f (sg as Sg (_, {data = Data tab, ...})) =
   362   let val x = fst (lookup_data sg tab kind)
   363   in f x handle Match => Object.kind_error kind end;
   364 
   365 fun print_data kind (sg as Sg (_, {data = Data tab, ...})) =
   366   let val (e, (_, _, _, prt)) = lookup_data sg tab kind
   367   in prt sg e handle exn => err_method ("print" ^ of_theory sg) (Object.name_of_kind kind) exn end;
   368 
   369 fun put_data_sg sg (Data tab) kind f x =
   370   Data (Symtab.update ((Object.name_of_kind kind,
   371     (kind, (f x, snd (lookup_data sg tab kind)))), tab));
   372 
   373 
   374 
   375 (** build signatures **)
   376 
   377 fun ext_stamps stamps (id as ref name) =
   378   let val stmps = (case stamps of ref "#" :: ss => ss | ss => ss) in
   379     if exists (equal name o !) stmps then
   380       error ("Theory already contains a " ^ quote name ^ " component")
   381     else id :: stmps
   382   end;
   383 
   384 fun create_sign self stamps name (syn, tsig, ctab, (path, spaces), data) =
   385   let
   386     val id = ref name;
   387     val sign =
   388       make_sign (id, self, tsig, ctab, syn, path, spaces, data, ext_stamps stamps id);
   389   in
   390     (case self of
   391       SgRef (Some r) => r := sign
   392     | _ => sys_error "Sign.create_sign");
   393     sign
   394   end;
   395 
   396 fun extend_sign keep extfun name decls
   397     (sg as Sg ({id = _, stamps}, {self, tsig, const_tab, syn, path, spaces, data})) =
   398   let
   399     val _ = check_stale sg;
   400     val (self', data') =
   401       if is_draft sg andalso keep then (self, data)
   402       else (SgRef (Some (ref sg)), prep_ext_data data);
   403   in
   404     create_sign self' stamps name
   405       (extfun (syn, tsig, const_tab, (path, spaces), data') decls)
   406   end;
   407 
   408 
   409 
   410 (** name spaces **)
   411 
   412 (* kinds *)
   413 
   414 val classK = "class";
   415 val typeK = "type";
   416 val constK = "const";
   417 
   418 
   419 (* declare and retrieve names *)
   420 
   421 fun space_of spaces kind =
   422   if_none (assoc (spaces, kind)) NameSpace.empty;
   423 
   424 (*input and output of qualified names*)
   425 fun intrn spaces kind = NameSpace.intern (space_of spaces kind);
   426 fun extrn spaces kind = NameSpace.extern (space_of spaces kind);
   427 fun cond_extrn spaces kind = NameSpace.cond_extern (space_of spaces kind);
   428 fun cond_extrn_table spaces kind tab = NameSpace.cond_extern_table (space_of spaces kind) tab;
   429 
   430 (*add / hide names*)
   431 fun change_space f spaces kind x = overwrite (spaces, (kind, f (space_of spaces kind, x)));
   432 fun add_names x = change_space NameSpace.extend x;
   433 fun hide_names x = change_space NameSpace.hide x;
   434 
   435 (*make full names*)
   436 fun full path name =
   437   if name = "" then error "Attempt to declare empty name \"\""
   438   else if NameSpace.is_qualified name then
   439     error ("Attempt to declare qualified name " ^ quote name)
   440   else NameSpace.pack (path @ [name]);
   441 
   442 (*base name*)
   443 val base_name = NameSpace.base;
   444 
   445 
   446 (* intern / extern names *)
   447 
   448 local
   449   (*prepare mapping of names*)
   450   fun mapping f add_xs t =
   451     let
   452       fun f' x = let val y = f x in if x = y then None else Some (x, y) end;
   453       val table = mapfilter f' (add_xs (t, []));
   454       fun lookup x = if_none (assoc (table, x)) x;
   455     in lookup end;
   456 
   457   (*intern / extern typ*)
   458   fun trn_typ trn T =
   459     T |> map_typ
   460       (mapping (trn classK) add_typ_classes T)
   461       (mapping (trn typeK) add_typ_tycons T);
   462 
   463   (*intern / extern term*)
   464   fun trn_term trn t =
   465     t |> map_term
   466       (mapping (trn classK) add_term_classes t)
   467       (mapping (trn typeK) add_term_tycons t)
   468       (mapping (trn constK) add_term_consts t);
   469 
   470   val spaces_of = #spaces o rep_sg;
   471 in
   472   fun intrn_class spaces = intrn spaces classK;
   473   fun extrn_class spaces = extrn spaces classK;
   474 
   475   val intrn_sort = map o intrn_class;
   476   val intrn_typ = trn_typ o intrn;
   477   val intrn_term = trn_term o intrn;
   478 
   479   val extrn_sort = map o extrn_class;
   480   val extrn_typ = trn_typ o extrn;
   481   val extrn_term = trn_term o extrn;
   482 
   483   fun intrn_tycons spaces T =
   484     map_typ I (mapping (intrn spaces typeK) add_typ_tycons T) T;
   485 
   486   val intern = intrn o spaces_of;
   487   val extern = extrn o spaces_of;
   488   val cond_extern = cond_extrn o spaces_of;
   489   fun cond_extern_table sg = cond_extrn_table (spaces_of sg);
   490 
   491   val intern_class = intrn_class o spaces_of;
   492   val intern_sort = intrn_sort o spaces_of;
   493   val intern_typ = intrn_typ o spaces_of;
   494   val intern_term = intrn_term o spaces_of;
   495 
   496   fun intern_tycon sg = intrn (spaces_of sg) typeK;
   497   fun intern_const sg = intrn (spaces_of sg) constK;
   498 
   499   val intern_tycons = intrn_tycons o spaces_of;
   500 
   501   val full_name = full o #path o rep_sg;
   502   fun full_name_path sg elems name =
   503     full (#path (rep_sg sg) @ NameSpace.unpack elems) name;
   504 end;
   505 
   506 
   507 
   508 (** pretty printing of terms, types etc. **)
   509 
   510 fun pretty_term (sg as Sg ({stamps, ...}, {syn, spaces, ...})) t =
   511   Syntax.pretty_term syn
   512     (exists (equal "CPure" o !) stamps)
   513     (if ! NameSpace.long_names then t else extrn_term spaces t);
   514 
   515 fun pretty_typ (Sg (_, {syn, spaces, ...})) T =
   516   Syntax.pretty_typ syn
   517     (if ! NameSpace.long_names then T else extrn_typ spaces T);
   518 
   519 fun pretty_sort (Sg (_, {syn, spaces, ...})) S =
   520   Syntax.pretty_sort syn
   521     (if ! NameSpace.long_names then S else extrn_sort spaces S);
   522 
   523 fun pretty_classrel sg (c1, c2) = Pretty.block
   524   [pretty_sort sg [c1], Pretty.str " <", Pretty.brk 1, pretty_sort sg [c2]];
   525 
   526 fun pretty_arity sg (t, Ss, S) =
   527   let
   528     val t' = cond_extern sg typeK t;
   529     val dom =
   530       if null Ss then []
   531       else [Pretty.list "(" ")" (map (pretty_sort sg) Ss), Pretty.brk 1];
   532   in
   533     Pretty.block
   534       ([Pretty.str (t' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort sg S])
   535   end;
   536 
   537 fun string_of_term sg t = Pretty.string_of (pretty_term sg t);
   538 fun string_of_typ sg T = Pretty.string_of (pretty_typ sg T);
   539 fun string_of_sort sg S = Pretty.string_of (pretty_sort sg S);
   540 
   541 fun str_of_sort sg S = Pretty.str_of (pretty_sort sg S);
   542 fun str_of_classrel sg c1_c2 = Pretty.str_of (pretty_classrel sg c1_c2);
   543 fun str_of_arity sg ar = Pretty.str_of (pretty_arity sg ar);
   544 
   545 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   546 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   547 
   548 
   549 
   550 (** read sorts **)  (*exception ERROR*)
   551 
   552 fun err_in_sort s =
   553   error ("The error(s) above occurred in sort " ^ quote s);
   554 
   555 fun rd_sort syn tsig spaces str =
   556   let val S = intrn_sort spaces (Syntax.read_sort syn str handle ERROR => err_in_sort str)
   557   in Type.cert_sort tsig S handle TYPE (msg, _, _) => (error_msg msg; err_in_sort str) end;
   558 
   559 (*read and certify sort wrt a signature*)
   560 fun read_sort (sg as Sg (_, {tsig, syn, spaces, ...})) str =
   561   (check_stale sg; rd_sort syn tsig spaces str);
   562 
   563 fun cert_sort _ tsig _ = Type.cert_sort tsig;
   564 
   565 
   566 
   567 (** read types **)  (*exception ERROR*)
   568 
   569 fun err_in_type s =
   570   error ("The error(s) above occurred in type " ^ quote s);
   571 
   572 fun rd_raw_typ syn tsig spaces def_sort str =
   573   intrn_tycons spaces
   574     (Syntax.read_typ syn (Type.get_sort tsig def_sort (intrn_sort spaces)) str
   575       handle ERROR => err_in_type str);
   576 
   577 fun read_raw_typ (sg as Sg (_, {tsig, syn, spaces, ...}), def_sort) str =
   578   (check_stale sg; rd_raw_typ syn tsig spaces def_sort str);
   579 
   580 (*read and certify typ wrt a signature*)
   581 local
   582   fun read_typ_aux cert (sg, def_sort) str =
   583     (cert (tsig_of sg) (read_raw_typ (sg, def_sort) str)
   584         handle TYPE (msg, _, _) => (error_msg msg; err_in_type str));
   585 in
   586   val read_typ = read_typ_aux Type.cert_typ;
   587   val read_typ_no_norm = read_typ_aux Type.cert_typ_no_norm;
   588 end;
   589 
   590 
   591 
   592 (** certify classes, sorts, types and terms **)   (*exception TYPE*)
   593 
   594 val certify_class = Type.cert_class o tsig_of;
   595 val certify_sort = Type.cert_sort o tsig_of;
   596 val certify_typ = Type.cert_typ o tsig_of;
   597 val certify_typ_no_norm = Type.cert_typ_no_norm o tsig_of;
   598 
   599 
   600 (* certify_term *)
   601 
   602 (*check for duplicate occurrences of TFree/TVar with distinct sorts*)
   603 fun nodup_tvars (env, Type (_, Ts)) = nodup_tvars_list (env, Ts)
   604   | nodup_tvars (env as (tfrees, tvars), T as TFree (v as (a, S))) =
   605       (case assoc_string (tfrees, a) of
   606         Some S' =>
   607           if S = S' then env
   608           else raise TYPE ("Type variable " ^ quote a ^
   609             " has two distinct sorts", [TFree (a, S'), T], [])
   610       | None => (v :: tfrees, tvars))
   611   | nodup_tvars (env as (tfrees, tvars), T as TVar (v as (a, S))) =
   612       (case assoc_string_int (tvars, a) of
   613         Some S' =>
   614           if S = S' then env
   615           else raise TYPE ("Type variable " ^ quote (Syntax.string_of_vname a) ^
   616             " has two distinct sorts", [TVar (a, S'), T], [])
   617       | None => (tfrees, v :: tvars))
   618 (*equivalent to foldl nodup_tvars_list, but 3X faster under Poly/ML*)
   619 and nodup_tvars_list (env, []) = env
   620   | nodup_tvars_list (env, T :: Ts) = nodup_tvars_list (nodup_tvars (env, T), Ts);
   621 
   622 (*check for duplicate occurrences of Free/Var with distinct types*)
   623 fun nodup_vars tm =
   624   let
   625     fun nodups (envs as (env as (frees, vars), envT)) tm =
   626       (case tm of
   627         Const (c, T) => (env, nodup_tvars (envT, T))
   628       | Free (v as (a, T)) =>
   629           (case assoc_string (frees, a) of
   630             Some T' =>
   631               if T = T' then (env, nodup_tvars (envT, T))
   632               else raise TYPE ("Variable " ^ quote a ^
   633                 " has two distinct types", [T', T], [])
   634           | None => ((v :: frees, vars), nodup_tvars (envT, T)))
   635       | Var (v as (ixn, T)) =>
   636           (case assoc_string_int (vars, ixn) of
   637             Some T' =>
   638               if T = T' then (env, nodup_tvars (envT, T))
   639               else raise TYPE ("Variable " ^ quote (Syntax.string_of_vname ixn) ^
   640                 " has two distinct types", [T', T], [])
   641           | None => ((frees, v :: vars), nodup_tvars (envT, T)))
   642       | Bound _ => envs
   643       | Abs (_, T, t) => nodups (env, nodup_tvars (envT, T)) t
   644       | s $ t => nodups (nodups envs s) t)
   645   in nodups (([], []), ([], [])) tm; tm end;
   646 
   647 (*compute and check type of the term*)
   648 fun type_check sg tm =
   649   let
   650     val prt = setmp Syntax.show_brackets true (pretty_term sg);
   651     val prT = pretty_typ sg;
   652 
   653     fun err_appl why bs t T u U =
   654       let
   655         val xs = map Free bs;		(*we do not rename here*)
   656         val t' = subst_bounds (xs, t);
   657         val u' = subst_bounds (xs, u);
   658         val text = cat_lines(TypeInfer.appl_error prt prT why t' T u' U);
   659       in raise TYPE (text, [T, U], [t', u']) end;
   660 
   661     fun typ_of (_, Const (_, T)) = T
   662       | typ_of (_, Free  (_, T)) = T
   663       | typ_of (_, Var (_, T)) = T
   664       | typ_of (bs, Bound i) = snd (nth_elem (i, bs) handle LIST _ =>
   665           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   666       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   667       | typ_of (bs, t $ u) =
   668           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   669             (case T of
   670               Type ("fun", [T1, T2]) =>
   671                 if T1 = U then T2 else err_appl "Incompatible operand type." bs t T u U
   672             | _ => err_appl "Operator not of function type." bs t T u U)
   673           end;
   674 
   675   in typ_of ([], tm) end;
   676 
   677 
   678 fun certify_term sg tm =
   679   let
   680     val _ = check_stale sg;
   681     val tsig = tsig_of sg;
   682 
   683     fun show_const a T = quote a ^ " :: " ^ quote (string_of_typ sg T);
   684 
   685     fun atom_err (errs, Const (a, T)) =
   686         (case const_type sg a of
   687           None => ("Undeclared constant " ^ show_const a T) :: errs
   688         | Some U =>
   689             if Type.typ_instance (tsig, T, U) then errs
   690             else ("Illegal type for constant " ^ show_const a T) :: errs)
   691       | atom_err (errs, Var ((x, i), _)) =
   692           if i < 0 then ("Negative index for Var " ^ quote x) :: errs else errs
   693       | atom_err (errs, _) = errs;
   694 
   695     val norm_tm =
   696       (case it_term_types (Type.typ_errors tsig) (tm, []) of
   697         [] => Type.norm_term tsig tm
   698       | errs => raise TYPE (cat_lines errs, [], [tm]));
   699     val _ = nodup_vars norm_tm;
   700   in
   701     (case foldl_aterms atom_err ([], norm_tm) of
   702       [] => (norm_tm, type_check sg norm_tm, maxidx_of_term norm_tm)
   703     | errs => raise TYPE (cat_lines errs, [], [norm_tm]))
   704   end;
   705 
   706 
   707 (** infer_types **)         (*exception ERROR*)
   708 
   709 (*
   710   def_type: partial map from indexnames to types (constrains Frees, Vars)
   711   def_sort: partial map from indexnames to sorts (constrains TFrees, TVars)
   712   used: list of already used type variables
   713   freeze: if true then generated parameters are turned into TFrees, else TVars
   714 
   715   termss: lists of alternative parses (only one combination should be type-correct)
   716   typs: expected types
   717 *)
   718 
   719 fun infer_types_simult sg def_type def_sort used freeze args =
   720   let
   721     val tsig = tsig_of sg;
   722     val prt = setmp Syntax.show_brackets true (pretty_term sg);
   723     val prT = pretty_typ sg;
   724 
   725     val termss = foldr multiply (map fst args, [[]]);
   726     val typs =
   727       map (fn (_, T) => certify_typ sg T handle TYPE (msg, _, _) => error msg) args;
   728 
   729     fun infer ts = OK
   730       (Type.infer_types prt prT tsig (const_type sg) def_type def_sort
   731         (intern_const sg) (intern_tycons sg) (intern_sort sg) used freeze typs ts)
   732       handle TYPE (msg, _, _) => Error msg;
   733 
   734     val err_results = map infer termss;
   735     val errs = mapfilter get_error err_results;
   736     val results = mapfilter get_ok err_results;
   737 
   738     val ambiguity = length termss;	(* FIXME !? *)
   739     (* FIXME to syntax.ML!? *)
   740     fun ambig_msg () =
   741       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   742       then
   743         error_msg "Got more than one parse tree.\n\
   744           \Retry with smaller Syntax.ambiguity_level for more information."
   745       else ();
   746   in
   747     if null results then (ambig_msg (); error (cat_lines errs))
   748     else if length results = 1 then
   749       (if ambiguity > ! Syntax.ambiguity_level then
   750         warning "Fortunately, only one parse tree is type correct.\n\
   751           \You may still want to disambiguate your grammar or your input."
   752       else (); hd results)
   753     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   754       (cat_lines (map (Pretty.string_of o prt) (flat (map fst results))))))
   755   end;
   756 
   757 
   758 fun infer_types sg def_type def_sort used freeze tsT =
   759   apfst hd (infer_types_simult sg def_type def_sort used freeze [tsT]);
   760 
   761 
   762 (** read_def_terms **)
   763 
   764 (*read terms, infer types*)
   765 fun read_def_terms (sign, types, sorts) used freeze sTs =
   766   let
   767     val syn = #syn (rep_sg sign);
   768     fun read (s, T) =
   769       let val T' = certify_typ sign T handle TYPE (msg, _, _) => error msg
   770       in (Syntax.read syn T' s, T') end;
   771     val tsTs = map read sTs;
   772   in infer_types_simult sign types sorts used freeze tsTs end;
   773 
   774 fun simple_read_term sign T s =
   775   (read_def_terms (sign, K None, K None) [] true [(s, T)]
   776     handle ERROR => error ("The error(s) above occurred for " ^ s)) |> #1 |> hd;
   777 
   778 
   779 
   780 (** extend signature **)    (*exception ERROR*)
   781 
   782 (** signature extension functions **)  (*exception ERROR*)
   783 
   784 fun decls_of path name_of mfixs =
   785   map (fn (x, y, mx) => (full path (name_of x mx), y)) mfixs;
   786 
   787 fun no_read _ _ _ decl = decl;
   788 
   789 
   790 (* add default sort *)
   791 
   792 fun ext_defS prep_sort (syn, tsig, ctab, (path, spaces), data) S =
   793   (syn, Type.ext_tsig_defsort tsig (prep_sort syn tsig spaces S), ctab, (path, spaces), data);
   794 
   795 fun ext_defsort arg   = ext_defS rd_sort arg;
   796 fun ext_defsort_i arg = ext_defS cert_sort arg;
   797 
   798 
   799 (* add type constructors *)
   800 
   801 fun ext_types (syn, tsig, ctab, (path, spaces), data) types =
   802   let val decls = decls_of path Syntax.type_name types in
   803     (Syntax.extend_type_gram syn types,
   804       Type.ext_tsig_types tsig decls, ctab,
   805       (path, add_names spaces typeK (map fst decls)), data)
   806   end;
   807 
   808 fun ext_nonterminals sg nonterms =
   809   ext_types sg (map (fn n => (n, 0, Syntax.NoSyn)) nonterms);
   810 
   811 
   812 (* add type abbreviations *)
   813 
   814 fun read_abbr syn tsig spaces (t, vs, rhs_src) =
   815   (t, vs, rd_raw_typ syn tsig spaces (K None) rhs_src)
   816     handle ERROR => error ("in type abbreviation " ^ t);
   817 
   818 fun ext_abbrs rd_abbr (syn, tsig, ctab, (path, spaces), data) abbrs =
   819   let
   820     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   821     val syn' = Syntax.extend_type_gram syn (map mfix_of abbrs);
   822 
   823     val abbrs' =
   824       map (fn (t, vs, rhs, mx) =>
   825         (full path (Syntax.type_name t mx), vs, rhs)) abbrs;
   826     val spaces' = add_names spaces typeK (map #1 abbrs');
   827     val decls = map (rd_abbr syn' tsig spaces') abbrs';
   828   in
   829     (syn', Type.ext_tsig_abbrs tsig decls, ctab, (path, spaces'), data)
   830   end;
   831 
   832 fun ext_tyabbrs abbrs = ext_abbrs read_abbr abbrs;
   833 fun ext_tyabbrs_i abbrs = ext_abbrs no_read abbrs;
   834 
   835 
   836 (* add type arities *)
   837 
   838 fun ext_ars int prep_sort (syn, tsig, ctab, (path, spaces), data) arities =
   839   let
   840     val prepS = prep_sort syn tsig spaces;
   841     fun prep_arity (c, Ss, S) =
   842       (if int then intrn spaces typeK c else c, map prepS Ss, prepS S);
   843     val tsig' = Type.ext_tsig_arities tsig (map prep_arity arities);
   844     val log_types = Type.logical_types tsig';
   845   in
   846     (Syntax.extend_log_types syn log_types, tsig', ctab, (path, spaces), data)
   847   end;
   848 
   849 fun ext_arities arg   = ext_ars true rd_sort arg;
   850 fun ext_arities_i arg = ext_ars false cert_sort arg;
   851 
   852 
   853 (* add term constants and syntax *)
   854 
   855 fun const_name path c mx =
   856   full path (Syntax.const_name c mx);
   857 
   858 fun err_in_const c =
   859   error ("in declaration of constant " ^ quote c);
   860 
   861 fun err_dup_consts cs =
   862   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   863 
   864 
   865 fun read_const syn tsig (path, spaces) (c, ty_src, mx) =
   866   (c, rd_raw_typ syn tsig spaces (K None) ty_src, mx)
   867     handle ERROR => err_in_const (const_name path c mx);
   868 
   869 fun ext_cnsts rd_const syn_only prmode (syn, tsig, ctab, (path, spaces), data) raw_consts =
   870   let
   871     fun prep_const (c, ty, mx) =
   872       (c, compress_type (Type.varifyT (Type.cert_typ tsig (Type.no_tvars ty))), mx)
   873         handle TYPE (msg, _, _) =>
   874           (error_msg msg; err_in_const (const_name path c mx));
   875 
   876     val consts = map (prep_const o rd_const syn tsig (path, spaces)) raw_consts;
   877     val decls =
   878       if syn_only then []
   879       else decls_of path Syntax.const_name consts;
   880   in
   881     (Syntax.extend_const_gram syn prmode consts, tsig,
   882       Symtab.extend (ctab, decls)
   883         handle Symtab.DUPS cs => err_dup_consts cs,
   884       (path, add_names spaces constK (map fst decls)), data)
   885   end;
   886 
   887 fun ext_consts_i sg = ext_cnsts no_read false ("", true) sg;
   888 fun ext_consts sg = ext_cnsts read_const false ("", true) sg;
   889 fun ext_syntax_i sg = ext_cnsts no_read true ("", true) sg;
   890 fun ext_syntax sg = ext_cnsts read_const true ("", true) sg;
   891 fun ext_modesyntax_i sg (prmode, consts) = ext_cnsts no_read true prmode sg consts;
   892 fun ext_modesyntax sg (prmode, consts) = ext_cnsts read_const true prmode sg consts;
   893 
   894 
   895 (* add type classes *)
   896 
   897 fun const_of_class c = c ^ "_class";
   898 
   899 fun class_of_const c_class =
   900   let
   901     val c = implode (take (size c_class - size "_class", explode c_class));
   902   in
   903     if const_of_class c = c_class then c
   904     else raise TERM ("class_of_const: bad name " ^ quote c_class, [])
   905   end;
   906 
   907 
   908 fun ext_classes int (syn, tsig, ctab, (path, spaces), data) classes =
   909   let
   910     val names = map fst classes;
   911     val consts =
   912       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   913 
   914     val full_names = map (full path) names;
   915     val spaces' = add_names spaces classK full_names;
   916     val intrn = if int then map (intrn_class spaces') else I;
   917     val classes' =
   918       ListPair.map (fn (c, (_, cs)) => (c, intrn cs)) (full_names, classes);
   919   in
   920     ext_consts_i
   921       (Syntax.extend_consts syn names,
   922         Type.ext_tsig_classes tsig classes', ctab, (path, spaces'), data)
   923     consts
   924   end;
   925 
   926 
   927 (* add to classrel *)
   928 
   929 fun ext_classrel int (syn, tsig, ctab, (path, spaces), data) pairs =
   930   let val intrn = if int then map (pairself (intrn_class spaces)) else I in
   931     (syn, Type.ext_tsig_classrel tsig (intrn pairs), ctab, (path, spaces), data)
   932   end;
   933 
   934 
   935 (* add translation rules *)
   936 
   937 fun ext_trrules (syn, tsig, ctab, (path, spaces), data) args =
   938   (Syntax.extend_trrules syn
   939     (map (Syntax.map_trrule (fn (root, str) => (intrn spaces typeK root, str))) args),
   940       tsig, ctab, (path, spaces), data);
   941 
   942 
   943 (* add to syntax *)
   944 
   945 fun ext_syn extfun (syn, tsig, ctab, names, data) args =
   946   (extfun syn args, tsig, ctab, names, data);
   947 
   948 
   949 (* add to path *)
   950 
   951 fun ext_path (syn, tsig, ctab, (path, spaces), data) elems =
   952   let
   953     val path' =
   954       if elems = ".." andalso not (null path) then fst (split_last path)
   955       else if elems = "/" then []
   956       else path @ NameSpace.unpack elems;
   957   in
   958     (syn, tsig, ctab, (path', spaces), data)
   959   end;      
   960 
   961 
   962 (* change name space *)
   963 
   964 fun ext_add_space (syn, tsig, ctab, (path, spaces), data) (kind, names) =
   965   (syn, tsig, ctab, (path, add_names spaces kind names), data);
   966 
   967 fun ext_hide_space (syn, tsig, ctab, (path, spaces), data) (kind, xnames) =
   968   (syn, tsig, ctab, (path, hide_names spaces kind (map (intrn spaces kind) xnames)), data);
   969 
   970 fun ext_hide_space_i (syn, tsig, ctab, (path, spaces), data) (kind, names) =
   971   (syn, tsig, ctab, (path, hide_names spaces kind names), data);
   972 
   973 
   974 (* signature data *)
   975 
   976 fun ext_init_data sg (syn, tsig, ctab, names, data) (kind, (e, cp, ext, mrg, prt)) =
   977   (syn, tsig, ctab, names, init_data_sg sg data kind e cp ext mrg prt);
   978 
   979 fun ext_put_data sg (syn, tsig, ctab, names, data) (kind, f, x) =
   980   (syn, tsig, ctab, names, put_data_sg sg data kind f x);
   981 
   982 
   983 fun copy_data (k, (e, mths as (cp, _, _, _))) =
   984   (k, (cp e handle exn => err_method "copy" (Object.name_of_kind k) exn, mths));
   985 
   986 fun copy (sg as Sg ({id = _, stamps}, {self, tsig, const_tab, syn, path, spaces, data})) =
   987   let
   988     val _ = check_stale sg;
   989     val self' = SgRef (Some (ref sg));
   990     val Data tab = data;
   991     val data' = Data (Symtab.map copy_data tab);
   992   in create_sign self' stamps "#" (syn, tsig, const_tab, (path, spaces), data') end;
   993 
   994 
   995 (* the external interfaces *)
   996 
   997 val add_classes       = extend_sign true (ext_classes true) "#";
   998 val add_classes_i     = extend_sign true (ext_classes false) "#";
   999 val add_classrel      = extend_sign true (ext_classrel true) "#";
  1000 val add_classrel_i    = extend_sign true (ext_classrel false) "#";
  1001 val add_defsort       = extend_sign true ext_defsort "#";
  1002 val add_defsort_i     = extend_sign true ext_defsort_i "#";
  1003 val add_types         = extend_sign true ext_types "#";
  1004 val add_nonterminals  = extend_sign true ext_nonterminals "#";
  1005 val add_tyabbrs       = extend_sign true ext_tyabbrs "#";
  1006 val add_tyabbrs_i     = extend_sign true ext_tyabbrs_i "#";
  1007 val add_arities       = extend_sign true ext_arities "#";
  1008 val add_arities_i     = extend_sign true ext_arities_i "#";
  1009 val add_consts        = extend_sign true ext_consts "#";
  1010 val add_consts_i      = extend_sign true ext_consts_i "#";
  1011 val add_syntax        = extend_sign true ext_syntax "#";
  1012 val add_syntax_i      = extend_sign true ext_syntax_i "#";
  1013 val add_modesyntax    = extend_sign true ext_modesyntax "#";
  1014 val add_modesyntax_i  = extend_sign true ext_modesyntax_i "#";
  1015 val add_trfuns        = extend_sign true (ext_syn Syntax.extend_trfuns) "#";
  1016 val add_trfunsT       = extend_sign true (ext_syn Syntax.extend_trfunsT) "#";
  1017 val add_tokentrfuns   = extend_sign true (ext_syn Syntax.extend_tokentrfuns) "#";
  1018 val add_trrules       = extend_sign true ext_trrules "#";
  1019 val add_trrules_i     = extend_sign true (ext_syn Syntax.extend_trrules_i) "#";
  1020 val add_path          = extend_sign true ext_path "#";
  1021 val add_space         = extend_sign true ext_add_space "#";
  1022 val hide_space        = extend_sign true ext_hide_space "#";
  1023 val hide_space_i      = extend_sign true ext_hide_space_i "#";
  1024 fun init_data arg sg  = extend_sign true (ext_init_data sg) "#" arg sg;
  1025 fun put_data k f x sg = extend_sign true (ext_put_data sg) "#" (k, f, x) sg;
  1026 fun add_name name sg  = extend_sign true K name () sg;
  1027 fun prep_ext sg       = extend_sign false K "#" () sg;
  1028 
  1029 
  1030 
  1031 (** merge signatures **)    	(*exception TERM*)
  1032 
  1033 (* merge_stamps *)
  1034 
  1035 fun merge_stamps stamps1 stamps2 =
  1036   let val stamps = merge_rev_lists stamps1 stamps2 in
  1037     (case duplicates (map ! stamps) of
  1038       [] => stamps
  1039     | dups => raise TERM ("Attempt to merge different versions of theories "
  1040         ^ commas_quote dups, []))
  1041   end;
  1042 
  1043 
  1044 (* implicit merge -- trivial only *)
  1045 
  1046 fun merge_refs (sgr1 as SgRef (Some (ref (sg1 as Sg ({stamps = s1, ...}, _)))),
  1047         sgr2 as SgRef (Some (ref (sg2 as Sg ({stamps = s2, ...}, _))))) =
  1048       if fast_subsig (sg2, sg1) then sgr1
  1049       else if fast_subsig (sg1, sg2) then sgr2
  1050       else if subsig (sg2, sg1) then sgr1
  1051       else if subsig (sg1, sg2) then sgr2
  1052       else (merge_stamps s1 s2; (*check for different versions*)
  1053         raise TERM ("Attempt to do non-trivial merge of signatures", []))
  1054   | merge_refs _ = sys_error "Sign.merge_refs";
  1055 
  1056 val merge = deref o merge_refs o pairself self_ref;
  1057 
  1058 
  1059 (* proper merge *)		(*exception TERM/ERROR*)
  1060 
  1061 fun nontriv_merge (sg1, sg2) =
  1062   if subsig (sg2, sg1) then sg1
  1063   else if subsig (sg1, sg2) then sg2
  1064   else if is_draft sg1 orelse is_draft sg2 then
  1065     raise TERM ("Attempt to merge draft signatures", [])
  1066   else
  1067     (*neither is union already; must form union*)
  1068     let
  1069       val Sg ({id = _, stamps = stamps1}, {self = _, tsig = tsig1, const_tab = const_tab1,
  1070         syn = syn1, path = _, spaces = spaces1, data = data1}) = sg1;
  1071       val Sg ({id = _, stamps = stamps2}, {self = _, tsig = tsig2, const_tab = const_tab2,
  1072         syn = syn2, path = _, spaces = spaces2, data = data2}) = sg2;
  1073 
  1074       val id = ref "";
  1075       val self_ref = ref sg1;                   (*dummy value*)
  1076       val self = SgRef (Some self_ref);
  1077 
  1078       val stamps = merge_stamps stamps1 stamps2;
  1079       val tsig = Type.merge_tsigs (tsig1, tsig2);
  1080       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
  1081         handle Symtab.DUPS cs =>
  1082           raise TERM ("Incompatible types for constant(s) " ^ commas_quote cs, []);
  1083       val syn = Syntax.merge_syntaxes syn1 syn2;
  1084 
  1085       val path = [];
  1086       val kinds = distinct (map fst (spaces1 @ spaces2));
  1087       val spaces =
  1088         kinds ~~
  1089           ListPair.map NameSpace.merge
  1090             (map (space_of spaces1) kinds, map (space_of spaces2) kinds);
  1091 
  1092       val data = merge_data (data1, data2);
  1093 
  1094       val sign = make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps);
  1095     in
  1096       self_ref := sign; sign
  1097     end;
  1098 
  1099 
  1100 
  1101 (** partial Pure signature **)
  1102 
  1103 val dummy_sg = make_sign (ref "", SgRef None, Type.tsig0,
  1104   Symtab.empty, Syntax.pure_syn, [], [], empty_data, []);
  1105 
  1106 val pre_pure =
  1107   create_sign (SgRef (Some (ref dummy_sg))) [] "#"
  1108     (Syntax.pure_syn, Type.tsig0, Symtab.empty, ([], []), empty_data);
  1109 
  1110 
  1111 end;