src/HOL/HOL.thy
author haftmann
Thu May 17 19:49:16 2007 +0200 (2007-05-17)
changeset 22993 838c66e760b5
parent 22839 ede26eb5e549
child 23037 6c72943a71b1
permissions -rw-r--r--
tuned
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports CPure
    10 uses ("simpdata.ML") "Tools/res_atpset.ML"
    11 begin
    12 
    13 subsection {* Primitive logic *}
    14 
    15 subsubsection {* Core syntax *}
    16 
    17 classes type
    18 defaultsort type
    19 
    20 global
    21 
    22 typedecl bool
    23 
    24 arities
    25   bool :: type
    26   "fun" :: (type, type) type
    27 
    28 judgment
    29   Trueprop      :: "bool => prop"                   ("(_)" 5)
    30 
    31 consts
    32   Not           :: "bool => bool"                   ("~ _" [40] 40)
    33   True          :: bool
    34   False         :: bool
    35   arbitrary     :: 'a
    36 
    37   The           :: "('a => bool) => 'a"
    38   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    39   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    40   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    41   Let           :: "['a, 'a => 'b] => 'b"
    42 
    43   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    44   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    45   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    46   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    47 
    48 local
    49 
    50 consts
    51   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    52 
    53 
    54 subsubsection {* Additional concrete syntax *}
    55 
    56 notation (output)
    57   "op ="  (infix "=" 50)
    58 
    59 abbreviation
    60   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    61   "x ~= y == ~ (x = y)"
    62 
    63 notation (output)
    64   not_equal  (infix "~=" 50)
    65 
    66 notation (xsymbols)
    67   Not  ("\<not> _" [40] 40) and
    68   "op &"  (infixr "\<and>" 35) and
    69   "op |"  (infixr "\<or>" 30) and
    70   "op -->"  (infixr "\<longrightarrow>" 25) and
    71   not_equal  (infix "\<noteq>" 50)
    72 
    73 notation (HTML output)
    74   Not  ("\<not> _" [40] 40) and
    75   "op &"  (infixr "\<and>" 35) and
    76   "op |"  (infixr "\<or>" 30) and
    77   not_equal  (infix "\<noteq>" 50)
    78 
    79 abbreviation (iff)
    80   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
    81   "A <-> B == A = B"
    82 
    83 notation (xsymbols)
    84   iff  (infixr "\<longleftrightarrow>" 25)
    85 
    86 
    87 nonterminals
    88   letbinds  letbind
    89   case_syn  cases_syn
    90 
    91 syntax
    92   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
    93 
    94   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
    95   ""            :: "letbind => letbinds"                 ("_")
    96   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
    97   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
    98 
    99   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   100   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   101   ""            :: "case_syn => cases_syn"               ("_")
   102   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   103 
   104 translations
   105   "THE x. P"              == "The (%x. P)"
   106   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   107   "let x = a in e"        == "Let a (%x. e)"
   108 
   109 print_translation {*
   110 (* To avoid eta-contraction of body: *)
   111 [("The", fn [Abs abs] =>
   112      let val (x,t) = atomic_abs_tr' abs
   113      in Syntax.const "_The" $ x $ t end)]
   114 *}
   115 
   116 syntax (xsymbols)
   117   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   118 
   119 notation (xsymbols)
   120   All  (binder "\<forall>" 10) and
   121   Ex  (binder "\<exists>" 10) and
   122   Ex1  (binder "\<exists>!" 10)
   123 
   124 notation (HTML output)
   125   All  (binder "\<forall>" 10) and
   126   Ex  (binder "\<exists>" 10) and
   127   Ex1  (binder "\<exists>!" 10)
   128 
   129 notation (HOL)
   130   All  (binder "! " 10) and
   131   Ex  (binder "? " 10) and
   132   Ex1  (binder "?! " 10)
   133 
   134 
   135 subsubsection {* Axioms and basic definitions *}
   136 
   137 axioms
   138   eq_reflection:  "(x=y) ==> (x==y)"
   139 
   140   refl:           "t = (t::'a)"
   141 
   142   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   143     -- {*Extensionality is built into the meta-logic, and this rule expresses
   144          a related property.  It is an eta-expanded version of the traditional
   145          rule, and similar to the ABS rule of HOL*}
   146 
   147   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   148 
   149   impI:           "(P ==> Q) ==> P-->Q"
   150   mp:             "[| P-->Q;  P |] ==> Q"
   151 
   152 
   153 defs
   154   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   155   All_def:      "All(P)    == (P = (%x. True))"
   156   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   157   False_def:    "False     == (!P. P)"
   158   not_def:      "~ P       == P-->False"
   159   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   160   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   161   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   162 
   163 axioms
   164   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   165   True_or_False:  "(P=True) | (P=False)"
   166 
   167 defs
   168   Let_def [code func]: "Let s f == f(s)"
   169   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   170 
   171 finalconsts
   172   "op ="
   173   "op -->"
   174   The
   175   arbitrary
   176 
   177 axiomatization
   178   undefined :: 'a
   179 
   180 axiomatization where
   181   undefined_fun: "undefined x = undefined"
   182 
   183 
   184 subsubsection {* Generic classes and algebraic operations *}
   185 
   186 class default = type +
   187   fixes default :: "'a"
   188 
   189 class zero = type + 
   190   fixes zero :: "'a"  ("\<^loc>0")
   191 
   192 class one = type +
   193   fixes one  :: "'a"  ("\<^loc>1")
   194 
   195 hide (open) const zero one
   196 
   197 class plus = type +
   198   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>+" 65)
   199 
   200 class minus = type +
   201   fixes uminus :: "'a \<Rightarrow> 'a" 
   202     and minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>-" 65)
   203     and abs :: "'a \<Rightarrow> 'a"
   204 
   205 class times = type +
   206   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>*" 70)
   207 
   208 class inverse = type +
   209   fixes inverse :: "'a \<Rightarrow> 'a"
   210     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "\<^loc>'/" 70)
   211 
   212 notation
   213   uminus  ("- _" [81] 80)
   214 
   215 notation (xsymbols)
   216   abs  ("\<bar>_\<bar>")
   217 notation (HTML output)
   218   abs  ("\<bar>_\<bar>")
   219 
   220 syntax
   221   "_index1"  :: index    ("\<^sub>1")
   222 translations
   223   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   224 
   225 typed_print_translation {*
   226 let
   227   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   228     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   229     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   230 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   231 *} -- {* show types that are presumably too general *}
   232 
   233 
   234 subsection {* Fundamental rules *}
   235 
   236 subsubsection {* Equality *}
   237 
   238 text {* Thanks to Stephan Merz *}
   239 lemma subst:
   240   assumes eq: "s = t" and p: "P s"
   241   shows "P t"
   242 proof -
   243   from eq have meta: "s \<equiv> t"
   244     by (rule eq_reflection)
   245   from p show ?thesis
   246     by (unfold meta)
   247 qed
   248 
   249 lemma sym: "s = t ==> t = s"
   250   by (erule subst) (rule refl)
   251 
   252 lemma ssubst: "t = s ==> P s ==> P t"
   253   by (drule sym) (erule subst)
   254 
   255 lemma trans: "[| r=s; s=t |] ==> r=t"
   256   by (erule subst)
   257 
   258 lemma meta_eq_to_obj_eq: 
   259   assumes meq: "A == B"
   260   shows "A = B"
   261   by (unfold meq) (rule refl)
   262 
   263 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   264      (* a = b
   265         |   |
   266         c = d   *)
   267 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   268 apply (rule trans)
   269 apply (rule trans)
   270 apply (rule sym)
   271 apply assumption+
   272 done
   273 
   274 text {* For calculational reasoning: *}
   275 
   276 lemma forw_subst: "a = b ==> P b ==> P a"
   277   by (rule ssubst)
   278 
   279 lemma back_subst: "P a ==> a = b ==> P b"
   280   by (rule subst)
   281 
   282 
   283 subsubsection {*Congruence rules for application*}
   284 
   285 (*similar to AP_THM in Gordon's HOL*)
   286 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   287 apply (erule subst)
   288 apply (rule refl)
   289 done
   290 
   291 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   292 lemma arg_cong: "x=y ==> f(x)=f(y)"
   293 apply (erule subst)
   294 apply (rule refl)
   295 done
   296 
   297 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   298 apply (erule ssubst)+
   299 apply (rule refl)
   300 done
   301 
   302 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   303 apply (erule subst)+
   304 apply (rule refl)
   305 done
   306 
   307 
   308 subsubsection {*Equality of booleans -- iff*}
   309 
   310 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   311   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   312 
   313 lemma iffD2: "[| P=Q; Q |] ==> P"
   314   by (erule ssubst)
   315 
   316 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   317   by (erule iffD2)
   318 
   319 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   320   by (drule sym) (rule iffD2)
   321 
   322 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   323   by (drule sym) (rule rev_iffD2)
   324 
   325 lemma iffE:
   326   assumes major: "P=Q"
   327     and minor: "[| P --> Q; Q --> P |] ==> R"
   328   shows R
   329   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   330 
   331 
   332 subsubsection {*True*}
   333 
   334 lemma TrueI: "True"
   335   unfolding True_def by (rule refl)
   336 
   337 lemma eqTrueI: "P ==> P = True"
   338   by (iprover intro: iffI TrueI)
   339 
   340 lemma eqTrueE: "P = True ==> P"
   341   by (erule iffD2) (rule TrueI)
   342 
   343 
   344 subsubsection {*Universal quantifier*}
   345 
   346 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   347   unfolding All_def by (iprover intro: ext eqTrueI assms)
   348 
   349 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   350 apply (unfold All_def)
   351 apply (rule eqTrueE)
   352 apply (erule fun_cong)
   353 done
   354 
   355 lemma allE:
   356   assumes major: "ALL x. P(x)"
   357     and minor: "P(x) ==> R"
   358   shows R
   359   by (iprover intro: minor major [THEN spec])
   360 
   361 lemma all_dupE:
   362   assumes major: "ALL x. P(x)"
   363     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   364   shows R
   365   by (iprover intro: minor major major [THEN spec])
   366 
   367 
   368 subsubsection {* False *}
   369 
   370 text {*
   371   Depends upon @{text spec}; it is impossible to do propositional
   372   logic before quantifiers!
   373 *}
   374 
   375 lemma FalseE: "False ==> P"
   376   apply (unfold False_def)
   377   apply (erule spec)
   378   done
   379 
   380 lemma False_neq_True: "False = True ==> P"
   381   by (erule eqTrueE [THEN FalseE])
   382 
   383 
   384 subsubsection {* Negation *}
   385 
   386 lemma notI:
   387   assumes "P ==> False"
   388   shows "~P"
   389   apply (unfold not_def)
   390   apply (iprover intro: impI assms)
   391   done
   392 
   393 lemma False_not_True: "False ~= True"
   394   apply (rule notI)
   395   apply (erule False_neq_True)
   396   done
   397 
   398 lemma True_not_False: "True ~= False"
   399   apply (rule notI)
   400   apply (drule sym)
   401   apply (erule False_neq_True)
   402   done
   403 
   404 lemma notE: "[| ~P;  P |] ==> R"
   405   apply (unfold not_def)
   406   apply (erule mp [THEN FalseE])
   407   apply assumption
   408   done
   409 
   410 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   411   by (erule notE [THEN notI]) (erule meta_mp)
   412 
   413 
   414 subsubsection {*Implication*}
   415 
   416 lemma impE:
   417   assumes "P-->Q" "P" "Q ==> R"
   418   shows "R"
   419 by (iprover intro: prems mp)
   420 
   421 (* Reduces Q to P-->Q, allowing substitution in P. *)
   422 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   423 by (iprover intro: mp)
   424 
   425 lemma contrapos_nn:
   426   assumes major: "~Q"
   427       and minor: "P==>Q"
   428   shows "~P"
   429 by (iprover intro: notI minor major [THEN notE])
   430 
   431 (*not used at all, but we already have the other 3 combinations *)
   432 lemma contrapos_pn:
   433   assumes major: "Q"
   434       and minor: "P ==> ~Q"
   435   shows "~P"
   436 by (iprover intro: notI minor major notE)
   437 
   438 lemma not_sym: "t ~= s ==> s ~= t"
   439   by (erule contrapos_nn) (erule sym)
   440 
   441 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   442   by (erule subst, erule ssubst, assumption)
   443 
   444 (*still used in HOLCF*)
   445 lemma rev_contrapos:
   446   assumes pq: "P ==> Q"
   447       and nq: "~Q"
   448   shows "~P"
   449 apply (rule nq [THEN contrapos_nn])
   450 apply (erule pq)
   451 done
   452 
   453 subsubsection {*Existential quantifier*}
   454 
   455 lemma exI: "P x ==> EX x::'a. P x"
   456 apply (unfold Ex_def)
   457 apply (iprover intro: allI allE impI mp)
   458 done
   459 
   460 lemma exE:
   461   assumes major: "EX x::'a. P(x)"
   462       and minor: "!!x. P(x) ==> Q"
   463   shows "Q"
   464 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   465 apply (iprover intro: impI [THEN allI] minor)
   466 done
   467 
   468 
   469 subsubsection {*Conjunction*}
   470 
   471 lemma conjI: "[| P; Q |] ==> P&Q"
   472 apply (unfold and_def)
   473 apply (iprover intro: impI [THEN allI] mp)
   474 done
   475 
   476 lemma conjunct1: "[| P & Q |] ==> P"
   477 apply (unfold and_def)
   478 apply (iprover intro: impI dest: spec mp)
   479 done
   480 
   481 lemma conjunct2: "[| P & Q |] ==> Q"
   482 apply (unfold and_def)
   483 apply (iprover intro: impI dest: spec mp)
   484 done
   485 
   486 lemma conjE:
   487   assumes major: "P&Q"
   488       and minor: "[| P; Q |] ==> R"
   489   shows "R"
   490 apply (rule minor)
   491 apply (rule major [THEN conjunct1])
   492 apply (rule major [THEN conjunct2])
   493 done
   494 
   495 lemma context_conjI:
   496   assumes prems: "P" "P ==> Q" shows "P & Q"
   497 by (iprover intro: conjI prems)
   498 
   499 
   500 subsubsection {*Disjunction*}
   501 
   502 lemma disjI1: "P ==> P|Q"
   503 apply (unfold or_def)
   504 apply (iprover intro: allI impI mp)
   505 done
   506 
   507 lemma disjI2: "Q ==> P|Q"
   508 apply (unfold or_def)
   509 apply (iprover intro: allI impI mp)
   510 done
   511 
   512 lemma disjE:
   513   assumes major: "P|Q"
   514       and minorP: "P ==> R"
   515       and minorQ: "Q ==> R"
   516   shows "R"
   517 by (iprover intro: minorP minorQ impI
   518                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   519 
   520 
   521 subsubsection {*Classical logic*}
   522 
   523 lemma classical:
   524   assumes prem: "~P ==> P"
   525   shows "P"
   526 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   527 apply assumption
   528 apply (rule notI [THEN prem, THEN eqTrueI])
   529 apply (erule subst)
   530 apply assumption
   531 done
   532 
   533 lemmas ccontr = FalseE [THEN classical, standard]
   534 
   535 (*notE with premises exchanged; it discharges ~R so that it can be used to
   536   make elimination rules*)
   537 lemma rev_notE:
   538   assumes premp: "P"
   539       and premnot: "~R ==> ~P"
   540   shows "R"
   541 apply (rule ccontr)
   542 apply (erule notE [OF premnot premp])
   543 done
   544 
   545 (*Double negation law*)
   546 lemma notnotD: "~~P ==> P"
   547 apply (rule classical)
   548 apply (erule notE)
   549 apply assumption
   550 done
   551 
   552 lemma contrapos_pp:
   553   assumes p1: "Q"
   554       and p2: "~P ==> ~Q"
   555   shows "P"
   556 by (iprover intro: classical p1 p2 notE)
   557 
   558 
   559 subsubsection {*Unique existence*}
   560 
   561 lemma ex1I:
   562   assumes prems: "P a" "!!x. P(x) ==> x=a"
   563   shows "EX! x. P(x)"
   564 by (unfold Ex1_def, iprover intro: prems exI conjI allI impI)
   565 
   566 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   567 lemma ex_ex1I:
   568   assumes ex_prem: "EX x. P(x)"
   569       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   570   shows "EX! x. P(x)"
   571 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   572 
   573 lemma ex1E:
   574   assumes major: "EX! x. P(x)"
   575       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   576   shows "R"
   577 apply (rule major [unfolded Ex1_def, THEN exE])
   578 apply (erule conjE)
   579 apply (iprover intro: minor)
   580 done
   581 
   582 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   583 apply (erule ex1E)
   584 apply (rule exI)
   585 apply assumption
   586 done
   587 
   588 
   589 subsubsection {*THE: definite description operator*}
   590 
   591 lemma the_equality:
   592   assumes prema: "P a"
   593       and premx: "!!x. P x ==> x=a"
   594   shows "(THE x. P x) = a"
   595 apply (rule trans [OF _ the_eq_trivial])
   596 apply (rule_tac f = "The" in arg_cong)
   597 apply (rule ext)
   598 apply (rule iffI)
   599  apply (erule premx)
   600 apply (erule ssubst, rule prema)
   601 done
   602 
   603 lemma theI:
   604   assumes "P a" and "!!x. P x ==> x=a"
   605   shows "P (THE x. P x)"
   606 by (iprover intro: prems the_equality [THEN ssubst])
   607 
   608 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   609 apply (erule ex1E)
   610 apply (erule theI)
   611 apply (erule allE)
   612 apply (erule mp)
   613 apply assumption
   614 done
   615 
   616 (*Easier to apply than theI: only one occurrence of P*)
   617 lemma theI2:
   618   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   619   shows "Q (THE x. P x)"
   620 by (iprover intro: prems theI)
   621 
   622 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   623 apply (rule the_equality)
   624 apply  assumption
   625 apply (erule ex1E)
   626 apply (erule all_dupE)
   627 apply (drule mp)
   628 apply  assumption
   629 apply (erule ssubst)
   630 apply (erule allE)
   631 apply (erule mp)
   632 apply assumption
   633 done
   634 
   635 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   636 apply (rule the_equality)
   637 apply (rule refl)
   638 apply (erule sym)
   639 done
   640 
   641 
   642 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   643 
   644 lemma disjCI:
   645   assumes "~Q ==> P" shows "P|Q"
   646 apply (rule classical)
   647 apply (iprover intro: prems disjI1 disjI2 notI elim: notE)
   648 done
   649 
   650 lemma excluded_middle: "~P | P"
   651 by (iprover intro: disjCI)
   652 
   653 text {*
   654   case distinction as a natural deduction rule.
   655   Note that @{term "~P"} is the second case, not the first
   656 *}
   657 lemma case_split_thm:
   658   assumes prem1: "P ==> Q"
   659       and prem2: "~P ==> Q"
   660   shows "Q"
   661 apply (rule excluded_middle [THEN disjE])
   662 apply (erule prem2)
   663 apply (erule prem1)
   664 done
   665 lemmas case_split = case_split_thm [case_names True False]
   666 
   667 (*Classical implies (-->) elimination. *)
   668 lemma impCE:
   669   assumes major: "P-->Q"
   670       and minor: "~P ==> R" "Q ==> R"
   671   shows "R"
   672 apply (rule excluded_middle [of P, THEN disjE])
   673 apply (iprover intro: minor major [THEN mp])+
   674 done
   675 
   676 (*This version of --> elimination works on Q before P.  It works best for
   677   those cases in which P holds "almost everywhere".  Can't install as
   678   default: would break old proofs.*)
   679 lemma impCE':
   680   assumes major: "P-->Q"
   681       and minor: "Q ==> R" "~P ==> R"
   682   shows "R"
   683 apply (rule excluded_middle [of P, THEN disjE])
   684 apply (iprover intro: minor major [THEN mp])+
   685 done
   686 
   687 (*Classical <-> elimination. *)
   688 lemma iffCE:
   689   assumes major: "P=Q"
   690       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   691   shows "R"
   692 apply (rule major [THEN iffE])
   693 apply (iprover intro: minor elim: impCE notE)
   694 done
   695 
   696 lemma exCI:
   697   assumes "ALL x. ~P(x) ==> P(a)"
   698   shows "EX x. P(x)"
   699 apply (rule ccontr)
   700 apply (iprover intro: prems exI allI notI notE [of "\<exists>x. P x"])
   701 done
   702 
   703 
   704 subsubsection {* Intuitionistic Reasoning *}
   705 
   706 lemma impE':
   707   assumes 1: "P --> Q"
   708     and 2: "Q ==> R"
   709     and 3: "P --> Q ==> P"
   710   shows R
   711 proof -
   712   from 3 and 1 have P .
   713   with 1 have Q by (rule impE)
   714   with 2 show R .
   715 qed
   716 
   717 lemma allE':
   718   assumes 1: "ALL x. P x"
   719     and 2: "P x ==> ALL x. P x ==> Q"
   720   shows Q
   721 proof -
   722   from 1 have "P x" by (rule spec)
   723   from this and 1 show Q by (rule 2)
   724 qed
   725 
   726 lemma notE':
   727   assumes 1: "~ P"
   728     and 2: "~ P ==> P"
   729   shows R
   730 proof -
   731   from 2 and 1 have P .
   732   with 1 show R by (rule notE)
   733 qed
   734 
   735 lemma TrueE: "True ==> P ==> P" .
   736 lemma notFalseE: "~ False ==> P ==> P" .
   737 
   738 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   739   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   740   and [Pure.elim 2] = allE notE' impE'
   741   and [Pure.intro] = exI disjI2 disjI1
   742 
   743 lemmas [trans] = trans
   744   and [sym] = sym not_sym
   745   and [Pure.elim?] = iffD1 iffD2 impE
   746 
   747 
   748 subsubsection {* Atomizing meta-level connectives *}
   749 
   750 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   751 proof
   752   assume "!!x. P x"
   753   show "ALL x. P x" by (rule allI)
   754 next
   755   assume "ALL x. P x"
   756   thus "!!x. P x" by (rule allE)
   757 qed
   758 
   759 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   760 proof
   761   assume r: "A ==> B"
   762   show "A --> B" by (rule impI) (rule r)
   763 next
   764   assume "A --> B" and A
   765   thus B by (rule mp)
   766 qed
   767 
   768 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   769 proof
   770   assume r: "A ==> False"
   771   show "~A" by (rule notI) (rule r)
   772 next
   773   assume "~A" and A
   774   thus False by (rule notE)
   775 qed
   776 
   777 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   778 proof
   779   assume "x == y"
   780   show "x = y" by (unfold prems) (rule refl)
   781 next
   782   assume "x = y"
   783   thus "x == y" by (rule eq_reflection)
   784 qed
   785 
   786 lemma atomize_conj [atomize]:
   787   includes meta_conjunction_syntax
   788   shows "(A && B) == Trueprop (A & B)"
   789 proof
   790   assume conj: "A && B"
   791   show "A & B"
   792   proof (rule conjI)
   793     from conj show A by (rule conjunctionD1)
   794     from conj show B by (rule conjunctionD2)
   795   qed
   796 next
   797   assume conj: "A & B"
   798   show "A && B"
   799   proof -
   800     from conj show A ..
   801     from conj show B ..
   802   qed
   803 qed
   804 
   805 lemmas [symmetric, rulify] = atomize_all atomize_imp
   806   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   807 
   808 
   809 subsection {* Package setup *}
   810 
   811 subsubsection {* Classical Reasoner setup *}
   812 
   813 lemma thin_refl:
   814   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   815 
   816 ML {*
   817 structure Hypsubst = HypsubstFun(
   818 struct
   819   structure Simplifier = Simplifier
   820   val dest_eq = HOLogic.dest_eq
   821   val dest_Trueprop = HOLogic.dest_Trueprop
   822   val dest_imp = HOLogic.dest_imp
   823   val eq_reflection = @{thm HOL.eq_reflection}
   824   val rev_eq_reflection = @{thm HOL.meta_eq_to_obj_eq}
   825   val imp_intr = @{thm HOL.impI}
   826   val rev_mp = @{thm HOL.rev_mp}
   827   val subst = @{thm HOL.subst}
   828   val sym = @{thm HOL.sym}
   829   val thin_refl = @{thm thin_refl};
   830 end);
   831 open Hypsubst;
   832 
   833 structure Classical = ClassicalFun(
   834 struct
   835   val mp = @{thm HOL.mp}
   836   val not_elim = @{thm HOL.notE}
   837   val classical = @{thm HOL.classical}
   838   val sizef = Drule.size_of_thm
   839   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   840 end);
   841 
   842 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   843 open BasicClassical;
   844 
   845 ML_Context.value_antiq "claset"
   846   (Scan.succeed ("claset", "Classical.local_claset_of (ML_Context.the_local_context ())"));
   847 *}
   848 
   849 setup {*
   850 let
   851   (*prevent substitution on bool*)
   852   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   853     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   854       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   855 in
   856   Hypsubst.hypsubst_setup
   857   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   858   #> Classical.setup
   859   #> ResAtpset.setup
   860 end
   861 *}
   862 
   863 declare iffI [intro!]
   864   and notI [intro!]
   865   and impI [intro!]
   866   and disjCI [intro!]
   867   and conjI [intro!]
   868   and TrueI [intro!]
   869   and refl [intro!]
   870 
   871 declare iffCE [elim!]
   872   and FalseE [elim!]
   873   and impCE [elim!]
   874   and disjE [elim!]
   875   and conjE [elim!]
   876   and conjE [elim!]
   877 
   878 declare ex_ex1I [intro!]
   879   and allI [intro!]
   880   and the_equality [intro]
   881   and exI [intro]
   882 
   883 declare exE [elim!]
   884   allE [elim]
   885 
   886 ML {* val HOL_cs = @{claset} *}
   887 
   888 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   889   apply (erule swap)
   890   apply (erule (1) meta_mp)
   891   done
   892 
   893 declare ex_ex1I [rule del, intro! 2]
   894   and ex1I [intro]
   895 
   896 lemmas [intro?] = ext
   897   and [elim?] = ex1_implies_ex
   898 
   899 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   900 lemma alt_ex1E [elim!]:
   901   assumes major: "\<exists>!x. P x"
   902       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   903   shows R
   904 apply (rule ex1E [OF major])
   905 apply (rule prem)
   906 apply (tactic {* ares_tac @{thms allI} 1 *})+
   907 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   908 apply iprover
   909 done
   910 
   911 ML {*
   912 structure Blast = BlastFun(
   913 struct
   914   type claset = Classical.claset
   915   val equality_name = @{const_name "op ="}
   916   val not_name = @{const_name Not}
   917   val notE = @{thm HOL.notE}
   918   val ccontr = @{thm HOL.ccontr}
   919   val contr_tac = Classical.contr_tac
   920   val dup_intr = Classical.dup_intr
   921   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   922   val claset = Classical.claset
   923   val rep_cs = Classical.rep_cs
   924   val cla_modifiers = Classical.cla_modifiers
   925   val cla_meth' = Classical.cla_meth'
   926 end);
   927 val Blast_tac = Blast.Blast_tac;
   928 val blast_tac = Blast.blast_tac;
   929 *}
   930 
   931 setup Blast.setup
   932 
   933 
   934 subsubsection {* Simplifier *}
   935 
   936 lemma eta_contract_eq: "(%s. f s) = f" ..
   937 
   938 lemma simp_thms:
   939   shows not_not: "(~ ~ P) = P"
   940   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   941   and
   942     "(P ~= Q) = (P = (~Q))"
   943     "(P | ~P) = True"    "(~P | P) = True"
   944     "(x = x) = True"
   945   and not_True_eq_False: "(\<not> True) = False"
   946   and not_False_eq_True: "(\<not> False) = True"
   947   and
   948     "(~P) ~= P"  "P ~= (~P)"
   949     "(True=P) = P"
   950   and eq_True: "(P = True) = P"
   951   and "(False=P) = (~P)"
   952   and eq_False: "(P = False) = (\<not> P)"
   953   and
   954     "(True --> P) = P"  "(False --> P) = True"
   955     "(P --> True) = True"  "(P --> P) = True"
   956     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   957     "(P & True) = P"  "(True & P) = P"
   958     "(P & False) = False"  "(False & P) = False"
   959     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   960     "(P & ~P) = False"    "(~P & P) = False"
   961     "(P | True) = True"  "(True | P) = True"
   962     "(P | False) = P"  "(False | P) = P"
   963     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   964     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   965     -- {* needed for the one-point-rule quantifier simplification procs *}
   966     -- {* essential for termination!! *} and
   967     "!!P. (EX x. x=t & P(x)) = P(t)"
   968     "!!P. (EX x. t=x & P(x)) = P(t)"
   969     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   970     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   971   by (blast, blast, blast, blast, blast, iprover+)
   972 
   973 lemma disj_absorb: "(A | A) = A"
   974   by blast
   975 
   976 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   977   by blast
   978 
   979 lemma conj_absorb: "(A & A) = A"
   980   by blast
   981 
   982 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   983   by blast
   984 
   985 lemma eq_ac:
   986   shows eq_commute: "(a=b) = (b=a)"
   987     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   988     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
   989 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
   990 
   991 lemma conj_comms:
   992   shows conj_commute: "(P&Q) = (Q&P)"
   993     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
   994 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
   995 
   996 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   997 
   998 lemma disj_comms:
   999   shows disj_commute: "(P|Q) = (Q|P)"
  1000     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1001 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1002 
  1003 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1004 
  1005 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1006 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1007 
  1008 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1009 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1010 
  1011 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1012 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1013 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1014 
  1015 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1016 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1017 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1018 
  1019 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1020 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1021 
  1022 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1023   by iprover
  1024 
  1025 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1026 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1027 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1028 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1029 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1030 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1031   by blast
  1032 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1033 
  1034 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1035 
  1036 
  1037 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1038   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1039   -- {* cases boil down to the same thing. *}
  1040   by blast
  1041 
  1042 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1043 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1044 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1045 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1046 
  1047 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1048 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1049 
  1050 text {*
  1051   \medskip The @{text "&"} congruence rule: not included by default!
  1052   May slow rewrite proofs down by as much as 50\% *}
  1053 
  1054 lemma conj_cong:
  1055     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1056   by iprover
  1057 
  1058 lemma rev_conj_cong:
  1059     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1060   by iprover
  1061 
  1062 text {* The @{text "|"} congruence rule: not included by default! *}
  1063 
  1064 lemma disj_cong:
  1065     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1066   by blast
  1067 
  1068 
  1069 text {* \medskip if-then-else rules *}
  1070 
  1071 lemma if_True: "(if True then x else y) = x"
  1072   by (unfold if_def) blast
  1073 
  1074 lemma if_False: "(if False then x else y) = y"
  1075   by (unfold if_def) blast
  1076 
  1077 lemma if_P: "P ==> (if P then x else y) = x"
  1078   by (unfold if_def) blast
  1079 
  1080 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1081   by (unfold if_def) blast
  1082 
  1083 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1084   apply (rule case_split [of Q])
  1085    apply (simplesubst if_P)
  1086     prefer 3 apply (simplesubst if_not_P, blast+)
  1087   done
  1088 
  1089 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1090 by (simplesubst split_if, blast)
  1091 
  1092 lemmas if_splits = split_if split_if_asm
  1093 
  1094 lemma if_cancel: "(if c then x else x) = x"
  1095 by (simplesubst split_if, blast)
  1096 
  1097 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1098 by (simplesubst split_if, blast)
  1099 
  1100 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1101   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1102   by (rule split_if)
  1103 
  1104 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1105   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1106   apply (simplesubst split_if, blast)
  1107   done
  1108 
  1109 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1110 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1111 
  1112 text {* \medskip let rules for simproc *}
  1113 
  1114 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1115   by (unfold Let_def)
  1116 
  1117 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1118   by (unfold Let_def)
  1119 
  1120 text {*
  1121   The following copy of the implication operator is useful for
  1122   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1123   its premise.
  1124 *}
  1125 
  1126 constdefs
  1127   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1128   "simp_implies \<equiv> op ==>"
  1129 
  1130 lemma simp_impliesI:
  1131   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1132   shows "PROP P =simp=> PROP Q"
  1133   apply (unfold simp_implies_def)
  1134   apply (rule PQ)
  1135   apply assumption
  1136   done
  1137 
  1138 lemma simp_impliesE:
  1139   assumes PQ:"PROP P =simp=> PROP Q"
  1140   and P: "PROP P"
  1141   and QR: "PROP Q \<Longrightarrow> PROP R"
  1142   shows "PROP R"
  1143   apply (rule QR)
  1144   apply (rule PQ [unfolded simp_implies_def])
  1145   apply (rule P)
  1146   done
  1147 
  1148 lemma simp_implies_cong:
  1149   assumes PP' :"PROP P == PROP P'"
  1150   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1151   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1152 proof (unfold simp_implies_def, rule equal_intr_rule)
  1153   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1154   and P': "PROP P'"
  1155   from PP' [symmetric] and P' have "PROP P"
  1156     by (rule equal_elim_rule1)
  1157   hence "PROP Q" by (rule PQ)
  1158   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1159 next
  1160   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1161   and P: "PROP P"
  1162   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1163   hence "PROP Q'" by (rule P'Q')
  1164   with P'QQ' [OF P', symmetric] show "PROP Q"
  1165     by (rule equal_elim_rule1)
  1166 qed
  1167 
  1168 lemma uncurry:
  1169   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1170   shows "P \<and> Q \<longrightarrow> R"
  1171   using prems by blast
  1172 
  1173 lemma iff_allI:
  1174   assumes "\<And>x. P x = Q x"
  1175   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1176   using prems by blast
  1177 
  1178 lemma iff_exI:
  1179   assumes "\<And>x. P x = Q x"
  1180   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1181   using prems by blast
  1182 
  1183 lemma all_comm:
  1184   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1185   by blast
  1186 
  1187 lemma ex_comm:
  1188   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1189   by blast
  1190 
  1191 use "simpdata.ML"
  1192 ML {* open Simpdata *}
  1193 
  1194 setup {*
  1195   Simplifier.method_setup Splitter.split_modifiers
  1196   #> (fn thy => (change_simpset_of thy (fn _ => Simpdata.simpset_simprocs); thy))
  1197   #> Splitter.setup
  1198   #> Clasimp.setup
  1199   #> EqSubst.setup
  1200 *}
  1201 
  1202 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1203 proof
  1204   assume prem: "True \<Longrightarrow> PROP P"
  1205   from prem [OF TrueI] show "PROP P" . 
  1206 next
  1207   assume "PROP P"
  1208   show "PROP P" .
  1209 qed
  1210 
  1211 lemma ex_simps:
  1212   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1213   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1214   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1215   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1216   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1217   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1218   -- {* Miniscoping: pushing in existential quantifiers. *}
  1219   by (iprover | blast)+
  1220 
  1221 lemma all_simps:
  1222   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1223   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1224   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1225   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1226   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1227   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1228   -- {* Miniscoping: pushing in universal quantifiers. *}
  1229   by (iprover | blast)+
  1230 
  1231 lemmas [simp] =
  1232   triv_forall_equality (*prunes params*)
  1233   True_implies_equals  (*prune asms `True'*)
  1234   if_True
  1235   if_False
  1236   if_cancel
  1237   if_eq_cancel
  1238   imp_disjL
  1239   (*In general it seems wrong to add distributive laws by default: they
  1240     might cause exponential blow-up.  But imp_disjL has been in for a while
  1241     and cannot be removed without affecting existing proofs.  Moreover,
  1242     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1243     grounds that it allows simplification of R in the two cases.*)
  1244   conj_assoc
  1245   disj_assoc
  1246   de_Morgan_conj
  1247   de_Morgan_disj
  1248   imp_disj1
  1249   imp_disj2
  1250   not_imp
  1251   disj_not1
  1252   not_all
  1253   not_ex
  1254   cases_simp
  1255   the_eq_trivial
  1256   the_sym_eq_trivial
  1257   ex_simps
  1258   all_simps
  1259   simp_thms
  1260 
  1261 lemmas [cong] = imp_cong simp_implies_cong
  1262 lemmas [split] = split_if
  1263 
  1264 ML {* val HOL_ss = @{simpset} *}
  1265 
  1266 text {* Simplifies x assuming c and y assuming ~c *}
  1267 lemma if_cong:
  1268   assumes "b = c"
  1269       and "c \<Longrightarrow> x = u"
  1270       and "\<not> c \<Longrightarrow> y = v"
  1271   shows "(if b then x else y) = (if c then u else v)"
  1272   unfolding if_def using prems by simp
  1273 
  1274 text {* Prevents simplification of x and y:
  1275   faster and allows the execution of functional programs. *}
  1276 lemma if_weak_cong [cong]:
  1277   assumes "b = c"
  1278   shows "(if b then x else y) = (if c then x else y)"
  1279   using prems by (rule arg_cong)
  1280 
  1281 text {* Prevents simplification of t: much faster *}
  1282 lemma let_weak_cong:
  1283   assumes "a = b"
  1284   shows "(let x = a in t x) = (let x = b in t x)"
  1285   using prems by (rule arg_cong)
  1286 
  1287 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1288 lemma eq_cong2:
  1289   assumes "u = u'"
  1290   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1291   using prems by simp
  1292 
  1293 lemma if_distrib:
  1294   "f (if c then x else y) = (if c then f x else f y)"
  1295   by simp
  1296 
  1297 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1298   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1299 lemma restrict_to_left:
  1300   assumes "x = y"
  1301   shows "(x = z) = (y = z)"
  1302   using prems by simp
  1303 
  1304 
  1305 subsubsection {* Generic cases and induction *}
  1306 
  1307 text {* Rule projections: *}
  1308 
  1309 ML {*
  1310 structure ProjectRule = ProjectRuleFun
  1311 (struct
  1312   val conjunct1 = @{thm conjunct1};
  1313   val conjunct2 = @{thm conjunct2};
  1314   val mp = @{thm mp};
  1315 end)
  1316 *}
  1317 
  1318 constdefs
  1319   induct_forall where "induct_forall P == \<forall>x. P x"
  1320   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1321   induct_equal where "induct_equal x y == x = y"
  1322   induct_conj where "induct_conj A B == A \<and> B"
  1323 
  1324 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1325   by (unfold atomize_all induct_forall_def)
  1326 
  1327 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1328   by (unfold atomize_imp induct_implies_def)
  1329 
  1330 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1331   by (unfold atomize_eq induct_equal_def)
  1332 
  1333 lemma induct_conj_eq:
  1334   includes meta_conjunction_syntax
  1335   shows "(A && B) == Trueprop (induct_conj A B)"
  1336   by (unfold atomize_conj induct_conj_def)
  1337 
  1338 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1339 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1340 lemmas induct_rulify_fallback =
  1341   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1342 
  1343 
  1344 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1345     induct_conj (induct_forall A) (induct_forall B)"
  1346   by (unfold induct_forall_def induct_conj_def) iprover
  1347 
  1348 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1349     induct_conj (induct_implies C A) (induct_implies C B)"
  1350   by (unfold induct_implies_def induct_conj_def) iprover
  1351 
  1352 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1353 proof
  1354   assume r: "induct_conj A B ==> PROP C" and A B
  1355   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1356 next
  1357   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1358   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1359 qed
  1360 
  1361 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1362 
  1363 hide const induct_forall induct_implies induct_equal induct_conj
  1364 
  1365 text {* Method setup. *}
  1366 
  1367 ML {*
  1368   structure InductMethod = InductMethodFun
  1369   (struct
  1370     val cases_default = @{thm case_split}
  1371     val atomize = @{thms induct_atomize}
  1372     val rulify = @{thms induct_rulify}
  1373     val rulify_fallback = @{thms induct_rulify_fallback}
  1374   end);
  1375 *}
  1376 
  1377 setup InductMethod.setup
  1378 
  1379 
  1380 
  1381 subsection {* Other simple lemmas and lemma duplicates *}
  1382 
  1383 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1384   by blast+
  1385 
  1386 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1387   apply (rule iffI)
  1388   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1389   apply (fast dest!: theI')
  1390   apply (fast intro: ext the1_equality [symmetric])
  1391   apply (erule ex1E)
  1392   apply (rule allI)
  1393   apply (rule ex1I)
  1394   apply (erule spec)
  1395   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1396   apply (erule impE)
  1397   apply (rule allI)
  1398   apply (rule_tac P = "xa = x" in case_split_thm)
  1399   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1400   done
  1401 
  1402 lemma mk_left_commute:
  1403   fixes f (infix "\<otimes>" 60)
  1404   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1405           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1406   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1407   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1408 
  1409 lemmas eq_sym_conv = eq_commute
  1410 
  1411 
  1412 subsection {* Basic ML bindings *}
  1413 
  1414 ML {*
  1415 val FalseE = @{thm FalseE}
  1416 val Let_def = @{thm Let_def}
  1417 val TrueI = @{thm TrueI}
  1418 val allE = @{thm allE}
  1419 val allI = @{thm allI}
  1420 val all_dupE = @{thm all_dupE}
  1421 val arg_cong = @{thm arg_cong}
  1422 val box_equals = @{thm box_equals}
  1423 val ccontr = @{thm ccontr}
  1424 val classical = @{thm classical}
  1425 val conjE = @{thm conjE}
  1426 val conjI = @{thm conjI}
  1427 val conjunct1 = @{thm conjunct1}
  1428 val conjunct2 = @{thm conjunct2}
  1429 val disjCI = @{thm disjCI}
  1430 val disjE = @{thm disjE}
  1431 val disjI1 = @{thm disjI1}
  1432 val disjI2 = @{thm disjI2}
  1433 val eq_reflection = @{thm eq_reflection}
  1434 val ex1E = @{thm ex1E}
  1435 val ex1I = @{thm ex1I}
  1436 val ex1_implies_ex = @{thm ex1_implies_ex}
  1437 val exE = @{thm exE}
  1438 val exI = @{thm exI}
  1439 val excluded_middle = @{thm excluded_middle}
  1440 val ext = @{thm ext}
  1441 val fun_cong = @{thm fun_cong}
  1442 val iffD1 = @{thm iffD1}
  1443 val iffD2 = @{thm iffD2}
  1444 val iffI = @{thm iffI}
  1445 val impE = @{thm impE}
  1446 val impI = @{thm impI}
  1447 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1448 val mp = @{thm mp}
  1449 val notE = @{thm notE}
  1450 val notI = @{thm notI}
  1451 val not_all = @{thm not_all}
  1452 val not_ex = @{thm not_ex}
  1453 val not_iff = @{thm not_iff}
  1454 val not_not = @{thm not_not}
  1455 val not_sym = @{thm not_sym}
  1456 val refl = @{thm refl}
  1457 val rev_mp = @{thm rev_mp}
  1458 val spec = @{thm spec}
  1459 val ssubst = @{thm ssubst}
  1460 val subst = @{thm subst}
  1461 val sym = @{thm sym}
  1462 val trans = @{thm trans}
  1463 *}
  1464 
  1465 
  1466 subsection {* Legacy tactics and ML bindings *}
  1467 
  1468 ML {*
  1469 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1470 
  1471 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1472 local
  1473   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1474     | wrong_prem (Bound _) = true
  1475     | wrong_prem _ = false;
  1476   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1477 in
  1478   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1479   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1480 end;
  1481 
  1482 val all_conj_distrib = thm "all_conj_distrib";
  1483 val all_simps = thms "all_simps";
  1484 val atomize_not = thm "atomize_not";
  1485 val case_split = thm "case_split_thm";
  1486 val case_split_thm = thm "case_split_thm"
  1487 val cases_simp = thm "cases_simp";
  1488 val choice_eq = thm "choice_eq"
  1489 val cong = thm "cong"
  1490 val conj_comms = thms "conj_comms";
  1491 val conj_cong = thm "conj_cong";
  1492 val de_Morgan_conj = thm "de_Morgan_conj";
  1493 val de_Morgan_disj = thm "de_Morgan_disj";
  1494 val disj_assoc = thm "disj_assoc";
  1495 val disj_comms = thms "disj_comms";
  1496 val disj_cong = thm "disj_cong";
  1497 val eq_ac = thms "eq_ac";
  1498 val eq_cong2 = thm "eq_cong2"
  1499 val Eq_FalseI = thm "Eq_FalseI";
  1500 val Eq_TrueI = thm "Eq_TrueI";
  1501 val Ex1_def = thm "Ex1_def"
  1502 val ex_disj_distrib = thm "ex_disj_distrib";
  1503 val ex_simps = thms "ex_simps";
  1504 val if_cancel = thm "if_cancel";
  1505 val if_eq_cancel = thm "if_eq_cancel";
  1506 val if_False = thm "if_False";
  1507 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1508 val iff = thm "iff"
  1509 val if_splits = thms "if_splits";
  1510 val if_True = thm "if_True";
  1511 val if_weak_cong = thm "if_weak_cong"
  1512 val imp_all = thm "imp_all";
  1513 val imp_cong = thm "imp_cong";
  1514 val imp_conjL = thm "imp_conjL";
  1515 val imp_conjR = thm "imp_conjR";
  1516 val imp_conv_disj = thm "imp_conv_disj";
  1517 val simp_implies_def = thm "simp_implies_def";
  1518 val simp_thms = thms "simp_thms";
  1519 val split_if = thm "split_if";
  1520 val the1_equality = thm "the1_equality"
  1521 val theI = thm "theI"
  1522 val theI' = thm "theI'"
  1523 val True_implies_equals = thm "True_implies_equals";
  1524 *}
  1525 
  1526 end