src/HOL/Probability/Measure_Space.thy
author paulson <lp15@cam.ac.uk>
Tue Apr 21 17:19:00 2015 +0100 (2015-04-21)
changeset 60141 833adf7db7d8
parent 60063 81835db730e8
child 60142 3275dddf356f
permissions -rw-r--r--
New material, mostly about limits. Consolidation.
     1 (*  Title:      HOL/Probability/Measure_Space.thy
     2     Author:     Lawrence C Paulson
     3     Author:     Johannes Hölzl, TU München
     4     Author:     Armin Heller, TU München
     5 *)
     6 
     7 section {* Measure spaces and their properties *}
     8 
     9 theory Measure_Space
    10 imports
    11   Measurable "~~/src/HOL/Multivariate_Analysis/Multivariate_Analysis"
    12 begin
    13 
    14 subsection "Relate extended reals and the indicator function"
    15 
    16 lemma suminf_cmult_indicator:
    17   fixes f :: "nat \<Rightarrow> ereal"
    18   assumes "disjoint_family A" "x \<in> A i" "\<And>i. 0 \<le> f i"
    19   shows "(\<Sum>n. f n * indicator (A n) x) = f i"
    20 proof -
    21   have **: "\<And>n. f n * indicator (A n) x = (if n = i then f n else 0 :: ereal)"
    22     using `x \<in> A i` assms unfolding disjoint_family_on_def indicator_def by auto
    23   then have "\<And>n. (\<Sum>j<n. f j * indicator (A j) x) = (if i < n then f i else 0 :: ereal)"
    24     by (auto simp: setsum.If_cases)
    25   moreover have "(SUP n. if i < n then f i else 0) = (f i :: ereal)"
    26   proof (rule SUP_eqI)
    27     fix y :: ereal assume "\<And>n. n \<in> UNIV \<Longrightarrow> (if i < n then f i else 0) \<le> y"
    28     from this[of "Suc i"] show "f i \<le> y" by auto
    29   qed (insert assms, simp)
    30   ultimately show ?thesis using assms
    31     by (subst suminf_ereal_eq_SUP) (auto simp: indicator_def)
    32 qed
    33 
    34 lemma suminf_indicator:
    35   assumes "disjoint_family A"
    36   shows "(\<Sum>n. indicator (A n) x :: ereal) = indicator (\<Union>i. A i) x"
    37 proof cases
    38   assume *: "x \<in> (\<Union>i. A i)"
    39   then obtain i where "x \<in> A i" by auto
    40   from suminf_cmult_indicator[OF assms(1), OF `x \<in> A i`, of "\<lambda>k. 1"]
    41   show ?thesis using * by simp
    42 qed simp
    43 
    44 text {*
    45   The type for emeasure spaces is already defined in @{theory Sigma_Algebra}, as it is also used to
    46   represent sigma algebras (with an arbitrary emeasure).
    47 *}
    48 
    49 subsection "Extend binary sets"
    50 
    51 lemma LIMSEQ_binaryset:
    52   assumes f: "f {} = 0"
    53   shows  "(\<lambda>n. \<Sum>i<n. f (binaryset A B i)) ----> f A + f B"
    54 proof -
    55   have "(\<lambda>n. \<Sum>i < Suc (Suc n). f (binaryset A B i)) = (\<lambda>n. f A + f B)"
    56     proof
    57       fix n
    58       show "(\<Sum>i < Suc (Suc n). f (binaryset A B i)) = f A + f B"
    59         by (induct n)  (auto simp add: binaryset_def f)
    60     qed
    61   moreover
    62   have "... ----> f A + f B" by (rule tendsto_const)
    63   ultimately
    64   have "(\<lambda>n. \<Sum>i< Suc (Suc n). f (binaryset A B i)) ----> f A + f B"
    65     by metis
    66   hence "(\<lambda>n. \<Sum>i< n+2. f (binaryset A B i)) ----> f A + f B"
    67     by simp
    68   thus ?thesis by (rule LIMSEQ_offset [where k=2])
    69 qed
    70 
    71 lemma binaryset_sums:
    72   assumes f: "f {} = 0"
    73   shows  "(\<lambda>n. f (binaryset A B n)) sums (f A + f B)"
    74     by (simp add: sums_def LIMSEQ_binaryset [where f=f, OF f] atLeast0LessThan)
    75 
    76 lemma suminf_binaryset_eq:
    77   fixes f :: "'a set \<Rightarrow> 'b::{comm_monoid_add, t2_space}"
    78   shows "f {} = 0 \<Longrightarrow> (\<Sum>n. f (binaryset A B n)) = f A + f B"
    79   by (metis binaryset_sums sums_unique)
    80 
    81 subsection {* Properties of a premeasure @{term \<mu>} *}
    82 
    83 text {*
    84   The definitions for @{const positive} and @{const countably_additive} should be here, by they are
    85   necessary to define @{typ "'a measure"} in @{theory Sigma_Algebra}.
    86 *}
    87 
    88 definition additive where
    89   "additive M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> \<mu> (x \<union> y) = \<mu> x + \<mu> y)"
    90 
    91 definition increasing where
    92   "increasing M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<subseteq> y \<longrightarrow> \<mu> x \<le> \<mu> y)"
    93 
    94 lemma positiveD1: "positive M f \<Longrightarrow> f {} = 0" by (auto simp: positive_def)
    95 lemma positiveD2: "positive M f \<Longrightarrow> A \<in> M \<Longrightarrow> 0 \<le> f A" by (auto simp: positive_def)
    96 
    97 lemma positiveD_empty:
    98   "positive M f \<Longrightarrow> f {} = 0"
    99   by (auto simp add: positive_def)
   100 
   101 lemma additiveD:
   102   "additive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) = f x + f y"
   103   by (auto simp add: additive_def)
   104 
   105 lemma increasingD:
   106   "increasing M f \<Longrightarrow> x \<subseteq> y \<Longrightarrow> x\<in>M \<Longrightarrow> y\<in>M \<Longrightarrow> f x \<le> f y"
   107   by (auto simp add: increasing_def)
   108 
   109 lemma countably_additiveI[case_names countably]:
   110   "(\<And>A. range A \<subseteq> M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i. A i) \<in> M \<Longrightarrow> (\<Sum>i. f (A i)) = f (\<Union>i. A i))
   111   \<Longrightarrow> countably_additive M f"
   112   by (simp add: countably_additive_def)
   113 
   114 lemma (in ring_of_sets) disjointed_additive:
   115   assumes f: "positive M f" "additive M f" and A: "range A \<subseteq> M" "incseq A"
   116   shows "(\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   117 proof (induct n)
   118   case (Suc n)
   119   then have "(\<Sum>i\<le>Suc n. f (disjointed A i)) = f (A n) + f (disjointed A (Suc n))"
   120     by simp
   121   also have "\<dots> = f (A n \<union> disjointed A (Suc n))"
   122     using A by (subst f(2)[THEN additiveD]) (auto simp: disjointed_incseq)
   123   also have "A n \<union> disjointed A (Suc n) = A (Suc n)"
   124     using `incseq A` by (auto dest: incseq_SucD simp: disjointed_incseq)
   125   finally show ?case .
   126 qed simp
   127 
   128 lemma (in ring_of_sets) additive_sum:
   129   fixes A:: "'i \<Rightarrow> 'a set"
   130   assumes f: "positive M f" and ad: "additive M f" and "finite S"
   131       and A: "A`S \<subseteq> M"
   132       and disj: "disjoint_family_on A S"
   133   shows  "(\<Sum>i\<in>S. f (A i)) = f (\<Union>i\<in>S. A i)"
   134   using `finite S` disj A
   135 proof induct
   136   case empty show ?case using f by (simp add: positive_def)
   137 next
   138   case (insert s S)
   139   then have "A s \<inter> (\<Union>i\<in>S. A i) = {}"
   140     by (auto simp add: disjoint_family_on_def neq_iff)
   141   moreover
   142   have "A s \<in> M" using insert by blast
   143   moreover have "(\<Union>i\<in>S. A i) \<in> M"
   144     using insert `finite S` by auto
   145   ultimately have "f (A s \<union> (\<Union>i\<in>S. A i)) = f (A s) + f(\<Union>i\<in>S. A i)"
   146     using ad UNION_in_sets A by (auto simp add: additive_def)
   147   with insert show ?case using ad disjoint_family_on_mono[of S "insert s S" A]
   148     by (auto simp add: additive_def subset_insertI)
   149 qed
   150 
   151 lemma (in ring_of_sets) additive_increasing:
   152   assumes posf: "positive M f" and addf: "additive M f"
   153   shows "increasing M f"
   154 proof (auto simp add: increasing_def)
   155   fix x y
   156   assume xy: "x \<in> M" "y \<in> M" "x \<subseteq> y"
   157   then have "y - x \<in> M" by auto
   158   then have "0 \<le> f (y-x)" using posf[unfolded positive_def] by auto
   159   then have "f x + 0 \<le> f x + f (y-x)" by (intro add_left_mono) auto
   160   also have "... = f (x \<union> (y-x))" using addf
   161     by (auto simp add: additive_def) (metis Diff_disjoint Un_Diff_cancel Diff xy(1,2))
   162   also have "... = f y"
   163     by (metis Un_Diff_cancel Un_absorb1 xy(3))
   164   finally show "f x \<le> f y" by simp
   165 qed
   166 
   167 lemma (in ring_of_sets) subadditive:
   168   assumes f: "positive M f" "additive M f" and A: "range A \<subseteq> M" and S: "finite S"
   169   shows "f (\<Union>i\<in>S. A i) \<le> (\<Sum>i\<in>S. f (A i))"
   170 using S
   171 proof (induct S)
   172   case empty thus ?case using f by (auto simp: positive_def)
   173 next
   174   case (insert x F)
   175   hence in_M: "A x \<in> M" "(\<Union> i\<in>F. A i) \<in> M" "(\<Union> i\<in>F. A i) - A x \<in> M" using A by force+
   176   have subs: "(\<Union> i\<in>F. A i) - A x \<subseteq> (\<Union> i\<in>F. A i)" by auto
   177   have "(\<Union> i\<in>(insert x F). A i) = A x \<union> ((\<Union> i\<in>F. A i) - A x)" by auto
   178   hence "f (\<Union> i\<in>(insert x F). A i) = f (A x \<union> ((\<Union> i\<in>F. A i) - A x))"
   179     by simp
   180   also have "\<dots> = f (A x) + f ((\<Union> i\<in>F. A i) - A x)"
   181     using f(2) by (rule additiveD) (insert in_M, auto)
   182   also have "\<dots> \<le> f (A x) + f (\<Union> i\<in>F. A i)"
   183     using additive_increasing[OF f] in_M subs by (auto simp: increasing_def intro: add_left_mono)
   184   also have "\<dots> \<le> f (A x) + (\<Sum>i\<in>F. f (A i))" using insert by (auto intro: add_left_mono)
   185   finally show "f (\<Union> i\<in>(insert x F). A i) \<le> (\<Sum>i\<in>(insert x F). f (A i))" using insert by simp
   186 qed
   187 
   188 lemma (in ring_of_sets) countably_additive_additive:
   189   assumes posf: "positive M f" and ca: "countably_additive M f"
   190   shows "additive M f"
   191 proof (auto simp add: additive_def)
   192   fix x y
   193   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   194   hence "disjoint_family (binaryset x y)"
   195     by (auto simp add: disjoint_family_on_def binaryset_def)
   196   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   197          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   198          f (\<Union>i. binaryset x y i) = (\<Sum> n. f (binaryset x y n))"
   199     using ca
   200     by (simp add: countably_additive_def)
   201   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   202          f (x \<union> y) = (\<Sum>n. f (binaryset x y n))"
   203     by (simp add: range_binaryset_eq UN_binaryset_eq)
   204   thus "f (x \<union> y) = f x + f y" using posf x y
   205     by (auto simp add: Un suminf_binaryset_eq positive_def)
   206 qed
   207 
   208 lemma (in algebra) increasing_additive_bound:
   209   fixes A:: "nat \<Rightarrow> 'a set" and  f :: "'a set \<Rightarrow> ereal"
   210   assumes f: "positive M f" and ad: "additive M f"
   211       and inc: "increasing M f"
   212       and A: "range A \<subseteq> M"
   213       and disj: "disjoint_family A"
   214   shows  "(\<Sum>i. f (A i)) \<le> f \<Omega>"
   215 proof (safe intro!: suminf_bound)
   216   fix N
   217   note disj_N = disjoint_family_on_mono[OF _ disj, of "{..<N}"]
   218   have "(\<Sum>i<N. f (A i)) = f (\<Union>i\<in>{..<N}. A i)"
   219     using A by (intro additive_sum [OF f ad _ _]) (auto simp: disj_N)
   220   also have "... \<le> f \<Omega>" using space_closed A
   221     by (intro increasingD[OF inc] finite_UN) auto
   222   finally show "(\<Sum>i<N. f (A i)) \<le> f \<Omega>" by simp
   223 qed (insert f A, auto simp: positive_def)
   224 
   225 lemma (in ring_of_sets) countably_additiveI_finite:
   226   assumes "finite \<Omega>" "positive M \<mu>" "additive M \<mu>"
   227   shows "countably_additive M \<mu>"
   228 proof (rule countably_additiveI)
   229   fix F :: "nat \<Rightarrow> 'a set" assume F: "range F \<subseteq> M" "(\<Union>i. F i) \<in> M" and disj: "disjoint_family F"
   230 
   231   have "\<forall>i\<in>{i. F i \<noteq> {}}. \<exists>x. x \<in> F i" by auto
   232   from bchoice[OF this] obtain f where f: "\<And>i. F i \<noteq> {} \<Longrightarrow> f i \<in> F i" by auto
   233 
   234   have inj_f: "inj_on f {i. F i \<noteq> {}}"
   235   proof (rule inj_onI, simp)
   236     fix i j a b assume *: "f i = f j" "F i \<noteq> {}" "F j \<noteq> {}"
   237     then have "f i \<in> F i" "f j \<in> F j" using f by force+
   238     with disj * show "i = j" by (auto simp: disjoint_family_on_def)
   239   qed
   240   have "finite (\<Union>i. F i)"
   241     by (metis F(2) assms(1) infinite_super sets_into_space)
   242 
   243   have F_subset: "{i. \<mu> (F i) \<noteq> 0} \<subseteq> {i. F i \<noteq> {}}"
   244     by (auto simp: positiveD_empty[OF `positive M \<mu>`])
   245   moreover have fin_not_empty: "finite {i. F i \<noteq> {}}"
   246   proof (rule finite_imageD)
   247     from f have "f`{i. F i \<noteq> {}} \<subseteq> (\<Union>i. F i)" by auto
   248     then show "finite (f`{i. F i \<noteq> {}})"
   249       by (rule finite_subset) fact
   250   qed fact
   251   ultimately have fin_not_0: "finite {i. \<mu> (F i) \<noteq> 0}"
   252     by (rule finite_subset)
   253 
   254   have disj_not_empty: "disjoint_family_on F {i. F i \<noteq> {}}"
   255     using disj by (auto simp: disjoint_family_on_def)
   256 
   257   from fin_not_0 have "(\<Sum>i. \<mu> (F i)) = (\<Sum>i | \<mu> (F i) \<noteq> 0. \<mu> (F i))"
   258     by (rule suminf_finite) auto
   259   also have "\<dots> = (\<Sum>i | F i \<noteq> {}. \<mu> (F i))"
   260     using fin_not_empty F_subset by (rule setsum.mono_neutral_left) auto
   261   also have "\<dots> = \<mu> (\<Union>i\<in>{i. F i \<noteq> {}}. F i)"
   262     using `positive M \<mu>` `additive M \<mu>` fin_not_empty disj_not_empty F by (intro additive_sum) auto
   263   also have "\<dots> = \<mu> (\<Union>i. F i)"
   264     by (rule arg_cong[where f=\<mu>]) auto
   265   finally show "(\<Sum>i. \<mu> (F i)) = \<mu> (\<Union>i. F i)" .
   266 qed
   267 
   268 lemma (in ring_of_sets) countably_additive_iff_continuous_from_below:
   269   assumes f: "positive M f" "additive M f"
   270   shows "countably_additive M f \<longleftrightarrow>
   271     (\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Union>i. A i))"
   272   unfolding countably_additive_def
   273 proof safe
   274   assume count_sum: "\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> UNION UNIV A \<in> M \<longrightarrow> (\<Sum>i. f (A i)) = f (UNION UNIV A)"
   275   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   276   then have dA: "range (disjointed A) \<subseteq> M" by (auto simp: range_disjointed_sets)
   277   with count_sum[THEN spec, of "disjointed A"] A(3)
   278   have f_UN: "(\<Sum>i. f (disjointed A i)) = f (\<Union>i. A i)"
   279     by (auto simp: UN_disjointed_eq disjoint_family_disjointed)
   280   moreover have "(\<lambda>n. (\<Sum>i<n. f (disjointed A i))) ----> (\<Sum>i. f (disjointed A i))"
   281     using f(1)[unfolded positive_def] dA
   282     by (auto intro!: summable_LIMSEQ summable_ereal_pos)
   283   from LIMSEQ_Suc[OF this]
   284   have "(\<lambda>n. (\<Sum>i\<le>n. f (disjointed A i))) ----> (\<Sum>i. f (disjointed A i))"
   285     unfolding lessThan_Suc_atMost .
   286   moreover have "\<And>n. (\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   287     using disjointed_additive[OF f A(1,2)] .
   288   ultimately show "(\<lambda>i. f (A i)) ----> f (\<Union>i. A i)" by simp
   289 next
   290   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Union>i. A i)"
   291   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "disjoint_family A" "(\<Union>i. A i) \<in> M"
   292   have *: "(\<Union>n. (\<Union>i<n. A i)) = (\<Union>i. A i)" by auto
   293   have "(\<lambda>n. f (\<Union>i<n. A i)) ----> f (\<Union>i. A i)"
   294   proof (unfold *[symmetric], intro cont[rule_format])
   295     show "range (\<lambda>i. \<Union> i<i. A i) \<subseteq> M" "(\<Union>i. \<Union> i<i. A i) \<in> M"
   296       using A * by auto
   297   qed (force intro!: incseq_SucI)
   298   moreover have "\<And>n. f (\<Union>i<n. A i) = (\<Sum>i<n. f (A i))"
   299     using A
   300     by (intro additive_sum[OF f, of _ A, symmetric])
   301        (auto intro: disjoint_family_on_mono[where B=UNIV])
   302   ultimately
   303   have "(\<lambda>i. f (A i)) sums f (\<Union>i. A i)"
   304     unfolding sums_def by simp
   305   from sums_unique[OF this]
   306   show "(\<Sum>i. f (A i)) = f (\<Union>i. A i)" by simp
   307 qed
   308 
   309 lemma (in ring_of_sets) continuous_from_above_iff_empty_continuous:
   310   assumes f: "positive M f" "additive M f"
   311   shows "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Inter>i. A i))
   312      \<longleftrightarrow> (\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> 0)"
   313 proof safe
   314   assume cont: "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> f (\<Inter>i. A i))"
   315   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) = {}" "\<forall>i. f (A i) \<noteq> \<infinity>"
   316   with cont[THEN spec, of A] show "(\<lambda>i. f (A i)) ----> 0"
   317     using `positive M f`[unfolded positive_def] by auto
   318 next
   319   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) ----> 0"
   320   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) \<in> M" "\<forall>i. f (A i) \<noteq> \<infinity>"
   321 
   322   have f_mono: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<subseteq> b \<Longrightarrow> f a \<le> f b"
   323     using additive_increasing[OF f] unfolding increasing_def by simp
   324 
   325   have decseq_fA: "decseq (\<lambda>i. f (A i))"
   326     using A by (auto simp: decseq_def intro!: f_mono)
   327   have decseq: "decseq (\<lambda>i. A i - (\<Inter>i. A i))"
   328     using A by (auto simp: decseq_def)
   329   then have decseq_f: "decseq (\<lambda>i. f (A i - (\<Inter>i. A i)))"
   330     using A unfolding decseq_def by (auto intro!: f_mono Diff)
   331   have "f (\<Inter>x. A x) \<le> f (A 0)"
   332     using A by (auto intro!: f_mono)
   333   then have f_Int_fin: "f (\<Inter>x. A x) \<noteq> \<infinity>"
   334     using A by auto
   335   { fix i
   336     have "f (A i - (\<Inter>i. A i)) \<le> f (A i)" using A by (auto intro!: f_mono)
   337     then have "f (A i - (\<Inter>i. A i)) \<noteq> \<infinity>"
   338       using A by auto }
   339   note f_fin = this
   340   have "(\<lambda>i. f (A i - (\<Inter>i. A i))) ----> 0"
   341   proof (intro cont[rule_format, OF _ decseq _ f_fin])
   342     show "range (\<lambda>i. A i - (\<Inter>i. A i)) \<subseteq> M" "(\<Inter>i. A i - (\<Inter>i. A i)) = {}"
   343       using A by auto
   344   qed
   345   from INF_Lim_ereal[OF decseq_f this]
   346   have "(INF n. f (A n - (\<Inter>i. A i))) = 0" .
   347   moreover have "(INF n. f (\<Inter>i. A i)) = f (\<Inter>i. A i)"
   348     by auto
   349   ultimately have "(INF n. f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i)) = 0 + f (\<Inter>i. A i)"
   350     using A(4) f_fin f_Int_fin
   351     by (subst INF_ereal_add) (auto simp: decseq_f)
   352   moreover {
   353     fix n
   354     have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f ((A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i))"
   355       using A by (subst f(2)[THEN additiveD]) auto
   356     also have "(A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i) = A n"
   357       by auto
   358     finally have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f (A n)" . }
   359   ultimately have "(INF n. f (A n)) = f (\<Inter>i. A i)"
   360     by simp
   361   with LIMSEQ_INF[OF decseq_fA]
   362   show "(\<lambda>i. f (A i)) ----> f (\<Inter>i. A i)" by simp
   363 qed
   364 
   365 lemma (in ring_of_sets) empty_continuous_imp_continuous_from_below:
   366   assumes f: "positive M f" "additive M f" "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   367   assumes cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<lambda>i. f (A i)) ----> 0"
   368   assumes A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   369   shows "(\<lambda>i. f (A i)) ----> f (\<Union>i. A i)"
   370 proof -
   371   have "\<forall>A\<in>M. \<exists>x. f A = ereal x"
   372   proof
   373     fix A assume "A \<in> M" with f show "\<exists>x. f A = ereal x"
   374       unfolding positive_def by (cases "f A") auto
   375   qed
   376   from bchoice[OF this] guess f' .. note f' = this[rule_format]
   377   from A have "(\<lambda>i. f ((\<Union>i. A i) - A i)) ----> 0"
   378     by (intro cont[rule_format]) (auto simp: decseq_def incseq_def)
   379   moreover
   380   { fix i
   381     have "f ((\<Union>i. A i) - A i) + f (A i) = f ((\<Union>i. A i) - A i \<union> A i)"
   382       using A by (intro f(2)[THEN additiveD, symmetric]) auto
   383     also have "(\<Union>i. A i) - A i \<union> A i = (\<Union>i. A i)"
   384       by auto
   385     finally have "f' (\<Union>i. A i) - f' (A i) = f' ((\<Union>i. A i) - A i)"
   386       using A by (subst (asm) (1 2 3) f') auto
   387     then have "f ((\<Union>i. A i) - A i) = ereal (f' (\<Union>i. A i) - f' (A i))"
   388       using A f' by auto }
   389   ultimately have "(\<lambda>i. f' (\<Union>i. A i) - f' (A i)) ----> 0"
   390     by (simp add: zero_ereal_def)
   391   then have "(\<lambda>i. f' (A i)) ----> f' (\<Union>i. A i)"
   392     by (rule Lim_transform[OF tendsto_const])
   393   then show "(\<lambda>i. f (A i)) ----> f (\<Union>i. A i)"
   394     using A by (subst (1 2) f') auto
   395 qed
   396 
   397 lemma (in ring_of_sets) empty_continuous_imp_countably_additive:
   398   assumes f: "positive M f" "additive M f" and fin: "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   399   assumes cont: "\<And>A. range A \<subseteq> M \<Longrightarrow> decseq A \<Longrightarrow> (\<Inter>i. A i) = {} \<Longrightarrow> (\<lambda>i. f (A i)) ----> 0"
   400   shows "countably_additive M f"
   401   using countably_additive_iff_continuous_from_below[OF f]
   402   using empty_continuous_imp_continuous_from_below[OF f fin] cont
   403   by blast
   404 
   405 subsection {* Properties of @{const emeasure} *}
   406 
   407 lemma emeasure_positive: "positive (sets M) (emeasure M)"
   408   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   409 
   410 lemma emeasure_empty[simp, intro]: "emeasure M {} = 0"
   411   using emeasure_positive[of M] by (simp add: positive_def)
   412 
   413 lemma emeasure_nonneg[intro!]: "0 \<le> emeasure M A"
   414   using emeasure_notin_sets[of A M] emeasure_positive[of M]
   415   by (cases "A \<in> sets M") (auto simp: positive_def)
   416 
   417 lemma emeasure_not_MInf[simp]: "emeasure M A \<noteq> - \<infinity>"
   418   using emeasure_nonneg[of M A] by auto
   419 
   420 lemma emeasure_le_0_iff: "emeasure M A \<le> 0 \<longleftrightarrow> emeasure M A = 0"
   421   using emeasure_nonneg[of M A] by auto
   422 
   423 lemma emeasure_less_0_iff: "emeasure M A < 0 \<longleftrightarrow> False"
   424   using emeasure_nonneg[of M A] by auto
   425 
   426 lemma emeasure_single_in_space: "emeasure M {x} \<noteq> 0 \<Longrightarrow> x \<in> space M"
   427   using emeasure_notin_sets[of "{x}" M] by (auto dest: sets.sets_into_space)
   428 
   429 lemma emeasure_countably_additive: "countably_additive (sets M) (emeasure M)"
   430   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   431 
   432 lemma suminf_emeasure:
   433   "range A \<subseteq> sets M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
   434   using sets.countable_UN[of A UNIV M] emeasure_countably_additive[of M]
   435   by (simp add: countably_additive_def)
   436 
   437 lemma sums_emeasure:
   438   "disjoint_family F \<Longrightarrow> (\<And>i. F i \<in> sets M) \<Longrightarrow> (\<lambda>i. emeasure M (F i)) sums emeasure M (\<Union>i. F i)"
   439   unfolding sums_iff by (intro conjI summable_ereal_pos emeasure_nonneg suminf_emeasure) auto
   440 
   441 lemma emeasure_additive: "additive (sets M) (emeasure M)"
   442   by (metis sets.countably_additive_additive emeasure_positive emeasure_countably_additive)
   443 
   444 lemma plus_emeasure:
   445   "a \<in> sets M \<Longrightarrow> b \<in> sets M \<Longrightarrow> a \<inter> b = {} \<Longrightarrow> emeasure M a + emeasure M b = emeasure M (a \<union> b)"
   446   using additiveD[OF emeasure_additive] ..
   447 
   448 lemma setsum_emeasure:
   449   "F`I \<subseteq> sets M \<Longrightarrow> disjoint_family_on F I \<Longrightarrow> finite I \<Longrightarrow>
   450     (\<Sum>i\<in>I. emeasure M (F i)) = emeasure M (\<Union>i\<in>I. F i)"
   451   by (metis sets.additive_sum emeasure_positive emeasure_additive)
   452 
   453 lemma emeasure_mono:
   454   "a \<subseteq> b \<Longrightarrow> b \<in> sets M \<Longrightarrow> emeasure M a \<le> emeasure M b"
   455   by (metis sets.additive_increasing emeasure_additive emeasure_nonneg emeasure_notin_sets
   456             emeasure_positive increasingD)
   457 
   458 lemma emeasure_space:
   459   "emeasure M A \<le> emeasure M (space M)"
   460   by (metis emeasure_mono emeasure_nonneg emeasure_notin_sets sets.sets_into_space sets.top)
   461 
   462 lemma emeasure_compl:
   463   assumes s: "s \<in> sets M" and fin: "emeasure M s \<noteq> \<infinity>"
   464   shows "emeasure M (space M - s) = emeasure M (space M) - emeasure M s"
   465 proof -
   466   from s have "0 \<le> emeasure M s" by auto
   467   have "emeasure M (space M) = emeasure M (s \<union> (space M - s))" using s
   468     by (metis Un_Diff_cancel Un_absorb1 s sets.sets_into_space)
   469   also have "... = emeasure M s + emeasure M (space M - s)"
   470     by (rule plus_emeasure[symmetric]) (auto simp add: s)
   471   finally have "emeasure M (space M) = emeasure M s + emeasure M (space M - s)" .
   472   then show ?thesis
   473     using fin `0 \<le> emeasure M s`
   474     unfolding ereal_eq_minus_iff by (auto simp: ac_simps)
   475 qed
   476 
   477 lemma emeasure_Diff:
   478   assumes finite: "emeasure M B \<noteq> \<infinity>"
   479   and [measurable]: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
   480   shows "emeasure M (A - B) = emeasure M A - emeasure M B"
   481 proof -
   482   have "0 \<le> emeasure M B" using assms by auto
   483   have "(A - B) \<union> B = A" using `B \<subseteq> A` by auto
   484   then have "emeasure M A = emeasure M ((A - B) \<union> B)" by simp
   485   also have "\<dots> = emeasure M (A - B) + emeasure M B"
   486     by (subst plus_emeasure[symmetric]) auto
   487   finally show "emeasure M (A - B) = emeasure M A - emeasure M B"
   488     unfolding ereal_eq_minus_iff
   489     using finite `0 \<le> emeasure M B` by auto
   490 qed
   491 
   492 lemma Lim_emeasure_incseq:
   493   "range A \<subseteq> sets M \<Longrightarrow> incseq A \<Longrightarrow> (\<lambda>i. (emeasure M (A i))) ----> emeasure M (\<Union>i. A i)"
   494   using emeasure_countably_additive
   495   by (auto simp add: sets.countably_additive_iff_continuous_from_below emeasure_positive
   496     emeasure_additive)
   497 
   498 lemma incseq_emeasure:
   499   assumes "range B \<subseteq> sets M" "incseq B"
   500   shows "incseq (\<lambda>i. emeasure M (B i))"
   501   using assms by (auto simp: incseq_def intro!: emeasure_mono)
   502 
   503 lemma SUP_emeasure_incseq:
   504   assumes A: "range A \<subseteq> sets M" "incseq A"
   505   shows "(SUP n. emeasure M (A n)) = emeasure M (\<Union>i. A i)"
   506   using LIMSEQ_SUP[OF incseq_emeasure, OF A] Lim_emeasure_incseq[OF A]
   507   by (simp add: LIMSEQ_unique)
   508 
   509 lemma decseq_emeasure:
   510   assumes "range B \<subseteq> sets M" "decseq B"
   511   shows "decseq (\<lambda>i. emeasure M (B i))"
   512   using assms by (auto simp: decseq_def intro!: emeasure_mono)
   513 
   514 lemma INF_emeasure_decseq:
   515   assumes A: "range A \<subseteq> sets M" and "decseq A"
   516   and finite: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   517   shows "(INF n. emeasure M (A n)) = emeasure M (\<Inter>i. A i)"
   518 proof -
   519   have le_MI: "emeasure M (\<Inter>i. A i) \<le> emeasure M (A 0)"
   520     using A by (auto intro!: emeasure_mono)
   521   hence *: "emeasure M (\<Inter>i. A i) \<noteq> \<infinity>" using finite[of 0] by auto
   522 
   523   have A0: "0 \<le> emeasure M (A 0)" using A by auto
   524 
   525   have "emeasure M (A 0) - (INF n. emeasure M (A n)) = emeasure M (A 0) + (SUP n. - emeasure M (A n))"
   526     by (simp add: ereal_SUP_uminus minus_ereal_def)
   527   also have "\<dots> = (SUP n. emeasure M (A 0) - emeasure M (A n))"
   528     unfolding minus_ereal_def using A0 assms
   529     by (subst SUP_ereal_add) (auto simp add: decseq_emeasure)
   530   also have "\<dots> = (SUP n. emeasure M (A 0 - A n))"
   531     using A finite `decseq A`[unfolded decseq_def] by (subst emeasure_Diff) auto
   532   also have "\<dots> = emeasure M (\<Union>i. A 0 - A i)"
   533   proof (rule SUP_emeasure_incseq)
   534     show "range (\<lambda>n. A 0 - A n) \<subseteq> sets M"
   535       using A by auto
   536     show "incseq (\<lambda>n. A 0 - A n)"
   537       using `decseq A` by (auto simp add: incseq_def decseq_def)
   538   qed
   539   also have "\<dots> = emeasure M (A 0) - emeasure M (\<Inter>i. A i)"
   540     using A finite * by (simp, subst emeasure_Diff) auto
   541   finally show ?thesis
   542     unfolding ereal_minus_eq_minus_iff using finite A0 by auto
   543 qed
   544 
   545 lemma Lim_emeasure_decseq:
   546   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   547   shows "(\<lambda>i. emeasure M (A i)) ----> emeasure M (\<Inter>i. A i)"
   548   using LIMSEQ_INF[OF decseq_emeasure, OF A]
   549   using INF_emeasure_decseq[OF A fin] by simp
   550 
   551 lemma emeasure_lfp[consumes 1, case_names cont measurable]:
   552   assumes "P M"
   553   assumes cont: "Order_Continuity.continuous F"
   554   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
   555   shows "emeasure M {x\<in>space M. lfp F x} = (SUP i. emeasure M {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   556 proof -
   557   have "emeasure M {x\<in>space M. lfp F x} = emeasure M (\<Union>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   558     using continuous_lfp[OF cont] by (auto simp add: bot_fun_def intro!: arg_cong2[where f=emeasure])
   559   moreover { fix i from `P M` have "{x\<in>space M. (F ^^ i) (\<lambda>x. False) x} \<in> sets M"
   560     by (induct i arbitrary: M) (auto simp add: pred_def[symmetric] intro: *) }
   561   moreover have "incseq (\<lambda>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   562   proof (rule incseq_SucI)
   563     fix i
   564     have "(F ^^ i) (\<lambda>x. False) \<le> (F ^^ (Suc i)) (\<lambda>x. False)"
   565     proof (induct i)
   566       case 0 show ?case by (simp add: le_fun_def)
   567     next
   568       case Suc thus ?case using monoD[OF continuous_mono[OF cont] Suc] by auto
   569     qed
   570     then show "{x \<in> space M. (F ^^ i) (\<lambda>x. False) x} \<subseteq> {x \<in> space M. (F ^^ Suc i) (\<lambda>x. False) x}"
   571       by auto
   572   qed
   573   ultimately show ?thesis
   574     by (subst SUP_emeasure_incseq) auto
   575 qed
   576 
   577 lemma emeasure_subadditive:
   578   assumes [measurable]: "A \<in> sets M" "B \<in> sets M"
   579   shows "emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   580 proof -
   581   from plus_emeasure[of A M "B - A"]
   582   have "emeasure M (A \<union> B) = emeasure M A + emeasure M (B - A)" by simp
   583   also have "\<dots> \<le> emeasure M A + emeasure M B"
   584     using assms by (auto intro!: add_left_mono emeasure_mono)
   585   finally show ?thesis .
   586 qed
   587 
   588 lemma emeasure_subadditive_finite:
   589   assumes "finite I" "A ` I \<subseteq> sets M"
   590   shows "emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
   591 using assms proof induct
   592   case (insert i I)
   593   then have "emeasure M (\<Union>i\<in>insert i I. A i) = emeasure M (A i \<union> (\<Union>i\<in>I. A i))"
   594     by simp
   595   also have "\<dots> \<le> emeasure M (A i) + emeasure M (\<Union>i\<in>I. A i)"
   596     using insert by (intro emeasure_subadditive) auto
   597   also have "\<dots> \<le> emeasure M (A i) + (\<Sum>i\<in>I. emeasure M (A i))"
   598     using insert by (intro add_mono) auto
   599   also have "\<dots> = (\<Sum>i\<in>insert i I. emeasure M (A i))"
   600     using insert by auto
   601   finally show ?case .
   602 qed simp
   603 
   604 lemma emeasure_subadditive_countably:
   605   assumes "range f \<subseteq> sets M"
   606   shows "emeasure M (\<Union>i. f i) \<le> (\<Sum>i. emeasure M (f i))"
   607 proof -
   608   have "emeasure M (\<Union>i. f i) = emeasure M (\<Union>i. disjointed f i)"
   609     unfolding UN_disjointed_eq ..
   610   also have "\<dots> = (\<Sum>i. emeasure M (disjointed f i))"
   611     using sets.range_disjointed_sets[OF assms] suminf_emeasure[of "disjointed f"]
   612     by (simp add:  disjoint_family_disjointed comp_def)
   613   also have "\<dots> \<le> (\<Sum>i. emeasure M (f i))"
   614     using sets.range_disjointed_sets[OF assms] assms
   615     by (auto intro!: suminf_le_pos emeasure_mono disjointed_subset)
   616   finally show ?thesis .
   617 qed
   618 
   619 lemma emeasure_insert:
   620   assumes sets: "{x} \<in> sets M" "A \<in> sets M" and "x \<notin> A"
   621   shows "emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   622 proof -
   623   have "{x} \<inter> A = {}" using `x \<notin> A` by auto
   624   from plus_emeasure[OF sets this] show ?thesis by simp
   625 qed
   626 
   627 lemma emeasure_insert_ne:
   628   "A \<noteq> {} \<Longrightarrow> {x} \<in> sets M \<Longrightarrow> A \<in> sets M \<Longrightarrow> x \<notin> A \<Longrightarrow> emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   629   by (rule emeasure_insert) 
   630 
   631 lemma emeasure_eq_setsum_singleton:
   632   assumes "finite S" "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
   633   shows "emeasure M S = (\<Sum>x\<in>S. emeasure M {x})"
   634   using setsum_emeasure[of "\<lambda>x. {x}" S M] assms
   635   by (auto simp: disjoint_family_on_def subset_eq)
   636 
   637 lemma setsum_emeasure_cover:
   638   assumes "finite S" and "A \<in> sets M" and br_in_M: "B ` S \<subseteq> sets M"
   639   assumes A: "A \<subseteq> (\<Union>i\<in>S. B i)"
   640   assumes disj: "disjoint_family_on B S"
   641   shows "emeasure M A = (\<Sum>i\<in>S. emeasure M (A \<inter> (B i)))"
   642 proof -
   643   have "(\<Sum>i\<in>S. emeasure M (A \<inter> (B i))) = emeasure M (\<Union>i\<in>S. A \<inter> (B i))"
   644   proof (rule setsum_emeasure)
   645     show "disjoint_family_on (\<lambda>i. A \<inter> B i) S"
   646       using `disjoint_family_on B S`
   647       unfolding disjoint_family_on_def by auto
   648   qed (insert assms, auto)
   649   also have "(\<Union>i\<in>S. A \<inter> (B i)) = A"
   650     using A by auto
   651   finally show ?thesis by simp
   652 qed
   653 
   654 lemma emeasure_eq_0:
   655   "N \<in> sets M \<Longrightarrow> emeasure M N = 0 \<Longrightarrow> K \<subseteq> N \<Longrightarrow> emeasure M K = 0"
   656   by (metis emeasure_mono emeasure_nonneg order_eq_iff)
   657 
   658 lemma emeasure_UN_eq_0:
   659   assumes "\<And>i::nat. emeasure M (N i) = 0" and "range N \<subseteq> sets M"
   660   shows "emeasure M (\<Union> i. N i) = 0"
   661 proof -
   662   have "0 \<le> emeasure M (\<Union> i. N i)" using assms by auto
   663   moreover have "emeasure M (\<Union> i. N i) \<le> 0"
   664     using emeasure_subadditive_countably[OF assms(2)] assms(1) by simp
   665   ultimately show ?thesis by simp
   666 qed
   667 
   668 lemma measure_eqI_finite:
   669   assumes [simp]: "sets M = Pow A" "sets N = Pow A" and "finite A"
   670   assumes eq: "\<And>a. a \<in> A \<Longrightarrow> emeasure M {a} = emeasure N {a}"
   671   shows "M = N"
   672 proof (rule measure_eqI)
   673   fix X assume "X \<in> sets M"
   674   then have X: "X \<subseteq> A" by auto
   675   then have "emeasure M X = (\<Sum>a\<in>X. emeasure M {a})"
   676     using `finite A` by (subst emeasure_eq_setsum_singleton) (auto dest: finite_subset)
   677   also have "\<dots> = (\<Sum>a\<in>X. emeasure N {a})"
   678     using X eq by (auto intro!: setsum.cong)
   679   also have "\<dots> = emeasure N X"
   680     using X `finite A` by (subst emeasure_eq_setsum_singleton) (auto dest: finite_subset)
   681   finally show "emeasure M X = emeasure N X" .
   682 qed simp
   683 
   684 lemma measure_eqI_generator_eq:
   685   fixes M N :: "'a measure" and E :: "'a set set" and A :: "nat \<Rightarrow> 'a set"
   686   assumes "Int_stable E" "E \<subseteq> Pow \<Omega>"
   687   and eq: "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
   688   and M: "sets M = sigma_sets \<Omega> E"
   689   and N: "sets N = sigma_sets \<Omega> E"
   690   and A: "range A \<subseteq> E" "(\<Union>i. A i) = \<Omega>" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   691   shows "M = N"
   692 proof -
   693   let ?\<mu>  = "emeasure M" and ?\<nu> = "emeasure N"
   694   interpret S: sigma_algebra \<Omega> "sigma_sets \<Omega> E" by (rule sigma_algebra_sigma_sets) fact
   695   have "space M = \<Omega>"
   696     using sets.top[of M] sets.space_closed[of M] S.top S.space_closed `sets M = sigma_sets \<Omega> E`
   697     by blast
   698 
   699   { fix F D assume "F \<in> E" and "?\<mu> F \<noteq> \<infinity>"
   700     then have [intro]: "F \<in> sigma_sets \<Omega> E" by auto
   701     have "?\<nu> F \<noteq> \<infinity>" using `?\<mu> F \<noteq> \<infinity>` `F \<in> E` eq by simp
   702     assume "D \<in> sets M"
   703     with `Int_stable E` `E \<subseteq> Pow \<Omega>` have "emeasure M (F \<inter> D) = emeasure N (F \<inter> D)"
   704       unfolding M
   705     proof (induct rule: sigma_sets_induct_disjoint)
   706       case (basic A)
   707       then have "F \<inter> A \<in> E" using `Int_stable E` `F \<in> E` by (auto simp: Int_stable_def)
   708       then show ?case using eq by auto
   709     next
   710       case empty then show ?case by simp
   711     next
   712       case (compl A)
   713       then have **: "F \<inter> (\<Omega> - A) = F - (F \<inter> A)"
   714         and [intro]: "F \<inter> A \<in> sigma_sets \<Omega> E"
   715         using `F \<in> E` S.sets_into_space by (auto simp: M)
   716       have "?\<nu> (F \<inter> A) \<le> ?\<nu> F" by (auto intro!: emeasure_mono simp: M N)
   717       then have "?\<nu> (F \<inter> A) \<noteq> \<infinity>" using `?\<nu> F \<noteq> \<infinity>` by auto
   718       have "?\<mu> (F \<inter> A) \<le> ?\<mu> F" by (auto intro!: emeasure_mono simp: M N)
   719       then have "?\<mu> (F \<inter> A) \<noteq> \<infinity>" using `?\<mu> F \<noteq> \<infinity>` by auto
   720       then have "?\<mu> (F \<inter> (\<Omega> - A)) = ?\<mu> F - ?\<mu> (F \<inter> A)" unfolding **
   721         using `F \<inter> A \<in> sigma_sets \<Omega> E` by (auto intro!: emeasure_Diff simp: M N)
   722       also have "\<dots> = ?\<nu> F - ?\<nu> (F \<inter> A)" using eq `F \<in> E` compl by simp
   723       also have "\<dots> = ?\<nu> (F \<inter> (\<Omega> - A))" unfolding **
   724         using `F \<inter> A \<in> sigma_sets \<Omega> E` `?\<nu> (F \<inter> A) \<noteq> \<infinity>`
   725         by (auto intro!: emeasure_Diff[symmetric] simp: M N)
   726       finally show ?case
   727         using `space M = \<Omega>` by auto
   728     next
   729       case (union A)
   730       then have "?\<mu> (\<Union>x. F \<inter> A x) = ?\<nu> (\<Union>x. F \<inter> A x)"
   731         by (subst (1 2) suminf_emeasure[symmetric]) (auto simp: disjoint_family_on_def subset_eq M N)
   732       with A show ?case
   733         by auto
   734     qed }
   735   note * = this
   736   show "M = N"
   737   proof (rule measure_eqI)
   738     show "sets M = sets N"
   739       using M N by simp
   740     have [simp, intro]: "\<And>i. A i \<in> sets M"
   741       using A(1) by (auto simp: subset_eq M)
   742     fix F assume "F \<in> sets M"
   743     let ?D = "disjointed (\<lambda>i. F \<inter> A i)"
   744     from `space M = \<Omega>` have F_eq: "F = (\<Union>i. ?D i)"
   745       using `F \<in> sets M`[THEN sets.sets_into_space] A(2)[symmetric] by (auto simp: UN_disjointed_eq)
   746     have [simp, intro]: "\<And>i. ?D i \<in> sets M"
   747       using sets.range_disjointed_sets[of "\<lambda>i. F \<inter> A i" M] `F \<in> sets M`
   748       by (auto simp: subset_eq)
   749     have "disjoint_family ?D"
   750       by (auto simp: disjoint_family_disjointed)
   751     moreover
   752     have "(\<Sum>i. emeasure M (?D i)) = (\<Sum>i. emeasure N (?D i))"
   753     proof (intro arg_cong[where f=suminf] ext)
   754       fix i
   755       have "A i \<inter> ?D i = ?D i"
   756         by (auto simp: disjointed_def)
   757       then show "emeasure M (?D i) = emeasure N (?D i)"
   758         using *[of "A i" "?D i", OF _ A(3)] A(1) by auto
   759     qed
   760     ultimately show "emeasure M F = emeasure N F"
   761       by (simp add: image_subset_iff `sets M = sets N`[symmetric] F_eq[symmetric] suminf_emeasure)
   762   qed
   763 qed
   764 
   765 lemma measure_of_of_measure: "measure_of (space M) (sets M) (emeasure M) = M"
   766 proof (intro measure_eqI emeasure_measure_of_sigma)
   767   show "sigma_algebra (space M) (sets M)" ..
   768   show "positive (sets M) (emeasure M)"
   769     by (simp add: positive_def emeasure_nonneg)
   770   show "countably_additive (sets M) (emeasure M)"
   771     by (simp add: emeasure_countably_additive)
   772 qed simp_all
   773 
   774 subsection {* @{text \<mu>}-null sets *}
   775 
   776 definition null_sets :: "'a measure \<Rightarrow> 'a set set" where
   777   "null_sets M = {N\<in>sets M. emeasure M N = 0}"
   778 
   779 lemma null_setsD1[dest]: "A \<in> null_sets M \<Longrightarrow> emeasure M A = 0"
   780   by (simp add: null_sets_def)
   781 
   782 lemma null_setsD2[dest]: "A \<in> null_sets M \<Longrightarrow> A \<in> sets M"
   783   unfolding null_sets_def by simp
   784 
   785 lemma null_setsI[intro]: "emeasure M A = 0 \<Longrightarrow> A \<in> sets M \<Longrightarrow> A \<in> null_sets M"
   786   unfolding null_sets_def by simp
   787 
   788 interpretation null_sets: ring_of_sets "space M" "null_sets M" for M
   789 proof (rule ring_of_setsI)
   790   show "null_sets M \<subseteq> Pow (space M)"
   791     using sets.sets_into_space by auto
   792   show "{} \<in> null_sets M"
   793     by auto
   794   fix A B assume null_sets: "A \<in> null_sets M" "B \<in> null_sets M"
   795   then have sets: "A \<in> sets M" "B \<in> sets M"
   796     by auto
   797   then have *: "emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   798     "emeasure M (A - B) \<le> emeasure M A"
   799     by (auto intro!: emeasure_subadditive emeasure_mono)
   800   then have "emeasure M B = 0" "emeasure M A = 0"
   801     using null_sets by auto
   802   with sets * show "A - B \<in> null_sets M" "A \<union> B \<in> null_sets M"
   803     by (auto intro!: antisym)
   804 qed
   805 
   806 lemma UN_from_nat_into: 
   807   assumes I: "countable I" "I \<noteq> {}"
   808   shows "(\<Union>i\<in>I. N i) = (\<Union>i. N (from_nat_into I i))"
   809 proof -
   810   have "(\<Union>i\<in>I. N i) = \<Union>(N ` range (from_nat_into I))"
   811     using I by simp
   812   also have "\<dots> = (\<Union>i. (N \<circ> from_nat_into I) i)"
   813     by (simp only: SUP_def image_comp)
   814   finally show ?thesis by simp
   815 qed
   816 
   817 lemma null_sets_UN':
   818   assumes "countable I"
   819   assumes "\<And>i. i \<in> I \<Longrightarrow> N i \<in> null_sets M"
   820   shows "(\<Union>i\<in>I. N i) \<in> null_sets M"
   821 proof cases
   822   assume "I = {}" then show ?thesis by simp
   823 next
   824   assume "I \<noteq> {}"
   825   show ?thesis
   826   proof (intro conjI CollectI null_setsI)
   827     show "(\<Union>i\<in>I. N i) \<in> sets M"
   828       using assms by (intro sets.countable_UN') auto
   829     have "emeasure M (\<Union>i\<in>I. N i) \<le> (\<Sum>n. emeasure M (N (from_nat_into I n)))"
   830       unfolding UN_from_nat_into[OF `countable I` `I \<noteq> {}`]
   831       using assms `I \<noteq> {}` by (intro emeasure_subadditive_countably) (auto intro: from_nat_into)
   832     also have "(\<lambda>n. emeasure M (N (from_nat_into I n))) = (\<lambda>_. 0)"
   833       using assms `I \<noteq> {}` by (auto intro: from_nat_into)
   834     finally show "emeasure M (\<Union>i\<in>I. N i) = 0"
   835       by (intro antisym emeasure_nonneg) simp
   836   qed
   837 qed
   838 
   839 lemma null_sets_UN[intro]:
   840   "(\<And>i::'i::countable. N i \<in> null_sets M) \<Longrightarrow> (\<Union>i. N i) \<in> null_sets M"
   841   by (rule null_sets_UN') auto
   842 
   843 lemma null_set_Int1:
   844   assumes "B \<in> null_sets M" "A \<in> sets M" shows "A \<inter> B \<in> null_sets M"
   845 proof (intro CollectI conjI null_setsI)
   846   show "emeasure M (A \<inter> B) = 0" using assms
   847     by (intro emeasure_eq_0[of B _ "A \<inter> B"]) auto
   848 qed (insert assms, auto)
   849 
   850 lemma null_set_Int2:
   851   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B \<inter> A \<in> null_sets M"
   852   using assms by (subst Int_commute) (rule null_set_Int1)
   853 
   854 lemma emeasure_Diff_null_set:
   855   assumes "B \<in> null_sets M" "A \<in> sets M"
   856   shows "emeasure M (A - B) = emeasure M A"
   857 proof -
   858   have *: "A - B = (A - (A \<inter> B))" by auto
   859   have "A \<inter> B \<in> null_sets M" using assms by (rule null_set_Int1)
   860   then show ?thesis
   861     unfolding * using assms
   862     by (subst emeasure_Diff) auto
   863 qed
   864 
   865 lemma null_set_Diff:
   866   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B - A \<in> null_sets M"
   867 proof (intro CollectI conjI null_setsI)
   868   show "emeasure M (B - A) = 0" using assms by (intro emeasure_eq_0[of B _ "B - A"]) auto
   869 qed (insert assms, auto)
   870 
   871 lemma emeasure_Un_null_set:
   872   assumes "A \<in> sets M" "B \<in> null_sets M"
   873   shows "emeasure M (A \<union> B) = emeasure M A"
   874 proof -
   875   have *: "A \<union> B = A \<union> (B - A)" by auto
   876   have "B - A \<in> null_sets M" using assms(2,1) by (rule null_set_Diff)
   877   then show ?thesis
   878     unfolding * using assms
   879     by (subst plus_emeasure[symmetric]) auto
   880 qed
   881 
   882 subsection {* The almost everywhere filter (i.e.\ quantifier) *}
   883 
   884 definition ae_filter :: "'a measure \<Rightarrow> 'a filter" where
   885   "ae_filter M = (INF N:null_sets M. principal (space M - N))"
   886 
   887 abbreviation almost_everywhere :: "'a measure \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   888   "almost_everywhere M P \<equiv> eventually P (ae_filter M)"
   889 
   890 syntax
   891   "_almost_everywhere" :: "pttrn \<Rightarrow> 'a \<Rightarrow> bool \<Rightarrow> bool" ("AE _ in _. _" [0,0,10] 10)
   892 
   893 translations
   894   "AE x in M. P" == "CONST almost_everywhere M (\<lambda>x. P)"
   895 
   896 lemma eventually_ae_filter: "eventually P (ae_filter M) \<longleftrightarrow> (\<exists>N\<in>null_sets M. {x \<in> space M. \<not> P x} \<subseteq> N)"
   897   unfolding ae_filter_def by (subst eventually_INF_base) (auto simp: eventually_principal subset_eq)
   898 
   899 lemma AE_I':
   900   "N \<in> null_sets M \<Longrightarrow> {x\<in>space M. \<not> P x} \<subseteq> N \<Longrightarrow> (AE x in M. P x)"
   901   unfolding eventually_ae_filter by auto
   902 
   903 lemma AE_iff_null:
   904   assumes "{x\<in>space M. \<not> P x} \<in> sets M" (is "?P \<in> sets M")
   905   shows "(AE x in M. P x) \<longleftrightarrow> {x\<in>space M. \<not> P x} \<in> null_sets M"
   906 proof
   907   assume "AE x in M. P x" then obtain N where N: "N \<in> sets M" "?P \<subseteq> N" "emeasure M N = 0"
   908     unfolding eventually_ae_filter by auto
   909   have "0 \<le> emeasure M ?P" by auto
   910   moreover have "emeasure M ?P \<le> emeasure M N"
   911     using assms N(1,2) by (auto intro: emeasure_mono)
   912   ultimately have "emeasure M ?P = 0" unfolding `emeasure M N = 0` by auto
   913   then show "?P \<in> null_sets M" using assms by auto
   914 next
   915   assume "?P \<in> null_sets M" with assms show "AE x in M. P x" by (auto intro: AE_I')
   916 qed
   917 
   918 lemma AE_iff_null_sets:
   919   "N \<in> sets M \<Longrightarrow> N \<in> null_sets M \<longleftrightarrow> (AE x in M. x \<notin> N)"
   920   using Int_absorb1[OF sets.sets_into_space, of N M]
   921   by (subst AE_iff_null) (auto simp: Int_def[symmetric])
   922 
   923 lemma AE_not_in:
   924   "N \<in> null_sets M \<Longrightarrow> AE x in M. x \<notin> N"
   925   by (metis AE_iff_null_sets null_setsD2)
   926 
   927 lemma AE_iff_measurable:
   928   "N \<in> sets M \<Longrightarrow> {x\<in>space M. \<not> P x} = N \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> emeasure M N = 0"
   929   using AE_iff_null[of _ P] by auto
   930 
   931 lemma AE_E[consumes 1]:
   932   assumes "AE x in M. P x"
   933   obtains N where "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
   934   using assms unfolding eventually_ae_filter by auto
   935 
   936 lemma AE_E2:
   937   assumes "AE x in M. P x" "{x\<in>space M. P x} \<in> sets M"
   938   shows "emeasure M {x\<in>space M. \<not> P x} = 0" (is "emeasure M ?P = 0")
   939 proof -
   940   have "{x\<in>space M. \<not> P x} = space M - {x\<in>space M. P x}" by auto
   941   with AE_iff_null[of M P] assms show ?thesis by auto
   942 qed
   943 
   944 lemma AE_I:
   945   assumes "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
   946   shows "AE x in M. P x"
   947   using assms unfolding eventually_ae_filter by auto
   948 
   949 lemma AE_mp[elim!]:
   950   assumes AE_P: "AE x in M. P x" and AE_imp: "AE x in M. P x \<longrightarrow> Q x"
   951   shows "AE x in M. Q x"
   952 proof -
   953   from AE_P obtain A where P: "{x\<in>space M. \<not> P x} \<subseteq> A"
   954     and A: "A \<in> sets M" "emeasure M A = 0"
   955     by (auto elim!: AE_E)
   956 
   957   from AE_imp obtain B where imp: "{x\<in>space M. P x \<and> \<not> Q x} \<subseteq> B"
   958     and B: "B \<in> sets M" "emeasure M B = 0"
   959     by (auto elim!: AE_E)
   960 
   961   show ?thesis
   962   proof (intro AE_I)
   963     have "0 \<le> emeasure M (A \<union> B)" using A B by auto
   964     moreover have "emeasure M (A \<union> B) \<le> 0"
   965       using emeasure_subadditive[of A M B] A B by auto
   966     ultimately show "A \<union> B \<in> sets M" "emeasure M (A \<union> B) = 0" using A B by auto
   967     show "{x\<in>space M. \<not> Q x} \<subseteq> A \<union> B"
   968       using P imp by auto
   969   qed
   970 qed
   971 
   972 (* depricated replace by laws about eventually *)
   973 lemma
   974   shows AE_iffI: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
   975     and AE_disjI1: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<or> Q x"
   976     and AE_disjI2: "AE x in M. Q x \<Longrightarrow> AE x in M. P x \<or> Q x"
   977     and AE_conjI: "AE x in M. P x \<Longrightarrow> AE x in M. Q x \<Longrightarrow> AE x in M. P x \<and> Q x"
   978     and AE_conj_iff[simp]: "(AE x in M. P x \<and> Q x) \<longleftrightarrow> (AE x in M. P x) \<and> (AE x in M. Q x)"
   979   by auto
   980 
   981 lemma AE_impI:
   982   "(P \<Longrightarrow> AE x in M. Q x) \<Longrightarrow> AE x in M. P \<longrightarrow> Q x"
   983   by (cases P) auto
   984 
   985 lemma AE_measure:
   986   assumes AE: "AE x in M. P x" and sets: "{x\<in>space M. P x} \<in> sets M" (is "?P \<in> sets M")
   987   shows "emeasure M {x\<in>space M. P x} = emeasure M (space M)"
   988 proof -
   989   from AE_E[OF AE] guess N . note N = this
   990   with sets have "emeasure M (space M) \<le> emeasure M (?P \<union> N)"
   991     by (intro emeasure_mono) auto
   992   also have "\<dots> \<le> emeasure M ?P + emeasure M N"
   993     using sets N by (intro emeasure_subadditive) auto
   994   also have "\<dots> = emeasure M ?P" using N by simp
   995   finally show "emeasure M ?P = emeasure M (space M)"
   996     using emeasure_space[of M "?P"] by auto
   997 qed
   998 
   999 lemma AE_space: "AE x in M. x \<in> space M"
  1000   by (rule AE_I[where N="{}"]) auto
  1001 
  1002 lemma AE_I2[simp, intro]:
  1003   "(\<And>x. x \<in> space M \<Longrightarrow> P x) \<Longrightarrow> AE x in M. P x"
  1004   using AE_space by force
  1005 
  1006 lemma AE_Ball_mp:
  1007   "\<forall>x\<in>space M. P x \<Longrightarrow> AE x in M. P x \<longrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
  1008   by auto
  1009 
  1010 lemma AE_cong[cong]:
  1011   "(\<And>x. x \<in> space M \<Longrightarrow> P x \<longleftrightarrow> Q x) \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> (AE x in M. Q x)"
  1012   by auto
  1013 
  1014 lemma AE_all_countable:
  1015   "(AE x in M. \<forall>i. P i x) \<longleftrightarrow> (\<forall>i::'i::countable. AE x in M. P i x)"
  1016 proof
  1017   assume "\<forall>i. AE x in M. P i x"
  1018   from this[unfolded eventually_ae_filter Bex_def, THEN choice]
  1019   obtain N where N: "\<And>i. N i \<in> null_sets M" "\<And>i. {x\<in>space M. \<not> P i x} \<subseteq> N i" by auto
  1020   have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. {x\<in>space M. \<not> P i x})" by auto
  1021   also have "\<dots> \<subseteq> (\<Union>i. N i)" using N by auto
  1022   finally have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. N i)" .
  1023   moreover from N have "(\<Union>i. N i) \<in> null_sets M"
  1024     by (intro null_sets_UN) auto
  1025   ultimately show "AE x in M. \<forall>i. P i x"
  1026     unfolding eventually_ae_filter by auto
  1027 qed auto
  1028 
  1029 lemma AE_ball_countable: 
  1030   assumes [intro]: "countable X"
  1031   shows "(AE x in M. \<forall>y\<in>X. P x y) \<longleftrightarrow> (\<forall>y\<in>X. AE x in M. P x y)"
  1032 proof
  1033   assume "\<forall>y\<in>X. AE x in M. P x y"
  1034   from this[unfolded eventually_ae_filter Bex_def, THEN bchoice]
  1035   obtain N where N: "\<And>y. y \<in> X \<Longrightarrow> N y \<in> null_sets M" "\<And>y. y \<in> X \<Longrightarrow> {x\<in>space M. \<not> P x y} \<subseteq> N y"
  1036     by auto
  1037   have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. {x\<in>space M. \<not> P x y})"
  1038     by auto
  1039   also have "\<dots> \<subseteq> (\<Union>y\<in>X. N y)"
  1040     using N by auto
  1041   finally have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. N y)" .
  1042   moreover from N have "(\<Union>y\<in>X. N y) \<in> null_sets M"
  1043     by (intro null_sets_UN') auto
  1044   ultimately show "AE x in M. \<forall>y\<in>X. P x y"
  1045     unfolding eventually_ae_filter by auto
  1046 qed auto
  1047 
  1048 lemma AE_discrete_difference:
  1049   assumes X: "countable X"
  1050   assumes null: "\<And>x. x \<in> X \<Longrightarrow> emeasure M {x} = 0" 
  1051   assumes sets: "\<And>x. x \<in> X \<Longrightarrow> {x} \<in> sets M"
  1052   shows "AE x in M. x \<notin> X"
  1053 proof -
  1054   have "(\<Union>x\<in>X. {x}) \<in> null_sets M"
  1055     using assms by (intro null_sets_UN') auto
  1056   from AE_not_in[OF this] show "AE x in M. x \<notin> X"
  1057     by auto
  1058 qed
  1059 
  1060 lemma AE_finite_all:
  1061   assumes f: "finite S" shows "(AE x in M. \<forall>i\<in>S. P i x) \<longleftrightarrow> (\<forall>i\<in>S. AE x in M. P i x)"
  1062   using f by induct auto
  1063 
  1064 lemma AE_finite_allI:
  1065   assumes "finite S"
  1066   shows "(\<And>s. s \<in> S \<Longrightarrow> AE x in M. Q s x) \<Longrightarrow> AE x in M. \<forall>s\<in>S. Q s x"
  1067   using AE_finite_all[OF `finite S`] by auto
  1068 
  1069 lemma emeasure_mono_AE:
  1070   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B"
  1071     and B: "B \<in> sets M"
  1072   shows "emeasure M A \<le> emeasure M B"
  1073 proof cases
  1074   assume A: "A \<in> sets M"
  1075   from imp obtain N where N: "{x\<in>space M. \<not> (x \<in> A \<longrightarrow> x \<in> B)} \<subseteq> N" "N \<in> null_sets M"
  1076     by (auto simp: eventually_ae_filter)
  1077   have "emeasure M A = emeasure M (A - N)"
  1078     using N A by (subst emeasure_Diff_null_set) auto
  1079   also have "emeasure M (A - N) \<le> emeasure M (B - N)"
  1080     using N A B sets.sets_into_space by (auto intro!: emeasure_mono)
  1081   also have "emeasure M (B - N) = emeasure M B"
  1082     using N B by (subst emeasure_Diff_null_set) auto
  1083   finally show ?thesis .
  1084 qed (simp add: emeasure_nonneg emeasure_notin_sets)
  1085 
  1086 lemma emeasure_eq_AE:
  1087   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1088   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1089   shows "emeasure M A = emeasure M B"
  1090   using assms by (safe intro!: antisym emeasure_mono_AE) auto
  1091 
  1092 lemma emeasure_Collect_eq_AE:
  1093   "AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> Measurable.pred M Q \<Longrightarrow> Measurable.pred M P \<Longrightarrow>
  1094    emeasure M {x\<in>space M. P x} = emeasure M {x\<in>space M. Q x}"
  1095    by (intro emeasure_eq_AE) auto
  1096 
  1097 lemma emeasure_eq_0_AE: "AE x in M. \<not> P x \<Longrightarrow> emeasure M {x\<in>space M. P x} = 0"
  1098   using AE_iff_measurable[OF _ refl, of M "\<lambda>x. \<not> P x"]
  1099   by (cases "{x\<in>space M. P x} \<in> sets M") (simp_all add: emeasure_notin_sets)
  1100 
  1101 subsection {* @{text \<sigma>}-finite Measures *}
  1102 
  1103 locale sigma_finite_measure =
  1104   fixes M :: "'a measure"
  1105   assumes sigma_finite_countable:
  1106     "\<exists>A::'a set set. countable A \<and> A \<subseteq> sets M \<and> (\<Union>A) = space M \<and> (\<forall>a\<in>A. emeasure M a \<noteq> \<infinity>)"
  1107 
  1108 lemma (in sigma_finite_measure) sigma_finite:
  1109   obtains A :: "nat \<Rightarrow> 'a set"
  1110   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1111 proof -
  1112   obtain A :: "'a set set" where
  1113     [simp]: "countable A" and
  1114     A: "A \<subseteq> sets M" "(\<Union>A) = space M" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  1115     using sigma_finite_countable by metis
  1116   show thesis
  1117   proof cases
  1118     assume "A = {}" with `(\<Union>A) = space M` show thesis
  1119       by (intro that[of "\<lambda>_. {}"]) auto
  1120   next
  1121     assume "A \<noteq> {}" 
  1122     show thesis
  1123     proof
  1124       show "range (from_nat_into A) \<subseteq> sets M"
  1125         using `A \<noteq> {}` A by auto
  1126       have "(\<Union>i. from_nat_into A i) = \<Union>A"
  1127         using range_from_nat_into[OF `A \<noteq> {}` `countable A`] by auto
  1128       with A show "(\<Union>i. from_nat_into A i) = space M"
  1129         by auto
  1130     qed (intro A from_nat_into `A \<noteq> {}`)
  1131   qed
  1132 qed
  1133 
  1134 lemma (in sigma_finite_measure) sigma_finite_disjoint:
  1135   obtains A :: "nat \<Rightarrow> 'a set"
  1136   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "disjoint_family A"
  1137 proof atomize_elim
  1138   case goal1
  1139   obtain A :: "nat \<Rightarrow> 'a set" where
  1140     range: "range A \<subseteq> sets M" and
  1141     space: "(\<Union>i. A i) = space M" and
  1142     measure: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1143     using sigma_finite by auto
  1144   note range' = sets.range_disjointed_sets[OF range] range
  1145   { fix i
  1146     have "emeasure M (disjointed A i) \<le> emeasure M (A i)"
  1147       using range' disjointed_subset[of A i] by (auto intro!: emeasure_mono)
  1148     then have "emeasure M (disjointed A i) \<noteq> \<infinity>"
  1149       using measure[of i] by auto }
  1150   with disjoint_family_disjointed UN_disjointed_eq[of A] space range'
  1151   show ?case by (auto intro!: exI[of _ "disjointed A"])
  1152 qed
  1153 
  1154 lemma (in sigma_finite_measure) sigma_finite_incseq:
  1155   obtains A :: "nat \<Rightarrow> 'a set"
  1156   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "incseq A"
  1157 proof atomize_elim
  1158   case goal1
  1159   obtain F :: "nat \<Rightarrow> 'a set" where
  1160     F: "range F \<subseteq> sets M" "(\<Union>i. F i) = space M" "\<And>i. emeasure M (F i) \<noteq> \<infinity>"
  1161     using sigma_finite by auto
  1162   then show ?case
  1163   proof (intro exI[of _ "\<lambda>n. \<Union>i\<le>n. F i"] conjI allI)
  1164     from F have "\<And>x. x \<in> space M \<Longrightarrow> \<exists>i. x \<in> F i" by auto
  1165     then show "(\<Union>n. \<Union> i\<le>n. F i) = space M"
  1166       using F by fastforce
  1167   next
  1168     fix n
  1169     have "emeasure M (\<Union> i\<le>n. F i) \<le> (\<Sum>i\<le>n. emeasure M (F i))" using F
  1170       by (auto intro!: emeasure_subadditive_finite)
  1171     also have "\<dots> < \<infinity>"
  1172       using F by (auto simp: setsum_Pinfty)
  1173     finally show "emeasure M (\<Union> i\<le>n. F i) \<noteq> \<infinity>" by simp
  1174   qed (force simp: incseq_def)+
  1175 qed
  1176 
  1177 subsection {* Measure space induced by distribution of @{const measurable}-functions *}
  1178 
  1179 definition distr :: "'a measure \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b measure" where
  1180   "distr M N f = measure_of (space N) (sets N) (\<lambda>A. emeasure M (f -` A \<inter> space M))"
  1181 
  1182 lemma
  1183   shows sets_distr[simp, measurable_cong]: "sets (distr M N f) = sets N"
  1184     and space_distr[simp]: "space (distr M N f) = space N"
  1185   by (auto simp: distr_def)
  1186 
  1187 lemma
  1188   shows measurable_distr_eq1[simp]: "measurable (distr Mf Nf f) Mf' = measurable Nf Mf'"
  1189     and measurable_distr_eq2[simp]: "measurable Mg' (distr Mg Ng g) = measurable Mg' Ng"
  1190   by (auto simp: measurable_def)
  1191 
  1192 lemma distr_cong:
  1193   "M = K \<Longrightarrow> sets N = sets L \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> distr M N f = distr K L g"
  1194   using sets_eq_imp_space_eq[of N L] by (simp add: distr_def Int_def cong: rev_conj_cong)
  1195 
  1196 lemma emeasure_distr:
  1197   fixes f :: "'a \<Rightarrow> 'b"
  1198   assumes f: "f \<in> measurable M N" and A: "A \<in> sets N"
  1199   shows "emeasure (distr M N f) A = emeasure M (f -` A \<inter> space M)" (is "_ = ?\<mu> A")
  1200   unfolding distr_def
  1201 proof (rule emeasure_measure_of_sigma)
  1202   show "positive (sets N) ?\<mu>"
  1203     by (auto simp: positive_def)
  1204 
  1205   show "countably_additive (sets N) ?\<mu>"
  1206   proof (intro countably_additiveI)
  1207     fix A :: "nat \<Rightarrow> 'b set" assume "range A \<subseteq> sets N" "disjoint_family A"
  1208     then have A: "\<And>i. A i \<in> sets N" "(\<Union>i. A i) \<in> sets N" by auto
  1209     then have *: "range (\<lambda>i. f -` (A i) \<inter> space M) \<subseteq> sets M"
  1210       using f by (auto simp: measurable_def)
  1211     moreover have "(\<Union>i. f -`  A i \<inter> space M) \<in> sets M"
  1212       using * by blast
  1213     moreover have **: "disjoint_family (\<lambda>i. f -` A i \<inter> space M)"
  1214       using `disjoint_family A` by (auto simp: disjoint_family_on_def)
  1215     ultimately show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)"
  1216       using suminf_emeasure[OF _ **] A f
  1217       by (auto simp: comp_def vimage_UN)
  1218   qed
  1219   show "sigma_algebra (space N) (sets N)" ..
  1220 qed fact
  1221 
  1222 lemma emeasure_Collect_distr:
  1223   assumes X[measurable]: "X \<in> measurable M N" "Measurable.pred N P"
  1224   shows "emeasure (distr M N X) {x\<in>space N. P x} = emeasure M {x\<in>space M. P (X x)}"
  1225   by (subst emeasure_distr)
  1226      (auto intro!: arg_cong2[where f=emeasure] X(1)[THEN measurable_space])
  1227 
  1228 lemma emeasure_lfp2[consumes 1, case_names cont f measurable]:
  1229   assumes "P M"
  1230   assumes cont: "Order_Continuity.continuous F"
  1231   assumes f: "\<And>M. P M \<Longrightarrow> f \<in> measurable M' M"
  1232   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
  1233   shows "emeasure M' {x\<in>space M'. lfp F (f x)} = (SUP i. emeasure M' {x\<in>space M'. (F ^^ i) (\<lambda>x. False) (f x)})"
  1234 proof (subst (1 2) emeasure_Collect_distr[symmetric, where X=f])
  1235   show "f \<in> measurable M' M"  "f \<in> measurable M' M"
  1236     using f[OF `P M`] by auto
  1237   { fix i show "Measurable.pred M ((F ^^ i) (\<lambda>x. False))"
  1238     using `P M` by (induction i arbitrary: M) (auto intro!: *) }
  1239   show "Measurable.pred M (lfp F)"
  1240     using `P M` cont * by (rule measurable_lfp_coinduct[of P])
  1241 
  1242   have "emeasure (distr M' M f) {x \<in> space (distr M' M f). lfp F x} =
  1243     (SUP i. emeasure (distr M' M f) {x \<in> space (distr M' M f). (F ^^ i) (\<lambda>x. False) x})"
  1244     using `P M`
  1245   proof (coinduction arbitrary: M rule: emeasure_lfp)
  1246     case (measurable A N) then have "\<And>N. P N \<Longrightarrow> Measurable.pred (distr M' N f) A"
  1247       by metis
  1248     then have "\<And>N. P N \<Longrightarrow> Measurable.pred N A"
  1249       by simp
  1250     with `P N`[THEN *] show ?case
  1251       by auto
  1252   qed fact
  1253   then show "emeasure (distr M' M f) {x \<in> space M. lfp F x} =
  1254     (SUP i. emeasure (distr M' M f) {x \<in> space M. (F ^^ i) (\<lambda>x. False) x})"
  1255    by simp
  1256 qed
  1257 
  1258 lemma distr_id[simp]: "distr N N (\<lambda>x. x) = N"
  1259   by (rule measure_eqI) (auto simp: emeasure_distr)
  1260 
  1261 lemma measure_distr:
  1262   "f \<in> measurable M N \<Longrightarrow> S \<in> sets N \<Longrightarrow> measure (distr M N f) S = measure M (f -` S \<inter> space M)"
  1263   by (simp add: emeasure_distr measure_def)
  1264 
  1265 lemma distr_cong_AE:
  1266   assumes 1: "M = K" "sets N = sets L" and 
  1267     2: "(AE x in M. f x = g x)" and "f \<in> measurable M N" and "g \<in> measurable K L"
  1268   shows "distr M N f = distr K L g"
  1269 proof (rule measure_eqI)
  1270   fix A assume "A \<in> sets (distr M N f)"
  1271   with assms show "emeasure (distr M N f) A = emeasure (distr K L g) A"
  1272     by (auto simp add: emeasure_distr intro!: emeasure_eq_AE measurable_sets)
  1273 qed (insert 1, simp)
  1274 
  1275 lemma AE_distrD:
  1276   assumes f: "f \<in> measurable M M'"
  1277     and AE: "AE x in distr M M' f. P x"
  1278   shows "AE x in M. P (f x)"
  1279 proof -
  1280   from AE[THEN AE_E] guess N .
  1281   with f show ?thesis
  1282     unfolding eventually_ae_filter
  1283     by (intro bexI[of _ "f -` N \<inter> space M"])
  1284        (auto simp: emeasure_distr measurable_def)
  1285 qed
  1286 
  1287 lemma AE_distr_iff:
  1288   assumes f[measurable]: "f \<in> measurable M N" and P[measurable]: "{x \<in> space N. P x} \<in> sets N"
  1289   shows "(AE x in distr M N f. P x) \<longleftrightarrow> (AE x in M. P (f x))"
  1290 proof (subst (1 2) AE_iff_measurable[OF _ refl])
  1291   have "f -` {x\<in>space N. \<not> P x} \<inter> space M = {x \<in> space M. \<not> P (f x)}"
  1292     using f[THEN measurable_space] by auto
  1293   then show "(emeasure (distr M N f) {x \<in> space (distr M N f). \<not> P x} = 0) =
  1294     (emeasure M {x \<in> space M. \<not> P (f x)} = 0)"
  1295     by (simp add: emeasure_distr)
  1296 qed auto
  1297 
  1298 lemma null_sets_distr_iff:
  1299   "f \<in> measurable M N \<Longrightarrow> A \<in> null_sets (distr M N f) \<longleftrightarrow> f -` A \<inter> space M \<in> null_sets M \<and> A \<in> sets N"
  1300   by (auto simp add: null_sets_def emeasure_distr)
  1301 
  1302 lemma distr_distr:
  1303   "g \<in> measurable N L \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> distr (distr M N f) L g = distr M L (g \<circ> f)"
  1304   by (auto simp add: emeasure_distr measurable_space
  1305            intro!: arg_cong[where f="emeasure M"] measure_eqI)
  1306 
  1307 subsection {* Real measure values *}
  1308 
  1309 lemma measure_nonneg: "0 \<le> measure M A"
  1310   using emeasure_nonneg[of M A] unfolding measure_def by (auto intro: real_of_ereal_pos)
  1311 
  1312 lemma measure_le_0_iff: "measure M X \<le> 0 \<longleftrightarrow> measure M X = 0"
  1313   using measure_nonneg[of M X] by auto
  1314 
  1315 lemma measure_empty[simp]: "measure M {} = 0"
  1316   unfolding measure_def by simp
  1317 
  1318 lemma emeasure_eq_ereal_measure:
  1319   "emeasure M A \<noteq> \<infinity> \<Longrightarrow> emeasure M A = ereal (measure M A)"
  1320   using emeasure_nonneg[of M A]
  1321   by (cases "emeasure M A") (auto simp: measure_def)
  1322 
  1323 lemma measure_Union:
  1324   assumes finite: "emeasure M A \<noteq> \<infinity>" "emeasure M B \<noteq> \<infinity>"
  1325   and measurable: "A \<in> sets M" "B \<in> sets M" "A \<inter> B = {}"
  1326   shows "measure M (A \<union> B) = measure M A + measure M B"
  1327   unfolding measure_def
  1328   using plus_emeasure[OF measurable, symmetric] finite
  1329   by (simp add: emeasure_eq_ereal_measure)
  1330 
  1331 lemma measure_finite_Union:
  1332   assumes measurable: "A`S \<subseteq> sets M" "disjoint_family_on A S" "finite S"
  1333   assumes finite: "\<And>i. i \<in> S \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>"
  1334   shows "measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1335   unfolding measure_def
  1336   using setsum_emeasure[OF measurable, symmetric] finite
  1337   by (simp add: emeasure_eq_ereal_measure)
  1338 
  1339 lemma measure_Diff:
  1340   assumes finite: "emeasure M A \<noteq> \<infinity>"
  1341   and measurable: "A \<in> sets M" "B \<in> sets M" "B \<subseteq> A"
  1342   shows "measure M (A - B) = measure M A - measure M B"
  1343 proof -
  1344   have "emeasure M (A - B) \<le> emeasure M A" "emeasure M B \<le> emeasure M A"
  1345     using measurable by (auto intro!: emeasure_mono)
  1346   hence "measure M ((A - B) \<union> B) = measure M (A - B) + measure M B"
  1347     using measurable finite by (rule_tac measure_Union) auto
  1348   thus ?thesis using `B \<subseteq> A` by (auto simp: Un_absorb2)
  1349 qed
  1350 
  1351 lemma measure_UNION:
  1352   assumes measurable: "range A \<subseteq> sets M" "disjoint_family A"
  1353   assumes finite: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1354   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1355 proof -
  1356   from summable_sums[OF summable_ereal_pos, of "\<lambda>i. emeasure M (A i)"]
  1357        suminf_emeasure[OF measurable] emeasure_nonneg[of M]
  1358   have "(\<lambda>i. emeasure M (A i)) sums (emeasure M (\<Union>i. A i))" by simp
  1359   moreover
  1360   { fix i
  1361     have "emeasure M (A i) \<le> emeasure M (\<Union>i. A i)"
  1362       using measurable by (auto intro!: emeasure_mono)
  1363     then have "emeasure M (A i) = ereal ((measure M (A i)))"
  1364       using finite by (intro emeasure_eq_ereal_measure) auto }
  1365   ultimately show ?thesis using finite
  1366     unfolding sums_ereal[symmetric] by (simp add: emeasure_eq_ereal_measure)
  1367 qed
  1368 
  1369 lemma measure_subadditive:
  1370   assumes measurable: "A \<in> sets M" "B \<in> sets M"
  1371   and fin: "emeasure M A \<noteq> \<infinity>" "emeasure M B \<noteq> \<infinity>"
  1372   shows "(measure M (A \<union> B)) \<le> (measure M A) + (measure M B)"
  1373 proof -
  1374   have "emeasure M (A \<union> B) \<noteq> \<infinity>"
  1375     using emeasure_subadditive[OF measurable] fin by auto
  1376   then show "(measure M (A \<union> B)) \<le> (measure M A) + (measure M B)"
  1377     using emeasure_subadditive[OF measurable] fin
  1378     by (auto simp: emeasure_eq_ereal_measure)
  1379 qed
  1380 
  1381 lemma measure_subadditive_finite:
  1382   assumes A: "finite I" "A`I \<subseteq> sets M" and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>"
  1383   shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1384 proof -
  1385   { have "emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
  1386       using emeasure_subadditive_finite[OF A] .
  1387     also have "\<dots> < \<infinity>"
  1388       using fin by (simp add: setsum_Pinfty)
  1389     finally have "emeasure M (\<Union>i\<in>I. A i) \<noteq> \<infinity>" by simp }
  1390   then show ?thesis
  1391     using emeasure_subadditive_finite[OF A] fin
  1392     unfolding measure_def by (simp add: emeasure_eq_ereal_measure suminf_ereal measure_nonneg)
  1393 qed
  1394 
  1395 lemma measure_subadditive_countably:
  1396   assumes A: "range A \<subseteq> sets M" and fin: "(\<Sum>i. emeasure M (A i)) \<noteq> \<infinity>"
  1397   shows "measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1398 proof -
  1399   from emeasure_nonneg fin have "\<And>i. emeasure M (A i) \<noteq> \<infinity>" by (rule suminf_PInfty)
  1400   moreover
  1401   { have "emeasure M (\<Union>i. A i) \<le> (\<Sum>i. emeasure M (A i))"
  1402       using emeasure_subadditive_countably[OF A] .
  1403     also have "\<dots> < \<infinity>"
  1404       using fin by simp
  1405     finally have "emeasure M (\<Union>i. A i) \<noteq> \<infinity>" by simp }
  1406   ultimately  show ?thesis
  1407     using emeasure_subadditive_countably[OF A] fin
  1408     unfolding measure_def by (simp add: emeasure_eq_ereal_measure suminf_ereal measure_nonneg)
  1409 qed
  1410 
  1411 lemma measure_eq_setsum_singleton:
  1412   assumes S: "finite S" "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
  1413   and fin: "\<And>x. x \<in> S \<Longrightarrow> emeasure M {x} \<noteq> \<infinity>"
  1414   shows "(measure M S) = (\<Sum>x\<in>S. (measure M {x}))"
  1415   unfolding measure_def
  1416   using emeasure_eq_setsum_singleton[OF S] fin
  1417   by simp (simp add: emeasure_eq_ereal_measure)
  1418 
  1419 lemma Lim_measure_incseq:
  1420   assumes A: "range A \<subseteq> sets M" "incseq A" and fin: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1421   shows "(\<lambda>i. (measure M (A i))) ----> (measure M (\<Union>i. A i))"
  1422 proof -
  1423   have "ereal ((measure M (\<Union>i. A i))) = emeasure M (\<Union>i. A i)"
  1424     using fin by (auto simp: emeasure_eq_ereal_measure)
  1425   then show ?thesis
  1426     using Lim_emeasure_incseq[OF A]
  1427     unfolding measure_def
  1428     by (intro lim_real_of_ereal) simp
  1429 qed
  1430 
  1431 lemma Lim_measure_decseq:
  1432   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1433   shows "(\<lambda>n. measure M (A n)) ----> measure M (\<Inter>i. A i)"
  1434 proof -
  1435   have "emeasure M (\<Inter>i. A i) \<le> emeasure M (A 0)"
  1436     using A by (auto intro!: emeasure_mono)
  1437   also have "\<dots> < \<infinity>"
  1438     using fin[of 0] by auto
  1439   finally have "ereal ((measure M (\<Inter>i. A i))) = emeasure M (\<Inter>i. A i)"
  1440     by (auto simp: emeasure_eq_ereal_measure)
  1441   then show ?thesis
  1442     unfolding measure_def
  1443     using Lim_emeasure_decseq[OF A fin]
  1444     by (intro lim_real_of_ereal) simp
  1445 qed
  1446 
  1447 subsection {* Measure spaces with @{term "emeasure M (space M) < \<infinity>"} *}
  1448 
  1449 locale finite_measure = sigma_finite_measure M for M +
  1450   assumes finite_emeasure_space: "emeasure M (space M) \<noteq> \<infinity>"
  1451 
  1452 lemma finite_measureI[Pure.intro!]:
  1453   "emeasure M (space M) \<noteq> \<infinity> \<Longrightarrow> finite_measure M"
  1454   proof qed (auto intro!: exI[of _ "{space M}"])
  1455 
  1456 lemma (in finite_measure) emeasure_finite[simp, intro]: "emeasure M A \<noteq> \<infinity>"
  1457   using finite_emeasure_space emeasure_space[of M A] by auto
  1458 
  1459 lemma (in finite_measure) emeasure_eq_measure: "emeasure M A = ereal (measure M A)"
  1460   unfolding measure_def by (simp add: emeasure_eq_ereal_measure)
  1461 
  1462 lemma (in finite_measure) emeasure_real: "\<exists>r. 0 \<le> r \<and> emeasure M A = ereal r"
  1463   using emeasure_finite[of A] emeasure_nonneg[of M A] by (cases "emeasure M A") auto
  1464 
  1465 lemma (in finite_measure) bounded_measure: "measure M A \<le> measure M (space M)"
  1466   using emeasure_space[of M A] emeasure_real[of A] emeasure_real[of "space M"] by (auto simp: measure_def)
  1467 
  1468 lemma (in finite_measure) finite_measure_Diff:
  1469   assumes sets: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
  1470   shows "measure M (A - B) = measure M A - measure M B"
  1471   using measure_Diff[OF _ assms] by simp
  1472 
  1473 lemma (in finite_measure) finite_measure_Union:
  1474   assumes sets: "A \<in> sets M" "B \<in> sets M" and "A \<inter> B = {}"
  1475   shows "measure M (A \<union> B) = measure M A + measure M B"
  1476   using measure_Union[OF _ _ assms] by simp
  1477 
  1478 lemma (in finite_measure) finite_measure_finite_Union:
  1479   assumes measurable: "A`S \<subseteq> sets M" "disjoint_family_on A S" "finite S"
  1480   shows "measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1481   using measure_finite_Union[OF assms] by simp
  1482 
  1483 lemma (in finite_measure) finite_measure_UNION:
  1484   assumes A: "range A \<subseteq> sets M" "disjoint_family A"
  1485   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1486   using measure_UNION[OF A] by simp
  1487 
  1488 lemma (in finite_measure) finite_measure_mono:
  1489   assumes "A \<subseteq> B" "B \<in> sets M" shows "measure M A \<le> measure M B"
  1490   using emeasure_mono[OF assms] emeasure_real[of A] emeasure_real[of B] by (auto simp: measure_def)
  1491 
  1492 lemma (in finite_measure) finite_measure_subadditive:
  1493   assumes m: "A \<in> sets M" "B \<in> sets M"
  1494   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1495   using measure_subadditive[OF m] by simp
  1496 
  1497 lemma (in finite_measure) finite_measure_subadditive_finite:
  1498   assumes "finite I" "A`I \<subseteq> sets M" shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1499   using measure_subadditive_finite[OF assms] by simp
  1500 
  1501 lemma (in finite_measure) finite_measure_subadditive_countably:
  1502   assumes A: "range A \<subseteq> sets M" and sum: "summable (\<lambda>i. measure M (A i))"
  1503   shows "measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1504 proof -
  1505   from `summable (\<lambda>i. measure M (A i))`
  1506   have "(\<lambda>i. ereal (measure M (A i))) sums ereal (\<Sum>i. measure M (A i))"
  1507     by (simp add: sums_ereal) (rule summable_sums)
  1508   from sums_unique[OF this, symmetric]
  1509        measure_subadditive_countably[OF A]
  1510   show ?thesis by (simp add: emeasure_eq_measure)
  1511 qed
  1512 
  1513 lemma (in finite_measure) finite_measure_eq_setsum_singleton:
  1514   assumes "finite S" and *: "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
  1515   shows "measure M S = (\<Sum>x\<in>S. measure M {x})"
  1516   using measure_eq_setsum_singleton[OF assms] by simp
  1517 
  1518 lemma (in finite_measure) finite_Lim_measure_incseq:
  1519   assumes A: "range A \<subseteq> sets M" "incseq A"
  1520   shows "(\<lambda>i. measure M (A i)) ----> measure M (\<Union>i. A i)"
  1521   using Lim_measure_incseq[OF A] by simp
  1522 
  1523 lemma (in finite_measure) finite_Lim_measure_decseq:
  1524   assumes A: "range A \<subseteq> sets M" "decseq A"
  1525   shows "(\<lambda>n. measure M (A n)) ----> measure M (\<Inter>i. A i)"
  1526   using Lim_measure_decseq[OF A] by simp
  1527 
  1528 lemma (in finite_measure) finite_measure_compl:
  1529   assumes S: "S \<in> sets M"
  1530   shows "measure M (space M - S) = measure M (space M) - measure M S"
  1531   using measure_Diff[OF _ sets.top S sets.sets_into_space] S by simp
  1532 
  1533 lemma (in finite_measure) finite_measure_mono_AE:
  1534   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B" and B: "B \<in> sets M"
  1535   shows "measure M A \<le> measure M B"
  1536   using assms emeasure_mono_AE[OF imp B]
  1537   by (simp add: emeasure_eq_measure)
  1538 
  1539 lemma (in finite_measure) finite_measure_eq_AE:
  1540   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1541   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1542   shows "measure M A = measure M B"
  1543   using assms emeasure_eq_AE[OF assms] by (simp add: emeasure_eq_measure)
  1544 
  1545 lemma (in finite_measure) measure_increasing: "increasing M (measure M)"
  1546   by (auto intro!: finite_measure_mono simp: increasing_def)
  1547 
  1548 lemma (in finite_measure) measure_zero_union:
  1549   assumes "s \<in> sets M" "t \<in> sets M" "measure M t = 0"
  1550   shows "measure M (s \<union> t) = measure M s"
  1551 using assms
  1552 proof -
  1553   have "measure M (s \<union> t) \<le> measure M s"
  1554     using finite_measure_subadditive[of s t] assms by auto
  1555   moreover have "measure M (s \<union> t) \<ge> measure M s"
  1556     using assms by (blast intro: finite_measure_mono)
  1557   ultimately show ?thesis by simp
  1558 qed
  1559 
  1560 lemma (in finite_measure) measure_eq_compl:
  1561   assumes "s \<in> sets M" "t \<in> sets M"
  1562   assumes "measure M (space M - s) = measure M (space M - t)"
  1563   shows "measure M s = measure M t"
  1564   using assms finite_measure_compl by auto
  1565 
  1566 lemma (in finite_measure) measure_eq_bigunion_image:
  1567   assumes "range f \<subseteq> sets M" "range g \<subseteq> sets M"
  1568   assumes "disjoint_family f" "disjoint_family g"
  1569   assumes "\<And> n :: nat. measure M (f n) = measure M (g n)"
  1570   shows "measure M (\<Union> i. f i) = measure M (\<Union> i. g i)"
  1571 using assms
  1572 proof -
  1573   have a: "(\<lambda> i. measure M (f i)) sums (measure M (\<Union> i. f i))"
  1574     by (rule finite_measure_UNION[OF assms(1,3)])
  1575   have b: "(\<lambda> i. measure M (g i)) sums (measure M (\<Union> i. g i))"
  1576     by (rule finite_measure_UNION[OF assms(2,4)])
  1577   show ?thesis using sums_unique[OF b] sums_unique[OF a] assms by simp
  1578 qed
  1579 
  1580 lemma (in finite_measure) measure_countably_zero:
  1581   assumes "range c \<subseteq> sets M"
  1582   assumes "\<And> i. measure M (c i) = 0"
  1583   shows "measure M (\<Union> i :: nat. c i) = 0"
  1584 proof (rule antisym)
  1585   show "measure M (\<Union> i :: nat. c i) \<le> 0"
  1586     using finite_measure_subadditive_countably[OF assms(1)] by (simp add: assms(2))
  1587 qed (simp add: measure_nonneg)
  1588 
  1589 lemma (in finite_measure) measure_space_inter:
  1590   assumes events:"s \<in> sets M" "t \<in> sets M"
  1591   assumes "measure M t = measure M (space M)"
  1592   shows "measure M (s \<inter> t) = measure M s"
  1593 proof -
  1594   have "measure M ((space M - s) \<union> (space M - t)) = measure M (space M - s)"
  1595     using events assms finite_measure_compl[of "t"] by (auto intro!: measure_zero_union)
  1596   also have "(space M - s) \<union> (space M - t) = space M - (s \<inter> t)"
  1597     by blast
  1598   finally show "measure M (s \<inter> t) = measure M s"
  1599     using events by (auto intro!: measure_eq_compl[of "s \<inter> t" s])
  1600 qed
  1601 
  1602 lemma (in finite_measure) measure_equiprobable_finite_unions:
  1603   assumes s: "finite s" "\<And>x. x \<in> s \<Longrightarrow> {x} \<in> sets M"
  1604   assumes "\<And> x y. \<lbrakk>x \<in> s; y \<in> s\<rbrakk> \<Longrightarrow> measure M {x} = measure M {y}"
  1605   shows "measure M s = real (card s) * measure M {SOME x. x \<in> s}"
  1606 proof cases
  1607   assume "s \<noteq> {}"
  1608   then have "\<exists> x. x \<in> s" by blast
  1609   from someI_ex[OF this] assms
  1610   have prob_some: "\<And> x. x \<in> s \<Longrightarrow> measure M {x} = measure M {SOME y. y \<in> s}" by blast
  1611   have "measure M s = (\<Sum> x \<in> s. measure M {x})"
  1612     using finite_measure_eq_setsum_singleton[OF s] by simp
  1613   also have "\<dots> = (\<Sum> x \<in> s. measure M {SOME y. y \<in> s})" using prob_some by auto
  1614   also have "\<dots> = real (card s) * measure M {(SOME x. x \<in> s)}"
  1615     using setsum_constant assms by (simp add: real_eq_of_nat)
  1616   finally show ?thesis by simp
  1617 qed simp
  1618 
  1619 lemma (in finite_measure) measure_real_sum_image_fn:
  1620   assumes "e \<in> sets M"
  1621   assumes "\<And> x. x \<in> s \<Longrightarrow> e \<inter> f x \<in> sets M"
  1622   assumes "finite s"
  1623   assumes disjoint: "\<And> x y. \<lbrakk>x \<in> s ; y \<in> s ; x \<noteq> y\<rbrakk> \<Longrightarrow> f x \<inter> f y = {}"
  1624   assumes upper: "space M \<subseteq> (\<Union> i \<in> s. f i)"
  1625   shows "measure M e = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  1626 proof -
  1627   have e: "e = (\<Union> i \<in> s. e \<inter> f i)"
  1628     using `e \<in> sets M` sets.sets_into_space upper by blast
  1629   hence "measure M e = measure M (\<Union> i \<in> s. e \<inter> f i)" by simp
  1630   also have "\<dots> = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  1631   proof (rule finite_measure_finite_Union)
  1632     show "finite s" by fact
  1633     show "(\<lambda>i. e \<inter> f i)`s \<subseteq> sets M" using assms(2) by auto
  1634     show "disjoint_family_on (\<lambda>i. e \<inter> f i) s"
  1635       using disjoint by (auto simp: disjoint_family_on_def)
  1636   qed
  1637   finally show ?thesis .
  1638 qed
  1639 
  1640 lemma (in finite_measure) measure_exclude:
  1641   assumes "A \<in> sets M" "B \<in> sets M"
  1642   assumes "measure M A = measure M (space M)" "A \<inter> B = {}"
  1643   shows "measure M B = 0"
  1644   using measure_space_inter[of B A] assms by (auto simp: ac_simps)
  1645 lemma (in finite_measure) finite_measure_distr:
  1646   assumes f: "f \<in> measurable M M'" 
  1647   shows "finite_measure (distr M M' f)"
  1648 proof (rule finite_measureI)
  1649   have "f -` space M' \<inter> space M = space M" using f by (auto dest: measurable_space)
  1650   with f show "emeasure (distr M M' f) (space (distr M M' f)) \<noteq> \<infinity>" by (auto simp: emeasure_distr)
  1651 qed
  1652 
  1653 subsection {* Counting space *}
  1654 
  1655 lemma strict_monoI_Suc:
  1656   assumes ord [simp]: "(\<And>n. f n < f (Suc n))" shows "strict_mono f"
  1657   unfolding strict_mono_def
  1658 proof safe
  1659   fix n m :: nat assume "n < m" then show "f n < f m"
  1660     by (induct m) (auto simp: less_Suc_eq intro: less_trans ord)
  1661 qed
  1662 
  1663 lemma emeasure_count_space:
  1664   assumes "X \<subseteq> A" shows "emeasure (count_space A) X = (if finite X then ereal (card X) else \<infinity>)"
  1665     (is "_ = ?M X")
  1666   unfolding count_space_def
  1667 proof (rule emeasure_measure_of_sigma)
  1668   show "X \<in> Pow A" using `X \<subseteq> A` by auto
  1669   show "sigma_algebra A (Pow A)" by (rule sigma_algebra_Pow)
  1670   show positive: "positive (Pow A) ?M"
  1671     by (auto simp: positive_def)
  1672   have additive: "additive (Pow A) ?M"
  1673     by (auto simp: card_Un_disjoint additive_def)
  1674 
  1675   interpret ring_of_sets A "Pow A"
  1676     by (rule ring_of_setsI) auto
  1677   show "countably_additive (Pow A) ?M" 
  1678     unfolding countably_additive_iff_continuous_from_below[OF positive additive]
  1679   proof safe
  1680     fix F :: "nat \<Rightarrow> 'a set" assume "incseq F"
  1681     show "(\<lambda>i. ?M (F i)) ----> ?M (\<Union>i. F i)"
  1682     proof cases
  1683       assume "\<exists>i. \<forall>j\<ge>i. F i = F j"
  1684       then guess i .. note i = this
  1685       { fix j from i `incseq F` have "F j \<subseteq> F i"
  1686           by (cases "i \<le> j") (auto simp: incseq_def) }
  1687       then have eq: "(\<Union>i. F i) = F i"
  1688         by auto
  1689       with i show ?thesis
  1690         by (auto intro!: Lim_eventually eventually_sequentiallyI[where c=i])
  1691     next
  1692       assume "\<not> (\<exists>i. \<forall>j\<ge>i. F i = F j)"
  1693       then obtain f where f: "\<And>i. i \<le> f i" "\<And>i. F i \<noteq> F (f i)" by metis
  1694       then have "\<And>i. F i \<subseteq> F (f i)" using `incseq F` by (auto simp: incseq_def)
  1695       with f have *: "\<And>i. F i \<subset> F (f i)" by auto
  1696 
  1697       have "incseq (\<lambda>i. ?M (F i))"
  1698         using `incseq F` unfolding incseq_def by (auto simp: card_mono dest: finite_subset)
  1699       then have "(\<lambda>i. ?M (F i)) ----> (SUP n. ?M (F n))"
  1700         by (rule LIMSEQ_SUP)
  1701 
  1702       moreover have "(SUP n. ?M (F n)) = \<infinity>"
  1703       proof (rule SUP_PInfty)
  1704         fix n :: nat show "\<exists>k::nat\<in>UNIV. ereal n \<le> ?M (F k)"
  1705         proof (induct n)
  1706           case (Suc n)
  1707           then guess k .. note k = this
  1708           moreover have "finite (F k) \<Longrightarrow> finite (F (f k)) \<Longrightarrow> card (F k) < card (F (f k))"
  1709             using `F k \<subset> F (f k)` by (simp add: psubset_card_mono)
  1710           moreover have "finite (F (f k)) \<Longrightarrow> finite (F k)"
  1711             using `k \<le> f k` `incseq F` by (auto simp: incseq_def dest: finite_subset)
  1712           ultimately show ?case
  1713             by (auto intro!: exI[of _ "f k"])
  1714         qed auto
  1715       qed
  1716 
  1717       moreover
  1718       have "inj (\<lambda>n. F ((f ^^ n) 0))"
  1719         by (intro strict_mono_imp_inj_on strict_monoI_Suc) (simp add: *)
  1720       then have 1: "infinite (range (\<lambda>i. F ((f ^^ i) 0)))"
  1721         by (rule range_inj_infinite)
  1722       have "infinite (Pow (\<Union>i. F i))"
  1723         by (rule infinite_super[OF _ 1]) auto
  1724       then have "infinite (\<Union>i. F i)"
  1725         by auto
  1726       
  1727       ultimately show ?thesis by auto
  1728     qed
  1729   qed
  1730 qed
  1731 
  1732 lemma distr_bij_count_space:
  1733   assumes f: "bij_betw f A B"
  1734   shows "distr (count_space A) (count_space B) f = count_space B"
  1735 proof (rule measure_eqI)
  1736   have f': "f \<in> measurable (count_space A) (count_space B)"
  1737     using f unfolding Pi_def bij_betw_def by auto
  1738   fix X assume "X \<in> sets (distr (count_space A) (count_space B) f)"
  1739   then have X: "X \<in> sets (count_space B)" by auto
  1740   moreover then have "f -` X \<inter> A = the_inv_into A f ` X"
  1741     using f by (auto simp: bij_betw_def subset_image_iff image_iff the_inv_into_f_f intro: the_inv_into_f_f[symmetric])
  1742   moreover have "inj_on (the_inv_into A f) B"
  1743     using X f by (auto simp: bij_betw_def inj_on_the_inv_into)
  1744   with X have "inj_on (the_inv_into A f) X"
  1745     by (auto intro: subset_inj_on)
  1746   ultimately show "emeasure (distr (count_space A) (count_space B) f) X = emeasure (count_space B) X"
  1747     using f unfolding emeasure_distr[OF f' X]
  1748     by (subst (1 2) emeasure_count_space) (auto simp: card_image dest: finite_imageD)
  1749 qed simp
  1750 
  1751 lemma emeasure_count_space_finite[simp]:
  1752   "X \<subseteq> A \<Longrightarrow> finite X \<Longrightarrow> emeasure (count_space A) X = ereal (card X)"
  1753   using emeasure_count_space[of X A] by simp
  1754 
  1755 lemma emeasure_count_space_infinite[simp]:
  1756   "X \<subseteq> A \<Longrightarrow> infinite X \<Longrightarrow> emeasure (count_space A) X = \<infinity>"
  1757   using emeasure_count_space[of X A] by simp
  1758 
  1759 lemma measure_count_space: "measure (count_space A) X = (if X \<subseteq> A then card X else 0)"
  1760   unfolding measure_def
  1761   by (cases "finite X") (simp_all add: emeasure_notin_sets)
  1762 
  1763 lemma emeasure_count_space_eq_0:
  1764   "emeasure (count_space A) X = 0 \<longleftrightarrow> (X \<subseteq> A \<longrightarrow> X = {})"
  1765 proof cases
  1766   assume X: "X \<subseteq> A"
  1767   then show ?thesis
  1768   proof (intro iffI impI)
  1769     assume "emeasure (count_space A) X = 0"
  1770     with X show "X = {}"
  1771       by (subst (asm) emeasure_count_space) (auto split: split_if_asm)
  1772   qed simp
  1773 qed (simp add: emeasure_notin_sets)
  1774 
  1775 lemma space_empty: "space M = {} \<Longrightarrow> M = count_space {}"
  1776   by (rule measure_eqI) (simp_all add: space_empty_iff)
  1777 
  1778 lemma null_sets_count_space: "null_sets (count_space A) = { {} }"
  1779   unfolding null_sets_def by (auto simp add: emeasure_count_space_eq_0)
  1780 
  1781 lemma AE_count_space: "(AE x in count_space A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
  1782   unfolding eventually_ae_filter by (auto simp add: null_sets_count_space)
  1783 
  1784 lemma sigma_finite_measure_count_space_countable:
  1785   assumes A: "countable A"
  1786   shows "sigma_finite_measure (count_space A)"
  1787   proof qed (auto intro!: exI[of _ "(\<lambda>a. {a}) ` A"] simp: A)
  1788 
  1789 lemma sigma_finite_measure_count_space:
  1790   fixes A :: "'a::countable set" shows "sigma_finite_measure (count_space A)"
  1791   by (rule sigma_finite_measure_count_space_countable) auto
  1792 
  1793 lemma finite_measure_count_space:
  1794   assumes [simp]: "finite A"
  1795   shows "finite_measure (count_space A)"
  1796   by rule simp
  1797 
  1798 lemma sigma_finite_measure_count_space_finite:
  1799   assumes A: "finite A" shows "sigma_finite_measure (count_space A)"
  1800 proof -
  1801   interpret finite_measure "count_space A" using A by (rule finite_measure_count_space)
  1802   show "sigma_finite_measure (count_space A)" ..
  1803 qed
  1804 
  1805 subsection {* Measure restricted to space *}
  1806 
  1807 lemma emeasure_restrict_space:
  1808   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  1809   shows "emeasure (restrict_space M \<Omega>) A = emeasure M A"
  1810 proof cases
  1811   assume "A \<in> sets M"
  1812   show ?thesis
  1813   proof (rule emeasure_measure_of[OF restrict_space_def])
  1814     show "op \<inter> \<Omega> ` sets M \<subseteq> Pow (\<Omega> \<inter> space M)" "A \<in> sets (restrict_space M \<Omega>)"
  1815       using `A \<subseteq> \<Omega>` `A \<in> sets M` sets.space_closed by (auto simp: sets_restrict_space)
  1816     show "positive (sets (restrict_space M \<Omega>)) (emeasure M)"
  1817       by (auto simp: positive_def emeasure_nonneg)
  1818     show "countably_additive (sets (restrict_space M \<Omega>)) (emeasure M)"
  1819     proof (rule countably_additiveI)
  1820       fix A :: "nat \<Rightarrow> _" assume "range A \<subseteq> sets (restrict_space M \<Omega>)" "disjoint_family A"
  1821       with assms have "\<And>i. A i \<in> sets M" "\<And>i. A i \<subseteq> space M" "disjoint_family A"
  1822         by (fastforce simp: sets_restrict_space_iff[OF assms(1)] image_subset_iff
  1823                       dest: sets.sets_into_space)+
  1824       then show "(\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
  1825         by (subst suminf_emeasure) (auto simp: disjoint_family_subset)
  1826     qed
  1827   qed
  1828 next
  1829   assume "A \<notin> sets M"
  1830   moreover with assms have "A \<notin> sets (restrict_space M \<Omega>)"
  1831     by (simp add: sets_restrict_space_iff)
  1832   ultimately show ?thesis
  1833     by (simp add: emeasure_notin_sets)
  1834 qed
  1835 
  1836 lemma measure_restrict_space:
  1837   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  1838   shows "measure (restrict_space M \<Omega>) A = measure M A"
  1839   using emeasure_restrict_space[OF assms] by (simp add: measure_def)
  1840 
  1841 lemma AE_restrict_space_iff:
  1842   assumes "\<Omega> \<inter> space M \<in> sets M"
  1843   shows "(AE x in restrict_space M \<Omega>. P x) \<longleftrightarrow> (AE x in M. x \<in> \<Omega> \<longrightarrow> P x)"
  1844 proof -
  1845   have ex_cong: "\<And>P Q f. (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> (\<And>x. Q x \<Longrightarrow> P (f x)) \<Longrightarrow> (\<exists>x. P x) \<longleftrightarrow> (\<exists>x. Q x)"
  1846     by auto
  1847   { fix X assume X: "X \<in> sets M" "emeasure M X = 0"
  1848     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) \<le> emeasure M X"
  1849       by (intro emeasure_mono) auto
  1850     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) = 0"
  1851       using X by (auto intro!: antisym) }
  1852   with assms show ?thesis
  1853     unfolding eventually_ae_filter
  1854     by (auto simp add: space_restrict_space null_sets_def sets_restrict_space_iff
  1855                        emeasure_restrict_space cong: conj_cong
  1856              intro!: ex_cong[where f="\<lambda>X. (\<Omega> \<inter> space M) \<inter> X"])
  1857 qed  
  1858 
  1859 lemma restrict_restrict_space:
  1860   assumes "A \<inter> space M \<in> sets M" "B \<inter> space M \<in> sets M"
  1861   shows "restrict_space (restrict_space M A) B = restrict_space M (A \<inter> B)" (is "?l = ?r")
  1862 proof (rule measure_eqI[symmetric])
  1863   show "sets ?r = sets ?l"
  1864     unfolding sets_restrict_space image_comp by (intro image_cong) auto
  1865 next
  1866   fix X assume "X \<in> sets (restrict_space M (A \<inter> B))"
  1867   then obtain Y where "Y \<in> sets M" "X = Y \<inter> A \<inter> B"
  1868     by (auto simp: sets_restrict_space)
  1869   with assms sets.Int[OF assms] show "emeasure ?r X = emeasure ?l X"
  1870     by (subst (1 2) emeasure_restrict_space)
  1871        (auto simp: space_restrict_space sets_restrict_space_iff emeasure_restrict_space ac_simps)
  1872 qed
  1873 
  1874 lemma restrict_count_space: "restrict_space (count_space B) A = count_space (A \<inter> B)"
  1875 proof (rule measure_eqI)
  1876   show "sets (restrict_space (count_space B) A) = sets (count_space (A \<inter> B))"
  1877     by (subst sets_restrict_space) auto
  1878   moreover fix X assume "X \<in> sets (restrict_space (count_space B) A)"
  1879   ultimately have "X \<subseteq> A \<inter> B" by auto
  1880   then show "emeasure (restrict_space (count_space B) A) X = emeasure (count_space (A \<inter> B)) X"
  1881     by (cases "finite X") (auto simp add: emeasure_restrict_space)
  1882 qed
  1883 
  1884 lemma sigma_finite_measure_restrict_space:
  1885   assumes "sigma_finite_measure M"
  1886   and A: "A \<in> sets M"
  1887   shows "sigma_finite_measure (restrict_space M A)"
  1888 proof -
  1889   interpret sigma_finite_measure M by fact
  1890   from sigma_finite_countable obtain C
  1891     where C: "countable C" "C \<subseteq> sets M" "(\<Union>C) = space M" "\<forall>a\<in>C. emeasure M a \<noteq> \<infinity>"
  1892     by blast
  1893   let ?C = "op \<inter> A ` C"
  1894   from C have "countable ?C" "?C \<subseteq> sets (restrict_space M A)" "(\<Union>?C) = space (restrict_space M A)"
  1895     by(auto simp add: sets_restrict_space space_restrict_space)
  1896   moreover {
  1897     fix a
  1898     assume "a \<in> ?C"
  1899     then obtain a' where "a = A \<inter> a'" "a' \<in> C" ..
  1900     then have "emeasure (restrict_space M A) a \<le> emeasure M a'"
  1901       using A C by(auto simp add: emeasure_restrict_space intro: emeasure_mono)
  1902     also have "\<dots> < \<infinity>" using C(4)[rule_format, of a'] \<open>a' \<in> C\<close> by simp
  1903     finally have "emeasure (restrict_space M A) a \<noteq> \<infinity>" by simp }
  1904   ultimately show ?thesis
  1905     by unfold_locales (rule exI conjI|assumption|blast)+
  1906 qed
  1907 
  1908 lemma finite_measure_restrict_space:
  1909   assumes "finite_measure M"
  1910   and A: "A \<in> sets M"
  1911   shows "finite_measure (restrict_space M A)"
  1912 proof -
  1913   interpret finite_measure M by fact
  1914   show ?thesis
  1915     by(rule finite_measureI)(simp add: emeasure_restrict_space A space_restrict_space)
  1916 qed
  1917 
  1918 lemma restrict_distr: 
  1919   assumes [measurable]: "f \<in> measurable M N"
  1920   assumes [simp]: "\<Omega> \<inter> space N \<in> sets N" and restrict: "f \<in> space M \<rightarrow> \<Omega>"
  1921   shows "restrict_space (distr M N f) \<Omega> = distr M (restrict_space N \<Omega>) f"
  1922   (is "?l = ?r")
  1923 proof (rule measure_eqI)
  1924   fix A assume "A \<in> sets (restrict_space (distr M N f) \<Omega>)"
  1925   with restrict show "emeasure ?l A = emeasure ?r A"
  1926     by (subst emeasure_distr)
  1927        (auto simp: sets_restrict_space_iff emeasure_restrict_space emeasure_distr
  1928              intro!: measurable_restrict_space2)
  1929 qed (simp add: sets_restrict_space)
  1930 
  1931 lemma measure_eqI_restrict_generator:
  1932   assumes E: "Int_stable E" "E \<subseteq> Pow \<Omega>" "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
  1933   assumes sets_eq: "sets M = sets N" and \<Omega>: "\<Omega> \<in> sets M"
  1934   assumes "sets (restrict_space M \<Omega>) = sigma_sets \<Omega> E"
  1935   assumes "sets (restrict_space N \<Omega>) = sigma_sets \<Omega> E" 
  1936   assumes ae: "AE x in M. x \<in> \<Omega>" "AE x in N. x \<in> \<Omega>"
  1937   assumes A: "countable A" "A \<noteq> {}" "A \<subseteq> E" "\<Union>A = \<Omega>" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  1938   shows "M = N"
  1939 proof (rule measure_eqI)
  1940   fix X assume X: "X \<in> sets M"
  1941   then have "emeasure M X = emeasure (restrict_space M \<Omega>) (X \<inter> \<Omega>)"
  1942     using ae \<Omega> by (auto simp add: emeasure_restrict_space intro!: emeasure_eq_AE)
  1943   also have "restrict_space M \<Omega> = restrict_space N \<Omega>"
  1944   proof (rule measure_eqI_generator_eq)
  1945     fix X assume "X \<in> E"
  1946     then show "emeasure (restrict_space M \<Omega>) X = emeasure (restrict_space N \<Omega>) X"
  1947       using E \<Omega> by (subst (1 2) emeasure_restrict_space) (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq])
  1948   next
  1949     show "range (from_nat_into A) \<subseteq> E" "(\<Union>i. from_nat_into A i) = \<Omega>"
  1950       unfolding Sup_image_eq[symmetric, where f="from_nat_into A"] using A by auto
  1951   next
  1952     fix i
  1953     have "emeasure (restrict_space M \<Omega>) (from_nat_into A i) = emeasure M (from_nat_into A i)"
  1954       using A \<Omega> by (subst emeasure_restrict_space)
  1955                    (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq] intro: from_nat_into)
  1956     with A show "emeasure (restrict_space M \<Omega>) (from_nat_into A i) \<noteq> \<infinity>"
  1957       by (auto intro: from_nat_into)
  1958   qed fact+
  1959   also have "emeasure (restrict_space N \<Omega>) (X \<inter> \<Omega>) = emeasure N X"
  1960     using X ae \<Omega> by (auto simp add: emeasure_restrict_space sets_eq intro!: emeasure_eq_AE)
  1961   finally show "emeasure M X = emeasure N X" .
  1962 qed fact
  1963 
  1964 subsection {* Null measure *}
  1965 
  1966 definition "null_measure M = sigma (space M) (sets M)"
  1967 
  1968 lemma space_null_measure[simp]: "space (null_measure M) = space M"
  1969   by (simp add: null_measure_def)
  1970 
  1971 lemma sets_null_measure[simp, measurable_cong]: "sets (null_measure M) = sets M" 
  1972   by (simp add: null_measure_def)
  1973 
  1974 lemma emeasure_null_measure[simp]: "emeasure (null_measure M) X = 0"
  1975   by (cases "X \<in> sets M", rule emeasure_measure_of)
  1976      (auto simp: positive_def countably_additive_def emeasure_notin_sets null_measure_def
  1977            dest: sets.sets_into_space)
  1978 
  1979 lemma measure_null_measure[simp]: "measure (null_measure M) X = 0"
  1980   by (simp add: measure_def)
  1981 
  1982 end
  1983