src/HOL/Multivariate_Analysis/Topology_Euclidean_Space.thy
author huffman
Sat Aug 20 06:34:51 2011 -0700 (2011-08-20)
changeset 44342 8321948340ea
parent 44286 8766839efb1b
child 44365 5daa55003649
permissions -rw-r--r--
redefine constant 'trivial_limit' as an abbreviation
     1 (*  title:      HOL/Library/Topology_Euclidian_Space.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3     Author:     Robert Himmelmann, TU Muenchen
     4     Author:     Brian Huffman, Portland State University
     5 *)
     6 
     7 header {* Elementary topology in Euclidean space. *}
     8 
     9 theory Topology_Euclidean_Space
    10 imports SEQ Linear_Algebra "~~/src/HOL/Library/Glbs"
    11 begin
    12 
    13 (* to be moved elsewhere *)
    14 
    15 lemma euclidean_dist_l2:"dist x (y::'a::euclidean_space) = setL2 (\<lambda>i. dist(x$$i) (y$$i)) {..<DIM('a)}"
    16   unfolding dist_norm norm_eq_sqrt_inner setL2_def apply(subst euclidean_inner)
    17   apply(auto simp add:power2_eq_square) unfolding euclidean_component_diff ..
    18 
    19 lemma dist_nth_le: "dist (x $$ i) (y $$ i) \<le> dist x (y::'a::euclidean_space)"
    20   apply(subst(2) euclidean_dist_l2) apply(cases "i<DIM('a)")
    21   apply(rule member_le_setL2) by auto
    22 
    23 subsection {* General notion of a topologies as values *}
    24 
    25 definition "istopology L \<longleftrightarrow> L {} \<and> (\<forall>S T. L S \<longrightarrow> L T \<longrightarrow> L (S \<inter> T)) \<and> (\<forall>K. Ball K L \<longrightarrow> L (\<Union> K))"
    26 typedef (open) 'a topology = "{L::('a set) \<Rightarrow> bool. istopology L}"
    27   morphisms "openin" "topology"
    28   unfolding istopology_def by blast
    29 
    30 lemma istopology_open_in[intro]: "istopology(openin U)"
    31   using openin[of U] by blast
    32 
    33 lemma topology_inverse': "istopology U \<Longrightarrow> openin (topology U) = U"
    34   using topology_inverse[unfolded mem_Collect_eq] .
    35 
    36 lemma topology_inverse_iff: "istopology U \<longleftrightarrow> openin (topology U) = U"
    37   using topology_inverse[of U] istopology_open_in[of "topology U"] by auto
    38 
    39 lemma topology_eq: "T1 = T2 \<longleftrightarrow> (\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S)"
    40 proof-
    41   {assume "T1=T2" hence "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S" by simp}
    42   moreover
    43   {assume H: "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S"
    44     hence "openin T1 = openin T2" by (simp add: fun_eq_iff)
    45     hence "topology (openin T1) = topology (openin T2)" by simp
    46     hence "T1 = T2" unfolding openin_inverse .}
    47   ultimately show ?thesis by blast
    48 qed
    49 
    50 text{* Infer the "universe" from union of all sets in the topology. *}
    51 
    52 definition "topspace T =  \<Union>{S. openin T S}"
    53 
    54 subsubsection {* Main properties of open sets *}
    55 
    56 lemma openin_clauses:
    57   fixes U :: "'a topology"
    58   shows "openin U {}"
    59   "\<And>S T. openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S\<inter>T)"
    60   "\<And>K. (\<forall>S \<in> K. openin U S) \<Longrightarrow> openin U (\<Union>K)"
    61   using openin[of U] unfolding istopology_def mem_Collect_eq
    62   by fast+
    63 
    64 lemma openin_subset[intro]: "openin U S \<Longrightarrow> S \<subseteq> topspace U"
    65   unfolding topspace_def by blast
    66 lemma openin_empty[simp]: "openin U {}" by (simp add: openin_clauses)
    67 
    68 lemma openin_Int[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<inter> T)"
    69   using openin_clauses by simp
    70 
    71 lemma openin_Union[intro]: "(\<forall>S \<in>K. openin U S) \<Longrightarrow> openin U (\<Union> K)"
    72   using openin_clauses by simp
    73 
    74 lemma openin_Un[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<union> T)"
    75   using openin_Union[of "{S,T}" U] by auto
    76 
    77 lemma openin_topspace[intro, simp]: "openin U (topspace U)" by (simp add: openin_Union topspace_def)
    78 
    79 lemma openin_subopen: "openin U S \<longleftrightarrow> (\<forall>x \<in> S. \<exists>T. openin U T \<and> x \<in> T \<and> T \<subseteq> S)" (is "?lhs \<longleftrightarrow> ?rhs")
    80 proof
    81   assume ?lhs then show ?rhs by auto
    82 next
    83   assume H: ?rhs
    84   let ?t = "\<Union>{T. openin U T \<and> T \<subseteq> S}"
    85   have "openin U ?t" by (simp add: openin_Union)
    86   also have "?t = S" using H by auto
    87   finally show "openin U S" .
    88 qed
    89 
    90 subsubsection {* Closed sets *}
    91 
    92 definition "closedin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> openin U (topspace U - S)"
    93 
    94 lemma closedin_subset: "closedin U S \<Longrightarrow> S \<subseteq> topspace U" by (metis closedin_def)
    95 lemma closedin_empty[simp]: "closedin U {}" by (simp add: closedin_def)
    96 lemma closedin_topspace[intro,simp]:
    97   "closedin U (topspace U)" by (simp add: closedin_def)
    98 lemma closedin_Un[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<union> T)"
    99   by (auto simp add: Diff_Un closedin_def)
   100 
   101 lemma Diff_Inter[intro]: "A - \<Inter>S = \<Union> {A - s|s. s\<in>S}" by auto
   102 lemma closedin_Inter[intro]: assumes Ke: "K \<noteq> {}" and Kc: "\<forall>S \<in>K. closedin U S"
   103   shows "closedin U (\<Inter> K)"  using Ke Kc unfolding closedin_def Diff_Inter by auto
   104 
   105 lemma closedin_Int[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<inter> T)"
   106   using closedin_Inter[of "{S,T}" U] by auto
   107 
   108 lemma Diff_Diff_Int: "A - (A - B) = A \<inter> B" by blast
   109 lemma openin_closedin_eq: "openin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> closedin U (topspace U - S)"
   110   apply (auto simp add: closedin_def Diff_Diff_Int inf_absorb2)
   111   apply (metis openin_subset subset_eq)
   112   done
   113 
   114 lemma openin_closedin:  "S \<subseteq> topspace U \<Longrightarrow> (openin U S \<longleftrightarrow> closedin U (topspace U - S))"
   115   by (simp add: openin_closedin_eq)
   116 
   117 lemma openin_diff[intro]: assumes oS: "openin U S" and cT: "closedin U T" shows "openin U (S - T)"
   118 proof-
   119   have "S - T = S \<inter> (topspace U - T)" using openin_subset[of U S]  oS cT
   120     by (auto simp add: topspace_def openin_subset)
   121   then show ?thesis using oS cT by (auto simp add: closedin_def)
   122 qed
   123 
   124 lemma closedin_diff[intro]: assumes oS: "closedin U S" and cT: "openin U T" shows "closedin U (S - T)"
   125 proof-
   126   have "S - T = S \<inter> (topspace U - T)" using closedin_subset[of U S]  oS cT
   127     by (auto simp add: topspace_def )
   128   then show ?thesis using oS cT by (auto simp add: openin_closedin_eq)
   129 qed
   130 
   131 subsubsection {* Subspace topology *}
   132 
   133 definition "subtopology U V = topology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   134 
   135 lemma istopology_subtopology: "istopology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   136   (is "istopology ?L")
   137 proof-
   138   have "?L {}" by blast
   139   {fix A B assume A: "?L A" and B: "?L B"
   140     from A B obtain Sa and Sb where Sa: "openin U Sa" "A = Sa \<inter> V" and Sb: "openin U Sb" "B = Sb \<inter> V" by blast
   141     have "A\<inter>B = (Sa \<inter> Sb) \<inter> V" "openin U (Sa \<inter> Sb)"  using Sa Sb by blast+
   142     then have "?L (A \<inter> B)" by blast}
   143   moreover
   144   {fix K assume K: "K \<subseteq> Collect ?L"
   145     have th0: "Collect ?L = (\<lambda>S. S \<inter> V) ` Collect (openin U)"
   146       apply (rule set_eqI)
   147       apply (simp add: Ball_def image_iff)
   148       by metis
   149     from K[unfolded th0 subset_image_iff]
   150     obtain Sk where Sk: "Sk \<subseteq> Collect (openin U)" "K = (\<lambda>S. S \<inter> V) ` Sk" by blast
   151     have "\<Union>K = (\<Union>Sk) \<inter> V" using Sk by auto
   152     moreover have "openin U (\<Union> Sk)" using Sk by (auto simp add: subset_eq)
   153     ultimately have "?L (\<Union>K)" by blast}
   154   ultimately show ?thesis
   155     unfolding subset_eq mem_Collect_eq istopology_def by blast
   156 qed
   157 
   158 lemma openin_subtopology:
   159   "openin (subtopology U V) S \<longleftrightarrow> (\<exists> T. (openin U T) \<and> (S = T \<inter> V))"
   160   unfolding subtopology_def topology_inverse'[OF istopology_subtopology]
   161   by auto
   162 
   163 lemma topspace_subtopology: "topspace(subtopology U V) = topspace U \<inter> V"
   164   by (auto simp add: topspace_def openin_subtopology)
   165 
   166 lemma closedin_subtopology:
   167   "closedin (subtopology U V) S \<longleftrightarrow> (\<exists>T. closedin U T \<and> S = T \<inter> V)"
   168   unfolding closedin_def topspace_subtopology
   169   apply (simp add: openin_subtopology)
   170   apply (rule iffI)
   171   apply clarify
   172   apply (rule_tac x="topspace U - T" in exI)
   173   by auto
   174 
   175 lemma openin_subtopology_refl: "openin (subtopology U V) V \<longleftrightarrow> V \<subseteq> topspace U"
   176   unfolding openin_subtopology
   177   apply (rule iffI, clarify)
   178   apply (frule openin_subset[of U])  apply blast
   179   apply (rule exI[where x="topspace U"])
   180   by auto
   181 
   182 lemma subtopology_superset: assumes UV: "topspace U \<subseteq> V"
   183   shows "subtopology U V = U"
   184 proof-
   185   {fix S
   186     {fix T assume T: "openin U T" "S = T \<inter> V"
   187       from T openin_subset[OF T(1)] UV have eq: "S = T" by blast
   188       have "openin U S" unfolding eq using T by blast}
   189     moreover
   190     {assume S: "openin U S"
   191       hence "\<exists>T. openin U T \<and> S = T \<inter> V"
   192         using openin_subset[OF S] UV by auto}
   193     ultimately have "(\<exists>T. openin U T \<and> S = T \<inter> V) \<longleftrightarrow> openin U S" by blast}
   194   then show ?thesis unfolding topology_eq openin_subtopology by blast
   195 qed
   196 
   197 lemma subtopology_topspace[simp]: "subtopology U (topspace U) = U"
   198   by (simp add: subtopology_superset)
   199 
   200 lemma subtopology_UNIV[simp]: "subtopology U UNIV = U"
   201   by (simp add: subtopology_superset)
   202 
   203 subsubsection {* The standard Euclidean topology *}
   204 
   205 definition
   206   euclidean :: "'a::topological_space topology" where
   207   "euclidean = topology open"
   208 
   209 lemma open_openin: "open S \<longleftrightarrow> openin euclidean S"
   210   unfolding euclidean_def
   211   apply (rule cong[where x=S and y=S])
   212   apply (rule topology_inverse[symmetric])
   213   apply (auto simp add: istopology_def)
   214   done
   215 
   216 lemma topspace_euclidean: "topspace euclidean = UNIV"
   217   apply (simp add: topspace_def)
   218   apply (rule set_eqI)
   219   by (auto simp add: open_openin[symmetric])
   220 
   221 lemma topspace_euclidean_subtopology[simp]: "topspace (subtopology euclidean S) = S"
   222   by (simp add: topspace_euclidean topspace_subtopology)
   223 
   224 lemma closed_closedin: "closed S \<longleftrightarrow> closedin euclidean S"
   225   by (simp add: closed_def closedin_def topspace_euclidean open_openin Compl_eq_Diff_UNIV)
   226 
   227 lemma open_subopen: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S)"
   228   by (simp add: open_openin openin_subopen[symmetric])
   229 
   230 text {* Basic "localization" results are handy for connectedness. *}
   231 
   232 lemma openin_open: "openin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. open T \<and> (S = U \<inter> T))"
   233   by (auto simp add: openin_subtopology open_openin[symmetric])
   234 
   235 lemma openin_open_Int[intro]: "open S \<Longrightarrow> openin (subtopology euclidean U) (U \<inter> S)"
   236   by (auto simp add: openin_open)
   237 
   238 lemma open_openin_trans[trans]:
   239  "open S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> openin (subtopology euclidean S) T"
   240   by (metis Int_absorb1  openin_open_Int)
   241 
   242 lemma open_subset:  "S \<subseteq> T \<Longrightarrow> open S \<Longrightarrow> openin (subtopology euclidean T) S"
   243   by (auto simp add: openin_open)
   244 
   245 lemma closedin_closed: "closedin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. closed T \<and> S = U \<inter> T)"
   246   by (simp add: closedin_subtopology closed_closedin Int_ac)
   247 
   248 lemma closedin_closed_Int: "closed S ==> closedin (subtopology euclidean U) (U \<inter> S)"
   249   by (metis closedin_closed)
   250 
   251 lemma closed_closedin_trans: "closed S \<Longrightarrow> closed T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> closedin (subtopology euclidean S) T"
   252   apply (subgoal_tac "S \<inter> T = T" )
   253   apply auto
   254   apply (frule closedin_closed_Int[of T S])
   255   by simp
   256 
   257 lemma closed_subset: "S \<subseteq> T \<Longrightarrow> closed S \<Longrightarrow> closedin (subtopology euclidean T) S"
   258   by (auto simp add: closedin_closed)
   259 
   260 lemma openin_euclidean_subtopology_iff:
   261   fixes S U :: "'a::metric_space set"
   262   shows "openin (subtopology euclidean U) S
   263   \<longleftrightarrow> S \<subseteq> U \<and> (\<forall>x\<in>S. \<exists>e>0. \<forall>x'\<in>U. dist x' x < e \<longrightarrow> x'\<in> S)" (is "?lhs \<longleftrightarrow> ?rhs")
   264 proof
   265   assume ?lhs thus ?rhs unfolding openin_open open_dist by blast
   266 next
   267   def T \<equiv> "{x. \<exists>a\<in>S. \<exists>d>0. (\<forall>y\<in>U. dist y a < d \<longrightarrow> y \<in> S) \<and> dist x a < d}"
   268   have 1: "\<forall>x\<in>T. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> T"
   269     unfolding T_def
   270     apply clarsimp
   271     apply (rule_tac x="d - dist x a" in exI)
   272     apply (clarsimp simp add: less_diff_eq)
   273     apply (erule rev_bexI)
   274     apply (rule_tac x=d in exI, clarify)
   275     apply (erule le_less_trans [OF dist_triangle])
   276     done
   277   assume ?rhs hence 2: "S = U \<inter> T"
   278     unfolding T_def
   279     apply auto
   280     apply (drule (1) bspec, erule rev_bexI)
   281     apply auto
   282     done
   283   from 1 2 show ?lhs
   284     unfolding openin_open open_dist by fast
   285 qed
   286 
   287 text {* These "transitivity" results are handy too *}
   288 
   289 lemma openin_trans[trans]: "openin (subtopology euclidean T) S \<Longrightarrow> openin (subtopology euclidean U) T
   290   \<Longrightarrow> openin (subtopology euclidean U) S"
   291   unfolding open_openin openin_open by blast
   292 
   293 lemma openin_open_trans: "openin (subtopology euclidean T) S \<Longrightarrow> open T \<Longrightarrow> open S"
   294   by (auto simp add: openin_open intro: openin_trans)
   295 
   296 lemma closedin_trans[trans]:
   297  "closedin (subtopology euclidean T) S \<Longrightarrow>
   298            closedin (subtopology euclidean U) T
   299            ==> closedin (subtopology euclidean U) S"
   300   by (auto simp add: closedin_closed closed_closedin closed_Inter Int_assoc)
   301 
   302 lemma closedin_closed_trans: "closedin (subtopology euclidean T) S \<Longrightarrow> closed T \<Longrightarrow> closed S"
   303   by (auto simp add: closedin_closed intro: closedin_trans)
   304 
   305 
   306 subsection {* Open and closed balls *}
   307 
   308 definition
   309   ball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   310   "ball x e = {y. dist x y < e}"
   311 
   312 definition
   313   cball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   314   "cball x e = {y. dist x y \<le> e}"
   315 
   316 lemma mem_ball[simp]: "y \<in> ball x e \<longleftrightarrow> dist x y < e" by (simp add: ball_def)
   317 lemma mem_cball[simp]: "y \<in> cball x e \<longleftrightarrow> dist x y \<le> e" by (simp add: cball_def)
   318 
   319 lemma mem_ball_0 [simp]:
   320   fixes x :: "'a::real_normed_vector"
   321   shows "x \<in> ball 0 e \<longleftrightarrow> norm x < e"
   322   by (simp add: dist_norm)
   323 
   324 lemma mem_cball_0 [simp]:
   325   fixes x :: "'a::real_normed_vector"
   326   shows "x \<in> cball 0 e \<longleftrightarrow> norm x \<le> e"
   327   by (simp add: dist_norm)
   328 
   329 lemma centre_in_cball[simp]: "x \<in> cball x e \<longleftrightarrow> 0\<le> e"  by simp
   330 lemma ball_subset_cball[simp,intro]: "ball x e \<subseteq> cball x e" by (simp add: subset_eq)
   331 lemma subset_ball[intro]: "d <= e ==> ball x d \<subseteq> ball x e" by (simp add: subset_eq)
   332 lemma subset_cball[intro]: "d <= e ==> cball x d \<subseteq> cball x e" by (simp add: subset_eq)
   333 lemma ball_max_Un: "ball a (max r s) = ball a r \<union> ball a s"
   334   by (simp add: set_eq_iff) arith
   335 
   336 lemma ball_min_Int: "ball a (min r s) = ball a r \<inter> ball a s"
   337   by (simp add: set_eq_iff)
   338 
   339 lemma diff_less_iff: "(a::real) - b > 0 \<longleftrightarrow> a > b"
   340   "(a::real) - b < 0 \<longleftrightarrow> a < b"
   341   "a - b < c \<longleftrightarrow> a < c +b" "a - b > c \<longleftrightarrow> a > c +b" by arith+
   342 lemma diff_le_iff: "(a::real) - b \<ge> 0 \<longleftrightarrow> a \<ge> b" "(a::real) - b \<le> 0 \<longleftrightarrow> a \<le> b"
   343   "a - b \<le> c \<longleftrightarrow> a \<le> c +b" "a - b \<ge> c \<longleftrightarrow> a \<ge> c +b"  by arith+
   344 
   345 lemma open_ball[intro, simp]: "open (ball x e)"
   346   unfolding open_dist ball_def mem_Collect_eq Ball_def
   347   unfolding dist_commute
   348   apply clarify
   349   apply (rule_tac x="e - dist xa x" in exI)
   350   using dist_triangle_alt[where z=x]
   351   apply (clarsimp simp add: diff_less_iff)
   352   apply atomize
   353   apply (erule_tac x="y" in allE)
   354   apply (erule_tac x="xa" in allE)
   355   by arith
   356 
   357 lemma centre_in_ball[simp]: "x \<in> ball x e \<longleftrightarrow> e > 0" by (metis mem_ball dist_self)
   358 lemma open_contains_ball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. ball x e \<subseteq> S)"
   359   unfolding open_dist subset_eq mem_ball Ball_def dist_commute ..
   360 
   361 lemma openE[elim?]:
   362   assumes "open S" "x\<in>S" 
   363   obtains e where "e>0" "ball x e \<subseteq> S"
   364   using assms unfolding open_contains_ball by auto
   365 
   366 lemma open_contains_ball_eq: "open S \<Longrightarrow> \<forall>x. x\<in>S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   367   by (metis open_contains_ball subset_eq centre_in_ball)
   368 
   369 lemma ball_eq_empty[simp]: "ball x e = {} \<longleftrightarrow> e \<le> 0"
   370   unfolding mem_ball set_eq_iff
   371   apply (simp add: not_less)
   372   by (metis zero_le_dist order_trans dist_self)
   373 
   374 lemma ball_empty[intro]: "e \<le> 0 ==> ball x e = {}" by simp
   375 
   376 
   377 subsection{* Connectedness *}
   378 
   379 definition "connected S \<longleftrightarrow>
   380   ~(\<exists>e1 e2. open e1 \<and> open e2 \<and> S \<subseteq> (e1 \<union> e2) \<and> (e1 \<inter> e2 \<inter> S = {})
   381   \<and> ~(e1 \<inter> S = {}) \<and> ~(e2 \<inter> S = {}))"
   382 
   383 lemma connected_local:
   384  "connected S \<longleftrightarrow> ~(\<exists>e1 e2.
   385                  openin (subtopology euclidean S) e1 \<and>
   386                  openin (subtopology euclidean S) e2 \<and>
   387                  S \<subseteq> e1 \<union> e2 \<and>
   388                  e1 \<inter> e2 = {} \<and>
   389                  ~(e1 = {}) \<and>
   390                  ~(e2 = {}))"
   391 unfolding connected_def openin_open by (safe, blast+)
   392 
   393 lemma exists_diff:
   394   fixes P :: "'a set \<Rightarrow> bool"
   395   shows "(\<exists>S. P(- S)) \<longleftrightarrow> (\<exists>S. P S)" (is "?lhs \<longleftrightarrow> ?rhs")
   396 proof-
   397   {assume "?lhs" hence ?rhs by blast }
   398   moreover
   399   {fix S assume H: "P S"
   400     have "S = - (- S)" by auto
   401     with H have "P (- (- S))" by metis }
   402   ultimately show ?thesis by metis
   403 qed
   404 
   405 lemma connected_clopen: "connected S \<longleftrightarrow>
   406         (\<forall>T. openin (subtopology euclidean S) T \<and>
   407             closedin (subtopology euclidean S) T \<longrightarrow> T = {} \<or> T = S)" (is "?lhs \<longleftrightarrow> ?rhs")
   408 proof-
   409   have " \<not> connected S \<longleftrightarrow> (\<exists>e1 e2. open e1 \<and> open (- e2) \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   410     unfolding connected_def openin_open closedin_closed
   411     apply (subst exists_diff) by blast
   412   hence th0: "connected S \<longleftrightarrow> \<not> (\<exists>e2 e1. closed e2 \<and> open e1 \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   413     (is " _ \<longleftrightarrow> \<not> (\<exists>e2 e1. ?P e2 e1)") apply (simp add: closed_def) by metis
   414 
   415   have th1: "?rhs \<longleftrightarrow> \<not> (\<exists>t' t. closed t'\<and>t = S\<inter>t' \<and> t\<noteq>{} \<and> t\<noteq>S \<and> (\<exists>t'. open t' \<and> t = S \<inter> t'))"
   416     (is "_ \<longleftrightarrow> \<not> (\<exists>t' t. ?Q t' t)")
   417     unfolding connected_def openin_open closedin_closed by auto
   418   {fix e2
   419     {fix e1 have "?P e2 e1 \<longleftrightarrow> (\<exists>t.  closed e2 \<and> t = S\<inter>e2 \<and> open e1 \<and> t = S\<inter>e1 \<and> t\<noteq>{} \<and> t\<noteq>S)"
   420         by auto}
   421     then have "(\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by metis}
   422   then have "\<forall>e2. (\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by blast
   423   then show ?thesis unfolding th0 th1 by simp
   424 qed
   425 
   426 lemma connected_empty[simp, intro]: "connected {}"
   427   by (simp add: connected_def)
   428 
   429 
   430 subsection{* Limit points *}
   431 
   432 definition (in topological_space)
   433   islimpt:: "'a \<Rightarrow> 'a set \<Rightarrow> bool" (infixr "islimpt" 60) where
   434   "x islimpt S \<longleftrightarrow> (\<forall>T. x\<in>T \<longrightarrow> open T \<longrightarrow> (\<exists>y\<in>S. y\<in>T \<and> y\<noteq>x))"
   435 
   436 lemma islimptI:
   437   assumes "\<And>T. x \<in> T \<Longrightarrow> open T \<Longrightarrow> \<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
   438   shows "x islimpt S"
   439   using assms unfolding islimpt_def by auto
   440 
   441 lemma islimptE:
   442   assumes "x islimpt S" and "x \<in> T" and "open T"
   443   obtains y where "y \<in> S" and "y \<in> T" and "y \<noteq> x"
   444   using assms unfolding islimpt_def by auto
   445 
   446 lemma islimpt_subset: "x islimpt S \<Longrightarrow> S \<subseteq> T ==> x islimpt T" by (auto simp add: islimpt_def)
   447 
   448 lemma islimpt_approachable:
   449   fixes x :: "'a::metric_space"
   450   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e)"
   451   unfolding islimpt_def
   452   apply auto
   453   apply(erule_tac x="ball x e" in allE)
   454   apply auto
   455   apply(rule_tac x=y in bexI)
   456   apply (auto simp add: dist_commute)
   457   apply (simp add: open_dist, drule (1) bspec)
   458   apply (clarify, drule spec, drule (1) mp, auto)
   459   done
   460 
   461 lemma islimpt_approachable_le:
   462   fixes x :: "'a::metric_space"
   463   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in> S. x' \<noteq> x \<and> dist x' x <= e)"
   464   unfolding islimpt_approachable
   465   using approachable_lt_le[where f="\<lambda>x'. dist x' x" and P="\<lambda>x'. \<not> (x'\<in>S \<and> x'\<noteq>x)"]
   466   by metis 
   467 
   468 text {* A perfect space has no isolated points. *}
   469 
   470 class perfect_space = topological_space +
   471   assumes islimpt_UNIV [simp, intro]: "x islimpt UNIV"
   472 
   473 lemma perfect_choose_dist:
   474   fixes x :: "'a::{perfect_space, metric_space}"
   475   shows "0 < r \<Longrightarrow> \<exists>a. a \<noteq> x \<and> dist a x < r"
   476 using islimpt_UNIV [of x]
   477 by (simp add: islimpt_approachable)
   478 
   479 instance euclidean_space \<subseteq> perfect_space
   480 proof
   481   fix x :: 'a
   482   { fix e :: real assume "0 < e"
   483     def y \<equiv> "x + scaleR (e/2) (sgn (basis 0))"
   484     from `0 < e` have "y \<noteq> x"
   485       unfolding y_def by (simp add: sgn_zero_iff DIM_positive)
   486     from `0 < e` have "dist y x < e"
   487       unfolding y_def by (simp add: dist_norm norm_sgn)
   488     from `y \<noteq> x` and `dist y x < e`
   489     have "\<exists>y\<in>UNIV. y \<noteq> x \<and> dist y x < e" by auto
   490   }
   491   then show "x islimpt UNIV" unfolding islimpt_approachable by blast
   492 qed
   493 
   494 lemma closed_limpt: "closed S \<longleftrightarrow> (\<forall>x. x islimpt S \<longrightarrow> x \<in> S)"
   495   unfolding closed_def
   496   apply (subst open_subopen)
   497   apply (simp add: islimpt_def subset_eq)
   498   by (metis ComplE ComplI)
   499 
   500 lemma islimpt_EMPTY[simp]: "\<not> x islimpt {}"
   501   unfolding islimpt_def by auto
   502 
   503 lemma finite_set_avoid:
   504   fixes a :: "'a::metric_space"
   505   assumes fS: "finite S" shows  "\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<longrightarrow> d <= dist a x"
   506 proof(induct rule: finite_induct[OF fS])
   507   case 1 thus ?case by (auto intro: zero_less_one)
   508 next
   509   case (2 x F)
   510   from 2 obtain d where d: "d >0" "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> d \<le> dist a x" by blast
   511   {assume "x = a" hence ?case using d by auto  }
   512   moreover
   513   {assume xa: "x\<noteq>a"
   514     let ?d = "min d (dist a x)"
   515     have dp: "?d > 0" using xa d(1) using dist_nz by auto
   516     from d have d': "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> ?d \<le> dist a x" by auto
   517     with dp xa have ?case by(auto intro!: exI[where x="?d"]) }
   518   ultimately show ?case by blast
   519 qed
   520 
   521 lemma islimpt_finite:
   522   fixes S :: "'a::metric_space set"
   523   assumes fS: "finite S" shows "\<not> a islimpt S"
   524   unfolding islimpt_approachable
   525   using finite_set_avoid[OF fS, of a] by (metis dist_commute  not_le)
   526 
   527 lemma islimpt_Un: "x islimpt (S \<union> T) \<longleftrightarrow> x islimpt S \<or> x islimpt T"
   528   apply (rule iffI)
   529   defer
   530   apply (metis Un_upper1 Un_upper2 islimpt_subset)
   531   unfolding islimpt_def
   532   apply (rule ccontr, clarsimp, rename_tac A B)
   533   apply (drule_tac x="A \<inter> B" in spec)
   534   apply (auto simp add: open_Int)
   535   done
   536 
   537 lemma discrete_imp_closed:
   538   fixes S :: "'a::metric_space set"
   539   assumes e: "0 < e" and d: "\<forall>x \<in> S. \<forall>y \<in> S. dist y x < e \<longrightarrow> y = x"
   540   shows "closed S"
   541 proof-
   542   {fix x assume C: "\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e"
   543     from e have e2: "e/2 > 0" by arith
   544     from C[rule_format, OF e2] obtain y where y: "y \<in> S" "y\<noteq>x" "dist y x < e/2" by blast
   545     let ?m = "min (e/2) (dist x y) "
   546     from e2 y(2) have mp: "?m > 0" by (simp add: dist_nz[THEN sym])
   547     from C[rule_format, OF mp] obtain z where z: "z \<in> S" "z\<noteq>x" "dist z x < ?m" by blast
   548     have th: "dist z y < e" using z y
   549       by (intro dist_triangle_lt [where z=x], simp)
   550     from d[rule_format, OF y(1) z(1) th] y z
   551     have False by (auto simp add: dist_commute)}
   552   then show ?thesis by (metis islimpt_approachable closed_limpt [where 'a='a])
   553 qed
   554 
   555 
   556 subsection {* Interior of a Set *}
   557 
   558 definition "interior S = {x. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S}"
   559 
   560 lemma interior_eq: "interior S = S \<longleftrightarrow> open S"
   561   apply (simp add: set_eq_iff interior_def)
   562   apply (subst (2) open_subopen) by (safe, blast+)
   563 
   564 lemma interior_open: "open S ==> (interior S = S)" by (metis interior_eq)
   565 
   566 lemma interior_empty[simp]: "interior {} = {}" by (simp add: interior_def)
   567 
   568 lemma open_interior[simp, intro]: "open(interior S)"
   569   apply (simp add: interior_def)
   570   apply (subst open_subopen) by blast
   571 
   572 lemma interior_interior[simp]: "interior(interior S) = interior S" by (metis interior_eq open_interior)
   573 lemma interior_subset: "interior S \<subseteq> S" by (auto simp add: interior_def)
   574 lemma subset_interior: "S \<subseteq> T ==> (interior S) \<subseteq> (interior T)" by (auto simp add: interior_def)
   575 lemma interior_maximal: "T \<subseteq> S \<Longrightarrow> open T ==> T \<subseteq> (interior S)" by (auto simp add: interior_def)
   576 lemma interior_unique: "T \<subseteq> S \<Longrightarrow> open T  \<Longrightarrow> (\<forall>T'. T' \<subseteq> S \<and> open T' \<longrightarrow> T' \<subseteq> T) \<Longrightarrow> interior S = T"
   577   by (metis equalityI interior_maximal interior_subset open_interior)
   578 lemma mem_interior: "x \<in> interior S \<longleftrightarrow> (\<exists>e. 0 < e \<and> ball x e \<subseteq> S)"
   579   apply (simp add: interior_def)
   580   by (metis open_contains_ball centre_in_ball open_ball subset_trans)
   581 
   582 lemma open_subset_interior: "open S ==> S \<subseteq> interior T \<longleftrightarrow> S \<subseteq> T"
   583   by (metis interior_maximal interior_subset subset_trans)
   584 
   585 lemma interior_inter[simp]: "interior(S \<inter> T) = interior S \<inter> interior T"
   586   apply (rule equalityI, simp)
   587   apply (metis Int_lower1 Int_lower2 subset_interior)
   588   by (metis Int_mono interior_subset open_Int open_interior open_subset_interior)
   589 
   590 lemma interior_limit_point [intro]:
   591   fixes x :: "'a::perfect_space"
   592   assumes x: "x \<in> interior S" shows "x islimpt S"
   593   using x islimpt_UNIV [of x]
   594   unfolding interior_def islimpt_def
   595   apply (clarsimp, rename_tac T T')
   596   apply (drule_tac x="T \<inter> T'" in spec)
   597   apply (auto simp add: open_Int)
   598   done
   599 
   600 lemma interior_closed_Un_empty_interior:
   601   assumes cS: "closed S" and iT: "interior T = {}"
   602   shows "interior(S \<union> T) = interior S"
   603 proof
   604   show "interior S \<subseteq> interior (S\<union>T)"
   605     by (rule subset_interior, blast)
   606 next
   607   show "interior (S \<union> T) \<subseteq> interior S"
   608   proof
   609     fix x assume "x \<in> interior (S \<union> T)"
   610     then obtain R where "open R" "x \<in> R" "R \<subseteq> S \<union> T"
   611       unfolding interior_def by fast
   612     show "x \<in> interior S"
   613     proof (rule ccontr)
   614       assume "x \<notin> interior S"
   615       with `x \<in> R` `open R` obtain y where "y \<in> R - S"
   616         unfolding interior_def set_eq_iff by fast
   617       from `open R` `closed S` have "open (R - S)" by (rule open_Diff)
   618       from `R \<subseteq> S \<union> T` have "R - S \<subseteq> T" by fast
   619       from `y \<in> R - S` `open (R - S)` `R - S \<subseteq> T` `interior T = {}`
   620       show "False" unfolding interior_def by fast
   621     qed
   622   qed
   623 qed
   624 
   625 
   626 subsection {* Closure of a Set *}
   627 
   628 definition "closure S = S \<union> {x | x. x islimpt S}"
   629 
   630 lemma closure_interior: "closure S = - interior (- S)"
   631 proof-
   632   { fix x
   633     have "x\<in>- interior (- S) \<longleftrightarrow> x \<in> closure S"  (is "?lhs = ?rhs")
   634     proof
   635       let ?exT = "\<lambda> y. (\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> - S)"
   636       assume "?lhs"
   637       hence *:"\<not> ?exT x"
   638         unfolding interior_def
   639         by simp
   640       { assume "\<not> ?rhs"
   641         hence False using *
   642           unfolding closure_def islimpt_def
   643           by blast
   644       }
   645       thus "?rhs"
   646         by blast
   647     next
   648       assume "?rhs" thus "?lhs"
   649         unfolding closure_def interior_def islimpt_def
   650         by blast
   651     qed
   652   }
   653   thus ?thesis
   654     by blast
   655 qed
   656 
   657 lemma interior_closure: "interior S = - (closure (- S))"
   658 proof-
   659   { fix x
   660     have "x \<in> interior S \<longleftrightarrow> x \<in> - (closure (- S))"
   661       unfolding interior_def closure_def islimpt_def
   662       by auto
   663   }
   664   thus ?thesis
   665     by blast
   666 qed
   667 
   668 lemma closed_closure[simp, intro]: "closed (closure S)"
   669 proof-
   670   have "closed (- interior (-S))" by blast
   671   thus ?thesis using closure_interior[of S] by simp
   672 qed
   673 
   674 lemma closure_hull: "closure S = closed hull S"
   675 proof-
   676   have "S \<subseteq> closure S"
   677     unfolding closure_def
   678     by blast
   679   moreover
   680   have "closed (closure S)"
   681     using closed_closure[of S]
   682     by assumption
   683   moreover
   684   { fix t
   685     assume *:"S \<subseteq> t" "closed t"
   686     { fix x
   687       assume "x islimpt S"
   688       hence "x islimpt t" using *(1)
   689         using islimpt_subset[of x, of S, of t]
   690         by blast
   691     }
   692     with * have "closure S \<subseteq> t"
   693       unfolding closure_def
   694       using closed_limpt[of t]
   695       by auto
   696   }
   697   ultimately show ?thesis
   698     using hull_unique[of S, of "closure S", of closed]
   699     by simp
   700 qed
   701 
   702 lemma closure_eq: "closure S = S \<longleftrightarrow> closed S"
   703   unfolding closure_hull
   704   using hull_eq[of closed, OF  closed_Inter, of S]
   705   by metis
   706 
   707 lemma closure_closed[simp]: "closed S \<Longrightarrow> closure S = S"
   708   using closure_eq[of S]
   709   by simp
   710 
   711 lemma closure_closure[simp]: "closure (closure S) = closure S"
   712   unfolding closure_hull
   713   using hull_hull[of closed S]
   714   by assumption
   715 
   716 lemma closure_subset: "S \<subseteq> closure S"
   717   unfolding closure_hull
   718   using hull_subset[of S closed]
   719   by assumption
   720 
   721 lemma subset_closure: "S \<subseteq> T \<Longrightarrow> closure S \<subseteq> closure T"
   722   unfolding closure_hull
   723   using hull_mono[of S T closed]
   724   by assumption
   725 
   726 lemma closure_minimal: "S \<subseteq> T \<Longrightarrow>  closed T \<Longrightarrow> closure S \<subseteq> T"
   727   using hull_minimal[of S T closed]
   728   unfolding closure_hull
   729   by simp
   730 
   731 lemma closure_unique: "S \<subseteq> T \<and> closed T \<and> (\<forall> T'. S \<subseteq> T' \<and> closed T' \<longrightarrow> T \<subseteq> T') \<Longrightarrow> closure S = T"
   732   using hull_unique[of S T closed]
   733   unfolding closure_hull
   734   by simp
   735 
   736 lemma closure_empty[simp]: "closure {} = {}"
   737   using closed_empty closure_closed[of "{}"]
   738   by simp
   739 
   740 lemma closure_univ[simp]: "closure UNIV = UNIV"
   741   using closure_closed[of UNIV]
   742   by simp
   743 
   744 lemma closure_eq_empty: "closure S = {} \<longleftrightarrow> S = {}"
   745   using closure_empty closure_subset[of S]
   746   by blast
   747 
   748 lemma closure_subset_eq: "closure S \<subseteq> S \<longleftrightarrow> closed S"
   749   using closure_eq[of S] closure_subset[of S]
   750   by simp
   751 
   752 lemma open_inter_closure_eq_empty:
   753   "open S \<Longrightarrow> (S \<inter> closure T) = {} \<longleftrightarrow> S \<inter> T = {}"
   754   using open_subset_interior[of S "- T"]
   755   using interior_subset[of "- T"]
   756   unfolding closure_interior
   757   by auto
   758 
   759 lemma open_inter_closure_subset:
   760   "open S \<Longrightarrow> (S \<inter> (closure T)) \<subseteq> closure(S \<inter> T)"
   761 proof
   762   fix x
   763   assume as: "open S" "x \<in> S \<inter> closure T"
   764   { assume *:"x islimpt T"
   765     have "x islimpt (S \<inter> T)"
   766     proof (rule islimptI)
   767       fix A
   768       assume "x \<in> A" "open A"
   769       with as have "x \<in> A \<inter> S" "open (A \<inter> S)"
   770         by (simp_all add: open_Int)
   771       with * obtain y where "y \<in> T" "y \<in> A \<inter> S" "y \<noteq> x"
   772         by (rule islimptE)
   773       hence "y \<in> S \<inter> T" "y \<in> A \<and> y \<noteq> x"
   774         by simp_all
   775       thus "\<exists>y\<in>(S \<inter> T). y \<in> A \<and> y \<noteq> x" ..
   776     qed
   777   }
   778   then show "x \<in> closure (S \<inter> T)" using as
   779     unfolding closure_def
   780     by blast
   781 qed
   782 
   783 lemma closure_complement: "closure(- S) = - interior(S)"
   784 proof-
   785   have "S = - (- S)"
   786     by auto
   787   thus ?thesis
   788     unfolding closure_interior
   789     by auto
   790 qed
   791 
   792 lemma interior_complement: "interior(- S) = - closure(S)"
   793   unfolding closure_interior
   794   by blast
   795 
   796 
   797 subsection {* Frontier (aka boundary) *}
   798 
   799 definition "frontier S = closure S - interior S"
   800 
   801 lemma frontier_closed: "closed(frontier S)"
   802   by (simp add: frontier_def closed_Diff)
   803 
   804 lemma frontier_closures: "frontier S = (closure S) \<inter> (closure(- S))"
   805   by (auto simp add: frontier_def interior_closure)
   806 
   807 lemma frontier_straddle:
   808   fixes a :: "'a::metric_space"
   809   shows "a \<in> frontier S \<longleftrightarrow> (\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e))" (is "?lhs \<longleftrightarrow> ?rhs")
   810 proof
   811   assume "?lhs"
   812   { fix e::real
   813     assume "e > 0"
   814     let ?rhse = "(\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e)"
   815     { assume "a\<in>S"
   816       have "\<exists>x\<in>S. dist a x < e" using `e>0` `a\<in>S` by(rule_tac x=a in bexI) auto
   817       moreover have "\<exists>x. x \<notin> S \<and> dist a x < e" using `?lhs` `a\<in>S`
   818         unfolding frontier_closures closure_def islimpt_def using `e>0`
   819         by (auto, erule_tac x="ball a e" in allE, auto)
   820       ultimately have ?rhse by auto
   821     }
   822     moreover
   823     { assume "a\<notin>S"
   824       hence ?rhse using `?lhs`
   825         unfolding frontier_closures closure_def islimpt_def
   826         using open_ball[of a e] `e > 0`
   827           by simp (metis centre_in_ball mem_ball open_ball) 
   828     }
   829     ultimately have ?rhse by auto
   830   }
   831   thus ?rhs by auto
   832 next
   833   assume ?rhs
   834   moreover
   835   { fix T assume "a\<notin>S" and
   836     as:"\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e)" "a \<notin> S" "a \<in> T" "open T"
   837     from `open T` `a \<in> T` have "\<exists>e>0. ball a e \<subseteq> T" unfolding open_contains_ball[of T] by auto
   838     then obtain e where "e>0" "ball a e \<subseteq> T" by auto
   839     then obtain y where y:"y\<in>S" "dist a y < e"  using as(1) by auto
   840     have "\<exists>y\<in>S. y \<in> T \<and> y \<noteq> a"
   841       using `dist a y < e` `ball a e \<subseteq> T` unfolding ball_def using `y\<in>S` `a\<notin>S` by auto
   842   }
   843   hence "a \<in> closure S" unfolding closure_def islimpt_def using `?rhs` by auto
   844   moreover
   845   { fix T assume "a \<in> T"  "open T" "a\<in>S"
   846     then obtain e where "e>0" and balle: "ball a e \<subseteq> T" unfolding open_contains_ball using `?rhs` by auto
   847     obtain x where "x \<notin> S" "dist a x < e" using `?rhs` using `e>0` by auto
   848     hence "\<exists>y\<in>- S. y \<in> T \<and> y \<noteq> a" using balle `a\<in>S` unfolding ball_def by (rule_tac x=x in bexI)auto
   849   }
   850   hence "a islimpt (- S) \<or> a\<notin>S" unfolding islimpt_def by auto
   851   ultimately show ?lhs unfolding frontier_closures using closure_def[of "- S"] by auto
   852 qed
   853 
   854 lemma frontier_subset_closed: "closed S \<Longrightarrow> frontier S \<subseteq> S"
   855   by (metis frontier_def closure_closed Diff_subset)
   856 
   857 lemma frontier_empty[simp]: "frontier {} = {}"
   858   by (simp add: frontier_def)
   859 
   860 lemma frontier_subset_eq: "frontier S \<subseteq> S \<longleftrightarrow> closed S"
   861 proof-
   862   { assume "frontier S \<subseteq> S"
   863     hence "closure S \<subseteq> S" using interior_subset unfolding frontier_def by auto
   864     hence "closed S" using closure_subset_eq by auto
   865   }
   866   thus ?thesis using frontier_subset_closed[of S] ..
   867 qed
   868 
   869 lemma frontier_complement: "frontier(- S) = frontier S"
   870   by (auto simp add: frontier_def closure_complement interior_complement)
   871 
   872 lemma frontier_disjoint_eq: "frontier S \<inter> S = {} \<longleftrightarrow> open S"
   873   using frontier_complement frontier_subset_eq[of "- S"]
   874   unfolding open_closed by auto
   875 
   876 
   877 subsection {* Filters and the ``eventually true'' quantifier *}
   878 
   879 definition
   880   at_infinity :: "'a::real_normed_vector filter" where
   881   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
   882 
   883 definition
   884   indirection :: "'a::real_normed_vector \<Rightarrow> 'a \<Rightarrow> 'a filter"
   885     (infixr "indirection" 70) where
   886   "a indirection v = (at a) within {b. \<exists>c\<ge>0. b - a = scaleR c v}"
   887 
   888 text{* Prove That They are all filters. *}
   889 
   890 lemma eventually_at_infinity:
   891   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. norm x >= b \<longrightarrow> P x)"
   892 unfolding at_infinity_def
   893 proof (rule eventually_Abs_filter, rule is_filter.intro)
   894   fix P Q :: "'a \<Rightarrow> bool"
   895   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
   896   then obtain r s where
   897     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
   898   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
   899   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
   900 qed auto
   901 
   902 text {* Identify Trivial limits, where we can't approach arbitrarily closely. *}
   903 
   904 lemma trivial_limit_within:
   905   shows "trivial_limit (at a within S) \<longleftrightarrow> \<not> a islimpt S"
   906 proof
   907   assume "trivial_limit (at a within S)"
   908   thus "\<not> a islimpt S"
   909     unfolding trivial_limit_def
   910     unfolding eventually_within eventually_at_topological
   911     unfolding islimpt_def
   912     apply (clarsimp simp add: set_eq_iff)
   913     apply (rename_tac T, rule_tac x=T in exI)
   914     apply (clarsimp, drule_tac x=y in bspec, simp_all)
   915     done
   916 next
   917   assume "\<not> a islimpt S"
   918   thus "trivial_limit (at a within S)"
   919     unfolding trivial_limit_def
   920     unfolding eventually_within eventually_at_topological
   921     unfolding islimpt_def
   922     apply clarsimp
   923     apply (rule_tac x=T in exI)
   924     apply auto
   925     done
   926 qed
   927 
   928 lemma trivial_limit_at_iff: "trivial_limit (at a) \<longleftrightarrow> \<not> a islimpt UNIV"
   929   using trivial_limit_within [of a UNIV]
   930   by (simp add: within_UNIV)
   931 
   932 lemma trivial_limit_at:
   933   fixes a :: "'a::perfect_space"
   934   shows "\<not> trivial_limit (at a)"
   935   by (simp add: trivial_limit_at_iff)
   936 
   937 lemma trivial_limit_at_infinity:
   938   "\<not> trivial_limit (at_infinity :: ('a::{real_normed_vector,perfect_space}) filter)"
   939   unfolding trivial_limit_def eventually_at_infinity
   940   apply clarsimp
   941   apply (subgoal_tac "\<exists>x::'a. x \<noteq> 0", clarify)
   942    apply (rule_tac x="scaleR (b / norm x) x" in exI, simp)
   943   apply (cut_tac islimpt_UNIV [of "0::'a", unfolded islimpt_def])
   944   apply (drule_tac x=UNIV in spec, simp)
   945   done
   946 
   947 text {* Some property holds "sufficiently close" to the limit point. *}
   948 
   949 lemma eventually_at: (* FIXME: this replaces Limits.eventually_at *)
   950   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   951 unfolding eventually_at dist_nz by auto
   952 
   953 lemma eventually_within: "eventually P (at a within S) \<longleftrightarrow>
   954         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   955 unfolding eventually_within eventually_at dist_nz by auto
   956 
   957 lemma eventually_within_le: "eventually P (at a within S) \<longleftrightarrow>
   958         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a <= d \<longrightarrow> P x)" (is "?lhs = ?rhs")
   959 unfolding eventually_within
   960 by auto (metis Rats_dense_in_nn_real order_le_less_trans order_refl) 
   961 
   962 lemma eventually_happens: "eventually P net ==> trivial_limit net \<or> (\<exists>x. P x)"
   963   unfolding trivial_limit_def
   964   by (auto elim: eventually_rev_mp)
   965 
   966 lemma trivial_limit_eventually: "trivial_limit net \<Longrightarrow> eventually P net"
   967   unfolding trivial_limit_def by (auto elim: eventually_rev_mp)
   968 
   969 lemma trivial_limit_eq: "trivial_limit net \<longleftrightarrow> (\<forall>P. eventually P net)"
   970   by (simp add: filter_eq_iff)
   971 
   972 text{* Combining theorems for "eventually" *}
   973 
   974 lemma eventually_rev_mono:
   975   "eventually P net \<Longrightarrow> (\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually Q net"
   976 using eventually_mono [of P Q] by fast
   977 
   978 lemma not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> ~(trivial_limit net) ==> ~(eventually (\<lambda>x. P x) net)"
   979   by (simp add: eventually_False)
   980 
   981 
   982 subsection {* Limits *}
   983 
   984 text{* Notation Lim to avoid collition with lim defined in analysis *}
   985 
   986 definition Lim :: "'a filter \<Rightarrow> ('a \<Rightarrow> 'b::t2_space) \<Rightarrow> 'b"
   987   where "Lim A f = (THE l. (f ---> l) A)"
   988 
   989 lemma Lim:
   990  "(f ---> l) net \<longleftrightarrow>
   991         trivial_limit net \<or>
   992         (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
   993   unfolding tendsto_iff trivial_limit_eq by auto
   994 
   995 text{* Show that they yield usual definitions in the various cases. *}
   996 
   997 lemma Lim_within_le: "(f ---> l)(at a within S) \<longleftrightarrow>
   998            (\<forall>e>0. \<exists>d>0. \<forall>x\<in>S. 0 < dist x a  \<and> dist x a  <= d \<longrightarrow> dist (f x) l < e)"
   999   by (auto simp add: tendsto_iff eventually_within_le)
  1000 
  1001 lemma Lim_within: "(f ---> l) (at a within S) \<longleftrightarrow>
  1002         (\<forall>e >0. \<exists>d>0. \<forall>x \<in> S. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
  1003   by (auto simp add: tendsto_iff eventually_within)
  1004 
  1005 lemma Lim_at: "(f ---> l) (at a) \<longleftrightarrow>
  1006         (\<forall>e >0. \<exists>d>0. \<forall>x. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
  1007   by (auto simp add: tendsto_iff eventually_at)
  1008 
  1009 lemma Lim_at_iff_LIM: "(f ---> l) (at a) \<longleftrightarrow> f -- a --> l"
  1010   unfolding Lim_at LIM_def by (simp only: zero_less_dist_iff)
  1011 
  1012 lemma Lim_at_infinity:
  1013   "(f ---> l) at_infinity \<longleftrightarrow> (\<forall>e>0. \<exists>b. \<forall>x. norm x >= b \<longrightarrow> dist (f x) l < e)"
  1014   by (auto simp add: tendsto_iff eventually_at_infinity)
  1015 
  1016 lemma Lim_sequentially:
  1017  "(S ---> l) sequentially \<longleftrightarrow>
  1018           (\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (S n) l < e)"
  1019   by (rule LIMSEQ_def) (* FIXME: redundant *)
  1020 
  1021 lemma Lim_eventually: "eventually (\<lambda>x. f x = l) net \<Longrightarrow> (f ---> l) net"
  1022   by (rule topological_tendstoI, auto elim: eventually_rev_mono)
  1023 
  1024 text{* The expected monotonicity property. *}
  1025 
  1026 lemma Lim_within_empty: "(f ---> l) (net within {})"
  1027   unfolding tendsto_def Limits.eventually_within by simp
  1028 
  1029 lemma Lim_within_subset: "(f ---> l) (net within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (net within T)"
  1030   unfolding tendsto_def Limits.eventually_within
  1031   by (auto elim!: eventually_elim1)
  1032 
  1033 lemma Lim_Un: assumes "(f ---> l) (net within S)" "(f ---> l) (net within T)"
  1034   shows "(f ---> l) (net within (S \<union> T))"
  1035   using assms unfolding tendsto_def Limits.eventually_within
  1036   apply clarify
  1037   apply (drule spec, drule (1) mp, drule (1) mp)
  1038   apply (drule spec, drule (1) mp, drule (1) mp)
  1039   apply (auto elim: eventually_elim2)
  1040   done
  1041 
  1042 lemma Lim_Un_univ:
  1043  "(f ---> l) (net within S) \<Longrightarrow> (f ---> l) (net within T) \<Longrightarrow>  S \<union> T = UNIV
  1044         ==> (f ---> l) net"
  1045   by (metis Lim_Un within_UNIV)
  1046 
  1047 text{* Interrelations between restricted and unrestricted limits. *}
  1048 
  1049 lemma Lim_at_within: "(f ---> l) net ==> (f ---> l)(net within S)"
  1050   (* FIXME: rename *)
  1051   unfolding tendsto_def Limits.eventually_within
  1052   apply (clarify, drule spec, drule (1) mp, drule (1) mp)
  1053   by (auto elim!: eventually_elim1)
  1054 
  1055 lemma eventually_within_interior:
  1056   assumes "x \<in> interior S"
  1057   shows "eventually P (at x within S) \<longleftrightarrow> eventually P (at x)" (is "?lhs = ?rhs")
  1058 proof-
  1059   from assms obtain T where T: "open T" "x \<in> T" "T \<subseteq> S"
  1060     unfolding interior_def by fast
  1061   { assume "?lhs"
  1062     then obtain A where "open A" "x \<in> A" "\<forall>y\<in>A. y \<noteq> x \<longrightarrow> y \<in> S \<longrightarrow> P y"
  1063       unfolding Limits.eventually_within Limits.eventually_at_topological
  1064       by auto
  1065     with T have "open (A \<inter> T)" "x \<in> A \<inter> T" "\<forall>y\<in>(A \<inter> T). y \<noteq> x \<longrightarrow> P y"
  1066       by auto
  1067     then have "?rhs"
  1068       unfolding Limits.eventually_at_topological by auto
  1069   } moreover
  1070   { assume "?rhs" hence "?lhs"
  1071       unfolding Limits.eventually_within
  1072       by (auto elim: eventually_elim1)
  1073   } ultimately
  1074   show "?thesis" ..
  1075 qed
  1076 
  1077 lemma at_within_interior:
  1078   "x \<in> interior S \<Longrightarrow> at x within S = at x"
  1079   by (simp add: filter_eq_iff eventually_within_interior)
  1080 
  1081 lemma at_within_open:
  1082   "\<lbrakk>x \<in> S; open S\<rbrakk> \<Longrightarrow> at x within S = at x"
  1083   by (simp only: at_within_interior interior_open)
  1084 
  1085 lemma Lim_within_open:
  1086   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1087   assumes"a \<in> S" "open S"
  1088   shows "(f ---> l)(at a within S) \<longleftrightarrow> (f ---> l)(at a)"
  1089   using assms by (simp only: at_within_open)
  1090 
  1091 lemma Lim_within_LIMSEQ:
  1092   fixes a :: real and L :: "'a::metric_space"
  1093   assumes "\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1094   shows "(X ---> L) (at a within T)"
  1095 proof (rule ccontr)
  1096   assume "\<not> (X ---> L) (at a within T)"
  1097   hence "\<exists>r>0. \<forall>s>0. \<exists>x\<in>T. x \<noteq> a \<and> \<bar>x - a\<bar> < s \<and> r \<le> dist (X x) L"
  1098     unfolding tendsto_iff eventually_within dist_norm by (simp add: not_less[symmetric])
  1099   then obtain r where r: "r > 0" "\<And>s. s > 0 \<Longrightarrow> \<exists>x\<in>T-{a}. \<bar>x - a\<bar> < s \<and> dist (X x) L \<ge> r" by blast
  1100 
  1101   let ?F = "\<lambda>n::nat. SOME x. x \<in> T \<and> x \<noteq> a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> dist (X x) L \<ge> r"
  1102   have "\<And>n. \<exists>x. x \<in> T \<and> x \<noteq> a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> dist (X x) L \<ge> r"
  1103     using r by (simp add: Bex_def)
  1104   hence F: "\<And>n. ?F n \<in> T \<and> ?F n \<noteq> a \<and> \<bar>?F n - a\<bar> < inverse (real (Suc n)) \<and> dist (X (?F n)) L \<ge> r"
  1105     by (rule someI_ex)
  1106   hence F1: "\<And>n. ?F n \<in> T \<and> ?F n \<noteq> a"
  1107     and F2: "\<And>n. \<bar>?F n - a\<bar> < inverse (real (Suc n))"
  1108     and F3: "\<And>n. dist (X (?F n)) L \<ge> r"
  1109     by fast+
  1110 
  1111   have "?F ----> a"
  1112   proof (rule LIMSEQ_I, unfold real_norm_def)
  1113       fix e::real
  1114       assume "0 < e"
  1115         (* choose no such that inverse (real (Suc n)) < e *)
  1116       then have "\<exists>no. inverse (real (Suc no)) < e" by (rule reals_Archimedean)
  1117       then obtain m where nodef: "inverse (real (Suc m)) < e" by auto
  1118       show "\<exists>no. \<forall>n. no \<le> n --> \<bar>?F n - a\<bar> < e"
  1119       proof (intro exI allI impI)
  1120         fix n
  1121         assume mlen: "m \<le> n"
  1122         have "\<bar>?F n - a\<bar> < inverse (real (Suc n))"
  1123           by (rule F2)
  1124         also have "inverse (real (Suc n)) \<le> inverse (real (Suc m))"
  1125           using mlen by auto
  1126         also from nodef have
  1127           "inverse (real (Suc m)) < e" .
  1128         finally show "\<bar>?F n - a\<bar> < e" .
  1129       qed
  1130   qed
  1131   moreover note `\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L`
  1132   ultimately have "(\<lambda>n. X (?F n)) ----> L" using F1 by simp
  1133   
  1134   moreover have "\<not> ((\<lambda>n. X (?F n)) ----> L)"
  1135   proof -
  1136     {
  1137       fix no::nat
  1138       obtain n where "n = no + 1" by simp
  1139       then have nolen: "no \<le> n" by simp
  1140         (* We prove this by showing that for any m there is an n\<ge>m such that |X (?F n) - L| \<ge> r *)
  1141       have "dist (X (?F n)) L \<ge> r"
  1142         by (rule F3)
  1143       with nolen have "\<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> r" by fast
  1144     }
  1145     then have "(\<forall>no. \<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> r)" by simp
  1146     with r have "\<exists>e>0. (\<forall>no. \<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> e)" by auto
  1147     thus ?thesis by (unfold LIMSEQ_def, auto simp add: not_less)
  1148   qed
  1149   ultimately show False by simp
  1150 qed
  1151 
  1152 lemma Lim_right_bound:
  1153   fixes f :: "real \<Rightarrow> real"
  1154   assumes mono: "\<And>a b. a \<in> I \<Longrightarrow> b \<in> I \<Longrightarrow> x < a \<Longrightarrow> a \<le> b \<Longrightarrow> f a \<le> f b"
  1155   assumes bnd: "\<And>a. a \<in> I \<Longrightarrow> x < a \<Longrightarrow> K \<le> f a"
  1156   shows "(f ---> Inf (f ` ({x<..} \<inter> I))) (at x within ({x<..} \<inter> I))"
  1157 proof cases
  1158   assume "{x<..} \<inter> I = {}" then show ?thesis by (simp add: Lim_within_empty)
  1159 next
  1160   assume [simp]: "{x<..} \<inter> I \<noteq> {}"
  1161   show ?thesis
  1162   proof (rule Lim_within_LIMSEQ, safe)
  1163     fix S assume S: "\<forall>n. S n \<noteq> x \<and> S n \<in> {x <..} \<inter> I" "S ----> x"
  1164     
  1165     show "(\<lambda>n. f (S n)) ----> Inf (f ` ({x<..} \<inter> I))"
  1166     proof (rule LIMSEQ_I, rule ccontr)
  1167       fix r :: real assume "0 < r"
  1168       with Inf_close[of "f ` ({x<..} \<inter> I)" r]
  1169       obtain y where y: "x < y" "y \<in> I" "f y < Inf (f ` ({x <..} \<inter> I)) + r" by auto
  1170       from `x < y` have "0 < y - x" by auto
  1171       from S(2)[THEN LIMSEQ_D, OF this]
  1172       obtain N where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>S n - x\<bar> < y - x" by auto
  1173       
  1174       assume "\<not> (\<exists>N. \<forall>n\<ge>N. norm (f (S n) - Inf (f ` ({x<..} \<inter> I))) < r)"
  1175       moreover have "\<And>n. Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1176         using S bnd by (intro Inf_lower[where z=K]) auto
  1177       ultimately obtain n where n: "N \<le> n" "r + Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1178         by (auto simp: not_less field_simps)
  1179       with N[OF n(1)] mono[OF _ `y \<in> I`, of "S n"] S(1)[THEN spec, of n] y
  1180       show False by auto
  1181     qed
  1182   qed
  1183 qed
  1184 
  1185 text{* Another limit point characterization. *}
  1186 
  1187 lemma islimpt_sequential:
  1188   fixes x :: "'a::metric_space"
  1189   shows "x islimpt S \<longleftrightarrow> (\<exists>f. (\<forall>n::nat. f n \<in> S -{x}) \<and> (f ---> x) sequentially)"
  1190     (is "?lhs = ?rhs")
  1191 proof
  1192   assume ?lhs
  1193   then obtain f where f:"\<forall>y. y>0 \<longrightarrow> f y \<in> S \<and> f y \<noteq> x \<and> dist (f y) x < y"
  1194     unfolding islimpt_approachable using choice[of "\<lambda>e y. e>0 \<longrightarrow> y\<in>S \<and> y\<noteq>x \<and> dist y x < e"] by auto
  1195   { fix n::nat
  1196     have "f (inverse (real n + 1)) \<in> S - {x}" using f by auto
  1197   }
  1198   moreover
  1199   { fix e::real assume "e>0"
  1200     hence "\<exists>N::nat. inverse (real (N + 1)) < e" using real_arch_inv[of e] apply (auto simp add: Suc_pred') apply(rule_tac x="n - 1" in exI) by auto
  1201     then obtain N::nat where "inverse (real (N + 1)) < e" by auto
  1202     hence "\<forall>n\<ge>N. inverse (real n + 1) < e" by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  1203     moreover have "\<forall>n\<ge>N. dist (f (inverse (real n + 1))) x < (inverse (real n + 1))" using f `e>0` by auto
  1204     ultimately have "\<exists>N::nat. \<forall>n\<ge>N. dist (f (inverse (real n + 1))) x < e" apply(rule_tac x=N in exI) apply auto apply(erule_tac x=n in allE)+ by auto
  1205   }
  1206   hence " ((\<lambda>n. f (inverse (real n + 1))) ---> x) sequentially"
  1207     unfolding Lim_sequentially using f by auto
  1208   ultimately show ?rhs apply (rule_tac x="(\<lambda>n::nat. f (inverse (real n + 1)))" in exI) by auto
  1209 next
  1210   assume ?rhs
  1211   then obtain f::"nat\<Rightarrow>'a"  where f:"(\<forall>n. f n \<in> S - {x})" "(\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f n) x < e)" unfolding Lim_sequentially by auto
  1212   { fix e::real assume "e>0"
  1213     then obtain N where "dist (f N) x < e" using f(2) by auto
  1214     moreover have "f N\<in>S" "f N \<noteq> x" using f(1) by auto
  1215     ultimately have "\<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e" by auto
  1216   }
  1217   thus ?lhs unfolding islimpt_approachable by auto
  1218 qed
  1219 
  1220 lemma Lim_inv: (* TODO: delete *)
  1221   fixes f :: "'a \<Rightarrow> real" and A :: "'a filter"
  1222   assumes "(f ---> l) A" and "l \<noteq> 0"
  1223   shows "((inverse o f) ---> inverse l) A"
  1224   unfolding o_def using assms by (rule tendsto_inverse)
  1225 
  1226 lemma Lim_null:
  1227   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1228   shows "(f ---> l) net \<longleftrightarrow> ((\<lambda>x. f(x) - l) ---> 0) net"
  1229   by (simp add: Lim dist_norm)
  1230 
  1231 lemma Lim_null_comparison:
  1232   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1233   assumes "eventually (\<lambda>x. norm (f x) \<le> g x) net" "(g ---> 0) net"
  1234   shows "(f ---> 0) net"
  1235 proof (rule metric_tendsto_imp_tendsto)
  1236   show "(g ---> 0) net" by fact
  1237   show "eventually (\<lambda>x. dist (f x) 0 \<le> dist (g x) 0) net"
  1238     using assms(1) by (rule eventually_elim1, simp add: dist_norm)
  1239 qed
  1240 
  1241 lemma Lim_transform_bound:
  1242   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1243   fixes g :: "'a \<Rightarrow> 'c::real_normed_vector"
  1244   assumes "eventually (\<lambda>n. norm(f n) <= norm(g n)) net"  "(g ---> 0) net"
  1245   shows "(f ---> 0) net"
  1246   using assms(1) tendsto_norm_zero [OF assms(2)]
  1247   by (rule Lim_null_comparison)
  1248 
  1249 text{* Deducing things about the limit from the elements. *}
  1250 
  1251 lemma Lim_in_closed_set:
  1252   assumes "closed S" "eventually (\<lambda>x. f(x) \<in> S) net" "\<not>(trivial_limit net)" "(f ---> l) net"
  1253   shows "l \<in> S"
  1254 proof (rule ccontr)
  1255   assume "l \<notin> S"
  1256   with `closed S` have "open (- S)" "l \<in> - S"
  1257     by (simp_all add: open_Compl)
  1258   with assms(4) have "eventually (\<lambda>x. f x \<in> - S) net"
  1259     by (rule topological_tendstoD)
  1260   with assms(2) have "eventually (\<lambda>x. False) net"
  1261     by (rule eventually_elim2) simp
  1262   with assms(3) show "False"
  1263     by (simp add: eventually_False)
  1264 qed
  1265 
  1266 text{* Need to prove closed(cball(x,e)) before deducing this as a corollary. *}
  1267 
  1268 lemma Lim_dist_ubound:
  1269   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. dist a (f x) <= e) net"
  1270   shows "dist a l <= e"
  1271 proof-
  1272   have "dist a l \<in> {..e}"
  1273   proof (rule Lim_in_closed_set)
  1274     show "closed {..e}" by simp
  1275     show "eventually (\<lambda>x. dist a (f x) \<in> {..e}) net" by (simp add: assms)
  1276     show "\<not> trivial_limit net" by fact
  1277     show "((\<lambda>x. dist a (f x)) ---> dist a l) net" by (intro tendsto_intros assms)
  1278   qed
  1279   thus ?thesis by simp
  1280 qed
  1281 
  1282 lemma Lim_norm_ubound:
  1283   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1284   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. norm(f x) <= e) net"
  1285   shows "norm(l) <= e"
  1286 proof-
  1287   have "norm l \<in> {..e}"
  1288   proof (rule Lim_in_closed_set)
  1289     show "closed {..e}" by simp
  1290     show "eventually (\<lambda>x. norm (f x) \<in> {..e}) net" by (simp add: assms)
  1291     show "\<not> trivial_limit net" by fact
  1292     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1293   qed
  1294   thus ?thesis by simp
  1295 qed
  1296 
  1297 lemma Lim_norm_lbound:
  1298   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1299   assumes "\<not> (trivial_limit net)"  "(f ---> l) net"  "eventually (\<lambda>x. e <= norm(f x)) net"
  1300   shows "e \<le> norm l"
  1301 proof-
  1302   have "norm l \<in> {e..}"
  1303   proof (rule Lim_in_closed_set)
  1304     show "closed {e..}" by simp
  1305     show "eventually (\<lambda>x. norm (f x) \<in> {e..}) net" by (simp add: assms)
  1306     show "\<not> trivial_limit net" by fact
  1307     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1308   qed
  1309   thus ?thesis by simp
  1310 qed
  1311 
  1312 text{* Uniqueness of the limit, when nontrivial. *}
  1313 
  1314 lemma tendsto_Lim:
  1315   fixes f :: "'a \<Rightarrow> 'b::t2_space"
  1316   shows "~(trivial_limit net) \<Longrightarrow> (f ---> l) net ==> Lim net f = l"
  1317   unfolding Lim_def using tendsto_unique[of net f] by auto
  1318 
  1319 text{* Limit under bilinear function *}
  1320 
  1321 lemma Lim_bilinear:
  1322   assumes "(f ---> l) net" and "(g ---> m) net" and "bounded_bilinear h"
  1323   shows "((\<lambda>x. h (f x) (g x)) ---> (h l m)) net"
  1324 using `bounded_bilinear h` `(f ---> l) net` `(g ---> m) net`
  1325 by (rule bounded_bilinear.tendsto)
  1326 
  1327 text{* These are special for limits out of the same vector space. *}
  1328 
  1329 lemma Lim_within_id: "(id ---> a) (at a within s)"
  1330   unfolding tendsto_def Limits.eventually_within eventually_at_topological
  1331   by auto
  1332 
  1333 lemma Lim_at_id: "(id ---> a) (at a)"
  1334 apply (subst within_UNIV[symmetric]) by (simp add: Lim_within_id)
  1335 
  1336 lemma Lim_at_zero:
  1337   fixes a :: "'a::real_normed_vector"
  1338   fixes l :: "'b::topological_space"
  1339   shows "(f ---> l) (at a) \<longleftrightarrow> ((\<lambda>x. f(a + x)) ---> l) (at 0)" (is "?lhs = ?rhs")
  1340   using LIM_offset_zero LIM_offset_zero_cancel ..
  1341 
  1342 text{* It's also sometimes useful to extract the limit point from the filter. *}
  1343 
  1344 definition
  1345   netlimit :: "'a::t2_space filter \<Rightarrow> 'a" where
  1346   "netlimit net = (SOME a. ((\<lambda>x. x) ---> a) net)"
  1347 
  1348 lemma netlimit_within:
  1349   assumes "\<not> trivial_limit (at a within S)"
  1350   shows "netlimit (at a within S) = a"
  1351 unfolding netlimit_def
  1352 apply (rule some_equality)
  1353 apply (rule Lim_at_within)
  1354 apply (rule LIM_ident)
  1355 apply (erule tendsto_unique [OF assms])
  1356 apply (rule Lim_at_within)
  1357 apply (rule LIM_ident)
  1358 done
  1359 
  1360 lemma netlimit_at:
  1361   fixes a :: "'a::{perfect_space,t2_space}"
  1362   shows "netlimit (at a) = a"
  1363   apply (subst within_UNIV[symmetric])
  1364   using netlimit_within[of a UNIV]
  1365   by (simp add: trivial_limit_at within_UNIV)
  1366 
  1367 lemma lim_within_interior:
  1368   "x \<in> interior S \<Longrightarrow> (f ---> l) (at x within S) \<longleftrightarrow> (f ---> l) (at x)"
  1369   by (simp add: at_within_interior)
  1370 
  1371 lemma netlimit_within_interior:
  1372   fixes x :: "'a::{t2_space,perfect_space}"
  1373   assumes "x \<in> interior S"
  1374   shows "netlimit (at x within S) = x"
  1375 using assms by (simp add: at_within_interior netlimit_at)
  1376 
  1377 text{* Transformation of limit. *}
  1378 
  1379 lemma Lim_transform:
  1380   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
  1381   assumes "((\<lambda>x. f x - g x) ---> 0) net" "(f ---> l) net"
  1382   shows "(g ---> l) net"
  1383   using tendsto_diff [OF assms(2) assms(1)] by simp
  1384 
  1385 lemma Lim_transform_eventually:
  1386   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1387   apply (rule topological_tendstoI)
  1388   apply (drule (2) topological_tendstoD)
  1389   apply (erule (1) eventually_elim2, simp)
  1390   done
  1391 
  1392 lemma Lim_transform_within:
  1393   assumes "0 < d" and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1394   and "(f ---> l) (at x within S)"
  1395   shows "(g ---> l) (at x within S)"
  1396 proof (rule Lim_transform_eventually)
  1397   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1398     unfolding eventually_within
  1399     using assms(1,2) by auto
  1400   show "(f ---> l) (at x within S)" by fact
  1401 qed
  1402 
  1403 lemma Lim_transform_at:
  1404   assumes "0 < d" and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1405   and "(f ---> l) (at x)"
  1406   shows "(g ---> l) (at x)"
  1407 proof (rule Lim_transform_eventually)
  1408   show "eventually (\<lambda>x. f x = g x) (at x)"
  1409     unfolding eventually_at
  1410     using assms(1,2) by auto
  1411   show "(f ---> l) (at x)" by fact
  1412 qed
  1413 
  1414 text{* Common case assuming being away from some crucial point like 0. *}
  1415 
  1416 lemma Lim_transform_away_within:
  1417   fixes a b :: "'a::t1_space"
  1418   assumes "a \<noteq> b" and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1419   and "(f ---> l) (at a within S)"
  1420   shows "(g ---> l) (at a within S)"
  1421 proof (rule Lim_transform_eventually)
  1422   show "(f ---> l) (at a within S)" by fact
  1423   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1424     unfolding Limits.eventually_within eventually_at_topological
  1425     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1426 qed
  1427 
  1428 lemma Lim_transform_away_at:
  1429   fixes a b :: "'a::t1_space"
  1430   assumes ab: "a\<noteq>b" and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1431   and fl: "(f ---> l) (at a)"
  1432   shows "(g ---> l) (at a)"
  1433   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl
  1434   by (auto simp add: within_UNIV)
  1435 
  1436 text{* Alternatively, within an open set. *}
  1437 
  1438 lemma Lim_transform_within_open:
  1439   assumes "open S" and "a \<in> S" and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1440   and "(f ---> l) (at a)"
  1441   shows "(g ---> l) (at a)"
  1442 proof (rule Lim_transform_eventually)
  1443   show "eventually (\<lambda>x. f x = g x) (at a)"
  1444     unfolding eventually_at_topological
  1445     using assms(1,2,3) by auto
  1446   show "(f ---> l) (at a)" by fact
  1447 qed
  1448 
  1449 text{* A congruence rule allowing us to transform limits assuming not at point. *}
  1450 
  1451 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1452 
  1453 lemma Lim_cong_within(*[cong add]*):
  1454   assumes "a = b" "x = y" "S = T"
  1455   assumes "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1456   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1457   unfolding tendsto_def Limits.eventually_within eventually_at_topological
  1458   using assms by simp
  1459 
  1460 lemma Lim_cong_at(*[cong add]*):
  1461   assumes "a = b" "x = y"
  1462   assumes "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1463   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1464   unfolding tendsto_def eventually_at_topological
  1465   using assms by simp
  1466 
  1467 text{* Useful lemmas on closure and set of possible sequential limits.*}
  1468 
  1469 lemma closure_sequential:
  1470   fixes l :: "'a::metric_space"
  1471   shows "l \<in> closure S \<longleftrightarrow> (\<exists>x. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially)" (is "?lhs = ?rhs")
  1472 proof
  1473   assume "?lhs" moreover
  1474   { assume "l \<in> S"
  1475     hence "?rhs" using tendsto_const[of l sequentially] by auto
  1476   } moreover
  1477   { assume "l islimpt S"
  1478     hence "?rhs" unfolding islimpt_sequential by auto
  1479   } ultimately
  1480   show "?rhs" unfolding closure_def by auto
  1481 next
  1482   assume "?rhs"
  1483   thus "?lhs" unfolding closure_def unfolding islimpt_sequential by auto
  1484 qed
  1485 
  1486 lemma closed_sequential_limits:
  1487   fixes S :: "'a::metric_space set"
  1488   shows "closed S \<longleftrightarrow> (\<forall>x l. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially \<longrightarrow> l \<in> S)"
  1489   unfolding closed_limpt
  1490   using closure_sequential [where 'a='a] closure_closed [where 'a='a] closed_limpt [where 'a='a] islimpt_sequential [where 'a='a] mem_delete [where 'a='a]
  1491   by metis
  1492 
  1493 lemma closure_approachable:
  1494   fixes S :: "'a::metric_space set"
  1495   shows "x \<in> closure S \<longleftrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e)"
  1496   apply (auto simp add: closure_def islimpt_approachable)
  1497   by (metis dist_self)
  1498 
  1499 lemma closed_approachable:
  1500   fixes S :: "'a::metric_space set"
  1501   shows "closed S ==> (\<forall>e>0. \<exists>y\<in>S. dist y x < e) \<longleftrightarrow> x \<in> S"
  1502   by (metis closure_closed closure_approachable)
  1503 
  1504 text{* Some other lemmas about sequences. *}
  1505 
  1506 lemma sequentially_offset:
  1507   assumes "eventually (\<lambda>i. P i) sequentially"
  1508   shows "eventually (\<lambda>i. P (i + k)) sequentially"
  1509   using assms unfolding eventually_sequentially by (metis trans_le_add1)
  1510 
  1511 lemma seq_offset:
  1512   assumes "(f ---> l) sequentially"
  1513   shows "((\<lambda>i. f (i + k)) ---> l) sequentially"
  1514   using assms unfolding tendsto_def
  1515   by clarify (rule sequentially_offset, simp)
  1516 
  1517 lemma seq_offset_neg:
  1518   "(f ---> l) sequentially ==> ((\<lambda>i. f(i - k)) ---> l) sequentially"
  1519   apply (rule topological_tendstoI)
  1520   apply (drule (2) topological_tendstoD)
  1521   apply (simp only: eventually_sequentially)
  1522   apply (subgoal_tac "\<And>N k (n::nat). N + k <= n ==> N <= n - k")
  1523   apply metis
  1524   by arith
  1525 
  1526 lemma seq_offset_rev:
  1527   "((\<lambda>i. f(i + k)) ---> l) sequentially ==> (f ---> l) sequentially"
  1528   apply (rule topological_tendstoI)
  1529   apply (drule (2) topological_tendstoD)
  1530   apply (simp only: eventually_sequentially)
  1531   apply (subgoal_tac "\<And>N k (n::nat). N + k <= n ==> N <= n - k \<and> (n - k) + k = n")
  1532   by metis arith
  1533 
  1534 lemma seq_harmonic: "((\<lambda>n. inverse (real n)) ---> 0) sequentially"
  1535 proof-
  1536   { fix e::real assume "e>0"
  1537     hence "\<exists>N::nat. \<forall>n::nat\<ge>N. inverse (real n) < e"
  1538       using real_arch_inv[of e] apply auto apply(rule_tac x=n in exI)
  1539       by (metis le_imp_inverse_le not_less real_of_nat_gt_zero_cancel_iff real_of_nat_less_iff xt1(7))
  1540   }
  1541   thus ?thesis unfolding Lim_sequentially dist_norm by simp
  1542 qed
  1543 
  1544 subsection {* More properties of closed balls *}
  1545 
  1546 lemma closed_cball: "closed (cball x e)"
  1547 unfolding cball_def closed_def
  1548 unfolding Collect_neg_eq [symmetric] not_le
  1549 apply (clarsimp simp add: open_dist, rename_tac y)
  1550 apply (rule_tac x="dist x y - e" in exI, clarsimp)
  1551 apply (rename_tac x')
  1552 apply (cut_tac x=x and y=x' and z=y in dist_triangle)
  1553 apply simp
  1554 done
  1555 
  1556 lemma open_contains_cball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0.  cball x e \<subseteq> S)"
  1557 proof-
  1558   { fix x and e::real assume "x\<in>S" "e>0" "ball x e \<subseteq> S"
  1559     hence "\<exists>d>0. cball x d \<subseteq> S" unfolding subset_eq by (rule_tac x="e/2" in exI, auto)
  1560   } moreover
  1561   { fix x and e::real assume "x\<in>S" "e>0" "cball x e \<subseteq> S"
  1562     hence "\<exists>d>0. ball x d \<subseteq> S" unfolding subset_eq apply(rule_tac x="e/2" in exI) by auto
  1563   } ultimately
  1564   show ?thesis unfolding open_contains_ball by auto
  1565 qed
  1566 
  1567 lemma open_contains_cball_eq: "open S ==> (\<forall>x. x \<in> S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S))"
  1568   by (metis open_contains_cball subset_eq order_less_imp_le centre_in_cball)
  1569 
  1570 lemma mem_interior_cball: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S)"
  1571   apply (simp add: interior_def, safe)
  1572   apply (force simp add: open_contains_cball)
  1573   apply (rule_tac x="ball x e" in exI)
  1574   apply (simp add: subset_trans [OF ball_subset_cball])
  1575   done
  1576 
  1577 lemma islimpt_ball:
  1578   fixes x y :: "'a::{real_normed_vector,perfect_space}"
  1579   shows "y islimpt ball x e \<longleftrightarrow> 0 < e \<and> y \<in> cball x e" (is "?lhs = ?rhs")
  1580 proof
  1581   assume "?lhs"
  1582   { assume "e \<le> 0"
  1583     hence *:"ball x e = {}" using ball_eq_empty[of x e] by auto
  1584     have False using `?lhs` unfolding * using islimpt_EMPTY[of y] by auto
  1585   }
  1586   hence "e > 0" by (metis not_less)
  1587   moreover
  1588   have "y \<in> cball x e" using closed_cball[of x e] islimpt_subset[of y "ball x e" "cball x e"] ball_subset_cball[of x e] `?lhs` unfolding closed_limpt by auto
  1589   ultimately show "?rhs" by auto
  1590 next
  1591   assume "?rhs" hence "e>0"  by auto
  1592   { fix d::real assume "d>0"
  1593     have "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1594     proof(cases "d \<le> dist x y")
  1595       case True thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1596       proof(cases "x=y")
  1597         case True hence False using `d \<le> dist x y` `d>0` by auto
  1598         thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by auto
  1599       next
  1600         case False
  1601 
  1602         have "dist x (y - (d / (2 * dist y x)) *\<^sub>R (y - x))
  1603               = norm (x - y + (d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1604           unfolding mem_cball mem_ball dist_norm diff_diff_eq2 diff_add_eq[THEN sym] by auto
  1605         also have "\<dots> = \<bar>- 1 + d / (2 * norm (x - y))\<bar> * norm (x - y)"
  1606           using scaleR_left_distrib[of "- 1" "d / (2 * norm (y - x))", THEN sym, of "y - x"]
  1607           unfolding scaleR_minus_left scaleR_one
  1608           by (auto simp add: norm_minus_commute)
  1609         also have "\<dots> = \<bar>- norm (x - y) + d / 2\<bar>"
  1610           unfolding abs_mult_pos[of "norm (x - y)", OF norm_ge_zero[of "x - y"]]
  1611           unfolding left_distrib using `x\<noteq>y`[unfolded dist_nz, unfolded dist_norm] by auto
  1612         also have "\<dots> \<le> e - d/2" using `d \<le> dist x y` and `d>0` and `?rhs` by(auto simp add: dist_norm)
  1613         finally have "y - (d / (2 * dist y x)) *\<^sub>R (y - x) \<in> ball x e" using `d>0` by auto
  1614 
  1615         moreover
  1616 
  1617         have "(d / (2*dist y x)) *\<^sub>R (y - x) \<noteq> 0"
  1618           using `x\<noteq>y`[unfolded dist_nz] `d>0` unfolding scaleR_eq_0_iff by (auto simp add: dist_commute)
  1619         moreover
  1620         have "dist (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) y < d" unfolding dist_norm apply simp unfolding norm_minus_cancel
  1621           using `d>0` `x\<noteq>y`[unfolded dist_nz] dist_commute[of x y]
  1622           unfolding dist_norm by auto
  1623         ultimately show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by (rule_tac  x="y - (d / (2*dist y x)) *\<^sub>R (y - x)" in bexI) auto
  1624       qed
  1625     next
  1626       case False hence "d > dist x y" by auto
  1627       show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1628       proof(cases "x=y")
  1629         case True
  1630         obtain z where **: "z \<noteq> y" "dist z y < min e d"
  1631           using perfect_choose_dist[of "min e d" y]
  1632           using `d > 0` `e>0` by auto
  1633         show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1634           unfolding `x = y`
  1635           using `z \<noteq> y` **
  1636           by (rule_tac x=z in bexI, auto simp add: dist_commute)
  1637       next
  1638         case False thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1639           using `d>0` `d > dist x y` `?rhs` by(rule_tac x=x in bexI, auto)
  1640       qed
  1641     qed  }
  1642   thus "?lhs" unfolding mem_cball islimpt_approachable mem_ball by auto
  1643 qed
  1644 
  1645 lemma closure_ball_lemma:
  1646   fixes x y :: "'a::real_normed_vector"
  1647   assumes "x \<noteq> y" shows "y islimpt ball x (dist x y)"
  1648 proof (rule islimptI)
  1649   fix T assume "y \<in> T" "open T"
  1650   then obtain r where "0 < r" "\<forall>z. dist z y < r \<longrightarrow> z \<in> T"
  1651     unfolding open_dist by fast
  1652   (* choose point between x and y, within distance r of y. *)
  1653   def k \<equiv> "min 1 (r / (2 * dist x y))"
  1654   def z \<equiv> "y + scaleR k (x - y)"
  1655   have z_def2: "z = x + scaleR (1 - k) (y - x)"
  1656     unfolding z_def by (simp add: algebra_simps)
  1657   have "dist z y < r"
  1658     unfolding z_def k_def using `0 < r`
  1659     by (simp add: dist_norm min_def)
  1660   hence "z \<in> T" using `\<forall>z. dist z y < r \<longrightarrow> z \<in> T` by simp
  1661   have "dist x z < dist x y"
  1662     unfolding z_def2 dist_norm
  1663     apply (simp add: norm_minus_commute)
  1664     apply (simp only: dist_norm [symmetric])
  1665     apply (subgoal_tac "\<bar>1 - k\<bar> * dist x y < 1 * dist x y", simp)
  1666     apply (rule mult_strict_right_mono)
  1667     apply (simp add: k_def divide_pos_pos zero_less_dist_iff `0 < r` `x \<noteq> y`)
  1668     apply (simp add: zero_less_dist_iff `x \<noteq> y`)
  1669     done
  1670   hence "z \<in> ball x (dist x y)" by simp
  1671   have "z \<noteq> y"
  1672     unfolding z_def k_def using `x \<noteq> y` `0 < r`
  1673     by (simp add: min_def)
  1674   show "\<exists>z\<in>ball x (dist x y). z \<in> T \<and> z \<noteq> y"
  1675     using `z \<in> ball x (dist x y)` `z \<in> T` `z \<noteq> y`
  1676     by fast
  1677 qed
  1678 
  1679 lemma closure_ball:
  1680   fixes x :: "'a::real_normed_vector"
  1681   shows "0 < e \<Longrightarrow> closure (ball x e) = cball x e"
  1682 apply (rule equalityI)
  1683 apply (rule closure_minimal)
  1684 apply (rule ball_subset_cball)
  1685 apply (rule closed_cball)
  1686 apply (rule subsetI, rename_tac y)
  1687 apply (simp add: le_less [where 'a=real])
  1688 apply (erule disjE)
  1689 apply (rule subsetD [OF closure_subset], simp)
  1690 apply (simp add: closure_def)
  1691 apply clarify
  1692 apply (rule closure_ball_lemma)
  1693 apply (simp add: zero_less_dist_iff)
  1694 done
  1695 
  1696 (* In a trivial vector space, this fails for e = 0. *)
  1697 lemma interior_cball:
  1698   fixes x :: "'a::{real_normed_vector, perfect_space}"
  1699   shows "interior (cball x e) = ball x e"
  1700 proof(cases "e\<ge>0")
  1701   case False note cs = this
  1702   from cs have "ball x e = {}" using ball_empty[of e x] by auto moreover
  1703   { fix y assume "y \<in> cball x e"
  1704     hence False unfolding mem_cball using dist_nz[of x y] cs by auto  }
  1705   hence "cball x e = {}" by auto
  1706   hence "interior (cball x e) = {}" using interior_empty by auto
  1707   ultimately show ?thesis by blast
  1708 next
  1709   case True note cs = this
  1710   have "ball x e \<subseteq> cball x e" using ball_subset_cball by auto moreover
  1711   { fix S y assume as: "S \<subseteq> cball x e" "open S" "y\<in>S"
  1712     then obtain d where "d>0" and d:"\<forall>x'. dist x' y < d \<longrightarrow> x' \<in> S" unfolding open_dist by blast
  1713 
  1714     then obtain xa where xa_y: "xa \<noteq> y" and xa: "dist xa y < d"
  1715       using perfect_choose_dist [of d] by auto
  1716     have "xa\<in>S" using d[THEN spec[where x=xa]] using xa by(auto simp add: dist_commute)
  1717     hence xa_cball:"xa \<in> cball x e" using as(1) by auto
  1718 
  1719     hence "y \<in> ball x e" proof(cases "x = y")
  1720       case True
  1721       hence "e>0" using xa_y[unfolded dist_nz] xa_cball[unfolded mem_cball] by (auto simp add: dist_commute)
  1722       thus "y \<in> ball x e" using `x = y ` by simp
  1723     next
  1724       case False
  1725       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) y < d" unfolding dist_norm
  1726         using `d>0` norm_ge_zero[of "y - x"] `x \<noteq> y` by auto
  1727       hence *:"y + (d / 2 / dist y x) *\<^sub>R (y - x) \<in> cball x e" using d as(1)[unfolded subset_eq] by blast
  1728       have "y - x \<noteq> 0" using `x \<noteq> y` by auto
  1729       hence **:"d / (2 * norm (y - x)) > 0" unfolding zero_less_norm_iff[THEN sym]
  1730         using `d>0` divide_pos_pos[of d "2*norm (y - x)"] by auto
  1731 
  1732       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) x = norm (y + (d / (2 * norm (y - x))) *\<^sub>R y - (d / (2 * norm (y - x))) *\<^sub>R x - x)"
  1733         by (auto simp add: dist_norm algebra_simps)
  1734       also have "\<dots> = norm ((1 + d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1735         by (auto simp add: algebra_simps)
  1736       also have "\<dots> = \<bar>1 + d / (2 * norm (y - x))\<bar> * norm (y - x)"
  1737         using ** by auto
  1738       also have "\<dots> = (dist y x) + d/2"using ** by (auto simp add: left_distrib dist_norm)
  1739       finally have "e \<ge> dist x y +d/2" using *[unfolded mem_cball] by (auto simp add: dist_commute)
  1740       thus "y \<in> ball x e" unfolding mem_ball using `d>0` by auto
  1741     qed  }
  1742   hence "\<forall>S \<subseteq> cball x e. open S \<longrightarrow> S \<subseteq> ball x e" by auto
  1743   ultimately show ?thesis using interior_unique[of "ball x e" "cball x e"] using open_ball[of x e] by auto
  1744 qed
  1745 
  1746 lemma frontier_ball:
  1747   fixes a :: "'a::real_normed_vector"
  1748   shows "0 < e ==> frontier(ball a e) = {x. dist a x = e}"
  1749   apply (simp add: frontier_def closure_ball interior_open order_less_imp_le)
  1750   apply (simp add: set_eq_iff)
  1751   by arith
  1752 
  1753 lemma frontier_cball:
  1754   fixes a :: "'a::{real_normed_vector, perfect_space}"
  1755   shows "frontier(cball a e) = {x. dist a x = e}"
  1756   apply (simp add: frontier_def interior_cball closed_cball order_less_imp_le)
  1757   apply (simp add: set_eq_iff)
  1758   by arith
  1759 
  1760 lemma cball_eq_empty: "(cball x e = {}) \<longleftrightarrow> e < 0"
  1761   apply (simp add: set_eq_iff not_le)
  1762   by (metis zero_le_dist dist_self order_less_le_trans)
  1763 lemma cball_empty: "e < 0 ==> cball x e = {}" by (simp add: cball_eq_empty)
  1764 
  1765 lemma cball_eq_sing:
  1766   fixes x :: "'a::{metric_space,perfect_space}"
  1767   shows "(cball x e = {x}) \<longleftrightarrow> e = 0"
  1768 proof (rule linorder_cases)
  1769   assume e: "0 < e"
  1770   obtain a where "a \<noteq> x" "dist a x < e"
  1771     using perfect_choose_dist [OF e] by auto
  1772   hence "a \<noteq> x" "dist x a \<le> e" by (auto simp add: dist_commute)
  1773   with e show ?thesis by (auto simp add: set_eq_iff)
  1774 qed auto
  1775 
  1776 lemma cball_sing:
  1777   fixes x :: "'a::metric_space"
  1778   shows "e = 0 ==> cball x e = {x}"
  1779   by (auto simp add: set_eq_iff)
  1780 
  1781 
  1782 subsection {* Boundedness *}
  1783 
  1784   (* FIXME: This has to be unified with BSEQ!! *)
  1785 definition (in metric_space)
  1786   bounded :: "'a set \<Rightarrow> bool" where
  1787   "bounded S \<longleftrightarrow> (\<exists>x e. \<forall>y\<in>S. dist x y \<le> e)"
  1788 
  1789 lemma bounded_any_center: "bounded S \<longleftrightarrow> (\<exists>e. \<forall>y\<in>S. dist a y \<le> e)"
  1790 unfolding bounded_def
  1791 apply safe
  1792 apply (rule_tac x="dist a x + e" in exI, clarify)
  1793 apply (drule (1) bspec)
  1794 apply (erule order_trans [OF dist_triangle add_left_mono])
  1795 apply auto
  1796 done
  1797 
  1798 lemma bounded_iff: "bounded S \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. norm x \<le> a)"
  1799 unfolding bounded_any_center [where a=0]
  1800 by (simp add: dist_norm)
  1801 
  1802 lemma bounded_empty[simp]: "bounded {}" by (simp add: bounded_def)
  1803 lemma bounded_subset: "bounded T \<Longrightarrow> S \<subseteq> T ==> bounded S"
  1804   by (metis bounded_def subset_eq)
  1805 
  1806 lemma bounded_interior[intro]: "bounded S ==> bounded(interior S)"
  1807   by (metis bounded_subset interior_subset)
  1808 
  1809 lemma bounded_closure[intro]: assumes "bounded S" shows "bounded(closure S)"
  1810 proof-
  1811   from assms obtain x and a where a: "\<forall>y\<in>S. dist x y \<le> a" unfolding bounded_def by auto
  1812   { fix y assume "y \<in> closure S"
  1813     then obtain f where f: "\<forall>n. f n \<in> S"  "(f ---> y) sequentially"
  1814       unfolding closure_sequential by auto
  1815     have "\<forall>n. f n \<in> S \<longrightarrow> dist x (f n) \<le> a" using a by simp
  1816     hence "eventually (\<lambda>n. dist x (f n) \<le> a) sequentially"
  1817       by (rule eventually_mono, simp add: f(1))
  1818     have "dist x y \<le> a"
  1819       apply (rule Lim_dist_ubound [of sequentially f])
  1820       apply (rule trivial_limit_sequentially)
  1821       apply (rule f(2))
  1822       apply fact
  1823       done
  1824   }
  1825   thus ?thesis unfolding bounded_def by auto
  1826 qed
  1827 
  1828 lemma bounded_cball[simp,intro]: "bounded (cball x e)"
  1829   apply (simp add: bounded_def)
  1830   apply (rule_tac x=x in exI)
  1831   apply (rule_tac x=e in exI)
  1832   apply auto
  1833   done
  1834 
  1835 lemma bounded_ball[simp,intro]: "bounded(ball x e)"
  1836   by (metis ball_subset_cball bounded_cball bounded_subset)
  1837 
  1838 lemma finite_imp_bounded[intro]:
  1839   fixes S :: "'a::metric_space set" assumes "finite S" shows "bounded S"
  1840 proof-
  1841   { fix a and F :: "'a set" assume as:"bounded F"
  1842     then obtain x e where "\<forall>y\<in>F. dist x y \<le> e" unfolding bounded_def by auto
  1843     hence "\<forall>y\<in>(insert a F). dist x y \<le> max e (dist x a)" by auto
  1844     hence "bounded (insert a F)" unfolding bounded_def by (intro exI)
  1845   }
  1846   thus ?thesis using finite_induct[of S bounded]  using bounded_empty assms by auto
  1847 qed
  1848 
  1849 lemma bounded_Un[simp]: "bounded (S \<union> T) \<longleftrightarrow> bounded S \<and> bounded T"
  1850   apply (auto simp add: bounded_def)
  1851   apply (rename_tac x y r s)
  1852   apply (rule_tac x=x in exI)
  1853   apply (rule_tac x="max r (dist x y + s)" in exI)
  1854   apply (rule ballI, rename_tac z, safe)
  1855   apply (drule (1) bspec, simp)
  1856   apply (drule (1) bspec)
  1857   apply (rule min_max.le_supI2)
  1858   apply (erule order_trans [OF dist_triangle add_left_mono])
  1859   done
  1860 
  1861 lemma bounded_Union[intro]: "finite F \<Longrightarrow> (\<forall>S\<in>F. bounded S) \<Longrightarrow> bounded(\<Union>F)"
  1862   by (induct rule: finite_induct[of F], auto)
  1863 
  1864 lemma bounded_pos: "bounded S \<longleftrightarrow> (\<exists>b>0. \<forall>x\<in> S. norm x <= b)"
  1865   apply (simp add: bounded_iff)
  1866   apply (subgoal_tac "\<And>x (y::real). 0 < 1 + abs y \<and> (x <= y \<longrightarrow> x <= 1 + abs y)")
  1867   by metis arith
  1868 
  1869 lemma bounded_Int[intro]: "bounded S \<or> bounded T \<Longrightarrow> bounded (S \<inter> T)"
  1870   by (metis Int_lower1 Int_lower2 bounded_subset)
  1871 
  1872 lemma bounded_diff[intro]: "bounded S ==> bounded (S - T)"
  1873 apply (metis Diff_subset bounded_subset)
  1874 done
  1875 
  1876 lemma bounded_insert[intro]:"bounded(insert x S) \<longleftrightarrow> bounded S"
  1877   by (metis Diff_cancel Un_empty_right Un_insert_right bounded_Un bounded_subset finite.emptyI finite_imp_bounded infinite_remove subset_insertI)
  1878 
  1879 lemma not_bounded_UNIV[simp, intro]:
  1880   "\<not> bounded (UNIV :: 'a::{real_normed_vector, perfect_space} set)"
  1881 proof(auto simp add: bounded_pos not_le)
  1882   obtain x :: 'a where "x \<noteq> 0"
  1883     using perfect_choose_dist [OF zero_less_one] by fast
  1884   fix b::real  assume b: "b >0"
  1885   have b1: "b +1 \<ge> 0" using b by simp
  1886   with `x \<noteq> 0` have "b < norm (scaleR (b + 1) (sgn x))"
  1887     by (simp add: norm_sgn)
  1888   then show "\<exists>x::'a. b < norm x" ..
  1889 qed
  1890 
  1891 lemma bounded_linear_image:
  1892   assumes "bounded S" "bounded_linear f"
  1893   shows "bounded(f ` S)"
  1894 proof-
  1895   from assms(1) obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1896   from assms(2) obtain B where B:"B>0" "\<forall>x. norm (f x) \<le> B * norm x" using bounded_linear.pos_bounded by (auto simp add: mult_ac)
  1897   { fix x assume "x\<in>S"
  1898     hence "norm x \<le> b" using b by auto
  1899     hence "norm (f x) \<le> B * b" using B(2) apply(erule_tac x=x in allE)
  1900       by (metis B(1) B(2) order_trans mult_le_cancel_left_pos)
  1901   }
  1902   thus ?thesis unfolding bounded_pos apply(rule_tac x="b*B" in exI)
  1903     using b B mult_pos_pos [of b B] by (auto simp add: mult_commute)
  1904 qed
  1905 
  1906 lemma bounded_scaling:
  1907   fixes S :: "'a::real_normed_vector set"
  1908   shows "bounded S \<Longrightarrow> bounded ((\<lambda>x. c *\<^sub>R x) ` S)"
  1909   apply (rule bounded_linear_image, assumption)
  1910   apply (rule bounded_linear_scaleR_right)
  1911   done
  1912 
  1913 lemma bounded_translation:
  1914   fixes S :: "'a::real_normed_vector set"
  1915   assumes "bounded S" shows "bounded ((\<lambda>x. a + x) ` S)"
  1916 proof-
  1917   from assms obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1918   { fix x assume "x\<in>S"
  1919     hence "norm (a + x) \<le> b + norm a" using norm_triangle_ineq[of a x] b by auto
  1920   }
  1921   thus ?thesis unfolding bounded_pos using norm_ge_zero[of a] b(1) using add_strict_increasing[of b 0 "norm a"]
  1922     by (auto intro!: add exI[of _ "b + norm a"])
  1923 qed
  1924 
  1925 
  1926 text{* Some theorems on sups and infs using the notion "bounded". *}
  1927 
  1928 lemma bounded_real:
  1929   fixes S :: "real set"
  1930   shows "bounded S \<longleftrightarrow>  (\<exists>a. \<forall>x\<in>S. abs x <= a)"
  1931   by (simp add: bounded_iff)
  1932 
  1933 lemma bounded_has_Sup:
  1934   fixes S :: "real set"
  1935   assumes "bounded S" "S \<noteq> {}"
  1936   shows "\<forall>x\<in>S. x <= Sup S" and "\<forall>b. (\<forall>x\<in>S. x <= b) \<longrightarrow> Sup S <= b"
  1937 proof
  1938   fix x assume "x\<in>S"
  1939   thus "x \<le> Sup S"
  1940     by (metis SupInf.Sup_upper abs_le_D1 assms(1) bounded_real)
  1941 next
  1942   show "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b" using assms
  1943     by (metis SupInf.Sup_least)
  1944 qed
  1945 
  1946 lemma Sup_insert:
  1947   fixes S :: "real set"
  1948   shows "bounded S ==> Sup(insert x S) = (if S = {} then x else max x (Sup S))" 
  1949 by auto (metis Int_absorb Sup_insert_nonempty assms bounded_has_Sup(1) disjoint_iff_not_equal) 
  1950 
  1951 lemma Sup_insert_finite:
  1952   fixes S :: "real set"
  1953   shows "finite S \<Longrightarrow> Sup(insert x S) = (if S = {} then x else max x (Sup S))"
  1954   apply (rule Sup_insert)
  1955   apply (rule finite_imp_bounded)
  1956   by simp
  1957 
  1958 lemma bounded_has_Inf:
  1959   fixes S :: "real set"
  1960   assumes "bounded S"  "S \<noteq> {}"
  1961   shows "\<forall>x\<in>S. x >= Inf S" and "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S >= b"
  1962 proof
  1963   fix x assume "x\<in>S"
  1964   from assms(1) obtain a where a:"\<forall>x\<in>S. \<bar>x\<bar> \<le> a" unfolding bounded_real by auto
  1965   thus "x \<ge> Inf S" using `x\<in>S`
  1966     by (metis Inf_lower_EX abs_le_D2 minus_le_iff)
  1967 next
  1968   show "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S \<ge> b" using assms
  1969     by (metis SupInf.Inf_greatest)
  1970 qed
  1971 
  1972 lemma Inf_insert:
  1973   fixes S :: "real set"
  1974   shows "bounded S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))" 
  1975 by auto (metis Int_absorb Inf_insert_nonempty bounded_has_Inf(1) disjoint_iff_not_equal) 
  1976 lemma Inf_insert_finite:
  1977   fixes S :: "real set"
  1978   shows "finite S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))"
  1979   by (rule Inf_insert, rule finite_imp_bounded, simp)
  1980 
  1981 (* TODO: Move this to RComplete.thy -- would need to include Glb into RComplete *)
  1982 lemma real_isGlb_unique: "[| isGlb R S x; isGlb R S y |] ==> x = (y::real)"
  1983   apply (frule isGlb_isLb)
  1984   apply (frule_tac x = y in isGlb_isLb)
  1985   apply (blast intro!: order_antisym dest!: isGlb_le_isLb)
  1986   done
  1987 
  1988 
  1989 subsection {* Equivalent versions of compactness *}
  1990 
  1991 subsubsection{* Sequential compactness *}
  1992 
  1993 definition
  1994   compact :: "'a::metric_space set \<Rightarrow> bool" where (* TODO: generalize *)
  1995   "compact S \<longleftrightarrow>
  1996    (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow>
  1997        (\<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially))"
  1998 
  1999 lemma compactI:
  2000   assumes "\<And>f. \<forall>n. f n \<in> S \<Longrightarrow> \<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially"
  2001   shows "compact S"
  2002   unfolding compact_def using assms by fast
  2003 
  2004 lemma compactE:
  2005   assumes "compact S" "\<forall>n. f n \<in> S"
  2006   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) ---> l) sequentially"
  2007   using assms unfolding compact_def by fast
  2008 
  2009 text {*
  2010   A metric space (or topological vector space) is said to have the
  2011   Heine-Borel property if every closed and bounded subset is compact.
  2012 *}
  2013 
  2014 class heine_borel = metric_space +
  2015   assumes bounded_imp_convergent_subsequence:
  2016     "bounded s \<Longrightarrow> \<forall>n. f n \<in> s
  2017       \<Longrightarrow> \<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2018 
  2019 lemma bounded_closed_imp_compact:
  2020   fixes s::"'a::heine_borel set"
  2021   assumes "bounded s" and "closed s" shows "compact s"
  2022 proof (unfold compact_def, clarify)
  2023   fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  2024   obtain l r where r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  2025     using bounded_imp_convergent_subsequence [OF `bounded s` `\<forall>n. f n \<in> s`] by auto
  2026   from f have fr: "\<forall>n. (f \<circ> r) n \<in> s" by simp
  2027   have "l \<in> s" using `closed s` fr l
  2028     unfolding closed_sequential_limits by blast
  2029   show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2030     using `l \<in> s` r l by blast
  2031 qed
  2032 
  2033 lemma subseq_bigger: assumes "subseq r" shows "n \<le> r n"
  2034 proof(induct n)
  2035   show "0 \<le> r 0" by auto
  2036 next
  2037   fix n assume "n \<le> r n"
  2038   moreover have "r n < r (Suc n)"
  2039     using assms [unfolded subseq_def] by auto
  2040   ultimately show "Suc n \<le> r (Suc n)" by auto
  2041 qed
  2042 
  2043 lemma eventually_subseq:
  2044   assumes r: "subseq r"
  2045   shows "eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  2046 unfolding eventually_sequentially
  2047 by (metis subseq_bigger [OF r] le_trans)
  2048 
  2049 lemma lim_subseq:
  2050   "subseq r \<Longrightarrow> (s ---> l) sequentially \<Longrightarrow> ((s o r) ---> l) sequentially"
  2051 unfolding tendsto_def eventually_sequentially o_def
  2052 by (metis subseq_bigger le_trans)
  2053 
  2054 lemma num_Axiom: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
  2055   unfolding Ex1_def
  2056   apply (rule_tac x="nat_rec e f" in exI)
  2057   apply (rule conjI)+
  2058 apply (rule def_nat_rec_0, simp)
  2059 apply (rule allI, rule def_nat_rec_Suc, simp)
  2060 apply (rule allI, rule impI, rule ext)
  2061 apply (erule conjE)
  2062 apply (induct_tac x)
  2063 apply simp
  2064 apply (erule_tac x="n" in allE)
  2065 apply (simp)
  2066 done
  2067 
  2068 lemma convergent_bounded_increasing: fixes s ::"nat\<Rightarrow>real"
  2069   assumes "incseq s" and "\<forall>n. abs(s n) \<le> b"
  2070   shows "\<exists> l. \<forall>e::real>0. \<exists> N. \<forall>n \<ge> N.  abs(s n - l) < e"
  2071 proof-
  2072   have "isUb UNIV (range s) b" using assms(2) and abs_le_D1 unfolding isUb_def and setle_def by auto
  2073   then obtain t where t:"isLub UNIV (range s) t" using reals_complete[of "range s" ] by auto
  2074   { fix e::real assume "e>0" and as:"\<forall>N. \<exists>n\<ge>N. \<not> \<bar>s n - t\<bar> < e"
  2075     { fix n::nat
  2076       obtain N where "N\<ge>n" and n:"\<bar>s N - t\<bar> \<ge> e" using as[THEN spec[where x=n]] by auto
  2077       have "t \<ge> s N" using isLub_isUb[OF t, unfolded isUb_def setle_def] by auto
  2078       with n have "s N \<le> t - e" using `e>0` by auto
  2079       hence "s n \<le> t - e" using assms(1)[unfolded incseq_def, THEN spec[where x=n], THEN spec[where x=N]] using `n\<le>N` by auto  }
  2080     hence "isUb UNIV (range s) (t - e)" unfolding isUb_def and setle_def by auto
  2081     hence False using isLub_le_isUb[OF t, of "t - e"] and `e>0` by auto  }
  2082   thus ?thesis by blast
  2083 qed
  2084 
  2085 lemma convergent_bounded_monotone: fixes s::"nat \<Rightarrow> real"
  2086   assumes "\<forall>n. abs(s n) \<le> b" and "monoseq s"
  2087   shows "\<exists>l. \<forall>e::real>0. \<exists>N. \<forall>n\<ge>N. abs(s n - l) < e"
  2088   using convergent_bounded_increasing[of s b] assms using convergent_bounded_increasing[of "\<lambda>n. - s n" b]
  2089   unfolding monoseq_def incseq_def
  2090   apply auto unfolding minus_add_distrib[THEN sym, unfolded diff_minus[THEN sym]]
  2091   unfolding abs_minus_cancel by(rule_tac x="-l" in exI)auto
  2092 
  2093 (* TODO: merge this lemma with the ones above *)
  2094 lemma bounded_increasing_convergent: fixes s::"nat \<Rightarrow> real"
  2095   assumes "bounded {s n| n::nat. True}"  "\<forall>n. (s n) \<le>(s(Suc n))"
  2096   shows "\<exists>l. (s ---> l) sequentially"
  2097 proof-
  2098   obtain a where a:"\<forall>n. \<bar> (s n)\<bar> \<le>  a" using assms(1)[unfolded bounded_iff] by auto
  2099   { fix m::nat
  2100     have "\<And> n. n\<ge>m \<longrightarrow>  (s m) \<le> (s n)"
  2101       apply(induct_tac n) apply simp using assms(2) apply(erule_tac x="na" in allE)
  2102       apply(case_tac "m \<le> na") unfolding not_less_eq_eq by(auto simp add: not_less_eq_eq)  }
  2103   hence "\<forall>m n. m \<le> n \<longrightarrow> (s m) \<le> (s n)" by auto
  2104   then obtain l where "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<bar> (s n) - l\<bar> < e" using convergent_bounded_monotone[OF a]
  2105     unfolding monoseq_def by auto
  2106   thus ?thesis unfolding Lim_sequentially apply(rule_tac x="l" in exI)
  2107     unfolding dist_norm  by auto
  2108 qed
  2109 
  2110 lemma compact_real_lemma:
  2111   assumes "\<forall>n::nat. abs(s n) \<le> b"
  2112   shows "\<exists>(l::real) r. subseq r \<and> ((s \<circ> r) ---> l) sequentially"
  2113 proof-
  2114   obtain r where r:"subseq r" "monoseq (\<lambda>n. s (r n))"
  2115     using seq_monosub[of s] by auto
  2116   thus ?thesis using convergent_bounded_monotone[of "\<lambda>n. s (r n)" b] and assms
  2117     unfolding tendsto_iff dist_norm eventually_sequentially by auto
  2118 qed
  2119 
  2120 instance real :: heine_borel
  2121 proof
  2122   fix s :: "real set" and f :: "nat \<Rightarrow> real"
  2123   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2124   then obtain b where b: "\<forall>n. abs (f n) \<le> b"
  2125     unfolding bounded_iff by auto
  2126   obtain l :: real and r :: "nat \<Rightarrow> nat" where
  2127     r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  2128     using compact_real_lemma [OF b] by auto
  2129   thus "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2130     by auto
  2131 qed
  2132 
  2133 lemma bounded_component: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $$ i) ` s)"
  2134   apply (erule bounded_linear_image)
  2135   apply (rule bounded_linear_euclidean_component)
  2136   done
  2137 
  2138 lemma compact_lemma:
  2139   fixes f :: "nat \<Rightarrow> 'a::euclidean_space"
  2140   assumes "bounded s" and "\<forall>n. f n \<in> s"
  2141   shows "\<forall>d. \<exists>l::'a. \<exists> r. subseq r \<and>
  2142         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2143 proof
  2144   fix d'::"nat set" def d \<equiv> "d' \<inter> {..<DIM('a)}"
  2145   have "finite d" "d\<subseteq>{..<DIM('a)}" unfolding d_def by auto
  2146   hence "\<exists>l::'a. \<exists>r. subseq r \<and>
  2147       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2148   proof(induct d) case empty thus ?case unfolding subseq_def by auto
  2149   next case (insert k d) have k[intro]:"k<DIM('a)" using insert by auto
  2150     have s': "bounded ((\<lambda>x. x $$ k) ` s)" using `bounded s` by (rule bounded_component)
  2151     obtain l1::"'a" and r1 where r1:"subseq r1" and
  2152       lr1:"\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially"
  2153       using insert(3) using insert(4) by auto
  2154     have f': "\<forall>n. f (r1 n) $$ k \<in> (\<lambda>x. x $$ k) ` s" using `\<forall>n. f n \<in> s` by simp
  2155     obtain l2 r2 where r2:"subseq r2" and lr2:"((\<lambda>i. f (r1 (r2 i)) $$ k) ---> l2) sequentially"
  2156       using bounded_imp_convergent_subsequence[OF s' f'] unfolding o_def by auto
  2157     def r \<equiv> "r1 \<circ> r2" have r:"subseq r"
  2158       using r1 and r2 unfolding r_def o_def subseq_def by auto
  2159     moreover
  2160     def l \<equiv> "(\<chi>\<chi> i. if i = k then l2 else l1$$i)::'a"
  2161     { fix e::real assume "e>0"
  2162       from lr1 `e>0` have N1:"eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially" by blast
  2163       from lr2 `e>0` have N2:"eventually (\<lambda>n. dist (f (r1 (r2 n)) $$ k) l2 < e) sequentially" by (rule tendstoD)
  2164       from r2 N1 have N1': "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 (r2 n)) $$ i) (l1 $$ i) < e) sequentially"
  2165         by (rule eventually_subseq)
  2166       have "eventually (\<lambda>n. \<forall>i\<in>(insert k d). dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2167         using N1' N2 apply(rule eventually_elim2) unfolding l_def r_def o_def
  2168         using insert.prems by auto
  2169     }
  2170     ultimately show ?case by auto
  2171   qed
  2172   thus "\<exists>l::'a. \<exists>r. subseq r \<and>
  2173       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d'. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2174     apply safe apply(rule_tac x=l in exI,rule_tac x=r in exI) apply safe
  2175     apply(erule_tac x=e in allE) unfolding d_def eventually_sequentially apply safe 
  2176     apply(rule_tac x=N in exI) apply safe apply(erule_tac x=n in allE,safe)
  2177     apply(erule_tac x=i in ballE) 
  2178   proof- fix i and r::"nat=>nat" and n::nat and e::real and l::'a
  2179     assume "i\<in>d'" "i \<notin> d' \<inter> {..<DIM('a)}" and e:"e>0"
  2180     hence *:"i\<ge>DIM('a)" by auto
  2181     thus "dist (f (r n) $$ i) (l $$ i) < e" using e by auto
  2182   qed
  2183 qed
  2184 
  2185 instance euclidean_space \<subseteq> heine_borel
  2186 proof
  2187   fix s :: "'a set" and f :: "nat \<Rightarrow> 'a"
  2188   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2189   then obtain l::'a and r where r: "subseq r"
  2190     and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2191     using compact_lemma [OF s f] by blast
  2192   let ?d = "{..<DIM('a)}"
  2193   { fix e::real assume "e>0"
  2194     hence "0 < e / (real_of_nat (card ?d))"
  2195       using DIM_positive using divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  2196     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))) sequentially"
  2197       by simp
  2198     moreover
  2199     { fix n assume n: "\<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))"
  2200       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $$ i) (l $$ i))"
  2201         apply(subst euclidean_dist_l2) using zero_le_dist by (rule setL2_le_setsum)
  2202       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  2203         apply(rule setsum_strict_mono) using n by auto
  2204       finally have "dist (f (r n)) l < e" unfolding setsum_constant
  2205         using DIM_positive[where 'a='a] by auto
  2206     }
  2207     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  2208       by (rule eventually_elim1)
  2209   }
  2210   hence *:"((f \<circ> r) ---> l) sequentially" unfolding o_def tendsto_iff by simp
  2211   with r show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" by auto
  2212 qed
  2213 
  2214 lemma bounded_fst: "bounded s \<Longrightarrow> bounded (fst ` s)"
  2215 unfolding bounded_def
  2216 apply clarify
  2217 apply (rule_tac x="a" in exI)
  2218 apply (rule_tac x="e" in exI)
  2219 apply clarsimp
  2220 apply (drule (1) bspec)
  2221 apply (simp add: dist_Pair_Pair)
  2222 apply (erule order_trans [OF real_sqrt_sum_squares_ge1])
  2223 done
  2224 
  2225 lemma bounded_snd: "bounded s \<Longrightarrow> bounded (snd ` s)"
  2226 unfolding bounded_def
  2227 apply clarify
  2228 apply (rule_tac x="b" in exI)
  2229 apply (rule_tac x="e" in exI)
  2230 apply clarsimp
  2231 apply (drule (1) bspec)
  2232 apply (simp add: dist_Pair_Pair)
  2233 apply (erule order_trans [OF real_sqrt_sum_squares_ge2])
  2234 done
  2235 
  2236 instance prod :: (heine_borel, heine_borel) heine_borel
  2237 proof
  2238   fix s :: "('a * 'b) set" and f :: "nat \<Rightarrow> 'a * 'b"
  2239   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2240   from s have s1: "bounded (fst ` s)" by (rule bounded_fst)
  2241   from f have f1: "\<forall>n. fst (f n) \<in> fst ` s" by simp
  2242   obtain l1 r1 where r1: "subseq r1"
  2243     and l1: "((\<lambda>n. fst (f (r1 n))) ---> l1) sequentially"
  2244     using bounded_imp_convergent_subsequence [OF s1 f1]
  2245     unfolding o_def by fast
  2246   from s have s2: "bounded (snd ` s)" by (rule bounded_snd)
  2247   from f have f2: "\<forall>n. snd (f (r1 n)) \<in> snd ` s" by simp
  2248   obtain l2 r2 where r2: "subseq r2"
  2249     and l2: "((\<lambda>n. snd (f (r1 (r2 n)))) ---> l2) sequentially"
  2250     using bounded_imp_convergent_subsequence [OF s2 f2]
  2251     unfolding o_def by fast
  2252   have l1': "((\<lambda>n. fst (f (r1 (r2 n)))) ---> l1) sequentially"
  2253     using lim_subseq [OF r2 l1] unfolding o_def .
  2254   have l: "((f \<circ> (r1 \<circ> r2)) ---> (l1, l2)) sequentially"
  2255     using tendsto_Pair [OF l1' l2] unfolding o_def by simp
  2256   have r: "subseq (r1 \<circ> r2)"
  2257     using r1 r2 unfolding subseq_def by simp
  2258   show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2259     using l r by fast
  2260 qed
  2261 
  2262 subsubsection{* Completeness *}
  2263 
  2264 lemma cauchy_def:
  2265   "Cauchy s \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m n. m \<ge> N \<and> n \<ge> N --> dist(s m)(s n) < e)"
  2266 unfolding Cauchy_def by blast
  2267 
  2268 definition
  2269   complete :: "'a::metric_space set \<Rightarrow> bool" where
  2270   "complete s \<longleftrightarrow> (\<forall>f. (\<forall>n. f n \<in> s) \<and> Cauchy f
  2271                       --> (\<exists>l \<in> s. (f ---> l) sequentially))"
  2272 
  2273 lemma cauchy: "Cauchy s \<longleftrightarrow> (\<forall>e>0.\<exists> N::nat. \<forall>n\<ge>N. dist(s n)(s N) < e)" (is "?lhs = ?rhs")
  2274 proof-
  2275   { assume ?rhs
  2276     { fix e::real
  2277       assume "e>0"
  2278       with `?rhs` obtain N where N:"\<forall>n\<ge>N. dist (s n) (s N) < e/2"
  2279         by (erule_tac x="e/2" in allE) auto
  2280       { fix n m
  2281         assume nm:"N \<le> m \<and> N \<le> n"
  2282         hence "dist (s m) (s n) < e" using N
  2283           using dist_triangle_half_l[of "s m" "s N" "e" "s n"]
  2284           by blast
  2285       }
  2286       hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"
  2287         by blast
  2288     }
  2289     hence ?lhs
  2290       unfolding cauchy_def
  2291       by blast
  2292   }
  2293   thus ?thesis
  2294     unfolding cauchy_def
  2295     using dist_triangle_half_l
  2296     by blast
  2297 qed
  2298 
  2299 lemma convergent_imp_cauchy:
  2300  "(s ---> l) sequentially ==> Cauchy s"
  2301 proof(simp only: cauchy_def, rule, rule)
  2302   fix e::real assume "e>0" "(s ---> l) sequentially"
  2303   then obtain N::nat where N:"\<forall>n\<ge>N. dist (s n) l < e/2" unfolding Lim_sequentially by(erule_tac x="e/2" in allE) auto
  2304   thus "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"  using dist_triangle_half_l[of _ l e _] by (rule_tac x=N in exI) auto
  2305 qed
  2306 
  2307 lemma cauchy_imp_bounded: assumes "Cauchy s" shows "bounded (range s)"
  2308 proof-
  2309   from assms obtain N::nat where "\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < 1" unfolding cauchy_def apply(erule_tac x= 1 in allE) by auto
  2310   hence N:"\<forall>n. N \<le> n \<longrightarrow> dist (s N) (s n) < 1" by auto
  2311   moreover
  2312   have "bounded (s ` {0..N})" using finite_imp_bounded[of "s ` {1..N}"] by auto
  2313   then obtain a where a:"\<forall>x\<in>s ` {0..N}. dist (s N) x \<le> a"
  2314     unfolding bounded_any_center [where a="s N"] by auto
  2315   ultimately show "?thesis"
  2316     unfolding bounded_any_center [where a="s N"]
  2317     apply(rule_tac x="max a 1" in exI) apply auto
  2318     apply(erule_tac x=y in allE) apply(erule_tac x=y in ballE) by auto
  2319 qed
  2320 
  2321 lemma compact_imp_complete: assumes "compact s" shows "complete s"
  2322 proof-
  2323   { fix f assume as: "(\<forall>n::nat. f n \<in> s)" "Cauchy f"
  2324     from as(1) obtain l r where lr: "l\<in>s" "subseq r" "((f \<circ> r) ---> l) sequentially" using assms unfolding compact_def by blast
  2325 
  2326     note lr' = subseq_bigger [OF lr(2)]
  2327 
  2328     { fix e::real assume "e>0"
  2329       from as(2) obtain N where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (f m) (f n) < e/2" unfolding cauchy_def using `e>0` apply (erule_tac x="e/2" in allE) by auto
  2330       from lr(3)[unfolded Lim_sequentially, THEN spec[where x="e/2"]] obtain M where M:"\<forall>n\<ge>M. dist ((f \<circ> r) n) l < e/2" using `e>0` by auto
  2331       { fix n::nat assume n:"n \<ge> max N M"
  2332         have "dist ((f \<circ> r) n) l < e/2" using n M by auto
  2333         moreover have "r n \<ge> N" using lr'[of n] n by auto
  2334         hence "dist (f n) ((f \<circ> r) n) < e / 2" using N using n by auto
  2335         ultimately have "dist (f n) l < e" using dist_triangle_half_r[of "f (r n)" "f n" e l] by (auto simp add: dist_commute)  }
  2336       hence "\<exists>N. \<forall>n\<ge>N. dist (f n) l < e" by blast  }
  2337     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `l\<in>s` unfolding Lim_sequentially by auto  }
  2338   thus ?thesis unfolding complete_def by auto
  2339 qed
  2340 
  2341 instance heine_borel < complete_space
  2342 proof
  2343   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2344   hence "bounded (range f)"
  2345     by (rule cauchy_imp_bounded)
  2346   hence "compact (closure (range f))"
  2347     using bounded_closed_imp_compact [of "closure (range f)"] by auto
  2348   hence "complete (closure (range f))"
  2349     by (rule compact_imp_complete)
  2350   moreover have "\<forall>n. f n \<in> closure (range f)"
  2351     using closure_subset [of "range f"] by auto
  2352   ultimately have "\<exists>l\<in>closure (range f). (f ---> l) sequentially"
  2353     using `Cauchy f` unfolding complete_def by auto
  2354   then show "convergent f"
  2355     unfolding convergent_def by auto
  2356 qed
  2357 
  2358 lemma complete_univ: "complete (UNIV :: 'a::complete_space set)"
  2359 proof(simp add: complete_def, rule, rule)
  2360   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2361   hence "convergent f" by (rule Cauchy_convergent)
  2362   thus "\<exists>l. f ----> l" unfolding convergent_def .  
  2363 qed
  2364 
  2365 lemma complete_imp_closed: assumes "complete s" shows "closed s"
  2366 proof -
  2367   { fix x assume "x islimpt s"
  2368     then obtain f where f: "\<forall>n. f n \<in> s - {x}" "(f ---> x) sequentially"
  2369       unfolding islimpt_sequential by auto
  2370     then obtain l where l: "l\<in>s" "(f ---> l) sequentially"
  2371       using `complete s`[unfolded complete_def] using convergent_imp_cauchy[of f x] by auto
  2372     hence "x \<in> s"  using tendsto_unique[of sequentially f l x] trivial_limit_sequentially f(2) by auto
  2373   }
  2374   thus "closed s" unfolding closed_limpt by auto
  2375 qed
  2376 
  2377 lemma complete_eq_closed:
  2378   fixes s :: "'a::complete_space set"
  2379   shows "complete s \<longleftrightarrow> closed s" (is "?lhs = ?rhs")
  2380 proof
  2381   assume ?lhs thus ?rhs by (rule complete_imp_closed)
  2382 next
  2383   assume ?rhs
  2384   { fix f assume as:"\<forall>n::nat. f n \<in> s" "Cauchy f"
  2385     then obtain l where "(f ---> l) sequentially" using complete_univ[unfolded complete_def, THEN spec[where x=f]] by auto
  2386     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `?rhs`[unfolded closed_sequential_limits, THEN spec[where x=f], THEN spec[where x=l]] using as(1) by auto  }
  2387   thus ?lhs unfolding complete_def by auto
  2388 qed
  2389 
  2390 lemma convergent_eq_cauchy:
  2391   fixes s :: "nat \<Rightarrow> 'a::complete_space"
  2392   shows "(\<exists>l. (s ---> l) sequentially) \<longleftrightarrow> Cauchy s" (is "?lhs = ?rhs")
  2393 proof
  2394   assume ?lhs then obtain l where "(s ---> l) sequentially" by auto
  2395   thus ?rhs using convergent_imp_cauchy by auto
  2396 next
  2397   assume ?rhs thus ?lhs using complete_univ[unfolded complete_def, THEN spec[where x=s]] by auto
  2398 qed
  2399 
  2400 lemma convergent_imp_bounded:
  2401   fixes s :: "nat \<Rightarrow> 'a::metric_space"
  2402   shows "(s ---> l) sequentially ==> bounded (s ` (UNIV::(nat set)))"
  2403   using convergent_imp_cauchy[of s]
  2404   using cauchy_imp_bounded[of s]
  2405   unfolding image_def
  2406   by auto
  2407 
  2408 subsubsection{* Total boundedness *}
  2409 
  2410 fun helper_1::"('a::metric_space set) \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> 'a" where
  2411   "helper_1 s e n = (SOME y::'a. y \<in> s \<and> (\<forall>m<n. \<not> (dist (helper_1 s e m) y < e)))"
  2412 declare helper_1.simps[simp del]
  2413 
  2414 lemma compact_imp_totally_bounded:
  2415   assumes "compact s"
  2416   shows "\<forall>e>0. \<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k))"
  2417 proof(rule, rule, rule ccontr)
  2418   fix e::real assume "e>0" and assm:"\<not> (\<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k)"
  2419   def x \<equiv> "helper_1 s e"
  2420   { fix n
  2421     have "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  2422     proof(induct_tac rule:nat_less_induct)
  2423       fix n  def Q \<equiv> "(\<lambda>y. y \<in> s \<and> (\<forall>m<n. \<not> dist (x m) y < e))"
  2424       assume as:"\<forall>m<n. x m \<in> s \<and> (\<forall>ma<m. \<not> dist (x ma) (x m) < e)"
  2425       have "\<not> s \<subseteq> (\<Union>x\<in>x ` {0..<n}. ball x e)" using assm apply simp apply(erule_tac x="x ` {0 ..< n}" in allE) using as by auto
  2426       then obtain z where z:"z\<in>s" "z \<notin> (\<Union>x\<in>x ` {0..<n}. ball x e)" unfolding subset_eq by auto
  2427       have "Q (x n)" unfolding x_def and helper_1.simps[of s e n]
  2428         apply(rule someI2[where a=z]) unfolding x_def[symmetric] and Q_def using z by auto
  2429       thus "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)" unfolding Q_def by auto
  2430     qed }
  2431   hence "\<forall>n::nat. x n \<in> s" and x:"\<forall>n. \<forall>m < n. \<not> (dist (x m) (x n) < e)" by blast+
  2432   then obtain l r where "l\<in>s" and r:"subseq r" and "((x \<circ> r) ---> l) sequentially" using assms(1)[unfolded compact_def, THEN spec[where x=x]] by auto
  2433   from this(3) have "Cauchy (x \<circ> r)" using convergent_imp_cauchy by auto
  2434   then obtain N::nat where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist ((x \<circ> r) m) ((x \<circ> r) n) < e" unfolding cauchy_def using `e>0` by auto
  2435   show False
  2436     using N[THEN spec[where x=N], THEN spec[where x="N+1"]]
  2437     using r[unfolded subseq_def, THEN spec[where x=N], THEN spec[where x="N+1"]]
  2438     using x[THEN spec[where x="r (N+1)"], THEN spec[where x="r (N)"]] by auto
  2439 qed
  2440 
  2441 subsubsection{* Heine-Borel theorem *}
  2442 
  2443 text {* Following Burkill \& Burkill vol. 2. *}
  2444 
  2445 lemma heine_borel_lemma: fixes s::"'a::metric_space set"
  2446   assumes "compact s"  "s \<subseteq> (\<Union> t)"  "\<forall>b \<in> t. open b"
  2447   shows "\<exists>e>0. \<forall>x \<in> s. \<exists>b \<in> t. ball x e \<subseteq> b"
  2448 proof(rule ccontr)
  2449   assume "\<not> (\<exists>e>0. \<forall>x\<in>s. \<exists>b\<in>t. ball x e \<subseteq> b)"
  2450   hence cont:"\<forall>e>0. \<exists>x\<in>s. \<forall>xa\<in>t. \<not> (ball x e \<subseteq> xa)" by auto
  2451   { fix n::nat
  2452     have "1 / real (n + 1) > 0" by auto
  2453     hence "\<exists>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> (ball x (inverse (real (n+1))) \<subseteq> xa))" using cont unfolding Bex_def by auto }
  2454   hence "\<forall>n::nat. \<exists>x. x \<in> s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)" by auto
  2455   then obtain f where f:"\<forall>n::nat. f n \<in> s \<and> (\<forall>xa\<in>t. \<not> ball (f n) (inverse (real (n + 1))) \<subseteq> xa)"
  2456     using choice[of "\<lambda>n::nat. \<lambda>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)"] by auto
  2457 
  2458   then obtain l r where l:"l\<in>s" and r:"subseq r" and lr:"((f \<circ> r) ---> l) sequentially"
  2459     using assms(1)[unfolded compact_def, THEN spec[where x=f]] by auto
  2460 
  2461   obtain b where "l\<in>b" "b\<in>t" using assms(2) and l by auto
  2462   then obtain e where "e>0" and e:"\<forall>z. dist z l < e \<longrightarrow> z\<in>b"
  2463     using assms(3)[THEN bspec[where x=b]] unfolding open_dist by auto
  2464 
  2465   then obtain N1 where N1:"\<forall>n\<ge>N1. dist ((f \<circ> r) n) l < e / 2"
  2466     using lr[unfolded Lim_sequentially, THEN spec[where x="e/2"]] by auto
  2467 
  2468   obtain N2::nat where N2:"N2>0" "inverse (real N2) < e /2" using real_arch_inv[of "e/2"] and `e>0` by auto
  2469   have N2':"inverse (real (r (N1 + N2) +1 )) < e/2"
  2470     apply(rule order_less_trans) apply(rule less_imp_inverse_less) using N2
  2471     using subseq_bigger[OF r, of "N1 + N2"] by auto
  2472 
  2473   def x \<equiv> "(f (r (N1 + N2)))"
  2474   have x:"\<not> ball x (inverse (real (r (N1 + N2) + 1))) \<subseteq> b" unfolding x_def
  2475     using f[THEN spec[where x="r (N1 + N2)"]] using `b\<in>t` by auto
  2476   have "\<exists>y\<in>ball x (inverse (real (r (N1 + N2) + 1))). y\<notin>b" apply(rule ccontr) using x by auto
  2477   then obtain y where y:"y \<in> ball x (inverse (real (r (N1 + N2) + 1)))" "y \<notin> b" by auto
  2478 
  2479   have "dist x l < e/2" using N1 unfolding x_def o_def by auto
  2480   hence "dist y l < e" using y N2' using dist_triangle[of y l x]by (auto simp add:dist_commute)
  2481 
  2482   thus False using e and `y\<notin>b` by auto
  2483 qed
  2484 
  2485 lemma compact_imp_heine_borel: "compact s ==> (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2486                \<longrightarrow> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))"
  2487 proof clarify
  2488   fix f assume "compact s" " \<forall>t\<in>f. open t" "s \<subseteq> \<Union>f"
  2489   then obtain e::real where "e>0" and "\<forall>x\<in>s. \<exists>b\<in>f. ball x e \<subseteq> b" using heine_borel_lemma[of s f] by auto
  2490   hence "\<forall>x\<in>s. \<exists>b. b\<in>f \<and> ball x e \<subseteq> b" by auto
  2491   hence "\<exists>bb. \<forall>x\<in>s. bb x \<in>f \<and> ball x e \<subseteq> bb x" using bchoice[of s "\<lambda>x b. b\<in>f \<and> ball x e \<subseteq> b"] by auto
  2492   then obtain  bb where bb:"\<forall>x\<in>s. (bb x) \<in> f \<and> ball x e \<subseteq> (bb x)" by blast
  2493 
  2494   from `compact s` have  "\<exists> k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" using compact_imp_totally_bounded[of s] `e>0` by auto
  2495   then obtain k where k:"finite k" "k \<subseteq> s" "s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" by auto
  2496 
  2497   have "finite (bb ` k)" using k(1) by auto
  2498   moreover
  2499   { fix x assume "x\<in>s"
  2500     hence "x\<in>\<Union>(\<lambda>x. ball x e) ` k" using k(3)  unfolding subset_eq by auto
  2501     hence "\<exists>X\<in>bb ` k. x \<in> X" using bb k(2) by blast
  2502     hence "x \<in> \<Union>(bb ` k)" using  Union_iff[of x "bb ` k"] by auto
  2503   }
  2504   ultimately show "\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f'" using bb k(2) by (rule_tac x="bb ` k" in exI) auto
  2505 qed
  2506 
  2507 subsubsection {* Bolzano-Weierstrass property *}
  2508 
  2509 lemma heine_borel_imp_bolzano_weierstrass:
  2510   assumes "\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f) --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f'))"
  2511           "infinite t"  "t \<subseteq> s"
  2512   shows "\<exists>x \<in> s. x islimpt t"
  2513 proof(rule ccontr)
  2514   assume "\<not> (\<exists>x \<in> s. x islimpt t)"
  2515   then obtain f where f:"\<forall>x\<in>s. x \<in> f x \<and> open (f x) \<and> (\<forall>y\<in>t. y \<in> f x \<longrightarrow> y = x)" unfolding islimpt_def
  2516     using bchoice[of s "\<lambda> x T. x \<in> T \<and> open T \<and> (\<forall>y\<in>t. y \<in> T \<longrightarrow> y = x)"] by auto
  2517   obtain g where g:"g\<subseteq>{t. \<exists>x. x \<in> s \<and> t = f x}" "finite g" "s \<subseteq> \<Union>g"
  2518     using assms(1)[THEN spec[where x="{t. \<exists>x. x\<in>s \<and> t = f x}"]] using f by auto
  2519   from g(1,3) have g':"\<forall>x\<in>g. \<exists>xa \<in> s. x = f xa" by auto
  2520   { fix x y assume "x\<in>t" "y\<in>t" "f x = f y"
  2521     hence "x \<in> f x"  "y \<in> f x \<longrightarrow> y = x" using f[THEN bspec[where x=x]] and `t\<subseteq>s` by auto
  2522     hence "x = y" using `f x = f y` and f[THEN bspec[where x=y]] and `y\<in>t` and `t\<subseteq>s` by auto  }
  2523   hence "inj_on f t" unfolding inj_on_def by simp
  2524   hence "infinite (f ` t)" using assms(2) using finite_imageD by auto
  2525   moreover
  2526   { fix x assume "x\<in>t" "f x \<notin> g"
  2527     from g(3) assms(3) `x\<in>t` obtain h where "h\<in>g" and "x\<in>h" by auto
  2528     then obtain y where "y\<in>s" "h = f y" using g'[THEN bspec[where x=h]] by auto
  2529     hence "y = x" using f[THEN bspec[where x=y]] and `x\<in>t` and `x\<in>h`[unfolded `h = f y`] by auto
  2530     hence False using `f x \<notin> g` `h\<in>g` unfolding `h = f y` by auto  }
  2531   hence "f ` t \<subseteq> g" by auto
  2532   ultimately show False using g(2) using finite_subset by auto
  2533 qed
  2534 
  2535 subsubsection {* Complete the chain of compactness variants *}
  2536 
  2537 lemma islimpt_range_imp_convergent_subsequence:
  2538   fixes f :: "nat \<Rightarrow> 'a::metric_space"
  2539   assumes "l islimpt (range f)"
  2540   shows "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2541 proof (intro exI conjI)
  2542   have *: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2543     using assms unfolding islimpt_def
  2544     by (drule_tac x="ball l e" in spec)
  2545        (auto simp add: zero_less_dist_iff dist_commute)
  2546 
  2547   def t \<equiv> "\<lambda>e. LEAST n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2548   have f_t_neq: "\<And>e. 0 < e \<Longrightarrow> 0 < dist (f (t e)) l"
  2549     unfolding t_def by (rule LeastI2_ex [OF * conjunct1])
  2550   have f_t_closer: "\<And>e. 0 < e \<Longrightarrow> dist (f (t e)) l < e"
  2551     unfolding t_def by (rule LeastI2_ex [OF * conjunct2])
  2552   have t_le: "\<And>n e. 0 < dist (f n) l \<Longrightarrow> dist (f n) l < e \<Longrightarrow> t e \<le> n"
  2553     unfolding t_def by (simp add: Least_le)
  2554   have less_tD: "\<And>n e. n < t e \<Longrightarrow> 0 < dist (f n) l \<Longrightarrow> e \<le> dist (f n) l"
  2555     unfolding t_def by (drule not_less_Least) simp
  2556   have t_antimono: "\<And>e e'. 0 < e \<Longrightarrow> e \<le> e' \<Longrightarrow> t e' \<le> t e"
  2557     apply (rule t_le)
  2558     apply (erule f_t_neq)
  2559     apply (erule (1) less_le_trans [OF f_t_closer])
  2560     done
  2561   have t_dist_f_neq: "\<And>n. 0 < dist (f n) l \<Longrightarrow> t (dist (f n) l) \<noteq> n"
  2562     by (drule f_t_closer) auto
  2563   have t_less: "\<And>e. 0 < e \<Longrightarrow> t e < t (dist (f (t e)) l)"
  2564     apply (subst less_le)
  2565     apply (rule conjI)
  2566     apply (rule t_antimono)
  2567     apply (erule f_t_neq)
  2568     apply (erule f_t_closer [THEN less_imp_le])
  2569     apply (rule t_dist_f_neq [symmetric])
  2570     apply (erule f_t_neq)
  2571     done
  2572   have dist_f_t_less':
  2573     "\<And>e e'. 0 < e \<Longrightarrow> 0 < e' \<Longrightarrow> t e \<le> t e' \<Longrightarrow> dist (f (t e')) l < e"
  2574     apply (simp add: le_less)
  2575     apply (erule disjE)
  2576     apply (rule less_trans)
  2577     apply (erule f_t_closer)
  2578     apply (rule le_less_trans)
  2579     apply (erule less_tD)
  2580     apply (erule f_t_neq)
  2581     apply (erule f_t_closer)
  2582     apply (erule subst)
  2583     apply (erule f_t_closer)
  2584     done
  2585 
  2586   def r \<equiv> "nat_rec (t 1) (\<lambda>_ x. t (dist (f x) l))"
  2587   have r_simps: "r 0 = t 1" "\<And>n. r (Suc n) = t (dist (f (r n)) l)"
  2588     unfolding r_def by simp_all
  2589   have f_r_neq: "\<And>n. 0 < dist (f (r n)) l"
  2590     by (induct_tac n) (simp_all add: r_simps f_t_neq)
  2591 
  2592   show "subseq r"
  2593     unfolding subseq_Suc_iff
  2594     apply (rule allI)
  2595     apply (case_tac n)
  2596     apply (simp_all add: r_simps)
  2597     apply (rule t_less, rule zero_less_one)
  2598     apply (rule t_less, rule f_r_neq)
  2599     done
  2600   show "((f \<circ> r) ---> l) sequentially"
  2601     unfolding Lim_sequentially o_def
  2602     apply (clarify, rule_tac x="t e" in exI, clarify)
  2603     apply (drule le_trans, rule seq_suble [OF `subseq r`])
  2604     apply (case_tac n, simp_all add: r_simps dist_f_t_less' f_r_neq)
  2605     done
  2606 qed
  2607 
  2608 lemma finite_range_imp_infinite_repeats:
  2609   fixes f :: "nat \<Rightarrow> 'a"
  2610   assumes "finite (range f)"
  2611   shows "\<exists>k. infinite {n. f n = k}"
  2612 proof -
  2613   { fix A :: "'a set" assume "finite A"
  2614     hence "\<And>f. infinite {n. f n \<in> A} \<Longrightarrow> \<exists>k. infinite {n. f n = k}"
  2615     proof (induct)
  2616       case empty thus ?case by simp
  2617     next
  2618       case (insert x A)
  2619      show ?case
  2620       proof (cases "finite {n. f n = x}")
  2621         case True
  2622         with `infinite {n. f n \<in> insert x A}`
  2623         have "infinite {n. f n \<in> A}" by simp
  2624         thus "\<exists>k. infinite {n. f n = k}" by (rule insert)
  2625       next
  2626         case False thus "\<exists>k. infinite {n. f n = k}" ..
  2627       qed
  2628     qed
  2629   } note H = this
  2630   from assms show "\<exists>k. infinite {n. f n = k}"
  2631     by (rule H) simp
  2632 qed
  2633 
  2634 lemma bolzano_weierstrass_imp_compact:
  2635   fixes s :: "'a::metric_space set"
  2636   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2637   shows "compact s"
  2638 proof -
  2639   { fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  2640     have "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2641     proof (cases "finite (range f)")
  2642       case True
  2643       hence "\<exists>l. infinite {n. f n = l}"
  2644         by (rule finite_range_imp_infinite_repeats)
  2645       then obtain l where "infinite {n. f n = l}" ..
  2646       hence "\<exists>r. subseq r \<and> (\<forall>n. r n \<in> {n. f n = l})"
  2647         by (rule infinite_enumerate)
  2648       then obtain r where "subseq r" and fr: "\<forall>n. f (r n) = l" by auto
  2649       hence "subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2650         unfolding o_def by (simp add: fr tendsto_const)
  2651       hence "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2652         by - (rule exI)
  2653       from f have "\<forall>n. f (r n) \<in> s" by simp
  2654       hence "l \<in> s" by (simp add: fr)
  2655       thus "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2656         by (rule rev_bexI) fact
  2657     next
  2658       case False
  2659       with f assms have "\<exists>x\<in>s. x islimpt (range f)" by auto
  2660       then obtain l where "l \<in> s" "l islimpt (range f)" ..
  2661       have "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2662         using `l islimpt (range f)`
  2663         by (rule islimpt_range_imp_convergent_subsequence)
  2664       with `l \<in> s` show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" ..
  2665     qed
  2666   }
  2667   thus ?thesis unfolding compact_def by auto
  2668 qed
  2669 
  2670 primrec helper_2::"(real \<Rightarrow> 'a::metric_space) \<Rightarrow> nat \<Rightarrow> 'a" where
  2671   "helper_2 beyond 0 = beyond 0" |
  2672   "helper_2 beyond (Suc n) = beyond (dist undefined (helper_2 beyond n) + 1 )"
  2673 
  2674 lemma bolzano_weierstrass_imp_bounded: fixes s::"'a::metric_space set"
  2675   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2676   shows "bounded s"
  2677 proof(rule ccontr)
  2678   assume "\<not> bounded s"
  2679   then obtain beyond where "\<forall>a. beyond a \<in>s \<and> \<not> dist undefined (beyond a) \<le> a"
  2680     unfolding bounded_any_center [where a=undefined]
  2681     apply simp using choice[of "\<lambda>a x. x\<in>s \<and> \<not> dist undefined x \<le> a"] by auto
  2682   hence beyond:"\<And>a. beyond a \<in>s" "\<And>a. dist undefined (beyond a) > a"
  2683     unfolding linorder_not_le by auto
  2684   def x \<equiv> "helper_2 beyond"
  2685 
  2686   { fix m n ::nat assume "m<n"
  2687     hence "dist undefined (x m) + 1 < dist undefined (x n)"
  2688     proof(induct n)
  2689       case 0 thus ?case by auto
  2690     next
  2691       case (Suc n)
  2692       have *:"dist undefined (x n) + 1 < dist undefined (x (Suc n))"
  2693         unfolding x_def and helper_2.simps
  2694         using beyond(2)[of "dist undefined (helper_2 beyond n) + 1"] by auto
  2695       thus ?case proof(cases "m < n")
  2696         case True thus ?thesis using Suc and * by auto
  2697       next
  2698         case False hence "m = n" using Suc(2) by auto
  2699         thus ?thesis using * by auto
  2700       qed
  2701     qed  } note * = this
  2702   { fix m n ::nat assume "m\<noteq>n"
  2703     have "1 < dist (x m) (x n)"
  2704     proof(cases "m<n")
  2705       case True
  2706       hence "1 < dist undefined (x n) - dist undefined (x m)" using *[of m n] by auto
  2707       thus ?thesis using dist_triangle [of undefined "x n" "x m"] by arith
  2708     next
  2709       case False hence "n<m" using `m\<noteq>n` by auto
  2710       hence "1 < dist undefined (x m) - dist undefined (x n)" using *[of n m] by auto
  2711       thus ?thesis using dist_triangle2 [of undefined "x m" "x n"] by arith
  2712     qed  } note ** = this
  2713   { fix a b assume "x a = x b" "a \<noteq> b"
  2714     hence False using **[of a b] by auto  }
  2715   hence "inj x" unfolding inj_on_def by auto
  2716   moreover
  2717   { fix n::nat
  2718     have "x n \<in> s"
  2719     proof(cases "n = 0")
  2720       case True thus ?thesis unfolding x_def using beyond by auto
  2721     next
  2722       case False then obtain z where "n = Suc z" using not0_implies_Suc by auto
  2723       thus ?thesis unfolding x_def using beyond by auto
  2724     qed  }
  2725   ultimately have "infinite (range x) \<and> range x \<subseteq> s" unfolding x_def using range_inj_infinite[of "helper_2 beyond"] using beyond(1) by auto
  2726 
  2727   then obtain l where "l\<in>s" and l:"l islimpt range x" using assms[THEN spec[where x="range x"]] by auto
  2728   then obtain y where "x y \<noteq> l" and y:"dist (x y) l < 1/2" unfolding islimpt_approachable apply(erule_tac x="1/2" in allE) by auto
  2729   then obtain z where "x z \<noteq> l" and z:"dist (x z) l < dist (x y) l" using l[unfolded islimpt_approachable, THEN spec[where x="dist (x y) l"]]
  2730     unfolding dist_nz by auto
  2731   show False using y and z and dist_triangle_half_l[of "x y" l 1 "x z"] and **[of y z] by auto
  2732 qed
  2733 
  2734 lemma sequence_infinite_lemma:
  2735   fixes f :: "nat \<Rightarrow> 'a::t1_space"
  2736   assumes "\<forall>n. f n \<noteq> l" and "(f ---> l) sequentially"
  2737   shows "infinite (range f)"
  2738 proof
  2739   assume "finite (range f)"
  2740   hence "closed (range f)" by (rule finite_imp_closed)
  2741   hence "open (- range f)" by (rule open_Compl)
  2742   from assms(1) have "l \<in> - range f" by auto
  2743   from assms(2) have "eventually (\<lambda>n. f n \<in> - range f) sequentially"
  2744     using `open (- range f)` `l \<in> - range f` by (rule topological_tendstoD)
  2745   thus False unfolding eventually_sequentially by auto
  2746 qed
  2747 
  2748 lemma closure_insert:
  2749   fixes x :: "'a::t1_space"
  2750   shows "closure (insert x s) = insert x (closure s)"
  2751 apply (rule closure_unique)
  2752 apply (rule conjI [OF insert_mono [OF closure_subset]])
  2753 apply (rule conjI [OF closed_insert [OF closed_closure]])
  2754 apply (simp add: closure_minimal)
  2755 done
  2756 
  2757 lemma islimpt_insert:
  2758   fixes x :: "'a::t1_space"
  2759   shows "x islimpt (insert a s) \<longleftrightarrow> x islimpt s"
  2760 proof
  2761   assume *: "x islimpt (insert a s)"
  2762   show "x islimpt s"
  2763   proof (rule islimptI)
  2764     fix t assume t: "x \<in> t" "open t"
  2765     show "\<exists>y\<in>s. y \<in> t \<and> y \<noteq> x"
  2766     proof (cases "x = a")
  2767       case True
  2768       obtain y where "y \<in> insert a s" "y \<in> t" "y \<noteq> x"
  2769         using * t by (rule islimptE)
  2770       with `x = a` show ?thesis by auto
  2771     next
  2772       case False
  2773       with t have t': "x \<in> t - {a}" "open (t - {a})"
  2774         by (simp_all add: open_Diff)
  2775       obtain y where "y \<in> insert a s" "y \<in> t - {a}" "y \<noteq> x"
  2776         using * t' by (rule islimptE)
  2777       thus ?thesis by auto
  2778     qed
  2779   qed
  2780 next
  2781   assume "x islimpt s" thus "x islimpt (insert a s)"
  2782     by (rule islimpt_subset) auto
  2783 qed
  2784 
  2785 lemma islimpt_union_finite:
  2786   fixes x :: "'a::t1_space"
  2787   shows "finite s \<Longrightarrow> x islimpt (s \<union> t) \<longleftrightarrow> x islimpt t"
  2788 by (induct set: finite, simp_all add: islimpt_insert)
  2789  
  2790 lemma sequence_unique_limpt:
  2791   fixes f :: "nat \<Rightarrow> 'a::t2_space"
  2792   assumes "(f ---> l) sequentially" and "l' islimpt (range f)"
  2793   shows "l' = l"
  2794 proof (rule ccontr)
  2795   assume "l' \<noteq> l"
  2796   obtain s t where "open s" "open t" "l' \<in> s" "l \<in> t" "s \<inter> t = {}"
  2797     using hausdorff [OF `l' \<noteq> l`] by auto
  2798   have "eventually (\<lambda>n. f n \<in> t) sequentially"
  2799     using assms(1) `open t` `l \<in> t` by (rule topological_tendstoD)
  2800   then obtain N where "\<forall>n\<ge>N. f n \<in> t"
  2801     unfolding eventually_sequentially by auto
  2802 
  2803   have "UNIV = {..<N} \<union> {N..}" by auto
  2804   hence "l' islimpt (f ` ({..<N} \<union> {N..}))" using assms(2) by simp
  2805   hence "l' islimpt (f ` {..<N} \<union> f ` {N..})" by (simp add: image_Un)
  2806   hence "l' islimpt (f ` {N..})" by (simp add: islimpt_union_finite)
  2807   then obtain y where "y \<in> f ` {N..}" "y \<in> s" "y \<noteq> l'"
  2808     using `l' \<in> s` `open s` by (rule islimptE)
  2809   then obtain n where "N \<le> n" "f n \<in> s" "f n \<noteq> l'" by auto
  2810   with `\<forall>n\<ge>N. f n \<in> t` have "f n \<in> s \<inter> t" by simp
  2811   with `s \<inter> t = {}` show False by simp
  2812 qed
  2813 
  2814 lemma bolzano_weierstrass_imp_closed:
  2815   fixes s :: "'a::metric_space set" (* TODO: can this be generalized? *)
  2816   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2817   shows "closed s"
  2818 proof-
  2819   { fix x l assume as: "\<forall>n::nat. x n \<in> s" "(x ---> l) sequentially"
  2820     hence "l \<in> s"
  2821     proof(cases "\<forall>n. x n \<noteq> l")
  2822       case False thus "l\<in>s" using as(1) by auto
  2823     next
  2824       case True note cas = this
  2825       with as(2) have "infinite (range x)" using sequence_infinite_lemma[of x l] by auto
  2826       then obtain l' where "l'\<in>s" "l' islimpt (range x)" using assms[THEN spec[where x="range x"]] as(1) by auto
  2827       thus "l\<in>s" using sequence_unique_limpt[of x l l'] using as cas by auto
  2828     qed  }
  2829   thus ?thesis unfolding closed_sequential_limits by fast
  2830 qed
  2831 
  2832 text {* Hence express everything as an equivalence. *}
  2833 
  2834 lemma compact_eq_heine_borel:
  2835   fixes s :: "'a::metric_space set"
  2836   shows "compact s \<longleftrightarrow>
  2837            (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2838                --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))" (is "?lhs = ?rhs")
  2839 proof
  2840   assume ?lhs thus ?rhs by (rule compact_imp_heine_borel)
  2841 next
  2842   assume ?rhs
  2843   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x\<in>s. x islimpt t)"
  2844     by (blast intro: heine_borel_imp_bolzano_weierstrass[of s])
  2845   thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2846 qed
  2847 
  2848 lemma compact_eq_bolzano_weierstrass:
  2849   fixes s :: "'a::metric_space set"
  2850   shows "compact s \<longleftrightarrow> (\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t))" (is "?lhs = ?rhs")
  2851 proof
  2852   assume ?lhs thus ?rhs unfolding compact_eq_heine_borel using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2853 next
  2854   assume ?rhs thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2855 qed
  2856 
  2857 lemma compact_eq_bounded_closed:
  2858   fixes s :: "'a::heine_borel set"
  2859   shows "compact s \<longleftrightarrow> bounded s \<and> closed s"  (is "?lhs = ?rhs")
  2860 proof
  2861   assume ?lhs thus ?rhs unfolding compact_eq_bolzano_weierstrass using bolzano_weierstrass_imp_bounded bolzano_weierstrass_imp_closed by auto
  2862 next
  2863   assume ?rhs thus ?lhs using bounded_closed_imp_compact by auto
  2864 qed
  2865 
  2866 lemma compact_imp_bounded:
  2867   fixes s :: "'a::metric_space set"
  2868   shows "compact s ==> bounded s"
  2869 proof -
  2870   assume "compact s"
  2871   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2872     by (rule compact_imp_heine_borel)
  2873   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2874     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2875   thus "bounded s"
  2876     by (rule bolzano_weierstrass_imp_bounded)
  2877 qed
  2878 
  2879 lemma compact_imp_closed:
  2880   fixes s :: "'a::metric_space set"
  2881   shows "compact s ==> closed s"
  2882 proof -
  2883   assume "compact s"
  2884   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2885     by (rule compact_imp_heine_borel)
  2886   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2887     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2888   thus "closed s"
  2889     by (rule bolzano_weierstrass_imp_closed)
  2890 qed
  2891 
  2892 text{* In particular, some common special cases. *}
  2893 
  2894 lemma compact_empty[simp]:
  2895  "compact {}"
  2896   unfolding compact_def
  2897   by simp
  2898 
  2899 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  2900   unfolding subseq_def by simp (* TODO: move somewhere else *)
  2901 
  2902 lemma compact_union [intro]:
  2903   assumes "compact s" and "compact t"
  2904   shows "compact (s \<union> t)"
  2905 proof (rule compactI)
  2906   fix f :: "nat \<Rightarrow> 'a"
  2907   assume "\<forall>n. f n \<in> s \<union> t"
  2908   hence "infinite {n. f n \<in> s \<union> t}" by simp
  2909   hence "infinite {n. f n \<in> s} \<or> infinite {n. f n \<in> t}" by simp
  2910   thus "\<exists>l\<in>s \<union> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2911   proof
  2912     assume "infinite {n. f n \<in> s}"
  2913     from infinite_enumerate [OF this]
  2914     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> s" by auto
  2915     obtain r l where "l \<in> s" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2916       using `compact s` `\<forall>n. (f \<circ> q) n \<in> s` by (rule compactE)
  2917     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2918       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2919     thus ?thesis by auto
  2920   next
  2921     assume "infinite {n. f n \<in> t}"
  2922     from infinite_enumerate [OF this]
  2923     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> t" by auto
  2924     obtain r l where "l \<in> t" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2925       using `compact t` `\<forall>n. (f \<circ> q) n \<in> t` by (rule compactE)
  2926     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2927       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2928     thus ?thesis by auto
  2929   qed
  2930 qed
  2931 
  2932 lemma compact_inter_closed [intro]:
  2933   assumes "compact s" and "closed t"
  2934   shows "compact (s \<inter> t)"
  2935 proof (rule compactI)
  2936   fix f :: "nat \<Rightarrow> 'a"
  2937   assume "\<forall>n. f n \<in> s \<inter> t"
  2938   hence "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t" by simp_all
  2939   obtain l r where "l \<in> s" "subseq r" "((f \<circ> r) ---> l) sequentially"
  2940     using `compact s` `\<forall>n. f n \<in> s` by (rule compactE)
  2941   moreover
  2942   from `closed t` `\<forall>n. f n \<in> t` `((f \<circ> r) ---> l) sequentially` have "l \<in> t"
  2943     unfolding closed_sequential_limits o_def by fast
  2944   ultimately show "\<exists>l\<in>s \<inter> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2945     by auto
  2946 qed
  2947 
  2948 lemma closed_inter_compact [intro]:
  2949   assumes "closed s" and "compact t"
  2950   shows "compact (s \<inter> t)"
  2951   using compact_inter_closed [of t s] assms
  2952   by (simp add: Int_commute)
  2953 
  2954 lemma compact_inter [intro]:
  2955   assumes "compact s" and "compact t"
  2956   shows "compact (s \<inter> t)"
  2957   using assms by (intro compact_inter_closed compact_imp_closed)
  2958 
  2959 lemma compact_sing [simp]: "compact {a}"
  2960   unfolding compact_def o_def subseq_def
  2961   by (auto simp add: tendsto_const)
  2962 
  2963 lemma compact_insert [simp]:
  2964   assumes "compact s" shows "compact (insert x s)"
  2965 proof -
  2966   have "compact ({x} \<union> s)"
  2967     using compact_sing assms by (rule compact_union)
  2968   thus ?thesis by simp
  2969 qed
  2970 
  2971 lemma finite_imp_compact:
  2972   shows "finite s \<Longrightarrow> compact s"
  2973   by (induct set: finite) simp_all
  2974 
  2975 lemma compact_cball[simp]:
  2976   fixes x :: "'a::heine_borel"
  2977   shows "compact(cball x e)"
  2978   using compact_eq_bounded_closed bounded_cball closed_cball
  2979   by blast
  2980 
  2981 lemma compact_frontier_bounded[intro]:
  2982   fixes s :: "'a::heine_borel set"
  2983   shows "bounded s ==> compact(frontier s)"
  2984   unfolding frontier_def
  2985   using compact_eq_bounded_closed
  2986   by blast
  2987 
  2988 lemma compact_frontier[intro]:
  2989   fixes s :: "'a::heine_borel set"
  2990   shows "compact s ==> compact (frontier s)"
  2991   using compact_eq_bounded_closed compact_frontier_bounded
  2992   by blast
  2993 
  2994 lemma frontier_subset_compact:
  2995   fixes s :: "'a::heine_borel set"
  2996   shows "compact s ==> frontier s \<subseteq> s"
  2997   using frontier_subset_closed compact_eq_bounded_closed
  2998   by blast
  2999 
  3000 lemma open_delete:
  3001   fixes s :: "'a::t1_space set"
  3002   shows "open s \<Longrightarrow> open (s - {x})"
  3003   by (simp add: open_Diff)
  3004 
  3005 text{* Finite intersection property. I could make it an equivalence in fact. *}
  3006 
  3007 lemma compact_imp_fip:
  3008   assumes "compact s"  "\<forall>t \<in> f. closed t"
  3009         "\<forall>f'. finite f' \<and> f' \<subseteq> f --> (s \<inter> (\<Inter> f') \<noteq> {})"
  3010   shows "s \<inter> (\<Inter> f) \<noteq> {}"
  3011 proof
  3012   assume as:"s \<inter> (\<Inter> f) = {}"
  3013   hence "s \<subseteq> \<Union> uminus ` f" by auto
  3014   moreover have "Ball (uminus ` f) open" using open_Diff closed_Diff using assms(2) by auto
  3015   ultimately obtain f' where f':"f' \<subseteq> uminus ` f"  "finite f'"  "s \<subseteq> \<Union>f'" using assms(1)[unfolded compact_eq_heine_borel, THEN spec[where x="(\<lambda>t. - t) ` f"]] by auto
  3016   hence "finite (uminus ` f') \<and> uminus ` f' \<subseteq> f" by(auto simp add: Diff_Diff_Int)
  3017   hence "s \<inter> \<Inter>uminus ` f' \<noteq> {}" using assms(3)[THEN spec[where x="uminus ` f'"]] by auto
  3018   thus False using f'(3) unfolding subset_eq and Union_iff by blast
  3019 qed
  3020 
  3021 
  3022 subsection {* Bounded closed nest property (proof does not use Heine-Borel) *}
  3023 
  3024 lemma bounded_closed_nest:
  3025   assumes "\<forall>n. closed(s n)" "\<forall>n. (s n \<noteq> {})"
  3026   "(\<forall>m n. m \<le> n --> s n \<subseteq> s m)"  "bounded(s 0)"
  3027   shows "\<exists>a::'a::heine_borel. \<forall>n::nat. a \<in> s(n)"
  3028 proof-
  3029   from assms(2) obtain x where x:"\<forall>n::nat. x n \<in> s n" using choice[of "\<lambda>n x. x\<in> s n"] by auto
  3030   from assms(4,1) have *:"compact (s 0)" using bounded_closed_imp_compact[of "s 0"] by auto
  3031 
  3032   then obtain l r where lr:"l\<in>s 0" "subseq r" "((x \<circ> r) ---> l) sequentially"
  3033     unfolding compact_def apply(erule_tac x=x in allE)  using x using assms(3) by blast
  3034 
  3035   { fix n::nat
  3036     { fix e::real assume "e>0"
  3037       with lr(3) obtain N where N:"\<forall>m\<ge>N. dist ((x \<circ> r) m) l < e" unfolding Lim_sequentially by auto
  3038       hence "dist ((x \<circ> r) (max N n)) l < e" by auto
  3039       moreover
  3040       have "r (max N n) \<ge> n" using lr(2) using subseq_bigger[of r "max N n"] by auto
  3041       hence "(x \<circ> r) (max N n) \<in> s n"
  3042         using x apply(erule_tac x=n in allE)
  3043         using x apply(erule_tac x="r (max N n)" in allE)
  3044         using assms(3) apply(erule_tac x=n in allE)apply( erule_tac x="r (max N n)" in allE) by auto
  3045       ultimately have "\<exists>y\<in>s n. dist y l < e" by auto
  3046     }
  3047     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by blast
  3048   }
  3049   thus ?thesis by auto
  3050 qed
  3051 
  3052 text {* Decreasing case does not even need compactness, just completeness. *}
  3053 
  3054 lemma decreasing_closed_nest:
  3055   assumes "\<forall>n. closed(s n)"
  3056           "\<forall>n. (s n \<noteq> {})"
  3057           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  3058           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y \<in> (s n). dist x y < e"
  3059   shows "\<exists>a::'a::heine_borel. \<forall>n::nat. a \<in> s n"
  3060 proof-
  3061   have "\<forall>n. \<exists> x. x\<in>s n" using assms(2) by auto
  3062   hence "\<exists>t. \<forall>n. t n \<in> s n" using choice[of "\<lambda> n x. x \<in> s n"] by auto
  3063   then obtain t where t: "\<forall>n. t n \<in> s n" by auto
  3064   { fix e::real assume "e>0"
  3065     then obtain N where N:"\<forall>x\<in>s N. \<forall>y\<in>s N. dist x y < e" using assms(4) by auto
  3066     { fix m n ::nat assume "N \<le> m \<and> N \<le> n"
  3067       hence "t m \<in> s N" "t n \<in> s N" using assms(3) t unfolding  subset_eq t by blast+
  3068       hence "dist (t m) (t n) < e" using N by auto
  3069     }
  3070     hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (t m) (t n) < e" by auto
  3071   }
  3072   hence  "Cauchy t" unfolding cauchy_def by auto
  3073   then obtain l where l:"(t ---> l) sequentially" using complete_univ unfolding complete_def by auto
  3074   { fix n::nat
  3075     { fix e::real assume "e>0"
  3076       then obtain N::nat where N:"\<forall>n\<ge>N. dist (t n) l < e" using l[unfolded Lim_sequentially] by auto
  3077       have "t (max n N) \<in> s n" using assms(3) unfolding subset_eq apply(erule_tac x=n in allE) apply (erule_tac x="max n N" in allE) using t by auto
  3078       hence "\<exists>y\<in>s n. dist y l < e" apply(rule_tac x="t (max n N)" in bexI) using N by auto
  3079     }
  3080     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by auto
  3081   }
  3082   then show ?thesis by auto
  3083 qed
  3084 
  3085 text {* Strengthen it to the intersection actually being a singleton. *}
  3086 
  3087 lemma decreasing_closed_nest_sing:
  3088   fixes s :: "nat \<Rightarrow> 'a::heine_borel set"
  3089   assumes "\<forall>n. closed(s n)"
  3090           "\<forall>n. s n \<noteq> {}"
  3091           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  3092           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y\<in>(s n). dist x y < e"
  3093   shows "\<exists>a. \<Inter>(range s) = {a}"
  3094 proof-
  3095   obtain a where a:"\<forall>n. a \<in> s n" using decreasing_closed_nest[of s] using assms by auto
  3096   { fix b assume b:"b \<in> \<Inter>(range s)"
  3097     { fix e::real assume "e>0"
  3098       hence "dist a b < e" using assms(4 )using b using a by blast
  3099     }
  3100     hence "dist a b = 0" by (metis dist_eq_0_iff dist_nz less_le)
  3101   }
  3102   with a have "\<Inter>(range s) = {a}" unfolding image_def by auto
  3103   thus ?thesis ..
  3104 qed
  3105 
  3106 text{* Cauchy-type criteria for uniform convergence. *}
  3107 
  3108 lemma uniformly_convergent_eq_cauchy: fixes s::"nat \<Rightarrow> 'b \<Rightarrow> 'a::heine_borel" shows
  3109  "(\<exists>l. \<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e) \<longleftrightarrow>
  3110   (\<forall>e>0. \<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e)" (is "?lhs = ?rhs")
  3111 proof(rule)
  3112   assume ?lhs
  3113   then obtain l where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e" by auto
  3114   { fix e::real assume "e>0"
  3115     then obtain N::nat where N:"\<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e / 2" using l[THEN spec[where x="e/2"]] by auto
  3116     { fix n m::nat and x::"'b" assume "N \<le> m \<and> N \<le> n \<and> P x"
  3117       hence "dist (s m x) (s n x) < e"
  3118         using N[THEN spec[where x=m], THEN spec[where x=x]]
  3119         using N[THEN spec[where x=n], THEN spec[where x=x]]
  3120         using dist_triangle_half_l[of "s m x" "l x" e "s n x"] by auto  }
  3121     hence "\<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e"  by auto  }
  3122   thus ?rhs by auto
  3123 next
  3124   assume ?rhs
  3125   hence "\<forall>x. P x \<longrightarrow> Cauchy (\<lambda>n. s n x)" unfolding cauchy_def apply auto by (erule_tac x=e in allE)auto
  3126   then obtain l where l:"\<forall>x. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l x) sequentially" unfolding convergent_eq_cauchy[THEN sym]
  3127     using choice[of "\<lambda>x l. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l) sequentially"] by auto
  3128   { fix e::real assume "e>0"
  3129     then obtain N where N:"\<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x \<longrightarrow> dist (s m x) (s n x) < e/2"
  3130       using `?rhs`[THEN spec[where x="e/2"]] by auto
  3131     { fix x assume "P x"
  3132       then obtain M where M:"\<forall>n\<ge>M. dist (s n x) (l x) < e/2"
  3133         using l[THEN spec[where x=x], unfolded Lim_sequentially] using `e>0` by(auto elim!: allE[where x="e/2"])
  3134       fix n::nat assume "n\<ge>N"
  3135       hence "dist(s n x)(l x) < e"  using `P x`and N[THEN spec[where x=n], THEN spec[where x="N+M"], THEN spec[where x=x]]
  3136         using M[THEN spec[where x="N+M"]] and dist_triangle_half_l[of "s n x" "s (N+M) x" e "l x"] by (auto simp add: dist_commute)  }
  3137     hence "\<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e" by auto }
  3138   thus ?lhs by auto
  3139 qed
  3140 
  3141 lemma uniformly_cauchy_imp_uniformly_convergent:
  3142   fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b::heine_borel"
  3143   assumes "\<forall>e>0.\<exists>N. \<forall>m (n::nat) x. N \<le> m \<and> N \<le> n \<and> P x --> dist(s m x)(s n x) < e"
  3144           "\<forall>x. P x --> (\<forall>e>0. \<exists>N. \<forall>n. N \<le> n --> dist(s n x)(l x) < e)"
  3145   shows "\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e"
  3146 proof-
  3147   obtain l' where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l' x) < e"
  3148     using assms(1) unfolding uniformly_convergent_eq_cauchy[THEN sym] by auto
  3149   moreover
  3150   { fix x assume "P x"
  3151     hence "l x = l' x" using tendsto_unique[OF trivial_limit_sequentially, of "\<lambda>n. s n x" "l x" "l' x"]
  3152       using l and assms(2) unfolding Lim_sequentially by blast  }
  3153   ultimately show ?thesis by auto
  3154 qed
  3155 
  3156 
  3157 subsection {* Continuity *}
  3158 
  3159 text {* Define continuity over a net to take in restrictions of the set. *}
  3160 
  3161 definition
  3162   continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  3163   where "continuous net f \<longleftrightarrow> (f ---> f(netlimit net)) net"
  3164 
  3165 lemma continuous_trivial_limit:
  3166  "trivial_limit net ==> continuous net f"
  3167   unfolding continuous_def tendsto_def trivial_limit_eq by auto
  3168 
  3169 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f(x)) (at x within s)"
  3170   unfolding continuous_def
  3171   unfolding tendsto_def
  3172   using netlimit_within[of x s]
  3173   by (cases "trivial_limit (at x within s)") (auto simp add: trivial_limit_eventually)
  3174 
  3175 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> (f ---> f(x)) (at x)"
  3176   using continuous_within [of x UNIV f] by (simp add: within_UNIV)
  3177 
  3178 lemma continuous_at_within:
  3179   assumes "continuous (at x) f"  shows "continuous (at x within s) f"
  3180   using assms unfolding continuous_at continuous_within
  3181   by (rule Lim_at_within)
  3182 
  3183 text{* Derive the epsilon-delta forms, which we often use as "definitions" *}
  3184 
  3185 lemma continuous_within_eps_delta:
  3186   "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'\<in> s.  dist x' x < d --> dist (f x') (f x) < e)"
  3187   unfolding continuous_within and Lim_within
  3188   apply auto unfolding dist_nz[THEN sym] apply(auto elim!:allE) apply(rule_tac x=d in exI) by auto
  3189 
  3190 lemma continuous_at_eps_delta: "continuous (at x) f \<longleftrightarrow>  (\<forall>e>0. \<exists>d>0.
  3191                            \<forall>x'. dist x' x < d --> dist(f x')(f x) < e)"
  3192   using continuous_within_eps_delta[of x UNIV f]
  3193   unfolding within_UNIV by blast
  3194 
  3195 text{* Versions in terms of open balls. *}
  3196 
  3197 lemma continuous_within_ball:
  3198  "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  3199                             f ` (ball x d \<inter> s) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3200 proof
  3201   assume ?lhs
  3202   { fix e::real assume "e>0"
  3203     then obtain d where d: "d>0" "\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < e"
  3204       using `?lhs`[unfolded continuous_within Lim_within] by auto
  3205     { fix y assume "y\<in>f ` (ball x d \<inter> s)"
  3206       hence "y \<in> ball (f x) e" using d(2) unfolding dist_nz[THEN sym]
  3207         apply (auto simp add: dist_commute) apply(erule_tac x=xa in ballE) apply auto using `e>0` by auto
  3208     }
  3209     hence "\<exists>d>0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e" using `d>0` unfolding subset_eq ball_def by (auto simp add: dist_commute)  }
  3210   thus ?rhs by auto
  3211 next
  3212   assume ?rhs thus ?lhs unfolding continuous_within Lim_within ball_def subset_eq
  3213     apply (auto simp add: dist_commute) apply(erule_tac x=e in allE) by auto
  3214 qed
  3215 
  3216 lemma continuous_at_ball:
  3217   "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. f ` (ball x d) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3218 proof
  3219   assume ?lhs thus ?rhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3220     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x=xa in allE) apply (auto simp add: dist_commute dist_nz)
  3221     unfolding dist_nz[THEN sym] by auto
  3222 next
  3223   assume ?rhs thus ?lhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3224     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x="f xa" in allE) by (auto simp add: dist_commute dist_nz)
  3225 qed
  3226 
  3227 text{* Define setwise continuity in terms of limits within the set. *}
  3228 
  3229 definition
  3230   continuous_on ::
  3231     "'a set \<Rightarrow> ('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  3232 where
  3233   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  3234 
  3235 lemma continuous_on_topological:
  3236   "continuous_on s f \<longleftrightarrow>
  3237     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3238       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3239 unfolding continuous_on_def tendsto_def
  3240 unfolding Limits.eventually_within eventually_at_topological
  3241 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3242 
  3243 lemma continuous_on_iff:
  3244   "continuous_on s f \<longleftrightarrow>
  3245     (\<forall>x\<in>s. \<forall>e>0. \<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3246 unfolding continuous_on_def Lim_within
  3247 apply (intro ball_cong [OF refl] all_cong ex_cong)
  3248 apply (rename_tac y, case_tac "y = x", simp)
  3249 apply (simp add: dist_nz)
  3250 done
  3251 
  3252 definition
  3253   uniformly_continuous_on ::
  3254     "'a set \<Rightarrow> ('a::metric_space \<Rightarrow> 'b::metric_space) \<Rightarrow> bool"
  3255 where
  3256   "uniformly_continuous_on s f \<longleftrightarrow>
  3257     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3258 
  3259 text{* Some simple consequential lemmas. *}
  3260 
  3261 lemma uniformly_continuous_imp_continuous:
  3262  " uniformly_continuous_on s f ==> continuous_on s f"
  3263   unfolding uniformly_continuous_on_def continuous_on_iff by blast
  3264 
  3265 lemma continuous_at_imp_continuous_within:
  3266  "continuous (at x) f ==> continuous (at x within s) f"
  3267   unfolding continuous_within continuous_at using Lim_at_within by auto
  3268 
  3269 lemma Lim_trivial_limit: "trivial_limit net \<Longrightarrow> (f ---> l) net"
  3270 unfolding tendsto_def by (simp add: trivial_limit_eq)
  3271 
  3272 lemma continuous_at_imp_continuous_on:
  3273   assumes "\<forall>x\<in>s. continuous (at x) f"
  3274   shows "continuous_on s f"
  3275 unfolding continuous_on_def
  3276 proof
  3277   fix x assume "x \<in> s"
  3278   with assms have *: "(f ---> f (netlimit (at x))) (at x)"
  3279     unfolding continuous_def by simp
  3280   have "(f ---> f x) (at x)"
  3281   proof (cases "trivial_limit (at x)")
  3282     case True thus ?thesis
  3283       by (rule Lim_trivial_limit)
  3284   next
  3285     case False
  3286     hence 1: "netlimit (at x) = x"
  3287       using netlimit_within [of x UNIV]
  3288       by (simp add: within_UNIV)
  3289     with * show ?thesis by simp
  3290   qed
  3291   thus "(f ---> f x) (at x within s)"
  3292     by (rule Lim_at_within)
  3293 qed
  3294 
  3295 lemma continuous_on_eq_continuous_within:
  3296   "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x within s) f)"
  3297 unfolding continuous_on_def continuous_def
  3298 apply (rule ball_cong [OF refl])
  3299 apply (case_tac "trivial_limit (at x within s)")
  3300 apply (simp add: Lim_trivial_limit)
  3301 apply (simp add: netlimit_within)
  3302 done
  3303 
  3304 lemmas continuous_on = continuous_on_def -- "legacy theorem name"
  3305 
  3306 lemma continuous_on_eq_continuous_at:
  3307   shows "open s ==> (continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x) f))"
  3308   by (auto simp add: continuous_on continuous_at Lim_within_open)
  3309 
  3310 lemma continuous_within_subset:
  3311  "continuous (at x within s) f \<Longrightarrow> t \<subseteq> s
  3312              ==> continuous (at x within t) f"
  3313   unfolding continuous_within by(metis Lim_within_subset)
  3314 
  3315 lemma continuous_on_subset:
  3316   shows "continuous_on s f \<Longrightarrow> t \<subseteq> s ==> continuous_on t f"
  3317   unfolding continuous_on by (metis subset_eq Lim_within_subset)
  3318 
  3319 lemma continuous_on_interior:
  3320   shows "continuous_on s f \<Longrightarrow> x \<in> interior s ==> continuous (at x) f"
  3321 unfolding interior_def
  3322 apply simp
  3323 by (meson continuous_on_eq_continuous_at continuous_on_subset)
  3324 
  3325 lemma continuous_on_eq:
  3326   "(\<forall>x \<in> s. f x = g x) \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on s g"
  3327   unfolding continuous_on_def tendsto_def Limits.eventually_within
  3328   by simp
  3329 
  3330 text {* Characterization of various kinds of continuity in terms of sequences. *}
  3331 
  3332 (* \<longrightarrow> could be generalized, but \<longleftarrow> requires metric space *)
  3333 lemma continuous_within_sequentially:
  3334   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  3335   shows "continuous (at a within s) f \<longleftrightarrow>
  3336                 (\<forall>x. (\<forall>n::nat. x n \<in> s) \<and> (x ---> a) sequentially
  3337                      --> ((f o x) ---> f a) sequentially)" (is "?lhs = ?rhs")
  3338 proof
  3339   assume ?lhs
  3340   { fix x::"nat \<Rightarrow> 'a" assume x:"\<forall>n. x n \<in> s" "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (x n) a < e"
  3341     fix e::real assume "e>0"
  3342     from `?lhs` obtain d where "d>0" and d:"\<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> dist (f x) (f a) < e" unfolding continuous_within Lim_within using `e>0` by auto
  3343     from x(2) `d>0` obtain N where N:"\<forall>n\<ge>N. dist (x n) a < d" by auto
  3344     hence "\<exists>N. \<forall>n\<ge>N. dist ((f \<circ> x) n) (f a) < e"
  3345       apply(rule_tac  x=N in exI) using N d  apply auto using x(1)
  3346       apply(erule_tac x=n in allE) apply(erule_tac x=n in allE)
  3347       apply(erule_tac x="x n" in ballE)  apply auto unfolding dist_nz[THEN sym] apply auto using `e>0` by auto
  3348   }
  3349   thus ?rhs unfolding continuous_within unfolding Lim_sequentially by simp
  3350 next
  3351   assume ?rhs
  3352   { fix e::real assume "e>0"
  3353     assume "\<not> (\<exists>d>0. \<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> dist (f x) (f a) < e)"
  3354     hence "\<forall>d. \<exists>x. d>0 \<longrightarrow> x\<in>s \<and> (0 < dist x a \<and> dist x a < d \<and> \<not> dist (f x) (f a) < e)" by blast
  3355     then obtain x where x:"\<forall>d>0. x d \<in> s \<and> (0 < dist (x d) a \<and> dist (x d) a < d \<and> \<not> dist (f (x d)) (f a) < e)"
  3356       using choice[of "\<lambda>d x.0<d \<longrightarrow> x\<in>s \<and> (0 < dist x a \<and> dist x a < d \<and> \<not> dist (f x) (f a) < e)"] by auto
  3357     { fix d::real assume "d>0"
  3358       hence "\<exists>N::nat. inverse (real (N + 1)) < d" using real_arch_inv[of d] by (auto, rule_tac x="n - 1" in exI)auto
  3359       then obtain N::nat where N:"inverse (real (N + 1)) < d" by auto
  3360       { fix n::nat assume n:"n\<ge>N"
  3361         hence "dist (x (inverse (real (n + 1)))) a < inverse (real (n + 1))" using x[THEN spec[where x="inverse (real (n + 1))"]] by auto
  3362         moreover have "inverse (real (n + 1)) < d" using N n by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  3363         ultimately have "dist (x (inverse (real (n + 1)))) a < d" by auto
  3364       }
  3365       hence "\<exists>N::nat. \<forall>n\<ge>N. dist (x (inverse (real (n + 1)))) a < d" by auto
  3366     }
  3367     hence "(\<forall>n::nat. x (inverse (real (n + 1))) \<in> s) \<and> (\<forall>e>0. \<exists>N::nat. \<forall>n\<ge>N. dist (x (inverse (real (n + 1)))) a < e)" using x by auto
  3368     hence "\<forall>e>0. \<exists>N::nat. \<forall>n\<ge>N. dist (f (x (inverse (real (n + 1))))) (f a) < e"  using `?rhs`[THEN spec[where x="\<lambda>n::nat. x (inverse (real (n+1)))"], unfolded Lim_sequentially] by auto
  3369     hence "False" apply(erule_tac x=e in allE) using `e>0` using x by auto
  3370   }
  3371   thus ?lhs  unfolding continuous_within unfolding Lim_within unfolding Lim_sequentially by blast
  3372 qed
  3373 
  3374 lemma continuous_at_sequentially:
  3375   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  3376   shows "continuous (at a) f \<longleftrightarrow> (\<forall>x. (x ---> a) sequentially
  3377                   --> ((f o x) ---> f a) sequentially)"
  3378   using continuous_within_sequentially[of a UNIV f] unfolding within_UNIV by auto
  3379 
  3380 lemma continuous_on_sequentially:
  3381   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  3382   shows "continuous_on s f \<longleftrightarrow>
  3383     (\<forall>x. \<forall>a \<in> s. (\<forall>n. x(n) \<in> s) \<and> (x ---> a) sequentially
  3384                     --> ((f o x) ---> f(a)) sequentially)" (is "?lhs = ?rhs")
  3385 proof
  3386   assume ?rhs thus ?lhs using continuous_within_sequentially[of _ s f] unfolding continuous_on_eq_continuous_within by auto
  3387 next
  3388   assume ?lhs thus ?rhs unfolding continuous_on_eq_continuous_within using continuous_within_sequentially[of _ s f] by auto
  3389 qed
  3390 
  3391 lemma uniformly_continuous_on_sequentially':
  3392   "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  3393                     ((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially
  3394                     \<longrightarrow> ((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially)" (is "?lhs = ?rhs")
  3395 proof
  3396   assume ?lhs
  3397   { fix x y assume x:"\<forall>n. x n \<in> s" and y:"\<forall>n. y n \<in> s" and xy:"((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially"
  3398     { fix e::real assume "e>0"
  3399       then obtain d where "d>0" and d:"\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  3400         using `?lhs`[unfolded uniformly_continuous_on_def, THEN spec[where x=e]] by auto
  3401       obtain N where N:"\<forall>n\<ge>N. dist (x n) (y n) < d" using xy[unfolded Lim_sequentially dist_norm] and `d>0` by auto
  3402       { fix n assume "n\<ge>N"
  3403         hence "dist (f (x n)) (f (y n)) < e"
  3404           using N[THEN spec[where x=n]] using d[THEN bspec[where x="x n"], THEN bspec[where x="y n"]] using x and y
  3405           unfolding dist_commute by simp  }
  3406       hence "\<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"  by auto  }
  3407     hence "((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially" unfolding Lim_sequentially and dist_real_def by auto  }
  3408   thus ?rhs by auto
  3409 next
  3410   assume ?rhs
  3411   { assume "\<not> ?lhs"
  3412     then obtain e where "e>0" "\<forall>d>0. \<exists>x\<in>s. \<exists>x'\<in>s. dist x' x < d \<and> \<not> dist (f x') (f x) < e" unfolding uniformly_continuous_on_def by auto
  3413     then obtain fa where fa:"\<forall>x.  0 < x \<longrightarrow> fst (fa x) \<in> s \<and> snd (fa x) \<in> s \<and> dist (fst (fa x)) (snd (fa x)) < x \<and> \<not> dist (f (fst (fa x))) (f (snd (fa x))) < e"
  3414       using choice[of "\<lambda>d x. d>0 \<longrightarrow> fst x \<in> s \<and> snd x \<in> s \<and> dist (snd x) (fst x) < d \<and> \<not> dist (f (snd x)) (f (fst x)) < e"] unfolding Bex_def
  3415       by (auto simp add: dist_commute)
  3416     def x \<equiv> "\<lambda>n::nat. fst (fa (inverse (real n + 1)))"
  3417     def y \<equiv> "\<lambda>n::nat. snd (fa (inverse (real n + 1)))"
  3418     have xyn:"\<forall>n. x n \<in> s \<and> y n \<in> s" and xy0:"\<forall>n. dist (x n) (y n) < inverse (real n + 1)" and fxy:"\<forall>n. \<not> dist (f (x n)) (f (y n)) < e"
  3419       unfolding x_def and y_def using fa by auto
  3420     { fix e::real assume "e>0"
  3421       then obtain N::nat where "N \<noteq> 0" and N:"0 < inverse (real N) \<and> inverse (real N) < e" unfolding real_arch_inv[of e]   by auto
  3422       { fix n::nat assume "n\<ge>N"
  3423         hence "inverse (real n + 1) < inverse (real N)" using real_of_nat_ge_zero and `N\<noteq>0` by auto
  3424         also have "\<dots> < e" using N by auto
  3425         finally have "inverse (real n + 1) < e" by auto
  3426         hence "dist (x n) (y n) < e" using xy0[THEN spec[where x=n]] by auto  }
  3427       hence "\<exists>N. \<forall>n\<ge>N. dist (x n) (y n) < e" by auto  }
  3428     hence "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e" using `?rhs`[THEN spec[where x=x], THEN spec[where x=y]] and xyn unfolding Lim_sequentially dist_real_def by auto
  3429     hence False using fxy and `e>0` by auto  }
  3430   thus ?lhs unfolding uniformly_continuous_on_def by blast
  3431 qed
  3432 
  3433 lemma uniformly_continuous_on_sequentially:
  3434   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
  3435   shows "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  3436                     ((\<lambda>n. x n - y n) ---> 0) sequentially
  3437                     \<longrightarrow> ((\<lambda>n. f(x n) - f(y n)) ---> 0) sequentially)" (is "?lhs = ?rhs")
  3438 (* BH: maybe the previous lemma should replace this one? *)
  3439 unfolding uniformly_continuous_on_sequentially'
  3440 unfolding dist_norm tendsto_norm_zero_iff ..
  3441 
  3442 text{* The usual transformation theorems. *}
  3443 
  3444 lemma continuous_transform_within:
  3445   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3446   assumes "0 < d" "x \<in> s" "\<forall>x' \<in> s. dist x' x < d --> f x' = g x'"
  3447           "continuous (at x within s) f"
  3448   shows "continuous (at x within s) g"
  3449 unfolding continuous_within
  3450 proof (rule Lim_transform_within)
  3451   show "0 < d" by fact
  3452   show "\<forall>x'\<in>s. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  3453     using assms(3) by auto
  3454   have "f x = g x"
  3455     using assms(1,2,3) by auto
  3456   thus "(f ---> g x) (at x within s)"
  3457     using assms(4) unfolding continuous_within by simp
  3458 qed
  3459 
  3460 lemma continuous_transform_at:
  3461   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3462   assumes "0 < d" "\<forall>x'. dist x' x < d --> f x' = g x'"
  3463           "continuous (at x) f"
  3464   shows "continuous (at x) g"
  3465   using continuous_transform_within [of d x UNIV f g] assms
  3466   by (simp add: within_UNIV)
  3467 
  3468 text{* Combination results for pointwise continuity. *}
  3469 
  3470 lemma continuous_const: "continuous net (\<lambda>x. c)"
  3471   by (auto simp add: continuous_def tendsto_const)
  3472 
  3473 lemma continuous_cmul:
  3474   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3475   shows "continuous net f ==> continuous net (\<lambda>x. c *\<^sub>R f x)"
  3476   by (auto simp add: continuous_def intro: tendsto_intros)
  3477 
  3478 lemma continuous_neg:
  3479   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3480   shows "continuous net f ==> continuous net (\<lambda>x. -(f x))"
  3481   by (auto simp add: continuous_def tendsto_minus)
  3482 
  3483 lemma continuous_add:
  3484   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3485   shows "continuous net f \<Longrightarrow> continuous net g \<Longrightarrow> continuous net (\<lambda>x. f x + g x)"
  3486   by (auto simp add: continuous_def tendsto_add)
  3487 
  3488 lemma continuous_sub:
  3489   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3490   shows "continuous net f \<Longrightarrow> continuous net g \<Longrightarrow> continuous net (\<lambda>x. f x - g x)"
  3491   by (auto simp add: continuous_def tendsto_diff)
  3492 
  3493 
  3494 text{* Same thing for setwise continuity. *}
  3495 
  3496 lemma continuous_on_const:
  3497  "continuous_on s (\<lambda>x. c)"
  3498   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3499 
  3500 lemma continuous_on_cmul:
  3501   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3502   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c *\<^sub>R (f x))"
  3503   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3504 
  3505 lemma continuous_on_neg:
  3506   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3507   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
  3508   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3509 
  3510 lemma continuous_on_add:
  3511   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3512   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3513            \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
  3514   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3515 
  3516 lemma continuous_on_sub:
  3517   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3518   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3519            \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
  3520   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3521 
  3522 text{* Same thing for uniform continuity, using sequential formulations. *}
  3523 
  3524 lemma uniformly_continuous_on_const:
  3525  "uniformly_continuous_on s (\<lambda>x. c)"
  3526   unfolding uniformly_continuous_on_def by simp
  3527 
  3528 lemma uniformly_continuous_on_cmul:
  3529   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3530   assumes "uniformly_continuous_on s f"
  3531   shows "uniformly_continuous_on s (\<lambda>x. c *\<^sub>R f(x))"
  3532 proof-
  3533   { fix x y assume "((\<lambda>n. f (x n) - f (y n)) ---> 0) sequentially"
  3534     hence "((\<lambda>n. c *\<^sub>R f (x n) - c *\<^sub>R f (y n)) ---> 0) sequentially"
  3535       using tendsto_scaleR [OF tendsto_const, of "(\<lambda>n. f (x n) - f (y n))" 0 sequentially c]
  3536       unfolding scaleR_zero_right scaleR_right_diff_distrib by auto
  3537   }
  3538   thus ?thesis using assms unfolding uniformly_continuous_on_sequentially'
  3539     unfolding dist_norm tendsto_norm_zero_iff by auto
  3540 qed
  3541 
  3542 lemma dist_minus:
  3543   fixes x y :: "'a::real_normed_vector"
  3544   shows "dist (- x) (- y) = dist x y"
  3545   unfolding dist_norm minus_diff_minus norm_minus_cancel ..
  3546 
  3547 lemma uniformly_continuous_on_neg:
  3548   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3549   shows "uniformly_continuous_on s f
  3550          ==> uniformly_continuous_on s (\<lambda>x. -(f x))"
  3551   unfolding uniformly_continuous_on_def dist_minus .
  3552 
  3553 lemma uniformly_continuous_on_add:
  3554   fixes f g :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3555   assumes "uniformly_continuous_on s f" "uniformly_continuous_on s g"
  3556   shows "uniformly_continuous_on s (\<lambda>x. f x + g x)"
  3557 proof-
  3558   {  fix x y assume "((\<lambda>n. f (x n) - f (y n)) ---> 0) sequentially"
  3559                     "((\<lambda>n. g (x n) - g (y n)) ---> 0) sequentially"
  3560     hence "((\<lambda>xa. f (x xa) - f (y xa) + (g (x xa) - g (y xa))) ---> 0 + 0) sequentially"
  3561       using tendsto_add[of "\<lambda> n. f (x n) - f (y n)" 0  sequentially "\<lambda> n. g (x n) - g (y n)" 0] by auto
  3562     hence "((\<lambda>n. f (x n) + g (x n) - (f (y n) + g (y n))) ---> 0) sequentially" unfolding Lim_sequentially and add_diff_add [symmetric] by auto  }
  3563   thus ?thesis using assms unfolding uniformly_continuous_on_sequentially'
  3564     unfolding dist_norm tendsto_norm_zero_iff by auto
  3565 qed
  3566 
  3567 lemma uniformly_continuous_on_sub:
  3568   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3569   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s g
  3570            ==> uniformly_continuous_on s  (\<lambda>x. f x - g x)"
  3571   unfolding ab_diff_minus
  3572   using uniformly_continuous_on_add[of s f "\<lambda>x. - g x"]
  3573   using uniformly_continuous_on_neg[of s g] by auto
  3574 
  3575 text{* Identity function is continuous in every sense. *}
  3576 
  3577 lemma continuous_within_id:
  3578  "continuous (at a within s) (\<lambda>x. x)"
  3579   unfolding continuous_within by (rule Lim_at_within [OF LIM_ident])
  3580 
  3581 lemma continuous_at_id:
  3582  "continuous (at a) (\<lambda>x. x)"
  3583   unfolding continuous_at by (rule LIM_ident)
  3584 
  3585 lemma continuous_on_id:
  3586  "continuous_on s (\<lambda>x. x)"
  3587   unfolding continuous_on_def by (auto intro: tendsto_ident_at_within)
  3588 
  3589 lemma uniformly_continuous_on_id:
  3590  "uniformly_continuous_on s (\<lambda>x. x)"
  3591   unfolding uniformly_continuous_on_def by auto
  3592 
  3593 text{* Continuity of all kinds is preserved under composition. *}
  3594 
  3595 lemma continuous_within_topological:
  3596   "continuous (at x within s) f \<longleftrightarrow>
  3597     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3598       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3599 unfolding continuous_within
  3600 unfolding tendsto_def Limits.eventually_within eventually_at_topological
  3601 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3602 
  3603 lemma continuous_within_compose:
  3604   assumes "continuous (at x within s) f"
  3605   assumes "continuous (at (f x) within f ` s) g"
  3606   shows "continuous (at x within s) (g o f)"
  3607 using assms unfolding continuous_within_topological by simp metis
  3608 
  3609 lemma continuous_at_compose:
  3610   assumes "continuous (at x) f"  "continuous (at (f x)) g"
  3611   shows "continuous (at x) (g o f)"
  3612 proof-
  3613   have " continuous (at (f x) within range f) g" using assms(2) using continuous_within_subset[of "f x" UNIV g "range f", unfolded within_UNIV] by auto
  3614   thus ?thesis using assms(1) using continuous_within_compose[of x UNIV f g, unfolded within_UNIV] by auto
  3615 qed
  3616 
  3617 lemma continuous_on_compose:
  3618   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  3619   unfolding continuous_on_topological by simp metis
  3620 
  3621 lemma uniformly_continuous_on_compose:
  3622   assumes "uniformly_continuous_on s f"  "uniformly_continuous_on (f ` s) g"
  3623   shows "uniformly_continuous_on s (g o f)"
  3624 proof-
  3625   { fix e::real assume "e>0"
  3626     then obtain d where "d>0" and d:"\<forall>x\<in>f ` s. \<forall>x'\<in>f ` s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e" using assms(2) unfolding uniformly_continuous_on_def by auto
  3627     obtain d' where "d'>0" "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d' \<longrightarrow> dist (f x') (f x) < d" using `d>0` using assms(1) unfolding uniformly_continuous_on_def by auto
  3628     hence "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist ((g \<circ> f) x') ((g \<circ> f) x) < e" using `d>0` using d by auto  }
  3629   thus ?thesis using assms unfolding uniformly_continuous_on_def by auto
  3630 qed
  3631 
  3632 text{* Continuity in terms of open preimages. *}
  3633 
  3634 lemma continuous_at_open:
  3635   shows "continuous (at x) f \<longleftrightarrow> (\<forall>t. open t \<and> f x \<in> t --> (\<exists>s. open s \<and> x \<in> s \<and> (\<forall>x' \<in> s. (f x') \<in> t)))"
  3636 unfolding continuous_within_topological [of x UNIV f, unfolded within_UNIV]
  3637 unfolding imp_conjL by (intro all_cong imp_cong ex_cong conj_cong refl) auto
  3638 
  3639 lemma continuous_on_open:
  3640   shows "continuous_on s f \<longleftrightarrow>
  3641         (\<forall>t. openin (subtopology euclidean (f ` s)) t
  3642             --> openin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3643 proof (safe)
  3644   fix t :: "'b set"
  3645   assume 1: "continuous_on s f"
  3646   assume 2: "openin (subtopology euclidean (f ` s)) t"
  3647   from 2 obtain B where B: "open B" and t: "t = f ` s \<inter> B"
  3648     unfolding openin_open by auto
  3649   def U == "\<Union>{A. open A \<and> (\<forall>x\<in>s. x \<in> A \<longrightarrow> f x \<in> B)}"
  3650   have "open U" unfolding U_def by (simp add: open_Union)
  3651   moreover have "\<forall>x\<in>s. x \<in> U \<longleftrightarrow> f x \<in> t"
  3652   proof (intro ballI iffI)
  3653     fix x assume "x \<in> s" and "x \<in> U" thus "f x \<in> t"
  3654       unfolding U_def t by auto
  3655   next
  3656     fix x assume "x \<in> s" and "f x \<in> t"
  3657     hence "x \<in> s" and "f x \<in> B"
  3658       unfolding t by auto
  3659     with 1 B obtain A where "open A" "x \<in> A" "\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B"
  3660       unfolding t continuous_on_topological by metis
  3661     then show "x \<in> U"
  3662       unfolding U_def by auto
  3663   qed
  3664   ultimately have "open U \<and> {x \<in> s. f x \<in> t} = s \<inter> U" by auto
  3665   then show "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3666     unfolding openin_open by fast
  3667 next
  3668   assume "?rhs" show "continuous_on s f"
  3669   unfolding continuous_on_topological
  3670   proof (clarify)
  3671     fix x and B assume "x \<in> s" and "open B" and "f x \<in> B"
  3672     have "openin (subtopology euclidean (f ` s)) (f ` s \<inter> B)"
  3673       unfolding openin_open using `open B` by auto
  3674     then have "openin (subtopology euclidean s) {x \<in> s. f x \<in> f ` s \<inter> B}"
  3675       using `?rhs` by fast
  3676     then show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  3677       unfolding openin_open using `x \<in> s` and `f x \<in> B` by auto
  3678   qed
  3679 qed
  3680 
  3681 text {* Similarly in terms of closed sets. *}
  3682 
  3683 lemma continuous_on_closed:
  3684   shows "continuous_on s f \<longleftrightarrow>  (\<forall>t. closedin (subtopology euclidean (f ` s)) t  --> closedin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3685 proof
  3686   assume ?lhs
  3687   { fix t
  3688     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3689     have **:"f ` s - (f ` s - (f ` s - t)) = f ` s - t" by auto
  3690     assume as:"closedin (subtopology euclidean (f ` s)) t"
  3691     hence "closedin (subtopology euclidean (f ` s)) (f ` s - (f ` s - t))" unfolding closedin_def topspace_euclidean_subtopology unfolding ** by auto
  3692     hence "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?lhs`[unfolded continuous_on_open, THEN spec[where x="(f ` s) - t"]]
  3693       unfolding openin_closedin_eq topspace_euclidean_subtopology unfolding * by auto  }
  3694   thus ?rhs by auto
  3695 next
  3696   assume ?rhs
  3697   { fix t
  3698     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3699     assume as:"openin (subtopology euclidean (f ` s)) t"
  3700     hence "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?rhs`[THEN spec[where x="(f ` s) - t"]]
  3701       unfolding openin_closedin_eq topspace_euclidean_subtopology *[THEN sym] closedin_subtopology by auto }
  3702   thus ?lhs unfolding continuous_on_open by auto
  3703 qed
  3704 
  3705 text {* Half-global and completely global cases. *}
  3706 
  3707 lemma continuous_open_in_preimage:
  3708   assumes "continuous_on s f"  "open t"
  3709   shows "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3710 proof-
  3711   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3712   have "openin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3713     using openin_open_Int[of t "f ` s", OF assms(2)] unfolding openin_open by auto
  3714   thus ?thesis using assms(1)[unfolded continuous_on_open, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3715 qed
  3716 
  3717 lemma continuous_closed_in_preimage:
  3718   assumes "continuous_on s f"  "closed t"
  3719   shows "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3720 proof-
  3721   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3722   have "closedin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3723     using closedin_closed_Int[of t "f ` s", OF assms(2)] unfolding Int_commute by auto
  3724   thus ?thesis
  3725     using assms(1)[unfolded continuous_on_closed, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3726 qed
  3727 
  3728 lemma continuous_open_preimage:
  3729   assumes "continuous_on s f" "open s" "open t"
  3730   shows "open {x \<in> s. f x \<in> t}"
  3731 proof-
  3732   obtain T where T: "open T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3733     using continuous_open_in_preimage[OF assms(1,3)] unfolding openin_open by auto
  3734   thus ?thesis using open_Int[of s T, OF assms(2)] by auto
  3735 qed
  3736 
  3737 lemma continuous_closed_preimage:
  3738   assumes "continuous_on s f" "closed s" "closed t"
  3739   shows "closed {x \<in> s. f x \<in> t}"
  3740 proof-
  3741   obtain T where T: "closed T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3742     using continuous_closed_in_preimage[OF assms(1,3)] unfolding closedin_closed by auto
  3743   thus ?thesis using closed_Int[of s T, OF assms(2)] by auto
  3744 qed
  3745 
  3746 lemma continuous_open_preimage_univ:
  3747   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open {x. f x \<in> s}"
  3748   using continuous_open_preimage[of UNIV f s] open_UNIV continuous_at_imp_continuous_on by auto
  3749 
  3750 lemma continuous_closed_preimage_univ:
  3751   shows "(\<forall>x. continuous (at x) f) \<Longrightarrow> closed s ==> closed {x. f x \<in> s}"
  3752   using continuous_closed_preimage[of UNIV f s] closed_UNIV continuous_at_imp_continuous_on by auto
  3753 
  3754 lemma continuous_open_vimage:
  3755   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open (f -` s)"
  3756   unfolding vimage_def by (rule continuous_open_preimage_univ)
  3757 
  3758 lemma continuous_closed_vimage:
  3759   shows "\<forall>x. continuous (at x) f \<Longrightarrow> closed s \<Longrightarrow> closed (f -` s)"
  3760   unfolding vimage_def by (rule continuous_closed_preimage_univ)
  3761 
  3762 lemma interior_image_subset:
  3763   assumes "\<forall>x. continuous (at x) f" "inj f"
  3764   shows "interior (f ` s) \<subseteq> f ` (interior s)"
  3765   apply rule unfolding interior_def mem_Collect_eq image_iff apply safe
  3766 proof- fix x T assume as:"open T" "x \<in> T" "T \<subseteq> f ` s" 
  3767   hence "x \<in> f ` s" by auto then guess y unfolding image_iff .. note y=this
  3768   thus "\<exists>xa\<in>{x. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> s}. x = f xa" apply(rule_tac x=y in bexI) using assms as
  3769     apply safe apply(rule_tac x="{x. f x \<in> T}" in exI) apply(safe,rule continuous_open_preimage_univ)
  3770   proof- fix x assume "f x \<in> T" hence "f x \<in> f ` s" using as by auto
  3771     thus "x \<in> s" unfolding inj_image_mem_iff[OF assms(2)] . qed auto qed
  3772 
  3773 text {* Equality of continuous functions on closure and related results. *}
  3774 
  3775 lemma continuous_closed_in_preimage_constant:
  3776   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3777   shows "continuous_on s f ==> closedin (subtopology euclidean s) {x \<in> s. f x = a}"
  3778   using continuous_closed_in_preimage[of s f "{a}"] by auto
  3779 
  3780 lemma continuous_closed_preimage_constant:
  3781   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3782   shows "continuous_on s f \<Longrightarrow> closed s ==> closed {x \<in> s. f x = a}"
  3783   using continuous_closed_preimage[of s f "{a}"] by auto
  3784 
  3785 lemma continuous_constant_on_closure:
  3786   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3787   assumes "continuous_on (closure s) f"
  3788           "\<forall>x \<in> s. f x = a"
  3789   shows "\<forall>x \<in> (closure s). f x = a"
  3790     using continuous_closed_preimage_constant[of "closure s" f a]
  3791     assms closure_minimal[of s "{x \<in> closure s. f x = a}"] closure_subset unfolding subset_eq by auto
  3792 
  3793 lemma image_closure_subset:
  3794   assumes "continuous_on (closure s) f"  "closed t"  "(f ` s) \<subseteq> t"
  3795   shows "f ` (closure s) \<subseteq> t"
  3796 proof-
  3797   have "s \<subseteq> {x \<in> closure s. f x \<in> t}" using assms(3) closure_subset by auto
  3798   moreover have "closed {x \<in> closure s. f x \<in> t}"
  3799     using continuous_closed_preimage[OF assms(1)] and assms(2) by auto
  3800   ultimately have "closure s = {x \<in> closure s . f x \<in> t}"
  3801     using closure_minimal[of s "{x \<in> closure s. f x \<in> t}"] by auto
  3802   thus ?thesis by auto
  3803 qed
  3804 
  3805 lemma continuous_on_closure_norm_le:
  3806   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3807   assumes "continuous_on (closure s) f"  "\<forall>y \<in> s. norm(f y) \<le> b"  "x \<in> (closure s)"
  3808   shows "norm(f x) \<le> b"
  3809 proof-
  3810   have *:"f ` s \<subseteq> cball 0 b" using assms(2)[unfolded mem_cball_0[THEN sym]] by auto
  3811   show ?thesis
  3812     using image_closure_subset[OF assms(1) closed_cball[of 0 b] *] assms(3)
  3813     unfolding subset_eq apply(erule_tac x="f x" in ballE) by (auto simp add: dist_norm)
  3814 qed
  3815 
  3816 text {* Making a continuous function avoid some value in a neighbourhood. *}
  3817 
  3818 lemma continuous_within_avoid:
  3819   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3820   assumes "continuous (at x within s) f"  "x \<in> s"  "f x \<noteq> a"
  3821   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e --> f y \<noteq> a"
  3822 proof-
  3823   obtain d where "d>0" and d:"\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < dist (f x) a"
  3824     using assms(1)[unfolded continuous_within Lim_within, THEN spec[where x="dist (f x) a"]] assms(3)[unfolded dist_nz] by auto
  3825   { fix y assume " y\<in>s"  "dist x y < d"
  3826     hence "f y \<noteq> a" using d[THEN bspec[where x=y]] assms(3)[unfolded dist_nz]
  3827       apply auto unfolding dist_nz[THEN sym] by (auto simp add: dist_commute) }
  3828   thus ?thesis using `d>0` by auto
  3829 qed
  3830 
  3831 lemma continuous_at_avoid:
  3832   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3833   assumes "continuous (at x) f"  "f x \<noteq> a"
  3834   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3835 using assms using continuous_within_avoid[of x UNIV f a, unfolded within_UNIV] by auto
  3836 
  3837 lemma continuous_on_avoid:
  3838   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3839   assumes "continuous_on s f"  "x \<in> s"  "f x \<noteq> a"
  3840   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e \<longrightarrow> f y \<noteq> a"
  3841 using assms(1)[unfolded continuous_on_eq_continuous_within, THEN bspec[where x=x], OF assms(2)]  continuous_within_avoid[of x s f a]  assms(2,3) by auto
  3842 
  3843 lemma continuous_on_open_avoid:
  3844   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3845   assumes "continuous_on s f"  "open s"  "x \<in> s"  "f x \<noteq> a"
  3846   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3847 using assms(1)[unfolded continuous_on_eq_continuous_at[OF assms(2)], THEN bspec[where x=x], OF assms(3)]  continuous_at_avoid[of x f a]  assms(3,4) by auto
  3848 
  3849 text {* Proving a function is constant by proving open-ness of level set. *}
  3850 
  3851 lemma continuous_levelset_open_in_cases:
  3852   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3853   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3854         openin (subtopology euclidean s) {x \<in> s. f x = a}
  3855         ==> (\<forall>x \<in> s. f x \<noteq> a) \<or> (\<forall>x \<in> s. f x = a)"
  3856 unfolding connected_clopen using continuous_closed_in_preimage_constant by auto
  3857 
  3858 lemma continuous_levelset_open_in:
  3859   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3860   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3861         openin (subtopology euclidean s) {x \<in> s. f x = a} \<Longrightarrow>
  3862         (\<exists>x \<in> s. f x = a)  ==> (\<forall>x \<in> s. f x = a)"
  3863 using continuous_levelset_open_in_cases[of s f ]
  3864 by meson
  3865 
  3866 lemma continuous_levelset_open:
  3867   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3868   assumes "connected s"  "continuous_on s f"  "open {x \<in> s. f x = a}"  "\<exists>x \<in> s.  f x = a"
  3869   shows "\<forall>x \<in> s. f x = a"
  3870 using continuous_levelset_open_in[OF assms(1,2), of a, unfolded openin_open] using assms (3,4) by fast
  3871 
  3872 text {* Some arithmetical combinations (more to prove). *}
  3873 
  3874 lemma open_scaling[intro]:
  3875   fixes s :: "'a::real_normed_vector set"
  3876   assumes "c \<noteq> 0"  "open s"
  3877   shows "open((\<lambda>x. c *\<^sub>R x) ` s)"
  3878 proof-
  3879   { fix x assume "x \<in> s"
  3880     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> s" using assms(2)[unfolded open_dist, THEN bspec[where x=x]] by auto
  3881     have "e * abs c > 0" using assms(1)[unfolded zero_less_abs_iff[THEN sym]] using mult_pos_pos[OF `e>0`] by auto
  3882     moreover
  3883     { fix y assume "dist y (c *\<^sub>R x) < e * \<bar>c\<bar>"
  3884       hence "norm ((1 / c) *\<^sub>R y - x) < e" unfolding dist_norm
  3885         using norm_scaleR[of c "(1 / c) *\<^sub>R y - x", unfolded scaleR_right_diff_distrib, unfolded scaleR_scaleR] assms(1)
  3886           assms(1)[unfolded zero_less_abs_iff[THEN sym]] by (simp del:zero_less_abs_iff)
  3887       hence "y \<in> op *\<^sub>R c ` s" using rev_image_eqI[of "(1 / c) *\<^sub>R y" s y "op *\<^sub>R c"]  e[THEN spec[where x="(1 / c) *\<^sub>R y"]]  assms(1) unfolding dist_norm scaleR_scaleR by auto  }
  3888     ultimately have "\<exists>e>0. \<forall>x'. dist x' (c *\<^sub>R x) < e \<longrightarrow> x' \<in> op *\<^sub>R c ` s" apply(rule_tac x="e * abs c" in exI) by auto  }
  3889   thus ?thesis unfolding open_dist by auto
  3890 qed
  3891 
  3892 lemma minus_image_eq_vimage:
  3893   fixes A :: "'a::ab_group_add set"
  3894   shows "(\<lambda>x. - x) ` A = (\<lambda>x. - x) -` A"
  3895   by (auto intro!: image_eqI [where f="\<lambda>x. - x"])
  3896 
  3897 lemma open_negations:
  3898   fixes s :: "'a::real_normed_vector set"
  3899   shows "open s ==> open ((\<lambda> x. -x) ` s)"
  3900   unfolding scaleR_minus1_left [symmetric]
  3901   by (rule open_scaling, auto)
  3902 
  3903 lemma open_translation:
  3904   fixes s :: "'a::real_normed_vector set"
  3905   assumes "open s"  shows "open((\<lambda>x. a + x) ` s)"
  3906 proof-
  3907   { fix x have "continuous (at x) (\<lambda>x. x - a)" using continuous_sub[of "at x" "\<lambda>x. x" "\<lambda>x. a"] continuous_at_id[of x] continuous_const[of "at x" a] by auto  }
  3908   moreover have "{x. x - a \<in> s}  = op + a ` s" apply auto unfolding image_iff apply(rule_tac x="x - a" in bexI) by auto
  3909   ultimately show ?thesis using continuous_open_preimage_univ[of "\<lambda>x. x - a" s] using assms by auto
  3910 qed
  3911 
  3912 lemma open_affinity:
  3913   fixes s :: "'a::real_normed_vector set"
  3914   assumes "open s"  "c \<noteq> 0"
  3915   shows "open ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  3916 proof-
  3917   have *:"(\<lambda>x. a + c *\<^sub>R x) = (\<lambda>x. a + x) \<circ> (\<lambda>x. c *\<^sub>R x)" unfolding o_def ..
  3918   have "op + a ` op *\<^sub>R c ` s = (op + a \<circ> op *\<^sub>R c) ` s" by auto
  3919   thus ?thesis using assms open_translation[of "op *\<^sub>R c ` s" a] unfolding * by auto
  3920 qed
  3921 
  3922 lemma interior_translation:
  3923   fixes s :: "'a::real_normed_vector set"
  3924   shows "interior ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (interior s)"
  3925 proof (rule set_eqI, rule)
  3926   fix x assume "x \<in> interior (op + a ` s)"
  3927   then obtain e where "e>0" and e:"ball x e \<subseteq> op + a ` s" unfolding mem_interior by auto
  3928   hence "ball (x - a) e \<subseteq> s" unfolding subset_eq Ball_def mem_ball dist_norm apply auto apply(erule_tac x="a + xa" in allE) unfolding ab_group_add_class.diff_diff_eq[THEN sym] by auto
  3929   thus "x \<in> op + a ` interior s" unfolding image_iff apply(rule_tac x="x - a" in bexI) unfolding mem_interior using `e > 0` by auto
  3930 next
  3931   fix x assume "x \<in> op + a ` interior s"
  3932   then obtain y e where "e>0" and e:"ball y e \<subseteq> s" and y:"x = a + y" unfolding image_iff Bex_def mem_interior by auto
  3933   { fix z have *:"a + y - z = y + a - z" by auto
  3934     assume "z\<in>ball x e"
  3935     hence "z - a \<in> s" using e[unfolded subset_eq, THEN bspec[where x="z - a"]] unfolding mem_ball dist_norm y ab_group_add_class.diff_diff_eq2 * by auto
  3936     hence "z \<in> op + a ` s" unfolding image_iff by(auto intro!: bexI[where x="z - a"])  }
  3937   hence "ball x e \<subseteq> op + a ` s" unfolding subset_eq by auto
  3938   thus "x \<in> interior (op + a ` s)" unfolding mem_interior using `e>0` by auto
  3939 qed
  3940 
  3941 text {* We can now extend limit compositions to consider the scalar multiplier. *}
  3942 
  3943 lemma continuous_vmul:
  3944   fixes c :: "'a::metric_space \<Rightarrow> real" and v :: "'b::real_normed_vector"
  3945   shows "continuous net c ==> continuous net (\<lambda>x. c(x) *\<^sub>R v)"
  3946   unfolding continuous_def by (intro tendsto_intros)
  3947 
  3948 lemma continuous_mul:
  3949   fixes c :: "'a::metric_space \<Rightarrow> real"
  3950   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3951   shows "continuous net c \<Longrightarrow> continuous net f
  3952              ==> continuous net (\<lambda>x. c(x) *\<^sub>R f x) "
  3953   unfolding continuous_def by (intro tendsto_intros)
  3954 
  3955 lemmas continuous_intros = continuous_add continuous_vmul continuous_cmul
  3956   continuous_const continuous_sub continuous_at_id continuous_within_id continuous_mul
  3957 
  3958 lemma continuous_on_vmul:
  3959   fixes c :: "'a::metric_space \<Rightarrow> real" and v :: "'b::real_normed_vector"
  3960   shows "continuous_on s c ==> continuous_on s (\<lambda>x. c(x) *\<^sub>R v)"
  3961   unfolding continuous_on_eq_continuous_within using continuous_vmul[of _ c] by auto
  3962 
  3963 lemma continuous_on_mul:
  3964   fixes c :: "'a::metric_space \<Rightarrow> real"
  3965   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3966   shows "continuous_on s c \<Longrightarrow> continuous_on s f
  3967              ==> continuous_on s (\<lambda>x. c(x) *\<^sub>R f x)"
  3968   unfolding continuous_on_eq_continuous_within using continuous_mul[of _ c] by auto
  3969 
  3970 lemma continuous_on_mul_real:
  3971   fixes f :: "'a::metric_space \<Rightarrow> real"
  3972   fixes g :: "'a::metric_space \<Rightarrow> real"
  3973   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3974              ==> continuous_on s (\<lambda>x. f x * g x)"
  3975   using continuous_on_mul[of s f g] unfolding real_scaleR_def .
  3976 
  3977 lemmas continuous_on_intros = continuous_on_add continuous_on_const
  3978   continuous_on_id continuous_on_compose continuous_on_cmul continuous_on_neg
  3979   continuous_on_sub continuous_on_mul continuous_on_vmul continuous_on_mul_real
  3980   uniformly_continuous_on_add uniformly_continuous_on_const
  3981   uniformly_continuous_on_id uniformly_continuous_on_compose
  3982   uniformly_continuous_on_cmul uniformly_continuous_on_neg
  3983   uniformly_continuous_on_sub
  3984 
  3985 text {* And so we have continuity of inverse. *}
  3986 
  3987 lemma continuous_inv:
  3988   fixes f :: "'a::metric_space \<Rightarrow> real"
  3989   shows "continuous net f \<Longrightarrow> f(netlimit net) \<noteq> 0
  3990            ==> continuous net (inverse o f)"
  3991   unfolding continuous_def using Lim_inv by auto
  3992 
  3993 lemma continuous_at_within_inv:
  3994   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_field"
  3995   assumes "continuous (at a within s) f" "f a \<noteq> 0"
  3996   shows "continuous (at a within s) (inverse o f)"
  3997   using assms unfolding continuous_within o_def
  3998   by (intro tendsto_intros)
  3999 
  4000 lemma continuous_at_inv:
  4001   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_field"
  4002   shows "continuous (at a) f \<Longrightarrow> f a \<noteq> 0
  4003          ==> continuous (at a) (inverse o f) "
  4004   using within_UNIV[THEN sym, of "at a"] using continuous_at_within_inv[of a UNIV] by auto
  4005 
  4006 text {* Topological properties of linear functions. *}
  4007 
  4008 lemma linear_lim_0:
  4009   assumes "bounded_linear f" shows "(f ---> 0) (at (0))"
  4010 proof-
  4011   interpret f: bounded_linear f by fact
  4012   have "(f ---> f 0) (at 0)"
  4013     using tendsto_ident_at by (rule f.tendsto)
  4014   thus ?thesis unfolding f.zero .
  4015 qed
  4016 
  4017 lemma linear_continuous_at:
  4018   assumes "bounded_linear f"  shows "continuous (at a) f"
  4019   unfolding continuous_at using assms
  4020   apply (rule bounded_linear.tendsto)
  4021   apply (rule tendsto_ident_at)
  4022   done
  4023 
  4024 lemma linear_continuous_within:
  4025   shows "bounded_linear f ==> continuous (at x within s) f"
  4026   using continuous_at_imp_continuous_within[of x f s] using linear_continuous_at[of f] by auto
  4027 
  4028 lemma linear_continuous_on:
  4029   shows "bounded_linear f ==> continuous_on s f"
  4030   using continuous_at_imp_continuous_on[of s f] using linear_continuous_at[of f] by auto
  4031 
  4032 text {* Also bilinear functions, in composition form. *}
  4033 
  4034 lemma bilinear_continuous_at_compose:
  4035   shows "continuous (at x) f \<Longrightarrow> continuous (at x) g \<Longrightarrow> bounded_bilinear h
  4036         ==> continuous (at x) (\<lambda>x. h (f x) (g x))"
  4037   unfolding continuous_at using Lim_bilinear[of f "f x" "(at x)" g "g x" h] by auto
  4038 
  4039 lemma bilinear_continuous_within_compose:
  4040   shows "continuous (at x within s) f \<Longrightarrow> continuous (at x within s) g \<Longrightarrow> bounded_bilinear h
  4041         ==> continuous (at x within s) (\<lambda>x. h (f x) (g x))"
  4042   unfolding continuous_within using Lim_bilinear[of f "f x"] by auto
  4043 
  4044 lemma bilinear_continuous_on_compose:
  4045   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> bounded_bilinear h
  4046              ==> continuous_on s (\<lambda>x. h (f x) (g x))"
  4047   unfolding continuous_on_def
  4048   by (fast elim: bounded_bilinear.tendsto)
  4049 
  4050 text {* Preservation of compactness and connectedness under continuous function. *}
  4051 
  4052 lemma compact_continuous_image:
  4053   assumes "continuous_on s f"  "compact s"
  4054   shows "compact(f ` s)"
  4055 proof-
  4056   { fix x assume x:"\<forall>n::nat. x n \<in> f ` s"
  4057     then obtain y where y:"\<forall>n. y n \<in> s \<and> x n = f (y n)" unfolding image_iff Bex_def using choice[of "\<lambda>n xa. xa \<in> s \<and> x n = f xa"] by auto
  4058     then obtain l r where "l\<in>s" and r:"subseq r" and lr:"((y \<circ> r) ---> l) sequentially" using assms(2)[unfolded compact_def, THEN spec[where x=y]] by auto
  4059     { fix e::real assume "e>0"
  4060       then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' l < d \<longrightarrow> dist (f x') (f l) < e" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=l], OF `l\<in>s`] by auto
  4061       then obtain N::nat where N:"\<forall>n\<ge>N. dist ((y \<circ> r) n) l < d" using lr[unfolded Lim_sequentially, THEN spec[where x=d]] by auto
  4062       { fix n::nat assume "n\<ge>N" hence "dist ((x \<circ> r) n) (f l) < e" using N[THEN spec[where x=n]] d[THEN bspec[where x="y (r n)"]] y[THEN spec[where x="r n"]] by auto  }
  4063       hence "\<exists>N. \<forall>n\<ge>N. dist ((x \<circ> r) n) (f l) < e" by auto  }
  4064     hence "\<exists>l\<in>f ` s. \<exists>r. subseq r \<and> ((x \<circ> r) ---> l) sequentially" unfolding Lim_sequentially using r lr `l\<in>s` by auto  }
  4065   thus ?thesis unfolding compact_def by auto
  4066 qed
  4067 
  4068 lemma connected_continuous_image:
  4069   assumes "continuous_on s f"  "connected s"
  4070   shows "connected(f ` s)"
  4071 proof-
  4072   { fix T assume as: "T \<noteq> {}"  "T \<noteq> f ` s"  "openin (subtopology euclidean (f ` s)) T"  "closedin (subtopology euclidean (f ` s)) T"
  4073     have "{x \<in> s. f x \<in> T} = {} \<or> {x \<in> s. f x \<in> T} = s"
  4074       using assms(1)[unfolded continuous_on_open, THEN spec[where x=T]]
  4075       using assms(1)[unfolded continuous_on_closed, THEN spec[where x=T]]
  4076       using assms(2)[unfolded connected_clopen, THEN spec[where x="{x \<in> s. f x \<in> T}"]] as(3,4) by auto
  4077     hence False using as(1,2)
  4078       using as(4)[unfolded closedin_def topspace_euclidean_subtopology] by auto }
  4079   thus ?thesis unfolding connected_clopen by auto
  4080 qed
  4081 
  4082 text {* Continuity implies uniform continuity on a compact domain. *}
  4083 
  4084 lemma compact_uniformly_continuous:
  4085   assumes "continuous_on s f"  "compact s"
  4086   shows "uniformly_continuous_on s f"
  4087 proof-
  4088     { fix x assume x:"x\<in>s"
  4089       hence "\<forall>xa. \<exists>y. 0 < xa \<longrightarrow> (y > 0 \<and> (\<forall>x'\<in>s. dist x' x < y \<longrightarrow> dist (f x') (f x) < xa))" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=x]] by auto
  4090       hence "\<exists>fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)" using choice[of "\<lambda>e d. e>0 \<longrightarrow> d>0 \<and>(\<forall>x'\<in>s. (dist x' x < d \<longrightarrow> dist (f x') (f x) < e))"] by auto  }
  4091     then have "\<forall>x\<in>s. \<exists>y. \<forall>xa. 0 < xa \<longrightarrow> (\<forall>x'\<in>s. y xa > 0 \<and> (dist x' x < y xa \<longrightarrow> dist (f x') (f x) < xa))" by auto
  4092     then obtain d where d:"\<forall>e>0. \<forall>x\<in>s. \<forall>x'\<in>s. d x e > 0 \<and> (dist x' x < d x e \<longrightarrow> dist (f x') (f x) < e)"
  4093       using bchoice[of s "\<lambda>x fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)"] by blast
  4094 
  4095   { fix e::real assume "e>0"
  4096 
  4097     { fix x assume "x\<in>s" hence "x \<in> ball x (d x (e / 2))" unfolding centre_in_ball using d[THEN spec[where x="e/2"]] using `e>0` by auto  }
  4098     hence "s \<subseteq> \<Union>{ball x (d x (e / 2)) |x. x \<in> s}" unfolding subset_eq by auto
  4099     moreover
  4100     { fix b assume "b\<in>{ball x (d x (e / 2)) |x. x \<in> s}" hence "open b" by auto  }
  4101     ultimately obtain ea where "ea>0" and ea:"\<forall>x\<in>s. \<exists>b\<in>{ball x (d x (e / 2)) |x. x \<in> s}. ball x ea \<subseteq> b" using heine_borel_lemma[OF assms(2), of "{ball x (d x (e / 2)) | x. x\<in>s }"] by auto
  4102 
  4103     { fix x y assume "x\<in>s" "y\<in>s" and as:"dist y x < ea"
  4104       obtain z where "z\<in>s" and z:"ball x ea \<subseteq> ball z (d z (e / 2))" using ea[THEN bspec[where x=x]] and `x\<in>s` by auto
  4105       hence "x\<in>ball z (d z (e / 2))" using `ea>0` unfolding subset_eq by auto
  4106       hence "dist (f z) (f x) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `x\<in>s` and `z\<in>s`
  4107         by (auto  simp add: dist_commute)
  4108       moreover have "y\<in>ball z (d z (e / 2))" using as and `ea>0` and z[unfolded subset_eq]
  4109         by (auto simp add: dist_commute)
  4110       hence "dist (f z) (f y) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `y\<in>s` and `z\<in>s`
  4111         by (auto  simp add: dist_commute)
  4112       ultimately have "dist (f y) (f x) < e" using dist_triangle_half_r[of "f z" "f x" e "f y"]
  4113         by (auto simp add: dist_commute)  }
  4114     then have "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e" using `ea>0` by auto  }
  4115   thus ?thesis unfolding uniformly_continuous_on_def by auto
  4116 qed
  4117 
  4118 text{* Continuity of inverse function on compact domain. *}
  4119 
  4120 lemma continuous_on_inverse:
  4121   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  4122     (* TODO: can this be generalized more? *)
  4123   assumes "continuous_on s f"  "compact s"  "\<forall>x \<in> s. g (f x) = x"
  4124   shows "continuous_on (f ` s) g"
  4125 proof-
  4126   have *:"g ` f ` s = s" using assms(3) by (auto simp add: image_iff)
  4127   { fix t assume t:"closedin (subtopology euclidean (g ` f ` s)) t"
  4128     then obtain T where T: "closed T" "t = s \<inter> T" unfolding closedin_closed unfolding * by auto
  4129     have "continuous_on (s \<inter> T) f" using continuous_on_subset[OF assms(1), of "s \<inter> t"]
  4130       unfolding T(2) and Int_left_absorb by auto
  4131     moreover have "compact (s \<inter> T)"
  4132       using assms(2) unfolding compact_eq_bounded_closed
  4133       using bounded_subset[of s "s \<inter> T"] and T(1) by auto
  4134     ultimately have "closed (f ` t)" using T(1) unfolding T(2)
  4135       using compact_continuous_image [of "s \<inter> T" f] unfolding compact_eq_bounded_closed by auto
  4136     moreover have "{x \<in> f ` s. g x \<in> t} = f ` s \<inter> f ` t" using assms(3) unfolding T(2) by auto
  4137     ultimately have "closedin (subtopology euclidean (f ` s)) {x \<in> f ` s. g x \<in> t}"
  4138       unfolding closedin_closed by auto  }
  4139   thus ?thesis unfolding continuous_on_closed by auto
  4140 qed
  4141 
  4142 text {* A uniformly convergent limit of continuous functions is continuous. *}
  4143 
  4144 lemma continuous_uniform_limit:
  4145   fixes f :: "'a \<Rightarrow> 'b::metric_space \<Rightarrow> 'c::metric_space"
  4146   assumes "\<not> trivial_limit F"
  4147   assumes "eventually (\<lambda>n. continuous_on s (f n)) F"
  4148   assumes "\<forall>e>0. eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e) F"
  4149   shows "continuous_on s g"
  4150 proof-
  4151   { fix x and e::real assume "x\<in>s" "e>0"
  4152     have "eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e / 3) F"
  4153       using `e>0` assms(3)[THEN spec[where x="e/3"]] by auto
  4154     from eventually_happens [OF eventually_conj [OF this assms(2)]]
  4155     obtain n where n:"\<forall>x\<in>s. dist (f n x) (g x) < e / 3"  "continuous_on s (f n)"
  4156       using assms(1) by blast
  4157     have "e / 3 > 0" using `e>0` by auto
  4158     then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f n x') (f n x) < e / 3"
  4159       using n(2)[unfolded continuous_on_iff, THEN bspec[where x=x], OF `x\<in>s`, THEN spec[where x="e/3"]] by blast
  4160     { fix y assume "y \<in> s" and "dist y x < d"
  4161       hence "dist (f n y) (f n x) < e / 3"
  4162         by (rule d [rule_format])
  4163       hence "dist (f n y) (g x) < 2 * e / 3"
  4164         using dist_triangle [of "f n y" "g x" "f n x"]
  4165         using n(1)[THEN bspec[where x=x], OF `x\<in>s`]
  4166         by auto
  4167       hence "dist (g y) (g x) < e"
  4168         using n(1)[THEN bspec[where x=y], OF `y\<in>s`]
  4169         using dist_triangle3 [of "g y" "g x" "f n y"]
  4170         by auto }
  4171     hence "\<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  4172       using `d>0` by auto }
  4173   thus ?thesis unfolding continuous_on_iff by auto
  4174 qed
  4175 
  4176 
  4177 subsection {* Topological stuff lifted from and dropped to R *}
  4178 
  4179 lemma open_real:
  4180   fixes s :: "real set" shows
  4181  "open s \<longleftrightarrow>
  4182         (\<forall>x \<in> s. \<exists>e>0. \<forall>x'. abs(x' - x) < e --> x' \<in> s)" (is "?lhs = ?rhs")
  4183   unfolding open_dist dist_norm by simp
  4184 
  4185 lemma islimpt_approachable_real:
  4186   fixes s :: "real set"
  4187   shows "x islimpt s \<longleftrightarrow> (\<forall>e>0.  \<exists>x'\<in> s. x' \<noteq> x \<and> abs(x' - x) < e)"
  4188   unfolding islimpt_approachable dist_norm by simp
  4189 
  4190 lemma closed_real:
  4191   fixes s :: "real set"
  4192   shows "closed s \<longleftrightarrow>
  4193         (\<forall>x. (\<forall>e>0.  \<exists>x' \<in> s. x' \<noteq> x \<and> abs(x' - x) < e)
  4194             --> x \<in> s)"
  4195   unfolding closed_limpt islimpt_approachable dist_norm by simp
  4196 
  4197 lemma continuous_at_real_range:
  4198   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4199   shows "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  4200         \<forall>x'. norm(x' - x) < d --> abs(f x' - f x) < e)"
  4201   unfolding continuous_at unfolding Lim_at
  4202   unfolding dist_nz[THEN sym] unfolding dist_norm apply auto
  4203   apply(erule_tac x=e in allE) apply auto apply (rule_tac x=d in exI) apply auto apply (erule_tac x=x' in allE) apply auto
  4204   apply(erule_tac x=e in allE) by auto
  4205 
  4206 lemma continuous_on_real_range:
  4207   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4208   shows "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. \<forall>e>0. \<exists>d>0. (\<forall>x' \<in> s. norm(x' - x) < d --> abs(f x' - f x) < e))"
  4209   unfolding continuous_on_iff dist_norm by simp
  4210 
  4211 lemma continuous_at_norm: "continuous (at x) norm"
  4212   unfolding continuous_at by (intro tendsto_intros)
  4213 
  4214 lemma continuous_on_norm: "continuous_on s norm"
  4215 unfolding continuous_on by (intro ballI tendsto_intros)
  4216 
  4217 lemma continuous_at_infnorm: "continuous (at x) infnorm"
  4218   unfolding continuous_at Lim_at o_def unfolding dist_norm
  4219   apply auto apply (rule_tac x=e in exI) apply auto
  4220   using order_trans[OF real_abs_sub_infnorm infnorm_le_norm, of _ x] by (metis xt1(7))
  4221 
  4222 text {* Hence some handy theorems on distance, diameter etc. of/from a set. *}
  4223 
  4224 lemma compact_attains_sup:
  4225   fixes s :: "real set"
  4226   assumes "compact s"  "s \<noteq> {}"
  4227   shows "\<exists>x \<in> s. \<forall>y \<in> s. y \<le> x"
  4228 proof-
  4229   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4230   { fix e::real assume as: "\<forall>x\<in>s. x \<le> Sup s" "Sup s \<notin> s"  "0 < e" "\<forall>x'\<in>s. x' = Sup s \<or> \<not> Sup s - x' < e"
  4231     have "isLub UNIV s (Sup s)" using Sup[OF assms(2)] unfolding setle_def using as(1) by auto
  4232     moreover have "isUb UNIV s (Sup s - e)" unfolding isUb_def unfolding setle_def using as(4,2) by auto
  4233     ultimately have False using isLub_le_isUb[of UNIV s "Sup s" "Sup s - e"] using `e>0` by auto  }
  4234   thus ?thesis using bounded_has_Sup(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Sup s"]]
  4235     apply(rule_tac x="Sup s" in bexI) by auto
  4236 qed
  4237 
  4238 lemma Inf:
  4239   fixes S :: "real set"
  4240   shows "S \<noteq> {} ==> (\<exists>b. b <=* S) ==> isGlb UNIV S (Inf S)"
  4241 by (auto simp add: isLb_def setle_def setge_def isGlb_def greatestP_def) 
  4242 
  4243 lemma compact_attains_inf:
  4244   fixes s :: "real set"
  4245   assumes "compact s" "s \<noteq> {}"  shows "\<exists>x \<in> s. \<forall>y \<in> s. x \<le> y"
  4246 proof-
  4247   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4248   { fix e::real assume as: "\<forall>x\<in>s. x \<ge> Inf s"  "Inf s \<notin> s"  "0 < e"
  4249       "\<forall>x'\<in>s. x' = Inf s \<or> \<not> abs (x' - Inf s) < e"
  4250     have "isGlb UNIV s (Inf s)" using Inf[OF assms(2)] unfolding setge_def using as(1) by auto
  4251     moreover
  4252     { fix x assume "x \<in> s"
  4253       hence *:"abs (x - Inf s) = x - Inf s" using as(1)[THEN bspec[where x=x]] by auto
  4254       have "Inf s + e \<le> x" using as(4)[THEN bspec[where x=x]] using as(2) `x\<in>s` unfolding * by auto }
  4255     hence "isLb UNIV s (Inf s + e)" unfolding isLb_def and setge_def by auto
  4256     ultimately have False using isGlb_le_isLb[of UNIV s "Inf s" "Inf s + e"] using `e>0` by auto  }
  4257   thus ?thesis using bounded_has_Inf(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Inf s"]]
  4258     apply(rule_tac x="Inf s" in bexI) by auto
  4259 qed
  4260 
  4261 lemma continuous_attains_sup:
  4262   fixes f :: "'a::metric_space \<Rightarrow> real"
  4263   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4264         ==> (\<exists>x \<in> s. \<forall>y \<in> s.  f y \<le> f x)"
  4265   using compact_attains_sup[of "f ` s"]
  4266   using compact_continuous_image[of s f] by auto
  4267 
  4268 lemma continuous_attains_inf:
  4269   fixes f :: "'a::metric_space \<Rightarrow> real"
  4270   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4271         \<Longrightarrow> (\<exists>x \<in> s. \<forall>y \<in> s. f x \<le> f y)"
  4272   using compact_attains_inf[of "f ` s"]
  4273   using compact_continuous_image[of s f] by auto
  4274 
  4275 lemma distance_attains_sup:
  4276   assumes "compact s" "s \<noteq> {}"
  4277   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a y \<le> dist a x"
  4278 proof (rule continuous_attains_sup [OF assms])
  4279   { fix x assume "x\<in>s"
  4280     have "(dist a ---> dist a x) (at x within s)"
  4281       by (intro tendsto_dist tendsto_const Lim_at_within LIM_ident)
  4282   }
  4283   thus "continuous_on s (dist a)"
  4284     unfolding continuous_on ..
  4285 qed
  4286 
  4287 text {* For \emph{minimal} distance, we only need closure, not compactness. *}
  4288 
  4289 lemma distance_attains_inf:
  4290   fixes a :: "'a::heine_borel"
  4291   assumes "closed s"  "s \<noteq> {}"
  4292   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a x \<le> dist a y"
  4293 proof-
  4294   from assms(2) obtain b where "b\<in>s" by auto
  4295   let ?B = "cball a (dist b a) \<inter> s"
  4296   have "b \<in> ?B" using `b\<in>s` by (simp add: dist_commute)
  4297   hence "?B \<noteq> {}" by auto
  4298   moreover
  4299   { fix x assume "x\<in>?B"
  4300     fix e::real assume "e>0"
  4301     { fix x' assume "x'\<in>?B" and as:"dist x' x < e"
  4302       from as have "\<bar>dist a x' - dist a x\<bar> < e"
  4303         unfolding abs_less_iff minus_diff_eq
  4304         using dist_triangle2 [of a x' x]
  4305         using dist_triangle [of a x x']
  4306         by arith
  4307     }
  4308     hence "\<exists>d>0. \<forall>x'\<in>?B. dist x' x < d \<longrightarrow> \<bar>dist a x' - dist a x\<bar> < e"
  4309       using `e>0` by auto
  4310   }
  4311   hence "continuous_on (cball a (dist b a) \<inter> s) (dist a)"
  4312     unfolding continuous_on Lim_within dist_norm real_norm_def
  4313     by fast
  4314   moreover have "compact ?B"
  4315     using compact_cball[of a "dist b a"]
  4316     unfolding compact_eq_bounded_closed
  4317     using bounded_Int and closed_Int and assms(1) by auto
  4318   ultimately obtain x where "x\<in>cball a (dist b a) \<inter> s" "\<forall>y\<in>cball a (dist b a) \<inter> s. dist a x \<le> dist a y"
  4319     using continuous_attains_inf[of ?B "dist a"] by fastsimp
  4320   thus ?thesis by fastsimp
  4321 qed
  4322 
  4323 
  4324 subsection {* Pasted sets *}
  4325 
  4326 lemma bounded_Times:
  4327   assumes "bounded s" "bounded t" shows "bounded (s \<times> t)"
  4328 proof-
  4329   obtain x y a b where "\<forall>z\<in>s. dist x z \<le> a" "\<forall>z\<in>t. dist y z \<le> b"
  4330     using assms [unfolded bounded_def] by auto
  4331   then have "\<forall>z\<in>s \<times> t. dist (x, y) z \<le> sqrt (a\<twosuperior> + b\<twosuperior>)"
  4332     by (auto simp add: dist_Pair_Pair real_sqrt_le_mono add_mono power_mono)
  4333   thus ?thesis unfolding bounded_any_center [where a="(x, y)"] by auto
  4334 qed
  4335 
  4336 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
  4337 by (induct x) simp
  4338 
  4339 lemma compact_Times: "compact s \<Longrightarrow> compact t \<Longrightarrow> compact (s \<times> t)"
  4340 unfolding compact_def
  4341 apply clarify
  4342 apply (drule_tac x="fst \<circ> f" in spec)
  4343 apply (drule mp, simp add: mem_Times_iff)
  4344 apply (clarify, rename_tac l1 r1)
  4345 apply (drule_tac x="snd \<circ> f \<circ> r1" in spec)
  4346 apply (drule mp, simp add: mem_Times_iff)
  4347 apply (clarify, rename_tac l2 r2)
  4348 apply (rule_tac x="(l1, l2)" in rev_bexI, simp)
  4349 apply (rule_tac x="r1 \<circ> r2" in exI)
  4350 apply (rule conjI, simp add: subseq_def)
  4351 apply (drule_tac r=r2 in lim_subseq [COMP swap_prems_rl], assumption)
  4352 apply (drule (1) tendsto_Pair) back
  4353 apply (simp add: o_def)
  4354 done
  4355 
  4356 text{* Hence some useful properties follow quite easily. *}
  4357 
  4358 lemma compact_scaling:
  4359   fixes s :: "'a::real_normed_vector set"
  4360   assumes "compact s"  shows "compact ((\<lambda>x. c *\<^sub>R x) ` s)"
  4361 proof-
  4362   let ?f = "\<lambda>x. scaleR c x"
  4363   have *:"bounded_linear ?f" by (rule bounded_linear_scaleR_right)
  4364   show ?thesis using compact_continuous_image[of s ?f] continuous_at_imp_continuous_on[of s ?f]
  4365     using linear_continuous_at[OF *] assms by auto
  4366 qed
  4367 
  4368 lemma compact_negations:
  4369   fixes s :: "'a::real_normed_vector set"
  4370   assumes "compact s"  shows "compact ((\<lambda>x. -x) ` s)"
  4371   using compact_scaling [OF assms, of "- 1"] by auto
  4372 
  4373 lemma compact_sums:
  4374   fixes s t :: "'a::real_normed_vector set"
  4375   assumes "compact s"  "compact t"  shows "compact {x + y | x y. x \<in> s \<and> y \<in> t}"
  4376 proof-
  4377   have *:"{x + y | x y. x \<in> s \<and> y \<in> t} = (\<lambda>z. fst z + snd z) ` (s \<times> t)"
  4378     apply auto unfolding image_iff apply(rule_tac x="(xa, y)" in bexI) by auto
  4379   have "continuous_on (s \<times> t) (\<lambda>z. fst z + snd z)"
  4380     unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  4381   thus ?thesis unfolding * using compact_continuous_image compact_Times [OF assms] by auto
  4382 qed
  4383 
  4384 lemma compact_differences:
  4385   fixes s t :: "'a::real_normed_vector set"
  4386   assumes "compact s" "compact t"  shows "compact {x - y | x y. x \<in> s \<and> y \<in> t}"
  4387 proof-
  4388   have "{x - y | x y. x\<in>s \<and> y \<in> t} =  {x + y | x y. x \<in> s \<and> y \<in> (uminus ` t)}"
  4389     apply auto apply(rule_tac x= xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4390   thus ?thesis using compact_sums[OF assms(1) compact_negations[OF assms(2)]] by auto
  4391 qed
  4392 
  4393 lemma compact_translation:
  4394   fixes s :: "'a::real_normed_vector set"
  4395   assumes "compact s"  shows "compact ((\<lambda>x. a + x) ` s)"
  4396 proof-
  4397   have "{x + y |x y. x \<in> s \<and> y \<in> {a}} = (\<lambda>x. a + x) ` s" by auto
  4398   thus ?thesis using compact_sums[OF assms compact_sing[of a]] by auto
  4399 qed
  4400 
  4401 lemma compact_affinity:
  4402   fixes s :: "'a::real_normed_vector set"
  4403   assumes "compact s"  shows "compact ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  4404 proof-
  4405   have "op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  4406   thus ?thesis using compact_translation[OF compact_scaling[OF assms], of a c] by auto
  4407 qed
  4408 
  4409 text {* Hence we get the following. *}
  4410 
  4411 lemma compact_sup_maxdistance:
  4412   fixes s :: "'a::real_normed_vector set"
  4413   assumes "compact s"  "s \<noteq> {}"
  4414   shows "\<exists>x\<in>s. \<exists>y\<in>s. \<forall>u\<in>s. \<forall>v\<in>s. norm(u - v) \<le> norm(x - y)"
  4415 proof-
  4416   have "{x - y | x y . x\<in>s \<and> y\<in>s} \<noteq> {}" using `s \<noteq> {}` by auto
  4417   then obtain x where x:"x\<in>{x - y |x y. x \<in> s \<and> y \<in> s}"  "\<forall>y\<in>{x - y |x y. x \<in> s \<and> y \<in> s}. norm y \<le> norm x"
  4418     using compact_differences[OF assms(1) assms(1)]
  4419     using distance_attains_sup[where 'a="'a", unfolded dist_norm, of "{x - y | x y . x\<in>s \<and> y\<in>s}" 0] by auto
  4420   from x(1) obtain a b where "a\<in>s" "b\<in>s" "x = a - b" by auto
  4421   thus ?thesis using x(2)[unfolded `x = a - b`] by blast
  4422 qed
  4423 
  4424 text {* We can state this in terms of diameter of a set. *}
  4425 
  4426 definition "diameter s = (if s = {} then 0::real else Sup {norm(x - y) | x y. x \<in> s \<and> y \<in> s})"
  4427   (* TODO: generalize to class metric_space *)
  4428 
  4429 lemma diameter_bounded:
  4430   assumes "bounded s"
  4431   shows "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4432         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)"
  4433 proof-
  4434   let ?D = "{norm (x - y) |x y. x \<in> s \<and> y \<in> s}"
  4435   obtain a where a:"\<forall>x\<in>s. norm x \<le> a" using assms[unfolded bounded_iff] by auto
  4436   { fix x y assume "x \<in> s" "y \<in> s"
  4437     hence "norm (x - y) \<le> 2 * a" using norm_triangle_ineq[of x "-y", unfolded norm_minus_cancel] a[THEN bspec[where x=x]] a[THEN bspec[where x=y]] by (auto simp add: field_simps)  }
  4438   note * = this
  4439   { fix x y assume "x\<in>s" "y\<in>s"  hence "s \<noteq> {}" by auto
  4440     have "norm(x - y) \<le> diameter s" unfolding diameter_def using `s\<noteq>{}` *[OF `x\<in>s` `y\<in>s`] `x\<in>s` `y\<in>s`
  4441       by simp (blast intro!: Sup_upper *) }
  4442   moreover
  4443   { fix d::real assume "d>0" "d < diameter s"
  4444     hence "s\<noteq>{}" unfolding diameter_def by auto
  4445     have "\<exists>d' \<in> ?D. d' > d"
  4446     proof(rule ccontr)
  4447       assume "\<not> (\<exists>d'\<in>{norm (x - y) |x y. x \<in> s \<and> y \<in> s}. d < d')"
  4448       hence "\<forall>d'\<in>?D. d' \<le> d" by auto (metis not_leE) 
  4449       thus False using `d < diameter s` `s\<noteq>{}` 
  4450         apply (auto simp add: diameter_def) 
  4451         apply (drule Sup_real_iff [THEN [2] rev_iffD2])
  4452         apply (auto, force) 
  4453         done
  4454     qed
  4455     hence "\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d" by auto  }
  4456   ultimately show "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4457         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)" by auto
  4458 qed
  4459 
  4460 lemma diameter_bounded_bound:
  4461  "bounded s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s ==> norm(x - y) \<le> diameter s"
  4462   using diameter_bounded by blast
  4463 
  4464 lemma diameter_compact_attained:
  4465   fixes s :: "'a::real_normed_vector set"
  4466   assumes "compact s"  "s \<noteq> {}"
  4467   shows "\<exists>x\<in>s. \<exists>y\<in>s. (norm(x - y) = diameter s)"
  4468 proof-
  4469   have b:"bounded s" using assms(1) by (rule compact_imp_bounded)
  4470   then obtain x y where xys:"x\<in>s" "y\<in>s" and xy:"\<forall>u\<in>s. \<forall>v\<in>s. norm (u - v) \<le> norm (x - y)" using compact_sup_maxdistance[OF assms] by auto
  4471   hence "diameter s \<le> norm (x - y)"
  4472     unfolding diameter_def by clarsimp (rule Sup_least, fast+)
  4473   thus ?thesis
  4474     by (metis b diameter_bounded_bound order_antisym xys)
  4475 qed
  4476 
  4477 text {* Related results with closure as the conclusion. *}
  4478 
  4479 lemma closed_scaling:
  4480   fixes s :: "'a::real_normed_vector set"
  4481   assumes "closed s" shows "closed ((\<lambda>x. c *\<^sub>R x) ` s)"
  4482 proof(cases "s={}")
  4483   case True thus ?thesis by auto
  4484 next
  4485   case False
  4486   show ?thesis
  4487   proof(cases "c=0")
  4488     have *:"(\<lambda>x. 0) ` s = {0}" using `s\<noteq>{}` by auto
  4489     case True thus ?thesis apply auto unfolding * by auto
  4490   next
  4491     case False
  4492     { fix x l assume as:"\<forall>n::nat. x n \<in> scaleR c ` s"  "(x ---> l) sequentially"
  4493       { fix n::nat have "scaleR (1 / c) (x n) \<in> s"
  4494           using as(1)[THEN spec[where x=n]]
  4495           using `c\<noteq>0` by auto
  4496       }
  4497       moreover
  4498       { fix e::real assume "e>0"
  4499         hence "0 < e *\<bar>c\<bar>"  using `c\<noteq>0` mult_pos_pos[of e "abs c"] by auto
  4500         then obtain N where "\<forall>n\<ge>N. dist (x n) l < e * \<bar>c\<bar>"
  4501           using as(2)[unfolded Lim_sequentially, THEN spec[where x="e * abs c"]] by auto
  4502         hence "\<exists>N. \<forall>n\<ge>N. dist (scaleR (1 / c) (x n)) (scaleR (1 / c) l) < e"
  4503           unfolding dist_norm unfolding scaleR_right_diff_distrib[THEN sym]
  4504           using mult_imp_div_pos_less[of "abs c" _ e] `c\<noteq>0` by auto  }
  4505       hence "((\<lambda>n. scaleR (1 / c) (x n)) ---> scaleR (1 / c) l) sequentially" unfolding Lim_sequentially by auto
  4506       ultimately have "l \<in> scaleR c ` s"
  4507         using assms[unfolded closed_sequential_limits, THEN spec[where x="\<lambda>n. scaleR (1/c) (x n)"], THEN spec[where x="scaleR (1/c) l"]]
  4508         unfolding image_iff using `c\<noteq>0` apply(rule_tac x="scaleR (1 / c) l" in bexI) by auto  }
  4509     thus ?thesis unfolding closed_sequential_limits by fast
  4510   qed
  4511 qed
  4512 
  4513 lemma closed_negations:
  4514   fixes s :: "'a::real_normed_vector set"
  4515   assumes "closed s"  shows "closed ((\<lambda>x. -x) ` s)"
  4516   using closed_scaling[OF assms, of "- 1"] by simp
  4517 
  4518 lemma compact_closed_sums:
  4519   fixes s :: "'a::real_normed_vector set"
  4520   assumes "compact s"  "closed t"  shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4521 proof-
  4522   let ?S = "{x + y |x y. x \<in> s \<and> y \<in> t}"
  4523   { fix x l assume as:"\<forall>n. x n \<in> ?S"  "(x ---> l) sequentially"
  4524     from as(1) obtain f where f:"\<forall>n. x n = fst (f n) + snd (f n)"  "\<forall>n. fst (f n) \<in> s"  "\<forall>n. snd (f n) \<in> t"
  4525       using choice[of "\<lambda>n y. x n = (fst y) + (snd y) \<and> fst y \<in> s \<and> snd y \<in> t"] by auto
  4526     obtain l' r where "l'\<in>s" and r:"subseq r" and lr:"(((\<lambda>n. fst (f n)) \<circ> r) ---> l') sequentially"
  4527       using assms(1)[unfolded compact_def, THEN spec[where x="\<lambda> n. fst (f n)"]] using f(2) by auto
  4528     have "((\<lambda>n. snd (f (r n))) ---> l - l') sequentially"
  4529       using tendsto_diff[OF lim_subseq[OF r as(2)] lr] and f(1) unfolding o_def by auto
  4530     hence "l - l' \<in> t"
  4531       using assms(2)[unfolded closed_sequential_limits, THEN spec[where x="\<lambda> n. snd (f (r n))"], THEN spec[where x="l - l'"]]
  4532       using f(3) by auto
  4533     hence "l \<in> ?S" using `l' \<in> s` apply auto apply(rule_tac x=l' in exI) apply(rule_tac x="l - l'" in exI) by auto
  4534   }
  4535   thus ?thesis unfolding closed_sequential_limits by fast
  4536 qed
  4537 
  4538 lemma closed_compact_sums:
  4539   fixes s t :: "'a::real_normed_vector set"
  4540   assumes "closed s"  "compact t"
  4541   shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4542 proof-
  4543   have "{x + y |x y. x \<in> t \<and> y \<in> s} = {x + y |x y. x \<in> s \<and> y \<in> t}" apply auto
  4544     apply(rule_tac x=y in exI) apply auto apply(rule_tac x=y in exI) by auto
  4545   thus ?thesis using compact_closed_sums[OF assms(2,1)] by simp
  4546 qed
  4547 
  4548 lemma compact_closed_differences:
  4549   fixes s t :: "'a::real_normed_vector set"
  4550   assumes "compact s"  "closed t"
  4551   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4552 proof-
  4553   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} =  {x - y |x y. x \<in> s \<and> y \<in> t}"
  4554     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4555   thus ?thesis using compact_closed_sums[OF assms(1) closed_negations[OF assms(2)]] by auto
  4556 qed
  4557 
  4558 lemma closed_compact_differences:
  4559   fixes s t :: "'a::real_normed_vector set"
  4560   assumes "closed s" "compact t"
  4561   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4562 proof-
  4563   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} = {x - y |x y. x \<in> s \<and> y \<in> t}"
  4564     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4565  thus ?thesis using closed_compact_sums[OF assms(1) compact_negations[OF assms(2)]] by simp
  4566 qed
  4567 
  4568 lemma closed_translation:
  4569   fixes a :: "'a::real_normed_vector"
  4570   assumes "closed s"  shows "closed ((\<lambda>x. a + x) ` s)"
  4571 proof-
  4572   have "{a + y |y. y \<in> s} = (op + a ` s)" by auto
  4573   thus ?thesis using compact_closed_sums[OF compact_sing[of a] assms] by auto
  4574 qed
  4575 
  4576 lemma translation_Compl:
  4577   fixes a :: "'a::ab_group_add"
  4578   shows "(\<lambda>x. a + x) ` (- t) = - ((\<lambda>x. a + x) ` t)"
  4579   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in bexI) by auto
  4580 
  4581 lemma translation_UNIV:
  4582   fixes a :: "'a::ab_group_add" shows "range (\<lambda>x. a + x) = UNIV"
  4583   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in exI) by auto
  4584 
  4585 lemma translation_diff:
  4586   fixes a :: "'a::ab_group_add"
  4587   shows "(\<lambda>x. a + x) ` (s - t) = ((\<lambda>x. a + x) ` s) - ((\<lambda>x. a + x) ` t)"
  4588   by auto
  4589 
  4590 lemma closure_translation:
  4591   fixes a :: "'a::real_normed_vector"
  4592   shows "closure ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (closure s)"
  4593 proof-
  4594   have *:"op + a ` (- s) = - op + a ` s"
  4595     apply auto unfolding image_iff apply(rule_tac x="x - a" in bexI) by auto
  4596   show ?thesis unfolding closure_interior translation_Compl
  4597     using interior_translation[of a "- s"] unfolding * by auto
  4598 qed
  4599 
  4600 lemma frontier_translation:
  4601   fixes a :: "'a::real_normed_vector"
  4602   shows "frontier((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (frontier s)"
  4603   unfolding frontier_def translation_diff interior_translation closure_translation by auto
  4604 
  4605 
  4606 subsection {* Separation between points and sets *}
  4607 
  4608 lemma separate_point_closed:
  4609   fixes s :: "'a::heine_borel set"
  4610   shows "closed s \<Longrightarrow> a \<notin> s  ==> (\<exists>d>0. \<forall>x\<in>s. d \<le> dist a x)"
  4611 proof(cases "s = {}")
  4612   case True
  4613   thus ?thesis by(auto intro!: exI[where x=1])
  4614 next
  4615   case False
  4616   assume "closed s" "a \<notin> s"
  4617   then obtain x where "x\<in>s" "\<forall>y\<in>s. dist a x \<le> dist a y" using `s \<noteq> {}` distance_attains_inf [of s a] by blast
  4618   with `x\<in>s` show ?thesis using dist_pos_lt[of a x] and`a \<notin> s` by blast
  4619 qed
  4620 
  4621 lemma separate_compact_closed:
  4622   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4623     (* TODO: does this generalize to heine_borel? *)
  4624   assumes "compact s" and "closed t" and "s \<inter> t = {}"
  4625   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4626 proof-
  4627   have "0 \<notin> {x - y |x y. x \<in> s \<and> y \<in> t}" using assms(3) by auto
  4628   then obtain d where "d>0" and d:"\<forall>x\<in>{x - y |x y. x \<in> s \<and> y \<in> t}. d \<le> dist 0 x"
  4629     using separate_point_closed[OF compact_closed_differences[OF assms(1,2)], of 0] by auto
  4630   { fix x y assume "x\<in>s" "y\<in>t"
  4631     hence "x - y \<in> {x - y |x y. x \<in> s \<and> y \<in> t}" by auto
  4632     hence "d \<le> dist (x - y) 0" using d[THEN bspec[where x="x - y"]] using dist_commute
  4633       by (auto  simp add: dist_commute)
  4634     hence "d \<le> dist x y" unfolding dist_norm by auto  }
  4635   thus ?thesis using `d>0` by auto
  4636 qed
  4637 
  4638 lemma separate_closed_compact:
  4639   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4640   assumes "closed s" and "compact t" and "s \<inter> t = {}"
  4641   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4642 proof-
  4643   have *:"t \<inter> s = {}" using assms(3) by auto
  4644   show ?thesis using separate_compact_closed[OF assms(2,1) *]
  4645     apply auto apply(rule_tac x=d in exI) apply auto apply (erule_tac x=y in ballE)
  4646     by (auto simp add: dist_commute)
  4647 qed
  4648 
  4649 
  4650 subsection {* Intervals *}
  4651   
  4652 lemma interval: fixes a :: "'a::ordered_euclidean_space" shows
  4653   "{a <..< b} = {x::'a. \<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i}" and
  4654   "{a .. b} = {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i}"
  4655   by(auto simp add:set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4656 
  4657 lemma mem_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4658   "x \<in> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i)"
  4659   "x \<in> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i)"
  4660   using interval[of a b] by(auto simp add: set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4661 
  4662 lemma interval_eq_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4663  "({a <..< b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i \<le> a$$i))" (is ?th1) and
  4664  "({a  ..  b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i < a$$i))" (is ?th2)
  4665 proof-
  4666   { fix i x assume i:"i<DIM('a)" and as:"b$$i \<le> a$$i" and x:"x\<in>{a <..< b}"
  4667     hence "a $$ i < x $$ i \<and> x $$ i < b $$ i" unfolding mem_interval by auto
  4668     hence "a$$i < b$$i" by auto
  4669     hence False using as by auto  }
  4670   moreover
  4671   { assume as:"\<forall>i<DIM('a). \<not> (b$$i \<le> a$$i)"
  4672     let ?x = "(1/2) *\<^sub>R (a + b)"
  4673     { fix i assume i:"i<DIM('a)" 
  4674       have "a$$i < b$$i" using as[THEN spec[where x=i]] using i by auto
  4675       hence "a$$i < ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i < b$$i"
  4676         unfolding euclidean_simps by auto }
  4677     hence "{a <..< b} \<noteq> {}" using mem_interval(1)[of "?x" a b] by auto  }
  4678   ultimately show ?th1 by blast
  4679 
  4680   { fix i x assume i:"i<DIM('a)" and as:"b$$i < a$$i" and x:"x\<in>{a .. b}"
  4681     hence "a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i" unfolding mem_interval by auto
  4682     hence "a$$i \<le> b$$i" by auto
  4683     hence False using as by auto  }
  4684   moreover
  4685   { assume as:"\<forall>i<DIM('a). \<not> (b$$i < a$$i)"
  4686     let ?x = "(1/2) *\<^sub>R (a + b)"
  4687     { fix i assume i:"i<DIM('a)"
  4688       have "a$$i \<le> b$$i" using as[THEN spec[where x=i]] by auto
  4689       hence "a$$i \<le> ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i \<le> b$$i"
  4690         unfolding euclidean_simps by auto }
  4691     hence "{a .. b} \<noteq> {}" using mem_interval(2)[of "?x" a b] by auto  }
  4692   ultimately show ?th2 by blast
  4693 qed
  4694 
  4695 lemma interval_ne_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4696   "{a  ..  b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> b$$i)" and
  4697   "{a <..< b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < b$$i)"
  4698   unfolding interval_eq_empty[of a b] by fastsimp+
  4699 
  4700 lemma interval_sing: fixes a :: "'a::ordered_euclidean_space" shows
  4701  "{a .. a} = {a}" "{a<..<a} = {}"
  4702   apply(auto simp add: set_eq_iff euclidean_eq[where 'a='a] eucl_less[where 'a='a] eucl_le[where 'a='a])
  4703   apply (simp add: order_eq_iff) apply(rule_tac x=0 in exI) by (auto simp add: not_less less_imp_le)
  4704 
  4705 lemma subset_interval_imp: fixes a :: "'a::ordered_euclidean_space" shows
  4706  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a .. b}" and
  4707  "(\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a<..<b}" and
  4708  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a .. b}" and
  4709  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a<..<b}"
  4710   unfolding subset_eq[unfolded Ball_def] unfolding mem_interval 
  4711   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
  4712 
  4713 lemma interval_open_subset_closed:  fixes a :: "'a::ordered_euclidean_space" shows
  4714  "{a<..<b} \<subseteq> {a .. b}"
  4715 proof(simp add: subset_eq, rule)
  4716   fix x
  4717   assume x:"x \<in>{a<..<b}"
  4718   { fix i assume "i<DIM('a)"
  4719     hence "a $$ i \<le> x $$ i"
  4720       using x order_less_imp_le[of "a$$i" "x$$i"] 
  4721       by(simp add: set_eq_iff eucl_less[where 'a='a] eucl_le[where 'a='a] euclidean_eq)
  4722   }
  4723   moreover
  4724   { fix i assume "i<DIM('a)"
  4725     hence "x $$ i \<le> b $$ i"
  4726       using x order_less_imp_le[of "x$$i" "b$$i"]
  4727       by(simp add: set_eq_iff eucl_less[where 'a='a] eucl_le[where 'a='a] euclidean_eq)
  4728   }
  4729   ultimately
  4730   show "a \<le> x \<and> x \<le> b"
  4731     by(simp add: set_eq_iff eucl_less[where 'a='a] eucl_le[where 'a='a] euclidean_eq)
  4732 qed
  4733 
  4734 lemma subset_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4735  "{c .. d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th1) and
  4736  "{c .. d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i)" (is ?th2) and
  4737  "{c<..<d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th3) and
  4738  "{c<..<d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th4)
  4739 proof-
  4740   show ?th1 unfolding subset_eq and Ball_def and mem_interval by (auto intro: order_trans)
  4741   show ?th2 unfolding subset_eq and Ball_def and mem_interval by (auto intro: le_less_trans less_le_trans order_trans less_imp_le)
  4742   { assume as: "{c<..<d} \<subseteq> {a .. b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4743     hence "{c<..<d} \<noteq> {}" unfolding interval_eq_empty by auto
  4744     fix i assume i:"i<DIM('a)"
  4745     (** TODO combine the following two parts as done in the HOL_light version. **)
  4746     { let ?x = "(\<chi>\<chi> j. (if j=i then ((min (a$$j) (d$$j))+c$$j)/2 else (c$$j+d$$j)/2))::'a"
  4747       assume as2: "a$$i > c$$i"
  4748       { fix j assume j:"j<DIM('a)"
  4749         hence "c $$ j < ?x $$ j \<and> ?x $$ j < d $$ j"
  4750           apply(cases "j=i") using as(2)[THEN spec[where x=j]] i
  4751           by (auto simp add: as2)  }
  4752       hence "?x\<in>{c<..<d}" using i unfolding mem_interval by auto
  4753       moreover
  4754       have "?x\<notin>{a .. b}"
  4755         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4756         using as(2)[THEN spec[where x=i]] and as2 i
  4757         by auto
  4758       ultimately have False using as by auto  }
  4759     hence "a$$i \<le> c$$i" by(rule ccontr)auto
  4760     moreover
  4761     { let ?x = "(\<chi>\<chi> j. (if j=i then ((max (b$$j) (c$$j))+d$$j)/2 else (c$$j+d$$j)/2))::'a"
  4762       assume as2: "b$$i < d$$i"
  4763       { fix j assume "j<DIM('a)"
  4764         hence "d $$ j > ?x $$ j \<and> ?x $$ j > c $$ j" 
  4765           apply(cases "j=i") using as(2)[THEN spec[where x=j]]
  4766           by (auto simp add: as2)  }
  4767       hence "?x\<in>{c<..<d}" unfolding mem_interval by auto
  4768       moreover
  4769       have "?x\<notin>{a .. b}"
  4770         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4771         using as(2)[THEN spec[where x=i]] and as2 using i
  4772         by auto
  4773       ultimately have False using as by auto  }
  4774     hence "b$$i \<ge> d$$i" by(rule ccontr)auto
  4775     ultimately
  4776     have "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" by auto
  4777   } note part1 = this
  4778   show ?th3 unfolding subset_eq and Ball_def and mem_interval 
  4779     apply(rule,rule,rule,rule) apply(rule part1) unfolding subset_eq and Ball_def and mem_interval
  4780     prefer 4 apply auto by(erule_tac x=i in allE,erule_tac x=i in allE,fastsimp)+ 
  4781   { assume as:"{c<..<d} \<subseteq> {a<..<b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4782     fix i assume i:"i<DIM('a)"
  4783     from as(1) have "{c<..<d} \<subseteq> {a..b}" using interval_open_subset_closed[of a b] by auto
  4784     hence "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" using part1 and as(2) using i by auto  } note * = this
  4785   show ?th4 unfolding subset_eq and Ball_def and mem_interval 
  4786     apply(rule,rule,rule,rule) apply(rule *) unfolding subset_eq and Ball_def and mem_interval prefer 4
  4787     apply auto by(erule_tac x=i in allE, simp)+ 
  4788 qed
  4789 
  4790 lemma disjoint_interval: fixes a::"'a::ordered_euclidean_space" shows
  4791   "{a .. b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i < c$$i \<or> b$$i < c$$i \<or> d$$i < a$$i))" (is ?th1) and
  4792   "{a .. b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th2) and
  4793   "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i < c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th3) and
  4794   "{a<..<b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th4)
  4795 proof-
  4796   let ?z = "(\<chi>\<chi> i. ((max (a$$i) (c$$i)) + (min (b$$i) (d$$i))) / 2)::'a"
  4797   note * = set_eq_iff Int_iff empty_iff mem_interval all_conj_distrib[THEN sym] eq_False
  4798   show ?th1 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4799     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4800   show ?th2 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4801     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4802   show ?th3 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4803     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4804   show ?th4 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4805     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4806 qed
  4807 
  4808 lemma inter_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4809  "{a .. b} \<inter> {c .. d} =  {(\<chi>\<chi> i. max (a$$i) (c$$i)) .. (\<chi>\<chi> i. min (b$$i) (d$$i))}"
  4810   unfolding set_eq_iff and Int_iff and mem_interval
  4811   by auto
  4812 
  4813 (* Moved interval_open_subset_closed a bit upwards *)
  4814 
  4815 lemma open_interval[intro]:
  4816   fixes a b :: "'a::ordered_euclidean_space" shows "open {a<..<b}"
  4817 proof-
  4818   have "open (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i})"
  4819     by (intro open_INT finite_lessThan ballI continuous_open_vimage allI
  4820       linear_continuous_at bounded_linear_euclidean_component
  4821       open_real_greaterThanLessThan)
  4822   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i}) = {a<..<b}"
  4823     by (auto simp add: eucl_less [where 'a='a])
  4824   finally show "open {a<..<b}" .
  4825 qed
  4826 
  4827 lemma closed_interval[intro]:
  4828   fixes a b :: "'a::ordered_euclidean_space" shows "closed {a .. b}"
  4829 proof-
  4830   have "closed (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i})"
  4831     by (intro closed_INT ballI continuous_closed_vimage allI
  4832       linear_continuous_at bounded_linear_euclidean_component
  4833       closed_real_atLeastAtMost)
  4834   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i}) = {a .. b}"
  4835     by (auto simp add: eucl_le [where 'a='a])
  4836   finally show "closed {a .. b}" .
  4837 qed
  4838 
  4839 lemma interior_closed_interval[intro]: fixes a :: "'a::ordered_euclidean_space" shows
  4840  "interior {a .. b} = {a<..<b}" (is "?L = ?R")
  4841 proof(rule subset_antisym)
  4842   show "?R \<subseteq> ?L" using interior_maximal[OF interval_open_subset_closed open_interval] by auto
  4843 next
  4844   { fix x assume "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> {a..b}"
  4845     then obtain s where s:"open s" "x \<in> s" "s \<subseteq> {a..b}" by auto
  4846     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> {a..b}" unfolding open_dist and subset_eq by auto
  4847     { fix i assume i:"i<DIM('a)"
  4848       have "dist (x - (e / 2) *\<^sub>R basis i) x < e"
  4849            "dist (x + (e / 2) *\<^sub>R basis i) x < e"
  4850         unfolding dist_norm apply auto
  4851         unfolding norm_minus_cancel using norm_basis and `e>0` by auto
  4852       hence "a $$ i \<le> (x - (e / 2) *\<^sub>R basis i) $$ i"
  4853                      "(x + (e / 2) *\<^sub>R basis i) $$ i \<le> b $$ i"
  4854         using e[THEN spec[where x="x - (e/2) *\<^sub>R basis i"]]
  4855         and   e[THEN spec[where x="x + (e/2) *\<^sub>R basis i"]]
  4856         unfolding mem_interval by (auto elim!: allE[where x=i])
  4857       hence "a $$ i < x $$ i" and "x $$ i < b $$ i" unfolding euclidean_simps
  4858         unfolding basis_component using `e>0` i by auto  }
  4859     hence "x \<in> {a<..<b}" unfolding mem_interval by auto  }
  4860   thus "?L \<subseteq> ?R" unfolding interior_def and subset_eq by auto
  4861 qed
  4862 
  4863 lemma bounded_closed_interval: fixes a :: "'a::ordered_euclidean_space" shows "bounded {a .. b}"
  4864 proof-
  4865   let ?b = "\<Sum>i<DIM('a). \<bar>a$$i\<bar> + \<bar>b$$i\<bar>"
  4866   { fix x::"'a" assume x:"\<forall>i<DIM('a). a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i"
  4867     { fix i assume "i<DIM('a)"
  4868       hence "\<bar>x$$i\<bar> \<le> \<bar>a$$i\<bar> + \<bar>b$$i\<bar>" using x[THEN spec[where x=i]] by auto  }
  4869     hence "(\<Sum>i<DIM('a). \<bar>x $$ i\<bar>) \<le> ?b" apply-apply(rule setsum_mono) by auto
  4870     hence "norm x \<le> ?b" using norm_le_l1[of x] by auto  }
  4871   thus ?thesis unfolding interval and bounded_iff by auto
  4872 qed
  4873 
  4874 lemma bounded_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4875  "bounded {a .. b} \<and> bounded {a<..<b}"
  4876   using bounded_closed_interval[of a b]
  4877   using interval_open_subset_closed[of a b]
  4878   using bounded_subset[of "{a..b}" "{a<..<b}"]
  4879   by simp
  4880 
  4881 lemma not_interval_univ: fixes a :: "'a::ordered_euclidean_space" shows
  4882  "({a .. b} \<noteq> UNIV) \<and> ({a<..<b} \<noteq> UNIV)"
  4883   using bounded_interval[of a b] by auto
  4884 
  4885 lemma compact_interval: fixes a :: "'a::ordered_euclidean_space" shows "compact {a .. b}"
  4886   using bounded_closed_imp_compact[of "{a..b}"] using bounded_interval[of a b]
  4887   by auto
  4888 
  4889 lemma open_interval_midpoint: fixes a :: "'a::ordered_euclidean_space"
  4890   assumes "{a<..<b} \<noteq> {}" shows "((1/2) *\<^sub>R (a + b)) \<in> {a<..<b}"
  4891 proof-
  4892   { fix i assume "i<DIM('a)"
  4893     hence "a $$ i < ((1 / 2) *\<^sub>R (a + b)) $$ i \<and> ((1 / 2) *\<^sub>R (a + b)) $$ i < b $$ i"
  4894       using assms[unfolded interval_ne_empty, THEN spec[where x=i]]
  4895       unfolding euclidean_simps by auto  }
  4896   thus ?thesis unfolding mem_interval by auto
  4897 qed
  4898 
  4899 lemma open_closed_interval_convex: fixes x :: "'a::ordered_euclidean_space"
  4900   assumes x:"x \<in> {a<..<b}" and y:"y \<in> {a .. b}" and e:"0 < e" "e \<le> 1"
  4901   shows "(e *\<^sub>R x + (1 - e) *\<^sub>R y) \<in> {a<..<b}"
  4902 proof-
  4903   { fix i assume i:"i<DIM('a)"
  4904     have "a $$ i = e * a$$i + (1 - e) * a$$i" unfolding left_diff_distrib by simp
  4905     also have "\<dots> < e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4906       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4907       using x unfolding mem_interval using i apply simp
  4908       using y unfolding mem_interval using i apply simp
  4909       done
  4910     finally have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i" unfolding euclidean_simps by auto
  4911     moreover {
  4912     have "b $$ i = e * b$$i + (1 - e) * b$$i" unfolding left_diff_distrib by simp
  4913     also have "\<dots> > e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4914       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4915       using x unfolding mem_interval using i apply simp
  4916       using y unfolding mem_interval using i apply simp
  4917       done
  4918     finally have "(e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" unfolding euclidean_simps by auto
  4919     } ultimately have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i \<and> (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" by auto }
  4920   thus ?thesis unfolding mem_interval by auto
  4921 qed
  4922 
  4923 lemma closure_open_interval: fixes a :: "'a::ordered_euclidean_space"
  4924   assumes "{a<..<b} \<noteq> {}"
  4925   shows "closure {a<..<b} = {a .. b}"
  4926 proof-
  4927   have ab:"a < b" using assms[unfolded interval_ne_empty] apply(subst eucl_less) by auto
  4928   let ?c = "(1 / 2) *\<^sub>R (a + b)"
  4929   { fix x assume as:"x \<in> {a .. b}"
  4930     def f == "\<lambda>n::nat. x + (inverse (real n + 1)) *\<^sub>R (?c - x)"
  4931     { fix n assume fn:"f n < b \<longrightarrow> a < f n \<longrightarrow> f n = x" and xc:"x \<noteq> ?c"
  4932       have *:"0 < inverse (real n + 1)" "inverse (real n + 1) \<le> 1" unfolding inverse_le_1_iff by auto
  4933       have "(inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b)) + (1 - inverse (real n + 1)) *\<^sub>R x =
  4934         x + (inverse (real n + 1)) *\<^sub>R (((1 / 2) *\<^sub>R (a + b)) - x)"
  4935         by (auto simp add: algebra_simps)
  4936       hence "f n < b" and "a < f n" using open_closed_interval_convex[OF open_interval_midpoint[OF assms] as *] unfolding f_def by auto
  4937       hence False using fn unfolding f_def using xc by auto  }
  4938     moreover
  4939     { assume "\<not> (f ---> x) sequentially"
  4940       { fix e::real assume "e>0"
  4941         hence "\<exists>N::nat. inverse (real (N + 1)) < e" using real_arch_inv[of e] apply (auto simp add: Suc_pred') apply(rule_tac x="n - 1" in exI) by auto
  4942         then obtain N::nat where "inverse (real (N + 1)) < e" by auto
  4943         hence "\<forall>n\<ge>N. inverse (real n + 1) < e" by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  4944         hence "\<exists>N::nat. \<forall>n\<ge>N. inverse (real n + 1) < e" by auto  }
  4945       hence "((\<lambda>n. inverse (real n + 1)) ---> 0) sequentially"
  4946         unfolding Lim_sequentially by(auto simp add: dist_norm)
  4947       hence "(f ---> x) sequentially" unfolding f_def
  4948         using tendsto_add[OF tendsto_const, of "\<lambda>n::nat. (inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b) - x)" 0 sequentially x]
  4949         using tendsto_scaleR [OF _ tendsto_const, of "\<lambda>n::nat. inverse (real n + 1)" 0 sequentially "((1 / 2) *\<^sub>R (a + b) - x)"] by auto  }
  4950     ultimately have "x \<in> closure {a<..<b}"
  4951       using as and open_interval_midpoint[OF assms] unfolding closure_def unfolding islimpt_sequential by(cases "x=?c")auto  }
  4952   thus ?thesis using closure_minimal[OF interval_open_subset_closed closed_interval, of a b] by blast
  4953 qed
  4954 
  4955 lemma bounded_subset_open_interval_symmetric: fixes s::"('a::ordered_euclidean_space) set"
  4956   assumes "bounded s"  shows "\<exists>a. s \<subseteq> {-a<..<a}"
  4957 proof-
  4958   obtain b where "b>0" and b:"\<forall>x\<in>s. norm x \<le> b" using assms[unfolded bounded_pos] by auto
  4959   def a \<equiv> "(\<chi>\<chi> i. b+1)::'a"
  4960   { fix x assume "x\<in>s"
  4961     fix i assume i:"i<DIM('a)"
  4962     hence "(-a)$$i < x$$i" and "x$$i < a$$i" using b[THEN bspec[where x=x], OF `x\<in>s`]
  4963       and component_le_norm[of x i] unfolding euclidean_simps and a_def by auto  }
  4964   thus ?thesis by(auto intro: exI[where x=a] simp add: eucl_less[where 'a='a])
  4965 qed
  4966 
  4967 lemma bounded_subset_open_interval:
  4968   fixes s :: "('a::ordered_euclidean_space) set"
  4969   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a<..<b})"
  4970   by (auto dest!: bounded_subset_open_interval_symmetric)
  4971 
  4972 lemma bounded_subset_closed_interval_symmetric:
  4973   fixes s :: "('a::ordered_euclidean_space) set"
  4974   assumes "bounded s" shows "\<exists>a. s \<subseteq> {-a .. a}"
  4975 proof-
  4976   obtain a where "s \<subseteq> {- a<..<a}" using bounded_subset_open_interval_symmetric[OF assms] by auto
  4977   thus ?thesis using interval_open_subset_closed[of "-a" a] by auto
  4978 qed
  4979 
  4980 lemma bounded_subset_closed_interval:
  4981   fixes s :: "('a::ordered_euclidean_space) set"
  4982   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a .. b})"
  4983   using bounded_subset_closed_interval_symmetric[of s] by auto
  4984 
  4985 lemma frontier_closed_interval:
  4986   fixes a b :: "'a::ordered_euclidean_space"
  4987   shows "frontier {a .. b} = {a .. b} - {a<..<b}"
  4988   unfolding frontier_def unfolding interior_closed_interval and closure_closed[OF closed_interval] ..
  4989 
  4990 lemma frontier_open_interval:
  4991   fixes a b :: "'a::ordered_euclidean_space"
  4992   shows "frontier {a<..<b} = (if {a<..<b} = {} then {} else {a .. b} - {a<..<b})"
  4993 proof(cases "{a<..<b} = {}")
  4994   case True thus ?thesis using frontier_empty by auto
  4995 next
  4996   case False thus ?thesis unfolding frontier_def and closure_open_interval[OF False] and interior_open[OF open_interval] by auto
  4997 qed
  4998 
  4999 lemma inter_interval_mixed_eq_empty: fixes a :: "'a::ordered_euclidean_space"
  5000   assumes "{c<..<d} \<noteq> {}"  shows "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> {a<..<b} \<inter> {c<..<d} = {}"
  5001   unfolding closure_open_interval[OF assms, THEN sym] unfolding open_inter_closure_eq_empty[OF open_interval] ..
  5002 
  5003 
  5004 (* Some stuff for half-infinite intervals too; FIXME: notation?  *)
  5005 
  5006 lemma closed_interval_left: fixes b::"'a::euclidean_space"
  5007   shows "closed {x::'a. \<forall>i<DIM('a). x$$i \<le> b$$i}"
  5008 proof-
  5009   { fix i assume i:"i<DIM('a)"
  5010     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). x $$ i \<le> b $$ i}. x' \<noteq> x \<and> dist x' x < e"
  5011     { assume "x$$i > b$$i"
  5012       then obtain y where "y $$ i \<le> b $$ i"  "y \<noteq> x"  "dist y x < x$$i - b$$i"
  5013         using x[THEN spec[where x="x$$i - b$$i"]] using i by auto
  5014       hence False using component_le_norm[of "y - x" i] unfolding dist_norm euclidean_simps using i 
  5015         by auto   }
  5016     hence "x$$i \<le> b$$i" by(rule ccontr)auto  }
  5017   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  5018 qed
  5019 
  5020 lemma closed_interval_right: fixes a::"'a::euclidean_space"
  5021   shows "closed {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i}"
  5022 proof-
  5023   { fix i assume i:"i<DIM('a)"
  5024     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). a $$ i \<le> x $$ i}. x' \<noteq> x \<and> dist x' x < e"
  5025     { assume "a$$i > x$$i"
  5026       then obtain y where "a $$ i \<le> y $$ i"  "y \<noteq> x"  "dist y x < a$$i - x$$i"
  5027         using x[THEN spec[where x="a$$i - x$$i"]] i by auto
  5028       hence False using component_le_norm[of "y - x" i] unfolding dist_norm and euclidean_simps by auto   }
  5029     hence "a$$i \<le> x$$i" by(rule ccontr)auto  }
  5030   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  5031 qed
  5032 
  5033 text {* Intervals in general, including infinite and mixtures of open and closed. *}
  5034 
  5035 definition "is_interval (s::('a::euclidean_space) set) \<longleftrightarrow>
  5036   (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i<DIM('a). ((a$$i \<le> x$$i \<and> x$$i \<le> b$$i) \<or> (b$$i \<le> x$$i \<and> x$$i \<le> a$$i))) \<longrightarrow> x \<in> s)"
  5037 
  5038 lemma is_interval_interval: "is_interval {a .. b::'a::ordered_euclidean_space}" (is ?th1)
  5039   "is_interval {a<..<b}" (is ?th2) proof -
  5040   have *:"\<And>x y z::real. x < y \<Longrightarrow> y < z \<Longrightarrow> x < z" by auto
  5041   show ?th1 ?th2  unfolding is_interval_def mem_interval Ball_def atLeastAtMost_iff
  5042     by(meson order_trans le_less_trans less_le_trans *)+ qed
  5043 
  5044 lemma is_interval_empty:
  5045  "is_interval {}"
  5046   unfolding is_interval_def
  5047   by simp
  5048 
  5049 lemma is_interval_univ:
  5050  "is_interval UNIV"
  5051   unfolding is_interval_def
  5052   by simp
  5053 
  5054 
  5055 subsection {* Closure of halfspaces and hyperplanes *}
  5056 
  5057 lemma isCont_open_vimage:
  5058   assumes "\<And>x. isCont f x" and "open s" shows "open (f -` s)"
  5059 proof -
  5060   from assms(1) have "continuous_on UNIV f"
  5061     unfolding isCont_def continuous_on_def within_UNIV by simp
  5062   hence "open {x \<in> UNIV. f x \<in> s}"
  5063     using open_UNIV `open s` by (rule continuous_open_preimage)
  5064   thus "open (f -` s)"
  5065     by (simp add: vimage_def)
  5066 qed
  5067 
  5068 lemma isCont_closed_vimage:
  5069   assumes "\<And>x. isCont f x" and "closed s" shows "closed (f -` s)"
  5070   using assms unfolding closed_def vimage_Compl [symmetric]
  5071   by (rule isCont_open_vimage)
  5072 
  5073 lemma open_Collect_less:
  5074   fixes f g :: "'a::topological_space \<Rightarrow> real"
  5075   assumes f: "\<And>x. isCont f x"
  5076   assumes g: "\<And>x. isCont g x"
  5077   shows "open {x. f x < g x}"
  5078 proof -
  5079   have "open ((\<lambda>x. g x - f x) -` {0<..})"
  5080     using isCont_diff [OF g f] open_real_greaterThan
  5081     by (rule isCont_open_vimage)
  5082   also have "((\<lambda>x. g x - f x) -` {0<..}) = {x. f x < g x}"
  5083     by auto
  5084   finally show ?thesis .
  5085 qed
  5086 
  5087 lemma closed_Collect_le:
  5088   fixes f g :: "'a::topological_space \<Rightarrow> real"
  5089   assumes f: "\<And>x. isCont f x"
  5090   assumes g: "\<And>x. isCont g x"
  5091   shows "closed {x. f x \<le> g x}"
  5092 proof -
  5093   have "closed ((\<lambda>x. g x - f x) -` {0..})"
  5094     using isCont_diff [OF g f] closed_real_atLeast
  5095     by (rule isCont_closed_vimage)
  5096   also have "((\<lambda>x. g x - f x) -` {0..}) = {x. f x \<le> g x}"
  5097     by auto
  5098   finally show ?thesis .
  5099 qed
  5100 
  5101 lemma closed_Collect_eq:
  5102   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  5103   assumes f: "\<And>x. isCont f x"
  5104   assumes g: "\<And>x. isCont g x"
  5105   shows "closed {x. f x = g x}"
  5106 proof -
  5107   have "open {(x::'b, y::'b). x \<noteq> y}"
  5108     unfolding open_prod_def by (auto dest!: hausdorff)
  5109   hence "closed {(x::'b, y::'b). x = y}"
  5110     unfolding closed_def split_def Collect_neg_eq .
  5111   with isCont_Pair [OF f g]
  5112   have "closed ((\<lambda>x. (f x, g x)) -` {(x, y). x = y})"
  5113     by (rule isCont_closed_vimage)
  5114   also have "\<dots> = {x. f x = g x}" by auto
  5115   finally show ?thesis .
  5116 qed
  5117 
  5118 lemma Lim_inner:
  5119   assumes "(f ---> l) net"  shows "((\<lambda>y. inner a (f y)) ---> inner a l) net"
  5120   by (intro tendsto_intros assms)
  5121 
  5122 lemma continuous_at_inner: "continuous (at x) (inner a)"
  5123   unfolding continuous_at by (intro tendsto_intros)
  5124 
  5125 lemma continuous_at_euclidean_component[intro!, simp]: "continuous (at x) (\<lambda>x. x $$ i)"
  5126   unfolding euclidean_component_def by (rule continuous_at_inner)
  5127 
  5128 lemma continuous_on_inner:
  5129   fixes s :: "'a::real_inner set"
  5130   shows "continuous_on s (inner a)"
  5131   unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  5132 
  5133 lemma closed_halfspace_le: "closed {x. inner a x \<le> b}"
  5134   by (simp add: closed_Collect_le)
  5135 
  5136 lemma closed_halfspace_ge: "closed {x. inner a x \<ge> b}"
  5137   by (simp add: closed_Collect_le)
  5138 
  5139 lemma closed_hyperplane: "closed {x. inner a x = b}"
  5140   by (simp add: closed_Collect_eq)
  5141 
  5142 lemma closed_halfspace_component_le:
  5143   shows "closed {x::'a::euclidean_space. x$$i \<le> a}"
  5144   by (simp add: closed_Collect_le)
  5145 
  5146 lemma closed_halfspace_component_ge:
  5147   shows "closed {x::'a::euclidean_space. x$$i \<ge> a}"
  5148   by (simp add: closed_Collect_le)
  5149 
  5150 text {* Openness of halfspaces. *}
  5151 
  5152 lemma open_halfspace_lt: "open {x. inner a x < b}"
  5153   by (simp add: open_Collect_less)
  5154 
  5155 lemma open_halfspace_gt: "open {x. inner a x > b}"
  5156   by (simp add: open_Collect_less)
  5157 
  5158 lemma open_halfspace_component_lt:
  5159   shows "open {x::'a::euclidean_space. x$$i < a}"
  5160   by (simp add: open_Collect_less)
  5161 
  5162 lemma open_halfspace_component_gt:
  5163   shows "open {x::'a::euclidean_space. x$$i > a}"
  5164   by (simp add: open_Collect_less)
  5165 
  5166 text{* Instantiation for intervals on @{text ordered_euclidean_space} *}
  5167 
  5168 lemma eucl_lessThan_eq_halfspaces:
  5169   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5170   shows "{..<a} = (\<Inter>i<DIM('a). {x. x $$ i < a $$ i})"
  5171  by (auto simp: eucl_less[where 'a='a])
  5172 
  5173 lemma eucl_greaterThan_eq_halfspaces:
  5174   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5175   shows "{a<..} = (\<Inter>i<DIM('a). {x. a $$ i < x $$ i})"
  5176  by (auto simp: eucl_less[where 'a='a])
  5177 
  5178 lemma eucl_atMost_eq_halfspaces:
  5179   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5180   shows "{.. a} = (\<Inter>i<DIM('a). {x. x $$ i \<le> a $$ i})"
  5181  by (auto simp: eucl_le[where 'a='a])
  5182 
  5183 lemma eucl_atLeast_eq_halfspaces:
  5184   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5185   shows "{a ..} = (\<Inter>i<DIM('a). {x. a $$ i \<le> x $$ i})"
  5186  by (auto simp: eucl_le[where 'a='a])
  5187 
  5188 lemma open_eucl_lessThan[simp, intro]:
  5189   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5190   shows "open {..< a}"
  5191   by (auto simp: eucl_lessThan_eq_halfspaces open_halfspace_component_lt)
  5192 
  5193 lemma open_eucl_greaterThan[simp, intro]:
  5194   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5195   shows "open {a <..}"
  5196   by (auto simp: eucl_greaterThan_eq_halfspaces open_halfspace_component_gt)
  5197 
  5198 lemma closed_eucl_atMost[simp, intro]:
  5199   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5200   shows "closed {.. a}"
  5201   unfolding eucl_atMost_eq_halfspaces
  5202   by (simp add: closed_INT closed_Collect_le)
  5203 
  5204 lemma closed_eucl_atLeast[simp, intro]:
  5205   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5206   shows "closed {a ..}"
  5207   unfolding eucl_atLeast_eq_halfspaces
  5208   by (simp add: closed_INT closed_Collect_le)
  5209 
  5210 lemma open_vimage_euclidean_component: "open S \<Longrightarrow> open ((\<lambda>x. x $$ i) -` S)"
  5211   by (auto intro!: continuous_open_vimage)
  5212 
  5213 text {* This gives a simple derivation of limit component bounds. *}
  5214 
  5215 lemma Lim_component_le: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5216   assumes "(f ---> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f(x)$$i \<le> b) net"
  5217   shows "l$$i \<le> b"
  5218 proof-
  5219   { fix x have "x \<in> {x::'b. inner (basis i) x \<le> b} \<longleftrightarrow> x$$i \<le> b"
  5220       unfolding euclidean_component_def by auto  } note * = this
  5221   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<le> b}" f net l] unfolding *
  5222     using closed_halfspace_le[of "(basis i)::'b" b] and assms(1,2,3) by auto
  5223 qed
  5224 
  5225 lemma Lim_component_ge: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5226   assumes "(f ---> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$$i) net"
  5227   shows "b \<le> l$$i"
  5228 proof-
  5229   { fix x have "x \<in> {x::'b. inner (basis i) x \<ge> b} \<longleftrightarrow> x$$i \<ge> b"
  5230       unfolding euclidean_component_def by auto  } note * = this
  5231   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<ge> b}" f net l] unfolding *
  5232     using closed_halfspace_ge[of b "(basis i)"] and assms(1,2,3) by auto
  5233 qed
  5234 
  5235 lemma Lim_component_eq: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5236   assumes net:"(f ---> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$$i = b) net"
  5237   shows "l$$i = b"
  5238   using ev[unfolded order_eq_iff eventually_conj_iff] using Lim_component_ge[OF net, of b i] and Lim_component_le[OF net, of i b] by auto
  5239 text{* Limits relative to a union.                                               *}
  5240 
  5241 lemma eventually_within_Un:
  5242   "eventually P (net within (s \<union> t)) \<longleftrightarrow>
  5243     eventually P (net within s) \<and> eventually P (net within t)"
  5244   unfolding Limits.eventually_within
  5245   by (auto elim!: eventually_rev_mp)
  5246 
  5247 lemma Lim_within_union:
  5248  "(f ---> l) (net within (s \<union> t)) \<longleftrightarrow>
  5249   (f ---> l) (net within s) \<and> (f ---> l) (net within t)"
  5250   unfolding tendsto_def
  5251   by (auto simp add: eventually_within_Un)
  5252 
  5253 lemma Lim_topological:
  5254  "(f ---> l) net \<longleftrightarrow>
  5255         trivial_limit net \<or>
  5256         (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
  5257   unfolding tendsto_def trivial_limit_eq by auto
  5258 
  5259 lemma continuous_on_union:
  5260   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t f"
  5261   shows "continuous_on (s \<union> t) f"
  5262   using assms unfolding continuous_on Lim_within_union
  5263   unfolding Lim_topological trivial_limit_within closed_limpt by auto
  5264 
  5265 lemma continuous_on_cases:
  5266   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t g"
  5267           "\<forall>x. (x\<in>s \<and> \<not> P x) \<or> (x \<in> t \<and> P x) \<longrightarrow> f x = g x"
  5268   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
  5269 proof-
  5270   let ?h = "(\<lambda>x. if P x then f x else g x)"
  5271   have "\<forall>x\<in>s. f x = (if P x then f x else g x)" using assms(5) by auto
  5272   hence "continuous_on s ?h" using continuous_on_eq[of s f ?h] using assms(3) by auto
  5273   moreover
  5274   have "\<forall>x\<in>t. g x = (if P x then f x else g x)" using assms(5) by auto
  5275   hence "continuous_on t ?h" using continuous_on_eq[of t g ?h] using assms(4) by auto
  5276   ultimately show ?thesis using continuous_on_union[OF assms(1,2), of ?h] by auto
  5277 qed
  5278 
  5279 
  5280 text{* Some more convenient intermediate-value theorem formulations.             *}
  5281 
  5282 lemma connected_ivt_hyperplane:
  5283   assumes "connected s" "x \<in> s" "y \<in> s" "inner a x \<le> b" "b \<le> inner a y"
  5284   shows "\<exists>z \<in> s. inner a z = b"
  5285 proof(rule ccontr)
  5286   assume as:"\<not> (\<exists>z\<in>s. inner a z = b)"
  5287   let ?A = "{x. inner a x < b}"
  5288   let ?B = "{x. inner a x > b}"
  5289   have "open ?A" "open ?B" using open_halfspace_lt and open_halfspace_gt by auto
  5290   moreover have "?A \<inter> ?B = {}" by auto
  5291   moreover have "s \<subseteq> ?A \<union> ?B" using as by auto
  5292   ultimately show False using assms(1)[unfolded connected_def not_ex, THEN spec[where x="?A"], THEN spec[where x="?B"]] and assms(2-5) by auto
  5293 qed
  5294 
  5295 lemma connected_ivt_component: fixes x::"'a::euclidean_space" shows
  5296  "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$$k \<le> a \<Longrightarrow> a \<le> y$$k \<Longrightarrow> (\<exists>z\<in>s.  z$$k = a)"
  5297   using connected_ivt_hyperplane[of s x y "(basis k)::'a" a]
  5298   unfolding euclidean_component_def by auto
  5299 
  5300 
  5301 subsection {* Homeomorphisms *}
  5302 
  5303 definition "homeomorphism s t f g \<equiv>
  5304      (\<forall>x\<in>s. (g(f x) = x)) \<and> (f ` s = t) \<and> continuous_on s f \<and>
  5305      (\<forall>y\<in>t. (f(g y) = y)) \<and> (g ` t = s) \<and> continuous_on t g"
  5306 
  5307 definition
  5308   homeomorphic :: "'a::metric_space set \<Rightarrow> 'b::metric_space set \<Rightarrow> bool"
  5309     (infixr "homeomorphic" 60) where
  5310   homeomorphic_def: "s homeomorphic t \<equiv> (\<exists>f g. homeomorphism s t f g)"
  5311 
  5312 lemma homeomorphic_refl: "s homeomorphic s"
  5313   unfolding homeomorphic_def
  5314   unfolding homeomorphism_def
  5315   using continuous_on_id
  5316   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5317   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5318   by blast
  5319 
  5320 lemma homeomorphic_sym:
  5321  "s homeomorphic t \<longleftrightarrow> t homeomorphic s"
  5322 unfolding homeomorphic_def
  5323 unfolding homeomorphism_def
  5324 by blast 
  5325 
  5326 lemma homeomorphic_trans:
  5327   assumes "s homeomorphic t" "t homeomorphic u" shows "s homeomorphic u"
  5328 proof-
  5329   obtain f1 g1 where fg1:"\<forall>x\<in>s. g1 (f1 x) = x"  "f1 ` s = t" "continuous_on s f1" "\<forall>y\<in>t. f1 (g1 y) = y" "g1 ` t = s" "continuous_on t g1"
  5330     using assms(1) unfolding homeomorphic_def homeomorphism_def by auto
  5331   obtain f2 g2 where fg2:"\<forall>x\<in>t. g2 (f2 x) = x"  "f2 ` t = u" "continuous_on t f2" "\<forall>y\<in>u. f2 (g2 y) = y" "g2 ` u = t" "continuous_on u g2"
  5332     using assms(2) unfolding homeomorphic_def homeomorphism_def by auto
  5333 
  5334   { fix x assume "x\<in>s" hence "(g1 \<circ> g2) ((f2 \<circ> f1) x) = x" using fg1(1)[THEN bspec[where x=x]] and fg2(1)[THEN bspec[where x="f1 x"]] and fg1(2) by auto }
  5335   moreover have "(f2 \<circ> f1) ` s = u" using fg1(2) fg2(2) by auto
  5336   moreover have "continuous_on s (f2 \<circ> f1)" using continuous_on_compose[OF fg1(3)] and fg2(3) unfolding fg1(2) by auto
  5337   moreover { fix y assume "y\<in>u" hence "(f2 \<circ> f1) ((g1 \<circ> g2) y) = y" using fg2(4)[THEN bspec[where x=y]] and fg1(4)[THEN bspec[where x="g2 y"]] and fg2(5) by auto }
  5338   moreover have "(g1 \<circ> g2) ` u = s" using fg1(5) fg2(5) by auto
  5339   moreover have "continuous_on u (g1 \<circ> g2)" using continuous_on_compose[OF fg2(6)] and fg1(6)  unfolding fg2(5) by auto
  5340   ultimately show ?thesis unfolding homeomorphic_def homeomorphism_def apply(rule_tac x="f2 \<circ> f1" in exI) apply(rule_tac x="g1 \<circ> g2" in exI) by auto
  5341 qed
  5342 
  5343 lemma homeomorphic_minimal:
  5344  "s homeomorphic t \<longleftrightarrow>
  5345     (\<exists>f g. (\<forall>x\<in>s. f(x) \<in> t \<and> (g(f(x)) = x)) \<and>
  5346            (\<forall>y\<in>t. g(y) \<in> s \<and> (f(g(y)) = y)) \<and>
  5347            continuous_on s f \<and> continuous_on t g)"
  5348 unfolding homeomorphic_def homeomorphism_def
  5349 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI)
  5350 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI) apply auto
  5351 unfolding image_iff
  5352 apply(erule_tac x="g x" in ballE) apply(erule_tac x="x" in ballE)
  5353 apply auto apply(rule_tac x="g x" in bexI) apply auto
  5354 apply(erule_tac x="f x" in ballE) apply(erule_tac x="x" in ballE)
  5355 apply auto apply(rule_tac x="f x" in bexI) by auto
  5356 
  5357 text {* Relatively weak hypotheses if a set is compact. *}
  5358 
  5359 lemma homeomorphism_compact:
  5360   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5361     (* class constraint due to continuous_on_inverse *)
  5362   assumes "compact s" "continuous_on s f"  "f ` s = t"  "inj_on f s"
  5363   shows "\<exists>g. homeomorphism s t f g"
  5364 proof-
  5365   def g \<equiv> "\<lambda>x. SOME y. y\<in>s \<and> f y = x"
  5366   have g:"\<forall>x\<in>s. g (f x) = x" using assms(3) assms(4)[unfolded inj_on_def] unfolding g_def by auto
  5367   { fix y assume "y\<in>t"
  5368     then obtain x where x:"f x = y" "x\<in>s" using assms(3) by auto
  5369     hence "g (f x) = x" using g by auto
  5370     hence "f (g y) = y" unfolding x(1)[THEN sym] by auto  }
  5371   hence g':"\<forall>x\<in>t. f (g x) = x" by auto
  5372   moreover
  5373   { fix x
  5374     have "x\<in>s \<Longrightarrow> x \<in> g ` t" using g[THEN bspec[where x=x]] unfolding image_iff using assms(3) by(auto intro!: bexI[where x="f x"])
  5375     moreover
  5376     { assume "x\<in>g ` t"
  5377       then obtain y where y:"y\<in>t" "g y = x" by auto
  5378       then obtain x' where x':"x'\<in>s" "f x' = y" using assms(3) by auto
  5379       hence "x \<in> s" unfolding g_def using someI2[of "\<lambda>b. b\<in>s \<and> f b = y" x' "\<lambda>x. x\<in>s"] unfolding y(2)[THEN sym] and g_def by auto }
  5380     ultimately have "x\<in>s \<longleftrightarrow> x \<in> g ` t" ..  }
  5381   hence "g ` t = s" by auto
  5382   ultimately
  5383   show ?thesis unfolding homeomorphism_def homeomorphic_def
  5384     apply(rule_tac x=g in exI) using g and assms(3) and continuous_on_inverse[OF assms(2,1), of g, unfolded assms(3)] and assms(2) by auto
  5385 qed
  5386 
  5387 lemma homeomorphic_compact:
  5388   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5389     (* class constraint due to continuous_on_inverse *)
  5390   shows "compact s \<Longrightarrow> continuous_on s f \<Longrightarrow> (f ` s = t) \<Longrightarrow> inj_on f s
  5391           \<Longrightarrow> s homeomorphic t"
  5392   unfolding homeomorphic_def by (metis homeomorphism_compact)
  5393 
  5394 text{* Preservation of topological properties.                                   *}
  5395 
  5396 lemma homeomorphic_compactness:
  5397  "s homeomorphic t ==> (compact s \<longleftrightarrow> compact t)"
  5398 unfolding homeomorphic_def homeomorphism_def
  5399 by (metis compact_continuous_image)
  5400 
  5401 text{* Results on translation, scaling etc.                                      *}
  5402 
  5403 lemma homeomorphic_scaling:
  5404   fixes s :: "'a::real_normed_vector set"
  5405   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. c *\<^sub>R x) ` s)"
  5406   unfolding homeomorphic_minimal
  5407   apply(rule_tac x="\<lambda>x. c *\<^sub>R x" in exI)
  5408   apply(rule_tac x="\<lambda>x. (1 / c) *\<^sub>R x" in exI)
  5409   using assms apply auto
  5410   using continuous_on_cmul[OF continuous_on_id] by auto
  5411 
  5412 lemma homeomorphic_translation:
  5413   fixes s :: "'a::real_normed_vector set"
  5414   shows "s homeomorphic ((\<lambda>x. a + x) ` s)"
  5415   unfolding homeomorphic_minimal
  5416   apply(rule_tac x="\<lambda>x. a + x" in exI)
  5417   apply(rule_tac x="\<lambda>x. -a + x" in exI)
  5418   using continuous_on_add[OF continuous_on_const continuous_on_id] by auto
  5419 
  5420 lemma homeomorphic_affinity:
  5421   fixes s :: "'a::real_normed_vector set"
  5422   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5423 proof-
  5424   have *:"op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  5425   show ?thesis
  5426     using homeomorphic_trans
  5427     using homeomorphic_scaling[OF assms, of s]
  5428     using homeomorphic_translation[of "(\<lambda>x. c *\<^sub>R x) ` s" a] unfolding * by auto
  5429 qed
  5430 
  5431 lemma homeomorphic_balls:
  5432   fixes a b ::"'a::real_normed_vector" (* FIXME: generalize to metric_space *)
  5433   assumes "0 < d"  "0 < e"
  5434   shows "(ball a d) homeomorphic  (ball b e)" (is ?th)
  5435         "(cball a d) homeomorphic (cball b e)" (is ?cth)
  5436 proof-
  5437   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5438   show ?th unfolding homeomorphic_minimal
  5439     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5440     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5441     using assms apply (auto simp add: dist_commute)
  5442     unfolding dist_norm
  5443     apply (auto simp add: pos_divide_less_eq mult_strict_left_mono)
  5444     unfolding continuous_on
  5445     by (intro ballI tendsto_intros, simp)+
  5446 next
  5447   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5448   show ?cth unfolding homeomorphic_minimal
  5449     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5450     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5451     using assms apply (auto simp add: dist_commute)
  5452     unfolding dist_norm
  5453     apply (auto simp add: pos_divide_le_eq)
  5454     unfolding continuous_on
  5455     by (intro ballI tendsto_intros, simp)+
  5456 qed
  5457 
  5458 text{* "Isometry" (up to constant bounds) of injective linear map etc.           *}
  5459 
  5460 lemma cauchy_isometric:
  5461   fixes x :: "nat \<Rightarrow> 'a::euclidean_space"
  5462   assumes e:"0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and xs:"\<forall>n::nat. x n \<in> s" and cf:"Cauchy(f o x)"
  5463   shows "Cauchy x"
  5464 proof-
  5465   interpret f: bounded_linear f by fact
  5466   { fix d::real assume "d>0"
  5467     then obtain N where N:"\<forall>n\<ge>N. norm (f (x n) - f (x N)) < e * d"
  5468       using cf[unfolded cauchy o_def dist_norm, THEN spec[where x="e*d"]] and e and mult_pos_pos[of e d] by auto
  5469     { fix n assume "n\<ge>N"
  5470       hence "norm (f (x n - x N)) < e * d" using N[THEN spec[where x=n]] unfolding f.diff[THEN sym] by auto
  5471       moreover have "e * norm (x n - x N) \<le> norm (f (x n - x N))"
  5472         using subspace_sub[OF s, of "x n" "x N"] using xs[THEN spec[where x=N]] and xs[THEN spec[where x=n]]
  5473         using normf[THEN bspec[where x="x n - x N"]] by auto
  5474       ultimately have "norm (x n - x N) < d" using `e>0`
  5475         using mult_left_less_imp_less[of e "norm (x n - x N)" d] by auto   }
  5476     hence "\<exists>N. \<forall>n\<ge>N. norm (x n - x N) < d" by auto }
  5477   thus ?thesis unfolding cauchy and dist_norm by auto
  5478 qed
  5479 
  5480 lemma complete_isometric_image:
  5481   fixes f :: "'a::euclidean_space => 'b::euclidean_space"
  5482   assumes "0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and cs:"complete s"
  5483   shows "complete(f ` s)"
  5484 proof-
  5485   { fix g assume as:"\<forall>n::nat. g n \<in> f ` s" and cfg:"Cauchy g"
  5486     then obtain x where "\<forall>n. x n \<in> s \<and> g n = f (x n)" 
  5487       using choice[of "\<lambda> n xa. xa \<in> s \<and> g n = f xa"] by auto
  5488     hence x:"\<forall>n. x n \<in> s"  "\<forall>n. g n = f (x n)" by auto
  5489     hence "f \<circ> x = g" unfolding fun_eq_iff by auto
  5490     then obtain l where "l\<in>s" and l:"(x ---> l) sequentially"
  5491       using cs[unfolded complete_def, THEN spec[where x="x"]]
  5492       using cauchy_isometric[OF `0<e` s f normf] and cfg and x(1) by auto
  5493     hence "\<exists>l\<in>f ` s. (g ---> l) sequentially"
  5494       using linear_continuous_at[OF f, unfolded continuous_at_sequentially, THEN spec[where x=x], of l]
  5495       unfolding `f \<circ> x = g` by auto  }
  5496   thus ?thesis unfolding complete_def by auto
  5497 qed
  5498 
  5499 lemma dist_0_norm:
  5500   fixes x :: "'a::real_normed_vector"
  5501   shows "dist 0 x = norm x"
  5502 unfolding dist_norm by simp
  5503 
  5504 lemma injective_imp_isometric: fixes f::"'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5505   assumes s:"closed s"  "subspace s"  and f:"bounded_linear f" "\<forall>x\<in>s. (f x = 0) \<longrightarrow> (x = 0)"
  5506   shows "\<exists>e>0. \<forall>x\<in>s. norm (f x) \<ge> e * norm(x)"
  5507 proof(cases "s \<subseteq> {0::'a}")
  5508   case True
  5509   { fix x assume "x \<in> s"
  5510     hence "x = 0" using True by auto
  5511     hence "norm x \<le> norm (f x)" by auto  }
  5512   thus ?thesis by(auto intro!: exI[where x=1])
  5513 next
  5514   interpret f: bounded_linear f by fact
  5515   case False
  5516   then obtain a where a:"a\<noteq>0" "a\<in>s" by auto
  5517   from False have "s \<noteq> {}" by auto
  5518   let ?S = "{f x| x. (x \<in> s \<and> norm x = norm a)}"
  5519   let ?S' = "{x::'a. x\<in>s \<and> norm x = norm a}"
  5520   let ?S'' = "{x::'a. norm x = norm a}"
  5521 
  5522   have "?S'' = frontier(cball 0 (norm a))" unfolding frontier_cball and dist_norm by auto
  5523   hence "compact ?S''" using compact_frontier[OF compact_cball, of 0 "norm a"] by auto
  5524   moreover have "?S' = s \<inter> ?S''" by auto
  5525   ultimately have "compact ?S'" using closed_inter_compact[of s ?S''] using s(1) by auto
  5526   moreover have *:"f ` ?S' = ?S" by auto
  5527   ultimately have "compact ?S" using compact_continuous_image[OF linear_continuous_on[OF f(1)], of ?S'] by auto
  5528   hence "closed ?S" using compact_imp_closed by auto
  5529   moreover have "?S \<noteq> {}" using a by auto
  5530   ultimately obtain b' where "b'\<in>?S" "\<forall>y\<in>?S. norm b' \<le> norm y" using distance_attains_inf[of ?S 0] unfolding dist_0_norm by auto
  5531   then obtain b where "b\<in>s" and ba:"norm b = norm a" and b:"\<forall>x\<in>{x \<in> s. norm x = norm a}. norm (f b) \<le> norm (f x)" unfolding *[THEN sym] unfolding image_iff by auto
  5532 
  5533   let ?e = "norm (f b) / norm b"
  5534   have "norm b > 0" using ba and a and norm_ge_zero by auto
  5535   moreover have "norm (f b) > 0" using f(2)[THEN bspec[where x=b], OF `b\<in>s`] using `norm b >0` unfolding zero_less_norm_iff by auto
  5536   ultimately have "0 < norm (f b) / norm b" by(simp only: divide_pos_pos)
  5537   moreover
  5538   { fix x assume "x\<in>s"
  5539     hence "norm (f b) / norm b * norm x \<le> norm (f x)"
  5540     proof(cases "x=0")
  5541       case True thus "norm (f b) / norm b * norm x \<le> norm (f x)" by auto
  5542     next
  5543       case False
  5544       hence *:"0 < norm a / norm x" using `a\<noteq>0` unfolding zero_less_norm_iff[THEN sym] by(simp only: divide_pos_pos)
  5545       have "\<forall>c. \<forall>x\<in>s. c *\<^sub>R x \<in> s" using s[unfolded subspace_def] by auto
  5546       hence "(norm a / norm x) *\<^sub>R x \<in> {x \<in> s. norm x = norm a}" using `x\<in>s` and `x\<noteq>0` by auto
  5547       thus "norm (f b) / norm b * norm x \<le> norm (f x)" using b[THEN bspec[where x="(norm a / norm x) *\<^sub>R x"]]
  5548         unfolding f.scaleR and ba using `x\<noteq>0` `a\<noteq>0`
  5549         by (auto simp add: mult_commute pos_le_divide_eq pos_divide_le_eq)
  5550     qed }
  5551   ultimately
  5552   show ?thesis by auto
  5553 qed
  5554 
  5555 lemma closed_injective_image_subspace:
  5556   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5557   assumes "subspace s" "bounded_linear f" "\<forall>x\<in>s. f x = 0 --> x = 0" "closed s"
  5558   shows "closed(f ` s)"
  5559 proof-
  5560   obtain e where "e>0" and e:"\<forall>x\<in>s. e * norm x \<le> norm (f x)" using injective_imp_isometric[OF assms(4,1,2,3)] by auto
  5561   show ?thesis using complete_isometric_image[OF `e>0` assms(1,2) e] and assms(4)
  5562     unfolding complete_eq_closed[THEN sym] by auto
  5563 qed
  5564 
  5565 
  5566 subsection {* Some properties of a canonical subspace *}
  5567 
  5568 lemma subspace_substandard:
  5569   "subspace {x::'a::euclidean_space. (\<forall>i<DIM('a). P i \<longrightarrow> x$$i = 0)}"
  5570   unfolding subspace_def by(auto simp add: euclidean_simps) (* FIXME: duplicate rewrite rule *)
  5571 
  5572 lemma closed_substandard:
  5573  "closed {x::'a::euclidean_space. \<forall>i<DIM('a). P i --> x$$i = 0}" (is "closed ?A")
  5574 proof-
  5575   let ?D = "{i. P i} \<inter> {..<DIM('a)}"
  5576   let ?Bs = "{{x::'a. inner (basis i) x = 0}| i. i \<in> ?D}"
  5577   { fix x
  5578     { assume "x\<in>?A"
  5579       hence x:"\<forall>i\<in>?D. x $$ i = 0" by auto
  5580       hence "x\<in> \<Inter> ?Bs" by(auto simp add: x euclidean_component_def) }
  5581     moreover
  5582     { assume x:"x\<in>\<Inter>?Bs"
  5583       { fix i assume i:"i \<in> ?D"
  5584         then obtain B where BB:"B \<in> ?Bs" and B:"B = {x::'a. inner (basis i) x = 0}" by auto
  5585         hence "x $$ i = 0" unfolding B using x unfolding euclidean_component_def by auto  }
  5586       hence "x\<in>?A" by auto }
  5587     ultimately have "x\<in>?A \<longleftrightarrow> x\<in> \<Inter>?Bs" .. }
  5588   hence "?A = \<Inter> ?Bs" by auto
  5589   thus ?thesis by(auto simp add: closed_Inter closed_hyperplane)
  5590 qed
  5591 
  5592 lemma dim_substandard: assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"
  5593   shows "dim {x::'a::euclidean_space. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0} = card d" (is "dim ?A = _")
  5594 proof-
  5595   let ?D = "{..<DIM('a)}"
  5596   let ?B = "(basis::nat => 'a) ` d"
  5597   let ?bas = "basis::nat \<Rightarrow> 'a"
  5598   have "?B \<subseteq> ?A" by auto
  5599   moreover
  5600   { fix x::"'a" assume "x\<in>?A"
  5601     hence "finite d" "x\<in>?A" using assms by(auto intro:finite_subset)
  5602     hence "x\<in> span ?B"
  5603     proof(induct d arbitrary: x)
  5604       case empty hence "x=0" apply(subst euclidean_eq) by auto
  5605       thus ?case using subspace_0[OF subspace_span[of "{}"]] by auto
  5606     next
  5607       case (insert k F)
  5608       hence *:"\<forall>i<DIM('a). i \<notin> insert k F \<longrightarrow> x $$ i = 0" by auto
  5609       have **:"F \<subseteq> insert k F" by auto
  5610       def y \<equiv> "x - x$$k *\<^sub>R basis k"
  5611       have y:"x = y + (x$$k) *\<^sub>R basis k" unfolding y_def by auto
  5612       { fix i assume i':"i \<notin> F"
  5613         hence "y $$ i = 0" unfolding y_def 
  5614           using *[THEN spec[where x=i]] by(auto simp add: euclidean_simps) }
  5615       hence "y \<in> span (basis ` F)" using insert(3) by auto
  5616       hence "y \<in> span (basis ` (insert k F))"
  5617         using span_mono[of "?bas ` F" "?bas ` (insert k F)"]
  5618         using image_mono[OF **, of basis] using assms by auto
  5619       moreover
  5620       have "basis k \<in> span (?bas ` (insert k F))" by(rule span_superset, auto)
  5621       hence "x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5622         using span_mul by auto
  5623       ultimately
  5624       have "y + x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5625         using span_add by auto
  5626       thus ?case using y by auto
  5627     qed
  5628   }
  5629   hence "?A \<subseteq> span ?B" by auto
  5630   moreover
  5631   { fix x assume "x \<in> ?B"
  5632     hence "x\<in>{(basis i)::'a |i. i \<in> ?D}" using assms by auto  }
  5633   hence "independent ?B" using independent_mono[OF independent_basis, of ?B] and assms by auto
  5634   moreover
  5635   have "d \<subseteq> ?D" unfolding subset_eq using assms by auto
  5636   hence *:"inj_on (basis::nat\<Rightarrow>'a) d" using subset_inj_on[OF basis_inj, of "d"] by auto
  5637   have "card ?B = card d" unfolding card_image[OF *] by auto
  5638   ultimately show ?thesis using dim_unique[of "basis ` d" ?A] by auto
  5639 qed
  5640 
  5641 text{* Hence closure and completeness of all subspaces.                          *}
  5642 
  5643 lemma closed_subspace_lemma: "n \<le> card (UNIV::'n::finite set) \<Longrightarrow> \<exists>A::'n set. card A = n"
  5644 apply (induct n)
  5645 apply (rule_tac x="{}" in exI, simp)
  5646 apply clarsimp
  5647 apply (subgoal_tac "\<exists>x. x \<notin> A")
  5648 apply (erule exE)
  5649 apply (rule_tac x="insert x A" in exI, simp)
  5650 apply (subgoal_tac "A \<noteq> UNIV", auto)
  5651 done
  5652 
  5653 lemma closed_subspace: fixes s::"('a::euclidean_space) set"
  5654   assumes "subspace s" shows "closed s"
  5655 proof-
  5656   have *:"dim s \<le> DIM('a)" using dim_subset_UNIV by auto
  5657   def d \<equiv> "{..<dim s}" have t:"card d = dim s" unfolding d_def by auto
  5658   let ?t = "{x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0}"
  5659   have "\<exists>f. linear f \<and> f ` {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0} = s \<and>
  5660       inj_on f {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0}"
  5661     apply(rule subspace_isomorphism[OF subspace_substandard[of "\<lambda>i. i \<notin> d"]])
  5662     using dim_substandard[of d,where 'a='a] and t unfolding d_def using * assms by auto
  5663   then guess f apply-by(erule exE conjE)+ note f = this
  5664   interpret f: bounded_linear f using f unfolding linear_conv_bounded_linear by auto
  5665   have "\<forall>x\<in>?t. f x = 0 \<longrightarrow> x = 0" using f.zero using f(3)[unfolded inj_on_def]
  5666     by(erule_tac x=0 in ballE) auto
  5667   moreover have "closed ?t" using closed_substandard .
  5668   moreover have "subspace ?t" using subspace_substandard .
  5669   ultimately show ?thesis using closed_injective_image_subspace[of ?t f]
  5670     unfolding f(2) using f(1) unfolding linear_conv_bounded_linear by auto
  5671 qed
  5672 
  5673 lemma complete_subspace:
  5674   fixes s :: "('a::euclidean_space) set" shows "subspace s ==> complete s"
  5675   using complete_eq_closed closed_subspace
  5676   by auto
  5677 
  5678 lemma dim_closure:
  5679   fixes s :: "('a::euclidean_space) set"
  5680   shows "dim(closure s) = dim s" (is "?dc = ?d")
  5681 proof-
  5682   have "?dc \<le> ?d" using closure_minimal[OF span_inc, of s]
  5683     using closed_subspace[OF subspace_span, of s]
  5684     using dim_subset[of "closure s" "span s"] unfolding dim_span by auto
  5685   thus ?thesis using dim_subset[OF closure_subset, of s] by auto
  5686 qed
  5687 
  5688 
  5689 subsection {* Affine transformations of intervals *}
  5690 
  5691 lemma real_affinity_le:
  5692  "0 < (m::'a::linordered_field) ==> (m * x + c \<le> y \<longleftrightarrow> x \<le> inverse(m) * y + -(c / m))"
  5693   by (simp add: field_simps inverse_eq_divide)
  5694 
  5695 lemma real_le_affinity:
  5696  "0 < (m::'a::linordered_field) ==> (y \<le> m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) \<le> x)"
  5697   by (simp add: field_simps inverse_eq_divide)
  5698 
  5699 lemma real_affinity_lt:
  5700  "0 < (m::'a::linordered_field) ==> (m * x + c < y \<longleftrightarrow> x < inverse(m) * y + -(c / m))"
  5701   by (simp add: field_simps inverse_eq_divide)
  5702 
  5703 lemma real_lt_affinity:
  5704  "0 < (m::'a::linordered_field) ==> (y < m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) < x)"
  5705   by (simp add: field_simps inverse_eq_divide)
  5706 
  5707 lemma real_affinity_eq:
  5708  "(m::'a::linordered_field) \<noteq> 0 ==> (m * x + c = y \<longleftrightarrow> x = inverse(m) * y + -(c / m))"
  5709   by (simp add: field_simps inverse_eq_divide)
  5710 
  5711 lemma real_eq_affinity:
  5712  "(m::'a::linordered_field) \<noteq> 0 ==> (y = m * x + c  \<longleftrightarrow> inverse(m) * y + -(c / m) = x)"
  5713   by (simp add: field_simps inverse_eq_divide)
  5714 
  5715 lemma image_affinity_interval: fixes m::real
  5716   fixes a b c :: "'a::ordered_euclidean_space"
  5717   shows "(\<lambda>x. m *\<^sub>R x + c) ` {a .. b} =
  5718             (if {a .. b} = {} then {}
  5719             else (if 0 \<le> m then {m *\<^sub>R a + c .. m *\<^sub>R b + c}
  5720             else {m *\<^sub>R b + c .. m *\<^sub>R a + c}))"
  5721 proof(cases "m=0")  
  5722   { fix x assume "x \<le> c" "c \<le> x"
  5723     hence "x=c" unfolding eucl_le[where 'a='a] apply-
  5724       apply(subst euclidean_eq) by (auto intro: order_antisym) }
  5725   moreover case True
  5726   moreover have "c \<in> {m *\<^sub>R a + c..m *\<^sub>R b + c}" unfolding True by(auto simp add: eucl_le[where 'a='a])
  5727   ultimately show ?thesis by auto
  5728 next
  5729   case False
  5730   { fix y assume "a \<le> y" "y \<le> b" "m > 0"
  5731     hence "m *\<^sub>R a + c \<le> m *\<^sub>R y + c"  "m *\<^sub>R y + c \<le> m *\<^sub>R b + c"
  5732       unfolding eucl_le[where 'a='a] by(auto simp add: euclidean_simps)
  5733   } moreover
  5734   { fix y assume "a \<le> y" "y \<le> b" "m < 0"
  5735