src/HOL/SEQ.thy
author paulson
Fri Sep 25 13:47:28 2009 +0100 (2009-09-25)
changeset 32707 836ec9d0a0c8
parent 32436 10cd49e0c067
child 32877 6f09346c7c08
permissions -rw-r--r--
New lemmas involving the real numbers, especially limits and series
     1 (*  Title       : SEQ.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Description : Convergence of sequences and series
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6     Additional contributions by Jeremy Avigad and Brian Huffman
     7 *)
     8 
     9 header {* Sequences and Convergence *}
    10 
    11 theory SEQ
    12 imports Limits
    13 begin
    14 
    15 definition
    16   Zseq :: "[nat \<Rightarrow> 'a::real_normed_vector] \<Rightarrow> bool" where
    17     --{*Standard definition of sequence converging to zero*}
    18   [code del]: "Zseq X = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. norm (X n) < r)"
    19 
    20 definition
    21   LIMSEQ :: "[nat \<Rightarrow> 'a::metric_space, 'a] \<Rightarrow> bool"
    22     ("((_)/ ----> (_))" [60, 60] 60) where
    23     --{*Standard definition of convergence of sequence*}
    24   [code del]: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
    25 
    26 definition
    27   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    28     --{*Standard definition of limit using choice operator*}
    29   "lim X = (THE L. X ----> L)"
    30 
    31 definition
    32   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    33     --{*Standard definition of convergence*}
    34   "convergent X = (\<exists>L. X ----> L)"
    35 
    36 definition
    37   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    38     --{*Standard definition for bounded sequence*}
    39   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    40 
    41 definition
    42   monoseq :: "(nat=>real)=>bool" where
    43     --{*Definition of monotonicity. 
    44         The use of disjunction here complicates proofs considerably. 
    45         One alternative is to add a Boolean argument to indicate the direction. 
    46         Another is to develop the notions of increasing and decreasing first.*}
    47   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    48 
    49 definition
    50   incseq :: "(nat=>real)=>bool" where
    51     --{*Increasing sequence*}
    52   [code del]: "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    53 
    54 definition
    55   decseq :: "(nat=>real)=>bool" where
    56     --{*Increasing sequence*}
    57   [code del]: "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    58 
    59 definition
    60   subseq :: "(nat => nat) => bool" where
    61     --{*Definition of subsequence*}
    62   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    63 
    64 definition
    65   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    66     --{*Standard definition of the Cauchy condition*}
    67   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    68 
    69 
    70 subsection {* Bounded Sequences *}
    71 
    72 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    73 unfolding Bseq_def
    74 proof (intro exI conjI allI)
    75   show "0 < max K 1" by simp
    76 next
    77   fix n::nat
    78   have "norm (X n) \<le> K" by (rule K)
    79   thus "norm (X n) \<le> max K 1" by simp
    80 qed
    81 
    82 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    83 unfolding Bseq_def by auto
    84 
    85 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    86 proof (rule BseqI')
    87   let ?A = "norm ` X ` {..N}"
    88   have 1: "finite ?A" by simp
    89   fix n::nat
    90   show "norm (X n) \<le> max K (Max ?A)"
    91   proof (cases rule: linorder_le_cases)
    92     assume "n \<ge> N"
    93     hence "norm (X n) \<le> K" using K by simp
    94     thus "norm (X n) \<le> max K (Max ?A)" by simp
    95   next
    96     assume "n \<le> N"
    97     hence "norm (X n) \<in> ?A" by simp
    98     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
    99     thus "norm (X n) \<le> max K (Max ?A)" by simp
   100   qed
   101 qed
   102 
   103 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   104 unfolding Bseq_def by auto
   105 
   106 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   107 apply (erule BseqE)
   108 apply (rule_tac N="k" and K="K" in BseqI2')
   109 apply clarify
   110 apply (drule_tac x="n - k" in spec, simp)
   111 done
   112 
   113 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   114 unfolding Bfun_def eventually_sequentially
   115 apply (rule iffI)
   116 apply (simp add: Bseq_def)
   117 apply (auto intro: BseqI2')
   118 done
   119 
   120 
   121 subsection {* Sequences That Converge to Zero *}
   122 
   123 lemma ZseqI:
   124   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r) \<Longrightarrow> Zseq X"
   125 unfolding Zseq_def by simp
   126 
   127 lemma ZseqD:
   128   "\<lbrakk>Zseq X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r"
   129 unfolding Zseq_def by simp
   130 
   131 lemma Zseq_conv_Zfun: "Zseq X \<longleftrightarrow> Zfun X sequentially"
   132 unfolding Zseq_def Zfun_def eventually_sequentially ..
   133 
   134 lemma Zseq_zero: "Zseq (\<lambda>n. 0)"
   135 unfolding Zseq_def by simp
   136 
   137 lemma Zseq_const_iff: "Zseq (\<lambda>n. k) = (k = 0)"
   138 unfolding Zseq_def by force
   139 
   140 lemma Zseq_norm_iff: "Zseq (\<lambda>n. norm (X n)) = Zseq (\<lambda>n. X n)"
   141 unfolding Zseq_def by simp
   142 
   143 lemma Zseq_imp_Zseq:
   144   assumes X: "Zseq X"
   145   assumes Y: "\<And>n. norm (Y n) \<le> norm (X n) * K"
   146   shows "Zseq (\<lambda>n. Y n)"
   147 using X Y Zfun_imp_Zfun [of X sequentially Y K]
   148 unfolding Zseq_conv_Zfun by simp
   149 
   150 lemma Zseq_le: "\<lbrakk>Zseq Y; \<forall>n. norm (X n) \<le> norm (Y n)\<rbrakk> \<Longrightarrow> Zseq X"
   151 by (erule_tac K="1" in Zseq_imp_Zseq, simp)
   152 
   153 lemma Zseq_add:
   154   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n + Y n)"
   155 unfolding Zseq_conv_Zfun by (rule Zfun_add)
   156 
   157 lemma Zseq_minus: "Zseq X \<Longrightarrow> Zseq (\<lambda>n. - X n)"
   158 unfolding Zseq_def by simp
   159 
   160 lemma Zseq_diff: "\<lbrakk>Zseq X; Zseq Y\<rbrakk> \<Longrightarrow> Zseq (\<lambda>n. X n - Y n)"
   161 by (simp only: diff_minus Zseq_add Zseq_minus)
   162 
   163 lemma (in bounded_linear) Zseq:
   164   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. f (X n))"
   165 unfolding Zseq_conv_Zfun by (rule Zfun)
   166 
   167 lemma (in bounded_bilinear) Zseq:
   168   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   169 unfolding Zseq_conv_Zfun by (rule Zfun)
   170 
   171 lemma (in bounded_bilinear) Zseq_prod_Bseq:
   172   "Zseq X \<Longrightarrow> Bseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   173 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   174 by (rule Zfun_prod_Bfun)
   175 
   176 lemma (in bounded_bilinear) Bseq_prod_Zseq:
   177   "Bseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   178 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   179 by (rule Bfun_prod_Zfun)
   180 
   181 lemma (in bounded_bilinear) Zseq_left:
   182   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. X n ** a)"
   183 by (rule bounded_linear_left [THEN bounded_linear.Zseq])
   184 
   185 lemma (in bounded_bilinear) Zseq_right:
   186   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. a ** X n)"
   187 by (rule bounded_linear_right [THEN bounded_linear.Zseq])
   188 
   189 lemmas Zseq_mult = mult.Zseq
   190 lemmas Zseq_mult_right = mult.Zseq_right
   191 lemmas Zseq_mult_left = mult.Zseq_left
   192 
   193 
   194 subsection {* Limits of Sequences *}
   195 
   196 lemma LIMSEQ_conv_tendsto: "(X ----> L) \<longleftrightarrow> (X ---> L) sequentially"
   197 unfolding LIMSEQ_def tendsto_iff eventually_sequentially ..
   198 
   199 lemma LIMSEQ_iff:
   200   fixes L :: "'a::real_normed_vector"
   201   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   202 unfolding LIMSEQ_def dist_norm ..
   203 
   204 lemma LIMSEQ_Zseq_iff: "((\<lambda>n. X n) ----> L) = Zseq (\<lambda>n. X n - L)"
   205 by (simp only: LIMSEQ_iff Zseq_def)
   206 
   207 lemma metric_LIMSEQ_I:
   208   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   209 by (simp add: LIMSEQ_def)
   210 
   211 lemma metric_LIMSEQ_D:
   212   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   213 by (simp add: LIMSEQ_def)
   214 
   215 lemma LIMSEQ_I:
   216   fixes L :: "'a::real_normed_vector"
   217   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   218 by (simp add: LIMSEQ_iff)
   219 
   220 lemma LIMSEQ_D:
   221   fixes L :: "'a::real_normed_vector"
   222   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   223 by (simp add: LIMSEQ_iff)
   224 
   225 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   226 by (simp add: LIMSEQ_def)
   227 
   228 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   229 apply (safe intro!: LIMSEQ_const)
   230 apply (rule ccontr)
   231 apply (drule_tac r="dist k l" in metric_LIMSEQ_D)
   232 apply (simp add: zero_less_dist_iff)
   233 apply auto
   234 done
   235 
   236 lemma LIMSEQ_norm:
   237   fixes a :: "'a::real_normed_vector"
   238   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   239 unfolding LIMSEQ_conv_tendsto by (rule tendsto_norm)
   240 
   241 lemma LIMSEQ_ignore_initial_segment:
   242   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   243 apply (rule metric_LIMSEQ_I)
   244 apply (drule (1) metric_LIMSEQ_D)
   245 apply (erule exE, rename_tac N)
   246 apply (rule_tac x=N in exI)
   247 apply simp
   248 done
   249 
   250 lemma LIMSEQ_offset:
   251   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   252 apply (rule metric_LIMSEQ_I)
   253 apply (drule (1) metric_LIMSEQ_D)
   254 apply (erule exE, rename_tac N)
   255 apply (rule_tac x="N + k" in exI)
   256 apply clarify
   257 apply (drule_tac x="n - k" in spec)
   258 apply (simp add: le_diff_conv2)
   259 done
   260 
   261 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   262 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   263 
   264 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   265 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   266 
   267 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   268 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   269 
   270 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   271   unfolding LIMSEQ_def
   272   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   273 
   274 lemma LIMSEQ_add:
   275   fixes a b :: "'a::real_normed_vector"
   276   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   277 unfolding LIMSEQ_conv_tendsto by (rule tendsto_add)
   278 
   279 lemma LIMSEQ_minus:
   280   fixes a :: "'a::real_normed_vector"
   281   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   282 unfolding LIMSEQ_conv_tendsto by (rule tendsto_minus)
   283 
   284 lemma LIMSEQ_minus_cancel:
   285   fixes a :: "'a::real_normed_vector"
   286   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   287 by (drule LIMSEQ_minus, simp)
   288 
   289 lemma LIMSEQ_diff:
   290   fixes a b :: "'a::real_normed_vector"
   291   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   292 unfolding LIMSEQ_conv_tendsto by (rule tendsto_diff)
   293 
   294 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   295 apply (rule ccontr)
   296 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   297 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   298 apply (clarify, rename_tac M N)
   299 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   300 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   301 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   302 apply (subst dist_commute, rule dist_triangle)
   303 done
   304 
   305 lemma (in bounded_linear) LIMSEQ:
   306   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   307 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   308 
   309 lemma (in bounded_bilinear) LIMSEQ:
   310   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   311 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   312 
   313 lemma LIMSEQ_mult:
   314   fixes a b :: "'a::real_normed_algebra"
   315   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   316 by (rule mult.LIMSEQ)
   317 
   318 lemma Bseq_inverse_lemma:
   319   fixes x :: "'a::real_normed_div_algebra"
   320   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   321 apply (subst nonzero_norm_inverse, clarsimp)
   322 apply (erule (1) le_imp_inverse_le)
   323 done
   324 
   325 lemma Bseq_inverse:
   326   fixes a :: "'a::real_normed_div_algebra"
   327   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   328 unfolding LIMSEQ_conv_tendsto Bseq_conv_Bfun
   329 by (rule Bfun_inverse)
   330 
   331 lemma LIMSEQ_inverse:
   332   fixes a :: "'a::real_normed_div_algebra"
   333   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   334 unfolding LIMSEQ_conv_tendsto
   335 by (rule tendsto_inverse)
   336 
   337 lemma LIMSEQ_divide:
   338   fixes a b :: "'a::real_normed_field"
   339   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   340 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   341 
   342 lemma LIMSEQ_pow:
   343   fixes a :: "'a::{power, real_normed_algebra}"
   344   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   345 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   346 
   347 lemma LIMSEQ_setsum:
   348   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   349   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   350   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   351 using n unfolding LIMSEQ_conv_tendsto by (rule tendsto_setsum)
   352 
   353 lemma LIMSEQ_setprod:
   354   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   355   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   356   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   357 proof (cases "finite S")
   358   case True
   359   thus ?thesis using n
   360   proof (induct)
   361     case empty
   362     show ?case
   363       by (simp add: LIMSEQ_const)
   364   next
   365     case insert
   366     thus ?case
   367       by (simp add: LIMSEQ_mult)
   368   qed
   369 next
   370   case False
   371   thus ?thesis
   372     by (simp add: setprod_def LIMSEQ_const)
   373 qed
   374 
   375 lemma LIMSEQ_add_const:
   376   fixes a :: "'a::real_normed_vector"
   377   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   378 by (simp add: LIMSEQ_add LIMSEQ_const)
   379 
   380 (* FIXME: delete *)
   381 lemma LIMSEQ_add_minus:
   382   fixes a b :: "'a::real_normed_vector"
   383   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   384 by (simp only: LIMSEQ_add LIMSEQ_minus)
   385 
   386 lemma LIMSEQ_diff_const:
   387   fixes a b :: "'a::real_normed_vector"
   388   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   389 by (simp add: LIMSEQ_diff LIMSEQ_const)
   390 
   391 lemma LIMSEQ_diff_approach_zero:
   392   fixes L :: "'a::real_normed_vector"
   393   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   394 by (drule (1) LIMSEQ_add, simp)
   395 
   396 lemma LIMSEQ_diff_approach_zero2:
   397   fixes L :: "'a::real_normed_vector"
   398   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L";
   399 by (drule (1) LIMSEQ_diff, simp)
   400 
   401 text{*A sequence tends to zero iff its abs does*}
   402 lemma LIMSEQ_norm_zero:
   403   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   404   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   405 by (simp add: LIMSEQ_iff)
   406 
   407 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   408 by (simp add: LIMSEQ_iff)
   409 
   410 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   411 by (drule LIMSEQ_norm, simp)
   412 
   413 text{*An unbounded sequence's inverse tends to 0*}
   414 
   415 lemma LIMSEQ_inverse_zero:
   416   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   417 apply (rule LIMSEQ_I)
   418 apply (drule_tac x="inverse r" in spec, safe)
   419 apply (rule_tac x="N" in exI, safe)
   420 apply (drule_tac x="n" in spec, safe)
   421 apply (frule positive_imp_inverse_positive)
   422 apply (frule (1) less_imp_inverse_less)
   423 apply (subgoal_tac "0 < X n", simp)
   424 apply (erule (1) order_less_trans)
   425 done
   426 
   427 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   428 
   429 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   430 apply (rule LIMSEQ_inverse_zero, safe)
   431 apply (cut_tac x = r in reals_Archimedean2)
   432 apply (safe, rule_tac x = n in exI)
   433 apply (auto simp add: real_of_nat_Suc)
   434 done
   435 
   436 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   437 infinity is now easily proved*}
   438 
   439 lemma LIMSEQ_inverse_real_of_nat_add:
   440      "(%n. r + inverse(real(Suc n))) ----> r"
   441 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   442 
   443 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   444      "(%n. r + -inverse(real(Suc n))) ----> r"
   445 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   446 
   447 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   448      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   449 by (cut_tac b=1 in
   450         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   451 
   452 lemma LIMSEQ_le_const:
   453   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   454 apply (rule ccontr, simp only: linorder_not_le)
   455 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   456 apply clarsimp
   457 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   458 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   459 apply simp
   460 done
   461 
   462 lemma LIMSEQ_le_const2:
   463   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   464 apply (subgoal_tac "- a \<le> - x", simp)
   465 apply (rule LIMSEQ_le_const)
   466 apply (erule LIMSEQ_minus)
   467 apply simp
   468 done
   469 
   470 lemma LIMSEQ_le:
   471   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   472 apply (subgoal_tac "0 \<le> y - x", simp)
   473 apply (rule LIMSEQ_le_const)
   474 apply (erule (1) LIMSEQ_diff)
   475 apply (simp add: le_diff_eq)
   476 done
   477 
   478 
   479 subsection {* Convergence *}
   480 
   481 lemma limI: "X ----> L ==> lim X = L"
   482 apply (simp add: lim_def)
   483 apply (blast intro: LIMSEQ_unique)
   484 done
   485 
   486 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   487 by (simp add: convergent_def)
   488 
   489 lemma convergentI: "(X ----> L) ==> convergent X"
   490 by (auto simp add: convergent_def)
   491 
   492 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   493 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   494 
   495 lemma convergent_minus_iff:
   496   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   497   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   498 apply (simp add: convergent_def)
   499 apply (auto dest: LIMSEQ_minus)
   500 apply (drule LIMSEQ_minus, auto)
   501 done
   502 
   503 lemma lim_le:
   504   fixes x :: real
   505   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   506   shows "lim f \<le> x"
   507 proof (rule classical)
   508   assume "\<not> lim f \<le> x"
   509   hence 0: "0 < lim f - x" by arith
   510   have 1: "f----> lim f"
   511     by (metis convergent_LIMSEQ_iff f) 
   512   thus ?thesis
   513     proof (simp add: LIMSEQ_iff)
   514       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   515       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   516 	by (metis 0)
   517       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   518 	by blast
   519       thus "lim f \<le> x"
   520 	by (metis add_cancel_end add_minus_cancel diff_def linorder_linear 
   521                   linorder_not_le minus_diff_eq abs_diff_less_iff fn_le) 
   522     qed
   523 qed
   524 
   525 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   526 
   527 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   528   unfolding Ex1_def
   529   apply (rule_tac x="nat_rec e f" in exI)
   530   apply (rule conjI)+
   531 apply (rule def_nat_rec_0, simp)
   532 apply (rule allI, rule def_nat_rec_Suc, simp)
   533 apply (rule allI, rule impI, rule ext)
   534 apply (erule conjE)
   535 apply (induct_tac x)
   536 apply (simp add: nat_rec_0)
   537 apply (erule_tac x="n" in allE)
   538 apply (simp)
   539 done
   540 
   541 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   542 
   543 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   544 apply (simp add: subseq_def)
   545 apply (auto dest!: less_imp_Suc_add)
   546 apply (induct_tac k)
   547 apply (auto intro: less_trans)
   548 done
   549 
   550 lemma monoseq_Suc:
   551    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   552                  | (\<forall>n. X (Suc n) \<le> X n))"
   553 apply (simp add: monoseq_def)
   554 apply (auto dest!: le_imp_less_or_eq)
   555 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   556 apply (induct_tac "ka")
   557 apply (auto intro: order_trans)
   558 apply (erule contrapos_np)
   559 apply (induct_tac "k")
   560 apply (auto intro: order_trans)
   561 done
   562 
   563 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   564 by (simp add: monoseq_def)
   565 
   566 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   567 by (simp add: monoseq_def)
   568 
   569 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   570 by (simp add: monoseq_Suc)
   571 
   572 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   573 by (simp add: monoseq_Suc)
   574 
   575 lemma monoseq_minus: assumes "monoseq a"
   576   shows "monoseq (\<lambda> n. - a n)"
   577 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   578   case True
   579   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   580   thus ?thesis by (rule monoI2)
   581 next
   582   case False
   583   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   584   thus ?thesis by (rule monoI1)
   585 qed
   586 
   587 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   588   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   589          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   590 proof -
   591   { fix x n fix a :: "nat \<Rightarrow> real"
   592     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   593     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   594     have "a n \<le> x"
   595     proof (rule ccontr)
   596       assume "\<not> a n \<le> x" hence "x < a n" by auto
   597       hence "0 < a n - x" by auto
   598       from `a ----> x`[THEN LIMSEQ_D, OF this]
   599       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   600       hence "norm (a (max no n) - x) < a n - x" by auto
   601       moreover
   602       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   603       hence "x < a (max no n)" by auto
   604       ultimately
   605       have "a (max no n) < a n" by auto
   606       with monotone[where m=n and n="max no n"]
   607       show False by (auto simp:max_def split:split_if_asm)
   608     qed
   609   } note top_down = this
   610   { fix x n m fix a :: "nat \<Rightarrow> real"
   611     assume "a ----> x" and "monoseq a" and "a m < x"
   612     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   613     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   614       case True with top_down and `a ----> x` show ?thesis by auto
   615     next
   616       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   617       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   618       hence False using `a m < x` by auto
   619       thus ?thesis ..
   620     qed
   621   } note when_decided = this
   622 
   623   show ?thesis
   624   proof (cases "\<exists> m. a m \<noteq> x")
   625     case True then obtain m where "a m \<noteq> x" by auto
   626     show ?thesis
   627     proof (cases "a m < x")
   628       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   629       show ?thesis by blast
   630     next
   631       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   632       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   633       show ?thesis by auto
   634     qed
   635   qed auto
   636 qed
   637 
   638 text{* for any sequence, there is a mootonic subsequence *}
   639 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   640 proof-
   641   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   642     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   643     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   644     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   645     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   646       using H apply - 
   647       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   648       unfolding order_le_less by blast 
   649     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   650     {fix n
   651       have "?P (f (Suc n)) (f n)" 
   652 	unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   653 	using H apply - 
   654       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   655       unfolding order_le_less by blast 
   656     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   657   note fSuc = this
   658     {fix p q assume pq: "p \<ge> f q"
   659       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   660 	by (cases q, simp_all) }
   661     note pqth = this
   662     {fix q
   663       have "f (Suc q) > f q" apply (induct q) 
   664 	using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   665     note fss = this
   666     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   667     {fix a b 
   668       have "f a \<le> f (a + b)"
   669       proof(induct b)
   670 	case 0 thus ?case by simp
   671       next
   672 	case (Suc b)
   673 	from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   674       qed}
   675     note fmon0 = this
   676     have "monoseq (\<lambda>n. s (f n))" 
   677     proof-
   678       {fix n
   679 	have "s (f n) \<ge> s (f (Suc n))" 
   680 	proof(cases n)
   681 	  case 0
   682 	  assume n0: "n = 0"
   683 	  from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   684 	  from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   685 	next
   686 	  case (Suc m)
   687 	  assume m: "n = Suc m"
   688 	  from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   689 	  from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   690 	qed}
   691       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   692     qed
   693     with th1 have ?thesis by blast}
   694   moreover
   695   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   696     {fix p assume p: "p \<ge> Suc N" 
   697       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   698       have "m \<noteq> p" using m(2) by auto 
   699       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   700     note th0 = this
   701     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   702     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   703     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   704       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   705     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   706       using N apply - 
   707       apply (erule allE[where x="Suc N"], clarsimp)
   708       apply (rule_tac x="m" in exI)
   709       apply auto
   710       apply (subgoal_tac "Suc N \<noteq> m")
   711       apply simp
   712       apply (rule ccontr, simp)
   713       done
   714     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   715     {fix n
   716       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   717 	unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   718       proof (induct n)
   719 	case 0 thus ?case
   720 	  using f0 N apply auto 
   721 	  apply (erule allE[where x="f 0"], clarsimp) 
   722 	  apply (rule_tac x="m" in exI, simp)
   723 	  by (subgoal_tac "f 0 \<noteq> m", auto)
   724       next
   725 	case (Suc n)
   726 	from Suc.hyps have Nfn: "N < f n" by blast
   727 	from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   728 	with Nfn have mN: "m > N" by arith
   729 	note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   730 	
   731 	from key have th0: "f (Suc n) > N" by simp
   732 	from N[rule_format, OF th0]
   733 	obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   734 	have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   735 	hence "m' > f (Suc n)" using m'(1) by simp
   736 	with key m'(2) show ?case by auto
   737       qed}
   738     note fSuc = this
   739     {fix n
   740       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   741       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   742     note thf = this
   743     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   744     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   745       apply -
   746       apply (rule disjI1)
   747       apply auto
   748       apply (rule order_less_imp_le)
   749       apply blast
   750       done
   751     then have ?thesis  using sqf by blast}
   752   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   753 qed
   754 
   755 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   756 proof(induct n)
   757   case 0 thus ?case by simp
   758 next
   759   case (Suc n)
   760   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   761   have "n < f (Suc n)" by arith 
   762   thus ?case by arith
   763 qed
   764 
   765 lemma LIMSEQ_subseq_LIMSEQ:
   766   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   767 apply (auto simp add: LIMSEQ_def) 
   768 apply (drule_tac x=r in spec, clarify)  
   769 apply (rule_tac x=no in exI, clarify) 
   770 apply (blast intro: seq_suble le_trans dest!: spec) 
   771 done
   772 
   773 subsection {* Bounded Monotonic Sequences *}
   774 
   775 
   776 text{*Bounded Sequence*}
   777 
   778 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   779 by (simp add: Bseq_def)
   780 
   781 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   782 by (auto simp add: Bseq_def)
   783 
   784 lemma lemma_NBseq_def:
   785      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   786       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   787 proof auto
   788   fix K :: real
   789   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   790   then have "K \<le> real (Suc n)" by auto
   791   assume "\<forall>m. norm (X m) \<le> K"
   792   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   793   proof
   794     fix m :: 'a
   795     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   796     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   797   qed
   798   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   799 next
   800   fix N :: nat
   801   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   802   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   803   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   804 qed
   805 
   806 
   807 text{* alternative definition for Bseq *}
   808 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   809 apply (simp add: Bseq_def)
   810 apply (simp (no_asm) add: lemma_NBseq_def)
   811 done
   812 
   813 lemma lemma_NBseq_def2:
   814      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   815 apply (subst lemma_NBseq_def, auto)
   816 apply (rule_tac x = "Suc N" in exI)
   817 apply (rule_tac [2] x = N in exI)
   818 apply (auto simp add: real_of_nat_Suc)
   819  prefer 2 apply (blast intro: order_less_imp_le)
   820 apply (drule_tac x = n in spec, simp)
   821 done
   822 
   823 (* yet another definition for Bseq *)
   824 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   825 by (simp add: Bseq_def lemma_NBseq_def2)
   826 
   827 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   828 
   829 lemma Bseq_isUb:
   830   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   831 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   832 
   833 
   834 text{* Use completeness of reals (supremum property)
   835    to show that any bounded sequence has a least upper bound*}
   836 
   837 lemma Bseq_isLub:
   838   "!!(X::nat=>real). Bseq X ==>
   839    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   840 by (blast intro: reals_complete Bseq_isUb)
   841 
   842 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   843 
   844 lemma lemma_converg1:
   845      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   846                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   847                |] ==> \<forall>n \<ge> ma. X n = X ma"
   848 apply safe
   849 apply (drule_tac y = "X n" in isLubD2)
   850 apply (blast dest: order_antisym)+
   851 done
   852 
   853 text{* The best of both worlds: Easier to prove this result as a standard
   854    theorem and then use equivalence to "transfer" it into the
   855    equivalent nonstandard form if needed!*}
   856 
   857 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   858 apply (simp add: LIMSEQ_def)
   859 apply (rule_tac x = "X m" in exI, safe)
   860 apply (rule_tac x = m in exI, safe)
   861 apply (drule spec, erule impE, auto)
   862 done
   863 
   864 lemma lemma_converg2:
   865    "!!(X::nat=>real).
   866     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   867 apply safe
   868 apply (drule_tac y = "X m" in isLubD2)
   869 apply (auto dest!: order_le_imp_less_or_eq)
   870 done
   871 
   872 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   873 by (rule setleI [THEN isUbI], auto)
   874 
   875 text{* FIXME: @{term "U - T < U"} is redundant *}
   876 lemma lemma_converg4: "!!(X::nat=> real).
   877                [| \<forall>m. X m ~= U;
   878                   isLub UNIV {x. \<exists>n. X n = x} U;
   879                   0 < T;
   880                   U + - T < U
   881                |] ==> \<exists>m. U + -T < X m & X m < U"
   882 apply (drule lemma_converg2, assumption)
   883 apply (rule ccontr, simp)
   884 apply (simp add: linorder_not_less)
   885 apply (drule lemma_converg3)
   886 apply (drule isLub_le_isUb, assumption)
   887 apply (auto dest: order_less_le_trans)
   888 done
   889 
   890 text{*A standard proof of the theorem for monotone increasing sequence*}
   891 
   892 lemma Bseq_mono_convergent:
   893      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   894 apply (simp add: convergent_def)
   895 apply (frule Bseq_isLub, safe)
   896 apply (case_tac "\<exists>m. X m = U", auto)
   897 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   898 (* second case *)
   899 apply (rule_tac x = U in exI)
   900 apply (subst LIMSEQ_iff, safe)
   901 apply (frule lemma_converg2, assumption)
   902 apply (drule lemma_converg4, auto)
   903 apply (rule_tac x = m in exI, safe)
   904 apply (subgoal_tac "X m \<le> X n")
   905  prefer 2 apply blast
   906 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   907 done
   908 
   909 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   910 by (simp add: Bseq_def)
   911 
   912 text{*Main monotonicity theorem*}
   913 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   914 apply (simp add: monoseq_def, safe)
   915 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   916 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   917 apply (auto intro!: Bseq_mono_convergent)
   918 done
   919 
   920 subsubsection{*Increasing and Decreasing Series*}
   921 
   922 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   923   by (simp add: incseq_def monoseq_def) 
   924 
   925 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   926   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   927 proof
   928   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   929   thus ?thesis by simp
   930 next
   931   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   932   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
   933     by (auto simp add: incseq_def intro: order_antisym)
   934   have X: "!!n. X n = X 0"
   935     by (blast intro: const [of 0]) 
   936   have "X = (\<lambda>n. X 0)"
   937     by (blast intro: ext X)
   938   hence "L = X 0" using LIMSEQ_const [of "X 0"]
   939     by (auto intro: LIMSEQ_unique lim) 
   940   thus ?thesis
   941     by (blast intro: eq_refl X)
   942 qed
   943 
   944 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   945   by (simp add: decseq_def monoseq_def)
   946 
   947 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
   948   by (simp add: decseq_def incseq_def)
   949 
   950 
   951 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
   952 proof -
   953   have inc: "incseq (\<lambda>n. - X n)" using dec
   954     by (simp add: decseq_eq_incseq)
   955   have "- X n \<le> - L" 
   956     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
   957   thus ?thesis
   958     by simp
   959 qed
   960 
   961 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
   962 
   963 text{*alternative formulation for boundedness*}
   964 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   965 apply (unfold Bseq_def, safe)
   966 apply (rule_tac [2] x = "k + norm x" in exI)
   967 apply (rule_tac x = K in exI, simp)
   968 apply (rule exI [where x = 0], auto)
   969 apply (erule order_less_le_trans, simp)
   970 apply (drule_tac x=n in spec, fold diff_def)
   971 apply (drule order_trans [OF norm_triangle_ineq2])
   972 apply simp
   973 done
   974 
   975 text{*alternative formulation for boundedness*}
   976 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
   977 apply safe
   978 apply (simp add: Bseq_def, safe)
   979 apply (rule_tac x = "K + norm (X N)" in exI)
   980 apply auto
   981 apply (erule order_less_le_trans, simp)
   982 apply (rule_tac x = N in exI, safe)
   983 apply (drule_tac x = n in spec)
   984 apply (rule order_trans [OF norm_triangle_ineq], simp)
   985 apply (auto simp add: Bseq_iff2)
   986 done
   987 
   988 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   989 apply (simp add: Bseq_def)
   990 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   991 apply (drule_tac x = n in spec, arith)
   992 done
   993 
   994 
   995 subsection {* Cauchy Sequences *}
   996 
   997 lemma metric_CauchyI:
   998   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
   999 by (simp add: Cauchy_def)
  1000 
  1001 lemma metric_CauchyD:
  1002   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1003 by (simp add: Cauchy_def)
  1004 
  1005 lemma Cauchy_iff:
  1006   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1007   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1008 unfolding Cauchy_def dist_norm ..
  1009 
  1010 lemma CauchyI:
  1011   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1012   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1013 by (simp add: Cauchy_iff)
  1014 
  1015 lemma CauchyD:
  1016   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1017   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1018 by (simp add: Cauchy_iff)
  1019 
  1020 lemma Cauchy_subseq_Cauchy:
  1021   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1022 apply (auto simp add: Cauchy_def)
  1023 apply (drule_tac x=e in spec, clarify)
  1024 apply (rule_tac x=M in exI, clarify)
  1025 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1026 done
  1027 
  1028 subsubsection {* Cauchy Sequences are Bounded *}
  1029 
  1030 text{*A Cauchy sequence is bounded -- this is the standard
  1031   proof mechanization rather than the nonstandard proof*}
  1032 
  1033 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1034           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1035 apply (clarify, drule spec, drule (1) mp)
  1036 apply (simp only: norm_minus_commute)
  1037 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1038 apply simp
  1039 done
  1040 
  1041 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1042 apply (simp add: Cauchy_iff)
  1043 apply (drule spec, drule mp, rule zero_less_one, safe)
  1044 apply (drule_tac x="M" in spec, simp)
  1045 apply (drule lemmaCauchy)
  1046 apply (rule_tac k="M" in Bseq_offset)
  1047 apply (simp add: Bseq_def)
  1048 apply (rule_tac x="1 + norm (X M)" in exI)
  1049 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1050 apply (simp add: order_less_imp_le)
  1051 done
  1052 
  1053 subsubsection {* Cauchy Sequences are Convergent *}
  1054 
  1055 axclass complete_space \<subseteq> metric_space
  1056   Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1057 
  1058 axclass banach \<subseteq> real_normed_vector, complete_space
  1059 
  1060 theorem LIMSEQ_imp_Cauchy:
  1061   assumes X: "X ----> a" shows "Cauchy X"
  1062 proof (rule metric_CauchyI)
  1063   fix e::real assume "0 < e"
  1064   hence "0 < e/2" by simp
  1065   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1066   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1067   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1068   proof (intro exI allI impI)
  1069     fix m assume "N \<le> m"
  1070     hence m: "dist (X m) a < e/2" using N by fast
  1071     fix n assume "N \<le> n"
  1072     hence n: "dist (X n) a < e/2" using N by fast
  1073     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1074       by (rule dist_triangle2)
  1075     also from m n have "\<dots> < e" by simp
  1076     finally show "dist (X m) (X n) < e" .
  1077   qed
  1078 qed
  1079 
  1080 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1081 unfolding convergent_def
  1082 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1083 
  1084 lemma Cauchy_convergent_iff:
  1085   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1086   shows "Cauchy X = convergent X"
  1087 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1088 
  1089 lemma convergent_subseq_convergent:
  1090   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1091   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1092   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1093 
  1094 text {*
  1095 Proof that Cauchy sequences converge based on the one from
  1096 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1097 *}
  1098 
  1099 text {*
  1100   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1101   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1102 *}
  1103 
  1104 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1105 by (simp add: isUbI setleI)
  1106 
  1107 locale real_Cauchy =
  1108   fixes X :: "nat \<Rightarrow> real"
  1109   assumes X: "Cauchy X"
  1110   fixes S :: "real set"
  1111   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1112 
  1113 lemma real_CauchyI:
  1114   assumes "Cauchy X"
  1115   shows "real_Cauchy X"
  1116   proof qed (fact assms)
  1117 
  1118 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1119 by (unfold S_def, auto)
  1120 
  1121 lemma (in real_Cauchy) bound_isUb:
  1122   assumes N: "\<forall>n\<ge>N. X n < x"
  1123   shows "isUb UNIV S x"
  1124 proof (rule isUb_UNIV_I)
  1125   fix y::real assume "y \<in> S"
  1126   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1127     by (simp add: S_def)
  1128   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1129   hence "y < X (max M N)" by simp
  1130   also have "\<dots> < x" using N by simp
  1131   finally show "y \<le> x"
  1132     by (rule order_less_imp_le)
  1133 qed
  1134 
  1135 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1136 proof (rule reals_complete)
  1137   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1138     using CauchyD [OF X zero_less_one] by auto
  1139   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1140   show "\<exists>x. x \<in> S"
  1141   proof
  1142     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1143       by (simp add: abs_diff_less_iff)
  1144     thus "X N - 1 \<in> S" by (rule mem_S)
  1145   qed
  1146   show "\<exists>u. isUb UNIV S u"
  1147   proof
  1148     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1149       by (simp add: abs_diff_less_iff)
  1150     thus "isUb UNIV S (X N + 1)"
  1151       by (rule bound_isUb)
  1152   qed
  1153 qed
  1154 
  1155 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1156   assumes x: "isLub UNIV S x"
  1157   shows "X ----> x"
  1158 proof (rule LIMSEQ_I)
  1159   fix r::real assume "0 < r"
  1160   hence r: "0 < r/2" by simp
  1161   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1162     using CauchyD [OF X r] by auto
  1163   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1164   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1165     by (simp only: real_norm_def abs_diff_less_iff)
  1166 
  1167   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1168   hence "X N - r/2 \<in> S" by (rule mem_S)
  1169   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1170 
  1171   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1172   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1173   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1174 
  1175   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1176   proof (intro exI allI impI)
  1177     fix n assume n: "N \<le> n"
  1178     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1179     thus "norm (X n - x) < r" using 1 2
  1180       by (simp add: abs_diff_less_iff)
  1181   qed
  1182 qed
  1183 
  1184 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1185 proof -
  1186   obtain x where "isLub UNIV S x"
  1187     using isLub_ex by fast
  1188   hence "X ----> x"
  1189     by (rule isLub_imp_LIMSEQ)
  1190   thus ?thesis ..
  1191 qed
  1192 
  1193 lemma real_Cauchy_convergent:
  1194   fixes X :: "nat \<Rightarrow> real"
  1195   shows "Cauchy X \<Longrightarrow> convergent X"
  1196 unfolding convergent_def
  1197 by (rule real_Cauchy.LIMSEQ_ex)
  1198  (rule real_CauchyI)
  1199 
  1200 instance real :: banach
  1201 by intro_classes (rule real_Cauchy_convergent)
  1202 
  1203 
  1204 subsection {* Power Sequences *}
  1205 
  1206 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1207 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1208   also fact that bounded and monotonic sequence converges.*}
  1209 
  1210 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1211 apply (simp add: Bseq_def)
  1212 apply (rule_tac x = 1 in exI)
  1213 apply (simp add: power_abs)
  1214 apply (auto dest: power_mono)
  1215 done
  1216 
  1217 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1218 apply (clarify intro!: mono_SucI2)
  1219 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1220 done
  1221 
  1222 lemma convergent_realpow:
  1223   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1224 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1225 
  1226 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1227   fixes x :: real
  1228   assumes x: "0 \<le> x"
  1229   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1230 apply (induct n)
  1231 apply simp
  1232 apply simp
  1233 apply (rule order_trans)
  1234 prefer 2
  1235 apply (erule mult_left_mono)
  1236 apply (rule add_increasing [OF x], simp)
  1237 apply (simp add: real_of_nat_Suc)
  1238 apply (simp add: ring_distribs)
  1239 apply (simp add: mult_nonneg_nonneg x)
  1240 done
  1241 
  1242 lemma LIMSEQ_inverse_realpow_zero:
  1243   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1244 proof (rule LIMSEQ_inverse_zero [rule_format])
  1245   fix y :: real
  1246   assume x: "1 < x"
  1247   hence "0 < x - 1" by simp
  1248   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1249     by (rule reals_Archimedean3)
  1250   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1251   then obtain N::nat where "y < real N * (x - 1)" ..
  1252   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1253   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1254     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1255   also have "\<dots> = x ^ N" by simp
  1256   finally have "y < x ^ N" .
  1257   hence "\<forall>n\<ge>N. y < x ^ n"
  1258     apply clarify
  1259     apply (erule order_less_le_trans)
  1260     apply (erule power_increasing)
  1261     apply (rule order_less_imp_le [OF x])
  1262     done
  1263   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1264 qed
  1265 
  1266 lemma LIMSEQ_realpow_zero:
  1267   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1268 proof (cases)
  1269   assume "x = 0"
  1270   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1271   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1272 next
  1273   assume "0 \<le> x" and "x \<noteq> 0"
  1274   hence x0: "0 < x" by simp
  1275   assume x1: "x < 1"
  1276   from x0 x1 have "1 < inverse x"
  1277     by (rule real_inverse_gt_one)
  1278   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1279     by (rule LIMSEQ_inverse_realpow_zero)
  1280   thus ?thesis by (simp add: power_inverse)
  1281 qed
  1282 
  1283 lemma LIMSEQ_power_zero:
  1284   fixes x :: "'a::{real_normed_algebra_1}"
  1285   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1286 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1287 apply (simp only: LIMSEQ_Zseq_iff, erule Zseq_le)
  1288 apply (simp add: power_abs norm_power_ineq)
  1289 done
  1290 
  1291 lemma LIMSEQ_divide_realpow_zero:
  1292   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1293 apply (cut_tac a = a and x1 = "inverse x" in
  1294         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1295 apply (auto simp add: divide_inverse power_inverse)
  1296 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1297 done
  1298 
  1299 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1300 
  1301 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1302 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1303 
  1304 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1305 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1306 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1307 done
  1308 
  1309 end