src/HOL/Library/Multiset_Order.thy
author haftmann
Sat Dec 17 15:22:13 2016 +0100 (2016-12-17)
changeset 64587 8355a6e2df79
parent 64418 91eae3a1be51
child 64978 5b9ba120d222
permissions -rw-r--r--
standardized notation
     1 (*  Title:      HOL/Library/Multiset_Order.thy
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Author:     Jasmin Blanchette, Inria, LORIA, MPII
     4 *)
     5 
     6 section \<open>More Theorems about the Multiset Order\<close>
     7 
     8 theory Multiset_Order
     9 imports Multiset
    10 begin
    11 
    12 subsection \<open>Alternative characterizations\<close>
    13 
    14 context preorder
    15 begin
    16 
    17 lemma order_mult: "class.order
    18   (\<lambda>M N. (M, N) \<in> mult {(x, y). x < y} \<or> M = N)
    19   (\<lambda>M N. (M, N) \<in> mult {(x, y). x < y})"
    20   (is "class.order ?le ?less")
    21 proof -
    22   have irrefl: "\<And>M :: 'a multiset. \<not> ?less M M"
    23   proof
    24     fix M :: "'a multiset"
    25     have "trans {(x'::'a, x). x' < x}"
    26       by (rule transI) (blast intro: less_trans)
    27     moreover
    28     assume "(M, M) \<in> mult {(x, y). x < y}"
    29     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
    30       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})"
    31       by (rule mult_implies_one_step)
    32     then obtain I J K where "M = I + J" and "M = I + K"
    33       and "J \<noteq> {#}" and "(\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})" by blast
    34     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset K. k < j" by auto
    35     have "finite (set_mset K)" by simp
    36     moreover note aux2
    37     ultimately have "set_mset K = {}"
    38       by (induct rule: finite_induct)
    39        (simp, metis (mono_tags) insert_absorb insert_iff insert_not_empty less_irrefl less_trans)
    40     with aux1 show False by simp
    41   qed
    42   have trans: "\<And>K M N :: 'a multiset. ?less K M \<Longrightarrow> ?less M N \<Longrightarrow> ?less K N"
    43     unfolding mult_def by (blast intro: trancl_trans)
    44   show "class.order ?le ?less"
    45     by standard (auto simp add: less_eq_multiset_def irrefl dest: trans)
    46 qed
    47 
    48 text \<open>The Dershowitz--Manna ordering:\<close>
    49 
    50 definition less_multiset\<^sub>D\<^sub>M where
    51   "less_multiset\<^sub>D\<^sub>M M N \<longleftrightarrow>
    52    (\<exists>X Y. X \<noteq> {#} \<and> X \<subseteq># N \<and> M = (N - X) + Y \<and> (\<forall>k. k \<in># Y \<longrightarrow> (\<exists>a. a \<in># X \<and> k < a)))"
    53 
    54 
    55 text \<open>The Huet--Oppen ordering:\<close>
    56 
    57 definition less_multiset\<^sub>H\<^sub>O where
    58   "less_multiset\<^sub>H\<^sub>O M N \<longleftrightarrow> M \<noteq> N \<and> (\<forall>y. count N y < count M y \<longrightarrow> (\<exists>x. y < x \<and> count M x < count N x))"
    59 
    60 lemma mult_imp_less_multiset\<^sub>H\<^sub>O:
    61   "(M, N) \<in> mult {(x, y). x < y} \<Longrightarrow> less_multiset\<^sub>H\<^sub>O M N"
    62 proof (unfold mult_def, induct rule: trancl_induct)
    63   case (base P)
    64   then show ?case
    65     by (auto elim!: mult1_lessE simp add: count_eq_zero_iff less_multiset\<^sub>H\<^sub>O_def split: if_splits dest!: Suc_lessD)
    66 next
    67   case (step N P)
    68   from step(3) have "M \<noteq> N" and
    69     **: "\<And>y. count N y < count M y \<Longrightarrow> (\<exists>x>y. count M x < count N x)"
    70     by (simp_all add: less_multiset\<^sub>H\<^sub>O_def)
    71   from step(2) obtain M0 a K where
    72     *: "P = add_mset a M0" "N = M0 + K" "a \<notin># K" "\<And>b. b \<in># K \<Longrightarrow> b < a"
    73     by (blast elim: mult1_lessE)
    74   from \<open>M \<noteq> N\<close> ** *(1,2,3) have "M \<noteq> P" by (force dest: *(4) elim!: less_asym split: if_splits )
    75   moreover
    76   { assume "count P a \<le> count M a"
    77     with \<open>a \<notin># K\<close> have "count N a < count M a" unfolding *(1,2)
    78       by (auto simp add: not_in_iff)
    79       with ** obtain z where z: "z > a" "count M z < count N z"
    80         by blast
    81       with * have "count N z \<le> count P z" 
    82         by (auto elim: less_asym intro: count_inI)
    83       with z have "\<exists>z > a. count M z < count P z" by auto
    84   } note count_a = this
    85   { fix y
    86     assume count_y: "count P y < count M y"
    87     have "\<exists>x>y. count M x < count P x"
    88     proof (cases "y = a")
    89       case True
    90       with count_y count_a show ?thesis by auto
    91     next
    92       case False
    93       show ?thesis
    94       proof (cases "y \<in># K")
    95         case True
    96         with *(4) have "y < a" by simp
    97         then show ?thesis by (cases "count P a \<le> count M a") (auto dest: count_a intro: less_trans)
    98       next
    99         case False
   100         with \<open>y \<noteq> a\<close> have "count P y = count N y" unfolding *(1,2)
   101           by (simp add: not_in_iff)
   102         with count_y ** obtain z where z: "z > y" "count M z < count N z" by auto
   103         show ?thesis
   104         proof (cases "z \<in># K")
   105           case True
   106           with *(4) have "z < a" by simp
   107           with z(1) show ?thesis
   108             by (cases "count P a \<le> count M a") (auto dest!: count_a intro: less_trans)
   109         next
   110           case False
   111           with \<open>a \<notin># K\<close> have "count N z \<le> count P z" unfolding *
   112             by (auto simp add: not_in_iff)
   113           with z show ?thesis by auto
   114         qed
   115       qed
   116     qed
   117   }
   118   ultimately show ?case unfolding less_multiset\<^sub>H\<^sub>O_def by blast
   119 qed
   120 
   121 lemma less_multiset\<^sub>D\<^sub>M_imp_mult:
   122   "less_multiset\<^sub>D\<^sub>M M N \<Longrightarrow> (M, N) \<in> mult {(x, y). x < y}"
   123 proof -
   124   assume "less_multiset\<^sub>D\<^sub>M M N"
   125   then obtain X Y where
   126     "X \<noteq> {#}" and "X \<subseteq># N" and "M = N - X + Y" and "\<forall>k. k \<in># Y \<longrightarrow> (\<exists>a. a \<in># X \<and> k < a)"
   127     unfolding less_multiset\<^sub>D\<^sub>M_def by blast
   128   then have "(N - X + Y, N - X + X) \<in> mult {(x, y). x < y}"
   129     by (intro one_step_implies_mult) (auto simp: Bex_def trans_def)
   130   with \<open>M = N - X + Y\<close> \<open>X \<subseteq># N\<close> show "(M, N) \<in> mult {(x, y). x < y}"
   131     by (metis subset_mset.diff_add)
   132 qed
   133 
   134 lemma less_multiset\<^sub>H\<^sub>O_imp_less_multiset\<^sub>D\<^sub>M: "less_multiset\<^sub>H\<^sub>O M N \<Longrightarrow> less_multiset\<^sub>D\<^sub>M M N"
   135 unfolding less_multiset\<^sub>D\<^sub>M_def
   136 proof (intro iffI exI conjI)
   137   assume "less_multiset\<^sub>H\<^sub>O M N"
   138   then obtain z where z: "count M z < count N z"
   139     unfolding less_multiset\<^sub>H\<^sub>O_def by (auto simp: multiset_eq_iff nat_neq_iff)
   140   define X where "X = N - M"
   141   define Y where "Y = M - N"
   142   from z show "X \<noteq> {#}" unfolding X_def by (auto simp: multiset_eq_iff not_less_eq_eq Suc_le_eq)
   143   from z show "X \<subseteq># N" unfolding X_def by auto
   144   show "M = (N - X) + Y" unfolding X_def Y_def multiset_eq_iff count_union count_diff by force
   145   show "\<forall>k. k \<in># Y \<longrightarrow> (\<exists>a. a \<in># X \<and> k < a)"
   146   proof (intro allI impI)
   147     fix k
   148     assume "k \<in># Y"
   149     then have "count N k < count M k" unfolding Y_def
   150       by (auto simp add: in_diff_count)
   151     with \<open>less_multiset\<^sub>H\<^sub>O M N\<close> obtain a where "k < a" and "count M a < count N a"
   152       unfolding less_multiset\<^sub>H\<^sub>O_def by blast
   153     then show "\<exists>a. a \<in># X \<and> k < a" unfolding X_def
   154       by (auto simp add: in_diff_count)
   155   qed
   156 qed
   157 
   158 lemma mult_less_multiset\<^sub>D\<^sub>M: "(M, N) \<in> mult {(x, y). x < y} \<longleftrightarrow> less_multiset\<^sub>D\<^sub>M M N"
   159   by (metis less_multiset\<^sub>D\<^sub>M_imp_mult less_multiset\<^sub>H\<^sub>O_imp_less_multiset\<^sub>D\<^sub>M mult_imp_less_multiset\<^sub>H\<^sub>O)
   160 
   161 lemma mult_less_multiset\<^sub>H\<^sub>O: "(M, N) \<in> mult {(x, y). x < y} \<longleftrightarrow> less_multiset\<^sub>H\<^sub>O M N"
   162   by (metis less_multiset\<^sub>D\<^sub>M_imp_mult less_multiset\<^sub>H\<^sub>O_imp_less_multiset\<^sub>D\<^sub>M mult_imp_less_multiset\<^sub>H\<^sub>O)
   163 
   164 lemmas mult\<^sub>D\<^sub>M = mult_less_multiset\<^sub>D\<^sub>M[unfolded less_multiset\<^sub>D\<^sub>M_def]
   165 lemmas mult\<^sub>H\<^sub>O = mult_less_multiset\<^sub>H\<^sub>O[unfolded less_multiset\<^sub>H\<^sub>O_def]
   166 
   167 end
   168 
   169 
   170 lemma less_multiset_less_multiset\<^sub>H\<^sub>O:
   171   "M < N \<longleftrightarrow> less_multiset\<^sub>H\<^sub>O M N"
   172   unfolding less_multiset_def mult\<^sub>H\<^sub>O less_multiset\<^sub>H\<^sub>O_def ..
   173 
   174 lemmas less_multiset\<^sub>D\<^sub>M = mult\<^sub>D\<^sub>M[folded less_multiset_def]
   175 lemmas less_multiset\<^sub>H\<^sub>O = mult\<^sub>H\<^sub>O[folded less_multiset_def]
   176 
   177 lemma subset_eq_imp_le_multiset:
   178   shows "M \<subseteq># N \<Longrightarrow> M \<le> N"
   179   unfolding less_eq_multiset_def less_multiset\<^sub>H\<^sub>O
   180   by (simp add: less_le_not_le subseteq_mset_def)
   181 
   182 lemma le_multiset_right_total:
   183   shows "M < add_mset x M"
   184   unfolding less_eq_multiset_def less_multiset\<^sub>H\<^sub>O by simp
   185 
   186 lemma less_eq_multiset_empty_left[simp]:
   187   shows "{#} \<le> M"
   188   by (simp add: subset_eq_imp_le_multiset)
   189 
   190 lemma ex_gt_imp_less_multiset: "(\<exists>y. y \<in># N \<and> (\<forall>x. x \<in># M \<longrightarrow> x < y)) \<Longrightarrow> M < N"
   191   unfolding less_multiset\<^sub>H\<^sub>O
   192   by (metis count_eq_zero_iff count_greater_zero_iff less_le_not_le)
   193 
   194 lemma less_eq_multiset_empty_right[simp]:
   195   "M \<noteq> {#} \<Longrightarrow> \<not> M \<le> {#}"
   196   by (metis less_eq_multiset_empty_left antisym)
   197 
   198 lemma le_multiset_empty_left[simp]: "M \<noteq> {#} \<Longrightarrow> {#} < M"
   199   by (simp add: less_multiset\<^sub>H\<^sub>O)
   200 
   201 lemma le_multiset_empty_right[simp]: "\<not> M < {#}"
   202   using subset_mset.le_zero_eq less_multiset\<^sub>D\<^sub>M by blast
   203 
   204 lemma union_le_diff_plus: "P \<subseteq># M \<Longrightarrow> N < P \<Longrightarrow> M - P + N < M"
   205   by (drule subset_mset.diff_add[symmetric]) (metis union_le_mono2)
   206 
   207 instantiation multiset :: (preorder) ordered_ab_semigroup_monoid_add_imp_le
   208 begin
   209 
   210 lemma less_eq_multiset\<^sub>H\<^sub>O:
   211   "M \<le> N \<longleftrightarrow> (\<forall>y. count N y < count M y \<longrightarrow> (\<exists>x. y < x \<and> count M x < count N x))"
   212   by (auto simp: less_eq_multiset_def less_multiset\<^sub>H\<^sub>O)
   213 
   214 instance by standard (auto simp: less_eq_multiset\<^sub>H\<^sub>O)
   215 
   216 lemma
   217   fixes M N :: "'a multiset"
   218   shows
   219     less_eq_multiset_plus_left: "N \<le> (M + N)" and
   220     less_eq_multiset_plus_right: "M \<le> (M + N)"
   221   by simp_all
   222 
   223 lemma
   224   fixes M N :: "'a multiset"
   225   shows
   226     le_multiset_plus_left_nonempty: "M \<noteq> {#} \<Longrightarrow> N < M + N" and
   227     le_multiset_plus_right_nonempty: "N \<noteq> {#} \<Longrightarrow> M < M + N"
   228     by simp_all
   229 
   230 end
   231 
   232 
   233 subsection \<open>Simprocs\<close>
   234 
   235 lemma mset_le_add_iff1:
   236   "j \<le> (i::nat) \<Longrightarrow> (repeat_mset i u + m \<le> repeat_mset j u + n) = (repeat_mset (i-j) u + m \<le> n)"
   237 proof -
   238   assume "j \<le> i"
   239   then have "j + (i - j) = i"
   240     using le_add_diff_inverse by blast
   241   then show ?thesis
   242     by (metis (no_types) add_le_cancel_left left_add_mult_distrib_mset)
   243 qed
   244 
   245 lemma mset_le_add_iff2:
   246   "i \<le> (j::nat) \<Longrightarrow> (repeat_mset i u + m \<le> repeat_mset j u + n) = (m \<le> repeat_mset (j-i) u + n)"
   247 proof -
   248   assume "i \<le> j"
   249   then have "i + (j - i) = j"
   250     using le_add_diff_inverse by blast
   251   then show ?thesis
   252     by (metis (no_types) add_le_cancel_left left_add_mult_distrib_mset)
   253 qed
   254 
   255 lemma mset_less_add_iff1:
   256   "j \<le> (i::nat) \<Longrightarrow> (repeat_mset i u + m < repeat_mset j u + n) = (repeat_mset (i-j) u + m < n)"
   257   by (simp add: less_le_not_le mset_le_add_iff1 mset_le_add_iff2)
   258 
   259 lemma mset_less_add_iff2:
   260      "i \<le> (j::nat) \<Longrightarrow> (repeat_mset i u + m < repeat_mset j u + n) = (m < repeat_mset (j-i) u + n)"
   261   by (simp add: less_le_not_le mset_le_add_iff1 mset_le_add_iff2)
   262 
   263 ML_file "multiset_order_simprocs.ML"
   264 
   265 simproc_setup msetless_cancel_numerals
   266   ("(l::'a::preorder multiset) + m < n" | "(l::'a multiset) < m + n" |
   267    "add_mset a m < n" | "m < add_mset a n") =
   268   \<open>fn phi => Multiset_Order_Simprocs.less_cancel_msets\<close>
   269 
   270 simproc_setup msetle_cancel_numerals
   271   ("(l::'a::preorder multiset) + m \<le> n" | "(l::'a multiset) \<le> m + n" |
   272    "add_mset a m \<le> n" | "m \<le> add_mset a n") =
   273   \<open>fn phi => Multiset_Order_Simprocs.le_cancel_msets\<close>
   274 
   275 
   276 subsection \<open>Additional facts and instantiations\<close>
   277 
   278 lemma ex_gt_count_imp_le_multiset:
   279   "(\<forall>y :: 'a :: order. y \<in># M + N \<longrightarrow> y \<le> x) \<Longrightarrow> count M x < count N x \<Longrightarrow> M < N"
   280   unfolding less_multiset\<^sub>H\<^sub>O
   281   by (metis count_greater_zero_iff le_imp_less_or_eq less_imp_not_less not_gr_zero union_iff)
   282 
   283 lemma mset_lt_single_iff[iff]: "{#x#} < {#y#} \<longleftrightarrow> x < y"
   284   unfolding less_multiset\<^sub>H\<^sub>O by simp
   285 
   286 lemma mset_le_single_iff[iff]: "{#x#} \<le> {#y#} \<longleftrightarrow> x \<le> y" for x y :: "'a::order"
   287   unfolding less_eq_multiset\<^sub>H\<^sub>O by force
   288 
   289 
   290 instance multiset :: (linorder) linordered_cancel_ab_semigroup_add
   291   by standard (metis less_eq_multiset\<^sub>H\<^sub>O not_less_iff_gr_or_eq)
   292 
   293 lemma less_eq_multiset_total:
   294   fixes M N :: "'a :: linorder multiset"
   295   shows "\<not> M \<le> N \<Longrightarrow> N \<le> M"
   296   by simp
   297 
   298 instantiation multiset :: (wellorder) wellorder
   299 begin
   300 
   301 lemma wf_less_multiset: "wf {(M :: 'a multiset, N). M < N}"
   302   unfolding less_multiset_def by (auto intro: wf_mult wf)
   303 
   304 instance by standard (metis less_multiset_def wf wf_def wf_mult)
   305 
   306 end
   307 
   308 instantiation multiset :: (preorder) order_bot
   309 begin
   310 
   311 definition bot_multiset :: "'a multiset" where "bot_multiset = {#}"
   312 
   313 instance by standard (simp add: bot_multiset_def)
   314 
   315 end
   316 
   317 instance multiset :: (preorder) no_top
   318 proof standard
   319   fix x :: "'a multiset"
   320   obtain a :: 'a where True by simp
   321   have "x < x + (x + {#a#})"
   322     by simp
   323   then show "\<exists>y. x < y"
   324     by blast
   325 qed
   326 
   327 instance multiset :: (preorder) ordered_cancel_comm_monoid_add
   328   by standard
   329 
   330 end